src/Pure/variable.ML
author wenzelm
Sat Mar 15 18:08:00 2008 +0100 (2008-03-15)
changeset 26279 e8440c90c474
parent 25573 a0e695567236
child 26714 4773b832f1b1
permissions -rw-r--r--
removed obsolete fact_index.ML;
added facts.ML;
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Proof.context -> bool
    11   val set_body: bool -> Proof.context -> Proof.context
    12   val restore_body: Proof.context -> Proof.context -> Proof.context
    13   val names_of: Proof.context -> Name.context
    14   val fixes_of: Proof.context -> (string * string) list
    15   val binds_of: Proof.context -> (typ * term) Vartab.table
    16   val maxidx_of: Proof.context -> int
    17   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    18   val is_declared: Proof.context -> string -> bool
    19   val is_fixed: Proof.context -> string -> bool
    20   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    21   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    22   val default_type: Proof.context -> string -> typ option
    23   val def_type: Proof.context -> bool -> indexname -> typ option
    24   val def_sort: Proof.context -> indexname -> sort option
    25   val declare_constraints: term -> Proof.context -> Proof.context
    26   val declare_names: term -> Proof.context -> Proof.context
    27   val declare_internal: term -> Proof.context -> Proof.context
    28   val declare_term: term -> Proof.context -> Proof.context
    29   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    30   val declare_thm: thm -> Proof.context -> Proof.context
    31   val thm_context: thm -> Proof.context
    32   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    33   val add_binds: (indexname * term option) list -> Proof.context -> Proof.context
    34   val expand_binds: Proof.context -> term -> term
    35   val lookup_const: Proof.context -> string -> string option
    36   val is_const: Proof.context -> string -> bool
    37   val declare_const: string * string -> Proof.context -> Proof.context
    38   val add_fixes: string list -> Proof.context -> string list * Proof.context
    39   val add_fixes_direct: string list -> Proof.context -> Proof.context
    40   val auto_fixes: term -> Proof.context -> Proof.context
    41   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    42   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    43   val export_terms: Proof.context -> Proof.context -> term list -> term list
    44   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    45   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    46   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    47   val export: Proof.context -> Proof.context -> thm list -> thm list
    48   val export_morphism: Proof.context -> Proof.context -> morphism
    49   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    50   val import_inst: bool -> term list -> Proof.context ->
    51     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    52   val importT_terms: term list -> Proof.context -> term list * Proof.context
    53   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    54   val importT_thms: thm list -> Proof.context -> (ctyp list * thm list) * Proof.context
    55   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    56   val import_thms: bool -> thm list -> Proof.context ->
    57     ((ctyp list * cterm list) * thm list) * Proof.context
    58   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    59   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    60   val focus: cterm -> Proof.context -> (cterm list * cterm) * Proof.context
    61   val focus_subgoal: int -> thm -> Proof.context -> (cterm list * cterm) * Proof.context
    62   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    63   val polymorphic_types: Proof.context -> term list -> (indexname * sort) list * term list
    64   val polymorphic: Proof.context -> term list -> term list
    65 end;
    66 
    67 structure Variable: VARIABLE =
    68 struct
    69 
    70 (** local context data **)
    71 
    72 datatype data = Data of
    73  {is_body: bool,                        (*inner body mode*)
    74   names: Name.context,                  (*type/term variable names*)
    75   consts: string Symtab.table,          (*consts within the local scope*)
    76   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    77   binds: (typ * term) Vartab.table,     (*term bindings*)
    78   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    79   maxidx: int,                          (*maximum var index*)
    80   constraints:
    81     typ Vartab.table *                  (*type constraints*)
    82     sort Vartab.table};                 (*default sorts*)
    83 
    84 fun make_data (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =
    85   Data {is_body = is_body, names = names, consts = consts, fixes = fixes, binds = binds,
    86     type_occs = type_occs, maxidx = maxidx, constraints = constraints};
    87 
    88 structure Data = ProofDataFun
    89 (
    90   type T = data;
    91   fun init thy =
    92     make_data (false, Name.context, Symtab.empty, [], Vartab.empty, Symtab.empty,
    93       ~1, (Vartab.empty, Vartab.empty));
    94 );
    95 
    96 fun map_data f =
    97   Data.map (fn Data {is_body, names, consts, fixes, binds, type_occs, maxidx, constraints} =>
    98     make_data (f (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints)));
    99 
   100 fun map_names f =
   101   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   102     (is_body, f names, consts, fixes, binds, type_occs, maxidx, constraints));
   103 
   104 fun map_consts f =
   105   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   106     (is_body, names, f consts, fixes, binds, type_occs, maxidx, constraints));
   107 
   108 fun map_fixes f =
   109   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   110     (is_body, names, consts, f fixes, binds, type_occs, maxidx, constraints));
   111 
   112 fun map_binds f =
   113   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   114     (is_body, names, consts, fixes, f binds, type_occs, maxidx, constraints));
   115 
   116 fun map_type_occs f =
   117   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   118     (is_body, names, consts, fixes, binds, f type_occs, maxidx, constraints));
   119 
   120 fun map_maxidx f =
   121   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   122     (is_body, names, consts, fixes, binds, type_occs, f maxidx, constraints));
   123 
   124 fun map_constraints f =
   125   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   126     (is_body, names, consts, fixes, binds, type_occs, maxidx, f constraints));
   127 
   128 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   129 
   130 val is_body = #is_body o rep_data;
   131 
   132 fun set_body b = map_data (fn (_, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   133   (b, names, consts, fixes, binds, type_occs, maxidx, constraints));
   134 
   135 fun restore_body ctxt = set_body (is_body ctxt);
   136 
   137 val names_of = #names o rep_data;
   138 val fixes_of = #fixes o rep_data;
   139 val binds_of = #binds o rep_data;
   140 val type_occs_of = #type_occs o rep_data;
   141 val maxidx_of = #maxidx o rep_data;
   142 val constraints_of = #constraints o rep_data;
   143 
   144 val is_declared = Name.is_declared o names_of;
   145 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   146 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   147 
   148 fun add_fixed ctxt = Term.fold_aterms
   149   (fn Free (x, T) => if is_fixed ctxt x then insert (op =) (x, T) else I | _ => I);
   150 
   151 
   152 
   153 (** declarations **)
   154 
   155 (* default sorts and types *)
   156 
   157 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   158 
   159 fun def_type ctxt pattern xi =
   160   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   161     (case Vartab.lookup types xi of
   162       NONE =>
   163         if pattern then NONE
   164         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   165     | some => some)
   166   end;
   167 
   168 val def_sort = Vartab.lookup o #2 o constraints_of;
   169 
   170 
   171 (* names *)
   172 
   173 fun declare_type_names t =
   174   map_names (fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I)) t) #>
   175   map_maxidx (fold_types Term.maxidx_typ t);
   176 
   177 fun declare_names t =
   178   declare_type_names t #>
   179   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t) #>
   180   map_maxidx (Term.maxidx_term t);
   181 
   182 
   183 (* type occurrences *)
   184 
   185 fun decl_type_occsT T = fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I) T;
   186 
   187 val decl_type_occs = fold_term_types
   188   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   189     | _ => decl_type_occsT);
   190 
   191 val declare_type_occsT = map_type_occs o fold_types decl_type_occsT;
   192 val declare_type_occs = map_type_occs o decl_type_occs;
   193 
   194 
   195 (* constraints *)
   196 
   197 fun constrain_tvar (xi, S) =
   198   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   199 
   200 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   201   let
   202     val types' = fold_aterms
   203       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   204         | Var v => Vartab.update v
   205         | _ => I) t types;
   206     val sorts' = fold_types (fold_atyps
   207       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   208         | TVar v => constrain_tvar v
   209         | _ => I)) t sorts;
   210   in (types', sorts') end)
   211   #> declare_type_occsT t
   212   #> declare_type_names t;
   213 
   214 
   215 (* common declarations *)
   216 
   217 fun declare_internal t =
   218   declare_names t #>
   219   declare_type_occs t;
   220 
   221 fun declare_term t =
   222   declare_internal t #>
   223   declare_constraints t;
   224 
   225 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   226 
   227 val declare_thm = Thm.fold_terms declare_internal;
   228 fun thm_context th = declare_thm th (ProofContext.init (Thm.theory_of_thm th));
   229 
   230 
   231 (* renaming term/type frees *)
   232 
   233 fun variant_frees ctxt ts frees =
   234   let
   235     val names = names_of (fold declare_names ts ctxt);
   236     val xs = fst (Name.variants (map #1 frees) names);
   237   in xs ~~ map snd frees end;
   238 
   239 
   240 
   241 (** term bindings **)
   242 
   243 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   244   | add_bind ((x, i), SOME t) =
   245       let
   246         val u = Term.close_schematic_term t;
   247         val U = Term.fastype_of u;
   248       in declare_term u #> map_binds (Vartab.update ((x, i), (U, u))) end;
   249 
   250 val add_binds = fold add_bind;
   251 
   252 fun expand_binds ctxt =
   253   let
   254     val binds = binds_of ctxt;
   255     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   256   in Envir.beta_norm o Envir.expand_term get end;
   257 
   258 
   259 
   260 (** consts **)
   261 
   262 val lookup_const = Symtab.lookup o #consts o rep_data;
   263 val is_const = is_some oo lookup_const;
   264 
   265 val declare_fixed = map_consts o Symtab.delete_safe;
   266 val declare_const = map_consts o Symtab.update;
   267 
   268 
   269 
   270 (** fixes **)
   271 
   272 local
   273 
   274 fun no_dups [] = ()
   275   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   276 
   277 fun new_fixes names' xs xs' =
   278   map_names (K names') #>
   279   fold declare_fixed xs #>
   280   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   281   fold (declare_constraints o Syntax.free) xs' #>
   282   pair xs';
   283 
   284 in
   285 
   286 fun add_fixes xs ctxt =
   287   let
   288     val _ =
   289       (case filter (can Name.dest_skolem) xs of [] => ()
   290       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   291     val _ = no_dups (duplicates (op =) xs);
   292     val (ys, zs) = split_list (fixes_of ctxt);
   293     val names = names_of ctxt;
   294     val (xs', names') =
   295       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   296       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   297         (xs, fold Name.declare xs names));
   298   in ctxt |> new_fixes names' xs xs' end;
   299 
   300 fun variant_fixes raw_xs ctxt =
   301   let
   302     val names = names_of ctxt;
   303     val xs = map Name.clean raw_xs;
   304     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   305   in ctxt |> new_fixes names' xs xs' end;
   306 
   307 end;
   308 
   309 
   310 fun add_fixes_direct xs ctxt = ctxt
   311   |> set_body false
   312   |> (snd o add_fixes xs)
   313   |> restore_body ctxt;
   314 
   315 fun fix_frees t ctxt = ctxt
   316   |> add_fixes_direct
   317       (rev (fold_aterms (fn Free (x, _) =>
   318         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []));
   319 
   320 fun auto_fixes t ctxt =
   321   (if is_body ctxt then ctxt else fix_frees t ctxt)
   322   |> declare_term t;
   323 
   324 fun invent_types Ss ctxt =
   325   let
   326     val tfrees = Name.invents (names_of ctxt) Name.aT (length Ss) ~~ Ss;
   327     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   328   in (tfrees, ctxt') end;
   329 
   330 
   331 
   332 (** export -- generalize type/term variables (beware of closure sizes) **)
   333 
   334 fun export_inst inner outer =
   335   let
   336     val declared_outer = is_declared outer;
   337     val fixes_inner = fixes_of inner;
   338     val fixes_outer = fixes_of outer;
   339 
   340     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   341     val still_fixed = not o member (op =) gen_fixes;
   342 
   343     val type_occs_inner = type_occs_of inner;
   344     fun gen_fixesT ts =
   345       Symtab.fold (fn (a, xs) =>
   346         if declared_outer a orelse exists still_fixed xs
   347         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   348   in (gen_fixesT, gen_fixes) end;
   349 
   350 fun exportT_inst inner outer = #1 (export_inst inner outer);
   351 
   352 fun exportT_terms inner outer =
   353   let val mk_tfrees = exportT_inst inner outer in
   354     fn ts => ts |> map
   355       (TermSubst.generalize (mk_tfrees ts, [])
   356         (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1))
   357   end;
   358 
   359 fun export_terms inner outer =
   360   let val (mk_tfrees, tfrees) = export_inst inner outer in
   361     fn ts => ts |> map
   362       (TermSubst.generalize (mk_tfrees ts, tfrees)
   363         (fold Term.maxidx_term ts ~1 + 1))
   364   end;
   365 
   366 fun export_prf inner outer prf =
   367   let
   368     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   369     val tfrees = mk_tfrees [];
   370     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   371     val gen_term = TermSubst.generalize_option (tfrees, frees) idx;
   372     val gen_typ = TermSubst.generalizeT_option tfrees idx;
   373   in Proofterm.map_proof_terms_option gen_term gen_typ prf end;
   374 
   375 
   376 fun gen_export (mk_tfrees, frees) ths =
   377   let
   378     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   379     val maxidx = fold Thm.maxidx_thm ths ~1;
   380   in map (Thm.generalize (tfrees, frees) (maxidx + 1)) ths end;
   381 
   382 fun exportT inner outer = gen_export (exportT_inst inner outer, []);
   383 fun export inner outer = gen_export (export_inst inner outer);
   384 
   385 fun export_morphism inner outer =
   386   let
   387     val fact = export inner outer;
   388     val term = singleton (export_terms inner outer);
   389     val typ = Logic.type_map term;
   390   in Morphism.morphism {name = I, var = I, typ = typ, term = term, fact = fact} end;
   391 
   392 
   393 
   394 (** import -- fix schematic type/term variables **)
   395 
   396 fun importT_inst ts ctxt =
   397   let
   398     val tvars = rev (fold Term.add_tvars ts []);
   399     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   400   in (tvars ~~ map TFree tfrees, ctxt') end;
   401 
   402 fun import_inst is_open ts ctxt =
   403   let
   404     val ren = if is_open then I else Name.internal;
   405     val (instT, ctxt') = importT_inst ts ctxt;
   406     val vars = map (apsnd (TermSubst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   407     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   408     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   409   in ((instT, inst), ctxt'') end;
   410 
   411 fun importT_terms ts ctxt =
   412   let val (instT, ctxt') = importT_inst ts ctxt
   413   in (map (TermSubst.instantiate (instT, [])) ts, ctxt') end;
   414 
   415 fun import_terms is_open ts ctxt =
   416   let val (inst, ctxt') = import_inst is_open ts ctxt
   417   in (map (TermSubst.instantiate inst) ts, ctxt') end;
   418 
   419 fun importT_thms ths ctxt =
   420   let
   421     val thy = ProofContext.theory_of ctxt;
   422     val certT = Thm.ctyp_of thy;
   423     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   424     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   425     val ths' = map (Thm.instantiate (instT', [])) ths;
   426   in ((map #2 instT', ths'), ctxt') end;
   427 
   428 fun import_prf is_open prf ctxt =
   429   let
   430     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   431     val (insts, ctxt') = import_inst is_open ts ctxt;
   432   in (Proofterm.instantiate insts prf, ctxt') end;
   433 
   434 fun import_thms is_open ths ctxt =
   435   let
   436     val thy = ProofContext.theory_of ctxt;
   437     val cert = Thm.cterm_of thy;
   438     val certT = Thm.ctyp_of thy;
   439     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   440     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   441     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   442     val ths' = map (Thm.instantiate (instT', inst')) ths;
   443   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   444 
   445 
   446 (* import/export *)
   447 
   448 fun gen_trade imp exp f ctxt ths =
   449   let val ((_, ths'), ctxt') = imp ths ctxt
   450   in exp ctxt' ctxt (f ctxt' ths') end;
   451 
   452 val tradeT = gen_trade importT_thms exportT;
   453 val trade = gen_trade (import_thms true) export;
   454 
   455 
   456 (* focus on outermost parameters *)
   457 
   458 fun forall_elim_prop t prop =
   459   Thm.beta_conversion false (Thm.capply (Thm.dest_arg prop) t)
   460   |> Thm.cprop_of |> Thm.dest_arg;
   461 
   462 fun focus goal ctxt =
   463   let
   464     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   465     val t = Thm.term_of goal;
   466     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   467     val (xs, Ts) = split_list ps;
   468     val (xs', ctxt') = variant_fixes xs ctxt;
   469     val ps' = ListPair.map (cert o Free) (xs', Ts);
   470     val goal' = fold forall_elim_prop ps' goal;
   471   in ((ps', goal'), ctxt') end;
   472 
   473 fun focus_subgoal i st =
   474   let
   475     val all_vars = Thm.fold_terms Term.add_vars st [];
   476     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   477   in
   478     add_binds no_binds #>
   479     fold (declare_constraints o Var) all_vars #>
   480     focus (Thm.cprem_of st i)
   481   end;
   482 
   483 
   484 
   485 (** implicit polymorphism **)
   486 
   487 (* warn_extra_tfrees *)
   488 
   489 fun warn_extra_tfrees ctxt1 ctxt2 =
   490   let
   491     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   492     fun occs_free a x =
   493       (case def_type ctxt1 false (x, ~1) of
   494         SOME T => if occs_typ a T then I else cons (a, x)
   495       | NONE => cons (a, x));
   496 
   497     val occs1 = type_occs_of ctxt1;
   498     val occs2 = type_occs_of ctxt2;
   499     val extras = Symtab.fold (fn (a, xs) =>
   500       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   501     val tfrees = map #1 extras |> sort_distinct string_ord;
   502     val frees = map #2 extras |> sort_distinct string_ord;
   503   in
   504     if null extras then ()
   505     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   506       space_implode " or " (map quote frees))
   507   end;
   508 
   509 
   510 (* polymorphic terms *)
   511 
   512 fun polymorphic_types ctxt ts =
   513   let
   514     val ctxt' = fold declare_term ts ctxt;
   515     val occs = type_occs_of ctxt;
   516     val occs' = type_occs_of ctxt';
   517     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   518     val idx = maxidx_of ctxt' + 1;
   519     val Ts' = (fold o fold_types o fold_atyps)
   520       (fn T as TFree _ =>
   521           (case TermSubst.generalizeT types idx T of TVar v => insert (op =) v | _ => I)
   522         | _ => I) ts [];
   523     val ts' = map (TermSubst.generalize (types, []) idx) ts;
   524   in (rev Ts', ts') end;
   525 
   526 fun polymorphic ctxt ts = snd (polymorphic_types ctxt ts);
   527 
   528 end;