src/HOL/Library/Product_Vector.thy
 author huffman Sun Aug 28 09:20:12 2011 -0700 (2011-08-28) changeset 44568 e6f291cb5810 parent 44282 f0de18b62d63 child 44575 c5e42b8590dd permissions -rw-r--r--
discontinue many legacy theorems about LIM and LIMSEQ, in favor of tendsto theorems
```     1 (*  Title:      HOL/Library/Product_Vector.thy
```
```     2     Author:     Brian Huffman
```
```     3 *)
```
```     4
```
```     5 header {* Cartesian Products as Vector Spaces *}
```
```     6
```
```     7 theory Product_Vector
```
```     8 imports Inner_Product Product_plus
```
```     9 begin
```
```    10
```
```    11 subsection {* Product is a real vector space *}
```
```    12
```
```    13 instantiation prod :: (real_vector, real_vector) real_vector
```
```    14 begin
```
```    15
```
```    16 definition scaleR_prod_def:
```
```    17   "scaleR r A = (scaleR r (fst A), scaleR r (snd A))"
```
```    18
```
```    19 lemma fst_scaleR [simp]: "fst (scaleR r A) = scaleR r (fst A)"
```
```    20   unfolding scaleR_prod_def by simp
```
```    21
```
```    22 lemma snd_scaleR [simp]: "snd (scaleR r A) = scaleR r (snd A)"
```
```    23   unfolding scaleR_prod_def by simp
```
```    24
```
```    25 lemma scaleR_Pair [simp]: "scaleR r (a, b) = (scaleR r a, scaleR r b)"
```
```    26   unfolding scaleR_prod_def by simp
```
```    27
```
```    28 instance proof
```
```    29   fix a b :: real and x y :: "'a \<times> 'b"
```
```    30   show "scaleR a (x + y) = scaleR a x + scaleR a y"
```
```    31     by (simp add: prod_eq_iff scaleR_right_distrib)
```
```    32   show "scaleR (a + b) x = scaleR a x + scaleR b x"
```
```    33     by (simp add: prod_eq_iff scaleR_left_distrib)
```
```    34   show "scaleR a (scaleR b x) = scaleR (a * b) x"
```
```    35     by (simp add: prod_eq_iff)
```
```    36   show "scaleR 1 x = x"
```
```    37     by (simp add: prod_eq_iff)
```
```    38 qed
```
```    39
```
```    40 end
```
```    41
```
```    42 subsection {* Product is a topological space *}
```
```    43
```
```    44 instantiation prod :: (topological_space, topological_space) topological_space
```
```    45 begin
```
```    46
```
```    47 definition open_prod_def:
```
```    48   "open (S :: ('a \<times> 'b) set) \<longleftrightarrow>
```
```    49     (\<forall>x\<in>S. \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S)"
```
```    50
```
```    51 lemma open_prod_elim:
```
```    52   assumes "open S" and "x \<in> S"
```
```    53   obtains A B where "open A" and "open B" and "x \<in> A \<times> B" and "A \<times> B \<subseteq> S"
```
```    54 using assms unfolding open_prod_def by fast
```
```    55
```
```    56 lemma open_prod_intro:
```
```    57   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S"
```
```    58   shows "open S"
```
```    59 using assms unfolding open_prod_def by fast
```
```    60
```
```    61 instance proof
```
```    62   show "open (UNIV :: ('a \<times> 'b) set)"
```
```    63     unfolding open_prod_def by auto
```
```    64 next
```
```    65   fix S T :: "('a \<times> 'b) set"
```
```    66   assume "open S" "open T"
```
```    67   show "open (S \<inter> T)"
```
```    68   proof (rule open_prod_intro)
```
```    69     fix x assume x: "x \<in> S \<inter> T"
```
```    70     from x have "x \<in> S" by simp
```
```    71     obtain Sa Sb where A: "open Sa" "open Sb" "x \<in> Sa \<times> Sb" "Sa \<times> Sb \<subseteq> S"
```
```    72       using `open S` and `x \<in> S` by (rule open_prod_elim)
```
```    73     from x have "x \<in> T" by simp
```
```    74     obtain Ta Tb where B: "open Ta" "open Tb" "x \<in> Ta \<times> Tb" "Ta \<times> Tb \<subseteq> T"
```
```    75       using `open T` and `x \<in> T` by (rule open_prod_elim)
```
```    76     let ?A = "Sa \<inter> Ta" and ?B = "Sb \<inter> Tb"
```
```    77     have "open ?A \<and> open ?B \<and> x \<in> ?A \<times> ?B \<and> ?A \<times> ?B \<subseteq> S \<inter> T"
```
```    78       using A B by (auto simp add: open_Int)
```
```    79     thus "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S \<inter> T"
```
```    80       by fast
```
```    81   qed
```
```    82 next
```
```    83   fix K :: "('a \<times> 'b) set set"
```
```    84   assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
```
```    85     unfolding open_prod_def by fast
```
```    86 qed
```
```    87
```
```    88 end
```
```    89
```
```    90 lemma open_Times: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<times> T)"
```
```    91 unfolding open_prod_def by auto
```
```    92
```
```    93 lemma fst_vimage_eq_Times: "fst -` S = S \<times> UNIV"
```
```    94 by auto
```
```    95
```
```    96 lemma snd_vimage_eq_Times: "snd -` S = UNIV \<times> S"
```
```    97 by auto
```
```    98
```
```    99 lemma open_vimage_fst: "open S \<Longrightarrow> open (fst -` S)"
```
```   100 by (simp add: fst_vimage_eq_Times open_Times)
```
```   101
```
```   102 lemma open_vimage_snd: "open S \<Longrightarrow> open (snd -` S)"
```
```   103 by (simp add: snd_vimage_eq_Times open_Times)
```
```   104
```
```   105 lemma closed_vimage_fst: "closed S \<Longrightarrow> closed (fst -` S)"
```
```   106 unfolding closed_open vimage_Compl [symmetric]
```
```   107 by (rule open_vimage_fst)
```
```   108
```
```   109 lemma closed_vimage_snd: "closed S \<Longrightarrow> closed (snd -` S)"
```
```   110 unfolding closed_open vimage_Compl [symmetric]
```
```   111 by (rule open_vimage_snd)
```
```   112
```
```   113 lemma closed_Times: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
```
```   114 proof -
```
```   115   have "S \<times> T = (fst -` S) \<inter> (snd -` T)" by auto
```
```   116   thus "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
```
```   117     by (simp add: closed_vimage_fst closed_vimage_snd closed_Int)
```
```   118 qed
```
```   119
```
```   120 lemma openI: (* TODO: move *)
```
```   121   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
```
```   122   shows "open S"
```
```   123 proof -
```
```   124   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
```
```   125   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
```
```   126   ultimately show "open S" by simp
```
```   127 qed
```
```   128
```
```   129 lemma subset_fst_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> y \<in> B \<Longrightarrow> A \<subseteq> fst ` S"
```
```   130   unfolding image_def subset_eq by force
```
```   131
```
```   132 lemma subset_snd_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> x \<in> A \<Longrightarrow> B \<subseteq> snd ` S"
```
```   133   unfolding image_def subset_eq by force
```
```   134
```
```   135 lemma open_image_fst: assumes "open S" shows "open (fst ` S)"
```
```   136 proof (rule openI)
```
```   137   fix x assume "x \<in> fst ` S"
```
```   138   then obtain y where "(x, y) \<in> S" by auto
```
```   139   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
```
```   140     using `open S` unfolding open_prod_def by auto
```
```   141   from `A \<times> B \<subseteq> S` `y \<in> B` have "A \<subseteq> fst ` S" by (rule subset_fst_imageI)
```
```   142   with `open A` `x \<in> A` have "open A \<and> x \<in> A \<and> A \<subseteq> fst ` S" by simp
```
```   143   then show "\<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> fst ` S" by - (rule exI)
```
```   144 qed
```
```   145
```
```   146 lemma open_image_snd: assumes "open S" shows "open (snd ` S)"
```
```   147 proof (rule openI)
```
```   148   fix y assume "y \<in> snd ` S"
```
```   149   then obtain x where "(x, y) \<in> S" by auto
```
```   150   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
```
```   151     using `open S` unfolding open_prod_def by auto
```
```   152   from `A \<times> B \<subseteq> S` `x \<in> A` have "B \<subseteq> snd ` S" by (rule subset_snd_imageI)
```
```   153   with `open B` `y \<in> B` have "open B \<and> y \<in> B \<and> B \<subseteq> snd ` S" by simp
```
```   154   then show "\<exists>T. open T \<and> y \<in> T \<and> T \<subseteq> snd ` S" by - (rule exI)
```
```   155 qed
```
```   156
```
```   157 text {* Product preserves separation axioms. *}
```
```   158
```
```   159 lemma mem_Times_iff: "x \<in> A \<times> B \<longleftrightarrow> fst x \<in> A \<and> snd x \<in> B"
```
```   160   by (induct x) simp (* TODO: move elsewhere *)
```
```   161
```
```   162 instance prod :: (t0_space, t0_space) t0_space
```
```   163 proof
```
```   164   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
```
```   165   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
```
```   166     by (simp add: prod_eq_iff)
```
```   167   thus "\<exists>U. open U \<and> (x \<in> U) \<noteq> (y \<in> U)"
```
```   168     apply (rule disjE)
```
```   169     apply (drule t0_space, erule exE, rule_tac x="U \<times> UNIV" in exI)
```
```   170     apply (simp add: open_Times mem_Times_iff)
```
```   171     apply (drule t0_space, erule exE, rule_tac x="UNIV \<times> U" in exI)
```
```   172     apply (simp add: open_Times mem_Times_iff)
```
```   173     done
```
```   174 qed
```
```   175
```
```   176 instance prod :: (t1_space, t1_space) t1_space
```
```   177 proof
```
```   178   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
```
```   179   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
```
```   180     by (simp add: prod_eq_iff)
```
```   181   thus "\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
```
```   182     apply (rule disjE)
```
```   183     apply (drule t1_space, erule exE, rule_tac x="U \<times> UNIV" in exI)
```
```   184     apply (simp add: open_Times mem_Times_iff)
```
```   185     apply (drule t1_space, erule exE, rule_tac x="UNIV \<times> U" in exI)
```
```   186     apply (simp add: open_Times mem_Times_iff)
```
```   187     done
```
```   188 qed
```
```   189
```
```   190 instance prod :: (t2_space, t2_space) t2_space
```
```   191 proof
```
```   192   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
```
```   193   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
```
```   194     by (simp add: prod_eq_iff)
```
```   195   thus "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
```
```   196     apply (rule disjE)
```
```   197     apply (drule hausdorff, clarify)
```
```   198     apply (rule_tac x="U \<times> UNIV" in exI, rule_tac x="V \<times> UNIV" in exI)
```
```   199     apply (simp add: open_Times mem_Times_iff disjoint_iff_not_equal)
```
```   200     apply (drule hausdorff, clarify)
```
```   201     apply (rule_tac x="UNIV \<times> U" in exI, rule_tac x="UNIV \<times> V" in exI)
```
```   202     apply (simp add: open_Times mem_Times_iff disjoint_iff_not_equal)
```
```   203     done
```
```   204 qed
```
```   205
```
```   206 subsection {* Product is a metric space *}
```
```   207
```
```   208 instantiation prod :: (metric_space, metric_space) metric_space
```
```   209 begin
```
```   210
```
```   211 definition dist_prod_def:
```
```   212   "dist x y = sqrt ((dist (fst x) (fst y))\<twosuperior> + (dist (snd x) (snd y))\<twosuperior>)"
```
```   213
```
```   214 lemma dist_Pair_Pair: "dist (a, b) (c, d) = sqrt ((dist a c)\<twosuperior> + (dist b d)\<twosuperior>)"
```
```   215   unfolding dist_prod_def by simp
```
```   216
```
```   217 lemma dist_fst_le: "dist (fst x) (fst y) \<le> dist x y"
```
```   218 unfolding dist_prod_def by (rule real_sqrt_sum_squares_ge1)
```
```   219
```
```   220 lemma dist_snd_le: "dist (snd x) (snd y) \<le> dist x y"
```
```   221 unfolding dist_prod_def by (rule real_sqrt_sum_squares_ge2)
```
```   222
```
```   223 instance proof
```
```   224   fix x y :: "'a \<times> 'b"
```
```   225   show "dist x y = 0 \<longleftrightarrow> x = y"
```
```   226     unfolding dist_prod_def prod_eq_iff by simp
```
```   227 next
```
```   228   fix x y z :: "'a \<times> 'b"
```
```   229   show "dist x y \<le> dist x z + dist y z"
```
```   230     unfolding dist_prod_def
```
```   231     by (intro order_trans [OF _ real_sqrt_sum_squares_triangle_ineq]
```
```   232         real_sqrt_le_mono add_mono power_mono dist_triangle2 zero_le_dist)
```
```   233 next
```
```   234   (* FIXME: long proof! *)
```
```   235   (* Maybe it would be easier to define topological spaces *)
```
```   236   (* in terms of neighborhoods instead of open sets? *)
```
```   237   fix S :: "('a \<times> 'b) set"
```
```   238   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
```
```   239   proof
```
```   240     assume "open S" show "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S"
```
```   241     proof
```
```   242       fix x assume "x \<in> S"
```
```   243       obtain A B where "open A" "open B" "x \<in> A \<times> B" "A \<times> B \<subseteq> S"
```
```   244         using `open S` and `x \<in> S` by (rule open_prod_elim)
```
```   245       obtain r where r: "0 < r" "\<forall>y. dist y (fst x) < r \<longrightarrow> y \<in> A"
```
```   246         using `open A` and `x \<in> A \<times> B` unfolding open_dist by auto
```
```   247       obtain s where s: "0 < s" "\<forall>y. dist y (snd x) < s \<longrightarrow> y \<in> B"
```
```   248         using `open B` and `x \<in> A \<times> B` unfolding open_dist by auto
```
```   249       let ?e = "min r s"
```
```   250       have "0 < ?e \<and> (\<forall>y. dist y x < ?e \<longrightarrow> y \<in> S)"
```
```   251       proof (intro allI impI conjI)
```
```   252         show "0 < min r s" by (simp add: r(1) s(1))
```
```   253       next
```
```   254         fix y assume "dist y x < min r s"
```
```   255         hence "dist y x < r" and "dist y x < s"
```
```   256           by simp_all
```
```   257         hence "dist (fst y) (fst x) < r" and "dist (snd y) (snd x) < s"
```
```   258           by (auto intro: le_less_trans dist_fst_le dist_snd_le)
```
```   259         hence "fst y \<in> A" and "snd y \<in> B"
```
```   260           by (simp_all add: r(2) s(2))
```
```   261         hence "y \<in> A \<times> B" by (induct y, simp)
```
```   262         with `A \<times> B \<subseteq> S` show "y \<in> S" ..
```
```   263       qed
```
```   264       thus "\<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" ..
```
```   265     qed
```
```   266   next
```
```   267     assume "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" thus "open S"
```
```   268     unfolding open_prod_def open_dist
```
```   269     apply safe
```
```   270     apply (drule (1) bspec)
```
```   271     apply clarify
```
```   272     apply (subgoal_tac "\<exists>r>0. \<exists>s>0. e = sqrt (r\<twosuperior> + s\<twosuperior>)")
```
```   273     apply clarify
```
```   274     apply (rule_tac x="{y. dist y a < r}" in exI)
```
```   275     apply (rule_tac x="{y. dist y b < s}" in exI)
```
```   276     apply (rule conjI)
```
```   277     apply clarify
```
```   278     apply (rule_tac x="r - dist x a" in exI, rule conjI, simp)
```
```   279     apply clarify
```
```   280     apply (simp add: less_diff_eq)
```
```   281     apply (erule le_less_trans [OF dist_triangle])
```
```   282     apply (rule conjI)
```
```   283     apply clarify
```
```   284     apply (rule_tac x="s - dist x b" in exI, rule conjI, simp)
```
```   285     apply clarify
```
```   286     apply (simp add: less_diff_eq)
```
```   287     apply (erule le_less_trans [OF dist_triangle])
```
```   288     apply (rule conjI)
```
```   289     apply simp
```
```   290     apply (clarify, rename_tac c d)
```
```   291     apply (drule spec, erule mp)
```
```   292     apply (simp add: dist_Pair_Pair add_strict_mono power_strict_mono)
```
```   293     apply (rule_tac x="e / sqrt 2" in exI, simp add: divide_pos_pos)
```
```   294     apply (rule_tac x="e / sqrt 2" in exI, simp add: divide_pos_pos)
```
```   295     apply (simp add: power_divide)
```
```   296     done
```
```   297   qed
```
```   298 qed
```
```   299
```
```   300 end
```
```   301
```
```   302 subsection {* Continuity of operations *}
```
```   303
```
```   304 lemma tendsto_fst [tendsto_intros]:
```
```   305   assumes "(f ---> a) net"
```
```   306   shows "((\<lambda>x. fst (f x)) ---> fst a) net"
```
```   307 proof (rule topological_tendstoI)
```
```   308   fix S assume "open S" "fst a \<in> S"
```
```   309   then have "open (fst -` S)" "a \<in> fst -` S"
```
```   310     unfolding open_prod_def
```
```   311     apply simp_all
```
```   312     apply clarify
```
```   313     apply (rule exI, erule conjI)
```
```   314     apply (rule exI, rule conjI [OF open_UNIV])
```
```   315     apply auto
```
```   316     done
```
```   317   with assms have "eventually (\<lambda>x. f x \<in> fst -` S) net"
```
```   318     by (rule topological_tendstoD)
```
```   319   then show "eventually (\<lambda>x. fst (f x) \<in> S) net"
```
```   320     by simp
```
```   321 qed
```
```   322
```
```   323 lemma tendsto_snd [tendsto_intros]:
```
```   324   assumes "(f ---> a) net"
```
```   325   shows "((\<lambda>x. snd (f x)) ---> snd a) net"
```
```   326 proof (rule topological_tendstoI)
```
```   327   fix S assume "open S" "snd a \<in> S"
```
```   328   then have "open (snd -` S)" "a \<in> snd -` S"
```
```   329     unfolding open_prod_def
```
```   330     apply simp_all
```
```   331     apply clarify
```
```   332     apply (rule exI, rule conjI [OF open_UNIV])
```
```   333     apply (rule exI, erule conjI)
```
```   334     apply auto
```
```   335     done
```
```   336   with assms have "eventually (\<lambda>x. f x \<in> snd -` S) net"
```
```   337     by (rule topological_tendstoD)
```
```   338   then show "eventually (\<lambda>x. snd (f x) \<in> S) net"
```
```   339     by simp
```
```   340 qed
```
```   341
```
```   342 lemma tendsto_Pair [tendsto_intros]:
```
```   343   assumes "(f ---> a) net" and "(g ---> b) net"
```
```   344   shows "((\<lambda>x. (f x, g x)) ---> (a, b)) net"
```
```   345 proof (rule topological_tendstoI)
```
```   346   fix S assume "open S" "(a, b) \<in> S"
```
```   347   then obtain A B where "open A" "open B" "a \<in> A" "b \<in> B" "A \<times> B \<subseteq> S"
```
```   348     unfolding open_prod_def by auto
```
```   349   have "eventually (\<lambda>x. f x \<in> A) net"
```
```   350     using `(f ---> a) net` `open A` `a \<in> A`
```
```   351     by (rule topological_tendstoD)
```
```   352   moreover
```
```   353   have "eventually (\<lambda>x. g x \<in> B) net"
```
```   354     using `(g ---> b) net` `open B` `b \<in> B`
```
```   355     by (rule topological_tendstoD)
```
```   356   ultimately
```
```   357   show "eventually (\<lambda>x. (f x, g x) \<in> S) net"
```
```   358     by (rule eventually_elim2)
```
```   359        (simp add: subsetD [OF `A \<times> B \<subseteq> S`])
```
```   360 qed
```
```   361
```
```   362 lemma isCont_fst [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. fst (f x)) a"
```
```   363   unfolding isCont_def by (rule tendsto_fst)
```
```   364
```
```   365 lemma isCont_snd [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. snd (f x)) a"
```
```   366   unfolding isCont_def by (rule tendsto_snd)
```
```   367
```
```   368 lemma isCont_Pair [simp]:
```
```   369   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) a"
```
```   370   unfolding isCont_def by (rule tendsto_Pair)
```
```   371
```
```   372 lemma Cauchy_fst: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. fst (X n))"
```
```   373 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_fst_le])
```
```   374
```
```   375 lemma Cauchy_snd: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. snd (X n))"
```
```   376 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_snd_le])
```
```   377
```
```   378 lemma Cauchy_Pair:
```
```   379   assumes "Cauchy X" and "Cauchy Y"
```
```   380   shows "Cauchy (\<lambda>n. (X n, Y n))"
```
```   381 proof (rule metric_CauchyI)
```
```   382   fix r :: real assume "0 < r"
```
```   383   then have "0 < r / sqrt 2" (is "0 < ?s")
```
```   384     by (simp add: divide_pos_pos)
```
```   385   obtain M where M: "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < ?s"
```
```   386     using metric_CauchyD [OF `Cauchy X` `0 < ?s`] ..
```
```   387   obtain N where N: "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (Y m) (Y n) < ?s"
```
```   388     using metric_CauchyD [OF `Cauchy Y` `0 < ?s`] ..
```
```   389   have "\<forall>m\<ge>max M N. \<forall>n\<ge>max M N. dist (X m, Y m) (X n, Y n) < r"
```
```   390     using M N by (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
```
```   391   then show "\<exists>n0. \<forall>m\<ge>n0. \<forall>n\<ge>n0. dist (X m, Y m) (X n, Y n) < r" ..
```
```   392 qed
```
```   393
```
```   394 subsection {* Product is a complete metric space *}
```
```   395
```
```   396 instance prod :: (complete_space, complete_space) complete_space
```
```   397 proof
```
```   398   fix X :: "nat \<Rightarrow> 'a \<times> 'b" assume "Cauchy X"
```
```   399   have 1: "(\<lambda>n. fst (X n)) ----> lim (\<lambda>n. fst (X n))"
```
```   400     using Cauchy_fst [OF `Cauchy X`]
```
```   401     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
```
```   402   have 2: "(\<lambda>n. snd (X n)) ----> lim (\<lambda>n. snd (X n))"
```
```   403     using Cauchy_snd [OF `Cauchy X`]
```
```   404     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
```
```   405   have "X ----> (lim (\<lambda>n. fst (X n)), lim (\<lambda>n. snd (X n)))"
```
```   406     using tendsto_Pair [OF 1 2] by simp
```
```   407   then show "convergent X"
```
```   408     by (rule convergentI)
```
```   409 qed
```
```   410
```
```   411 subsection {* Product is a normed vector space *}
```
```   412
```
```   413 instantiation prod :: (real_normed_vector, real_normed_vector) real_normed_vector
```
```   414 begin
```
```   415
```
```   416 definition norm_prod_def:
```
```   417   "norm x = sqrt ((norm (fst x))\<twosuperior> + (norm (snd x))\<twosuperior>)"
```
```   418
```
```   419 definition sgn_prod_def:
```
```   420   "sgn (x::'a \<times> 'b) = scaleR (inverse (norm x)) x"
```
```   421
```
```   422 lemma norm_Pair: "norm (a, b) = sqrt ((norm a)\<twosuperior> + (norm b)\<twosuperior>)"
```
```   423   unfolding norm_prod_def by simp
```
```   424
```
```   425 instance proof
```
```   426   fix r :: real and x y :: "'a \<times> 'b"
```
```   427   show "0 \<le> norm x"
```
```   428     unfolding norm_prod_def by simp
```
```   429   show "norm x = 0 \<longleftrightarrow> x = 0"
```
```   430     unfolding norm_prod_def
```
```   431     by (simp add: prod_eq_iff)
```
```   432   show "norm (x + y) \<le> norm x + norm y"
```
```   433     unfolding norm_prod_def
```
```   434     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
```
```   435     apply (simp add: add_mono power_mono norm_triangle_ineq)
```
```   436     done
```
```   437   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
```
```   438     unfolding norm_prod_def
```
```   439     apply (simp add: power_mult_distrib)
```
```   440     apply (simp add: right_distrib [symmetric])
```
```   441     apply (simp add: real_sqrt_mult_distrib)
```
```   442     done
```
```   443   show "sgn x = scaleR (inverse (norm x)) x"
```
```   444     by (rule sgn_prod_def)
```
```   445   show "dist x y = norm (x - y)"
```
```   446     unfolding dist_prod_def norm_prod_def
```
```   447     by (simp add: dist_norm)
```
```   448 qed
```
```   449
```
```   450 end
```
```   451
```
```   452 instance prod :: (banach, banach) banach ..
```
```   453
```
```   454 subsection {* Product is an inner product space *}
```
```   455
```
```   456 instantiation prod :: (real_inner, real_inner) real_inner
```
```   457 begin
```
```   458
```
```   459 definition inner_prod_def:
```
```   460   "inner x y = inner (fst x) (fst y) + inner (snd x) (snd y)"
```
```   461
```
```   462 lemma inner_Pair [simp]: "inner (a, b) (c, d) = inner a c + inner b d"
```
```   463   unfolding inner_prod_def by simp
```
```   464
```
```   465 instance proof
```
```   466   fix r :: real
```
```   467   fix x y z :: "'a::real_inner * 'b::real_inner"
```
```   468   show "inner x y = inner y x"
```
```   469     unfolding inner_prod_def
```
```   470     by (simp add: inner_commute)
```
```   471   show "inner (x + y) z = inner x z + inner y z"
```
```   472     unfolding inner_prod_def
```
```   473     by (simp add: inner_add_left)
```
```   474   show "inner (scaleR r x) y = r * inner x y"
```
```   475     unfolding inner_prod_def
```
```   476     by (simp add: right_distrib)
```
```   477   show "0 \<le> inner x x"
```
```   478     unfolding inner_prod_def
```
```   479     by (intro add_nonneg_nonneg inner_ge_zero)
```
```   480   show "inner x x = 0 \<longleftrightarrow> x = 0"
```
```   481     unfolding inner_prod_def prod_eq_iff
```
```   482     by (simp add: add_nonneg_eq_0_iff)
```
```   483   show "norm x = sqrt (inner x x)"
```
```   484     unfolding norm_prod_def inner_prod_def
```
```   485     by (simp add: power2_norm_eq_inner)
```
```   486 qed
```
```   487
```
```   488 end
```
```   489
```
```   490 subsection {* Pair operations are linear *}
```
```   491
```
```   492 lemma bounded_linear_fst: "bounded_linear fst"
```
```   493   using fst_add fst_scaleR
```
```   494   by (rule bounded_linear_intro [where K=1], simp add: norm_prod_def)
```
```   495
```
```   496 lemma bounded_linear_snd: "bounded_linear snd"
```
```   497   using snd_add snd_scaleR
```
```   498   by (rule bounded_linear_intro [where K=1], simp add: norm_prod_def)
```
```   499
```
```   500 text {* TODO: move to NthRoot *}
```
```   501 lemma sqrt_add_le_add_sqrt:
```
```   502   assumes x: "0 \<le> x" and y: "0 \<le> y"
```
```   503   shows "sqrt (x + y) \<le> sqrt x + sqrt y"
```
```   504 apply (rule power2_le_imp_le)
```
```   505 apply (simp add: real_sum_squared_expand x y)
```
```   506 apply (simp add: mult_nonneg_nonneg x y)
```
```   507 apply (simp add: x y)
```
```   508 done
```
```   509
```
```   510 lemma bounded_linear_Pair:
```
```   511   assumes f: "bounded_linear f"
```
```   512   assumes g: "bounded_linear g"
```
```   513   shows "bounded_linear (\<lambda>x. (f x, g x))"
```
```   514 proof
```
```   515   interpret f: bounded_linear f by fact
```
```   516   interpret g: bounded_linear g by fact
```
```   517   fix x y and r :: real
```
```   518   show "(f (x + y), g (x + y)) = (f x, g x) + (f y, g y)"
```
```   519     by (simp add: f.add g.add)
```
```   520   show "(f (r *\<^sub>R x), g (r *\<^sub>R x)) = r *\<^sub>R (f x, g x)"
```
```   521     by (simp add: f.scaleR g.scaleR)
```
```   522   obtain Kf where "0 < Kf" and norm_f: "\<And>x. norm (f x) \<le> norm x * Kf"
```
```   523     using f.pos_bounded by fast
```
```   524   obtain Kg where "0 < Kg" and norm_g: "\<And>x. norm (g x) \<le> norm x * Kg"
```
```   525     using g.pos_bounded by fast
```
```   526   have "\<forall>x. norm (f x, g x) \<le> norm x * (Kf + Kg)"
```
```   527     apply (rule allI)
```
```   528     apply (simp add: norm_Pair)
```
```   529     apply (rule order_trans [OF sqrt_add_le_add_sqrt], simp, simp)
```
```   530     apply (simp add: right_distrib)
```
```   531     apply (rule add_mono [OF norm_f norm_g])
```
```   532     done
```
```   533   then show "\<exists>K. \<forall>x. norm (f x, g x) \<le> norm x * K" ..
```
```   534 qed
```
```   535
```
```   536 subsection {* Frechet derivatives involving pairs *}
```
```   537
```
```   538 lemma FDERIV_Pair:
```
```   539   assumes f: "FDERIV f x :> f'" and g: "FDERIV g x :> g'"
```
```   540   shows "FDERIV (\<lambda>x. (f x, g x)) x :> (\<lambda>h. (f' h, g' h))"
```
```   541 apply (rule FDERIV_I)
```
```   542 apply (rule bounded_linear_Pair)
```
```   543 apply (rule FDERIV_bounded_linear [OF f])
```
```   544 apply (rule FDERIV_bounded_linear [OF g])
```
```   545 apply (simp add: norm_Pair)
```
```   546 apply (rule real_LIM_sandwich_zero)
```
```   547 apply (rule tendsto_add_zero)
```
```   548 apply (rule FDERIV_D [OF f])
```
```   549 apply (rule FDERIV_D [OF g])
```
```   550 apply (rename_tac h)
```
```   551 apply (simp add: divide_nonneg_pos)
```
```   552 apply (rename_tac h)
```
```   553 apply (subst add_divide_distrib [symmetric])
```
```   554 apply (rule divide_right_mono [OF _ norm_ge_zero])
```
```   555 apply (rule order_trans [OF sqrt_add_le_add_sqrt])
```
```   556 apply simp
```
```   557 apply simp
```
```   558 apply simp
```
```   559 done
```
```   560
```
```   561 end
```