src/HOL/Complex.thy
 author wenzelm Mon Apr 25 16:09:26 2016 +0200 (2016-04-25) changeset 63040 eb4ddd18d635 parent 62620 d21dab28b3f9 child 63114 27afe7af7379 permissions -rw-r--r--
eliminated old 'def';
     1 (*  Title:       HOL/Complex.thy

     2     Author:      Jacques D. Fleuriot

     3     Copyright:   2001 University of Edinburgh

     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4

     5 *)

     6

     7 section \<open>Complex Numbers: Rectangular and Polar Representations\<close>

     8

     9 theory Complex

    10 imports Transcendental

    11 begin

    12

    13 text \<open>

    14 We use the \<open>codatatype\<close> command to define the type of complex numbers. This allows us to use

    15 \<open>primcorec\<close> to define complex functions by defining their real and imaginary result

    16 separately.

    17 \<close>

    18

    19 codatatype complex = Complex (Re: real) (Im: real)

    20

    21 lemma complex_surj: "Complex (Re z) (Im z) = z"

    22   by (rule complex.collapse)

    23

    24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"

    25   by (rule complex.expand) simp

    26

    27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"

    28   by (auto intro: complex.expand)

    29

    30 subsection \<open>Addition and Subtraction\<close>

    31

    32 instantiation complex :: ab_group_add

    33 begin

    34

    35 primcorec zero_complex where

    36   "Re 0 = 0"

    37 | "Im 0 = 0"

    38

    39 primcorec plus_complex where

    40   "Re (x + y) = Re x + Re y"

    41 | "Im (x + y) = Im x + Im y"

    42

    43 primcorec uminus_complex where

    44   "Re (- x) = - Re x"

    45 | "Im (- x) = - Im x"

    46

    47 primcorec minus_complex where

    48   "Re (x - y) = Re x - Re y"

    49 | "Im (x - y) = Im x - Im y"

    50

    51 instance

    52   by intro_classes (simp_all add: complex_eq_iff)

    53

    54 end

    55

    56 subsection \<open>Multiplication and Division\<close>

    57

    58 instantiation complex :: field

    59 begin

    60

    61 primcorec one_complex where

    62   "Re 1 = 1"

    63 | "Im 1 = 0"

    64

    65 primcorec times_complex where

    66   "Re (x * y) = Re x * Re y - Im x * Im y"

    67 | "Im (x * y) = Re x * Im y + Im x * Re y"

    68

    69 primcorec inverse_complex where

    70   "Re (inverse x) = Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"

    71 | "Im (inverse x) = - Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"

    72

    73 definition "x div (y::complex) = x * inverse y"

    74

    75 instance

    76   by intro_classes

    77      (simp_all add: complex_eq_iff divide_complex_def

    78       distrib_left distrib_right right_diff_distrib left_diff_distrib

    79       power2_eq_square add_divide_distrib [symmetric])

    80

    81 end

    82

    83 lemma Re_divide: "Re (x / y) = (Re x * Re y + Im x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"

    84   unfolding divide_complex_def by (simp add: add_divide_distrib)

    85

    86 lemma Im_divide: "Im (x / y) = (Im x * Re y - Re x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"

    87   unfolding divide_complex_def times_complex.sel inverse_complex.sel

    88   by (simp_all add: divide_simps)

    89

    90 lemma Re_power2: "Re (x ^ 2) = (Re x)^2 - (Im x)^2"

    91   by (simp add: power2_eq_square)

    92

    93 lemma Im_power2: "Im (x ^ 2) = 2 * Re x * Im x"

    94   by (simp add: power2_eq_square)

    95

    96 lemma Re_power_real [simp]: "Im x = 0 \<Longrightarrow> Re (x ^ n) = Re x ^ n "

    97   by (induct n) simp_all

    98

    99 lemma Im_power_real [simp]: "Im x = 0 \<Longrightarrow> Im (x ^ n) = 0"

   100   by (induct n) simp_all

   101

   102 subsection \<open>Scalar Multiplication\<close>

   103

   104 instantiation complex :: real_field

   105 begin

   106

   107 primcorec scaleR_complex where

   108   "Re (scaleR r x) = r * Re x"

   109 | "Im (scaleR r x) = r * Im x"

   110

   111 instance

   112 proof

   113   fix a b :: real and x y :: complex

   114   show "scaleR a (x + y) = scaleR a x + scaleR a y"

   115     by (simp add: complex_eq_iff distrib_left)

   116   show "scaleR (a + b) x = scaleR a x + scaleR b x"

   117     by (simp add: complex_eq_iff distrib_right)

   118   show "scaleR a (scaleR b x) = scaleR (a * b) x"

   119     by (simp add: complex_eq_iff mult.assoc)

   120   show "scaleR 1 x = x"

   121     by (simp add: complex_eq_iff)

   122   show "scaleR a x * y = scaleR a (x * y)"

   123     by (simp add: complex_eq_iff algebra_simps)

   124   show "x * scaleR a y = scaleR a (x * y)"

   125     by (simp add: complex_eq_iff algebra_simps)

   126 qed

   127

   128 end

   129

   130 subsection \<open>Numerals, Arithmetic, and Embedding from Reals\<close>

   131

   132 abbreviation complex_of_real :: "real \<Rightarrow> complex"

   133   where "complex_of_real \<equiv> of_real"

   134

   135 declare [[coercion "of_real :: real \<Rightarrow> complex"]]

   136 declare [[coercion "of_rat :: rat \<Rightarrow> complex"]]

   137 declare [[coercion "of_int :: int \<Rightarrow> complex"]]

   138 declare [[coercion "of_nat :: nat \<Rightarrow> complex"]]

   139

   140 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"

   141   by (induct n) simp_all

   142

   143 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"

   144   by (induct n) simp_all

   145

   146 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"

   147   by (cases z rule: int_diff_cases) simp

   148

   149 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"

   150   by (cases z rule: int_diff_cases) simp

   151

   152 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"

   153   using complex_Re_of_int [of "numeral v"] by simp

   154

   155 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"

   156   using complex_Im_of_int [of "numeral v"] by simp

   157

   158 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"

   159   by (simp add: of_real_def)

   160

   161 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"

   162   by (simp add: of_real_def)

   163

   164 lemma Re_divide_numeral [simp]: "Re (z / numeral w) = Re z / numeral w"

   165   by (simp add: Re_divide sqr_conv_mult)

   166

   167 lemma Im_divide_numeral [simp]: "Im (z / numeral w) = Im z / numeral w"

   168   by (simp add: Im_divide sqr_conv_mult)

   169

   170 lemma Re_divide_of_nat [simp]: "Re (z / of_nat n) = Re z / of_nat n"

   171   by (cases n) (simp_all add: Re_divide divide_simps power2_eq_square del: of_nat_Suc)

   172

   173 lemma Im_divide_of_nat [simp]: "Im (z / of_nat n) = Im z / of_nat n"

   174   by (cases n) (simp_all add: Im_divide divide_simps power2_eq_square del: of_nat_Suc)

   175

   176 lemma of_real_Re [simp]:

   177     "z \<in> \<real> \<Longrightarrow> of_real (Re z) = z"

   178   by (auto simp: Reals_def)

   179

   180 lemma complex_Re_fact [simp]: "Re (fact n) = fact n"

   181 proof -

   182   have "(fact n :: complex) = of_real (fact n)" by simp

   183   also have "Re \<dots> = fact n" by (subst Re_complex_of_real) simp_all

   184   finally show ?thesis .

   185 qed

   186

   187 lemma complex_Im_fact [simp]: "Im (fact n) = 0"

   188   by (subst of_nat_fact [symmetric]) (simp only: complex_Im_of_nat)

   189

   190

   191 subsection \<open>The Complex Number $i$\<close>

   192

   193 primcorec "ii" :: complex  ("\<i>") where

   194   "Re ii = 0"

   195 | "Im ii = 1"

   196

   197 lemma Complex_eq[simp]: "Complex a b = a + \<i> * b"

   198   by (simp add: complex_eq_iff)

   199

   200 lemma complex_eq: "a = Re a + \<i> * Im a"

   201   by (simp add: complex_eq_iff)

   202

   203 lemma fun_complex_eq: "f = (\<lambda>x. Re (f x) + \<i> * Im (f x))"

   204   by (simp add: fun_eq_iff complex_eq)

   205

   206 lemma i_squared [simp]: "ii * ii = -1"

   207   by (simp add: complex_eq_iff)

   208

   209 lemma power2_i [simp]: "ii\<^sup>2 = -1"

   210   by (simp add: power2_eq_square)

   211

   212 lemma inverse_i [simp]: "inverse ii = - ii"

   213   by (rule inverse_unique) simp

   214

   215 lemma divide_i [simp]: "x / ii = - ii * x"

   216   by (simp add: divide_complex_def)

   217

   218 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"

   219   by (simp add: mult.assoc [symmetric])

   220

   221 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"

   222   by (simp add: complex_eq_iff)

   223

   224 lemma complex_i_not_one [simp]: "ii \<noteq> 1"

   225   by (simp add: complex_eq_iff)

   226

   227 lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"

   228   by (simp add: complex_eq_iff)

   229

   230 lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> - numeral w"

   231   by (simp add: complex_eq_iff)

   232

   233 lemma complex_split_polar: "\<exists>r a. z = complex_of_real r * (cos a + \<i> * sin a)"

   234   by (simp add: complex_eq_iff polar_Ex)

   235

   236 lemma i_even_power [simp]: "\<i> ^ (n * 2) = (-1) ^ n"

   237   by (metis mult.commute power2_i power_mult)

   238

   239 lemma Re_ii_times [simp]: "Re (ii*z) = - Im z"

   240   by simp

   241

   242 lemma Im_ii_times [simp]: "Im (ii*z) = Re z"

   243   by simp

   244

   245 lemma ii_times_eq_iff: "ii*w = z \<longleftrightarrow> w = -(ii*z)"

   246   by auto

   247

   248 lemma divide_numeral_i [simp]: "z / (numeral n * ii) = -(ii*z) / numeral n"

   249   by (metis divide_divide_eq_left divide_i mult.commute mult_minus_right)

   250

   251 subsection \<open>Vector Norm\<close>

   252

   253 instantiation complex :: real_normed_field

   254 begin

   255

   256 definition "norm z = sqrt ((Re z)\<^sup>2 + (Im z)\<^sup>2)"

   257

   258 abbreviation cmod :: "complex \<Rightarrow> real"

   259   where "cmod \<equiv> norm"

   260

   261 definition complex_sgn_def:

   262   "sgn x = x /\<^sub>R cmod x"

   263

   264 definition dist_complex_def:

   265   "dist x y = cmod (x - y)"

   266

   267 definition uniformity_complex_def [code del]:

   268   "(uniformity :: (complex \<times> complex) filter) = (INF e:{0 <..}. principal {(x, y). dist x y < e})"

   269

   270 definition open_complex_def [code del]:

   271   "open (U :: complex set) \<longleftrightarrow> (\<forall>x\<in>U. eventually (\<lambda>(x', y). x' = x \<longrightarrow> y \<in> U) uniformity)"

   272

   273 instance proof

   274   fix r :: real and x y :: complex and S :: "complex set"

   275   show "(norm x = 0) = (x = 0)"

   276     by (simp add: norm_complex_def complex_eq_iff)

   277   show "norm (x + y) \<le> norm x + norm y"

   278     by (simp add: norm_complex_def complex_eq_iff real_sqrt_sum_squares_triangle_ineq)

   279   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"

   280     by (simp add: norm_complex_def complex_eq_iff power_mult_distrib distrib_left [symmetric] real_sqrt_mult)

   281   show "norm (x * y) = norm x * norm y"

   282     by (simp add: norm_complex_def complex_eq_iff real_sqrt_mult [symmetric] power2_eq_square algebra_simps)

   283 qed (rule complex_sgn_def dist_complex_def open_complex_def uniformity_complex_def)+

   284

   285 end

   286

   287 declare uniformity_Abort[where 'a=complex, code]

   288

   289 lemma norm_ii [simp]: "norm ii = 1"

   290   by (simp add: norm_complex_def)

   291

   292 lemma cmod_unit_one: "cmod (cos a + \<i> * sin a) = 1"

   293   by (simp add: norm_complex_def)

   294

   295 lemma cmod_complex_polar: "cmod (r * (cos a + \<i> * sin a)) = \<bar>r\<bar>"

   296   by (simp add: norm_mult cmod_unit_one)

   297

   298 lemma complex_Re_le_cmod: "Re x \<le> cmod x"

   299   unfolding norm_complex_def

   300   by (rule real_sqrt_sum_squares_ge1)

   301

   302 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"

   303   by (rule order_trans [OF _ norm_ge_zero]) simp

   304

   305 lemma complex_mod_triangle_ineq2: "cmod (b + a) - cmod b \<le> cmod a"

   306   by (rule ord_le_eq_trans [OF norm_triangle_ineq2]) simp

   307

   308 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"

   309   by (simp add: norm_complex_def)

   310

   311 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"

   312   by (simp add: norm_complex_def)

   313

   314 lemma cmod_le: "cmod z \<le> \<bar>Re z\<bar> + \<bar>Im z\<bar>"

   315   apply (subst complex_eq)

   316   apply (rule order_trans)

   317   apply (rule norm_triangle_ineq)

   318   apply (simp add: norm_mult)

   319   done

   320

   321 lemma cmod_eq_Re: "Im z = 0 \<Longrightarrow> cmod z = \<bar>Re z\<bar>"

   322   by (simp add: norm_complex_def)

   323

   324 lemma cmod_eq_Im: "Re z = 0 \<Longrightarrow> cmod z = \<bar>Im z\<bar>"

   325   by (simp add: norm_complex_def)

   326

   327 lemma cmod_power2: "cmod z ^ 2 = (Re z)^2 + (Im z)^2"

   328   by (simp add: norm_complex_def)

   329

   330 lemma cmod_plus_Re_le_0_iff: "cmod z + Re z \<le> 0 \<longleftrightarrow> Re z = - cmod z"

   331   using abs_Re_le_cmod[of z] by auto

   332

   333 lemma cmod_Re_le_iff: "Im x = Im y \<Longrightarrow> cmod x \<le> cmod y \<longleftrightarrow> abs (Re x) \<le> abs (Re y)"

   334   by (metis add.commute add_le_cancel_left norm_complex_def real_sqrt_abs real_sqrt_le_iff)

   335

   336 lemma cmod_Im_le_iff: "Re x = Re y \<Longrightarrow> cmod x \<le> cmod y \<longleftrightarrow> abs (Im x) \<le> abs (Im y)"

   337   by (metis add_le_cancel_left norm_complex_def real_sqrt_abs real_sqrt_le_iff)

   338

   339 lemma Im_eq_0: "\<bar>Re z\<bar> = cmod z \<Longrightarrow> Im z = 0"

   340   by (subst (asm) power_eq_iff_eq_base[symmetric, where n=2])

   341      (auto simp add: norm_complex_def)

   342

   343 lemma abs_sqrt_wlog:

   344   fixes x::"'a::linordered_idom"

   345   assumes "\<And>x::'a. x \<ge> 0 \<Longrightarrow> P x (x\<^sup>2)" shows "P \<bar>x\<bar> (x\<^sup>2)"

   346 by (metis abs_ge_zero assms power2_abs)

   347

   348 lemma complex_abs_le_norm: "\<bar>Re z\<bar> + \<bar>Im z\<bar> \<le> sqrt 2 * norm z"

   349   unfolding norm_complex_def

   350   apply (rule abs_sqrt_wlog [where x="Re z"])

   351   apply (rule abs_sqrt_wlog [where x="Im z"])

   352   apply (rule power2_le_imp_le)

   353   apply (simp_all add: power2_sum add.commute sum_squares_bound real_sqrt_mult [symmetric])

   354   done

   355

   356 lemma complex_unit_circle: "z \<noteq> 0 \<Longrightarrow> (Re z / cmod z)\<^sup>2 + (Im z / cmod z)\<^sup>2 = 1"

   357   by (simp add: norm_complex_def divide_simps complex_eq_iff)

   358

   359

   360 text \<open>Properties of complex signum.\<close>

   361

   362 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"

   363   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult.commute)

   364

   365 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"

   366   by (simp add: complex_sgn_def divide_inverse)

   367

   368 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"

   369   by (simp add: complex_sgn_def divide_inverse)

   370

   371

   372 subsection \<open>Completeness of the Complexes\<close>

   373

   374 lemma bounded_linear_Re: "bounded_linear Re"

   375   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)

   376

   377 lemma bounded_linear_Im: "bounded_linear Im"

   378   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)

   379

   380 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]

   381 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]

   382 lemmas tendsto_Re [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Re]

   383 lemmas tendsto_Im [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Im]

   384 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]

   385 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]

   386 lemmas continuous_Re [simp] = bounded_linear.continuous [OF bounded_linear_Re]

   387 lemmas continuous_Im [simp] = bounded_linear.continuous [OF bounded_linear_Im]

   388 lemmas continuous_on_Re [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Re]

   389 lemmas continuous_on_Im [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Im]

   390 lemmas has_derivative_Re [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Re]

   391 lemmas has_derivative_Im [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Im]

   392 lemmas sums_Re = bounded_linear.sums [OF bounded_linear_Re]

   393 lemmas sums_Im = bounded_linear.sums [OF bounded_linear_Im]

   394

   395 lemma tendsto_Complex [tendsto_intros]:

   396   "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. Complex (f x) (g x)) \<longlongrightarrow> Complex a b) F"

   397   by (auto intro!: tendsto_intros)

   398

   399 lemma tendsto_complex_iff:

   400   "(f \<longlongrightarrow> x) F \<longleftrightarrow> (((\<lambda>x. Re (f x)) \<longlongrightarrow> Re x) F \<and> ((\<lambda>x. Im (f x)) \<longlongrightarrow> Im x) F)"

   401 proof safe

   402   assume "((\<lambda>x. Re (f x)) \<longlongrightarrow> Re x) F" "((\<lambda>x. Im (f x)) \<longlongrightarrow> Im x) F"

   403   from tendsto_Complex[OF this] show "(f \<longlongrightarrow> x) F"

   404     unfolding complex.collapse .

   405 qed (auto intro: tendsto_intros)

   406

   407 lemma continuous_complex_iff: "continuous F f \<longleftrightarrow>

   408     continuous F (\<lambda>x. Re (f x)) \<and> continuous F (\<lambda>x. Im (f x))"

   409   unfolding continuous_def tendsto_complex_iff ..

   410

   411 lemma has_vector_derivative_complex_iff: "(f has_vector_derivative x) F \<longleftrightarrow>

   412     ((\<lambda>x. Re (f x)) has_field_derivative (Re x)) F \<and>

   413     ((\<lambda>x. Im (f x)) has_field_derivative (Im x)) F"

   414   unfolding has_vector_derivative_def has_field_derivative_def has_derivative_def tendsto_complex_iff

   415   by (simp add: field_simps bounded_linear_scaleR_left bounded_linear_mult_right)

   416

   417 lemma has_field_derivative_Re[derivative_intros]:

   418   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Re (f x)) has_field_derivative (Re D)) F"

   419   unfolding has_vector_derivative_complex_iff by safe

   420

   421 lemma has_field_derivative_Im[derivative_intros]:

   422   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Im (f x)) has_field_derivative (Im D)) F"

   423   unfolding has_vector_derivative_complex_iff by safe

   424

   425 instance complex :: banach

   426 proof

   427   fix X :: "nat \<Rightarrow> complex"

   428   assume X: "Cauchy X"

   429   then have "(\<lambda>n. Complex (Re (X n)) (Im (X n))) \<longlonglongrightarrow> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"

   430     by (intro tendsto_Complex convergent_LIMSEQ_iff[THEN iffD1] Cauchy_convergent_iff[THEN iffD1] Cauchy_Re Cauchy_Im)

   431   then show "convergent X"

   432     unfolding complex.collapse by (rule convergentI)

   433 qed

   434

   435 declare

   436   DERIV_power[where 'a=complex, unfolded of_nat_def[symmetric], derivative_intros]

   437

   438 subsection \<open>Complex Conjugation\<close>

   439

   440 primcorec cnj :: "complex \<Rightarrow> complex" where

   441   "Re (cnj z) = Re z"

   442 | "Im (cnj z) = - Im z"

   443

   444 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"

   445   by (simp add: complex_eq_iff)

   446

   447 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"

   448   by (simp add: complex_eq_iff)

   449

   450 lemma complex_cnj_zero [simp]: "cnj 0 = 0"

   451   by (simp add: complex_eq_iff)

   452

   453 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"

   454   by (simp add: complex_eq_iff)

   455

   456 lemma complex_cnj_add [simp]: "cnj (x + y) = cnj x + cnj y"

   457   by (simp add: complex_eq_iff)

   458

   459 lemma cnj_setsum [simp]: "cnj (setsum f s) = (\<Sum>x\<in>s. cnj (f x))"

   460   by (induct s rule: infinite_finite_induct) auto

   461

   462 lemma complex_cnj_diff [simp]: "cnj (x - y) = cnj x - cnj y"

   463   by (simp add: complex_eq_iff)

   464

   465 lemma complex_cnj_minus [simp]: "cnj (- x) = - cnj x"

   466   by (simp add: complex_eq_iff)

   467

   468 lemma complex_cnj_one [simp]: "cnj 1 = 1"

   469   by (simp add: complex_eq_iff)

   470

   471 lemma complex_cnj_mult [simp]: "cnj (x * y) = cnj x * cnj y"

   472   by (simp add: complex_eq_iff)

   473

   474 lemma cnj_setprod [simp]: "cnj (setprod f s) = (\<Prod>x\<in>s. cnj (f x))"

   475   by (induct s rule: infinite_finite_induct) auto

   476

   477 lemma complex_cnj_inverse [simp]: "cnj (inverse x) = inverse (cnj x)"

   478   by (simp add: complex_eq_iff)

   479

   480 lemma complex_cnj_divide [simp]: "cnj (x / y) = cnj x / cnj y"

   481   by (simp add: divide_complex_def)

   482

   483 lemma complex_cnj_power [simp]: "cnj (x ^ n) = cnj x ^ n"

   484   by (induct n) simp_all

   485

   486 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"

   487   by (simp add: complex_eq_iff)

   488

   489 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"

   490   by (simp add: complex_eq_iff)

   491

   492 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"

   493   by (simp add: complex_eq_iff)

   494

   495 lemma complex_cnj_neg_numeral [simp]: "cnj (- numeral w) = - numeral w"

   496   by (simp add: complex_eq_iff)

   497

   498 lemma complex_cnj_scaleR [simp]: "cnj (scaleR r x) = scaleR r (cnj x)"

   499   by (simp add: complex_eq_iff)

   500

   501 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"

   502   by (simp add: norm_complex_def)

   503

   504 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"

   505   by (simp add: complex_eq_iff)

   506

   507 lemma complex_cnj_i [simp]: "cnj ii = - ii"

   508   by (simp add: complex_eq_iff)

   509

   510 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"

   511   by (simp add: complex_eq_iff)

   512

   513 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"

   514   by (simp add: complex_eq_iff)

   515

   516 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<^sup>2 + (Im z)\<^sup>2)"

   517   by (simp add: complex_eq_iff power2_eq_square)

   518

   519 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<^sup>2"

   520   by (simp add: norm_mult power2_eq_square)

   521

   522 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"

   523   by (simp add: norm_complex_def power2_eq_square)

   524

   525 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"

   526   by simp

   527

   528 lemma complex_cnj_fact [simp]: "cnj (fact n) = fact n"

   529   by (subst of_nat_fact [symmetric], subst complex_cnj_of_nat) simp

   530

   531 lemma complex_cnj_pochhammer [simp]: "cnj (pochhammer z n) = pochhammer (cnj z) n"

   532   by (induction n arbitrary: z) (simp_all add: pochhammer_rec)

   533

   534 lemma bounded_linear_cnj: "bounded_linear cnj"

   535   using complex_cnj_add complex_cnj_scaleR

   536   by (rule bounded_linear_intro [where K=1], simp)

   537

   538 lemmas tendsto_cnj [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_cnj]

   539 lemmas isCont_cnj [simp] = bounded_linear.isCont [OF bounded_linear_cnj]

   540 lemmas continuous_cnj [simp, continuous_intros] = bounded_linear.continuous [OF bounded_linear_cnj]

   541 lemmas continuous_on_cnj [simp, continuous_intros] = bounded_linear.continuous_on [OF bounded_linear_cnj]

   542 lemmas has_derivative_cnj [simp, derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_cnj]

   543

   544 lemma lim_cnj: "((\<lambda>x. cnj(f x)) \<longlongrightarrow> cnj l) F \<longleftrightarrow> (f \<longlongrightarrow> l) F"

   545   by (simp add: tendsto_iff dist_complex_def complex_cnj_diff [symmetric] del: complex_cnj_diff)

   546

   547 lemma sums_cnj: "((\<lambda>x. cnj(f x)) sums cnj l) \<longleftrightarrow> (f sums l)"

   548   by (simp add: sums_def lim_cnj cnj_setsum [symmetric] del: cnj_setsum)

   549

   550

   551 subsection\<open>Basic Lemmas\<close>

   552

   553 lemma complex_eq_0: "z=0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 = 0"

   554   by (metis zero_complex.sel complex_eqI sum_power2_eq_zero_iff)

   555

   556 lemma complex_neq_0: "z\<noteq>0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 > 0"

   557   by (metis complex_eq_0 less_numeral_extra(3) sum_power2_gt_zero_iff)

   558

   559 lemma complex_norm_square: "of_real ((norm z)\<^sup>2) = z * cnj z"

   560 by (cases z)

   561    (auto simp: complex_eq_iff norm_complex_def power2_eq_square[symmetric] of_real_power[symmetric]

   562          simp del: of_real_power)

   563

   564 lemma complex_div_cnj: "a / b = (a * cnj b) / (norm b)^2"

   565   using complex_norm_square by auto

   566

   567 lemma Re_complex_div_eq_0: "Re (a / b) = 0 \<longleftrightarrow> Re (a * cnj b) = 0"

   568   by (auto simp add: Re_divide)

   569

   570 lemma Im_complex_div_eq_0: "Im (a / b) = 0 \<longleftrightarrow> Im (a * cnj b) = 0"

   571   by (auto simp add: Im_divide)

   572

   573 lemma complex_div_gt_0:

   574   "(Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0) \<and> (Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0)"

   575 proof cases

   576   assume "b = 0" then show ?thesis by auto

   577 next

   578   assume "b \<noteq> 0"

   579   then have "0 < (Re b)\<^sup>2 + (Im b)\<^sup>2"

   580     by (simp add: complex_eq_iff sum_power2_gt_zero_iff)

   581   then show ?thesis

   582     by (simp add: Re_divide Im_divide zero_less_divide_iff)

   583 qed

   584

   585 lemma Re_complex_div_gt_0: "Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0"

   586   and Im_complex_div_gt_0: "Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0"

   587   using complex_div_gt_0 by auto

   588

   589 lemma Re_complex_div_ge_0: "Re(a / b) \<ge> 0 \<longleftrightarrow> Re(a * cnj b) \<ge> 0"

   590   by (metis le_less Re_complex_div_eq_0 Re_complex_div_gt_0)

   591

   592 lemma Im_complex_div_ge_0: "Im(a / b) \<ge> 0 \<longleftrightarrow> Im(a * cnj b) \<ge> 0"

   593   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 le_less)

   594

   595 lemma Re_complex_div_lt_0: "Re(a / b) < 0 \<longleftrightarrow> Re(a * cnj b) < 0"

   596   by (metis less_asym neq_iff Re_complex_div_eq_0 Re_complex_div_gt_0)

   597

   598 lemma Im_complex_div_lt_0: "Im(a / b) < 0 \<longleftrightarrow> Im(a * cnj b) < 0"

   599   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 less_asym neq_iff)

   600

   601 lemma Re_complex_div_le_0: "Re(a / b) \<le> 0 \<longleftrightarrow> Re(a * cnj b) \<le> 0"

   602   by (metis not_le Re_complex_div_gt_0)

   603

   604 lemma Im_complex_div_le_0: "Im(a / b) \<le> 0 \<longleftrightarrow> Im(a * cnj b) \<le> 0"

   605   by (metis Im_complex_div_gt_0 not_le)

   606

   607 lemma Re_divide_of_real [simp]: "Re (z / of_real r) = Re z / r"

   608   by (simp add: Re_divide power2_eq_square)

   609

   610 lemma Im_divide_of_real [simp]: "Im (z / of_real r) = Im z / r"

   611   by (simp add: Im_divide power2_eq_square)

   612

   613 lemma Re_divide_Reals: "r \<in> Reals \<Longrightarrow> Re (z / r) = Re z / Re r"

   614   by (metis Re_divide_of_real of_real_Re)

   615

   616 lemma Im_divide_Reals: "r \<in> Reals \<Longrightarrow> Im (z / r) = Im z / Re r"

   617   by (metis Im_divide_of_real of_real_Re)

   618

   619 lemma Re_setsum[simp]: "Re (setsum f s) = (\<Sum>x\<in>s. Re (f x))"

   620   by (induct s rule: infinite_finite_induct) auto

   621

   622 lemma Im_setsum[simp]: "Im (setsum f s) = (\<Sum>x\<in>s. Im(f x))"

   623   by (induct s rule: infinite_finite_induct) auto

   624

   625 lemma sums_complex_iff: "f sums x \<longleftrightarrow> ((\<lambda>x. Re (f x)) sums Re x) \<and> ((\<lambda>x. Im (f x)) sums Im x)"

   626   unfolding sums_def tendsto_complex_iff Im_setsum Re_setsum ..

   627

   628 lemma summable_complex_iff: "summable f \<longleftrightarrow> summable (\<lambda>x. Re (f x)) \<and>  summable (\<lambda>x. Im (f x))"

   629   unfolding summable_def sums_complex_iff[abs_def] by (metis complex.sel)

   630

   631 lemma summable_complex_of_real [simp]: "summable (\<lambda>n. complex_of_real (f n)) \<longleftrightarrow> summable f"

   632   unfolding summable_complex_iff by simp

   633

   634 lemma summable_Re: "summable f \<Longrightarrow> summable (\<lambda>x. Re (f x))"

   635   unfolding summable_complex_iff by blast

   636

   637 lemma summable_Im: "summable f \<Longrightarrow> summable (\<lambda>x. Im (f x))"

   638   unfolding summable_complex_iff by blast

   639

   640 lemma complex_is_Nat_iff: "z \<in> \<nat> \<longleftrightarrow> Im z = 0 \<and> (\<exists>i. Re z = of_nat i)"

   641   by (auto simp: Nats_def complex_eq_iff)

   642

   643 lemma complex_is_Int_iff: "z \<in> \<int> \<longleftrightarrow> Im z = 0 \<and> (\<exists>i. Re z = of_int i)"

   644   by (auto simp: Ints_def complex_eq_iff)

   645

   646 lemma complex_is_Real_iff: "z \<in> \<real> \<longleftrightarrow> Im z = 0"

   647   by (auto simp: Reals_def complex_eq_iff)

   648

   649 lemma Reals_cnj_iff: "z \<in> \<real> \<longleftrightarrow> cnj z = z"

   650   by (auto simp: complex_is_Real_iff complex_eq_iff)

   651

   652 lemma in_Reals_norm: "z \<in> \<real> \<Longrightarrow> norm z = \<bar>Re z\<bar>"

   653   by (simp add: complex_is_Real_iff norm_complex_def)

   654

   655 lemma series_comparison_complex:

   656   fixes f:: "nat \<Rightarrow> 'a::banach"

   657   assumes sg: "summable g"

   658      and "\<And>n. g n \<in> \<real>" "\<And>n. Re (g n) \<ge> 0"

   659      and fg: "\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> norm(g n)"

   660   shows "summable f"

   661 proof -

   662   have g: "\<And>n. cmod (g n) = Re (g n)" using assms

   663     by (metis abs_of_nonneg in_Reals_norm)

   664   show ?thesis

   665     apply (rule summable_comparison_test' [where g = "\<lambda>n. norm (g n)" and N=N])

   666     using sg

   667     apply (auto simp: summable_def)

   668     apply (rule_tac x="Re s" in exI)

   669     apply (auto simp: g sums_Re)

   670     apply (metis fg g)

   671     done

   672 qed

   673

   674 subsection\<open>Polar Form for Complex Numbers\<close>

   675

   676 lemma complex_unimodular_polar:

   677   assumes "(norm z = 1)"

   678   obtains t where "0 \<le> t" "t < 2*pi" "z = Complex (cos t) (sin t)"

   679 by (metis cmod_power2 one_power2 complex_surj sincos_total_2pi [of "Re z" "Im z"] assms)

   680

   681 subsubsection \<open>$\cos \theta + i \sin \theta$\<close>

   682

   683 primcorec cis :: "real \<Rightarrow> complex" where

   684   "Re (cis a) = cos a"

   685 | "Im (cis a) = sin a"

   686

   687 lemma cis_zero [simp]: "cis 0 = 1"

   688   by (simp add: complex_eq_iff)

   689

   690 lemma norm_cis [simp]: "norm (cis a) = 1"

   691   by (simp add: norm_complex_def)

   692

   693 lemma sgn_cis [simp]: "sgn (cis a) = cis a"

   694   by (simp add: sgn_div_norm)

   695

   696 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"

   697   by (metis norm_cis norm_zero zero_neq_one)

   698

   699 lemma cis_mult: "cis a * cis b = cis (a + b)"

   700   by (simp add: complex_eq_iff cos_add sin_add)

   701

   702 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"

   703   by (induct n, simp_all add: of_nat_Suc algebra_simps cis_mult)

   704

   705 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"

   706   by (simp add: complex_eq_iff)

   707

   708 lemma cis_divide: "cis a / cis b = cis (a - b)"

   709   by (simp add: divide_complex_def cis_mult)

   710

   711 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"

   712   by (auto simp add: DeMoivre)

   713

   714 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"

   715   by (auto simp add: DeMoivre)

   716

   717 lemma cis_pi: "cis pi = -1"

   718   by (simp add: complex_eq_iff)

   719

   720 subsubsection \<open>$r(\cos \theta + i \sin \theta)$\<close>

   721

   722 definition rcis :: "real \<Rightarrow> real \<Rightarrow> complex" where

   723   "rcis r a = complex_of_real r * cis a"

   724

   725 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"

   726   by (simp add: rcis_def)

   727

   728 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"

   729   by (simp add: rcis_def)

   730

   731 lemma rcis_Ex: "\<exists>r a. z = rcis r a"

   732   by (simp add: complex_eq_iff polar_Ex)

   733

   734 lemma complex_mod_rcis [simp]: "cmod (rcis r a) = \<bar>r\<bar>"

   735   by (simp add: rcis_def norm_mult)

   736

   737 lemma cis_rcis_eq: "cis a = rcis 1 a"

   738   by (simp add: rcis_def)

   739

   740 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"

   741   by (simp add: rcis_def cis_mult)

   742

   743 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"

   744   by (simp add: rcis_def)

   745

   746 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"

   747   by (simp add: rcis_def)

   748

   749 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"

   750   by (simp add: rcis_def)

   751

   752 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"

   753   by (simp add: rcis_def power_mult_distrib DeMoivre)

   754

   755 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"

   756   by (simp add: divide_inverse rcis_def)

   757

   758 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"

   759   by (simp add: rcis_def cis_divide [symmetric])

   760

   761 subsubsection \<open>Complex exponential\<close>

   762

   763 lemma cis_conv_exp: "cis b = exp (\<i> * b)"

   764 proof -

   765   { fix n :: nat

   766     have "\<i> ^ n = fact n *\<^sub>R (cos_coeff n + \<i> * sin_coeff n)"

   767       by (induct n)

   768          (simp_all add: sin_coeff_Suc cos_coeff_Suc complex_eq_iff Re_divide Im_divide field_simps

   769                         power2_eq_square of_nat_Suc add_nonneg_eq_0_iff)

   770     then have "(\<i> * complex_of_real b) ^ n /\<^sub>R fact n =

   771         of_real (cos_coeff n * b^n) + \<i> * of_real (sin_coeff n * b^n)"

   772       by (simp add: field_simps) }

   773   then show ?thesis using sin_converges [of b] cos_converges [of b]

   774     by (auto simp add: cis.ctr exp_def simp del: of_real_mult

   775              intro!: sums_unique sums_add sums_mult sums_of_real)

   776 qed

   777

   778 lemma exp_eq_polar: "exp z = exp (Re z) * cis (Im z)"

   779   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by (cases z) simp

   780

   781 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"

   782   unfolding exp_eq_polar by simp

   783

   784 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"

   785   unfolding exp_eq_polar by simp

   786

   787 lemma norm_cos_sin [simp]: "norm (Complex (cos t) (sin t)) = 1"

   788   by (simp add: norm_complex_def)

   789

   790 lemma norm_exp_eq_Re [simp]: "norm (exp z) = exp (Re z)"

   791   by (simp add: cis.code cmod_complex_polar exp_eq_polar)

   792

   793 lemma complex_exp_exists: "\<exists>a r. z = complex_of_real r * exp a"

   794   apply (insert rcis_Ex [of z])

   795   apply (auto simp add: exp_eq_polar rcis_def mult.assoc [symmetric])

   796   apply (rule_tac x = "ii * complex_of_real a" in exI, auto)

   797   done

   798

   799 lemma exp_pi_i [simp]: "exp(of_real pi * ii) = -1"

   800   by (metis cis_conv_exp cis_pi mult.commute)

   801

   802 lemma exp_two_pi_i [simp]: "exp(2 * of_real pi * ii) = 1"

   803   by (simp add: exp_eq_polar complex_eq_iff)

   804

   805 subsubsection \<open>Complex argument\<close>

   806

   807 definition arg :: "complex \<Rightarrow> real" where

   808   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"

   809

   810 lemma arg_zero: "arg 0 = 0"

   811   by (simp add: arg_def)

   812

   813 lemma arg_unique:

   814   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"

   815   shows "arg z = x"

   816 proof -

   817   from assms have "z \<noteq> 0" by auto

   818   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"

   819   proof

   820     fix a

   821     define d where "d = a - x"

   822     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"

   823     from a assms have "- (2*pi) < d \<and> d < 2*pi"

   824       unfolding d_def by simp

   825     moreover from a assms have "cos a = cos x" and "sin a = sin x"

   826       by (simp_all add: complex_eq_iff)

   827     hence cos: "cos d = 1" unfolding d_def cos_diff by simp

   828     moreover from cos have "sin d = 0" by (rule cos_one_sin_zero)

   829     ultimately have "d = 0"

   830       unfolding sin_zero_iff

   831       by (auto elim!: evenE dest!: less_2_cases)

   832     thus "a = x" unfolding d_def by simp

   833   qed (simp add: assms del: Re_sgn Im_sgn)

   834   with \<open>z \<noteq> 0\<close> show "arg z = x"

   835     unfolding arg_def by simp

   836 qed

   837

   838 lemma arg_correct:

   839   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"

   840 proof (simp add: arg_def assms, rule someI_ex)

   841   obtain r a where z: "z = rcis r a" using rcis_Ex by fast

   842   with assms have "r \<noteq> 0" by auto

   843   define b where "b = (if 0 < r then a else a + pi)"

   844   have b: "sgn z = cis b"

   845     unfolding z b_def rcis_def using \<open>r \<noteq> 0\<close>

   846     by (simp add: of_real_def sgn_scaleR sgn_if complex_eq_iff)

   847   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"

   848     by (induct_tac n) (simp_all add: distrib_left cis_mult [symmetric] complex_eq_iff)

   849   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"

   850     by (case_tac x rule: int_diff_cases)

   851        (simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)

   852   define c where "c = b - 2 * pi * of_int \<lceil>(b - pi) / (2 * pi)\<rceil>"

   853   have "sgn z = cis c"

   854     unfolding b c_def

   855     by (simp add: cis_divide [symmetric] cis_2pi_int)

   856   moreover have "- pi < c \<and> c \<le> pi"

   857     using ceiling_correct [of "(b - pi) / (2*pi)"]

   858     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps del: le_of_int_ceiling)

   859   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast

   860 qed

   861

   862 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"

   863   by (cases "z = 0") (simp_all add: arg_zero arg_correct)

   864

   865 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"

   866   by (simp add: arg_correct)

   867

   868 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"

   869   by (cases "z = 0") (simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)

   870

   871 lemma cos_arg_i_mult_zero [simp]: "y \<noteq> 0 \<Longrightarrow> Re y = 0 \<Longrightarrow> cos (arg y) = 0"

   872   using cis_arg [of y] by (simp add: complex_eq_iff)

   873

   874 subsection \<open>Square root of complex numbers\<close>

   875

   876 primcorec csqrt :: "complex \<Rightarrow> complex" where

   877   "Re (csqrt z) = sqrt ((cmod z + Re z) / 2)"

   878 | "Im (csqrt z) = (if Im z = 0 then 1 else sgn (Im z)) * sqrt ((cmod z - Re z) / 2)"

   879

   880 lemma csqrt_of_real_nonneg [simp]: "Im x = 0 \<Longrightarrow> Re x \<ge> 0 \<Longrightarrow> csqrt x = sqrt (Re x)"

   881   by (simp add: complex_eq_iff norm_complex_def)

   882

   883 lemma csqrt_of_real_nonpos [simp]: "Im x = 0 \<Longrightarrow> Re x \<le> 0 \<Longrightarrow> csqrt x = \<i> * sqrt \<bar>Re x\<bar>"

   884   by (simp add: complex_eq_iff norm_complex_def)

   885

   886 lemma of_real_sqrt: "x \<ge> 0 \<Longrightarrow> of_real (sqrt x) = csqrt (of_real x)"

   887   by (simp add: complex_eq_iff norm_complex_def)

   888

   889 lemma csqrt_0 [simp]: "csqrt 0 = 0"

   890   by simp

   891

   892 lemma csqrt_1 [simp]: "csqrt 1 = 1"

   893   by simp

   894

   895 lemma csqrt_ii [simp]: "csqrt \<i> = (1 + \<i>) / sqrt 2"

   896   by (simp add: complex_eq_iff Re_divide Im_divide real_sqrt_divide real_div_sqrt)

   897

   898 lemma power2_csqrt[simp,algebra]: "(csqrt z)\<^sup>2 = z"

   899 proof cases

   900   assume "Im z = 0" then show ?thesis

   901     using real_sqrt_pow2[of "Re z"] real_sqrt_pow2[of "- Re z"]

   902     by (cases "0::real" "Re z" rule: linorder_cases)

   903        (simp_all add: complex_eq_iff Re_power2 Im_power2 power2_eq_square cmod_eq_Re)

   904 next

   905   assume "Im z \<noteq> 0"

   906   moreover

   907   have "cmod z * cmod z - Re z * Re z = Im z * Im z"

   908     by (simp add: norm_complex_def power2_eq_square)

   909   moreover

   910   have "\<bar>Re z\<bar> \<le> cmod z"

   911     by (simp add: norm_complex_def)

   912   ultimately show ?thesis

   913     by (simp add: Re_power2 Im_power2 complex_eq_iff real_sgn_eq

   914                   field_simps real_sqrt_mult[symmetric] real_sqrt_divide)

   915 qed

   916

   917 lemma csqrt_eq_0 [simp]: "csqrt z = 0 \<longleftrightarrow> z = 0"

   918   by auto (metis power2_csqrt power_eq_0_iff)

   919

   920 lemma csqrt_eq_1 [simp]: "csqrt z = 1 \<longleftrightarrow> z = 1"

   921   by auto (metis power2_csqrt power2_eq_1_iff)

   922

   923 lemma csqrt_principal: "0 < Re (csqrt z) \<or> Re (csqrt z) = 0 \<and> 0 \<le> Im (csqrt z)"

   924   by (auto simp add: not_less cmod_plus_Re_le_0_iff Im_eq_0)

   925

   926 lemma Re_csqrt: "0 \<le> Re (csqrt z)"

   927   by (metis csqrt_principal le_less)

   928

   929 lemma csqrt_square:

   930   assumes "0 < Re b \<or> (Re b = 0 \<and> 0 \<le> Im b)"

   931   shows "csqrt (b^2) = b"

   932 proof -

   933   have "csqrt (b^2) = b \<or> csqrt (b^2) = - b"

   934     unfolding power2_eq_iff[symmetric] by (simp add: power2_csqrt)

   935   moreover have "csqrt (b^2) \<noteq> -b \<or> b = 0"

   936     using csqrt_principal[of "b ^ 2"] assms by (intro disjCI notI) (auto simp: complex_eq_iff)

   937   ultimately show ?thesis

   938     by auto

   939 qed

   940

   941 lemma csqrt_unique:

   942     "w^2 = z \<Longrightarrow> (0 < Re w \<or> Re w = 0 \<and> 0 \<le> Im w) \<Longrightarrow> csqrt z = w"

   943   by (auto simp: csqrt_square)

   944

   945 lemma csqrt_minus [simp]:

   946   assumes "Im x < 0 \<or> (Im x = 0 \<and> 0 \<le> Re x)"

   947   shows "csqrt (- x) = \<i> * csqrt x"

   948 proof -

   949   have "csqrt ((\<i> * csqrt x)^2) = \<i> * csqrt x"

   950   proof (rule csqrt_square)

   951     have "Im (csqrt x) \<le> 0"

   952       using assms by (auto simp add: cmod_eq_Re mult_le_0_iff field_simps complex_Re_le_cmod)

   953     then show "0 < Re (\<i> * csqrt x) \<or> Re (\<i> * csqrt x) = 0 \<and> 0 \<le> Im (\<i> * csqrt x)"

   954       by (auto simp add: Re_csqrt simp del: csqrt.simps)

   955   qed

   956   also have "(\<i> * csqrt x)^2 = - x"

   957     by (simp add: power_mult_distrib)

   958   finally show ?thesis .

   959 qed

   960

   961 text \<open>Legacy theorem names\<close>

   962

   963 lemmas expand_complex_eq = complex_eq_iff

   964 lemmas complex_Re_Im_cancel_iff = complex_eq_iff

   965 lemmas complex_equality = complex_eqI

   966 lemmas cmod_def = norm_complex_def

   967 lemmas complex_norm_def = norm_complex_def

   968 lemmas complex_divide_def = divide_complex_def

   969

   970 lemma legacy_Complex_simps:

   971   shows Complex_eq_0: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"

   972     and complex_add: "Complex a b + Complex c d = Complex (a + c) (b + d)"

   973     and complex_minus: "- (Complex a b) = Complex (- a) (- b)"

   974     and complex_diff: "Complex a b - Complex c d = Complex (a - c) (b - d)"

   975     and Complex_eq_1: "Complex a b = 1 \<longleftrightarrow> a = 1 \<and> b = 0"

   976     and Complex_eq_neg_1: "Complex a b = - 1 \<longleftrightarrow> a = - 1 \<and> b = 0"

   977     and complex_mult: "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"

   978     and complex_inverse: "inverse (Complex a b) = Complex (a / (a\<^sup>2 + b\<^sup>2)) (- b / (a\<^sup>2 + b\<^sup>2))"

   979     and Complex_eq_numeral: "Complex a b = numeral w \<longleftrightarrow> a = numeral w \<and> b = 0"

   980     and Complex_eq_neg_numeral: "Complex a b = - numeral w \<longleftrightarrow> a = - numeral w \<and> b = 0"

   981     and complex_scaleR: "scaleR r (Complex a b) = Complex (r * a) (r * b)"

   982     and Complex_eq_i: "(Complex x y = ii) = (x = 0 \<and> y = 1)"

   983     and i_mult_Complex: "ii * Complex a b = Complex (- b) a"

   984     and Complex_mult_i: "Complex a b * ii = Complex (- b) a"

   985     and i_complex_of_real: "ii * complex_of_real r = Complex 0 r"

   986     and complex_of_real_i: "complex_of_real r * ii = Complex 0 r"

   987     and Complex_add_complex_of_real: "Complex x y + complex_of_real r = Complex (x+r) y"

   988     and complex_of_real_add_Complex: "complex_of_real r + Complex x y = Complex (r+x) y"

   989     and Complex_mult_complex_of_real: "Complex x y * complex_of_real r = Complex (x*r) (y*r)"

   990     and complex_of_real_mult_Complex: "complex_of_real r * Complex x y = Complex (r*x) (r*y)"

   991     and complex_eq_cancel_iff2: "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"

   992     and complex_cn: "cnj (Complex a b) = Complex a (- b)"

   993     and Complex_setsum': "setsum (%x. Complex (f x) 0) s = Complex (setsum f s) 0"

   994     and Complex_setsum: "Complex (setsum f s) 0 = setsum (%x. Complex (f x) 0) s"

   995     and complex_of_real_def: "complex_of_real r = Complex r 0"

   996     and complex_norm: "cmod (Complex x y) = sqrt (x\<^sup>2 + y\<^sup>2)"

   997   by (simp_all add: norm_complex_def field_simps complex_eq_iff Re_divide Im_divide del: Complex_eq)

   998

   999 lemma Complex_in_Reals: "Complex x 0 \<in> \<real>"

  1000   by (metis Reals_of_real complex_of_real_def)

  1001

  1002 end