src/Pure/library.ML
author paulson
Thu Sep 25 12:09:41 1997 +0200 (1997-09-25)
changeset 3706 e57b5902822f
parent 3699 7c30ab9e25d1
child 3762 f20b071a429a
permissions -rw-r--r--
Generalized and exported biresolution_from_nets_tac to allow the declaration
of Clarify_tac
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, association lists, generic tables, balanced trees,
     8 orders, input / output, timing, filenames, misc functions.
     9 *)
    10 
    11 infix |> ~~ \ \\ orelf ins ins_string ins_int orf andf prefix upto downto
    12       mem mem_int mem_string union union_int union_string  
    13       inter inter_int inter_string subset subset_int subset_string subdir_of;
    14 
    15 
    16 structure Library =
    17 struct
    18 
    19 (** functions **)
    20 
    21 (*handy combinators*)
    22 fun curry f x y = f (x, y);
    23 fun uncurry f (x, y) = f x y;
    24 fun I x = x;
    25 fun K x y = x;
    26 
    27 (*reverse apply*)
    28 fun (x |> f) = f x;
    29 
    30 (*combine two functions forming the union of their domains*)
    31 fun (f orelf g) = fn x => f x handle Match => g x;
    32 
    33 (*application of (infix) operator to its left or right argument*)
    34 fun apl (x, f) y = f (x, y);
    35 fun apr (f, y) x = f (x, y);
    36 
    37 (*functional for pairs*)
    38 fun pairself f (x, y) = (f x, f y);
    39 
    40 (*function exponentiation: f(...(f x)...) with n applications of f*)
    41 fun funpow n f x =
    42   let fun rep (0, x) = x
    43         | rep (n, x) = rep (n - 1, f x)
    44   in rep (n, x) end;
    45 
    46 
    47 
    48 (** stamps **)
    49 
    50 type stamp = unit ref;
    51 val stamp: unit -> stamp = ref;
    52 
    53 
    54 
    55 (** options **)
    56 
    57 datatype 'a option = None | Some of 'a;
    58 
    59 exception OPTION of string;
    60 
    61 fun the (Some x) = x
    62   | the None = raise OPTION "the";
    63 
    64 fun if_none None y = y
    65   | if_none (Some x) _ = x;
    66 
    67 fun is_some (Some _) = true
    68   | is_some None = false;
    69 
    70 fun is_none (Some _) = false
    71   | is_none None = true;
    72 
    73 fun apsome f (Some x) = Some (f x)
    74   | apsome _ None = None;
    75 
    76 
    77 
    78 (** pairs **)
    79 
    80 fun pair x y = (x, y);
    81 fun rpair x y = (y, x);
    82 
    83 fun fst (x, y) = x;
    84 fun snd (x, y) = y;
    85 
    86 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
    87 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
    88 
    89 fun swap (x, y) = (y, x);
    90 
    91 (*apply the function to a component of a pair*)
    92 fun apfst f (x, y) = (f x, y);
    93 fun apsnd f (x, y) = (x, f y);
    94 
    95 
    96 
    97 (** booleans **)
    98 
    99 (* equality *)
   100 
   101 fun equal x y = x = y;
   102 fun not_equal x y = x <> y;
   103 
   104 
   105 (* operators for combining predicates *)
   106 
   107 fun (p orf q) = fn x => p x orelse q x;
   108 
   109 fun (p andf q) = fn x => p x andalso q x;
   110 
   111 fun notf p x = not (p x);
   112 
   113 
   114 (* predicates on lists *)
   115 
   116 fun orl [] = false
   117   | orl (x :: xs) = x orelse orl xs;
   118 
   119 fun andl [] = true
   120   | andl (x :: xs) = x andalso andl xs;
   121 
   122 (*Several object-logics declare theories named List or Option, hiding the
   123   eponymous basis library structures.*)
   124 structure List_ = List
   125 and       Option_ = Option;
   126 
   127 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   128 fun exists (pred: 'a -> bool) : 'a list -> bool =
   129   let fun boolf [] = false
   130         | boolf (x :: xs) = pred x orelse boolf xs
   131   in boolf end;
   132 
   133 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   134 fun forall (pred: 'a -> bool) : 'a list -> bool =
   135   let fun boolf [] = true
   136         | boolf (x :: xs) = pred x andalso boolf xs
   137   in boolf end;
   138 
   139 
   140 (* flags *)
   141 
   142 fun set flag = (flag := true; true);
   143 fun reset flag = (flag := false; false);
   144 fun toggle flag = (flag := not (! flag); ! flag);
   145 
   146 fun setmp flag value f x =
   147   let
   148     val orig_value = ! flag;
   149     fun return y = (flag := orig_value; y);
   150   in
   151     flag := value;
   152     return (f x handle exn => (return (); raise exn))
   153   end;
   154 
   155 
   156 
   157 (** lists **)
   158 
   159 exception LIST of string;
   160 
   161 fun null [] = true
   162   | null (_ :: _) = false;
   163 
   164 fun hd [] = raise LIST "hd"
   165   | hd (x :: _) = x;
   166 
   167 fun tl [] = raise LIST "tl"
   168   | tl (_ :: xs) = xs;
   169 
   170 fun cons x xs = x :: xs;
   171 
   172 
   173 (* fold *)
   174 
   175 (*the following versions of fold are designed to fit nicely with infixes*)
   176 
   177 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   178     for operators that associate to the left (TAIL RECURSIVE)*)
   179 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   180   let fun itl (e, [])  = e
   181         | itl (e, a::l) = itl (f(e, a), l)
   182   in  itl end;
   183 
   184 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   185     for operators that associate to the right (not tail recursive)*)
   186 fun foldr f (l, e) =
   187   let fun itr [] = e
   188         | itr (a::l) = f(a, itr l)
   189   in  itr l  end;
   190 
   191 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   192     for n > 0, operators that associate to the right (not tail recursive)*)
   193 fun foldr1 f l =
   194   let fun itr [x] = x                       (* FIXME [] case: elim warn (?) *)
   195         | itr (x::l) = f(x, itr l)
   196   in  itr l  end;
   197 
   198 
   199 (* basic list functions *)
   200 
   201 (*length of a list, should unquestionably be a standard function*)
   202 local fun length1 (n, [])  = n   (*TAIL RECURSIVE*)
   203         | length1 (n, x :: xs) = length1 (n + 1, xs)
   204 in  fun length l = length1 (0, l) end;
   205 
   206 (*take the first n elements from a list*)
   207 fun take (n, []) = []
   208   | take (n, x :: xs) =
   209       if n > 0 then x :: take (n - 1, xs) else [];
   210 
   211 (*drop the first n elements from a list*)
   212 fun drop (n, []) = []
   213   | drop (n, x :: xs) =
   214       if n > 0 then drop (n - 1, xs) else x :: xs;
   215 
   216 (*return nth element of a list, where 0 designates the first element;
   217   raise EXCEPTION if list too short*)
   218 fun nth_elem NL =
   219   (case drop NL of
   220     [] => raise LIST "nth_elem"
   221   | x :: _ => x);
   222 
   223 (*last element of a list*)
   224 fun last_elem [] = raise LIST "last_elem"
   225   | last_elem [x] = x
   226   | last_elem (_ :: xs) = last_elem xs;
   227 
   228 (*find the position of an element in a list*)
   229 fun find (x, ys) =
   230   let fun f (y :: ys, i) = if x = y then i else f (ys, i + 1)
   231         | f (_, _) = raise LIST "find"
   232   in f (ys, 0) end;
   233 
   234 (*flatten a list of lists to a list*)
   235 fun flat (ls: 'c list list) : 'c list = foldr (op @) (ls, []);
   236 
   237 
   238 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   239   (proc x1; ...; proc xn) for side effects*)
   240 fun seq (proc: 'a -> unit) : 'a list -> unit =
   241   let fun seqf [] = ()
   242         | seqf (x :: xs) = (proc x; seqf xs)
   243   in seqf end;
   244 
   245 
   246 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   247 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   248   | separate _ xs = xs;
   249 
   250 (*make the list [x, x, ..., x] of length n*)
   251 fun replicate n (x: 'a) : 'a list =
   252   let fun rep (0, xs) = xs
   253         | rep (n, xs) = rep (n - 1, x :: xs)
   254   in
   255     if n < 0 then raise LIST "replicate"
   256     else rep (n, [])
   257   end;
   258 
   259 
   260 (* filter *)
   261 
   262 (*copy the list preserving elements that satisfy the predicate*)
   263 fun filter (pred: 'a->bool) : 'a list -> 'a list =
   264   let fun filt [] = []
   265         | filt (x :: xs) = if pred x then x :: filt xs else filt xs
   266   in filt end;
   267 
   268 fun filter_out f = filter (not o f);
   269 
   270 
   271 fun mapfilter (f: 'a -> 'b option) ([]: 'a list) = [] : 'b list
   272   | mapfilter f (x :: xs) =
   273       (case f x of
   274         None => mapfilter f xs
   275       | Some y => y :: mapfilter f xs);
   276 
   277 
   278 fun find_first _ [] = None
   279   | find_first pred (x :: xs) =
   280       if pred x then Some x else find_first pred xs;
   281 
   282 
   283 (* lists of pairs *)
   284 
   285 fun map2 _ ([], []) = []
   286   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   287   | map2 _ _ = raise LIST "map2";
   288 
   289 fun exists2 _ ([], []) = false
   290   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   291   | exists2 _ _ = raise LIST "exists2";
   292 
   293 fun forall2 _ ([], []) = true
   294   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   295   | forall2 _ _ = raise LIST "forall2";
   296 
   297 (*combine two lists forming a list of pairs:
   298   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   299 fun [] ~~ [] = []
   300   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   301   | _ ~~ _ = raise LIST "~~";
   302 
   303 
   304 (*inverse of ~~; the old 'split':
   305   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   306 fun split_list (l: ('a * 'b) list) = (map #1 l, map #2 l);
   307 
   308 
   309 (* prefixes, suffixes *)
   310 
   311 fun [] prefix _ = true
   312   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   313   | _ prefix _ = false;
   314 
   315 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   316    where xi is the first element that does not satisfy the predicate*)
   317 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   318   let fun take (rxs, []) = (rev rxs, [])
   319         | take (rxs, x :: xs) =
   320             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   321   in  take([], xs)  end;
   322 
   323 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   324    where xi is the last element that does not satisfy the predicate*)
   325 fun take_suffix _ [] = ([], [])
   326   | take_suffix pred (x :: xs) =
   327       (case take_suffix pred xs of
   328         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   329       | (prfx, sffx) => (x :: prfx, sffx));
   330 
   331 
   332 
   333 (** integers **)
   334 
   335 fun inc i = (i := ! i + 1; ! i);
   336 fun dec i = (i := ! i - 1; ! i);
   337 
   338 
   339 (* lists of integers *)
   340 
   341 (*make the list [from, from + 1, ..., to]*)
   342 fun (from upto to) =
   343   if from > to then [] else from :: ((from + 1) upto to);
   344 
   345 (*make the list [from, from - 1, ..., to]*)
   346 fun (from downto to) =
   347   if from < to then [] else from :: ((from - 1) downto to);
   348 
   349 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   350 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   351   | downto0 ([], n) = n = ~1;
   352 
   353 
   354 (* convert integers to strings *)
   355 
   356 (*expand the number in the given base;
   357   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   358 fun radixpand (base, num) : int list =
   359   let
   360     fun radix (n, tail) =
   361       if n < base then n :: tail
   362       else radix (n div base, (n mod base) :: tail)
   363   in radix (num, []) end;
   364 
   365 (*expands a number into a string of characters starting from "zerochar";
   366   example: radixstring (2, "0", 8) gives "1000"*)
   367 fun radixstring (base, zerochar, num) =
   368   let val offset = ord zerochar;
   369       fun chrof n = chr (offset + n)
   370   in implode (map chrof (radixpand (base, num))) end;
   371 
   372 
   373 val string_of_int = Int.toString;
   374 
   375 fun string_of_indexname (a,0) = a
   376   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   377 
   378 
   379 (** strings **)
   380 
   381 fun is_letter ch =
   382   ord "A" <= ord ch andalso ord ch <= ord "Z" orelse
   383   ord "a" <= ord ch andalso ord ch <= ord "z";
   384 
   385 fun is_digit ch =
   386   ord "0" <= ord ch andalso ord ch <= ord "9";
   387 
   388 (*letter or _ or prime (')*)
   389 fun is_quasi_letter "_" = true
   390   | is_quasi_letter "'" = true
   391   | is_quasi_letter ch = is_letter ch;
   392 
   393 (*white space: blanks, tabs, newlines, formfeeds*)
   394 val is_blank : string -> bool =
   395   fn " " => true | "\t" => true | "\n" => true | "\^L" => true | "\160" => true
   396     | _ => false;
   397 
   398 val is_letdig = is_quasi_letter orf is_digit;
   399 
   400 (*printable chars*)
   401 fun is_printable c = ord c > ord " " andalso ord c <= ord "~";
   402 
   403 
   404 (*lower all chars of string*)
   405 val to_lower =
   406   let
   407     fun lower ch =
   408       if ch >= "A" andalso ch <= "Z" then
   409         chr (ord ch - ord "A" + ord "a")
   410       else ch;
   411   in implode o (map lower) o explode end;
   412 
   413 
   414 (*enclose in brackets*)
   415 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   416 
   417 (*simple quoting (does not escape special chars)*)
   418 val quote = enclose "\"" "\"";
   419 
   420 (*space_implode "..." (explode "hello"); gives "h...e...l...l...o"*)
   421 fun space_implode a bs = implode (separate a bs);
   422 
   423 val commas = space_implode ", ";
   424 val commas_quote = commas o map quote;
   425 
   426 (*concatenate messages, one per line, into a string*)
   427 val cat_lines = space_implode "\n";
   428 
   429 (*space_explode "." "h.e..l.lo"; gives ["h", "e", "l", "lo"]*)
   430 fun space_explode sep s =
   431   let fun divide [] "" = []
   432         | divide [] part = [part]
   433         | divide (c::s) part =
   434             if c = sep then
   435               (if part = "" then divide s "" else part :: divide s "")
   436             else divide s (part ^ c)
   437   in divide (explode s) "" end;
   438 
   439 
   440 (** lists as sets **)
   441 
   442 (*membership in a list*)
   443 fun x mem [] = false
   444   | x mem (y :: ys) = x = y orelse x mem ys;
   445 
   446 (*membership in a list, optimized version for ints*)
   447 fun (x:int) mem_int [] = false
   448   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   449 
   450 (*membership in a list, optimized version for strings*)
   451 fun (x:string) mem_string [] = false
   452   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   453 
   454 (*generalized membership test*)
   455 fun gen_mem eq (x, []) = false
   456   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   457 
   458 
   459 (*insertion into list if not already there*)
   460 fun (x ins xs) = if x mem xs then xs else x :: xs;
   461 
   462 (*insertion into list, optimized version for ints*)
   463 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   464 
   465 (*insertion into list, optimized version for strings*)
   466 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   467 
   468 (*generalized insertion*)
   469 fun gen_ins eq (x, xs) = if gen_mem eq (x, xs) then xs else x :: xs;
   470 
   471 
   472 (*union of sets represented as lists: no repetitions*)
   473 fun xs union [] = xs
   474   | [] union ys = ys
   475   | (x :: xs) union ys = xs union (x ins ys);
   476 
   477 (*union of sets, optimized version for ints*)
   478 fun (xs:int list) union_int [] = xs
   479   | [] union_int ys = ys
   480   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   481 
   482 (*union of sets, optimized version for strings*)
   483 fun (xs:string list) union_string [] = xs
   484   | [] union_string ys = ys
   485   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   486 
   487 (*generalized union*)
   488 fun gen_union eq (xs, []) = xs
   489   | gen_union eq ([], ys) = ys
   490   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   491 
   492 
   493 (*intersection*)
   494 fun [] inter ys = []
   495   | (x :: xs) inter ys =
   496       if x mem ys then x :: (xs inter ys) else xs inter ys;
   497 
   498 (*intersection, optimized version for ints*)
   499 fun ([]:int list) inter_int ys = []
   500   | (x :: xs) inter_int ys =
   501       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   502 
   503 (*intersection, optimized version for strings *)
   504 fun ([]:string list) inter_string ys = []
   505   | (x :: xs) inter_string ys =
   506       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   507 
   508 
   509 (*subset*)
   510 fun [] subset ys = true
   511   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   512 
   513 (*subset, optimized version for ints*)
   514 fun ([]:int list) subset_int ys = true
   515   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   516 
   517 (*subset, optimized version for strings*)
   518 fun ([]:string list) subset_string ys = true
   519   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   520 
   521 (*set equality for strings*)
   522 fun eq_set_string ((xs:string list), ys) =
   523   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   524 
   525 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   526 
   527 
   528 (*removing an element from a list WITHOUT duplicates*)
   529 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   530   | [] \ x = [];
   531 
   532 fun ys \\ xs = foldl (op \) (ys,xs);
   533 
   534 (*removing an element from a list -- possibly WITH duplicates*)
   535 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   536 
   537 fun gen_rems eq = foldl (gen_rem eq);
   538 
   539 
   540 (*makes a list of the distinct members of the input; preserves order, takes
   541   first of equal elements*)
   542 fun gen_distinct eq lst =
   543   let
   544     val memb = gen_mem eq;
   545 
   546     fun dist (rev_seen, []) = rev rev_seen
   547       | dist (rev_seen, x :: xs) =
   548           if memb (x, rev_seen) then dist (rev_seen, xs)
   549           else dist (x :: rev_seen, xs);
   550   in
   551     dist ([], lst)
   552   end;
   553 
   554 fun distinct l = gen_distinct (op =) l;
   555 
   556 
   557 (*returns the tail beginning with the first repeated element, or []*)
   558 fun findrep [] = []
   559   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   560 
   561 
   562 (*returns a list containing all repeated elements exactly once; preserves
   563   order, takes first of equal elements*)
   564 fun gen_duplicates eq lst =
   565   let
   566     val memb = gen_mem eq;
   567 
   568     fun dups (rev_dups, []) = rev rev_dups
   569       | dups (rev_dups, x :: xs) =
   570           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   571             dups (rev_dups, xs)
   572           else dups (x :: rev_dups, xs);
   573   in
   574     dups ([], lst)
   575   end;
   576 
   577 fun duplicates l = gen_duplicates (op =) l;
   578 
   579 
   580 
   581 (** association lists **)
   582 
   583 (*association list lookup*)
   584 fun assoc ([], key) = None
   585   | assoc ((keyi, xi) :: pairs, key) =
   586       if key = keyi then Some xi else assoc (pairs, key);
   587 
   588 (*association list lookup, optimized version for ints*)
   589 fun assoc_int ([], (key:int)) = None
   590   | assoc_int ((keyi, xi) :: pairs, key) =
   591       if key = keyi then Some xi else assoc_int (pairs, key);
   592 
   593 (*association list lookup, optimized version for strings*)
   594 fun assoc_string ([], (key:string)) = None
   595   | assoc_string ((keyi, xi) :: pairs, key) =
   596       if key = keyi then Some xi else assoc_string (pairs, key);
   597 
   598 (*association list lookup, optimized version for string*ints*)
   599 fun assoc_string_int ([], (key:string*int)) = None
   600   | assoc_string_int ((keyi, xi) :: pairs, key) =
   601       if key = keyi then Some xi else assoc_string_int (pairs, key);
   602 
   603 fun assocs ps x =
   604   (case assoc (ps, x) of
   605     None => []
   606   | Some ys => ys);
   607 
   608 (*two-fold association list lookup*)
   609 fun assoc2 (aal, (key1, key2)) =
   610   (case assoc (aal, key1) of
   611     Some al => assoc (al, key2)
   612   | None => None);
   613 
   614 (*generalized association list lookup*)
   615 fun gen_assoc eq ([], key) = None
   616   | gen_assoc eq ((keyi, xi) :: pairs, key) =
   617       if eq (key, keyi) then Some xi else gen_assoc eq (pairs, key);
   618 
   619 (*association list update*)
   620 fun overwrite (al, p as (key, _)) =
   621   let fun over ((q as (keyi, _)) :: pairs) =
   622             if keyi = key then p :: pairs else q :: (over pairs)
   623         | over [] = [p]
   624   in over al end;
   625 
   626 fun gen_overwrite eq (al, p as (key, _)) =
   627   let fun over ((q as (keyi, _)) :: pairs) =
   628             if eq (keyi, key) then p :: pairs else q :: (over pairs)
   629         | over [] = [p]
   630   in over al end;
   631 
   632 
   633 
   634 (** generic tables **)
   635 
   636 (*Tables are supposed to be 'efficient' encodings of lists of elements distinct
   637   wrt. an equality "eq". The extend and merge operations below are optimized
   638   for long-term space efficiency.*)
   639 
   640 (*append (new) elements to a table*)
   641 fun generic_extend _ _ _ tab [] = tab
   642   | generic_extend eq dest_tab mk_tab tab1 lst2 =
   643       let
   644         val lst1 = dest_tab tab1;
   645         val new_lst2 = gen_rems eq (lst2, lst1);
   646       in
   647         if null new_lst2 then tab1
   648         else mk_tab (lst1 @ new_lst2)
   649       end;
   650 
   651 (*append (new) elements of 2nd table to 1st table*)
   652 fun generic_merge eq dest_tab mk_tab tab1 tab2 =
   653   let
   654     val lst1 = dest_tab tab1;
   655     val lst2 = dest_tab tab2;
   656     val new_lst2 = gen_rems eq (lst2, lst1);
   657   in
   658     if null new_lst2 then tab1
   659     else if gen_subset eq (lst1, lst2) then tab2
   660     else mk_tab (lst1 @ new_lst2)
   661   end;
   662 
   663 
   664 (*lists as tables*)
   665 fun extend_list tab = generic_extend (op =) I I tab;
   666 fun merge_lists tab = generic_merge (op =) I I tab;
   667 
   668 fun merge_rev_lists xs [] = xs
   669   | merge_rev_lists [] ys = ys
   670   | merge_rev_lists xs (y :: ys) =
   671       (if y mem xs then I else cons y) (merge_rev_lists xs ys);
   672 
   673 
   674 
   675 (** balanced trees **)
   676 
   677 exception Balance;      (*indicates non-positive argument to balancing fun*)
   678 
   679 (*balanced folding; avoids deep nesting*)
   680 fun fold_bal f [x] = x
   681   | fold_bal f [] = raise Balance
   682   | fold_bal f xs =
   683       let val k = length xs div 2
   684       in  f (fold_bal f (take(k, xs)),
   685              fold_bal f (drop(k, xs)))
   686       end;
   687 
   688 (*construct something of the form f(...g(...(x)...)) for balanced access*)
   689 fun access_bal (f, g, x) n i =
   690   let fun acc n i =     (*1<=i<=n*)
   691           if n=1 then x else
   692           let val n2 = n div 2
   693           in  if i<=n2 then f (acc n2 i)
   694                        else g (acc (n-n2) (i-n2))
   695           end
   696   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
   697 
   698 (*construct ALL such accesses; could try harder to share recursive calls!*)
   699 fun accesses_bal (f, g, x) n =
   700   let fun acc n =
   701           if n=1 then [x] else
   702           let val n2 = n div 2
   703               val acc2 = acc n2
   704           in  if n-n2=n2 then map f acc2 @ map g acc2
   705                          else map f acc2 @ map g (acc (n-n2)) end
   706   in  if 1<=n then acc n else raise Balance  end;
   707 
   708 
   709 
   710 (** orders **)
   711 
   712 datatype order = LESS | EQUAL | GREATER;
   713 
   714 fun intord (i, j: int) =
   715   if i < j then LESS
   716   else if i = j then EQUAL
   717   else GREATER;
   718 
   719 fun stringord (a, b: string) =
   720   if a < b then LESS
   721   else if a = b then EQUAL
   722   else GREATER;
   723 
   724 
   725 
   726 (** input / output and diagnostics **)
   727 
   728 val cd = OS.FileSys.chDir;
   729 val pwd = OS.FileSys.getDir;
   730 
   731 
   732 local
   733   fun out s =
   734     (TextIO.output (TextIO.stdOut, s); TextIO.flushOut TextIO.stdOut);
   735 
   736   fun lines cs =
   737     (case take_prefix (not_equal "\n") cs of
   738       (cs', []) => [implode cs']
   739     | (cs', _ :: cs'') => implode cs' :: lines cs'');
   740 
   741   fun prefix_lines prfx txt =
   742     txt |> explode |> lines |> map (fn s => prfx ^ s ^ "\n") |> implode;
   743 in
   744 
   745 (*hooks for output channels: normal, warning, error*)
   746 val prs_fn = ref (fn s => out s);
   747 val warning_fn = ref (fn s => out (prefix_lines "### " s));
   748 val error_fn = ref (fn s => out (prefix_lines "*** " s));
   749 
   750 end;
   751 
   752 fun prs s = !prs_fn s;
   753 fun writeln s = prs (s ^ "\n");
   754 
   755 fun warning s = !warning_fn s;
   756 
   757 (*print error message and abort to top level*)
   758 exception ERROR;
   759 fun error_msg s = !error_fn s;
   760 fun error s = (error_msg s; raise ERROR);
   761 fun sys_error msg = (error_msg " !! SYSTEM ERROR !!\n"; error msg);
   762 
   763 fun assert p msg = if p then () else error msg;
   764 fun deny p msg = if p then error msg else ();
   765 
   766 (*Assert pred for every member of l, generating a message if pred fails*)
   767 fun assert_all pred l msg_fn = 
   768   let fun asl [] = ()
   769         | asl (x::xs) = if pred x then asl xs
   770                         else error (msg_fn x)
   771   in  asl l  end;
   772 
   773 
   774 (* handle errors (capturing messages) *)
   775 
   776 datatype 'a error =
   777   Error of string |
   778   OK of 'a;
   779 
   780 fun handle_error f x =
   781   let
   782     val buffer = ref "";
   783     fun capture s = buffer := ! buffer ^ s ^ "\n";
   784     val result = Some (setmp error_fn capture f x) handle ERROR => None;
   785   in
   786     case result of
   787       None => Error (! buffer)
   788     | Some y => OK y
   789   end;
   790 
   791 
   792 (* read / write files *)
   793 
   794 fun read_file name =
   795   let
   796     val instream  = TextIO.openIn name;
   797     val intext = TextIO.inputAll instream;
   798   in
   799     TextIO.closeIn instream;
   800     intext
   801   end;
   802 
   803 fun write_file name txt =
   804   let val outstream = TextIO.openOut name in
   805     TextIO.output (outstream, txt);
   806     TextIO.closeOut outstream
   807   end;
   808 
   809 fun append_file name txt =
   810   let val outstream = TextIO.openAppend name in
   811     TextIO.output (outstream, txt);
   812     TextIO.closeOut outstream
   813   end;
   814 
   815 
   816 (*for the "test" target in IsaMakefiles -- signifies successful termination*)
   817 fun maketest msg =
   818   (writeln msg; write_file "test" "Test examples ran successfully\n");
   819 
   820 
   821 (*print a list surrounded by the brackets lpar and rpar, with comma separator
   822   print nothing for empty list*)
   823 fun print_list (lpar, rpar, pre: 'a -> unit) (l : 'a list) =
   824   let fun prec x = (prs ","; pre x)
   825   in
   826     (case l of
   827       [] => ()
   828     | x::l => (prs lpar; pre x; seq prec l; prs rpar))
   829   end;
   830 
   831 (*print a list of items separated by newlines*)
   832 fun print_list_ln (pre: 'a -> unit) : 'a list -> unit =
   833   seq (fn x => (pre x; writeln ""));
   834 
   835 
   836 val print_int = prs o string_of_int;
   837 
   838 
   839 (* output to LaTeX / xdvi *)
   840 fun latex s =
   841   execute ("( cd /tmp ; echo \"" ^ s ^
   842     "\" | isa2latex -s > $$.tex ; latex $$.tex ; xdvi $$.dvi ; rm $$.* ) > /dev/null &");
   843 
   844 
   845 (** timing **)
   846 
   847 (*unconditional timing function*)
   848 fun timeit x = cond_timeit true x;
   849 
   850 (*timed application function*)
   851 fun timeap f x = timeit (fn () => f x);
   852 
   853 (*timed "use" function, printing filenames*)
   854 fun time_use fname = timeit (fn () =>
   855   (writeln ("\n**** Starting " ^ fname ^ " ****"); use fname;
   856    writeln ("\n**** Finished " ^ fname ^ " ****")));
   857 
   858 (*use the file, but exit with error code if errors found.*)
   859 fun exit_use fname = use fname handle _ => exit 1;
   860 
   861 
   862 (** filenames and paths **)
   863 
   864 (*Convert UNIX filename of the form "path/file" to "path/" and "file";
   865   if filename contains no slash, then it returns "" and "file"*)
   866 val split_filename =
   867   (pairself implode) o take_suffix (not_equal "/") o explode;
   868 
   869 val base_name = #2 o split_filename;
   870 
   871 (*Merge splitted filename (path and file);
   872   if path does not end with one a slash is appended*)
   873 fun tack_on "" name = name
   874   | tack_on path name =
   875       if last_elem (explode path) = "/" then path ^ name
   876       else path ^ "/" ^ name;
   877 
   878 (*Remove the extension of a filename, i.e. the part after the last '.'*)
   879 val remove_ext = implode o #1 o take_suffix (not_equal ".") o explode;
   880 
   881 (*Make relative path to reach an absolute location from a different one*)
   882 fun relative_path cur_path dest_path =
   883   let (*Remove common beginning of both paths and make relative path*)
   884       fun mk_relative [] [] = []
   885         | mk_relative [] ds = ds
   886         | mk_relative cs [] = map (fn _ => "..") cs
   887         | mk_relative (c::cs) (d::ds) =
   888             if c = d then mk_relative cs ds
   889             else ".." :: map (fn _ => "..") cs @ (d::ds);
   890   in if cur_path = "" orelse hd (explode cur_path) <> "/" orelse
   891         dest_path = "" orelse hd (explode dest_path) <> "/" then
   892        error "Relative or empty path passed to relative_path"
   893      else ();
   894      space_implode "/" (mk_relative (space_explode "/" cur_path)
   895                                     (space_explode "/" dest_path))
   896   end;
   897 
   898 (*Determine if absolute path1 is a subdirectory of absolute path2*)
   899 fun path1 subdir_of path2 =
   900   if hd (explode path1) <> "/" orelse hd (explode path2) <> "/" then
   901     error "Relative or empty path passed to subdir_of"
   902   else (space_explode "/" path2) prefix (space_explode "/" path1);
   903 
   904 fun absolute_path cwd file =
   905   let fun rm_points [] result = rev result
   906         | rm_points (".."::ds) result = rm_points ds (tl result)
   907         | rm_points ("."::ds) result = rm_points ds result
   908         | rm_points (d::ds) result = rm_points ds (d::result);
   909   in if file = "" then ""
   910      else if hd (explode file) = "/" then file
   911      else "/" ^ space_implode "/"
   912                   (rm_points (space_explode "/" (tack_on cwd file)) [])
   913   end;
   914 
   915 fun file_exists file = (file_info file <> "");
   916 
   917 
   918 (** misc functions **)
   919 
   920 (*use the keyfun to make a list of (x, key) pairs*)
   921 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
   922   let fun keypair x = (x, keyfun x)
   923   in map keypair end;
   924 
   925 (*given a list of (x, key) pairs and a searchkey
   926   return the list of xs from each pair whose key equals searchkey*)
   927 fun keyfilter [] searchkey = []
   928   | keyfilter ((x, key) :: pairs) searchkey =
   929       if key = searchkey then x :: keyfilter pairs searchkey
   930       else keyfilter pairs searchkey;
   931 
   932 
   933 (*Partition list into elements that satisfy predicate and those that don't.
   934   Preserves order of elements in both lists.*)
   935 fun partition (pred: 'a->bool) (ys: 'a list) : ('a list * 'a list) =
   936     let fun part ([], answer) = answer
   937           | part (x::xs, (ys, ns)) = if pred(x)
   938             then  part (xs, (x::ys, ns))
   939             else  part (xs, (ys, x::ns))
   940     in  part (rev ys, ([], []))  end;
   941 
   942 
   943 fun partition_eq (eq:'a * 'a -> bool) =
   944     let fun part [] = []
   945           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
   946                            in (x::xs)::(part xs') end
   947     in part end;
   948 
   949 
   950 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
   951    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
   952 fun partition_list p i j =
   953   let fun part k xs =
   954             if k>j then
   955               (case xs of [] => []
   956                          | _ => raise LIST "partition_list")
   957             else
   958             let val (ns, rest) = partition (p k) xs;
   959             in  ns :: part(k+1)rest  end
   960   in  part i end;
   961 
   962 
   963 (* sorting *)
   964 
   965 (*insertion sort; stable (does not reorder equal elements)
   966   'less' is less-than test on type 'a*)
   967 fun sort (less: 'a*'a -> bool) =
   968   let fun insert (x, []) = [x]
   969         | insert (x, y::ys) =
   970               if less(y, x) then y :: insert (x, ys) else x::y::ys;
   971       fun sort1 [] = []
   972         | sort1 (x::xs) = insert (x, sort1 xs)
   973   in  sort1  end;
   974 
   975 (*sort strings*)
   976 val sort_strings = sort (op <= : string * string -> bool);
   977 
   978 
   979 (* transitive closure (not Warshall's algorithm) *)
   980 
   981 fun transitive_closure [] = []
   982   | transitive_closure ((x, ys)::ps) =
   983       let val qs = transitive_closure ps
   984           val zs = foldl (fn (zs, y) => assocs qs y union_string zs) (ys, ys)
   985           fun step(u, us) = (u, if x mem_string us then zs union_string us 
   986                                 else us)
   987       in (x, zs) :: map step qs end;
   988 
   989 
   990 (* generating identifiers *)
   991 
   992 local
   993   val a = ord "a" and z = ord "z" and A = ord "A" and Z = ord "Z"
   994   and k0 = ord "0" and k9 = ord "9"
   995 
   996   val seedr = ref 0;
   997 in
   998 
   999 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1000 fun newid n = 
  1001   let fun char i =
  1002                if i<26 then chr (A+i)
  1003           else if i<52 then chr (a+i-26)
  1004           else if i<62 then chr (k0+i-52)
  1005           else if i=62 then "_"
  1006           else  (*i=63*)    "'"
  1007   in  implode (map char (radixpand (64,n)))  end;
  1008 
  1009 (*Freshly generated identifiers with given prefix; MUST start with a letter*)
  1010 fun gensym pre = pre ^ 
  1011                  (#1(newid (!seedr), 
  1012                      seedr := 1+ !seedr))
  1013 
  1014 (*Increment a list of letters like a reversed base 26 number.
  1015   If head is "z", bumps chars in tail.
  1016   Digits are incremented as if they were integers.
  1017   "_" and "'" are not changed.
  1018   For making variants of identifiers.*)
  1019 
  1020 fun bump_int_list(c::cs) = if c="9" then "0" :: bump_int_list cs else
  1021         if k0 <= ord(c) andalso ord(c) < k9 then chr(ord(c)+1) :: cs
  1022         else "1" :: c :: cs
  1023   | bump_int_list([]) = error("bump_int_list: not an identifier");
  1024 
  1025 fun bump_list([], d) = [d]
  1026   | bump_list(["'"], d) = [d, "'"]
  1027   | bump_list("z"::cs, _) = "a" :: bump_list(cs, "a")
  1028   | bump_list("Z"::cs, _) = "A" :: bump_list(cs, "A")
  1029   | bump_list("9"::cs, _) = "0" :: bump_int_list cs
  1030   | bump_list(c::cs, _) = let val k = ord(c)
  1031         in if (a <= k andalso k < z) orelse (A <= k andalso k < Z) orelse
  1032               (k0 <= k andalso k < k9) then chr(k+1) :: cs else
  1033            if c="'" orelse c="_" then c :: bump_list(cs, "") else
  1034                 error("bump_list: not legal in identifier: " ^
  1035                         implode(rev(c::cs)))
  1036         end;
  1037 
  1038 end;
  1039 
  1040 fun bump_string s : string = implode (rev (bump_list(rev(explode s), "")));
  1041 
  1042 
  1043 (* lexical scanning *)
  1044 
  1045 (*scan a list of characters into "words" composed of "letters" (recognized by
  1046   is_let) and separated by any number of non-"letters"*)
  1047 fun scanwords is_let cs =
  1048   let fun scan1 [] = []
  1049         | scan1 cs =
  1050             let val (lets, rest) = take_prefix is_let cs
  1051             in implode lets :: scanwords is_let rest end;
  1052   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1053 
  1054 end;
  1055 
  1056 (*Variable-branching trees: for proof terms*)
  1057 datatype 'a mtree = Join of 'a * 'a mtree list;
  1058 
  1059 open Library;