src/HOL/Library/Polynomial.thy
author haftmann
Wed Jul 08 14:01:39 2015 +0200 (2015-07-08)
changeset 60686 ea5bc46c11e6
parent 60685 cb21b7022b00
child 61260 e6f03fae14d5
permissions -rw-r--r--
more algebraic properties for gcd/lcm
     1 (*  Title:      HOL/Library/Polynomial.thy
     2     Author:     Brian Huffman
     3     Author:     Clemens Ballarin
     4     Author:     Florian Haftmann
     5 *)
     6 
     7 section \<open>Polynomials as type over a ring structure\<close>
     8 
     9 theory Polynomial
    10 imports Main "~~/src/HOL/GCD" "~~/src/HOL/Library/More_List" "~~/src/HOL/Library/Infinite_Set"
    11 begin
    12 
    13 subsection \<open>Auxiliary: operations for lists (later) representing coefficients\<close>
    14 
    15 definition cCons :: "'a::zero \<Rightarrow> 'a list \<Rightarrow> 'a list"  (infixr "##" 65)
    16 where
    17   "x ## xs = (if xs = [] \<and> x = 0 then [] else x # xs)"
    18 
    19 lemma cCons_0_Nil_eq [simp]:
    20   "0 ## [] = []"
    21   by (simp add: cCons_def)
    22 
    23 lemma cCons_Cons_eq [simp]:
    24   "x ## y # ys = x # y # ys"
    25   by (simp add: cCons_def)
    26 
    27 lemma cCons_append_Cons_eq [simp]:
    28   "x ## xs @ y # ys = x # xs @ y # ys"
    29   by (simp add: cCons_def)
    30 
    31 lemma cCons_not_0_eq [simp]:
    32   "x \<noteq> 0 \<Longrightarrow> x ## xs = x # xs"
    33   by (simp add: cCons_def)
    34 
    35 lemma strip_while_not_0_Cons_eq [simp]:
    36   "strip_while (\<lambda>x. x = 0) (x # xs) = x ## strip_while (\<lambda>x. x = 0) xs"
    37 proof (cases "x = 0")
    38   case False then show ?thesis by simp
    39 next
    40   case True show ?thesis
    41   proof (induct xs rule: rev_induct)
    42     case Nil with True show ?case by simp
    43   next
    44     case (snoc y ys) then show ?case
    45       by (cases "y = 0") (simp_all add: append_Cons [symmetric] del: append_Cons)
    46   qed
    47 qed
    48 
    49 lemma tl_cCons [simp]:
    50   "tl (x ## xs) = xs"
    51   by (simp add: cCons_def)
    52 
    53 subsection \<open>Definition of type @{text poly}\<close>
    54 
    55 typedef 'a poly = "{f :: nat \<Rightarrow> 'a::zero. \<forall>\<^sub>\<infinity> n. f n = 0}"
    56   morphisms coeff Abs_poly by (auto intro!: ALL_MOST)
    57 
    58 setup_lifting type_definition_poly
    59 
    60 lemma poly_eq_iff: "p = q \<longleftrightarrow> (\<forall>n. coeff p n = coeff q n)"
    61   by (simp add: coeff_inject [symmetric] fun_eq_iff)
    62 
    63 lemma poly_eqI: "(\<And>n. coeff p n = coeff q n) \<Longrightarrow> p = q"
    64   by (simp add: poly_eq_iff)
    65 
    66 lemma MOST_coeff_eq_0: "\<forall>\<^sub>\<infinity> n. coeff p n = 0"
    67   using coeff [of p] by simp
    68 
    69 
    70 subsection \<open>Degree of a polynomial\<close>
    71 
    72 definition degree :: "'a::zero poly \<Rightarrow> nat"
    73 where
    74   "degree p = (LEAST n. \<forall>i>n. coeff p i = 0)"
    75 
    76 lemma coeff_eq_0:
    77   assumes "degree p < n"
    78   shows "coeff p n = 0"
    79 proof -
    80   have "\<exists>n. \<forall>i>n. coeff p i = 0"
    81     using MOST_coeff_eq_0 by (simp add: MOST_nat)
    82   then have "\<forall>i>degree p. coeff p i = 0"
    83     unfolding degree_def by (rule LeastI_ex)
    84   with assms show ?thesis by simp
    85 qed
    86 
    87 lemma le_degree: "coeff p n \<noteq> 0 \<Longrightarrow> n \<le> degree p"
    88   by (erule contrapos_np, rule coeff_eq_0, simp)
    89 
    90 lemma degree_le: "\<forall>i>n. coeff p i = 0 \<Longrightarrow> degree p \<le> n"
    91   unfolding degree_def by (erule Least_le)
    92 
    93 lemma less_degree_imp: "n < degree p \<Longrightarrow> \<exists>i>n. coeff p i \<noteq> 0"
    94   unfolding degree_def by (drule not_less_Least, simp)
    95 
    96 
    97 subsection \<open>The zero polynomial\<close>
    98 
    99 instantiation poly :: (zero) zero
   100 begin
   101 
   102 lift_definition zero_poly :: "'a poly"
   103   is "\<lambda>_. 0" by (rule MOST_I) simp
   104 
   105 instance ..
   106 
   107 end
   108 
   109 lemma coeff_0 [simp]:
   110   "coeff 0 n = 0"
   111   by transfer rule
   112 
   113 lemma degree_0 [simp]:
   114   "degree 0 = 0"
   115   by (rule order_antisym [OF degree_le le0]) simp
   116 
   117 lemma leading_coeff_neq_0:
   118   assumes "p \<noteq> 0"
   119   shows "coeff p (degree p) \<noteq> 0"
   120 proof (cases "degree p")
   121   case 0
   122   from \<open>p \<noteq> 0\<close> have "\<exists>n. coeff p n \<noteq> 0"
   123     by (simp add: poly_eq_iff)
   124   then obtain n where "coeff p n \<noteq> 0" ..
   125   hence "n \<le> degree p" by (rule le_degree)
   126   with \<open>coeff p n \<noteq> 0\<close> and \<open>degree p = 0\<close>
   127   show "coeff p (degree p) \<noteq> 0" by simp
   128 next
   129   case (Suc n)
   130   from \<open>degree p = Suc n\<close> have "n < degree p" by simp
   131   hence "\<exists>i>n. coeff p i \<noteq> 0" by (rule less_degree_imp)
   132   then obtain i where "n < i" and "coeff p i \<noteq> 0" by fast
   133   from \<open>degree p = Suc n\<close> and \<open>n < i\<close> have "degree p \<le> i" by simp
   134   also from \<open>coeff p i \<noteq> 0\<close> have "i \<le> degree p" by (rule le_degree)
   135   finally have "degree p = i" .
   136   with \<open>coeff p i \<noteq> 0\<close> show "coeff p (degree p) \<noteq> 0" by simp
   137 qed
   138 
   139 lemma leading_coeff_0_iff [simp]:
   140   "coeff p (degree p) = 0 \<longleftrightarrow> p = 0"
   141   by (cases "p = 0", simp, simp add: leading_coeff_neq_0)
   142 
   143 
   144 subsection \<open>List-style constructor for polynomials\<close>
   145 
   146 lift_definition pCons :: "'a::zero \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   147   is "\<lambda>a p. case_nat a (coeff p)"
   148   by (rule MOST_SucD) (simp add: MOST_coeff_eq_0)
   149 
   150 lemmas coeff_pCons = pCons.rep_eq
   151 
   152 lemma coeff_pCons_0 [simp]:
   153   "coeff (pCons a p) 0 = a"
   154   by transfer simp
   155 
   156 lemma coeff_pCons_Suc [simp]:
   157   "coeff (pCons a p) (Suc n) = coeff p n"
   158   by (simp add: coeff_pCons)
   159 
   160 lemma degree_pCons_le:
   161   "degree (pCons a p) \<le> Suc (degree p)"
   162   by (rule degree_le) (simp add: coeff_eq_0 coeff_pCons split: nat.split)
   163 
   164 lemma degree_pCons_eq:
   165   "p \<noteq> 0 \<Longrightarrow> degree (pCons a p) = Suc (degree p)"
   166   apply (rule order_antisym [OF degree_pCons_le])
   167   apply (rule le_degree, simp)
   168   done
   169 
   170 lemma degree_pCons_0:
   171   "degree (pCons a 0) = 0"
   172   apply (rule order_antisym [OF _ le0])
   173   apply (rule degree_le, simp add: coeff_pCons split: nat.split)
   174   done
   175 
   176 lemma degree_pCons_eq_if [simp]:
   177   "degree (pCons a p) = (if p = 0 then 0 else Suc (degree p))"
   178   apply (cases "p = 0", simp_all)
   179   apply (rule order_antisym [OF _ le0])
   180   apply (rule degree_le, simp add: coeff_pCons split: nat.split)
   181   apply (rule order_antisym [OF degree_pCons_le])
   182   apply (rule le_degree, simp)
   183   done
   184 
   185 lemma pCons_0_0 [simp]:
   186   "pCons 0 0 = 0"
   187   by (rule poly_eqI) (simp add: coeff_pCons split: nat.split)
   188 
   189 lemma pCons_eq_iff [simp]:
   190   "pCons a p = pCons b q \<longleftrightarrow> a = b \<and> p = q"
   191 proof safe
   192   assume "pCons a p = pCons b q"
   193   then have "coeff (pCons a p) 0 = coeff (pCons b q) 0" by simp
   194   then show "a = b" by simp
   195 next
   196   assume "pCons a p = pCons b q"
   197   then have "\<forall>n. coeff (pCons a p) (Suc n) =
   198                  coeff (pCons b q) (Suc n)" by simp
   199   then show "p = q" by (simp add: poly_eq_iff)
   200 qed
   201 
   202 lemma pCons_eq_0_iff [simp]:
   203   "pCons a p = 0 \<longleftrightarrow> a = 0 \<and> p = 0"
   204   using pCons_eq_iff [of a p 0 0] by simp
   205 
   206 lemma pCons_cases [cases type: poly]:
   207   obtains (pCons) a q where "p = pCons a q"
   208 proof
   209   show "p = pCons (coeff p 0) (Abs_poly (\<lambda>n. coeff p (Suc n)))"
   210     by transfer
   211        (simp_all add: MOST_inj[where f=Suc and P="\<lambda>n. p n = 0" for p] fun_eq_iff Abs_poly_inverse
   212                  split: nat.split)
   213 qed
   214 
   215 lemma pCons_induct [case_names 0 pCons, induct type: poly]:
   216   assumes zero: "P 0"
   217   assumes pCons: "\<And>a p. a \<noteq> 0 \<or> p \<noteq> 0 \<Longrightarrow> P p \<Longrightarrow> P (pCons a p)"
   218   shows "P p"
   219 proof (induct p rule: measure_induct_rule [where f=degree])
   220   case (less p)
   221   obtain a q where "p = pCons a q" by (rule pCons_cases)
   222   have "P q"
   223   proof (cases "q = 0")
   224     case True
   225     then show "P q" by (simp add: zero)
   226   next
   227     case False
   228     then have "degree (pCons a q) = Suc (degree q)"
   229       by (rule degree_pCons_eq)
   230     then have "degree q < degree p"
   231       using \<open>p = pCons a q\<close> by simp
   232     then show "P q"
   233       by (rule less.hyps)
   234   qed
   235   have "P (pCons a q)"
   236   proof (cases "a \<noteq> 0 \<or> q \<noteq> 0")
   237     case True
   238     with \<open>P q\<close> show ?thesis by (auto intro: pCons)
   239   next
   240     case False
   241     with zero show ?thesis by simp
   242   qed
   243   then show ?case
   244     using \<open>p = pCons a q\<close> by simp
   245 qed
   246 
   247 lemma degree_eq_zeroE:
   248   fixes p :: "'a::zero poly"
   249   assumes "degree p = 0"
   250   obtains a where "p = pCons a 0"
   251 proof -
   252   obtain a q where p: "p = pCons a q" by (cases p)
   253   with assms have "q = 0" by (cases "q = 0") simp_all
   254   with p have "p = pCons a 0" by simp
   255   with that show thesis .
   256 qed
   257 
   258 
   259 subsection \<open>List-style syntax for polynomials\<close>
   260 
   261 syntax
   262   "_poly" :: "args \<Rightarrow> 'a poly"  ("[:(_):]")
   263 
   264 translations
   265   "[:x, xs:]" == "CONST pCons x [:xs:]"
   266   "[:x:]" == "CONST pCons x 0"
   267   "[:x:]" <= "CONST pCons x (_constrain 0 t)"
   268 
   269 
   270 subsection \<open>Representation of polynomials by lists of coefficients\<close>
   271 
   272 primrec Poly :: "'a::zero list \<Rightarrow> 'a poly"
   273 where
   274   [code_post]: "Poly [] = 0"
   275 | [code_post]: "Poly (a # as) = pCons a (Poly as)"
   276 
   277 lemma Poly_replicate_0 [simp]:
   278   "Poly (replicate n 0) = 0"
   279   by (induct n) simp_all
   280 
   281 lemma Poly_eq_0:
   282   "Poly as = 0 \<longleftrightarrow> (\<exists>n. as = replicate n 0)"
   283   by (induct as) (auto simp add: Cons_replicate_eq)
   284 
   285 definition coeffs :: "'a poly \<Rightarrow> 'a::zero list"
   286 where
   287   "coeffs p = (if p = 0 then [] else map (\<lambda>i. coeff p i) [0 ..< Suc (degree p)])"
   288 
   289 lemma coeffs_eq_Nil [simp]:
   290   "coeffs p = [] \<longleftrightarrow> p = 0"
   291   by (simp add: coeffs_def)
   292 
   293 lemma not_0_coeffs_not_Nil:
   294   "p \<noteq> 0 \<Longrightarrow> coeffs p \<noteq> []"
   295   by simp
   296 
   297 lemma coeffs_0_eq_Nil [simp]:
   298   "coeffs 0 = []"
   299   by simp
   300 
   301 lemma coeffs_pCons_eq_cCons [simp]:
   302   "coeffs (pCons a p) = a ## coeffs p"
   303 proof -
   304   { fix ms :: "nat list" and f :: "nat \<Rightarrow> 'a" and x :: "'a"
   305     assume "\<forall>m\<in>set ms. m > 0"
   306     then have "map (case_nat x f) ms = map f (map (\<lambda>n. n - 1) ms)"
   307       by (induct ms) (auto split: nat.split)
   308   }
   309   note * = this
   310   show ?thesis
   311     by (simp add: coeffs_def * upt_conv_Cons coeff_pCons map_decr_upt del: upt_Suc)
   312 qed
   313 
   314 lemma not_0_cCons_eq [simp]:
   315   "p \<noteq> 0 \<Longrightarrow> a ## coeffs p = a # coeffs p"
   316   by (simp add: cCons_def)
   317 
   318 lemma Poly_coeffs [simp, code abstype]:
   319   "Poly (coeffs p) = p"
   320   by (induct p) auto
   321 
   322 lemma coeffs_Poly [simp]:
   323   "coeffs (Poly as) = strip_while (HOL.eq 0) as"
   324 proof (induct as)
   325   case Nil then show ?case by simp
   326 next
   327   case (Cons a as)
   328   have "(\<forall>n. as \<noteq> replicate n 0) \<longleftrightarrow> (\<exists>a\<in>set as. a \<noteq> 0)"
   329     using replicate_length_same [of as 0] by (auto dest: sym [of _ as])
   330   with Cons show ?case by auto
   331 qed
   332 
   333 lemma last_coeffs_not_0:
   334   "p \<noteq> 0 \<Longrightarrow> last (coeffs p) \<noteq> 0"
   335   by (induct p) (auto simp add: cCons_def)
   336 
   337 lemma strip_while_coeffs [simp]:
   338   "strip_while (HOL.eq 0) (coeffs p) = coeffs p"
   339   by (cases "p = 0") (auto dest: last_coeffs_not_0 intro: strip_while_not_last)
   340 
   341 lemma coeffs_eq_iff:
   342   "p = q \<longleftrightarrow> coeffs p = coeffs q" (is "?P \<longleftrightarrow> ?Q")
   343 proof
   344   assume ?P then show ?Q by simp
   345 next
   346   assume ?Q
   347   then have "Poly (coeffs p) = Poly (coeffs q)" by simp
   348   then show ?P by simp
   349 qed
   350 
   351 lemma coeff_Poly_eq:
   352   "coeff (Poly xs) n = nth_default 0 xs n"
   353   apply (induct xs arbitrary: n) apply simp_all
   354   by (metis nat.case not0_implies_Suc nth_default_Cons_0 nth_default_Cons_Suc pCons.rep_eq)
   355 
   356 lemma nth_default_coeffs_eq:
   357   "nth_default 0 (coeffs p) = coeff p"
   358   by (simp add: fun_eq_iff coeff_Poly_eq [symmetric])
   359 
   360 lemma [code]:
   361   "coeff p = nth_default 0 (coeffs p)"
   362   by (simp add: nth_default_coeffs_eq)
   363 
   364 lemma coeffs_eqI:
   365   assumes coeff: "\<And>n. coeff p n = nth_default 0 xs n"
   366   assumes zero: "xs \<noteq> [] \<Longrightarrow> last xs \<noteq> 0"
   367   shows "coeffs p = xs"
   368 proof -
   369   from coeff have "p = Poly xs" by (simp add: poly_eq_iff coeff_Poly_eq)
   370   with zero show ?thesis by simp (cases xs, simp_all)
   371 qed
   372 
   373 lemma degree_eq_length_coeffs [code]:
   374   "degree p = length (coeffs p) - 1"
   375   by (simp add: coeffs_def)
   376 
   377 lemma length_coeffs_degree:
   378   "p \<noteq> 0 \<Longrightarrow> length (coeffs p) = Suc (degree p)"
   379   by (induct p) (auto simp add: cCons_def)
   380 
   381 lemma [code abstract]:
   382   "coeffs 0 = []"
   383   by (fact coeffs_0_eq_Nil)
   384 
   385 lemma [code abstract]:
   386   "coeffs (pCons a p) = a ## coeffs p"
   387   by (fact coeffs_pCons_eq_cCons)
   388 
   389 instantiation poly :: ("{zero, equal}") equal
   390 begin
   391 
   392 definition
   393   [code]: "HOL.equal (p::'a poly) q \<longleftrightarrow> HOL.equal (coeffs p) (coeffs q)"
   394 
   395 instance
   396   by standard (simp add: equal equal_poly_def coeffs_eq_iff)
   397 
   398 end
   399 
   400 lemma [code nbe]: "HOL.equal (p :: _ poly) p \<longleftrightarrow> True"
   401   by (fact equal_refl)
   402 
   403 definition is_zero :: "'a::zero poly \<Rightarrow> bool"
   404 where
   405   [code]: "is_zero p \<longleftrightarrow> List.null (coeffs p)"
   406 
   407 lemma is_zero_null [code_abbrev]:
   408   "is_zero p \<longleftrightarrow> p = 0"
   409   by (simp add: is_zero_def null_def)
   410 
   411 
   412 subsection \<open>Fold combinator for polynomials\<close>
   413 
   414 definition fold_coeffs :: "('a::zero \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a poly \<Rightarrow> 'b \<Rightarrow> 'b"
   415 where
   416   "fold_coeffs f p = foldr f (coeffs p)"
   417 
   418 lemma fold_coeffs_0_eq [simp]:
   419   "fold_coeffs f 0 = id"
   420   by (simp add: fold_coeffs_def)
   421 
   422 lemma fold_coeffs_pCons_eq [simp]:
   423   "f 0 = id \<Longrightarrow> fold_coeffs f (pCons a p) = f a \<circ> fold_coeffs f p"
   424   by (simp add: fold_coeffs_def cCons_def fun_eq_iff)
   425 
   426 lemma fold_coeffs_pCons_0_0_eq [simp]:
   427   "fold_coeffs f (pCons 0 0) = id"
   428   by (simp add: fold_coeffs_def)
   429 
   430 lemma fold_coeffs_pCons_coeff_not_0_eq [simp]:
   431   "a \<noteq> 0 \<Longrightarrow> fold_coeffs f (pCons a p) = f a \<circ> fold_coeffs f p"
   432   by (simp add: fold_coeffs_def)
   433 
   434 lemma fold_coeffs_pCons_not_0_0_eq [simp]:
   435   "p \<noteq> 0 \<Longrightarrow> fold_coeffs f (pCons a p) = f a \<circ> fold_coeffs f p"
   436   by (simp add: fold_coeffs_def)
   437 
   438 
   439 subsection \<open>Canonical morphism on polynomials -- evaluation\<close>
   440 
   441 definition poly :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a"
   442 where
   443   "poly p = fold_coeffs (\<lambda>a f x. a + x * f x) p (\<lambda>x. 0)" -- \<open>The Horner Schema\<close>
   444 
   445 lemma poly_0 [simp]:
   446   "poly 0 x = 0"
   447   by (simp add: poly_def)
   448 
   449 lemma poly_pCons [simp]:
   450   "poly (pCons a p) x = a + x * poly p x"
   451   by (cases "p = 0 \<and> a = 0") (auto simp add: poly_def)
   452 
   453 
   454 subsection \<open>Monomials\<close>
   455 
   456 lift_definition monom :: "'a \<Rightarrow> nat \<Rightarrow> 'a::zero poly"
   457   is "\<lambda>a m n. if m = n then a else 0"
   458   by (simp add: MOST_iff_cofinite)
   459 
   460 lemma coeff_monom [simp]:
   461   "coeff (monom a m) n = (if m = n then a else 0)"
   462   by transfer rule
   463 
   464 lemma monom_0:
   465   "monom a 0 = pCons a 0"
   466   by (rule poly_eqI) (simp add: coeff_pCons split: nat.split)
   467 
   468 lemma monom_Suc:
   469   "monom a (Suc n) = pCons 0 (monom a n)"
   470   by (rule poly_eqI) (simp add: coeff_pCons split: nat.split)
   471 
   472 lemma monom_eq_0 [simp]: "monom 0 n = 0"
   473   by (rule poly_eqI) simp
   474 
   475 lemma monom_eq_0_iff [simp]: "monom a n = 0 \<longleftrightarrow> a = 0"
   476   by (simp add: poly_eq_iff)
   477 
   478 lemma monom_eq_iff [simp]: "monom a n = monom b n \<longleftrightarrow> a = b"
   479   by (simp add: poly_eq_iff)
   480 
   481 lemma degree_monom_le: "degree (monom a n) \<le> n"
   482   by (rule degree_le, simp)
   483 
   484 lemma degree_monom_eq: "a \<noteq> 0 \<Longrightarrow> degree (monom a n) = n"
   485   apply (rule order_antisym [OF degree_monom_le])
   486   apply (rule le_degree, simp)
   487   done
   488 
   489 lemma coeffs_monom [code abstract]:
   490   "coeffs (monom a n) = (if a = 0 then [] else replicate n 0 @ [a])"
   491   by (induct n) (simp_all add: monom_0 monom_Suc)
   492 
   493 lemma fold_coeffs_monom [simp]:
   494   "a \<noteq> 0 \<Longrightarrow> fold_coeffs f (monom a n) = f 0 ^^ n \<circ> f a"
   495   by (simp add: fold_coeffs_def coeffs_monom fun_eq_iff)
   496 
   497 lemma poly_monom:
   498   fixes a x :: "'a::{comm_semiring_1}"
   499   shows "poly (monom a n) x = a * x ^ n"
   500   by (cases "a = 0", simp_all)
   501     (induct n, simp_all add: mult.left_commute poly_def)
   502 
   503 
   504 subsection \<open>Addition and subtraction\<close>
   505 
   506 instantiation poly :: (comm_monoid_add) comm_monoid_add
   507 begin
   508 
   509 lift_definition plus_poly :: "'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   510   is "\<lambda>p q n. coeff p n + coeff q n"
   511 proof -
   512   fix q p :: "'a poly"
   513   show "\<forall>\<^sub>\<infinity>n. coeff p n + coeff q n = 0"
   514     using MOST_coeff_eq_0[of p] MOST_coeff_eq_0[of q] by eventually_elim simp
   515 qed
   516 
   517 lemma coeff_add [simp]: "coeff (p + q) n = coeff p n + coeff q n"
   518   by (simp add: plus_poly.rep_eq)
   519 
   520 instance
   521 proof
   522   fix p q r :: "'a poly"
   523   show "(p + q) + r = p + (q + r)"
   524     by (simp add: poly_eq_iff add.assoc)
   525   show "p + q = q + p"
   526     by (simp add: poly_eq_iff add.commute)
   527   show "0 + p = p"
   528     by (simp add: poly_eq_iff)
   529 qed
   530 
   531 end
   532 
   533 instantiation poly :: (cancel_comm_monoid_add) cancel_comm_monoid_add
   534 begin
   535 
   536 lift_definition minus_poly :: "'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   537   is "\<lambda>p q n. coeff p n - coeff q n"
   538 proof -
   539   fix q p :: "'a poly"
   540   show "\<forall>\<^sub>\<infinity>n. coeff p n - coeff q n = 0"
   541     using MOST_coeff_eq_0[of p] MOST_coeff_eq_0[of q] by eventually_elim simp
   542 qed
   543 
   544 lemma coeff_diff [simp]: "coeff (p - q) n = coeff p n - coeff q n"
   545   by (simp add: minus_poly.rep_eq)
   546 
   547 instance
   548 proof
   549   fix p q r :: "'a poly"
   550   show "p + q - p = q"
   551     by (simp add: poly_eq_iff)
   552   show "p - q - r = p - (q + r)"
   553     by (simp add: poly_eq_iff diff_diff_eq)
   554 qed
   555 
   556 end
   557 
   558 instantiation poly :: (ab_group_add) ab_group_add
   559 begin
   560 
   561 lift_definition uminus_poly :: "'a poly \<Rightarrow> 'a poly"
   562   is "\<lambda>p n. - coeff p n"
   563 proof -
   564   fix p :: "'a poly"
   565   show "\<forall>\<^sub>\<infinity>n. - coeff p n = 0"
   566     using MOST_coeff_eq_0 by simp
   567 qed
   568 
   569 lemma coeff_minus [simp]: "coeff (- p) n = - coeff p n"
   570   by (simp add: uminus_poly.rep_eq)
   571 
   572 instance
   573 proof
   574   fix p q :: "'a poly"
   575   show "- p + p = 0"
   576     by (simp add: poly_eq_iff)
   577   show "p - q = p + - q"
   578     by (simp add: poly_eq_iff)
   579 qed
   580 
   581 end
   582 
   583 lemma add_pCons [simp]:
   584   "pCons a p + pCons b q = pCons (a + b) (p + q)"
   585   by (rule poly_eqI, simp add: coeff_pCons split: nat.split)
   586 
   587 lemma minus_pCons [simp]:
   588   "- pCons a p = pCons (- a) (- p)"
   589   by (rule poly_eqI, simp add: coeff_pCons split: nat.split)
   590 
   591 lemma diff_pCons [simp]:
   592   "pCons a p - pCons b q = pCons (a - b) (p - q)"
   593   by (rule poly_eqI, simp add: coeff_pCons split: nat.split)
   594 
   595 lemma degree_add_le_max: "degree (p + q) \<le> max (degree p) (degree q)"
   596   by (rule degree_le, auto simp add: coeff_eq_0)
   597 
   598 lemma degree_add_le:
   599   "\<lbrakk>degree p \<le> n; degree q \<le> n\<rbrakk> \<Longrightarrow> degree (p + q) \<le> n"
   600   by (auto intro: order_trans degree_add_le_max)
   601 
   602 lemma degree_add_less:
   603   "\<lbrakk>degree p < n; degree q < n\<rbrakk> \<Longrightarrow> degree (p + q) < n"
   604   by (auto intro: le_less_trans degree_add_le_max)
   605 
   606 lemma degree_add_eq_right:
   607   "degree p < degree q \<Longrightarrow> degree (p + q) = degree q"
   608   apply (cases "q = 0", simp)
   609   apply (rule order_antisym)
   610   apply (simp add: degree_add_le)
   611   apply (rule le_degree)
   612   apply (simp add: coeff_eq_0)
   613   done
   614 
   615 lemma degree_add_eq_left:
   616   "degree q < degree p \<Longrightarrow> degree (p + q) = degree p"
   617   using degree_add_eq_right [of q p]
   618   by (simp add: add.commute)
   619 
   620 lemma degree_minus [simp]:
   621   "degree (- p) = degree p"
   622   unfolding degree_def by simp
   623 
   624 lemma degree_diff_le_max:
   625   fixes p q :: "'a :: ab_group_add poly"
   626   shows "degree (p - q) \<le> max (degree p) (degree q)"
   627   using degree_add_le [where p=p and q="-q"]
   628   by simp
   629 
   630 lemma degree_diff_le:
   631   fixes p q :: "'a :: ab_group_add poly"
   632   assumes "degree p \<le> n" and "degree q \<le> n"
   633   shows "degree (p - q) \<le> n"
   634   using assms degree_add_le [of p n "- q"] by simp
   635 
   636 lemma degree_diff_less:
   637   fixes p q :: "'a :: ab_group_add poly"
   638   assumes "degree p < n" and "degree q < n"
   639   shows "degree (p - q) < n"
   640   using assms degree_add_less [of p n "- q"] by simp
   641 
   642 lemma add_monom: "monom a n + monom b n = monom (a + b) n"
   643   by (rule poly_eqI) simp
   644 
   645 lemma diff_monom: "monom a n - monom b n = monom (a - b) n"
   646   by (rule poly_eqI) simp
   647 
   648 lemma minus_monom: "- monom a n = monom (-a) n"
   649   by (rule poly_eqI) simp
   650 
   651 lemma coeff_setsum: "coeff (\<Sum>x\<in>A. p x) i = (\<Sum>x\<in>A. coeff (p x) i)"
   652   by (cases "finite A", induct set: finite, simp_all)
   653 
   654 lemma monom_setsum: "monom (\<Sum>x\<in>A. a x) n = (\<Sum>x\<in>A. monom (a x) n)"
   655   by (rule poly_eqI) (simp add: coeff_setsum)
   656 
   657 fun plus_coeffs :: "'a::comm_monoid_add list \<Rightarrow> 'a list \<Rightarrow> 'a list"
   658 where
   659   "plus_coeffs xs [] = xs"
   660 | "plus_coeffs [] ys = ys"
   661 | "plus_coeffs (x # xs) (y # ys) = (x + y) ## plus_coeffs xs ys"
   662 
   663 lemma coeffs_plus_eq_plus_coeffs [code abstract]:
   664   "coeffs (p + q) = plus_coeffs (coeffs p) (coeffs q)"
   665 proof -
   666   { fix xs ys :: "'a list" and n
   667     have "nth_default 0 (plus_coeffs xs ys) n = nth_default 0 xs n + nth_default 0 ys n"
   668     proof (induct xs ys arbitrary: n rule: plus_coeffs.induct)
   669       case (3 x xs y ys n)
   670       then show ?case by (cases n) (auto simp add: cCons_def)
   671     qed simp_all }
   672   note * = this
   673   { fix xs ys :: "'a list"
   674     assume "xs \<noteq> [] \<Longrightarrow> last xs \<noteq> 0" and "ys \<noteq> [] \<Longrightarrow> last ys \<noteq> 0"
   675     moreover assume "plus_coeffs xs ys \<noteq> []"
   676     ultimately have "last (plus_coeffs xs ys) \<noteq> 0"
   677     proof (induct xs ys rule: plus_coeffs.induct)
   678       case (3 x xs y ys) then show ?case by (auto simp add: cCons_def) metis
   679     qed simp_all }
   680   note ** = this
   681   show ?thesis
   682     apply (rule coeffs_eqI)
   683     apply (simp add: * nth_default_coeffs_eq)
   684     apply (rule **)
   685     apply (auto dest: last_coeffs_not_0)
   686     done
   687 qed
   688 
   689 lemma coeffs_uminus [code abstract]:
   690   "coeffs (- p) = map (\<lambda>a. - a) (coeffs p)"
   691   by (rule coeffs_eqI)
   692     (simp_all add: not_0_coeffs_not_Nil last_map last_coeffs_not_0 nth_default_map_eq nth_default_coeffs_eq)
   693 
   694 lemma [code]:
   695   fixes p q :: "'a::ab_group_add poly"
   696   shows "p - q = p + - q"
   697   by (fact diff_conv_add_uminus)
   698 
   699 lemma poly_add [simp]: "poly (p + q) x = poly p x + poly q x"
   700   apply (induct p arbitrary: q, simp)
   701   apply (case_tac q, simp, simp add: algebra_simps)
   702   done
   703 
   704 lemma poly_minus [simp]:
   705   fixes x :: "'a::comm_ring"
   706   shows "poly (- p) x = - poly p x"
   707   by (induct p) simp_all
   708 
   709 lemma poly_diff [simp]:
   710   fixes x :: "'a::comm_ring"
   711   shows "poly (p - q) x = poly p x - poly q x"
   712   using poly_add [of p "- q" x] by simp
   713 
   714 lemma poly_setsum: "poly (\<Sum>k\<in>A. p k) x = (\<Sum>k\<in>A. poly (p k) x)"
   715   by (induct A rule: infinite_finite_induct) simp_all
   716 
   717 
   718 subsection \<open>Multiplication by a constant, polynomial multiplication and the unit polynomial\<close>
   719 
   720 lift_definition smult :: "'a::comm_semiring_0 \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   721   is "\<lambda>a p n. a * coeff p n"
   722 proof -
   723   fix a :: 'a and p :: "'a poly" show "\<forall>\<^sub>\<infinity> i. a * coeff p i = 0"
   724     using MOST_coeff_eq_0[of p] by eventually_elim simp
   725 qed
   726 
   727 lemma coeff_smult [simp]:
   728   "coeff (smult a p) n = a * coeff p n"
   729   by (simp add: smult.rep_eq)
   730 
   731 lemma degree_smult_le: "degree (smult a p) \<le> degree p"
   732   by (rule degree_le, simp add: coeff_eq_0)
   733 
   734 lemma smult_smult [simp]: "smult a (smult b p) = smult (a * b) p"
   735   by (rule poly_eqI, simp add: mult.assoc)
   736 
   737 lemma smult_0_right [simp]: "smult a 0 = 0"
   738   by (rule poly_eqI, simp)
   739 
   740 lemma smult_0_left [simp]: "smult 0 p = 0"
   741   by (rule poly_eqI, simp)
   742 
   743 lemma smult_1_left [simp]: "smult (1::'a::comm_semiring_1) p = p"
   744   by (rule poly_eqI, simp)
   745 
   746 lemma smult_add_right:
   747   "smult a (p + q) = smult a p + smult a q"
   748   by (rule poly_eqI, simp add: algebra_simps)
   749 
   750 lemma smult_add_left:
   751   "smult (a + b) p = smult a p + smult b p"
   752   by (rule poly_eqI, simp add: algebra_simps)
   753 
   754 lemma smult_minus_right [simp]:
   755   "smult (a::'a::comm_ring) (- p) = - smult a p"
   756   by (rule poly_eqI, simp)
   757 
   758 lemma smult_minus_left [simp]:
   759   "smult (- a::'a::comm_ring) p = - smult a p"
   760   by (rule poly_eqI, simp)
   761 
   762 lemma smult_diff_right:
   763   "smult (a::'a::comm_ring) (p - q) = smult a p - smult a q"
   764   by (rule poly_eqI, simp add: algebra_simps)
   765 
   766 lemma smult_diff_left:
   767   "smult (a - b::'a::comm_ring) p = smult a p - smult b p"
   768   by (rule poly_eqI, simp add: algebra_simps)
   769 
   770 lemmas smult_distribs =
   771   smult_add_left smult_add_right
   772   smult_diff_left smult_diff_right
   773 
   774 lemma smult_pCons [simp]:
   775   "smult a (pCons b p) = pCons (a * b) (smult a p)"
   776   by (rule poly_eqI, simp add: coeff_pCons split: nat.split)
   777 
   778 lemma smult_monom: "smult a (monom b n) = monom (a * b) n"
   779   by (induct n, simp add: monom_0, simp add: monom_Suc)
   780 
   781 lemma degree_smult_eq [simp]:
   782   fixes a :: "'a::idom"
   783   shows "degree (smult a p) = (if a = 0 then 0 else degree p)"
   784   by (cases "a = 0", simp, simp add: degree_def)
   785 
   786 lemma smult_eq_0_iff [simp]:
   787   fixes a :: "'a::idom"
   788   shows "smult a p = 0 \<longleftrightarrow> a = 0 \<or> p = 0"
   789   by (simp add: poly_eq_iff)
   790 
   791 lemma coeffs_smult [code abstract]:
   792   fixes p :: "'a::idom poly"
   793   shows "coeffs (smult a p) = (if a = 0 then [] else map (Groups.times a) (coeffs p))"
   794   by (rule coeffs_eqI)
   795     (auto simp add: not_0_coeffs_not_Nil last_map last_coeffs_not_0 nth_default_map_eq nth_default_coeffs_eq)
   796 
   797 instantiation poly :: (comm_semiring_0) comm_semiring_0
   798 begin
   799 
   800 definition
   801   "p * q = fold_coeffs (\<lambda>a p. smult a q + pCons 0 p) p 0"
   802 
   803 lemma mult_poly_0_left: "(0::'a poly) * q = 0"
   804   by (simp add: times_poly_def)
   805 
   806 lemma mult_pCons_left [simp]:
   807   "pCons a p * q = smult a q + pCons 0 (p * q)"
   808   by (cases "p = 0 \<and> a = 0") (auto simp add: times_poly_def)
   809 
   810 lemma mult_poly_0_right: "p * (0::'a poly) = 0"
   811   by (induct p) (simp add: mult_poly_0_left, simp)
   812 
   813 lemma mult_pCons_right [simp]:
   814   "p * pCons a q = smult a p + pCons 0 (p * q)"
   815   by (induct p) (simp add: mult_poly_0_left, simp add: algebra_simps)
   816 
   817 lemmas mult_poly_0 = mult_poly_0_left mult_poly_0_right
   818 
   819 lemma mult_smult_left [simp]:
   820   "smult a p * q = smult a (p * q)"
   821   by (induct p) (simp add: mult_poly_0, simp add: smult_add_right)
   822 
   823 lemma mult_smult_right [simp]:
   824   "p * smult a q = smult a (p * q)"
   825   by (induct q) (simp add: mult_poly_0, simp add: smult_add_right)
   826 
   827 lemma mult_poly_add_left:
   828   fixes p q r :: "'a poly"
   829   shows "(p + q) * r = p * r + q * r"
   830   by (induct r) (simp add: mult_poly_0, simp add: smult_distribs algebra_simps)
   831 
   832 instance
   833 proof
   834   fix p q r :: "'a poly"
   835   show 0: "0 * p = 0"
   836     by (rule mult_poly_0_left)
   837   show "p * 0 = 0"
   838     by (rule mult_poly_0_right)
   839   show "(p + q) * r = p * r + q * r"
   840     by (rule mult_poly_add_left)
   841   show "(p * q) * r = p * (q * r)"
   842     by (induct p, simp add: mult_poly_0, simp add: mult_poly_add_left)
   843   show "p * q = q * p"
   844     by (induct p, simp add: mult_poly_0, simp)
   845 qed
   846 
   847 end
   848 
   849 instance poly :: (comm_semiring_0_cancel) comm_semiring_0_cancel ..
   850 
   851 lemma coeff_mult:
   852   "coeff (p * q) n = (\<Sum>i\<le>n. coeff p i * coeff q (n-i))"
   853 proof (induct p arbitrary: n)
   854   case 0 show ?case by simp
   855 next
   856   case (pCons a p n) thus ?case
   857     by (cases n, simp, simp add: setsum_atMost_Suc_shift
   858                             del: setsum_atMost_Suc)
   859 qed
   860 
   861 lemma degree_mult_le: "degree (p * q) \<le> degree p + degree q"
   862 apply (rule degree_le)
   863 apply (induct p)
   864 apply simp
   865 apply (simp add: coeff_eq_0 coeff_pCons split: nat.split)
   866 done
   867 
   868 lemma mult_monom: "monom a m * monom b n = monom (a * b) (m + n)"
   869   by (induct m) (simp add: monom_0 smult_monom, simp add: monom_Suc)
   870 
   871 instantiation poly :: (comm_semiring_1) comm_semiring_1
   872 begin
   873 
   874 definition one_poly_def: "1 = pCons 1 0"
   875 
   876 instance
   877 proof
   878   show "1 * p = p" for p :: "'a poly"
   879     unfolding one_poly_def by simp
   880   show "0 \<noteq> (1::'a poly)"
   881     unfolding one_poly_def by simp
   882 qed
   883 
   884 end
   885 
   886 instance poly :: (comm_ring) comm_ring ..
   887 
   888 instance poly :: (comm_ring_1) comm_ring_1 ..
   889 
   890 lemma coeff_1 [simp]: "coeff 1 n = (if n = 0 then 1 else 0)"
   891   unfolding one_poly_def
   892   by (simp add: coeff_pCons split: nat.split)
   893 
   894 lemma monom_eq_1 [simp]:
   895   "monom 1 0 = 1"
   896   by (simp add: monom_0 one_poly_def)
   897   
   898 lemma degree_1 [simp]: "degree 1 = 0"
   899   unfolding one_poly_def
   900   by (rule degree_pCons_0)
   901 
   902 lemma coeffs_1_eq [simp, code abstract]:
   903   "coeffs 1 = [1]"
   904   by (simp add: one_poly_def)
   905 
   906 lemma degree_power_le:
   907   "degree (p ^ n) \<le> degree p * n"
   908   by (induct n) (auto intro: order_trans degree_mult_le)
   909 
   910 lemma poly_smult [simp]:
   911   "poly (smult a p) x = a * poly p x"
   912   by (induct p, simp, simp add: algebra_simps)
   913 
   914 lemma poly_mult [simp]:
   915   "poly (p * q) x = poly p x * poly q x"
   916   by (induct p, simp_all, simp add: algebra_simps)
   917 
   918 lemma poly_1 [simp]:
   919   "poly 1 x = 1"
   920   by (simp add: one_poly_def)
   921 
   922 lemma poly_power [simp]:
   923   fixes p :: "'a::{comm_semiring_1} poly"
   924   shows "poly (p ^ n) x = poly p x ^ n"
   925   by (induct n) simp_all
   926 
   927 
   928 subsection \<open>Lemmas about divisibility\<close>
   929 
   930 lemma dvd_smult: "p dvd q \<Longrightarrow> p dvd smult a q"
   931 proof -
   932   assume "p dvd q"
   933   then obtain k where "q = p * k" ..
   934   then have "smult a q = p * smult a k" by simp
   935   then show "p dvd smult a q" ..
   936 qed
   937 
   938 lemma dvd_smult_cancel:
   939   fixes a :: "'a::field"
   940   shows "p dvd smult a q \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> p dvd q"
   941   by (drule dvd_smult [where a="inverse a"]) simp
   942 
   943 lemma dvd_smult_iff:
   944   fixes a :: "'a::field"
   945   shows "a \<noteq> 0 \<Longrightarrow> p dvd smult a q \<longleftrightarrow> p dvd q"
   946   by (safe elim!: dvd_smult dvd_smult_cancel)
   947 
   948 lemma smult_dvd_cancel:
   949   "smult a p dvd q \<Longrightarrow> p dvd q"
   950 proof -
   951   assume "smult a p dvd q"
   952   then obtain k where "q = smult a p * k" ..
   953   then have "q = p * smult a k" by simp
   954   then show "p dvd q" ..
   955 qed
   956 
   957 lemma smult_dvd:
   958   fixes a :: "'a::field"
   959   shows "p dvd q \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> smult a p dvd q"
   960   by (rule smult_dvd_cancel [where a="inverse a"]) simp
   961 
   962 lemma smult_dvd_iff:
   963   fixes a :: "'a::field"
   964   shows "smult a p dvd q \<longleftrightarrow> (if a = 0 then q = 0 else p dvd q)"
   965   by (auto elim: smult_dvd smult_dvd_cancel)
   966 
   967 
   968 subsection \<open>Polynomials form an integral domain\<close>
   969 
   970 lemma coeff_mult_degree_sum:
   971   "coeff (p * q) (degree p + degree q) =
   972    coeff p (degree p) * coeff q (degree q)"
   973   by (induct p, simp, simp add: coeff_eq_0)
   974 
   975 instance poly :: (idom) idom
   976 proof
   977   fix p q :: "'a poly"
   978   assume "p \<noteq> 0" and "q \<noteq> 0"
   979   have "coeff (p * q) (degree p + degree q) =
   980         coeff p (degree p) * coeff q (degree q)"
   981     by (rule coeff_mult_degree_sum)
   982   also have "coeff p (degree p) * coeff q (degree q) \<noteq> 0"
   983     using \<open>p \<noteq> 0\<close> and \<open>q \<noteq> 0\<close> by simp
   984   finally have "\<exists>n. coeff (p * q) n \<noteq> 0" ..
   985   thus "p * q \<noteq> 0" by (simp add: poly_eq_iff)
   986 qed
   987 
   988 lemma degree_mult_eq:
   989   fixes p q :: "'a::idom poly"
   990   shows "\<lbrakk>p \<noteq> 0; q \<noteq> 0\<rbrakk> \<Longrightarrow> degree (p * q) = degree p + degree q"
   991 apply (rule order_antisym [OF degree_mult_le le_degree])
   992 apply (simp add: coeff_mult_degree_sum)
   993 done
   994 
   995 lemma degree_mult_right_le:
   996   fixes p q :: "'a::idom poly"
   997   assumes "q \<noteq> 0"
   998   shows "degree p \<le> degree (p * q)"
   999   using assms by (cases "p = 0") (simp_all add: degree_mult_eq)
  1000 
  1001 lemma coeff_degree_mult:
  1002   fixes p q :: "'a::idom poly"
  1003   shows "coeff (p * q) (degree (p * q)) =
  1004     coeff q (degree q) * coeff p (degree p)"
  1005   by (cases "p = 0 \<or> q = 0") (auto simp add: degree_mult_eq coeff_mult_degree_sum)
  1006 
  1007 lemma dvd_imp_degree_le:
  1008   fixes p q :: "'a::idom poly"
  1009   shows "\<lbrakk>p dvd q; q \<noteq> 0\<rbrakk> \<Longrightarrow> degree p \<le> degree q"
  1010   by (erule dvdE, simp add: degree_mult_eq)
  1011 
  1012 
  1013 subsection \<open>Polynomials form an ordered integral domain\<close>
  1014 
  1015 definition pos_poly :: "'a::linordered_idom poly \<Rightarrow> bool"
  1016 where
  1017   "pos_poly p \<longleftrightarrow> 0 < coeff p (degree p)"
  1018 
  1019 lemma pos_poly_pCons:
  1020   "pos_poly (pCons a p) \<longleftrightarrow> pos_poly p \<or> (p = 0 \<and> 0 < a)"
  1021   unfolding pos_poly_def by simp
  1022 
  1023 lemma not_pos_poly_0 [simp]: "\<not> pos_poly 0"
  1024   unfolding pos_poly_def by simp
  1025 
  1026 lemma pos_poly_add: "\<lbrakk>pos_poly p; pos_poly q\<rbrakk> \<Longrightarrow> pos_poly (p + q)"
  1027   apply (induct p arbitrary: q, simp)
  1028   apply (case_tac q, force simp add: pos_poly_pCons add_pos_pos)
  1029   done
  1030 
  1031 lemma pos_poly_mult: "\<lbrakk>pos_poly p; pos_poly q\<rbrakk> \<Longrightarrow> pos_poly (p * q)"
  1032   unfolding pos_poly_def
  1033   apply (subgoal_tac "p \<noteq> 0 \<and> q \<noteq> 0")
  1034   apply (simp add: degree_mult_eq coeff_mult_degree_sum)
  1035   apply auto
  1036   done
  1037 
  1038 lemma pos_poly_total: "p = 0 \<or> pos_poly p \<or> pos_poly (- p)"
  1039 by (induct p) (auto simp add: pos_poly_pCons)
  1040 
  1041 lemma last_coeffs_eq_coeff_degree:
  1042   "p \<noteq> 0 \<Longrightarrow> last (coeffs p) = coeff p (degree p)"
  1043   by (simp add: coeffs_def)
  1044 
  1045 lemma pos_poly_coeffs [code]:
  1046   "pos_poly p \<longleftrightarrow> (let as = coeffs p in as \<noteq> [] \<and> last as > 0)" (is "?P \<longleftrightarrow> ?Q")
  1047 proof
  1048   assume ?Q then show ?P by (auto simp add: pos_poly_def last_coeffs_eq_coeff_degree)
  1049 next
  1050   assume ?P then have *: "0 < coeff p (degree p)" by (simp add: pos_poly_def)
  1051   then have "p \<noteq> 0" by auto
  1052   with * show ?Q by (simp add: last_coeffs_eq_coeff_degree)
  1053 qed
  1054 
  1055 instantiation poly :: (linordered_idom) linordered_idom
  1056 begin
  1057 
  1058 definition
  1059   "x < y \<longleftrightarrow> pos_poly (y - x)"
  1060 
  1061 definition
  1062   "x \<le> y \<longleftrightarrow> x = y \<or> pos_poly (y - x)"
  1063 
  1064 definition
  1065   "abs (x::'a poly) = (if x < 0 then - x else x)"
  1066 
  1067 definition
  1068   "sgn (x::'a poly) = (if x = 0 then 0 else if 0 < x then 1 else - 1)"
  1069 
  1070 instance
  1071 proof
  1072   fix x y z :: "'a poly"
  1073   show "x < y \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
  1074     unfolding less_eq_poly_def less_poly_def
  1075     apply safe
  1076     apply simp
  1077     apply (drule (1) pos_poly_add)
  1078     apply simp
  1079     done
  1080   show "x \<le> x"
  1081     unfolding less_eq_poly_def by simp
  1082   show "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
  1083     unfolding less_eq_poly_def
  1084     apply safe
  1085     apply (drule (1) pos_poly_add)
  1086     apply (simp add: algebra_simps)
  1087     done
  1088   show "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
  1089     unfolding less_eq_poly_def
  1090     apply safe
  1091     apply (drule (1) pos_poly_add)
  1092     apply simp
  1093     done
  1094   show "x \<le> y \<Longrightarrow> z + x \<le> z + y"
  1095     unfolding less_eq_poly_def
  1096     apply safe
  1097     apply (simp add: algebra_simps)
  1098     done
  1099   show "x \<le> y \<or> y \<le> x"
  1100     unfolding less_eq_poly_def
  1101     using pos_poly_total [of "x - y"]
  1102     by auto
  1103   show "x < y \<Longrightarrow> 0 < z \<Longrightarrow> z * x < z * y"
  1104     unfolding less_poly_def
  1105     by (simp add: right_diff_distrib [symmetric] pos_poly_mult)
  1106   show "\<bar>x\<bar> = (if x < 0 then - x else x)"
  1107     by (rule abs_poly_def)
  1108   show "sgn x = (if x = 0 then 0 else if 0 < x then 1 else - 1)"
  1109     by (rule sgn_poly_def)
  1110 qed
  1111 
  1112 end
  1113 
  1114 text \<open>TODO: Simplification rules for comparisons\<close>
  1115 
  1116 
  1117 subsection \<open>Synthetic division and polynomial roots\<close>
  1118 
  1119 text \<open>
  1120   Synthetic division is simply division by the linear polynomial @{term "x - c"}.
  1121 \<close>
  1122 
  1123 definition synthetic_divmod :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a poly \<times> 'a"
  1124 where
  1125   "synthetic_divmod p c = fold_coeffs (\<lambda>a (q, r). (pCons r q, a + c * r)) p (0, 0)"
  1126 
  1127 definition synthetic_div :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a poly"
  1128 where
  1129   "synthetic_div p c = fst (synthetic_divmod p c)"
  1130 
  1131 lemma synthetic_divmod_0 [simp]:
  1132   "synthetic_divmod 0 c = (0, 0)"
  1133   by (simp add: synthetic_divmod_def)
  1134 
  1135 lemma synthetic_divmod_pCons [simp]:
  1136   "synthetic_divmod (pCons a p) c = (\<lambda>(q, r). (pCons r q, a + c * r)) (synthetic_divmod p c)"
  1137   by (cases "p = 0 \<and> a = 0") (auto simp add: synthetic_divmod_def)
  1138 
  1139 lemma synthetic_div_0 [simp]:
  1140   "synthetic_div 0 c = 0"
  1141   unfolding synthetic_div_def by simp
  1142 
  1143 lemma synthetic_div_unique_lemma: "smult c p = pCons a p \<Longrightarrow> p = 0"
  1144 by (induct p arbitrary: a) simp_all
  1145 
  1146 lemma snd_synthetic_divmod:
  1147   "snd (synthetic_divmod p c) = poly p c"
  1148   by (induct p, simp, simp add: split_def)
  1149 
  1150 lemma synthetic_div_pCons [simp]:
  1151   "synthetic_div (pCons a p) c = pCons (poly p c) (synthetic_div p c)"
  1152   unfolding synthetic_div_def
  1153   by (simp add: split_def snd_synthetic_divmod)
  1154 
  1155 lemma synthetic_div_eq_0_iff:
  1156   "synthetic_div p c = 0 \<longleftrightarrow> degree p = 0"
  1157   by (induct p, simp, case_tac p, simp)
  1158 
  1159 lemma degree_synthetic_div:
  1160   "degree (synthetic_div p c) = degree p - 1"
  1161   by (induct p, simp, simp add: synthetic_div_eq_0_iff)
  1162 
  1163 lemma synthetic_div_correct:
  1164   "p + smult c (synthetic_div p c) = pCons (poly p c) (synthetic_div p c)"
  1165   by (induct p) simp_all
  1166 
  1167 lemma synthetic_div_unique:
  1168   "p + smult c q = pCons r q \<Longrightarrow> r = poly p c \<and> q = synthetic_div p c"
  1169 apply (induct p arbitrary: q r)
  1170 apply (simp, frule synthetic_div_unique_lemma, simp)
  1171 apply (case_tac q, force)
  1172 done
  1173 
  1174 lemma synthetic_div_correct':
  1175   fixes c :: "'a::comm_ring_1"
  1176   shows "[:-c, 1:] * synthetic_div p c + [:poly p c:] = p"
  1177   using synthetic_div_correct [of p c]
  1178   by (simp add: algebra_simps)
  1179 
  1180 lemma poly_eq_0_iff_dvd:
  1181   fixes c :: "'a::idom"
  1182   shows "poly p c = 0 \<longleftrightarrow> [:-c, 1:] dvd p"
  1183 proof
  1184   assume "poly p c = 0"
  1185   with synthetic_div_correct' [of c p]
  1186   have "p = [:-c, 1:] * synthetic_div p c" by simp
  1187   then show "[:-c, 1:] dvd p" ..
  1188 next
  1189   assume "[:-c, 1:] dvd p"
  1190   then obtain k where "p = [:-c, 1:] * k" by (rule dvdE)
  1191   then show "poly p c = 0" by simp
  1192 qed
  1193 
  1194 lemma dvd_iff_poly_eq_0:
  1195   fixes c :: "'a::idom"
  1196   shows "[:c, 1:] dvd p \<longleftrightarrow> poly p (-c) = 0"
  1197   by (simp add: poly_eq_0_iff_dvd)
  1198 
  1199 lemma poly_roots_finite:
  1200   fixes p :: "'a::idom poly"
  1201   shows "p \<noteq> 0 \<Longrightarrow> finite {x. poly p x = 0}"
  1202 proof (induct n \<equiv> "degree p" arbitrary: p)
  1203   case (0 p)
  1204   then obtain a where "a \<noteq> 0" and "p = [:a:]"
  1205     by (cases p, simp split: if_splits)
  1206   then show "finite {x. poly p x = 0}" by simp
  1207 next
  1208   case (Suc n p)
  1209   show "finite {x. poly p x = 0}"
  1210   proof (cases "\<exists>x. poly p x = 0")
  1211     case False
  1212     then show "finite {x. poly p x = 0}" by simp
  1213   next
  1214     case True
  1215     then obtain a where "poly p a = 0" ..
  1216     then have "[:-a, 1:] dvd p" by (simp only: poly_eq_0_iff_dvd)
  1217     then obtain k where k: "p = [:-a, 1:] * k" ..
  1218     with \<open>p \<noteq> 0\<close> have "k \<noteq> 0" by auto
  1219     with k have "degree p = Suc (degree k)"
  1220       by (simp add: degree_mult_eq del: mult_pCons_left)
  1221     with \<open>Suc n = degree p\<close> have "n = degree k" by simp
  1222     then have "finite {x. poly k x = 0}" using \<open>k \<noteq> 0\<close> by (rule Suc.hyps)
  1223     then have "finite (insert a {x. poly k x = 0})" by simp
  1224     then show "finite {x. poly p x = 0}"
  1225       by (simp add: k Collect_disj_eq del: mult_pCons_left)
  1226   qed
  1227 qed
  1228 
  1229 lemma poly_eq_poly_eq_iff:
  1230   fixes p q :: "'a::{idom,ring_char_0} poly"
  1231   shows "poly p = poly q \<longleftrightarrow> p = q" (is "?P \<longleftrightarrow> ?Q")
  1232 proof
  1233   assume ?Q then show ?P by simp
  1234 next
  1235   { fix p :: "'a::{idom,ring_char_0} poly"
  1236     have "poly p = poly 0 \<longleftrightarrow> p = 0"
  1237       apply (cases "p = 0", simp_all)
  1238       apply (drule poly_roots_finite)
  1239       apply (auto simp add: infinite_UNIV_char_0)
  1240       done
  1241   } note this [of "p - q"]
  1242   moreover assume ?P
  1243   ultimately show ?Q by auto
  1244 qed
  1245 
  1246 lemma poly_all_0_iff_0:
  1247   fixes p :: "'a::{ring_char_0, idom} poly"
  1248   shows "(\<forall>x. poly p x = 0) \<longleftrightarrow> p = 0"
  1249   by (auto simp add: poly_eq_poly_eq_iff [symmetric])
  1250 
  1251 
  1252 subsection \<open>Long division of polynomials\<close>
  1253 
  1254 definition pdivmod_rel :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<Rightarrow> bool"
  1255 where
  1256   "pdivmod_rel x y q r \<longleftrightarrow>
  1257     x = q * y + r \<and> (if y = 0 then q = 0 else r = 0 \<or> degree r < degree y)"
  1258 
  1259 lemma pdivmod_rel_0:
  1260   "pdivmod_rel 0 y 0 0"
  1261   unfolding pdivmod_rel_def by simp
  1262 
  1263 lemma pdivmod_rel_by_0:
  1264   "pdivmod_rel x 0 0 x"
  1265   unfolding pdivmod_rel_def by simp
  1266 
  1267 lemma eq_zero_or_degree_less:
  1268   assumes "degree p \<le> n" and "coeff p n = 0"
  1269   shows "p = 0 \<or> degree p < n"
  1270 proof (cases n)
  1271   case 0
  1272   with \<open>degree p \<le> n\<close> and \<open>coeff p n = 0\<close>
  1273   have "coeff p (degree p) = 0" by simp
  1274   then have "p = 0" by simp
  1275   then show ?thesis ..
  1276 next
  1277   case (Suc m)
  1278   have "\<forall>i>n. coeff p i = 0"
  1279     using \<open>degree p \<le> n\<close> by (simp add: coeff_eq_0)
  1280   then have "\<forall>i\<ge>n. coeff p i = 0"
  1281     using \<open>coeff p n = 0\<close> by (simp add: le_less)
  1282   then have "\<forall>i>m. coeff p i = 0"
  1283     using \<open>n = Suc m\<close> by (simp add: less_eq_Suc_le)
  1284   then have "degree p \<le> m"
  1285     by (rule degree_le)
  1286   then have "degree p < n"
  1287     using \<open>n = Suc m\<close> by (simp add: less_Suc_eq_le)
  1288   then show ?thesis ..
  1289 qed
  1290 
  1291 lemma pdivmod_rel_pCons:
  1292   assumes rel: "pdivmod_rel x y q r"
  1293   assumes y: "y \<noteq> 0"
  1294   assumes b: "b = coeff (pCons a r) (degree y) / coeff y (degree y)"
  1295   shows "pdivmod_rel (pCons a x) y (pCons b q) (pCons a r - smult b y)"
  1296     (is "pdivmod_rel ?x y ?q ?r")
  1297 proof -
  1298   have x: "x = q * y + r" and r: "r = 0 \<or> degree r < degree y"
  1299     using assms unfolding pdivmod_rel_def by simp_all
  1300 
  1301   have 1: "?x = ?q * y + ?r"
  1302     using b x by simp
  1303 
  1304   have 2: "?r = 0 \<or> degree ?r < degree y"
  1305   proof (rule eq_zero_or_degree_less)
  1306     show "degree ?r \<le> degree y"
  1307     proof (rule degree_diff_le)
  1308       show "degree (pCons a r) \<le> degree y"
  1309         using r by auto
  1310       show "degree (smult b y) \<le> degree y"
  1311         by (rule degree_smult_le)
  1312     qed
  1313   next
  1314     show "coeff ?r (degree y) = 0"
  1315       using \<open>y \<noteq> 0\<close> unfolding b by simp
  1316   qed
  1317 
  1318   from 1 2 show ?thesis
  1319     unfolding pdivmod_rel_def
  1320     using \<open>y \<noteq> 0\<close> by simp
  1321 qed
  1322 
  1323 lemma pdivmod_rel_exists: "\<exists>q r. pdivmod_rel x y q r"
  1324 apply (cases "y = 0")
  1325 apply (fast intro!: pdivmod_rel_by_0)
  1326 apply (induct x)
  1327 apply (fast intro!: pdivmod_rel_0)
  1328 apply (fast intro!: pdivmod_rel_pCons)
  1329 done
  1330 
  1331 lemma pdivmod_rel_unique:
  1332   assumes 1: "pdivmod_rel x y q1 r1"
  1333   assumes 2: "pdivmod_rel x y q2 r2"
  1334   shows "q1 = q2 \<and> r1 = r2"
  1335 proof (cases "y = 0")
  1336   assume "y = 0" with assms show ?thesis
  1337     by (simp add: pdivmod_rel_def)
  1338 next
  1339   assume [simp]: "y \<noteq> 0"
  1340   from 1 have q1: "x = q1 * y + r1" and r1: "r1 = 0 \<or> degree r1 < degree y"
  1341     unfolding pdivmod_rel_def by simp_all
  1342   from 2 have q2: "x = q2 * y + r2" and r2: "r2 = 0 \<or> degree r2 < degree y"
  1343     unfolding pdivmod_rel_def by simp_all
  1344   from q1 q2 have q3: "(q1 - q2) * y = r2 - r1"
  1345     by (simp add: algebra_simps)
  1346   from r1 r2 have r3: "(r2 - r1) = 0 \<or> degree (r2 - r1) < degree y"
  1347     by (auto intro: degree_diff_less)
  1348 
  1349   show "q1 = q2 \<and> r1 = r2"
  1350   proof (rule ccontr)
  1351     assume "\<not> (q1 = q2 \<and> r1 = r2)"
  1352     with q3 have "q1 \<noteq> q2" and "r1 \<noteq> r2" by auto
  1353     with r3 have "degree (r2 - r1) < degree y" by simp
  1354     also have "degree y \<le> degree (q1 - q2) + degree y" by simp
  1355     also have "\<dots> = degree ((q1 - q2) * y)"
  1356       using \<open>q1 \<noteq> q2\<close> by (simp add: degree_mult_eq)
  1357     also have "\<dots> = degree (r2 - r1)"
  1358       using q3 by simp
  1359     finally have "degree (r2 - r1) < degree (r2 - r1)" .
  1360     then show "False" by simp
  1361   qed
  1362 qed
  1363 
  1364 lemma pdivmod_rel_0_iff: "pdivmod_rel 0 y q r \<longleftrightarrow> q = 0 \<and> r = 0"
  1365 by (auto dest: pdivmod_rel_unique intro: pdivmod_rel_0)
  1366 
  1367 lemma pdivmod_rel_by_0_iff: "pdivmod_rel x 0 q r \<longleftrightarrow> q = 0 \<and> r = x"
  1368 by (auto dest: pdivmod_rel_unique intro: pdivmod_rel_by_0)
  1369 
  1370 lemmas pdivmod_rel_unique_div = pdivmod_rel_unique [THEN conjunct1]
  1371 
  1372 lemmas pdivmod_rel_unique_mod = pdivmod_rel_unique [THEN conjunct2]
  1373 
  1374 instantiation poly :: (field) ring_div
  1375 begin
  1376 
  1377 definition divide_poly where
  1378   div_poly_def: "x div y = (THE q. \<exists>r. pdivmod_rel x y q r)"
  1379 
  1380 definition mod_poly where
  1381   "x mod y = (THE r. \<exists>q. pdivmod_rel x y q r)"
  1382 
  1383 lemma div_poly_eq:
  1384   "pdivmod_rel x y q r \<Longrightarrow> x div y = q"
  1385 unfolding div_poly_def
  1386 by (fast elim: pdivmod_rel_unique_div)
  1387 
  1388 lemma mod_poly_eq:
  1389   "pdivmod_rel x y q r \<Longrightarrow> x mod y = r"
  1390 unfolding mod_poly_def
  1391 by (fast elim: pdivmod_rel_unique_mod)
  1392 
  1393 lemma pdivmod_rel:
  1394   "pdivmod_rel x y (x div y) (x mod y)"
  1395 proof -
  1396   from pdivmod_rel_exists
  1397     obtain q r where "pdivmod_rel x y q r" by fast
  1398   thus ?thesis
  1399     by (simp add: div_poly_eq mod_poly_eq)
  1400 qed
  1401 
  1402 instance
  1403 proof
  1404   fix x y :: "'a poly"
  1405   show "x div y * y + x mod y = x"
  1406     using pdivmod_rel [of x y]
  1407     by (simp add: pdivmod_rel_def)
  1408 next
  1409   fix x :: "'a poly"
  1410   have "pdivmod_rel x 0 0 x"
  1411     by (rule pdivmod_rel_by_0)
  1412   thus "x div 0 = 0"
  1413     by (rule div_poly_eq)
  1414 next
  1415   fix y :: "'a poly"
  1416   have "pdivmod_rel 0 y 0 0"
  1417     by (rule pdivmod_rel_0)
  1418   thus "0 div y = 0"
  1419     by (rule div_poly_eq)
  1420 next
  1421   fix x y z :: "'a poly"
  1422   assume "y \<noteq> 0"
  1423   hence "pdivmod_rel (x + z * y) y (z + x div y) (x mod y)"
  1424     using pdivmod_rel [of x y]
  1425     by (simp add: pdivmod_rel_def distrib_right)
  1426   thus "(x + z * y) div y = z + x div y"
  1427     by (rule div_poly_eq)
  1428 next
  1429   fix x y z :: "'a poly"
  1430   assume "x \<noteq> 0"
  1431   show "(x * y) div (x * z) = y div z"
  1432   proof (cases "y \<noteq> 0 \<and> z \<noteq> 0")
  1433     have "\<And>x::'a poly. pdivmod_rel x 0 0 x"
  1434       by (rule pdivmod_rel_by_0)
  1435     then have [simp]: "\<And>x::'a poly. x div 0 = 0"
  1436       by (rule div_poly_eq)
  1437     have "\<And>x::'a poly. pdivmod_rel 0 x 0 0"
  1438       by (rule pdivmod_rel_0)
  1439     then have [simp]: "\<And>x::'a poly. 0 div x = 0"
  1440       by (rule div_poly_eq)
  1441     case False then show ?thesis by auto
  1442   next
  1443     case True then have "y \<noteq> 0" and "z \<noteq> 0" by auto
  1444     with \<open>x \<noteq> 0\<close>
  1445     have "\<And>q r. pdivmod_rel y z q r \<Longrightarrow> pdivmod_rel (x * y) (x * z) q (x * r)"
  1446       by (auto simp add: pdivmod_rel_def algebra_simps)
  1447         (rule classical, simp add: degree_mult_eq)
  1448     moreover from pdivmod_rel have "pdivmod_rel y z (y div z) (y mod z)" .
  1449     ultimately have "pdivmod_rel (x * y) (x * z) (y div z) (x * (y mod z))" .
  1450     then show ?thesis by (simp add: div_poly_eq)
  1451   qed
  1452 qed
  1453 
  1454 end
  1455 
  1456 lemma is_unit_monom_0:
  1457   fixes a :: "'a::field"
  1458   assumes "a \<noteq> 0"
  1459   shows "is_unit (monom a 0)"
  1460 proof
  1461   from assms show "1 = monom a 0 * monom (1 / a) 0"
  1462     by (simp add: mult_monom)
  1463 qed
  1464 
  1465 lemma is_unit_triv:
  1466   fixes a :: "'a::field"
  1467   assumes "a \<noteq> 0"
  1468   shows "is_unit [:a:]"
  1469   using assms by (simp add: is_unit_monom_0 monom_0 [symmetric])
  1470 
  1471 lemma is_unit_iff_degree:
  1472   assumes "p \<noteq> 0"
  1473   shows "is_unit p \<longleftrightarrow> degree p = 0" (is "?P \<longleftrightarrow> ?Q")
  1474 proof
  1475   assume ?Q
  1476   then obtain a where "p = [:a:]" by (rule degree_eq_zeroE)
  1477   with assms show ?P by (simp add: is_unit_triv)
  1478 next
  1479   assume ?P
  1480   then obtain q where "q \<noteq> 0" "p * q = 1" ..
  1481   then have "degree (p * q) = degree 1"
  1482     by simp
  1483   with \<open>p \<noteq> 0\<close> \<open>q \<noteq> 0\<close> have "degree p + degree q = 0"
  1484     by (simp add: degree_mult_eq)
  1485   then show ?Q by simp
  1486 qed
  1487 
  1488 lemma is_unit_pCons_iff:
  1489   "is_unit (pCons a p) \<longleftrightarrow> p = 0 \<and> a \<noteq> 0" (is "?P \<longleftrightarrow> ?Q")
  1490   by (cases "p = 0") (auto simp add: is_unit_triv is_unit_iff_degree)
  1491 
  1492 lemma is_unit_monom_trival:
  1493   fixes p :: "'a::field poly"
  1494   assumes "is_unit p"
  1495   shows "monom (coeff p (degree p)) 0 = p"
  1496   using assms by (cases p) (simp_all add: monom_0 is_unit_pCons_iff)
  1497 
  1498 lemma is_unit_polyE:
  1499   assumes "is_unit p"
  1500   obtains a where "p = monom a 0" and "a \<noteq> 0"
  1501 proof -
  1502   obtain a q where "p = pCons a q" by (cases p)
  1503   with assms have "p = [:a:]" and "a \<noteq> 0"
  1504     by (simp_all add: is_unit_pCons_iff)
  1505   with that show thesis by (simp add: monom_0)
  1506 qed
  1507 
  1508 instantiation poly :: (field) normalization_semidom
  1509 begin
  1510 
  1511 definition normalize_poly :: "'a poly \<Rightarrow> 'a poly"
  1512   where "normalize_poly p = smult (1 / coeff p (degree p)) p"
  1513 
  1514 definition unit_factor_poly :: "'a poly \<Rightarrow> 'a poly"
  1515   where "unit_factor_poly p = monom (coeff p (degree p)) 0"
  1516 
  1517 instance
  1518 proof
  1519   fix p :: "'a poly"
  1520   show "unit_factor p * normalize p = p"
  1521     by (simp add: normalize_poly_def unit_factor_poly_def)
  1522       (simp only: mult_smult_left [symmetric] smult_monom, simp)
  1523 next
  1524   show "normalize 0 = (0::'a poly)"
  1525     by (simp add: normalize_poly_def)
  1526 next
  1527   show "unit_factor 0 = (0::'a poly)"
  1528     by (simp add: unit_factor_poly_def)
  1529 next
  1530   fix p :: "'a poly"
  1531   assume "is_unit p"
  1532   then obtain a where "p = monom a 0" and "a \<noteq> 0"
  1533     by (rule is_unit_polyE)
  1534   then show "normalize p = 1"
  1535     by (auto simp add: normalize_poly_def smult_monom degree_monom_eq)
  1536 next
  1537   fix p q :: "'a poly"
  1538   assume "q \<noteq> 0"
  1539   from \<open>q \<noteq> 0\<close> have "is_unit (monom (coeff q (degree q)) 0)"
  1540     by (auto intro: is_unit_monom_0)
  1541   then show "is_unit (unit_factor q)"
  1542     by (simp add: unit_factor_poly_def)
  1543 next
  1544   fix p q :: "'a poly"
  1545   have "monom (coeff (p * q) (degree (p * q))) 0 =
  1546     monom (coeff p (degree p)) 0 * monom (coeff q (degree q)) 0"
  1547     by (simp add: monom_0 coeff_degree_mult)
  1548   then show "unit_factor (p * q) =
  1549     unit_factor p * unit_factor q"
  1550     by (simp add: unit_factor_poly_def)
  1551 qed
  1552 
  1553 end
  1554 
  1555 lemma degree_mod_less:
  1556   "y \<noteq> 0 \<Longrightarrow> x mod y = 0 \<or> degree (x mod y) < degree y"
  1557   using pdivmod_rel [of x y]
  1558   unfolding pdivmod_rel_def by simp
  1559 
  1560 lemma div_poly_less: "degree x < degree y \<Longrightarrow> x div y = 0"
  1561 proof -
  1562   assume "degree x < degree y"
  1563   hence "pdivmod_rel x y 0 x"
  1564     by (simp add: pdivmod_rel_def)
  1565   thus "x div y = 0" by (rule div_poly_eq)
  1566 qed
  1567 
  1568 lemma mod_poly_less: "degree x < degree y \<Longrightarrow> x mod y = x"
  1569 proof -
  1570   assume "degree x < degree y"
  1571   hence "pdivmod_rel x y 0 x"
  1572     by (simp add: pdivmod_rel_def)
  1573   thus "x mod y = x" by (rule mod_poly_eq)
  1574 qed
  1575 
  1576 lemma pdivmod_rel_smult_left:
  1577   "pdivmod_rel x y q r
  1578     \<Longrightarrow> pdivmod_rel (smult a x) y (smult a q) (smult a r)"
  1579   unfolding pdivmod_rel_def by (simp add: smult_add_right)
  1580 
  1581 lemma div_smult_left: "(smult a x) div y = smult a (x div y)"
  1582   by (rule div_poly_eq, rule pdivmod_rel_smult_left, rule pdivmod_rel)
  1583 
  1584 lemma mod_smult_left: "(smult a x) mod y = smult a (x mod y)"
  1585   by (rule mod_poly_eq, rule pdivmod_rel_smult_left, rule pdivmod_rel)
  1586 
  1587 lemma poly_div_minus_left [simp]:
  1588   fixes x y :: "'a::field poly"
  1589   shows "(- x) div y = - (x div y)"
  1590   using div_smult_left [of "- 1::'a"] by simp
  1591 
  1592 lemma poly_mod_minus_left [simp]:
  1593   fixes x y :: "'a::field poly"
  1594   shows "(- x) mod y = - (x mod y)"
  1595   using mod_smult_left [of "- 1::'a"] by simp
  1596 
  1597 lemma pdivmod_rel_add_left:
  1598   assumes "pdivmod_rel x y q r"
  1599   assumes "pdivmod_rel x' y q' r'"
  1600   shows "pdivmod_rel (x + x') y (q + q') (r + r')"
  1601   using assms unfolding pdivmod_rel_def
  1602   by (auto simp add: algebra_simps degree_add_less)
  1603 
  1604 lemma poly_div_add_left:
  1605   fixes x y z :: "'a::field poly"
  1606   shows "(x + y) div z = x div z + y div z"
  1607   using pdivmod_rel_add_left [OF pdivmod_rel pdivmod_rel]
  1608   by (rule div_poly_eq)
  1609 
  1610 lemma poly_mod_add_left:
  1611   fixes x y z :: "'a::field poly"
  1612   shows "(x + y) mod z = x mod z + y mod z"
  1613   using pdivmod_rel_add_left [OF pdivmod_rel pdivmod_rel]
  1614   by (rule mod_poly_eq)
  1615 
  1616 lemma poly_div_diff_left:
  1617   fixes x y z :: "'a::field poly"
  1618   shows "(x - y) div z = x div z - y div z"
  1619   by (simp only: diff_conv_add_uminus poly_div_add_left poly_div_minus_left)
  1620 
  1621 lemma poly_mod_diff_left:
  1622   fixes x y z :: "'a::field poly"
  1623   shows "(x - y) mod z = x mod z - y mod z"
  1624   by (simp only: diff_conv_add_uminus poly_mod_add_left poly_mod_minus_left)
  1625 
  1626 lemma pdivmod_rel_smult_right:
  1627   "\<lbrakk>a \<noteq> 0; pdivmod_rel x y q r\<rbrakk>
  1628     \<Longrightarrow> pdivmod_rel x (smult a y) (smult (inverse a) q) r"
  1629   unfolding pdivmod_rel_def by simp
  1630 
  1631 lemma div_smult_right:
  1632   "a \<noteq> 0 \<Longrightarrow> x div (smult a y) = smult (inverse a) (x div y)"
  1633   by (rule div_poly_eq, erule pdivmod_rel_smult_right, rule pdivmod_rel)
  1634 
  1635 lemma mod_smult_right: "a \<noteq> 0 \<Longrightarrow> x mod (smult a y) = x mod y"
  1636   by (rule mod_poly_eq, erule pdivmod_rel_smult_right, rule pdivmod_rel)
  1637 
  1638 lemma poly_div_minus_right [simp]:
  1639   fixes x y :: "'a::field poly"
  1640   shows "x div (- y) = - (x div y)"
  1641   using div_smult_right [of "- 1::'a"] by (simp add: nonzero_inverse_minus_eq)
  1642 
  1643 lemma poly_mod_minus_right [simp]:
  1644   fixes x y :: "'a::field poly"
  1645   shows "x mod (- y) = x mod y"
  1646   using mod_smult_right [of "- 1::'a"] by simp
  1647 
  1648 lemma pdivmod_rel_mult:
  1649   "\<lbrakk>pdivmod_rel x y q r; pdivmod_rel q z q' r'\<rbrakk>
  1650     \<Longrightarrow> pdivmod_rel x (y * z) q' (y * r' + r)"
  1651 apply (cases "z = 0", simp add: pdivmod_rel_def)
  1652 apply (cases "y = 0", simp add: pdivmod_rel_by_0_iff pdivmod_rel_0_iff)
  1653 apply (cases "r = 0")
  1654 apply (cases "r' = 0")
  1655 apply (simp add: pdivmod_rel_def)
  1656 apply (simp add: pdivmod_rel_def field_simps degree_mult_eq)
  1657 apply (cases "r' = 0")
  1658 apply (simp add: pdivmod_rel_def degree_mult_eq)
  1659 apply (simp add: pdivmod_rel_def field_simps)
  1660 apply (simp add: degree_mult_eq degree_add_less)
  1661 done
  1662 
  1663 lemma poly_div_mult_right:
  1664   fixes x y z :: "'a::field poly"
  1665   shows "x div (y * z) = (x div y) div z"
  1666   by (rule div_poly_eq, rule pdivmod_rel_mult, (rule pdivmod_rel)+)
  1667 
  1668 lemma poly_mod_mult_right:
  1669   fixes x y z :: "'a::field poly"
  1670   shows "x mod (y * z) = y * (x div y mod z) + x mod y"
  1671   by (rule mod_poly_eq, rule pdivmod_rel_mult, (rule pdivmod_rel)+)
  1672 
  1673 lemma mod_pCons:
  1674   fixes a and x
  1675   assumes y: "y \<noteq> 0"
  1676   defines b: "b \<equiv> coeff (pCons a (x mod y)) (degree y) / coeff y (degree y)"
  1677   shows "(pCons a x) mod y = (pCons a (x mod y) - smult b y)"
  1678 unfolding b
  1679 apply (rule mod_poly_eq)
  1680 apply (rule pdivmod_rel_pCons [OF pdivmod_rel y refl])
  1681 done
  1682 
  1683 definition pdivmod :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<times> 'a poly"
  1684 where
  1685   "pdivmod p q = (p div q, p mod q)"
  1686 
  1687 lemma div_poly_code [code]: 
  1688   "p div q = fst (pdivmod p q)"
  1689   by (simp add: pdivmod_def)
  1690 
  1691 lemma mod_poly_code [code]:
  1692   "p mod q = snd (pdivmod p q)"
  1693   by (simp add: pdivmod_def)
  1694 
  1695 lemma pdivmod_0:
  1696   "pdivmod 0 q = (0, 0)"
  1697   by (simp add: pdivmod_def)
  1698 
  1699 lemma pdivmod_pCons:
  1700   "pdivmod (pCons a p) q =
  1701     (if q = 0 then (0, pCons a p) else
  1702       (let (s, r) = pdivmod p q;
  1703            b = coeff (pCons a r) (degree q) / coeff q (degree q)
  1704         in (pCons b s, pCons a r - smult b q)))"
  1705   apply (simp add: pdivmod_def Let_def, safe)
  1706   apply (rule div_poly_eq)
  1707   apply (erule pdivmod_rel_pCons [OF pdivmod_rel _ refl])
  1708   apply (rule mod_poly_eq)
  1709   apply (erule pdivmod_rel_pCons [OF pdivmod_rel _ refl])
  1710   done
  1711 
  1712 lemma pdivmod_fold_coeffs [code]:
  1713   "pdivmod p q = (if q = 0 then (0, p)
  1714     else fold_coeffs (\<lambda>a (s, r).
  1715       let b = coeff (pCons a r) (degree q) / coeff q (degree q)
  1716       in (pCons b s, pCons a r - smult b q)
  1717    ) p (0, 0))"
  1718   apply (cases "q = 0")
  1719   apply (simp add: pdivmod_def)
  1720   apply (rule sym)
  1721   apply (induct p)
  1722   apply (simp_all add: pdivmod_0 pdivmod_pCons)
  1723   apply (case_tac "a = 0 \<and> p = 0")
  1724   apply (auto simp add: pdivmod_def)
  1725   done
  1726 
  1727 
  1728 subsection \<open>Order of polynomial roots\<close>
  1729 
  1730 definition order :: "'a::idom \<Rightarrow> 'a poly \<Rightarrow> nat"
  1731 where
  1732   "order a p = (LEAST n. \<not> [:-a, 1:] ^ Suc n dvd p)"
  1733 
  1734 lemma coeff_linear_power:
  1735   fixes a :: "'a::comm_semiring_1"
  1736   shows "coeff ([:a, 1:] ^ n) n = 1"
  1737 apply (induct n, simp_all)
  1738 apply (subst coeff_eq_0)
  1739 apply (auto intro: le_less_trans degree_power_le)
  1740 done
  1741 
  1742 lemma degree_linear_power:
  1743   fixes a :: "'a::comm_semiring_1"
  1744   shows "degree ([:a, 1:] ^ n) = n"
  1745 apply (rule order_antisym)
  1746 apply (rule ord_le_eq_trans [OF degree_power_le], simp)
  1747 apply (rule le_degree, simp add: coeff_linear_power)
  1748 done
  1749 
  1750 lemma order_1: "[:-a, 1:] ^ order a p dvd p"
  1751 apply (cases "p = 0", simp)
  1752 apply (cases "order a p", simp)
  1753 apply (subgoal_tac "nat < (LEAST n. \<not> [:-a, 1:] ^ Suc n dvd p)")
  1754 apply (drule not_less_Least, simp)
  1755 apply (fold order_def, simp)
  1756 done
  1757 
  1758 lemma order_2: "p \<noteq> 0 \<Longrightarrow> \<not> [:-a, 1:] ^ Suc (order a p) dvd p"
  1759 unfolding order_def
  1760 apply (rule LeastI_ex)
  1761 apply (rule_tac x="degree p" in exI)
  1762 apply (rule notI)
  1763 apply (drule (1) dvd_imp_degree_le)
  1764 apply (simp only: degree_linear_power)
  1765 done
  1766 
  1767 lemma order:
  1768   "p \<noteq> 0 \<Longrightarrow> [:-a, 1:] ^ order a p dvd p \<and> \<not> [:-a, 1:] ^ Suc (order a p) dvd p"
  1769 by (rule conjI [OF order_1 order_2])
  1770 
  1771 lemma order_degree:
  1772   assumes p: "p \<noteq> 0"
  1773   shows "order a p \<le> degree p"
  1774 proof -
  1775   have "order a p = degree ([:-a, 1:] ^ order a p)"
  1776     by (simp only: degree_linear_power)
  1777   also have "\<dots> \<le> degree p"
  1778     using order_1 p by (rule dvd_imp_degree_le)
  1779   finally show ?thesis .
  1780 qed
  1781 
  1782 lemma order_root: "poly p a = 0 \<longleftrightarrow> p = 0 \<or> order a p \<noteq> 0"
  1783 apply (cases "p = 0", simp_all)
  1784 apply (rule iffI)
  1785 apply (metis order_2 not_gr0 poly_eq_0_iff_dvd power_0 power_Suc_0 power_one_right)
  1786 unfolding poly_eq_0_iff_dvd
  1787 apply (metis dvd_power dvd_trans order_1)
  1788 done
  1789 
  1790 
  1791 subsection \<open>GCD of polynomials\<close>
  1792 
  1793 instantiation poly :: (field) gcd
  1794 begin
  1795 
  1796 function gcd_poly :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
  1797 where
  1798   "gcd (x::'a poly) 0 = smult (inverse (coeff x (degree x))) x"
  1799 | "y \<noteq> 0 \<Longrightarrow> gcd (x::'a poly) y = gcd y (x mod y)"
  1800 by auto
  1801 
  1802 termination "gcd :: _ poly \<Rightarrow> _"
  1803 by (relation "measure (\<lambda>(x, y). if y = 0 then 0 else Suc (degree y))")
  1804    (auto dest: degree_mod_less)
  1805 
  1806 declare gcd_poly.simps [simp del]
  1807 
  1808 definition lcm_poly :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
  1809 where
  1810   "lcm_poly a b = a * b div smult (coeff a (degree a) * coeff b (degree b)) (gcd a b)"
  1811 
  1812 instance ..
  1813 
  1814 end
  1815 
  1816 lemma
  1817   fixes x y :: "_ poly"
  1818   shows poly_gcd_dvd1 [iff]: "gcd x y dvd x"
  1819     and poly_gcd_dvd2 [iff]: "gcd x y dvd y"
  1820   apply (induct x y rule: gcd_poly.induct)
  1821   apply (simp_all add: gcd_poly.simps)
  1822   apply (fastforce simp add: smult_dvd_iff dest: inverse_zero_imp_zero)
  1823   apply (blast dest: dvd_mod_imp_dvd)
  1824   done
  1825 
  1826 lemma poly_gcd_greatest:
  1827   fixes k x y :: "_ poly"
  1828   shows "k dvd x \<Longrightarrow> k dvd y \<Longrightarrow> k dvd gcd x y"
  1829   by (induct x y rule: gcd_poly.induct)
  1830      (simp_all add: gcd_poly.simps dvd_mod dvd_smult)
  1831 
  1832 lemma dvd_poly_gcd_iff [iff]:
  1833   fixes k x y :: "_ poly"
  1834   shows "k dvd gcd x y \<longleftrightarrow> k dvd x \<and> k dvd y"
  1835   by (auto intro!: poly_gcd_greatest intro: dvd_trans [of _ "gcd x y"])
  1836 
  1837 lemma poly_gcd_monic:
  1838   fixes x y :: "_ poly"
  1839   shows "coeff (gcd x y) (degree (gcd x y)) =
  1840     (if x = 0 \<and> y = 0 then 0 else 1)"
  1841   by (induct x y rule: gcd_poly.induct)
  1842      (simp_all add: gcd_poly.simps nonzero_imp_inverse_nonzero)
  1843 
  1844 lemma poly_gcd_zero_iff [simp]:
  1845   fixes x y :: "_ poly"
  1846   shows "gcd x y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
  1847   by (simp only: dvd_0_left_iff [symmetric] dvd_poly_gcd_iff)
  1848 
  1849 lemma poly_gcd_0_0 [simp]:
  1850   "gcd (0::_ poly) 0 = 0"
  1851   by simp
  1852 
  1853 lemma poly_dvd_antisym:
  1854   fixes p q :: "'a::idom poly"
  1855   assumes coeff: "coeff p (degree p) = coeff q (degree q)"
  1856   assumes dvd1: "p dvd q" and dvd2: "q dvd p" shows "p = q"
  1857 proof (cases "p = 0")
  1858   case True with coeff show "p = q" by simp
  1859 next
  1860   case False with coeff have "q \<noteq> 0" by auto
  1861   have degree: "degree p = degree q"
  1862     using \<open>p dvd q\<close> \<open>q dvd p\<close> \<open>p \<noteq> 0\<close> \<open>q \<noteq> 0\<close>
  1863     by (intro order_antisym dvd_imp_degree_le)
  1864 
  1865   from \<open>p dvd q\<close> obtain a where a: "q = p * a" ..
  1866   with \<open>q \<noteq> 0\<close> have "a \<noteq> 0" by auto
  1867   with degree a \<open>p \<noteq> 0\<close> have "degree a = 0"
  1868     by (simp add: degree_mult_eq)
  1869   with coeff a show "p = q"
  1870     by (cases a, auto split: if_splits)
  1871 qed
  1872 
  1873 lemma poly_gcd_unique:
  1874   fixes d x y :: "_ poly"
  1875   assumes dvd1: "d dvd x" and dvd2: "d dvd y"
  1876     and greatest: "\<And>k. k dvd x \<Longrightarrow> k dvd y \<Longrightarrow> k dvd d"
  1877     and monic: "coeff d (degree d) = (if x = 0 \<and> y = 0 then 0 else 1)"
  1878   shows "gcd x y = d"
  1879 proof -
  1880   have "coeff (gcd x y) (degree (gcd x y)) = coeff d (degree d)"
  1881     by (simp_all add: poly_gcd_monic monic)
  1882   moreover have "gcd x y dvd d"
  1883     using poly_gcd_dvd1 poly_gcd_dvd2 by (rule greatest)
  1884   moreover have "d dvd gcd x y"
  1885     using dvd1 dvd2 by (rule poly_gcd_greatest)
  1886   ultimately show ?thesis
  1887     by (rule poly_dvd_antisym)
  1888 qed
  1889 
  1890 interpretation gcd_poly!: abel_semigroup "gcd :: _ poly \<Rightarrow> _"
  1891 proof
  1892   fix x y z :: "'a poly"
  1893   show "gcd (gcd x y) z = gcd x (gcd y z)"
  1894     by (rule poly_gcd_unique) (auto intro: dvd_trans simp add: poly_gcd_monic)
  1895   show "gcd x y = gcd y x"
  1896     by (rule poly_gcd_unique) (simp_all add: poly_gcd_monic)
  1897 qed
  1898 
  1899 lemmas poly_gcd_assoc = gcd_poly.assoc
  1900 lemmas poly_gcd_commute = gcd_poly.commute
  1901 lemmas poly_gcd_left_commute = gcd_poly.left_commute
  1902 
  1903 lemmas poly_gcd_ac = poly_gcd_assoc poly_gcd_commute poly_gcd_left_commute
  1904 
  1905 lemma poly_gcd_1_left [simp]: "gcd 1 y = (1 :: _ poly)"
  1906 by (rule poly_gcd_unique) simp_all
  1907 
  1908 lemma poly_gcd_1_right [simp]: "gcd x 1 = (1 :: _ poly)"
  1909 by (rule poly_gcd_unique) simp_all
  1910 
  1911 lemma poly_gcd_minus_left [simp]: "gcd (- x) y = gcd x (y :: _ poly)"
  1912 by (rule poly_gcd_unique) (simp_all add: poly_gcd_monic)
  1913 
  1914 lemma poly_gcd_minus_right [simp]: "gcd x (- y) = gcd x (y :: _ poly)"
  1915 by (rule poly_gcd_unique) (simp_all add: poly_gcd_monic)
  1916 
  1917 lemma poly_gcd_code [code]:
  1918   "gcd x y = (if y = 0 then smult (inverse (coeff x (degree x))) x else gcd y (x mod (y :: _ poly)))"
  1919   by (simp add: gcd_poly.simps)
  1920 
  1921 
  1922 subsection \<open>Composition of polynomials\<close>
  1923 
  1924 definition pcompose :: "'a::comm_semiring_0 poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
  1925 where
  1926   "pcompose p q = fold_coeffs (\<lambda>a c. [:a:] + q * c) p 0"
  1927 
  1928 lemma pcompose_0 [simp]:
  1929   "pcompose 0 q = 0"
  1930   by (simp add: pcompose_def)
  1931 
  1932 lemma pcompose_pCons:
  1933   "pcompose (pCons a p) q = [:a:] + q * pcompose p q"
  1934   by (cases "p = 0 \<and> a = 0") (auto simp add: pcompose_def)
  1935 
  1936 lemma poly_pcompose:
  1937   "poly (pcompose p q) x = poly p (poly q x)"
  1938   by (induct p) (simp_all add: pcompose_pCons)
  1939 
  1940 lemma degree_pcompose_le:
  1941   "degree (pcompose p q) \<le> degree p * degree q"
  1942 apply (induct p, simp)
  1943 apply (simp add: pcompose_pCons, clarify)
  1944 apply (rule degree_add_le, simp)
  1945 apply (rule order_trans [OF degree_mult_le], simp)
  1946 done
  1947 
  1948 
  1949 no_notation cCons (infixr "##" 65)
  1950 
  1951 end