src/HOL/Fun.thy
author hoelzl
Fri May 20 21:38:32 2011 +0200 (2011-05-20)
changeset 42903 ec9eb1fbfcb8
parent 42238 d53dccb38dd1
child 43705 8e421a529a48
permissions -rw-r--r--
add surj_vimage_empty
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattice
    10 uses ("Tools/enriched_type.ML")
    11 begin
    12 
    13 text{*As a simplification rule, it replaces all function equalities by
    14   first-order equalities.*}
    15 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
    16 apply (rule iffI)
    17 apply (simp (no_asm_simp))
    18 apply (rule ext)
    19 apply (simp (no_asm_simp))
    20 done
    21 
    22 lemma apply_inverse:
    23   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    24   by auto
    25 
    26 
    27 subsection {* The Identity Function @{text id} *}
    28 
    29 definition
    30   id :: "'a \<Rightarrow> 'a"
    31 where
    32   "id = (\<lambda>x. x)"
    33 
    34 lemma id_apply [simp]: "id x = x"
    35   by (simp add: id_def)
    36 
    37 lemma image_ident [simp]: "(%x. x) ` Y = Y"
    38 by blast
    39 
    40 lemma image_id [simp]: "id ` Y = Y"
    41 by (simp add: id_def)
    42 
    43 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
    44 by blast
    45 
    46 lemma vimage_id [simp]: "id -` A = A"
    47 by (simp add: id_def)
    48 
    49 
    50 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    51 
    52 definition
    53   comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55)
    54 where
    55   "f o g = (\<lambda>x. f (g x))"
    56 
    57 notation (xsymbols)
    58   comp  (infixl "\<circ>" 55)
    59 
    60 notation (HTML output)
    61   comp  (infixl "\<circ>" 55)
    62 
    63 text{*compatibility*}
    64 lemmas o_def = comp_def
    65 
    66 lemma o_apply [simp]: "(f o g) x = f (g x)"
    67 by (simp add: comp_def)
    68 
    69 lemma o_assoc: "f o (g o h) = f o g o h"
    70 by (simp add: comp_def)
    71 
    72 lemma id_o [simp]: "id o g = g"
    73 by (simp add: comp_def)
    74 
    75 lemma o_id [simp]: "f o id = f"
    76 by (simp add: comp_def)
    77 
    78 lemma o_eq_dest:
    79   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    80   by (simp only: o_def) (fact fun_cong)
    81 
    82 lemma o_eq_elim:
    83   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    84   by (erule meta_mp) (fact o_eq_dest) 
    85 
    86 lemma image_compose: "(f o g) ` r = f`(g`r)"
    87 by (simp add: comp_def, blast)
    88 
    89 lemma vimage_compose: "(g \<circ> f) -` x = f -` (g -` x)"
    90   by auto
    91 
    92 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
    93 by (unfold comp_def, blast)
    94 
    95 
    96 subsection {* The Forward Composition Operator @{text fcomp} *}
    97 
    98 definition
    99   fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60)
   100 where
   101   "f \<circ>> g = (\<lambda>x. g (f x))"
   102 
   103 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
   104   by (simp add: fcomp_def)
   105 
   106 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
   107   by (simp add: fcomp_def)
   108 
   109 lemma id_fcomp [simp]: "id \<circ>> g = g"
   110   by (simp add: fcomp_def)
   111 
   112 lemma fcomp_id [simp]: "f \<circ>> id = f"
   113   by (simp add: fcomp_def)
   114 
   115 code_const fcomp
   116   (Eval infixl 1 "#>")
   117 
   118 no_notation fcomp (infixl "\<circ>>" 60)
   119 
   120 
   121 subsection {* Mapping functions *}
   122 
   123 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   124   "map_fun f g h = g \<circ> h \<circ> f"
   125 
   126 lemma map_fun_apply [simp]:
   127   "map_fun f g h x = g (h (f x))"
   128   by (simp add: map_fun_def)
   129 
   130 
   131 subsection {* Injectivity and Bijectivity *}
   132 
   133 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   134   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   135 
   136 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   137   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   138 
   139 text{*A common special case: functions injective, surjective or bijective over
   140 the entire domain type.*}
   141 
   142 abbreviation
   143   "inj f \<equiv> inj_on f UNIV"
   144 
   145 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   146   "surj f \<equiv> (range f = UNIV)"
   147 
   148 abbreviation
   149   "bij f \<equiv> bij_betw f UNIV UNIV"
   150 
   151 lemma injI:
   152   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   153   shows "inj f"
   154   using assms unfolding inj_on_def by auto
   155 
   156 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   157   by (unfold inj_on_def, blast)
   158 
   159 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   160 by (simp add: inj_on_def)
   161 
   162 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   163 by (force simp add: inj_on_def)
   164 
   165 lemma inj_on_cong:
   166   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   167 unfolding inj_on_def by auto
   168 
   169 lemma inj_on_strict_subset:
   170   "\<lbrakk> inj_on f B; A < B \<rbrakk> \<Longrightarrow> f`A < f`B"
   171 unfolding inj_on_def unfolding image_def by blast
   172 
   173 lemma inj_comp:
   174   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   175   by (simp add: inj_on_def)
   176 
   177 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   178   by (simp add: inj_on_def fun_eq_iff)
   179 
   180 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   181 by (simp add: inj_on_eq_iff)
   182 
   183 lemma inj_on_id[simp]: "inj_on id A"
   184   by (simp add: inj_on_def)
   185 
   186 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   187 by (simp add: inj_on_def)
   188 
   189 lemma inj_on_Int: "\<lbrakk>inj_on f A; inj_on f B\<rbrakk> \<Longrightarrow> inj_on f (A \<inter> B)"
   190 unfolding inj_on_def by blast
   191 
   192 lemma inj_on_INTER:
   193   "\<lbrakk>I \<noteq> {}; \<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)\<rbrakk> \<Longrightarrow> inj_on f (\<Inter> i \<in> I. A i)"
   194 unfolding inj_on_def by blast
   195 
   196 lemma inj_on_Inter:
   197   "\<lbrakk>S \<noteq> {}; \<And> A. A \<in> S \<Longrightarrow> inj_on f A\<rbrakk> \<Longrightarrow> inj_on f (Inter S)"
   198 unfolding inj_on_def by blast
   199 
   200 lemma inj_on_UNION_chain:
   201   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   202          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   203   shows "inj_on f (\<Union> i \<in> I. A i)"
   204 proof(unfold inj_on_def UNION_def, auto)
   205   fix i j x y
   206   assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
   207          and ***: "f x = f y"
   208   show "x = y"
   209   proof-
   210     {assume "A i \<le> A j"
   211      with ** have "x \<in> A j" by auto
   212      with INJ * ** *** have ?thesis
   213      by(auto simp add: inj_on_def)
   214     }
   215     moreover
   216     {assume "A j \<le> A i"
   217      with ** have "y \<in> A i" by auto
   218      with INJ * ** *** have ?thesis
   219      by(auto simp add: inj_on_def)
   220     }
   221     ultimately show ?thesis using  CH * by blast
   222   qed
   223 qed
   224 
   225 lemma surj_id: "surj id"
   226 by simp
   227 
   228 lemma bij_id[simp]: "bij id"
   229 by (simp add: bij_betw_def)
   230 
   231 lemma inj_onI:
   232     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   233 by (simp add: inj_on_def)
   234 
   235 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   236 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   237 
   238 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   239 by (unfold inj_on_def, blast)
   240 
   241 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   242 by (blast dest!: inj_onD)
   243 
   244 lemma comp_inj_on:
   245      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   246 by (simp add: comp_def inj_on_def)
   247 
   248 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   249 apply(simp add:inj_on_def image_def)
   250 apply blast
   251 done
   252 
   253 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   254   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   255 apply(unfold inj_on_def)
   256 apply blast
   257 done
   258 
   259 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   260 by (unfold inj_on_def, blast)
   261 
   262 lemma inj_singleton: "inj (%s. {s})"
   263 by (simp add: inj_on_def)
   264 
   265 lemma inj_on_empty[iff]: "inj_on f {}"
   266 by(simp add: inj_on_def)
   267 
   268 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   269 by (unfold inj_on_def, blast)
   270 
   271 lemma inj_on_Un:
   272  "inj_on f (A Un B) =
   273   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   274 apply(unfold inj_on_def)
   275 apply (blast intro:sym)
   276 done
   277 
   278 lemma inj_on_insert[iff]:
   279   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   280 apply(unfold inj_on_def)
   281 apply (blast intro:sym)
   282 done
   283 
   284 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   285 apply(unfold inj_on_def)
   286 apply (blast)
   287 done
   288 
   289 lemma comp_inj_on_iff:
   290   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   291 by(auto simp add: comp_inj_on inj_on_def)
   292 
   293 lemma inj_on_imageI2:
   294   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   295 by(auto simp add: comp_inj_on inj_on_def)
   296 
   297 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   298   by auto
   299 
   300 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   301   using *[symmetric] by auto
   302 
   303 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   304   by (simp add: surj_def)
   305 
   306 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   307   by (simp add: surj_def, blast)
   308 
   309 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   310 apply (simp add: comp_def surj_def, clarify)
   311 apply (drule_tac x = y in spec, clarify)
   312 apply (drule_tac x = x in spec, blast)
   313 done
   314 
   315 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   316   unfolding bij_betw_def by auto
   317 
   318 lemma bij_betw_empty1:
   319   assumes "bij_betw f {} A"
   320   shows "A = {}"
   321 using assms unfolding bij_betw_def by blast
   322 
   323 lemma bij_betw_empty2:
   324   assumes "bij_betw f A {}"
   325   shows "A = {}"
   326 using assms unfolding bij_betw_def by blast
   327 
   328 lemma inj_on_imp_bij_betw:
   329   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   330 unfolding bij_betw_def by simp
   331 
   332 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   333   unfolding bij_betw_def ..
   334 
   335 lemma bijI: "[| inj f; surj f |] ==> bij f"
   336 by (simp add: bij_def)
   337 
   338 lemma bij_is_inj: "bij f ==> inj f"
   339 by (simp add: bij_def)
   340 
   341 lemma bij_is_surj: "bij f ==> surj f"
   342 by (simp add: bij_def)
   343 
   344 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   345 by (simp add: bij_betw_def)
   346 
   347 lemma bij_betw_trans:
   348   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   349 by(auto simp add:bij_betw_def comp_inj_on)
   350 
   351 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   352   by (rule bij_betw_trans)
   353 
   354 lemma bij_betw_comp_iff:
   355   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   356 by(auto simp add: bij_betw_def inj_on_def)
   357 
   358 lemma bij_betw_comp_iff2:
   359   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   360   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   361 using assms
   362 proof(auto simp add: bij_betw_comp_iff)
   363   assume *: "bij_betw (f' \<circ> f) A A''"
   364   thus "bij_betw f A A'"
   365   using IM
   366   proof(auto simp add: bij_betw_def)
   367     assume "inj_on (f' \<circ> f) A"
   368     thus "inj_on f A" using inj_on_imageI2 by blast
   369   next
   370     fix a' assume **: "a' \<in> A'"
   371     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   372     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   373     unfolding bij_betw_def by force
   374     hence "f a \<in> A'" using IM by auto
   375     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   376     thus "a' \<in> f ` A" using 1 by auto
   377   qed
   378 qed
   379 
   380 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   381 proof -
   382   have i: "inj_on f A" and s: "f ` A = B"
   383     using assms by(auto simp:bij_betw_def)
   384   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   385   { fix a b assume P: "?P b a"
   386     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   387     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   388     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   389   } note g = this
   390   have "inj_on ?g B"
   391   proof(rule inj_onI)
   392     fix x y assume "x:B" "y:B" "?g x = ?g y"
   393     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   394     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   395     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   396   qed
   397   moreover have "?g ` B = A"
   398   proof(auto simp:image_def)
   399     fix b assume "b:B"
   400     with s obtain a where P: "?P b a" unfolding image_def by blast
   401     thus "?g b \<in> A" using g[OF P] by auto
   402   next
   403     fix a assume "a:A"
   404     then obtain b where P: "?P b a" using s unfolding image_def by blast
   405     then have "b:B" using s unfolding image_def by blast
   406     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   407   qed
   408   ultimately show ?thesis by(auto simp:bij_betw_def)
   409 qed
   410 
   411 lemma bij_betw_cong:
   412   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   413 unfolding bij_betw_def inj_on_def by force
   414 
   415 lemma bij_betw_id[intro, simp]:
   416   "bij_betw id A A"
   417 unfolding bij_betw_def id_def by auto
   418 
   419 lemma bij_betw_id_iff:
   420   "bij_betw id A B \<longleftrightarrow> A = B"
   421 by(auto simp add: bij_betw_def)
   422 
   423 lemma bij_betw_combine:
   424   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   425   shows "bij_betw f (A \<union> C) (B \<union> D)"
   426   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   427 
   428 lemma bij_betw_UNION_chain:
   429   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   430          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
   431   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
   432 proof(unfold bij_betw_def, auto simp add: image_def)
   433   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   434   using BIJ bij_betw_def[of f] by auto
   435   thus "inj_on f (\<Union> i \<in> I. A i)"
   436   using CH inj_on_UNION_chain[of I A f] by auto
   437 next
   438   fix i x
   439   assume *: "i \<in> I" "x \<in> A i"
   440   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
   441   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
   442 next
   443   fix i x'
   444   assume *: "i \<in> I" "x' \<in> A' i"
   445   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
   446   thus "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
   447   using * by blast
   448 qed
   449 
   450 lemma bij_betw_Disj_Un:
   451   assumes DISJ: "A \<inter> B = {}" and DISJ': "A' \<inter> B' = {}" and
   452           B1: "bij_betw f A A'" and B2: "bij_betw f B B'"
   453   shows "bij_betw f (A \<union> B) (A' \<union> B')"
   454 proof-
   455   have 1: "inj_on f A \<and> inj_on f B"
   456   using B1 B2 by (auto simp add: bij_betw_def)
   457   have 2: "f`A = A' \<and> f`B = B'"
   458   using B1 B2 by (auto simp add: bij_betw_def)
   459   hence "f`(A - B) \<inter> f`(B - A) = {}"
   460   using DISJ DISJ' by blast
   461   hence "inj_on f (A \<union> B)"
   462   using 1 by (auto simp add: inj_on_Un)
   463   (*  *)
   464   moreover
   465   have "f`(A \<union> B) = A' \<union> B'"
   466   using 2 by auto
   467   ultimately show ?thesis
   468   unfolding bij_betw_def by auto
   469 qed
   470 
   471 lemma bij_betw_subset:
   472   assumes BIJ: "bij_betw f A A'" and
   473           SUB: "B \<le> A" and IM: "f ` B = B'"
   474   shows "bij_betw f B B'"
   475 using assms
   476 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   477 
   478 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   479 by simp
   480 
   481 lemma surj_vimage_empty:
   482   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   483   using surj_image_vimage_eq[OF `surj f`, of A]
   484   by (intro iffI) fastsimp+
   485 
   486 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   487 by (simp add: inj_on_def, blast)
   488 
   489 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   490 by (blast intro: sym)
   491 
   492 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   493 by (unfold inj_on_def, blast)
   494 
   495 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   496 apply (unfold bij_def)
   497 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   498 done
   499 
   500 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   501 by(blast dest: inj_onD)
   502 
   503 lemma inj_on_image_Int:
   504    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   505 apply (simp add: inj_on_def, blast)
   506 done
   507 
   508 lemma inj_on_image_set_diff:
   509    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   510 apply (simp add: inj_on_def, blast)
   511 done
   512 
   513 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   514 by (simp add: inj_on_def, blast)
   515 
   516 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   517 by (simp add: inj_on_def, blast)
   518 
   519 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   520 by (blast dest: injD)
   521 
   522 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   523 by (simp add: inj_on_def, blast)
   524 
   525 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   526 by (blast dest: injD)
   527 
   528 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   529 lemma image_INT:
   530    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   531     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   532 apply (simp add: inj_on_def, blast)
   533 done
   534 
   535 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   536   it doesn't matter whether A is empty*)
   537 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   538 apply (simp add: bij_def)
   539 apply (simp add: inj_on_def surj_def, blast)
   540 done
   541 
   542 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   543 by auto
   544 
   545 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   546 by (auto simp add: inj_on_def)
   547 
   548 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   549 apply (simp add: bij_def)
   550 apply (rule equalityI)
   551 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   552 done
   553 
   554 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   555   -- {* The inverse image of a singleton under an injective function
   556          is included in a singleton. *}
   557   apply (auto simp add: inj_on_def)
   558   apply (blast intro: the_equality [symmetric])
   559   done
   560 
   561 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   562   by (auto intro!: inj_onI)
   563 
   564 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   565   by (auto intro!: inj_onI dest: strict_mono_eq)
   566 
   567 
   568 subsection{*Function Updating*}
   569 
   570 definition
   571   fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   572   "fun_upd f a b == % x. if x=a then b else f x"
   573 
   574 nonterminal updbinds and updbind
   575 
   576 syntax
   577   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   578   ""         :: "updbind => updbinds"             ("_")
   579   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   580   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   581 
   582 translations
   583   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   584   "f(x:=y)" == "CONST fun_upd f x y"
   585 
   586 (* Hint: to define the sum of two functions (or maps), use sum_case.
   587          A nice infix syntax could be defined (in Datatype.thy or below) by
   588 notation
   589   sum_case  (infixr "'(+')"80)
   590 *)
   591 
   592 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   593 apply (simp add: fun_upd_def, safe)
   594 apply (erule subst)
   595 apply (rule_tac [2] ext, auto)
   596 done
   597 
   598 (* f x = y ==> f(x:=y) = f *)
   599 lemmas fun_upd_idem = fun_upd_idem_iff [THEN iffD2, standard]
   600 
   601 (* f(x := f x) = f *)
   602 lemmas fun_upd_triv = refl [THEN fun_upd_idem]
   603 declare fun_upd_triv [iff]
   604 
   605 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   606 by (simp add: fun_upd_def)
   607 
   608 (* fun_upd_apply supersedes these two,   but they are useful
   609    if fun_upd_apply is intentionally removed from the simpset *)
   610 lemma fun_upd_same: "(f(x:=y)) x = y"
   611 by simp
   612 
   613 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   614 by simp
   615 
   616 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   617 by (simp add: fun_eq_iff)
   618 
   619 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   620 by (rule ext, auto)
   621 
   622 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   623 by (fastsimp simp:inj_on_def image_def)
   624 
   625 lemma fun_upd_image:
   626      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   627 by auto
   628 
   629 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   630 by (auto intro: ext)
   631 
   632 
   633 subsection {* @{text override_on} *}
   634 
   635 definition
   636   override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
   637 where
   638   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   639 
   640 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   641 by(simp add:override_on_def)
   642 
   643 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   644 by(simp add:override_on_def)
   645 
   646 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   647 by(simp add:override_on_def)
   648 
   649 
   650 subsection {* @{text swap} *}
   651 
   652 definition
   653   swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   654 where
   655   "swap a b f = f (a := f b, b:= f a)"
   656 
   657 lemma swap_self [simp]: "swap a a f = f"
   658 by (simp add: swap_def)
   659 
   660 lemma swap_commute: "swap a b f = swap b a f"
   661 by (rule ext, simp add: fun_upd_def swap_def)
   662 
   663 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   664 by (rule ext, simp add: fun_upd_def swap_def)
   665 
   666 lemma swap_triple:
   667   assumes "a \<noteq> c" and "b \<noteq> c"
   668   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   669   using assms by (simp add: fun_eq_iff swap_def)
   670 
   671 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   672 by (rule ext, simp add: fun_upd_def swap_def)
   673 
   674 lemma swap_image_eq [simp]:
   675   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   676 proof -
   677   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   678     using assms by (auto simp: image_iff swap_def)
   679   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   680   with subset[of f] show ?thesis by auto
   681 qed
   682 
   683 lemma inj_on_imp_inj_on_swap:
   684   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   685   by (simp add: inj_on_def swap_def, blast)
   686 
   687 lemma inj_on_swap_iff [simp]:
   688   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   689 proof
   690   assume "inj_on (swap a b f) A"
   691   with A have "inj_on (swap a b (swap a b f)) A"
   692     by (iprover intro: inj_on_imp_inj_on_swap)
   693   thus "inj_on f A" by simp
   694 next
   695   assume "inj_on f A"
   696   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   697 qed
   698 
   699 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   700   by simp
   701 
   702 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   703   by simp
   704 
   705 lemma bij_betw_swap_iff [simp]:
   706   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   707   by (auto simp: bij_betw_def)
   708 
   709 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   710   by simp
   711 
   712 hide_const (open) swap
   713 
   714 subsection {* Inversion of injective functions *}
   715 
   716 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   717 "the_inv_into A f == %x. THE y. y : A & f y = x"
   718 
   719 lemma the_inv_into_f_f:
   720   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   721 apply (simp add: the_inv_into_def inj_on_def)
   722 apply blast
   723 done
   724 
   725 lemma f_the_inv_into_f:
   726   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   727 apply (simp add: the_inv_into_def)
   728 apply (rule the1I2)
   729  apply(blast dest: inj_onD)
   730 apply blast
   731 done
   732 
   733 lemma the_inv_into_into:
   734   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   735 apply (simp add: the_inv_into_def)
   736 apply (rule the1I2)
   737  apply(blast dest: inj_onD)
   738 apply blast
   739 done
   740 
   741 lemma the_inv_into_onto[simp]:
   742   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   743 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   744 
   745 lemma the_inv_into_f_eq:
   746   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   747   apply (erule subst)
   748   apply (erule the_inv_into_f_f, assumption)
   749   done
   750 
   751 lemma the_inv_into_comp:
   752   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   753   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   754 apply (rule the_inv_into_f_eq)
   755   apply (fast intro: comp_inj_on)
   756  apply (simp add: f_the_inv_into_f the_inv_into_into)
   757 apply (simp add: the_inv_into_into)
   758 done
   759 
   760 lemma inj_on_the_inv_into:
   761   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   762 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   763 
   764 lemma bij_betw_the_inv_into:
   765   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   766 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   767 
   768 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   769   "the_inv f \<equiv> the_inv_into UNIV f"
   770 
   771 lemma the_inv_f_f:
   772   assumes "inj f"
   773   shows "the_inv f (f x) = x" using assms UNIV_I
   774   by (rule the_inv_into_f_f)
   775 
   776 subsection {* Cantor's Paradox *}
   777 
   778 lemma Cantors_paradox [no_atp]:
   779   "\<not>(\<exists>f. f ` A = Pow A)"
   780 proof clarify
   781   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   782   let ?X = "{a \<in> A. a \<notin> f a}"
   783   have "?X \<in> Pow A" unfolding Pow_def by auto
   784   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   785   thus False by best
   786 qed
   787 
   788 subsection {* Setup *} 
   789 
   790 subsubsection {* Proof tools *}
   791 
   792 text {* simplifies terms of the form
   793   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   794 
   795 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   796 let
   797   fun gen_fun_upd NONE T _ _ = NONE
   798     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   799   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   800   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   801     let
   802       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   803             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   804         | find t = NONE
   805     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   806 
   807   fun proc ss ct =
   808     let
   809       val ctxt = Simplifier.the_context ss
   810       val t = Thm.term_of ct
   811     in
   812       case find_double t of
   813         (T, NONE) => NONE
   814       | (T, SOME rhs) =>
   815           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   816             (fn _ =>
   817               rtac eq_reflection 1 THEN
   818               rtac ext 1 THEN
   819               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   820     end
   821 in proc end
   822 *}
   823 
   824 
   825 subsubsection {* Code generator *}
   826 
   827 types_code
   828   "fun"  ("(_ ->/ _)")
   829 attach (term_of) {*
   830 fun term_of_fun_type _ aT _ bT _ = Free ("<function>", aT --> bT);
   831 *}
   832 attach (test) {*
   833 fun gen_fun_type aF aT bG bT i =
   834   let
   835     val tab = Unsynchronized.ref [];
   836     fun mk_upd (x, (_, y)) t = Const ("Fun.fun_upd",
   837       (aT --> bT) --> aT --> bT --> aT --> bT) $ t $ aF x $ y ()
   838   in
   839     (fn x =>
   840        case AList.lookup op = (!tab) x of
   841          NONE =>
   842            let val p as (y, _) = bG i
   843            in (tab := (x, p) :: !tab; y) end
   844        | SOME (y, _) => y,
   845      fn () => Basics.fold mk_upd (!tab) (Const ("HOL.undefined", aT --> bT)))
   846   end;
   847 *}
   848 
   849 code_const "op \<circ>"
   850   (SML infixl 5 "o")
   851   (Haskell infixr 9 ".")
   852 
   853 code_const "id"
   854   (Haskell "id")
   855 
   856 
   857 subsubsection {* Functorial structure of types *}
   858 
   859 use "Tools/enriched_type.ML"
   860 
   861 end