src/Pure/Thy/thy_parse.ML
author wenzelm
Fri Jan 27 13:40:07 1995 +0100 (1995-01-27)
changeset 889 e87c01fd0351
parent 865 b38c67991122
child 1027 651637377289
permissions -rw-r--r--
binder: optional body pri now [bracketted];
     1 (*  Title:      Pure/Thy/thy_parse.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The parser for theory files.
     6 *)
     7 
     8 infix 5 -- --$$ $$-- ^^;
     9 infix 3 >>;
    10 infix 0 ||;
    11 
    12 signature THY_PARSE =
    13 sig
    14   type token
    15   val !! : ('a -> 'b * 'c) -> 'a -> 'b * 'c
    16   val >> : ('a -> 'b * 'c) * ('b -> 'd) -> 'a -> 'd * 'c
    17   val || : ('a -> 'b) * ('a -> 'b) -> 'a -> 'b
    18   val -- : ('a -> 'b * 'c) * ('c -> 'd * 'e) -> 'a -> ('b * 'd) * 'e
    19   val ^^ : ('a -> string * 'b) * ('b -> string * 'c) -> 'a -> string * 'c
    20   val $$ : string -> token list -> string * token list
    21   val $$-- : string * (token list -> 'b * 'c) -> token list -> 'b * 'c
    22   val --$$ : ('a -> 'b * token list) * string -> 'a -> 'b * token list
    23   val ident: token list -> string * token list
    24   val long_ident: token list -> string * token list
    25   val long_id: token list -> string * token list
    26   val type_var: token list -> string * token list
    27   val type_args: token list -> string list * token list
    28   val nat: token list -> string * token list
    29   val string: token list -> string * token list
    30   val verbatim: token list -> string * token list
    31   val empty: 'a -> 'b list * 'a
    32   val optional: ('a -> 'b * 'a) -> 'b -> 'a -> 'b * 'a
    33   val repeat: ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    34   val repeat1: ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    35   val enum: string -> (token list -> 'a * token list)
    36     -> token list -> 'a list * token list
    37   val enum1: string -> (token list -> 'a * token list)
    38     -> token list -> 'a list * token list
    39   val list: (token list -> 'a * token list)
    40     -> token list -> 'a list * token list
    41   val list1: (token list -> 'a * token list)
    42     -> token list -> 'a list * token list
    43   val name: token list -> string * token list
    44   val sort: token list -> string * token list
    45   val opt_infix: token list -> string * token list
    46   val opt_mixfix: token list -> string * token list
    47   val opt_witness: token list -> string * token list
    48   type syntax
    49   val make_syntax: string list ->
    50     (string * (token list -> (string * string) * token list)) list -> syntax
    51   val parse_thy: syntax -> string -> string -> string
    52   val section: string -> string -> (token list -> string * token list)
    53     -> (string * (token list -> (string * string) * token list))
    54   val axm_section: string -> string
    55     -> (token list -> (string * string list) * token list)
    56     -> (string * (token list -> (string * string) * token list))
    57   val pure_keywords: string list
    58   val pure_sections:
    59     (string * (token list -> (string * string) * token list)) list
    60   (*items for building strings*)
    61   val cat: string -> string -> string
    62   val parens: string -> string
    63   val brackets: string -> string
    64   val mk_list: string list -> string
    65   val mk_big_list: string list -> string
    66   val mk_pair: string * string -> string
    67   val mk_triple: string * string * string -> string
    68   val strip_quotes: string -> string
    69 end;
    70 
    71 functor ThyParseFun(structure Symtab: SYMTAB and ThyScan: THY_SCAN): THY_PARSE =
    72 struct
    73 
    74 open ThyScan;
    75 
    76 
    77 (** parser toolbox **)
    78 
    79 type token = token_kind * string * int;
    80 
    81 
    82 (* errors *)
    83 
    84 exception SYNTAX_ERROR of string * string * int;
    85 
    86 fun syn_err s1 s2 n = raise SYNTAX_ERROR (s1, s2, n);
    87 
    88 fun eof_err () = error "Unexpected end-of-file";
    89 
    90 (*Similar to Prolog's cut: reports any syntax error instead of backtracking
    91   through a superior || *)
    92 fun !! parse toks = parse toks
    93   handle SYNTAX_ERROR (s1, s2, n) => error ("Syntax error on line " ^
    94     string_of_int n ^ ": " ^ s1 ^ " expected and " ^ s2 ^ " was found");
    95 
    96 
    97 (* parser combinators *)
    98 
    99 fun (parse >> f) toks = apfst f (parse toks);
   100 
   101 fun (parse1 || parse2) toks =
   102   parse1 toks handle SYNTAX_ERROR _ => parse2 toks;
   103 
   104 fun (parse1 -- parse2) toks =
   105   let
   106     val (x, toks') = parse1 toks;
   107     val (y, toks'') = parse2 toks';
   108   in
   109     ((x, y), toks'')
   110   end;
   111 
   112 fun (parse1 ^^ parse2) = parse1 -- parse2 >> op ^;
   113 
   114 
   115 (* generic parsers *)
   116 
   117 fun $$ a ((k, b, n) :: toks) =
   118       if k = Keyword andalso a = b then (a, toks)
   119       else syn_err (quote a) (quote b) n
   120   | $$ _ [] = eof_err ();
   121 
   122 fun (a $$-- parse) = $$ a -- parse >> #2;
   123 
   124 fun (parse --$$ a) = parse -- $$ a >> #1;
   125 
   126 
   127 fun kind k1 ((k2, s, n) :: toks) =
   128       if k1 = k2 then (s, toks)
   129       else syn_err (name_of_kind k1) (quote s) n
   130   | kind _ [] = eof_err ();
   131 
   132 val ident = kind Ident;
   133 val long_ident = kind LongIdent;
   134 val long_id = ident || long_ident;
   135 val type_var = kind TypeVar >> quote;
   136 val nat = kind Nat;
   137 val string = kind String;
   138 val verbatim = kind Verbatim;
   139 val eof = kind EOF;
   140 
   141 fun empty toks = ([], toks);
   142 
   143 fun optional parse def = parse || empty >> K def;
   144 
   145 fun repeat parse toks = (parse -- repeat parse >> op :: || empty) toks;
   146 fun repeat1 parse = parse -- repeat parse >> op ::;
   147 
   148 fun enum1 sep parse = parse -- repeat (sep $$-- parse) >> op ::;
   149 fun enum sep parse = enum1 sep parse || empty;
   150 
   151 val list = enum ",";
   152 val list1 = enum1 ",";
   153 
   154 
   155 
   156 (** theory parsers **)
   157 
   158 (* misc utilities *)
   159 
   160 fun cat s1 s2 = s1 ^ " " ^ s2;
   161 
   162 val parens = enclose "(" ")";
   163 val brackets = enclose "[" "]";
   164 
   165 val mk_list = brackets o commas;
   166 val mk_big_list = brackets o space_implode ",\n ";
   167 
   168 fun mk_pair (x, y) = parens (commas [x, y]);
   169 fun mk_triple (x, y, z) = parens (commas [x, y, z]);
   170 fun mk_triple1 ((x, y), z) = mk_triple (x, y, z);
   171 fun mk_triple2 (x, (y, z)) = mk_triple (x, y, z);
   172 
   173 val split_decls = flat o map (fn (xs, y) => map (rpair y) xs);
   174 
   175 fun strip_quotes str =
   176   implode (tl (take (size str - 1, explode str)));
   177 
   178 
   179 (* names *)
   180 
   181 val name = ident >> quote || string;
   182 val names = list name;
   183 val names1 = list1 name;
   184 val name_list = names >> mk_list;
   185 val name_list1 = names1 >> mk_list;
   186 
   187 
   188 (* classes *)
   189 
   190 val subclass = name -- optional ("<" $$-- !! name_list1) "[]";
   191 
   192 val class_decls = repeat1 (subclass >> mk_pair) >> mk_big_list;
   193 
   194 
   195 (* arities *)
   196 
   197 val sort =
   198   name >> brackets ||
   199   "{" $$-- name_list --$$ "}";
   200 
   201 val sort_list1 = list1 sort >> mk_list;
   202 
   203 
   204 val arity = optional ("(" $$-- !! (sort_list1 --$$")")) "[]" -- sort;
   205 
   206 val arity_decls = repeat1 (names1 --$$ "::" -- !! arity)
   207   >> (mk_big_list o map mk_triple2 o split_decls);
   208 
   209 
   210 (* mixfix annotations *)
   211 
   212 val infxl = "infixl" $$-- !! nat >> cat "Infixl";
   213 val infxr = "infixr" $$-- !! nat >> cat "Infixr";
   214 
   215 val binder = "binder" $$--
   216   !! (string -- optional ("[" $$-- nat --$$ "]") "0" -- nat)
   217   >> (cat "Binder" o mk_triple1);
   218 
   219 val opt_pris = optional ("[" $$-- !! (list nat --$$ "]")) [] >> mk_list;
   220 
   221 val mixfix = string -- !! (opt_pris -- optional nat "max_pri")
   222   >> (cat "Mixfix" o mk_triple2);
   223 
   224 fun opt_syn fx = optional ("(" $$-- fx --$$ ")") "NoSyn";
   225 
   226 val opt_infix = opt_syn (infxl || infxr);
   227 val opt_mixfix = opt_syn (mixfix || infxl || infxr || binder);
   228 
   229 
   230 (* types *)
   231 
   232 fun mk_old_type_decl ((ts, n), syn) =
   233   map (fn t => (mk_triple (t, n, syn), false)) ts;
   234 
   235 fun mk_type_decl (((xs, t), None), syn) =
   236       [(mk_triple (t, string_of_int (length xs), syn), false)]
   237   | mk_type_decl (((xs, t), Some rhs), syn) =
   238       [(parens (commas [t, mk_list xs, rhs, syn]), true)];
   239 
   240 fun mk_type_decls tys =
   241   "|> add_types\n" ^ mk_big_list (keyfilter tys false) ^ "\n\n\
   242   \|> add_tyabbrs\n" ^ mk_big_list (keyfilter tys true);
   243 
   244 
   245 val old_type_decl = names1 -- nat -- opt_infix >> mk_old_type_decl;
   246 
   247 val type_args =
   248   type_var >> (fn x => [x]) ||
   249   "(" $$-- !! (list1 type_var --$$ ")") ||
   250   empty >> K [];
   251 
   252 val type_decl = type_args -- name -- optional ("=" $$-- !! string >> Some) None
   253   -- opt_infix >> mk_type_decl;
   254 
   255 val type_decls = repeat1 (old_type_decl || type_decl) >> (mk_type_decls o flat);
   256 
   257 
   258 (* consts *)
   259 
   260 val const_decls = repeat1 (names1 --$$ "::" -- !! (string -- opt_mixfix))
   261   >> (mk_big_list o map mk_triple2 o split_decls);
   262 
   263 
   264 (* translations *)
   265 
   266 val trans_pat =
   267   optional ("(" $$-- !! (name --$$ ")")) "\"logic\"" -- string >> mk_pair;
   268 
   269 val trans_arrow =
   270   $$ "=>" >> K " |-> " ||
   271   $$ "<=" >> K " <-| " ||
   272   $$ "==" >> K " <-> ";
   273 
   274 val trans_decls = repeat1 (trans_pat ^^ !! (trans_arrow ^^ trans_pat))
   275   >> mk_big_list;
   276 
   277 
   278 (* ML translations *)
   279 
   280 val trfun_defs =
   281   " val parse_ast_translation = [];\n\
   282   \ val parse_translation = [];\n\
   283   \ val print_translation = [];\n\
   284   \ val print_ast_translation = [];";
   285 
   286 val trfun_args =
   287   "(parse_ast_translation, parse_translation, \
   288   \print_translation, print_ast_translation)";
   289 
   290 fun mk_mltrans txt =
   291   "let\n"
   292   ^ trfun_defs ^ "\n"
   293   ^ txt ^ "\n\
   294   \in\n\
   295   \ " ^ trfun_args ^ "\n\
   296   \end";
   297 
   298 val mltrans = verbatim >> mk_mltrans;
   299 
   300 
   301 (* axioms *)
   302 
   303 val mk_axms = mk_big_list o map (mk_pair o apfst quote);
   304 
   305 fun mk_axiom_decls axms = (mk_axms axms, map fst axms);
   306 
   307 val axiom_decls = repeat1 (ident -- !! string) >> mk_axiom_decls;
   308 
   309 
   310 (* axclass *)
   311 
   312 fun mk_axclass_decl ((c, cs), axms) =
   313   (mk_pair (c, cs) ^ "\n" ^ mk_axms axms,
   314     (strip_quotes c ^ "I") :: map fst axms);
   315 
   316 val axclass_decl = subclass -- repeat (ident -- !! string) >> mk_axclass_decl;
   317 
   318 
   319 (* instance *)
   320 
   321 fun mk_witness (axths, opt_tac) =
   322   mk_list (keyfilter axths false) ^ "\n" ^
   323   mk_list (keyfilter axths true) ^ "\n" ^
   324   opt_tac;
   325 
   326 val axm_or_thm =
   327   string >> rpair false ||
   328   long_id >> rpair true;
   329 
   330 
   331 val opt_witness =
   332   optional ("(" $$-- list1 axm_or_thm --$$ ")") [] --
   333   optional (verbatim >> (parens o cat "Some" o parens)) "None"
   334   >> mk_witness;
   335 
   336 val instance_decl =
   337   (name --$$ "<" -- name >> (pair "|> AxClass.add_inst_subclass" o mk_pair) ||
   338     name --$$ "::" -- arity >> (pair "|> AxClass.add_inst_arity" o mk_triple2))
   339   -- opt_witness
   340   >> (fn ((x, y), z) => (cat_lines [x, y, z]));
   341 
   342 
   343 
   344 (** theory syntax **)
   345 
   346 type syntax =
   347   lexicon * (token list -> (string * string) * token list) Symtab.table;
   348 
   349 fun make_syntax keywords sects =
   350   (make_lexicon (map fst sects @ keywords),
   351     Symtab.make sects handle Symtab.DUPS dups =>
   352       error ("Duplicate sections in theory file syntax: " ^ commas_quote dups));
   353 
   354 
   355 (* header *)
   356 
   357 fun mk_header (thy_name, bases) =
   358   (thy_name, "mk_base " ^ mk_list bases ^ " " ^ quote thy_name);
   359 
   360 val base =
   361   ident >> (cat "Thy" o quote) ||
   362   string >> cat "File";
   363 
   364 val header = ident --$$ "=" -- enum1 "+" base >> mk_header;
   365 
   366 
   367 (* extension *)
   368 
   369 fun mk_extension (txts, mltxt) =
   370   let
   371     val cat_sects = space_implode "\n\n" o filter_out (equal "");
   372     val (extxts, postxts) = split_list txts;
   373   in
   374     (cat_sects extxts, cat_sects postxts, mltxt)
   375   end;
   376 
   377 fun sect tab ((Keyword, s, n) :: toks) =
   378       (case Symtab.lookup (tab, s) of
   379         Some parse => !! parse toks
   380       | None => syn_err "section" s n)
   381   | sect _ ((_, s, n) :: _) = syn_err "section" s n
   382   | sect _ [] = eof_err ();
   383 
   384 fun extension sectab = "+" $$-- !! (repeat (sect sectab) --$$ "end") --
   385   optional ("ML" $$-- verbatim) "" >> mk_extension;
   386 
   387 
   388 (* theory definition *)
   389 
   390 fun mk_structure tname ((thy_name, old_thys), opt_txts) =
   391   if thy_name <> tname then
   392     error ("Filename \"" ^ tname ^ ".thy\" and theory name "
   393       ^ quote thy_name ^ " are different")
   394   else
   395     (case opt_txts of
   396       Some (extxt, postxt, mltxt) =>
   397         "val thy = " ^ old_thys ^ " true;\n\n\
   398         \structure " ^ thy_name ^ " =\n\
   399         \struct\n\
   400         \\n\
   401         \local\n"
   402         ^ trfun_defs ^ "\n\
   403         \in\n\
   404         \\n"
   405         ^ mltxt ^ "\n\
   406         \\n\
   407         \val thy = thy\n\
   408         \\n\
   409         \|> add_trfuns\n"
   410         ^ trfun_args ^ "\n\
   411         \\n"
   412         ^ extxt ^ "\n\
   413         \\n\
   414         \|> add_thyname " ^ quote thy_name ^ ";\n\
   415         \\n\
   416         \val () = store_theory (thy, " ^ quote thy_name ^ ");\n\
   417         \\n\
   418         \\n"
   419         ^ postxt ^ "\n\
   420         \\n\
   421         \end;\n\
   422         \end;\n"
   423     | None =>
   424         "val thy = " ^ old_thys ^ " false;\n\
   425         \\n\
   426         \structure " ^ thy_name ^ " =\n\
   427         \struct\n\
   428         \\n\
   429         \val thy = thy\n\
   430         \\n\
   431         \val () = store_theory (thy, " ^ quote thy_name ^ ");\n\
   432         \\n\
   433         \end;\n");
   434 
   435 fun theory_defn sectab tname =
   436   header -- optional (extension sectab >> Some) None -- eof
   437   >> (mk_structure tname o #1);
   438 
   439 fun parse_thy (lex, sectab) tname str =
   440   #1 (!! (theory_defn sectab tname) (tokenize lex str));
   441 
   442 
   443 (* standard sections *)
   444 
   445 fun mk_val ax = "val " ^ ax ^ " = get_axiom thy " ^ quote ax ^ ";";
   446 val mk_vals = cat_lines o map mk_val;
   447 
   448 fun mk_axm_sect "" (txt, axs) = (txt, mk_vals axs)
   449   | mk_axm_sect pretxt (txt, axs) = (pretxt ^ "\n" ^ txt, mk_vals axs);
   450 
   451 fun axm_section name pretxt parse =
   452   (name, parse >> mk_axm_sect pretxt);
   453 
   454 fun section name pretxt parse =
   455   axm_section name pretxt (parse >> rpair []);
   456 
   457 
   458 val pure_keywords =
   459  ["end", "ML", "mixfix", "infixr", "infixl", "binder", "=", "+", ",", "<",
   460   "{", "}", "(", ")", "[", "]", "::", "==", "=>", "<="];
   461 
   462 val pure_sections =
   463  [section "classes" "|> add_classes" class_decls,
   464   section "default" "|> add_defsort" sort,
   465   section "types" "" type_decls,
   466   section "arities" "|> add_arities" arity_decls,
   467   section "consts" "|> add_consts" const_decls,
   468   section "syntax" "|> add_syntax" const_decls,
   469   section "translations" "|> add_trrules" trans_decls,
   470   section "MLtrans" "|> add_trfuns" mltrans,
   471   section "MLtext" "" verbatim,
   472   axm_section "rules" "|> add_axioms" axiom_decls,
   473   axm_section "defs" "|> add_defs" axiom_decls,
   474   axm_section "axclass" "|> AxClass.add_axclass" axclass_decl,
   475   section "instance" "" instance_decl];
   476 
   477 
   478 end;