src/HOL/Limits.thy
author wenzelm
Mon Apr 25 16:09:26 2016 +0200 (2016-04-25)
changeset 63040 eb4ddd18d635
parent 62393 a620a8756b7c
child 63081 5a5beb3dbe7e
permissions -rw-r--r--
eliminated old 'def';
tuned comments;
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 *)
     7 
     8 section \<open>Limits on Real Vector Spaces\<close>
     9 
    10 theory Limits
    11 imports Real_Vector_Spaces
    12 begin
    13 
    14 subsection \<open>Filter going to infinity norm\<close>
    15 
    16 definition at_infinity :: "'a::real_normed_vector filter" where
    17   "at_infinity = (INF r. principal {x. r \<le> norm x})"
    18 
    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    20   unfolding at_infinity_def
    21   by (subst eventually_INF_base)
    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
    23 
    24 corollary eventually_at_infinity_pos:
    25    "eventually p at_infinity \<longleftrightarrow> (\<exists>b. 0 < b \<and> (\<forall>x. norm x \<ge> b \<longrightarrow> p x))"
    26 apply (simp add: eventually_at_infinity, auto)
    27 apply (case_tac "b \<le> 0")
    28 using norm_ge_zero order_trans zero_less_one apply blast
    29 apply (force simp:)
    30 done
    31 
    32 lemma at_infinity_eq_at_top_bot:
    33   "(at_infinity :: real filter) = sup at_top at_bot"
    34   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
    35                    eventually_at_top_linorder eventually_at_bot_linorder)
    36   apply safe
    37   apply (rule_tac x="b" in exI, simp)
    38   apply (rule_tac x="- b" in exI, simp)
    39   apply (rule_tac x="max (- Na) N" in exI, auto simp: abs_real_def)
    40   done
    41 
    42 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
    43   unfolding at_infinity_eq_at_top_bot by simp
    44 
    45 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
    46   unfolding at_infinity_eq_at_top_bot by simp
    47 
    48 lemma filterlim_at_top_imp_at_infinity:
    49   fixes f :: "_ \<Rightarrow> real"
    50   shows "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    51   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    52 
    53 lemma lim_infinity_imp_sequentially:
    54   "(f \<longlongrightarrow> l) at_infinity \<Longrightarrow> ((\<lambda>n. f(n)) \<longlongrightarrow> l) sequentially"
    55 by (simp add: filterlim_at_top_imp_at_infinity filterlim_compose filterlim_real_sequentially)
    56 
    57 
    58 subsubsection \<open>Boundedness\<close>
    59 
    60 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    61   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    62 
    63 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    64   "Bseq X \<equiv> Bfun X sequentially"
    65 
    66 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    67 
    68 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    69   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    70 
    71 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    72   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    73 
    74 lemma Bfun_def:
    75   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    76   unfolding Bfun_metric_def norm_conv_dist
    77 proof safe
    78   fix y K assume K: "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    79   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    80     by (intro always_eventually) (metis dist_commute dist_triangle)
    81   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    82     by eventually_elim auto
    83   with \<open>0 < K\<close> show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    84     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    85 qed (force simp del: norm_conv_dist [symmetric])
    86 
    87 lemma BfunI:
    88   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    89 unfolding Bfun_def
    90 proof (intro exI conjI allI)
    91   show "0 < max K 1" by simp
    92 next
    93   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    94     using K by (rule eventually_mono, simp)
    95 qed
    96 
    97 lemma BfunE:
    98   assumes "Bfun f F"
    99   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   100 using assms unfolding Bfun_def by blast
   101 
   102 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
   103   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
   104   apply (erule_tac x=1 in allE)
   105   apply simp
   106   apply safe
   107   apply (rule_tac x="X M" in exI)
   108   apply (rule_tac x=1 in exI)
   109   apply (erule_tac x=M in allE)
   110   apply simp
   111   apply (rule_tac x=M in exI)
   112   apply (auto simp: dist_commute)
   113   done
   114 
   115 
   116 subsubsection \<open>Bounded Sequences\<close>
   117 
   118 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   119   by (intro BfunI) (auto simp: eventually_sequentially)
   120 
   121 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   122   by (intro BfunI) (auto simp: eventually_sequentially)
   123 
   124 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   125   unfolding Bfun_def eventually_sequentially
   126 proof safe
   127   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   128   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   129     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   130        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   131 qed auto
   132 
   133 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   134 unfolding Bseq_def by auto
   135 
   136 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   137 by (simp add: Bseq_def)
   138 
   139 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   140 by (auto simp add: Bseq_def)
   141 
   142 lemma Bseq_bdd_above: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_above (range X)"
   143 proof (elim BseqE, intro bdd_aboveI2)
   144   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "X n \<le> K"
   145     by (auto elim!: allE[of _ n])
   146 qed
   147 
   148 lemma Bseq_bdd_above':
   149   "Bseq (X::nat \<Rightarrow> 'a :: real_normed_vector) \<Longrightarrow> bdd_above (range (\<lambda>n. norm (X n)))"
   150 proof (elim BseqE, intro bdd_aboveI2)
   151   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "norm (X n) \<le> K"
   152     by (auto elim!: allE[of _ n])
   153 qed
   154 
   155 lemma Bseq_bdd_below: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_below (range X)"
   156 proof (elim BseqE, intro bdd_belowI2)
   157   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "- K \<le> X n"
   158     by (auto elim!: allE[of _ n])
   159 qed
   160 
   161 lemma Bseq_eventually_mono:
   162   assumes "eventually (\<lambda>n. norm (f n) \<le> norm (g n)) sequentially" "Bseq g"
   163   shows   "Bseq f"
   164 proof -
   165   from assms(1) obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> norm (f n) \<le> norm (g n)"
   166     by (auto simp: eventually_at_top_linorder)
   167   moreover from assms(2) obtain K where K: "\<And>n. norm (g n) \<le> K" by (blast elim!: BseqE)
   168   ultimately have "norm (f n) \<le> max K (Max {norm (f n) |n. n < N})" for n
   169     apply (cases "n < N")
   170     apply (rule max.coboundedI2, rule Max.coboundedI, auto) []
   171     apply (rule max.coboundedI1, force intro: order.trans[OF N K])
   172     done
   173   thus ?thesis by (blast intro: BseqI')
   174 qed
   175 
   176 lemma lemma_NBseq_def:
   177   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   178 proof safe
   179   fix K :: real
   180   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   181   then have "K \<le> real (Suc n)" by auto
   182   moreover assume "\<forall>m. norm (X m) \<le> K"
   183   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   184     by (blast intro: order_trans)
   185   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   186 next
   187   show "\<And>N. \<forall>n. norm (X n) \<le> real (Suc N) \<Longrightarrow> \<exists>K>0. \<forall>n. norm (X n) \<le> K"
   188     using of_nat_0_less_iff by blast
   189 qed
   190 
   191 text\<open>alternative definition for Bseq\<close>
   192 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   193 apply (simp add: Bseq_def)
   194 apply (simp (no_asm) add: lemma_NBseq_def)
   195 done
   196 
   197 lemma lemma_NBseq_def2:
   198      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   199 apply (subst lemma_NBseq_def, auto)
   200 apply (rule_tac x = "Suc N" in exI)
   201 apply (rule_tac [2] x = N in exI)
   202 apply (auto simp add: of_nat_Suc)
   203  prefer 2 apply (blast intro: order_less_imp_le)
   204 apply (drule_tac x = n in spec, simp)
   205 done
   206 
   207 (* yet another definition for Bseq *)
   208 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   209 by (simp add: Bseq_def lemma_NBseq_def2)
   210 
   211 subsubsection\<open>A Few More Equivalence Theorems for Boundedness\<close>
   212 
   213 text\<open>alternative formulation for boundedness\<close>
   214 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   215 apply (unfold Bseq_def, safe)
   216 apply (rule_tac [2] x = "k + norm x" in exI)
   217 apply (rule_tac x = K in exI, simp)
   218 apply (rule exI [where x = 0], auto)
   219 apply (erule order_less_le_trans, simp)
   220 apply (drule_tac x=n in spec)
   221 apply (drule order_trans [OF norm_triangle_ineq2])
   222 apply simp
   223 done
   224 
   225 text\<open>alternative formulation for boundedness\<close>
   226 lemma Bseq_iff3:
   227   "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)" (is "?P \<longleftrightarrow> ?Q")
   228 proof
   229   assume ?P
   230   then obtain K
   231     where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K" by (auto simp add: Bseq_def)
   232   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   233   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   234     by (auto intro: order_trans norm_triangle_ineq4)
   235   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   236     by simp
   237   with \<open>0 < K + norm (X 0)\<close> show ?Q by blast
   238 next
   239   assume ?Q then show ?P by (auto simp add: Bseq_iff2)
   240 qed
   241 
   242 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   243 apply (simp add: Bseq_def)
   244 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   245 apply (drule_tac x = n in spec, arith)
   246 done
   247 
   248 
   249 subsubsection\<open>Upper Bounds and Lubs of Bounded Sequences\<close>
   250 
   251 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   252   by (simp add: Bseq_def)
   253 
   254 lemma Bseq_add:
   255   assumes "Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   256   shows   "Bseq (\<lambda>x. f x + c)"
   257 proof -
   258   from assms obtain K where K: "\<And>x. norm (f x) \<le> K" unfolding Bseq_def by blast
   259   {
   260     fix x :: nat
   261     have "norm (f x + c) \<le> norm (f x) + norm c" by (rule norm_triangle_ineq)
   262     also have "norm (f x) \<le> K" by (rule K)
   263     finally have "norm (f x + c) \<le> K + norm c" by simp
   264   }
   265   thus ?thesis by (rule BseqI')
   266 qed
   267 
   268 lemma Bseq_add_iff: "Bseq (\<lambda>x. f x + c) \<longleftrightarrow> Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   269   using Bseq_add[of f c] Bseq_add[of "\<lambda>x. f x + c" "-c"] by auto
   270 
   271 lemma Bseq_mult:
   272   assumes "Bseq (f :: nat \<Rightarrow> 'a :: real_normed_field)"
   273   assumes "Bseq (g :: nat \<Rightarrow> 'a :: real_normed_field)"
   274   shows   "Bseq (\<lambda>x. f x * g x)"
   275 proof -
   276   from assms obtain K1 K2 where K: "\<And>x. norm (f x) \<le> K1" "K1 > 0" "\<And>x. norm (g x) \<le> K2" "K2 > 0"
   277     unfolding Bseq_def by blast
   278   hence "\<And>x. norm (f x * g x) \<le> K1 * K2" by (auto simp: norm_mult intro!: mult_mono)
   279   thus ?thesis by (rule BseqI')
   280 qed
   281 
   282 lemma Bfun_const [simp]: "Bfun (\<lambda>_. c) F"
   283   unfolding Bfun_metric_def by (auto intro!: exI[of _ c] exI[of _ "1::real"])
   284 
   285 lemma Bseq_cmult_iff: "(c :: 'a :: real_normed_field) \<noteq> 0 \<Longrightarrow> Bseq (\<lambda>x. c * f x) \<longleftrightarrow> Bseq f"
   286 proof
   287   assume "c \<noteq> 0" "Bseq (\<lambda>x. c * f x)"
   288   find_theorems "Bfun (\<lambda>_. ?c) _"
   289   from Bfun_const this(2) have "Bseq (\<lambda>x. inverse c * (c * f x))" by (rule Bseq_mult)
   290   with \<open>c \<noteq> 0\<close> show "Bseq f" by (simp add: divide_simps)
   291 qed (intro Bseq_mult Bfun_const)
   292 
   293 lemma Bseq_subseq: "Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector) \<Longrightarrow> Bseq (\<lambda>x. f (g x))"
   294   unfolding Bseq_def by auto
   295 
   296 lemma Bseq_Suc_iff: "Bseq (\<lambda>n. f (Suc n)) \<longleftrightarrow> Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   297   using Bseq_offset[of f 1] by (auto intro: Bseq_subseq)
   298 
   299 lemma increasing_Bseq_subseq_iff:
   300   assumes "\<And>x y. x \<le> y \<Longrightarrow> norm (f x :: 'a :: real_normed_vector) \<le> norm (f y)" "subseq g"
   301   shows   "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   302 proof
   303   assume "Bseq (\<lambda>x. f (g x))"
   304   then obtain K where K: "\<And>x. norm (f (g x)) \<le> K" unfolding Bseq_def by auto
   305   {
   306     fix x :: nat
   307     from filterlim_subseq[OF assms(2)] obtain y where "g y \<ge> x"
   308       by (auto simp: filterlim_at_top eventually_at_top_linorder)
   309     hence "norm (f x) \<le> norm (f (g y))" using assms(1) by blast
   310     also have "norm (f (g y)) \<le> K" by (rule K)
   311     finally have "norm (f x) \<le> K" .
   312   }
   313   thus "Bseq f" by (rule BseqI')
   314 qed (insert Bseq_subseq[of f g], simp_all)
   315 
   316 lemma nonneg_incseq_Bseq_subseq_iff:
   317   assumes "\<And>x. f x \<ge> 0" "incseq (f :: nat \<Rightarrow> real)" "subseq g"
   318   shows   "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   319   using assms by (intro increasing_Bseq_subseq_iff) (auto simp: incseq_def)
   320 
   321 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   322   apply (simp add: subset_eq)
   323   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   324   apply (erule_tac x=n in allE)
   325   apply auto
   326   done
   327 
   328 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   329   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   330 
   331 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   332   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   333 
   334 subsection \<open>Bounded Monotonic Sequences\<close>
   335 
   336 subsubsection\<open>A Bounded and Monotonic Sequence Converges\<close>
   337 
   338 (* TODO: delete *)
   339 (* FIXME: one use in NSA/HSEQ.thy *)
   340 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X \<longlonglongrightarrow> L)"
   341   apply (rule_tac x="X m" in exI)
   342   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   343   unfolding eventually_sequentially
   344   apply blast
   345   done
   346 
   347 subsection \<open>Convergence to Zero\<close>
   348 
   349 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   350   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   351 
   352 lemma ZfunI:
   353   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   354   unfolding Zfun_def by simp
   355 
   356 lemma ZfunD:
   357   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   358   unfolding Zfun_def by simp
   359 
   360 lemma Zfun_ssubst:
   361   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   362   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   363 
   364 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   365   unfolding Zfun_def by simp
   366 
   367 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   368   unfolding Zfun_def by simp
   369 
   370 lemma Zfun_imp_Zfun:
   371   assumes f: "Zfun f F"
   372   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   373   shows "Zfun (\<lambda>x. g x) F"
   374 proof (cases)
   375   assume K: "0 < K"
   376   show ?thesis
   377   proof (rule ZfunI)
   378     fix r::real assume "0 < r"
   379     hence "0 < r / K" using K by simp
   380     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   381       using ZfunD [OF f] by blast
   382     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   383     proof eventually_elim
   384       case (elim x)
   385       hence "norm (f x) * K < r"
   386         by (simp add: pos_less_divide_eq K)
   387       thus ?case
   388         by (simp add: order_le_less_trans [OF elim(1)])
   389     qed
   390   qed
   391 next
   392   assume "\<not> 0 < K"
   393   hence K: "K \<le> 0" by (simp only: not_less)
   394   show ?thesis
   395   proof (rule ZfunI)
   396     fix r :: real
   397     assume "0 < r"
   398     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   399     proof eventually_elim
   400       case (elim x)
   401       also have "norm (f x) * K \<le> norm (f x) * 0"
   402         using K norm_ge_zero by (rule mult_left_mono)
   403       finally show ?case
   404         using \<open>0 < r\<close> by simp
   405     qed
   406   qed
   407 qed
   408 
   409 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   410   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   411 
   412 lemma Zfun_add:
   413   assumes f: "Zfun f F" and g: "Zfun g F"
   414   shows "Zfun (\<lambda>x. f x + g x) F"
   415 proof (rule ZfunI)
   416   fix r::real assume "0 < r"
   417   hence r: "0 < r / 2" by simp
   418   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   419     using f r by (rule ZfunD)
   420   moreover
   421   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   422     using g r by (rule ZfunD)
   423   ultimately
   424   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   425   proof eventually_elim
   426     case (elim x)
   427     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   428       by (rule norm_triangle_ineq)
   429     also have "\<dots> < r/2 + r/2"
   430       using elim by (rule add_strict_mono)
   431     finally show ?case
   432       by simp
   433   qed
   434 qed
   435 
   436 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   437   unfolding Zfun_def by simp
   438 
   439 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   440   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   441 
   442 lemma (in bounded_linear) Zfun:
   443   assumes g: "Zfun g F"
   444   shows "Zfun (\<lambda>x. f (g x)) F"
   445 proof -
   446   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   447     using bounded by blast
   448   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   449     by simp
   450   with g show ?thesis
   451     by (rule Zfun_imp_Zfun)
   452 qed
   453 
   454 lemma (in bounded_bilinear) Zfun:
   455   assumes f: "Zfun f F"
   456   assumes g: "Zfun g F"
   457   shows "Zfun (\<lambda>x. f x ** g x) F"
   458 proof (rule ZfunI)
   459   fix r::real assume r: "0 < r"
   460   obtain K where K: "0 < K"
   461     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   462     using pos_bounded by blast
   463   from K have K': "0 < inverse K"
   464     by (rule positive_imp_inverse_positive)
   465   have "eventually (\<lambda>x. norm (f x) < r) F"
   466     using f r by (rule ZfunD)
   467   moreover
   468   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   469     using g K' by (rule ZfunD)
   470   ultimately
   471   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   472   proof eventually_elim
   473     case (elim x)
   474     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   475       by (rule norm_le)
   476     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   477       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   478     also from K have "r * inverse K * K = r"
   479       by simp
   480     finally show ?case .
   481   qed
   482 qed
   483 
   484 lemma (in bounded_bilinear) Zfun_left:
   485   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   486   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   487 
   488 lemma (in bounded_bilinear) Zfun_right:
   489   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   490   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   491 
   492 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   493 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   494 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   495 
   496 lemma tendsto_Zfun_iff: "(f \<longlongrightarrow> a) F = Zfun (\<lambda>x. f x - a) F"
   497   by (simp only: tendsto_iff Zfun_def dist_norm)
   498 
   499 lemma tendsto_0_le: "\<lbrakk>(f \<longlongrightarrow> 0) F; eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F\<rbrakk>
   500                      \<Longrightarrow> (g \<longlongrightarrow> 0) F"
   501   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   502 
   503 subsubsection \<open>Distance and norms\<close>
   504 
   505 lemma tendsto_dist [tendsto_intros]:
   506   fixes l m :: "'a :: metric_space"
   507   assumes f: "(f \<longlongrightarrow> l) F" and g: "(g \<longlongrightarrow> m) F"
   508   shows "((\<lambda>x. dist (f x) (g x)) \<longlongrightarrow> dist l m) F"
   509 proof (rule tendstoI)
   510   fix e :: real assume "0 < e"
   511   hence e2: "0 < e/2" by simp
   512   from tendstoD [OF f e2] tendstoD [OF g e2]
   513   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   514   proof (eventually_elim)
   515     case (elim x)
   516     then show "dist (dist (f x) (g x)) (dist l m) < e"
   517       unfolding dist_real_def
   518       using dist_triangle2 [of "f x" "g x" "l"]
   519       using dist_triangle2 [of "g x" "l" "m"]
   520       using dist_triangle3 [of "l" "m" "f x"]
   521       using dist_triangle [of "f x" "m" "g x"]
   522       by arith
   523   qed
   524 qed
   525 
   526 lemma continuous_dist[continuous_intros]:
   527   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   528   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   529   unfolding continuous_def by (rule tendsto_dist)
   530 
   531 lemma continuous_on_dist[continuous_intros]:
   532   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   533   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   534   unfolding continuous_on_def by (auto intro: tendsto_dist)
   535 
   536 lemma tendsto_norm [tendsto_intros]:
   537   "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> norm a) F"
   538   unfolding norm_conv_dist by (intro tendsto_intros)
   539 
   540 lemma continuous_norm [continuous_intros]:
   541   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   542   unfolding continuous_def by (rule tendsto_norm)
   543 
   544 lemma continuous_on_norm [continuous_intros]:
   545   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   546   unfolding continuous_on_def by (auto intro: tendsto_norm)
   547 
   548 lemma tendsto_norm_zero:
   549   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F"
   550   by (drule tendsto_norm, simp)
   551 
   552 lemma tendsto_norm_zero_cancel:
   553   "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   554   unfolding tendsto_iff dist_norm by simp
   555 
   556 lemma tendsto_norm_zero_iff:
   557   "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   558   unfolding tendsto_iff dist_norm by simp
   559 
   560 lemma tendsto_rabs [tendsto_intros]:
   561   "(f \<longlongrightarrow> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> \<bar>l\<bar>) F"
   562   by (fold real_norm_def, rule tendsto_norm)
   563 
   564 lemma continuous_rabs [continuous_intros]:
   565   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   566   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   567 
   568 lemma continuous_on_rabs [continuous_intros]:
   569   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   570   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   571 
   572 lemma tendsto_rabs_zero:
   573   "(f \<longlongrightarrow> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> 0) F"
   574   by (fold real_norm_def, rule tendsto_norm_zero)
   575 
   576 lemma tendsto_rabs_zero_cancel:
   577   "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   578   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   579 
   580 lemma tendsto_rabs_zero_iff:
   581   "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   582   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   583 
   584 subsection \<open>Topological Monoid\<close>
   585 
   586 class topological_monoid_add = topological_space + monoid_add +
   587   assumes tendsto_add_Pair: "LIM x (nhds a \<times>\<^sub>F nhds b). fst x + snd x :> nhds (a + b)"
   588 
   589 class topological_comm_monoid_add = topological_monoid_add + comm_monoid_add
   590 
   591 lemma tendsto_add [tendsto_intros]:
   592   fixes a b :: "'a::topological_monoid_add"
   593   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> a + b) F"
   594   using filterlim_compose[OF tendsto_add_Pair, of "\<lambda>x. (f x, g x)" a b F]
   595   by (simp add: nhds_prod[symmetric] tendsto_Pair)
   596 
   597 lemma continuous_add [continuous_intros]:
   598   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   599   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   600   unfolding continuous_def by (rule tendsto_add)
   601 
   602 lemma continuous_on_add [continuous_intros]:
   603   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   604   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   605   unfolding continuous_on_def by (auto intro: tendsto_add)
   606 
   607 lemma tendsto_add_zero:
   608   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   609   shows "\<lbrakk>(f \<longlongrightarrow> 0) F; (g \<longlongrightarrow> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> 0) F"
   610   by (drule (1) tendsto_add, simp)
   611 
   612 lemma tendsto_setsum [tendsto_intros]:
   613   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::topological_comm_monoid_add"
   614   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> a i) F"
   615   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) \<longlongrightarrow> (\<Sum>i\<in>S. a i)) F"
   616 proof (cases "finite S")
   617   assume "finite S" thus ?thesis using assms
   618     by (induct, simp, simp add: tendsto_add)
   619 qed simp
   620 
   621 lemma continuous_setsum [continuous_intros]:
   622   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
   623   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   624   unfolding continuous_def by (rule tendsto_setsum)
   625 
   626 lemma continuous_on_setsum [continuous_intros]:
   627   fixes f :: "'a \<Rightarrow> 'b::topological_space \<Rightarrow> 'c::topological_comm_monoid_add"
   628   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   629   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   630 
   631 instance nat :: topological_comm_monoid_add
   632   proof qed (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
   633 
   634 instance int :: topological_comm_monoid_add
   635   proof qed (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
   636 
   637 subsubsection \<open>Addition and subtraction\<close>
   638 
   639 instance real_normed_vector < topological_comm_monoid_add
   640 proof
   641   fix a b :: 'a show "((\<lambda>x. fst x + snd x) \<longlongrightarrow> a + b) (nhds a \<times>\<^sub>F nhds b)"
   642     unfolding tendsto_Zfun_iff add_diff_add
   643     using tendsto_fst[OF filterlim_ident, of "(a,b)"] tendsto_snd[OF filterlim_ident, of "(a,b)"]
   644     by (intro Zfun_add)
   645        (auto simp add: tendsto_Zfun_iff[symmetric] nhds_prod[symmetric] intro!: tendsto_fst)
   646 qed
   647 
   648 lemma tendsto_minus [tendsto_intros]:
   649   fixes a :: "'a::real_normed_vector"
   650   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> - a) F"
   651   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   652 
   653 lemma continuous_minus [continuous_intros]:
   654   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   655   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   656   unfolding continuous_def by (rule tendsto_minus)
   657 
   658 lemma continuous_on_minus [continuous_intros]:
   659   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   660   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   661   unfolding continuous_on_def by (auto intro: tendsto_minus)
   662 
   663 lemma tendsto_minus_cancel:
   664   fixes a :: "'a::real_normed_vector"
   665   shows "((\<lambda>x. - f x) \<longlongrightarrow> - a) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
   666   by (drule tendsto_minus, simp)
   667 
   668 lemma tendsto_minus_cancel_left:
   669     "(f \<longlongrightarrow> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> y) F"
   670   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   671   by auto
   672 
   673 lemma tendsto_diff [tendsto_intros]:
   674   fixes a b :: "'a::real_normed_vector"
   675   shows "\<lbrakk>(f \<longlongrightarrow> a) F; (g \<longlongrightarrow> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> a - b) F"
   676   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   677 
   678 lemma continuous_diff [continuous_intros]:
   679   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   680   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   681   unfolding continuous_def by (rule tendsto_diff)
   682 
   683 lemma continuous_on_diff [continuous_intros]:
   684   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   685   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   686   unfolding continuous_on_def by (auto intro: tendsto_diff)
   687 
   688 lemma continuous_on_op_minus: "continuous_on (s::'a::real_normed_vector set) (op - x)"
   689   by (rule continuous_intros | simp)+
   690 
   691 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   692 
   693 subsubsection \<open>Linear operators and multiplication\<close>
   694 
   695 lemma linear_times:
   696   fixes c::"'a::real_algebra" shows "linear (\<lambda>x. c * x)"
   697   by (auto simp: linearI distrib_left)
   698 
   699 lemma (in bounded_linear) tendsto:
   700   "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> f a) F"
   701   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   702 
   703 lemma (in bounded_linear) continuous:
   704   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   705   using tendsto[of g _ F] by (auto simp: continuous_def)
   706 
   707 lemma (in bounded_linear) continuous_on:
   708   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   709   using tendsto[of g] by (auto simp: continuous_on_def)
   710 
   711 lemma (in bounded_linear) tendsto_zero:
   712   "(g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> 0) F"
   713   by (drule tendsto, simp only: zero)
   714 
   715 lemma (in bounded_bilinear) tendsto:
   716   "\<lbrakk>(f \<longlongrightarrow> a) F; (g \<longlongrightarrow> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) \<longlongrightarrow> a ** b) F"
   717   by (simp only: tendsto_Zfun_iff prod_diff_prod
   718                  Zfun_add Zfun Zfun_left Zfun_right)
   719 
   720 lemma (in bounded_bilinear) continuous:
   721   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   722   using tendsto[of f _ F g] by (auto simp: continuous_def)
   723 
   724 lemma (in bounded_bilinear) continuous_on:
   725   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   726   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   727 
   728 lemma (in bounded_bilinear) tendsto_zero:
   729   assumes f: "(f \<longlongrightarrow> 0) F"
   730   assumes g: "(g \<longlongrightarrow> 0) F"
   731   shows "((\<lambda>x. f x ** g x) \<longlongrightarrow> 0) F"
   732   using tendsto [OF f g] by (simp add: zero_left)
   733 
   734 lemma (in bounded_bilinear) tendsto_left_zero:
   735   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) \<longlongrightarrow> 0) F"
   736   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   737 
   738 lemma (in bounded_bilinear) tendsto_right_zero:
   739   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) \<longlongrightarrow> 0) F"
   740   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   741 
   742 lemmas tendsto_of_real [tendsto_intros] =
   743   bounded_linear.tendsto [OF bounded_linear_of_real]
   744 
   745 lemmas tendsto_scaleR [tendsto_intros] =
   746   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   747 
   748 lemmas tendsto_mult [tendsto_intros] =
   749   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   750 
   751 lemma tendsto_mult_left:
   752   fixes c::"'a::real_normed_algebra"
   753   shows "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. c * (f x)) \<longlongrightarrow> c * l) F"
   754 by (rule tendsto_mult [OF tendsto_const])
   755 
   756 lemma tendsto_mult_right:
   757   fixes c::"'a::real_normed_algebra"
   758   shows "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. (f x) * c) \<longlongrightarrow> l * c) F"
   759 by (rule tendsto_mult [OF _ tendsto_const])
   760 
   761 lemmas continuous_of_real [continuous_intros] =
   762   bounded_linear.continuous [OF bounded_linear_of_real]
   763 
   764 lemmas continuous_scaleR [continuous_intros] =
   765   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   766 
   767 lemmas continuous_mult [continuous_intros] =
   768   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   769 
   770 lemmas continuous_on_of_real [continuous_intros] =
   771   bounded_linear.continuous_on [OF bounded_linear_of_real]
   772 
   773 lemmas continuous_on_scaleR [continuous_intros] =
   774   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   775 
   776 lemmas continuous_on_mult [continuous_intros] =
   777   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   778 
   779 lemmas tendsto_mult_zero =
   780   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   781 
   782 lemmas tendsto_mult_left_zero =
   783   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   784 
   785 lemmas tendsto_mult_right_zero =
   786   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   787 
   788 lemma tendsto_power [tendsto_intros]:
   789   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   790   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) \<longlongrightarrow> a ^ n) F"
   791   by (induct n) (simp_all add: tendsto_mult)
   792 
   793 lemma continuous_power [continuous_intros]:
   794   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   795   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   796   unfolding continuous_def by (rule tendsto_power)
   797 
   798 lemma continuous_on_power [continuous_intros]:
   799   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   800   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   801   unfolding continuous_on_def by (auto intro: tendsto_power)
   802 
   803 lemma tendsto_setprod [tendsto_intros]:
   804   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   805   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> L i) F"
   806   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) \<longlongrightarrow> (\<Prod>i\<in>S. L i)) F"
   807 proof (cases "finite S")
   808   assume "finite S" thus ?thesis using assms
   809     by (induct, simp, simp add: tendsto_mult)
   810 qed simp
   811 
   812 lemma continuous_setprod [continuous_intros]:
   813   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   814   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   815   unfolding continuous_def by (rule tendsto_setprod)
   816 
   817 lemma continuous_on_setprod [continuous_intros]:
   818   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   819   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   820   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   821 
   822 lemma tendsto_of_real_iff:
   823   "((\<lambda>x. of_real (f x) :: 'a :: real_normed_div_algebra) \<longlongrightarrow> of_real c) F \<longleftrightarrow> (f \<longlongrightarrow> c) F"
   824   unfolding tendsto_iff by simp
   825 
   826 lemma tendsto_add_const_iff:
   827   "((\<lambda>x. c + f x :: 'a :: real_normed_vector) \<longlongrightarrow> c + d) F \<longleftrightarrow> (f \<longlongrightarrow> d) F"
   828   using tendsto_add[OF tendsto_const[of c], of f d]
   829         tendsto_add[OF tendsto_const[of "-c"], of "\<lambda>x. c + f x" "c + d"] by auto
   830 
   831 
   832 subsubsection \<open>Inverse and division\<close>
   833 
   834 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   835   assumes f: "Zfun f F"
   836   assumes g: "Bfun g F"
   837   shows "Zfun (\<lambda>x. f x ** g x) F"
   838 proof -
   839   obtain K where K: "0 \<le> K"
   840     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   841     using nonneg_bounded by blast
   842   obtain B where B: "0 < B"
   843     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   844     using g by (rule BfunE)
   845   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   846   using norm_g proof eventually_elim
   847     case (elim x)
   848     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   849       by (rule norm_le)
   850     also have "\<dots> \<le> norm (f x) * B * K"
   851       by (intro mult_mono' order_refl norm_g norm_ge_zero
   852                 mult_nonneg_nonneg K elim)
   853     also have "\<dots> = norm (f x) * (B * K)"
   854       by (rule mult.assoc)
   855     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   856   qed
   857   with f show ?thesis
   858     by (rule Zfun_imp_Zfun)
   859 qed
   860 
   861 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   862   assumes f: "Bfun f F"
   863   assumes g: "Zfun g F"
   864   shows "Zfun (\<lambda>x. f x ** g x) F"
   865   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   866 
   867 lemma Bfun_inverse_lemma:
   868   fixes x :: "'a::real_normed_div_algebra"
   869   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   870   apply (subst nonzero_norm_inverse, clarsimp)
   871   apply (erule (1) le_imp_inverse_le)
   872   done
   873 
   874 lemma Bfun_inverse:
   875   fixes a :: "'a::real_normed_div_algebra"
   876   assumes f: "(f \<longlongrightarrow> a) F"
   877   assumes a: "a \<noteq> 0"
   878   shows "Bfun (\<lambda>x. inverse (f x)) F"
   879 proof -
   880   from a have "0 < norm a" by simp
   881   hence "\<exists>r>0. r < norm a" by (rule dense)
   882   then obtain r where r1: "0 < r" and r2: "r < norm a" by blast
   883   have "eventually (\<lambda>x. dist (f x) a < r) F"
   884     using tendstoD [OF f r1] by blast
   885   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   886   proof eventually_elim
   887     case (elim x)
   888     hence 1: "norm (f x - a) < r"
   889       by (simp add: dist_norm)
   890     hence 2: "f x \<noteq> 0" using r2 by auto
   891     hence "norm (inverse (f x)) = inverse (norm (f x))"
   892       by (rule nonzero_norm_inverse)
   893     also have "\<dots> \<le> inverse (norm a - r)"
   894     proof (rule le_imp_inverse_le)
   895       show "0 < norm a - r" using r2 by simp
   896     next
   897       have "norm a - norm (f x) \<le> norm (a - f x)"
   898         by (rule norm_triangle_ineq2)
   899       also have "\<dots> = norm (f x - a)"
   900         by (rule norm_minus_commute)
   901       also have "\<dots> < r" using 1 .
   902       finally show "norm a - r \<le> norm (f x)" by simp
   903     qed
   904     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   905   qed
   906   thus ?thesis by (rule BfunI)
   907 qed
   908 
   909 lemma tendsto_inverse [tendsto_intros]:
   910   fixes a :: "'a::real_normed_div_algebra"
   911   assumes f: "(f \<longlongrightarrow> a) F"
   912   assumes a: "a \<noteq> 0"
   913   shows "((\<lambda>x. inverse (f x)) \<longlongrightarrow> inverse a) F"
   914 proof -
   915   from a have "0 < norm a" by simp
   916   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   917     by (rule tendstoD)
   918   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   919     unfolding dist_norm by (auto elim!: eventually_mono)
   920   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   921     - (inverse (f x) * (f x - a) * inverse a)) F"
   922     by (auto elim!: eventually_mono simp: inverse_diff_inverse)
   923   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   924     by (intro Zfun_minus Zfun_mult_left
   925       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   926       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   927   ultimately show ?thesis
   928     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   929 qed
   930 
   931 lemma continuous_inverse:
   932   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   933   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   934   shows "continuous F (\<lambda>x. inverse (f x))"
   935   using assms unfolding continuous_def by (rule tendsto_inverse)
   936 
   937 lemma continuous_at_within_inverse[continuous_intros]:
   938   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   939   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   940   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   941   using assms unfolding continuous_within by (rule tendsto_inverse)
   942 
   943 lemma isCont_inverse[continuous_intros, simp]:
   944   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   945   assumes "isCont f a" and "f a \<noteq> 0"
   946   shows "isCont (\<lambda>x. inverse (f x)) a"
   947   using assms unfolding continuous_at by (rule tendsto_inverse)
   948 
   949 lemma continuous_on_inverse[continuous_intros]:
   950   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   951   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   952   shows "continuous_on s (\<lambda>x. inverse (f x))"
   953   using assms unfolding continuous_on_def by (blast intro: tendsto_inverse)
   954 
   955 lemma tendsto_divide [tendsto_intros]:
   956   fixes a b :: "'a::real_normed_field"
   957   shows "\<lbrakk>(f \<longlongrightarrow> a) F; (g \<longlongrightarrow> b) F; b \<noteq> 0\<rbrakk>
   958     \<Longrightarrow> ((\<lambda>x. f x / g x) \<longlongrightarrow> a / b) F"
   959   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   960 
   961 lemma continuous_divide:
   962   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   963   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   964   shows "continuous F (\<lambda>x. (f x) / (g x))"
   965   using assms unfolding continuous_def by (rule tendsto_divide)
   966 
   967 lemma continuous_at_within_divide[continuous_intros]:
   968   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   969   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   970   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   971   using assms unfolding continuous_within by (rule tendsto_divide)
   972 
   973 lemma isCont_divide[continuous_intros, simp]:
   974   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   975   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   976   shows "isCont (\<lambda>x. (f x) / g x) a"
   977   using assms unfolding continuous_at by (rule tendsto_divide)
   978 
   979 lemma continuous_on_divide[continuous_intros]:
   980   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   981   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   982   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   983   using assms unfolding continuous_on_def by (blast intro: tendsto_divide)
   984 
   985 lemma tendsto_sgn [tendsto_intros]:
   986   fixes l :: "'a::real_normed_vector"
   987   shows "\<lbrakk>(f \<longlongrightarrow> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) \<longlongrightarrow> sgn l) F"
   988   unfolding sgn_div_norm by (simp add: tendsto_intros)
   989 
   990 lemma continuous_sgn:
   991   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   992   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   993   shows "continuous F (\<lambda>x. sgn (f x))"
   994   using assms unfolding continuous_def by (rule tendsto_sgn)
   995 
   996 lemma continuous_at_within_sgn[continuous_intros]:
   997   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   998   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   999   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
  1000   using assms unfolding continuous_within by (rule tendsto_sgn)
  1001 
  1002 lemma isCont_sgn[continuous_intros]:
  1003   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1004   assumes "isCont f a" and "f a \<noteq> 0"
  1005   shows "isCont (\<lambda>x. sgn (f x)) a"
  1006   using assms unfolding continuous_at by (rule tendsto_sgn)
  1007 
  1008 lemma continuous_on_sgn[continuous_intros]:
  1009   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1010   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
  1011   shows "continuous_on s (\<lambda>x. sgn (f x))"
  1012   using assms unfolding continuous_on_def by (blast intro: tendsto_sgn)
  1013 
  1014 lemma filterlim_at_infinity:
  1015   fixes f :: "_ \<Rightarrow> 'a::real_normed_vector"
  1016   assumes "0 \<le> c"
  1017   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
  1018   unfolding filterlim_iff eventually_at_infinity
  1019 proof safe
  1020   fix P :: "'a \<Rightarrow> bool" and b
  1021   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
  1022     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
  1023   have "max b (c + 1) > c" by auto
  1024   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
  1025     by auto
  1026   then show "eventually (\<lambda>x. P (f x)) F"
  1027   proof eventually_elim
  1028     fix x assume "max b (c + 1) \<le> norm (f x)"
  1029     with P show "P (f x)" by auto
  1030   qed
  1031 qed force
  1032 
  1033 lemma not_tendsto_and_filterlim_at_infinity:
  1034   assumes "F \<noteq> bot"
  1035   assumes "(f \<longlongrightarrow> (c :: 'a :: real_normed_vector)) F"
  1036   assumes "filterlim f at_infinity F"
  1037   shows   False
  1038 proof -
  1039   from tendstoD[OF assms(2), of "1/2"]
  1040     have "eventually (\<lambda>x. dist (f x) c < 1/2) F" by simp
  1041   moreover from filterlim_at_infinity[of "norm c" f F] assms(3)
  1042     have "eventually (\<lambda>x. norm (f x) \<ge> norm c + 1) F" by simp
  1043   ultimately have "eventually (\<lambda>x. False) F"
  1044   proof eventually_elim
  1045     fix x assume A: "dist (f x) c < 1/2" and B: "norm (f x) \<ge> norm c + 1"
  1046     note B
  1047     also have "norm (f x) = dist (f x) 0" by simp
  1048     also have "... \<le> dist (f x) c + dist c 0" by (rule dist_triangle)
  1049     finally show False using A by simp
  1050   qed
  1051   with assms show False by simp
  1052 qed
  1053 
  1054 lemma filterlim_at_infinity_imp_not_convergent:
  1055   assumes "filterlim f at_infinity sequentially"
  1056   shows   "\<not>convergent f"
  1057   by (rule notI, rule not_tendsto_and_filterlim_at_infinity[OF _ _ assms])
  1058      (simp_all add: convergent_LIMSEQ_iff)
  1059 
  1060 lemma filterlim_at_infinity_imp_eventually_ne:
  1061   assumes "filterlim f at_infinity F"
  1062   shows   "eventually (\<lambda>z. f z \<noteq> c) F"
  1063 proof -
  1064   have "norm c + 1 > 0" by (intro add_nonneg_pos) simp_all
  1065   with filterlim_at_infinity[OF order.refl, of f F] assms
  1066     have "eventually (\<lambda>z. norm (f z) \<ge> norm c + 1) F" by blast
  1067   thus ?thesis by eventually_elim auto
  1068 qed
  1069 
  1070 lemma tendsto_of_nat [tendsto_intros]:
  1071   "filterlim (of_nat :: nat \<Rightarrow> 'a :: real_normed_algebra_1) at_infinity sequentially"
  1072 proof (subst filterlim_at_infinity[OF order.refl], intro allI impI)
  1073   fix r :: real
  1074   assume r: "r > 0"
  1075   define n where "n = nat \<lceil>r\<rceil>"
  1076   from r have n: "\<forall>m\<ge>n. of_nat m \<ge> r" unfolding n_def by linarith
  1077   from eventually_ge_at_top[of n] show "eventually (\<lambda>m. norm (of_nat m :: 'a) \<ge> r) sequentially"
  1078     by eventually_elim (insert n, simp_all)
  1079 qed
  1080 
  1081 
  1082 subsection \<open>Relate @{const at}, @{const at_left} and @{const at_right}\<close>
  1083 
  1084 text \<open>
  1085 
  1086 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
  1087 @{term "at_right x"} and also @{term "at_right 0"}.
  1088 
  1089 \<close>
  1090 
  1091 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
  1092 
  1093 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
  1094   by (rule filtermap_fun_inverse[where g="\<lambda>x. x + d"])
  1095      (auto intro!: tendsto_eq_intros filterlim_ident)
  1096 
  1097 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
  1098   by (rule filtermap_fun_inverse[where g=uminus])
  1099      (auto intro!: tendsto_eq_intros filterlim_ident)
  1100 
  1101 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
  1102   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1103 
  1104 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
  1105   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1106 
  1107 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
  1108   using filtermap_at_right_shift[of "-a" 0] by simp
  1109 
  1110 lemma filterlim_at_right_to_0:
  1111   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
  1112   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
  1113 
  1114 lemma eventually_at_right_to_0:
  1115   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
  1116   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
  1117 
  1118 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
  1119   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1120 
  1121 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
  1122   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1123 
  1124 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
  1125   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1126 
  1127 lemma filterlim_at_left_to_right:
  1128   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
  1129   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
  1130 
  1131 lemma eventually_at_left_to_right:
  1132   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
  1133   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
  1134 
  1135 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
  1136   unfolding filterlim_at_top eventually_at_bot_dense
  1137   by (metis leI minus_less_iff order_less_asym)
  1138 
  1139 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
  1140   unfolding filterlim_at_bot eventually_at_top_dense
  1141   by (metis leI less_minus_iff order_less_asym)
  1142 
  1143 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
  1144   by (rule filtermap_fun_inverse[symmetric, of uminus])
  1145      (auto intro: filterlim_uminus_at_bot_at_top filterlim_uminus_at_top_at_bot)
  1146 
  1147 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
  1148   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
  1149 
  1150 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
  1151   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
  1152 
  1153 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
  1154   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
  1155 
  1156 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
  1157   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
  1158   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
  1159   by auto
  1160 
  1161 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
  1162   unfolding filterlim_uminus_at_top by simp
  1163 
  1164 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
  1165   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
  1166 proof safe
  1167   fix Z :: real assume [arith]: "0 < Z"
  1168   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1169     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1170   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1171     by (auto elim!: eventually_mono simp: inverse_eq_divide field_simps)
  1172 qed
  1173 
  1174 lemma tendsto_inverse_0:
  1175   fixes x :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
  1176   shows "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1177   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1178 proof safe
  1179   fix r :: real assume "0 < r"
  1180   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1181   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1182     fix x :: 'a
  1183     from \<open>0 < r\<close> have "0 < inverse (r / 2)" by simp
  1184     also assume *: "inverse (r / 2) \<le> norm x"
  1185     finally show "norm (inverse x) < r"
  1186       using * \<open>0 < r\<close> by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1187   qed
  1188 qed
  1189 
  1190 lemma tendsto_add_filterlim_at_infinity:
  1191   assumes "(f \<longlongrightarrow> (c :: 'b :: real_normed_vector)) (F :: 'a filter)"
  1192   assumes "filterlim g at_infinity F"
  1193   shows   "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1194 proof (subst filterlim_at_infinity[OF order_refl], safe)
  1195   fix r :: real assume r: "r > 0"
  1196   from assms(1) have "((\<lambda>x. norm (f x)) \<longlongrightarrow> norm c) F" by (rule tendsto_norm)
  1197   hence "eventually (\<lambda>x. norm (f x) < norm c + 1) F" by (rule order_tendstoD) simp_all
  1198   moreover from r have "r + norm c + 1 > 0" by (intro add_pos_nonneg) simp_all
  1199   with assms(2) have "eventually (\<lambda>x. norm (g x) \<ge> r + norm c + 1) F"
  1200     unfolding filterlim_at_infinity[OF order_refl] by (elim allE[of _ "r + norm c + 1"]) simp_all
  1201   ultimately show "eventually (\<lambda>x. norm (f x + g x) \<ge> r) F"
  1202   proof eventually_elim
  1203     fix x :: 'a assume A: "norm (f x) < norm c + 1" and B: "r + norm c + 1 \<le> norm (g x)"
  1204     from A B have "r \<le> norm (g x) - norm (f x)" by simp
  1205     also have "norm (g x) - norm (f x) \<le> norm (g x + f x)" by (rule norm_diff_ineq)
  1206     finally show "r \<le> norm (f x + g x)" by (simp add: add_ac)
  1207   qed
  1208 qed
  1209 
  1210 lemma tendsto_add_filterlim_at_infinity':
  1211   assumes "filterlim f at_infinity F"
  1212   assumes "(g \<longlongrightarrow> (c :: 'b :: real_normed_vector)) (F :: 'a filter)"
  1213   shows   "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1214   by (subst add.commute) (rule tendsto_add_filterlim_at_infinity assms)+
  1215 
  1216 lemma filterlim_inverse_at_right_top: "LIM x at_top. inverse x :> at_right (0::real)"
  1217   unfolding filterlim_at
  1218   by (auto simp: eventually_at_top_dense)
  1219      (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1220 
  1221 lemma filterlim_inverse_at_top:
  1222   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1223   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1224      (simp add: filterlim_def eventually_filtermap eventually_mono at_within_def le_principal)
  1225 
  1226 lemma filterlim_inverse_at_bot_neg:
  1227   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1228   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1229 
  1230 lemma filterlim_inverse_at_bot:
  1231   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1232   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1233   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1234 
  1235 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1236   by (intro filtermap_fun_inverse[symmetric, where g=inverse])
  1237      (auto intro: filterlim_inverse_at_top_right filterlim_inverse_at_right_top)
  1238 
  1239 lemma eventually_at_right_to_top:
  1240   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1241   unfolding at_right_to_top eventually_filtermap ..
  1242 
  1243 lemma filterlim_at_right_to_top:
  1244   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1245   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1246 
  1247 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1248   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1249 
  1250 lemma eventually_at_top_to_right:
  1251   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1252   unfolding at_top_to_right eventually_filtermap ..
  1253 
  1254 lemma filterlim_at_top_to_right:
  1255   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1256   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1257 
  1258 lemma filterlim_inverse_at_infinity:
  1259   fixes x :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1260   shows "filterlim inverse at_infinity (at (0::'a))"
  1261   unfolding filterlim_at_infinity[OF order_refl]
  1262 proof safe
  1263   fix r :: real assume "0 < r"
  1264   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1265     unfolding eventually_at norm_inverse
  1266     by (intro exI[of _ "inverse r"])
  1267        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1268 qed
  1269 
  1270 lemma filterlim_inverse_at_iff:
  1271   fixes g :: "'a \<Rightarrow> 'b::{real_normed_div_algebra, division_ring}"
  1272   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1273   unfolding filterlim_def filtermap_filtermap[symmetric]
  1274 proof
  1275   assume "filtermap g F \<le> at_infinity"
  1276   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1277     by (rule filtermap_mono)
  1278   also have "\<dots> \<le> at 0"
  1279     using tendsto_inverse_0[where 'a='b]
  1280     by (auto intro!: exI[of _ 1]
  1281              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1282   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1283 next
  1284   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1285   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1286     by (rule filtermap_mono)
  1287   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1288     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1289 qed
  1290 
  1291 lemma tendsto_mult_filterlim_at_infinity:
  1292   assumes "F \<noteq> bot" "(f \<longlongrightarrow> (c :: 'a :: real_normed_field)) F" "c \<noteq> 0"
  1293   assumes "filterlim g at_infinity F"
  1294   shows   "filterlim (\<lambda>x. f x * g x) at_infinity F"
  1295 proof -
  1296   have "((\<lambda>x. inverse (f x) * inverse (g x)) \<longlongrightarrow> inverse c * 0) F"
  1297     by (intro tendsto_mult tendsto_inverse assms filterlim_compose[OF tendsto_inverse_0])
  1298   hence "filterlim (\<lambda>x. inverse (f x) * inverse (g x)) (at (inverse c * 0)) F"
  1299     unfolding filterlim_at using assms
  1300     by (auto intro: filterlim_at_infinity_imp_eventually_ne tendsto_imp_eventually_ne eventually_conj)
  1301   thus ?thesis by (subst filterlim_inverse_at_iff[symmetric]) simp_all
  1302 qed
  1303 
  1304 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) \<longlongrightarrow> 0) F"
  1305  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1306 
  1307 lemma mult_nat_left_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. c * x :: nat) at_top sequentially"
  1308   by (rule filterlim_subseq) (auto simp: subseq_def)
  1309 
  1310 lemma mult_nat_right_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. x * c :: nat) at_top sequentially"
  1311   by (rule filterlim_subseq) (auto simp: subseq_def)
  1312 
  1313 lemma at_to_infinity:
  1314   fixes x :: "'a :: {real_normed_field,field}"
  1315   shows "(at (0::'a)) = filtermap inverse at_infinity"
  1316 proof (rule antisym)
  1317   have "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1318     by (fact tendsto_inverse_0)
  1319   then show "filtermap inverse at_infinity \<le> at (0::'a)"
  1320     apply (simp add: le_principal eventually_filtermap eventually_at_infinity filterlim_def at_within_def)
  1321     apply (rule_tac x="1" in exI, auto)
  1322     done
  1323 next
  1324   have "filtermap inverse (filtermap inverse (at (0::'a))) \<le> filtermap inverse at_infinity"
  1325     using filterlim_inverse_at_infinity unfolding filterlim_def
  1326     by (rule filtermap_mono)
  1327   then show "at (0::'a) \<le> filtermap inverse at_infinity"
  1328     by (simp add: filtermap_ident filtermap_filtermap)
  1329 qed
  1330 
  1331 lemma lim_at_infinity_0:
  1332   fixes l :: "'a :: {real_normed_field,field}"
  1333   shows "(f \<longlongrightarrow> l) at_infinity \<longleftrightarrow> ((f o inverse) \<longlongrightarrow> l) (at (0::'a))"
  1334 by (simp add: tendsto_compose_filtermap at_to_infinity filtermap_filtermap)
  1335 
  1336 lemma lim_zero_infinity:
  1337   fixes l :: "'a :: {real_normed_field,field}"
  1338   shows "((\<lambda>x. f(1 / x)) \<longlongrightarrow> l) (at (0::'a)) \<Longrightarrow> (f \<longlongrightarrow> l) at_infinity"
  1339 by (simp add: inverse_eq_divide lim_at_infinity_0 comp_def)
  1340 
  1341 
  1342 text \<open>
  1343 
  1344 We only show rules for multiplication and addition when the functions are either against a real
  1345 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1346 
  1347 \<close>
  1348 
  1349 lemma filterlim_tendsto_pos_mult_at_top:
  1350   assumes f: "(f \<longlongrightarrow> c) F" and c: "0 < c"
  1351   assumes g: "LIM x F. g x :> at_top"
  1352   shows "LIM x F. (f x * g x :: real) :> at_top"
  1353   unfolding filterlim_at_top_gt[where c=0]
  1354 proof safe
  1355   fix Z :: real assume "0 < Z"
  1356   from f \<open>0 < c\<close> have "eventually (\<lambda>x. c / 2 < f x) F"
  1357     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_mono
  1358              simp: dist_real_def abs_real_def split: if_split_asm)
  1359   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1360     unfolding filterlim_at_top by auto
  1361   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1362   proof eventually_elim
  1363     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1364     with \<open>0 < Z\<close> \<open>0 < c\<close> have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1365       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1366     with \<open>0 < c\<close> show "Z \<le> f x * g x"
  1367        by simp
  1368   qed
  1369 qed
  1370 
  1371 lemma filterlim_at_top_mult_at_top:
  1372   assumes f: "LIM x F. f x :> at_top"
  1373   assumes g: "LIM x F. g x :> at_top"
  1374   shows "LIM x F. (f x * g x :: real) :> at_top"
  1375   unfolding filterlim_at_top_gt[where c=0]
  1376 proof safe
  1377   fix Z :: real assume "0 < Z"
  1378   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1379     unfolding filterlim_at_top by auto
  1380   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1381     unfolding filterlim_at_top by auto
  1382   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1383   proof eventually_elim
  1384     fix x assume "1 \<le> f x" "Z \<le> g x"
  1385     with \<open>0 < Z\<close> have "1 * Z \<le> f x * g x"
  1386       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1387     then show "Z \<le> f x * g x"
  1388        by simp
  1389   qed
  1390 qed
  1391 
  1392 lemma filterlim_tendsto_pos_mult_at_bot:
  1393   assumes "(f \<longlongrightarrow> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1394   shows "LIM x F. f x * g x :> at_bot"
  1395   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1396   unfolding filterlim_uminus_at_bot by simp
  1397 
  1398 lemma filterlim_tendsto_neg_mult_at_bot:
  1399   assumes c: "(f \<longlongrightarrow> c) F" "(c::real) < 0" and g: "filterlim g at_top F"
  1400   shows "LIM x F. f x * g x :> at_bot"
  1401   using c filterlim_tendsto_pos_mult_at_top[of "\<lambda>x. - f x" "- c" F, OF _ _ g]
  1402   unfolding filterlim_uminus_at_bot tendsto_minus_cancel_left by simp
  1403 
  1404 lemma filterlim_pow_at_top:
  1405   fixes f :: "real \<Rightarrow> real"
  1406   assumes "0 < n" and f: "LIM x F. f x :> at_top"
  1407   shows "LIM x F. (f x)^n :: real :> at_top"
  1408 using \<open>0 < n\<close> proof (induct n)
  1409   case (Suc n) with f show ?case
  1410     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1411 qed simp
  1412 
  1413 lemma filterlim_pow_at_bot_even:
  1414   fixes f :: "real \<Rightarrow> real"
  1415   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1416   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1417 
  1418 lemma filterlim_pow_at_bot_odd:
  1419   fixes f :: "real \<Rightarrow> real"
  1420   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1421   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1422 
  1423 lemma filterlim_tendsto_add_at_top:
  1424   assumes f: "(f \<longlongrightarrow> c) F"
  1425   assumes g: "LIM x F. g x :> at_top"
  1426   shows "LIM x F. (f x + g x :: real) :> at_top"
  1427   unfolding filterlim_at_top_gt[where c=0]
  1428 proof safe
  1429   fix Z :: real assume "0 < Z"
  1430   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1431     by (auto dest!: tendstoD[where e=1] elim!: eventually_mono simp: dist_real_def)
  1432   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1433     unfolding filterlim_at_top by auto
  1434   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1435     by eventually_elim simp
  1436 qed
  1437 
  1438 lemma LIM_at_top_divide:
  1439   fixes f g :: "'a \<Rightarrow> real"
  1440   assumes f: "(f \<longlongrightarrow> a) F" "0 < a"
  1441   assumes g: "(g \<longlongrightarrow> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1442   shows "LIM x F. f x / g x :> at_top"
  1443   unfolding divide_inverse
  1444   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1445 
  1446 lemma filterlim_at_top_add_at_top:
  1447   assumes f: "LIM x F. f x :> at_top"
  1448   assumes g: "LIM x F. g x :> at_top"
  1449   shows "LIM x F. (f x + g x :: real) :> at_top"
  1450   unfolding filterlim_at_top_gt[where c=0]
  1451 proof safe
  1452   fix Z :: real assume "0 < Z"
  1453   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1454     unfolding filterlim_at_top by auto
  1455   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1456     unfolding filterlim_at_top by auto
  1457   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1458     by eventually_elim simp
  1459 qed
  1460 
  1461 lemma tendsto_divide_0:
  1462   fixes f :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1463   assumes f: "(f \<longlongrightarrow> c) F"
  1464   assumes g: "LIM x F. g x :> at_infinity"
  1465   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
  1466   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1467 
  1468 lemma linear_plus_1_le_power:
  1469   fixes x :: real
  1470   assumes x: "0 \<le> x"
  1471   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1472 proof (induct n)
  1473   case (Suc n)
  1474   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1475     by (simp add: field_simps of_nat_Suc x)
  1476   also have "\<dots> \<le> (x + 1)^Suc n"
  1477     using Suc x by (simp add: mult_left_mono)
  1478   finally show ?case .
  1479 qed simp
  1480 
  1481 lemma filterlim_realpow_sequentially_gt1:
  1482   fixes x :: "'a :: real_normed_div_algebra"
  1483   assumes x[arith]: "1 < norm x"
  1484   shows "LIM n sequentially. x ^ n :> at_infinity"
  1485 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1486   fix y :: real assume "0 < y"
  1487   have "0 < norm x - 1" by simp
  1488   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1489   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1490   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1491   also have "\<dots> = norm x ^ N" by simp
  1492   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1493     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1494   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1495     unfolding eventually_sequentially
  1496     by (auto simp: norm_power)
  1497 qed simp
  1498 
  1499 
  1500 subsection \<open>Limits of Sequences\<close>
  1501 
  1502 lemma [trans]: "X = Y \<Longrightarrow> Y \<longlonglongrightarrow> z \<Longrightarrow> X \<longlonglongrightarrow> z"
  1503   by simp
  1504 
  1505 lemma LIMSEQ_iff:
  1506   fixes L :: "'a::real_normed_vector"
  1507   shows "(X \<longlonglongrightarrow> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1508 unfolding lim_sequentially dist_norm ..
  1509 
  1510 lemma LIMSEQ_I:
  1511   fixes L :: "'a::real_normed_vector"
  1512   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X \<longlonglongrightarrow> L"
  1513 by (simp add: LIMSEQ_iff)
  1514 
  1515 lemma LIMSEQ_D:
  1516   fixes L :: "'a::real_normed_vector"
  1517   shows "\<lbrakk>X \<longlonglongrightarrow> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1518 by (simp add: LIMSEQ_iff)
  1519 
  1520 lemma LIMSEQ_linear: "\<lbrakk> X \<longlonglongrightarrow> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) \<longlonglongrightarrow> x"
  1521   unfolding tendsto_def eventually_sequentially
  1522   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
  1523 
  1524 lemma Bseq_inverse_lemma:
  1525   fixes x :: "'a::real_normed_div_algebra"
  1526   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1527 apply (subst nonzero_norm_inverse, clarsimp)
  1528 apply (erule (1) le_imp_inverse_le)
  1529 done
  1530 
  1531 lemma Bseq_inverse:
  1532   fixes a :: "'a::real_normed_div_algebra"
  1533   shows "\<lbrakk>X \<longlonglongrightarrow> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1534   by (rule Bfun_inverse)
  1535 
  1536 text\<open>Transformation of limit.\<close>
  1537 
  1538 lemma Lim_transform:
  1539   fixes a b :: "'a::real_normed_vector"
  1540   shows "\<lbrakk>(g \<longlongrightarrow> a) F; ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F\<rbrakk> \<Longrightarrow> (f \<longlongrightarrow> a) F"
  1541   using tendsto_add [of g a F "\<lambda>x. f x - g x" 0] by simp
  1542 
  1543 lemma Lim_transform2:
  1544   fixes a b :: "'a::real_normed_vector"
  1545   shows "\<lbrakk>(f \<longlongrightarrow> a) F; ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F\<rbrakk> \<Longrightarrow> (g \<longlongrightarrow> a) F"
  1546   by (erule Lim_transform) (simp add: tendsto_minus_cancel)
  1547 
  1548 proposition Lim_transform_eq:
  1549   fixes a :: "'a::real_normed_vector"
  1550   shows "((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> a) F \<longleftrightarrow> (g \<longlongrightarrow> a) F"
  1551 using Lim_transform Lim_transform2 by blast
  1552 
  1553 lemma Lim_transform_eventually:
  1554   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> (g \<longlongrightarrow> l) net"
  1555   apply (rule topological_tendstoI)
  1556   apply (drule (2) topological_tendstoD)
  1557   apply (erule (1) eventually_elim2, simp)
  1558   done
  1559 
  1560 lemma Lim_transform_within:
  1561   assumes "(f \<longlongrightarrow> l) (at x within S)"
  1562     and "0 < d"
  1563     and "\<And>x'. \<lbrakk>x'\<in>S; 0 < dist x' x; dist x' x < d\<rbrakk> \<Longrightarrow> f x' = g x'"
  1564   shows "(g \<longlongrightarrow> l) (at x within S)"
  1565 proof (rule Lim_transform_eventually)
  1566   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1567     using assms by (auto simp: eventually_at)
  1568   show "(f \<longlongrightarrow> l) (at x within S)" by fact
  1569 qed
  1570 
  1571 text\<open>Common case assuming being away from some crucial point like 0.\<close>
  1572 
  1573 lemma Lim_transform_away_within:
  1574   fixes a b :: "'a::t1_space"
  1575   assumes "a \<noteq> b"
  1576     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1577     and "(f \<longlongrightarrow> l) (at a within S)"
  1578   shows "(g \<longlongrightarrow> l) (at a within S)"
  1579 proof (rule Lim_transform_eventually)
  1580   show "(f \<longlongrightarrow> l) (at a within S)" by fact
  1581   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1582     unfolding eventually_at_topological
  1583     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1584 qed
  1585 
  1586 lemma Lim_transform_away_at:
  1587   fixes a b :: "'a::t1_space"
  1588   assumes ab: "a\<noteq>b"
  1589     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1590     and fl: "(f \<longlongrightarrow> l) (at a)"
  1591   shows "(g \<longlongrightarrow> l) (at a)"
  1592   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  1593 
  1594 text\<open>Alternatively, within an open set.\<close>
  1595 
  1596 lemma Lim_transform_within_open:
  1597   assumes "(f \<longlongrightarrow> l) (at a within T)"
  1598     and "open s" and "a \<in> s"
  1599     and "\<And>x. \<lbrakk>x\<in>s; x \<noteq> a\<rbrakk> \<Longrightarrow> f x = g x"
  1600   shows "(g \<longlongrightarrow> l) (at a within T)"
  1601 proof (rule Lim_transform_eventually)
  1602   show "eventually (\<lambda>x. f x = g x) (at a within T)"
  1603     unfolding eventually_at_topological
  1604     using assms by auto
  1605   show "(f \<longlongrightarrow> l) (at a within T)" by fact
  1606 qed
  1607 
  1608 text\<open>A congruence rule allowing us to transform limits assuming not at point.\<close>
  1609 
  1610 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1611 
  1612 lemma Lim_cong_within(*[cong add]*):
  1613   assumes "a = b"
  1614     and "x = y"
  1615     and "S = T"
  1616     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1617   shows "(f \<longlongrightarrow> x) (at a within S) \<longleftrightarrow> (g \<longlongrightarrow> y) (at b within T)"
  1618   unfolding tendsto_def eventually_at_topological
  1619   using assms by simp
  1620 
  1621 lemma Lim_cong_at(*[cong add]*):
  1622   assumes "a = b" "x = y"
  1623     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1624   shows "((\<lambda>x. f x) \<longlongrightarrow> x) (at a) \<longleftrightarrow> ((g \<longlongrightarrow> y) (at a))"
  1625   unfolding tendsto_def eventually_at_topological
  1626   using assms by simp
  1627 text\<open>An unbounded sequence's inverse tends to 0\<close>
  1628 
  1629 lemma LIMSEQ_inverse_zero:
  1630   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) \<longlonglongrightarrow> 0"
  1631   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1632   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1633   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1634   done
  1635 
  1636 text\<open>The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity\<close>
  1637 
  1638 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) \<longlonglongrightarrow> 0"
  1639   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1640             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1641 
  1642 text\<open>The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1643 infinity is now easily proved\<close>
  1644 
  1645 lemma LIMSEQ_inverse_real_of_nat_add:
  1646      "(%n. r + inverse(real(Suc n))) \<longlonglongrightarrow> r"
  1647   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1648 
  1649 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1650      "(%n. r + -inverse(real(Suc n))) \<longlonglongrightarrow> r"
  1651   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1652   by auto
  1653 
  1654 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1655      "(%n. r*( 1 + -inverse(real(Suc n)))) \<longlonglongrightarrow> r"
  1656   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1657   by auto
  1658 
  1659 lemma lim_inverse_n: "((\<lambda>n. inverse(of_nat n)) \<longlongrightarrow> (0::'a::real_normed_field)) sequentially"
  1660   using lim_1_over_n by (simp add: inverse_eq_divide)
  1661 
  1662 lemma LIMSEQ_Suc_n_over_n: "(\<lambda>n. of_nat (Suc n) / of_nat n :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1663 proof (rule Lim_transform_eventually)
  1664   show "eventually (\<lambda>n. 1 + inverse (of_nat n :: 'a) = of_nat (Suc n) / of_nat n) sequentially"
  1665     using eventually_gt_at_top[of "0::nat"] by eventually_elim (simp add: field_simps)
  1666   have "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1 + 0"
  1667     by (intro tendsto_add tendsto_const lim_inverse_n)
  1668   thus "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1" by simp
  1669 qed
  1670 
  1671 lemma LIMSEQ_n_over_Suc_n: "(\<lambda>n. of_nat n / of_nat (Suc n) :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1672 proof (rule Lim_transform_eventually)
  1673   show "eventually (\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a) =
  1674                         of_nat n / of_nat (Suc n)) sequentially"
  1675     using eventually_gt_at_top[of "0::nat"]
  1676     by eventually_elim (simp add: field_simps del: of_nat_Suc)
  1677   have "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> inverse 1"
  1678     by (intro tendsto_inverse LIMSEQ_Suc_n_over_n) simp_all
  1679   thus "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> 1" by simp
  1680 qed
  1681 
  1682 subsection \<open>Convergence on sequences\<close>
  1683 
  1684 lemma convergent_cong:
  1685   assumes "eventually (\<lambda>x. f x = g x) sequentially"
  1686   shows   "convergent f \<longleftrightarrow> convergent g"
  1687   unfolding convergent_def by (subst filterlim_cong[OF refl refl assms]) (rule refl)
  1688 
  1689 lemma convergent_Suc_iff: "convergent (\<lambda>n. f (Suc n)) \<longleftrightarrow> convergent f"
  1690   by (auto simp: convergent_def LIMSEQ_Suc_iff)
  1691 
  1692 lemma convergent_ignore_initial_segment: "convergent (\<lambda>n. f (n + m)) = convergent f"
  1693 proof (induction m arbitrary: f)
  1694   case (Suc m)
  1695   have "convergent (\<lambda>n. f (n + Suc m)) \<longleftrightarrow> convergent (\<lambda>n. f (Suc n + m))" by simp
  1696   also have "\<dots> \<longleftrightarrow> convergent (\<lambda>n. f (n + m))" by (rule convergent_Suc_iff)
  1697   also have "\<dots> \<longleftrightarrow> convergent f" by (rule Suc)
  1698   finally show ?case .
  1699 qed simp_all
  1700 
  1701 lemma convergent_add:
  1702   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1703   assumes "convergent (\<lambda>n. X n)"
  1704   assumes "convergent (\<lambda>n. Y n)"
  1705   shows "convergent (\<lambda>n. X n + Y n)"
  1706   using assms unfolding convergent_def by (blast intro: tendsto_add)
  1707 
  1708 lemma convergent_setsum:
  1709   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1710   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1711   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1712 proof (cases "finite A")
  1713   case True from this and assms show ?thesis
  1714     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1715 qed (simp add: convergent_const)
  1716 
  1717 lemma (in bounded_linear) convergent:
  1718   assumes "convergent (\<lambda>n. X n)"
  1719   shows "convergent (\<lambda>n. f (X n))"
  1720   using assms unfolding convergent_def by (blast intro: tendsto)
  1721 
  1722 lemma (in bounded_bilinear) convergent:
  1723   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1724   shows "convergent (\<lambda>n. X n ** Y n)"
  1725   using assms unfolding convergent_def by (blast intro: tendsto)
  1726 
  1727 lemma convergent_minus_iff:
  1728   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1729   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1730 apply (simp add: convergent_def)
  1731 apply (auto dest: tendsto_minus)
  1732 apply (drule tendsto_minus, auto)
  1733 done
  1734 
  1735 lemma convergent_diff:
  1736   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1737   assumes "convergent (\<lambda>n. X n)"
  1738   assumes "convergent (\<lambda>n. Y n)"
  1739   shows "convergent (\<lambda>n. X n - Y n)"
  1740   using assms unfolding convergent_def by (blast intro: tendsto_diff)
  1741 
  1742 lemma convergent_norm:
  1743   assumes "convergent f"
  1744   shows   "convergent (\<lambda>n. norm (f n))"
  1745 proof -
  1746   from assms have "f \<longlonglongrightarrow> lim f" by (simp add: convergent_LIMSEQ_iff)
  1747   hence "(\<lambda>n. norm (f n)) \<longlonglongrightarrow> norm (lim f)" by (rule tendsto_norm)
  1748   thus ?thesis by (auto simp: convergent_def)
  1749 qed
  1750 
  1751 lemma convergent_of_real:
  1752   "convergent f \<Longrightarrow> convergent (\<lambda>n. of_real (f n) :: 'a :: real_normed_algebra_1)"
  1753   unfolding convergent_def by (blast intro!: tendsto_of_real)
  1754 
  1755 lemma convergent_add_const_iff:
  1756   "convergent (\<lambda>n. c + f n :: 'a :: real_normed_vector) \<longleftrightarrow> convergent f"
  1757 proof
  1758   assume "convergent (\<lambda>n. c + f n)"
  1759   from convergent_diff[OF this convergent_const[of c]] show "convergent f" by simp
  1760 next
  1761   assume "convergent f"
  1762   from convergent_add[OF convergent_const[of c] this] show "convergent (\<lambda>n. c + f n)" by simp
  1763 qed
  1764 
  1765 lemma convergent_add_const_right_iff:
  1766   "convergent (\<lambda>n. f n + c :: 'a :: real_normed_vector) \<longleftrightarrow> convergent f"
  1767   using convergent_add_const_iff[of c f] by (simp add: add_ac)
  1768 
  1769 lemma convergent_diff_const_right_iff:
  1770   "convergent (\<lambda>n. f n - c :: 'a :: real_normed_vector) \<longleftrightarrow> convergent f"
  1771   using convergent_add_const_right_iff[of f "-c"] by (simp add: add_ac)
  1772 
  1773 lemma convergent_mult:
  1774   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
  1775   assumes "convergent (\<lambda>n. X n)"
  1776   assumes "convergent (\<lambda>n. Y n)"
  1777   shows "convergent (\<lambda>n. X n * Y n)"
  1778   using assms unfolding convergent_def by (blast intro: tendsto_mult)
  1779 
  1780 lemma convergent_mult_const_iff:
  1781   assumes "c \<noteq> 0"
  1782   shows   "convergent (\<lambda>n. c * f n :: 'a :: real_normed_field) \<longleftrightarrow> convergent f"
  1783 proof
  1784   assume "convergent (\<lambda>n. c * f n)"
  1785   from assms convergent_mult[OF this convergent_const[of "inverse c"]]
  1786     show "convergent f" by (simp add: field_simps)
  1787 next
  1788   assume "convergent f"
  1789   from convergent_mult[OF convergent_const[of c] this] show "convergent (\<lambda>n. c * f n)" by simp
  1790 qed
  1791 
  1792 lemma convergent_mult_const_right_iff:
  1793   assumes "c \<noteq> 0"
  1794   shows   "convergent (\<lambda>n. (f n :: 'a :: real_normed_field) * c) \<longleftrightarrow> convergent f"
  1795   using convergent_mult_const_iff[OF assms, of f] by (simp add: mult_ac)
  1796 
  1797 lemma convergent_imp_Bseq: "convergent f \<Longrightarrow> Bseq f"
  1798   by (simp add: Cauchy_Bseq convergent_Cauchy)
  1799 
  1800 
  1801 text \<open>A monotone sequence converges to its least upper bound.\<close>
  1802 
  1803 lemma LIMSEQ_incseq_SUP:
  1804   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1805   assumes u: "bdd_above (range X)"
  1806   assumes X: "incseq X"
  1807   shows "X \<longlonglongrightarrow> (SUP i. X i)"
  1808   by (rule order_tendstoI)
  1809      (auto simp: eventually_sequentially u less_cSUP_iff intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  1810 
  1811 lemma LIMSEQ_decseq_INF:
  1812   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1813   assumes u: "bdd_below (range X)"
  1814   assumes X: "decseq X"
  1815   shows "X \<longlonglongrightarrow> (INF i. X i)"
  1816   by (rule order_tendstoI)
  1817      (auto simp: eventually_sequentially u cINF_less_iff intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  1818 
  1819 text\<open>Main monotonicity theorem\<close>
  1820 
  1821 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1822   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP dest: Bseq_bdd_above Bseq_bdd_below)
  1823 
  1824 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1825   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  1826 
  1827 lemma monoseq_imp_convergent_iff_Bseq: "monoseq (f :: nat \<Rightarrow> real) \<Longrightarrow> convergent f \<longleftrightarrow> Bseq f"
  1828   using Bseq_monoseq_convergent[of f] convergent_imp_Bseq[of f] by blast
  1829 
  1830 lemma Bseq_monoseq_convergent'_inc:
  1831   "Bseq (\<lambda>n. f (n + M) :: real) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<le> f n) \<Longrightarrow> convergent f"
  1832   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  1833      (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  1834 
  1835 lemma Bseq_monoseq_convergent'_dec:
  1836   "Bseq (\<lambda>n. f (n + M) :: real) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<ge> f n) \<Longrightarrow> convergent f"
  1837   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  1838      (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  1839 
  1840 lemma Cauchy_iff:
  1841   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1842   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1843   unfolding Cauchy_def dist_norm ..
  1844 
  1845 lemma CauchyI:
  1846   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1847   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1848 by (simp add: Cauchy_iff)
  1849 
  1850 lemma CauchyD:
  1851   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1852   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1853 by (simp add: Cauchy_iff)
  1854 
  1855 lemma incseq_convergent:
  1856   fixes X :: "nat \<Rightarrow> real"
  1857   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1858   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. X i \<le> L"
  1859 proof atomize_elim
  1860   from incseq_bounded[OF assms] \<open>incseq X\<close> Bseq_monoseq_convergent[of X]
  1861   obtain L where "X \<longlonglongrightarrow> L"
  1862     by (auto simp: convergent_def monoseq_def incseq_def)
  1863   with \<open>incseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. X i \<le> L)"
  1864     by (auto intro!: exI[of _ L] incseq_le)
  1865 qed
  1866 
  1867 lemma decseq_convergent:
  1868   fixes X :: "nat \<Rightarrow> real"
  1869   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1870   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. L \<le> X i"
  1871 proof atomize_elim
  1872   from decseq_bounded[OF assms] \<open>decseq X\<close> Bseq_monoseq_convergent[of X]
  1873   obtain L where "X \<longlonglongrightarrow> L"
  1874     by (auto simp: convergent_def monoseq_def decseq_def)
  1875   with \<open>decseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. L \<le> X i)"
  1876     by (auto intro!: exI[of _ L] decseq_le)
  1877 qed
  1878 
  1879 subsubsection \<open>Cauchy Sequences are Bounded\<close>
  1880 
  1881 text\<open>A Cauchy sequence is bounded -- this is the standard
  1882   proof mechanization rather than the nonstandard proof\<close>
  1883 
  1884 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1885           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1886 apply (clarify, drule spec, drule (1) mp)
  1887 apply (simp only: norm_minus_commute)
  1888 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1889 apply simp
  1890 done
  1891 
  1892 subsection \<open>Power Sequences\<close>
  1893 
  1894 text\<open>The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1895 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1896   also fact that bounded and monotonic sequence converges.\<close>
  1897 
  1898 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1899 apply (simp add: Bseq_def)
  1900 apply (rule_tac x = 1 in exI)
  1901 apply (simp add: power_abs)
  1902 apply (auto dest: power_mono)
  1903 done
  1904 
  1905 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1906 apply (clarify intro!: mono_SucI2)
  1907 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1908 done
  1909 
  1910 lemma convergent_realpow:
  1911   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1912 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1913 
  1914 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) \<longlonglongrightarrow> 0"
  1915   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1916 
  1917 lemma LIMSEQ_realpow_zero:
  1918   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  1919 proof cases
  1920   assume "0 \<le> x" and "x \<noteq> 0"
  1921   hence x0: "0 < x" by simp
  1922   assume x1: "x < 1"
  1923   from x0 x1 have "1 < inverse x"
  1924     by (rule one_less_inverse)
  1925   hence "(\<lambda>n. inverse (inverse x ^ n)) \<longlonglongrightarrow> 0"
  1926     by (rule LIMSEQ_inverse_realpow_zero)
  1927   thus ?thesis by (simp add: power_inverse)
  1928 qed (rule LIMSEQ_imp_Suc, simp)
  1929 
  1930 lemma LIMSEQ_power_zero:
  1931   fixes x :: "'a::{real_normed_algebra_1}"
  1932   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  1933 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1934 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1935 apply (simp add: power_abs norm_power_ineq)
  1936 done
  1937 
  1938 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) \<longlonglongrightarrow> 0"
  1939   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1940 
  1941 text\<open>Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}\<close>
  1942 
  1943 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) \<longlonglongrightarrow> 0"
  1944   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1945 
  1946 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) \<longlonglongrightarrow> 0"
  1947   by (rule LIMSEQ_power_zero) simp
  1948 
  1949 
  1950 subsection \<open>Limits of Functions\<close>
  1951 
  1952 lemma LIM_eq:
  1953   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1954   shows "f \<midarrow>a\<rightarrow> L =
  1955      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1956 by (simp add: LIM_def dist_norm)
  1957 
  1958 lemma LIM_I:
  1959   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1960   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1961       ==> f \<midarrow>a\<rightarrow> L"
  1962 by (simp add: LIM_eq)
  1963 
  1964 lemma LIM_D:
  1965   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1966   shows "[| f \<midarrow>a\<rightarrow> L; 0<r |]
  1967       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1968 by (simp add: LIM_eq)
  1969 
  1970 lemma LIM_offset:
  1971   fixes a :: "'a::real_normed_vector"
  1972   shows "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>x. f (x + k)) \<midarrow>(a - k)\<rightarrow> L"
  1973   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1974 
  1975 lemma LIM_offset_zero:
  1976   fixes a :: "'a::real_normed_vector"
  1977   shows "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  1978 by (drule_tac k="a" in LIM_offset, simp add: add.commute)
  1979 
  1980 lemma LIM_offset_zero_cancel:
  1981   fixes a :: "'a::real_normed_vector"
  1982   shows "(\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  1983 by (drule_tac k="- a" in LIM_offset, simp)
  1984 
  1985 lemma LIM_offset_zero_iff:
  1986   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1987   shows  "f \<midarrow>a\<rightarrow> L \<longleftrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  1988   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1989 
  1990 lemma LIM_zero:
  1991   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1992   shows "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. f x - l) \<longlongrightarrow> 0) F"
  1993 unfolding tendsto_iff dist_norm by simp
  1994 
  1995 lemma LIM_zero_cancel:
  1996   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1997   shows "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> l) F"
  1998 unfolding tendsto_iff dist_norm by simp
  1999 
  2000 lemma LIM_zero_iff:
  2001   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  2002   shows "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F = (f \<longlongrightarrow> l) F"
  2003 unfolding tendsto_iff dist_norm by simp
  2004 
  2005 lemma LIM_imp_LIM:
  2006   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  2007   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  2008   assumes f: "f \<midarrow>a\<rightarrow> l"
  2009   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  2010   shows "g \<midarrow>a\<rightarrow> m"
  2011   by (rule metric_LIM_imp_LIM [OF f],
  2012     simp add: dist_norm le)
  2013 
  2014 lemma LIM_equal2:
  2015   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2016   assumes 1: "0 < R"
  2017   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  2018   shows "g \<midarrow>a\<rightarrow> l \<Longrightarrow> f \<midarrow>a\<rightarrow> l"
  2019 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  2020 
  2021 lemma LIM_compose2:
  2022   fixes a :: "'a::real_normed_vector"
  2023   assumes f: "f \<midarrow>a\<rightarrow> b"
  2024   assumes g: "g \<midarrow>b\<rightarrow> c"
  2025   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  2026   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  2027 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  2028 
  2029 lemma real_LIM_sandwich_zero:
  2030   fixes f g :: "'a::topological_space \<Rightarrow> real"
  2031   assumes f: "f \<midarrow>a\<rightarrow> 0"
  2032   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  2033   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  2034   shows "g \<midarrow>a\<rightarrow> 0"
  2035 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  2036   fix x assume x: "x \<noteq> a"
  2037   have "norm (g x - 0) = g x" by (simp add: 1 x)
  2038   also have "g x \<le> f x" by (rule 2 [OF x])
  2039   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  2040   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  2041   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  2042 qed
  2043 
  2044 
  2045 subsection \<open>Continuity\<close>
  2046 
  2047 lemma LIM_isCont_iff:
  2048   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2049   shows "(f \<midarrow>a\<rightarrow> f a) = ((\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> f a)"
  2050 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  2051 
  2052 lemma isCont_iff:
  2053   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2054   shows "isCont f x = (\<lambda>h. f (x + h)) \<midarrow>0\<rightarrow> f x"
  2055 by (simp add: isCont_def LIM_isCont_iff)
  2056 
  2057 lemma isCont_LIM_compose2:
  2058   fixes a :: "'a::real_normed_vector"
  2059   assumes f [unfolded isCont_def]: "isCont f a"
  2060   assumes g: "g \<midarrow>f a\<rightarrow> l"
  2061   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  2062   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> l"
  2063 by (rule LIM_compose2 [OF f g inj])
  2064 
  2065 
  2066 lemma isCont_norm [simp]:
  2067   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2068   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  2069   by (fact continuous_norm)
  2070 
  2071 lemma isCont_rabs [simp]:
  2072   fixes f :: "'a::t2_space \<Rightarrow> real"
  2073   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  2074   by (fact continuous_rabs)
  2075 
  2076 lemma isCont_add [simp]:
  2077   fixes f :: "'a::t2_space \<Rightarrow> 'b::topological_monoid_add"
  2078   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  2079   by (fact continuous_add)
  2080 
  2081 lemma isCont_minus [simp]:
  2082   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2083   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  2084   by (fact continuous_minus)
  2085 
  2086 lemma isCont_diff [simp]:
  2087   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2088   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  2089   by (fact continuous_diff)
  2090 
  2091 lemma isCont_mult [simp]:
  2092   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  2093   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  2094   by (fact continuous_mult)
  2095 
  2096 lemma (in bounded_linear) isCont:
  2097   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  2098   by (fact continuous)
  2099 
  2100 lemma (in bounded_bilinear) isCont:
  2101   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  2102   by (fact continuous)
  2103 
  2104 lemmas isCont_scaleR [simp] =
  2105   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  2106 
  2107 lemmas isCont_of_real [simp] =
  2108   bounded_linear.isCont [OF bounded_linear_of_real]
  2109 
  2110 lemma isCont_power [simp]:
  2111   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  2112   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  2113   by (fact continuous_power)
  2114 
  2115 lemma isCont_setsum [simp]:
  2116   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
  2117   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  2118   by (auto intro: continuous_setsum)
  2119 
  2120 subsection \<open>Uniform Continuity\<close>
  2121 
  2122 definition
  2123   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  2124   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  2125 
  2126 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  2127 by (simp add: isUCont_def isCont_def LIM_def, force)
  2128 
  2129 lemma isUCont_Cauchy:
  2130   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2131 unfolding isUCont_def
  2132 apply (rule metric_CauchyI)
  2133 apply (drule_tac x=e in spec, safe)
  2134 apply (drule_tac e=s in metric_CauchyD, safe)
  2135 apply (rule_tac x=M in exI, simp)
  2136 done
  2137 
  2138 lemma (in bounded_linear) isUCont: "isUCont f"
  2139 unfolding isUCont_def dist_norm
  2140 proof (intro allI impI)
  2141   fix r::real assume r: "0 < r"
  2142   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  2143     using pos_bounded by blast
  2144   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  2145   proof (rule exI, safe)
  2146     from r K show "0 < r / K" by simp
  2147   next
  2148     fix x y :: 'a
  2149     assume xy: "norm (x - y) < r / K"
  2150     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  2151     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  2152     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  2153     finally show "norm (f x - f y) < r" .
  2154   qed
  2155 qed
  2156 
  2157 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2158 by (rule isUCont [THEN isUCont_Cauchy])
  2159 
  2160 lemma LIM_less_bound:
  2161   fixes f :: "real \<Rightarrow> real"
  2162   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  2163   shows "0 \<le> f x"
  2164 proof (rule tendsto_le_const)
  2165   show "(f \<longlongrightarrow> f x) (at_left x)"
  2166     using \<open>isCont f x\<close> by (simp add: filterlim_at_split isCont_def)
  2167   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  2168     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  2169 qed simp
  2170 
  2171 
  2172 subsection \<open>Nested Intervals and Bisection -- Needed for Compactness\<close>
  2173 
  2174 lemma nested_sequence_unique:
  2175   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) \<longlonglongrightarrow> 0"
  2176   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f \<longlonglongrightarrow> l) \<and> ((\<forall>n. l \<le> g n) \<and> g \<longlonglongrightarrow> l)"
  2177 proof -
  2178   have "incseq f" unfolding incseq_Suc_iff by fact
  2179   have "decseq g" unfolding decseq_Suc_iff by fact
  2180 
  2181   { fix n
  2182     from \<open>decseq g\<close> have "g n \<le> g 0" by (rule decseqD) simp
  2183     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] have "f n \<le> g 0" by auto }
  2184   then obtain u where "f \<longlonglongrightarrow> u" "\<forall>i. f i \<le> u"
  2185     using incseq_convergent[OF \<open>incseq f\<close>] by auto
  2186   moreover
  2187   { fix n
  2188     from \<open>incseq f\<close> have "f 0 \<le> f n" by (rule incseqD) simp
  2189     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] have "f 0 \<le> g n" by simp }
  2190   then obtain l where "g \<longlonglongrightarrow> l" "\<forall>i. l \<le> g i"
  2191     using decseq_convergent[OF \<open>decseq g\<close>] by auto
  2192   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF \<open>f \<longlonglongrightarrow> u\<close> \<open>g \<longlonglongrightarrow> l\<close>]]
  2193   ultimately show ?thesis by auto
  2194 qed
  2195 
  2196 lemma Bolzano[consumes 1, case_names trans local]:
  2197   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  2198   assumes [arith]: "a \<le> b"
  2199   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  2200   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  2201   shows "P a b"
  2202 proof -
  2203   define bisect where "bisect =
  2204     rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  2205   define l u where "l n = fst (bisect n)" and "u n = snd (bisect n)" for n
  2206   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  2207     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  2208     by (simp_all add: l_def u_def bisect_def split: prod.split)
  2209 
  2210   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  2211 
  2212   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l \<longlonglongrightarrow> x) \<and> ((\<forall>n. x \<le> u n) \<and> u \<longlonglongrightarrow> x)"
  2213   proof (safe intro!: nested_sequence_unique)
  2214     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  2215   next
  2216     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  2217     then show "(\<lambda>n. l n - u n) \<longlonglongrightarrow> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  2218   qed fact
  2219   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l \<longlonglongrightarrow> x" "u \<longlonglongrightarrow> x" by auto
  2220   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  2221     using \<open>l 0 \<le> x\<close> \<open>x \<le> u 0\<close> local[of x] by auto
  2222 
  2223   show "P a b"
  2224   proof (rule ccontr)
  2225     assume "\<not> P a b"
  2226     { fix n have "\<not> P (l n) (u n)"
  2227       proof (induct n)
  2228         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  2229       qed (simp add: \<open>\<not> P a b\<close>) }
  2230     moreover
  2231     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  2232         using \<open>0 < d\<close> \<open>l \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2233       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  2234         using \<open>0 < d\<close> \<open>u \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2235       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  2236       proof eventually_elim
  2237         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  2238         from add_strict_mono[OF this] have "u n - l n < d" by simp
  2239         with x show "P (l n) (u n)" by (rule d)
  2240       qed }
  2241     ultimately show False by simp
  2242   qed
  2243 qed
  2244 
  2245 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  2246 proof (cases "a \<le> b", rule compactI)
  2247   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  2248   define T where "T = {a .. b}"
  2249   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  2250   proof (induct rule: Bolzano)
  2251     case (trans a b c)
  2252     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  2253     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  2254       by (auto simp: *)
  2255     with trans show ?case
  2256       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  2257   next
  2258     case (local x)
  2259     then have "x \<in> \<Union>C" using C by auto
  2260     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  2261     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  2262       by (auto simp: open_dist dist_real_def subset_eq Ball_def abs_less_iff)
  2263     with \<open>c \<in> C\<close> show ?case
  2264       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  2265   qed
  2266 qed simp
  2267 
  2268 
  2269 lemma continuous_image_closed_interval:
  2270   fixes a b and f :: "real \<Rightarrow> real"
  2271   defines "S \<equiv> {a..b}"
  2272   assumes "a \<le> b" and f: "continuous_on S f"
  2273   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
  2274 proof -
  2275   have S: "compact S" "S \<noteq> {}"
  2276     using \<open>a \<le> b\<close> by (auto simp: S_def)
  2277   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
  2278     using continuous_attains_sup[OF S f] by auto
  2279   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
  2280     using continuous_attains_inf[OF S f] by auto
  2281   moreover have "connected (f`S)"
  2282     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
  2283   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
  2284     by (auto simp: connected_iff_interval)
  2285   then show ?thesis
  2286     by auto
  2287 qed
  2288 
  2289 lemma open_Collect_positive:
  2290  fixes f :: "'a::t2_space \<Rightarrow> real"
  2291  assumes f: "continuous_on s f"
  2292  shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. 0 < f x}"
  2293  using continuous_on_open_invariant[THEN iffD1, OF f, rule_format, of "{0 <..}"]
  2294  by (auto simp: Int_def field_simps)
  2295 
  2296 lemma open_Collect_less_Int:
  2297  fixes f g :: "'a::t2_space \<Rightarrow> real"
  2298  assumes f: "continuous_on s f" and g: "continuous_on s g"
  2299  shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. f x < g x}"
  2300  using open_Collect_positive[OF continuous_on_diff[OF g f]] by (simp add: field_simps)
  2301 
  2302 
  2303 subsection \<open>Boundedness of continuous functions\<close>
  2304 
  2305 text\<open>By bisection, function continuous on closed interval is bounded above\<close>
  2306 
  2307 lemma isCont_eq_Ub:
  2308   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2309   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2310     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2311   using continuous_attains_sup[of "{a .. b}" f]
  2312   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2313 
  2314 lemma isCont_eq_Lb:
  2315   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2316   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2317     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2318   using continuous_attains_inf[of "{a .. b}" f]
  2319   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2320 
  2321 lemma isCont_bounded:
  2322   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2323   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  2324   using isCont_eq_Ub[of a b f] by auto
  2325 
  2326 lemma isCont_has_Ub:
  2327   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2328   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2329     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  2330   using isCont_eq_Ub[of a b f] by auto
  2331 
  2332 (*HOL style here: object-level formulations*)
  2333 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  2334       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  2335       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  2336   by (blast intro: IVT)
  2337 
  2338 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  2339       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  2340       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  2341   by (blast intro: IVT2)
  2342 
  2343 lemma isCont_Lb_Ub:
  2344   fixes f :: "real \<Rightarrow> real"
  2345   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  2346   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and>
  2347                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  2348 proof -
  2349   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  2350     using isCont_eq_Ub[OF assms] by auto
  2351   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  2352     using isCont_eq_Lb[OF assms] by auto
  2353   show ?thesis
  2354     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  2355     apply (rule_tac x="f L" in exI)
  2356     apply (rule_tac x="f M" in exI)
  2357     apply (cases "L \<le> M")
  2358     apply (simp, metis order_trans)
  2359     apply (simp, metis order_trans)
  2360     done
  2361 qed
  2362 
  2363 
  2364 text\<open>Continuity of inverse function\<close>
  2365 
  2366 lemma isCont_inverse_function:
  2367   fixes f g :: "real \<Rightarrow> real"
  2368   assumes d: "0 < d"
  2369       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  2370       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  2371   shows "isCont g (f x)"
  2372 proof -
  2373   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  2374 
  2375   have f: "continuous_on ?D f"
  2376     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  2377   then have g: "continuous_on (f`?D) g"
  2378     using inj by (intro continuous_on_inv) auto
  2379 
  2380   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  2381     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  2382   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  2383     by (rule continuous_on_subset)
  2384   moreover
  2385   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  2386     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  2387   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  2388     by auto
  2389   ultimately
  2390   show ?thesis
  2391     by (simp add: continuous_on_eq_continuous_at)
  2392 qed
  2393 
  2394 lemma isCont_inverse_function2:
  2395   fixes f g :: "real \<Rightarrow> real" shows
  2396   "\<lbrakk>a < x; x < b;
  2397     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2398     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2399    \<Longrightarrow> isCont g (f x)"
  2400 apply (rule isCont_inverse_function
  2401        [where f=f and d="min (x - a) (b - x)"])
  2402 apply (simp_all add: abs_le_iff)
  2403 done
  2404 
  2405 (* need to rename second isCont_inverse *)
  2406 
  2407 lemma isCont_inv_fun:
  2408   fixes f g :: "real \<Rightarrow> real"
  2409   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;
  2410          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]
  2411       ==> isCont g (f x)"
  2412 by (rule isCont_inverse_function)
  2413 
  2414 text\<open>Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110\<close>
  2415 lemma LIM_fun_gt_zero:
  2416   fixes f :: "real \<Rightarrow> real"
  2417   shows "f \<midarrow>c\<rightarrow> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  2418 apply (drule (1) LIM_D, clarify)
  2419 apply (rule_tac x = s in exI)
  2420 apply (simp add: abs_less_iff)
  2421 done
  2422 
  2423 lemma LIM_fun_less_zero:
  2424   fixes f :: "real \<Rightarrow> real"
  2425   shows "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  2426 apply (drule LIM_D [where r="-l"], simp, clarify)
  2427 apply (rule_tac x = s in exI)
  2428 apply (simp add: abs_less_iff)
  2429 done
  2430 
  2431 lemma LIM_fun_not_zero:
  2432   fixes f :: "real \<Rightarrow> real"
  2433   shows "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  2434   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  2435 
  2436 end