src/Pure/tactic.ML
author wenzelm
Sat Oct 27 23:19:04 2001 +0200 (2001-10-27)
changeset 11970 e7eedbd2c8ca
parent 11961 e5911a25d094
child 11974 f76c3e1ab352
permissions -rw-r--r--
tuned prove;
added prove_standard;
     1 (*  Title:      Pure/tactic.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Tactics.
     7 *)
     8 
     9 signature BASIC_TACTIC =
    10 sig
    11   val ares_tac          : thm list -> int -> tactic
    12   val asm_rewrite_goal_tac: bool*bool*bool ->
    13     (MetaSimplifier.meta_simpset -> tactic) -> MetaSimplifier.meta_simpset -> int -> tactic
    14   val assume_tac        : int -> tactic
    15   val atac      : int ->tactic
    16   val bimatch_from_nets_tac:
    17       (int*(bool*thm)) Net.net * (int*(bool*thm)) Net.net -> int -> tactic
    18   val bimatch_tac       : (bool*thm)list -> int -> tactic
    19   val biresolution_from_nets_tac:
    20         ('a list -> (bool * thm) list) ->
    21         bool -> 'a Net.net * 'a Net.net -> int -> tactic
    22   val biresolve_from_nets_tac:
    23       (int*(bool*thm)) Net.net * (int*(bool*thm)) Net.net -> int -> tactic
    24   val biresolve_tac     : (bool*thm)list -> int -> tactic
    25   val build_net : thm list -> (int*thm) Net.net
    26   val build_netpair:    (int*(bool*thm)) Net.net * (int*(bool*thm)) Net.net ->
    27       (bool*thm)list -> (int*(bool*thm)) Net.net * (int*(bool*thm)) Net.net
    28   val compose_inst_tac  : (string*string)list -> (bool*thm*int) ->
    29                           int -> tactic
    30   val compose_tac       : (bool * thm * int) -> int -> tactic
    31   val cut_facts_tac     : thm list -> int -> tactic
    32   val cut_inst_tac      : (string*string)list -> thm -> int -> tactic
    33   val datac             : thm -> int -> int -> tactic
    34   val defer_tac         : int -> tactic
    35   val distinct_subgoals_tac     : tactic
    36   val dmatch_tac        : thm list -> int -> tactic
    37   val dresolve_tac      : thm list -> int -> tactic
    38   val dres_inst_tac     : (string*string)list -> thm -> int -> tactic
    39   val dtac              : thm -> int ->tactic
    40   val eatac             : thm -> int -> int -> tactic
    41   val etac              : thm -> int ->tactic
    42   val eq_assume_tac     : int -> tactic
    43   val ematch_tac        : thm list -> int -> tactic
    44   val eresolve_tac      : thm list -> int -> tactic
    45   val eres_inst_tac     : (string*string)list -> thm -> int -> tactic
    46   val fatac             : thm -> int -> int -> tactic
    47   val filter_prems_tac  : (term -> bool) -> int -> tactic
    48   val filter_thms       : (term*term->bool) -> int*term*thm list -> thm list
    49   val filt_resolve_tac  : thm list -> int -> int -> tactic
    50   val flexflex_tac      : tactic
    51   val fold_goals_tac    : thm list -> tactic
    52   val fold_rule         : thm list -> thm -> thm
    53   val fold_tac          : thm list -> tactic
    54   val forward_tac       : thm list -> int -> tactic
    55   val forw_inst_tac     : (string*string)list -> thm -> int -> tactic
    56   val ftac              : thm -> int ->tactic
    57   val insert_tagged_brl : ('a*(bool*thm)) *
    58                           (('a*(bool*thm))Net.net * ('a*(bool*thm))Net.net) ->
    59                           ('a*(bool*thm))Net.net * ('a*(bool*thm))Net.net
    60   val delete_tagged_brl : (bool*thm) *
    61                          ((int*(bool*thm))Net.net * (int*(bool*thm))Net.net) ->
    62                     (int*(bool*thm))Net.net * (int*(bool*thm))Net.net
    63   val is_fact           : thm -> bool
    64   val lessb             : (bool * thm) * (bool * thm) -> bool
    65   val lift_inst_rule    : thm * int * (string*string)list * thm -> thm
    66   val make_elim         : thm -> thm
    67   val match_from_net_tac        : (int*thm) Net.net -> int -> tactic
    68   val match_tac : thm list -> int -> tactic
    69   val metacut_tac       : thm -> int -> tactic
    70   val net_bimatch_tac   : (bool*thm) list -> int -> tactic
    71   val net_biresolve_tac : (bool*thm) list -> int -> tactic
    72   val net_match_tac     : thm list -> int -> tactic
    73   val net_resolve_tac   : thm list -> int -> tactic
    74   val norm_hhf          : thm -> thm
    75   val norm_hhf_tac      : int -> tactic
    76   val PRIMITIVE         : (thm -> thm) -> tactic
    77   val PRIMSEQ           : (thm -> thm Seq.seq) -> tactic
    78   val prune_params_tac  : tactic
    79   val rename_params_tac : string list -> int -> tactic
    80   val rename_tac        : string -> int -> tactic
    81   val rename_last_tac   : string -> string list -> int -> tactic
    82   val resolve_from_net_tac      : (int*thm) Net.net -> int -> tactic
    83   val resolve_tac       : thm list -> int -> tactic
    84   val res_inst_tac      : (string*string)list -> thm -> int -> tactic
    85   val rewrite_goal_tac  : thm list -> int -> tactic
    86   val rewrite_goals_rule: thm list -> thm -> thm
    87   val rewrite_rule      : thm list -> thm -> thm
    88   val rewrite_goals_tac : thm list -> tactic
    89   val rewrite_tac       : thm list -> tactic
    90   val rewtac            : thm -> tactic
    91   val rotate_tac        : int -> int -> tactic
    92   val rtac              : thm -> int -> tactic
    93   val rule_by_tactic    : tactic -> thm -> thm
    94   val solve_tac         : thm list -> int -> tactic
    95   val subgoal_tac       : string -> int -> tactic
    96   val subgoals_tac      : string list -> int -> tactic
    97   val subgoals_of_brl   : bool * thm -> int
    98   val term_lift_inst_rule       :
    99       thm * int * (indexname*typ)list * ((indexname*typ)*term)list  * thm
   100       -> thm
   101   val instantiate_tac   : (string * string) list -> tactic
   102   val thin_tac          : string -> int -> tactic
   103   val trace_goalno_tac  : (int -> tactic) -> int -> tactic
   104 end;
   105 
   106 signature TACTIC =
   107 sig
   108   include BASIC_TACTIC
   109   val innermost_params: int -> thm -> (string * typ) list
   110   val untaglist: (int * 'a) list -> 'a list
   111   val orderlist: (int * 'a) list -> 'a list
   112   val rewrite: bool -> thm list -> cterm -> thm
   113   val rewrite_cterm: bool -> thm list -> cterm -> cterm
   114   val simplify: bool -> thm list -> thm -> thm
   115   val prove: Sign.sg -> string list -> term list -> term -> (thm list -> tactic) -> thm
   116   val prove_standard: Sign.sg -> string list -> term list -> term -> (thm list -> tactic) -> thm
   117 end;
   118 
   119 structure Tactic: TACTIC =
   120 struct
   121 
   122 (*Discover which goal is chosen:  SOMEGOAL(trace_goalno_tac tac) *)
   123 fun trace_goalno_tac tac i st =
   124     case Seq.pull(tac i st) of
   125         None    => Seq.empty
   126       | seqcell => (writeln ("Subgoal " ^ string_of_int i ^ " selected");
   127                          Seq.make(fn()=> seqcell));
   128 
   129 (*Makes a rule by applying a tactic to an existing rule*)
   130 fun rule_by_tactic tac rl =
   131   let val (st, thaw) = freeze_thaw (zero_var_indexes rl)
   132   in case Seq.pull (tac st)  of
   133         None        => raise THM("rule_by_tactic", 0, [rl])
   134       | Some(st',_) => Thm.varifyT (thaw st')
   135   end;
   136 
   137 (*** Basic tactics ***)
   138 
   139 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
   140 fun PRIMSEQ thmfun st =  thmfun st handle THM _ => Seq.empty;
   141 
   142 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
   143 fun PRIMITIVE thmfun = PRIMSEQ (Seq.single o thmfun);
   144 
   145 (*** The following fail if the goal number is out of range:
   146      thus (REPEAT (resolve_tac rules i)) stops once subgoal i disappears. *)
   147 
   148 (*Solve subgoal i by assumption*)
   149 fun assume_tac i = PRIMSEQ (assumption i);
   150 
   151 (*Solve subgoal i by assumption, using no unification*)
   152 fun eq_assume_tac i = PRIMITIVE (eq_assumption i);
   153 
   154 (** Resolution/matching tactics **)
   155 
   156 (*The composition rule/state: no lifting or var renaming.
   157   The arg = (bires_flg, orule, m) ;  see bicompose for explanation.*)
   158 fun compose_tac arg i = PRIMSEQ (bicompose false arg i);
   159 
   160 (*Converts a "destruct" rule like P&Q==>P to an "elimination" rule
   161   like [| P&Q; P==>R |] ==> R *)
   162 fun make_elim rl = zero_var_indexes (rl RS revcut_rl);
   163 
   164 (*Attack subgoal i by resolution, using flags to indicate elimination rules*)
   165 fun biresolve_tac brules i = PRIMSEQ (biresolution false brules i);
   166 
   167 (*Resolution: the simple case, works for introduction rules*)
   168 fun resolve_tac rules = biresolve_tac (map (pair false) rules);
   169 
   170 (*Resolution with elimination rules only*)
   171 fun eresolve_tac rules = biresolve_tac (map (pair true) rules);
   172 
   173 (*Forward reasoning using destruction rules.*)
   174 fun forward_tac rls = resolve_tac (map make_elim rls) THEN' assume_tac;
   175 
   176 (*Like forward_tac, but deletes the assumption after use.*)
   177 fun dresolve_tac rls = eresolve_tac (map make_elim rls);
   178 
   179 (*Shorthand versions: for resolution with a single theorem*)
   180 val atac    =   assume_tac;
   181 fun rtac rl =  resolve_tac [rl];
   182 fun dtac rl = dresolve_tac [rl];
   183 fun etac rl = eresolve_tac [rl];
   184 fun ftac rl =  forward_tac [rl];
   185 fun datac thm j = EVERY' (dtac thm::replicate j atac);
   186 fun eatac thm j = EVERY' (etac thm::replicate j atac);
   187 fun fatac thm j = EVERY' (ftac thm::replicate j atac);
   188 
   189 (*Use an assumption or some rules ... A popular combination!*)
   190 fun ares_tac rules = assume_tac  ORELSE'  resolve_tac rules;
   191 
   192 fun solve_tac rules = resolve_tac rules THEN_ALL_NEW assume_tac;
   193 
   194 (*Matching tactics -- as above, but forbid updating of state*)
   195 fun bimatch_tac brules i = PRIMSEQ (biresolution true brules i);
   196 fun match_tac rules  = bimatch_tac (map (pair false) rules);
   197 fun ematch_tac rules = bimatch_tac (map (pair true) rules);
   198 fun dmatch_tac rls   = ematch_tac (map make_elim rls);
   199 
   200 (*Smash all flex-flex disagreement pairs in the proof state.*)
   201 val flexflex_tac = PRIMSEQ flexflex_rule;
   202 
   203 
   204 (*Remove duplicate subgoals.  By Mark Staples*)
   205 local
   206 fun cterm_aconv (a,b) = #t (rep_cterm a) aconv #t (rep_cterm b);
   207 in
   208 fun distinct_subgoals_tac state =
   209     let val (frozth,thawfn) = freeze_thaw state
   210         val froz_prems = cprems_of frozth
   211         val assumed = implies_elim_list frozth (map assume froz_prems)
   212         val implied = implies_intr_list (gen_distinct cterm_aconv froz_prems)
   213                                         assumed;
   214     in  Seq.single (thawfn implied)  end
   215 end;
   216 
   217 
   218 (*Determine print names of goal parameters (reversed)*)
   219 fun innermost_params i st =
   220   let val (_, _, Bi, _) = dest_state (st, i)
   221   in rename_wrt_term Bi (Logic.strip_params Bi) end;
   222 
   223 (*Lift and instantiate a rule wrt the given state and subgoal number *)
   224 fun lift_inst_rule (st, i, sinsts, rule) =
   225 let val {maxidx,sign,...} = rep_thm st
   226     val (_, _, Bi, _) = dest_state(st,i)
   227     val params = Logic.strip_params Bi          (*params of subgoal i*)
   228     val params = rev(rename_wrt_term Bi params) (*as they are printed*)
   229     val paramTs = map #2 params
   230     and inc = maxidx+1
   231     fun liftvar (Var ((a,j), T)) = Var((a, j+inc), paramTs---> incr_tvar inc T)
   232       | liftvar t = raise TERM("Variable expected", [t]);
   233     fun liftterm t = list_abs_free (params,
   234                                     Logic.incr_indexes(paramTs,inc) t)
   235     (*Lifts instantiation pair over params*)
   236     fun liftpair (cv,ct) = (cterm_fun liftvar cv, cterm_fun liftterm ct)
   237     fun lifttvar((a,i),ctyp) =
   238         let val {T,sign} = rep_ctyp ctyp
   239         in  ((a,i+inc), ctyp_of sign (incr_tvar inc T)) end
   240     val rts = types_sorts rule and (types,sorts) = types_sorts st
   241     fun types'(a,~1) = (case assoc(params,a) of None => types(a,~1) | sm => sm)
   242       | types'(ixn) = types ixn;
   243     val used = add_term_tvarnames
   244                   (#prop(rep_thm st) $ #prop(rep_thm rule),[])
   245     val (Tinsts,insts) = read_insts sign rts (types',sorts) used sinsts
   246 in Drule.instantiate (map lifttvar Tinsts, map liftpair insts)
   247                      (lift_rule (st,i) rule)
   248 end;
   249 
   250 (*
   251 Like lift_inst_rule but takes terms, not strings, where the terms may contain
   252 Bounds referring to parameters of the subgoal.
   253 
   254 insts: [...,(vj,tj),...]
   255 
   256 The tj may contain references to parameters of subgoal i of the state st
   257 in the form of Bound k, i.e. the tj may be subterms of the subgoal.
   258 To saturate the lose bound vars, the tj are enclosed in abstractions
   259 corresponding to the parameters of subgoal i, thus turning them into
   260 functions. At the same time, the types of the vj are lifted.
   261 
   262 NB: the types in insts must be correctly instantiated already,
   263     i.e. Tinsts is not applied to insts.
   264 *)
   265 fun term_lift_inst_rule (st, i, Tinsts, insts, rule) =
   266 let val {maxidx,sign,...} = rep_thm st
   267     val (_, _, Bi, _) = dest_state(st,i)
   268     val params = Logic.strip_params Bi          (*params of subgoal i*)
   269     val paramTs = map #2 params
   270     and inc = maxidx+1
   271     fun liftvar ((a,j), T) = Var((a, j+inc), paramTs---> incr_tvar inc T)
   272     (*lift only Var, not term, which must be lifted already*)
   273     fun liftpair (v,t) = (cterm_of sign (liftvar v), cterm_of sign t)
   274     fun liftTpair((a,i),T) = ((a,i+inc), ctyp_of sign (incr_tvar inc T))
   275 in Drule.instantiate (map liftTpair Tinsts, map liftpair insts)
   276                      (lift_rule (st,i) rule)
   277 end;
   278 
   279 (*** Resolve after lifting and instantation; may refer to parameters of the
   280      subgoal.  Fails if "i" is out of range.  ***)
   281 
   282 (*compose version: arguments are as for bicompose.*)
   283 fun compose_inst_tac sinsts (bires_flg, rule, nsubgoal) i st =
   284   if i > nprems_of st then no_tac st
   285   else st |>
   286     (compose_tac (bires_flg, lift_inst_rule (st, i, sinsts, rule), nsubgoal) i
   287      handle TERM (msg,_)   => (writeln msg;  no_tac)
   288           | THM  (msg,_,_) => (writeln msg;  no_tac));
   289 
   290 (*"Resolve" version.  Note: res_inst_tac cannot behave sensibly if the
   291   terms that are substituted contain (term or type) unknowns from the
   292   goal, because it is unable to instantiate goal unknowns at the same time.
   293 
   294   The type checker is instructed not to freeze flexible type vars that
   295   were introduced during type inference and still remain in the term at the
   296   end.  This increases flexibility but can introduce schematic type vars in
   297   goals.
   298 *)
   299 fun res_inst_tac sinsts rule i =
   300     compose_inst_tac sinsts (false, rule, nprems_of rule) i;
   301 
   302 (*eresolve elimination version*)
   303 fun eres_inst_tac sinsts rule i =
   304     compose_inst_tac sinsts (true, rule, nprems_of rule) i;
   305 
   306 (*For forw_inst_tac and dres_inst_tac.  Preserve Var indexes of rl;
   307   increment revcut_rl instead.*)
   308 fun make_elim_preserve rl =
   309   let val {maxidx,...} = rep_thm rl
   310       fun cvar ixn = cterm_of (Theory.sign_of ProtoPure.thy) (Var(ixn,propT));
   311       val revcut_rl' =
   312           instantiate ([],  [(cvar("V",0), cvar("V",maxidx+1)),
   313                              (cvar("W",0), cvar("W",maxidx+1))]) revcut_rl
   314       val arg = (false, rl, nprems_of rl)
   315       val [th] = Seq.list_of (bicompose false arg 1 revcut_rl')
   316   in  th  end
   317   handle Bind => raise THM("make_elim_preserve", 1, [rl]);
   318 
   319 (*instantiate and cut -- for a FACT, anyway...*)
   320 fun cut_inst_tac sinsts rule = res_inst_tac sinsts (make_elim_preserve rule);
   321 
   322 (*forward tactic applies a RULE to an assumption without deleting it*)
   323 fun forw_inst_tac sinsts rule = cut_inst_tac sinsts rule THEN' assume_tac;
   324 
   325 (*dresolve tactic applies a RULE to replace an assumption*)
   326 fun dres_inst_tac sinsts rule = eres_inst_tac sinsts (make_elim_preserve rule);
   327 
   328 (*instantiate variables in the whole state*)
   329 val instantiate_tac = PRIMITIVE o read_instantiate;
   330 
   331 (*Deletion of an assumption*)
   332 fun thin_tac s = eres_inst_tac [("V",s)] thin_rl;
   333 
   334 (*** Applications of cut_rl ***)
   335 
   336 (*Used by metacut_tac*)
   337 fun bires_cut_tac arg i =
   338     resolve_tac [cut_rl] i  THEN  biresolve_tac arg (i+1) ;
   339 
   340 (*The conclusion of the rule gets assumed in subgoal i,
   341   while subgoal i+1,... are the premises of the rule.*)
   342 fun metacut_tac rule = bires_cut_tac [(false,rule)];
   343 
   344 (*Recognizes theorems that are not rules, but simple propositions*)
   345 fun is_fact rl =
   346     case prems_of rl of
   347         [] => true  |  _::_ => false;
   348 
   349 (*"Cut" all facts from theorem list into the goal as assumptions. *)
   350 fun cut_facts_tac ths i =
   351     EVERY (map (fn th => metacut_tac th i) (filter is_fact ths));
   352 
   353 (*Introduce the given proposition as a lemma and subgoal*)
   354 fun subgoal_tac sprop i st =
   355   let val st'    = Seq.hd (res_inst_tac [("psi", sprop)] cut_rl i st)
   356       val concl' = Logic.strip_assums_concl (List.nth(prems_of st', i))
   357   in
   358       if null (term_tvars concl') then ()
   359       else warning"Type variables in new subgoal: add a type constraint?";
   360       Seq.single st'
   361   end;
   362 
   363 (*Introduce a list of lemmas and subgoals*)
   364 fun subgoals_tac sprops = EVERY' (map subgoal_tac sprops);
   365 
   366 
   367 (**** Indexing and filtering of theorems ****)
   368 
   369 (*Returns the list of potentially resolvable theorems for the goal "prem",
   370         using the predicate  could(subgoal,concl).
   371   Resulting list is no longer than "limit"*)
   372 fun filter_thms could (limit, prem, ths) =
   373   let val pb = Logic.strip_assums_concl prem;   (*delete assumptions*)
   374       fun filtr (limit, []) = []
   375         | filtr (limit, th::ths) =
   376             if limit=0 then  []
   377             else if could(pb, concl_of th)  then th :: filtr(limit-1, ths)
   378             else filtr(limit,ths)
   379   in  filtr(limit,ths)  end;
   380 
   381 
   382 (*** biresolution and resolution using nets ***)
   383 
   384 (** To preserve the order of the rules, tag them with increasing integers **)
   385 
   386 (*insert tags*)
   387 fun taglist k [] = []
   388   | taglist k (x::xs) = (k,x) :: taglist (k+1) xs;
   389 
   390 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   391 fun untaglist [] = []
   392   | untaglist [(k:int,x)] = [x]
   393   | untaglist ((k,x) :: (rest as (k',x')::_)) =
   394       if k=k' then untaglist rest
   395       else    x :: untaglist rest;
   396 
   397 (*return list elements in original order*)
   398 fun orderlist kbrls = untaglist (sort (int_ord o pairself fst) kbrls);
   399 
   400 (*insert one tagged brl into the pair of nets*)
   401 fun insert_tagged_brl (kbrl as (k,(eres,th)), (inet,enet)) =
   402     if eres then
   403         case prems_of th of
   404             prem::_ => (inet, Net.insert_term ((prem,kbrl), enet, K false))
   405           | [] => error"insert_tagged_brl: elimination rule with no premises"
   406     else (Net.insert_term ((concl_of th, kbrl), inet, K false), enet);
   407 
   408 (*build a pair of nets for biresolution*)
   409 fun build_netpair netpair brls =
   410     foldr insert_tagged_brl (taglist 1 brls, netpair);
   411 
   412 (*delete one kbrl from the pair of nets;
   413   we don't know the value of k, so we use 0 and ignore it in the comparison*)
   414 local
   415   fun eq_kbrl ((k,(eres,th)), (k',(eres',th'))) = eq_thm (th,th')
   416 in
   417 fun delete_tagged_brl (brl as (eres,th), (inet,enet)) =
   418     if eres then
   419         case prems_of th of
   420             prem::_ => (inet, Net.delete_term ((prem, (0,brl)), enet, eq_kbrl))
   421           | []      => (inet,enet)     (*no major premise: ignore*)
   422     else (Net.delete_term ((concl_of th, (0,brl)), inet, eq_kbrl), enet);
   423 end;
   424 
   425 
   426 (*biresolution using a pair of nets rather than rules.
   427     function "order" must sort and possibly filter the list of brls.
   428     boolean "match" indicates matching or unification.*)
   429 fun biresolution_from_nets_tac order match (inet,enet) =
   430   SUBGOAL
   431     (fn (prem,i) =>
   432       let val hyps = Logic.strip_assums_hyp prem
   433           and concl = Logic.strip_assums_concl prem
   434           val kbrls = Net.unify_term inet concl @
   435                       List.concat (map (Net.unify_term enet) hyps)
   436       in PRIMSEQ (biresolution match (order kbrls) i) end);
   437 
   438 (*versions taking pre-built nets.  No filtering of brls*)
   439 val biresolve_from_nets_tac = biresolution_from_nets_tac orderlist false;
   440 val bimatch_from_nets_tac   = biresolution_from_nets_tac orderlist true;
   441 
   442 (*fast versions using nets internally*)
   443 val net_biresolve_tac =
   444     biresolve_from_nets_tac o build_netpair(Net.empty,Net.empty);
   445 
   446 val net_bimatch_tac =
   447     bimatch_from_nets_tac o build_netpair(Net.empty,Net.empty);
   448 
   449 (*** Simpler version for resolve_tac -- only one net, and no hyps ***)
   450 
   451 (*insert one tagged rl into the net*)
   452 fun insert_krl (krl as (k,th), net) =
   453     Net.insert_term ((concl_of th, krl), net, K false);
   454 
   455 (*build a net of rules for resolution*)
   456 fun build_net rls =
   457     foldr insert_krl (taglist 1 rls, Net.empty);
   458 
   459 (*resolution using a net rather than rules; pred supports filt_resolve_tac*)
   460 fun filt_resolution_from_net_tac match pred net =
   461   SUBGOAL
   462     (fn (prem,i) =>
   463       let val krls = Net.unify_term net (Logic.strip_assums_concl prem)
   464       in
   465          if pred krls
   466          then PRIMSEQ
   467                 (biresolution match (map (pair false) (orderlist krls)) i)
   468          else no_tac
   469       end);
   470 
   471 (*Resolve the subgoal using the rules (making a net) unless too flexible,
   472    which means more than maxr rules are unifiable.      *)
   473 fun filt_resolve_tac rules maxr =
   474     let fun pred krls = length krls <= maxr
   475     in  filt_resolution_from_net_tac false pred (build_net rules)  end;
   476 
   477 (*versions taking pre-built nets*)
   478 val resolve_from_net_tac = filt_resolution_from_net_tac false (K true);
   479 val match_from_net_tac = filt_resolution_from_net_tac true (K true);
   480 
   481 (*fast versions using nets internally*)
   482 val net_resolve_tac = resolve_from_net_tac o build_net;
   483 val net_match_tac = match_from_net_tac o build_net;
   484 
   485 
   486 (*** For Natural Deduction using (bires_flg, rule) pairs ***)
   487 
   488 (*The number of new subgoals produced by the brule*)
   489 fun subgoals_of_brl (true,rule)  = nprems_of rule - 1
   490   | subgoals_of_brl (false,rule) = nprems_of rule;
   491 
   492 (*Less-than test: for sorting to minimize number of new subgoals*)
   493 fun lessb (brl1,brl2) = subgoals_of_brl brl1 < subgoals_of_brl brl2;
   494 
   495 
   496 (*** Meta-Rewriting Tactics ***)
   497 
   498 fun result1 tacf mss thm =
   499   apsome fst (Seq.pull (tacf mss thm));
   500 
   501 val simple_prover =
   502   result1 (fn mss => ALLGOALS (resolve_tac (MetaSimplifier.prems_of_mss mss)));
   503 
   504 val rewrite = MetaSimplifier.rewrite_aux simple_prover;
   505 val rewrite_cterm = (#2 o Thm.dest_comb o #prop o Thm.crep_thm) ooo rewrite;
   506 val simplify = MetaSimplifier.simplify_aux simple_prover;
   507 val rewrite_rule = simplify true;
   508 val rewrite_goals_rule = MetaSimplifier.rewrite_goals_rule_aux simple_prover;
   509 
   510 (*Rewrite subgoal i only.  SELECT_GOAL avoids inefficiencies in goals_conv.*)
   511 fun asm_rewrite_goal_tac mode prover_tac mss =
   512   SELECT_GOAL
   513     (PRIMITIVE (MetaSimplifier.rewrite_goal_rule mode (result1 prover_tac) mss 1));
   514 
   515 fun rewrite_goal_tac rews =
   516   asm_rewrite_goal_tac (true, false, false) (K no_tac) (MetaSimplifier.mss_of rews);
   517 
   518 (*Rewrite throughout proof state. *)
   519 fun rewrite_tac defs = PRIMITIVE(rewrite_rule defs);
   520 
   521 (*Rewrite subgoals only, not main goal. *)
   522 fun rewrite_goals_tac defs = PRIMITIVE (rewrite_goals_rule defs);
   523 fun rewtac def = rewrite_goals_tac [def];
   524 
   525 fun norm_hhf th =
   526   (if Logic.is_norm_hhf (#prop (Thm.rep_thm th)) then th else rewrite_rule [Drule.norm_hhf_eq] th)
   527   |> Drule.forall_elim_vars_safe;
   528 
   529 val norm_hhf_tac = SUBGOAL (fn (t, i) =>
   530   if Logic.is_norm_hhf t then all_tac
   531   else rewrite_goal_tac [Drule.norm_hhf_eq] i);
   532 
   533 
   534 (*** for folding definitions, handling critical pairs ***)
   535 
   536 (*The depth of nesting in a term*)
   537 fun term_depth (Abs(a,T,t)) = 1 + term_depth t
   538   | term_depth (f$t) = 1 + Int.max(term_depth f, term_depth t)
   539   | term_depth _ = 0;
   540 
   541 val lhs_of_thm = #1 o Logic.dest_equals o #prop o rep_thm;
   542 
   543 (*folding should handle critical pairs!  E.g. K == Inl(0),  S == Inr(Inl(0))
   544   Returns longest lhs first to avoid folding its subexpressions.*)
   545 fun sort_lhs_depths defs =
   546   let val keylist = make_keylist (term_depth o lhs_of_thm) defs
   547       val keys = distinct (sort (rev_order o int_ord) (map #2 keylist))
   548   in  map (keyfilter keylist) keys  end;
   549 
   550 val rev_defs = sort_lhs_depths o map symmetric;
   551 
   552 fun fold_rule defs thm = foldl (fn (th, ds) => rewrite_rule ds th) (thm, rev_defs defs);
   553 fun fold_tac defs = EVERY (map rewrite_tac (rev_defs defs));
   554 fun fold_goals_tac defs = EVERY (map rewrite_goals_tac (rev_defs defs));
   555 
   556 
   557 (*** Renaming of parameters in a subgoal
   558      Names may contain letters, digits or primes and must be
   559      separated by blanks ***)
   560 
   561 (*Calling this will generate the warning "Same as previous level" since
   562   it affects nothing but the names of bound variables!*)
   563 fun rename_params_tac xs i =
   564   (if !Logic.auto_rename
   565     then (warning "Resetting Logic.auto_rename";
   566         Logic.auto_rename := false)
   567    else (); PRIMITIVE (rename_params_rule (xs, i)));
   568 
   569 fun rename_tac str i =
   570   let val cs = Symbol.explode str in
   571   case #2 (take_prefix (Symbol.is_letdig orf Symbol.is_blank) cs) of
   572       [] => rename_params_tac (scanwords Symbol.is_letdig cs) i
   573     | c::_ => error ("Illegal character: " ^ c)
   574   end;
   575 
   576 (*Rename recent parameters using names generated from a and the suffixes,
   577   provided the string a, which represents a term, is an identifier. *)
   578 fun rename_last_tac a sufs i =
   579   let val names = map (curry op^ a) sufs
   580   in  if Syntax.is_identifier a
   581       then PRIMITIVE (rename_params_rule (names,i))
   582       else all_tac
   583   end;
   584 
   585 (*Prunes all redundant parameters from the proof state by rewriting.
   586   DOES NOT rewrite main goal, where quantification over an unused bound
   587     variable is sometimes done to avoid the need for cut_facts_tac.*)
   588 val prune_params_tac = rewrite_goals_tac [triv_forall_equality];
   589 
   590 (*rotate_tac n i: rotate the assumptions of subgoal i by n positions, from
   591   right to left if n is positive, and from left to right if n is negative.*)
   592 fun rotate_tac 0 i = all_tac
   593   | rotate_tac k i = PRIMITIVE (rotate_rule k i);
   594 
   595 (*Rotates the given subgoal to be the last.*)
   596 fun defer_tac i = PRIMITIVE (permute_prems (i-1) 1);
   597 
   598 (* remove premises that do not satisfy p; fails if all prems satisfy p *)
   599 fun filter_prems_tac p =
   600   let fun Then None tac = Some tac
   601         | Then (Some tac) tac' = Some(tac THEN' tac');
   602       fun thins ((tac,n),H) =
   603         if p H then (tac,n+1)
   604         else (Then tac (rotate_tac n THEN' etac thin_rl),0);
   605   in SUBGOAL(fn (subg,n) =>
   606        let val Hs = Logic.strip_assums_hyp subg
   607        in case fst(foldl thins ((None,0),Hs)) of
   608             None => no_tac | Some tac => tac n
   609        end)
   610   end;
   611 
   612 
   613 (** minimal goal interface for internal use *)
   614 
   615 fun prove sign xs asms prop tac =
   616   let
   617     val statement = Logic.list_implies (asms, prop);
   618     val frees = map Term.dest_Free (Term.term_frees statement);
   619     val fixed_frees = filter_out (fn (x, _) => x mem_string xs) frees;
   620     val fixed_tfrees = foldr Term.add_typ_tfree_names (map #2 fixed_frees, []);
   621 
   622     val params = mapfilter (fn x => apsome (pair x) (assoc_string (frees, x))) xs;
   623 
   624     fun err msg = error (msg ^ "\nThe error(s) above occurred for the goal statement:\n" ^
   625       Sign.string_of_term sign (Term.list_all_free (params, statement)));
   626 
   627     fun cert_safe t = Thm.cterm_of sign t
   628       handle TERM (msg, _) => err msg | TYPE (msg, _, _) => err msg;
   629 
   630     val _ = cert_safe statement;
   631     val _ = Term.no_dummy_patterns statement handle TERM (msg, _) => error msg;
   632 
   633     val casms = map cert_safe asms;
   634     val prems = map (norm_hhf o Thm.assume) casms;
   635     val goal = Drule.mk_triv_goal (cert_safe prop);
   636 
   637     val goal' =
   638       (case Seq.pull (tac prems goal) of Some (goal', _) => goal' | _ => err "Tactic failed.");
   639     val ngoals = Thm.nprems_of goal';
   640     val raw_result = goal' RS Drule.rev_triv_goal;
   641     val prop' = #prop (Thm.rep_thm raw_result);
   642   in
   643     if ngoals <> 0 then
   644       err ("Proof failed.\n" ^ Pretty.string_of (Pretty.chunks (Display.pretty_goals ngoals goal'))
   645         ^ ("\n" ^ string_of_int ngoals ^ " unsolved goal(s)!"))
   646     else if not (Pattern.matches (Sign.tsig_of sign) (prop, prop')) then
   647       err ("Proved a different theorem: " ^ Sign.string_of_term sign prop')
   648     else
   649       raw_result
   650       |> Drule.implies_intr_list casms
   651       |> Drule.forall_intr_list (map (cert_safe o Free) params)
   652       |> norm_hhf
   653       |> Thm.varifyT' fixed_tfrees
   654       |> Drule.zero_var_indexes
   655   end;
   656 
   657 fun prove_standard sign xs asms prop tac = Drule.standard (prove sign xs asms prop tac);
   658 
   659 end;
   660 
   661 structure BasicTactic: BASIC_TACTIC = Tactic;
   662 open BasicTactic;