src/Pure/axclass.ML
author wenzelm
Sat Mar 15 18:08:00 2008 +0100 (2008-03-15)
changeset 26279 e8440c90c474
parent 26246 e212c22f35c2
child 26516 1bf210ac0a90
permissions -rw-r--r--
removed obsolete fact_index.ML;
added facts.ML;
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Type classes defined as predicates, associated with a record of
     6 parameters.
     7 *)
     8 
     9 signature AX_CLASS =
    10 sig
    11   val define_class: bstring * class list -> string list ->
    12     ((bstring * attribute list) * term list) list -> theory -> class * theory
    13   val add_classrel: thm -> theory -> theory
    14   val add_arity: thm -> theory -> theory
    15   val prove_classrel: class * class -> tactic -> theory -> theory
    16   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    17   val get_info: theory -> class ->
    18     {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    19   val class_intros: theory -> thm list
    20   val class_of_param: theory -> string -> class option
    21   val cert_classrel: theory -> class * class -> class * class
    22   val read_classrel: theory -> xstring * xstring -> class * class
    23   val axiomatize_class: bstring * class list -> theory -> theory
    24   val axiomatize_class_cmd: bstring * xstring list -> theory -> theory
    25   val axiomatize_classrel: (class * class) list -> theory -> theory
    26   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    27   val axiomatize_arity: arity -> theory -> theory
    28   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    29   val instance_name: string * class -> string
    30   val declare_overloaded: string * typ -> theory -> term * theory
    31   val define_overloaded: string -> string * term -> theory -> thm * theory
    32   val inst_tyco_of: theory -> string * typ -> string option
    33   val unoverload: theory -> thm -> thm
    34   val overload: theory -> thm -> thm
    35   val unoverload_conv: theory -> conv
    36   val overload_conv: theory -> conv
    37   val unoverload_const: theory -> string * typ -> string
    38   val param_of_inst: theory -> string * string -> string
    39   val inst_of_param: theory -> string -> (string * string) option
    40   type cache
    41   val of_sort: theory -> typ * sort -> cache -> thm list * cache  (*exception Sorts.CLASS_ERROR*)
    42   val cache: cache
    43   val introN: string
    44   val axiomsN: string
    45 end;
    46 
    47 structure AxClass: AX_CLASS =
    48 struct
    49 
    50 (** theory data **)
    51 
    52 (* class parameters (canonical order) *)
    53 
    54 type param = string * class;
    55 
    56 fun add_param pp ((x, c): param) params =
    57   (case AList.lookup (op =) params x of
    58     NONE => (x, c) :: params
    59   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    60       " for " ^ Pretty.string_of_sort pp [c] ^
    61       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    62 
    63 fun merge_params _ ([], qs) = qs
    64   | merge_params pp (ps, qs) =
    65       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
    66 
    67 
    68 (* axclasses *)
    69 
    70 val introN = "intro";
    71 val superN = "super";
    72 val axiomsN = "axioms";
    73 
    74 datatype axclass = AxClass of
    75  {def: thm,
    76   intro: thm,
    77   axioms: thm list,
    78   params: (string * typ) list};
    79 
    80 type axclasses = axclass Symtab.table * param list;
    81 
    82 fun make_axclass ((def, intro, axioms), params) =
    83   AxClass {def = def, intro = intro, axioms = axioms, params = params};
    84 
    85 fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
    86   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
    87 
    88 
    89 (* instances *)
    90 
    91 val classrel_prefix = "classrel_";
    92 val arity_prefix = "arity_";
    93 
    94 type instances =
    95   ((class * class) * thm) list *
    96   ((class * sort list) * thm) list Symtab.table;
    97 
    98 fun merge_instances ((classrel1, arities1): instances, (classrel2, arities2)) =
    99  (merge (eq_fst op =) (classrel1, classrel2),
   100   Symtab.join (K (merge (eq_fst op =))) (arities1, arities2));
   101 
   102 
   103 (* instance parameters *)
   104 
   105 type inst_params =
   106   (string * thm) Symtab.table Symtab.table
   107     (*constant name ~> type constructor ~> (constant name, equation)*)
   108   * (string * string) Symtab.table; (*constant name ~> (constant name, type constructor)*)
   109 
   110 fun merge_inst_params ((const_param1, param_const1), (const_param2, param_const2)) =
   111   (Symtab.join  (K (Symtab.merge (K true))) (const_param1, const_param2),
   112     Symtab.merge (K true) (param_const1, param_const2));
   113 
   114 
   115 (* setup data *)
   116 
   117 structure AxClassData = TheoryDataFun
   118 (
   119   type T = axclasses * (instances * inst_params);
   120   val empty = ((Symtab.empty, []), (([], Symtab.empty), (Symtab.empty, Symtab.empty)));
   121   val copy = I;
   122   val extend = I;
   123   fun merge pp ((axclasses1, (instances1, inst_params1)), (axclasses2, (instances2, inst_params2))) =
   124     (merge_axclasses pp (axclasses1, axclasses2),
   125       (merge_instances (instances1, instances2), merge_inst_params (inst_params1, inst_params2)));
   126 );
   127 
   128 
   129 (* maintain axclasses *)
   130 
   131 val get_axclasses = #1 o AxClassData.get;
   132 val map_axclasses = AxClassData.map o apfst;
   133 
   134 val lookup_def = Symtab.lookup o #1 o get_axclasses;
   135 
   136 fun get_info thy c =
   137   (case lookup_def thy c of
   138     SOME (AxClass info) => info
   139   | NONE => error ("No such axclass: " ^ quote c));
   140 
   141 fun class_intros thy =
   142   let
   143     fun add_intro c =
   144       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
   145     val classes = Sign.all_classes thy;
   146   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   147 
   148 
   149 fun get_params thy pred =
   150   let val params = #2 (get_axclasses thy);
   151   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
   152 
   153 fun params_of thy c = get_params thy (fn c' => c' = c);
   154 fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
   155 
   156 fun class_of_param thy = AList.lookup (op =) (#2 (get_axclasses thy));
   157 
   158 
   159 (* maintain instances *)
   160 
   161 fun instance_name (a, c) = NameSpace.base c ^ "_" ^ NameSpace.base a;
   162 
   163 val get_instances = #1 o #2 o AxClassData.get;
   164 val map_instances = AxClassData.map o apsnd o apfst;
   165 
   166 
   167 fun the_classrel thy (c1, c2) =
   168   (case AList.lookup (op =) (#1 (get_instances thy)) (c1, c2) of
   169     SOME th => Thm.transfer thy th
   170   | NONE => error ("Unproven class relation " ^
   171       Syntax.string_of_classrel (ProofContext.init thy) [c1, c2]));
   172 
   173 fun put_classrel arg = map_instances (fn (classrel, arities) =>
   174   (insert (eq_fst op =) arg classrel, arities));
   175 
   176 
   177 fun the_arity thy a (c, Ss) =
   178   (case AList.lookup (op =) (Symtab.lookup_list (#2 (get_instances thy)) a) (c, Ss) of
   179     SOME th => Thm.transfer thy th
   180   | NONE => error ("Unproven type arity " ^
   181       Syntax.string_of_arity (ProofContext.init thy) (a, Ss, [c])));
   182 
   183 fun put_arity ((t, Ss, c), th) = map_instances (fn (classrel, arities) =>
   184   (classrel, arities |> Symtab.insert_list (eq_fst op =) (t, ((c, Ss), th))));
   185 
   186 
   187 (* maintain instance parameters *)
   188 
   189 val get_inst_params = #2 o #2 o AxClassData.get;
   190 val map_inst_params = AxClassData.map o apsnd o apsnd;
   191 
   192 fun get_inst_param thy (c, tyco) =
   193   (the o Symtab.lookup ((the o Symtab.lookup (fst (get_inst_params thy))) c)) tyco;
   194 
   195 fun add_inst_param (c, tyco) inst = (map_inst_params o apfst
   196       o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   197   #> (map_inst_params o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   198 
   199 val inst_of_param = Symtab.lookup o snd o get_inst_params;
   200 val param_of_inst = fst oo get_inst_param;
   201 
   202 fun inst_thms thy = (Symtab.fold (Symtab.fold (cons o snd o snd) o snd) o fst)
   203   (get_inst_params thy) [];
   204 
   205 fun inst_tyco_of thy = try (fst o dest_Type o the_single o Sign.const_typargs thy);
   206 
   207 fun unoverload thy = MetaSimplifier.simplify true (inst_thms thy);
   208 fun overload thy = MetaSimplifier.simplify true (map Thm.symmetric (inst_thms thy));
   209 
   210 fun unoverload_conv thy = MetaSimplifier.rewrite true (inst_thms thy);
   211 fun overload_conv thy = MetaSimplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   212 
   213 fun unoverload_const thy (c_ty as (c, _)) =
   214   case class_of_param thy c
   215    of SOME class => (case inst_tyco_of thy c_ty
   216        of SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   217         | NONE => c)
   218     | NONE => c;
   219 
   220 
   221 (** instances **)
   222 
   223 (* class relations *)
   224 
   225 fun cert_classrel thy raw_rel =
   226   let
   227     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   228     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   229     val _ =
   230       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   231         [] => ()
   232       | xs => raise TYPE ("Class " ^ Sign.string_of_sort thy [c1] ^ " lacks parameter(s) " ^
   233           commas_quote xs ^ " of " ^ Sign.string_of_sort thy [c2], [], []));
   234   in (c1, c2) end;
   235 
   236 fun read_classrel thy raw_rel =
   237   cert_classrel thy (pairself (Sign.read_class thy) raw_rel)
   238     handle TYPE (msg, _, _) => error msg;
   239 
   240 
   241 (* primitive rules *)
   242 
   243 fun add_classrel th thy =
   244   let
   245     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   246     val prop = Thm.plain_prop_of (Thm.transfer thy th);
   247     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   248     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   249   in
   250     thy
   251     |> Sign.primitive_classrel (c1, c2)
   252     |> put_classrel ((c1, c2), Drule.unconstrainTs th)
   253   end;
   254 
   255 fun add_arity th thy =
   256   let
   257     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   258     val prop = Thm.plain_prop_of (Thm.transfer thy th);
   259     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   260     val _ = map (Sign.certify_sort thy) Ss = Ss orelse err ();
   261     (*FIXME turn this into a mere check as soon as "attach" has disappeared*)
   262     val missing_params = Sign.complete_sort thy [c]
   263       |> maps (these o Option.map (fn AxClass { params, ... } => params) o lookup_def thy)
   264       |> filter_out (fn (p, _) => can (get_inst_param thy) (p, t));
   265     fun declare_missing (p, T0) thy =
   266       let
   267         val name_inst = instance_name (t, c) ^ "_inst";
   268         val p' = NameSpace.base p ^ "_" ^ NameSpace.base t;
   269         val vs = Name.names Name.context Name.aT (replicate (Sign.arity_number thy t) []);
   270         val T = map_atyps (fn _ => Type (t, map TFree vs)) T0;
   271       in
   272         thy
   273         |> Sign.sticky_prefix name_inst
   274         |> Sign.no_base_names
   275         |> Sign.declare_const [] (p', T, NoSyn)
   276         |-> (fn const' as Const (p'', _) => Thm.add_def false true
   277               (Thm.def_name p', Logic.mk_equals (const', Const (p, T)))
   278         #>> Thm.varifyT
   279         #-> (fn thm => add_inst_param (p, t) (p'', Thm.symmetric thm)
   280         #> PureThy.note Thm.internalK (p', thm)
   281         #> snd
   282         #> Sign.restore_naming thy))
   283       end;
   284 
   285   in
   286     thy
   287     |> Sign.primitive_arity (t, Ss, [c])
   288     |> put_arity ((t, Ss, c), Drule.unconstrainTs th)
   289     |> fold declare_missing missing_params
   290   end;
   291 
   292 
   293 (* tactical proofs *)
   294 
   295 fun prove_classrel raw_rel tac thy =
   296   let
   297     val ctxt = ProofContext.init thy;
   298     val (c1, c2) = cert_classrel thy raw_rel;
   299     val th = Goal.prove ctxt [] []
   300         (Logic.mk_classrel (c1, c2)) (fn _ => tac) handle ERROR msg =>
   301       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   302         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   303   in
   304     thy
   305     |> PureThy.add_thms [((prefix classrel_prefix (Logic.name_classrel (c1, c2)), th), [])]
   306     |-> (fn [th'] => add_classrel th')
   307   end;
   308 
   309 fun prove_arity raw_arity tac thy =
   310   let
   311     val ctxt = ProofContext.init thy;
   312     val arity = Sign.cert_arity thy raw_arity;
   313     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   314     val props = Logic.mk_arities arity;
   315     val ths = Goal.prove_multi ctxt [] [] props
   316       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   317         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   318           quote (Syntax.string_of_arity ctxt arity));
   319   in
   320     thy
   321     |> PureThy.add_thms (map (rpair []) (names ~~ ths))
   322     |-> fold add_arity
   323   end;
   324 
   325 
   326 (* instance parameters and overloaded definitions *)
   327 
   328 (* declaration and definition of instances of overloaded constants *)
   329 
   330 fun declare_overloaded (c, T) thy =
   331   let
   332     val class = case class_of_param thy c
   333      of SOME class => class
   334       | NONE => error ("Not a class parameter: " ^ quote c);
   335     val tyco = case inst_tyco_of thy (c, T)
   336      of SOME tyco => tyco
   337       | NONE => error ("Illegal type for instantiation of class parameter: "
   338         ^ quote (c ^ " :: " ^ Sign.string_of_typ thy T));
   339     val name_inst = instance_name (tyco, class) ^ "_inst";
   340     val c' = NameSpace.base c ^ "_" ^ NameSpace.base tyco;
   341     val T' = Type.strip_sorts T;
   342   in
   343     thy
   344     |> Sign.sticky_prefix name_inst
   345     |> Sign.no_base_names
   346     |> Sign.declare_const [] (c', T', NoSyn)
   347     |-> (fn const' as Const (c'', _) => Thm.add_def false true
   348           (Thm.def_name c', Logic.mk_equals (Const (c, T'), const'))
   349     #>> Thm.varifyT
   350     #-> (fn thm => add_inst_param (c, tyco) (c'', thm)
   351     #> PureThy.note Thm.internalK (c', thm)
   352     #> snd
   353     #> Sign.restore_naming thy
   354     #> pair (Const (c, T))))
   355   end;
   356 
   357 fun define_overloaded name (c, t) thy =
   358   let
   359     val T = Term.fastype_of t;
   360     val SOME tyco = inst_tyco_of thy (c, T);
   361     val (c', eq) = get_inst_param thy (c, tyco);
   362     val prop = Logic.mk_equals (Const (c', T), t);
   363     val name' = Thm.def_name_optional
   364       (NameSpace.base c ^ "_" ^ NameSpace.base tyco) name;
   365   in
   366     thy
   367     |> Thm.add_def false false (name', prop)
   368     |>> (fn thm =>  Drule.transitive_thm OF [eq, thm])
   369   end;
   370 
   371 
   372 
   373 (** class definitions **)
   374 
   375 fun split_defined n eq =
   376   let
   377     val intro =
   378       (eq RS Drule.equal_elim_rule2)
   379       |> Conjunction.curry_balanced n
   380       |> n = 0 ? Thm.eq_assumption 1;
   381     val dests =
   382       if n = 0 then []
   383       else
   384         (eq RS Drule.equal_elim_rule1)
   385         |> BalancedTree.dest (fn th =>
   386           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   387   in (intro, dests) end;
   388 
   389 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   390   let
   391     val ctxt = ProofContext.init thy;
   392     val pp = Syntax.pp ctxt;
   393 
   394 
   395     (* class *)
   396 
   397     val bconst = Logic.const_of_class bclass;
   398     val class = Sign.full_name thy bclass;
   399     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   400 
   401     fun check_constraint (a, S) =
   402       if Sign.subsort thy (super, S) then ()
   403       else error ("Sort constraint of type variable " ^
   404         setmp show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   405         " needs to be weaker than " ^ Pretty.string_of_sort pp super);
   406 
   407 
   408     (* params *)
   409 
   410     val params = raw_params |> map (fn p =>
   411       let
   412         val T = Sign.the_const_type thy p;
   413         val _ =
   414           (case Term.add_tvarsT T [] of
   415             [((a, _), S)] => check_constraint (a, S)
   416           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   417         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   418       in (p, T') end);
   419 
   420 
   421     (* axioms *)
   422 
   423     fun prep_axiom t =
   424       (case Term.add_tfrees t [] of
   425         [(a, S)] => check_constraint (a, S)
   426       | [] => ()
   427       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t);
   428       t
   429       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   430       |> Logic.close_form);
   431 
   432     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   433     val name_atts = map fst raw_specs;
   434 
   435 
   436     (* definition *)
   437 
   438     val conjs = map (curry Logic.mk_inclass (Term.aT [])) super @ flat axiomss;
   439     val class_eq =
   440       Logic.mk_equals (Logic.mk_inclass (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   441 
   442     val ([def], def_thy) =
   443       thy
   444       |> Sign.primitive_class (bclass, super)
   445       |> PureThy.add_defs_i false [((Thm.def_name bconst, class_eq), [])];
   446     val (raw_intro, (raw_classrel, raw_axioms)) =
   447       split_defined (length conjs) def ||> chop (length super);
   448 
   449 
   450     (* facts *)
   451 
   452     val class_triv = Thm.class_triv def_thy class;
   453     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   454       def_thy
   455       |> PureThy.note_thmss_qualified "" bconst
   456         [((introN, []), [([Drule.standard raw_intro], [])]),
   457          ((superN, []), [(map Drule.standard raw_classrel, [])]),
   458          ((axiomsN, []), [(map (fn th => Drule.standard (class_triv RS th)) raw_axioms, [])])];
   459 
   460 
   461     (* result *)
   462 
   463     val axclass = make_axclass ((def, intro, axioms), params);
   464     val result_thy =
   465       facts_thy
   466       |> fold put_classrel (map (pair class) super ~~ classrel)
   467       |> Sign.add_path bconst
   468       |> PureThy.note_thmss_i "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   469       |> Sign.restore_naming facts_thy
   470       |> map_axclasses (fn (axclasses, parameters) =>
   471         (Symtab.update (class, axclass) axclasses,
   472           fold (fn (x, _) => add_param pp (x, class)) params parameters));
   473 
   474   in (class, result_thy) end;
   475 
   476 
   477 
   478 (** axiomatizations **)
   479 
   480 local
   481 
   482 fun axiomatize prep mk name add raw_args thy =
   483   let
   484     val args = prep thy raw_args;
   485     val specs = mk args;
   486     val names = name args;
   487   in thy |> PureThy.add_axioms_i (map (rpair []) (names ~~ specs)) |-> fold add end;
   488 
   489 fun ax_classrel prep =
   490   axiomatize (map o prep) (map Logic.mk_classrel)
   491     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   492 
   493 fun ax_arity prep =
   494   axiomatize prep Logic.mk_arities
   495     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   496 
   497 fun class_const c =
   498   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   499 
   500 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   501   let
   502     val class = Sign.full_name thy bclass;
   503     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   504   in
   505     thy
   506     |> Sign.primitive_class (bclass, super)
   507     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   508     |> Theory.add_deps "" (class_const class) (map class_const super)
   509   end;
   510 
   511 in
   512 
   513 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   514 val axiomatize_class_cmd = ax_class Sign.read_class read_classrel;
   515 val axiomatize_classrel = ax_classrel cert_classrel;
   516 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   517 val axiomatize_arity = ax_arity Sign.cert_arity;
   518 val axiomatize_arity_cmd = ax_arity Sign.read_arity;
   519 
   520 end;
   521 
   522 
   523 
   524 (** explicit derivations -- cached **)
   525 
   526 datatype cache = Types of (class * thm) list Typtab.table;
   527 
   528 local
   529 
   530 fun lookup_type (Types cache) = AList.lookup (op =) o Typtab.lookup_list cache;
   531 fun insert_type T der (Types cache) = Types (Typtab.insert_list (eq_fst op =) (T, der) cache);
   532 
   533 fun derive_type _ (_, []) = []
   534   | derive_type thy (typ, sort) =
   535       let
   536         val vars = Term.fold_atyps
   537             (fn T as TFree (_, S) => insert (eq_fst op =) (T, S)
   538               | T as TVar (_, S) => insert (eq_fst op =) (T, S)
   539               | _ => I) typ [];
   540         val hyps = vars
   541           |> map (fn (T, S) => (T, Drule.sort_triv thy (T, S) ~~ S));
   542         val ths = (typ, sort) |> Sorts.of_sort_derivation (Sign.pp thy) (Sign.classes_of thy)
   543            {class_relation =
   544               fn (th, c1) => fn c2 => th RS the_classrel thy (c1, c2),
   545             type_constructor =
   546               fn a => fn dom => fn c =>
   547                 let val Ss = map (map snd) dom and ths = maps (map fst) dom
   548                 in ths MRS the_arity thy a (c, Ss) end,
   549             type_variable =
   550               the_default [] o AList.lookup (op =) hyps};
   551       in ths end;
   552 
   553 in
   554 
   555 fun of_sort thy (typ, sort) cache =
   556   let
   557     val sort' = filter (is_none o lookup_type cache typ) sort;
   558     val ths' = derive_type thy (typ, sort')
   559       handle ERROR msg => cat_error msg ("The error(s) above occurred for sort derivation: " ^
   560         Sign.string_of_typ thy typ ^ " :: " ^ Sign.string_of_sort thy sort');
   561     val cache' = cache |> fold (insert_type typ) (sort' ~~ ths');
   562     val ths =
   563       sort |> map (fn c =>
   564         Goal.finish (the (lookup_type cache' typ c) RS
   565           Goal.init (Thm.cterm_of thy (Logic.mk_inclass (typ, c))))
   566         |> Thm.adjust_maxidx_thm ~1);
   567   in (ths, cache') end;
   568 
   569 end;
   570 
   571 val cache = Types Typtab.empty;
   572 
   573 end;