src/HOL/Library/FuncSet.thy
author hoelzl
Wed Oct 07 17:11:16 2015 +0200 (2015-10-07)
changeset 61359 e985b52c3eb3
parent 59425 c5e79df8cc21
child 61378 3e04c9ca001a
permissions -rw-r--r--
cleanup projective limit of probability distributions; proved Ionescu-Tulcea; used it to prove infinite prob. distribution
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     4 
     5 section \<open>Pi and Function Sets\<close>
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition Pi :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
    12   where "Pi A B = {f. \<forall>x. x \<in> A \<longrightarrow> f x \<in> B x}"
    13 
    14 definition extensional :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) set"
    15   where "extensional A = {f. \<forall>x. x \<notin> A \<longrightarrow> f x = undefined}"
    16 
    17 definition "restrict" :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
    18   where "restrict f A = (\<lambda>x. if x \<in> A then f x else undefined)"
    19 
    20 abbreviation funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  (infixr "->" 60)
    21   where "A -> B \<equiv> Pi A (\<lambda>_. B)"
    22 
    23 notation (xsymbols)
    24   funcset  (infixr "\<rightarrow>" 60)
    25 
    26 syntax
    27   "_Pi"  :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PI _:_./ _)" 10)
    28   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    29 syntax (xsymbols)
    30   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    31   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    32 syntax (HTML output)
    33   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    34   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    35 translations
    36   "\<Pi> x\<in>A. B" \<rightleftharpoons> "CONST Pi A (\<lambda>x. B)"
    37   "\<lambda>x\<in>A. f" \<rightleftharpoons> "CONST restrict (\<lambda>x. f) A"
    38 
    39 definition "compose" :: "'a set \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'c)"
    40   where "compose A g f = (\<lambda>x\<in>A. g (f x))"
    41 
    42 
    43 subsection \<open>Basic Properties of @{term Pi}\<close>
    44 
    45 lemma Pi_I[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    46   by (simp add: Pi_def)
    47 
    48 lemma Pi_I'[simp]: "(\<And>x. x \<in> A \<longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    49   by (simp add:Pi_def)
    50 
    51 lemma funcsetI: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> f \<in> A \<rightarrow> B"
    52   by (simp add: Pi_def)
    53 
    54 lemma Pi_mem: "f \<in> Pi A B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B x"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    58   unfolding Pi_def by auto
    59 
    60 lemma PiE [elim]: "f \<in> Pi A B \<Longrightarrow> (f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> Q) \<Longrightarrow> Q"
    61   by (auto simp: Pi_def)
    62 
    63 lemma Pi_cong: "(\<And>w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    64   by (auto simp: Pi_def)
    65 
    66 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    67   by auto
    68 
    69 lemma funcset_mem: "f \<in> A \<rightarrow> B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B"
    70   by (simp add: Pi_def)
    71 
    72 lemma funcset_image: "f \<in> A \<rightarrow> B \<Longrightarrow> f ` A \<subseteq> B"
    73   by auto
    74 
    75 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    76   by auto
    77 
    78 lemma Pi_eq_empty[simp]: "(\<Pi> x \<in> A. B x) = {} \<longleftrightarrow> (\<exists>x\<in>A. B x = {})"
    79   apply (simp add: Pi_def)
    80   apply auto
    81   txt \<open>Converse direction requires Axiom of Choice to exhibit a function
    82   picking an element from each non-empty @{term "B x"}\<close>
    83   apply (drule_tac x = "\<lambda>u. SOME y. y \<in> B u" in spec)
    84   apply auto
    85   apply (cut_tac P = "\<lambda>y. y \<in> B x" in some_eq_ex)
    86   apply auto
    87   done
    88 
    89 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    90   by (simp add: Pi_def)
    91 
    92 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
    93   by auto
    94 
    95 lemma Pi_UN:
    96   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
    97   assumes "finite I"
    98     and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
    99   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
   100 proof (intro set_eqI iffI)
   101   fix f
   102   assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
   103   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i"
   104     by auto
   105   from bchoice[OF this] obtain n where n: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> (A (n i) i)"
   106     by auto
   107   obtain k where k: "\<And>i. i \<in> I \<Longrightarrow> n i \<le> k"
   108     using \<open>finite I\<close> finite_nat_set_iff_bounded_le[of "n`I"] by auto
   109   have "f \<in> Pi I (A k)"
   110   proof (intro Pi_I)
   111     fix i
   112     assume "i \<in> I"
   113     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   114     show "f i \<in> A k i" by auto
   115   qed
   116   then show "f \<in> (\<Union>n. Pi I (A n))"
   117     by auto
   118 qed auto
   119 
   120 lemma Pi_UNIV [simp]: "A \<rightarrow> UNIV = UNIV"
   121   by (simp add: Pi_def)
   122 
   123 text \<open>Covariance of Pi-sets in their second argument\<close>
   124 lemma Pi_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi A B \<subseteq> Pi A C"
   125   by auto
   126 
   127 text \<open>Contravariance of Pi-sets in their first argument\<close>
   128 lemma Pi_anti_mono: "A' \<subseteq> A \<Longrightarrow> Pi A B \<subseteq> Pi A' B"
   129   by auto
   130 
   131 lemma prod_final:
   132   assumes 1: "fst \<circ> f \<in> Pi A B"
   133     and 2: "snd \<circ> f \<in> Pi A C"
   134   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   135 proof (rule Pi_I)
   136   fix z
   137   assume z: "z \<in> A"
   138   have "f z = (fst (f z), snd (f z))"
   139     by simp
   140   also have "\<dots> \<in> B z \<times> C z"
   141     by (metis SigmaI PiE o_apply 1 2 z)
   142   finally show "f z \<in> B z \<times> C z" .
   143 qed
   144 
   145 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   146   by (auto simp: Pi_def)
   147 
   148 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   149   by (auto simp: Pi_def)
   150 
   151 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   152   by (auto simp: Pi_def)
   153 
   154 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   155   by (auto simp: Pi_def)
   156 
   157 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   158   apply auto
   159   apply (drule_tac x=x in Pi_mem)
   160   apply (simp_all split: split_if_asm)
   161   apply (drule_tac x=i in Pi_mem)
   162   apply (auto dest!: Pi_mem)
   163   done
   164 
   165 
   166 subsection \<open>Composition With a Restricted Domain: @{term compose}\<close>
   167 
   168 lemma funcset_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> g \<in> B \<rightarrow> C \<Longrightarrow> compose A g f \<in> A \<rightarrow> C"
   169   by (simp add: Pi_def compose_def restrict_def)
   170 
   171 lemma compose_assoc:
   172   assumes "f \<in> A \<rightarrow> B"
   173     and "g \<in> B \<rightarrow> C"
   174     and "h \<in> C \<rightarrow> D"
   175   shows "compose A h (compose A g f) = compose A (compose B h g) f"
   176   using assms by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   177 
   178 lemma compose_eq: "x \<in> A \<Longrightarrow> compose A g f x = g (f x)"
   179   by (simp add: compose_def restrict_def)
   180 
   181 lemma surj_compose: "f ` A = B \<Longrightarrow> g ` B = C \<Longrightarrow> compose A g f ` A = C"
   182   by (auto simp add: image_def compose_eq)
   183 
   184 
   185 subsection \<open>Bounded Abstraction: @{term restrict}\<close>
   186 
   187 lemma restrict_cong: "I = J \<Longrightarrow> (\<And>i. i \<in> J =simp=> f i = g i) \<Longrightarrow> restrict f I = restrict g J"
   188   by (auto simp: restrict_def fun_eq_iff simp_implies_def)
   189 
   190 lemma restrict_in_funcset: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> A \<rightarrow> B"
   191   by (simp add: Pi_def restrict_def)
   192 
   193 lemma restrictI[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   194   by (simp add: Pi_def restrict_def)
   195 
   196 lemma restrict_apply[simp]: "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   197   by (simp add: restrict_def)
   198 
   199 lemma restrict_apply': "x \<in> A \<Longrightarrow> (\<lambda>y\<in>A. f y) x = f x"
   200   by simp
   201 
   202 lemma restrict_ext: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   203   by (simp add: fun_eq_iff Pi_def restrict_def)
   204 
   205 lemma restrict_UNIV: "restrict f UNIV = f"
   206   by (simp add: restrict_def)
   207 
   208 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   209   by (simp add: inj_on_def restrict_def)
   210 
   211 lemma Id_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> f \<in> extensional A \<Longrightarrow> compose A (\<lambda>y\<in>B. y) f = f"
   212   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   213 
   214 lemma compose_Id: "g \<in> A \<rightarrow> B \<Longrightarrow> g \<in> extensional A \<Longrightarrow> compose A g (\<lambda>x\<in>A. x) = g"
   215   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   216 
   217 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   218   by (auto simp add: restrict_def)
   219 
   220 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
   221   unfolding restrict_def by (simp add: fun_eq_iff)
   222 
   223 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   224   by (auto simp: restrict_def)
   225 
   226 lemma restrict_upd[simp]: "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   227   by (auto simp: fun_eq_iff)
   228 
   229 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
   230   by (auto simp: restrict_def Pi_def)
   231 
   232 
   233 subsection \<open>Bijections Between Sets\<close>
   234 
   235 text \<open>The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   236 the theorems belong here, or need at least @{term Hilbert_Choice}.\<close>
   237 
   238 lemma bij_betwI:
   239   assumes "f \<in> A \<rightarrow> B"
   240     and "g \<in> B \<rightarrow> A"
   241     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x"
   242     and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   243   shows "bij_betw f A B"
   244   unfolding bij_betw_def
   245 proof
   246   show "inj_on f A"
   247     by (metis g_f inj_on_def)
   248   have "f ` A \<subseteq> B"
   249     using \<open>f \<in> A \<rightarrow> B\<close> by auto
   250   moreover
   251   have "B \<subseteq> f ` A"
   252     by auto (metis Pi_mem \<open>g \<in> B \<rightarrow> A\<close> f_g image_iff)
   253   ultimately show "f ` A = B"
   254     by blast
   255 qed
   256 
   257 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   258   by (auto simp add: bij_betw_def)
   259 
   260 lemma inj_on_compose: "bij_betw f A B \<Longrightarrow> inj_on g B \<Longrightarrow> inj_on (compose A g f) A"
   261   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   262 
   263 lemma bij_betw_compose: "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (compose A g f) A C"
   264   apply (simp add: bij_betw_def compose_eq inj_on_compose)
   265   apply (auto simp add: compose_def image_def)
   266   done
   267 
   268 lemma bij_betw_restrict_eq [simp]: "bij_betw (restrict f A) A B = bij_betw f A B"
   269   by (simp add: bij_betw_def)
   270 
   271 
   272 subsection \<open>Extensionality\<close>
   273 
   274 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
   275   unfolding extensional_def by auto
   276 
   277 lemma extensional_arb: "f \<in> extensional A \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = undefined"
   278   by (simp add: extensional_def)
   279 
   280 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   281   by (simp add: restrict_def extensional_def)
   282 
   283 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   284   by (simp add: compose_def)
   285 
   286 lemma extensionalityI:
   287   assumes "f \<in> extensional A"
   288     and "g \<in> extensional A"
   289     and "\<And>x. x \<in> A \<Longrightarrow> f x = g x"
   290   shows "f = g"
   291   using assms by (force simp add: fun_eq_iff extensional_def)
   292 
   293 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   294   by (rule extensionalityI[OF restrict_extensional]) auto
   295 
   296 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
   297   unfolding extensional_def by auto
   298 
   299 lemma inv_into_funcset: "f ` A = B \<Longrightarrow> (\<lambda>x\<in>B. inv_into A f x) \<in> B \<rightarrow> A"
   300   by (unfold inv_into_def) (fast intro: someI2)
   301 
   302 lemma compose_inv_into_id: "bij_betw f A B \<Longrightarrow> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   303   apply (simp add: bij_betw_def compose_def)
   304   apply (rule restrict_ext, auto)
   305   done
   306 
   307 lemma compose_id_inv_into: "f ` A = B \<Longrightarrow> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   308   apply (simp add: compose_def)
   309   apply (rule restrict_ext)
   310   apply (simp add: f_inv_into_f)
   311   done
   312 
   313 lemma extensional_insert[intro, simp]:
   314   assumes "a \<in> extensional (insert i I)"
   315   shows "a(i := b) \<in> extensional (insert i I)"
   316   using assms unfolding extensional_def by auto
   317 
   318 lemma extensional_Int[simp]: "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
   319   unfolding extensional_def by auto
   320 
   321 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
   322   by (auto simp: extensional_def)
   323 
   324 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
   325   unfolding restrict_def extensional_def by auto
   326 
   327 lemma extensional_insert_undefined[intro, simp]:
   328   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
   329   unfolding extensional_def by auto
   330 
   331 lemma extensional_insert_cancel[intro, simp]:
   332   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
   333   unfolding extensional_def by auto
   334 
   335 
   336 subsection \<open>Cardinality\<close>
   337 
   338 lemma card_inj: "f \<in> A \<rightarrow> B \<Longrightarrow> inj_on f A \<Longrightarrow> finite B \<Longrightarrow> card A \<le> card B"
   339   by (rule card_inj_on_le) auto
   340 
   341 lemma card_bij:
   342   assumes "f \<in> A \<rightarrow> B" "inj_on f A"
   343     and "g \<in> B \<rightarrow> A" "inj_on g B"
   344     and "finite A" "finite B"
   345   shows "card A = card B"
   346   using assms by (blast intro: card_inj order_antisym)
   347 
   348 
   349 subsection \<open>Extensional Function Spaces\<close>
   350 
   351 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
   352   where "PiE S T = Pi S T \<inter> extensional S"
   353 
   354 abbreviation "Pi\<^sub>E A B \<equiv> PiE A B"
   355 
   356 syntax
   357   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PIE _:_./ _)" 10)
   358 syntax (xsymbols)
   359   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   360 syntax (HTML output)
   361   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   362 translations "\<Pi>\<^sub>E x\<in>A. B" \<rightleftharpoons> "CONST Pi\<^sub>E A (\<lambda>x. B)"
   363 
   364 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "->\<^sub>E" 60)
   365   where "A ->\<^sub>E B \<equiv> (\<Pi>\<^sub>E i\<in>A. B)"
   366 
   367 notation (xsymbols)
   368   extensional_funcset  (infixr "\<rightarrow>\<^sub>E" 60)
   369 
   370 lemma extensional_funcset_def: "extensional_funcset S T = (S \<rightarrow> T) \<inter> extensional S"
   371   by (simp add: PiE_def)
   372 
   373 lemma PiE_empty_domain[simp]: "PiE {} T = {\<lambda>x. undefined}"
   374   unfolding PiE_def by simp
   375 
   376 lemma PiE_UNIV_domain: "PiE UNIV T = Pi UNIV T"
   377   unfolding PiE_def by simp
   378 
   379 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (\<Pi>\<^sub>E i\<in>I. F i) = {}"
   380   unfolding PiE_def by auto
   381 
   382 lemma PiE_eq_empty_iff: "Pi\<^sub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   383 proof
   384   assume "Pi\<^sub>E I F = {}"
   385   show "\<exists>i\<in>I. F i = {}"
   386   proof (rule ccontr)
   387     assume "\<not> ?thesis"
   388     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)"
   389       by auto
   390     from choice[OF this]
   391     obtain f where " \<forall>x. (x \<in> I \<longrightarrow> f x \<in> F x) \<and> (x \<notin> I \<longrightarrow> f x = undefined)" ..
   392     then have "f \<in> Pi\<^sub>E I F"
   393       by (auto simp: extensional_def PiE_def)
   394     with \<open>Pi\<^sub>E I F = {}\<close> show False
   395       by auto
   396   qed
   397 qed (auto simp: PiE_def)
   398 
   399 lemma PiE_arb: "f \<in> PiE S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
   400   unfolding PiE_def by auto (auto dest!: extensional_arb)
   401 
   402 lemma PiE_mem: "f \<in> PiE S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
   403   unfolding PiE_def by auto
   404 
   405 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> PiE S T \<Longrightarrow> f(x := y) \<in> PiE (insert x S) T"
   406   unfolding PiE_def extensional_def by auto
   407 
   408 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> PiE (insert x S) T \<Longrightarrow> f(x := undefined) \<in> PiE S T"
   409   unfolding PiE_def extensional_def by auto
   410 
   411 lemma PiE_insert_eq: "PiE (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   412 proof -
   413   {
   414     fix f assume "f \<in> PiE (insert x S) T" "x \<notin> S"
   415     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   416       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
   417   }
   418   moreover
   419   {
   420     fix f assume "f \<in> PiE (insert x S) T" "x \<in> S"
   421     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   422       by (auto intro!: image_eqI[where x="(f x, f)"] intro: fun_upd_in_PiE PiE_mem simp: insert_absorb)
   423   }
   424   ultimately show ?thesis
   425     using assms by (auto intro: PiE_fun_upd)
   426 qed
   427 
   428 lemma PiE_Int: "Pi\<^sub>E I A \<inter> Pi\<^sub>E I B = Pi\<^sub>E I (\<lambda>x. A x \<inter> B x)"
   429   by (auto simp: PiE_def)
   430 
   431 lemma PiE_cong: "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^sub>E I A = Pi\<^sub>E I B"
   432   unfolding PiE_def by (auto simp: Pi_cong)
   433 
   434 lemma PiE_E [elim]:
   435   assumes "f \<in> PiE A B"
   436   obtains "x \<in> A" and "f x \<in> B x"
   437     | "x \<notin> A" and "f x = undefined"
   438   using assms by (auto simp: Pi_def PiE_def extensional_def)
   439 
   440 lemma PiE_I[intro!]:
   441   "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> PiE A B"
   442   by (simp add: PiE_def extensional_def)
   443 
   444 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> PiE A B \<subseteq> PiE A C"
   445   by auto
   446 
   447 lemma PiE_iff: "f \<in> PiE I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
   448   by (simp add: PiE_def Pi_iff)
   449 
   450 lemma PiE_restrict[simp]:  "f \<in> PiE A B \<Longrightarrow> restrict f A = f"
   451   by (simp add: extensional_restrict PiE_def)
   452 
   453 lemma restrict_PiE[simp]: "restrict f I \<in> PiE I S \<longleftrightarrow> f \<in> Pi I S"
   454   by (auto simp: PiE_iff)
   455 
   456 lemma PiE_eq_subset:
   457   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   458     and eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   459     and "i \<in> I"
   460   shows "F i \<subseteq> F' i"
   461 proof
   462   fix x
   463   assume "x \<in> F i"
   464   with ne have "\<forall>j. \<exists>y. (j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined)"
   465     by auto
   466   from choice[OF this] obtain f
   467     where f: " \<forall>j. (j \<in> I \<longrightarrow> f j \<in> F j \<and> (i = j \<longrightarrow> x = f j)) \<and> (j \<notin> I \<longrightarrow> f j = undefined)" ..
   468   then have "f \<in> Pi\<^sub>E I F"
   469     by (auto simp: extensional_def PiE_def)
   470   then have "f \<in> Pi\<^sub>E I F'"
   471     using assms by simp
   472   then show "x \<in> F' i"
   473     using f \<open>i \<in> I\<close> by (auto simp: PiE_def)
   474 qed
   475 
   476 lemma PiE_eq_iff_not_empty:
   477   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   478   shows "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   479 proof (intro iffI ballI)
   480   fix i
   481   assume eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   482   assume i: "i \<in> I"
   483   show "F i = F' i"
   484     using PiE_eq_subset[of I F F', OF ne eq i]
   485     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   486     by auto
   487 qed (auto simp: PiE_def)
   488 
   489 lemma PiE_eq_iff:
   490   "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   491 proof (intro iffI disjCI)
   492   assume eq[simp]: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   493   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   494   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   495     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
   496   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i"
   497     by auto
   498 next
   499   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   500   then show "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   501     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
   502 qed
   503 
   504 lemma extensional_funcset_fun_upd_restricts_rangeI:
   505   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f \<in> (insert x S) \<rightarrow>\<^sub>E T \<Longrightarrow> f(x := undefined) \<in> S \<rightarrow>\<^sub>E (T - {f x})"
   506   unfolding extensional_funcset_def extensional_def
   507   apply auto
   508   apply (case_tac "x = xa")
   509   apply auto
   510   done
   511 
   512 lemma extensional_funcset_fun_upd_extends_rangeI:
   513   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   514   shows "f(x := a) \<in> insert x S \<rightarrow>\<^sub>E  T"
   515   using assms unfolding extensional_funcset_def extensional_def by auto
   516 
   517 
   518 subsubsection \<open>Injective Extensional Function Spaces\<close>
   519 
   520 lemma extensional_funcset_fun_upd_inj_onI:
   521   assumes "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   522     and "inj_on f S"
   523   shows "inj_on (f(x := a)) S"
   524   using assms
   525   unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   526 
   527 lemma extensional_funcset_extend_domain_inj_on_eq:
   528   assumes "x \<notin> S"
   529   shows "{f. f \<in> (insert x S) \<rightarrow>\<^sub>E T \<and> inj_on f (insert x S)} =
   530     (\<lambda>(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   531   using assms
   532   apply (auto del: PiE_I PiE_E)
   533   apply (auto intro: extensional_funcset_fun_upd_inj_onI
   534     extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
   535   apply (auto simp add: image_iff inj_on_def)
   536   apply (rule_tac x="xa x" in exI)
   537   apply (auto intro: PiE_mem del: PiE_I PiE_E)
   538   apply (rule_tac x="xa(x := undefined)" in exI)
   539   apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   540   apply (auto dest!: PiE_mem split: split_if_asm)
   541   done
   542 
   543 lemma extensional_funcset_extend_domain_inj_onI:
   544   assumes "x \<notin> S"
   545   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   546   using assms
   547   apply (auto intro!: inj_onI)
   548   apply (metis fun_upd_same)
   549   apply (metis assms PiE_arb fun_upd_triv fun_upd_upd)
   550   done
   551 
   552 
   553 subsubsection \<open>Cardinality\<close>
   554 
   555 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (\<Pi>\<^sub>E i \<in> S. T i)"
   556   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
   557 
   558 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^sub>E S T)"
   559 proof (safe intro!: inj_onI ext)
   560   fix f y g z
   561   assume "x \<notin> S"
   562   assume fg: "f \<in> Pi\<^sub>E S T" "g \<in> Pi\<^sub>E S T"
   563   assume "f(x := y) = g(x := z)"
   564   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
   565     unfolding fun_eq_iff by auto
   566   from this[of x] show "y = z" by simp
   567   fix i from *[of i] \<open>x \<notin> S\<close> fg show "f i = g i"
   568     by (auto split: split_if_asm simp: PiE_def extensional_def)
   569 qed
   570 
   571 lemma card_PiE: "finite S \<Longrightarrow> card (\<Pi>\<^sub>E i \<in> S. T i) = (\<Prod> i\<in>S. card (T i))"
   572 proof (induct rule: finite_induct)
   573   case empty
   574   then show ?case by auto
   575 next
   576   case (insert x S)
   577   then show ?case
   578     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
   579 qed
   580 
   581 end