src/HOL/Rings.thy
author paulson <lp15@cam.ac.uk>
Tue Jun 30 13:56:16 2015 +0100 (2015-06-30)
changeset 60615 e5fa1d5d3952
parent 60570 7ed2cde6806d
child 60685 cb21b7022b00
permissions -rw-r--r--
Useful lemmas. The theorem concerning swapping the variables in a double integral.
     1 (*  Title:      HOL/Rings.thy
     2     Author:     Gertrud Bauer
     3     Author:     Steven Obua
     4     Author:     Tobias Nipkow
     5     Author:     Lawrence C Paulson
     6     Author:     Markus Wenzel
     7     Author:     Jeremy Avigad
     8 *)
     9 
    10 section {* Rings *}
    11 
    12 theory Rings
    13 imports Groups
    14 begin
    15 
    16 class semiring = ab_semigroup_add + semigroup_mult +
    17   assumes distrib_right[algebra_simps]: "(a + b) * c = a * c + b * c"
    18   assumes distrib_left[algebra_simps]: "a * (b + c) = a * b + a * c"
    19 begin
    20 
    21 text{*For the @{text combine_numerals} simproc*}
    22 lemma combine_common_factor:
    23   "a * e + (b * e + c) = (a + b) * e + c"
    24 by (simp add: distrib_right ac_simps)
    25 
    26 end
    27 
    28 class mult_zero = times + zero +
    29   assumes mult_zero_left [simp]: "0 * a = 0"
    30   assumes mult_zero_right [simp]: "a * 0 = 0"
    31 begin
    32 
    33 lemma mult_not_zero:
    34   "a * b \<noteq> 0 \<Longrightarrow> a \<noteq> 0 \<and> b \<noteq> 0"
    35   by auto
    36 
    37 end
    38 
    39 class semiring_0 = semiring + comm_monoid_add + mult_zero
    40 
    41 class semiring_0_cancel = semiring + cancel_comm_monoid_add
    42 begin
    43 
    44 subclass semiring_0
    45 proof
    46   fix a :: 'a
    47   have "0 * a + 0 * a = 0 * a + 0" by (simp add: distrib_right [symmetric])
    48   thus "0 * a = 0" by (simp only: add_left_cancel)
    49 next
    50   fix a :: 'a
    51   have "a * 0 + a * 0 = a * 0 + 0" by (simp add: distrib_left [symmetric])
    52   thus "a * 0 = 0" by (simp only: add_left_cancel)
    53 qed
    54 
    55 end
    56 
    57 class comm_semiring = ab_semigroup_add + ab_semigroup_mult +
    58   assumes distrib: "(a + b) * c = a * c + b * c"
    59 begin
    60 
    61 subclass semiring
    62 proof
    63   fix a b c :: 'a
    64   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    65   have "a * (b + c) = (b + c) * a" by (simp add: ac_simps)
    66   also have "... = b * a + c * a" by (simp only: distrib)
    67   also have "... = a * b + a * c" by (simp add: ac_simps)
    68   finally show "a * (b + c) = a * b + a * c" by blast
    69 qed
    70 
    71 end
    72 
    73 class comm_semiring_0 = comm_semiring + comm_monoid_add + mult_zero
    74 begin
    75 
    76 subclass semiring_0 ..
    77 
    78 end
    79 
    80 class comm_semiring_0_cancel = comm_semiring + cancel_comm_monoid_add
    81 begin
    82 
    83 subclass semiring_0_cancel ..
    84 
    85 subclass comm_semiring_0 ..
    86 
    87 end
    88 
    89 class zero_neq_one = zero + one +
    90   assumes zero_neq_one [simp]: "0 \<noteq> 1"
    91 begin
    92 
    93 lemma one_neq_zero [simp]: "1 \<noteq> 0"
    94 by (rule not_sym) (rule zero_neq_one)
    95 
    96 definition of_bool :: "bool \<Rightarrow> 'a"
    97 where
    98   "of_bool p = (if p then 1 else 0)"
    99 
   100 lemma of_bool_eq [simp, code]:
   101   "of_bool False = 0"
   102   "of_bool True = 1"
   103   by (simp_all add: of_bool_def)
   104 
   105 lemma of_bool_eq_iff:
   106   "of_bool p = of_bool q \<longleftrightarrow> p = q"
   107   by (simp add: of_bool_def)
   108 
   109 lemma split_of_bool [split]:
   110   "P (of_bool p) \<longleftrightarrow> (p \<longrightarrow> P 1) \<and> (\<not> p \<longrightarrow> P 0)"
   111   by (cases p) simp_all
   112 
   113 lemma split_of_bool_asm:
   114   "P (of_bool p) \<longleftrightarrow> \<not> (p \<and> \<not> P 1 \<or> \<not> p \<and> \<not> P 0)"
   115   by (cases p) simp_all
   116 
   117 end
   118 
   119 class semiring_1 = zero_neq_one + semiring_0 + monoid_mult
   120 
   121 text {* Abstract divisibility *}
   122 
   123 class dvd = times
   124 begin
   125 
   126 definition dvd :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "dvd" 50) where
   127   "b dvd a \<longleftrightarrow> (\<exists>k. a = b * k)"
   128 
   129 lemma dvdI [intro?]: "a = b * k \<Longrightarrow> b dvd a"
   130   unfolding dvd_def ..
   131 
   132 lemma dvdE [elim?]: "b dvd a \<Longrightarrow> (\<And>k. a = b * k \<Longrightarrow> P) \<Longrightarrow> P"
   133   unfolding dvd_def by blast
   134 
   135 end
   136 
   137 context comm_monoid_mult
   138 begin
   139 
   140 subclass dvd .
   141 
   142 lemma dvd_refl [simp]:
   143   "a dvd a"
   144 proof
   145   show "a = a * 1" by simp
   146 qed
   147 
   148 lemma dvd_trans:
   149   assumes "a dvd b" and "b dvd c"
   150   shows "a dvd c"
   151 proof -
   152   from assms obtain v where "b = a * v" by (auto elim!: dvdE)
   153   moreover from assms obtain w where "c = b * w" by (auto elim!: dvdE)
   154   ultimately have "c = a * (v * w)" by (simp add: mult.assoc)
   155   then show ?thesis ..
   156 qed
   157 
   158 lemma one_dvd [simp]:
   159   "1 dvd a"
   160   by (auto intro!: dvdI)
   161 
   162 lemma dvd_mult [simp]:
   163   "a dvd c \<Longrightarrow> a dvd (b * c)"
   164   by (auto intro!: mult.left_commute dvdI elim!: dvdE)
   165 
   166 lemma dvd_mult2 [simp]:
   167   "a dvd b \<Longrightarrow> a dvd (b * c)"
   168   using dvd_mult [of a b c] by (simp add: ac_simps)
   169 
   170 lemma dvd_triv_right [simp]:
   171   "a dvd b * a"
   172   by (rule dvd_mult) (rule dvd_refl)
   173 
   174 lemma dvd_triv_left [simp]:
   175   "a dvd a * b"
   176   by (rule dvd_mult2) (rule dvd_refl)
   177 
   178 lemma mult_dvd_mono:
   179   assumes "a dvd b"
   180     and "c dvd d"
   181   shows "a * c dvd b * d"
   182 proof -
   183   from `a dvd b` obtain b' where "b = a * b'" ..
   184   moreover from `c dvd d` obtain d' where "d = c * d'" ..
   185   ultimately have "b * d = (a * c) * (b' * d')" by (simp add: ac_simps)
   186   then show ?thesis ..
   187 qed
   188 
   189 lemma dvd_mult_left:
   190   "a * b dvd c \<Longrightarrow> a dvd c"
   191   by (simp add: dvd_def mult.assoc) blast
   192 
   193 lemma dvd_mult_right:
   194   "a * b dvd c \<Longrightarrow> b dvd c"
   195   using dvd_mult_left [of b a c] by (simp add: ac_simps)
   196 
   197 end
   198 
   199 class comm_semiring_1 = zero_neq_one + comm_semiring_0 + comm_monoid_mult
   200 begin
   201 
   202 subclass semiring_1 ..
   203 
   204 lemma dvd_0_left_iff [simp]:
   205   "0 dvd a \<longleftrightarrow> a = 0"
   206   by (auto intro: dvd_refl elim!: dvdE)
   207 
   208 lemma dvd_0_right [iff]:
   209   "a dvd 0"
   210 proof
   211   show "0 = a * 0" by simp
   212 qed
   213 
   214 lemma dvd_0_left:
   215   "0 dvd a \<Longrightarrow> a = 0"
   216   by simp
   217 
   218 lemma dvd_add [simp]:
   219   assumes "a dvd b" and "a dvd c"
   220   shows "a dvd (b + c)"
   221 proof -
   222   from `a dvd b` obtain b' where "b = a * b'" ..
   223   moreover from `a dvd c` obtain c' where "c = a * c'" ..
   224   ultimately have "b + c = a * (b' + c')" by (simp add: distrib_left)
   225   then show ?thesis ..
   226 qed
   227 
   228 end
   229 
   230 class semiring_1_cancel = semiring + cancel_comm_monoid_add
   231   + zero_neq_one + monoid_mult
   232 begin
   233 
   234 subclass semiring_0_cancel ..
   235 
   236 subclass semiring_1 ..
   237 
   238 end
   239 
   240 class comm_semiring_1_cancel = comm_semiring + cancel_comm_monoid_add +
   241                                zero_neq_one + comm_monoid_mult +
   242   assumes right_diff_distrib' [algebra_simps]: "a * (b - c) = a * b - a * c"
   243 begin
   244 
   245 subclass semiring_1_cancel ..
   246 subclass comm_semiring_0_cancel ..
   247 subclass comm_semiring_1 ..
   248 
   249 lemma left_diff_distrib' [algebra_simps]:
   250   "(b - c) * a = b * a - c * a"
   251   by (simp add: algebra_simps)
   252 
   253 lemma dvd_add_times_triv_left_iff [simp]:
   254   "a dvd c * a + b \<longleftrightarrow> a dvd b"
   255 proof -
   256   have "a dvd a * c + b \<longleftrightarrow> a dvd b" (is "?P \<longleftrightarrow> ?Q")
   257   proof
   258     assume ?Q then show ?P by simp
   259   next
   260     assume ?P
   261     then obtain d where "a * c + b = a * d" ..
   262     then have "a * c + b - a * c = a * d - a * c" by simp
   263     then have "b = a * d - a * c" by simp
   264     then have "b = a * (d - c)" by (simp add: algebra_simps)
   265     then show ?Q ..
   266   qed
   267   then show "a dvd c * a + b \<longleftrightarrow> a dvd b" by (simp add: ac_simps)
   268 qed
   269 
   270 lemma dvd_add_times_triv_right_iff [simp]:
   271   "a dvd b + c * a \<longleftrightarrow> a dvd b"
   272   using dvd_add_times_triv_left_iff [of a c b] by (simp add: ac_simps)
   273 
   274 lemma dvd_add_triv_left_iff [simp]:
   275   "a dvd a + b \<longleftrightarrow> a dvd b"
   276   using dvd_add_times_triv_left_iff [of a 1 b] by simp
   277 
   278 lemma dvd_add_triv_right_iff [simp]:
   279   "a dvd b + a \<longleftrightarrow> a dvd b"
   280   using dvd_add_times_triv_right_iff [of a b 1] by simp
   281 
   282 lemma dvd_add_right_iff:
   283   assumes "a dvd b"
   284   shows "a dvd b + c \<longleftrightarrow> a dvd c" (is "?P \<longleftrightarrow> ?Q")
   285 proof
   286   assume ?P then obtain d where "b + c = a * d" ..
   287   moreover from `a dvd b` obtain e where "b = a * e" ..
   288   ultimately have "a * e + c = a * d" by simp
   289   then have "a * e + c - a * e = a * d - a * e" by simp
   290   then have "c = a * d - a * e" by simp
   291   then have "c = a * (d - e)" by (simp add: algebra_simps)
   292   then show ?Q ..
   293 next
   294   assume ?Q with assms show ?P by simp
   295 qed
   296 
   297 lemma dvd_add_left_iff:
   298   assumes "a dvd c"
   299   shows "a dvd b + c \<longleftrightarrow> a dvd b"
   300   using assms dvd_add_right_iff [of a c b] by (simp add: ac_simps)
   301 
   302 end
   303 
   304 class ring = semiring + ab_group_add
   305 begin
   306 
   307 subclass semiring_0_cancel ..
   308 
   309 text {* Distribution rules *}
   310 
   311 lemma minus_mult_left: "- (a * b) = - a * b"
   312 by (rule minus_unique) (simp add: distrib_right [symmetric])
   313 
   314 lemma minus_mult_right: "- (a * b) = a * - b"
   315 by (rule minus_unique) (simp add: distrib_left [symmetric])
   316 
   317 text{*Extract signs from products*}
   318 lemmas mult_minus_left [simp] = minus_mult_left [symmetric]
   319 lemmas mult_minus_right [simp] = minus_mult_right [symmetric]
   320 
   321 lemma minus_mult_minus [simp]: "- a * - b = a * b"
   322 by simp
   323 
   324 lemma minus_mult_commute: "- a * b = a * - b"
   325 by simp
   326 
   327 lemma right_diff_distrib [algebra_simps]:
   328   "a * (b - c) = a * b - a * c"
   329   using distrib_left [of a b "-c "] by simp
   330 
   331 lemma left_diff_distrib [algebra_simps]:
   332   "(a - b) * c = a * c - b * c"
   333   using distrib_right [of a "- b" c] by simp
   334 
   335 lemmas ring_distribs =
   336   distrib_left distrib_right left_diff_distrib right_diff_distrib
   337 
   338 lemma eq_add_iff1:
   339   "a * e + c = b * e + d \<longleftrightarrow> (a - b) * e + c = d"
   340 by (simp add: algebra_simps)
   341 
   342 lemma eq_add_iff2:
   343   "a * e + c = b * e + d \<longleftrightarrow> c = (b - a) * e + d"
   344 by (simp add: algebra_simps)
   345 
   346 end
   347 
   348 lemmas ring_distribs =
   349   distrib_left distrib_right left_diff_distrib right_diff_distrib
   350 
   351 class comm_ring = comm_semiring + ab_group_add
   352 begin
   353 
   354 subclass ring ..
   355 subclass comm_semiring_0_cancel ..
   356 
   357 lemma square_diff_square_factored:
   358   "x * x - y * y = (x + y) * (x - y)"
   359   by (simp add: algebra_simps)
   360 
   361 end
   362 
   363 class ring_1 = ring + zero_neq_one + monoid_mult
   364 begin
   365 
   366 subclass semiring_1_cancel ..
   367 
   368 lemma square_diff_one_factored:
   369   "x * x - 1 = (x + 1) * (x - 1)"
   370   by (simp add: algebra_simps)
   371 
   372 end
   373 
   374 class comm_ring_1 = comm_ring + zero_neq_one + comm_monoid_mult
   375 begin
   376 
   377 subclass ring_1 ..
   378 subclass comm_semiring_1_cancel
   379   by unfold_locales (simp add: algebra_simps)
   380 
   381 lemma dvd_minus_iff [simp]: "x dvd - y \<longleftrightarrow> x dvd y"
   382 proof
   383   assume "x dvd - y"
   384   then have "x dvd - 1 * - y" by (rule dvd_mult)
   385   then show "x dvd y" by simp
   386 next
   387   assume "x dvd y"
   388   then have "x dvd - 1 * y" by (rule dvd_mult)
   389   then show "x dvd - y" by simp
   390 qed
   391 
   392 lemma minus_dvd_iff [simp]: "- x dvd y \<longleftrightarrow> x dvd y"
   393 proof
   394   assume "- x dvd y"
   395   then obtain k where "y = - x * k" ..
   396   then have "y = x * - k" by simp
   397   then show "x dvd y" ..
   398 next
   399   assume "x dvd y"
   400   then obtain k where "y = x * k" ..
   401   then have "y = - x * - k" by simp
   402   then show "- x dvd y" ..
   403 qed
   404 
   405 lemma dvd_diff [simp]:
   406   "x dvd y \<Longrightarrow> x dvd z \<Longrightarrow> x dvd (y - z)"
   407   using dvd_add [of x y "- z"] by simp
   408 
   409 end
   410 
   411 class semiring_no_zero_divisors = semiring_0 +
   412   assumes no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
   413 begin
   414 
   415 lemma divisors_zero:
   416   assumes "a * b = 0"
   417   shows "a = 0 \<or> b = 0"
   418 proof (rule classical)
   419   assume "\<not> (a = 0 \<or> b = 0)"
   420   then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   421   with no_zero_divisors have "a * b \<noteq> 0" by blast
   422   with assms show ?thesis by simp
   423 qed
   424 
   425 lemma mult_eq_0_iff [simp]:
   426   shows "a * b = 0 \<longleftrightarrow> a = 0 \<or> b = 0"
   427 proof (cases "a = 0 \<or> b = 0")
   428   case False then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   429     then show ?thesis using no_zero_divisors by simp
   430 next
   431   case True then show ?thesis by auto
   432 qed
   433 
   434 end
   435 
   436 class semiring_no_zero_divisors_cancel = semiring_no_zero_divisors +
   437   assumes mult_cancel_right [simp]: "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   438     and mult_cancel_left [simp]: "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   439 begin
   440 
   441 lemma mult_left_cancel:
   442   "c \<noteq> 0 \<Longrightarrow> c * a = c * b \<longleftrightarrow> a = b"
   443   by simp
   444 
   445 lemma mult_right_cancel:
   446   "c \<noteq> 0 \<Longrightarrow> a * c = b * c \<longleftrightarrow> a = b"
   447   by simp
   448 
   449 end
   450 
   451 class ring_no_zero_divisors = ring + semiring_no_zero_divisors
   452 begin
   453 
   454 subclass semiring_no_zero_divisors_cancel
   455 proof
   456   fix a b c
   457   have "a * c = b * c \<longleftrightarrow> (a - b) * c = 0"
   458     by (simp add: algebra_simps)
   459   also have "\<dots> \<longleftrightarrow> c = 0 \<or> a = b"
   460     by auto
   461   finally show "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b" .
   462   have "c * a = c * b \<longleftrightarrow> c * (a - b) = 0"
   463     by (simp add: algebra_simps)
   464   also have "\<dots> \<longleftrightarrow> c = 0 \<or> a = b"
   465     by auto
   466   finally show "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b" .
   467 qed
   468 
   469 end
   470 
   471 class ring_1_no_zero_divisors = ring_1 + ring_no_zero_divisors
   472 begin
   473 
   474 lemma square_eq_1_iff:
   475   "x * x = 1 \<longleftrightarrow> x = 1 \<or> x = - 1"
   476 proof -
   477   have "(x - 1) * (x + 1) = x * x - 1"
   478     by (simp add: algebra_simps)
   479   hence "x * x = 1 \<longleftrightarrow> (x - 1) * (x + 1) = 0"
   480     by simp
   481   thus ?thesis
   482     by (simp add: eq_neg_iff_add_eq_0)
   483 qed
   484 
   485 lemma mult_cancel_right1 [simp]:
   486   "c = b * c \<longleftrightarrow> c = 0 \<or> b = 1"
   487 by (insert mult_cancel_right [of 1 c b], force)
   488 
   489 lemma mult_cancel_right2 [simp]:
   490   "a * c = c \<longleftrightarrow> c = 0 \<or> a = 1"
   491 by (insert mult_cancel_right [of a c 1], simp)
   492 
   493 lemma mult_cancel_left1 [simp]:
   494   "c = c * b \<longleftrightarrow> c = 0 \<or> b = 1"
   495 by (insert mult_cancel_left [of c 1 b], force)
   496 
   497 lemma mult_cancel_left2 [simp]:
   498   "c * a = c \<longleftrightarrow> c = 0 \<or> a = 1"
   499 by (insert mult_cancel_left [of c a 1], simp)
   500 
   501 end
   502 
   503 class semidom = comm_semiring_1_cancel + semiring_no_zero_divisors
   504 
   505 class idom = comm_ring_1 + semiring_no_zero_divisors
   506 begin
   507 
   508 subclass semidom ..
   509 
   510 subclass ring_1_no_zero_divisors ..
   511 
   512 lemma dvd_mult_cancel_right [simp]:
   513   "a * c dvd b * c \<longleftrightarrow> c = 0 \<or> a dvd b"
   514 proof -
   515   have "a * c dvd b * c \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   516     unfolding dvd_def by (simp add: ac_simps)
   517   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   518     unfolding dvd_def by simp
   519   finally show ?thesis .
   520 qed
   521 
   522 lemma dvd_mult_cancel_left [simp]:
   523   "c * a dvd c * b \<longleftrightarrow> c = 0 \<or> a dvd b"
   524 proof -
   525   have "c * a dvd c * b \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   526     unfolding dvd_def by (simp add: ac_simps)
   527   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   528     unfolding dvd_def by simp
   529   finally show ?thesis .
   530 qed
   531 
   532 lemma square_eq_iff: "a * a = b * b \<longleftrightarrow> a = b \<or> a = - b"
   533 proof
   534   assume "a * a = b * b"
   535   then have "(a - b) * (a + b) = 0"
   536     by (simp add: algebra_simps)
   537   then show "a = b \<or> a = - b"
   538     by (simp add: eq_neg_iff_add_eq_0)
   539 next
   540   assume "a = b \<or> a = - b"
   541   then show "a * a = b * b" by auto
   542 qed
   543 
   544 end
   545 
   546 text {*
   547   The theory of partially ordered rings is taken from the books:
   548   \begin{itemize}
   549   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979
   550   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
   551   \end{itemize}
   552   Most of the used notions can also be looked up in
   553   \begin{itemize}
   554   \item @{url "http://www.mathworld.com"} by Eric Weisstein et. al.
   555   \item \emph{Algebra I} by van der Waerden, Springer.
   556   \end{itemize}
   557 *}
   558 
   559 class divide =
   560   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "div" 70)
   561 
   562 setup {* Sign.add_const_constraint (@{const_name "divide"}, SOME @{typ "'a \<Rightarrow> 'a \<Rightarrow> 'a"}) *}
   563 
   564 context semiring
   565 begin
   566 
   567 lemma [field_simps]:
   568   shows distrib_left_NO_MATCH: "NO_MATCH (x div y) a \<Longrightarrow> a * (b + c) = a * b + a * c"
   569     and distrib_right_NO_MATCH: "NO_MATCH (x div y) c \<Longrightarrow> (a + b) * c = a * c + b * c"
   570   by (rule distrib_left distrib_right)+
   571 
   572 end
   573 
   574 context ring
   575 begin
   576 
   577 lemma [field_simps]:
   578   shows left_diff_distrib_NO_MATCH: "NO_MATCH (x div y) c \<Longrightarrow> (a - b) * c = a * c - b * c"
   579     and right_diff_distrib_NO_MATCH: "NO_MATCH (x div y) a \<Longrightarrow> a * (b - c) = a * b - a * c"
   580   by (rule left_diff_distrib right_diff_distrib)+
   581 
   582 end
   583 
   584 setup {* Sign.add_const_constraint (@{const_name "divide"}, SOME @{typ "'a::divide \<Rightarrow> 'a \<Rightarrow> 'a"}) *}
   585 
   586 class semidom_divide = semidom + divide +
   587   assumes nonzero_mult_divide_cancel_right [simp]: "b \<noteq> 0 \<Longrightarrow> (a * b) div b = a"
   588   assumes divide_zero [simp]: "a div 0 = 0"
   589 begin
   590 
   591 lemma nonzero_mult_divide_cancel_left [simp]:
   592   "a \<noteq> 0 \<Longrightarrow> (a * b) div a = b"
   593   using nonzero_mult_divide_cancel_right [of a b] by (simp add: ac_simps)
   594 
   595 subclass semiring_no_zero_divisors_cancel
   596 proof
   597   fix a b c
   598   { fix a b c
   599     show "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   600     proof (cases "c = 0")
   601       case True then show ?thesis by simp
   602     next
   603       case False
   604       { assume "a * c = b * c"
   605         then have "a * c div c = b * c div c"
   606           by simp
   607         with False have "a = b"
   608           by simp
   609       } then show ?thesis by auto
   610     qed
   611   }
   612   from this [of a c b]
   613   show "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   614     by (simp add: ac_simps)
   615 qed
   616 
   617 lemma div_self [simp]:
   618   assumes "a \<noteq> 0"
   619   shows "a div a = 1"
   620   using assms nonzero_mult_divide_cancel_left [of a 1] by simp
   621 
   622 lemma divide_zero_left [simp]:
   623   "0 div a = 0"
   624 proof (cases "a = 0")
   625   case True then show ?thesis by simp
   626 next
   627   case False then have "a * 0 div a = 0"
   628     by (rule nonzero_mult_divide_cancel_left)
   629   then show ?thesis by simp
   630 qed 
   631 
   632 end
   633 
   634 class idom_divide = idom + semidom_divide
   635 
   636 class algebraic_semidom = semidom_divide
   637 begin
   638 
   639 lemma dvd_div_mult_self [simp]:
   640   "a dvd b \<Longrightarrow> b div a * a = b"
   641   by (cases "a = 0") (auto elim: dvdE simp add: ac_simps)
   642 
   643 lemma dvd_mult_div_cancel [simp]:
   644   "a dvd b \<Longrightarrow> a * (b div a) = b"
   645   using dvd_div_mult_self [of a b] by (simp add: ac_simps)
   646 
   647 lemma div_mult_swap:
   648   assumes "c dvd b"
   649   shows "a * (b div c) = (a * b) div c"
   650 proof (cases "c = 0")
   651   case True then show ?thesis by simp
   652 next
   653   case False from assms obtain d where "b = c * d" ..
   654   moreover from False have "a * divide (d * c) c = ((a * d) * c) div c"
   655     by simp
   656   ultimately show ?thesis by (simp add: ac_simps)
   657 qed
   658 
   659 lemma dvd_div_mult:
   660   assumes "c dvd b"
   661   shows "b div c * a = (b * a) div c"
   662   using assms div_mult_swap [of c b a] by (simp add: ac_simps)
   663 
   664 lemma dvd_div_mult2_eq:
   665   assumes "b * c dvd a"
   666   shows "a div (b * c) = a div b div c"
   667 using assms proof
   668   fix k
   669   assume "a = b * c * k"
   670   then show ?thesis
   671     by (cases "b = 0 \<or> c = 0") (auto, simp add: ac_simps)
   672 qed
   673 
   674 
   675 text \<open>Units: invertible elements in a ring\<close>
   676 
   677 abbreviation is_unit :: "'a \<Rightarrow> bool"
   678 where
   679   "is_unit a \<equiv> a dvd 1"
   680 
   681 lemma not_is_unit_0 [simp]:
   682   "\<not> is_unit 0"
   683   by simp
   684 
   685 lemma unit_imp_dvd [dest]:
   686   "is_unit b \<Longrightarrow> b dvd a"
   687   by (rule dvd_trans [of _ 1]) simp_all
   688 
   689 lemma unit_dvdE:
   690   assumes "is_unit a"
   691   obtains c where "a \<noteq> 0" and "b = a * c"
   692 proof -
   693   from assms have "a dvd b" by auto
   694   then obtain c where "b = a * c" ..
   695   moreover from assms have "a \<noteq> 0" by auto
   696   ultimately show thesis using that by blast
   697 qed
   698 
   699 lemma dvd_unit_imp_unit:
   700   "a dvd b \<Longrightarrow> is_unit b \<Longrightarrow> is_unit a"
   701   by (rule dvd_trans)
   702 
   703 lemma unit_div_1_unit [simp, intro]:
   704   assumes "is_unit a"
   705   shows "is_unit (1 div a)"
   706 proof -
   707   from assms have "1 = 1 div a * a" by simp
   708   then show "is_unit (1 div a)" by (rule dvdI)
   709 qed
   710 
   711 lemma is_unitE [elim?]:
   712   assumes "is_unit a"
   713   obtains b where "a \<noteq> 0" and "b \<noteq> 0"
   714     and "is_unit b" and "1 div a = b" and "1 div b = a"
   715     and "a * b = 1" and "c div a = c * b"
   716 proof (rule that)
   717   def b \<equiv> "1 div a"
   718   then show "1 div a = b" by simp
   719   from b_def `is_unit a` show "is_unit b" by simp
   720   from `is_unit a` and `is_unit b` show "a \<noteq> 0" and "b \<noteq> 0" by auto
   721   from b_def `is_unit a` show "a * b = 1" by simp
   722   then have "1 = a * b" ..
   723   with b_def `b \<noteq> 0` show "1 div b = a" by simp
   724   from `is_unit a` have "a dvd c" ..
   725   then obtain d where "c = a * d" ..
   726   with `a \<noteq> 0` `a * b = 1` show "c div a = c * b"
   727     by (simp add: mult.assoc mult.left_commute [of a])
   728 qed
   729 
   730 lemma unit_prod [intro]:
   731   "is_unit a \<Longrightarrow> is_unit b \<Longrightarrow> is_unit (a * b)"
   732   by (subst mult_1_left [of 1, symmetric]) (rule mult_dvd_mono)
   733 
   734 lemma unit_div [intro]:
   735   "is_unit a \<Longrightarrow> is_unit b \<Longrightarrow> is_unit (a div b)"
   736   by (erule is_unitE [of b a]) (simp add: ac_simps unit_prod)
   737 
   738 lemma mult_unit_dvd_iff:
   739   assumes "is_unit b"
   740   shows "a * b dvd c \<longleftrightarrow> a dvd c"
   741 proof
   742   assume "a * b dvd c"
   743   with assms show "a dvd c"
   744     by (simp add: dvd_mult_left)
   745 next
   746   assume "a dvd c"
   747   then obtain k where "c = a * k" ..
   748   with assms have "c = (a * b) * (1 div b * k)"
   749     by (simp add: mult_ac)
   750   then show "a * b dvd c" by (rule dvdI)
   751 qed
   752 
   753 lemma dvd_mult_unit_iff:
   754   assumes "is_unit b"
   755   shows "a dvd c * b \<longleftrightarrow> a dvd c"
   756 proof
   757   assume "a dvd c * b"
   758   with assms have "c * b dvd c * (b * (1 div b))"
   759     by (subst mult_assoc [symmetric]) simp
   760   also from `is_unit b` have "b * (1 div b) = 1" by (rule is_unitE) simp
   761   finally have "c * b dvd c" by simp
   762   with `a dvd c * b` show "a dvd c" by (rule dvd_trans)
   763 next
   764   assume "a dvd c"
   765   then show "a dvd c * b" by simp
   766 qed
   767 
   768 lemma div_unit_dvd_iff:
   769   "is_unit b \<Longrightarrow> a div b dvd c \<longleftrightarrow> a dvd c"
   770   by (erule is_unitE [of _ a]) (auto simp add: mult_unit_dvd_iff)
   771 
   772 lemma dvd_div_unit_iff:
   773   "is_unit b \<Longrightarrow> a dvd c div b \<longleftrightarrow> a dvd c"
   774   by (erule is_unitE [of _ c]) (simp add: dvd_mult_unit_iff)
   775 
   776 lemmas unit_dvd_iff = mult_unit_dvd_iff div_unit_dvd_iff
   777   dvd_mult_unit_iff dvd_div_unit_iff -- \<open>FIXME consider fact collection\<close>
   778 
   779 lemma unit_mult_div_div [simp]:
   780   "is_unit a \<Longrightarrow> b * (1 div a) = b div a"
   781   by (erule is_unitE [of _ b]) simp
   782 
   783 lemma unit_div_mult_self [simp]:
   784   "is_unit a \<Longrightarrow> b div a * a = b"
   785   by (rule dvd_div_mult_self) auto
   786 
   787 lemma unit_div_1_div_1 [simp]:
   788   "is_unit a \<Longrightarrow> 1 div (1 div a) = a"
   789   by (erule is_unitE) simp
   790 
   791 lemma unit_div_mult_swap:
   792   "is_unit c \<Longrightarrow> a * (b div c) = (a * b) div c"
   793   by (erule unit_dvdE [of _ b]) (simp add: mult.left_commute [of _ c])
   794 
   795 lemma unit_div_commute:
   796   "is_unit b \<Longrightarrow> (a div b) * c = (a * c) div b"
   797   using unit_div_mult_swap [of b c a] by (simp add: ac_simps)
   798 
   799 lemma unit_eq_div1:
   800   "is_unit b \<Longrightarrow> a div b = c \<longleftrightarrow> a = c * b"
   801   by (auto elim: is_unitE)
   802 
   803 lemma unit_eq_div2:
   804   "is_unit b \<Longrightarrow> a = c div b \<longleftrightarrow> a * b = c"
   805   using unit_eq_div1 [of b c a] by auto
   806 
   807 lemma unit_mult_left_cancel:
   808   assumes "is_unit a"
   809   shows "a * b = a * c \<longleftrightarrow> b = c" (is "?P \<longleftrightarrow> ?Q")
   810   using assms mult_cancel_left [of a b c] by auto
   811 
   812 lemma unit_mult_right_cancel:
   813   "is_unit a \<Longrightarrow> b * a = c * a \<longleftrightarrow> b = c"
   814   using unit_mult_left_cancel [of a b c] by (auto simp add: ac_simps)
   815 
   816 lemma unit_div_cancel:
   817   assumes "is_unit a"
   818   shows "b div a = c div a \<longleftrightarrow> b = c"
   819 proof -
   820   from assms have "is_unit (1 div a)" by simp
   821   then have "b * (1 div a) = c * (1 div a) \<longleftrightarrow> b = c"
   822     by (rule unit_mult_right_cancel)
   823   with assms show ?thesis by simp
   824 qed
   825 
   826 lemma is_unit_div_mult2_eq:
   827   assumes "is_unit b" and "is_unit c"
   828   shows "a div (b * c) = a div b div c"
   829 proof -
   830   from assms have "is_unit (b * c)" by (simp add: unit_prod)
   831   then have "b * c dvd a"
   832     by (rule unit_imp_dvd)
   833   then show ?thesis
   834     by (rule dvd_div_mult2_eq)
   835 qed
   836 
   837 
   838 text \<open>Associated elements in a ring --- an equivalence relation induced
   839   by the quasi-order divisibility.\<close>
   840 
   841 definition associated :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   842 where
   843   "associated a b \<longleftrightarrow> a dvd b \<and> b dvd a"
   844 
   845 lemma associatedI:
   846   "a dvd b \<Longrightarrow> b dvd a \<Longrightarrow> associated a b"
   847   by (simp add: associated_def)
   848 
   849 lemma associatedD1:
   850   "associated a b \<Longrightarrow> a dvd b"
   851   by (simp add: associated_def)
   852 
   853 lemma associatedD2:
   854   "associated a b \<Longrightarrow> b dvd a"
   855   by (simp add: associated_def)
   856 
   857 lemma associated_refl [simp]:
   858   "associated a a"
   859   by (auto intro: associatedI)
   860 
   861 lemma associated_sym:
   862   "associated b a \<longleftrightarrow> associated a b"
   863   by (auto intro: associatedI dest: associatedD1 associatedD2)
   864 
   865 lemma associated_trans:
   866   "associated a b \<Longrightarrow> associated b c \<Longrightarrow> associated a c"
   867   by (auto intro: associatedI dvd_trans dest: associatedD1 associatedD2)
   868 
   869 lemma associated_0 [simp]:
   870   "associated 0 b \<longleftrightarrow> b = 0"
   871   "associated a 0 \<longleftrightarrow> a = 0"
   872   by (auto dest: associatedD1 associatedD2)
   873 
   874 lemma associated_unit:
   875   "associated a b \<Longrightarrow> is_unit a \<Longrightarrow> is_unit b"
   876   using dvd_unit_imp_unit by (auto dest!: associatedD1 associatedD2)
   877 
   878 lemma is_unit_associatedI:
   879   assumes "is_unit c" and "a = c * b"
   880   shows "associated a b"
   881 proof (rule associatedI)
   882   from `a = c * b` show "b dvd a" by auto
   883   from `is_unit c` obtain d where "c * d = 1" by (rule is_unitE)
   884   moreover from `a = c * b` have "d * a = d * (c * b)" by simp
   885   ultimately have "b = a * d" by (simp add: ac_simps)
   886   then show "a dvd b" ..
   887 qed
   888 
   889 lemma associated_is_unitE:
   890   assumes "associated a b"
   891   obtains c where "is_unit c" and "a = c * b"
   892 proof (cases "b = 0")
   893   case True with assms have "is_unit 1" and "a = 1 * b" by simp_all
   894   with that show thesis .
   895 next
   896   case False
   897   from assms have "a dvd b" and "b dvd a" by (auto dest: associatedD1 associatedD2)
   898   then obtain c d where "b = a * d" and "a = b * c" by (blast elim: dvdE)
   899   then have "a = c * b" and "(c * d) * b = 1 * b" by (simp_all add: ac_simps)
   900   with False have "c * d = 1" using mult_cancel_right [of "c * d" b 1] by simp
   901   then have "is_unit c" by auto
   902   with `a = c * b` that show thesis by blast
   903 qed
   904 
   905 lemmas unit_simps = mult_unit_dvd_iff div_unit_dvd_iff dvd_mult_unit_iff
   906   dvd_div_unit_iff unit_div_mult_swap unit_div_commute
   907   unit_mult_left_cancel unit_mult_right_cancel unit_div_cancel
   908   unit_eq_div1 unit_eq_div2
   909 
   910 end
   911 
   912 class ordered_semiring = semiring + comm_monoid_add + ordered_ab_semigroup_add +
   913   assumes mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   914   assumes mult_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * c"
   915 begin
   916 
   917 lemma mult_mono:
   918   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   919 apply (erule mult_right_mono [THEN order_trans], assumption)
   920 apply (erule mult_left_mono, assumption)
   921 done
   922 
   923 lemma mult_mono':
   924   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   925 apply (rule mult_mono)
   926 apply (fast intro: order_trans)+
   927 done
   928 
   929 end
   930 
   931 class ordered_cancel_semiring = ordered_semiring + cancel_comm_monoid_add
   932 begin
   933 
   934 subclass semiring_0_cancel ..
   935 
   936 lemma mult_nonneg_nonneg[simp]: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a * b"
   937 using mult_left_mono [of 0 b a] by simp
   938 
   939 lemma mult_nonneg_nonpos: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> a * b \<le> 0"
   940 using mult_left_mono [of b 0 a] by simp
   941 
   942 lemma mult_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> b \<Longrightarrow> a * b \<le> 0"
   943 using mult_right_mono [of a 0 b] by simp
   944 
   945 text {* Legacy - use @{text mult_nonpos_nonneg} *}
   946 lemma mult_nonneg_nonpos2: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> b * a \<le> 0"
   947 by (drule mult_right_mono [of b 0], auto)
   948 
   949 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> 0"
   950 by (auto simp add: mult_nonneg_nonpos mult_nonneg_nonpos2)
   951 
   952 end
   953 
   954 class linordered_semiring = ordered_semiring + linordered_cancel_ab_semigroup_add
   955 begin
   956 
   957 subclass ordered_cancel_semiring ..
   958 
   959 subclass ordered_comm_monoid_add ..
   960 
   961 lemma mult_left_less_imp_less:
   962   "c * a < c * b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   963 by (force simp add: mult_left_mono not_le [symmetric])
   964 
   965 lemma mult_right_less_imp_less:
   966   "a * c < b * c \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   967 by (force simp add: mult_right_mono not_le [symmetric])
   968 
   969 end
   970 
   971 class linordered_semiring_1 = linordered_semiring + semiring_1
   972 begin
   973 
   974 lemma convex_bound_le:
   975   assumes "x \<le> a" "y \<le> a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   976   shows "u * x + v * y \<le> a"
   977 proof-
   978   from assms have "u * x + v * y \<le> u * a + v * a"
   979     by (simp add: add_mono mult_left_mono)
   980   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   981 qed
   982 
   983 end
   984 
   985 class linordered_semiring_strict = semiring + comm_monoid_add + linordered_cancel_ab_semigroup_add +
   986   assumes mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   987   assumes mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   988 begin
   989 
   990 subclass semiring_0_cancel ..
   991 
   992 subclass linordered_semiring
   993 proof
   994   fix a b c :: 'a
   995   assume A: "a \<le> b" "0 \<le> c"
   996   from A show "c * a \<le> c * b"
   997     unfolding le_less
   998     using mult_strict_left_mono by (cases "c = 0") auto
   999   from A show "a * c \<le> b * c"
  1000     unfolding le_less
  1001     using mult_strict_right_mono by (cases "c = 0") auto
  1002 qed
  1003 
  1004 lemma mult_left_le_imp_le:
  1005   "c * a \<le> c * b \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
  1006 by (force simp add: mult_strict_left_mono _not_less [symmetric])
  1007 
  1008 lemma mult_right_le_imp_le:
  1009   "a * c \<le> b * c \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
  1010 by (force simp add: mult_strict_right_mono not_less [symmetric])
  1011 
  1012 lemma mult_pos_pos[simp]: "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> 0 < a * b"
  1013 using mult_strict_left_mono [of 0 b a] by simp
  1014 
  1015 lemma mult_pos_neg: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> a * b < 0"
  1016 using mult_strict_left_mono [of b 0 a] by simp
  1017 
  1018 lemma mult_neg_pos: "a < 0 \<Longrightarrow> 0 < b \<Longrightarrow> a * b < 0"
  1019 using mult_strict_right_mono [of a 0 b] by simp
  1020 
  1021 text {* Legacy - use @{text mult_neg_pos} *}
  1022 lemma mult_pos_neg2: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> b * a < 0"
  1023 by (drule mult_strict_right_mono [of b 0], auto)
  1024 
  1025 lemma zero_less_mult_pos:
  1026   "0 < a * b \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
  1027 apply (cases "b\<le>0")
  1028  apply (auto simp add: le_less not_less)
  1029 apply (drule_tac mult_pos_neg [of a b])
  1030  apply (auto dest: less_not_sym)
  1031 done
  1032 
  1033 lemma zero_less_mult_pos2:
  1034   "0 < b * a \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
  1035 apply (cases "b\<le>0")
  1036  apply (auto simp add: le_less not_less)
  1037 apply (drule_tac mult_pos_neg2 [of a b])
  1038  apply (auto dest: less_not_sym)
  1039 done
  1040 
  1041 text{*Strict monotonicity in both arguments*}
  1042 lemma mult_strict_mono:
  1043   assumes "a < b" and "c < d" and "0 < b" and "0 \<le> c"
  1044   shows "a * c < b * d"
  1045   using assms apply (cases "c=0")
  1046   apply (simp)
  1047   apply (erule mult_strict_right_mono [THEN less_trans])
  1048   apply (force simp add: le_less)
  1049   apply (erule mult_strict_left_mono, assumption)
  1050   done
  1051 
  1052 text{*This weaker variant has more natural premises*}
  1053 lemma mult_strict_mono':
  1054   assumes "a < b" and "c < d" and "0 \<le> a" and "0 \<le> c"
  1055   shows "a * c < b * d"
  1056 by (rule mult_strict_mono) (insert assms, auto)
  1057 
  1058 lemma mult_less_le_imp_less:
  1059   assumes "a < b" and "c \<le> d" and "0 \<le> a" and "0 < c"
  1060   shows "a * c < b * d"
  1061   using assms apply (subgoal_tac "a * c < b * c")
  1062   apply (erule less_le_trans)
  1063   apply (erule mult_left_mono)
  1064   apply simp
  1065   apply (erule mult_strict_right_mono)
  1066   apply assumption
  1067   done
  1068 
  1069 lemma mult_le_less_imp_less:
  1070   assumes "a \<le> b" and "c < d" and "0 < a" and "0 \<le> c"
  1071   shows "a * c < b * d"
  1072   using assms apply (subgoal_tac "a * c \<le> b * c")
  1073   apply (erule le_less_trans)
  1074   apply (erule mult_strict_left_mono)
  1075   apply simp
  1076   apply (erule mult_right_mono)
  1077   apply simp
  1078   done
  1079 
  1080 end
  1081 
  1082 class linordered_semiring_1_strict = linordered_semiring_strict + semiring_1
  1083 begin
  1084 
  1085 subclass linordered_semiring_1 ..
  1086 
  1087 lemma convex_bound_lt:
  1088   assumes "x < a" "y < a" "0 \<le> u" "0 \<le> v" "u + v = 1"
  1089   shows "u * x + v * y < a"
  1090 proof -
  1091   from assms have "u * x + v * y < u * a + v * a"
  1092     by (cases "u = 0")
  1093        (auto intro!: add_less_le_mono mult_strict_left_mono mult_left_mono)
  1094   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
  1095 qed
  1096 
  1097 end
  1098 
  1099 class ordered_comm_semiring = comm_semiring_0 + ordered_ab_semigroup_add +
  1100   assumes comm_mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
  1101 begin
  1102 
  1103 subclass ordered_semiring
  1104 proof
  1105   fix a b c :: 'a
  1106   assume "a \<le> b" "0 \<le> c"
  1107   thus "c * a \<le> c * b" by (rule comm_mult_left_mono)
  1108   thus "a * c \<le> b * c" by (simp only: mult.commute)
  1109 qed
  1110 
  1111 end
  1112 
  1113 class ordered_cancel_comm_semiring = ordered_comm_semiring + cancel_comm_monoid_add
  1114 begin
  1115 
  1116 subclass comm_semiring_0_cancel ..
  1117 subclass ordered_comm_semiring ..
  1118 subclass ordered_cancel_semiring ..
  1119 
  1120 end
  1121 
  1122 class linordered_comm_semiring_strict = comm_semiring_0 + linordered_cancel_ab_semigroup_add +
  1123   assumes comm_mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
  1124 begin
  1125 
  1126 subclass linordered_semiring_strict
  1127 proof
  1128   fix a b c :: 'a
  1129   assume "a < b" "0 < c"
  1130   thus "c * a < c * b" by (rule comm_mult_strict_left_mono)
  1131   thus "a * c < b * c" by (simp only: mult.commute)
  1132 qed
  1133 
  1134 subclass ordered_cancel_comm_semiring
  1135 proof
  1136   fix a b c :: 'a
  1137   assume "a \<le> b" "0 \<le> c"
  1138   thus "c * a \<le> c * b"
  1139     unfolding le_less
  1140     using mult_strict_left_mono by (cases "c = 0") auto
  1141 qed
  1142 
  1143 end
  1144 
  1145 class ordered_ring = ring + ordered_cancel_semiring
  1146 begin
  1147 
  1148 subclass ordered_ab_group_add ..
  1149 
  1150 lemma less_add_iff1:
  1151   "a * e + c < b * e + d \<longleftrightarrow> (a - b) * e + c < d"
  1152 by (simp add: algebra_simps)
  1153 
  1154 lemma less_add_iff2:
  1155   "a * e + c < b * e + d \<longleftrightarrow> c < (b - a) * e + d"
  1156 by (simp add: algebra_simps)
  1157 
  1158 lemma le_add_iff1:
  1159   "a * e + c \<le> b * e + d \<longleftrightarrow> (a - b) * e + c \<le> d"
  1160 by (simp add: algebra_simps)
  1161 
  1162 lemma le_add_iff2:
  1163   "a * e + c \<le> b * e + d \<longleftrightarrow> c \<le> (b - a) * e + d"
  1164 by (simp add: algebra_simps)
  1165 
  1166 lemma mult_left_mono_neg:
  1167   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c * a \<le> c * b"
  1168   apply (drule mult_left_mono [of _ _ "- c"])
  1169   apply simp_all
  1170   done
  1171 
  1172 lemma mult_right_mono_neg:
  1173   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a * c \<le> b * c"
  1174   apply (drule mult_right_mono [of _ _ "- c"])
  1175   apply simp_all
  1176   done
  1177 
  1178 lemma mult_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a * b"
  1179 using mult_right_mono_neg [of a 0 b] by simp
  1180 
  1181 lemma split_mult_pos_le:
  1182   "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a * b"
  1183 by (auto simp add: mult_nonpos_nonpos)
  1184 
  1185 end
  1186 
  1187 class linordered_ring = ring + linordered_semiring + linordered_ab_group_add + abs_if
  1188 begin
  1189 
  1190 subclass ordered_ring ..
  1191 
  1192 subclass ordered_ab_group_add_abs
  1193 proof
  1194   fix a b
  1195   show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
  1196     by (auto simp add: abs_if not_le not_less algebra_simps simp del: add.commute dest: add_neg_neg add_nonneg_nonneg)
  1197 qed (auto simp add: abs_if)
  1198 
  1199 lemma zero_le_square [simp]: "0 \<le> a * a"
  1200   using linear [of 0 a]
  1201   by (auto simp add: mult_nonpos_nonpos)
  1202 
  1203 lemma not_square_less_zero [simp]: "\<not> (a * a < 0)"
  1204   by (simp add: not_less)
  1205 
  1206 end
  1207 
  1208 class linordered_ring_strict = ring + linordered_semiring_strict
  1209   + ordered_ab_group_add + abs_if
  1210 begin
  1211 
  1212 subclass linordered_ring ..
  1213 
  1214 lemma mult_strict_left_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> c * a < c * b"
  1215 using mult_strict_left_mono [of b a "- c"] by simp
  1216 
  1217 lemma mult_strict_right_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> a * c < b * c"
  1218 using mult_strict_right_mono [of b a "- c"] by simp
  1219 
  1220 lemma mult_neg_neg: "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> 0 < a * b"
  1221 using mult_strict_right_mono_neg [of a 0 b] by simp
  1222 
  1223 subclass ring_no_zero_divisors
  1224 proof
  1225   fix a b
  1226   assume "a \<noteq> 0" then have A: "a < 0 \<or> 0 < a" by (simp add: neq_iff)
  1227   assume "b \<noteq> 0" then have B: "b < 0 \<or> 0 < b" by (simp add: neq_iff)
  1228   have "a * b < 0 \<or> 0 < a * b"
  1229   proof (cases "a < 0")
  1230     case True note A' = this
  1231     show ?thesis proof (cases "b < 0")
  1232       case True with A'
  1233       show ?thesis by (auto dest: mult_neg_neg)
  1234     next
  1235       case False with B have "0 < b" by auto
  1236       with A' show ?thesis by (auto dest: mult_strict_right_mono)
  1237     qed
  1238   next
  1239     case False with A have A': "0 < a" by auto
  1240     show ?thesis proof (cases "b < 0")
  1241       case True with A'
  1242       show ?thesis by (auto dest: mult_strict_right_mono_neg)
  1243     next
  1244       case False with B have "0 < b" by auto
  1245       with A' show ?thesis by auto
  1246     qed
  1247   qed
  1248   then show "a * b \<noteq> 0" by (simp add: neq_iff)
  1249 qed
  1250 
  1251 lemma zero_less_mult_iff: "0 < a * b \<longleftrightarrow> 0 < a \<and> 0 < b \<or> a < 0 \<and> b < 0"
  1252   by (cases a 0 b 0 rule: linorder_cases[case_product linorder_cases])
  1253      (auto simp add: mult_neg_neg not_less le_less dest: zero_less_mult_pos zero_less_mult_pos2)
  1254 
  1255 lemma zero_le_mult_iff: "0 \<le> a * b \<longleftrightarrow> 0 \<le> a \<and> 0 \<le> b \<or> a \<le> 0 \<and> b \<le> 0"
  1256   by (auto simp add: eq_commute [of 0] le_less not_less zero_less_mult_iff)
  1257 
  1258 lemma mult_less_0_iff:
  1259   "a * b < 0 \<longleftrightarrow> 0 < a \<and> b < 0 \<or> a < 0 \<and> 0 < b"
  1260   apply (insert zero_less_mult_iff [of "-a" b])
  1261   apply force
  1262   done
  1263 
  1264 lemma mult_le_0_iff:
  1265   "a * b \<le> 0 \<longleftrightarrow> 0 \<le> a \<and> b \<le> 0 \<or> a \<le> 0 \<and> 0 \<le> b"
  1266   apply (insert zero_le_mult_iff [of "-a" b])
  1267   apply force
  1268   done
  1269 
  1270 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
  1271    also with the relations @{text "\<le>"} and equality.*}
  1272 
  1273 text{*These ``disjunction'' versions produce two cases when the comparison is
  1274  an assumption, but effectively four when the comparison is a goal.*}
  1275 
  1276 lemma mult_less_cancel_right_disj:
  1277   "a * c < b * c \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
  1278   apply (cases "c = 0")
  1279   apply (auto simp add: neq_iff mult_strict_right_mono
  1280                       mult_strict_right_mono_neg)
  1281   apply (auto simp add: not_less
  1282                       not_le [symmetric, of "a*c"]
  1283                       not_le [symmetric, of a])
  1284   apply (erule_tac [!] notE)
  1285   apply (auto simp add: less_imp_le mult_right_mono
  1286                       mult_right_mono_neg)
  1287   done
  1288 
  1289 lemma mult_less_cancel_left_disj:
  1290   "c * a < c * b \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
  1291   apply (cases "c = 0")
  1292   apply (auto simp add: neq_iff mult_strict_left_mono
  1293                       mult_strict_left_mono_neg)
  1294   apply (auto simp add: not_less
  1295                       not_le [symmetric, of "c*a"]
  1296                       not_le [symmetric, of a])
  1297   apply (erule_tac [!] notE)
  1298   apply (auto simp add: less_imp_le mult_left_mono
  1299                       mult_left_mono_neg)
  1300   done
  1301 
  1302 text{*The ``conjunction of implication'' lemmas produce two cases when the
  1303 comparison is a goal, but give four when the comparison is an assumption.*}
  1304 
  1305 lemma mult_less_cancel_right:
  1306   "a * c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
  1307   using mult_less_cancel_right_disj [of a c b] by auto
  1308 
  1309 lemma mult_less_cancel_left:
  1310   "c * a < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
  1311   using mult_less_cancel_left_disj [of c a b] by auto
  1312 
  1313 lemma mult_le_cancel_right:
  1314    "a * c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
  1315 by (simp add: not_less [symmetric] mult_less_cancel_right_disj)
  1316 
  1317 lemma mult_le_cancel_left:
  1318   "c * a \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
  1319 by (simp add: not_less [symmetric] mult_less_cancel_left_disj)
  1320 
  1321 lemma mult_le_cancel_left_pos:
  1322   "0 < c \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> a \<le> b"
  1323 by (auto simp: mult_le_cancel_left)
  1324 
  1325 lemma mult_le_cancel_left_neg:
  1326   "c < 0 \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> b \<le> a"
  1327 by (auto simp: mult_le_cancel_left)
  1328 
  1329 lemma mult_less_cancel_left_pos:
  1330   "0 < c \<Longrightarrow> c * a < c * b \<longleftrightarrow> a < b"
  1331 by (auto simp: mult_less_cancel_left)
  1332 
  1333 lemma mult_less_cancel_left_neg:
  1334   "c < 0 \<Longrightarrow> c * a < c * b \<longleftrightarrow> b < a"
  1335 by (auto simp: mult_less_cancel_left)
  1336 
  1337 end
  1338 
  1339 lemmas mult_sign_intros =
  1340   mult_nonneg_nonneg mult_nonneg_nonpos
  1341   mult_nonpos_nonneg mult_nonpos_nonpos
  1342   mult_pos_pos mult_pos_neg
  1343   mult_neg_pos mult_neg_neg
  1344 
  1345 class ordered_comm_ring = comm_ring + ordered_comm_semiring
  1346 begin
  1347 
  1348 subclass ordered_ring ..
  1349 subclass ordered_cancel_comm_semiring ..
  1350 
  1351 end
  1352 
  1353 class linordered_semidom = semidom + linordered_comm_semiring_strict +
  1354   assumes zero_less_one [simp]: "0 < 1"
  1355   assumes le_add_diff_inverse2 [simp]: "b \<le> a \<Longrightarrow> a - b + b = a"
  1356 begin
  1357 
  1358 text {* Addition is the inverse of subtraction. *}
  1359 
  1360 lemma le_add_diff_inverse [simp]: "b \<le> a \<Longrightarrow> b + (a - b) = a"
  1361   by (frule le_add_diff_inverse2) (simp add: add.commute)
  1362 
  1363 lemma add_diff_inverse: "~ a<b \<Longrightarrow> b + (a - b) = a"
  1364   by simp
  1365 
  1366 lemma add_le_imp_le_diff: 
  1367   shows "i + k \<le> n \<Longrightarrow> i \<le> n - k"
  1368   apply (subst add_le_cancel_right [where c=k, symmetric])
  1369   apply (frule le_add_diff_inverse2)
  1370   apply (simp only: add.assoc [symmetric])
  1371   using add_implies_diff by fastforce
  1372 
  1373 lemma add_le_add_imp_diff_le: 
  1374   assumes a1: "i + k \<le> n"
  1375       and a2: "n \<le> j + k"
  1376   shows "\<lbrakk>i + k \<le> n; n \<le> j + k\<rbrakk> \<Longrightarrow> n - k \<le> j"
  1377 proof -
  1378   have "n - (i + k) + (i + k) = n"
  1379     using a1 by simp
  1380   moreover have "n - k = n - k - i + i"
  1381     using a1 by (simp add: add_le_imp_le_diff)
  1382   ultimately show ?thesis
  1383     using a2
  1384     apply (simp add: add.assoc [symmetric])
  1385     apply (rule add_le_imp_le_diff [of _ k "j+k", simplified add_diff_cancel_right'])
  1386     by (simp add: add.commute diff_diff_add)
  1387 qed
  1388 
  1389 lemma pos_add_strict:
  1390   shows "0 < a \<Longrightarrow> b < c \<Longrightarrow> b < a + c"
  1391   using add_strict_mono [of 0 a b c] by simp
  1392 
  1393 lemma zero_le_one [simp]: "0 \<le> 1"
  1394 by (rule zero_less_one [THEN less_imp_le])
  1395 
  1396 lemma not_one_le_zero [simp]: "\<not> 1 \<le> 0"
  1397 by (simp add: not_le)
  1398 
  1399 lemma not_one_less_zero [simp]: "\<not> 1 < 0"
  1400 by (simp add: not_less)
  1401 
  1402 lemma less_1_mult:
  1403   assumes "1 < m" and "1 < n"
  1404   shows "1 < m * n"
  1405   using assms mult_strict_mono [of 1 m 1 n]
  1406     by (simp add:  less_trans [OF zero_less_one])
  1407 
  1408 lemma mult_left_le: "c \<le> 1 \<Longrightarrow> 0 \<le> a \<Longrightarrow> a * c \<le> a"
  1409   using mult_left_mono[of c 1 a] by simp
  1410 
  1411 lemma mult_le_one: "a \<le> 1 \<Longrightarrow> 0 \<le> b \<Longrightarrow> b \<le> 1 \<Longrightarrow> a * b \<le> 1"
  1412   using mult_mono[of a 1 b 1] by simp
  1413 
  1414 end
  1415 
  1416 class linordered_idom = comm_ring_1 +
  1417   linordered_comm_semiring_strict + ordered_ab_group_add +
  1418   abs_if + sgn_if
  1419 begin
  1420 
  1421 subclass linordered_semiring_1_strict ..
  1422 subclass linordered_ring_strict ..
  1423 subclass ordered_comm_ring ..
  1424 subclass idom ..
  1425 
  1426 subclass linordered_semidom
  1427 proof
  1428   have "0 \<le> 1 * 1" by (rule zero_le_square)
  1429   thus "0 < 1" by (simp add: le_less)
  1430   show "\<And>b a. b \<le> a \<Longrightarrow> a - b + b = a"
  1431     by simp
  1432 qed
  1433 
  1434 lemma linorder_neqE_linordered_idom:
  1435   assumes "x \<noteq> y" obtains "x < y" | "y < x"
  1436   using assms by (rule neqE)
  1437 
  1438 text {* These cancellation simprules also produce two cases when the comparison is a goal. *}
  1439 
  1440 lemma mult_le_cancel_right1:
  1441   "c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1442 by (insert mult_le_cancel_right [of 1 c b], simp)
  1443 
  1444 lemma mult_le_cancel_right2:
  1445   "a * c \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1446 by (insert mult_le_cancel_right [of a c 1], simp)
  1447 
  1448 lemma mult_le_cancel_left1:
  1449   "c \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1450 by (insert mult_le_cancel_left [of c 1 b], simp)
  1451 
  1452 lemma mult_le_cancel_left2:
  1453   "c * a \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1454 by (insert mult_le_cancel_left [of c a 1], simp)
  1455 
  1456 lemma mult_less_cancel_right1:
  1457   "c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1458 by (insert mult_less_cancel_right [of 1 c b], simp)
  1459 
  1460 lemma mult_less_cancel_right2:
  1461   "a * c < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1462 by (insert mult_less_cancel_right [of a c 1], simp)
  1463 
  1464 lemma mult_less_cancel_left1:
  1465   "c < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1466 by (insert mult_less_cancel_left [of c 1 b], simp)
  1467 
  1468 lemma mult_less_cancel_left2:
  1469   "c * a < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1470 by (insert mult_less_cancel_left [of c a 1], simp)
  1471 
  1472 lemma sgn_sgn [simp]:
  1473   "sgn (sgn a) = sgn a"
  1474 unfolding sgn_if by simp
  1475 
  1476 lemma sgn_0_0:
  1477   "sgn a = 0 \<longleftrightarrow> a = 0"
  1478 unfolding sgn_if by simp
  1479 
  1480 lemma sgn_1_pos:
  1481   "sgn a = 1 \<longleftrightarrow> a > 0"
  1482 unfolding sgn_if by simp
  1483 
  1484 lemma sgn_1_neg:
  1485   "sgn a = - 1 \<longleftrightarrow> a < 0"
  1486 unfolding sgn_if by auto
  1487 
  1488 lemma sgn_pos [simp]:
  1489   "0 < a \<Longrightarrow> sgn a = 1"
  1490 unfolding sgn_1_pos .
  1491 
  1492 lemma sgn_neg [simp]:
  1493   "a < 0 \<Longrightarrow> sgn a = - 1"
  1494 unfolding sgn_1_neg .
  1495 
  1496 lemma sgn_times:
  1497   "sgn (a * b) = sgn a * sgn b"
  1498 by (auto simp add: sgn_if zero_less_mult_iff)
  1499 
  1500 lemma abs_sgn: "\<bar>k\<bar> = k * sgn k"
  1501 unfolding sgn_if abs_if by auto
  1502 
  1503 lemma sgn_greater [simp]:
  1504   "0 < sgn a \<longleftrightarrow> 0 < a"
  1505   unfolding sgn_if by auto
  1506 
  1507 lemma sgn_less [simp]:
  1508   "sgn a < 0 \<longleftrightarrow> a < 0"
  1509   unfolding sgn_if by auto
  1510 
  1511 lemma abs_dvd_iff [simp]: "\<bar>m\<bar> dvd k \<longleftrightarrow> m dvd k"
  1512   by (simp add: abs_if)
  1513 
  1514 lemma dvd_abs_iff [simp]: "m dvd \<bar>k\<bar> \<longleftrightarrow> m dvd k"
  1515   by (simp add: abs_if)
  1516 
  1517 lemma dvd_if_abs_eq:
  1518   "\<bar>l\<bar> = \<bar>k\<bar> \<Longrightarrow> l dvd k"
  1519 by(subst abs_dvd_iff[symmetric]) simp
  1520 
  1521 text {* The following lemmas can be proven in more general structures, but
  1522 are dangerous as simp rules in absence of @{thm neg_equal_zero},
  1523 @{thm neg_less_pos}, @{thm neg_less_eq_nonneg}. *}
  1524 
  1525 lemma equation_minus_iff_1 [simp, no_atp]:
  1526   "1 = - a \<longleftrightarrow> a = - 1"
  1527   by (fact equation_minus_iff)
  1528 
  1529 lemma minus_equation_iff_1 [simp, no_atp]:
  1530   "- a = 1 \<longleftrightarrow> a = - 1"
  1531   by (subst minus_equation_iff, auto)
  1532 
  1533 lemma le_minus_iff_1 [simp, no_atp]:
  1534   "1 \<le> - b \<longleftrightarrow> b \<le> - 1"
  1535   by (fact le_minus_iff)
  1536 
  1537 lemma minus_le_iff_1 [simp, no_atp]:
  1538   "- a \<le> 1 \<longleftrightarrow> - 1 \<le> a"
  1539   by (fact minus_le_iff)
  1540 
  1541 lemma less_minus_iff_1 [simp, no_atp]:
  1542   "1 < - b \<longleftrightarrow> b < - 1"
  1543   by (fact less_minus_iff)
  1544 
  1545 lemma minus_less_iff_1 [simp, no_atp]:
  1546   "- a < 1 \<longleftrightarrow> - 1 < a"
  1547   by (fact minus_less_iff)
  1548 
  1549 end
  1550 
  1551 text {* Simprules for comparisons where common factors can be cancelled. *}
  1552 
  1553 lemmas mult_compare_simps =
  1554     mult_le_cancel_right mult_le_cancel_left
  1555     mult_le_cancel_right1 mult_le_cancel_right2
  1556     mult_le_cancel_left1 mult_le_cancel_left2
  1557     mult_less_cancel_right mult_less_cancel_left
  1558     mult_less_cancel_right1 mult_less_cancel_right2
  1559     mult_less_cancel_left1 mult_less_cancel_left2
  1560     mult_cancel_right mult_cancel_left
  1561     mult_cancel_right1 mult_cancel_right2
  1562     mult_cancel_left1 mult_cancel_left2
  1563 
  1564 text {* Reasoning about inequalities with division *}
  1565 
  1566 context linordered_semidom
  1567 begin
  1568 
  1569 lemma less_add_one: "a < a + 1"
  1570 proof -
  1571   have "a + 0 < a + 1"
  1572     by (blast intro: zero_less_one add_strict_left_mono)
  1573   thus ?thesis by simp
  1574 qed
  1575 
  1576 lemma zero_less_two: "0 < 1 + 1"
  1577 by (blast intro: less_trans zero_less_one less_add_one)
  1578 
  1579 end
  1580 
  1581 context linordered_idom
  1582 begin
  1583 
  1584 lemma mult_right_le_one_le:
  1585   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> x * y \<le> x"
  1586   by (rule mult_left_le)
  1587 
  1588 lemma mult_left_le_one_le:
  1589   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> y * x \<le> x"
  1590   by (auto simp add: mult_le_cancel_right2)
  1591 
  1592 end
  1593 
  1594 text {* Absolute Value *}
  1595 
  1596 context linordered_idom
  1597 begin
  1598 
  1599 lemma mult_sgn_abs:
  1600   "sgn x * \<bar>x\<bar> = x"
  1601   unfolding abs_if sgn_if by auto
  1602 
  1603 lemma abs_one [simp]:
  1604   "\<bar>1\<bar> = 1"
  1605   by (simp add: abs_if)
  1606 
  1607 end
  1608 
  1609 class ordered_ring_abs = ordered_ring + ordered_ab_group_add_abs +
  1610   assumes abs_eq_mult:
  1611     "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0) \<Longrightarrow> \<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1612 
  1613 context linordered_idom
  1614 begin
  1615 
  1616 subclass ordered_ring_abs proof
  1617 qed (auto simp add: abs_if not_less mult_less_0_iff)
  1618 
  1619 lemma abs_mult:
  1620   "\<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1621   by (rule abs_eq_mult) auto
  1622 
  1623 lemma abs_mult_self:
  1624   "\<bar>a\<bar> * \<bar>a\<bar> = a * a"
  1625   by (simp add: abs_if)
  1626 
  1627 lemma abs_mult_less:
  1628   "\<bar>a\<bar> < c \<Longrightarrow> \<bar>b\<bar> < d \<Longrightarrow> \<bar>a\<bar> * \<bar>b\<bar> < c * d"
  1629 proof -
  1630   assume ac: "\<bar>a\<bar> < c"
  1631   hence cpos: "0<c" by (blast intro: le_less_trans abs_ge_zero)
  1632   assume "\<bar>b\<bar> < d"
  1633   thus ?thesis by (simp add: ac cpos mult_strict_mono)
  1634 qed
  1635 
  1636 lemma abs_less_iff:
  1637   "\<bar>a\<bar> < b \<longleftrightarrow> a < b \<and> - a < b"
  1638   by (simp add: less_le abs_le_iff) (auto simp add: abs_if)
  1639 
  1640 lemma abs_mult_pos:
  1641   "0 \<le> x \<Longrightarrow> \<bar>y\<bar> * x = \<bar>y * x\<bar>"
  1642   by (simp add: abs_mult)
  1643 
  1644 lemma abs_diff_less_iff:
  1645   "\<bar>x - a\<bar> < r \<longleftrightarrow> a - r < x \<and> x < a + r"
  1646   by (auto simp add: diff_less_eq ac_simps abs_less_iff)
  1647 
  1648 lemma abs_diff_le_iff:
  1649    "\<bar>x - a\<bar> \<le> r \<longleftrightarrow> a - r \<le> x \<and> x \<le> a + r"
  1650   by (auto simp add: diff_le_eq ac_simps abs_le_iff)
  1651 
  1652 end
  1653 
  1654 hide_fact (open) comm_mult_left_mono comm_mult_strict_left_mono distrib
  1655 
  1656 code_identifier
  1657   code_module Rings \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1658 
  1659 end