src/Tools/nbe.ML
author haftmann
Wed Sep 15 13:44:11 2010 +0200 (2010-09-15)
changeset 39396 e9cad160aa0f
parent 39392 7a0fcee7a2a3
child 39399 267235a14938
permissions -rw-r--r--
dropped redundant normal_form command
     1 (*  Title:      Tools/nbe.ML
     2     Authors:    Klaus Aehlig, LMU Muenchen; Tobias Nipkow, Florian Haftmann, TU Muenchen
     3 
     4 Normalization by evaluation, based on generic code generator.
     5 *)
     6 
     7 signature NBE =
     8 sig
     9   val dynamic_eval_conv: conv
    10   val dynamic_eval_value: theory -> term -> term
    11 
    12   datatype Univ =
    13       Const of int * Univ list               (*named (uninterpreted) constants*)
    14     | DFree of string * int                  (*free (uninterpreted) dictionary parameters*)
    15     | BVar of int * Univ list
    16     | Abs of (int * (Univ list -> Univ)) * Univ list
    17   val apps: Univ -> Univ list -> Univ        (*explicit applications*)
    18   val abss: int -> (Univ list -> Univ) -> Univ
    19                                              (*abstractions as closures*)
    20   val same: Univ -> Univ -> bool
    21 
    22   val put_result: (unit -> Univ list -> Univ list) -> Proof.context -> Proof.context
    23   val trace: bool Unsynchronized.ref
    24 
    25   val setup: theory -> theory
    26   val add_const_alias: thm -> theory -> theory
    27 end;
    28 
    29 structure Nbe: NBE =
    30 struct
    31 
    32 (* generic non-sense *)
    33 
    34 val trace = Unsynchronized.ref false;
    35 fun traced f x = if !trace then (tracing (f x); x) else x;
    36 
    37 
    38 (** certificates and oracle for "trivial type classes" **)
    39 
    40 structure Triv_Class_Data = Theory_Data
    41 (
    42   type T = (class * thm) list;
    43   val empty = [];
    44   val extend = I;
    45   fun merge data : T = AList.merge (op =) (K true) data;
    46 );
    47 
    48 fun add_const_alias thm thy =
    49   let
    50     val (ofclass, eqn) = case try Logic.dest_equals (Thm.prop_of thm)
    51      of SOME ofclass_eq => ofclass_eq
    52       | _ => error ("Bad certificate: " ^ Display.string_of_thm_global thy thm);
    53     val (T, class) = case try Logic.dest_of_class ofclass
    54      of SOME T_class => T_class
    55       | _ => error ("Bad certificate: " ^ Display.string_of_thm_global thy thm);
    56     val tvar = case try Term.dest_TVar T
    57      of SOME (tvar as (_, sort)) => if null (filter (can (AxClass.get_info thy)) sort)
    58           then tvar
    59           else error ("Bad sort: " ^ Display.string_of_thm_global thy thm)
    60       | _ => error ("Bad type: " ^ Display.string_of_thm_global thy thm);
    61     val _ = if Term.add_tvars eqn [] = [tvar] then ()
    62       else error ("Inconsistent type: " ^ Display.string_of_thm_global thy thm);
    63     val lhs_rhs = case try Logic.dest_equals eqn
    64      of SOME lhs_rhs => lhs_rhs
    65       | _ => error ("Not an equation: " ^ Syntax.string_of_term_global thy eqn);
    66     val c_c' = case try (pairself (Code.check_const thy)) lhs_rhs
    67      of SOME c_c' => c_c'
    68       | _ => error ("Not an equation with two constants: "
    69           ^ Syntax.string_of_term_global thy eqn);
    70     val _ = if the_list (AxClass.class_of_param thy (snd c_c')) = [class] then ()
    71       else error ("Inconsistent class: " ^ Display.string_of_thm_global thy thm);
    72   in Triv_Class_Data.map (AList.update (op =) (class, thm)) thy end;
    73 
    74 local
    75 
    76 val get_triv_classes = map fst o Triv_Class_Data.get;
    77 
    78 val (_, triv_of_class) = Context.>>> (Context.map_theory_result
    79   (Thm.add_oracle (Binding.name "triv_of_class", fn (thy, T, class) =>
    80     Thm.cterm_of thy (Logic.mk_of_class (T, class)))));
    81 
    82 in
    83 
    84 fun lift_triv_classes_conv thy conv ct =
    85   let
    86     val algebra = Sign.classes_of thy;
    87     val certT = Thm.ctyp_of thy;
    88     val triv_classes = get_triv_classes thy;
    89     fun additional_classes sort = filter_out (fn class => Sorts.sort_le algebra (sort, [class])) triv_classes;
    90     fun mk_entry (v, sort) =
    91       let
    92         val T = TFree (v, sort);
    93         val cT = certT T;
    94         val triv_sort = additional_classes sort;
    95       in
    96         (v, (Sorts.inter_sort algebra (sort, triv_sort),
    97           (cT, AList.make (fn class => Thm.of_class (cT, class)) sort
    98             @ AList.make (fn class => triv_of_class (thy, T, class)) triv_sort)))
    99       end;
   100     val vs_tab = map mk_entry (Term.add_tfrees (Thm.term_of ct) []);
   101     fun instantiate thm =
   102       let
   103         val cert_tvars = map (certT o TVar) (Term.add_tvars
   104           ((fst o Logic.dest_equals o Logic.strip_imp_concl o Thm.prop_of) thm) []);
   105         val instantiation =
   106           map2 (fn cert_tvar => fn (_, (_, (cT, _))) => (cert_tvar, cT)) cert_tvars vs_tab;
   107       in Thm.instantiate (instantiation, []) thm end;
   108     fun of_class (TFree (v, _), class) =
   109           the (AList.lookup (op =) ((snd o snd o the o AList.lookup (op =) vs_tab) v) class)
   110       | of_class (T, _) = error ("Bad type " ^ Syntax.string_of_typ_global thy T);
   111     fun strip_of_class thm =
   112       let
   113         val prems_of_class = Thm.prop_of thm
   114           |> Logic.strip_imp_prems
   115           |> map (Logic.dest_of_class #> of_class);
   116       in fold Thm.elim_implies prems_of_class thm end;
   117   in
   118     ct
   119     |> (Drule.cterm_fun o map_types o map_type_tfree)
   120         (fn (v, sort) => TFree (v, (fst o the o AList.lookup (op =) vs_tab) v))
   121     |> conv
   122     |> Thm.strip_shyps
   123     |> Thm.varifyT_global
   124     |> Thm.unconstrainT
   125     |> instantiate
   126     |> strip_of_class
   127   end;
   128 
   129 fun lift_triv_classes_rew thy rew t =
   130   let
   131     val algebra = Sign.classes_of thy;
   132     val triv_classes = get_triv_classes thy;
   133     val vs = Term.add_tfrees t [];
   134   in t
   135     |> (map_types o map_type_tfree)
   136         (fn (v, sort) => TFree (v, Sorts.inter_sort algebra (sort, triv_classes)))
   137     |> rew
   138     |> (map_types o map_type_tfree)
   139         (fn (v, _) => TFree (v, the (AList.lookup (op =) vs v)))
   140   end;
   141 
   142 end;
   143 
   144 
   145 (** the semantic universe **)
   146 
   147 (*
   148    Functions are given by their semantical function value. To avoid
   149    trouble with the ML-type system, these functions have the most
   150    generic type, that is "Univ list -> Univ". The calling convention is
   151    that the arguments come as a list, the last argument first. In
   152    other words, a function call that usually would look like
   153 
   154    f x_1 x_2 ... x_n   or   f(x_1,x_2, ..., x_n)
   155 
   156    would be in our convention called as
   157 
   158               f [x_n,..,x_2,x_1]
   159 
   160    Moreover, to handle functions that are still waiting for some
   161    arguments we have additionally a list of arguments collected to far
   162    and the number of arguments we're still waiting for.
   163 *)
   164 
   165 datatype Univ =
   166     Const of int * Univ list           (*named (uninterpreted) constants*)
   167   | DFree of string * int              (*free (uninterpreted) dictionary parameters*)
   168   | BVar of int * Univ list            (*bound variables, named*)
   169   | Abs of (int * (Univ list -> Univ)) * Univ list
   170                                        (*abstractions as closures*);
   171 
   172 fun same (Const (k, xs)) (Const (l, ys)) = k = l andalso sames xs ys
   173   | same (DFree (s, k)) (DFree (t, l)) = s = t andalso k = l
   174   | same (BVar (k, xs)) (BVar (l, ys)) = k = l andalso sames xs ys
   175   | same _ _ = false
   176 and sames xs ys = length xs = length ys andalso forall (uncurry same) (xs ~~ ys);
   177 
   178 
   179 (* constructor functions *)
   180 
   181 fun abss n f = Abs ((n, f), []);
   182 fun apps (Abs ((n, f), xs)) ys = let val k = n - length ys in
   183       case int_ord (k, 0)
   184        of EQUAL => f (ys @ xs)
   185         | LESS => let val (zs, ws) = chop (~ k) ys in apps (f (ws @ xs)) zs end
   186         | GREATER => Abs ((k, f), ys @ xs) (*note: reverse convention also for apps!*)
   187       end
   188   | apps (Const (name, xs)) ys = Const (name, ys @ xs)
   189   | apps (BVar (n, xs)) ys = BVar (n, ys @ xs);
   190 
   191 
   192 (** assembling and compiling ML code from terms **)
   193 
   194 (* abstract ML syntax *)
   195 
   196 infix 9 `$` `$$`;
   197 fun e1 `$` e2 = "(" ^ e1 ^ " " ^ e2 ^ ")";
   198 fun e `$$` [] = e
   199   | e `$$` es = "(" ^ e ^ " " ^ space_implode " " es ^ ")";
   200 fun ml_abs v e = "(fn " ^ v ^ " => " ^ e ^ ")";
   201 
   202 fun ml_cases t cs =
   203   "(case " ^ t ^ " of " ^ space_implode " | " (map (fn (p, t) => p ^ " => " ^ t) cs) ^ ")";
   204 fun ml_Let d e = "let\n" ^ d ^ " in " ^ e ^ " end";
   205 fun ml_as v t = "(" ^ v ^ " as " ^ t ^ ")";
   206 
   207 fun ml_and [] = "true"
   208   | ml_and [x] = x
   209   | ml_and xs = "(" ^ space_implode " andalso " xs ^ ")";
   210 fun ml_if b x y = "(if " ^ b ^ " then " ^ x ^ " else " ^ y ^ ")";
   211 
   212 fun ml_list es = "[" ^ commas es ^ "]";
   213 
   214 fun ml_fundefs ([(name, [([], e)])]) =
   215       "val " ^ name ^ " = " ^ e ^ "\n"
   216   | ml_fundefs (eqs :: eqss) =
   217       let
   218         fun fundef (name, eqs) =
   219           let
   220             fun eqn (es, e) = name ^ " " ^ space_implode " " es ^ " = " ^ e
   221           in space_implode "\n  | " (map eqn eqs) end;
   222       in
   223         (prefix "fun " o fundef) eqs :: map (prefix "and " o fundef) eqss
   224         |> cat_lines
   225         |> suffix "\n"
   226       end;
   227 
   228 
   229 (* nbe specific syntax and sandbox communication *)
   230 
   231 structure Univs = Proof_Data(
   232   type T = unit -> Univ list -> Univ list
   233   fun init thy () = error "Univs"
   234 );
   235 val put_result = Univs.put;
   236 
   237 local
   238   val prefix =      "Nbe.";
   239   val name_put =    prefix ^ "put_result";
   240   val name_ref =    prefix ^ "univs_ref";
   241   val name_const =  prefix ^ "Const";
   242   val name_abss =   prefix ^ "abss";
   243   val name_apps =   prefix ^ "apps";
   244   val name_same =   prefix ^ "same";
   245 in
   246 
   247 val univs_cookie = (Univs.get, put_result, name_put);
   248 
   249 fun nbe_fun 0 "" = "nbe_value"
   250   | nbe_fun i c = "c_" ^ translate_string (fn "." => "_" | c => c) c ^ "_" ^ string_of_int i;
   251 fun nbe_dict v n = "d_" ^ v ^ "_" ^ string_of_int n;
   252 fun nbe_bound v = "v_" ^ v;
   253 fun nbe_bound_optional NONE = "_"
   254   | nbe_bound_optional (SOME v) = nbe_bound v;
   255 fun nbe_default v = "w_" ^ v;
   256 
   257 (*note: these three are the "turning spots" where proper argument order is established!*)
   258 fun nbe_apps t [] = t
   259   | nbe_apps t ts = name_apps `$$` [t, ml_list (rev ts)];
   260 fun nbe_apps_local i c ts = nbe_fun i c `$` ml_list (rev ts);
   261 fun nbe_apps_constr idx_of c ts =
   262   let
   263     val c' = if !trace then string_of_int (idx_of c) ^ " (*" ^ c ^ "*)"
   264       else string_of_int (idx_of c);
   265   in name_const `$` ("(" ^ c' ^ ", " ^ ml_list (rev ts) ^ ")") end;
   266 
   267 fun nbe_abss 0 f = f `$` ml_list []
   268   | nbe_abss n f = name_abss `$$` [string_of_int n, f];
   269 
   270 fun nbe_same v1 v2 = "(" ^ name_same ^ " " ^ nbe_bound v1 ^ " " ^ nbe_bound v2 ^ ")";
   271 
   272 end;
   273 
   274 open Basic_Code_Thingol;
   275 
   276 
   277 (* code generation *)
   278 
   279 fun assemble_eqnss idx_of deps eqnss =
   280   let
   281     fun prep_eqns (c, (vs, eqns)) =
   282       let
   283         val dicts = maps (fn (v, sort) => map_index (nbe_dict v o fst) sort) vs;
   284         val num_args = length dicts + ((length o fst o hd) eqns);
   285       in (c, (num_args, (dicts, eqns))) end;
   286     val eqnss' = map prep_eqns eqnss;
   287 
   288     fun assemble_constapp c dss ts = 
   289       let
   290         val ts' = (maps o map) assemble_idict dss @ ts;
   291       in case AList.lookup (op =) eqnss' c
   292        of SOME (num_args, _) => if num_args <= length ts'
   293             then let val (ts1, ts2) = chop num_args ts'
   294             in nbe_apps (nbe_apps_local 0 c ts1) ts2
   295             end else nbe_apps (nbe_abss num_args (nbe_fun 0 c)) ts'
   296         | NONE => if member (op =) deps c
   297             then nbe_apps (nbe_fun 0 c) ts'
   298             else nbe_apps_constr idx_of c ts'
   299       end
   300     and assemble_idict (DictConst (inst, dss)) =
   301           assemble_constapp inst dss []
   302       | assemble_idict (DictVar (supers, (v, (n, _)))) =
   303           fold_rev (fn super => assemble_constapp super [] o single) supers (nbe_dict v n);
   304 
   305     fun assemble_iterm constapp =
   306       let
   307         fun of_iterm match_cont t =
   308           let
   309             val (t', ts) = Code_Thingol.unfold_app t
   310           in of_iapp match_cont t' (fold_rev (cons o of_iterm NONE) ts []) end
   311         and of_iapp match_cont (IConst (c, ((_, dss), _))) ts = constapp c dss ts
   312           | of_iapp match_cont (IVar v) ts = nbe_apps (nbe_bound_optional v) ts
   313           | of_iapp match_cont ((v, _) `|=> t) ts =
   314               nbe_apps (nbe_abss 1 (ml_abs (ml_list [nbe_bound_optional v]) (of_iterm NONE t))) ts
   315           | of_iapp match_cont (ICase (((t, _), cs), t0)) ts =
   316               nbe_apps (ml_cases (of_iterm NONE t)
   317                 (map (fn (p, t) => (of_iterm NONE p, of_iterm match_cont t)) cs
   318                   @ [("_", case match_cont of SOME s => s | NONE => of_iterm NONE t0)])) ts
   319       in of_iterm end;
   320 
   321     fun subst_nonlin_vars args =
   322       let
   323         val vs = (fold o Code_Thingol.fold_varnames)
   324           (fn v => AList.map_default (op =) (v, 0) (Integer.add 1)) args [];
   325         val names = Name.make_context (map fst vs);
   326         fun declare v k ctxt = let val vs = Name.invents ctxt v k
   327           in (vs, fold Name.declare vs ctxt) end;
   328         val (vs_renames, _) = fold_map (fn (v, k) => if k > 1
   329           then declare v (k - 1) #>> (fn vs => (v, vs))
   330           else pair (v, [])) vs names;
   331         val samepairs = maps (fn (v, vs) => map (pair v) vs) vs_renames;
   332         fun subst_vars (t as IConst _) samepairs = (t, samepairs)
   333           | subst_vars (t as IVar NONE) samepairs = (t, samepairs)
   334           | subst_vars (t as IVar (SOME v)) samepairs = (case AList.lookup (op =) samepairs v
   335              of SOME v' => (IVar (SOME v'), AList.delete (op =) v samepairs)
   336               | NONE => (t, samepairs))
   337           | subst_vars (t1 `$ t2) samepairs = samepairs
   338               |> subst_vars t1
   339               ||>> subst_vars t2
   340               |>> (op `$)
   341           | subst_vars (ICase (_, t)) samepairs = subst_vars t samepairs;
   342         val (args', _) = fold_map subst_vars args samepairs;
   343       in (samepairs, args') end;
   344 
   345     fun assemble_eqn c dicts default_args (i, (args, rhs)) =
   346       let
   347         val is_eval = (c = "");
   348         val default_rhs = nbe_apps_local (i+1) c (dicts @ default_args);
   349         val match_cont = if is_eval then NONE else SOME default_rhs;
   350         val assemble_arg = assemble_iterm
   351           (fn c => fn _ => fn ts => nbe_apps_constr idx_of c ts) NONE;
   352         val assemble_rhs = assemble_iterm assemble_constapp match_cont;
   353         val (samepairs, args') = subst_nonlin_vars args;
   354         val s_args = map assemble_arg args';
   355         val s_rhs = if null samepairs then assemble_rhs rhs
   356           else ml_if (ml_and (map (uncurry nbe_same) samepairs))
   357             (assemble_rhs rhs) default_rhs;
   358         val eqns = if is_eval then
   359             [([ml_list (rev (dicts @ s_args))], s_rhs)]
   360           else
   361             [([ml_list (rev (dicts @ map2 ml_as default_args s_args))], s_rhs),
   362               ([ml_list (rev (dicts @ default_args))], default_rhs)]
   363       in (nbe_fun i c, eqns) end;
   364 
   365     fun assemble_eqns (c, (num_args, (dicts, eqns))) =
   366       let
   367         val default_args = map nbe_default
   368           (Name.invent_list [] "a" (num_args - length dicts));
   369         val eqns' = map_index (assemble_eqn c dicts default_args) eqns
   370           @ (if c = "" then [] else [(nbe_fun (length eqns) c,
   371             [([ml_list (rev (dicts @ default_args))],
   372               nbe_apps_constr idx_of c (dicts @ default_args))])]);
   373       in (eqns', nbe_abss num_args (nbe_fun 0 c)) end;
   374 
   375     val (fun_vars, fun_vals) = map_split assemble_eqns eqnss';
   376     val deps_vars = ml_list (map (nbe_fun 0) deps);
   377   in ml_abs deps_vars (ml_Let (ml_fundefs (flat fun_vars)) (ml_list fun_vals)) end;
   378 
   379 
   380 (* compile equations *)
   381 
   382 fun compile_eqnss thy nbe_program raw_deps [] = []
   383   | compile_eqnss thy nbe_program raw_deps eqnss =
   384       let
   385         val ctxt = ProofContext.init_global thy;
   386         val (deps, deps_vals) = split_list (map_filter
   387           (fn dep => Option.map (fn univ => (dep, univ)) (fst ((Graph.get_node nbe_program dep)))) raw_deps);
   388         val idx_of = raw_deps
   389           |> map (fn dep => (dep, snd (Graph.get_node nbe_program dep)))
   390           |> AList.lookup (op =)
   391           |> (fn f => the o f);
   392         val s = assemble_eqnss idx_of deps eqnss;
   393         val cs = map fst eqnss;
   394       in
   395         s
   396         |> traced (fn s => "\n--- code to be evaluated:\n" ^ s)
   397         |> pair ""
   398         |> ML_Context.value ctxt univs_cookie
   399         |> (fn f => f deps_vals)
   400         |> (fn univs => cs ~~ univs)
   401       end;
   402 
   403 
   404 (* extract equations from statements *)
   405 
   406 fun eqns_of_stmt (_, Code_Thingol.Fun (_, ((_, []), _))) =
   407       []
   408   | eqns_of_stmt (const, Code_Thingol.Fun (_, (((vs, _), eqns), _))) =
   409       [(const, (vs, map fst eqns))]
   410   | eqns_of_stmt (_, Code_Thingol.Datatypecons _) =
   411       []
   412   | eqns_of_stmt (_, Code_Thingol.Datatype _) =
   413       []
   414   | eqns_of_stmt (class, Code_Thingol.Class (_, (v, (super_classes, classparams)))) =
   415       let
   416         val names = map snd super_classes @ map fst classparams;
   417         val params = Name.invent_list [] "d" (length names);
   418         fun mk (k, name) =
   419           (name, ([(v, [])],
   420             [([IConst (class, (([], []), [])) `$$ map (IVar o SOME) params],
   421               IVar (SOME (nth params k)))]));
   422       in map_index mk names end
   423   | eqns_of_stmt (_, Code_Thingol.Classrel _) =
   424       []
   425   | eqns_of_stmt (_, Code_Thingol.Classparam _) =
   426       []
   427   | eqns_of_stmt (inst, Code_Thingol.Classinst ((class, (_, arity_args)), (super_instances, (classparam_instances, _)))) =
   428       [(inst, (arity_args, [([], IConst (class, (([], []), [])) `$$
   429         map (fn (_, (_, (inst, dss))) => IConst (inst, (([], dss), []))) super_instances
   430         @ map (IConst o snd o fst) classparam_instances)]))];
   431 
   432 
   433 (* compile whole programs *)
   434 
   435 fun compile_stmts thy stmts_deps =
   436   let
   437     val names = map (fst o fst) stmts_deps;
   438     val names_deps = map (fn ((name, _), deps) => (name, deps)) stmts_deps;
   439     val eqnss = maps (eqns_of_stmt o fst) stmts_deps;
   440     val refl_deps = names_deps
   441       |> maps snd
   442       |> distinct (op =)
   443       |> fold (insert (op =)) names;
   444     fun new_node name (nbe_program, (maxidx, idx_tab)) = if can (Graph.get_node nbe_program) name
   445       then (nbe_program, (maxidx, idx_tab))
   446       else (Graph.new_node (name, (NONE, maxidx)) nbe_program,
   447         (maxidx + 1, Inttab.update_new (maxidx, name) idx_tab));
   448     fun compile nbe_program = eqnss
   449       |> compile_eqnss thy nbe_program refl_deps
   450       |> rpair nbe_program;
   451   in
   452     fold new_node refl_deps
   453     #> apfst (fold (fn (name, deps) => fold (curry Graph.add_edge name) deps) names_deps
   454       #> compile
   455       #-> fold (fn (name, univ) => (Graph.map_node name o apfst) (K (SOME univ))))
   456   end;
   457 
   458 fun compile_program thy program =
   459   let
   460     fun add_stmts names (nbe_program, (maxidx, idx_tab)) = if exists ((can o Graph.get_node) nbe_program) names
   461       then (nbe_program, (maxidx, idx_tab))
   462       else (nbe_program, (maxidx, idx_tab))
   463         |> compile_stmts thy (map (fn name => ((name, Graph.get_node program name),
   464           Graph.imm_succs program name)) names);
   465   in
   466     fold_rev add_stmts (Graph.strong_conn program)
   467   end;
   468 
   469 
   470 (** evaluation **)
   471 
   472 (* term evaluation by compilation *)
   473 
   474 fun compile_term thy nbe_program deps (vs : (string * sort) list, t) =
   475   let 
   476     val dict_frees = maps (fn (v, sort) => map_index (curry DFree v o fst) sort) vs;
   477   in
   478     ("", (vs, [([], t)]))
   479     |> singleton (compile_eqnss thy nbe_program deps)
   480     |> snd
   481     |> (fn t => apps t (rev dict_frees))
   482   end;
   483 
   484 
   485 (* reconstruction *)
   486 
   487 fun typ_of_itype program vs (ityco `%% itys) =
   488       let
   489         val Code_Thingol.Datatype (tyco, _) = Graph.get_node program ityco;
   490       in Type (tyco, map (typ_of_itype program vs) itys) end
   491   | typ_of_itype program vs (ITyVar v) =
   492       let
   493         val sort = (the o AList.lookup (op =) vs) v;
   494       in TFree ("'" ^ v, sort) end;
   495 
   496 fun term_of_univ thy program idx_tab t =
   497   let
   498     fun take_until f [] = []
   499       | take_until f (x::xs) = if f x then [] else x :: take_until f xs;
   500     fun is_dict (Const (idx, _)) = (case (Graph.get_node program o the o Inttab.lookup idx_tab) idx
   501          of Code_Thingol.Class _ => true
   502           | Code_Thingol.Classrel _ => true
   503           | Code_Thingol.Classinst _ => true
   504           | _ => false)
   505       | is_dict (DFree _) = true
   506       | is_dict _ = false;
   507     fun const_of_idx idx = (case (Graph.get_node program o the o Inttab.lookup idx_tab) idx
   508      of Code_Thingol.Fun (c, _) => c
   509       | Code_Thingol.Datatypecons (c, _) => c
   510       | Code_Thingol.Classparam (c, _) => c);
   511     fun of_apps bounds (t, ts) =
   512       fold_map (of_univ bounds) ts
   513       #>> (fn ts' => list_comb (t, rev ts'))
   514     and of_univ bounds (Const (idx, ts)) typidx =
   515           let
   516             val ts' = take_until is_dict ts;
   517             val c = const_of_idx idx;
   518             val T = map_type_tvar (fn ((v, i), _) =>
   519               Type_Infer.param typidx (v ^ string_of_int i, []))
   520                 (Sign.the_const_type thy c);
   521             val typidx' = typidx + 1;
   522           in of_apps bounds (Term.Const (c, T), ts') typidx' end
   523       | of_univ bounds (BVar (n, ts)) typidx =
   524           of_apps bounds (Bound (bounds - n - 1), ts) typidx
   525       | of_univ bounds (t as Abs _) typidx =
   526           typidx
   527           |> of_univ (bounds + 1) (apps t [BVar (bounds, [])])
   528           |-> (fn t' => pair (Term.Abs ("u", dummyT, t')))
   529   in of_univ 0 t 0 |> fst end;
   530 
   531 
   532 (* evaluation with type reconstruction *)
   533 
   534 fun eval_term thy program (nbe_program, idx_tab) ((vs0, (vs, ty)), t) deps =
   535   let
   536     val ctxt = Syntax.init_pretty_global thy;
   537     val string_of_term = Syntax.string_of_term (Config.put show_types true ctxt);
   538     val ty' = typ_of_itype program vs0 ty;
   539     fun type_infer t = singleton
   540       (Type_Infer.infer_types ctxt (try (Type.strip_sorts o Sign.the_const_type thy)) (K NONE))
   541       (Type.constraint ty' t);
   542     fun check_tvars t =
   543       if null (Term.add_tvars t []) then t
   544       else error ("Illegal schematic type variables in normalized term: " ^ string_of_term t);
   545   in
   546     compile_term thy nbe_program deps (vs, t)
   547     |> term_of_univ thy program idx_tab
   548     |> traced (fn t => "Normalized:\n" ^ string_of_term t)
   549     |> type_infer
   550     |> traced (fn t => "Types inferred:\n" ^ string_of_term t)
   551     |> check_tvars
   552     |> traced (fn _ => "---\n")
   553   end;
   554 
   555 (* function store *)
   556 
   557 structure Nbe_Functions = Code_Data
   558 (
   559   type T = (Univ option * int) Graph.T * (int * string Inttab.table);
   560   val empty = (Graph.empty, (0, Inttab.empty));
   561 );
   562 
   563 fun compile thy program =
   564   let
   565     val (nbe_program, (_, idx_tab)) =
   566       Nbe_Functions.change thy (compile_program thy program);
   567   in (nbe_program, idx_tab) end;
   568 
   569 
   570 (* dynamic evaluation oracle *)
   571 
   572 fun mk_equals thy lhs raw_rhs =
   573   let
   574     val ty = Thm.typ_of (Thm.ctyp_of_term lhs);
   575     val eq = Thm.cterm_of thy (Term.Const ("==", ty --> ty --> propT));
   576     val rhs = Thm.cterm_of thy raw_rhs;
   577   in Thm.mk_binop eq lhs rhs end;
   578 
   579 val (_, raw_oracle) = Context.>>> (Context.map_theory_result
   580   (Thm.add_oracle (Binding.name "norm", fn (thy, program, vsp_ty_t, deps, ct) =>
   581     mk_equals thy ct (eval_term thy program (compile thy program) vsp_ty_t deps))));
   582 
   583 fun oracle thy program vsp_ty_t deps ct = raw_oracle (thy, program, vsp_ty_t, deps, ct);
   584 
   585 fun no_frees_rew rew t =
   586   let
   587     val frees = map Free (Term.add_frees t []);
   588   in
   589     t
   590     |> fold_rev lambda frees
   591     |> rew
   592     |> curry (Term.betapplys o swap) frees
   593   end;
   594 
   595 val dynamic_eval_conv = Code_Simp.no_frees_conv (Conv.tap_thy
   596   (fn thy => lift_triv_classes_conv thy (Code_Thingol.dynamic_eval_conv thy (K (oracle thy)))));
   597 
   598 fun dynamic_eval_value thy = lift_triv_classes_rew thy
   599   (no_frees_rew (Code_Thingol.dynamic_eval_value thy I
   600     (K (fn program => eval_term thy program (compile thy program)))));
   601 
   602 
   603 (** setup **)
   604 
   605 val setup = Value.add_evaluator ("nbe", dynamic_eval_value o ProofContext.theory_of);
   606 
   607 end;
   608