src/HOL/Number_Theory/Residues.thy
author haftmann
Sat Nov 11 18:41:08 2017 +0000 (19 months ago)
changeset 67051 e7e54a0b9197
parent 66954 0230af0f3c59
child 67091 1393c2340eec
permissions -rw-r--r--
dedicated definition for coprimality
     1 (*  Title:      HOL/Number_Theory/Residues.thy
     2     Author:     Jeremy Avigad
     3 
     4 An algebraic treatment of residue rings, and resulting proofs of
     5 Euler's theorem and Wilson's theorem.
     6 *)
     7 
     8 section \<open>Residue rings\<close>
     9 
    10 theory Residues
    11 imports
    12   Cong
    13   "HOL-Algebra.More_Group"
    14   "HOL-Algebra.More_Ring"
    15   "HOL-Algebra.More_Finite_Product"
    16   "HOL-Algebra.Multiplicative_Group"
    17   Totient
    18 begin
    19 
    20 definition QuadRes :: "int \<Rightarrow> int \<Rightarrow> bool"
    21   where "QuadRes p a = (\<exists>y. ([y^2 = a] (mod p)))"
    22 
    23 definition Legendre :: "int \<Rightarrow> int \<Rightarrow> int"
    24   where "Legendre a p =
    25     (if ([a = 0] (mod p)) then 0
    26      else if QuadRes p a then 1
    27      else -1)"
    28 
    29 
    30 subsection \<open>A locale for residue rings\<close>
    31 
    32 definition residue_ring :: "int \<Rightarrow> int ring"
    33   where
    34     "residue_ring m =
    35       \<lparr>carrier = {0..m - 1},
    36        monoid.mult = \<lambda>x y. (x * y) mod m,
    37        one = 1,
    38        zero = 0,
    39        add = \<lambda>x y. (x + y) mod m\<rparr>"
    40 
    41 locale residues =
    42   fixes m :: int and R (structure)
    43   assumes m_gt_one: "m > 1"
    44   defines "R \<equiv> residue_ring m"
    45 begin
    46 
    47 lemma abelian_group: "abelian_group R"
    48 proof -
    49   have "\<exists>y\<in>{0..m - 1}. (x + y) mod m = 0" if "0 \<le> x" "x < m" for x
    50   proof (cases "x = 0")
    51     case True
    52     with m_gt_one show ?thesis by simp
    53   next
    54     case False
    55     then have "(x + (m - x)) mod m = 0"
    56       by simp
    57     with m_gt_one that show ?thesis
    58       by (metis False atLeastAtMost_iff diff_ge_0_iff_ge diff_left_mono int_one_le_iff_zero_less less_le)
    59   qed
    60   with m_gt_one show ?thesis
    61     by (fastforce simp add: R_def residue_ring_def mod_add_right_eq ac_simps  intro!: abelian_groupI)
    62 qed
    63 
    64 lemma comm_monoid: "comm_monoid R"
    65   unfolding R_def residue_ring_def
    66   apply (rule comm_monoidI)
    67     using m_gt_one  apply auto
    68   apply (metis mod_mult_right_eq mult.assoc mult.commute)
    69   apply (metis mult.commute)
    70   done
    71 
    72 lemma cring: "cring R"
    73   apply (intro cringI abelian_group comm_monoid)
    74   unfolding R_def residue_ring_def
    75   apply (auto simp add: comm_semiring_class.distrib mod_add_eq mod_mult_left_eq)
    76   done
    77 
    78 end
    79 
    80 sublocale residues < cring
    81   by (rule cring)
    82 
    83 
    84 context residues
    85 begin
    86 
    87 text \<open>
    88   These lemmas translate back and forth between internal and
    89   external concepts.
    90 \<close>
    91 
    92 lemma res_carrier_eq: "carrier R = {0..m - 1}"
    93   by (auto simp: R_def residue_ring_def)
    94 
    95 lemma res_add_eq: "x \<oplus> y = (x + y) mod m"
    96   by (auto simp: R_def residue_ring_def)
    97 
    98 lemma res_mult_eq: "x \<otimes> y = (x * y) mod m"
    99   by (auto simp: R_def residue_ring_def)
   100 
   101 lemma res_zero_eq: "\<zero> = 0"
   102   by (auto simp: R_def residue_ring_def)
   103 
   104 lemma res_one_eq: "\<one> = 1"
   105   by (auto simp: R_def residue_ring_def units_of_def)
   106 
   107 lemma res_units_eq: "Units R = {x. 0 < x \<and> x < m \<and> coprime x m}"
   108   using m_gt_one
   109   apply (auto simp add: Units_def R_def residue_ring_def ac_simps invertible_coprime intro: ccontr)
   110   apply (subst (asm) coprime_iff_invertible'_int)
   111    apply (auto simp add: cong_def)
   112   done
   113 
   114 lemma res_neg_eq: "\<ominus> x = (- x) mod m"
   115   using m_gt_one unfolding R_def a_inv_def m_inv_def residue_ring_def
   116   apply simp
   117   apply (rule the_equality)
   118    apply (simp add: mod_add_right_eq)
   119    apply (simp add: add.commute mod_add_right_eq)
   120   apply (metis add.right_neutral minus_add_cancel mod_add_right_eq mod_pos_pos_trivial)
   121   done
   122 
   123 lemma finite [iff]: "finite (carrier R)"
   124   by (simp add: res_carrier_eq)
   125 
   126 lemma finite_Units [iff]: "finite (Units R)"
   127   by (simp add: finite_ring_finite_units)
   128 
   129 text \<open>
   130   The function \<open>a \<mapsto> a mod m\<close> maps the integers to the
   131   residue classes. The following lemmas show that this mapping
   132   respects addition and multiplication on the integers.
   133 \<close>
   134 
   135 lemma mod_in_carrier [iff]: "a mod m \<in> carrier R"
   136   unfolding res_carrier_eq
   137   using insert m_gt_one by auto
   138 
   139 lemma add_cong: "(x mod m) \<oplus> (y mod m) = (x + y) mod m"
   140   by (auto simp: R_def residue_ring_def mod_simps)
   141 
   142 lemma mult_cong: "(x mod m) \<otimes> (y mod m) = (x * y) mod m"
   143   by (auto simp: R_def residue_ring_def mod_simps)
   144 
   145 lemma zero_cong: "\<zero> = 0"
   146   by (auto simp: R_def residue_ring_def)
   147 
   148 lemma one_cong: "\<one> = 1 mod m"
   149   using m_gt_one by (auto simp: R_def residue_ring_def)
   150 
   151 (* FIXME revise algebra library to use 1? *)
   152 lemma pow_cong: "(x mod m) (^) n = x^n mod m"
   153   using m_gt_one
   154   apply (induct n)
   155   apply (auto simp add: nat_pow_def one_cong)
   156   apply (metis mult.commute mult_cong)
   157   done
   158 
   159 lemma neg_cong: "\<ominus> (x mod m) = (- x) mod m"
   160   by (metis mod_minus_eq res_neg_eq)
   161 
   162 lemma (in residues) prod_cong: "finite A \<Longrightarrow> (\<Otimes>i\<in>A. (f i) mod m) = (\<Prod>i\<in>A. f i) mod m"
   163   by (induct set: finite) (auto simp: one_cong mult_cong)
   164 
   165 lemma (in residues) sum_cong: "finite A \<Longrightarrow> (\<Oplus>i\<in>A. (f i) mod m) = (\<Sum>i\<in>A. f i) mod m"
   166   by (induct set: finite) (auto simp: zero_cong add_cong)
   167 
   168 lemma mod_in_res_units [simp]:
   169   assumes "1 < m" and "coprime a m"
   170   shows "a mod m \<in> Units R"
   171 proof (cases "a mod m = 0")
   172   case True
   173   with assms show ?thesis
   174     by (auto simp add: res_units_eq gcd_red_int [symmetric])
   175 next
   176   case False
   177   from assms have "0 < m" by simp
   178   then have "0 \<le> a mod m" by (rule pos_mod_sign [of m a])
   179   with False have "0 < a mod m" by simp
   180   with assms show ?thesis
   181     by (auto simp add: res_units_eq gcd_red_int [symmetric] ac_simps)
   182 qed
   183 
   184 lemma res_eq_to_cong: "(a mod m) = (b mod m) \<longleftrightarrow> [a = b] (mod m)"
   185   by (auto simp: cong_def)
   186 
   187 
   188 text \<open>Simplifying with these will translate a ring equation in R to a congruence.\<close>
   189 lemmas res_to_cong_simps =
   190   add_cong mult_cong pow_cong one_cong
   191   prod_cong sum_cong neg_cong res_eq_to_cong
   192 
   193 text \<open>Other useful facts about the residue ring.\<close>
   194 lemma one_eq_neg_one: "\<one> = \<ominus> \<one> \<Longrightarrow> m = 2"
   195   apply (simp add: res_one_eq res_neg_eq)
   196   apply (metis add.commute add_diff_cancel mod_mod_trivial one_add_one uminus_add_conv_diff
   197     zero_neq_one zmod_zminus1_eq_if)
   198   done
   199 
   200 end
   201 
   202 
   203 subsection \<open>Prime residues\<close>
   204 
   205 locale residues_prime =
   206   fixes p :: nat and R (structure)
   207   assumes p_prime [intro]: "prime p"
   208   defines "R \<equiv> residue_ring (int p)"
   209 
   210 sublocale residues_prime < residues p
   211   unfolding R_def residues_def
   212   using p_prime apply auto
   213   apply (metis (full_types) of_nat_1 of_nat_less_iff prime_gt_1_nat)
   214   done
   215 
   216 context residues_prime
   217 begin
   218 
   219 lemma p_coprime_left:
   220   "coprime p a \<longleftrightarrow> \<not> p dvd a"
   221   using p_prime by (auto intro: prime_imp_coprime dest: coprime_common_divisor)
   222 
   223 lemma p_coprime_right:
   224   "coprime a p  \<longleftrightarrow> \<not> p dvd a"
   225   using p_coprime_left [of a] by (simp add: ac_simps)
   226 
   227 lemma p_coprime_left_int:
   228   "coprime (int p) a \<longleftrightarrow> \<not> int p dvd a"
   229   using p_prime by (auto intro: prime_imp_coprime dest: coprime_common_divisor)
   230 
   231 lemma p_coprime_right_int:
   232   "coprime a (int p) \<longleftrightarrow> \<not> int p dvd a"
   233   using p_coprime_left_int [of a] by (simp add: ac_simps)
   234 
   235 lemma is_field: "field R"
   236 proof -
   237   have "0 < x \<Longrightarrow> x < int p \<Longrightarrow> coprime (int p) x" for x
   238     by (rule prime_imp_coprime) (auto simp add: zdvd_not_zless)
   239   then show ?thesis
   240     by (intro cring.field_intro2 cring)
   241       (auto simp add: res_carrier_eq res_one_eq res_zero_eq res_units_eq ac_simps)
   242 qed
   243 
   244 lemma res_prime_units_eq: "Units R = {1..p - 1}"
   245   apply (subst res_units_eq)
   246   apply (auto simp add: p_coprime_right_int zdvd_not_zless)
   247   done
   248 
   249 end
   250 
   251 sublocale residues_prime < field
   252   by (rule is_field)
   253 
   254 
   255 section \<open>Test cases: Euler's theorem and Wilson's theorem\<close>
   256 
   257 subsection \<open>Euler's theorem\<close>
   258 
   259 lemma (in residues) totatives_eq:
   260   "totatives (nat m) = nat ` Units R"
   261 proof -
   262   from m_gt_one have "\<bar>m\<bar> > 1"
   263     by simp
   264   then have "totatives (nat \<bar>m\<bar>) = nat ` abs ` Units R"
   265     by (auto simp add: totatives_def res_units_eq image_iff le_less)
   266       (use m_gt_one zless_nat_eq_int_zless in force)
   267   moreover have "\<bar>m\<bar> = m" "abs ` Units R = Units R"
   268     using m_gt_one by (auto simp add: res_units_eq image_iff)
   269   ultimately show ?thesis
   270     by simp
   271 qed
   272 
   273 lemma (in residues) totient_eq:
   274   "totient (nat m) = card (Units R)"
   275 proof  -
   276   have *: "inj_on nat (Units R)"
   277     by (rule inj_onI) (auto simp add: res_units_eq)
   278   then show ?thesis
   279     by (simp add: totient_def totatives_eq card_image)
   280 qed
   281 
   282 lemma (in residues_prime) totient_eq: "totient p = p - 1"
   283   using totient_eq by (simp add: res_prime_units_eq)
   284 
   285 lemma (in residues) euler_theorem:
   286   assumes "coprime a m"
   287   shows "[a ^ totient (nat m) = 1] (mod m)"
   288 proof -
   289   have "a ^ totient (nat m) mod m = 1 mod m"
   290     by (metis assms finite_Units m_gt_one mod_in_res_units one_cong totient_eq pow_cong units_power_order_eq_one)
   291   then show ?thesis
   292     using res_eq_to_cong by blast
   293 qed
   294 
   295 lemma euler_theorem:
   296   fixes a m :: nat
   297   assumes "coprime a m"
   298   shows "[a ^ totient m = 1] (mod m)"
   299 proof (cases "m = 0 | m = 1")
   300   case True
   301   then show ?thesis by auto
   302 next
   303   case False
   304   with assms show ?thesis
   305     using residues.euler_theorem [of "int m" "int a"] cong_int_iff
   306     by (auto simp add: residues_def gcd_int_def) fastforce
   307 qed
   308 
   309 lemma fermat_theorem:
   310   fixes p a :: nat
   311   assumes "prime p" and "\<not> p dvd a"
   312   shows "[a ^ (p - 1) = 1] (mod p)"
   313 proof -
   314   from assms prime_imp_coprime [of p a] have "coprime a p"
   315     by (auto simp add: ac_simps)
   316   then have "[a ^ totient p = 1] (mod p)"
   317      by (rule euler_theorem)
   318   also have "totient p = p - 1"
   319     by (rule totient_prime) (rule assms)
   320   finally show ?thesis .
   321 qed
   322 
   323 
   324 subsection \<open>Wilson's theorem\<close>
   325 
   326 lemma (in field) inv_pair_lemma: "x \<in> Units R \<Longrightarrow> y \<in> Units R \<Longrightarrow>
   327     {x, inv x} \<noteq> {y, inv y} \<Longrightarrow> {x, inv x} \<inter> {y, inv y} = {}"
   328   apply auto
   329   apply (metis Units_inv_inv)+
   330   done
   331 
   332 lemma (in residues_prime) wilson_theorem1:
   333   assumes a: "p > 2"
   334   shows "[fact (p - 1) = (-1::int)] (mod p)"
   335 proof -
   336   let ?Inverse_Pairs = "{{x, inv x}| x. x \<in> Units R - {\<one>, \<ominus> \<one>}}"
   337   have UR: "Units R = {\<one>, \<ominus> \<one>} \<union> \<Union>?Inverse_Pairs"
   338     by auto
   339   have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) \<otimes> (\<Otimes>i\<in>\<Union>?Inverse_Pairs. i)"
   340     apply (subst UR)
   341     apply (subst finprod_Un_disjoint)
   342          apply (auto intro: funcsetI)
   343     using inv_one apply auto[1]
   344     using inv_eq_neg_one_eq apply auto
   345     done
   346   also have "(\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) = \<ominus> \<one>"
   347     apply (subst finprod_insert)
   348         apply auto
   349     apply (frule one_eq_neg_one)
   350     using a apply force
   351     done
   352   also have "(\<Otimes>i\<in>(\<Union>?Inverse_Pairs). i) = (\<Otimes>A\<in>?Inverse_Pairs. (\<Otimes>y\<in>A. y))"
   353     apply (subst finprod_Union_disjoint)
   354        apply auto
   355      apply (metis Units_inv_inv)+
   356     done
   357   also have "\<dots> = \<one>"
   358     apply (rule finprod_one)
   359      apply auto
   360     apply (subst finprod_insert)
   361         apply auto
   362     apply (metis inv_eq_self)
   363     done
   364   finally have "(\<Otimes>i\<in>Units R. i) = \<ominus> \<one>"
   365     by simp
   366   also have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>Units R. i mod p)"
   367     by (rule finprod_cong') (auto simp: res_units_eq)
   368   also have "\<dots> = (\<Prod>i\<in>Units R. i) mod p"
   369     by (rule prod_cong) auto
   370   also have "\<dots> = fact (p - 1) mod p"
   371     apply (simp add: fact_prod)
   372     using assms
   373     apply (subst res_prime_units_eq)
   374     apply (simp add: int_prod zmod_int prod_int_eq)
   375     done
   376   finally have "fact (p - 1) mod p = \<ominus> \<one>" .
   377   then show ?thesis
   378     by (simp add: cong_def res_neg_eq res_one_eq zmod_int)
   379 qed
   380 
   381 lemma wilson_theorem:
   382   assumes "prime p"
   383   shows "[fact (p - 1) = - 1] (mod p)"
   384 proof (cases "p = 2")
   385   case True
   386   then show ?thesis
   387     by (simp add: cong_def fact_prod)
   388 next
   389   case False
   390   then show ?thesis
   391     using assms prime_ge_2_nat
   392     by (metis residues_prime.wilson_theorem1 residues_prime.intro le_eq_less_or_eq)
   393 qed
   394 
   395 text \<open>
   396   This result can be transferred to the multiplicative group of
   397   \<open>\<int>/p\<int>\<close> for \<open>p\<close> prime.\<close>
   398 
   399 lemma mod_nat_int_pow_eq:
   400   fixes n :: nat and p a :: int
   401   shows "a \<ge> 0 \<Longrightarrow> p \<ge> 0 \<Longrightarrow> (nat a ^ n) mod (nat p) = nat ((a ^ n) mod p)"
   402   by (simp add: int_one_le_iff_zero_less nat_mod_distrib order_less_imp_le nat_power_eq[symmetric])
   403 
   404 theorem residue_prime_mult_group_has_gen :
   405  fixes p :: nat
   406  assumes prime_p : "prime p"
   407  shows "\<exists>a \<in> {1 .. p - 1}. {1 .. p - 1} = {a^i mod p|i . i \<in> UNIV}"
   408 proof -
   409   have "p \<ge> 2"
   410     using prime_gt_1_nat[OF prime_p] by simp
   411   interpret R: residues_prime p "residue_ring p"
   412     by (simp add: residues_prime_def prime_p)
   413   have car: "carrier (residue_ring (int p)) - {\<zero>\<^bsub>residue_ring (int p)\<^esub>} = {1 .. int p - 1}"
   414     by (auto simp add: R.zero_cong R.res_carrier_eq)
   415 
   416   have "x (^)\<^bsub>residue_ring (int p)\<^esub> i = x ^ i mod (int p)"
   417     if "x \<in> {1 .. int p - 1}" for x and i :: nat
   418     using that R.pow_cong[of x i] by auto
   419   moreover
   420   obtain a where a: "a \<in> {1 .. int p - 1}"
   421     and a_gen: "{1 .. int p - 1} = {a(^)\<^bsub>residue_ring (int p)\<^esub>i|i::nat . i \<in> UNIV}"
   422     using field.finite_field_mult_group_has_gen[OF R.is_field]
   423     by (auto simp add: car[symmetric] carrier_mult_of)
   424   moreover
   425   have "nat ` {1 .. int p - 1} = {1 .. p - 1}" (is "?L = ?R")
   426   proof
   427     have "n \<in> ?R" if "n \<in> ?L" for n
   428       using that \<open>p\<ge>2\<close> by force
   429     then show "?L \<subseteq> ?R" by blast
   430     have "n \<in> ?L" if "n \<in> ?R" for n
   431       using that \<open>p\<ge>2\<close> by (auto intro: rev_image_eqI [of "int n"])
   432     then show "?R \<subseteq> ?L" by blast
   433   qed
   434   moreover
   435   have "nat ` {a^i mod (int p) | i::nat. i \<in> UNIV} = {nat a^i mod p | i . i \<in> UNIV}" (is "?L = ?R")
   436   proof
   437     have "x \<in> ?R" if "x \<in> ?L" for x
   438     proof -
   439       from that obtain i where i: "x = nat (a^i mod (int p))"
   440         by blast
   441       then have "x = nat a ^ i mod p"
   442         using mod_nat_int_pow_eq[of a "int p" i] a \<open>p\<ge>2\<close> by auto
   443       with i show ?thesis by blast
   444     qed
   445     then show "?L \<subseteq> ?R" by blast
   446     have "x \<in> ?L" if "x \<in> ?R" for x
   447     proof -
   448       from that obtain i where i: "x = nat a^i mod p"
   449         by blast
   450       with mod_nat_int_pow_eq[of a "int p" i] a \<open>p\<ge>2\<close> show ?thesis
   451         by auto
   452     qed
   453     then show "?R \<subseteq> ?L" by blast
   454   qed
   455   ultimately have "{1 .. p - 1} = {nat a^i mod p | i. i \<in> UNIV}"
   456     by presburger
   457   moreover from a have "nat a \<in> {1 .. p - 1}" by force
   458   ultimately show ?thesis ..
   459 qed
   460 
   461 end