src/HOL/Real/RealDef.thy
author paulson
Thu Jul 29 16:57:41 2004 +0200 (2004-07-29)
changeset 15086 e6a2a98d5ef5
parent 15085 5693a977a767
child 15131 c69542757a4d
permissions -rw-r--r--
removal of more iff-rules from RealDef.thy
     1 (*  Title       : Real/RealDef.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     6 *)
     7 
     8 header{*Defining the Reals from the Positive Reals*}
     9 
    10 theory RealDef = PReal
    11 files ("real_arith.ML"):
    12 
    13 constdefs
    14   realrel   ::  "((preal * preal) * (preal * preal)) set"
    15   "realrel == {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    16 
    17 typedef (Real)  real = "UNIV//realrel"
    18   by (auto simp add: quotient_def)
    19 
    20 instance real :: "{ord, zero, one, plus, times, minus, inverse}" ..
    21 
    22 constdefs
    23 
    24   (** these don't use the overloaded "real" function: users don't see them **)
    25 
    26   real_of_preal :: "preal => real"
    27   "real_of_preal m     ==
    28            Abs_Real(realrel``{(m + preal_of_rat 1, preal_of_rat 1)})"
    29 
    30 consts
    31    (*Overloaded constant denoting the Real subset of enclosing
    32      types such as hypreal and complex*)
    33    Reals :: "'a set"
    34 
    35    (*overloaded constant for injecting other types into "real"*)
    36    real :: "'a => real"
    37 
    38 syntax (xsymbols)
    39   Reals     :: "'a set"                   ("\<real>")
    40 
    41 
    42 defs (overloaded)
    43 
    44   real_zero_def:
    45   "0 == Abs_Real(realrel``{(preal_of_rat 1, preal_of_rat 1)})"
    46 
    47   real_one_def:
    48   "1 == Abs_Real(realrel``
    49                {(preal_of_rat 1 + preal_of_rat 1,
    50 		 preal_of_rat 1)})"
    51 
    52   real_minus_def:
    53   "- r ==  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    54 
    55   real_add_def:
    56    "z + w ==
    57        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    58 		 { Abs_Real(realrel``{(x+u, y+v)}) })"
    59 
    60   real_diff_def:
    61    "r - (s::real) == r + - s"
    62 
    63   real_mult_def:
    64     "z * w ==
    65        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    66 		 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
    67 
    68   real_inverse_def:
    69   "inverse (R::real) == (SOME S. (R = 0 & S = 0) | S * R = 1)"
    70 
    71   real_divide_def:
    72   "R / (S::real) == R * inverse S"
    73 
    74   real_le_def:
    75    "z \<le> (w::real) == 
    76     \<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w"
    77 
    78   real_less_def: "(x < (y::real)) == (x \<le> y & x \<noteq> y)"
    79 
    80   real_abs_def:  "abs (r::real) == (if 0 \<le> r then r else -r)"
    81 
    82 
    83 
    84 subsection{*Proving that realrel is an equivalence relation*}
    85 
    86 lemma preal_trans_lemma:
    87   assumes "x + y1 = x1 + y"
    88       and "x + y2 = x2 + y"
    89   shows "x1 + y2 = x2 + (y1::preal)"
    90 proof -
    91   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: preal_add_ac) 
    92   also have "... = (x2 + y) + x1"  by (simp add: prems)
    93   also have "... = x2 + (x1 + y)"  by (simp add: preal_add_ac)
    94   also have "... = x2 + (x + y1)"  by (simp add: prems)
    95   also have "... = (x2 + y1) + x"  by (simp add: preal_add_ac)
    96   finally have "(x1 + y2) + x = (x2 + y1) + x" .
    97   thus ?thesis by (simp add: preal_add_right_cancel_iff) 
    98 qed
    99 
   100 
   101 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
   102 by (simp add: realrel_def)
   103 
   104 lemma equiv_realrel: "equiv UNIV realrel"
   105 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
   106 apply (blast dest: preal_trans_lemma) 
   107 done
   108 
   109 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
   110   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
   111 lemmas equiv_realrel_iff = 
   112        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   113 
   114 declare equiv_realrel_iff [simp]
   115 
   116 
   117 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   118 by (simp add: Real_def realrel_def quotient_def, blast)
   119 
   120 
   121 lemma inj_on_Abs_Real: "inj_on Abs_Real Real"
   122 apply (rule inj_on_inverseI)
   123 apply (erule Abs_Real_inverse)
   124 done
   125 
   126 declare inj_on_Abs_Real [THEN inj_on_iff, simp]
   127 declare Abs_Real_inverse [simp]
   128 
   129 
   130 text{*Case analysis on the representation of a real number as an equivalence
   131       class of pairs of positive reals.*}
   132 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   133      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   134 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   135 apply (drule arg_cong [where f=Abs_Real])
   136 apply (auto simp add: Rep_Real_inverse)
   137 done
   138 
   139 
   140 subsection{*Congruence property for addition*}
   141 
   142 lemma real_add_congruent2_lemma:
   143      "[|a + ba = aa + b; ab + bc = ac + bb|]
   144       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   145 apply (simp add: preal_add_assoc) 
   146 apply (rule preal_add_left_commute [of ab, THEN ssubst])
   147 apply (simp add: preal_add_assoc [symmetric])
   148 apply (simp add: preal_add_ac)
   149 done
   150 
   151 lemma real_add:
   152      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   153       Abs_Real (realrel``{(x+u, y+v)})"
   154 proof -
   155   have "congruent2 realrel realrel
   156         (\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)"
   157     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   158   thus ?thesis
   159     by (simp add: real_add_def UN_UN_split_split_eq
   160                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   161 qed
   162 
   163 lemma real_add_commute: "(z::real) + w = w + z"
   164 by (cases z, cases w, simp add: real_add preal_add_ac)
   165 
   166 lemma real_add_assoc: "((z1::real) + z2) + z3 = z1 + (z2 + z3)"
   167 by (cases z1, cases z2, cases z3, simp add: real_add preal_add_assoc)
   168 
   169 lemma real_add_zero_left: "(0::real) + z = z"
   170 by (cases z, simp add: real_add real_zero_def preal_add_ac)
   171 
   172 instance real :: comm_monoid_add
   173   by (intro_classes,
   174       (assumption | 
   175        rule real_add_commute real_add_assoc real_add_zero_left)+)
   176 
   177 
   178 subsection{*Additive Inverse on real*}
   179 
   180 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   181 proof -
   182   have "congruent realrel (\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})})"
   183     by (simp add: congruent_def preal_add_commute) 
   184   thus ?thesis
   185     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   186 qed
   187 
   188 lemma real_add_minus_left: "(-z) + z = (0::real)"
   189 by (cases z, simp add: real_minus real_add real_zero_def preal_add_commute)
   190 
   191 
   192 subsection{*Congruence property for multiplication*}
   193 
   194 lemma real_mult_congruent2_lemma:
   195      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   196           x * x1 + y * y1 + (x * y2 + y * x2) =
   197           x * x2 + y * y2 + (x * y1 + y * x1)"
   198 apply (simp add: preal_add_left_commute preal_add_assoc [symmetric])
   199 apply (simp add: preal_add_assoc preal_add_mult_distrib2 [symmetric])
   200 apply (simp add: preal_add_commute)
   201 done
   202 
   203 lemma real_mult_congruent2:
   204     "congruent2 realrel realrel (%p1 p2.
   205         (%(x1,y1). (%(x2,y2). 
   206           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)"
   207 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   208 apply (simp add: preal_mult_commute preal_add_commute)
   209 apply (auto simp add: real_mult_congruent2_lemma)
   210 done
   211 
   212 lemma real_mult:
   213       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   214        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   215 by (simp add: real_mult_def UN_UN_split_split_eq
   216          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   217 
   218 lemma real_mult_commute: "(z::real) * w = w * z"
   219 by (cases z, cases w, simp add: real_mult preal_add_ac preal_mult_ac)
   220 
   221 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   222 apply (cases z1, cases z2, cases z3)
   223 apply (simp add: real_mult preal_add_mult_distrib2 preal_add_ac preal_mult_ac)
   224 done
   225 
   226 lemma real_mult_1: "(1::real) * z = z"
   227 apply (cases z)
   228 apply (simp add: real_mult real_one_def preal_add_mult_distrib2
   229                  preal_mult_1_right preal_mult_ac preal_add_ac)
   230 done
   231 
   232 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   233 apply (cases z1, cases z2, cases w)
   234 apply (simp add: real_add real_mult preal_add_mult_distrib2 
   235                  preal_add_ac preal_mult_ac)
   236 done
   237 
   238 text{*one and zero are distinct*}
   239 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   240 proof -
   241   have "preal_of_rat 1 < preal_of_rat 1 + preal_of_rat 1"
   242     by (simp add: preal_self_less_add_left) 
   243   thus ?thesis
   244     by (simp add: real_zero_def real_one_def preal_add_right_cancel_iff)
   245 qed
   246 
   247 subsection{*existence of inverse*}
   248 
   249 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   250 by (simp add: real_zero_def preal_add_commute)
   251 
   252 text{*Instead of using an existential quantifier and constructing the inverse
   253 within the proof, we could define the inverse explicitly.*}
   254 
   255 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   256 apply (simp add: real_zero_def real_one_def, cases x)
   257 apply (cut_tac x = xa and y = y in linorder_less_linear)
   258 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   259 apply (rule_tac
   260         x = "Abs_Real (realrel `` { (preal_of_rat 1, 
   261                             inverse (D) + preal_of_rat 1)}) " 
   262        in exI)
   263 apply (rule_tac [2]
   264         x = "Abs_Real (realrel `` { (inverse (D) + preal_of_rat 1,
   265                    preal_of_rat 1)})" 
   266        in exI)
   267 apply (auto simp add: real_mult preal_mult_1_right
   268               preal_add_mult_distrib2 preal_add_mult_distrib preal_mult_1
   269               preal_mult_inverse_right preal_add_ac preal_mult_ac)
   270 done
   271 
   272 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   273 apply (simp add: real_inverse_def)
   274 apply (frule real_mult_inverse_left_ex, safe)
   275 apply (rule someI2, auto)
   276 done
   277 
   278 
   279 subsection{*The Real Numbers form a Field*}
   280 
   281 instance real :: field
   282 proof
   283   fix x y z :: real
   284   show "- x + x = 0" by (rule real_add_minus_left)
   285   show "x - y = x + (-y)" by (simp add: real_diff_def)
   286   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   287   show "x * y = y * x" by (rule real_mult_commute)
   288   show "1 * x = x" by (rule real_mult_1)
   289   show "(x + y) * z = x * z + y * z" by (simp add: real_add_mult_distrib)
   290   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   291   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   292   show "x / y = x * inverse y" by (simp add: real_divide_def)
   293 qed
   294 
   295 
   296 text{*Inverse of zero!  Useful to simplify certain equations*}
   297 
   298 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   299 by (simp add: real_inverse_def)
   300 
   301 instance real :: division_by_zero
   302 proof
   303   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   304 qed
   305 
   306 
   307 (*Pull negations out*)
   308 declare minus_mult_right [symmetric, simp] 
   309         minus_mult_left [symmetric, simp]
   310 
   311 lemma real_mult_1_right: "z * (1::real) = z"
   312   by (rule OrderedGroup.mult_1_right)
   313 
   314 
   315 subsection{*The @{text "\<le>"} Ordering*}
   316 
   317 lemma real_le_refl: "w \<le> (w::real)"
   318 by (cases w, force simp add: real_le_def)
   319 
   320 text{*The arithmetic decision procedure is not set up for type preal.
   321   This lemma is currently unused, but it could simplify the proofs of the
   322   following two lemmas.*}
   323 lemma preal_eq_le_imp_le:
   324   assumes eq: "a+b = c+d" and le: "c \<le> a"
   325   shows "b \<le> (d::preal)"
   326 proof -
   327   have "c+d \<le> a+d" by (simp add: prems preal_cancels)
   328   hence "a+b \<le> a+d" by (simp add: prems)
   329   thus "b \<le> d" by (simp add: preal_cancels)
   330 qed
   331 
   332 lemma real_le_lemma:
   333   assumes l: "u1 + v2 \<le> u2 + v1"
   334       and "x1 + v1 = u1 + y1"
   335       and "x2 + v2 = u2 + y2"
   336   shows "x1 + y2 \<le> x2 + (y1::preal)"
   337 proof -
   338   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   339   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: preal_add_ac)
   340   also have "... \<le> (x2+y1) + (u2+v1)"
   341          by (simp add: prems preal_add_le_cancel_left)
   342   finally show ?thesis by (simp add: preal_add_le_cancel_right)
   343 qed						 
   344 
   345 lemma real_le: 
   346      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   347       (x1 + y2 \<le> x2 + y1)"
   348 apply (simp add: real_le_def) 
   349 apply (auto intro: real_le_lemma)
   350 done
   351 
   352 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   353 by (cases z, cases w, simp add: real_le order_antisym)
   354 
   355 lemma real_trans_lemma:
   356   assumes "x + v \<le> u + y"
   357       and "u + v' \<le> u' + v"
   358       and "x2 + v2 = u2 + y2"
   359   shows "x + v' \<le> u' + (y::preal)"
   360 proof -
   361   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: preal_add_ac)
   362   also have "... \<le> (u+y) + (u+v')" 
   363     by (simp add: preal_add_le_cancel_right prems) 
   364   also have "... \<le> (u+y) + (u'+v)" 
   365     by (simp add: preal_add_le_cancel_left prems) 
   366   also have "... = (u'+y) + (u+v)"  by (simp add: preal_add_ac)
   367   finally show ?thesis by (simp add: preal_add_le_cancel_right)
   368 qed						 
   369 
   370 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   371 apply (cases i, cases j, cases k)
   372 apply (simp add: real_le)
   373 apply (blast intro: real_trans_lemma) 
   374 done
   375 
   376 (* Axiom 'order_less_le' of class 'order': *)
   377 lemma real_less_le: "((w::real) < z) = (w \<le> z & w \<noteq> z)"
   378 by (simp add: real_less_def)
   379 
   380 instance real :: order
   381 proof qed
   382  (assumption |
   383   rule real_le_refl real_le_trans real_le_anti_sym real_less_le)+
   384 
   385 (* Axiom 'linorder_linear' of class 'linorder': *)
   386 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   387 apply (cases z, cases w) 
   388 apply (auto simp add: real_le real_zero_def preal_add_ac preal_cancels)
   389 done
   390 
   391 
   392 instance real :: linorder
   393   by (intro_classes, rule real_le_linear)
   394 
   395 
   396 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   397 apply (cases x, cases y) 
   398 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   399                       preal_add_ac)
   400 apply (simp_all add: preal_add_assoc [symmetric] preal_cancels)
   401 done 
   402 
   403 lemma real_add_left_mono: 
   404   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   405 proof -
   406   have "z + x - (z + y) = (z + -z) + (x - y)"
   407     by (simp add: diff_minus add_ac) 
   408   with le show ?thesis 
   409     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   410 qed
   411 
   412 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   413 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   414 
   415 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   416 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   417 
   418 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   419 apply (cases x, cases y)
   420 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   421                  linorder_not_le [where 'a = preal] 
   422                   real_zero_def real_le real_mult)
   423   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   424 apply (auto  dest!: less_add_left_Ex 
   425      simp add: preal_add_ac preal_mult_ac 
   426           preal_add_mult_distrib2 preal_cancels preal_self_less_add_right)
   427 done
   428 
   429 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   430 apply (rule real_sum_gt_zero_less)
   431 apply (drule real_less_sum_gt_zero [of x y])
   432 apply (drule real_mult_order, assumption)
   433 apply (simp add: right_distrib)
   434 done
   435 
   436 text{*lemma for proving @{term "0<(1::real)"}*}
   437 lemma real_zero_le_one: "0 \<le> (1::real)"
   438 by (simp add: real_zero_def real_one_def real_le 
   439                  preal_self_less_add_left order_less_imp_le)
   440 
   441 
   442 subsection{*The Reals Form an Ordered Field*}
   443 
   444 instance real :: ordered_field
   445 proof
   446   fix x y z :: real
   447   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   448   show "x < y ==> 0 < z ==> z * x < z * y" by (simp add: real_mult_less_mono2)
   449   show "\<bar>x\<bar> = (if x < 0 then -x else x)"
   450     by (auto dest: order_le_less_trans simp add: real_abs_def linorder_not_le)
   451 qed
   452 
   453 
   454 
   455 text{*The function @{term real_of_preal} requires many proofs, but it seems
   456 to be essential for proving completeness of the reals from that of the
   457 positive reals.*}
   458 
   459 lemma real_of_preal_add:
   460      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   461 by (simp add: real_of_preal_def real_add preal_add_mult_distrib preal_mult_1 
   462               preal_add_ac)
   463 
   464 lemma real_of_preal_mult:
   465      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   466 by (simp add: real_of_preal_def real_mult preal_add_mult_distrib2
   467               preal_mult_1 preal_mult_1_right preal_add_ac preal_mult_ac)
   468 
   469 
   470 text{*Gleason prop 9-4.4 p 127*}
   471 lemma real_of_preal_trichotomy:
   472       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   473 apply (simp add: real_of_preal_def real_zero_def, cases x)
   474 apply (auto simp add: real_minus preal_add_ac)
   475 apply (cut_tac x = x and y = y in linorder_less_linear)
   476 apply (auto dest!: less_add_left_Ex simp add: preal_add_assoc [symmetric])
   477 apply (auto simp add: preal_add_commute)
   478 done
   479 
   480 lemma real_of_preal_leD:
   481       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   482 by (simp add: real_of_preal_def real_le preal_cancels)
   483 
   484 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   485 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   486 
   487 lemma real_of_preal_lessD:
   488       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   489 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric] 
   490               preal_cancels) 
   491 
   492 
   493 lemma real_of_preal_less_iff [simp]:
   494      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   495 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   496 
   497 lemma real_of_preal_le_iff:
   498      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   499 by (simp add: linorder_not_less [symmetric]) 
   500 
   501 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   502 apply (auto simp add: real_zero_def real_of_preal_def real_less_def real_le_def
   503             preal_add_ac preal_cancels)
   504 apply (simp_all add: preal_add_assoc [symmetric] preal_cancels)
   505 apply (blast intro: preal_self_less_add_left order_less_imp_le)
   506 apply (insert preal_not_eq_self [of "preal_of_rat 1" m]) 
   507 apply (simp add: preal_add_ac) 
   508 done
   509 
   510 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   511 by (simp add: real_of_preal_zero_less)
   512 
   513 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   514 proof -
   515   from real_of_preal_minus_less_zero
   516   show ?thesis by (blast dest: order_less_trans)
   517 qed
   518 
   519 
   520 subsection{*Theorems About the Ordering*}
   521 
   522 text{*obsolete but used a lot*}
   523 
   524 lemma real_not_refl2: "x < y ==> x \<noteq> (y::real)"
   525 by blast 
   526 
   527 lemma real_le_imp_less_or_eq: "!!(x::real). x \<le> y ==> x < y | x = y"
   528 by (simp add: order_le_less)
   529 
   530 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   531 apply (auto simp add: real_of_preal_zero_less)
   532 apply (cut_tac x = x in real_of_preal_trichotomy)
   533 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   534 done
   535 
   536 lemma real_gt_preal_preal_Ex:
   537      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   538 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   539              intro: real_gt_zero_preal_Ex [THEN iffD1])
   540 
   541 lemma real_ge_preal_preal_Ex:
   542      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   543 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   544 
   545 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   546 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   547             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   548             simp add: real_of_preal_zero_less)
   549 
   550 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   551 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   552 
   553 lemma real_add_less_le_mono: "[| w'<w; z'\<le>z |] ==> w' + z' < w + (z::real)"
   554   by (rule OrderedGroup.add_less_le_mono)
   555 
   556 lemma real_add_le_less_mono:
   557      "!!z z'::real. [| w'\<le>w; z'<z |] ==> w' + z' < w + z"
   558   by (rule OrderedGroup.add_le_less_mono)
   559 
   560 lemma real_le_square [simp]: "(0::real) \<le> x*x"
   561  by (rule Ring_and_Field.zero_le_square)
   562 
   563 
   564 subsection{*More Lemmas*}
   565 
   566 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   567 by auto
   568 
   569 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   570 by auto
   571 
   572 text{*The precondition could be weakened to @{term "0\<le>x"}*}
   573 lemma real_mult_less_mono:
   574      "[| u<v;  x<y;  (0::real) < v;  0 < x |] ==> u*x < v* y"
   575  by (simp add: Ring_and_Field.mult_strict_mono order_less_imp_le)
   576 
   577 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   578   by (force elim: order_less_asym
   579             simp add: Ring_and_Field.mult_less_cancel_right)
   580 
   581 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   582 apply (simp add: mult_le_cancel_right)
   583 apply (blast intro: elim: order_less_asym) 
   584 done
   585 
   586 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   587   by (force elim: order_less_asym
   588             simp add: Ring_and_Field.mult_le_cancel_left)
   589 
   590 text{*Only two uses?*}
   591 lemma real_mult_less_mono':
   592      "[| x < y;  r1 < r2;  (0::real) \<le> r1;  0 \<le> x|] ==> r1 * x < r2 * y"
   593  by (rule Ring_and_Field.mult_strict_mono')
   594 
   595 text{*FIXME: delete or at least combine the next two lemmas*}
   596 lemma real_sum_squares_cancel: "x * x + y * y = 0 ==> x = (0::real)"
   597 apply (drule OrderedGroup.equals_zero_I [THEN sym])
   598 apply (cut_tac x = y in real_le_square) 
   599 apply (auto, drule order_antisym, auto)
   600 done
   601 
   602 lemma real_sum_squares_cancel2: "x * x + y * y = 0 ==> y = (0::real)"
   603 apply (rule_tac y = x in real_sum_squares_cancel)
   604 apply (simp add: add_commute)
   605 done
   606 
   607 lemma real_add_order: "[| 0 < x; 0 < y |] ==> (0::real) < x + y"
   608 by (drule add_strict_mono [of concl: 0 0], assumption, simp)
   609 
   610 lemma real_le_add_order: "[| 0 \<le> x; 0 \<le> y |] ==> (0::real) \<le> x + y"
   611 apply (drule order_le_imp_less_or_eq)+
   612 apply (auto intro: real_add_order order_less_imp_le)
   613 done
   614 
   615 lemma real_inverse_unique: "x*y = (1::real) ==> y = inverse x"
   616 apply (case_tac "x \<noteq> 0")
   617 apply (rule_tac c1 = x in real_mult_left_cancel [THEN iffD1], auto)
   618 done
   619 
   620 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   621 by (auto dest: less_imp_inverse_less)
   622 
   623 lemma real_mult_self_sum_ge_zero: "(0::real) \<le> x*x + y*y"
   624 proof -
   625   have "0 + 0 \<le> x*x + y*y" by (blast intro: add_mono zero_le_square)
   626   thus ?thesis by simp
   627 qed
   628 
   629 
   630 subsection{*Embedding the Integers into the Reals*}
   631 
   632 defs (overloaded)
   633   real_of_nat_def: "real z == of_nat z"
   634   real_of_int_def: "real z == of_int z"
   635 
   636 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   637 by (simp add: real_of_int_def) 
   638 
   639 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   640 by (simp add: real_of_int_def) 
   641 
   642 lemma real_of_int_add: "real (x::int) + real y = real (x + y)"
   643 by (simp add: real_of_int_def) 
   644 declare real_of_int_add [symmetric, simp]
   645 
   646 lemma real_of_int_minus: "-real (x::int) = real (-x)"
   647 by (simp add: real_of_int_def) 
   648 declare real_of_int_minus [symmetric, simp]
   649 
   650 lemma real_of_int_diff: "real (x::int) - real y = real (x - y)"
   651 by (simp add: real_of_int_def) 
   652 declare real_of_int_diff [symmetric, simp]
   653 
   654 lemma real_of_int_mult: "real (x::int) * real y = real (x * y)"
   655 by (simp add: real_of_int_def) 
   656 declare real_of_int_mult [symmetric, simp]
   657 
   658 lemma real_of_int_zero_cancel [simp]: "(real x = 0) = (x = (0::int))"
   659 by (simp add: real_of_int_def) 
   660 
   661 lemma real_of_int_inject [iff]: "(real (x::int) = real y) = (x = y)"
   662 by (simp add: real_of_int_def) 
   663 
   664 lemma real_of_int_less_iff [iff]: "(real (x::int) < real y) = (x < y)"
   665 by (simp add: real_of_int_def) 
   666 
   667 lemma real_of_int_le_iff [simp]: "(real (x::int) \<le> real y) = (x \<le> y)"
   668 by (simp add: real_of_int_def) 
   669 
   670 
   671 subsection{*Embedding the Naturals into the Reals*}
   672 
   673 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   674 by (simp add: real_of_nat_def)
   675 
   676 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   677 by (simp add: real_of_nat_def)
   678 
   679 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   680 by (simp add: real_of_nat_def)
   681 
   682 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   683 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   684 by (simp add: real_of_nat_def)
   685 
   686 lemma real_of_nat_less_iff [iff]: 
   687      "(real (n::nat) < real m) = (n < m)"
   688 by (simp add: real_of_nat_def)
   689 
   690 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   691 by (simp add: real_of_nat_def)
   692 
   693 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   694 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   695 
   696 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   697 by (simp add: real_of_nat_def del: of_nat_Suc)
   698 
   699 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   700 by (simp add: real_of_nat_def)
   701 
   702 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   703 by (simp add: real_of_nat_def)
   704 
   705 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   706 by (simp add: real_of_nat_def)
   707 
   708 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   709 by (simp add: add: real_of_nat_def) 
   710 
   711 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   712 by (simp add: add: real_of_nat_def) 
   713 
   714 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   715 by (simp add: add: real_of_nat_def)
   716 
   717 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   718 by (simp add: add: real_of_nat_def)
   719 
   720 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat)) = (0 \<le> n)"
   721 by (simp add: add: real_of_nat_def)
   722 
   723 lemma real_of_int_real_of_nat: "real (int n) = real n"
   724 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   725 
   726 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   727 by (simp add: real_of_int_def real_of_nat_def)
   728 
   729 
   730 
   731 subsection{*Numerals and Arithmetic*}
   732 
   733 instance real :: number ..
   734 
   735 defs (overloaded)
   736   real_number_of_def: "(number_of w :: real) == of_int (Rep_Bin w)"
   737     --{*the type constraint is essential!*}
   738 
   739 instance real :: number_ring
   740 by (intro_classes, simp add: real_number_of_def) 
   741 
   742 
   743 text{*Collapse applications of @{term real} to @{term number_of}*}
   744 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   745 by (simp add:  real_of_int_def of_int_number_of_eq)
   746 
   747 lemma real_of_nat_number_of [simp]:
   748      "real (number_of v :: nat) =  
   749         (if neg (number_of v :: int) then 0  
   750          else (number_of v :: real))"
   751 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   752  
   753 
   754 use "real_arith.ML"
   755 
   756 setup real_arith_setup
   757 
   758 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   759 
   760 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   761 lemma real_0_le_divide_iff:
   762      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   763 by (simp add: real_divide_def zero_le_mult_iff, auto)
   764 
   765 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   766 by arith
   767 
   768 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   769 by auto
   770 
   771 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   772 by auto
   773 
   774 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   775 by auto
   776 
   777 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   778 by auto
   779 
   780 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   781 by auto
   782 
   783 
   784 (*
   785 FIXME: we should have this, as for type int, but many proofs would break.
   786 It replaces x+-y by x-y.
   787 declare real_diff_def [symmetric, simp]
   788 *)
   789 
   790 
   791 subsubsection{*Density of the Reals*}
   792 
   793 lemma real_lbound_gt_zero:
   794      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
   795 apply (rule_tac x = " (min d1 d2) /2" in exI)
   796 apply (simp add: min_def)
   797 done
   798 
   799 
   800 text{*Similar results are proved in @{text Ring_and_Field}*}
   801 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
   802   by auto
   803 
   804 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
   805   by auto
   806 
   807 
   808 subsection{*Absolute Value Function for the Reals*}
   809 
   810 text{*FIXME: these should go!*}
   811 lemma abs_eqI1: "(0::real)\<le>x ==> abs x = x"
   812 by (simp add: abs_if)
   813 
   814 lemma abs_eqI2: "(0::real) < x ==> abs x = x"
   815 by (simp add: abs_if)
   816 
   817 lemma abs_minus_eqI2: "x < (0::real) ==> abs x = -x"
   818 by (simp add: abs_if linorder_not_less [symmetric])
   819 
   820 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
   821 by (simp add: abs_if)
   822 
   823 lemma abs_interval_iff: "(abs x < r) = (-r < x & x < (r::real))"
   824 by (force simp add: Ring_and_Field.abs_less_iff)
   825 
   826 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
   827 by (force simp add: OrderedGroup.abs_le_iff)
   828 
   829 (*FIXME: used only once, in SEQ.ML*)
   830 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
   831 by (simp add: abs_if)
   832 
   833 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
   834 by (auto intro: abs_eqI1 simp add: real_of_nat_ge_zero)
   835 
   836 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
   837 apply (simp add: linorder_not_less)
   838 apply (auto intro: abs_ge_self [THEN order_trans])
   839 done
   840  
   841 text{*Used only in Hyperreal/Lim.ML*}
   842 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
   843 apply (simp add: real_add_assoc)
   844 apply (rule_tac a1 = y in add_left_commute [THEN ssubst])
   845 apply (rule real_add_assoc [THEN subst])
   846 apply (rule abs_triangle_ineq)
   847 done
   848 
   849 
   850 
   851 ML
   852 {*
   853 val real_lbound_gt_zero = thm"real_lbound_gt_zero";
   854 val real_less_half_sum = thm"real_less_half_sum";
   855 val real_gt_half_sum = thm"real_gt_half_sum";
   856 
   857 val abs_eqI1 = thm"abs_eqI1";
   858 val abs_eqI2 = thm"abs_eqI2";
   859 val abs_minus_eqI2 = thm"abs_minus_eqI2";
   860 val abs_ge_zero = thm"abs_ge_zero";
   861 val abs_idempotent = thm"abs_idempotent";
   862 val abs_eq_0 = thm"abs_eq_0";
   863 val abs_ge_self = thm"abs_ge_self";
   864 val abs_ge_minus_self = thm"abs_ge_minus_self";
   865 val abs_mult = thm"abs_mult";
   866 val abs_inverse = thm"abs_inverse";
   867 val abs_triangle_ineq = thm"abs_triangle_ineq";
   868 val abs_minus_cancel = thm"abs_minus_cancel";
   869 val abs_minus_add_cancel = thm"abs_minus_add_cancel";
   870 val abs_interval_iff = thm"abs_interval_iff";
   871 val abs_le_interval_iff = thm"abs_le_interval_iff";
   872 val abs_add_one_gt_zero = thm"abs_add_one_gt_zero";
   873 val abs_le_zero_iff = thm"abs_le_zero_iff";
   874 val abs_add_one_not_less_self = thm"abs_add_one_not_less_self";
   875 val abs_sum_triangle_ineq = thm"abs_sum_triangle_ineq";
   876 
   877 val abs_mult_less = thm"abs_mult_less";
   878 *}
   879 
   880 
   881 end