src/HOL/Product_Type.thy
author haftmann
Fri May 28 13:37:28 2010 +0200 (2010-05-28)
changeset 37166 e8400e31528a
parent 37136 e0c9d3e49e15
child 37278 307845cc7f51
permissions -rw-r--r--
more coherent theory structure; tuned headings
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_set.ML")
    13 begin
    14 
    15 subsection {* @{typ bool} is a datatype *}
    16 
    17 rep_datatype True False by (auto intro: bool_induct)
    18 
    19 declare case_split [cases type: bool]
    20   -- "prefer plain propositional version"
    21 
    22 lemma
    23   shows [code]: "eq_class.eq False P \<longleftrightarrow> \<not> P"
    24     and [code]: "eq_class.eq True P \<longleftrightarrow> P" 
    25     and [code]: "eq_class.eq P False \<longleftrightarrow> \<not> P" 
    26     and [code]: "eq_class.eq P True \<longleftrightarrow> P"
    27     and [code nbe]: "eq_class.eq P P \<longleftrightarrow> True"
    28   by (simp_all add: eq)
    29 
    30 code_const "eq_class.eq \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    31   (Haskell infixl 4 "==")
    32 
    33 code_instance bool :: eq
    34   (Haskell -)
    35 
    36 
    37 subsection {* The @{text unit} type *}
    38 
    39 typedef unit = "{True}"
    40 proof
    41   show "True : ?unit" ..
    42 qed
    43 
    44 definition
    45   Unity :: unit    ("'(')")
    46 where
    47   "() = Abs_unit True"
    48 
    49 lemma unit_eq [no_atp]: "u = ()"
    50   by (induct u) (simp add: unit_def Unity_def)
    51 
    52 text {*
    53   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    54   this rule directly --- it loops!
    55 *}
    56 
    57 ML {*
    58   val unit_eq_proc =
    59     let val unit_meta_eq = mk_meta_eq @{thm unit_eq} in
    60       Simplifier.simproc @{theory} "unit_eq" ["x::unit"]
    61       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    62     end;
    63 
    64   Addsimprocs [unit_eq_proc];
    65 *}
    66 
    67 rep_datatype "()" by simp
    68 
    69 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    70   by simp
    71 
    72 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    73   by (rule triv_forall_equality)
    74 
    75 text {*
    76   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    77   [source] "%u::unit. f u"}, replacing it by @{term [source]
    78   f} rather than by @{term [source] "%u. f ()"}.
    79 *}
    80 
    81 lemma unit_abs_eta_conv [simp,no_atp]: "(%u::unit. f ()) = f"
    82   by (rule ext) simp
    83 
    84 instantiation unit :: default
    85 begin
    86 
    87 definition "default = ()"
    88 
    89 instance ..
    90 
    91 end
    92 
    93 lemma [code]:
    94   "eq_class.eq (u\<Colon>unit) v \<longleftrightarrow> True" unfolding eq unit_eq [of u] unit_eq [of v] by rule+
    95 
    96 code_type unit
    97   (SML "unit")
    98   (OCaml "unit")
    99   (Haskell "()")
   100   (Scala "Unit")
   101 
   102 code_const Unity
   103   (SML "()")
   104   (OCaml "()")
   105   (Haskell "()")
   106   (Scala "()")
   107 
   108 code_instance unit :: eq
   109   (Haskell -)
   110 
   111 code_const "eq_class.eq \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   112   (Haskell infixl 4 "==")
   113 
   114 code_reserved SML
   115   unit
   116 
   117 code_reserved OCaml
   118   unit
   119 
   120 code_reserved Scala
   121   Unit
   122 
   123 
   124 subsection {* The product type *}
   125 
   126 subsubsection {* Type definition *}
   127 
   128 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   129   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   130 
   131 global
   132 
   133 typedef (Prod)
   134   ('a, 'b) "*"    (infixr "*" 20)
   135     = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   136 proof
   137   fix a b show "Pair_Rep a b \<in> ?Prod"
   138     by rule+
   139 qed
   140 
   141 type_notation (xsymbols)
   142   "*"  ("(_ \<times>/ _)" [21, 20] 20)
   143 type_notation (HTML output)
   144   "*"  ("(_ \<times>/ _)" [21, 20] 20)
   145 
   146 consts
   147   Pair     :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b"
   148 
   149 local
   150 
   151 defs
   152   Pair_def:     "Pair a b == Abs_Prod (Pair_Rep a b)"
   153 
   154 rep_datatype (prod) Pair proof -
   155   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   156   assume "\<And>a b. P (Pair a b)"
   157   then show "P p" by (cases p) (auto simp add: Prod_def Pair_def Pair_Rep_def)
   158 next
   159   fix a c :: 'a and b d :: 'b
   160   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   161     by (auto simp add: Pair_Rep_def expand_fun_eq)
   162   moreover have "Pair_Rep a b \<in> Prod" and "Pair_Rep c d \<in> Prod"
   163     by (auto simp add: Prod_def)
   164   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   165     by (simp add: Pair_def Abs_Prod_inject)
   166 qed
   167 
   168 
   169 subsubsection {* Tuple syntax *}
   170 
   171 global consts
   172   split    :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c"
   173 
   174 local defs
   175   split_prod_case: "split == prod_case"
   176 
   177 text {*
   178   Patterns -- extends pre-defined type @{typ pttrn} used in
   179   abstractions.
   180 *}
   181 
   182 nonterminals
   183   tuple_args patterns
   184 
   185 syntax
   186   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   187   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   188   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   189   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   190   ""            :: "pttrn => patterns"                  ("_")
   191   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   192 
   193 translations
   194   "(x, y)" == "CONST Pair x y"
   195   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   196   "%(x, y, zs). b" == "CONST split (%x (y, zs). b)"
   197   "%(x, y). b" == "CONST split (%x y. b)"
   198   "_abs (CONST Pair x y) t" => "%(x, y). t"
   199   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   200      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   201 
   202 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   203   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   204 print_translation {*
   205 let
   206   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   207         (* split (%x y. t) => %(x,y) t *)
   208         let
   209           val (y, t') = atomic_abs_tr' abs;
   210           val (x', t'') = atomic_abs_tr' (x, T, t');
   211         in
   212           Syntax.const @{syntax_const "_abs"} $
   213             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   214         end
   215     | split_tr' [Abs (x, T, (s as Const (@{const_syntax split}, _) $ t))] =
   216         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   217         let
   218           val Const (@{syntax_const "_abs"}, _) $
   219             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   220           val (x', t'') = atomic_abs_tr' (x, T, t');
   221         in
   222           Syntax.const @{syntax_const "_abs"} $
   223             (Syntax.const @{syntax_const "_pattern"} $ x' $
   224               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   225         end
   226     | split_tr' [Const (@{const_syntax split}, _) $ t] =
   227         (* split (split (%x y z. t)) => %((x, y), z). t *)
   228         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   229     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   230         (* split (%pttrn z. t) => %(pttrn,z). t *)
   231         let val (z, t) = atomic_abs_tr' abs in
   232           Syntax.const @{syntax_const "_abs"} $
   233             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   234         end
   235     | split_tr' _ = raise Match;
   236 in [(@{const_syntax split}, split_tr')] end
   237 *}
   238 
   239 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   240 typed_print_translation {*
   241 let
   242   fun split_guess_names_tr' _ T [Abs (x, _, Abs _)] = raise Match
   243     | split_guess_names_tr' _ T [Abs (x, xT, t)] =
   244         (case (head_of t) of
   245           Const (@{const_syntax split}, _) => raise Match
   246         | _ =>
   247           let 
   248             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   249             val (y, t') = atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   250             val (x', t'') = atomic_abs_tr' (x, xT, t');
   251           in
   252             Syntax.const @{syntax_const "_abs"} $
   253               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   254           end)
   255     | split_guess_names_tr' _ T [t] =
   256         (case head_of t of
   257           Const (@{const_syntax split}, _) => raise Match
   258         | _ =>
   259           let
   260             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   261             val (y, t') = atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   262             val (x', t'') = atomic_abs_tr' ("x", xT, t');
   263           in
   264             Syntax.const @{syntax_const "_abs"} $
   265               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   266           end)
   267     | split_guess_names_tr' _ _ _ = raise Match;
   268 in [(@{const_syntax split}, split_guess_names_tr')] end
   269 *}
   270 
   271 
   272 subsubsection {* Code generator setup *}
   273 
   274 lemma split_case_cert:
   275   assumes "CASE \<equiv> split f"
   276   shows "CASE (a, b) \<equiv> f a b"
   277   using assms by (simp add: split_prod_case)
   278 
   279 setup {*
   280   Code.add_case @{thm split_case_cert}
   281 *}
   282 
   283 code_type *
   284   (SML infix 2 "*")
   285   (OCaml infix 2 "*")
   286   (Haskell "!((_),/ (_))")
   287   (Scala "((_),/ (_))")
   288 
   289 code_const Pair
   290   (SML "!((_),/ (_))")
   291   (OCaml "!((_),/ (_))")
   292   (Haskell "!((_),/ (_))")
   293   (Scala "!((_),/ (_))")
   294 
   295 code_instance * :: eq
   296   (Haskell -)
   297 
   298 code_const "eq_class.eq \<Colon> 'a\<Colon>eq \<times> 'b\<Colon>eq \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   299   (Haskell infixl 4 "==")
   300 
   301 types_code
   302   "*"     ("(_ */ _)")
   303 attach (term_of) {*
   304 fun term_of_id_42 aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   305 *}
   306 attach (test) {*
   307 fun gen_id_42 aG aT bG bT i =
   308   let
   309     val (x, t) = aG i;
   310     val (y, u) = bG i
   311   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   312 *}
   313 
   314 consts_code
   315   "Pair"    ("(_,/ _)")
   316 
   317 setup {*
   318 let
   319 
   320 fun strip_abs_split 0 t = ([], t)
   321   | strip_abs_split i (Abs (s, T, t)) =
   322       let
   323         val s' = Codegen.new_name t s;
   324         val v = Free (s', T)
   325       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   326   | strip_abs_split i (u as Const (@{const_name split}, _) $ t) =
   327       (case strip_abs_split (i+1) t of
   328         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   329       | _ => ([], u))
   330   | strip_abs_split i t =
   331       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
   332 
   333 fun let_codegen thy defs dep thyname brack t gr =
   334   (case strip_comb t of
   335     (t1 as Const (@{const_name Let}, _), t2 :: t3 :: ts) =>
   336     let
   337       fun dest_let (l as Const (@{const_name Let}, _) $ t $ u) =
   338           (case strip_abs_split 1 u of
   339              ([p], u') => apfst (cons (p, t)) (dest_let u')
   340            | _ => ([], l))
   341         | dest_let t = ([], t);
   342       fun mk_code (l, r) gr =
   343         let
   344           val (pl, gr1) = Codegen.invoke_codegen thy defs dep thyname false l gr;
   345           val (pr, gr2) = Codegen.invoke_codegen thy defs dep thyname false r gr1;
   346         in ((pl, pr), gr2) end
   347     in case dest_let (t1 $ t2 $ t3) of
   348         ([], _) => NONE
   349       | (ps, u) =>
   350           let
   351             val (qs, gr1) = fold_map mk_code ps gr;
   352             val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
   353             val (pargs, gr3) = fold_map
   354               (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
   355           in
   356             SOME (Codegen.mk_app brack
   357               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
   358                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   359                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
   360                        Pretty.brk 1, pr]]) qs))),
   361                 Pretty.brk 1, Codegen.str "in ", pu,
   362                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
   363           end
   364     end
   365   | _ => NONE);
   366 
   367 fun split_codegen thy defs dep thyname brack t gr = (case strip_comb t of
   368     (t1 as Const (@{const_name split}, _), t2 :: ts) =>
   369       let
   370         val ([p], u) = strip_abs_split 1 (t1 $ t2);
   371         val (q, gr1) = Codegen.invoke_codegen thy defs dep thyname false p gr;
   372         val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
   373         val (pargs, gr3) = fold_map
   374           (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
   375       in
   376         SOME (Codegen.mk_app brack
   377           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
   378             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
   379       end
   380   | _ => NONE);
   381 
   382 in
   383 
   384   Codegen.add_codegen "let_codegen" let_codegen
   385   #> Codegen.add_codegen "split_codegen" split_codegen
   386 
   387 end
   388 *}
   389 
   390 
   391 subsubsection {* Fundamental operations and properties *}
   392 
   393 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   394   by (cases p) simp
   395 
   396 global consts
   397   fst      :: "'a \<times> 'b \<Rightarrow> 'a"
   398   snd      :: "'a \<times> 'b \<Rightarrow> 'b"
   399 
   400 local defs
   401   fst_def:      "fst p == case p of (a, b) \<Rightarrow> a"
   402   snd_def:      "snd p == case p of (a, b) \<Rightarrow> b"
   403 
   404 lemma fst_conv [simp, code]: "fst (a, b) = a"
   405   unfolding fst_def by simp
   406 
   407 lemma snd_conv [simp, code]: "snd (a, b) = b"
   408   unfolding snd_def by simp
   409 
   410 code_const fst and snd
   411   (Haskell "fst" and "snd")
   412 
   413 lemma prod_case_unfold: "prod_case = (%c p. c (fst p) (snd p))"
   414   by (simp add: expand_fun_eq split: prod.split)
   415 
   416 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   417   by simp
   418 
   419 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   420   by simp
   421 
   422 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   423   by (cases p) simp
   424 
   425 lemmas surjective_pairing = pair_collapse [symmetric]
   426 
   427 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   428   by (cases s, cases t) simp
   429 
   430 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   431   by (simp add: Pair_fst_snd_eq)
   432 
   433 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   434   by (simp add: split_prod_case)
   435 
   436 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   437   by (rule split_conv [THEN iffD2])
   438 
   439 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   440   by (rule split_conv [THEN iffD1])
   441 
   442 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   443   by (simp add: split_prod_case expand_fun_eq split: prod.split)
   444 
   445 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   446   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   447   by (simp add: split_prod_case expand_fun_eq split: prod.split)
   448 
   449 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   450   by (cases x) simp
   451 
   452 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   453   by (cases p) simp
   454 
   455 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   456   by (simp add: split_prod_case prod_case_unfold)
   457 
   458 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   459   -- {* Prevents simplification of @{term c}: much faster *}
   460   by (erule arg_cong)
   461 
   462 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   463   by (simp add: split_eta)
   464 
   465 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   466 proof
   467   fix a b
   468   assume "!!x. PROP P x"
   469   then show "PROP P (a, b)" .
   470 next
   471   fix x
   472   assume "!!a b. PROP P (a, b)"
   473   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   474 qed
   475 
   476 text {*
   477   The rule @{thm [source] split_paired_all} does not work with the
   478   Simplifier because it also affects premises in congrence rules,
   479   where this can lead to premises of the form @{text "!!a b. ... =
   480   ?P(a, b)"} which cannot be solved by reflexivity.
   481 *}
   482 
   483 lemmas split_tupled_all = split_paired_all unit_all_eq2
   484 
   485 ML {*
   486   (* replace parameters of product type by individual component parameters *)
   487   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   488   local (* filtering with exists_paired_all is an essential optimization *)
   489     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   490           can HOLogic.dest_prodT T orelse exists_paired_all t
   491       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   492       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   493       | exists_paired_all _ = false;
   494     val ss = HOL_basic_ss
   495       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   496       addsimprocs [unit_eq_proc];
   497   in
   498     val split_all_tac = SUBGOAL (fn (t, i) =>
   499       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   500     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   501       if exists_paired_all t then full_simp_tac ss i else no_tac);
   502     fun split_all th =
   503    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   504   end;
   505 *}
   506 
   507 declaration {* fn _ =>
   508   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   509 *}
   510 
   511 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   512   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   513   by fast
   514 
   515 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   516   by fast
   517 
   518 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   519   -- {* Can't be added to simpset: loops! *}
   520   by (simp add: split_eta)
   521 
   522 text {*
   523   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   524   @{thm [source] split_eta} as a rewrite rule is not general enough,
   525   and using @{thm [source] cond_split_eta} directly would render some
   526   existing proofs very inefficient; similarly for @{text
   527   split_beta}.
   528 *}
   529 
   530 ML {*
   531 local
   532   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   533   fun Pair_pat k 0 (Bound m) = (m = k)
   534     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   535         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   536     | Pair_pat _ _ _ = false;
   537   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   538     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   539     | no_args k i (Bound m) = m < k orelse m > k + i
   540     | no_args _ _ _ = true;
   541   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   542     | split_pat tp i (Const (@{const_name split}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   543     | split_pat tp i _ = NONE;
   544   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   545         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   546         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   547 
   548   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   549     | beta_term_pat k i (t $ u) =
   550         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   551     | beta_term_pat k i t = no_args k i t;
   552   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   553     | eta_term_pat _ _ _ = false;
   554   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   555     | subst arg k i (t $ u) =
   556         if Pair_pat k i (t $ u) then incr_boundvars k arg
   557         else (subst arg k i t $ subst arg k i u)
   558     | subst arg k i t = t;
   559   fun beta_proc ss (s as Const (@{const_name split}, _) $ Abs (_, _, t) $ arg) =
   560         (case split_pat beta_term_pat 1 t of
   561           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   562         | NONE => NONE)
   563     | beta_proc _ _ = NONE;
   564   fun eta_proc ss (s as Const (@{const_name split}, _) $ Abs (_, _, t)) =
   565         (case split_pat eta_term_pat 1 t of
   566           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   567         | NONE => NONE)
   568     | eta_proc _ _ = NONE;
   569 in
   570   val split_beta_proc = Simplifier.simproc @{theory} "split_beta" ["split f z"] (K beta_proc);
   571   val split_eta_proc = Simplifier.simproc @{theory} "split_eta" ["split f"] (K eta_proc);
   572 end;
   573 
   574 Addsimprocs [split_beta_proc, split_eta_proc];
   575 *}
   576 
   577 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   578   by (subst surjective_pairing, rule split_conv)
   579 
   580 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   581   -- {* For use with @{text split} and the Simplifier. *}
   582   by (insert surj_pair [of p], clarify, simp)
   583 
   584 text {*
   585   @{thm [source] split_split} could be declared as @{text "[split]"}
   586   done after the Splitter has been speeded up significantly;
   587   precompute the constants involved and don't do anything unless the
   588   current goal contains one of those constants.
   589 *}
   590 
   591 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   592 by (subst split_split, simp)
   593 
   594 text {*
   595   \medskip @{term split} used as a logical connective or set former.
   596 
   597   \medskip These rules are for use with @{text blast}; could instead
   598   call @{text simp} using @{thm [source] split} as rewrite. *}
   599 
   600 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   601   apply (simp only: split_tupled_all)
   602   apply (simp (no_asm_simp))
   603   done
   604 
   605 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   606   apply (simp only: split_tupled_all)
   607   apply (simp (no_asm_simp))
   608   done
   609 
   610 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   611   by (induct p) (auto simp add: split_prod_case)
   612 
   613 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   614   by (induct p) (auto simp add: split_prod_case)
   615 
   616 lemma splitE2:
   617   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   618 proof -
   619   assume q: "Q (split P z)"
   620   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   621   show R
   622     apply (rule r surjective_pairing)+
   623     apply (rule split_beta [THEN subst], rule q)
   624     done
   625 qed
   626 
   627 lemma splitD': "split R (a,b) c ==> R a b c"
   628   by simp
   629 
   630 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   631   by simp
   632 
   633 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   634 by (simp only: split_tupled_all, simp)
   635 
   636 lemma mem_splitE:
   637   assumes major: "z \<in> split c p"
   638     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   639   shows Q
   640   by (rule major [unfolded split_prod_case prod_case_unfold] cases surjective_pairing)+
   641 
   642 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   643 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   644 
   645 ML {*
   646 local (* filtering with exists_p_split is an essential optimization *)
   647   fun exists_p_split (Const (@{const_name split},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   648     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   649     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   650     | exists_p_split _ = false;
   651   val ss = HOL_basic_ss addsimps @{thms split_conv};
   652 in
   653 val split_conv_tac = SUBGOAL (fn (t, i) =>
   654     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   655 end;
   656 *}
   657 
   658 (* This prevents applications of splitE for already splitted arguments leading
   659    to quite time-consuming computations (in particular for nested tuples) *)
   660 declaration {* fn _ =>
   661   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   662 *}
   663 
   664 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   665   by (rule ext) fast
   666 
   667 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   668   by (rule ext) fast
   669 
   670 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   671   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   672   by (rule ext) blast
   673 
   674 (* Do NOT make this a simp rule as it
   675    a) only helps in special situations
   676    b) can lead to nontermination in the presence of split_def
   677 *)
   678 lemma split_comp_eq: 
   679   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   680   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   681   by (rule ext) auto
   682 
   683 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   684   apply (rule_tac x = "(a, b)" in image_eqI)
   685    apply auto
   686   done
   687 
   688 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   689   by blast
   690 
   691 (*
   692 the following  would be slightly more general,
   693 but cannot be used as rewrite rule:
   694 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   695 ### ?y = .x
   696 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   697 by (rtac some_equality 1)
   698 by ( Simp_tac 1)
   699 by (split_all_tac 1)
   700 by (Asm_full_simp_tac 1)
   701 qed "The_split_eq";
   702 *)
   703 
   704 text {*
   705   Setup of internal @{text split_rule}.
   706 *}
   707 
   708 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   709 
   710 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   711   by auto
   712 
   713 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   714   by (auto simp: split_tupled_all)
   715 
   716 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   717   by (induct p) auto
   718 
   719 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   720   by (induct p) auto
   721 
   722 declare prod_caseI2' [intro!] prod_caseI2 [intro!] prod_caseI [intro!]
   723 declare prod_caseE' [elim!] prod_caseE [elim!]
   724 
   725 lemma prod_case_split:
   726   "prod_case = split"
   727   by (auto simp add: expand_fun_eq)
   728 
   729 lemma prod_case_beta:
   730   "prod_case f p = f (fst p) (snd p)"
   731   unfolding prod_case_split split_beta ..
   732 
   733 lemma prod_cases3 [cases type]:
   734   obtains (fields) a b c where "y = (a, b, c)"
   735   by (cases y, case_tac b) blast
   736 
   737 lemma prod_induct3 [case_names fields, induct type]:
   738     "(!!a b c. P (a, b, c)) ==> P x"
   739   by (cases x) blast
   740 
   741 lemma prod_cases4 [cases type]:
   742   obtains (fields) a b c d where "y = (a, b, c, d)"
   743   by (cases y, case_tac c) blast
   744 
   745 lemma prod_induct4 [case_names fields, induct type]:
   746     "(!!a b c d. P (a, b, c, d)) ==> P x"
   747   by (cases x) blast
   748 
   749 lemma prod_cases5 [cases type]:
   750   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   751   by (cases y, case_tac d) blast
   752 
   753 lemma prod_induct5 [case_names fields, induct type]:
   754     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   755   by (cases x) blast
   756 
   757 lemma prod_cases6 [cases type]:
   758   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   759   by (cases y, case_tac e) blast
   760 
   761 lemma prod_induct6 [case_names fields, induct type]:
   762     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   763   by (cases x) blast
   764 
   765 lemma prod_cases7 [cases type]:
   766   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   767   by (cases y, case_tac f) blast
   768 
   769 lemma prod_induct7 [case_names fields, induct type]:
   770     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   771   by (cases x) blast
   772 
   773 lemma split_def:
   774   "split = (\<lambda>c p. c (fst p) (snd p))"
   775   unfolding split_prod_case prod_case_unfold ..
   776 
   777 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   778   "internal_split == split"
   779 
   780 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   781   by (simp only: internal_split_def split_conv)
   782 
   783 use "Tools/split_rule.ML"
   784 setup Split_Rule.setup
   785 
   786 hide_const internal_split
   787 
   788 
   789 subsubsection {* Derived operations *}
   790 
   791 global consts
   792   curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c"
   793 
   794 local defs
   795   curry_def:    "curry == (%c x y. c (Pair x y))"
   796 
   797 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   798   by (simp add: curry_def)
   799 
   800 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   801   by (simp add: curry_def)
   802 
   803 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   804   by (simp add: curry_def)
   805 
   806 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   807   by (simp add: curry_def)
   808 
   809 lemma curry_split [simp]: "curry (split f) = f"
   810   by (simp add: curry_def split_def)
   811 
   812 lemma split_curry [simp]: "split (curry f) = f"
   813   by (simp add: curry_def split_def)
   814 
   815 text {*
   816   The composition-uncurry combinator.
   817 *}
   818 
   819 notation fcomp (infixl "o>" 60)
   820 
   821 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "o\<rightarrow>" 60) where
   822   "f o\<rightarrow> g = (\<lambda>x. split g (f x))"
   823 
   824 lemma scomp_apply:  "(f o\<rightarrow> g) x = split g (f x)"
   825   by (simp add: scomp_def)
   826 
   827 lemma Pair_scomp: "Pair x o\<rightarrow> f = f x"
   828   by (simp add: expand_fun_eq scomp_apply)
   829 
   830 lemma scomp_Pair: "x o\<rightarrow> Pair = x"
   831   by (simp add: expand_fun_eq scomp_apply)
   832 
   833 lemma scomp_scomp: "(f o\<rightarrow> g) o\<rightarrow> h = f o\<rightarrow> (\<lambda>x. g x o\<rightarrow> h)"
   834   by (simp add: expand_fun_eq split_twice scomp_def)
   835 
   836 lemma scomp_fcomp: "(f o\<rightarrow> g) o> h = f o\<rightarrow> (\<lambda>x. g x o> h)"
   837   by (simp add: expand_fun_eq scomp_apply fcomp_def split_def)
   838 
   839 lemma fcomp_scomp: "(f o> g) o\<rightarrow> h = f o> (g o\<rightarrow> h)"
   840   by (simp add: expand_fun_eq scomp_apply fcomp_apply)
   841 
   842 code_const scomp
   843   (Eval infixl 3 "#->")
   844 
   845 no_notation fcomp (infixl "o>" 60)
   846 no_notation scomp (infixl "o\<rightarrow>" 60)
   847 
   848 text {*
   849   @{term prod_fun} --- action of the product functor upon
   850   functions.
   851 *}
   852 
   853 definition prod_fun :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   854   [code del]: "prod_fun f g = (\<lambda>(x, y). (f x, g y))"
   855 
   856 lemma prod_fun [simp, code]: "prod_fun f g (a, b) = (f a, g b)"
   857   by (simp add: prod_fun_def)
   858 
   859 lemma prod_fun_compose: "prod_fun (f1 o f2) (g1 o g2) = (prod_fun f1 g1 o prod_fun f2 g2)"
   860   by (rule ext) auto
   861 
   862 lemma prod_fun_ident [simp]: "prod_fun (%x. x) (%y. y) = (%z. z)"
   863   by (rule ext) auto
   864 
   865 lemma prod_fun_imageI [intro]: "(a, b) : r ==> (f a, g b) : prod_fun f g ` r"
   866   apply (rule image_eqI)
   867   apply (rule prod_fun [symmetric], assumption)
   868   done
   869 
   870 lemma prod_fun_imageE [elim!]:
   871   assumes major: "c: (prod_fun f g)`r"
   872     and cases: "!!x y. [| c=(f(x),g(y));  (x,y):r |] ==> P"
   873   shows P
   874   apply (rule major [THEN imageE])
   875   apply (case_tac x)
   876   apply (rule cases)
   877    apply (blast intro: prod_fun)
   878   apply blast
   879   done
   880 
   881 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   882   "apfst f = prod_fun f id"
   883 
   884 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   885   "apsnd f = prod_fun id f"
   886 
   887 lemma apfst_conv [simp, code]:
   888   "apfst f (x, y) = (f x, y)" 
   889   by (simp add: apfst_def)
   890 
   891 lemma apsnd_conv [simp, code]:
   892   "apsnd f (x, y) = (x, f y)" 
   893   by (simp add: apsnd_def)
   894 
   895 lemma fst_apfst [simp]:
   896   "fst (apfst f x) = f (fst x)"
   897   by (cases x) simp
   898 
   899 lemma fst_apsnd [simp]:
   900   "fst (apsnd f x) = fst x"
   901   by (cases x) simp
   902 
   903 lemma snd_apfst [simp]:
   904   "snd (apfst f x) = snd x"
   905   by (cases x) simp
   906 
   907 lemma snd_apsnd [simp]:
   908   "snd (apsnd f x) = f (snd x)"
   909   by (cases x) simp
   910 
   911 lemma apfst_compose:
   912   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   913   by (cases x) simp
   914 
   915 lemma apsnd_compose:
   916   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   917   by (cases x) simp
   918 
   919 lemma apfst_apsnd [simp]:
   920   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   921   by (cases x) simp
   922 
   923 lemma apsnd_apfst [simp]:
   924   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   925   by (cases x) simp
   926 
   927 lemma apfst_id [simp] :
   928   "apfst id = id"
   929   by (simp add: expand_fun_eq)
   930 
   931 lemma apsnd_id [simp] :
   932   "apsnd id = id"
   933   by (simp add: expand_fun_eq)
   934 
   935 lemma apfst_eq_conv [simp]:
   936   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   937   by (cases x) simp
   938 
   939 lemma apsnd_eq_conv [simp]:
   940   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   941   by (cases x) simp
   942 
   943 lemma apsnd_apfst_commute:
   944   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   945   by simp
   946 
   947 text {*
   948   Disjoint union of a family of sets -- Sigma.
   949 *}
   950 
   951 definition  Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   952   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   953 
   954 abbreviation
   955   Times :: "['a set, 'b set] => ('a * 'b) set"
   956     (infixr "<*>" 80) where
   957   "A <*> B == Sigma A (%_. B)"
   958 
   959 notation (xsymbols)
   960   Times  (infixr "\<times>" 80)
   961 
   962 notation (HTML output)
   963   Times  (infixr "\<times>" 80)
   964 
   965 syntax
   966   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   967 translations
   968   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   969 
   970 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   971   by (unfold Sigma_def) blast
   972 
   973 lemma SigmaE [elim!]:
   974     "[| c: Sigma A B;
   975         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   976      |] ==> P"
   977   -- {* The general elimination rule. *}
   978   by (unfold Sigma_def) blast
   979 
   980 text {*
   981   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   982   eigenvariables.
   983 *}
   984 
   985 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   986   by blast
   987 
   988 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   989   by blast
   990 
   991 lemma SigmaE2:
   992     "[| (a, b) : Sigma A B;
   993         [| a:A;  b:B(a) |] ==> P
   994      |] ==> P"
   995   by blast
   996 
   997 lemma Sigma_cong:
   998      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   999       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1000   by auto
  1001 
  1002 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1003   by blast
  1004 
  1005 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1006   by blast
  1007 
  1008 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1009   by blast
  1010 
  1011 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1012   by auto
  1013 
  1014 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1015   by auto
  1016 
  1017 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1018   by auto
  1019 
  1020 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1021   by blast
  1022 
  1023 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1024   by blast
  1025 
  1026 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1027   by (blast elim: equalityE)
  1028 
  1029 lemma SetCompr_Sigma_eq:
  1030     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1031   by blast
  1032 
  1033 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1034   by blast
  1035 
  1036 lemma UN_Times_distrib:
  1037   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1038   -- {* Suggested by Pierre Chartier *}
  1039   by blast
  1040 
  1041 lemma split_paired_Ball_Sigma [simp,no_atp]:
  1042     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1043   by blast
  1044 
  1045 lemma split_paired_Bex_Sigma [simp,no_atp]:
  1046     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1047   by blast
  1048 
  1049 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1050   by blast
  1051 
  1052 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1053   by blast
  1054 
  1055 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1056   by blast
  1057 
  1058 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1059   by blast
  1060 
  1061 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1062   by blast
  1063 
  1064 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1065   by blast
  1066 
  1067 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1068   by blast
  1069 
  1070 text {*
  1071   Non-dependent versions are needed to avoid the need for higher-order
  1072   matching, especially when the rules are re-oriented.
  1073 *}
  1074 
  1075 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1076 by blast
  1077 
  1078 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1079 by blast
  1080 
  1081 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1082 by blast
  1083 
  1084 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1085   by auto
  1086 
  1087 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1088   by (auto intro!: image_eqI)
  1089 
  1090 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1091   by (auto intro!: image_eqI)
  1092 
  1093 lemma insert_times_insert[simp]:
  1094   "insert a A \<times> insert b B =
  1095    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1096 by blast
  1097 
  1098 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1099   by (auto, case_tac "f x", auto)
  1100 
  1101 lemma swap_inj_on:
  1102   "inj_on (\<lambda>(i, j). (j, i)) A"
  1103   by (auto intro!: inj_onI)
  1104 
  1105 lemma swap_product:
  1106   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1107   by (simp add: split_def image_def) blast
  1108 
  1109 lemma image_split_eq_Sigma:
  1110   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1111 proof (safe intro!: imageI vimageI)
  1112   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1113   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1114     using * eq[symmetric] by auto
  1115 qed simp_all
  1116 
  1117 
  1118 subsection {* Inductively defined sets *}
  1119 
  1120 use "Tools/inductive_set.ML"
  1121 setup Inductive_Set.setup
  1122 
  1123 
  1124 subsection {* Legacy theorem bindings and duplicates *}
  1125 
  1126 lemma PairE:
  1127   obtains x y where "p = (x, y)"
  1128   by (fact prod.exhaust)
  1129 
  1130 lemma Pair_inject:
  1131   assumes "(a, b) = (a', b')"
  1132     and "a = a' ==> b = b' ==> R"
  1133   shows R
  1134   using assms by simp
  1135 
  1136 lemmas Pair_eq = prod.inject
  1137 
  1138 lemmas split = split_conv  -- {* for backwards compatibility *}
  1139 
  1140 end