src/HOL/Arith.ML
author paulson
Wed Aug 19 10:26:02 1998 +0200 (1998-08-19)
changeset 5333 ea33e66dcedd
parent 5329 1003ddc30299
child 5356 6ef114ba5b55
permissions -rw-r--r--
Some new theorems. zero_less_diff replaces less_imp_diff_positive
     1 (*  Title:      HOL/Arith.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1998  University of Cambridge
     5 
     6 Proofs about elementary arithmetic: addition, multiplication, etc.
     7 Some from the Hoare example from Norbert Galm
     8 *)
     9 
    10 (*** Basic rewrite rules for the arithmetic operators ***)
    11 
    12 
    13 (** Difference **)
    14 
    15 qed_goal "diff_0_eq_0" thy
    16     "0 - n = 0"
    17  (fn _ => [induct_tac "n" 1,  ALLGOALS Asm_simp_tac]);
    18 
    19 (*Must simplify BEFORE the induction!!  (Else we get a critical pair)
    20   Suc(m) - Suc(n)   rewrites to   pred(Suc(m) - n)  *)
    21 qed_goal "diff_Suc_Suc" thy
    22     "Suc(m) - Suc(n) = m - n"
    23  (fn _ =>
    24   [Simp_tac 1, induct_tac "n" 1, ALLGOALS Asm_simp_tac]);
    25 
    26 Addsimps [diff_0_eq_0, diff_Suc_Suc];
    27 
    28 (* Could be (and is, below) generalized in various ways;
    29    However, none of the generalizations are currently in the simpset,
    30    and I dread to think what happens if I put them in *)
    31 Goal "0 < n ==> Suc(n-1) = n";
    32 by (asm_simp_tac (simpset() addsplits [nat.split]) 1);
    33 qed "Suc_pred";
    34 Addsimps [Suc_pred];
    35 
    36 Delsimps [diff_Suc];
    37 
    38 
    39 (**** Inductive properties of the operators ****)
    40 
    41 (*** Addition ***)
    42 
    43 qed_goal "add_0_right" thy "m + 0 = m"
    44  (fn _ => [induct_tac "m" 1, ALLGOALS Asm_simp_tac]);
    45 
    46 qed_goal "add_Suc_right" thy "m + Suc(n) = Suc(m+n)"
    47  (fn _ => [induct_tac "m" 1, ALLGOALS Asm_simp_tac]);
    48 
    49 Addsimps [add_0_right,add_Suc_right];
    50 
    51 (*Associative law for addition*)
    52 qed_goal "add_assoc" thy "(m + n) + k = m + ((n + k)::nat)"
    53  (fn _ => [induct_tac "m" 1, ALLGOALS Asm_simp_tac]);
    54 
    55 (*Commutative law for addition*)  
    56 qed_goal "add_commute" thy "m + n = n + (m::nat)"
    57  (fn _ =>  [induct_tac "m" 1, ALLGOALS Asm_simp_tac]);
    58 
    59 qed_goal "add_left_commute" thy "x+(y+z)=y+((x+z)::nat)"
    60  (fn _ => [rtac (add_commute RS trans) 1, rtac (add_assoc RS trans) 1,
    61            rtac (add_commute RS arg_cong) 1]);
    62 
    63 (*Addition is an AC-operator*)
    64 val add_ac = [add_assoc, add_commute, add_left_commute];
    65 
    66 Goal "!!k::nat. (k + m = k + n) = (m=n)";
    67 by (induct_tac "k" 1);
    68 by (Simp_tac 1);
    69 by (Asm_simp_tac 1);
    70 qed "add_left_cancel";
    71 
    72 Goal "!!k::nat. (m + k = n + k) = (m=n)";
    73 by (induct_tac "k" 1);
    74 by (Simp_tac 1);
    75 by (Asm_simp_tac 1);
    76 qed "add_right_cancel";
    77 
    78 Goal "!!k::nat. (k + m <= k + n) = (m<=n)";
    79 by (induct_tac "k" 1);
    80 by (Simp_tac 1);
    81 by (Asm_simp_tac 1);
    82 qed "add_left_cancel_le";
    83 
    84 Goal "!!k::nat. (k + m < k + n) = (m<n)";
    85 by (induct_tac "k" 1);
    86 by (Simp_tac 1);
    87 by (Asm_simp_tac 1);
    88 qed "add_left_cancel_less";
    89 
    90 Addsimps [add_left_cancel, add_right_cancel,
    91           add_left_cancel_le, add_left_cancel_less];
    92 
    93 (** Reasoning about m+0=0, etc. **)
    94 
    95 Goal "(m+n = 0) = (m=0 & n=0)";
    96 by (induct_tac "m" 1);
    97 by (ALLGOALS Asm_simp_tac);
    98 qed "add_is_0";
    99 AddIffs [add_is_0];
   100 
   101 Goal "(0<m+n) = (0<m | 0<n)";
   102 by (simp_tac (simpset() delsimps [neq0_conv] addsimps [neq0_conv RS sym]) 1);
   103 qed "add_gr_0";
   104 AddIffs [add_gr_0];
   105 
   106 (* FIXME: really needed?? *)
   107 Goal "((m+n)-1 = 0) = (m=0 & n-1 = 0 | m-1 = 0 & n=0)";
   108 by (exhaust_tac "m" 1);
   109 by (ALLGOALS (fast_tac (claset() addss (simpset()))));
   110 qed "pred_add_is_0";
   111 Addsimps [pred_add_is_0];
   112 
   113 (* Could be generalized, eg to "!!n. k<n ==> m+(n-(Suc k)) = (m+n)-(Suc k)" *)
   114 Goal "0<n ==> m + (n-1) = (m+n)-1";
   115 by (exhaust_tac "m" 1);
   116 by (ALLGOALS (asm_simp_tac (simpset() addsimps [diff_Suc]
   117                                       addsplits [nat.split])));
   118 qed "add_pred";
   119 Addsimps [add_pred];
   120 
   121 Goal "!!m::nat. m + n = m ==> n = 0";
   122 by (dtac (add_0_right RS ssubst) 1);
   123 by (asm_full_simp_tac (simpset() addsimps [add_assoc]
   124                                  delsimps [add_0_right]) 1);
   125 qed "add_eq_self_zero";
   126 
   127 
   128 (**** Additional theorems about "less than" ****)
   129 
   130 (*Deleted less_natE; instead use less_eq_Suc_add RS exE*)
   131 Goal "m<n --> (? k. n=Suc(m+k))";
   132 by (induct_tac "n" 1);
   133 by (ALLGOALS (simp_tac (simpset() addsimps [less_Suc_eq])));
   134 by (blast_tac (claset() addSEs [less_SucE] 
   135                        addSIs [add_0_right RS sym, add_Suc_right RS sym]) 1);
   136 qed_spec_mp "less_eq_Suc_add";
   137 
   138 Goal "n <= ((m + n)::nat)";
   139 by (induct_tac "m" 1);
   140 by (ALLGOALS Simp_tac);
   141 by (etac le_trans 1);
   142 by (rtac (lessI RS less_imp_le) 1);
   143 qed "le_add2";
   144 
   145 Goal "n <= ((n + m)::nat)";
   146 by (simp_tac (simpset() addsimps add_ac) 1);
   147 by (rtac le_add2 1);
   148 qed "le_add1";
   149 
   150 bind_thm ("less_add_Suc1", (lessI RS (le_add1 RS le_less_trans)));
   151 bind_thm ("less_add_Suc2", (lessI RS (le_add2 RS le_less_trans)));
   152 
   153 (*"i <= j ==> i <= j+m"*)
   154 bind_thm ("trans_le_add1", le_add1 RSN (2,le_trans));
   155 
   156 (*"i <= j ==> i <= m+j"*)
   157 bind_thm ("trans_le_add2", le_add2 RSN (2,le_trans));
   158 
   159 (*"i < j ==> i < j+m"*)
   160 bind_thm ("trans_less_add1", le_add1 RSN (2,less_le_trans));
   161 
   162 (*"i < j ==> i < m+j"*)
   163 bind_thm ("trans_less_add2", le_add2 RSN (2,less_le_trans));
   164 
   165 Goal "i+j < (k::nat) ==> i<k";
   166 by (etac rev_mp 1);
   167 by (induct_tac "j" 1);
   168 by (ALLGOALS Asm_simp_tac);
   169 by (blast_tac (claset() addDs [Suc_lessD]) 1);
   170 qed "add_lessD1";
   171 
   172 Goal "!!i::nat. ~ (i+j < i)";
   173 by (rtac notI 1);
   174 by (etac (add_lessD1 RS less_irrefl) 1);
   175 qed "not_add_less1";
   176 
   177 Goal "!!i::nat. ~ (j+i < i)";
   178 by (simp_tac (simpset() addsimps [add_commute, not_add_less1]) 1);
   179 qed "not_add_less2";
   180 AddIffs [not_add_less1, not_add_less2];
   181 
   182 Goal "m+k<=n --> m<=(n::nat)";
   183 by (induct_tac "k" 1);
   184 by (ALLGOALS Asm_simp_tac);
   185 by (blast_tac (claset() addDs [Suc_leD]) 1);
   186 qed_spec_mp "add_leD1";
   187 
   188 Goal "!!n::nat. m+k<=n ==> k<=n";
   189 by (full_simp_tac (simpset() addsimps [add_commute]) 1);
   190 by (etac add_leD1 1);
   191 qed_spec_mp "add_leD2";
   192 
   193 Goal "!!n::nat. m+k<=n ==> m<=n & k<=n";
   194 by (blast_tac (claset() addDs [add_leD1, add_leD2]) 1);
   195 bind_thm ("add_leE", result() RS conjE);
   196 
   197 Goal "!!k l::nat. [| k<l; m+l = k+n |] ==> m<n";
   198 by (safe_tac (claset() addSDs [less_eq_Suc_add]));
   199 by (asm_full_simp_tac
   200     (simpset() delsimps [add_Suc_right]
   201                 addsimps ([add_Suc_right RS sym, add_left_cancel] @add_ac)) 1);
   202 by (etac subst 1);
   203 by (simp_tac (simpset() addsimps [less_add_Suc1]) 1);
   204 qed "less_add_eq_less";
   205 
   206 
   207 (*** Monotonicity of Addition ***)
   208 
   209 (*strict, in 1st argument*)
   210 Goal "!!i j k::nat. i < j ==> i + k < j + k";
   211 by (induct_tac "k" 1);
   212 by (ALLGOALS Asm_simp_tac);
   213 qed "add_less_mono1";
   214 
   215 (*strict, in both arguments*)
   216 Goal "!!i j k::nat. [|i < j; k < l|] ==> i + k < j + l";
   217 by (rtac (add_less_mono1 RS less_trans) 1);
   218 by (REPEAT (assume_tac 1));
   219 by (induct_tac "j" 1);
   220 by (ALLGOALS Asm_simp_tac);
   221 qed "add_less_mono";
   222 
   223 (*A [clumsy] way of lifting < monotonicity to <= monotonicity *)
   224 val [lt_mono,le] = Goal
   225      "[| !!i j::nat. i<j ==> f(i) < f(j);       \
   226 \        i <= j                                 \
   227 \     |] ==> f(i) <= (f(j)::nat)";
   228 by (cut_facts_tac [le] 1);
   229 by (asm_full_simp_tac (simpset() addsimps [le_eq_less_or_eq]) 1);
   230 by (blast_tac (claset() addSIs [lt_mono]) 1);
   231 qed "less_mono_imp_le_mono";
   232 
   233 (*non-strict, in 1st argument*)
   234 Goal "!!i j k::nat. i<=j ==> i + k <= j + k";
   235 by (res_inst_tac [("f", "%j. j+k")] less_mono_imp_le_mono 1);
   236 by (etac add_less_mono1 1);
   237 by (assume_tac 1);
   238 qed "add_le_mono1";
   239 
   240 (*non-strict, in both arguments*)
   241 Goal "!!k l::nat. [|i<=j;  k<=l |] ==> i + k <= j + l";
   242 by (etac (add_le_mono1 RS le_trans) 1);
   243 by (simp_tac (simpset() addsimps [add_commute]) 1);
   244 (*j moves to the end because it is free while k, l are bound*)
   245 by (etac add_le_mono1 1);
   246 qed "add_le_mono";
   247 
   248 
   249 (*** Multiplication ***)
   250 
   251 (*right annihilation in product*)
   252 qed_goal "mult_0_right" thy "m * 0 = 0"
   253  (fn _ => [induct_tac "m" 1, ALLGOALS Asm_simp_tac]);
   254 
   255 (*right successor law for multiplication*)
   256 qed_goal "mult_Suc_right" thy  "m * Suc(n) = m + (m * n)"
   257  (fn _ => [induct_tac "m" 1,
   258            ALLGOALS(asm_simp_tac (simpset() addsimps add_ac))]);
   259 
   260 Addsimps [mult_0_right, mult_Suc_right];
   261 
   262 Goal "1 * n = n";
   263 by (Asm_simp_tac 1);
   264 qed "mult_1";
   265 
   266 Goal "n * 1 = n";
   267 by (Asm_simp_tac 1);
   268 qed "mult_1_right";
   269 
   270 (*Commutative law for multiplication*)
   271 qed_goal "mult_commute" thy "m * n = n * (m::nat)"
   272  (fn _ => [induct_tac "m" 1, ALLGOALS Asm_simp_tac]);
   273 
   274 (*addition distributes over multiplication*)
   275 qed_goal "add_mult_distrib" thy "(m + n)*k = (m*k) + ((n*k)::nat)"
   276  (fn _ => [induct_tac "m" 1,
   277            ALLGOALS(asm_simp_tac (simpset() addsimps add_ac))]);
   278 
   279 qed_goal "add_mult_distrib2" thy "k*(m + n) = (k*m) + ((k*n)::nat)"
   280  (fn _ => [induct_tac "m" 1,
   281            ALLGOALS(asm_simp_tac (simpset() addsimps add_ac))]);
   282 
   283 (*Associative law for multiplication*)
   284 qed_goal "mult_assoc" thy "(m * n) * k = m * ((n * k)::nat)"
   285   (fn _ => [induct_tac "m" 1, 
   286             ALLGOALS (asm_simp_tac (simpset() addsimps [add_mult_distrib]))]);
   287 
   288 qed_goal "mult_left_commute" thy "x*(y*z) = y*((x*z)::nat)"
   289  (fn _ => [rtac trans 1, rtac mult_commute 1, rtac trans 1,
   290            rtac mult_assoc 1, rtac (mult_commute RS arg_cong) 1]);
   291 
   292 val mult_ac = [mult_assoc,mult_commute,mult_left_commute];
   293 
   294 Goal "(m*n = 0) = (m=0 | n=0)";
   295 by (induct_tac "m" 1);
   296 by (induct_tac "n" 2);
   297 by (ALLGOALS Asm_simp_tac);
   298 qed "mult_is_0";
   299 Addsimps [mult_is_0];
   300 
   301 Goal "!!m::nat. m <= m*m";
   302 by (induct_tac "m" 1);
   303 by (ALLGOALS (asm_simp_tac (simpset() addsimps [add_assoc RS sym])));
   304 by (etac (le_add2 RSN (2,le_trans)) 1);
   305 qed "le_square";
   306 
   307 
   308 (*** Difference ***)
   309 
   310 
   311 qed_goal "diff_self_eq_0" thy "m - m = 0"
   312  (fn _ => [induct_tac "m" 1, ALLGOALS Asm_simp_tac]);
   313 Addsimps [diff_self_eq_0];
   314 
   315 (*Addition is the inverse of subtraction: if n<=m then n+(m-n) = m. *)
   316 Goal "~ m<n --> n+(m-n) = (m::nat)";
   317 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   318 by (ALLGOALS Asm_simp_tac);
   319 qed_spec_mp "add_diff_inverse";
   320 
   321 Goal "n<=m ==> n+(m-n) = (m::nat)";
   322 by (asm_simp_tac (simpset() addsimps [add_diff_inverse, not_less_iff_le]) 1);
   323 qed "le_add_diff_inverse";
   324 
   325 Goal "n<=m ==> (m-n)+n = (m::nat)";
   326 by (asm_simp_tac (simpset() addsimps [le_add_diff_inverse, add_commute]) 1);
   327 qed "le_add_diff_inverse2";
   328 
   329 Addsimps  [le_add_diff_inverse, le_add_diff_inverse2];
   330 
   331 
   332 (*** More results about difference ***)
   333 
   334 Goal "n < Suc(m) ==> Suc(m)-n = Suc(m-n)";
   335 by (etac rev_mp 1);
   336 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   337 by (ALLGOALS Asm_simp_tac);
   338 qed "Suc_diff_n";
   339 
   340 Goal "m - n < Suc(m)";
   341 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   342 by (etac less_SucE 3);
   343 by (ALLGOALS (asm_simp_tac (simpset() addsimps [less_Suc_eq])));
   344 qed "diff_less_Suc";
   345 
   346 Goal "!!m::nat. m - n <= m";
   347 by (res_inst_tac [("m","m"), ("n","n")] diff_induct 1);
   348 by (ALLGOALS Asm_simp_tac);
   349 qed "diff_le_self";
   350 Addsimps [diff_le_self];
   351 
   352 (* j<k ==> j-n < k *)
   353 bind_thm ("less_imp_diff_less", diff_le_self RS le_less_trans);
   354 
   355 Goal "!!i::nat. i-j-k = i - (j+k)";
   356 by (res_inst_tac [("m","i"),("n","j")] diff_induct 1);
   357 by (ALLGOALS Asm_simp_tac);
   358 qed "diff_diff_left";
   359 
   360 Goal "(Suc m - n) - Suc k = m - n - k";
   361 by (simp_tac (simpset() addsimps [diff_diff_left]) 1);
   362 qed "Suc_diff_diff";
   363 Addsimps [Suc_diff_diff];
   364 
   365 Goal "0<n ==> n - Suc i < n";
   366 by (exhaust_tac "n" 1);
   367 by Safe_tac;
   368 by (asm_simp_tac (simpset() addsimps [le_eq_less_Suc RS sym]) 1);
   369 qed "diff_Suc_less";
   370 Addsimps [diff_Suc_less];
   371 
   372 Goal "i<n ==> n - Suc i < n - i";
   373 by (exhaust_tac "n" 1);
   374 by Safe_tac;
   375 by (asm_simp_tac (simpset() addsimps [Suc_diff_n]) 1);
   376 qed "diff_Suc_less_diff";
   377 
   378 Goal "m - n <= Suc m - n";
   379 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   380 by (ALLGOALS Asm_simp_tac);
   381 qed "diff_le_Suc_diff";
   382 
   383 (*This and the next few suggested by Florian Kammueller*)
   384 Goal "!!i::nat. i-j-k = i-k-j";
   385 by (simp_tac (simpset() addsimps [diff_diff_left, add_commute]) 1);
   386 qed "diff_commute";
   387 
   388 Goal "!!i j k:: nat. k<=j --> j<=i --> i - (j - k) = i - j + k";
   389 by (res_inst_tac [("m","i"),("n","j")] diff_induct 1);
   390 by (ALLGOALS Asm_simp_tac);
   391 by (asm_simp_tac
   392     (simpset() addsimps [Suc_diff_n, le_imp_less_Suc, le_Suc_eq]) 1);
   393 qed_spec_mp "diff_diff_right";
   394 
   395 Goal "!!i j k:: nat. k<=j --> (i + j) - k = i + (j - k)";
   396 by (res_inst_tac [("m","j"),("n","k")] diff_induct 1);
   397 by (ALLGOALS Asm_simp_tac);
   398 qed_spec_mp "diff_add_assoc";
   399 
   400 Goal "!!i j k:: nat. k<=j --> (j + i) - k = i + (j - k)";
   401 by (asm_simp_tac (simpset() addsimps [add_commute, diff_add_assoc]) 1);
   402 qed_spec_mp "diff_add_assoc2";
   403 
   404 Goal "!!n::nat. (n+m) - n = m";
   405 by (induct_tac "n" 1);
   406 by (ALLGOALS Asm_simp_tac);
   407 qed "diff_add_inverse";
   408 Addsimps [diff_add_inverse];
   409 
   410 Goal "!!n::nat.(m+n) - n = m";
   411 by (simp_tac (simpset() addsimps [diff_add_assoc]) 1);
   412 qed "diff_add_inverse2";
   413 Addsimps [diff_add_inverse2];
   414 
   415 Goal "!!i j k::nat. i<=j ==> (j-i=k) = (j=k+i)";
   416 by Safe_tac;
   417 by (ALLGOALS Asm_simp_tac);
   418 qed "le_imp_diff_is_add";
   419 
   420 Goal "m < Suc(n) ==> m-n = 0";
   421 by (etac rev_mp 1);
   422 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   423 by (asm_simp_tac (simpset() addsimps [less_Suc_eq]) 1);
   424 by (ALLGOALS Asm_simp_tac);
   425 qed "less_imp_diff_is_0";
   426 
   427 Goal "m-n = 0  -->  n-m = 0  -->  m=n";
   428 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   429 by (REPEAT(Simp_tac 1 THEN TRY(atac 1)));
   430 qed_spec_mp "diffs0_imp_equal";
   431 
   432 Goal "(0<n-m) = (m<n)";
   433 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   434 by (ALLGOALS Asm_simp_tac);
   435 qed "zero_less_diff";
   436 Addsimps [zero_less_diff];
   437 
   438 Goal "i < j  ==> ? k. 0<k & i+k = j";
   439 by (res_inst_tac [("x","j - i")] exI 1);
   440 by (asm_simp_tac (simpset() addsimps [add_diff_inverse, less_not_sym]) 1);
   441 qed "less_imp_add_positive";
   442 
   443 Goal "Suc(m)-n = (if m<n then 0 else Suc(m-n))";
   444 by (simp_tac (simpset() addsimps [less_imp_diff_is_0,
   445 				  not_less_eq, Suc_diff_n]) 1);
   446 qed "if_Suc_diff_n";
   447 
   448 Goal "Suc(m)-n <= Suc(m-n)";
   449 by (simp_tac (simpset() addsimps [if_Suc_diff_n]) 1);
   450 qed "diff_Suc_le_Suc_diff";
   451 
   452 Goal "P(k) --> (!n. P(Suc(n))--> P(n)) --> P(k-i)";
   453 by (res_inst_tac [("m","k"),("n","i")] diff_induct 1);
   454 by (ALLGOALS (Clarify_tac THEN' Simp_tac THEN' TRY o Blast_tac));
   455 qed "zero_induct_lemma";
   456 
   457 val prems = Goal "[| P(k);  !!n. P(Suc(n)) ==> P(n) |] ==> P(0)";
   458 by (rtac (diff_self_eq_0 RS subst) 1);
   459 by (rtac (zero_induct_lemma RS mp RS mp) 1);
   460 by (REPEAT (ares_tac ([impI,allI]@prems) 1));
   461 qed "zero_induct";
   462 
   463 Goal "!!k::nat. (k+m) - (k+n) = m - n";
   464 by (induct_tac "k" 1);
   465 by (ALLGOALS Asm_simp_tac);
   466 qed "diff_cancel";
   467 Addsimps [diff_cancel];
   468 
   469 Goal "!!m::nat. (m+k) - (n+k) = m - n";
   470 val add_commute_k = read_instantiate [("n","k")] add_commute;
   471 by (asm_simp_tac (simpset() addsimps ([add_commute_k])) 1);
   472 qed "diff_cancel2";
   473 Addsimps [diff_cancel2];
   474 
   475 (*From Clemens Ballarin*)
   476 Goal "!!n::nat. [| k<=n; n<=m |] ==> (m-k) - (n-k) = m-n";
   477 by (subgoal_tac "k<=n --> n<=m --> (m-k) - (n-k) = m-n" 1);
   478 by (Asm_full_simp_tac 1);
   479 by (induct_tac "k" 1);
   480 by (Simp_tac 1);
   481 (* Induction step *)
   482 by (subgoal_tac "Suc na <= m --> n <= m --> Suc na <= n --> \
   483 \                Suc (m - Suc na) - Suc (n - Suc na) = m-n" 1);
   484 by (Asm_full_simp_tac 1);
   485 by (blast_tac (claset() addIs [le_trans]) 1);
   486 by (auto_tac (claset() addIs [Suc_leD], simpset() delsimps [diff_Suc_Suc]));
   487 by (asm_full_simp_tac (simpset() delsimps [Suc_less_eq] 
   488 		       addsimps [Suc_diff_n RS sym, le_eq_less_Suc]) 1);
   489 qed "diff_right_cancel";
   490 
   491 Goal "!!n::nat. n - (n+m) = 0";
   492 by (induct_tac "n" 1);
   493 by (ALLGOALS Asm_simp_tac);
   494 qed "diff_add_0";
   495 Addsimps [diff_add_0];
   496 
   497 (** Difference distributes over multiplication **)
   498 
   499 Goal "!!m::nat. (m - n) * k = (m * k) - (n * k)";
   500 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   501 by (ALLGOALS Asm_simp_tac);
   502 qed "diff_mult_distrib" ;
   503 
   504 Goal "!!m::nat. k * (m - n) = (k * m) - (k * n)";
   505 val mult_commute_k = read_instantiate [("m","k")] mult_commute;
   506 by (simp_tac (simpset() addsimps [diff_mult_distrib, mult_commute_k]) 1);
   507 qed "diff_mult_distrib2" ;
   508 (*NOT added as rewrites, since sometimes they are used from right-to-left*)
   509 
   510 
   511 (*** Monotonicity of Multiplication ***)
   512 
   513 Goal "!!i::nat. i<=j ==> i*k<=j*k";
   514 by (induct_tac "k" 1);
   515 by (ALLGOALS (asm_simp_tac (simpset() addsimps [add_le_mono])));
   516 qed "mult_le_mono1";
   517 
   518 (*<=monotonicity, BOTH arguments*)
   519 Goal "!!i::nat. [| i<=j; k<=l |] ==> i*k<=j*l";
   520 by (etac (mult_le_mono1 RS le_trans) 1);
   521 by (rtac le_trans 1);
   522 by (stac mult_commute 2);
   523 by (etac mult_le_mono1 2);
   524 by (simp_tac (simpset() addsimps [mult_commute]) 1);
   525 qed "mult_le_mono";
   526 
   527 (*strict, in 1st argument; proof is by induction on k>0*)
   528 Goal "!!i::nat. [| i<j; 0<k |] ==> k*i < k*j";
   529 by (eres_inst_tac [("m1","0")] (less_eq_Suc_add RS exE) 1);
   530 by (Asm_simp_tac 1);
   531 by (induct_tac "x" 1);
   532 by (ALLGOALS (asm_simp_tac (simpset() addsimps [add_less_mono])));
   533 qed "mult_less_mono2";
   534 
   535 Goal "!!i::nat. [| i<j; 0<k |] ==> i*k < j*k";
   536 by (dtac mult_less_mono2 1);
   537 by (ALLGOALS (asm_full_simp_tac (simpset() addsimps [mult_commute])));
   538 qed "mult_less_mono1";
   539 
   540 Goal "(0 < m*n) = (0<m & 0<n)";
   541 by (induct_tac "m" 1);
   542 by (induct_tac "n" 2);
   543 by (ALLGOALS Asm_simp_tac);
   544 qed "zero_less_mult_iff";
   545 Addsimps [zero_less_mult_iff];
   546 
   547 Goal "(m*n = 1) = (m=1 & n=1)";
   548 by (induct_tac "m" 1);
   549 by (Simp_tac 1);
   550 by (induct_tac "n" 1);
   551 by (Simp_tac 1);
   552 by (fast_tac (claset() addss simpset()) 1);
   553 qed "mult_eq_1_iff";
   554 Addsimps [mult_eq_1_iff];
   555 
   556 Goal "0<k ==> (m*k < n*k) = (m<n)";
   557 by (safe_tac (claset() addSIs [mult_less_mono1]));
   558 by (cut_facts_tac [less_linear] 1);
   559 by (blast_tac (claset() addIs [mult_less_mono1] addEs [less_asym]) 1);
   560 qed "mult_less_cancel2";
   561 
   562 Goal "0<k ==> (k*m < k*n) = (m<n)";
   563 by (dtac mult_less_cancel2 1);
   564 by (asm_full_simp_tac (simpset() addsimps [mult_commute]) 1);
   565 qed "mult_less_cancel1";
   566 Addsimps [mult_less_cancel1, mult_less_cancel2];
   567 
   568 Goal "(Suc k * m < Suc k * n) = (m < n)";
   569 by (rtac mult_less_cancel1 1);
   570 by (Simp_tac 1);
   571 qed "Suc_mult_less_cancel1";
   572 
   573 Goalw [le_def] "(Suc k * m <= Suc k * n) = (m <= n)";
   574 by (simp_tac (simpset_of HOL.thy) 1);
   575 by (rtac Suc_mult_less_cancel1 1);
   576 qed "Suc_mult_le_cancel1";
   577 
   578 Goal "0<k ==> (m*k = n*k) = (m=n)";
   579 by (cut_facts_tac [less_linear] 1);
   580 by Safe_tac;
   581 by (assume_tac 2);
   582 by (ALLGOALS (dtac mult_less_mono1 THEN' assume_tac));
   583 by (ALLGOALS Asm_full_simp_tac);
   584 qed "mult_cancel2";
   585 
   586 Goal "0<k ==> (k*m = k*n) = (m=n)";
   587 by (dtac mult_cancel2 1);
   588 by (asm_full_simp_tac (simpset() addsimps [mult_commute]) 1);
   589 qed "mult_cancel1";
   590 Addsimps [mult_cancel1, mult_cancel2];
   591 
   592 Goal "(Suc k * m = Suc k * n) = (m = n)";
   593 by (rtac mult_cancel1 1);
   594 by (Simp_tac 1);
   595 qed "Suc_mult_cancel1";
   596 
   597 
   598 (** Lemma for gcd **)
   599 
   600 Goal "m = m*n ==> n=1 | m=0";
   601 by (dtac sym 1);
   602 by (rtac disjCI 1);
   603 by (rtac nat_less_cases 1 THEN assume_tac 2);
   604 by (fast_tac (claset() addSEs [less_SucE] addss simpset()) 1);
   605 by (best_tac (claset() addDs [mult_less_mono2] addss simpset()) 1);
   606 qed "mult_eq_self_implies_10";
   607 
   608 
   609 (*** Subtraction laws -- mostly from Clemens Ballarin ***)
   610 
   611 Goal "!! a b c::nat. [| a < b; c <= a |] ==> a-c < b-c";
   612 by (subgoal_tac "c+(a-c) < c+(b-c)" 1);
   613 by (Full_simp_tac 1);
   614 by (subgoal_tac "c <= b" 1);
   615 by (blast_tac (claset() addIs [less_imp_le, le_trans]) 2);
   616 by (Asm_simp_tac 1);
   617 qed "diff_less_mono";
   618 
   619 Goal "!! a b c::nat. a+b < c ==> a < c-b";
   620 by (dtac diff_less_mono 1);
   621 by (rtac le_add2 1);
   622 by (Asm_full_simp_tac 1);
   623 qed "add_less_imp_less_diff";
   624 
   625 Goal "n <= m ==> Suc m - n = Suc (m - n)";
   626 by (asm_full_simp_tac (simpset() addsimps [Suc_diff_n, le_eq_less_Suc]) 1);
   627 qed "Suc_diff_le";
   628 
   629 Goal "Suc i <= n ==> Suc (n - Suc i) = n - i";
   630 by (asm_full_simp_tac
   631     (simpset() addsimps [Suc_diff_n RS sym, le_eq_less_Suc]) 1);
   632 qed "Suc_diff_Suc";
   633 
   634 Goal "!! i::nat. i <= n ==> n - (n - i) = i";
   635 by (etac rev_mp 1);
   636 by (res_inst_tac [("m","n"),("n","i")] diff_induct 1);
   637 by (ALLGOALS (asm_simp_tac  (simpset() addsimps [Suc_diff_le])));
   638 qed "diff_diff_cancel";
   639 Addsimps [diff_diff_cancel];
   640 
   641 Goal "!!k::nat. k <= n ==> m <= n + m - k";
   642 by (etac rev_mp 1);
   643 by (res_inst_tac [("m", "k"), ("n", "n")] diff_induct 1);
   644 by (Simp_tac 1);
   645 by (simp_tac (simpset() addsimps [less_add_Suc2, less_imp_le]) 1);
   646 by (Simp_tac 1);
   647 qed "le_add_diff";
   648 
   649 Goal "!!i::nat. 0<k ==> j<i --> j+k-i < k";
   650 by (res_inst_tac [("m","j"),("n","i")] diff_induct 1);
   651 by (ALLGOALS Asm_simp_tac);
   652 qed_spec_mp "add_diff_less";
   653 
   654 
   655 
   656 (** (Anti)Monotonicity of subtraction -- by Stefan Merz **)
   657 
   658 (* Monotonicity of subtraction in first argument *)
   659 Goal "!!n::nat. m<=n --> (m-l) <= (n-l)";
   660 by (induct_tac "n" 1);
   661 by (Simp_tac 1);
   662 by (simp_tac (simpset() addsimps [le_Suc_eq]) 1);
   663 by (blast_tac (claset() addIs [diff_le_Suc_diff, le_trans]) 1);
   664 qed_spec_mp "diff_le_mono";
   665 
   666 Goal "!!n::nat. m<=n ==> (l-n) <= (l-m)";
   667 by (induct_tac "l" 1);
   668 by (Simp_tac 1);
   669 by (case_tac "n <= na" 1);
   670 by (subgoal_tac "m <= na" 1);
   671 by (asm_simp_tac (simpset() addsimps [Suc_diff_le]) 1);
   672 by (fast_tac (claset() addEs [le_trans]) 1);
   673 by (dtac not_leE 1);
   674 by (asm_simp_tac (simpset() addsimps [if_Suc_diff_n]) 1);
   675 qed_spec_mp "diff_le_mono2";