src/HOL/Map.thy
author nipkow
Thu Mar 23 20:03:53 2006 +0100 (2006-03-23)
changeset 19323 ec5cd5b1804c
parent 18576 8d98b7711e47
child 19378 6cc9ac729eb5
permissions -rw-r--r--
Converted translations to abbbreviations.
Removed a few odd functions from Map and AssocList.
Moved chg_map from Map to Bali/Basis.
     1 (*  Title:      HOL/Map.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     4     Copyright   1997-2003 TU Muenchen
     5 
     6 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     7 *)
     8 
     9 header {* Maps *}
    10 
    11 theory Map
    12 imports List
    13 begin
    14 
    15 types ('a,'b) "~=>" = "'a => 'b option" (infixr 0)
    16 translations (type) "a ~=> b " <= (type) "a => b option"
    17 
    18 consts
    19 map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)" (infixl "++" 100)
    20 restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" (infixl "|`"  110)
    21 dom	:: "('a ~=> 'b) => 'a set"
    22 ran	:: "('a ~=> 'b) => 'b set"
    23 map_of	:: "('a * 'b)list => 'a ~=> 'b"
    24 map_upds:: "('a ~=> 'b) => 'a list => 'b list => ('a ~=> 'b)"
    25 map_le  :: "('a ~=> 'b) => ('a ~=> 'b) => bool" (infix "\<subseteq>\<^sub>m" 50)
    26 
    27 constdefs
    28   map_comp :: "('b ~=> 'c)  => ('a ~=> 'b) => ('a ~=> 'c)" (infixl "o'_m" 55)
    29   "f o_m g  == (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    30 
    31 syntax
    32   empty     ::  "'a ~=> 'b"
    33 translations
    34   "empty"    => "%_. None"
    35   "empty"    <= "%x. None"
    36 
    37 nonterminals
    38   maplets maplet
    39 
    40 syntax
    41   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    42   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    43   ""         :: "maplet => maplets"             ("_")
    44   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    45   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    46   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    47 
    48 syntax (xsymbols)
    49   "~=>"     :: "[type, type] => type"    (infixr "\<rightharpoonup>" 0)
    50 
    51   map_comp :: "('b ~=> 'c)  => ('a ~=> 'b) => ('a ~=> 'c)" (infixl "\<circ>\<^sub>m" 55)
    52 
    53   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    54   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    55 
    56 syntax (latex output)
    57   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    58   --"requires amssymb!"
    59 
    60 translations
    61   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    62   "_MapUpd m (_maplet  x y)"    == "m(x:=Some y)"
    63   "_MapUpd m (_maplets x y)"    == "map_upds m x y"
    64   "_Map ms"                     == "_MapUpd empty ms"
    65   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    66   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    67 
    68 defs
    69 map_add_def:   "m1++m2 == %x. case m2 x of None => m1 x | Some y => Some y"
    70 restrict_map_def: "m|`A == %x. if x : A then m x else None"
    71 
    72 map_upds_def: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    73 
    74 dom_def: "dom(m) == {a. m a ~= None}"
    75 ran_def: "ran(m) == {b. EX a. m a = Some b}"
    76 
    77 map_le_def: "m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2  ==  ALL a : dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a"
    78 
    79 primrec
    80   "map_of [] = empty"
    81   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
    82 
    83 (* special purpose constants that should be defined somewhere else and
    84 whose syntax is a bit odd as well:
    85 
    86  "@chg_map" :: "('a ~=> 'b) => 'a => ('b => 'b) => ('a ~=> 'b)"
    87 					  ("_/'(_/\<mapsto>\<lambda>_. _')"  [900,0,0,0] 900)
    88   "m(x\<mapsto>\<lambda>y. f)" == "chg_map (\<lambda>y. f) x m"
    89 
    90 map_upd_s::"('a ~=> 'b) => 'a set => 'b => 
    91 	    ('a ~=> 'b)"			 ("_/'(_{|->}_/')" [900,0,0]900)
    92 map_subst::"('a ~=> 'b) => 'b => 'b => 
    93 	    ('a ~=> 'b)"			 ("_/'(_~>_/')"    [900,0,0]900)
    94 
    95 map_upd_s_def: "m(as{|->}b) == %x. if x : as then Some b else m x"
    96 map_subst_def: "m(a~>b)     == %x. if m x = Some a then Some b else m x"
    97 
    98   map_upd_s  :: "('a ~=> 'b) => 'a set => 'b => ('a ~=> 'b)"
    99 				    		 ("_/'(_/{\<mapsto>}/_')" [900,0,0]900)
   100   map_subst :: "('a ~=> 'b) => 'b => 'b => 
   101 	        ('a ~=> 'b)"			 ("_/'(_\<leadsto>_/')"    [900,0,0]900)
   102 
   103 
   104 subsection {* @{term [source] map_upd_s} *}
   105 
   106 lemma map_upd_s_apply [simp]: 
   107   "(m(as{|->}b)) x = (if x : as then Some b else m x)"
   108 by (simp add: map_upd_s_def)
   109 
   110 lemma map_subst_apply [simp]: 
   111   "(m(a~>b)) x = (if m x = Some a then Some b else m x)" 
   112 by (simp add: map_subst_def)
   113 
   114 *)
   115 
   116 subsection {* @{term [source] empty} *}
   117 
   118 lemma empty_upd_none[simp]: "empty(x := None) = empty"
   119 apply (rule ext)
   120 apply (simp (no_asm))
   121 done
   122 
   123 
   124 (* FIXME: what is this sum_case nonsense?? *)
   125 lemma sum_case_empty_empty[simp]: "sum_case empty empty = empty"
   126 apply (rule ext)
   127 apply (simp (no_asm) split add: sum.split)
   128 done
   129 
   130 subsection {* @{term [source] map_upd} *}
   131 
   132 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   133 apply (rule ext)
   134 apply (simp (no_asm_simp))
   135 done
   136 
   137 lemma map_upd_nonempty[simp]: "t(k|->x) ~= empty"
   138 apply safe
   139 apply (drule_tac x = k in fun_cong)
   140 apply (simp (no_asm_use))
   141 done
   142 
   143 lemma map_upd_eqD1: "m(a\<mapsto>x) = n(a\<mapsto>y) \<Longrightarrow> x = y"
   144 by (drule fun_cong [of _ _ a], auto)
   145 
   146 lemma map_upd_Some_unfold: 
   147   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   148 by auto
   149 
   150 lemma image_map_upd[simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   151 by fastsimp
   152 
   153 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   154 apply (unfold image_def)
   155 apply (simp (no_asm_use) add: full_SetCompr_eq)
   156 apply (rule finite_subset)
   157 prefer 2 apply assumption
   158 apply auto
   159 done
   160 
   161 
   162 (* FIXME: what is this sum_case nonsense?? *)
   163 subsection {* @{term [source] sum_case} and @{term [source] empty}/@{term [source] map_upd} *}
   164 
   165 lemma sum_case_map_upd_empty[simp]:
   166  "sum_case (m(k|->y)) empty =  (sum_case m empty)(Inl k|->y)"
   167 apply (rule ext)
   168 apply (simp (no_asm) split add: sum.split)
   169 done
   170 
   171 lemma sum_case_empty_map_upd[simp]:
   172  "sum_case empty (m(k|->y)) =  (sum_case empty m)(Inr k|->y)"
   173 apply (rule ext)
   174 apply (simp (no_asm) split add: sum.split)
   175 done
   176 
   177 lemma sum_case_map_upd_map_upd[simp]:
   178  "sum_case (m1(k1|->y1)) (m2(k2|->y2)) = (sum_case (m1(k1|->y1)) m2)(Inr k2|->y2)"
   179 apply (rule ext)
   180 apply (simp (no_asm) split add: sum.split)
   181 done
   182 
   183 
   184 subsection {* @{term [source] map_of} *}
   185 
   186 lemma map_of_eq_None_iff:
   187  "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   188 by (induct xys) simp_all
   189 
   190 lemma map_of_is_SomeD:
   191  "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   192 apply(induct xys)
   193  apply simp
   194 apply(clarsimp split:if_splits)
   195 done
   196 
   197 lemma map_of_eq_Some_iff[simp]:
   198  "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   199 apply(induct xys)
   200  apply(simp)
   201 apply(auto simp:map_of_eq_None_iff[symmetric])
   202 done
   203 
   204 lemma Some_eq_map_of_iff[simp]:
   205  "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   206 by(auto simp del:map_of_eq_Some_iff simp add:map_of_eq_Some_iff[symmetric])
   207 
   208 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   209   \<Longrightarrow> map_of xys x = Some y"
   210 apply (induct xys)
   211  apply simp
   212 apply force
   213 done
   214 
   215 lemma map_of_zip_is_None[simp]:
   216   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   217 by (induct rule:list_induct2, simp_all)
   218 
   219 lemma finite_range_map_of: "finite (range (map_of xys))"
   220 apply (induct xys)
   221 apply  (simp_all (no_asm) add: image_constant)
   222 apply (rule finite_subset)
   223 prefer 2 apply assumption
   224 apply auto
   225 done
   226 
   227 lemma map_of_SomeD [rule_format]: "map_of xs k = Some y --> (k,y):set xs"
   228 by (induct "xs", auto)
   229 
   230 lemma map_of_mapk_SomeI [rule_format]:
   231      "inj f ==> map_of t k = Some x -->  
   232         map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   233 apply (induct "t")
   234 apply  (auto simp add: inj_eq)
   235 done
   236 
   237 lemma weak_map_of_SomeI [rule_format]:
   238      "(k, x) : set l --> (\<exists>x. map_of l k = Some x)"
   239 by (induct "l", auto)
   240 
   241 lemma map_of_filter_in: 
   242 "[| map_of xs k = Some z; P k z |] ==> map_of (filter (split P) xs) k = Some z"
   243 apply (rule mp)
   244 prefer 2 apply assumption
   245 apply (erule thin_rl)
   246 apply (induct "xs", auto)
   247 done
   248 
   249 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = option_map f (map_of xs x)"
   250 by (induct "xs", auto)
   251 
   252 
   253 subsection {* @{term [source] option_map} related *}
   254 
   255 lemma option_map_o_empty[simp]: "option_map f o empty = empty"
   256 apply (rule ext)
   257 apply (simp (no_asm))
   258 done
   259 
   260 lemma option_map_o_map_upd[simp]:
   261  "option_map f o m(a|->b) = (option_map f o m)(a|->f b)"
   262 apply (rule ext)
   263 apply (simp (no_asm))
   264 done
   265 
   266 subsection {* @{term [source] map_comp} related *}
   267 
   268 lemma map_comp_empty [simp]: 
   269   "m \<circ>\<^sub>m empty = empty"
   270   "empty \<circ>\<^sub>m m = empty"
   271   by (auto simp add: map_comp_def intro: ext split: option.splits)
   272 
   273 lemma map_comp_simps [simp]: 
   274   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   275   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'" 
   276   by (auto simp add: map_comp_def)
   277 
   278 lemma map_comp_Some_iff:
   279   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)" 
   280   by (auto simp add: map_comp_def split: option.splits)
   281 
   282 lemma map_comp_None_iff:
   283   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) " 
   284   by (auto simp add: map_comp_def split: option.splits)
   285 
   286 subsection {* @{text "++"} *}
   287 
   288 lemma map_add_empty[simp]: "m ++ empty = m"
   289 apply (unfold map_add_def)
   290 apply (simp (no_asm))
   291 done
   292 
   293 lemma empty_map_add[simp]: "empty ++ m = m"
   294 apply (unfold map_add_def)
   295 apply (rule ext)
   296 apply (simp split add: option.split)
   297 done
   298 
   299 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   300 apply(rule ext)
   301 apply(simp add: map_add_def split:option.split)
   302 done
   303 
   304 lemma map_add_Some_iff: 
   305  "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   306 apply (unfold map_add_def)
   307 apply (simp (no_asm) split add: option.split)
   308 done
   309 
   310 lemmas map_add_SomeD = map_add_Some_iff [THEN iffD1, standard]
   311 declare map_add_SomeD [dest!]
   312 
   313 lemma map_add_find_right[simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   314 by (subst map_add_Some_iff, fast)
   315 
   316 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   317 apply (unfold map_add_def)
   318 apply (simp (no_asm) split add: option.split)
   319 done
   320 
   321 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   322 apply (unfold map_add_def)
   323 apply (rule ext, auto)
   324 done
   325 
   326 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   327 by(simp add:map_upds_def)
   328 
   329 lemma map_of_append[simp]: "map_of (xs@ys) = map_of ys ++ map_of xs"
   330 apply (unfold map_add_def)
   331 apply (induct "xs")
   332 apply (simp (no_asm))
   333 apply (rule ext)
   334 apply (simp (no_asm_simp) split add: option.split)
   335 done
   336 
   337 declare fun_upd_apply [simp del]
   338 lemma finite_range_map_of_map_add:
   339  "finite (range f) ==> finite (range (f ++ map_of l))"
   340 apply (induct "l", auto)
   341 apply (erule finite_range_updI)
   342 done
   343 declare fun_upd_apply [simp]
   344 
   345 lemma inj_on_map_add_dom[iff]:
   346  "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   347 by(fastsimp simp add:map_add_def dom_def inj_on_def split:option.splits)
   348 
   349 subsection {* @{term [source] restrict_map} *}
   350 
   351 lemma restrict_map_to_empty[simp]: "m|`{} = empty"
   352 by(simp add: restrict_map_def)
   353 
   354 lemma restrict_map_empty[simp]: "empty|`D = empty"
   355 by(simp add: restrict_map_def)
   356 
   357 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   358 by (auto simp: restrict_map_def)
   359 
   360 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   361 by (auto simp: restrict_map_def)
   362 
   363 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   364 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   365 
   366 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   367 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   368 
   369 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   370 by (rule ext, auto simp: restrict_map_def)
   371 
   372 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   373 by (rule ext, auto simp: restrict_map_def)
   374 
   375 lemma restrict_fun_upd[simp]:
   376  "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   377 by(simp add: restrict_map_def expand_fun_eq)
   378 
   379 lemma fun_upd_None_restrict[simp]:
   380   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   381 by(simp add: restrict_map_def expand_fun_eq)
   382 
   383 lemma fun_upd_restrict:
   384  "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   385 by(simp add: restrict_map_def expand_fun_eq)
   386 
   387 lemma fun_upd_restrict_conv[simp]:
   388  "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   389 by(simp add: restrict_map_def expand_fun_eq)
   390 
   391 
   392 subsection {* @{term [source] map_upds} *}
   393 
   394 lemma map_upds_Nil1[simp]: "m([] [|->] bs) = m"
   395 by(simp add:map_upds_def)
   396 
   397 lemma map_upds_Nil2[simp]: "m(as [|->] []) = m"
   398 by(simp add:map_upds_def)
   399 
   400 lemma map_upds_Cons[simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   401 by(simp add:map_upds_def)
   402 
   403 lemma map_upds_append1[simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   404   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   405 apply(induct xs)
   406  apply(clarsimp simp add:neq_Nil_conv)
   407 apply (case_tac ys, simp, simp)
   408 done
   409 
   410 lemma map_upds_list_update2_drop[simp]:
   411  "\<And>m ys i. \<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   412      \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   413 apply (induct xs, simp)
   414 apply (case_tac ys, simp)
   415 apply(simp split:nat.split)
   416 done
   417 
   418 lemma map_upd_upds_conv_if: "!!x y ys f.
   419  (f(x|->y))(xs [|->] ys) =
   420  (if x : set(take (length ys) xs) then f(xs [|->] ys)
   421                                   else (f(xs [|->] ys))(x|->y))"
   422 apply (induct xs, simp)
   423 apply(case_tac ys)
   424  apply(auto split:split_if simp:fun_upd_twist)
   425 done
   426 
   427 lemma map_upds_twist [simp]:
   428  "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   429 apply(insert set_take_subset)
   430 apply (fastsimp simp add: map_upd_upds_conv_if)
   431 done
   432 
   433 lemma map_upds_apply_nontin[simp]:
   434  "!!ys. x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   435 apply (induct xs, simp)
   436 apply(case_tac ys)
   437  apply(auto simp: map_upd_upds_conv_if)
   438 done
   439 
   440 lemma fun_upds_append_drop[simp]:
   441   "!!m ys. size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   442 apply(induct xs)
   443  apply (simp)
   444 apply(case_tac ys)
   445 apply simp_all
   446 done
   447 
   448 lemma fun_upds_append2_drop[simp]:
   449   "!!m ys. size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   450 apply(induct xs)
   451  apply (simp)
   452 apply(case_tac ys)
   453 apply simp_all
   454 done
   455 
   456 
   457 lemma restrict_map_upds[simp]: "!!m ys.
   458  \<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   459  \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   460 apply (induct xs, simp)
   461 apply (case_tac ys, simp)
   462 apply(simp add:Diff_insert[symmetric] insert_absorb)
   463 apply(simp add: map_upd_upds_conv_if)
   464 done
   465 
   466 
   467 subsection {* @{term [source] dom} *}
   468 
   469 lemma domI: "m a = Some b ==> a : dom m"
   470 by (unfold dom_def, auto)
   471 (* declare domI [intro]? *)
   472 
   473 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   474 apply (case_tac "m a") 
   475 apply (auto simp add: dom_def) 
   476 done
   477 
   478 lemma domIff[iff]: "(a : dom m) = (m a ~= None)"
   479 by (unfold dom_def, auto)
   480 declare domIff [simp del]
   481 
   482 lemma dom_empty[simp]: "dom empty = {}"
   483 apply (unfold dom_def)
   484 apply (simp (no_asm))
   485 done
   486 
   487 lemma dom_fun_upd[simp]:
   488  "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   489 by (simp add:dom_def) blast
   490 
   491 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   492 apply(induct xys)
   493 apply(auto simp del:fun_upd_apply)
   494 done
   495 
   496 lemma dom_map_of_conv_image_fst:
   497   "dom(map_of xys) = fst ` (set xys)"
   498 by(force simp: dom_map_of)
   499 
   500 lemma dom_map_of_zip[simp]: "[| length xs = length ys; distinct xs |] ==>
   501   dom(map_of(zip xs ys)) = set xs"
   502 by(induct rule: list_induct2, simp_all)
   503 
   504 lemma finite_dom_map_of: "finite (dom (map_of l))"
   505 apply (unfold dom_def)
   506 apply (induct "l")
   507 apply (auto simp add: insert_Collect [symmetric])
   508 done
   509 
   510 lemma dom_map_upds[simp]:
   511  "!!m ys. dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   512 apply (induct xs, simp)
   513 apply (case_tac ys, auto)
   514 done
   515 
   516 lemma dom_map_add[simp]: "dom(m++n) = dom n Un dom m"
   517 by (unfold dom_def, auto)
   518 
   519 lemma dom_override_on[simp]:
   520  "dom(override_on f g A) =
   521  (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   522 by(auto simp add: dom_def override_on_def)
   523 
   524 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   525 apply(rule ext)
   526 apply(force simp: map_add_def dom_def split:option.split) 
   527 done
   528 
   529 subsection {* @{term [source] ran} *}
   530 
   531 lemma ranI: "m a = Some b ==> b : ran m" 
   532 by (auto simp add: ran_def)
   533 (* declare ranI [intro]? *)
   534 
   535 lemma ran_empty[simp]: "ran empty = {}"
   536 apply (unfold ran_def)
   537 apply (simp (no_asm))
   538 done
   539 
   540 lemma ran_map_upd[simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   541 apply (unfold ran_def, auto)
   542 apply (subgoal_tac "~ (aa = a) ")
   543 apply auto
   544 done
   545 
   546 subsection {* @{text "map_le"} *}
   547 
   548 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   549 by(simp add:map_le_def)
   550 
   551 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   552 by(force simp add:map_le_def)
   553 
   554 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   555 by(fastsimp simp add:map_le_def)
   556 
   557 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   558 by(force simp add:map_le_def)
   559 
   560 lemma map_le_upds[simp]:
   561  "!!f g bs. f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   562 apply (induct as, simp)
   563 apply (case_tac bs, auto)
   564 done
   565 
   566 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   567   by (fastsimp simp add: map_le_def dom_def)
   568 
   569 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   570   by (simp add: map_le_def)
   571 
   572 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   573   by (auto simp add: map_le_def dom_def)
   574 
   575 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   576   apply (unfold map_le_def)
   577   apply (rule ext)
   578   apply (case_tac "x \<in> dom f", simp)
   579   apply (case_tac "x \<in> dom g", simp, fastsimp)
   580 done
   581 
   582 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   583   by (fastsimp simp add: map_le_def)
   584 
   585 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   586 by(fastsimp simp add:map_add_def map_le_def expand_fun_eq split:option.splits)
   587 
   588 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   589 by (fastsimp simp add: map_le_def map_add_def dom_def)
   590 
   591 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   592 by (clarsimp simp add: map_le_def map_add_def dom_def split:option.splits)
   593 
   594 end