src/HOL/Power.thy
author wenzelm
Mon Dec 28 21:47:32 2015 +0100 (2015-12-28)
changeset 61955 e96292f32c3c
parent 61944 5d06ecfdb472
child 62083 7582b39f51ed
permissions -rw-r--r--
former "xsymbols" syntax is used by default, and ASCII replacement syntax with print mode "ASCII";
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 section \<open>Exponentiation\<close>
     7 
     8 theory Power
     9 imports Num Equiv_Relations
    10 begin
    11 
    12 context linordered_ring (* TODO: move *)
    13 begin
    14 
    15 lemma sum_squares_ge_zero:
    16   "0 \<le> x * x + y * y"
    17   by (intro add_nonneg_nonneg zero_le_square)
    18 
    19 lemma not_sum_squares_lt_zero:
    20   "\<not> x * x + y * y < 0"
    21   by (simp add: not_less sum_squares_ge_zero)
    22 
    23 end
    24 
    25 subsection \<open>Powers for Arbitrary Monoids\<close>
    26 
    27 class power = one + times
    28 begin
    29 
    30 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a"  (infixr "^" 80)
    31 where
    32   power_0: "a ^ 0 = 1"
    33 | power_Suc: "a ^ Suc n = a * a ^ n"
    34 
    35 notation (latex output)
    36   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    37 
    38 text \<open>Special syntax for squares.\<close>
    39 abbreviation power2 :: "'a \<Rightarrow> 'a"  ("(_\<^sup>2)" [1000] 999)
    40   where "x\<^sup>2 \<equiv> x ^ 2"
    41 
    42 end
    43 
    44 context monoid_mult
    45 begin
    46 
    47 subclass power .
    48 
    49 lemma power_one [simp]:
    50   "1 ^ n = 1"
    51   by (induct n) simp_all
    52 
    53 lemma power_one_right [simp]:
    54   "a ^ 1 = a"
    55   by simp
    56 
    57 lemma power_Suc0_right [simp]:
    58   "a ^ Suc 0 = a"
    59   by simp
    60 
    61 lemma power_commutes:
    62   "a ^ n * a = a * a ^ n"
    63   by (induct n) (simp_all add: mult.assoc)
    64 
    65 lemma power_Suc2:
    66   "a ^ Suc n = a ^ n * a"
    67   by (simp add: power_commutes)
    68 
    69 lemma power_add:
    70   "a ^ (m + n) = a ^ m * a ^ n"
    71   by (induct m) (simp_all add: algebra_simps)
    72 
    73 lemma power_mult:
    74   "a ^ (m * n) = (a ^ m) ^ n"
    75   by (induct n) (simp_all add: power_add)
    76 
    77 lemma power2_eq_square: "a\<^sup>2 = a * a"
    78   by (simp add: numeral_2_eq_2)
    79 
    80 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    81   by (simp add: numeral_3_eq_3 mult.assoc)
    82 
    83 lemma power_even_eq:
    84   "a ^ (2 * n) = (a ^ n)\<^sup>2"
    85   by (subst mult.commute) (simp add: power_mult)
    86 
    87 lemma power_odd_eq:
    88   "a ^ Suc (2*n) = a * (a ^ n)\<^sup>2"
    89   by (simp add: power_even_eq)
    90 
    91 lemma power_numeral_even:
    92   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    93   unfolding numeral_Bit0 power_add Let_def ..
    94 
    95 lemma power_numeral_odd:
    96   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
    97   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
    98   unfolding power_Suc power_add Let_def mult.assoc ..
    99 
   100 lemma funpow_times_power:
   101   "(times x ^^ f x) = times (x ^ f x)"
   102 proof (induct "f x" arbitrary: f)
   103   case 0 then show ?case by (simp add: fun_eq_iff)
   104 next
   105   case (Suc n)
   106   def g \<equiv> "\<lambda>x. f x - 1"
   107   with Suc have "n = g x" by simp
   108   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
   109   moreover from Suc g_def have "f x = g x + 1" by simp
   110   ultimately show ?case by (simp add: power_add funpow_add fun_eq_iff mult.assoc)
   111 qed
   112 
   113 lemma power_commuting_commutes:
   114   assumes "x * y = y * x"
   115   shows "x ^ n * y = y * x ^n"
   116 proof (induct n)
   117   case (Suc n)
   118   have "x ^ Suc n * y = x ^ n * y * x"
   119     by (subst power_Suc2) (simp add: assms ac_simps)
   120   also have "\<dots> = y * x ^ Suc n"
   121     unfolding Suc power_Suc2
   122     by (simp add: ac_simps)
   123   finally show ?case .
   124 qed simp
   125 
   126 end
   127 
   128 context comm_monoid_mult
   129 begin
   130 
   131 lemma power_mult_distrib [field_simps]:
   132   "(a * b) ^ n = (a ^ n) * (b ^ n)"
   133   by (induct n) (simp_all add: ac_simps)
   134 
   135 end
   136 
   137 text\<open>Extract constant factors from powers\<close>
   138 declare power_mult_distrib [where a = "numeral w" for w, simp]
   139 declare power_mult_distrib [where b = "numeral w" for w, simp]
   140 
   141 lemma power_add_numeral [simp]:
   142   fixes a :: "'a :: monoid_mult"
   143   shows "a^numeral m * a^numeral n = a^numeral (m + n)"
   144   by (simp add: power_add [symmetric])
   145 
   146 lemma power_add_numeral2 [simp]:
   147   fixes a :: "'a :: monoid_mult"
   148   shows "a^numeral m * (a^numeral n * b) = a^numeral (m + n) * b"
   149   by (simp add: mult.assoc [symmetric])
   150 
   151 lemma power_mult_numeral [simp]:
   152   fixes a :: "'a :: monoid_mult"
   153   shows"(a^numeral m)^numeral n = a^numeral (m * n)"
   154   by (simp only: numeral_mult power_mult)
   155 
   156 context semiring_numeral
   157 begin
   158 
   159 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   160   by (simp only: sqr_conv_mult numeral_mult)
   161 
   162 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   163   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   164     numeral_sqr numeral_mult power_add power_one_right)
   165 
   166 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   167   by (rule numeral_pow [symmetric])
   168 
   169 end
   170 
   171 context semiring_1
   172 begin
   173 
   174 lemma of_nat_power [simp]:
   175   "of_nat (m ^ n) = of_nat m ^ n"
   176   by (induct n) (simp_all add: of_nat_mult)
   177 
   178 lemma zero_power:
   179   "0 < n \<Longrightarrow> 0 ^ n = 0"
   180   by (cases n) simp_all
   181 
   182 lemma power_zero_numeral [simp]:
   183   "0 ^ numeral k = 0"
   184   by (simp add: numeral_eq_Suc)
   185 
   186 lemma zero_power2: "0\<^sup>2 = 0" (* delete? *)
   187   by (rule power_zero_numeral)
   188 
   189 lemma one_power2: "1\<^sup>2 = 1" (* delete? *)
   190   by (rule power_one)
   191 
   192 lemma power_0_Suc [simp]:
   193   "0 ^ Suc n = 0"
   194   by simp
   195 
   196 text\<open>It looks plausible as a simprule, but its effect can be strange.\<close>
   197 lemma power_0_left:
   198   "0 ^ n = (if n = 0 then 1 else 0)"
   199   by (cases n) simp_all
   200 
   201 end
   202 
   203 context comm_semiring_1
   204 begin
   205 
   206 text \<open>The divides relation\<close>
   207 
   208 lemma le_imp_power_dvd:
   209   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   210 proof
   211   have "a ^ n = a ^ (m + (n - m))"
   212     using \<open>m \<le> n\<close> by simp
   213   also have "\<dots> = a ^ m * a ^ (n - m)"
   214     by (rule power_add)
   215   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   216 qed
   217 
   218 lemma power_le_dvd:
   219   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   220   by (rule dvd_trans [OF le_imp_power_dvd])
   221 
   222 lemma dvd_power_same:
   223   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   224   by (induct n) (auto simp add: mult_dvd_mono)
   225 
   226 lemma dvd_power_le:
   227   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   228   by (rule power_le_dvd [OF dvd_power_same])
   229 
   230 lemma dvd_power [simp]:
   231   assumes "n > (0::nat) \<or> x = 1"
   232   shows "x dvd (x ^ n)"
   233 using assms proof
   234   assume "0 < n"
   235   then have "x ^ n = x ^ Suc (n - 1)" by simp
   236   then show "x dvd (x ^ n)" by simp
   237 next
   238   assume "x = 1"
   239   then show "x dvd (x ^ n)" by simp
   240 qed
   241 
   242 end
   243 
   244 class semiring_1_no_zero_divisors = semiring_1 + semiring_no_zero_divisors
   245 begin
   246 
   247 subclass power .
   248 
   249 lemma power_eq_0_iff [simp]:
   250   "a ^ n = 0 \<longleftrightarrow> a = 0 \<and> n > 0"
   251   by (induct n) auto
   252 
   253 lemma power_not_zero:
   254   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   255   by (induct n) auto
   256 
   257 lemma zero_eq_power2 [simp]:
   258   "a\<^sup>2 = 0 \<longleftrightarrow> a = 0"
   259   unfolding power2_eq_square by simp
   260 
   261 end
   262 
   263 context semidom
   264 begin
   265 
   266 subclass semiring_1_no_zero_divisors ..
   267 
   268 end
   269 
   270 context ring_1
   271 begin
   272 
   273 lemma power_minus:
   274   "(- a) ^ n = (- 1) ^ n * a ^ n"
   275 proof (induct n)
   276   case 0 show ?case by simp
   277 next
   278   case (Suc n) then show ?case
   279     by (simp del: power_Suc add: power_Suc2 mult.assoc)
   280 qed
   281 
   282 lemma power_minus': "NO_MATCH 1 x \<Longrightarrow> (-x) ^ n = (-1)^n * x ^ n"
   283   by (rule power_minus)
   284 
   285 lemma power_minus_Bit0:
   286   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   287   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   288     power_one_right mult_minus_left mult_minus_right minus_minus)
   289 
   290 lemma power_minus_Bit1:
   291   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   292   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   293 
   294 lemma power2_minus [simp]:
   295   "(- a)\<^sup>2 = a\<^sup>2"
   296   by (fact power_minus_Bit0)
   297 
   298 lemma power_minus1_even [simp]:
   299   "(- 1) ^ (2*n) = 1"
   300 proof (induct n)
   301   case 0 show ?case by simp
   302 next
   303   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   304 qed
   305 
   306 lemma power_minus1_odd:
   307   "(- 1) ^ Suc (2*n) = -1"
   308   by simp
   309 
   310 lemma power_minus_even [simp]:
   311   "(-a) ^ (2*n) = a ^ (2*n)"
   312   by (simp add: power_minus [of a])
   313 
   314 end
   315 
   316 context ring_1_no_zero_divisors
   317 begin
   318 
   319 subclass semiring_1_no_zero_divisors ..
   320 
   321 lemma power2_eq_1_iff:
   322   "a\<^sup>2 = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   323   using square_eq_1_iff [of a] by (simp add: power2_eq_square)
   324 
   325 end
   326 
   327 context idom
   328 begin
   329 
   330 lemma power2_eq_iff: "x\<^sup>2 = y\<^sup>2 \<longleftrightarrow> x = y \<or> x = - y"
   331   unfolding power2_eq_square by (rule square_eq_iff)
   332 
   333 end
   334 
   335 context algebraic_semidom
   336 begin
   337 
   338 lemma div_power:
   339   assumes "b dvd a"
   340   shows "(a div b) ^ n = a ^ n div b ^ n"
   341   using assms by (induct n) (simp_all add: div_mult_div_if_dvd dvd_power_same)
   342 
   343 end
   344 
   345 context normalization_semidom
   346 begin
   347 
   348 lemma normalize_power:
   349   "normalize (a ^ n) = normalize a ^ n"
   350   by (induct n) (simp_all add: normalize_mult)
   351 
   352 lemma unit_factor_power:
   353   "unit_factor (a ^ n) = unit_factor a ^ n"
   354   by (induct n) (simp_all add: unit_factor_mult)
   355 
   356 end
   357 
   358 context division_ring
   359 begin
   360 
   361 text\<open>Perhaps these should be simprules.\<close>
   362 lemma power_inverse [field_simps, divide_simps]:
   363   "inverse a ^ n = inverse (a ^ n)"
   364 proof (cases "a = 0")
   365   case True then show ?thesis by (simp add: power_0_left)
   366 next
   367   case False then have "inverse (a ^ n) = inverse a ^ n"
   368     by (induct n) (simp_all add: nonzero_inverse_mult_distrib power_commutes)
   369   then show ?thesis by simp
   370 qed
   371 
   372 lemma power_one_over [field_simps, divide_simps]:
   373   "(1 / a) ^ n = 1 / a ^ n"
   374   using power_inverse [of a] by (simp add: divide_inverse)
   375 
   376 end
   377 
   378 context field
   379 begin
   380 
   381 lemma power_diff:
   382   assumes nz: "a \<noteq> 0"
   383   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   384   by (induct m n rule: diff_induct) (simp_all add: nz power_not_zero)
   385 
   386 lemma power_divide [field_simps, divide_simps]:
   387   "(a / b) ^ n = a ^ n / b ^ n"
   388   by (induct n) simp_all
   389 
   390 end
   391 
   392 
   393 subsection \<open>Exponentiation on ordered types\<close>
   394 
   395 context linordered_semidom
   396 begin
   397 
   398 lemma zero_less_power [simp]:
   399   "0 < a \<Longrightarrow> 0 < a ^ n"
   400   by (induct n) simp_all
   401 
   402 lemma zero_le_power [simp]:
   403   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   404   by (induct n) simp_all
   405 
   406 lemma power_mono:
   407   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   408   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   409 
   410 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   411   using power_mono [of 1 a n] by simp
   412 
   413 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
   414   using power_mono [of a 1 n] by simp
   415 
   416 lemma power_gt1_lemma:
   417   assumes gt1: "1 < a"
   418   shows "1 < a * a ^ n"
   419 proof -
   420   from gt1 have "0 \<le> a"
   421     by (fact order_trans [OF zero_le_one less_imp_le])
   422   have "1 * 1 < a * 1" using gt1 by simp
   423   also have "\<dots> \<le> a * a ^ n" using gt1
   424     by (simp only: mult_mono \<open>0 \<le> a\<close> one_le_power order_less_imp_le
   425         zero_le_one order_refl)
   426   finally show ?thesis by simp
   427 qed
   428 
   429 lemma power_gt1:
   430   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   431   by (simp add: power_gt1_lemma)
   432 
   433 lemma one_less_power [simp]:
   434   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   435   by (cases n) (simp_all add: power_gt1_lemma)
   436 
   437 lemma power_le_imp_le_exp:
   438   assumes gt1: "1 < a"
   439   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   440 proof (induct m arbitrary: n)
   441   case 0
   442   show ?case by simp
   443 next
   444   case (Suc m)
   445   show ?case
   446   proof (cases n)
   447     case 0
   448     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   449     with gt1 show ?thesis
   450       by (force simp only: power_gt1_lemma
   451           not_less [symmetric])
   452   next
   453     case (Suc n)
   454     with Suc.prems Suc.hyps show ?thesis
   455       by (force dest: mult_left_le_imp_le
   456           simp add: less_trans [OF zero_less_one gt1])
   457   qed
   458 qed
   459 
   460 lemma of_nat_zero_less_power_iff [simp]:
   461   "of_nat x ^ n > 0 \<longleftrightarrow> x > 0 \<or> n = 0"
   462   by (induct n) auto
   463 
   464 text\<open>Surely we can strengthen this? It holds for \<open>0<a<1\<close> too.\<close>
   465 lemma power_inject_exp [simp]:
   466   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   467   by (force simp add: order_antisym power_le_imp_le_exp)
   468 
   469 text\<open>Can relax the first premise to @{term "0<a"} in the case of the
   470 natural numbers.\<close>
   471 lemma power_less_imp_less_exp:
   472   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   473   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   474     power_le_imp_le_exp)
   475 
   476 lemma power_strict_mono [rule_format]:
   477   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   478   by (induct n)
   479    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   480 
   481 text\<open>Lemma for \<open>power_strict_decreasing\<close>\<close>
   482 lemma power_Suc_less:
   483   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   484   by (induct n)
   485     (auto simp add: mult_strict_left_mono)
   486 
   487 lemma power_strict_decreasing [rule_format]:
   488   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   489 proof (induct N)
   490   case 0 then show ?case by simp
   491 next
   492   case (Suc N) then show ?case
   493   apply (auto simp add: power_Suc_less less_Suc_eq)
   494   apply (subgoal_tac "a * a^N < 1 * a^n")
   495   apply simp
   496   apply (rule mult_strict_mono) apply auto
   497   done
   498 qed
   499 
   500 text\<open>Proof resembles that of \<open>power_strict_decreasing\<close>\<close>
   501 lemma power_decreasing [rule_format]:
   502   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   503 proof (induct N)
   504   case 0 then show ?case by simp
   505 next
   506   case (Suc N) then show ?case
   507   apply (auto simp add: le_Suc_eq)
   508   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   509   apply (rule mult_mono) apply auto
   510   done
   511 qed
   512 
   513 lemma power_Suc_less_one:
   514   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   515   using power_strict_decreasing [of 0 "Suc n" a] by simp
   516 
   517 text\<open>Proof again resembles that of \<open>power_strict_decreasing\<close>\<close>
   518 lemma power_increasing [rule_format]:
   519   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   520 proof (induct N)
   521   case 0 then show ?case by simp
   522 next
   523   case (Suc N) then show ?case
   524   apply (auto simp add: le_Suc_eq)
   525   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   526   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   527   done
   528 qed
   529 
   530 text\<open>Lemma for \<open>power_strict_increasing\<close>\<close>
   531 lemma power_less_power_Suc:
   532   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   533   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   534 
   535 lemma power_strict_increasing [rule_format]:
   536   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   537 proof (induct N)
   538   case 0 then show ?case by simp
   539 next
   540   case (Suc N) then show ?case
   541   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   542   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   543   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   544   done
   545 qed
   546 
   547 lemma power_increasing_iff [simp]:
   548   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   549   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   550 
   551 lemma power_strict_increasing_iff [simp]:
   552   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   553 by (blast intro: power_less_imp_less_exp power_strict_increasing)
   554 
   555 lemma power_le_imp_le_base:
   556   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   557     and ynonneg: "0 \<le> b"
   558   shows "a \<le> b"
   559 proof (rule ccontr)
   560   assume "~ a \<le> b"
   561   then have "b < a" by (simp only: linorder_not_le)
   562   then have "b ^ Suc n < a ^ Suc n"
   563     by (simp only: assms power_strict_mono)
   564   from le and this show False
   565     by (simp add: linorder_not_less [symmetric])
   566 qed
   567 
   568 lemma power_less_imp_less_base:
   569   assumes less: "a ^ n < b ^ n"
   570   assumes nonneg: "0 \<le> b"
   571   shows "a < b"
   572 proof (rule contrapos_pp [OF less])
   573   assume "~ a < b"
   574   hence "b \<le> a" by (simp only: linorder_not_less)
   575   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   576   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   577 qed
   578 
   579 lemma power_inject_base:
   580   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   581 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   582 
   583 lemma power_eq_imp_eq_base:
   584   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   585   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   586 
   587 lemma power2_le_imp_le:
   588   "x\<^sup>2 \<le> y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   589   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   590 
   591 lemma power2_less_imp_less:
   592   "x\<^sup>2 < y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   593   by (rule power_less_imp_less_base)
   594 
   595 lemma power2_eq_imp_eq:
   596   "x\<^sup>2 = y\<^sup>2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   597   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   598 
   599 end
   600 
   601 context linordered_ring_strict
   602 begin
   603 
   604 lemma sum_squares_eq_zero_iff:
   605   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   606   by (simp add: add_nonneg_eq_0_iff)
   607 
   608 lemma sum_squares_le_zero_iff:
   609   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   610   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   611 
   612 lemma sum_squares_gt_zero_iff:
   613   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   614   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   615 
   616 end
   617 
   618 context linordered_idom
   619 begin
   620 
   621 lemma power_abs: "\<bar>a ^ n\<bar> = \<bar>a\<bar> ^ n"
   622   by (induct n) (auto simp add: abs_mult)
   623 
   624 lemma abs_power_minus [simp]: "\<bar>(-a) ^ n\<bar> = \<bar>a ^ n\<bar>"
   625   by (simp add: power_abs)
   626 
   627 lemma zero_less_power_abs_iff [simp]: "0 < \<bar>a\<bar> ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   628 proof (induct n)
   629   case 0 show ?case by simp
   630 next
   631   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   632 qed
   633 
   634 lemma zero_le_power_abs [simp]: "0 \<le> \<bar>a\<bar> ^ n"
   635   by (rule zero_le_power [OF abs_ge_zero])
   636 
   637 lemma zero_le_power2 [simp]:
   638   "0 \<le> a\<^sup>2"
   639   by (simp add: power2_eq_square)
   640 
   641 lemma zero_less_power2 [simp]:
   642   "0 < a\<^sup>2 \<longleftrightarrow> a \<noteq> 0"
   643   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   644 
   645 lemma power2_less_0 [simp]:
   646   "\<not> a\<^sup>2 < 0"
   647   by (force simp add: power2_eq_square mult_less_0_iff)
   648 
   649 lemma power2_less_eq_zero_iff [simp]:
   650   "a\<^sup>2 \<le> 0 \<longleftrightarrow> a = 0"
   651   by (simp add: le_less)
   652 
   653 lemma abs_power2 [simp]: "\<bar>a\<^sup>2\<bar> = a\<^sup>2"
   654   by (simp add: power2_eq_square abs_mult abs_mult_self)
   655 
   656 lemma power2_abs [simp]: "\<bar>a\<bar>\<^sup>2 = a\<^sup>2"
   657   by (simp add: power2_eq_square abs_mult_self)
   658 
   659 lemma odd_power_less_zero:
   660   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   661 proof (induct n)
   662   case 0
   663   then show ?case by simp
   664 next
   665   case (Suc n)
   666   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   667     by (simp add: ac_simps power_add power2_eq_square)
   668   thus ?case
   669     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   670 qed
   671 
   672 lemma odd_0_le_power_imp_0_le:
   673   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   674   using odd_power_less_zero [of a n]
   675     by (force simp add: linorder_not_less [symmetric])
   676 
   677 lemma zero_le_even_power'[simp]:
   678   "0 \<le> a ^ (2*n)"
   679 proof (induct n)
   680   case 0
   681     show ?case by simp
   682 next
   683   case (Suc n)
   684     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)"
   685       by (simp add: ac_simps power_add power2_eq_square)
   686     thus ?case
   687       by (simp add: Suc zero_le_mult_iff)
   688 qed
   689 
   690 lemma sum_power2_ge_zero:
   691   "0 \<le> x\<^sup>2 + y\<^sup>2"
   692   by (intro add_nonneg_nonneg zero_le_power2)
   693 
   694 lemma not_sum_power2_lt_zero:
   695   "\<not> x\<^sup>2 + y\<^sup>2 < 0"
   696   unfolding not_less by (rule sum_power2_ge_zero)
   697 
   698 lemma sum_power2_eq_zero_iff:
   699   "x\<^sup>2 + y\<^sup>2 = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   700   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   701 
   702 lemma sum_power2_le_zero_iff:
   703   "x\<^sup>2 + y\<^sup>2 \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   704   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   705 
   706 lemma sum_power2_gt_zero_iff:
   707   "0 < x\<^sup>2 + y\<^sup>2 \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   708   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   709 
   710 lemma abs_le_square_iff:
   711    "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> x\<^sup>2 \<le> y\<^sup>2"
   712 proof
   713   assume "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   714   then have "\<bar>x\<bar>\<^sup>2 \<le> \<bar>y\<bar>\<^sup>2" by (rule power_mono, simp)
   715   then show "x\<^sup>2 \<le> y\<^sup>2" by simp
   716 next
   717   assume "x\<^sup>2 \<le> y\<^sup>2"
   718   then show "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   719     by (auto intro!: power2_le_imp_le [OF _ abs_ge_zero])
   720 qed
   721 
   722 lemma abs_square_le_1:"x\<^sup>2 \<le> 1 \<longleftrightarrow> \<bar>x\<bar> \<le> 1"
   723   using abs_le_square_iff [of x 1]
   724   by simp
   725 
   726 lemma abs_square_eq_1: "x\<^sup>2 = 1 \<longleftrightarrow> \<bar>x\<bar> = 1"
   727   by (auto simp add: abs_if power2_eq_1_iff)
   728 
   729 lemma abs_square_less_1: "x\<^sup>2 < 1 \<longleftrightarrow> \<bar>x\<bar> < 1"
   730   using  abs_square_eq_1 [of x] abs_square_le_1 [of x]
   731   by (auto simp add: le_less)
   732 
   733 end
   734 
   735 
   736 subsection \<open>Miscellaneous rules\<close>
   737 
   738 lemma (in linordered_semidom) self_le_power:
   739   "1 \<le> a \<Longrightarrow> 0 < n \<Longrightarrow> a \<le> a ^ n"
   740   using power_increasing [of 1 n a] power_one_right [of a] by auto
   741 
   742 lemma (in power) power_eq_if:
   743   "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   744   unfolding One_nat_def by (cases m) simp_all
   745 
   746 lemma (in comm_semiring_1) power2_sum:
   747   "(x + y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 + 2 * x * y"
   748   by (simp add: algebra_simps power2_eq_square mult_2_right)
   749 
   750 lemma (in comm_ring_1) power2_diff:
   751   "(x - y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 - 2 * x * y"
   752   by (simp add: algebra_simps power2_eq_square mult_2_right)
   753 
   754 lemma (in comm_ring_1) power2_commute:
   755   "(x - y)\<^sup>2 = (y - x)\<^sup>2"
   756   by (simp add: algebra_simps power2_eq_square)
   757 
   758 
   759 text \<open>Simprules for comparisons where common factors can be cancelled.\<close>
   760 
   761 lemmas zero_compare_simps =
   762     add_strict_increasing add_strict_increasing2 add_increasing
   763     zero_le_mult_iff zero_le_divide_iff
   764     zero_less_mult_iff zero_less_divide_iff
   765     mult_le_0_iff divide_le_0_iff
   766     mult_less_0_iff divide_less_0_iff
   767     zero_le_power2 power2_less_0
   768 
   769 
   770 subsection \<open>Exponentiation for the Natural Numbers\<close>
   771 
   772 lemma nat_one_le_power [simp]:
   773   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   774   by (rule one_le_power [of i n, unfolded One_nat_def])
   775 
   776 lemma nat_zero_less_power_iff [simp]:
   777   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   778   by (induct n) auto
   779 
   780 lemma nat_power_eq_Suc_0_iff [simp]:
   781   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   782   by (induct m) auto
   783 
   784 lemma power_Suc_0 [simp]:
   785   "Suc 0 ^ n = Suc 0"
   786   by simp
   787 
   788 text\<open>Valid for the naturals, but what if \<open>0<i<1\<close>?
   789 Premises cannot be weakened: consider the case where @{term "i=0"},
   790 @{term "m=1"} and @{term "n=0"}.\<close>
   791 lemma nat_power_less_imp_less:
   792   assumes nonneg: "0 < (i::nat)"
   793   assumes less: "i ^ m < i ^ n"
   794   shows "m < n"
   795 proof (cases "i = 1")
   796   case True with less power_one [where 'a = nat] show ?thesis by simp
   797 next
   798   case False with nonneg have "1 < i" by auto
   799   from power_strict_increasing_iff [OF this] less show ?thesis ..
   800 qed
   801 
   802 lemma power_dvd_imp_le:
   803   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   804   apply (rule power_le_imp_le_exp, assumption)
   805   apply (erule dvd_imp_le, simp)
   806   done
   807 
   808 lemma power2_nat_le_eq_le:
   809   fixes m n :: nat
   810   shows "m\<^sup>2 \<le> n\<^sup>2 \<longleftrightarrow> m \<le> n"
   811   by (auto intro: power2_le_imp_le power_mono)
   812 
   813 lemma power2_nat_le_imp_le:
   814   fixes m n :: nat
   815   assumes "m\<^sup>2 \<le> n"
   816   shows "m \<le> n"
   817 proof (cases m)
   818   case 0 then show ?thesis by simp
   819 next
   820   case (Suc k)
   821   show ?thesis
   822   proof (rule ccontr)
   823     assume "\<not> m \<le> n"
   824     then have "n < m" by simp
   825     with assms Suc show False
   826       by (simp add: power2_eq_square)
   827   qed
   828 qed
   829 
   830 subsubsection \<open>Cardinality of the Powerset\<close>
   831 
   832 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
   833   unfolding UNIV_bool by simp
   834 
   835 lemma card_Pow: "finite A \<Longrightarrow> card (Pow A) = 2 ^ card A"
   836 proof (induct rule: finite_induct)
   837   case empty
   838     show ?case by auto
   839 next
   840   case (insert x A)
   841   then have "inj_on (insert x) (Pow A)"
   842     unfolding inj_on_def by (blast elim!: equalityE)
   843   then have "card (Pow A) + card (insert x ` Pow A) = 2 * 2 ^ card A"
   844     by (simp add: mult_2 card_image Pow_insert insert.hyps)
   845   then show ?case using insert
   846     apply (simp add: Pow_insert)
   847     apply (subst card_Un_disjoint, auto)
   848     done
   849 qed
   850 
   851 
   852 subsubsection \<open>Generalized sum over a set\<close>
   853 
   854 lemma setsum_zero_power [simp]:
   855   fixes c :: "nat \<Rightarrow> 'a::division_ring"
   856   shows "(\<Sum>i\<in>A. c i * 0^i) = (if finite A \<and> 0 \<in> A then c 0 else 0)"
   857 apply (cases "finite A")
   858   by (induction A rule: finite_induct) auto
   859 
   860 lemma setsum_zero_power' [simp]:
   861   fixes c :: "nat \<Rightarrow> 'a::field"
   862   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
   863   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
   864   by auto
   865 
   866 
   867 subsubsection \<open>Generalized product over a set\<close>
   868 
   869 lemma setprod_constant: "finite A ==> (\<Prod>x\<in> A. (y::'a::{comm_monoid_mult})) = y^(card A)"
   870 apply (erule finite_induct)
   871 apply auto
   872 done
   873 
   874 lemma setprod_power_distrib:
   875   fixes f :: "'a \<Rightarrow> 'b::comm_semiring_1"
   876   shows "setprod f A ^ n = setprod (\<lambda>x. (f x) ^ n) A"
   877 proof (cases "finite A")
   878   case True then show ?thesis
   879     by (induct A rule: finite_induct) (auto simp add: power_mult_distrib)
   880 next
   881   case False then show ?thesis
   882     by simp
   883 qed
   884 
   885 lemma power_setsum:
   886   "c ^ (\<Sum>a\<in>A. f a) = (\<Prod>a\<in>A. c ^ f a)"
   887   by (induct A rule: infinite_finite_induct) (simp_all add: power_add)
   888 
   889 lemma setprod_gen_delta:
   890   assumes fS: "finite S"
   891   shows "setprod (\<lambda>k. if k=a then b k else c) S = (if a \<in> S then (b a ::'a::comm_monoid_mult) * c^ (card S - 1) else c^ card S)"
   892 proof-
   893   let ?f = "(\<lambda>k. if k=a then b k else c)"
   894   {assume a: "a \<notin> S"
   895     hence "\<forall> k\<in> S. ?f k = c" by simp
   896     hence ?thesis  using a setprod_constant[OF fS, of c] by simp }
   897   moreover
   898   {assume a: "a \<in> S"
   899     let ?A = "S - {a}"
   900     let ?B = "{a}"
   901     have eq: "S = ?A \<union> ?B" using a by blast
   902     have dj: "?A \<inter> ?B = {}" by simp
   903     from fS have fAB: "finite ?A" "finite ?B" by auto
   904     have fA0:"setprod ?f ?A = setprod (\<lambda>i. c) ?A"
   905       apply (rule setprod.cong) by auto
   906     have cA: "card ?A = card S - 1" using fS a by auto
   907     have fA1: "setprod ?f ?A = c ^ card ?A"  unfolding fA0 apply (rule setprod_constant) using fS by auto
   908     have "setprod ?f ?A * setprod ?f ?B = setprod ?f S"
   909       using setprod.union_disjoint[OF fAB dj, of ?f, unfolded eq[symmetric]]
   910       by simp
   911     then have ?thesis using a cA
   912       by (simp add: fA1 field_simps cong add: setprod.cong cong del: if_weak_cong)}
   913   ultimately show ?thesis by blast
   914 qed
   915 
   916 subsection \<open>Code generator tweak\<close>
   917 
   918 code_identifier
   919   code_module Power \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
   920 
   921 end