src/HOL/Tools/record.ML
author haftmann
Wed Nov 25 09:13:46 2009 +0100 (2009-11-25)
changeset 33957 e9afca2118d4
parent 33955 fff6f11b1f09
child 34151 8d57ce46b3f7
permissions -rw-r--r--
normalized uncurry take/drop
     1 (*  Title:      HOL/Tools/record.ML
     2     Author:     Wolfgang Naraschewski, TU Muenchen
     3     Author:     Markus Wenzel, TU Muenchen
     4     Author:     Norbert Schirmer, TU Muenchen
     5     Author:     Thomas Sewell, NICTA
     6 
     7 Extensible records with structural subtyping.
     8 *)
     9 
    10 signature BASIC_RECORD =
    11 sig
    12   val record_simproc: simproc
    13   val record_eq_simproc: simproc
    14   val record_upd_simproc: simproc
    15   val record_split_simproc: (term -> int) -> simproc
    16   val record_ex_sel_eq_simproc: simproc
    17   val record_split_tac: int -> tactic
    18   val record_split_simp_tac: thm list -> (term -> int) -> int -> tactic
    19   val record_split_name: string
    20   val record_split_wrapper: string * wrapper
    21   val print_record_type_abbr: bool Unsynchronized.ref
    22   val print_record_type_as_fields: bool Unsynchronized.ref
    23 end;
    24 
    25 signature RECORD =
    26 sig
    27   include BASIC_RECORD
    28   val timing: bool Unsynchronized.ref
    29   val updateN: string
    30   val ext_typeN: string
    31   val extN: string
    32   val makeN: string
    33   val moreN: string
    34   val last_extT: typ -> (string * typ list) option
    35   val dest_recTs: typ -> (string * typ list) list
    36   val get_extT_fields: theory -> typ -> (string * typ) list * (string * typ)
    37   val get_recT_fields: theory -> typ -> (string * typ) list * (string * typ)
    38   val get_parent: theory -> string -> (typ list * string) option
    39   val get_extension: theory -> string -> (string * typ list) option
    40   val get_extinjects: theory -> thm list
    41   val get_simpset: theory -> simpset
    42   val print_records: theory -> unit
    43   val read_typ: Proof.context -> string -> (string * sort) list -> typ * (string * sort) list
    44   val cert_typ: Proof.context -> typ -> (string * sort) list -> typ * (string * sort) list
    45   val add_record: bool -> string list * string -> string option -> (string * string * mixfix) list
    46     -> theory -> theory
    47   val add_record_i: bool -> string list * string -> (typ list * string) option
    48     -> (string * typ * mixfix) list -> theory -> theory
    49   val setup: theory -> theory
    50 end;
    51 
    52 
    53 signature ISTUPLE_SUPPORT =
    54 sig
    55   val add_istuple_type: bstring * string list -> typ * typ -> theory -> (term * term) * theory
    56   val mk_cons_tuple: term * term -> term
    57   val dest_cons_tuple: term -> term * term
    58   val istuple_intros_tac: int -> tactic
    59   val named_cterm_instantiate: (string * cterm) list -> thm -> thm
    60 end;
    61 
    62 structure IsTupleSupport: ISTUPLE_SUPPORT =
    63 struct
    64 
    65 val isomN = "_TupleIsom";
    66 
    67 val istuple_intro = @{thm isomorphic_tuple_intro};
    68 val istuple_intros = Tactic.build_net @{thms isomorphic_tuple.intros};
    69 
    70 val tuple_istuple = (@{const_name tuple_istuple}, @{thm tuple_istuple});
    71 
    72 fun named_cterm_instantiate values thm =
    73   let
    74     fun match name ((name', _), _) = name = name'
    75       | match name _ = false;
    76     fun getvar name =
    77       (case find_first (match name) (Term.add_vars (prop_of thm) []) of
    78         SOME var => cterm_of (theory_of_thm thm) (Var var)
    79       | NONE => raise THM ("named_cterm_instantiate: " ^ name, 0, [thm]));
    80   in
    81     cterm_instantiate (map (apfst getvar) values) thm
    82   end;
    83 
    84 structure IsTupleThms = Theory_Data
    85 (
    86   type T = thm Symtab.table;
    87   val empty = Symtab.make [tuple_istuple];
    88   val extend = I;
    89   fun merge data = Symtab.merge Thm.eq_thm_prop data;   (* FIXME handle Symtab.DUP ?? *)
    90 );
    91 
    92 fun do_typedef name repT alphas thy =
    93   let
    94     fun get_thms thy name =
    95       let
    96         val SOME {Rep_inject = rep_inject, Abs_name = absN, abs_type = absT,
    97           Abs_inverse = abs_inverse, ...} = Typedef.get_info thy name;
    98         val rewrite_rule =
    99           MetaSimplifier.rewrite_rule [@{thm istuple_UNIV_I}, @{thm istuple_True_simp}];
   100       in
   101         (map rewrite_rule [rep_inject, abs_inverse], Const (absN, repT --> absT), absT)
   102       end;
   103   in
   104     thy
   105     |> Typecopy.typecopy (Binding.name name, alphas) repT NONE
   106     |-> (fn (name, _) => `(fn thy => get_thms thy name))
   107   end;
   108 
   109 fun mk_cons_tuple (left, right) =
   110   let
   111     val (leftT, rightT) = (fastype_of left, fastype_of right);
   112     val prodT = HOLogic.mk_prodT (leftT, rightT);
   113     val isomT = Type (@{type_name tuple_isomorphism}, [prodT, leftT, rightT]);
   114   in
   115     Const (@{const_name istuple_cons}, isomT --> leftT --> rightT --> prodT) $
   116       Const (fst tuple_istuple, isomT) $ left $ right
   117   end;
   118 
   119 fun dest_cons_tuple (Const (@{const_name istuple_cons}, _) $ Const _ $ t $ u) = (t, u)
   120   | dest_cons_tuple t = raise TERM ("dest_cons_tuple", [t]);
   121 
   122 fun add_istuple_type (name, alphas) (leftT, rightT) thy =
   123   let
   124     val repT = HOLogic.mk_prodT (leftT, rightT);
   125 
   126     val (([rep_inject, abs_inverse], absC, absT), typ_thy) =
   127       thy
   128       |> do_typedef name repT alphas
   129       ||> Sign.add_path name;
   130 
   131     (*construct a type and body for the isomorphism constant by
   132       instantiating the theorem to which the definition will be applied*)
   133     val intro_inst =
   134       rep_inject RS named_cterm_instantiate [("abst", cterm_of typ_thy absC)] istuple_intro;
   135     val (_, body) = Logic.dest_equals (List.last (prems_of intro_inst));
   136     val isomT = fastype_of body;
   137     val isom_bind = Binding.name (name ^ isomN);
   138     val isom_name = Sign.full_name typ_thy isom_bind;
   139     val isom = Const (isom_name, isomT);
   140     val isom_spec = (Thm.def_name (name ^ isomN), Logic.mk_equals (isom, body));
   141 
   142     val ([isom_def], cdef_thy) =
   143       typ_thy
   144       |> Sign.add_consts_i [Syntax.no_syn (isom_bind, isomT)]
   145       |> PureThy.add_defs false [Thm.no_attributes (apfst Binding.name isom_spec)];
   146 
   147     val istuple = isom_def RS (abs_inverse RS (rep_inject RS istuple_intro));
   148     val cons = Const (@{const_name istuple_cons}, isomT --> leftT --> rightT --> absT);
   149 
   150     val thm_thy =
   151       cdef_thy
   152       |> IsTupleThms.map (Symtab.insert Thm.eq_thm_prop (isom_name, istuple))
   153       |> Sign.parent_path
   154       |> Code.add_default_eqn isom_def;
   155   in
   156     ((isom, cons $ isom), thm_thy)
   157   end;
   158 
   159 val istuple_intros_tac = resolve_from_net_tac istuple_intros THEN'
   160   CSUBGOAL (fn (cgoal, i) =>
   161     let
   162       val thy = Thm.theory_of_cterm cgoal;
   163       val goal = Thm.term_of cgoal;
   164 
   165       val isthms = IsTupleThms.get thy;
   166       fun err s t = raise TERM ("istuple_intros_tac: " ^ s, [t]);
   167 
   168       val goal' = Envir.beta_eta_contract goal;
   169       val is =
   170         (case goal' of
   171           Const (@{const_name Trueprop}, _) $
   172             (Const (@{const_name isomorphic_tuple}, _) $ Const is) => is
   173         | _ => err "unexpected goal format" goal');
   174       val isthm =
   175         (case Symtab.lookup isthms (#1 is) of
   176           SOME isthm => isthm
   177         | NONE => err "no thm found for constant" (Const is));
   178     in rtac isthm i end);
   179 
   180 end;
   181 
   182 
   183 structure Record: RECORD =
   184 struct
   185 
   186 val eq_reflection = @{thm eq_reflection};
   187 val atomize_all = @{thm HOL.atomize_all};
   188 val atomize_imp = @{thm HOL.atomize_imp};
   189 val meta_allE = @{thm Pure.meta_allE};
   190 val prop_subst = @{thm prop_subst};
   191 val K_record_comp = @{thm K_record_comp};
   192 val K_comp_convs = [@{thm o_apply}, K_record_comp]
   193 val o_assoc = @{thm o_assoc};
   194 val id_apply = @{thm id_apply};
   195 val id_o_apps = [@{thm id_apply}, @{thm id_o}, @{thm o_id}];
   196 val Not_eq_iff = @{thm Not_eq_iff};
   197 
   198 val refl_conj_eq = @{thm refl_conj_eq};
   199 
   200 val surject_assistI = @{thm "istuple_surjective_proof_assistI"};
   201 val surject_assist_idE = @{thm "istuple_surjective_proof_assist_idE"};
   202 
   203 val updacc_accessor_eqE = @{thm "update_accessor_accessor_eqE"};
   204 val updacc_updator_eqE = @{thm "update_accessor_updator_eqE"};
   205 val updacc_eq_idI = @{thm "istuple_update_accessor_eq_assist_idI"};
   206 val updacc_eq_triv = @{thm "istuple_update_accessor_eq_assist_triv"};
   207 
   208 val updacc_foldE = @{thm "update_accessor_congruence_foldE"};
   209 val updacc_unfoldE = @{thm "update_accessor_congruence_unfoldE"};
   210 val updacc_noopE = @{thm "update_accessor_noopE"};
   211 val updacc_noop_compE = @{thm "update_accessor_noop_compE"};
   212 val updacc_cong_idI = @{thm "update_accessor_cong_assist_idI"};
   213 val updacc_cong_triv = @{thm "update_accessor_cong_assist_triv"};
   214 val updacc_cong_from_eq = @{thm "istuple_update_accessor_cong_from_eq"};
   215 
   216 val o_eq_dest = @{thm o_eq_dest};
   217 val o_eq_id_dest = @{thm o_eq_id_dest};
   218 val o_eq_dest_lhs = @{thm o_eq_dest_lhs};
   219 
   220 
   221 
   222 (** name components **)
   223 
   224 val rN = "r";
   225 val wN = "w";
   226 val moreN = "more";
   227 val schemeN = "_scheme";
   228 val ext_typeN = "_ext_type";
   229 val inner_typeN = "_inner_type";
   230 val extN ="_ext";
   231 val updateN = "_update";
   232 val makeN = "make";
   233 val fields_selN = "fields";
   234 val extendN = "extend";
   235 val truncateN = "truncate";
   236 
   237 
   238 
   239 (*** utilities ***)
   240 
   241 fun but_last xs = fst (split_last xs);
   242 
   243 fun varifyT midx =
   244   let fun varify (a, S) = TVar ((a, midx + 1), S);
   245   in map_type_tfree varify end;
   246 
   247 
   248 (* timing *)
   249 
   250 val timing = Unsynchronized.ref false;
   251 fun timeit_msg s x = if ! timing then (warning s; timeit x) else x ();
   252 fun timing_msg s = if ! timing then warning s else ();
   253 
   254 
   255 (* syntax *)
   256 
   257 val Trueprop = HOLogic.mk_Trueprop;
   258 fun All xs t = Term.list_all_free (xs, t);
   259 
   260 infix 9 $$;
   261 infix 0 :== ===;
   262 infixr 0 ==>;
   263 
   264 val op $$ = Term.list_comb;
   265 val op :== = Primitive_Defs.mk_defpair;
   266 val op === = Trueprop o HOLogic.mk_eq;
   267 val op ==> = Logic.mk_implies;
   268 
   269 
   270 (* constructor *)
   271 
   272 fun mk_extC (name, T) Ts = (suffix extN name, Ts ---> T);
   273 
   274 fun mk_ext (name, T) ts =
   275   let val Ts = map fastype_of ts
   276   in list_comb (Const (mk_extC (name, T) Ts), ts) end;
   277 
   278 
   279 (* selector *)
   280 
   281 fun mk_selC sT (c, T) = (c, sT --> T);
   282 
   283 fun mk_sel s (c, T) =
   284   let val sT = fastype_of s
   285   in Const (mk_selC sT (c, T)) $ s end;
   286 
   287 
   288 (* updates *)
   289 
   290 fun mk_updC sfx sT (c, T) = (suffix sfx c, (T --> T) --> sT --> sT);
   291 
   292 fun mk_upd' sfx c v sT =
   293   let val vT = domain_type (fastype_of v);
   294   in Const (mk_updC sfx sT (c, vT)) $ v end;
   295 
   296 fun mk_upd sfx c v s = mk_upd' sfx c v (fastype_of s) $ s;
   297 
   298 
   299 (* types *)
   300 
   301 fun dest_recT (typ as Type (c_ext_type, Ts as (_ :: _))) =
   302       (case try (unsuffix ext_typeN) c_ext_type of
   303         NONE => raise TYPE ("Record.dest_recT", [typ], [])
   304       | SOME c => ((c, Ts), List.last Ts))
   305   | dest_recT typ = raise TYPE ("Record.dest_recT", [typ], []);
   306 
   307 val is_recT = can dest_recT;
   308 
   309 fun dest_recTs T =
   310   let val ((c, Ts), U) = dest_recT T
   311   in (c, Ts) :: dest_recTs U
   312   end handle TYPE _ => [];
   313 
   314 fun last_extT T =
   315   let val ((c, Ts), U) = dest_recT T in
   316     (case last_extT U of
   317       NONE => SOME (c, Ts)
   318     | SOME l => SOME l)
   319   end handle TYPE _ => NONE;
   320 
   321 fun rec_id i T =
   322   let
   323     val rTs = dest_recTs T;
   324     val rTs' = if i < 0 then rTs else take i rTs;
   325   in implode (map #1 rTs') end;
   326 
   327 
   328 
   329 (*** extend theory by record definition ***)
   330 
   331 (** record info **)
   332 
   333 (* type record_info and parent_info *)
   334 
   335 type record_info =
   336  {args: (string * sort) list,
   337   parent: (typ list * string) option,
   338   fields: (string * typ) list,
   339   extension: (string * typ list),
   340   induct: thm,
   341   extdef: thm};
   342 
   343 fun make_record_info args parent fields extension induct extdef =
   344  {args = args, parent = parent, fields = fields, extension = extension,
   345   induct = induct, extdef = extdef}: record_info;
   346 
   347 
   348 type parent_info =
   349  {name: string,
   350   fields: (string * typ) list,
   351   extension: (string * typ list),
   352   induct: thm,
   353   extdef: thm};
   354 
   355 fun make_parent_info name fields extension induct extdef =
   356  {name = name, fields = fields, extension = extension,
   357   induct = induct, extdef = extdef}: parent_info;
   358 
   359 
   360 (* theory data *)
   361 
   362 type record_data =
   363  {records: record_info Symtab.table,
   364   sel_upd:
   365    {selectors: (int * bool) Symtab.table,
   366     updates: string Symtab.table,
   367     simpset: Simplifier.simpset,
   368     defset: Simplifier.simpset,
   369     foldcong: Simplifier.simpset,
   370     unfoldcong: Simplifier.simpset},
   371   equalities: thm Symtab.table,
   372   extinjects: thm list,
   373   extsplit: thm Symtab.table,  (*maps extension name to split rule*)
   374   splits: (thm * thm * thm * thm) Symtab.table,  (*!!, !, EX - split-equalities, induct rule*)
   375   extfields: (string * typ) list Symtab.table,  (*maps extension to its fields*)
   376   fieldext: (string * typ list) Symtab.table};  (*maps field to its extension*)
   377 
   378 fun make_record_data
   379     records sel_upd equalities extinjects extsplit splits extfields fieldext =
   380  {records = records, sel_upd = sel_upd,
   381   equalities = equalities, extinjects=extinjects, extsplit = extsplit, splits = splits,
   382   extfields = extfields, fieldext = fieldext }: record_data;
   383 
   384 structure RecordsData = Theory_Data
   385 (
   386   type T = record_data;
   387   val empty =
   388     make_record_data Symtab.empty
   389       {selectors = Symtab.empty, updates = Symtab.empty,
   390           simpset = HOL_basic_ss, defset = HOL_basic_ss,
   391           foldcong = HOL_basic_ss, unfoldcong = HOL_basic_ss}
   392        Symtab.empty [] Symtab.empty Symtab.empty Symtab.empty Symtab.empty;
   393   val extend = I;
   394   fun merge
   395    ({records = recs1,
   396      sel_upd =
   397       {selectors = sels1, updates = upds1,
   398        simpset = ss1, defset = ds1,
   399        foldcong = fc1, unfoldcong = uc1},
   400      equalities = equalities1,
   401      extinjects = extinjects1,
   402      extsplit = extsplit1,
   403      splits = splits1,
   404      extfields = extfields1,
   405      fieldext = fieldext1},
   406     {records = recs2,
   407      sel_upd =
   408       {selectors = sels2, updates = upds2,
   409        simpset = ss2, defset = ds2,
   410        foldcong = fc2, unfoldcong = uc2},
   411      equalities = equalities2,
   412      extinjects = extinjects2,
   413      extsplit = extsplit2,
   414      splits = splits2,
   415      extfields = extfields2,
   416      fieldext = fieldext2}) =
   417     make_record_data
   418       (Symtab.merge (K true) (recs1, recs2))
   419       {selectors = Symtab.merge (K true) (sels1, sels2),
   420         updates = Symtab.merge (K true) (upds1, upds2),
   421         simpset = Simplifier.merge_ss (ss1, ss2),
   422         defset = Simplifier.merge_ss (ds1, ds2),
   423         foldcong = Simplifier.merge_ss (fc1, fc2),
   424         unfoldcong = Simplifier.merge_ss (uc1, uc2)}
   425       (Symtab.merge Thm.eq_thm_prop (equalities1, equalities2))
   426       (Thm.merge_thms (extinjects1, extinjects2))
   427       (Symtab.merge Thm.eq_thm_prop (extsplit1, extsplit2))
   428       (Symtab.merge (fn ((a, b, c, d), (w, x, y, z)) =>
   429           Thm.eq_thm (a, w) andalso Thm.eq_thm (b, x) andalso
   430           Thm.eq_thm (c, y) andalso Thm.eq_thm (d, z)) (splits1, splits2))
   431       (Symtab.merge (K true) (extfields1, extfields2))
   432       (Symtab.merge (K true) (fieldext1, fieldext2));
   433 );
   434 
   435 fun print_records thy =
   436   let
   437     val {records = recs, ...} = RecordsData.get thy;
   438     val prt_typ = Syntax.pretty_typ_global thy;
   439 
   440     fun pretty_parent NONE = []
   441       | pretty_parent (SOME (Ts, name)) =
   442           [Pretty.block [prt_typ (Type (name, Ts)), Pretty.str " +"]];
   443 
   444     fun pretty_field (c, T) = Pretty.block
   445       [Pretty.str (Sign.extern_const thy c), Pretty.str " ::",
   446         Pretty.brk 1, Pretty.quote (prt_typ T)];
   447 
   448     fun pretty_record (name, {args, parent, fields, ...}: record_info) =
   449       Pretty.block (Pretty.fbreaks (Pretty.block
   450         [prt_typ (Type (name, map TFree args)), Pretty.str " = "] ::
   451         pretty_parent parent @ map pretty_field fields));
   452   in map pretty_record (Symtab.dest recs) |> Pretty.chunks |> Pretty.writeln end;
   453 
   454 
   455 (* access 'records' *)
   456 
   457 val get_record = Symtab.lookup o #records o RecordsData.get;
   458 
   459 fun put_record name info thy =
   460   let
   461     val {records, sel_upd, equalities, extinjects, extsplit, splits, extfields, fieldext} =
   462       RecordsData.get thy;
   463     val data = make_record_data (Symtab.update (name, info) records)
   464       sel_upd equalities extinjects extsplit splits extfields fieldext;
   465   in RecordsData.put data thy end;
   466 
   467 
   468 (* access 'sel_upd' *)
   469 
   470 val get_sel_upd = #sel_upd o RecordsData.get;
   471 
   472 val is_selector = Symtab.defined o #selectors o get_sel_upd;
   473 val get_updates = Symtab.lookup o #updates o get_sel_upd;
   474 fun get_ss_with_context getss thy = Simplifier.theory_context thy (getss (get_sel_upd thy));
   475 
   476 val get_simpset = get_ss_with_context #simpset;
   477 val get_sel_upd_defs = get_ss_with_context #defset;
   478 
   479 fun get_update_details u thy =
   480   let val sel_upd = get_sel_upd thy in
   481     (case Symtab.lookup (#updates sel_upd) u of
   482       SOME s =>
   483         let val SOME (dep, ismore) = Symtab.lookup (#selectors sel_upd) s
   484         in SOME (s, dep, ismore) end
   485     | NONE => NONE)
   486   end;
   487 
   488 fun put_sel_upd names more depth simps defs (folds, unfolds) thy =
   489   let
   490     val all = names @ [more];
   491     val sels = map (rpair (depth, false)) names @ [(more, (depth, true))];
   492     val upds = map (suffix updateN) all ~~ all;
   493 
   494     val {records, sel_upd = {selectors, updates, simpset, defset, foldcong, unfoldcong},
   495       equalities, extinjects, extsplit, splits, extfields, fieldext} = RecordsData.get thy;
   496     val data = make_record_data records
   497       {selectors = fold Symtab.update_new sels selectors,
   498         updates = fold Symtab.update_new upds updates,
   499         simpset = Simplifier.addsimps (simpset, simps),
   500         defset = Simplifier.addsimps (defset, defs),
   501         foldcong = foldcong addcongs folds,
   502         unfoldcong = unfoldcong addcongs unfolds}
   503        equalities extinjects extsplit splits extfields fieldext;
   504   in RecordsData.put data thy end;
   505 
   506 
   507 (* access 'equalities' *)
   508 
   509 fun add_record_equalities name thm thy =
   510   let
   511     val {records, sel_upd, equalities, extinjects, extsplit, splits, extfields, fieldext} =
   512       RecordsData.get thy;
   513     val data = make_record_data records sel_upd
   514       (Symtab.update_new (name, thm) equalities) extinjects extsplit splits extfields fieldext;
   515   in RecordsData.put data thy end;
   516 
   517 val get_equalities = Symtab.lookup o #equalities o RecordsData.get;
   518 
   519 
   520 (* access 'extinjects' *)
   521 
   522 fun add_extinjects thm thy =
   523   let
   524     val {records, sel_upd, equalities, extinjects, extsplit, splits, extfields, fieldext} =
   525       RecordsData.get thy;
   526     val data =
   527       make_record_data records sel_upd equalities (insert Thm.eq_thm_prop thm extinjects)
   528         extsplit splits extfields fieldext;
   529   in RecordsData.put data thy end;
   530 
   531 val get_extinjects = rev o #extinjects o RecordsData.get;
   532 
   533 
   534 (* access 'extsplit' *)
   535 
   536 fun add_extsplit name thm thy =
   537   let
   538     val {records, sel_upd, equalities, extinjects, extsplit, splits, extfields, fieldext} =
   539       RecordsData.get thy;
   540     val data = make_record_data records sel_upd
   541       equalities extinjects (Symtab.update_new (name, thm) extsplit) splits
   542       extfields fieldext;
   543   in RecordsData.put data thy end;
   544 
   545 
   546 (* access 'splits' *)
   547 
   548 fun add_record_splits name thmP thy =
   549   let
   550     val {records, sel_upd, equalities, extinjects, extsplit, splits, extfields, fieldext} =
   551       RecordsData.get thy;
   552     val data = make_record_data records sel_upd
   553       equalities extinjects extsplit (Symtab.update_new (name, thmP) splits)
   554       extfields fieldext;
   555   in RecordsData.put data thy end;
   556 
   557 val get_splits = Symtab.lookup o #splits o RecordsData.get;
   558 
   559 
   560 (* parent/extension of named record *)
   561 
   562 val get_parent = (Option.join o Option.map #parent) oo (Symtab.lookup o #records o RecordsData.get);
   563 val get_extension = Option.map #extension oo (Symtab.lookup o #records o RecordsData.get);
   564 
   565 
   566 (* access 'extfields' *)
   567 
   568 fun add_extfields name fields thy =
   569   let
   570     val {records, sel_upd, equalities, extinjects, extsplit, splits, extfields, fieldext} =
   571       RecordsData.get thy;
   572     val data =
   573       make_record_data records sel_upd
   574         equalities extinjects extsplit splits
   575         (Symtab.update_new (name, fields) extfields) fieldext;
   576   in RecordsData.put data thy end;
   577 
   578 val get_extfields = Symtab.lookup o #extfields o RecordsData.get;
   579 
   580 fun get_extT_fields thy T =
   581   let
   582     val ((name, Ts), moreT) = dest_recT T;
   583     val recname =
   584       let val (nm :: _ :: rst) = rev (Long_Name.explode name)   (* FIXME !? *)
   585       in Long_Name.implode (rev (nm :: rst)) end;
   586     val midx = maxidx_of_typs (moreT :: Ts);
   587     val varifyT = varifyT midx;
   588     val {records, extfields, ...} = RecordsData.get thy;
   589     val (flds, (more, _)) = split_last (Symtab.lookup_list extfields name);
   590     val args = map varifyT (snd (#extension (the (Symtab.lookup records recname))));
   591 
   592     val subst = fold (Sign.typ_match thy) (but_last args ~~ but_last Ts) (Vartab.empty);
   593     val flds' = map (apsnd ((Envir.norm_type subst) o varifyT)) flds;
   594   in (flds', (more, moreT)) end;
   595 
   596 fun get_recT_fields thy T =
   597   let
   598     val (root_flds, (root_more, root_moreT)) = get_extT_fields thy T;
   599     val (rest_flds, rest_more) =
   600       if is_recT root_moreT then get_recT_fields thy root_moreT
   601       else ([], (root_more, root_moreT));
   602   in (root_flds @ rest_flds, rest_more) end;
   603 
   604 
   605 (* access 'fieldext' *)
   606 
   607 fun add_fieldext extname_types fields thy =
   608   let
   609     val {records, sel_upd, equalities, extinjects, extsplit, splits, extfields, fieldext} =
   610       RecordsData.get thy;
   611     val fieldext' =
   612       fold (fn field => Symtab.update_new (field, extname_types)) fields fieldext;
   613     val data =
   614       make_record_data records sel_upd equalities extinjects
   615         extsplit splits extfields fieldext';
   616   in RecordsData.put data thy end;
   617 
   618 val get_fieldext = Symtab.lookup o #fieldext o RecordsData.get;
   619 
   620 
   621 (* parent records *)
   622 
   623 fun add_parents _ NONE parents = parents
   624   | add_parents thy (SOME (types, name)) parents =
   625       let
   626         fun err msg = error (msg ^ " parent record " ^ quote name);
   627 
   628         val {args, parent, fields, extension, induct, extdef} =
   629           (case get_record thy name of SOME info => info | NONE => err "Unknown");
   630         val _ = if length types <> length args then err "Bad number of arguments for" else ();
   631 
   632         fun bad_inst ((x, S), T) =
   633           if Sign.of_sort thy (T, S) then NONE else SOME x
   634         val bads = map_filter bad_inst (args ~~ types);
   635         val _ = null bads orelse err ("Ill-sorted instantiation of " ^ commas bads ^ " in");
   636 
   637         val inst = map fst args ~~ types;
   638         val subst = Term.map_type_tfree (the o AList.lookup (op =) inst o fst);
   639         val parent' = Option.map (apfst (map subst)) parent;
   640         val fields' = map (apsnd subst) fields;
   641         val extension' = apsnd (map subst) extension;
   642       in
   643         add_parents thy parent'
   644           (make_parent_info name fields' extension' induct extdef :: parents)
   645       end;
   646 
   647 
   648 
   649 (** concrete syntax for records **)
   650 
   651 (* decode type *)
   652 
   653 fun decode_type thy t =
   654   let
   655     fun get_sort xs n = AList.lookup (op =) xs (n: indexname) |> the_default (Sign.defaultS thy);
   656     val map_sort = Sign.intern_sort thy;
   657   in
   658     Syntax.typ_of_term (get_sort (Syntax.term_sorts map_sort t)) map_sort t
   659     |> Sign.intern_tycons thy
   660   end;
   661 
   662 
   663 (* parse translations *)
   664 
   665 fun gen_field_tr mark sfx (t as Const (c, _) $ Const (name, _) $ arg) =
   666       if c = mark then Syntax.const (suffix sfx name) $ Abs ("_", dummyT, arg)
   667       else raise TERM ("gen_field_tr: " ^ mark, [t])
   668   | gen_field_tr mark _ t = raise TERM ("gen_field_tr: " ^ mark, [t]);
   669 
   670 fun gen_fields_tr sep mark sfx (tm as Const (c, _) $ t $ u) =
   671       if c = sep then gen_field_tr mark sfx t :: gen_fields_tr sep mark sfx u
   672       else [gen_field_tr mark sfx tm]
   673   | gen_fields_tr _ mark sfx tm = [gen_field_tr mark sfx tm];
   674 
   675 
   676 fun record_update_tr [t, u] =
   677       Library.foldr (op $) (rev (gen_fields_tr "_updates" "_update" updateN u), t)
   678   | record_update_tr ts = raise TERM ("record_update_tr", ts);
   679 
   680 fun update_name_tr (Free (x, T) :: ts) = Free (suffix updateN x, T) $$ ts
   681   | update_name_tr (Const (x, T) :: ts) = Const (suffix updateN x, T) $$ ts
   682   | update_name_tr (((c as Const ("_constrain", _)) $ t $ ty) :: ts) =
   683       (c $ update_name_tr [t] $ (Syntax.const "fun" $ ty $ Syntax.const "dummy")) $$ ts
   684   | update_name_tr ts = raise TERM ("update_name_tr", ts);
   685 
   686 fun dest_ext_field mark (t as (Const (c, _) $ Const (name, _) $ arg)) =
   687       if c = mark then (name, arg)
   688       else raise TERM ("dest_ext_field: " ^ mark, [t])
   689   | dest_ext_field _ t = raise TERM ("dest_ext_field", [t]);
   690 
   691 fun dest_ext_fields sep mark (trm as (Const (c, _) $ t $ u)) =
   692       if c = sep then dest_ext_field mark t :: dest_ext_fields sep mark u
   693       else [dest_ext_field mark trm]
   694   | dest_ext_fields _ mark t = [dest_ext_field mark t];
   695 
   696 fun gen_ext_fields_tr sep mark sfx more ctxt t =
   697   let
   698     val thy = ProofContext.theory_of ctxt;
   699     val msg = "error in record input: ";
   700 
   701     val fieldargs = dest_ext_fields sep mark t;
   702     fun splitargs (field :: fields) ((name, arg) :: fargs) =
   703           if can (unsuffix name) field
   704           then
   705             let val (args, rest) = splitargs fields fargs
   706             in (arg :: args, rest) end
   707           else raise TERM (msg ^ "expecting field " ^ field ^ " but got " ^ name, [t])
   708       | splitargs [] (fargs as (_ :: _)) = ([], fargs)
   709       | splitargs (_ :: _) [] = raise TERM (msg ^ "expecting more fields", [t])
   710       | splitargs _ _ = ([], []);
   711 
   712     fun mk_ext (fargs as (name, _) :: _) =
   713           (case get_fieldext thy (Sign.intern_const thy name) of
   714             SOME (ext, _) =>
   715               (case get_extfields thy ext of
   716                 SOME flds =>
   717                   let
   718                     val (args, rest) = splitargs (map fst (but_last flds)) fargs;
   719                     val more' = mk_ext rest;
   720                   in list_comb (Syntax.const (suffix sfx ext), args @ [more']) end
   721               | NONE => raise TERM (msg ^ "no fields defined for " ^ ext, [t]))
   722           | NONE => raise TERM (msg ^ name ^" is no proper field", [t]))
   723       | mk_ext [] = more;
   724   in mk_ext fieldargs end;
   725 
   726 fun gen_ext_type_tr sep mark sfx more ctxt t =
   727   let
   728     val thy = ProofContext.theory_of ctxt;
   729     val msg = "error in record-type input: ";
   730 
   731     val fieldargs = dest_ext_fields sep mark t;
   732     fun splitargs (field :: fields) ((name, arg) :: fargs) =
   733           if can (unsuffix name) field then
   734             let val (args, rest) = splitargs fields fargs
   735             in (arg :: args, rest) end
   736           else raise TERM (msg ^ "expecting field " ^ field ^ " but got " ^ name, [t])
   737       | splitargs [] (fargs as (_ :: _)) = ([], fargs)
   738       | splitargs (_ :: _) [] = raise TERM (msg ^ "expecting more fields", [t])
   739       | splitargs _ _ = ([], []);
   740 
   741     fun mk_ext (fargs as (name, _) :: _) =
   742           (case get_fieldext thy (Sign.intern_const thy name) of
   743             SOME (ext, alphas) =>
   744               (case get_extfields thy ext of
   745                 SOME flds =>
   746                  (let
   747                     val flds' = but_last flds;
   748                     val types = map snd flds';
   749                     val (args, rest) = splitargs (map fst flds') fargs;
   750                     val argtypes = map (Sign.certify_typ thy o decode_type thy) args;
   751                     val midx = fold Term.maxidx_typ argtypes 0;
   752                     val varifyT = varifyT midx;
   753                     val vartypes = map varifyT types;
   754 
   755                     val subst = fold (Sign.typ_match thy) (vartypes ~~ argtypes) Vartab.empty;
   756                     val alphas' =
   757                       map (Syntax.term_of_typ (! Syntax.show_sorts) o Envir.norm_type subst o varifyT)
   758                         (but_last alphas);
   759 
   760                     val more' = mk_ext rest;
   761                   in
   762                     list_comb (Syntax.const (suffix sfx ext), alphas' @ [more'])
   763                   end handle Type.TYPE_MATCH =>
   764                     raise TERM (msg ^ "type is no proper record (extension)", [t]))
   765               | NONE => raise TERM (msg ^ "no fields defined for " ^ ext, [t]))
   766           | NONE => raise TERM (msg ^ name ^" is no proper field", [t]))
   767       | mk_ext [] = more;
   768 
   769   in mk_ext fieldargs end;
   770 
   771 fun gen_adv_record_tr sep mark sfx unit ctxt [t] =
   772       gen_ext_fields_tr sep mark sfx unit ctxt t
   773   | gen_adv_record_tr _ _ _ _ _ ts = raise TERM ("gen_record_tr", ts);
   774 
   775 fun gen_adv_record_scheme_tr sep mark sfx ctxt [t, more] =
   776       gen_ext_fields_tr sep mark sfx more ctxt t
   777   | gen_adv_record_scheme_tr _ _ _ _ ts = raise TERM ("gen_record_scheme_tr", ts);
   778 
   779 fun gen_adv_record_type_tr sep mark sfx unit ctxt [t] =
   780       gen_ext_type_tr sep mark sfx unit ctxt t
   781   | gen_adv_record_type_tr _ _ _ _ _ ts = raise TERM ("gen_record_tr", ts);
   782 
   783 fun gen_adv_record_type_scheme_tr sep mark sfx ctxt [t, more] =
   784       gen_ext_type_tr sep mark sfx more ctxt t
   785   | gen_adv_record_type_scheme_tr _ _ _ _ ts = raise TERM ("gen_record_scheme_tr", ts);
   786 
   787 val adv_record_tr = gen_adv_record_tr "_fields" "_field" extN HOLogic.unit;
   788 
   789 val adv_record_scheme_tr = gen_adv_record_scheme_tr "_fields" "_field" extN;
   790 
   791 val adv_record_type_tr =
   792   gen_adv_record_type_tr "_field_types" "_field_type" ext_typeN
   793     (Syntax.term_of_typ false (HOLogic.unitT));
   794 
   795 val adv_record_type_scheme_tr =
   796   gen_adv_record_type_scheme_tr "_field_types" "_field_type" ext_typeN;
   797 
   798 
   799 val parse_translation =
   800  [("_record_update", record_update_tr),
   801   ("_update_name", update_name_tr)];
   802 
   803 val adv_parse_translation =
   804  [("_record", adv_record_tr),
   805   ("_record_scheme", adv_record_scheme_tr),
   806   ("_record_type", adv_record_type_tr),
   807   ("_record_type_scheme", adv_record_type_scheme_tr)];
   808 
   809 
   810 (* print translations *)
   811 
   812 val print_record_type_abbr = Unsynchronized.ref true;
   813 val print_record_type_as_fields = Unsynchronized.ref true;
   814 
   815 fun gen_field_upds_tr' mark sfx (tm as Const (name_field, _) $ k $ u) =
   816       let
   817         val t =
   818           (case k of
   819             Abs (_, _, Abs (_, _, t) $ Bound 0) =>
   820               if null (loose_bnos t) then t else raise Match
   821           | Abs (_, _, t) =>
   822               if null (loose_bnos t) then t else raise Match
   823           | _ => raise Match);
   824 
   825           (* FIXME ? *)
   826           (* (case k of (Const ("K_record", _) $ t) => t
   827                    | Abs (x, _, Const ("K_record", _) $ t $ Bound 0) => t
   828                    | _ => raise Match)*)
   829       in
   830         (case try (unsuffix sfx) name_field of
   831           SOME name =>
   832             apfst (cons (Syntax.const mark $ Syntax.free name $ t)) (gen_field_upds_tr' mark sfx u)
   833         | NONE => ([], tm))
   834       end
   835   | gen_field_upds_tr' _ _ tm = ([], tm);
   836 
   837 fun record_update_tr' tm =
   838   let val (ts, u) = gen_field_upds_tr' "_update" updateN tm in
   839     if null ts then raise Match
   840     else
   841       Syntax.const "_record_update" $ u $
   842         foldr1 (fn (v, w) => Syntax.const "_updates" $ v $ w) (rev ts)
   843   end;
   844 
   845 fun gen_field_tr' sfx tr' name =
   846   let val name_sfx = suffix sfx name
   847   in (name_sfx, fn [t, u] => tr' (Syntax.const name_sfx $ t $ u) | _ => raise Match) end;
   848 
   849 fun record_tr' sep mark record record_scheme unit ctxt t =
   850   let
   851     val thy = ProofContext.theory_of ctxt;
   852 
   853     fun field_lst t =
   854       (case strip_comb t of
   855         (Const (ext, _), args as (_ :: _)) =>
   856           (case try (unsuffix extN) (Sign.intern_const thy ext) of
   857             SOME ext' =>
   858               (case get_extfields thy ext' of
   859                 SOME flds =>
   860                  (let
   861                     val f :: fs = but_last (map fst flds);
   862                     val flds' = Sign.extern_const thy f :: map Long_Name.base_name fs;
   863                     val (args', more) = split_last args;
   864                   in (flds' ~~ args') @ field_lst more end
   865                   handle Library.UnequalLengths => [("", t)])
   866               | NONE => [("", t)])
   867           | NONE => [("", t)])
   868        | _ => [("", t)]);
   869 
   870     val (flds, (_, more)) = split_last (field_lst t);
   871     val _ = if null flds then raise Match else ();
   872     val flds' = map (fn (n, t) => Syntax.const mark $ Syntax.const n $ t) flds;
   873     val flds'' = foldr1 (fn (x, y) => Syntax.const sep $ x $ y) flds';
   874   in
   875     if unit more
   876     then Syntax.const record $ flds''
   877     else Syntax.const record_scheme $ flds'' $ more
   878   end;
   879 
   880 fun gen_record_tr' name =
   881   let
   882     val name_sfx = suffix extN name;
   883     val unit = (fn Const (@{const_syntax "Product_Type.Unity"}, _) => true | _ => false);
   884     fun tr' ctxt ts =
   885       record_tr' "_fields" "_field" "_record" "_record_scheme" unit ctxt
   886         (list_comb (Syntax.const name_sfx, ts));
   887   in (name_sfx, tr') end;
   888 
   889 fun print_translation names =
   890   map (gen_field_tr' updateN record_update_tr') names;
   891 
   892 
   893 (* record_type_abbr_tr' *)
   894 
   895 (*try to reconstruct the record name type abbreviation from
   896   the (nested) extension types*)
   897 fun record_type_abbr_tr' default_tr' abbr alphas zeta lastExt schemeT ctxt tm =
   898   let
   899     val thy = ProofContext.theory_of ctxt;
   900 
   901     (*tm is term representation of a (nested) field type. We first reconstruct the
   902       type from tm so that we can continue on the type level rather then the term level*)
   903 
   904     (*WORKAROUND:
   905       If a record type occurs in an error message of type inference there
   906       may be some internal frees donoted by ??:
   907       (Const "_tfree",_) $ Free ("??'a", _).
   908 
   909       This will unfortunately be translated to Type ("??'a", []) instead of
   910       TFree ("??'a", _) by typ_of_term, which will confuse unify below.
   911       fixT works around.*)
   912     fun fixT (T as Type (x, [])) =
   913           if String.isPrefix "??'" x then TFree (x, Sign.defaultS thy) else T
   914       | fixT (Type (x, xs)) = Type (x, map fixT xs)
   915       | fixT T = T;
   916 
   917     val T = fixT (decode_type thy tm);
   918     val midx = maxidx_of_typ T;
   919     val varifyT = varifyT midx;
   920 
   921     fun mk_type_abbr subst name alphas =
   922       let val abbrT = Type (name, map (fn a => varifyT (TFree (a, Sign.defaultS thy))) alphas) in
   923         Syntax.term_of_typ (! Syntax.show_sorts)
   924           (Sign.extern_typ thy (Envir.norm_type subst abbrT))
   925       end;
   926 
   927     fun match rT T = Sign.typ_match thy (varifyT rT, T) Vartab.empty;
   928   in
   929     if ! print_record_type_abbr then
   930       (case last_extT T of
   931         SOME (name, _) =>
   932           if name = lastExt then
   933            (let val subst = match schemeT T in
   934               if HOLogic.is_unitT (Envir.norm_type subst (varifyT (TFree (zeta, Sign.defaultS thy))))
   935               then mk_type_abbr subst abbr alphas
   936               else mk_type_abbr subst (suffix schemeN abbr) (alphas @ [zeta])
   937             end handle Type.TYPE_MATCH => default_tr' ctxt tm)
   938           else raise Match (*give print translation of specialised record a chance*)
   939       | _ => raise Match)
   940     else default_tr' ctxt tm
   941   end;
   942 
   943 fun record_type_tr' sep mark record record_scheme ctxt t =
   944   let
   945     val thy = ProofContext.theory_of ctxt;
   946 
   947     val T = decode_type thy t;
   948     val varifyT = varifyT (Term.maxidx_of_typ T);
   949 
   950     fun term_of_type T = Syntax.term_of_typ (! Syntax.show_sorts) (Sign.extern_typ thy T);
   951 
   952     fun field_lst T =
   953       (case T of
   954         Type (ext, args) =>
   955           (case try (unsuffix ext_typeN) ext of
   956             SOME ext' =>
   957               (case get_extfields thy ext' of
   958                 SOME flds =>
   959                   (case get_fieldext thy (fst (hd flds)) of
   960                     SOME (_, alphas) =>
   961                      (let
   962                         val f :: fs = but_last flds;
   963                         val flds' = apfst (Sign.extern_const thy) f ::
   964                           map (apfst Long_Name.base_name) fs;
   965                         val (args', more) = split_last args;
   966                         val alphavars = map varifyT (but_last alphas);
   967                         val subst = fold2 (curry (Sign.typ_match thy)) alphavars args' Vartab.empty;
   968                         val flds'' = (map o apsnd) (Envir.norm_type subst o varifyT) flds';
   969                       in flds'' @ field_lst more end
   970                       handle Type.TYPE_MATCH => [("", T)] | Library.UnequalLengths => [("", T)])
   971                   | NONE => [("", T)])
   972               | NONE => [("", T)])
   973           | NONE => [("", T)])
   974       | _ => [("", T)]);
   975 
   976     val (flds, (_, moreT)) = split_last (field_lst T);
   977     val flds' = map (fn (n, T) => Syntax.const mark $ Syntax.const n $ term_of_type T) flds;
   978     val flds'' =
   979       foldr1 (fn (x, y) => Syntax.const sep $ x $ y) flds'
   980         handle Empty => raise Match;
   981   in
   982     if not (! print_record_type_as_fields) orelse null flds then raise Match
   983     else if moreT = HOLogic.unitT then Syntax.const record $ flds''
   984     else Syntax.const record_scheme $ flds'' $ term_of_type moreT
   985   end;
   986 
   987 
   988 fun gen_record_type_tr' name =
   989   let
   990     val name_sfx = suffix ext_typeN name;
   991     fun tr' ctxt ts =
   992       record_type_tr' "_field_types" "_field_type" "_record_type" "_record_type_scheme"
   993         ctxt (list_comb (Syntax.const name_sfx, ts))
   994   in (name_sfx, tr') end;
   995 
   996 
   997 fun gen_record_type_abbr_tr' abbr alphas zeta lastExt schemeT name =
   998   let
   999     val name_sfx = suffix ext_typeN name;
  1000     val default_tr' =
  1001       record_type_tr' "_field_types" "_field_type" "_record_type" "_record_type_scheme";
  1002     fun tr' ctxt ts =
  1003       record_type_abbr_tr' default_tr' abbr alphas zeta lastExt schemeT ctxt
  1004         (list_comb (Syntax.const name_sfx, ts));
  1005   in (name_sfx, tr') end;
  1006 
  1007 
  1008 
  1009 (** record simprocs **)
  1010 
  1011 fun future_forward_prf_standard thy prf prop () =
  1012   let val thm =
  1013     if ! quick_and_dirty then Skip_Proof.make_thm thy prop
  1014     else if Goal.future_enabled () then
  1015       Goal.future_result (ProofContext.init thy) (Future.fork_pri ~1 prf) prop
  1016     else prf ()
  1017   in Drule.standard thm end;
  1018 
  1019 fun prove_common immediate stndrd thy asms prop tac =
  1020   let
  1021     val prv =
  1022       if ! quick_and_dirty then Skip_Proof.prove
  1023       else if immediate orelse not (Goal.future_enabled ()) then Goal.prove
  1024       else Goal.prove_future;
  1025     val prf = prv (ProofContext.init thy) [] asms prop tac;
  1026   in if stndrd then Drule.standard prf else prf end;
  1027 
  1028 val prove_future_global = prove_common false;
  1029 val prove_global = prove_common true;
  1030 
  1031 fun is_sel_upd_pair thy (Const (s, _)) (Const (u, t')) =
  1032   (case get_updates thy u of
  1033     SOME u_name => u_name = s
  1034   | NONE => raise TERM ("is_sel_upd_pair: not update", [Const (u, t')]));
  1035 
  1036 fun mk_comp f g =
  1037   let
  1038     val X = fastype_of g;
  1039     val A = domain_type X;
  1040     val B = range_type X;
  1041     val C = range_type (fastype_of f);
  1042     val T = (B --> C) --> (A --> B) --> A --> C;
  1043   in Const ("Fun.comp", T) $ f $ g end;
  1044 
  1045 fun mk_comp_id f =
  1046   let val T = range_type (fastype_of f)
  1047   in mk_comp (Const ("Fun.id", T --> T)) f end;
  1048 
  1049 fun get_upd_funs (upd $ _ $ t) = upd :: get_upd_funs t
  1050   | get_upd_funs _ = [];
  1051 
  1052 fun get_accupd_simps thy term defset =
  1053   let
  1054     val (acc, [body]) = strip_comb term;
  1055     val upd_funs = sort_distinct TermOrd.fast_term_ord (get_upd_funs body);
  1056     fun get_simp upd =
  1057       let
  1058         val T = domain_type (fastype_of upd);
  1059         val lhs = mk_comp acc (upd $ Free ("f", T));
  1060         val rhs =
  1061           if is_sel_upd_pair thy acc upd
  1062           then mk_comp (Free ("f", T)) acc
  1063           else mk_comp_id acc;
  1064         val prop = lhs === rhs;
  1065         val othm =
  1066           Goal.prove (ProofContext.init thy) [] [] prop
  1067             (fn _ =>
  1068               simp_tac defset 1 THEN
  1069               REPEAT_DETERM (IsTupleSupport.istuple_intros_tac 1) THEN
  1070               TRY (simp_tac (HOL_ss addsimps id_o_apps) 1));
  1071         val dest =
  1072           if is_sel_upd_pair thy acc upd
  1073           then o_eq_dest
  1074           else o_eq_id_dest;
  1075       in Drule.standard (othm RS dest) end;
  1076   in map get_simp upd_funs end;
  1077 
  1078 fun get_updupd_simp thy defset u u' comp =
  1079   let
  1080     val f = Free ("f", domain_type (fastype_of u));
  1081     val f' = Free ("f'", domain_type (fastype_of u'));
  1082     val lhs = mk_comp (u $ f) (u' $ f');
  1083     val rhs =
  1084       if comp
  1085       then u $ mk_comp f f'
  1086       else mk_comp (u' $ f') (u $ f);
  1087     val prop = lhs === rhs;
  1088     val othm =
  1089       Goal.prove (ProofContext.init thy) [] [] prop
  1090         (fn _ =>
  1091           simp_tac defset 1 THEN
  1092           REPEAT_DETERM (IsTupleSupport.istuple_intros_tac 1) THEN
  1093           TRY (simp_tac (HOL_ss addsimps [id_apply]) 1));
  1094     val dest = if comp then o_eq_dest_lhs else o_eq_dest;
  1095   in Drule.standard (othm RS dest) end;
  1096 
  1097 fun get_updupd_simps thy term defset =
  1098   let
  1099     val upd_funs = get_upd_funs term;
  1100     val cname = fst o dest_Const;
  1101     fun getswap u u' = get_updupd_simp thy defset u u' (cname u = cname u');
  1102     fun build_swaps_to_eq _ [] swaps = swaps
  1103       | build_swaps_to_eq upd (u :: us) swaps =
  1104           let
  1105             val key = (cname u, cname upd);
  1106             val newswaps =
  1107               if Symreltab.defined swaps key then swaps
  1108               else Symreltab.insert (K true) (key, getswap u upd) swaps;
  1109           in
  1110             if cname u = cname upd then newswaps
  1111             else build_swaps_to_eq upd us newswaps
  1112           end;
  1113     fun swaps_needed [] _ _ swaps = map snd (Symreltab.dest swaps)
  1114       | swaps_needed (u :: us) prev seen swaps =
  1115           if Symtab.defined seen (cname u)
  1116           then swaps_needed us prev seen (build_swaps_to_eq u prev swaps)
  1117           else swaps_needed us (u :: prev) (Symtab.insert (K true) (cname u, ()) seen) swaps;
  1118   in swaps_needed upd_funs [] Symtab.empty Symreltab.empty end;
  1119 
  1120 val named_cterm_instantiate = IsTupleSupport.named_cterm_instantiate;
  1121 
  1122 fun prove_unfold_defs thy ex_simps ex_simprs prop =
  1123   let
  1124     val defset = get_sel_upd_defs thy;
  1125     val prop' = Envir.beta_eta_contract prop;
  1126     val (lhs, _) = Logic.dest_equals (Logic.strip_assums_concl prop');
  1127     val (_, args) = strip_comb lhs;
  1128     val simps = (if length args = 1 then get_accupd_simps else get_updupd_simps) thy lhs defset;
  1129   in
  1130     Goal.prove (ProofContext.init thy) [] [] prop'
  1131       (fn _ =>
  1132         simp_tac (HOL_basic_ss addsimps (simps @ [K_record_comp])) 1 THEN
  1133         TRY (simp_tac (HOL_basic_ss addsimps ex_simps addsimprocs ex_simprs) 1))
  1134   end;
  1135 
  1136 
  1137 local
  1138 
  1139 fun eq (s1: string) (s2: string) = (s1 = s2);
  1140 
  1141 fun has_field extfields f T =
  1142   exists (fn (eN, _) => exists (eq f o fst) (Symtab.lookup_list extfields eN)) (dest_recTs T);
  1143 
  1144 fun K_skeleton n (T as Type (_, [_, kT])) (b as Bound i) (Abs (x, xT, t)) =
  1145       if null (loose_bnos t) then ((n, kT), (Abs (x, xT, Bound (i + 1)))) else ((n, T), b)
  1146   | K_skeleton n T b _ = ((n, T), b);
  1147 
  1148 in
  1149 
  1150 (* record_simproc *)
  1151 
  1152 (*
  1153   Simplify selections of an record update:
  1154     (1)  S (S_update k r) = k (S r)
  1155     (2)  S (X_update k r) = S r
  1156 
  1157   The simproc skips multiple updates at once, eg:
  1158    S (X_update x (Y_update y (S_update k r))) = k (S r)
  1159 
  1160   But be careful in (2) because of the extensibility of records.
  1161   - If S is a more-selector we have to make sure that the update on component
  1162     X does not affect the selected subrecord.
  1163   - If X is a more-selector we have to make sure that S is not in the updated
  1164     subrecord.
  1165 *)
  1166 val record_simproc =
  1167   Simplifier.simproc @{theory HOL} "record_simp" ["x"]
  1168     (fn thy => fn _ => fn t =>
  1169       (case t of
  1170         (sel as Const (s, Type (_, [_, rangeS]))) $
  1171             ((upd as Const (u, Type (_, [_, Type (_, [rT, _])]))) $ k $ r) =>
  1172           if is_selector thy s andalso is_some (get_updates thy u) then
  1173             let
  1174               val {sel_upd = {updates, ...}, extfields, ...} = RecordsData.get thy;
  1175 
  1176               fun mk_eq_terms ((upd as Const (u, Type(_, [kT, _]))) $ k $ r) =
  1177                     (case Symtab.lookup updates u of
  1178                       NONE => NONE
  1179                     | SOME u_name =>
  1180                         if u_name = s then
  1181                           (case mk_eq_terms r of
  1182                             NONE =>
  1183                               let
  1184                                 val rv = ("r", rT);
  1185                                 val rb = Bound 0;
  1186                                 val (kv, kb) = K_skeleton "k" kT (Bound 1) k;
  1187                               in SOME (upd $ kb $ rb, kb $ (sel $ rb), [kv, rv]) end
  1188                           | SOME (trm, trm', vars) =>
  1189                               let
  1190                                 val (kv, kb) = K_skeleton "k" kT (Bound (length vars)) k;
  1191                               in SOME (upd $ kb $ trm, kb $ trm', kv :: vars) end)
  1192                         else if has_field extfields u_name rangeS orelse
  1193                           has_field extfields s (domain_type kT) then NONE
  1194                         else
  1195                           (case mk_eq_terms r of
  1196                             SOME (trm, trm', vars) =>
  1197                               let val (kv, kb) = K_skeleton "k" kT (Bound (length vars)) k
  1198                               in SOME (upd $ kb $ trm, trm', kv :: vars) end
  1199                           | NONE =>
  1200                               let
  1201                                 val rv = ("r", rT);
  1202                                 val rb = Bound 0;
  1203                                 val (kv, kb) = K_skeleton "k" kT (Bound 1) k;
  1204                               in SOME (upd $ kb $ rb, sel $ rb, [kv, rv]) end))
  1205                 | mk_eq_terms _ = NONE;
  1206             in
  1207               (case mk_eq_terms (upd $ k $ r) of
  1208                 SOME (trm, trm', vars) =>
  1209                   SOME
  1210                     (prove_unfold_defs thy [] []
  1211                       (list_all (vars, Logic.mk_equals (sel $ trm, trm'))))
  1212               | NONE => NONE)
  1213             end
  1214           else NONE
  1215       | _ => NONE));
  1216 
  1217 fun get_upd_acc_cong_thm upd acc thy simpset =
  1218   let
  1219     val insts = [("upd", cterm_of thy upd), ("acc", cterm_of thy acc)];
  1220     val prop = Thm.concl_of (named_cterm_instantiate insts updacc_cong_triv);
  1221   in
  1222     Goal.prove (ProofContext.init thy) [] [] prop
  1223       (fn _ =>
  1224         simp_tac simpset 1 THEN
  1225         REPEAT_DETERM (IsTupleSupport.istuple_intros_tac 1) THEN
  1226         TRY (resolve_tac [updacc_cong_idI] 1))
  1227   end;
  1228 
  1229 
  1230 (* record_upd_simproc *)
  1231 
  1232 (*Simplify multiple updates:
  1233     (1) "N_update y (M_update g (N_update x (M_update f r))) =
  1234           (N_update (y o x) (M_update (g o f) r))"
  1235     (2)  "r(|M:= M r|) = r"
  1236 
  1237   In both cases "more" updates complicate matters: for this reason
  1238   we omit considering further updates if doing so would introduce
  1239   both a more update and an update to a field within it.*)
  1240 val record_upd_simproc =
  1241   Simplifier.simproc @{theory HOL} "record_upd_simp" ["x"]
  1242     (fn thy => fn _ => fn t =>
  1243       let
  1244         (*We can use more-updators with other updators as long
  1245           as none of the other updators go deeper than any more
  1246           updator. min here is the depth of the deepest other
  1247           updator, max the depth of the shallowest more updator.*)
  1248         fun include_depth (dep, true) (min, max) =
  1249               if min <= dep
  1250               then SOME (min, if dep <= max orelse max = ~1 then dep else max)
  1251               else NONE
  1252           | include_depth (dep, false) (min, max) =
  1253               if dep <= max orelse max = ~1
  1254               then SOME (if min <= dep then dep else min, max)
  1255               else NONE;
  1256 
  1257         fun getupdseq (term as (upd as Const (u, _)) $ f $ tm) min max =
  1258               (case get_update_details u thy of
  1259                 SOME (s, dep, ismore) =>
  1260                   (case include_depth (dep, ismore) (min, max) of
  1261                     SOME (min', max') =>
  1262                       let val (us, bs, _) = getupdseq tm min' max'
  1263                       in ((upd, s, f) :: us, bs, fastype_of term) end
  1264                   | NONE => ([], term, HOLogic.unitT))
  1265               | NONE => ([], term, HOLogic.unitT))
  1266           | getupdseq term _ _ = ([], term, HOLogic.unitT);
  1267 
  1268         val (upds, base, baseT) = getupdseq t 0 ~1;
  1269 
  1270         fun is_upd_noop s (Abs (n, T, Const (s', T') $ tm')) tm =
  1271               if s = s' andalso null (loose_bnos tm')
  1272                 andalso subst_bound (HOLogic.unit, tm') = tm
  1273               then (true, Abs (n, T, Const (s', T') $ Bound 1))
  1274               else (false, HOLogic.unit)
  1275           | is_upd_noop _ _ _ = (false, HOLogic.unit);
  1276 
  1277         fun get_noop_simps (upd as Const _) (Abs (_, _, (acc as Const _) $ _)) =
  1278           let
  1279             val ss = get_sel_upd_defs thy;
  1280             val uathm = get_upd_acc_cong_thm upd acc thy ss;
  1281           in
  1282            [Drule.standard (uathm RS updacc_noopE),
  1283             Drule.standard (uathm RS updacc_noop_compE)]
  1284           end;
  1285 
  1286         (*If f is constant then (f o g) = f.  We know that K_skeleton
  1287           only returns constant abstractions thus when we see an
  1288           abstraction we can discard inner updates.*)
  1289         fun add_upd (f as Abs _) fs = [f]
  1290           | add_upd f fs = (f :: fs);
  1291 
  1292         (*mk_updterm returns
  1293           (orig-term-skeleton, simplified-skeleton,
  1294             variables, duplicate-updates, simp-flag, noop-simps)
  1295 
  1296           where duplicate-updates is a table used to pass upward
  1297           the list of update functions which can be composed
  1298           into an update above them, simp-flag indicates whether
  1299           any simplification was achieved, and noop-simps are
  1300           used for eliminating case (2) defined above*)
  1301         fun mk_updterm ((upd as Const (u, T), s, f) :: upds) above term =
  1302               let
  1303                 val (lhs, rhs, vars, dups, simp, noops) =
  1304                   mk_updterm upds (Symtab.update (u, ()) above) term;
  1305                 val (fvar, skelf) =
  1306                   K_skeleton (Long_Name.base_name s) (domain_type T) (Bound (length vars)) f;
  1307                 val (isnoop, skelf') = is_upd_noop s f term;
  1308                 val funT = domain_type T;
  1309                 fun mk_comp_local (f, f') = Const ("Fun.comp", funT --> funT --> funT) $ f $ f';
  1310               in
  1311                 if isnoop then
  1312                   (upd $ skelf' $ lhs, rhs, vars,
  1313                     Symtab.update (u, []) dups, true,
  1314                     if Symtab.defined noops u then noops
  1315                     else Symtab.update (u, get_noop_simps upd skelf') noops)
  1316                 else if Symtab.defined above u then
  1317                   (upd $ skelf $ lhs, rhs, fvar :: vars,
  1318                     Symtab.map_default (u, []) (add_upd skelf) dups,
  1319                     true, noops)
  1320                 else
  1321                   (case Symtab.lookup dups u of
  1322                     SOME fs =>
  1323                      (upd $ skelf $ lhs,
  1324                       upd $ foldr1 mk_comp_local (add_upd skelf fs) $ rhs,
  1325                       fvar :: vars, dups, true, noops)
  1326                   | NONE => (upd $ skelf $ lhs, upd $ skelf $ rhs, fvar :: vars, dups, simp, noops))
  1327               end
  1328           | mk_updterm [] _ _ =
  1329               (Bound 0, Bound 0, [("r", baseT)], Symtab.empty, false, Symtab.empty)
  1330           | mk_updterm us _ _ = raise TERM ("mk_updterm match", map (fn (x, _, _) => x) us);
  1331 
  1332         val (lhs, rhs, vars, _, simp, noops) = mk_updterm upds Symtab.empty base;
  1333         val noops' = maps snd (Symtab.dest noops);
  1334       in
  1335         if simp then
  1336           SOME
  1337             (prove_unfold_defs thy noops' [record_simproc]
  1338               (list_all (vars, Logic.mk_equals (lhs, rhs))))
  1339         else NONE
  1340       end);
  1341 
  1342 end;
  1343 
  1344 
  1345 (* record_eq_simproc *)
  1346 
  1347 (*Look up the most specific record-equality.
  1348 
  1349  Note on efficiency:
  1350  Testing equality of records boils down to the test of equality of all components.
  1351  Therefore the complexity is: #components * complexity for single component.
  1352  Especially if a record has a lot of components it may be better to split up
  1353  the record first and do simplification on that (record_split_simp_tac).
  1354  e.g. r(|lots of updates|) = x
  1355 
  1356              record_eq_simproc          record_split_simp_tac
  1357  Complexity: #components * #updates     #updates
  1358 *)
  1359 val record_eq_simproc =
  1360   Simplifier.simproc @{theory HOL} "record_eq_simp" ["r = s"]
  1361     (fn thy => fn _ => fn t =>
  1362       (case t of Const ("op =", Type (_, [T, _])) $ _ $ _ =>
  1363         (case rec_id ~1 T of
  1364           "" => NONE
  1365         | name =>
  1366             (case get_equalities thy name of
  1367               NONE => NONE
  1368             | SOME thm => SOME (thm RS Eq_TrueI)))
  1369       | _ => NONE));
  1370 
  1371 
  1372 (* record_split_simproc *)
  1373 
  1374 (*Split quantified occurrences of records, for which P holds.  P can peek on the
  1375   subterm starting at the quantified occurrence of the record (including the quantifier):
  1376     P t = 0: do not split
  1377     P t = ~1: completely split
  1378     P t > 0: split up to given bound of record extensions.*)
  1379 fun record_split_simproc P =
  1380   Simplifier.simproc @{theory HOL} "record_split_simp" ["x"]
  1381     (fn thy => fn _ => fn t =>
  1382       (case t of
  1383         Const (quantifier, Type (_, [Type (_, [T, _]), _])) $ _ =>
  1384           if quantifier = "All" orelse quantifier = "all" orelse quantifier = "Ex" then
  1385             (case rec_id ~1 T of
  1386               "" => NONE
  1387             | _ =>
  1388                 let val split = P t in
  1389                   if split <> 0 then
  1390                     (case get_splits thy (rec_id split T) of
  1391                       NONE => NONE
  1392                     | SOME (all_thm, All_thm, Ex_thm, _) =>
  1393                         SOME
  1394                           (case quantifier of
  1395                             "all" => all_thm
  1396                           | "All" => All_thm RS eq_reflection
  1397                           | "Ex" => Ex_thm RS eq_reflection
  1398                           | _ => error "record_split_simproc"))
  1399                   else NONE
  1400                 end)
  1401           else NONE
  1402       | _ => NONE));
  1403 
  1404 val record_ex_sel_eq_simproc =
  1405   Simplifier.simproc @{theory HOL} "record_ex_sel_eq_simproc" ["Ex t"]
  1406     (fn thy => fn ss => fn t =>
  1407       let
  1408         fun prove prop =
  1409           prove_global true thy [] prop
  1410             (fn _ => simp_tac (Simplifier.inherit_context ss (get_simpset thy)
  1411                 addsimps simp_thms addsimprocs [record_split_simproc (K ~1)]) 1);
  1412 
  1413         fun mkeq (lr, Teq, (sel, Tsel), x) i =
  1414           if is_selector thy sel then
  1415             let
  1416               val x' =
  1417                 if not (loose_bvar1 (x, 0))
  1418                 then Free ("x" ^ string_of_int i, range_type Tsel)
  1419                 else raise TERM ("", [x]);
  1420               val sel' = Const (sel, Tsel) $ Bound 0;
  1421               val (l, r) = if lr then (sel', x') else (x', sel');
  1422             in Const ("op =", Teq) $ l $ r end
  1423           else raise TERM ("", [Const (sel, Tsel)]);
  1424 
  1425         fun dest_sel_eq (Const ("op =", Teq) $ (Const (sel, Tsel) $ Bound 0) $ X) =
  1426               (true, Teq, (sel, Tsel), X)
  1427           | dest_sel_eq (Const ("op =", Teq) $ X $ (Const (sel, Tsel) $ Bound 0)) =
  1428               (false, Teq, (sel, Tsel), X)
  1429           | dest_sel_eq _ = raise TERM ("", []);
  1430       in
  1431         (case t of
  1432           Const ("Ex", Tex) $ Abs (s, T, t) =>
  1433            (let
  1434               val eq = mkeq (dest_sel_eq t) 0;
  1435               val prop =
  1436                 list_all ([("r", T)],
  1437                   Logic.mk_equals (Const ("Ex", Tex) $ Abs (s, T, eq), HOLogic.true_const));
  1438             in SOME (prove prop) end
  1439             handle TERM _ => NONE)
  1440         | _ => NONE)
  1441       end);
  1442 
  1443 
  1444 (* record_split_simp_tac *)
  1445 
  1446 (*Split (and simplify) all records in the goal for which P holds.
  1447   For quantified occurrences of a record
  1448   P can peek on the whole subterm (including the quantifier); for free variables P
  1449   can only peek on the variable itself.
  1450   P t = 0: do not split
  1451   P t = ~1: completely split
  1452   P t > 0: split up to given bound of record extensions.*)
  1453 fun record_split_simp_tac thms P = CSUBGOAL (fn (cgoal, i) =>
  1454   let
  1455     val thy = Thm.theory_of_cterm cgoal;
  1456 
  1457     val goal = term_of cgoal;
  1458     val frees = filter (is_recT o #2) (Term.add_frees goal []);
  1459 
  1460     val has_rec = exists_Const
  1461       (fn (s, Type (_, [Type (_, [T, _]), _])) =>
  1462           (s = "all" orelse s = "All" orelse s = "Ex") andalso is_recT T
  1463         | _ => false);
  1464 
  1465     fun mk_split_free_tac free induct_thm i =
  1466       let
  1467         val cfree = cterm_of thy free;
  1468         val _$ (_ $ r) = concl_of induct_thm;
  1469         val crec = cterm_of thy r;
  1470         val thm = cterm_instantiate [(crec, cfree)] induct_thm;
  1471       in
  1472         simp_tac (HOL_basic_ss addsimps @{thms induct_atomize}) i THEN
  1473         rtac thm i THEN
  1474         simp_tac (HOL_basic_ss addsimps @{thms induct_rulify}) i
  1475       end;
  1476 
  1477     val split_frees_tacs =
  1478       frees |> map_filter (fn (x, T) =>
  1479         (case rec_id ~1 T of
  1480           "" => NONE
  1481         | _ =>
  1482             let
  1483               val free = Free (x, T);
  1484               val split = P free;
  1485             in
  1486               if split <> 0 then
  1487                 (case get_splits thy (rec_id split T) of
  1488                   NONE => NONE
  1489                 | SOME (_, _, _, induct_thm) =>
  1490                     SOME (mk_split_free_tac free induct_thm i))
  1491               else NONE
  1492             end));
  1493 
  1494     val simprocs = if has_rec goal then [record_split_simproc P] else [];
  1495     val thms' = K_comp_convs @ thms;
  1496   in
  1497     EVERY split_frees_tacs THEN
  1498     Simplifier.full_simp_tac (get_simpset thy addsimps thms' addsimprocs simprocs) i
  1499   end);
  1500 
  1501 
  1502 (* record_split_tac *)
  1503 
  1504 (*Split all records in the goal, which are quantified by ! or !!.*)
  1505 val record_split_tac = CSUBGOAL (fn (cgoal, i) =>
  1506   let
  1507     val goal = term_of cgoal;
  1508 
  1509     val has_rec = exists_Const
  1510       (fn (s, Type (_, [Type (_, [T, _]), _])) =>
  1511           (s = "all" orelse s = "All") andalso is_recT T
  1512         | _ => false);
  1513 
  1514     fun is_all t =
  1515       (case t of
  1516         Const (quantifier, _) $ _ =>
  1517           if quantifier = "All" orelse quantifier = "all" then ~1 else 0
  1518       | _ => 0);
  1519   in
  1520     if has_rec goal then
  1521       Simplifier.full_simp_tac (HOL_basic_ss addsimprocs [record_split_simproc is_all]) i
  1522     else no_tac
  1523   end);
  1524 
  1525 
  1526 (* wrapper *)
  1527 
  1528 val record_split_name = "record_split_tac";
  1529 val record_split_wrapper = (record_split_name, fn tac => record_split_tac ORELSE' tac);
  1530 
  1531 
  1532 
  1533 (** theory extender interface **)
  1534 
  1535 (* prepare arguments *)
  1536 
  1537 fun read_raw_parent ctxt raw_T =
  1538   (case ProofContext.read_typ_abbrev ctxt raw_T of
  1539     Type (name, Ts) => (Ts, name)
  1540   | T => error ("Bad parent record specification: " ^ Syntax.string_of_typ ctxt T));
  1541 
  1542 fun read_typ ctxt raw_T env =
  1543   let
  1544     val ctxt' = fold (Variable.declare_typ o TFree) env ctxt;
  1545     val T = Syntax.read_typ ctxt' raw_T;
  1546     val env' = OldTerm.add_typ_tfrees (T, env);
  1547   in (T, env') end;
  1548 
  1549 fun cert_typ ctxt raw_T env =
  1550   let
  1551     val thy = ProofContext.theory_of ctxt;
  1552     val T = Type.no_tvars (Sign.certify_typ thy raw_T)
  1553       handle TYPE (msg, _, _) => error msg;
  1554     val env' = OldTerm.add_typ_tfrees (T, env);
  1555   in (T, env') end;
  1556 
  1557 
  1558 (* attributes *)
  1559 
  1560 fun case_names_fields x = Rule_Cases.case_names ["fields"] x;
  1561 fun induct_type_global name = [case_names_fields, Induct.induct_type name];
  1562 fun cases_type_global name = [case_names_fields, Induct.cases_type name];
  1563 
  1564 
  1565 (* tactics *)
  1566 
  1567 fun simp_all_tac ss simps = ALLGOALS (Simplifier.asm_full_simp_tac (ss addsimps simps));
  1568 
  1569 (*Do case analysis / induction according to rule on last parameter of ith subgoal
  1570   (or on s if there are no parameters).
  1571   Instatiation of record variable (and predicate) in rule is calculated to
  1572   avoid problems with higher order unification.*)
  1573 fun try_param_tac s rule = CSUBGOAL (fn (cgoal, i) =>
  1574   let
  1575     val cert = Thm.cterm_of (Thm.theory_of_cterm cgoal);
  1576 
  1577     val g = Thm.term_of cgoal;
  1578     val params = Logic.strip_params g;
  1579     val concl = HOLogic.dest_Trueprop (Logic.strip_assums_concl g);
  1580     val rule' = Thm.lift_rule cgoal rule;
  1581     val (P, ys) = strip_comb (HOLogic.dest_Trueprop
  1582       (Logic.strip_assums_concl (prop_of rule')));
  1583     (*ca indicates if rule is a case analysis or induction rule*)
  1584     val (x, ca) =
  1585       (case rev (drop (length params) ys) of
  1586         [] => (head_of (fst (HOLogic.dest_eq (HOLogic.dest_Trueprop
  1587           (hd (rev (Logic.strip_assums_hyp (hd (prems_of rule')))))))), true)
  1588       | [x] => (head_of x, false));
  1589     val rule'' = cterm_instantiate (map (pairself cert)
  1590       (case rev params of
  1591         [] =>
  1592           (case AList.lookup (op =) (Term.add_frees g []) s of
  1593             NONE => sys_error "try_param_tac: no such variable"
  1594           | SOME T => [(P, if ca then concl else lambda (Free (s, T)) concl), (x, Free (s, T))])
  1595       | (_, T) :: _ =>
  1596           [(P, list_abs (params, if ca then concl else incr_boundvars 1 (Abs (s, T, concl)))),
  1597             (x, list_abs (params, Bound 0))])) rule';
  1598   in compose_tac (false, rule'', nprems_of rule) i end);
  1599 
  1600 
  1601 fun extension_definition name fields alphas zeta moreT more vars thy =
  1602   let
  1603     val base = Long_Name.base_name;
  1604     val fieldTs = map snd fields;
  1605     val alphas_zeta = alphas @ [zeta];
  1606     val alphas_zetaTs = map (fn a => TFree (a, HOLogic.typeS)) alphas_zeta;
  1607     val extT_name = suffix ext_typeN name
  1608     val extT = Type (extT_name, alphas_zetaTs);
  1609     val fields_moreTs = fieldTs @ [moreT];
  1610 
  1611 
  1612     (*before doing anything else, create the tree of new types
  1613       that will back the record extension*)
  1614 
  1615     val mktreeV = Balanced_Tree.make IsTupleSupport.mk_cons_tuple;
  1616 
  1617     fun mk_istuple (left, right) (thy, i) =
  1618       let
  1619         val suff = if i = 0 then ext_typeN else inner_typeN ^ string_of_int i;
  1620         val nm = suffix suff (Long_Name.base_name name);
  1621         val ((_, cons), thy') =
  1622           IsTupleSupport.add_istuple_type
  1623             (nm, alphas_zeta) (fastype_of left, fastype_of right) thy;
  1624       in
  1625         (cons $ left $ right, (thy', i + 1))
  1626       end;
  1627 
  1628     (*trying to create a 1-element istuple will fail, and is pointless anyway*)
  1629     fun mk_even_istuple [arg] = pair arg
  1630       | mk_even_istuple args = mk_istuple (IsTupleSupport.dest_cons_tuple (mktreeV args));
  1631 
  1632     fun build_meta_tree_type i thy vars more =
  1633       let val len = length vars in
  1634         if len < 1 then raise TYPE ("meta_tree_type args too short", [], vars)
  1635         else if len > 16 then
  1636           let
  1637             fun group16 [] = []
  1638               | group16 xs = take 16 xs :: group16 (drop 16 xs);
  1639             val vars' = group16 vars;
  1640             val (composites, (thy', i')) = fold_map mk_even_istuple vars' (thy, i);
  1641           in
  1642             build_meta_tree_type i' thy' composites more
  1643           end
  1644         else
  1645           let val (term, (thy', _)) = mk_istuple (mktreeV vars, more) (thy, 0)
  1646           in (term, thy') end
  1647       end;
  1648 
  1649     val _ = timing_msg "record extension preparing definitions";
  1650 
  1651 
  1652     (* 1st stage part 1: introduce the tree of new types *)
  1653 
  1654     fun get_meta_tree () = build_meta_tree_type 1 thy vars more;
  1655     val (ext_body, typ_thy) =
  1656       timeit_msg "record extension nested type def:" get_meta_tree;
  1657 
  1658 
  1659     (* prepare declarations and definitions *)
  1660 
  1661     (*fields constructor*)
  1662     val ext_decl = mk_extC (name, extT) fields_moreTs;
  1663     val ext_spec = list_comb (Const ext_decl, vars @ [more]) :== ext_body;
  1664 
  1665     fun mk_ext args = list_comb (Const ext_decl, args);
  1666 
  1667 
  1668     (* 1st stage part 2: define the ext constant *)
  1669 
  1670     fun mk_defs () =
  1671       typ_thy
  1672       |> Sign.add_consts_i [Syntax.no_syn (apfst (Binding.name o base) ext_decl)]
  1673       |> PureThy.add_defs false [Thm.no_attributes (apfst Binding.name ext_spec)]
  1674       ||> Theory.checkpoint
  1675     val ([ext_def], defs_thy) =
  1676       timeit_msg "record extension constructor def:" mk_defs;
  1677 
  1678 
  1679     (* prepare propositions *)
  1680 
  1681     val _ = timing_msg "record extension preparing propositions";
  1682     val vars_more = vars @ [more];
  1683     val variants = map (fn Free (x, _) => x) vars_more;
  1684     val ext = mk_ext vars_more;
  1685     val s = Free (rN, extT);
  1686     val P = Free (Name.variant variants "P", extT --> HOLogic.boolT);
  1687 
  1688     val inject_prop =
  1689       let val vars_more' = map (fn (Free (x, T)) => Free (x ^ "'", T)) vars_more in
  1690         HOLogic.mk_conj (HOLogic.eq_const extT $
  1691           mk_ext vars_more $ mk_ext vars_more', HOLogic.true_const)
  1692         ===
  1693         foldr1 HOLogic.mk_conj
  1694           (map HOLogic.mk_eq (vars_more ~~ vars_more') @ [HOLogic.true_const])
  1695       end;
  1696 
  1697     val induct_prop =
  1698       (All (map dest_Free vars_more) (Trueprop (P $ ext)), Trueprop (P $ s));
  1699 
  1700     val split_meta_prop =
  1701       let val P = Free (Name.variant variants "P", extT --> Term.propT) in
  1702         Logic.mk_equals
  1703          (All [dest_Free s] (P $ s), All (map dest_Free vars_more) (P $ ext))
  1704       end;
  1705 
  1706     val prove_standard = prove_future_global true defs_thy;
  1707 
  1708     fun inject_prf () =
  1709       simplify HOL_ss
  1710         (prove_standard [] inject_prop
  1711           (fn _ =>
  1712             simp_tac (HOL_basic_ss addsimps [ext_def]) 1 THEN
  1713             REPEAT_DETERM
  1714               (rtac refl_conj_eq 1 ORELSE
  1715                 IsTupleSupport.istuple_intros_tac 1 ORELSE
  1716                 rtac refl 1)));
  1717 
  1718     val inject = timeit_msg "record extension inject proof:" inject_prf;
  1719 
  1720     (*We need a surjection property r = (| f = f r, g = g r ... |)
  1721       to prove other theorems. We haven't given names to the accessors
  1722       f, g etc yet however, so we generate an ext structure with
  1723       free variables as all arguments and allow the introduction tactic to
  1724       operate on it as far as it can. We then use Drule.standard to convert
  1725       the free variables into unifiable variables and unify them with
  1726       (roughly) the definition of the accessor.*)
  1727     fun surject_prf () =
  1728       let
  1729         val cterm_ext = cterm_of defs_thy ext;
  1730         val start = named_cterm_instantiate [("y", cterm_ext)] surject_assist_idE;
  1731         val tactic1 =
  1732           simp_tac (HOL_basic_ss addsimps [ext_def]) 1 THEN
  1733           REPEAT_ALL_NEW IsTupleSupport.istuple_intros_tac 1;
  1734         val tactic2 = REPEAT (rtac surject_assistI 1 THEN rtac refl 1);
  1735         val [halfway] = Seq.list_of (tactic1 start);
  1736         val [surject] = Seq.list_of (tactic2 (Drule.standard halfway));
  1737       in
  1738         surject
  1739       end;
  1740     val surject = timeit_msg "record extension surjective proof:" surject_prf;
  1741 
  1742     fun split_meta_prf () =
  1743       prove_standard [] split_meta_prop
  1744         (fn _ =>
  1745           EVERY1
  1746            [rtac equal_intr_rule, Goal.norm_hhf_tac,
  1747             etac meta_allE, atac,
  1748             rtac (prop_subst OF [surject]),
  1749             REPEAT o etac meta_allE, atac]);
  1750     val split_meta = timeit_msg "record extension split_meta proof:" split_meta_prf;
  1751 
  1752     fun induct_prf () =
  1753       let val (assm, concl) = induct_prop in
  1754         prove_standard [assm] concl
  1755           (fn {prems, ...} =>
  1756             cut_rules_tac [split_meta RS Drule.equal_elim_rule2] 1 THEN
  1757             resolve_tac prems 2 THEN
  1758             asm_simp_tac HOL_ss 1)
  1759       end;
  1760     val induct = timeit_msg "record extension induct proof:" induct_prf;
  1761 
  1762     val ([inject', induct', surjective', split_meta'], thm_thy) =
  1763       defs_thy
  1764       |> PureThy.add_thms (map (Thm.no_attributes o apfst Binding.name)
  1765            [("ext_inject", inject),
  1766             ("ext_induct", induct),
  1767             ("ext_surjective", surject),
  1768             ("ext_split", split_meta)])
  1769       ||> Code.add_default_eqn ext_def;
  1770 
  1771   in (thm_thy, extT, induct', inject', split_meta', ext_def) end;
  1772 
  1773 fun chunks [] [] = []
  1774   | chunks [] xs = [xs]
  1775   | chunks (l :: ls) xs = take l xs :: chunks ls (drop l xs);
  1776 
  1777 fun chop_last [] = error "chop_last: list should not be empty"
  1778   | chop_last [x] = ([], x)
  1779   | chop_last (x :: xs) = let val (tl, l) = chop_last xs in (x :: tl, l) end;
  1780 
  1781 fun subst_last _ [] = error "subst_last: list should not be empty"
  1782   | subst_last s [_] = [s]
  1783   | subst_last s (x :: xs) = x :: subst_last s xs;
  1784 
  1785 
  1786 (* mk_recordT *)
  1787 
  1788 (*builds up the record type from the current extension tpye extT and a list
  1789   of parent extensions, starting with the root of the record hierarchy*)
  1790 fun mk_recordT extT =
  1791   fold_rev (fn (parent, Ts) => fn T => Type (parent, subst_last T Ts)) extT;
  1792 
  1793 
  1794 fun obj_to_meta_all thm =
  1795   let
  1796     fun E thm =  (* FIXME proper name *)
  1797       (case (SOME (spec OF [thm]) handle THM _ => NONE) of
  1798         SOME thm' => E thm'
  1799       | NONE => thm);
  1800     val th1 = E thm;
  1801     val th2 = Drule.forall_intr_vars th1;
  1802   in th2 end;
  1803 
  1804 fun meta_to_obj_all thm =
  1805   let
  1806     val thy = Thm.theory_of_thm thm;
  1807     val prop = Thm.prop_of thm;
  1808     val params = Logic.strip_params prop;
  1809     val concl = HOLogic.dest_Trueprop (Logic.strip_assums_concl prop);
  1810     val ct = cterm_of thy (HOLogic.mk_Trueprop (HOLogic.list_all (params, concl)));
  1811     val thm' = Seq.hd (REPEAT (rtac allI 1) (Thm.trivial ct));
  1812   in Thm.implies_elim thm' thm end;
  1813 
  1814 
  1815 (* record_definition *)
  1816 
  1817 fun record_definition (args, bname) parent (parents: parent_info list) raw_fields thy =
  1818   let
  1819     val external_names = Name_Space.external_names (Sign.naming_of thy);
  1820 
  1821     val alphas = map fst args;
  1822     val name = Sign.full_bname thy bname;
  1823     val full = Sign.full_bname_path thy bname;
  1824     val base = Long_Name.base_name;
  1825 
  1826     val (bfields, field_syntax) =
  1827       split_list (map (fn (x, T, mx) => ((x, T), mx)) raw_fields);
  1828 
  1829     val parent_fields = maps #fields parents;
  1830     val parent_chunks = map (length o #fields) parents;
  1831     val parent_names = map fst parent_fields;
  1832     val parent_types = map snd parent_fields;
  1833     val parent_fields_len = length parent_fields;
  1834     val parent_variants = Name.variant_list [moreN, rN, rN ^ "'", wN] (map base parent_names);
  1835     val parent_vars = ListPair.map Free (parent_variants, parent_types);
  1836     val parent_len = length parents;
  1837 
  1838     val fields = map (apfst full) bfields;
  1839     val names = map fst fields;
  1840     val extN = full bname;
  1841     val types = map snd fields;
  1842     val alphas_fields = fold Term.add_tfree_namesT types [];
  1843     val alphas_ext = inter (op =) alphas_fields alphas;
  1844     val len = length fields;
  1845     val variants =
  1846       Name.variant_list (moreN :: rN :: (rN ^ "'") :: wN :: parent_variants)
  1847         (map fst bfields);
  1848     val vars = ListPair.map Free (variants, types);
  1849     val named_vars = names ~~ vars;
  1850     val idxms = 0 upto len;
  1851 
  1852     val all_fields = parent_fields @ fields;
  1853     val all_types = parent_types @ types;
  1854     val all_variants = parent_variants @ variants;
  1855     val all_vars = parent_vars @ vars;
  1856     val all_named_vars = (parent_names ~~ parent_vars) @ named_vars;
  1857 
  1858 
  1859     val zeta = Name.variant alphas "'z";
  1860     val moreT = TFree (zeta, HOLogic.typeS);
  1861     val more = Free (moreN, moreT);
  1862     val full_moreN = full moreN;
  1863     val bfields_more = bfields @ [(moreN, moreT)];
  1864     val fields_more = fields @ [(full_moreN, moreT)];
  1865     val named_vars_more = named_vars @ [(full_moreN, more)];
  1866     val all_vars_more = all_vars @ [more];
  1867     val all_named_vars_more = all_named_vars @ [(full_moreN, more)];
  1868 
  1869 
  1870     (* 1st stage: extension_thy *)
  1871 
  1872     val (extension_thy, extT, ext_induct, ext_inject, ext_split, ext_def) =
  1873       thy
  1874       |> Sign.add_path bname
  1875       |> extension_definition extN fields alphas_ext zeta moreT more vars;
  1876 
  1877     val _ = timing_msg "record preparing definitions";
  1878     val Type extension_scheme = extT;
  1879     val extension_name = unsuffix ext_typeN (fst extension_scheme);
  1880     val extension = let val (n, Ts) = extension_scheme in (n, subst_last HOLogic.unitT Ts) end;
  1881     val extension_names = map (unsuffix ext_typeN o fst o #extension) parents @ [extN];
  1882     val extension_id = implode extension_names;
  1883 
  1884     fun rec_schemeT n = mk_recordT (map #extension (drop n parents)) extT;
  1885     val rec_schemeT0 = rec_schemeT 0;
  1886 
  1887     fun recT n =
  1888       let val (c, Ts) = extension in
  1889         mk_recordT (map #extension (drop n parents))
  1890           (Type (c, subst_last HOLogic.unitT Ts))
  1891       end;
  1892     val recT0 = recT 0;
  1893 
  1894     fun mk_rec args n =
  1895       let
  1896         val (args', more) = chop_last args;
  1897         fun mk_ext' ((name, T), args) more = mk_ext (name, T) (args @ [more]);
  1898         fun build Ts =
  1899           fold_rev mk_ext' (drop n ((extension_names ~~ Ts) ~~ chunks parent_chunks args'))
  1900             more;
  1901       in
  1902         if more = HOLogic.unit
  1903         then build (map_range recT (parent_len + 1))
  1904         else build (map_range rec_schemeT (parent_len + 1))
  1905       end;
  1906 
  1907     val r_rec0 = mk_rec all_vars_more 0;
  1908     val r_rec_unit0 = mk_rec (all_vars @ [HOLogic.unit]) 0;
  1909 
  1910     fun r n = Free (rN, rec_schemeT n)
  1911     val r0 = r 0;
  1912     fun r_unit n = Free (rN, recT n)
  1913     val r_unit0 = r_unit 0;
  1914     val w = Free (wN, rec_schemeT 0)
  1915 
  1916 
  1917     (* prepare print translation functions *)
  1918 
  1919     val field_tr's =
  1920       print_translation (distinct (op =) (maps external_names (full_moreN :: names)));
  1921 
  1922     val adv_ext_tr's =
  1923       let val trnames = external_names extN
  1924       in map (gen_record_tr') trnames end;
  1925 
  1926     val adv_record_type_abbr_tr's =
  1927       let
  1928         val trnames = external_names (hd extension_names);
  1929         val lastExt = unsuffix ext_typeN (fst extension);
  1930       in map (gen_record_type_abbr_tr' name alphas zeta lastExt rec_schemeT0) trnames end;
  1931 
  1932     val adv_record_type_tr's =
  1933       let
  1934         val trnames = if parent_len > 0 then external_names extN else [];
  1935         (*avoid conflict with adv_record_type_abbr_tr's*)
  1936       in map (gen_record_type_tr') trnames end;
  1937 
  1938 
  1939     (* prepare declarations *)
  1940 
  1941     val sel_decls = map (mk_selC rec_schemeT0) bfields_more;
  1942     val upd_decls = map (mk_updC updateN rec_schemeT0) bfields_more;
  1943     val make_decl = (makeN, all_types ---> recT0);
  1944     val fields_decl = (fields_selN, types ---> Type extension);
  1945     val extend_decl = (extendN, recT0 --> moreT --> rec_schemeT0);
  1946     val truncate_decl = (truncateN, rec_schemeT0 --> recT0);
  1947 
  1948     (* prepare definitions *)
  1949 
  1950     (*record (scheme) type abbreviation*)
  1951     val recordT_specs =
  1952       [(Binding.name (suffix schemeN bname), alphas @ [zeta], rec_schemeT0, Syntax.NoSyn),
  1953         (Binding.name bname, alphas, recT0, Syntax.NoSyn)];
  1954 
  1955     val ext_defs = ext_def :: map #extdef parents;
  1956 
  1957     (*Theorems from the istuple intros.
  1958       This is complex enough to deserve a full comment.
  1959       By unfolding ext_defs from r_rec0 we create a tree of constructor
  1960       calls (many of them Pair, but others as well). The introduction
  1961       rules for update_accessor_eq_assist can unify two different ways
  1962       on these constructors. If we take the complete result sequence of
  1963       running a the introduction tactic, we get one theorem for each upd/acc
  1964       pair, from which we can derive the bodies of our selector and
  1965       updator and their convs.*)
  1966     fun get_access_update_thms () =
  1967       let
  1968         val r_rec0_Vars =
  1969           let
  1970             (*pick variable indices of 1 to avoid possible variable
  1971               collisions with existing variables in updacc_eq_triv*)
  1972             fun to_Var (Free (c, T)) = Var ((c, 1), T);
  1973           in mk_rec (map to_Var all_vars_more) 0 end;
  1974 
  1975         val cterm_rec = cterm_of extension_thy r_rec0;
  1976         val cterm_vrs = cterm_of extension_thy r_rec0_Vars;
  1977         val insts = [("v", cterm_rec), ("v'", cterm_vrs)];
  1978         val init_thm = named_cterm_instantiate insts updacc_eq_triv;
  1979         val terminal = rtac updacc_eq_idI 1 THEN rtac refl 1;
  1980         val tactic =
  1981           simp_tac (HOL_basic_ss addsimps ext_defs) 1 THEN
  1982           REPEAT (IsTupleSupport.istuple_intros_tac 1 ORELSE terminal);
  1983         val updaccs = Seq.list_of (tactic init_thm);
  1984       in
  1985         (updaccs RL [updacc_accessor_eqE],
  1986          updaccs RL [updacc_updator_eqE],
  1987          updaccs RL [updacc_cong_from_eq])
  1988       end;
  1989     val (accessor_thms, updator_thms, upd_acc_cong_assists) =
  1990       timeit_msg "record getting tree access/updates:" get_access_update_thms;
  1991 
  1992     fun lastN xs = drop parent_fields_len xs;
  1993 
  1994     (*selectors*)
  1995     fun mk_sel_spec ((c, T), thm) =
  1996       let
  1997         val acc $ arg =
  1998           (fst o HOLogic.dest_eq o HOLogic.dest_Trueprop o Envir.beta_eta_contract o concl_of) thm;
  1999         val _ =
  2000           if (arg aconv r_rec0) then ()
  2001           else raise TERM ("mk_sel_spec: different arg", [arg]);
  2002       in
  2003         Const (mk_selC rec_schemeT0 (c, T)) :== acc
  2004       end;
  2005     val sel_specs = map mk_sel_spec (fields_more ~~ lastN accessor_thms);
  2006 
  2007     (*updates*)
  2008     fun mk_upd_spec ((c, T), thm) =
  2009       let
  2010         val (upd $ _ $ arg) =
  2011           (fst o HOLogic.dest_eq o HOLogic.dest_Trueprop o Envir.beta_eta_contract o concl_of) thm;
  2012         val _ =
  2013           if (arg aconv r_rec0) then ()
  2014           else raise TERM ("mk_sel_spec: different arg", [arg]);
  2015       in Const (mk_updC updateN rec_schemeT0 (c, T)) :== upd end;
  2016     val upd_specs = map mk_upd_spec (fields_more ~~ lastN updator_thms);
  2017 
  2018     (*derived operations*)
  2019     val make_spec = Const (full makeN, all_types ---> recT0) $$ all_vars :==
  2020       mk_rec (all_vars @ [HOLogic.unit]) 0;
  2021     val fields_spec = Const (full fields_selN, types ---> Type extension) $$ vars :==
  2022       mk_rec (all_vars @ [HOLogic.unit]) parent_len;
  2023     val extend_spec =
  2024       Const (full extendN, recT0-->moreT-->rec_schemeT0) $ r_unit0 $ more :==
  2025       mk_rec ((map (mk_sel r_unit0) all_fields) @ [more]) 0;
  2026     val truncate_spec = Const (full truncateN, rec_schemeT0 --> recT0) $ r0 :==
  2027       mk_rec ((map (mk_sel r0) all_fields) @ [HOLogic.unit]) 0;
  2028 
  2029 
  2030     (* 2st stage: defs_thy *)
  2031 
  2032     fun mk_defs () =
  2033       extension_thy
  2034       |> Sign.add_trfuns ([], [], field_tr's, [])
  2035       |> Sign.add_advanced_trfuns
  2036           ([], [], adv_ext_tr's @ adv_record_type_tr's @ adv_record_type_abbr_tr's, [])
  2037       |> Sign.parent_path
  2038       |> Sign.add_tyabbrs_i recordT_specs
  2039       |> Sign.add_path bname
  2040       |> Sign.add_consts_i
  2041           (map2 (fn (x, T) => fn mx => (Binding.name x, T, mx))
  2042             sel_decls (field_syntax @ [Syntax.NoSyn]))
  2043       |> (Sign.add_consts_i o map (fn (x, T) => (Binding.name x, T, Syntax.NoSyn)))
  2044           (upd_decls @ [make_decl, fields_decl, extend_decl, truncate_decl])
  2045       |> ((PureThy.add_defs false o map (Thm.no_attributes o apfst Binding.name)) sel_specs)
  2046       ||>> ((PureThy.add_defs false o map (Thm.no_attributes o apfst Binding.name)) upd_specs)
  2047       ||>> ((PureThy.add_defs false o map (Thm.no_attributes o apfst Binding.name))
  2048              [make_spec, fields_spec, extend_spec, truncate_spec])
  2049       |->
  2050         (fn defs as ((sel_defs, upd_defs), derived_defs) =>
  2051           fold Code.add_default_eqn sel_defs
  2052           #> fold Code.add_default_eqn upd_defs
  2053           #> fold Code.add_default_eqn derived_defs
  2054           #> pair defs)
  2055       ||> Theory.checkpoint
  2056     val (((sel_defs, upd_defs), derived_defs), defs_thy) =
  2057       timeit_msg "record trfuns/tyabbrs/selectors/updates/make/fields/extend/truncate defs:"
  2058         mk_defs;
  2059 
  2060     (* prepare propositions *)
  2061     val _ = timing_msg "record preparing propositions";
  2062     val P = Free (Name.variant all_variants "P", rec_schemeT0 --> HOLogic.boolT);
  2063     val C = Free (Name.variant all_variants "C", HOLogic.boolT);
  2064     val P_unit = Free (Name.variant all_variants "P", recT0 --> HOLogic.boolT);
  2065 
  2066     (*selectors*)
  2067     val sel_conv_props =
  2068        map (fn (c, x as Free (_, T)) => mk_sel r_rec0 (c, T) === x) named_vars_more;
  2069 
  2070     (*updates*)
  2071     fun mk_upd_prop (i, (c, T)) =
  2072       let
  2073         val x' = Free (Name.variant all_variants (base c ^ "'"), T --> T);
  2074         val n = parent_fields_len + i;
  2075         val args' = nth_map n (K (x' $ nth all_vars_more n)) all_vars_more
  2076       in mk_upd updateN c x' r_rec0 === mk_rec args' 0 end;
  2077     val upd_conv_props = ListPair.map mk_upd_prop (idxms, fields_more);
  2078 
  2079     (*induct*)
  2080     val induct_scheme_prop =
  2081       All (map dest_Free all_vars_more) (Trueprop (P $ r_rec0)) ==> Trueprop (P $ r0);
  2082     val induct_prop =
  2083       (All (map dest_Free all_vars) (Trueprop (P_unit $ r_rec_unit0)),
  2084         Trueprop (P_unit $ r_unit0));
  2085 
  2086     (*surjective*)
  2087     val surjective_prop =
  2088       let val args = map (fn (c, Free (_, T)) => mk_sel r0 (c, T)) all_named_vars_more
  2089       in r0 === mk_rec args 0 end;
  2090 
  2091     (*cases*)
  2092     val cases_scheme_prop =
  2093       (All (map dest_Free all_vars_more) ((r0 === r_rec0) ==> Trueprop C))
  2094         ==> Trueprop C;
  2095 
  2096     val cases_prop =
  2097       (All (map dest_Free all_vars) ((r_unit0 === r_rec_unit0) ==> Trueprop C))
  2098          ==> Trueprop C;
  2099 
  2100     (*split*)
  2101     val split_meta_prop =
  2102       let val P = Free (Name.variant all_variants "P", rec_schemeT0-->Term.propT) in
  2103         Logic.mk_equals
  2104          (All [dest_Free r0] (P $ r0), All (map dest_Free all_vars_more) (P $ r_rec0))
  2105       end;
  2106 
  2107     val split_object_prop =
  2108       let val ALL = fold_rev (fn (v, T) => fn t => HOLogic.mk_all (v, T, t))
  2109       in ALL [dest_Free r0] (P $ r0) === ALL (map dest_Free all_vars_more) (P $ r_rec0) end;
  2110 
  2111     val split_ex_prop =
  2112       let val EX = fold_rev (fn (v, T) => fn t => HOLogic.mk_exists (v, T, t))
  2113       in EX [dest_Free r0] (P $ r0) === EX (map dest_Free all_vars_more) (P $ r_rec0) end;
  2114 
  2115     (*equality*)
  2116     val equality_prop =
  2117       let
  2118         val s' = Free (rN ^ "'", rec_schemeT0);
  2119         fun mk_sel_eq (c, Free (_, T)) = mk_sel r0 (c, T) === mk_sel s' (c, T);
  2120         val seleqs = map mk_sel_eq all_named_vars_more;
  2121       in All (map dest_Free [r0, s']) (Logic.list_implies (seleqs, r0 === s')) end;
  2122 
  2123 
  2124     (* 3rd stage: thms_thy *)
  2125 
  2126     fun prove stndrd = prove_future_global stndrd defs_thy;
  2127     val prove_standard = prove_future_global true defs_thy;
  2128     val future_forward_prf = future_forward_prf_standard defs_thy;
  2129 
  2130     fun prove_simp stndrd ss simps =
  2131       let val tac = simp_all_tac ss simps
  2132       in fn prop => prove stndrd [] prop (K tac) end;
  2133 
  2134     val ss = get_simpset defs_thy;
  2135 
  2136     fun sel_convs_prf () =
  2137       map (prove_simp false ss (sel_defs @ accessor_thms)) sel_conv_props;
  2138     val sel_convs = timeit_msg "record sel_convs proof:" sel_convs_prf;
  2139     fun sel_convs_standard_prf () = map Drule.standard sel_convs
  2140     val sel_convs_standard =
  2141       timeit_msg "record sel_convs_standard proof:" sel_convs_standard_prf;
  2142 
  2143     fun upd_convs_prf () =
  2144       map (prove_simp false ss (upd_defs @ updator_thms)) upd_conv_props;
  2145     val upd_convs = timeit_msg "record upd_convs proof:" upd_convs_prf;
  2146     fun upd_convs_standard_prf () = map Drule.standard upd_convs
  2147     val upd_convs_standard =
  2148       timeit_msg "record upd_convs_standard proof:" upd_convs_standard_prf;
  2149 
  2150     fun get_upd_acc_congs () =
  2151       let
  2152         val symdefs = map symmetric (sel_defs @ upd_defs);
  2153         val fold_ss = HOL_basic_ss addsimps symdefs;
  2154         val ua_congs = map (Drule.standard o simplify fold_ss) upd_acc_cong_assists;
  2155       in (ua_congs RL [updacc_foldE], ua_congs RL [updacc_unfoldE]) end;
  2156     val (fold_congs, unfold_congs) =
  2157       timeit_msg "record upd fold/unfold congs:" get_upd_acc_congs;
  2158 
  2159     val parent_induct = if null parents then [] else [#induct (hd (rev parents))];
  2160 
  2161     fun induct_scheme_prf () =
  2162       prove_standard [] induct_scheme_prop
  2163         (fn _ =>
  2164           EVERY
  2165            [if null parent_induct then all_tac else try_param_tac rN (hd parent_induct) 1,
  2166             try_param_tac rN ext_induct 1,
  2167             asm_simp_tac HOL_basic_ss 1]);
  2168     val induct_scheme = timeit_msg "record induct_scheme proof:" induct_scheme_prf;
  2169 
  2170     fun induct_prf () =
  2171       let val (assm, concl) = induct_prop in
  2172         prove_standard [assm] concl (fn {prems, ...} =>
  2173           try_param_tac rN induct_scheme 1
  2174           THEN try_param_tac "more" @{thm unit.induct} 1
  2175           THEN resolve_tac prems 1)
  2176       end;
  2177     val induct = timeit_msg "record induct proof:" induct_prf;
  2178 
  2179     fun cases_scheme_prf () =
  2180       let
  2181         val _ $ (Pvar $ _) = concl_of induct_scheme;
  2182         val ind =
  2183           cterm_instantiate
  2184             [(cterm_of defs_thy Pvar, cterm_of defs_thy
  2185               (lambda w (HOLogic.imp $ HOLogic.mk_eq (r0, w) $ C)))]
  2186             induct_scheme;
  2187         in ObjectLogic.rulify (mp OF [ind, refl]) end;
  2188 
  2189     val cases_scheme_prf = future_forward_prf cases_scheme_prf cases_scheme_prop;
  2190     val cases_scheme = timeit_msg "record cases_scheme proof:" cases_scheme_prf;
  2191 
  2192     fun cases_prf () =
  2193       prove_standard [] cases_prop
  2194         (fn _ =>
  2195           try_param_tac rN cases_scheme 1 THEN
  2196           simp_all_tac HOL_basic_ss [unit_all_eq1]);
  2197     val cases = timeit_msg "record cases proof:" cases_prf;
  2198 
  2199     fun surjective_prf () =
  2200       let
  2201         val leaf_ss = get_sel_upd_defs defs_thy addsimps (sel_defs @ (o_assoc :: id_o_apps));
  2202         val init_ss = HOL_basic_ss addsimps ext_defs;
  2203       in
  2204         prove_standard [] surjective_prop
  2205           (fn _ =>
  2206             EVERY
  2207              [rtac surject_assist_idE 1,
  2208               simp_tac init_ss 1,
  2209               REPEAT
  2210                 (IsTupleSupport.istuple_intros_tac 1 ORELSE
  2211                   (rtac surject_assistI 1 THEN simp_tac leaf_ss 1))])
  2212       end;
  2213     val surjective = timeit_msg "record surjective proof:" surjective_prf;
  2214 
  2215     fun split_meta_prf () =
  2216       prove false [] split_meta_prop
  2217         (fn _ =>
  2218           EVERY1
  2219            [rtac equal_intr_rule, Goal.norm_hhf_tac,
  2220             etac meta_allE, atac,
  2221             rtac (prop_subst OF [surjective]),
  2222             REPEAT o etac meta_allE, atac]);
  2223     val split_meta = timeit_msg "record split_meta proof:" split_meta_prf;
  2224     fun split_meta_standardise () = Drule.standard split_meta;
  2225     val split_meta_standard =
  2226       timeit_msg "record split_meta standard:" split_meta_standardise;
  2227 
  2228     fun split_object_prf () =
  2229       let
  2230         val cPI= cterm_of defs_thy (lambda r0 (Trueprop (P $ r0)));
  2231         val _ $ Abs (_, _, P $ _) = fst (Logic.dest_equals (concl_of split_meta_standard));
  2232         val cP = cterm_of defs_thy P;
  2233         val split_meta' = cterm_instantiate [(cP, cPI)] split_meta_standard;
  2234         val (l, r) = HOLogic.dest_eq (HOLogic.dest_Trueprop split_object_prop);
  2235         val cl = cterm_of defs_thy (HOLogic.mk_Trueprop l);
  2236         val cr = cterm_of defs_thy (HOLogic.mk_Trueprop r);
  2237         val thl =
  2238           assume cl                   (*All r. P r*) (* 1 *)
  2239           |> obj_to_meta_all          (*!!r. P r*)
  2240           |> equal_elim split_meta'   (*!!n m more. P (ext n m more)*)
  2241           |> meta_to_obj_all          (*All n m more. P (ext n m more)*) (* 2*)
  2242           |> implies_intr cl          (* 1 ==> 2 *)
  2243         val thr =
  2244           assume cr                             (*All n m more. P (ext n m more)*)
  2245           |> obj_to_meta_all                    (*!!n m more. P (ext n m more)*)
  2246           |> equal_elim (symmetric split_meta') (*!!r. P r*)
  2247           |> meta_to_obj_all                    (*All r. P r*)
  2248           |> implies_intr cr                    (* 2 ==> 1 *)
  2249      in thr COMP (thl COMP iffI) end;
  2250 
  2251 
  2252     val split_object_prf = future_forward_prf split_object_prf split_object_prop;
  2253     val split_object = timeit_msg "record split_object proof:" split_object_prf;
  2254 
  2255 
  2256     fun split_ex_prf () =
  2257       let
  2258         val ss = HOL_basic_ss addsimps [not_ex RS sym, Not_eq_iff];
  2259         val P_nm = fst (dest_Free P);
  2260         val not_P = cterm_of defs_thy (lambda r0 (HOLogic.mk_not (P $ r0)));
  2261         val so' = named_cterm_instantiate ([(P_nm, not_P)]) split_object;
  2262         val so'' = simplify ss so';
  2263       in
  2264         prove_standard [] split_ex_prop (fn _ => resolve_tac [so''] 1)
  2265       end;
  2266     val split_ex = timeit_msg "record split_ex proof:" split_ex_prf;
  2267 
  2268     fun equality_tac thms =
  2269       let
  2270         val s' :: s :: eqs = rev thms;
  2271         val ss' = ss addsimps (s' :: s :: sel_convs_standard);
  2272         val eqs' = map (simplify ss') eqs;
  2273       in simp_tac (HOL_basic_ss addsimps (s' :: s :: eqs')) 1 end;
  2274 
  2275     fun equality_prf () =
  2276       prove_standard [] equality_prop (fn {context, ...} =>
  2277         fn st =>
  2278           let val [s, s'] = map #1 (rev (Tactic.innermost_params 1 st)) in
  2279             st |> (res_inst_tac context [((rN, 0), s)] cases_scheme 1 THEN
  2280               res_inst_tac context [((rN, 0), s')] cases_scheme 1 THEN
  2281               Subgoal.FOCUS (fn {prems, ...} => equality_tac prems) context 1)
  2282              (*simp_all_tac ss (sel_convs) would also work but is less efficient*)
  2283           end);
  2284     val equality = timeit_msg "record equality proof:" equality_prf;
  2285 
  2286     val ((([sel_convs', upd_convs', sel_defs', upd_defs',
  2287             fold_congs', unfold_congs',
  2288           [split_meta', split_object', split_ex'], derived_defs'],
  2289           [surjective', equality']),
  2290           [induct_scheme', induct', cases_scheme', cases']), thms_thy) =
  2291       defs_thy
  2292       |> (PureThy.add_thmss o map (Thm.no_attributes o apfst Binding.name))
  2293          [("select_convs", sel_convs_standard),
  2294           ("update_convs", upd_convs_standard),
  2295           ("select_defs", sel_defs),
  2296           ("update_defs", upd_defs),
  2297           ("fold_congs", fold_congs),
  2298           ("unfold_congs", unfold_congs),
  2299           ("splits", [split_meta_standard, split_object, split_ex]),
  2300           ("defs", derived_defs)]
  2301       ||>> (PureThy.add_thms o map (Thm.no_attributes o apfst Binding.name))
  2302           [("surjective", surjective),
  2303            ("equality", equality)]
  2304       ||>> (PureThy.add_thms o (map o apfst o apfst) Binding.name)
  2305         [(("induct_scheme", induct_scheme), induct_type_global (suffix schemeN name)),
  2306          (("induct", induct), induct_type_global name),
  2307          (("cases_scheme", cases_scheme), cases_type_global (suffix schemeN name)),
  2308          (("cases", cases), cases_type_global name)];
  2309 
  2310     val sel_upd_simps = sel_convs' @ upd_convs';
  2311     val sel_upd_defs = sel_defs' @ upd_defs';
  2312     val iffs = [ext_inject]
  2313     val depth = parent_len + 1;
  2314     val final_thy =
  2315       thms_thy
  2316       |> (snd oo PureThy.add_thmss)
  2317           [((Binding.name "simps", sel_upd_simps), [Simplifier.simp_add]),
  2318            ((Binding.name "iffs", iffs), [iff_add])]
  2319       |> put_record name (make_record_info args parent fields extension induct_scheme' ext_def)
  2320       |> put_sel_upd names full_moreN depth sel_upd_simps sel_upd_defs (fold_congs', unfold_congs')
  2321       |> add_record_equalities extension_id equality'
  2322       |> add_extinjects ext_inject
  2323       |> add_extsplit extension_name ext_split
  2324       |> add_record_splits extension_id (split_meta', split_object', split_ex', induct_scheme')
  2325       |> add_extfields extension_name (fields @ [(full_moreN, moreT)])
  2326       |> add_fieldext (extension_name, snd extension) (names @ [full_moreN])
  2327       |> Sign.parent_path;
  2328 
  2329   in final_thy end;
  2330 
  2331 
  2332 (* add_record *)
  2333 
  2334 (*We do all preparations and error checks here, deferring the real
  2335   work to record_definition.*)
  2336 fun gen_add_record prep_typ prep_raw_parent quiet_mode (params, bname) raw_parent raw_fields thy =
  2337   let
  2338     val _ = Theory.requires thy "Record" "record definitions";
  2339     val _ = if quiet_mode then () else writeln ("Defining record " ^ quote bname ^ " ...");
  2340 
  2341     val ctxt = ProofContext.init thy;
  2342 
  2343 
  2344     (* parents *)
  2345 
  2346     fun prep_inst T = fst (cert_typ ctxt T []);
  2347 
  2348     val parent = Option.map (apfst (map prep_inst) o prep_raw_parent ctxt) raw_parent
  2349       handle ERROR msg => cat_error msg ("The error(s) above in parent record specification");
  2350     val parents = add_parents thy parent [];
  2351 
  2352     val init_env =
  2353       (case parent of
  2354         NONE => []
  2355       | SOME (types, _) => fold Term.add_tfreesT types []);
  2356 
  2357 
  2358     (* fields *)
  2359 
  2360     fun prep_field (c, raw_T, mx) env =
  2361       let val (T, env') = prep_typ ctxt raw_T env handle ERROR msg =>
  2362         cat_error msg ("The error(s) above occured in record field " ^ quote c)
  2363       in ((c, T, mx), env') end;
  2364 
  2365     val (bfields, envir) = fold_map prep_field raw_fields init_env;
  2366     val envir_names = map fst envir;
  2367 
  2368 
  2369     (* args *)
  2370 
  2371     val defaultS = Sign.defaultS thy;
  2372     val args = map (fn x => (x, AList.lookup (op =) envir x |> the_default defaultS)) params;
  2373 
  2374 
  2375     (* errors *)
  2376 
  2377     val name = Sign.full_bname thy bname;
  2378     val err_dup_record =
  2379       if is_none (get_record thy name) then []
  2380       else ["Duplicate definition of record " ^ quote name];
  2381 
  2382     val err_dup_parms =
  2383       (case duplicates (op =) params of
  2384         [] => []
  2385       | dups => ["Duplicate parameter(s) " ^ commas dups]);
  2386 
  2387     val err_extra_frees =
  2388       (case subtract (op =) params envir_names of
  2389         [] => []
  2390       | extras => ["Extra free type variable(s) " ^ commas extras]);
  2391 
  2392     val err_no_fields = if null bfields then ["No fields present"] else [];
  2393 
  2394     val err_dup_fields =
  2395       (case duplicates (op =) (map #1 bfields) of
  2396         [] => []
  2397       | dups => ["Duplicate field(s) " ^ commas_quote dups]);
  2398 
  2399     val err_bad_fields =
  2400       if forall (not_equal moreN o #1) bfields then []
  2401       else ["Illegal field name " ^ quote moreN];
  2402 
  2403     val err_dup_sorts =
  2404       (case duplicates (op =) envir_names of
  2405         [] => []
  2406       | dups => ["Inconsistent sort constraints for " ^ commas dups]);
  2407 
  2408     val errs =
  2409       err_dup_record @ err_dup_parms @ err_extra_frees @ err_no_fields @
  2410       err_dup_fields @ err_bad_fields @ err_dup_sorts;
  2411 
  2412     val _ = if null errs then () else error (cat_lines errs);
  2413   in
  2414     thy |> record_definition (args, bname) parent parents bfields
  2415   end
  2416   handle ERROR msg => cat_error msg ("Failed to define record " ^ quote bname);
  2417 
  2418 val add_record = gen_add_record read_typ read_raw_parent;
  2419 val add_record_i = gen_add_record cert_typ (K I);
  2420 
  2421 
  2422 (* setup theory *)
  2423 
  2424 val setup =
  2425   Sign.add_trfuns ([], parse_translation, [], []) #>
  2426   Sign.add_advanced_trfuns ([], adv_parse_translation, [], []) #>
  2427   Simplifier.map_simpset (fn ss =>
  2428     ss addsimprocs [record_simproc, record_upd_simproc, record_eq_simproc]);
  2429 
  2430 
  2431 (* outer syntax *)
  2432 
  2433 local structure P = OuterParse and K = OuterKeyword in
  2434 
  2435 val record_decl =
  2436   P.type_args -- P.name --
  2437     (P.$$$ "=" |-- Scan.option (P.typ --| P.$$$ "+") -- Scan.repeat1 P.const);
  2438 
  2439 val _ =
  2440   OuterSyntax.command "record" "define extensible record" K.thy_decl
  2441     (record_decl >> (fn (x, (y, z)) => Toplevel.theory (add_record false x y z)));
  2442 
  2443 end;
  2444 
  2445 end;
  2446 
  2447 structure Basic_Record: BASIC_RECORD = Record;
  2448 open Basic_Record;