src/Pure/sign.ML
author wenzelm
Thu Apr 26 14:24:14 2007 +0200 (2007-04-26)
changeset 22811 eb59c9b76d52
parent 22796 34c316d7b630
child 22846 fb79144af9a3
permissions -rw-r--r--
renamed some old names Theory.xxx to Sign.xxx;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_trfuns:
    27     (string * (ast list -> ast)) list *
    28     (string * (term list -> term)) list *
    29     (string * (term list -> term)) list *
    30     (string * (ast list -> ast)) list -> theory -> theory
    31   val add_trfunsT:
    32     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    33   val add_advanced_trfuns:
    34     (string * (Proof.context -> ast list -> ast)) list *
    35     (string * (Proof.context -> term list -> term)) list *
    36     (string * (Proof.context -> term list -> term)) list *
    37     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
    38   val add_advanced_trfunsT:
    39     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
    40   val add_tokentrfuns:
    41     (string * string * (string -> string * real)) list -> theory -> theory
    42   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    43     -> theory -> theory
    44   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    45   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    46   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    47   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    48   val add_path: string -> theory -> theory
    49   val parent_path: theory -> theory
    50   val root_path: theory -> theory
    51   val absolute_path: theory -> theory
    52   val local_path: theory -> theory
    53   val no_base_names: theory -> theory
    54   val qualified_names: theory -> theory
    55   val sticky_prefix: string -> theory -> theory
    56   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    57     theory -> theory
    58   val restore_naming: theory -> theory -> theory
    59 end
    60 
    61 signature SIGN =
    62 sig
    63   val init_data: theory -> theory
    64   val rep_sg: theory ->
    65    {naming: NameSpace.naming,
    66     syn: Syntax.syntax,
    67     tsig: Type.tsig,
    68     consts: Consts.T}
    69   val naming_of: theory -> NameSpace.naming
    70   val base_name: string -> bstring
    71   val full_name: theory -> bstring -> string
    72   val full_name_path: theory -> string -> bstring -> string
    73   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    74   val syn_of: theory -> Syntax.syntax
    75   val tsig_of: theory -> Type.tsig
    76   val classes_of: theory -> Sorts.algebra
    77   val all_classes: theory -> class list
    78   val super_classes: theory -> class -> class list
    79   val defaultS: theory -> sort
    80   val subsort: theory -> sort * sort -> bool
    81   val of_sort: theory -> typ * sort -> bool
    82   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    83   val universal_witness: theory -> (typ * sort) option
    84   val all_sorts_nonempty: theory -> bool
    85   val typ_instance: theory -> typ * typ -> bool
    86   val typ_equiv: theory -> typ * typ -> bool
    87   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    88   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    89   val is_logtype: theory -> string -> bool
    90   val consts_of: theory -> Consts.T
    91   val const_constraint: theory -> string -> typ option
    92   val the_const_constraint: theory -> string -> typ
    93   val const_type: theory -> string -> typ option
    94   val the_const_type: theory -> string -> typ
    95   val declared_tyname: theory -> string -> bool
    96   val declared_const: theory -> string -> bool
    97   val const_monomorphic: theory -> string -> bool
    98   val const_syntax_name: theory -> string -> string
    99   val const_typargs: theory -> string * typ -> typ list
   100   val const_instance: theory -> string * typ list -> typ
   101   val class_space: theory -> NameSpace.T
   102   val type_space: theory -> NameSpace.T
   103   val const_space: theory -> NameSpace.T
   104   val intern_class: theory -> xstring -> string
   105   val extern_class: theory -> string -> xstring
   106   val intern_type: theory -> xstring -> string
   107   val extern_type: theory -> string -> xstring
   108   val intern_const: theory -> xstring -> string
   109   val extern_const: theory -> string -> xstring
   110   val intern_sort: theory -> sort -> sort
   111   val extern_sort: theory -> sort -> sort
   112   val intern_typ: theory -> typ -> typ
   113   val extern_typ: theory -> typ -> typ
   114   val intern_term: theory -> term -> term
   115   val extern_term: (string -> xstring) -> theory -> term -> term
   116   val intern_tycons: theory -> typ -> typ
   117   val pretty_term': Proof.context -> Syntax.syntax -> (string -> xstring) -> term -> Pretty.T
   118   val pretty_term: theory -> term -> Pretty.T
   119   val pretty_typ: theory -> typ -> Pretty.T
   120   val pretty_sort: theory -> sort -> Pretty.T
   121   val pretty_classrel: theory -> class list -> Pretty.T
   122   val pretty_arity: theory -> arity -> Pretty.T
   123   val string_of_term: theory -> term -> string
   124   val string_of_typ: theory -> typ -> string
   125   val string_of_sort: theory -> sort -> string
   126   val string_of_classrel: theory -> class list -> string
   127   val string_of_arity: theory -> arity -> string
   128   val pp: theory -> Pretty.pp
   129   val arity_number: theory -> string -> int
   130   val arity_sorts: theory -> string -> sort -> sort list
   131   val certify_class: theory -> class -> class
   132   val certify_sort: theory -> sort -> sort
   133   val certify_typ: theory -> typ -> typ
   134   val certify_typ_syntax: theory -> typ -> typ
   135   val certify_typ_abbrev: theory -> typ -> typ
   136   val certify': bool -> bool -> Pretty.pp -> Consts.T -> theory -> term -> term * typ * int
   137   val certify_term: theory -> term -> term * typ * int
   138   val certify_prop: theory -> term -> term * typ * int
   139   val cert_term: theory -> term -> term
   140   val cert_prop: theory -> term -> term
   141   val no_frees: Pretty.pp -> term -> term
   142   val no_vars: Pretty.pp -> term -> term
   143   val cert_def: Pretty.pp -> term -> (string * typ) * term
   144   val read_class: theory -> xstring -> class
   145   val read_sort': Syntax.syntax -> Proof.context -> string -> sort
   146   val read_sort: theory -> string -> sort
   147   val read_arity: theory -> xstring * string list * string -> arity
   148   val cert_arity: theory -> arity -> arity
   149   val get_sort: theory ->
   150     (indexname -> sort option) -> (indexname * sort) list -> indexname -> sort
   151   val read_typ': Syntax.syntax -> Proof.context -> (indexname -> sort option) -> string -> typ
   152   val read_typ_syntax': Syntax.syntax -> Proof.context ->
   153     (indexname -> sort option) -> string -> typ
   154   val read_typ_abbrev': Syntax.syntax -> Proof.context ->
   155     (indexname -> sort option) -> string -> typ
   156   val read_def_typ: theory * (indexname -> sort option) -> string -> typ
   157   val read_typ: theory -> string -> typ
   158   val read_typ_syntax: theory -> string -> typ
   159   val read_typ_abbrev: theory -> string -> typ
   160   val read_tyname: theory -> string -> typ
   161   val read_const: theory -> string -> term
   162   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   163     (string -> string option) -> Proof.context ->
   164     (indexname -> typ option) * (indexname -> sort option) ->
   165     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   166   val read_def_terms:
   167     theory * (indexname -> typ option) * (indexname -> sort option) ->
   168     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   169   val simple_read_term: theory -> typ -> string -> term
   170   val read_term: theory -> string -> term
   171   val read_prop: theory -> string -> term
   172   val add_consts_authentic: (bstring * typ * mixfix) list -> theory -> theory
   173   val add_notation: Syntax.mode -> (term * mixfix) list -> theory -> theory
   174   val add_abbrev: string -> bstring * term -> theory -> (term * term) * theory
   175   include SIGN_THEORY
   176   val add_const_constraint: xstring * string option -> theory -> theory
   177   val add_const_constraint_i: string * typ option -> theory -> theory
   178   val primitive_class: string * class list -> theory -> theory
   179   val primitive_classrel: class * class -> theory -> theory
   180   val primitive_arity: arity -> theory -> theory
   181   val hide_classes: bool -> xstring list -> theory -> theory
   182   val hide_classes_i: bool -> string list -> theory -> theory
   183   val hide_types: bool -> xstring list -> theory -> theory
   184   val hide_types_i: bool -> string list -> theory -> theory
   185   val hide_consts: bool -> xstring list -> theory -> theory
   186   val hide_consts_i: bool -> string list -> theory -> theory
   187   val hide_names: bool -> string * xstring list -> theory -> theory
   188   val hide_names_i: bool -> string * string list -> theory -> theory
   189 end
   190 
   191 structure Sign: SIGN =
   192 struct
   193 
   194 (** datatype sign **)
   195 
   196 datatype sign = Sign of
   197  {naming: NameSpace.naming,     (*common naming conventions*)
   198   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   199   tsig: Type.tsig,              (*order-sorted signature of types*)
   200   consts: Consts.T};            (*polymorphic constants*)
   201 
   202 fun make_sign (naming, syn, tsig, consts) =
   203   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   204 
   205 structure SignData = TheoryDataFun
   206 (struct
   207   val name = "Pure/sign";
   208   type T = sign;
   209   val copy = I;
   210   fun extend (Sign {syn, tsig, consts, ...}) =
   211     make_sign (NameSpace.default_naming, syn, tsig, consts);
   212 
   213   val empty =
   214     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   215 
   216   fun merge pp (sign1, sign2) =
   217     let
   218       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   219       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   220 
   221       val naming = NameSpace.default_naming;
   222       val syn = Syntax.merge_syntaxes syn1 syn2;
   223       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   224       val consts = Consts.merge (consts1, consts2);
   225     in make_sign (naming, syn, tsig, consts) end;
   226 
   227   fun print _ _ = ();
   228 end);
   229 
   230 val init_data = SignData.init;
   231 
   232 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   233 
   234 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   235   make_sign (f (naming, syn, tsig, consts)));
   236 
   237 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   238 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   239 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   240 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   241 
   242 
   243 (* naming *)
   244 
   245 val naming_of = #naming o rep_sg;
   246 val base_name = NameSpace.base;
   247 val full_name = NameSpace.full o naming_of;
   248 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   249 val declare_name = NameSpace.declare o naming_of;
   250 
   251 
   252 (* syntax *)
   253 
   254 val syn_of = #syn o rep_sg;
   255 
   256 
   257 (* type signature *)
   258 
   259 val tsig_of = #tsig o rep_sg;
   260 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   261 val all_classes = Sorts.all_classes o classes_of;
   262 val minimal_classes = Sorts.minimal_classes o classes_of;
   263 val super_classes = Sorts.super_classes o classes_of;
   264 val defaultS = Type.defaultS o tsig_of;
   265 val subsort = Type.subsort o tsig_of;
   266 val of_sort = Type.of_sort o tsig_of;
   267 val witness_sorts = Type.witness_sorts o tsig_of;
   268 val universal_witness = Type.universal_witness o tsig_of;
   269 val all_sorts_nonempty = is_some o universal_witness;
   270 val typ_instance = Type.typ_instance o tsig_of;
   271 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   272 val typ_match = Type.typ_match o tsig_of;
   273 val typ_unify = Type.unify o tsig_of;
   274 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   275 
   276 
   277 (* polymorphic constants *)
   278 
   279 val consts_of = #consts o rep_sg;
   280 val the_const_constraint = Consts.the_constraint o consts_of;
   281 val const_constraint = try o the_const_constraint;
   282 val the_const_type = Consts.the_declaration o consts_of;
   283 val const_type = try o the_const_type;
   284 val const_monomorphic = Consts.is_monomorphic o consts_of;
   285 val const_syntax_name = Consts.syntax_name o consts_of;
   286 val const_typargs = Consts.typargs o consts_of;
   287 val const_instance = Consts.instance o consts_of;
   288 
   289 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   290 val declared_const = is_some oo const_constraint;
   291 
   292 
   293 
   294 (** intern / extern names **)
   295 
   296 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   297 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   298 val const_space = Consts.space_of o consts_of;
   299 
   300 val intern_class = NameSpace.intern o class_space;
   301 val extern_class = NameSpace.extern o class_space;
   302 val intern_type = NameSpace.intern o type_space;
   303 val extern_type = NameSpace.extern o type_space;
   304 val intern_const = NameSpace.intern o const_space;
   305 val extern_const = NameSpace.extern o const_space;
   306 
   307 val intern_sort = map o intern_class;
   308 val extern_sort = map o extern_class;
   309 
   310 local
   311 
   312 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   313   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   314   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   315 
   316 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   317   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   318   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   319   | map_term _ _ _ (t as Bound _) = t
   320   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   321   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   322 
   323 val add_classesT = Term.fold_atyps
   324   (fn TFree (_, S) => fold (insert (op =)) S
   325     | TVar (_, S) => fold (insert (op =)) S
   326     | _ => I);
   327 
   328 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   329   | add_tyconsT _ = I;
   330 
   331 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   332 
   333 fun mapping add_names f t =
   334   let
   335     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   336     val tab = map_filter f' (add_names t []);
   337     fun get x = the_default x (AList.lookup (op =) tab x);
   338   in get end;
   339 
   340 fun typ_mapping f g thy T =
   341   T |> map_typ
   342     (mapping add_classesT (f thy) T)
   343     (mapping add_tyconsT (g thy) T);
   344 
   345 fun term_mapping f g h thy t =
   346   t |> map_term
   347     (mapping (Term.fold_types add_classesT) (f thy) t)
   348     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   349     (mapping add_consts (h thy) t);
   350 
   351 in
   352 
   353 val intern_typ = typ_mapping intern_class intern_type;
   354 val extern_typ = typ_mapping extern_class extern_type;
   355 val intern_term = term_mapping intern_class intern_type intern_const;
   356 fun extern_term h = term_mapping extern_class extern_type (K h);
   357 val intern_tycons = typ_mapping (K I) intern_type;
   358 
   359 end;
   360 
   361 
   362 
   363 (** pretty printing of terms, types etc. **)
   364 
   365 fun pretty_term' ctxt syn ext t =
   366   let val curried = Context.exists_name Context.CPureN (ProofContext.theory_of ctxt)
   367   in Syntax.pretty_term ext ctxt syn curried t end;
   368 
   369 fun pretty_term thy t =
   370   pretty_term' (ProofContext.init thy) (syn_of thy) (Consts.extern (consts_of thy))
   371     (extern_term (Consts.extern_early (consts_of thy)) thy t);
   372 
   373 fun pretty_typ thy T =
   374   Syntax.pretty_typ (ProofContext.init thy) (syn_of thy) (extern_typ thy T);
   375 
   376 fun pretty_sort thy S =
   377   Syntax.pretty_sort (ProofContext.init thy) (syn_of thy) (extern_sort thy S);
   378 
   379 fun pretty_classrel thy cs = Pretty.block (flat
   380   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   381 
   382 fun pretty_arity thy (a, Ss, S) =
   383   let
   384     val a' = extern_type thy a;
   385     val dom =
   386       if null Ss then []
   387       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   388   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   389 
   390 val string_of_term = Pretty.string_of oo pretty_term;
   391 val string_of_typ = Pretty.string_of oo pretty_typ;
   392 val string_of_sort = Pretty.string_of oo pretty_sort;
   393 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   394 val string_of_arity = Pretty.string_of oo pretty_arity;
   395 
   396 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   397   pretty_classrel thy, pretty_arity thy);
   398 
   399 
   400 
   401 (** certify entities **)    (*exception TYPE*)
   402 
   403 (* certify wrt. type signature *)
   404 
   405 val arity_number = Type.arity_number o tsig_of;
   406 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   407 
   408 fun certify cert = cert o tsig_of o Context.check_thy;
   409 
   410 val certify_class      = certify Type.cert_class;
   411 val certify_sort       = certify Type.cert_sort;
   412 val certify_typ        = certify Type.cert_typ;
   413 val certify_typ_syntax = certify Type.cert_typ_syntax;
   414 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   415 
   416 
   417 (* certify term/prop *)
   418 
   419 local
   420 
   421 fun type_check pp tm =
   422   let
   423     fun err_appl why bs t T u U =
   424       let
   425         val xs = map Free bs;           (*we do not rename here*)
   426         val t' = subst_bounds (xs, t);
   427         val u' = subst_bounds (xs, u);
   428         val msg = cat_lines
   429           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   430       in raise TYPE (msg, [T, U], [t', u']) end;
   431 
   432     fun typ_of (_, Const (_, T)) = T
   433       | typ_of (_, Free  (_, T)) = T
   434       | typ_of (_, Var (_, T)) = T
   435       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   436           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   437       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   438       | typ_of (bs, t $ u) =
   439           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   440             (case T of
   441               Type ("fun", [T1, T2]) =>
   442                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   443             | _ => err_appl "Operator not of function type" bs t T u U)
   444           end;
   445   in typ_of ([], tm) end;
   446 
   447 fun err msg = raise TYPE (msg, [], []);
   448 
   449 fun check_vars (t $ u) = (check_vars t; check_vars u)
   450   | check_vars (Abs (_, _, t)) = check_vars t
   451   | check_vars (Var (xi as (_, i), _)) =
   452       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   453   | check_vars _ = ();
   454 
   455 in
   456 
   457 fun certify' normalize prop pp consts thy tm =
   458   let
   459     val _ = Context.check_thy thy;
   460     val _ = check_vars tm;
   461     val tm' = Term.map_types (certify_typ thy) tm;
   462     val T = type_check pp tm';
   463     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   464     val tm'' = Consts.certify pp (tsig_of thy) consts tm';
   465     val tm'' = if normalize then tm'' else tm';
   466   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   467 
   468 fun certify_term thy = certify' true false (pp thy) (consts_of thy) thy;
   469 fun certify_prop thy = certify' true true (pp thy) (consts_of thy) thy;
   470 
   471 fun cert_term_abbrev thy = #1 o certify' false false (pp thy) (consts_of thy) thy;
   472 val cert_term = #1 oo certify_term;
   473 val cert_prop = #1 oo certify_prop;
   474 
   475 end;
   476 
   477 
   478 (* specifications *)
   479 
   480 fun no_variables kind add addT mk mkT pp tm =
   481   (case (add tm [], addT tm []) of
   482     ([], []) => tm
   483   | (frees, tfrees) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   484       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") ::
   485        map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   486 
   487 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   488 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   489 
   490 fun cert_def pp tm =
   491   let val ((lhs, rhs), _) = tm
   492     |> no_vars pp
   493     |> Logic.strip_imp_concl
   494     |> Logic.dest_def pp Term.is_Const (K false) (K false)
   495   in (Term.dest_Const (Term.head_of lhs), rhs) end
   496   handle TERM (msg, _) => error msg;
   497 
   498 
   499 
   500 (** read and certify entities **)    (*exception ERROR*)
   501 
   502 (* classes and sorts *)
   503 
   504 fun read_class thy c = certify_class thy (intern_class thy c)
   505   handle TYPE (msg, _, _) => error msg;
   506 
   507 fun read_sort' syn ctxt str =
   508   let
   509     val thy = ProofContext.theory_of ctxt;
   510     val _ = Context.check_thy thy;
   511     val S = Syntax.read_sort ctxt syn (intern_sort thy) str;
   512   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   513 
   514 fun read_sort thy str = read_sort' (syn_of thy) (ProofContext.init thy) str;
   515 
   516 
   517 (* type arities *)
   518 
   519 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   520   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   521   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   522 
   523 val read_arity = prep_arity intern_type read_sort;
   524 val cert_arity = prep_arity (K I) certify_sort;
   525 
   526 
   527 (* types *)
   528 
   529 fun get_sort thy def_sort raw_env =
   530   let
   531     val tsig = tsig_of thy;
   532 
   533     fun eq ((xi, S), (xi', S')) =
   534       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   535     val env = distinct eq raw_env;
   536     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   537       | dups => error ("Inconsistent sort constraints for type variable(s) "
   538           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   539 
   540     fun get xi =
   541       (case (AList.lookup (op =) env xi, def_sort xi) of
   542         (NONE, NONE) => Type.defaultS tsig
   543       | (NONE, SOME S) => S
   544       | (SOME S, NONE) => S
   545       | (SOME S, SOME S') =>
   546           if Type.eq_sort tsig (S, S') then S'
   547           else error ("Sort constraint inconsistent with default for type variable " ^
   548             quote (Term.string_of_vname' xi)));
   549   in get end;
   550 
   551 local
   552 
   553 fun gen_read_typ' cert syn ctxt def_sort str =
   554   let
   555     val thy = ProofContext.theory_of ctxt;
   556     val _ = Context.check_thy thy;
   557     val T = intern_tycons thy
   558       (Syntax.read_typ ctxt syn (get_sort thy def_sort) (intern_sort thy) str);
   559   in cert thy T handle TYPE (msg, _, _) => error msg end
   560   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   561 
   562 fun gen_read_typ cert (thy, def_sort) str =
   563   gen_read_typ' cert (syn_of thy) (ProofContext.init thy) def_sort str;
   564 
   565 in
   566 
   567 fun no_def_sort thy = (thy: theory, K NONE);
   568 
   569 val read_typ'        = gen_read_typ' certify_typ;
   570 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   571 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   572 val read_def_typ     = gen_read_typ certify_typ;
   573 
   574 val read_typ = read_def_typ o no_def_sort;
   575 val read_typ_syntax  = gen_read_typ certify_typ_syntax o no_def_sort;
   576 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev o no_def_sort;
   577 
   578 end;
   579 
   580 
   581 (* type and constant names *)
   582 
   583 fun read_tyname thy raw_c =
   584   let val c = intern_type thy raw_c
   585   in Type (c, replicate (arity_number thy c) dummyT) end;
   586 
   587 val read_const = Consts.read_const o consts_of;
   588 
   589 
   590 
   591 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   592 
   593 (*
   594   def_type: partial map from indexnames to types (constrains Frees and Vars)
   595   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   596   used: context of already used type variables
   597   freeze: if true then generated parameters are turned into TFrees, else TVars
   598 *)
   599 
   600 fun read_def_terms' pp is_logtype syn consts map_free ctxt (def_type, def_sort) used freeze sTs =
   601   let
   602     val thy = ProofContext.theory_of ctxt;
   603 
   604     (*read terms -- potentially ambiguous*)
   605     val map_const = try (#1 o Term.dest_Const o Consts.read_const consts);
   606     val read =
   607       Syntax.read_term (get_sort thy def_sort) map_const map_free
   608         (intern_tycons thy) (intern_sort thy) ctxt is_logtype syn;
   609 
   610     val args = sTs |> map (fn (s, raw_T) =>
   611       let val T = certify_typ thy raw_T handle TYPE (msg, _, _) => error msg
   612       in (read (#1 (TypeInfer.paramify_dummies T 0)) s, T) end);
   613 
   614     (*brute-force disambiguation via type-inference*)
   615     val termss = fold_rev (multiply o fst) args [[]];
   616     val typs = map snd args;
   617 
   618     fun infer ts = Result (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   619         (try (Consts.the_constraint consts)) def_type used freeze (ts ~~ typs) |>> map fst)
   620       handle TYPE (msg, _, _) => Exn (ERROR msg);
   621 
   622     val err_results = map infer termss;
   623     val errs = map_filter (fn Exn (ERROR msg) => SOME msg | _ => NONE) err_results;
   624     val results = map_filter get_result err_results;
   625 
   626     val ambiguity = length termss;
   627     fun ambig_msg () =
   628       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level then
   629         "Got more than one parse tree.\n\
   630         \Retry with smaller Syntax.ambiguity_level for more information."
   631       else "";
   632   in
   633     if null results then cat_error (ambig_msg ()) (cat_lines errs)
   634     else if length results = 1 then
   635       (if ambiguity > ! Syntax.ambiguity_level then
   636         warning "Fortunately, only one parse tree is type correct.\n\
   637           \You may still want to disambiguate your grammar or your input."
   638       else (); hd results)
   639     else cat_error (ambig_msg ()) ("More than one term is type correct:\n" ^
   640       cat_lines (map (Pretty.string_of_term pp) (maps fst results)))
   641   end;
   642 
   643 fun read_def_terms (thy, types, sorts) used freeze sTs =
   644   let
   645     val pp = pp thy;
   646     val consts = consts_of thy;
   647     val cert_consts = Consts.certify pp (tsig_of thy) consts;
   648     fun map_free x = if is_some (types (x, ~1)) then SOME x else NONE;
   649     val (ts, inst) =
   650       read_def_terms' pp (is_logtype thy) (syn_of thy) consts map_free
   651         (ProofContext.init thy) (types, sorts) (Name.make_context used) freeze sTs;
   652   in (map cert_consts ts, inst) end;
   653 
   654 fun simple_read_term thy T s =
   655   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   656   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   657 
   658 fun read_term thy = simple_read_term thy dummyT;
   659 fun read_prop thy = simple_read_term thy propT;
   660 
   661 
   662 
   663 (** signature extension functions **)  (*exception ERROR/TYPE*)
   664 
   665 (* add default sort *)
   666 
   667 fun gen_add_defsort prep_sort s thy =
   668   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   669 
   670 val add_defsort = gen_add_defsort read_sort;
   671 val add_defsort_i = gen_add_defsort certify_sort;
   672 
   673 
   674 (* add type constructors *)
   675 
   676 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   677   let
   678     val syn' = Syntax.extend_type_gram types syn;
   679     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   680     val tsig' = Type.add_types naming decls tsig;
   681   in (naming, syn', tsig', consts) end);
   682 
   683 fun add_typedecls decls thy =
   684   let
   685     fun type_of (a, vs: string list, mx) =
   686       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   687       else error ("Duplicate parameters in type declaration: " ^ quote a);
   688   in add_types (map type_of decls) thy end;
   689 
   690 
   691 (* add nonterminals *)
   692 
   693 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   694   let
   695     val syn' = Syntax.extend_consts ns syn;
   696     val tsig' = Type.add_nonterminals naming ns tsig;
   697   in (naming, syn', tsig', consts) end);
   698 
   699 
   700 (* add type abbreviations *)
   701 
   702 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   703   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   704     let
   705       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   706       val a' = Syntax.type_name a mx;
   707       val abbr = (a', vs, prep_typ thy rhs)
   708         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   709       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   710     in (naming, syn', tsig', consts) end);
   711 
   712 val add_tyabbrs = fold (gen_add_tyabbr read_typ_syntax);
   713 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   714 
   715 
   716 (* modify syntax *)
   717 
   718 fun gen_syntax change_gram prep_typ mode args thy =
   719   let
   720     fun prep (c, T, mx) = (c, prep_typ thy T, mx) handle ERROR msg =>
   721       cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   722   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   723 
   724 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   725 
   726 val add_modesyntax = gen_add_syntax read_typ_syntax;
   727 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   728 val add_syntax = add_modesyntax Syntax.default_mode;
   729 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   730 val del_modesyntax = gen_syntax Syntax.remove_const_gram read_typ_syntax;
   731 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   732 
   733 fun const_syntax thy (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   734   | const_syntax _ _ = NONE;
   735 
   736 fun add_notation mode args thy =
   737   thy |> add_modesyntax_i mode (map_filter (const_syntax thy) args);
   738 
   739 
   740 (* add constants *)
   741 
   742 local
   743 
   744 fun gen_add_consts prep_typ authentic raw_args thy =
   745   let
   746     val prepT = Compress.typ thy o Logic.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   747     fun prep (raw_c, raw_T, raw_mx) =
   748       let
   749         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   750         val c' = if authentic then Syntax.constN ^ full_name thy c else c;
   751         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   752           cat_error msg ("in declaration of constant " ^ quote c);
   753       in (((c, T), authentic), (c', T, mx)) end;
   754     val args = map prep raw_args;
   755   in
   756     thy
   757     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   758     |> add_syntax_i (map #2 args)
   759   end;
   760 
   761 in
   762 
   763 val add_consts = gen_add_consts read_typ false;
   764 val add_consts_i = gen_add_consts certify_typ false;
   765 val add_consts_authentic = gen_add_consts certify_typ true;
   766 
   767 end;
   768 
   769 
   770 (* add abbreviations *)
   771 
   772 fun add_abbrev mode (c, raw_t) thy =
   773   let
   774     val pp = pp thy;
   775     val prep_tm = Compress.term thy o no_frees pp o
   776       map_types Logic.legacy_varifyT (* FIXME tmp *) o
   777       Term.no_dummy_patterns o cert_term_abbrev thy;
   778     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   779       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   780     val (res, consts') = consts_of thy
   781       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode (c, t);
   782   in (res, thy |> map_consts (K consts')) end;
   783 
   784 
   785 (* add constraints *)
   786 
   787 fun gen_add_constraint int_const prep_typ (raw_c, opt_T) thy =
   788   let
   789     val c = int_const thy raw_c;
   790     fun prepT raw_T =
   791       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (prep_typ thy raw_T)))
   792       in cert_term thy (Const (c, T)); T end
   793       handle TYPE (msg, _, _) => error msg;
   794   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   795 
   796 val add_const_constraint = gen_add_constraint intern_const read_typ;
   797 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   798 
   799 
   800 (* primitive classes and arities *)
   801 
   802 fun primitive_class (bclass, classes) thy =
   803   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   804     let
   805       val syn' = Syntax.extend_consts [bclass] syn;
   806       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   807     in (naming, syn', tsig', consts) end)
   808   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   809 
   810 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   811 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   812 
   813 
   814 (* add translation functions *)
   815 
   816 local
   817 
   818 fun mk trs = map Syntax.mk_trfun trs;
   819 
   820 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   821   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   822 
   823 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   824 
   825 in
   826 
   827 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   828 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   829 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   830 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   831 
   832 end;
   833 
   834 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   835 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   836 
   837 
   838 (* translation rules *)
   839 
   840 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   841   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   842   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   843 
   844 val add_trrules = gen_trrules Syntax.extend_trrules;
   845 val del_trrules = gen_trrules Syntax.remove_trrules;
   846 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   847 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   848 
   849 
   850 (* modify naming *)
   851 
   852 val add_path        = map_naming o NameSpace.add_path;
   853 val no_base_names   = map_naming NameSpace.no_base_names;
   854 val qualified_names = map_naming NameSpace.qualified_names;
   855 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   856 val set_policy      = map_naming o NameSpace.set_policy;
   857 val restore_naming  = map_naming o K o naming_of;
   858 
   859 val parent_path   = add_path "..";
   860 val root_path     = add_path "/";
   861 val absolute_path = add_path "//";
   862 
   863 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   864 
   865 
   866 (* hide names *)
   867 
   868 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   869 val hide_classes_i = map_tsig oo Type.hide_classes;
   870 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   871 val hide_types_i = map_tsig oo Type.hide_types;
   872 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   873 val hide_consts_i = map_consts oo (fold o Consts.hide);
   874 
   875 local
   876 
   877 val kinds =
   878  [("class", (intern_class, can o certify_class, hide_classes_i)),
   879   ("type", (intern_type, declared_tyname, hide_types_i)),
   880   ("const", (intern_const, declared_const, hide_consts_i))];
   881 
   882 fun gen_hide int b (kind, xnames) thy =
   883   (case AList.lookup (op =) kinds kind of
   884     SOME (intern, check, hide) =>
   885       let
   886         val names = if int then map (intern thy) xnames else xnames;
   887         val bads = filter_out (check thy) names;
   888       in
   889         if null bads then hide b names thy
   890         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   891       end
   892   | NONE => error ("Bad name space specification: " ^ quote kind));
   893 
   894 in
   895 
   896 val hide_names = gen_hide true;
   897 val hide_names_i = gen_hide false;
   898 
   899 end;
   900 
   901 end;