src/HOL/HOL.thy
author haftmann
Sun Feb 22 22:32:50 2009 +0100 (2009-02-22)
changeset 30063 e7723cb4b2a6
parent 30049 05354c653d3a
child 30160 5f7b17941730
permissions -rw-r--r--
experimental switch to new well-sorting algorithm
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* The basis of Higher-Order Logic *}
     6 
     7 theory HOL
     8 imports Pure
     9 uses
    10   ("Tools/hologic.ML")
    11   "~~/src/Tools/IsaPlanner/zipper.ML"
    12   "~~/src/Tools/IsaPlanner/isand.ML"
    13   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    14   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    15   "~~/src/Provers/project_rule.ML"
    16   "~~/src/Provers/hypsubst.ML"
    17   "~~/src/Provers/splitter.ML"
    18   "~~/src/Provers/classical.ML"
    19   "~~/src/Provers/blast.ML"
    20   "~~/src/Provers/clasimp.ML"
    21   "~~/src/Provers/coherent.ML"
    22   "~~/src/Provers/eqsubst.ML"
    23   "~~/src/Provers/quantifier1.ML"
    24   ("Tools/simpdata.ML")
    25   "~~/src/Tools/random_word.ML"
    26   "~~/src/Tools/atomize_elim.ML"
    27   "~~/src/Tools/induct.ML"
    28   ("~~/src/Tools/induct_tacs.ML")
    29   "~~/src/Tools/value.ML"
    30   "~~/src/Tools/code/code_name.ML"
    31   "~~/src/Tools/code/code_wellsorted.ML" (* formal dependency *)
    32   (*"~~/src/Tools/code/code_funcgr.ML"*)
    33   "~~/src/Tools/code/code_thingol.ML"
    34   "~~/src/Tools/code/code_printer.ML"
    35   "~~/src/Tools/code/code_target.ML"
    36   "~~/src/Tools/code/code_ml.ML"
    37   "~~/src/Tools/code/code_haskell.ML"
    38   "~~/src/Tools/nbe.ML"
    39   ("Tools/recfun_codegen.ML")
    40 begin
    41 
    42 subsection {* Primitive logic *}
    43 
    44 subsubsection {* Core syntax *}
    45 
    46 classes type
    47 defaultsort type
    48 setup {* ObjectLogic.add_base_sort @{sort type} *}
    49 
    50 arities
    51   "fun" :: (type, type) type
    52   itself :: (type) type
    53 
    54 global
    55 
    56 typedecl bool
    57 
    58 judgment
    59   Trueprop      :: "bool => prop"                   ("(_)" 5)
    60 
    61 consts
    62   Not           :: "bool => bool"                   ("~ _" [40] 40)
    63   True          :: bool
    64   False         :: bool
    65 
    66   The           :: "('a => bool) => 'a"
    67   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    68   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    69   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    70   Let           :: "['a, 'a => 'b] => 'b"
    71 
    72   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    73   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    74   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    75   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    76 
    77 local
    78 
    79 consts
    80   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    81 
    82 
    83 subsubsection {* Additional concrete syntax *}
    84 
    85 notation (output)
    86   "op ="  (infix "=" 50)
    87 
    88 abbreviation
    89   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    90   "x ~= y == ~ (x = y)"
    91 
    92 notation (output)
    93   not_equal  (infix "~=" 50)
    94 
    95 notation (xsymbols)
    96   Not  ("\<not> _" [40] 40) and
    97   "op &"  (infixr "\<and>" 35) and
    98   "op |"  (infixr "\<or>" 30) and
    99   "op -->"  (infixr "\<longrightarrow>" 25) and
   100   not_equal  (infix "\<noteq>" 50)
   101 
   102 notation (HTML output)
   103   Not  ("\<not> _" [40] 40) and
   104   "op &"  (infixr "\<and>" 35) and
   105   "op |"  (infixr "\<or>" 30) and
   106   not_equal  (infix "\<noteq>" 50)
   107 
   108 abbreviation (iff)
   109   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   110   "A <-> B == A = B"
   111 
   112 notation (xsymbols)
   113   iff  (infixr "\<longleftrightarrow>" 25)
   114 
   115 
   116 nonterminals
   117   letbinds  letbind
   118   case_syn  cases_syn
   119 
   120 syntax
   121   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   122 
   123   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   124   ""            :: "letbind => letbinds"                 ("_")
   125   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   126   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   127 
   128   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   129   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   130   ""            :: "case_syn => cases_syn"               ("_")
   131   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   132 
   133 translations
   134   "THE x. P"              == "The (%x. P)"
   135   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   136   "let x = a in e"        == "Let a (%x. e)"
   137 
   138 print_translation {*
   139 (* To avoid eta-contraction of body: *)
   140 [("The", fn [Abs abs] =>
   141      let val (x,t) = atomic_abs_tr' abs
   142      in Syntax.const "_The" $ x $ t end)]
   143 *}
   144 
   145 syntax (xsymbols)
   146   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   147 
   148 notation (xsymbols)
   149   All  (binder "\<forall>" 10) and
   150   Ex  (binder "\<exists>" 10) and
   151   Ex1  (binder "\<exists>!" 10)
   152 
   153 notation (HTML output)
   154   All  (binder "\<forall>" 10) and
   155   Ex  (binder "\<exists>" 10) and
   156   Ex1  (binder "\<exists>!" 10)
   157 
   158 notation (HOL)
   159   All  (binder "! " 10) and
   160   Ex  (binder "? " 10) and
   161   Ex1  (binder "?! " 10)
   162 
   163 
   164 subsubsection {* Axioms and basic definitions *}
   165 
   166 axioms
   167   refl:           "t = (t::'a)"
   168   subst:          "s = t \<Longrightarrow> P s \<Longrightarrow> P t"
   169   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   170     -- {*Extensionality is built into the meta-logic, and this rule expresses
   171          a related property.  It is an eta-expanded version of the traditional
   172          rule, and similar to the ABS rule of HOL*}
   173 
   174   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   175 
   176   impI:           "(P ==> Q) ==> P-->Q"
   177   mp:             "[| P-->Q;  P |] ==> Q"
   178 
   179 
   180 defs
   181   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   182   All_def:      "All(P)    == (P = (%x. True))"
   183   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   184   False_def:    "False     == (!P. P)"
   185   not_def:      "~ P       == P-->False"
   186   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   187   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   188   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   189 
   190 axioms
   191   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   192   True_or_False:  "(P=True) | (P=False)"
   193 
   194 defs
   195   Let_def:      "Let s f == f(s)"
   196   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   197 
   198 finalconsts
   199   "op ="
   200   "op -->"
   201   The
   202 
   203 axiomatization
   204   undefined :: 'a
   205 
   206 abbreviation (input)
   207   "arbitrary \<equiv> undefined"
   208 
   209 
   210 subsubsection {* Generic classes and algebraic operations *}
   211 
   212 class default =
   213   fixes default :: 'a
   214 
   215 class zero = 
   216   fixes zero :: 'a  ("0")
   217 
   218 class one =
   219   fixes one  :: 'a  ("1")
   220 
   221 hide (open) const zero one
   222 
   223 class plus =
   224   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
   225 
   226 class minus =
   227   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
   228 
   229 class uminus =
   230   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
   231 
   232 class times =
   233   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
   234 
   235 class inverse =
   236   fixes inverse :: "'a \<Rightarrow> 'a"
   237     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
   238 
   239 class abs =
   240   fixes abs :: "'a \<Rightarrow> 'a"
   241 begin
   242 
   243 notation (xsymbols)
   244   abs  ("\<bar>_\<bar>")
   245 
   246 notation (HTML output)
   247   abs  ("\<bar>_\<bar>")
   248 
   249 end
   250 
   251 class sgn =
   252   fixes sgn :: "'a \<Rightarrow> 'a"
   253 
   254 class ord =
   255   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   256     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   257 begin
   258 
   259 notation
   260   less_eq  ("op <=") and
   261   less_eq  ("(_/ <= _)" [51, 51] 50) and
   262   less  ("op <") and
   263   less  ("(_/ < _)"  [51, 51] 50)
   264   
   265 notation (xsymbols)
   266   less_eq  ("op \<le>") and
   267   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   268 
   269 notation (HTML output)
   270   less_eq  ("op \<le>") and
   271   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   272 
   273 abbreviation (input)
   274   greater_eq  (infix ">=" 50) where
   275   "x >= y \<equiv> y <= x"
   276 
   277 notation (input)
   278   greater_eq  (infix "\<ge>" 50)
   279 
   280 abbreviation (input)
   281   greater  (infix ">" 50) where
   282   "x > y \<equiv> y < x"
   283 
   284 end
   285 
   286 syntax
   287   "_index1"  :: index    ("\<^sub>1")
   288 translations
   289   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   290 
   291 typed_print_translation {*
   292 let
   293   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   294     if (not o null) ts orelse T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   295     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   296 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   297 *} -- {* show types that are presumably too general *}
   298 
   299 
   300 subsection {* Fundamental rules *}
   301 
   302 subsubsection {* Equality *}
   303 
   304 lemma sym: "s = t ==> t = s"
   305   by (erule subst) (rule refl)
   306 
   307 lemma ssubst: "t = s ==> P s ==> P t"
   308   by (drule sym) (erule subst)
   309 
   310 lemma trans: "[| r=s; s=t |] ==> r=t"
   311   by (erule subst)
   312 
   313 lemma meta_eq_to_obj_eq: 
   314   assumes meq: "A == B"
   315   shows "A = B"
   316   by (unfold meq) (rule refl)
   317 
   318 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   319      (* a = b
   320         |   |
   321         c = d   *)
   322 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   323 apply (rule trans)
   324 apply (rule trans)
   325 apply (rule sym)
   326 apply assumption+
   327 done
   328 
   329 text {* For calculational reasoning: *}
   330 
   331 lemma forw_subst: "a = b ==> P b ==> P a"
   332   by (rule ssubst)
   333 
   334 lemma back_subst: "P a ==> a = b ==> P b"
   335   by (rule subst)
   336 
   337 
   338 subsubsection {*Congruence rules for application*}
   339 
   340 (*similar to AP_THM in Gordon's HOL*)
   341 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   342 apply (erule subst)
   343 apply (rule refl)
   344 done
   345 
   346 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   347 lemma arg_cong: "x=y ==> f(x)=f(y)"
   348 apply (erule subst)
   349 apply (rule refl)
   350 done
   351 
   352 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   353 apply (erule ssubst)+
   354 apply (rule refl)
   355 done
   356 
   357 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   358 apply (erule subst)+
   359 apply (rule refl)
   360 done
   361 
   362 
   363 subsubsection {*Equality of booleans -- iff*}
   364 
   365 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   366   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   367 
   368 lemma iffD2: "[| P=Q; Q |] ==> P"
   369   by (erule ssubst)
   370 
   371 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   372   by (erule iffD2)
   373 
   374 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   375   by (drule sym) (rule iffD2)
   376 
   377 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   378   by (drule sym) (rule rev_iffD2)
   379 
   380 lemma iffE:
   381   assumes major: "P=Q"
   382     and minor: "[| P --> Q; Q --> P |] ==> R"
   383   shows R
   384   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   385 
   386 
   387 subsubsection {*True*}
   388 
   389 lemma TrueI: "True"
   390   unfolding True_def by (rule refl)
   391 
   392 lemma eqTrueI: "P ==> P = True"
   393   by (iprover intro: iffI TrueI)
   394 
   395 lemma eqTrueE: "P = True ==> P"
   396   by (erule iffD2) (rule TrueI)
   397 
   398 
   399 subsubsection {*Universal quantifier*}
   400 
   401 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   402   unfolding All_def by (iprover intro: ext eqTrueI assms)
   403 
   404 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   405 apply (unfold All_def)
   406 apply (rule eqTrueE)
   407 apply (erule fun_cong)
   408 done
   409 
   410 lemma allE:
   411   assumes major: "ALL x. P(x)"
   412     and minor: "P(x) ==> R"
   413   shows R
   414   by (iprover intro: minor major [THEN spec])
   415 
   416 lemma all_dupE:
   417   assumes major: "ALL x. P(x)"
   418     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   419   shows R
   420   by (iprover intro: minor major major [THEN spec])
   421 
   422 
   423 subsubsection {* False *}
   424 
   425 text {*
   426   Depends upon @{text spec}; it is impossible to do propositional
   427   logic before quantifiers!
   428 *}
   429 
   430 lemma FalseE: "False ==> P"
   431   apply (unfold False_def)
   432   apply (erule spec)
   433   done
   434 
   435 lemma False_neq_True: "False = True ==> P"
   436   by (erule eqTrueE [THEN FalseE])
   437 
   438 
   439 subsubsection {* Negation *}
   440 
   441 lemma notI:
   442   assumes "P ==> False"
   443   shows "~P"
   444   apply (unfold not_def)
   445   apply (iprover intro: impI assms)
   446   done
   447 
   448 lemma False_not_True: "False ~= True"
   449   apply (rule notI)
   450   apply (erule False_neq_True)
   451   done
   452 
   453 lemma True_not_False: "True ~= False"
   454   apply (rule notI)
   455   apply (drule sym)
   456   apply (erule False_neq_True)
   457   done
   458 
   459 lemma notE: "[| ~P;  P |] ==> R"
   460   apply (unfold not_def)
   461   apply (erule mp [THEN FalseE])
   462   apply assumption
   463   done
   464 
   465 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   466   by (erule notE [THEN notI]) (erule meta_mp)
   467 
   468 
   469 subsubsection {*Implication*}
   470 
   471 lemma impE:
   472   assumes "P-->Q" "P" "Q ==> R"
   473   shows "R"
   474 by (iprover intro: assms mp)
   475 
   476 (* Reduces Q to P-->Q, allowing substitution in P. *)
   477 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   478 by (iprover intro: mp)
   479 
   480 lemma contrapos_nn:
   481   assumes major: "~Q"
   482       and minor: "P==>Q"
   483   shows "~P"
   484 by (iprover intro: notI minor major [THEN notE])
   485 
   486 (*not used at all, but we already have the other 3 combinations *)
   487 lemma contrapos_pn:
   488   assumes major: "Q"
   489       and minor: "P ==> ~Q"
   490   shows "~P"
   491 by (iprover intro: notI minor major notE)
   492 
   493 lemma not_sym: "t ~= s ==> s ~= t"
   494   by (erule contrapos_nn) (erule sym)
   495 
   496 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   497   by (erule subst, erule ssubst, assumption)
   498 
   499 (*still used in HOLCF*)
   500 lemma rev_contrapos:
   501   assumes pq: "P ==> Q"
   502       and nq: "~Q"
   503   shows "~P"
   504 apply (rule nq [THEN contrapos_nn])
   505 apply (erule pq)
   506 done
   507 
   508 subsubsection {*Existential quantifier*}
   509 
   510 lemma exI: "P x ==> EX x::'a. P x"
   511 apply (unfold Ex_def)
   512 apply (iprover intro: allI allE impI mp)
   513 done
   514 
   515 lemma exE:
   516   assumes major: "EX x::'a. P(x)"
   517       and minor: "!!x. P(x) ==> Q"
   518   shows "Q"
   519 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   520 apply (iprover intro: impI [THEN allI] minor)
   521 done
   522 
   523 
   524 subsubsection {*Conjunction*}
   525 
   526 lemma conjI: "[| P; Q |] ==> P&Q"
   527 apply (unfold and_def)
   528 apply (iprover intro: impI [THEN allI] mp)
   529 done
   530 
   531 lemma conjunct1: "[| P & Q |] ==> P"
   532 apply (unfold and_def)
   533 apply (iprover intro: impI dest: spec mp)
   534 done
   535 
   536 lemma conjunct2: "[| P & Q |] ==> Q"
   537 apply (unfold and_def)
   538 apply (iprover intro: impI dest: spec mp)
   539 done
   540 
   541 lemma conjE:
   542   assumes major: "P&Q"
   543       and minor: "[| P; Q |] ==> R"
   544   shows "R"
   545 apply (rule minor)
   546 apply (rule major [THEN conjunct1])
   547 apply (rule major [THEN conjunct2])
   548 done
   549 
   550 lemma context_conjI:
   551   assumes "P" "P ==> Q" shows "P & Q"
   552 by (iprover intro: conjI assms)
   553 
   554 
   555 subsubsection {*Disjunction*}
   556 
   557 lemma disjI1: "P ==> P|Q"
   558 apply (unfold or_def)
   559 apply (iprover intro: allI impI mp)
   560 done
   561 
   562 lemma disjI2: "Q ==> P|Q"
   563 apply (unfold or_def)
   564 apply (iprover intro: allI impI mp)
   565 done
   566 
   567 lemma disjE:
   568   assumes major: "P|Q"
   569       and minorP: "P ==> R"
   570       and minorQ: "Q ==> R"
   571   shows "R"
   572 by (iprover intro: minorP minorQ impI
   573                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   574 
   575 
   576 subsubsection {*Classical logic*}
   577 
   578 lemma classical:
   579   assumes prem: "~P ==> P"
   580   shows "P"
   581 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   582 apply assumption
   583 apply (rule notI [THEN prem, THEN eqTrueI])
   584 apply (erule subst)
   585 apply assumption
   586 done
   587 
   588 lemmas ccontr = FalseE [THEN classical, standard]
   589 
   590 (*notE with premises exchanged; it discharges ~R so that it can be used to
   591   make elimination rules*)
   592 lemma rev_notE:
   593   assumes premp: "P"
   594       and premnot: "~R ==> ~P"
   595   shows "R"
   596 apply (rule ccontr)
   597 apply (erule notE [OF premnot premp])
   598 done
   599 
   600 (*Double negation law*)
   601 lemma notnotD: "~~P ==> P"
   602 apply (rule classical)
   603 apply (erule notE)
   604 apply assumption
   605 done
   606 
   607 lemma contrapos_pp:
   608   assumes p1: "Q"
   609       and p2: "~P ==> ~Q"
   610   shows "P"
   611 by (iprover intro: classical p1 p2 notE)
   612 
   613 
   614 subsubsection {*Unique existence*}
   615 
   616 lemma ex1I:
   617   assumes "P a" "!!x. P(x) ==> x=a"
   618   shows "EX! x. P(x)"
   619 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   620 
   621 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   622 lemma ex_ex1I:
   623   assumes ex_prem: "EX x. P(x)"
   624       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   625   shows "EX! x. P(x)"
   626 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   627 
   628 lemma ex1E:
   629   assumes major: "EX! x. P(x)"
   630       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   631   shows "R"
   632 apply (rule major [unfolded Ex1_def, THEN exE])
   633 apply (erule conjE)
   634 apply (iprover intro: minor)
   635 done
   636 
   637 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   638 apply (erule ex1E)
   639 apply (rule exI)
   640 apply assumption
   641 done
   642 
   643 
   644 subsubsection {*THE: definite description operator*}
   645 
   646 lemma the_equality:
   647   assumes prema: "P a"
   648       and premx: "!!x. P x ==> x=a"
   649   shows "(THE x. P x) = a"
   650 apply (rule trans [OF _ the_eq_trivial])
   651 apply (rule_tac f = "The" in arg_cong)
   652 apply (rule ext)
   653 apply (rule iffI)
   654  apply (erule premx)
   655 apply (erule ssubst, rule prema)
   656 done
   657 
   658 lemma theI:
   659   assumes "P a" and "!!x. P x ==> x=a"
   660   shows "P (THE x. P x)"
   661 by (iprover intro: assms the_equality [THEN ssubst])
   662 
   663 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   664 apply (erule ex1E)
   665 apply (erule theI)
   666 apply (erule allE)
   667 apply (erule mp)
   668 apply assumption
   669 done
   670 
   671 (*Easier to apply than theI: only one occurrence of P*)
   672 lemma theI2:
   673   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   674   shows "Q (THE x. P x)"
   675 by (iprover intro: assms theI)
   676 
   677 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   678 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   679            elim:allE impE)
   680 
   681 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   682 apply (rule the_equality)
   683 apply  assumption
   684 apply (erule ex1E)
   685 apply (erule all_dupE)
   686 apply (drule mp)
   687 apply  assumption
   688 apply (erule ssubst)
   689 apply (erule allE)
   690 apply (erule mp)
   691 apply assumption
   692 done
   693 
   694 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   695 apply (rule the_equality)
   696 apply (rule refl)
   697 apply (erule sym)
   698 done
   699 
   700 
   701 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   702 
   703 lemma disjCI:
   704   assumes "~Q ==> P" shows "P|Q"
   705 apply (rule classical)
   706 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   707 done
   708 
   709 lemma excluded_middle: "~P | P"
   710 by (iprover intro: disjCI)
   711 
   712 text {*
   713   case distinction as a natural deduction rule.
   714   Note that @{term "~P"} is the second case, not the first
   715 *}
   716 lemma case_split [case_names True False]:
   717   assumes prem1: "P ==> Q"
   718       and prem2: "~P ==> Q"
   719   shows "Q"
   720 apply (rule excluded_middle [THEN disjE])
   721 apply (erule prem2)
   722 apply (erule prem1)
   723 done
   724 
   725 (*Classical implies (-->) elimination. *)
   726 lemma impCE:
   727   assumes major: "P-->Q"
   728       and minor: "~P ==> R" "Q ==> R"
   729   shows "R"
   730 apply (rule excluded_middle [of P, THEN disjE])
   731 apply (iprover intro: minor major [THEN mp])+
   732 done
   733 
   734 (*This version of --> elimination works on Q before P.  It works best for
   735   those cases in which P holds "almost everywhere".  Can't install as
   736   default: would break old proofs.*)
   737 lemma impCE':
   738   assumes major: "P-->Q"
   739       and minor: "Q ==> R" "~P ==> R"
   740   shows "R"
   741 apply (rule excluded_middle [of P, THEN disjE])
   742 apply (iprover intro: minor major [THEN mp])+
   743 done
   744 
   745 (*Classical <-> elimination. *)
   746 lemma iffCE:
   747   assumes major: "P=Q"
   748       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   749   shows "R"
   750 apply (rule major [THEN iffE])
   751 apply (iprover intro: minor elim: impCE notE)
   752 done
   753 
   754 lemma exCI:
   755   assumes "ALL x. ~P(x) ==> P(a)"
   756   shows "EX x. P(x)"
   757 apply (rule ccontr)
   758 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   759 done
   760 
   761 
   762 subsubsection {* Intuitionistic Reasoning *}
   763 
   764 lemma impE':
   765   assumes 1: "P --> Q"
   766     and 2: "Q ==> R"
   767     and 3: "P --> Q ==> P"
   768   shows R
   769 proof -
   770   from 3 and 1 have P .
   771   with 1 have Q by (rule impE)
   772   with 2 show R .
   773 qed
   774 
   775 lemma allE':
   776   assumes 1: "ALL x. P x"
   777     and 2: "P x ==> ALL x. P x ==> Q"
   778   shows Q
   779 proof -
   780   from 1 have "P x" by (rule spec)
   781   from this and 1 show Q by (rule 2)
   782 qed
   783 
   784 lemma notE':
   785   assumes 1: "~ P"
   786     and 2: "~ P ==> P"
   787   shows R
   788 proof -
   789   from 2 and 1 have P .
   790   with 1 show R by (rule notE)
   791 qed
   792 
   793 lemma TrueE: "True ==> P ==> P" .
   794 lemma notFalseE: "~ False ==> P ==> P" .
   795 
   796 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   797   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   798   and [Pure.elim 2] = allE notE' impE'
   799   and [Pure.intro] = exI disjI2 disjI1
   800 
   801 lemmas [trans] = trans
   802   and [sym] = sym not_sym
   803   and [Pure.elim?] = iffD1 iffD2 impE
   804 
   805 use "Tools/hologic.ML"
   806 
   807 
   808 subsubsection {* Atomizing meta-level connectives *}
   809 
   810 axiomatization where
   811   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   812 
   813 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   814 proof
   815   assume "!!x. P x"
   816   then show "ALL x. P x" ..
   817 next
   818   assume "ALL x. P x"
   819   then show "!!x. P x" by (rule allE)
   820 qed
   821 
   822 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   823 proof
   824   assume r: "A ==> B"
   825   show "A --> B" by (rule impI) (rule r)
   826 next
   827   assume "A --> B" and A
   828   then show B by (rule mp)
   829 qed
   830 
   831 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   832 proof
   833   assume r: "A ==> False"
   834   show "~A" by (rule notI) (rule r)
   835 next
   836   assume "~A" and A
   837   then show False by (rule notE)
   838 qed
   839 
   840 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   841 proof
   842   assume "x == y"
   843   show "x = y" by (unfold `x == y`) (rule refl)
   844 next
   845   assume "x = y"
   846   then show "x == y" by (rule eq_reflection)
   847 qed
   848 
   849 lemma atomize_conj [atomize]: "(A &&& B) == Trueprop (A & B)"
   850 proof
   851   assume conj: "A &&& B"
   852   show "A & B"
   853   proof (rule conjI)
   854     from conj show A by (rule conjunctionD1)
   855     from conj show B by (rule conjunctionD2)
   856   qed
   857 next
   858   assume conj: "A & B"
   859   show "A &&& B"
   860   proof -
   861     from conj show A ..
   862     from conj show B ..
   863   qed
   864 qed
   865 
   866 lemmas [symmetric, rulify] = atomize_all atomize_imp
   867   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   868 
   869 
   870 subsubsection {* Atomizing elimination rules *}
   871 
   872 setup AtomizeElim.setup
   873 
   874 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   875   by rule iprover+
   876 
   877 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   878   by rule iprover+
   879 
   880 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   881   by rule iprover+
   882 
   883 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   884 
   885 
   886 subsection {* Package setup *}
   887 
   888 subsubsection {* Classical Reasoner setup *}
   889 
   890 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   891   by (rule classical) iprover
   892 
   893 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   894   by (rule classical) iprover
   895 
   896 lemma thin_refl:
   897   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   898 
   899 ML {*
   900 structure Hypsubst = HypsubstFun(
   901 struct
   902   structure Simplifier = Simplifier
   903   val dest_eq = HOLogic.dest_eq
   904   val dest_Trueprop = HOLogic.dest_Trueprop
   905   val dest_imp = HOLogic.dest_imp
   906   val eq_reflection = @{thm eq_reflection}
   907   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   908   val imp_intr = @{thm impI}
   909   val rev_mp = @{thm rev_mp}
   910   val subst = @{thm subst}
   911   val sym = @{thm sym}
   912   val thin_refl = @{thm thin_refl};
   913   val prop_subst = @{lemma "PROP P t ==> PROP prop (x = t ==> PROP P x)"
   914                      by (unfold prop_def) (drule eq_reflection, unfold)}
   915 end);
   916 open Hypsubst;
   917 
   918 structure Classical = ClassicalFun(
   919 struct
   920   val imp_elim = @{thm imp_elim}
   921   val not_elim = @{thm notE}
   922   val swap = @{thm swap}
   923   val classical = @{thm classical}
   924   val sizef = Drule.size_of_thm
   925   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   926 end);
   927 
   928 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   929 open BasicClassical;
   930 
   931 ML_Antiquote.value "claset"
   932   (Scan.succeed "Classical.local_claset_of (ML_Context.the_local_context ())");
   933 
   934 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   935 
   936 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "theorems blacklisted for ATP");
   937 *}
   938 
   939 text {*ResBlacklist holds theorems blacklisted to sledgehammer. 
   940   These theorems typically produce clauses that are prolific (match too many equality or
   941   membership literals) and relate to seldom-used facts. Some duplicate other rules.*}
   942 
   943 setup {*
   944 let
   945   (*prevent substitution on bool*)
   946   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   947     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   948       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   949 in
   950   Hypsubst.hypsubst_setup
   951   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   952   #> Classical.setup
   953   #> ResAtpset.setup
   954   #> ResBlacklist.setup
   955 end
   956 *}
   957 
   958 declare iffI [intro!]
   959   and notI [intro!]
   960   and impI [intro!]
   961   and disjCI [intro!]
   962   and conjI [intro!]
   963   and TrueI [intro!]
   964   and refl [intro!]
   965 
   966 declare iffCE [elim!]
   967   and FalseE [elim!]
   968   and impCE [elim!]
   969   and disjE [elim!]
   970   and conjE [elim!]
   971   and conjE [elim!]
   972 
   973 declare ex_ex1I [intro!]
   974   and allI [intro!]
   975   and the_equality [intro]
   976   and exI [intro]
   977 
   978 declare exE [elim!]
   979   allE [elim]
   980 
   981 ML {* val HOL_cs = @{claset} *}
   982 
   983 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   984   apply (erule swap)
   985   apply (erule (1) meta_mp)
   986   done
   987 
   988 declare ex_ex1I [rule del, intro! 2]
   989   and ex1I [intro]
   990 
   991 lemmas [intro?] = ext
   992   and [elim?] = ex1_implies_ex
   993 
   994 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   995 lemma alt_ex1E [elim!]:
   996   assumes major: "\<exists>!x. P x"
   997       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   998   shows R
   999 apply (rule ex1E [OF major])
  1000 apply (rule prem)
  1001 apply (tactic {* ares_tac @{thms allI} 1 *})+
  1002 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
  1003 apply iprover
  1004 done
  1005 
  1006 ML {*
  1007 structure Blast = BlastFun
  1008 (
  1009   type claset = Classical.claset
  1010   val equality_name = @{const_name "op ="}
  1011   val not_name = @{const_name Not}
  1012   val notE = @{thm notE}
  1013   val ccontr = @{thm ccontr}
  1014   val contr_tac = Classical.contr_tac
  1015   val dup_intr = Classical.dup_intr
  1016   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1017   val claset = Classical.claset
  1018   val rep_cs = Classical.rep_cs
  1019   val cla_modifiers = Classical.cla_modifiers
  1020   val cla_meth' = Classical.cla_meth'
  1021 );
  1022 val Blast_tac = Blast.Blast_tac;
  1023 val blast_tac = Blast.blast_tac;
  1024 *}
  1025 
  1026 setup Blast.setup
  1027 
  1028 
  1029 subsubsection {* Simplifier *}
  1030 
  1031 lemma eta_contract_eq: "(%s. f s) = f" ..
  1032 
  1033 lemma simp_thms:
  1034   shows not_not: "(~ ~ P) = P"
  1035   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1036   and
  1037     "(P ~= Q) = (P = (~Q))"
  1038     "(P | ~P) = True"    "(~P | P) = True"
  1039     "(x = x) = True"
  1040   and not_True_eq_False: "(\<not> True) = False"
  1041   and not_False_eq_True: "(\<not> False) = True"
  1042   and
  1043     "(~P) ~= P"  "P ~= (~P)"
  1044     "(True=P) = P"
  1045   and eq_True: "(P = True) = P"
  1046   and "(False=P) = (~P)"
  1047   and eq_False: "(P = False) = (\<not> P)"
  1048   and
  1049     "(True --> P) = P"  "(False --> P) = True"
  1050     "(P --> True) = True"  "(P --> P) = True"
  1051     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1052     "(P & True) = P"  "(True & P) = P"
  1053     "(P & False) = False"  "(False & P) = False"
  1054     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1055     "(P & ~P) = False"    "(~P & P) = False"
  1056     "(P | True) = True"  "(True | P) = True"
  1057     "(P | False) = P"  "(False | P) = P"
  1058     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1059     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1060     -- {* needed for the one-point-rule quantifier simplification procs *}
  1061     -- {* essential for termination!! *} and
  1062     "!!P. (EX x. x=t & P(x)) = P(t)"
  1063     "!!P. (EX x. t=x & P(x)) = P(t)"
  1064     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1065     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1066   by (blast, blast, blast, blast, blast, iprover+)
  1067 
  1068 lemma disj_absorb: "(A | A) = A"
  1069   by blast
  1070 
  1071 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1072   by blast
  1073 
  1074 lemma conj_absorb: "(A & A) = A"
  1075   by blast
  1076 
  1077 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1078   by blast
  1079 
  1080 lemma eq_ac:
  1081   shows eq_commute: "(a=b) = (b=a)"
  1082     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1083     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1084 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1085 
  1086 lemma conj_comms:
  1087   shows conj_commute: "(P&Q) = (Q&P)"
  1088     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1089 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1090 
  1091 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1092 
  1093 lemma disj_comms:
  1094   shows disj_commute: "(P|Q) = (Q|P)"
  1095     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1096 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1097 
  1098 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1099 
  1100 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1101 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1102 
  1103 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1104 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1105 
  1106 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1107 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1108 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1109 
  1110 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1111 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1112 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1113 
  1114 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1115 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1116 
  1117 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1118   by iprover
  1119 
  1120 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1121 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1122 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1123 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1124 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1125 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1126   by blast
  1127 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1128 
  1129 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1130 
  1131 
  1132 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1133   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1134   -- {* cases boil down to the same thing. *}
  1135   by blast
  1136 
  1137 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1138 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1139 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1140 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1141 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1142 
  1143 declare All_def [noatp]
  1144 
  1145 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1146 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1147 
  1148 text {*
  1149   \medskip The @{text "&"} congruence rule: not included by default!
  1150   May slow rewrite proofs down by as much as 50\% *}
  1151 
  1152 lemma conj_cong:
  1153     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1154   by iprover
  1155 
  1156 lemma rev_conj_cong:
  1157     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1158   by iprover
  1159 
  1160 text {* The @{text "|"} congruence rule: not included by default! *}
  1161 
  1162 lemma disj_cong:
  1163     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1164   by blast
  1165 
  1166 
  1167 text {* \medskip if-then-else rules *}
  1168 
  1169 lemma if_True: "(if True then x else y) = x"
  1170   by (unfold if_def) blast
  1171 
  1172 lemma if_False: "(if False then x else y) = y"
  1173   by (unfold if_def) blast
  1174 
  1175 lemma if_P: "P ==> (if P then x else y) = x"
  1176   by (unfold if_def) blast
  1177 
  1178 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1179   by (unfold if_def) blast
  1180 
  1181 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1182   apply (rule case_split [of Q])
  1183    apply (simplesubst if_P)
  1184     prefer 3 apply (simplesubst if_not_P, blast+)
  1185   done
  1186 
  1187 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1188 by (simplesubst split_if, blast)
  1189 
  1190 lemmas if_splits [noatp] = split_if split_if_asm
  1191 
  1192 lemma if_cancel: "(if c then x else x) = x"
  1193 by (simplesubst split_if, blast)
  1194 
  1195 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1196 by (simplesubst split_if, blast)
  1197 
  1198 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1199   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1200   by (rule split_if)
  1201 
  1202 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1203   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1204   apply (simplesubst split_if, blast)
  1205   done
  1206 
  1207 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1208 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1209 
  1210 text {* \medskip let rules for simproc *}
  1211 
  1212 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1213   by (unfold Let_def)
  1214 
  1215 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1216   by (unfold Let_def)
  1217 
  1218 text {*
  1219   The following copy of the implication operator is useful for
  1220   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1221   its premise.
  1222 *}
  1223 
  1224 constdefs
  1225   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1226   [code del]: "simp_implies \<equiv> op ==>"
  1227 
  1228 lemma simp_impliesI:
  1229   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1230   shows "PROP P =simp=> PROP Q"
  1231   apply (unfold simp_implies_def)
  1232   apply (rule PQ)
  1233   apply assumption
  1234   done
  1235 
  1236 lemma simp_impliesE:
  1237   assumes PQ: "PROP P =simp=> PROP Q"
  1238   and P: "PROP P"
  1239   and QR: "PROP Q \<Longrightarrow> PROP R"
  1240   shows "PROP R"
  1241   apply (rule QR)
  1242   apply (rule PQ [unfolded simp_implies_def])
  1243   apply (rule P)
  1244   done
  1245 
  1246 lemma simp_implies_cong:
  1247   assumes PP' :"PROP P == PROP P'"
  1248   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1249   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1250 proof (unfold simp_implies_def, rule equal_intr_rule)
  1251   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1252   and P': "PROP P'"
  1253   from PP' [symmetric] and P' have "PROP P"
  1254     by (rule equal_elim_rule1)
  1255   then have "PROP Q" by (rule PQ)
  1256   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1257 next
  1258   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1259   and P: "PROP P"
  1260   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1261   then have "PROP Q'" by (rule P'Q')
  1262   with P'QQ' [OF P', symmetric] show "PROP Q"
  1263     by (rule equal_elim_rule1)
  1264 qed
  1265 
  1266 lemma uncurry:
  1267   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1268   shows "P \<and> Q \<longrightarrow> R"
  1269   using assms by blast
  1270 
  1271 lemma iff_allI:
  1272   assumes "\<And>x. P x = Q x"
  1273   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1274   using assms by blast
  1275 
  1276 lemma iff_exI:
  1277   assumes "\<And>x. P x = Q x"
  1278   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1279   using assms by blast
  1280 
  1281 lemma all_comm:
  1282   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1283   by blast
  1284 
  1285 lemma ex_comm:
  1286   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1287   by blast
  1288 
  1289 use "Tools/simpdata.ML"
  1290 ML {* open Simpdata *}
  1291 
  1292 setup {*
  1293   Simplifier.method_setup Splitter.split_modifiers
  1294   #> Simplifier.map_simpset (K Simpdata.simpset_simprocs)
  1295   #> Splitter.setup
  1296   #> clasimp_setup
  1297   #> EqSubst.setup
  1298 *}
  1299 
  1300 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1301 
  1302 simproc_setup neq ("x = y") = {* fn _ =>
  1303 let
  1304   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1305   fun is_neq eq lhs rhs thm =
  1306     (case Thm.prop_of thm of
  1307       _ $ (Not $ (eq' $ l' $ r')) =>
  1308         Not = HOLogic.Not andalso eq' = eq andalso
  1309         r' aconv lhs andalso l' aconv rhs
  1310     | _ => false);
  1311   fun proc ss ct =
  1312     (case Thm.term_of ct of
  1313       eq $ lhs $ rhs =>
  1314         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1315           SOME thm => SOME (thm RS neq_to_EQ_False)
  1316         | NONE => NONE)
  1317      | _ => NONE);
  1318 in proc end;
  1319 *}
  1320 
  1321 simproc_setup let_simp ("Let x f") = {*
  1322 let
  1323   val (f_Let_unfold, x_Let_unfold) =
  1324     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_unfold}
  1325     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1326   val (f_Let_folded, x_Let_folded) =
  1327     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_folded}
  1328     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1329   val g_Let_folded =
  1330     let val [(_ $ _ $ (g $ _))] = prems_of @{thm Let_folded}
  1331     in cterm_of @{theory} g end;
  1332   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1333     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1334     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1335     | count_loose _ _ = 0;
  1336   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1337    case t
  1338     of Abs (_, _, t') => count_loose t' 0 <= 1
  1339      | _ => true;
  1340 in fn _ => fn ss => fn ct => if is_trivial_let (Thm.term_of ct)
  1341   then SOME @{thm Let_def} (*no or one ocurrenc of bound variable*)
  1342   else let (*Norbert Schirmer's case*)
  1343     val ctxt = Simplifier.the_context ss;
  1344     val thy = ProofContext.theory_of ctxt;
  1345     val t = Thm.term_of ct;
  1346     val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1347   in Option.map (hd o Variable.export ctxt' ctxt o single)
  1348     (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1349       if is_Free x orelse is_Bound x orelse is_Const x
  1350       then SOME @{thm Let_def}
  1351       else
  1352         let
  1353           val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1354           val cx = cterm_of thy x;
  1355           val {T = xT, ...} = rep_cterm cx;
  1356           val cf = cterm_of thy f;
  1357           val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1358           val (_ $ _ $ g) = prop_of fx_g;
  1359           val g' = abstract_over (x,g);
  1360         in (if (g aconv g')
  1361              then
  1362                 let
  1363                   val rl =
  1364                     cterm_instantiate [(f_Let_unfold, cf), (x_Let_unfold, cx)] @{thm Let_unfold};
  1365                 in SOME (rl OF [fx_g]) end
  1366              else if Term.betapply (f, x) aconv g then NONE (*avoid identity conversion*)
  1367              else let
  1368                    val abs_g'= Abs (n,xT,g');
  1369                    val g'x = abs_g'$x;
  1370                    val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1371                    val rl = cterm_instantiate
  1372                              [(f_Let_folded, cterm_of thy f), (x_Let_folded, cx),
  1373                               (g_Let_folded, cterm_of thy abs_g')]
  1374                              @{thm Let_folded};
  1375                  in SOME (rl OF [transitive fx_g g_g'x])
  1376                  end)
  1377         end
  1378     | _ => NONE)
  1379   end
  1380 end *}
  1381 
  1382 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1383 proof
  1384   assume "True \<Longrightarrow> PROP P"
  1385   from this [OF TrueI] show "PROP P" .
  1386 next
  1387   assume "PROP P"
  1388   then show "PROP P" .
  1389 qed
  1390 
  1391 lemma ex_simps:
  1392   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1393   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1394   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1395   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1396   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1397   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1398   -- {* Miniscoping: pushing in existential quantifiers. *}
  1399   by (iprover | blast)+
  1400 
  1401 lemma all_simps:
  1402   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1403   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1404   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1405   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1406   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1407   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1408   -- {* Miniscoping: pushing in universal quantifiers. *}
  1409   by (iprover | blast)+
  1410 
  1411 lemmas [simp] =
  1412   triv_forall_equality (*prunes params*)
  1413   True_implies_equals  (*prune asms `True'*)
  1414   if_True
  1415   if_False
  1416   if_cancel
  1417   if_eq_cancel
  1418   imp_disjL
  1419   (*In general it seems wrong to add distributive laws by default: they
  1420     might cause exponential blow-up.  But imp_disjL has been in for a while
  1421     and cannot be removed without affecting existing proofs.  Moreover,
  1422     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1423     grounds that it allows simplification of R in the two cases.*)
  1424   conj_assoc
  1425   disj_assoc
  1426   de_Morgan_conj
  1427   de_Morgan_disj
  1428   imp_disj1
  1429   imp_disj2
  1430   not_imp
  1431   disj_not1
  1432   not_all
  1433   not_ex
  1434   cases_simp
  1435   the_eq_trivial
  1436   the_sym_eq_trivial
  1437   ex_simps
  1438   all_simps
  1439   simp_thms
  1440 
  1441 lemmas [cong] = imp_cong simp_implies_cong
  1442 lemmas [split] = split_if
  1443 
  1444 ML {* val HOL_ss = @{simpset} *}
  1445 
  1446 text {* Simplifies x assuming c and y assuming ~c *}
  1447 lemma if_cong:
  1448   assumes "b = c"
  1449       and "c \<Longrightarrow> x = u"
  1450       and "\<not> c \<Longrightarrow> y = v"
  1451   shows "(if b then x else y) = (if c then u else v)"
  1452   unfolding if_def using assms by simp
  1453 
  1454 text {* Prevents simplification of x and y:
  1455   faster and allows the execution of functional programs. *}
  1456 lemma if_weak_cong [cong]:
  1457   assumes "b = c"
  1458   shows "(if b then x else y) = (if c then x else y)"
  1459   using assms by (rule arg_cong)
  1460 
  1461 text {* Prevents simplification of t: much faster *}
  1462 lemma let_weak_cong:
  1463   assumes "a = b"
  1464   shows "(let x = a in t x) = (let x = b in t x)"
  1465   using assms by (rule arg_cong)
  1466 
  1467 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1468 lemma eq_cong2:
  1469   assumes "u = u'"
  1470   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1471   using assms by simp
  1472 
  1473 lemma if_distrib:
  1474   "f (if c then x else y) = (if c then f x else f y)"
  1475   by simp
  1476 
  1477 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1478   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1479 lemma restrict_to_left:
  1480   assumes "x = y"
  1481   shows "(x = z) = (y = z)"
  1482   using assms by simp
  1483 
  1484 
  1485 subsubsection {* Generic cases and induction *}
  1486 
  1487 text {* Rule projections: *}
  1488 
  1489 ML {*
  1490 structure ProjectRule = ProjectRuleFun
  1491 (
  1492   val conjunct1 = @{thm conjunct1}
  1493   val conjunct2 = @{thm conjunct2}
  1494   val mp = @{thm mp}
  1495 )
  1496 *}
  1497 
  1498 constdefs
  1499   induct_forall where "induct_forall P == \<forall>x. P x"
  1500   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1501   induct_equal where "induct_equal x y == x = y"
  1502   induct_conj where "induct_conj A B == A \<and> B"
  1503 
  1504 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1505   by (unfold atomize_all induct_forall_def)
  1506 
  1507 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1508   by (unfold atomize_imp induct_implies_def)
  1509 
  1510 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1511   by (unfold atomize_eq induct_equal_def)
  1512 
  1513 lemma induct_conj_eq: "(A &&& B) == Trueprop (induct_conj A B)"
  1514   by (unfold atomize_conj induct_conj_def)
  1515 
  1516 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1517 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1518 lemmas induct_rulify_fallback =
  1519   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1520 
  1521 
  1522 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1523     induct_conj (induct_forall A) (induct_forall B)"
  1524   by (unfold induct_forall_def induct_conj_def) iprover
  1525 
  1526 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1527     induct_conj (induct_implies C A) (induct_implies C B)"
  1528   by (unfold induct_implies_def induct_conj_def) iprover
  1529 
  1530 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1531 proof
  1532   assume r: "induct_conj A B ==> PROP C" and A B
  1533   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1534 next
  1535   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1536   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1537 qed
  1538 
  1539 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1540 
  1541 hide const induct_forall induct_implies induct_equal induct_conj
  1542 
  1543 text {* Method setup. *}
  1544 
  1545 ML {*
  1546 structure Induct = InductFun
  1547 (
  1548   val cases_default = @{thm case_split}
  1549   val atomize = @{thms induct_atomize}
  1550   val rulify = @{thms induct_rulify}
  1551   val rulify_fallback = @{thms induct_rulify_fallback}
  1552 )
  1553 *}
  1554 
  1555 setup Induct.setup
  1556 
  1557 use "~~/src/Tools/induct_tacs.ML"
  1558 setup InductTacs.setup
  1559 
  1560 
  1561 subsubsection {* Coherent logic *}
  1562 
  1563 ML {*
  1564 structure Coherent = CoherentFun
  1565 (
  1566   val atomize_elimL = @{thm atomize_elimL}
  1567   val atomize_exL = @{thm atomize_exL}
  1568   val atomize_conjL = @{thm atomize_conjL}
  1569   val atomize_disjL = @{thm atomize_disjL}
  1570   val operator_names =
  1571     [@{const_name "op |"}, @{const_name "op &"}, @{const_name "Ex"}]
  1572 );
  1573 *}
  1574 
  1575 setup Coherent.setup
  1576 
  1577 
  1578 subsection {* Other simple lemmas and lemma duplicates *}
  1579 
  1580 lemma Let_0 [simp]: "Let 0 f = f 0"
  1581   unfolding Let_def ..
  1582 
  1583 lemma Let_1 [simp]: "Let 1 f = f 1"
  1584   unfolding Let_def ..
  1585 
  1586 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1587   by blast+
  1588 
  1589 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1590   apply (rule iffI)
  1591   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1592   apply (fast dest!: theI')
  1593   apply (fast intro: ext the1_equality [symmetric])
  1594   apply (erule ex1E)
  1595   apply (rule allI)
  1596   apply (rule ex1I)
  1597   apply (erule spec)
  1598   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1599   apply (erule impE)
  1600   apply (rule allI)
  1601   apply (case_tac "xa = x")
  1602   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1603   done
  1604 
  1605 lemma mk_left_commute:
  1606   fixes f (infix "\<otimes>" 60)
  1607   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1608           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1609   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1610   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1611 
  1612 lemmas eq_sym_conv = eq_commute
  1613 
  1614 lemma nnf_simps:
  1615   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1616   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1617   "(\<not> \<not>(P)) = P"
  1618 by blast+
  1619 
  1620 
  1621 subsection {* Basic ML bindings *}
  1622 
  1623 ML {*
  1624 val FalseE = @{thm FalseE}
  1625 val Let_def = @{thm Let_def}
  1626 val TrueI = @{thm TrueI}
  1627 val allE = @{thm allE}
  1628 val allI = @{thm allI}
  1629 val all_dupE = @{thm all_dupE}
  1630 val arg_cong = @{thm arg_cong}
  1631 val box_equals = @{thm box_equals}
  1632 val ccontr = @{thm ccontr}
  1633 val classical = @{thm classical}
  1634 val conjE = @{thm conjE}
  1635 val conjI = @{thm conjI}
  1636 val conjunct1 = @{thm conjunct1}
  1637 val conjunct2 = @{thm conjunct2}
  1638 val disjCI = @{thm disjCI}
  1639 val disjE = @{thm disjE}
  1640 val disjI1 = @{thm disjI1}
  1641 val disjI2 = @{thm disjI2}
  1642 val eq_reflection = @{thm eq_reflection}
  1643 val ex1E = @{thm ex1E}
  1644 val ex1I = @{thm ex1I}
  1645 val ex1_implies_ex = @{thm ex1_implies_ex}
  1646 val exE = @{thm exE}
  1647 val exI = @{thm exI}
  1648 val excluded_middle = @{thm excluded_middle}
  1649 val ext = @{thm ext}
  1650 val fun_cong = @{thm fun_cong}
  1651 val iffD1 = @{thm iffD1}
  1652 val iffD2 = @{thm iffD2}
  1653 val iffI = @{thm iffI}
  1654 val impE = @{thm impE}
  1655 val impI = @{thm impI}
  1656 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1657 val mp = @{thm mp}
  1658 val notE = @{thm notE}
  1659 val notI = @{thm notI}
  1660 val not_all = @{thm not_all}
  1661 val not_ex = @{thm not_ex}
  1662 val not_iff = @{thm not_iff}
  1663 val not_not = @{thm not_not}
  1664 val not_sym = @{thm not_sym}
  1665 val refl = @{thm refl}
  1666 val rev_mp = @{thm rev_mp}
  1667 val spec = @{thm spec}
  1668 val ssubst = @{thm ssubst}
  1669 val subst = @{thm subst}
  1670 val sym = @{thm sym}
  1671 val trans = @{thm trans}
  1672 *}
  1673 
  1674 
  1675 subsection {* Code generator basics -- see further theory @{text "Code_Setup"} *}
  1676 
  1677 text {* Equality *}
  1678 
  1679 class eq =
  1680   fixes eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1681   assumes eq_equals: "eq x y \<longleftrightarrow> x = y"
  1682 begin
  1683 
  1684 lemma eq: "eq = (op =)"
  1685   by (rule ext eq_equals)+
  1686 
  1687 lemma eq_refl: "eq x x \<longleftrightarrow> True"
  1688   unfolding eq by rule+
  1689 
  1690 end
  1691 
  1692 text {* Module setup *}
  1693 
  1694 use "Tools/recfun_codegen.ML"
  1695 
  1696 setup {*
  1697   Code_ML.setup
  1698   #> Code_Haskell.setup
  1699   #> Nbe.setup
  1700   #> Codegen.setup
  1701   #> RecfunCodegen.setup
  1702 *}
  1703 
  1704 
  1705 subsection {* Nitpick theorem store *}
  1706 
  1707 ML {*
  1708 structure Nitpick_Const_Simp_Thms = NamedThmsFun
  1709 (
  1710   val name = "nitpick_const_simp"
  1711   val description = "equational specification of constants as needed by Nitpick"
  1712 )
  1713 structure Nitpick_Const_Psimp_Thms = NamedThmsFun
  1714 (
  1715   val name = "nitpick_const_psimp"
  1716   val description = "partial equational specification of constants as needed by Nitpick"
  1717 )
  1718 structure Nitpick_Ind_Intro_Thms = NamedThmsFun
  1719 (
  1720   val name = "nitpick_ind_intro"
  1721   val description = "introduction rules for (co)inductive predicates as needed by Nitpick"
  1722 )
  1723 *}
  1724 setup {* Nitpick_Const_Simp_Thms.setup
  1725          #> Nitpick_Const_Psimp_Thms.setup
  1726          #> Nitpick_Ind_Intro_Thms.setup *}
  1727 
  1728 subsection {* Legacy tactics and ML bindings *}
  1729 
  1730 ML {*
  1731 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1732 
  1733 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1734 local
  1735   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1736     | wrong_prem (Bound _) = true
  1737     | wrong_prem _ = false;
  1738   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1739 in
  1740   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1741   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1742 end;
  1743 
  1744 val all_conj_distrib = thm "all_conj_distrib";
  1745 val all_simps = thms "all_simps";
  1746 val atomize_not = thm "atomize_not";
  1747 val case_split = thm "case_split";
  1748 val cases_simp = thm "cases_simp";
  1749 val choice_eq = thm "choice_eq"
  1750 val cong = thm "cong"
  1751 val conj_comms = thms "conj_comms";
  1752 val conj_cong = thm "conj_cong";
  1753 val de_Morgan_conj = thm "de_Morgan_conj";
  1754 val de_Morgan_disj = thm "de_Morgan_disj";
  1755 val disj_assoc = thm "disj_assoc";
  1756 val disj_comms = thms "disj_comms";
  1757 val disj_cong = thm "disj_cong";
  1758 val eq_ac = thms "eq_ac";
  1759 val eq_cong2 = thm "eq_cong2"
  1760 val Eq_FalseI = thm "Eq_FalseI";
  1761 val Eq_TrueI = thm "Eq_TrueI";
  1762 val Ex1_def = thm "Ex1_def"
  1763 val ex_disj_distrib = thm "ex_disj_distrib";
  1764 val ex_simps = thms "ex_simps";
  1765 val if_cancel = thm "if_cancel";
  1766 val if_eq_cancel = thm "if_eq_cancel";
  1767 val if_False = thm "if_False";
  1768 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1769 val iff = thm "iff"
  1770 val if_splits = thms "if_splits";
  1771 val if_True = thm "if_True";
  1772 val if_weak_cong = thm "if_weak_cong"
  1773 val imp_all = thm "imp_all";
  1774 val imp_cong = thm "imp_cong";
  1775 val imp_conjL = thm "imp_conjL";
  1776 val imp_conjR = thm "imp_conjR";
  1777 val imp_conv_disj = thm "imp_conv_disj";
  1778 val simp_implies_def = thm "simp_implies_def";
  1779 val simp_thms = thms "simp_thms";
  1780 val split_if = thm "split_if";
  1781 val the1_equality = thm "the1_equality"
  1782 val theI = thm "theI"
  1783 val theI' = thm "theI'"
  1784 val True_implies_equals = thm "True_implies_equals";
  1785 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  1786 
  1787 *}
  1788 
  1789 end