src/HOL/Analysis/Complex_Analysis_Basics.thy
author nipkow
Wed Jan 10 15:25:09 2018 +0100 (16 months ago)
changeset 67399 eab6ce8368fa
parent 67371 2d9cf74943e1
child 67968 a5ad4c015d1c
permissions -rw-r--r--
ran isabelle update_op on all sources
     1 (*  Author: John Harrison, Marco Maggesi, Graziano Gentili, Gianni Ciolli, Valentina Bruno
     2     Ported from "hol_light/Multivariate/canal.ml" by L C Paulson (2014)
     3 *)
     4 
     5 section \<open>Complex Analysis Basics\<close>
     6 
     7 theory Complex_Analysis_Basics
     8 imports Equivalence_Lebesgue_Henstock_Integration "HOL-Library.Nonpos_Ints"
     9 begin
    10 
    11 
    12 subsection\<open>General lemmas\<close>
    13 
    14 lemma nonneg_Reals_cmod_eq_Re: "z \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> norm z = Re z"
    15   by (simp add: complex_nonneg_Reals_iff cmod_eq_Re)
    16 
    17 lemma has_derivative_mult_right:
    18   fixes c:: "'a :: real_normed_algebra"
    19   shows "((( * ) c) has_derivative (( * ) c)) F"
    20 by (rule has_derivative_mult_right [OF has_derivative_id])
    21 
    22 lemma has_derivative_of_real[derivative_intros, simp]:
    23   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_derivative (\<lambda>x. of_real (f' x))) F"
    24   using bounded_linear.has_derivative[OF bounded_linear_of_real] .
    25 
    26 lemma has_vector_derivative_real_field:
    27   "DERIV f (of_real a) :> f' \<Longrightarrow> ((\<lambda>x. f (of_real x)) has_vector_derivative f') (at a within s)"
    28   using has_derivative_compose[of of_real of_real a _ f "( * ) f'"]
    29   by (simp add: scaleR_conv_of_real ac_simps has_vector_derivative_def has_field_derivative_def)
    30 lemmas has_vector_derivative_real_complex = has_vector_derivative_real_field
    31 
    32 lemma fact_cancel:
    33   fixes c :: "'a::real_field"
    34   shows "of_nat (Suc n) * c / (fact (Suc n)) = c / (fact n)"
    35   by (simp add: of_nat_mult del: of_nat_Suc times_nat.simps)
    36 
    37 lemma bilinear_times:
    38   fixes c::"'a::real_algebra" shows "bilinear (\<lambda>x y::'a. x*y)"
    39   by (auto simp: bilinear_def distrib_left distrib_right intro!: linearI)
    40 
    41 lemma linear_cnj: "linear cnj"
    42   using bounded_linear.linear[OF bounded_linear_cnj] .
    43 
    44 lemma tendsto_Re_upper:
    45   assumes "~ (trivial_limit F)"
    46           "(f \<longlongrightarrow> l) F"
    47           "eventually (\<lambda>x. Re(f x) \<le> b) F"
    48     shows  "Re(l) \<le> b"
    49   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Re)
    50 
    51 lemma tendsto_Re_lower:
    52   assumes "~ (trivial_limit F)"
    53           "(f \<longlongrightarrow> l) F"
    54           "eventually (\<lambda>x. b \<le> Re(f x)) F"
    55     shows  "b \<le> Re(l)"
    56   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Re)
    57 
    58 lemma tendsto_Im_upper:
    59   assumes "~ (trivial_limit F)"
    60           "(f \<longlongrightarrow> l) F"
    61           "eventually (\<lambda>x. Im(f x) \<le> b) F"
    62     shows  "Im(l) \<le> b"
    63   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Im)
    64 
    65 lemma tendsto_Im_lower:
    66   assumes "~ (trivial_limit F)"
    67           "(f \<longlongrightarrow> l) F"
    68           "eventually (\<lambda>x. b \<le> Im(f x)) F"
    69     shows  "b \<le> Im(l)"
    70   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Im)
    71 
    72 lemma lambda_zero: "(\<lambda>h::'a::mult_zero. 0) = ( * ) 0"
    73   by auto
    74 
    75 lemma lambda_one: "(\<lambda>x::'a::monoid_mult. x) = ( * ) 1"
    76   by auto
    77 
    78 lemma continuous_mult_left:
    79   fixes c::"'a::real_normed_algebra"
    80   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. c * f x)"
    81 by (rule continuous_mult [OF continuous_const])
    82 
    83 lemma continuous_mult_right:
    84   fixes c::"'a::real_normed_algebra"
    85   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x * c)"
    86 by (rule continuous_mult [OF _ continuous_const])
    87 
    88 lemma continuous_on_mult_left:
    89   fixes c::"'a::real_normed_algebra"
    90   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. c * f x)"
    91 by (rule continuous_on_mult [OF continuous_on_const])
    92 
    93 lemma continuous_on_mult_right:
    94   fixes c::"'a::real_normed_algebra"
    95   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x * c)"
    96 by (rule continuous_on_mult [OF _ continuous_on_const])
    97 
    98 lemma uniformly_continuous_on_cmul_right [continuous_intros]:
    99   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   100   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f x * c)"
   101   using bounded_linear.uniformly_continuous_on[OF bounded_linear_mult_left] .
   102 
   103 lemma uniformly_continuous_on_cmul_left[continuous_intros]:
   104   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   105   assumes "uniformly_continuous_on s f"
   106     shows "uniformly_continuous_on s (\<lambda>x. c * f x)"
   107 by (metis assms bounded_linear.uniformly_continuous_on bounded_linear_mult_right)
   108 
   109 lemma continuous_within_norm_id [continuous_intros]: "continuous (at x within S) norm"
   110   by (rule continuous_norm [OF continuous_ident])
   111 
   112 lemma continuous_on_norm_id [continuous_intros]: "continuous_on S norm"
   113   by (intro continuous_on_id continuous_on_norm)
   114 
   115 subsection\<open>DERIV stuff\<close>
   116 
   117 lemma DERIV_zero_connected_constant:
   118   fixes f :: "'a::{real_normed_field,euclidean_space} \<Rightarrow> 'a"
   119   assumes "connected s"
   120       and "open s"
   121       and "finite k"
   122       and "continuous_on s f"
   123       and "\<forall>x\<in>(s - k). DERIV f x :> 0"
   124     obtains c where "\<And>x. x \<in> s \<Longrightarrow> f(x) = c"
   125 using has_derivative_zero_connected_constant [OF assms(1-4)] assms
   126 by (metis DERIV_const has_derivative_const Diff_iff at_within_open frechet_derivative_at has_field_derivative_def)
   127 
   128 lemmas DERIV_zero_constant = has_field_derivative_zero_constant
   129 
   130 lemma DERIV_zero_unique:
   131   assumes "convex s"
   132       and d0: "\<And>x. x\<in>s \<Longrightarrow> (f has_field_derivative 0) (at x within s)"
   133       and "a \<in> s"
   134       and "x \<in> s"
   135     shows "f x = f a"
   136   by (rule has_derivative_zero_unique [OF assms(1) _ assms(4,3)])
   137      (metis d0 has_field_derivative_imp_has_derivative lambda_zero)
   138 
   139 lemma DERIV_zero_connected_unique:
   140   assumes "connected s"
   141       and "open s"
   142       and d0: "\<And>x. x\<in>s \<Longrightarrow> DERIV f x :> 0"
   143       and "a \<in> s"
   144       and "x \<in> s"
   145     shows "f x = f a"
   146     by (rule has_derivative_zero_unique_connected [OF assms(2,1) _ assms(5,4)])
   147        (metis has_field_derivative_def lambda_zero d0)
   148 
   149 lemma DERIV_transform_within:
   150   assumes "(f has_field_derivative f') (at a within s)"
   151       and "0 < d" "a \<in> s"
   152       and "\<And>x. x\<in>s \<Longrightarrow> dist x a < d \<Longrightarrow> f x = g x"
   153     shows "(g has_field_derivative f') (at a within s)"
   154   using assms unfolding has_field_derivative_def
   155   by (blast intro: has_derivative_transform_within)
   156 
   157 lemma DERIV_transform_within_open:
   158   assumes "DERIV f a :> f'"
   159       and "open s" "a \<in> s"
   160       and "\<And>x. x\<in>s \<Longrightarrow> f x = g x"
   161     shows "DERIV g a :> f'"
   162   using assms unfolding has_field_derivative_def
   163 by (metis has_derivative_transform_within_open)
   164 
   165 lemma DERIV_transform_at:
   166   assumes "DERIV f a :> f'"
   167       and "0 < d"
   168       and "\<And>x. dist x a < d \<Longrightarrow> f x = g x"
   169     shows "DERIV g a :> f'"
   170   by (blast intro: assms DERIV_transform_within)
   171 
   172 (*generalising DERIV_isconst_all, which requires type real (using the ordering)*)
   173 lemma DERIV_zero_UNIV_unique:
   174   "(\<And>x. DERIV f x :> 0) \<Longrightarrow> f x = f a"
   175   by (metis DERIV_zero_unique UNIV_I convex_UNIV)
   176 
   177 subsection \<open>Some limit theorems about real part of real series etc.\<close>
   178 
   179 (*MOVE? But not to Finite_Cartesian_Product*)
   180 lemma sums_vec_nth :
   181   assumes "f sums a"
   182   shows "(\<lambda>x. f x $ i) sums a $ i"
   183 using assms unfolding sums_def
   184 by (auto dest: tendsto_vec_nth [where i=i])
   185 
   186 lemma summable_vec_nth :
   187   assumes "summable f"
   188   shows "summable (\<lambda>x. f x $ i)"
   189 using assms unfolding summable_def
   190 by (blast intro: sums_vec_nth)
   191 
   192 subsection \<open>Complex number lemmas\<close>
   193 
   194 lemma
   195   shows open_halfspace_Re_lt: "open {z. Re(z) < b}"
   196     and open_halfspace_Re_gt: "open {z. Re(z) > b}"
   197     and closed_halfspace_Re_ge: "closed {z. Re(z) \<ge> b}"
   198     and closed_halfspace_Re_le: "closed {z. Re(z) \<le> b}"
   199     and closed_halfspace_Re_eq: "closed {z. Re(z) = b}"
   200     and open_halfspace_Im_lt: "open {z. Im(z) < b}"
   201     and open_halfspace_Im_gt: "open {z. Im(z) > b}"
   202     and closed_halfspace_Im_ge: "closed {z. Im(z) \<ge> b}"
   203     and closed_halfspace_Im_le: "closed {z. Im(z) \<le> b}"
   204     and closed_halfspace_Im_eq: "closed {z. Im(z) = b}"
   205   by (intro open_Collect_less closed_Collect_le closed_Collect_eq continuous_on_Re
   206             continuous_on_Im continuous_on_id continuous_on_const)+
   207 
   208 lemma closed_complex_Reals: "closed (\<real> :: complex set)"
   209 proof -
   210   have "(\<real> :: complex set) = {z. Im z = 0}"
   211     by (auto simp: complex_is_Real_iff)
   212   then show ?thesis
   213     by (metis closed_halfspace_Im_eq)
   214 qed
   215 
   216 lemma closed_Real_halfspace_Re_le: "closed (\<real> \<inter> {w. Re w \<le> x})"
   217   by (simp add: closed_Int closed_complex_Reals closed_halfspace_Re_le)
   218 
   219 corollary closed_nonpos_Reals_complex [simp]: "closed (\<real>\<^sub>\<le>\<^sub>0 :: complex set)"
   220 proof -
   221   have "\<real>\<^sub>\<le>\<^sub>0 = \<real> \<inter> {z. Re(z) \<le> 0}"
   222     using complex_nonpos_Reals_iff complex_is_Real_iff by auto
   223   then show ?thesis
   224     by (metis closed_Real_halfspace_Re_le)
   225 qed
   226 
   227 lemma closed_Real_halfspace_Re_ge: "closed (\<real> \<inter> {w. x \<le> Re(w)})"
   228   using closed_halfspace_Re_ge
   229   by (simp add: closed_Int closed_complex_Reals)
   230 
   231 corollary closed_nonneg_Reals_complex [simp]: "closed (\<real>\<^sub>\<ge>\<^sub>0 :: complex set)"
   232 proof -
   233   have "\<real>\<^sub>\<ge>\<^sub>0 = \<real> \<inter> {z. Re(z) \<ge> 0}"
   234     using complex_nonneg_Reals_iff complex_is_Real_iff by auto
   235   then show ?thesis
   236     by (metis closed_Real_halfspace_Re_ge)
   237 qed
   238 
   239 lemma closed_real_abs_le: "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   240 proof -
   241   have "{w \<in> \<real>. \<bar>Re w\<bar> \<le> r} = (\<real> \<inter> {w. Re w \<le> r}) \<inter> (\<real> \<inter> {w. Re w \<ge> -r})"
   242     by auto
   243   then show "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   244     by (simp add: closed_Int closed_Real_halfspace_Re_ge closed_Real_halfspace_Re_le)
   245 qed
   246 
   247 lemma real_lim:
   248   fixes l::complex
   249   assumes "(f \<longlongrightarrow> l) F" and "~(trivial_limit F)" and "eventually P F" and "\<And>a. P a \<Longrightarrow> f a \<in> \<real>"
   250   shows  "l \<in> \<real>"
   251 proof (rule Lim_in_closed_set[OF closed_complex_Reals _ assms(2,1)])
   252   show "eventually (\<lambda>x. f x \<in> \<real>) F"
   253     using assms(3, 4) by (auto intro: eventually_mono)
   254 qed
   255 
   256 lemma real_lim_sequentially:
   257   fixes l::complex
   258   shows "(f \<longlongrightarrow> l) sequentially \<Longrightarrow> (\<exists>N. \<forall>n\<ge>N. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   259 by (rule real_lim [where F=sequentially]) (auto simp: eventually_sequentially)
   260 
   261 lemma real_series:
   262   fixes l::complex
   263   shows "f sums l \<Longrightarrow> (\<And>n. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   264 unfolding sums_def
   265 by (metis real_lim_sequentially sum_in_Reals)
   266 
   267 lemma Lim_null_comparison_Re:
   268   assumes "eventually (\<lambda>x. norm(f x) \<le> Re(g x)) F" "(g \<longlongrightarrow> 0) F" shows "(f \<longlongrightarrow> 0) F"
   269   by (rule Lim_null_comparison[OF assms(1)] tendsto_eq_intros assms(2))+ simp
   270 
   271 subsection\<open>Holomorphic functions\<close>
   272 
   273 subsection\<open>Holomorphic functions\<close>
   274 
   275 definition holomorphic_on :: "[complex \<Rightarrow> complex, complex set] \<Rightarrow> bool"
   276            (infixl "(holomorphic'_on)" 50)
   277   where "f holomorphic_on s \<equiv> \<forall>x\<in>s. f field_differentiable (at x within s)"
   278 
   279 named_theorems holomorphic_intros "structural introduction rules for holomorphic_on"
   280 
   281 lemma holomorphic_onI [intro?]: "(\<And>x. x \<in> s \<Longrightarrow> f field_differentiable (at x within s)) \<Longrightarrow> f holomorphic_on s"
   282   by (simp add: holomorphic_on_def)
   283 
   284 lemma holomorphic_onD [dest?]: "\<lbrakk>f holomorphic_on s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x within s)"
   285   by (simp add: holomorphic_on_def)
   286 
   287 lemma holomorphic_on_imp_differentiable_on:
   288     "f holomorphic_on s \<Longrightarrow> f differentiable_on s"
   289   unfolding holomorphic_on_def differentiable_on_def
   290   by (simp add: field_differentiable_imp_differentiable)
   291 
   292 lemma holomorphic_on_imp_differentiable_at:
   293    "\<lbrakk>f holomorphic_on s; open s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x)"
   294 using at_within_open holomorphic_on_def by fastforce
   295 
   296 lemma holomorphic_on_empty [holomorphic_intros]: "f holomorphic_on {}"
   297   by (simp add: holomorphic_on_def)
   298 
   299 lemma holomorphic_on_open:
   300     "open s \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>f'. DERIV f x :> f')"
   301   by (auto simp: holomorphic_on_def field_differentiable_def has_field_derivative_def at_within_open [of _ s])
   302 
   303 lemma holomorphic_on_imp_continuous_on:
   304     "f holomorphic_on s \<Longrightarrow> continuous_on s f"
   305   by (metis field_differentiable_imp_continuous_at continuous_on_eq_continuous_within holomorphic_on_def)
   306 
   307 lemma holomorphic_on_subset [elim]:
   308     "f holomorphic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f holomorphic_on t"
   309   unfolding holomorphic_on_def
   310   by (metis field_differentiable_within_subset subsetD)
   311 
   312 lemma holomorphic_transform: "\<lbrakk>f holomorphic_on s; \<And>x. x \<in> s \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> g holomorphic_on s"
   313   by (metis field_differentiable_transform_within linordered_field_no_ub holomorphic_on_def)
   314 
   315 lemma holomorphic_cong: "s = t ==> (\<And>x. x \<in> s \<Longrightarrow> f x = g x) \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> g holomorphic_on t"
   316   by (metis holomorphic_transform)
   317 
   318 lemma holomorphic_on_linear [simp, holomorphic_intros]: "(( * ) c) holomorphic_on s"
   319   unfolding holomorphic_on_def by (metis field_differentiable_linear)
   320 
   321 lemma holomorphic_on_const [simp, holomorphic_intros]: "(\<lambda>z. c) holomorphic_on s"
   322   unfolding holomorphic_on_def by (metis field_differentiable_const)
   323 
   324 lemma holomorphic_on_ident [simp, holomorphic_intros]: "(\<lambda>x. x) holomorphic_on s"
   325   unfolding holomorphic_on_def by (metis field_differentiable_ident)
   326 
   327 lemma holomorphic_on_id [simp, holomorphic_intros]: "id holomorphic_on s"
   328   unfolding id_def by (rule holomorphic_on_ident)
   329 
   330 lemma holomorphic_on_compose:
   331   "f holomorphic_on s \<Longrightarrow> g holomorphic_on (f ` s) \<Longrightarrow> (g o f) holomorphic_on s"
   332   using field_differentiable_compose_within[of f _ s g]
   333   by (auto simp: holomorphic_on_def)
   334 
   335 lemma holomorphic_on_compose_gen:
   336   "f holomorphic_on s \<Longrightarrow> g holomorphic_on t \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> (g o f) holomorphic_on s"
   337   by (metis holomorphic_on_compose holomorphic_on_subset)
   338 
   339 lemma holomorphic_on_minus [holomorphic_intros]: "f holomorphic_on s \<Longrightarrow> (\<lambda>z. -(f z)) holomorphic_on s"
   340   by (metis field_differentiable_minus holomorphic_on_def)
   341 
   342 lemma holomorphic_on_add [holomorphic_intros]:
   343   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z + g z) holomorphic_on s"
   344   unfolding holomorphic_on_def by (metis field_differentiable_add)
   345 
   346 lemma holomorphic_on_diff [holomorphic_intros]:
   347   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z - g z) holomorphic_on s"
   348   unfolding holomorphic_on_def by (metis field_differentiable_diff)
   349 
   350 lemma holomorphic_on_mult [holomorphic_intros]:
   351   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z * g z) holomorphic_on s"
   352   unfolding holomorphic_on_def by (metis field_differentiable_mult)
   353 
   354 lemma holomorphic_on_inverse [holomorphic_intros]:
   355   "\<lbrakk>f holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. inverse (f z)) holomorphic_on s"
   356   unfolding holomorphic_on_def by (metis field_differentiable_inverse)
   357 
   358 lemma holomorphic_on_divide [holomorphic_intros]:
   359   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. f z / g z) holomorphic_on s"
   360   unfolding holomorphic_on_def by (metis field_differentiable_divide)
   361 
   362 lemma holomorphic_on_power [holomorphic_intros]:
   363   "f holomorphic_on s \<Longrightarrow> (\<lambda>z. (f z)^n) holomorphic_on s"
   364   unfolding holomorphic_on_def by (metis field_differentiable_power)
   365 
   366 lemma holomorphic_on_sum [holomorphic_intros]:
   367   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) holomorphic_on s"
   368   unfolding holomorphic_on_def by (metis field_differentiable_sum)
   369 
   370 lemma holomorphic_on_prod [holomorphic_intros]:
   371   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. prod (\<lambda>i. f i x) I) holomorphic_on s"
   372   by (induction I rule: infinite_finite_induct) (auto intro: holomorphic_intros)
   373 
   374 lemma holomorphic_pochhammer [holomorphic_intros]:
   375   "f holomorphic_on A \<Longrightarrow> (\<lambda>s. pochhammer (f s) n) holomorphic_on A"
   376   by (induction n) (auto intro!: holomorphic_intros simp: pochhammer_Suc)
   377 
   378 lemma holomorphic_on_scaleR [holomorphic_intros]:
   379   "f holomorphic_on A \<Longrightarrow> (\<lambda>x. c *\<^sub>R f x) holomorphic_on A"
   380   by (auto simp: scaleR_conv_of_real intro!: holomorphic_intros)
   381 
   382 lemma holomorphic_on_Un [holomorphic_intros]:
   383   assumes "f holomorphic_on A" "f holomorphic_on B" "open A" "open B"
   384   shows   "f holomorphic_on (A \<union> B)"
   385   using assms by (auto simp: holomorphic_on_def  at_within_open[of _ A] 
   386                              at_within_open[of _ B]  at_within_open[of _ "A \<union> B"] open_Un)
   387 
   388 lemma holomorphic_on_If_Un [holomorphic_intros]:
   389   assumes "f holomorphic_on A" "g holomorphic_on B" "open A" "open B"
   390   assumes "\<And>z. z \<in> A \<Longrightarrow> z \<in> B \<Longrightarrow> f z = g z"
   391   shows   "(\<lambda>z. if z \<in> A then f z else g z) holomorphic_on (A \<union> B)" (is "?h holomorphic_on _")
   392 proof (intro holomorphic_on_Un)
   393   note \<open>f holomorphic_on A\<close>
   394   also have "f holomorphic_on A \<longleftrightarrow> ?h holomorphic_on A"
   395     by (intro holomorphic_cong) auto
   396   finally show \<dots> .
   397 next
   398   note \<open>g holomorphic_on B\<close>
   399   also have "g holomorphic_on B \<longleftrightarrow> ?h holomorphic_on B"
   400     using assms by (intro holomorphic_cong) auto
   401   finally show \<dots> .
   402 qed (insert assms, auto)
   403 
   404 lemma leibniz_rule_holomorphic:
   405   fixes f::"complex \<Rightarrow> 'b::euclidean_space \<Rightarrow> complex"
   406   assumes "\<And>x t. x \<in> U \<Longrightarrow> t \<in> cbox a b \<Longrightarrow> ((\<lambda>x. f x t) has_field_derivative fx x t) (at x within U)"
   407   assumes "\<And>x. x \<in> U \<Longrightarrow> (f x) integrable_on cbox a b"
   408   assumes "continuous_on (U \<times> (cbox a b)) (\<lambda>(x, t). fx x t)"
   409   assumes "convex U"
   410   shows "(\<lambda>x. integral (cbox a b) (f x)) holomorphic_on U"
   411   using leibniz_rule_field_differentiable[OF assms(1-3) _ assms(4)]
   412   by (auto simp: holomorphic_on_def)
   413 
   414 lemma DERIV_deriv_iff_field_differentiable:
   415   "DERIV f x :> deriv f x \<longleftrightarrow> f field_differentiable at x"
   416   unfolding field_differentiable_def by (metis DERIV_imp_deriv)
   417 
   418 lemma holomorphic_derivI:
   419      "\<lbrakk>f holomorphic_on S; open S; x \<in> S\<rbrakk>
   420       \<Longrightarrow> (f has_field_derivative deriv f x) (at x within T)"
   421 by (metis DERIV_deriv_iff_field_differentiable at_within_open  holomorphic_on_def has_field_derivative_at_within)
   422 
   423 lemma complex_derivative_chain:
   424   "f field_differentiable at x \<Longrightarrow> g field_differentiable at (f x)
   425     \<Longrightarrow> deriv (g o f) x = deriv g (f x) * deriv f x"
   426   by (metis DERIV_deriv_iff_field_differentiable DERIV_chain DERIV_imp_deriv)
   427 
   428 lemma deriv_linear [simp]: "deriv (\<lambda>w. c * w) = (\<lambda>z. c)"
   429   by (metis DERIV_imp_deriv DERIV_cmult_Id)
   430 
   431 lemma deriv_ident [simp]: "deriv (\<lambda>w. w) = (\<lambda>z. 1)"
   432   by (metis DERIV_imp_deriv DERIV_ident)
   433 
   434 lemma deriv_id [simp]: "deriv id = (\<lambda>z. 1)"
   435   by (simp add: id_def)
   436 
   437 lemma deriv_const [simp]: "deriv (\<lambda>w. c) = (\<lambda>z. 0)"
   438   by (metis DERIV_imp_deriv DERIV_const)
   439 
   440 lemma deriv_add [simp]:
   441   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   442    \<Longrightarrow> deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   443   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   444   by (auto intro!: DERIV_imp_deriv derivative_intros)
   445 
   446 lemma deriv_diff [simp]:
   447   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   448    \<Longrightarrow> deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   449   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   450   by (auto intro!: DERIV_imp_deriv derivative_intros)
   451 
   452 lemma deriv_mult [simp]:
   453   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   454    \<Longrightarrow> deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   455   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   456   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   457 
   458 lemma deriv_cmult [simp]:
   459   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. c * f w) z = c * deriv f z"
   460   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   461   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   462 
   463 lemma deriv_cmult_right [simp]:
   464   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w * c) z = deriv f z * c"
   465   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   466   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   467 
   468 lemma deriv_cdivide_right [simp]:
   469   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w / c) z = deriv f z / c"
   470   unfolding Fields.field_class.field_divide_inverse
   471   by (blast intro: deriv_cmult_right)
   472 
   473 lemma complex_derivative_transform_within_open:
   474   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; open s; z \<in> s; \<And>w. w \<in> s \<Longrightarrow> f w = g w\<rbrakk>
   475    \<Longrightarrow> deriv f z = deriv g z"
   476   unfolding holomorphic_on_def
   477   by (rule DERIV_imp_deriv)
   478      (metis DERIV_deriv_iff_field_differentiable DERIV_transform_within_open at_within_open)
   479 
   480 lemma deriv_compose_linear:
   481   "f field_differentiable at (c * z) \<Longrightarrow> deriv (\<lambda>w. f (c * w)) z = c * deriv f (c * z)"
   482 apply (rule DERIV_imp_deriv)
   483 apply (simp add: DERIV_deriv_iff_field_differentiable [symmetric])
   484 apply (drule DERIV_chain' [of "times c" c z UNIV f "deriv f (c * z)", OF DERIV_cmult_Id])
   485 apply (simp add: algebra_simps)
   486 done
   487 
   488 lemma nonzero_deriv_nonconstant:
   489   assumes df: "DERIV f \<xi> :> df" and S: "open S" "\<xi> \<in> S" and "df \<noteq> 0"
   490     shows "\<not> f constant_on S"
   491 unfolding constant_on_def
   492 by (metis \<open>df \<noteq> 0\<close> DERIV_transform_within_open [OF df S] DERIV_const DERIV_unique)
   493 
   494 lemma holomorphic_nonconstant:
   495   assumes holf: "f holomorphic_on S" and "open S" "\<xi> \<in> S" "deriv f \<xi> \<noteq> 0"
   496     shows "\<not> f constant_on S"
   497     apply (rule nonzero_deriv_nonconstant [of f "deriv f \<xi>" \<xi> S])
   498     using assms
   499     apply (auto simp: holomorphic_derivI)
   500     done
   501 
   502 subsection\<open>Caratheodory characterization\<close>
   503 
   504 lemma field_differentiable_caratheodory_at:
   505   "f field_differentiable (at z) \<longleftrightarrow>
   506          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z) g)"
   507   using CARAT_DERIV [of f]
   508   by (simp add: field_differentiable_def has_field_derivative_def)
   509 
   510 lemma field_differentiable_caratheodory_within:
   511   "f field_differentiable (at z within s) \<longleftrightarrow>
   512          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z within s) g)"
   513   using DERIV_caratheodory_within [of f]
   514   by (simp add: field_differentiable_def has_field_derivative_def)
   515 
   516 subsection\<open>Analyticity on a set\<close>
   517 
   518 definition analytic_on (infixl "(analytic'_on)" 50)
   519   where
   520    "f analytic_on s \<equiv> \<forall>x \<in> s. \<exists>e. 0 < e \<and> f holomorphic_on (ball x e)"
   521 
   522 named_theorems analytic_intros "introduction rules for proving analyticity"
   523 
   524 lemma analytic_imp_holomorphic: "f analytic_on s \<Longrightarrow> f holomorphic_on s"
   525   by (simp add: at_within_open [OF _ open_ball] analytic_on_def holomorphic_on_def)
   526      (metis centre_in_ball field_differentiable_at_within)
   527 
   528 lemma analytic_on_open: "open s \<Longrightarrow> f analytic_on s \<longleftrightarrow> f holomorphic_on s"
   529 apply (auto simp: analytic_imp_holomorphic)
   530 apply (auto simp: analytic_on_def holomorphic_on_def)
   531 by (metis holomorphic_on_def holomorphic_on_subset open_contains_ball)
   532 
   533 lemma analytic_on_imp_differentiable_at:
   534   "f analytic_on s \<Longrightarrow> x \<in> s \<Longrightarrow> f field_differentiable (at x)"
   535  apply (auto simp: analytic_on_def holomorphic_on_def)
   536 by (metis open_ball centre_in_ball field_differentiable_within_open)
   537 
   538 lemma analytic_on_subset: "f analytic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f analytic_on t"
   539   by (auto simp: analytic_on_def)
   540 
   541 lemma analytic_on_Un: "f analytic_on (s \<union> t) \<longleftrightarrow> f analytic_on s \<and> f analytic_on t"
   542   by (auto simp: analytic_on_def)
   543 
   544 lemma analytic_on_Union: "f analytic_on (\<Union>s) \<longleftrightarrow> (\<forall>t \<in> s. f analytic_on t)"
   545   by (auto simp: analytic_on_def)
   546 
   547 lemma analytic_on_UN: "f analytic_on (\<Union>i\<in>I. s i) \<longleftrightarrow> (\<forall>i\<in>I. f analytic_on (s i))"
   548   by (auto simp: analytic_on_def)
   549 
   550 lemma analytic_on_holomorphic:
   551   "f analytic_on s \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f holomorphic_on t)"
   552   (is "?lhs = ?rhs")
   553 proof -
   554   have "?lhs \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t)"
   555   proof safe
   556     assume "f analytic_on s"
   557     then show "\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t"
   558       apply (simp add: analytic_on_def)
   559       apply (rule exI [where x="\<Union>{u. open u \<and> f analytic_on u}"], auto)
   560       apply (metis open_ball analytic_on_open centre_in_ball)
   561       by (metis analytic_on_def)
   562   next
   563     fix t
   564     assume "open t" "s \<subseteq> t" "f analytic_on t"
   565     then show "f analytic_on s"
   566         by (metis analytic_on_subset)
   567   qed
   568   also have "... \<longleftrightarrow> ?rhs"
   569     by (auto simp: analytic_on_open)
   570   finally show ?thesis .
   571 qed
   572 
   573 lemma analytic_on_linear [analytic_intros,simp]: "(( * ) c) analytic_on s"
   574   by (auto simp add: analytic_on_holomorphic)
   575 
   576 lemma analytic_on_const [analytic_intros,simp]: "(\<lambda>z. c) analytic_on s"
   577   by (metis analytic_on_def holomorphic_on_const zero_less_one)
   578 
   579 lemma analytic_on_ident [analytic_intros,simp]: "(\<lambda>x. x) analytic_on s"
   580   by (simp add: analytic_on_def gt_ex)
   581 
   582 lemma analytic_on_id [analytic_intros]: "id analytic_on s"
   583   unfolding id_def by (rule analytic_on_ident)
   584 
   585 lemma analytic_on_compose:
   586   assumes f: "f analytic_on s"
   587       and g: "g analytic_on (f ` s)"
   588     shows "(g o f) analytic_on s"
   589 unfolding analytic_on_def
   590 proof (intro ballI)
   591   fix x
   592   assume x: "x \<in> s"
   593   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball x e" using f
   594     by (metis analytic_on_def)
   595   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball (f x) e'" using g
   596     by (metis analytic_on_def g image_eqI x)
   597   have "isCont f x"
   598     by (metis analytic_on_imp_differentiable_at field_differentiable_imp_continuous_at f x)
   599   with e' obtain d where d: "0 < d" and fd: "f ` ball x d \<subseteq> ball (f x) e'"
   600      by (auto simp: continuous_at_ball)
   601   have "g \<circ> f holomorphic_on ball x (min d e)"
   602     apply (rule holomorphic_on_compose)
   603     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   604     by (metis fd gh holomorphic_on_subset image_mono min.cobounded1 subset_ball)
   605   then show "\<exists>e>0. g \<circ> f holomorphic_on ball x e"
   606     by (metis d e min_less_iff_conj)
   607 qed
   608 
   609 lemma analytic_on_compose_gen:
   610   "f analytic_on s \<Longrightarrow> g analytic_on t \<Longrightarrow> (\<And>z. z \<in> s \<Longrightarrow> f z \<in> t)
   611              \<Longrightarrow> g o f analytic_on s"
   612 by (metis analytic_on_compose analytic_on_subset image_subset_iff)
   613 
   614 lemma analytic_on_neg [analytic_intros]:
   615   "f analytic_on s \<Longrightarrow> (\<lambda>z. -(f z)) analytic_on s"
   616 by (metis analytic_on_holomorphic holomorphic_on_minus)
   617 
   618 lemma analytic_on_add [analytic_intros]:
   619   assumes f: "f analytic_on s"
   620       and g: "g analytic_on s"
   621     shows "(\<lambda>z. f z + g z) analytic_on s"
   622 unfolding analytic_on_def
   623 proof (intro ballI)
   624   fix z
   625   assume z: "z \<in> s"
   626   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   627     by (metis analytic_on_def)
   628   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   629     by (metis analytic_on_def g z)
   630   have "(\<lambda>z. f z + g z) holomorphic_on ball z (min e e')"
   631     apply (rule holomorphic_on_add)
   632     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   633     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   634   then show "\<exists>e>0. (\<lambda>z. f z + g z) holomorphic_on ball z e"
   635     by (metis e e' min_less_iff_conj)
   636 qed
   637 
   638 lemma analytic_on_diff [analytic_intros]:
   639   assumes f: "f analytic_on s"
   640       and g: "g analytic_on s"
   641     shows "(\<lambda>z. f z - g z) analytic_on s"
   642 unfolding analytic_on_def
   643 proof (intro ballI)
   644   fix z
   645   assume z: "z \<in> s"
   646   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   647     by (metis analytic_on_def)
   648   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   649     by (metis analytic_on_def g z)
   650   have "(\<lambda>z. f z - g z) holomorphic_on ball z (min e e')"
   651     apply (rule holomorphic_on_diff)
   652     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   653     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   654   then show "\<exists>e>0. (\<lambda>z. f z - g z) holomorphic_on ball z e"
   655     by (metis e e' min_less_iff_conj)
   656 qed
   657 
   658 lemma analytic_on_mult [analytic_intros]:
   659   assumes f: "f analytic_on s"
   660       and g: "g analytic_on s"
   661     shows "(\<lambda>z. f z * g z) analytic_on s"
   662 unfolding analytic_on_def
   663 proof (intro ballI)
   664   fix z
   665   assume z: "z \<in> s"
   666   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   667     by (metis analytic_on_def)
   668   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   669     by (metis analytic_on_def g z)
   670   have "(\<lambda>z. f z * g z) holomorphic_on ball z (min e e')"
   671     apply (rule holomorphic_on_mult)
   672     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   673     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   674   then show "\<exists>e>0. (\<lambda>z. f z * g z) holomorphic_on ball z e"
   675     by (metis e e' min_less_iff_conj)
   676 qed
   677 
   678 lemma analytic_on_inverse [analytic_intros]:
   679   assumes f: "f analytic_on s"
   680       and nz: "(\<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0)"
   681     shows "(\<lambda>z. inverse (f z)) analytic_on s"
   682 unfolding analytic_on_def
   683 proof (intro ballI)
   684   fix z
   685   assume z: "z \<in> s"
   686   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   687     by (metis analytic_on_def)
   688   have "continuous_on (ball z e) f"
   689     by (metis fh holomorphic_on_imp_continuous_on)
   690   then obtain e' where e': "0 < e'" and nz': "\<And>y. dist z y < e' \<Longrightarrow> f y \<noteq> 0"
   691     by (metis open_ball centre_in_ball continuous_on_open_avoid e z nz)
   692   have "(\<lambda>z. inverse (f z)) holomorphic_on ball z (min e e')"
   693     apply (rule holomorphic_on_inverse)
   694     apply (metis fh holomorphic_on_subset min.cobounded2 min.commute subset_ball)
   695     by (metis nz' mem_ball min_less_iff_conj)
   696   then show "\<exists>e>0. (\<lambda>z. inverse (f z)) holomorphic_on ball z e"
   697     by (metis e e' min_less_iff_conj)
   698 qed
   699 
   700 lemma analytic_on_divide [analytic_intros]:
   701   assumes f: "f analytic_on s"
   702       and g: "g analytic_on s"
   703       and nz: "(\<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0)"
   704     shows "(\<lambda>z. f z / g z) analytic_on s"
   705 unfolding divide_inverse
   706 by (metis analytic_on_inverse analytic_on_mult f g nz)
   707 
   708 lemma analytic_on_power [analytic_intros]:
   709   "f analytic_on s \<Longrightarrow> (\<lambda>z. (f z) ^ n) analytic_on s"
   710 by (induct n) (auto simp: analytic_on_mult)
   711 
   712 lemma analytic_on_sum [analytic_intros]:
   713   "(\<And>i. i \<in> I \<Longrightarrow> (f i) analytic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) analytic_on s"
   714   by (induct I rule: infinite_finite_induct) (auto simp: analytic_on_const analytic_on_add)
   715 
   716 lemma deriv_left_inverse:
   717   assumes "f holomorphic_on S" and "g holomorphic_on T"
   718       and "open S" and "open T"
   719       and "f ` S \<subseteq> T"
   720       and [simp]: "\<And>z. z \<in> S \<Longrightarrow> g (f z) = z"
   721       and "w \<in> S"
   722     shows "deriv f w * deriv g (f w) = 1"
   723 proof -
   724   have "deriv f w * deriv g (f w) = deriv g (f w) * deriv f w"
   725     by (simp add: algebra_simps)
   726   also have "... = deriv (g o f) w"
   727     using assms
   728     by (metis analytic_on_imp_differentiable_at analytic_on_open complex_derivative_chain image_subset_iff)
   729   also have "... = deriv id w"
   730     apply (rule complex_derivative_transform_within_open [where s=S])
   731     apply (rule assms holomorphic_on_compose_gen holomorphic_intros)+
   732     apply simp
   733     done
   734   also have "... = 1"
   735     by simp
   736   finally show ?thesis .
   737 qed
   738 
   739 subsection\<open>analyticity at a point\<close>
   740 
   741 lemma analytic_at_ball:
   742   "f analytic_on {z} \<longleftrightarrow> (\<exists>e. 0<e \<and> f holomorphic_on ball z e)"
   743 by (metis analytic_on_def singleton_iff)
   744 
   745 lemma analytic_at:
   746     "f analytic_on {z} \<longleftrightarrow> (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s)"
   747 by (metis analytic_on_holomorphic empty_subsetI insert_subset)
   748 
   749 lemma analytic_on_analytic_at:
   750     "f analytic_on s \<longleftrightarrow> (\<forall>z \<in> s. f analytic_on {z})"
   751 by (metis analytic_at_ball analytic_on_def)
   752 
   753 lemma analytic_at_two:
   754   "f analytic_on {z} \<and> g analytic_on {z} \<longleftrightarrow>
   755    (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s \<and> g holomorphic_on s)"
   756   (is "?lhs = ?rhs")
   757 proof
   758   assume ?lhs
   759   then obtain s t
   760     where st: "open s" "z \<in> s" "f holomorphic_on s"
   761               "open t" "z \<in> t" "g holomorphic_on t"
   762     by (auto simp: analytic_at)
   763   show ?rhs
   764     apply (rule_tac x="s \<inter> t" in exI)
   765     using st
   766     apply (auto simp: Diff_subset holomorphic_on_subset)
   767     done
   768 next
   769   assume ?rhs
   770   then show ?lhs
   771     by (force simp add: analytic_at)
   772 qed
   773 
   774 subsection\<open>Combining theorems for derivative with ``analytic at'' hypotheses\<close>
   775 
   776 lemma
   777   assumes "f analytic_on {z}" "g analytic_on {z}"
   778   shows complex_derivative_add_at: "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   779     and complex_derivative_diff_at: "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   780     and complex_derivative_mult_at: "deriv (\<lambda>w. f w * g w) z =
   781            f z * deriv g z + deriv f z * g z"
   782 proof -
   783   obtain s where s: "open s" "z \<in> s" "f holomorphic_on s" "g holomorphic_on s"
   784     using assms by (metis analytic_at_two)
   785   show "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   786     apply (rule DERIV_imp_deriv [OF DERIV_add])
   787     using s
   788     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   789     done
   790   show "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   791     apply (rule DERIV_imp_deriv [OF DERIV_diff])
   792     using s
   793     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   794     done
   795   show "deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   796     apply (rule DERIV_imp_deriv [OF DERIV_mult'])
   797     using s
   798     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   799     done
   800 qed
   801 
   802 lemma deriv_cmult_at:
   803   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. c * f w) z = c * deriv f z"
   804 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   805 
   806 lemma deriv_cmult_right_at:
   807   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. f w * c) z = deriv f z * c"
   808 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   809 
   810 subsection\<open>Complex differentiation of sequences and series\<close>
   811 
   812 (* TODO: Could probably be simplified using Uniform_Limit *)
   813 lemma has_complex_derivative_sequence:
   814   fixes s :: "complex set"
   815   assumes cvs: "convex s"
   816       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   817       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s \<longrightarrow> norm (f' n x - g' x) \<le> e"
   818       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   819     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) \<longlongrightarrow> g x) sequentially \<and>
   820                        (g has_field_derivative (g' x)) (at x within s)"
   821 proof -
   822   from assms obtain x l where x: "x \<in> s" and tf: "((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   823     by blast
   824   { fix e::real assume e: "e > 0"
   825     then obtain N where N: "\<forall>n\<ge>N. \<forall>x. x \<in> s \<longrightarrow> cmod (f' n x - g' x) \<le> e"
   826       by (metis conv)
   827     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   828     proof (rule exI [of _ N], clarify)
   829       fix n y h
   830       assume "N \<le> n" "y \<in> s"
   831       then have "cmod (f' n y - g' y) \<le> e"
   832         by (metis N)
   833       then have "cmod h * cmod (f' n y - g' y) \<le> cmod h * e"
   834         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   835       then show "cmod (f' n y * h - g' y * h) \<le> e * cmod h"
   836         by (simp add: norm_mult [symmetric] field_simps)
   837     qed
   838   } note ** = this
   839   show ?thesis
   840   unfolding has_field_derivative_def
   841   proof (rule has_derivative_sequence [OF cvs _ _ x])
   842     show "\<forall>n. \<forall>x\<in>s. (f n has_derivative (( * ) (f' n x))) (at x within s)"
   843       by (metis has_field_derivative_def df)
   844   next show "(\<lambda>n. f n x) \<longlonglongrightarrow> l"
   845     by (rule tf)
   846   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   847     by (blast intro: **)
   848   qed
   849 qed
   850 
   851 lemma has_complex_derivative_series:
   852   fixes s :: "complex set"
   853   assumes cvs: "convex s"
   854       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   855       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   856                 \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   857       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) sums l)"
   858     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) sums g x) \<and> ((g has_field_derivative g' x) (at x within s))"
   859 proof -
   860   from assms obtain x l where x: "x \<in> s" and sf: "((\<lambda>n. f n x) sums l)"
   861     by blast
   862   { fix e::real assume e: "e > 0"
   863     then obtain N where N: "\<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   864             \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   865       by (metis conv)
   866     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   867     proof (rule exI [of _ N], clarify)
   868       fix n y h
   869       assume "N \<le> n" "y \<in> s"
   870       then have "cmod ((\<Sum>i<n. f' i y) - g' y) \<le> e"
   871         by (metis N)
   872       then have "cmod h * cmod ((\<Sum>i<n. f' i y) - g' y) \<le> cmod h * e"
   873         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   874       then show "cmod ((\<Sum>i<n. h * f' i y) - g' y * h) \<le> e * cmod h"
   875         by (simp add: norm_mult [symmetric] field_simps sum_distrib_left)
   876     qed
   877   } note ** = this
   878   show ?thesis
   879   unfolding has_field_derivative_def
   880   proof (rule has_derivative_series [OF cvs _ _ x])
   881     fix n x
   882     assume "x \<in> s"
   883     then show "((f n) has_derivative (\<lambda>z. z * f' n x)) (at x within s)"
   884       by (metis df has_field_derivative_def mult_commute_abs)
   885   next show " ((\<lambda>n. f n x) sums l)"
   886     by (rule sf)
   887   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   888     by (blast intro: **)
   889   qed
   890 qed
   891 
   892 
   893 lemma field_differentiable_series:
   894   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach} \<Rightarrow> 'a"
   895   assumes "convex s" "open s"
   896   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   897   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   898   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)" and x: "x \<in> s"
   899   shows   "summable (\<lambda>n. f n x)" and "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)"
   900 proof -
   901   from assms(4) obtain g' where A: "uniform_limit s (\<lambda>n x. \<Sum>i<n. f' i x) g' sequentially"
   902     unfolding uniformly_convergent_on_def by blast
   903   from x and \<open>open s\<close> have s: "at x within s = at x" by (rule at_within_open)
   904   have "\<exists>g. \<forall>x\<in>s. (\<lambda>n. f n x) sums g x \<and> (g has_field_derivative g' x) (at x within s)"
   905     by (intro has_field_derivative_series[of s f f' g' x0] assms A has_field_derivative_at_within)
   906   then obtain g where g: "\<And>x. x \<in> s \<Longrightarrow> (\<lambda>n. f n x) sums g x"
   907     "\<And>x. x \<in> s \<Longrightarrow> (g has_field_derivative g' x) (at x within s)" by blast
   908   from g[OF x] show "summable (\<lambda>n. f n x)" by (auto simp: summable_def)
   909   from g(2)[OF x] have g': "(g has_derivative ( * ) (g' x)) (at x)"
   910     by (simp add: has_field_derivative_def s)
   911   have "((\<lambda>x. \<Sum>n. f n x) has_derivative ( * ) (g' x)) (at x)"
   912     by (rule has_derivative_transform_within_open[OF g' \<open>open s\<close> x])
   913        (insert g, auto simp: sums_iff)
   914   thus "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)" unfolding differentiable_def
   915     by (auto simp: summable_def field_differentiable_def has_field_derivative_def)
   916 qed
   917 
   918 lemma field_differentiable_series':
   919   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach} \<Rightarrow> 'a"
   920   assumes "convex s" "open s"
   921   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   922   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   923   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)"
   924   shows   "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x0)"
   925   using field_differentiable_series[OF assms, of x0] \<open>x0 \<in> s\<close> by blast+
   926 
   927 subsection\<open>Bound theorem\<close>
   928 
   929 lemma field_differentiable_bound:
   930   fixes s :: "'a::real_normed_field set"
   931   assumes cvs: "convex s"
   932       and df:  "\<And>z. z \<in> s \<Longrightarrow> (f has_field_derivative f' z) (at z within s)"
   933       and dn:  "\<And>z. z \<in> s \<Longrightarrow> norm (f' z) \<le> B"
   934       and "x \<in> s"  "y \<in> s"
   935     shows "norm(f x - f y) \<le> B * norm(x - y)"
   936   apply (rule differentiable_bound [OF cvs])
   937   apply (rule ballI, erule df [unfolded has_field_derivative_def])
   938   apply (rule ballI, rule onorm_le, simp add: norm_mult mult_right_mono dn)
   939   apply fact
   940   apply fact
   941   done
   942 
   943 subsection\<open>Inverse function theorem for complex derivatives\<close>
   944 
   945 lemma has_field_derivative_inverse_basic:
   946   shows "DERIV f (g y) :> f' \<Longrightarrow>
   947         f' \<noteq> 0 \<Longrightarrow>
   948         continuous (at y) g \<Longrightarrow>
   949         open t \<Longrightarrow>
   950         y \<in> t \<Longrightarrow>
   951         (\<And>z. z \<in> t \<Longrightarrow> f (g z) = z)
   952         \<Longrightarrow> DERIV g y :> inverse (f')"
   953   unfolding has_field_derivative_def
   954   apply (rule has_derivative_inverse_basic)
   955   apply (auto simp:  bounded_linear_mult_right)
   956   done
   957 
   958 lemmas has_complex_derivative_inverse_basic = has_field_derivative_inverse_basic
   959 
   960 lemma has_field_derivative_inverse_strong:
   961   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   962   shows "DERIV f x :> f' \<Longrightarrow>
   963          f' \<noteq> 0 \<Longrightarrow>
   964          open s \<Longrightarrow>
   965          x \<in> s \<Longrightarrow>
   966          continuous_on s f \<Longrightarrow>
   967          (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   968          \<Longrightarrow> DERIV g (f x) :> inverse (f')"
   969   unfolding has_field_derivative_def
   970   apply (rule has_derivative_inverse_strong [of s x f g ])
   971   by auto
   972 lemmas has_complex_derivative_inverse_strong = has_field_derivative_inverse_strong
   973 
   974 lemma has_field_derivative_inverse_strong_x:
   975   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   976   shows  "DERIV f (g y) :> f' \<Longrightarrow>
   977           f' \<noteq> 0 \<Longrightarrow>
   978           open s \<Longrightarrow>
   979           continuous_on s f \<Longrightarrow>
   980           g y \<in> s \<Longrightarrow> f(g y) = y \<Longrightarrow>
   981           (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   982           \<Longrightarrow> DERIV g y :> inverse (f')"
   983   unfolding has_field_derivative_def
   984   apply (rule has_derivative_inverse_strong_x [of s g y f])
   985   by auto
   986 lemmas has_complex_derivative_inverse_strong_x = has_field_derivative_inverse_strong_x
   987 
   988 subsection \<open>Taylor on Complex Numbers\<close>
   989 
   990 lemma sum_Suc_reindex:
   991   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   992     shows  "sum f {0..n} = f 0 - f (Suc n) + sum (\<lambda>i. f (Suc i)) {0..n}"
   993 by (induct n) auto
   994 
   995 lemma field_taylor:
   996   assumes s: "convex s"
   997       and f: "\<And>i x. x \<in> s \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within s)"
   998       and B: "\<And>x. x \<in> s \<Longrightarrow> norm (f (Suc n) x) \<le> B"
   999       and w: "w \<in> s"
  1000       and z: "z \<in> s"
  1001     shows "norm(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
  1002           \<le> B * norm(z - w)^(Suc n) / fact n"
  1003 proof -
  1004   have wzs: "closed_segment w z \<subseteq> s" using assms
  1005     by (metis convex_contains_segment)
  1006   { fix u
  1007     assume "u \<in> closed_segment w z"
  1008     then have "u \<in> s"
  1009       by (metis wzs subsetD)
  1010     have "(\<Sum>i\<le>n. f i u * (- of_nat i * (z-u)^(i - 1)) / (fact i) +
  1011                       f (Suc i) u * (z-u)^i / (fact i)) =
  1012               f (Suc n) u * (z-u) ^ n / (fact n)"
  1013     proof (induction n)
  1014       case 0 show ?case by simp
  1015     next
  1016       case (Suc n)
  1017       have "(\<Sum>i\<le>Suc n. f i u * (- of_nat i * (z-u) ^ (i - 1)) / (fact i) +
  1018                              f (Suc i) u * (z-u) ^ i / (fact i)) =
  1019            f (Suc n) u * (z-u) ^ n / (fact n) +
  1020            f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n) / (fact (Suc n)) -
  1021            f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n) / (fact (Suc n))"
  1022         using Suc by simp
  1023       also have "... = f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n))"
  1024       proof -
  1025         have "(fact(Suc n)) *
  1026              (f(Suc n) u *(z-u) ^ n / (fact n) +
  1027                f(Suc(Suc n)) u *((z-u) *(z-u) ^ n) / (fact(Suc n)) -
  1028                f(Suc n) u *((1 + of_nat n) *(z-u) ^ n) / (fact(Suc n))) =
  1029             ((fact(Suc n)) *(f(Suc n) u *(z-u) ^ n)) / (fact n) +
  1030             ((fact(Suc n)) *(f(Suc(Suc n)) u *((z-u) *(z-u) ^ n)) / (fact(Suc n))) -
  1031             ((fact(Suc n)) *(f(Suc n) u *(of_nat(Suc n) *(z-u) ^ n))) / (fact(Suc n))"
  1032           by (simp add: algebra_simps del: fact_Suc)
  1033         also have "... = ((fact (Suc n)) * (f (Suc n) u * (z-u) ^ n)) / (fact n) +
  1034                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1035                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1036           by (simp del: fact_Suc)
  1037         also have "... = (of_nat (Suc n) * (f (Suc n) u * (z-u) ^ n)) +
  1038                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1039                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1040           by (simp only: fact_Suc of_nat_mult ac_simps) simp
  1041         also have "... = f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)"
  1042           by (simp add: algebra_simps)
  1043         finally show ?thesis
  1044         by (simp add: mult_left_cancel [where c = "(fact (Suc n))", THEN iffD1] del: fact_Suc)
  1045       qed
  1046       finally show ?case .
  1047     qed
  1048     then have "((\<lambda>v. (\<Sum>i\<le>n. f i v * (z - v)^i / (fact i)))
  1049                 has_field_derivative f (Suc n) u * (z-u) ^ n / (fact n))
  1050                (at u within s)"
  1051       apply (intro derivative_eq_intros)
  1052       apply (blast intro: assms \<open>u \<in> s\<close>)
  1053       apply (rule refl)+
  1054       apply (auto simp: field_simps)
  1055       done
  1056   } note sum_deriv = this
  1057   { fix u
  1058     assume u: "u \<in> closed_segment w z"
  1059     then have us: "u \<in> s"
  1060       by (metis wzs subsetD)
  1061     have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> norm (f (Suc n) u) * norm (u - z) ^ n"
  1062       by (metis norm_minus_commute order_refl)
  1063     also have "... \<le> norm (f (Suc n) u) * norm (z - w) ^ n"
  1064       by (metis mult_left_mono norm_ge_zero power_mono segment_bound [OF u])
  1065     also have "... \<le> B * norm (z - w) ^ n"
  1066       by (metis norm_ge_zero zero_le_power mult_right_mono  B [OF us])
  1067     finally have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> B * norm (z - w) ^ n" .
  1068   } note cmod_bound = this
  1069   have "(\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)) = (\<Sum>i\<le>n. (f i z / (fact i)) * 0 ^ i)"
  1070     by simp
  1071   also have "\<dots> = f 0 z / (fact 0)"
  1072     by (subst sum_zero_power) simp
  1073   finally have "norm (f 0 z - (\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)))
  1074                 \<le> norm ((\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)) -
  1075                         (\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)))"
  1076     by (simp add: norm_minus_commute)
  1077   also have "... \<le> B * norm (z - w) ^ n / (fact n) * norm (w - z)"
  1078     apply (rule field_differentiable_bound
  1079       [where f' = "\<lambda>w. f (Suc n) w * (z - w)^n / (fact n)"
  1080          and s = "closed_segment w z", OF convex_closed_segment])
  1081     apply (auto simp: ends_in_segment DERIV_subset [OF sum_deriv wzs]
  1082                   norm_divide norm_mult norm_power divide_le_cancel cmod_bound)
  1083     done
  1084   also have "...  \<le> B * norm (z - w) ^ Suc n / (fact n)"
  1085     by (simp add: algebra_simps norm_minus_commute)
  1086   finally show ?thesis .
  1087 qed
  1088 
  1089 lemma complex_taylor:
  1090   assumes s: "convex s"
  1091       and f: "\<And>i x. x \<in> s \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within s)"
  1092       and B: "\<And>x. x \<in> s \<Longrightarrow> cmod (f (Suc n) x) \<le> B"
  1093       and w: "w \<in> s"
  1094       and z: "z \<in> s"
  1095     shows "cmod(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
  1096           \<le> B * cmod(z - w)^(Suc n) / fact n"
  1097   using assms by (rule field_taylor)
  1098 
  1099 
  1100 text\<open>Something more like the traditional MVT for real components\<close>
  1101 
  1102 lemma complex_mvt_line:
  1103   assumes "\<And>u. u \<in> closed_segment w z \<Longrightarrow> (f has_field_derivative f'(u)) (at u)"
  1104     shows "\<exists>u. u \<in> closed_segment w z \<and> Re(f z) - Re(f w) = Re(f'(u) * (z - w))"
  1105 proof -
  1106   have twz: "\<And>t. (1 - t) *\<^sub>R w + t *\<^sub>R z = w + t *\<^sub>R (z - w)"
  1107     by (simp add: real_vector.scale_left_diff_distrib real_vector.scale_right_diff_distrib)
  1108   note assms[unfolded has_field_derivative_def, derivative_intros]
  1109   show ?thesis
  1110     apply (cut_tac mvt_simple
  1111                      [of 0 1 "Re o f o (\<lambda>t. (1 - t) *\<^sub>R w +  t *\<^sub>R z)"
  1112                       "\<lambda>u. Re o (\<lambda>h. f'((1 - u) *\<^sub>R w + u *\<^sub>R z) * h) o (\<lambda>t. t *\<^sub>R (z - w))"])
  1113     apply auto
  1114     apply (rule_tac x="(1 - x) *\<^sub>R w + x *\<^sub>R z" in exI)
  1115     apply (auto simp: closed_segment_def twz) []
  1116     apply (intro derivative_eq_intros has_derivative_at_within, simp_all)
  1117     apply (simp add: fun_eq_iff real_vector.scale_right_diff_distrib)
  1118     apply (force simp: twz closed_segment_def)
  1119     done
  1120 qed
  1121 
  1122 lemma complex_taylor_mvt:
  1123   assumes "\<And>i x. \<lbrakk>x \<in> closed_segment w z; i \<le> n\<rbrakk> \<Longrightarrow> ((f i) has_field_derivative f (Suc i) x) (at x)"
  1124     shows "\<exists>u. u \<in> closed_segment w z \<and>
  1125             Re (f 0 z) =
  1126             Re ((\<Sum>i = 0..n. f i w * (z - w) ^ i / (fact i)) +
  1127                 (f (Suc n) u * (z-u)^n / (fact n)) * (z - w))"
  1128 proof -
  1129   { fix u
  1130     assume u: "u \<in> closed_segment w z"
  1131     have "(\<Sum>i = 0..n.
  1132                (f (Suc i) u * (z-u) ^ i - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) /
  1133                (fact i)) =
  1134           f (Suc 0) u -
  1135              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1136              (fact (Suc n)) +
  1137              (\<Sum>i = 0..n.
  1138                  (f (Suc (Suc i)) u * ((z-u) ^ Suc i) - of_nat (Suc i) * (f (Suc i) u * (z-u) ^ i)) /
  1139                  (fact (Suc i)))"
  1140        by (subst sum_Suc_reindex) simp
  1141     also have "... = f (Suc 0) u -
  1142              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1143              (fact (Suc n)) +
  1144              (\<Sum>i = 0..n.
  1145                  f (Suc (Suc i)) u * ((z-u) ^ Suc i) / (fact (Suc i))  -
  1146                  f (Suc i) u * (z-u) ^ i / (fact i))"
  1147       by (simp only: diff_divide_distrib fact_cancel ac_simps)
  1148     also have "... = f (Suc 0) u -
  1149              (f (Suc (Suc n)) u * (z-u) ^ Suc n - of_nat (Suc n) * (z-u) ^ n * f (Suc n) u) /
  1150              (fact (Suc n)) +
  1151              f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n)) - f (Suc 0) u"
  1152       by (subst sum_Suc_diff) auto
  1153     also have "... = f (Suc n) u * (z-u) ^ n / (fact n)"
  1154       by (simp only: algebra_simps diff_divide_distrib fact_cancel)
  1155     finally have "(\<Sum>i = 0..n. (f (Suc i) u * (z - u) ^ i
  1156                              - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) / (fact i)) =
  1157                   f (Suc n) u * (z - u) ^ n / (fact n)" .
  1158     then have "((\<lambda>u. \<Sum>i = 0..n. f i u * (z - u) ^ i / (fact i)) has_field_derivative
  1159                 f (Suc n) u * (z - u) ^ n / (fact n))  (at u)"
  1160       apply (intro derivative_eq_intros)+
  1161       apply (force intro: u assms)
  1162       apply (rule refl)+
  1163       apply (auto simp: ac_simps)
  1164       done
  1165   }
  1166   then show ?thesis
  1167     apply (cut_tac complex_mvt_line [of w z "\<lambda>u. \<Sum>i = 0..n. f i u * (z-u) ^ i / (fact i)"
  1168                "\<lambda>u. (f (Suc n) u * (z-u)^n / (fact n))"])
  1169     apply (auto simp add: intro: open_closed_segment)
  1170     done
  1171 qed
  1172 
  1173 
  1174 subsection \<open>Polynomal function extremal theorem, from HOL Light\<close>
  1175 
  1176 lemma polyfun_extremal_lemma: (*COMPLEX_POLYFUN_EXTREMAL_LEMMA in HOL Light*)
  1177     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1178   assumes "0 < e"
  1179     shows "\<exists>M. \<forall>z. M \<le> norm(z) \<longrightarrow> norm (\<Sum>i\<le>n. c(i) * z^i) \<le> e * norm(z) ^ (Suc n)"
  1180 proof (induct n)
  1181   case 0 with assms
  1182   show ?case
  1183     apply (rule_tac x="norm (c 0) / e" in exI)
  1184     apply (auto simp: field_simps)
  1185     done
  1186 next
  1187   case (Suc n)
  1188   obtain M where M: "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1189     using Suc assms by blast
  1190   show ?case
  1191   proof (rule exI [where x= "max M (1 + norm(c(Suc n)) / e)"], clarsimp simp del: power_Suc)
  1192     fix z::'a
  1193     assume z1: "M \<le> norm z" and "1 + norm (c (Suc n)) / e \<le> norm z"
  1194     then have z2: "e + norm (c (Suc n)) \<le> e * norm z"
  1195       using assms by (simp add: field_simps)
  1196     have "norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1197       using M [OF z1] by simp
  1198     then have "norm (\<Sum>i\<le>n. c i * z^i) + norm (c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1199       by simp
  1200     then have "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1201       by (blast intro: norm_triangle_le elim: )
  1202     also have "... \<le> (e + norm (c (Suc n))) * norm z ^ Suc n"
  1203       by (simp add: norm_power norm_mult algebra_simps)
  1204     also have "... \<le> (e * norm z) * norm z ^ Suc n"
  1205       by (metis z2 mult.commute mult_left_mono norm_ge_zero norm_power)
  1206     finally show "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc (Suc n)"
  1207       by simp
  1208   qed
  1209 qed
  1210 
  1211 lemma polyfun_extremal: (*COMPLEX_POLYFUN_EXTREMAL in HOL Light*)
  1212     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1213   assumes k: "c k \<noteq> 0" "1\<le>k" and kn: "k\<le>n"
  1214     shows "eventually (\<lambda>z. norm (\<Sum>i\<le>n. c(i) * z^i) \<ge> B) at_infinity"
  1215 using kn
  1216 proof (induction n)
  1217   case 0
  1218   then show ?case
  1219     using k  by simp
  1220 next
  1221   case (Suc m)
  1222   let ?even = ?case
  1223   show ?even
  1224   proof (cases "c (Suc m) = 0")
  1225     case True
  1226     then show ?even using Suc k
  1227       by auto (metis antisym_conv less_eq_Suc_le not_le)
  1228   next
  1229     case False
  1230     then obtain M where M:
  1231           "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>m. c i * z^i) \<le> norm (c (Suc m)) / 2 * norm z ^ Suc m"
  1232       using polyfun_extremal_lemma [of "norm(c (Suc m)) / 2" c m] Suc
  1233       by auto
  1234     have "\<exists>b. \<forall>z. b \<le> norm z \<longrightarrow> B \<le> norm (\<Sum>i\<le>Suc m. c i * z^i)"
  1235     proof (rule exI [where x="max M (max 1 (\<bar>B\<bar> / (norm(c (Suc m)) / 2)))"], clarsimp simp del: power_Suc)
  1236       fix z::'a
  1237       assume z1: "M \<le> norm z" "1 \<le> norm z"
  1238          and "\<bar>B\<bar> * 2 / norm (c (Suc m)) \<le> norm z"
  1239       then have z2: "\<bar>B\<bar> \<le> norm (c (Suc m)) * norm z / 2"
  1240         using False by (simp add: field_simps)
  1241       have nz: "norm z \<le> norm z ^ Suc m"
  1242         by (metis \<open>1 \<le> norm z\<close> One_nat_def less_eq_Suc_le power_increasing power_one_right zero_less_Suc)
  1243       have *: "\<And>y x. norm (c (Suc m)) * norm z / 2 \<le> norm y - norm x \<Longrightarrow> B \<le> norm (x + y)"
  1244         by (metis abs_le_iff add.commute norm_diff_ineq order_trans z2)
  1245       have "norm z * norm (c (Suc m)) + 2 * norm (\<Sum>i\<le>m. c i * z^i)
  1246             \<le> norm (c (Suc m)) * norm z + norm (c (Suc m)) * norm z ^ Suc m"
  1247         using M [of z] Suc z1  by auto
  1248       also have "... \<le> 2 * (norm (c (Suc m)) * norm z ^ Suc m)"
  1249         using nz by (simp add: mult_mono del: power_Suc)
  1250       finally show "B \<le> norm ((\<Sum>i\<le>m. c i * z^i) + c (Suc m) * z ^ Suc m)"
  1251         using Suc.IH
  1252         apply (auto simp: eventually_at_infinity)
  1253         apply (rule *)
  1254         apply (simp add: field_simps norm_mult norm_power)
  1255         done
  1256     qed
  1257     then show ?even
  1258       by (simp add: eventually_at_infinity)
  1259   qed
  1260 qed
  1261 
  1262 end