src/HOL/Complete_Lattices.thy
author wenzelm
Wed Apr 10 21:20:35 2013 +0200 (2013-04-10)
changeset 51692 ecd34f863242
parent 51540 eea5c4ca4a0e
child 52141 eff000cab70f
permissions -rw-r--r--
tuned pretty layout: avoid nested Pretty.string_of, which merely happens to work with Isabelle/jEdit since formatting is delegated to Scala side;
declare command "print_case_translations" where it is actually defined;
     1  (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices *}
     4 
     5 theory Complete_Lattices
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50)
    12 
    13 
    14 subsection {* Syntactic infimum and supremum operations *}
    15 
    16 class Inf =
    17   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    18 
    19 class Sup =
    20   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    21 
    22 
    23 subsection {* Abstract complete lattices *}
    24 
    25 class complete_lattice = bounded_lattice + Inf + Sup +
    26   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    27      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    28   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    29      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    30 begin
    31 
    32 lemma dual_complete_lattice:
    33   "class.complete_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
    34   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    35     (unfold_locales, (fact bot_least top_greatest
    36         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    37 
    38 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    39   INF_def: "INFI A f = \<Sqinter>(f ` A)"
    40 
    41 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    42   SUP_def: "SUPR A f = \<Squnion>(f ` A)"
    43 
    44 text {*
    45   Note: must use names @{const INFI} and @{const SUPR} here instead of
    46   @{text INF} and @{text SUP} to allow the following syntax coexist
    47   with the plain constant names.
    48 *}
    49 
    50 end
    51 
    52 syntax
    53   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
    54   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
    55   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
    56   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
    57 
    58 syntax (xsymbols)
    59   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
    60   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
    61   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
    62   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
    63 
    64 translations
    65   "INF x y. B"   == "INF x. INF y. B"
    66   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
    67   "INF x. B"     == "INF x:CONST UNIV. B"
    68   "INF x:A. B"   == "CONST INFI A (%x. B)"
    69   "SUP x y. B"   == "SUP x. SUP y. B"
    70   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
    71   "SUP x. B"     == "SUP x:CONST UNIV. B"
    72   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
    73 
    74 print_translation {*
    75   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
    76     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
    77 *} -- {* to avoid eta-contraction of body *}
    78 
    79 context complete_lattice
    80 begin
    81 
    82 lemma INF_foundation_dual [no_atp]:
    83   "complete_lattice.SUPR Inf = INFI"
    84   by (simp add: fun_eq_iff INF_def
    85     complete_lattice.SUP_def [OF dual_complete_lattice])
    86 
    87 lemma SUP_foundation_dual [no_atp]:
    88   "complete_lattice.INFI Sup = SUPR"
    89   by (simp add: fun_eq_iff SUP_def
    90     complete_lattice.INF_def [OF dual_complete_lattice])
    91 
    92 lemma Sup_eqI:
    93   "(\<And>y. y \<in> A \<Longrightarrow> y \<le> x) \<Longrightarrow> (\<And>y. (\<And>z. z \<in> A \<Longrightarrow> z \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> \<Squnion>A = x"
    94   by (blast intro: antisym Sup_least Sup_upper)
    95 
    96 lemma Inf_eqI:
    97   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> y \<le> i) \<Longrightarrow> y \<le> x) \<Longrightarrow> \<Sqinter>A = x"
    98   by (blast intro: antisym Inf_greatest Inf_lower)
    99 
   100 lemma SUP_eqI:
   101   "(\<And>i. i \<in> A \<Longrightarrow> f i \<le> x) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> (\<Squnion>i\<in>A. f i) = x"
   102   unfolding SUP_def by (rule Sup_eqI) auto
   103 
   104 lemma INF_eqI:
   105   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> f i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<ge> y) \<Longrightarrow> x \<ge> y) \<Longrightarrow> (\<Sqinter>i\<in>A. f i) = x"
   106   unfolding INF_def by (rule Inf_eqI) auto
   107 
   108 lemma INF_lower: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> f i"
   109   by (auto simp add: INF_def intro: Inf_lower)
   110 
   111 lemma INF_greatest: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> f i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. f i)"
   112   by (auto simp add: INF_def intro: Inf_greatest)
   113 
   114 lemma SUP_upper: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   115   by (auto simp add: SUP_def intro: Sup_upper)
   116 
   117 lemma SUP_least: "(\<And>i. i \<in> A \<Longrightarrow> f i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. f i) \<sqsubseteq> u"
   118   by (auto simp add: SUP_def intro: Sup_least)
   119 
   120 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   121   using Inf_lower [of u A] by auto
   122 
   123 lemma INF_lower2: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> u"
   124   using INF_lower [of i A f] by auto
   125 
   126 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   127   using Sup_upper [of u A] by auto
   128 
   129 lemma SUP_upper2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> f i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   130   using SUP_upper [of i A f] by auto
   131 
   132 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
   133   by (auto intro: Inf_greatest dest: Inf_lower)
   134 
   135 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. f i) \<longleftrightarrow> (\<forall>i\<in>A. u \<sqsubseteq> f i)"
   136   by (auto simp add: INF_def le_Inf_iff)
   137 
   138 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
   139   by (auto intro: Sup_least dest: Sup_upper)
   140 
   141 lemma SUP_le_iff: "(\<Squnion>i\<in>A. f i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i\<in>A. f i \<sqsubseteq> u)"
   142   by (auto simp add: SUP_def Sup_le_iff)
   143 
   144 lemma Inf_empty [simp]:
   145   "\<Sqinter>{} = \<top>"
   146   by (auto intro: antisym Inf_greatest)
   147 
   148 lemma INF_empty [simp]: "(\<Sqinter>x\<in>{}. f x) = \<top>"
   149   by (simp add: INF_def)
   150 
   151 lemma Sup_empty [simp]:
   152   "\<Squnion>{} = \<bottom>"
   153   by (auto intro: antisym Sup_least)
   154 
   155 lemma SUP_empty [simp]: "(\<Squnion>x\<in>{}. f x) = \<bottom>"
   156   by (simp add: SUP_def)
   157 
   158 lemma Inf_UNIV [simp]:
   159   "\<Sqinter>UNIV = \<bottom>"
   160   by (auto intro!: antisym Inf_lower)
   161 
   162 lemma Sup_UNIV [simp]:
   163   "\<Squnion>UNIV = \<top>"
   164   by (auto intro!: antisym Sup_upper)
   165 
   166 lemma Inf_insert [simp]: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   167   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
   168 
   169 lemma INF_insert: "(\<Sqinter>x\<in>insert a A. f x) = f a \<sqinter> INFI A f"
   170   by (simp add: INF_def)
   171 
   172 lemma Sup_insert [simp]: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   173   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
   174 
   175 lemma SUP_insert: "(\<Squnion>x\<in>insert a A. f x) = f a \<squnion> SUPR A f"
   176   by (simp add: SUP_def)
   177 
   178 lemma INF_image [simp]: "(\<Sqinter>x\<in>f`A. g x) = (\<Sqinter>x\<in>A. g (f x))"
   179   by (simp add: INF_def image_image)
   180 
   181 lemma SUP_image [simp]: "(\<Squnion>x\<in>f`A. g x) = (\<Squnion>x\<in>A. g (f x))"
   182   by (simp add: SUP_def image_image)
   183 
   184 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
   185   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   186 
   187 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
   188   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   189 
   190 lemma Inf_superset_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   191   by (auto intro: Inf_greatest Inf_lower)
   192 
   193 lemma Sup_subset_mono: "A \<subseteq> B \<Longrightarrow> \<Squnion>A \<sqsubseteq> \<Squnion>B"
   194   by (auto intro: Sup_least Sup_upper)
   195 
   196 lemma INF_cong:
   197   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Sqinter>x\<in>A. C x) = (\<Sqinter>x\<in>B. D x)"
   198   by (simp add: INF_def image_def)
   199 
   200 lemma SUP_cong:
   201   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Squnion>x\<in>A. C x) = (\<Squnion>x\<in>B. D x)"
   202   by (simp add: SUP_def image_def)
   203 
   204 lemma Inf_mono:
   205   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
   206   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   207 proof (rule Inf_greatest)
   208   fix b assume "b \<in> B"
   209   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
   210   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
   211   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
   212 qed
   213 
   214 lemma INF_mono:
   215   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   216   unfolding INF_def by (rule Inf_mono) fast
   217 
   218 lemma Sup_mono:
   219   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   220   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   221 proof (rule Sup_least)
   222   fix a assume "a \<in> A"
   223   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   224   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   225   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   226 qed
   227 
   228 lemma SUP_mono:
   229   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   230   unfolding SUP_def by (rule Sup_mono) fast
   231 
   232 lemma INF_superset_mono:
   233   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Sqinter>x\<in>A. f x) \<sqsubseteq> (\<Sqinter>x\<in>B. g x)"
   234   -- {* The last inclusion is POSITIVE! *}
   235   by (blast intro: INF_mono dest: subsetD)
   236 
   237 lemma SUP_subset_mono:
   238   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Squnion>x\<in>A. f x) \<sqsubseteq> (\<Squnion>x\<in>B. g x)"
   239   by (blast intro: SUP_mono dest: subsetD)
   240 
   241 lemma Inf_less_eq:
   242   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   243     and "A \<noteq> {}"
   244   shows "\<Sqinter>A \<sqsubseteq> u"
   245 proof -
   246   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   247   moreover with assms have "v \<sqsubseteq> u" by blast
   248   ultimately show ?thesis by (rule Inf_lower2)
   249 qed
   250 
   251 lemma less_eq_Sup:
   252   assumes "\<And>v. v \<in> A \<Longrightarrow> u \<sqsubseteq> v"
   253     and "A \<noteq> {}"
   254   shows "u \<sqsubseteq> \<Squnion>A"
   255 proof -
   256   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   257   moreover with assms have "u \<sqsubseteq> v" by blast
   258   ultimately show ?thesis by (rule Sup_upper2)
   259 qed
   260 
   261 lemma SUPR_eq:
   262   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<le> g j"
   263   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<le> f i"
   264   shows "(SUP i:A. f i) = (SUP j:B. g j)"
   265   by (intro antisym SUP_least) (blast intro: SUP_upper2 dest: assms)+
   266 
   267 lemma INFI_eq:
   268   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<ge> g j"
   269   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<ge> f i"
   270   shows "(INF i:A. f i) = (INF j:B. g j)"
   271   by (intro antisym INF_greatest) (blast intro: INF_lower2 dest: assms)+
   272 
   273 lemma less_eq_Inf_inter: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   274   by (auto intro: Inf_greatest Inf_lower)
   275 
   276 lemma Sup_inter_less_eq: "\<Squnion>(A \<inter> B) \<sqsubseteq> \<Squnion>A \<sqinter> \<Squnion>B "
   277   by (auto intro: Sup_least Sup_upper)
   278 
   279 lemma Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   280   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   281 
   282 lemma INF_union:
   283   "(\<Sqinter>i \<in> A \<union> B. M i) = (\<Sqinter>i \<in> A. M i) \<sqinter> (\<Sqinter>i\<in>B. M i)"
   284   by (auto intro!: antisym INF_mono intro: le_infI1 le_infI2 INF_greatest INF_lower)
   285 
   286 lemma Sup_union_distrib: "\<Squnion>(A \<union> B) = \<Squnion>A \<squnion> \<Squnion>B"
   287   by (rule antisym) (auto intro: Sup_least Sup_upper le_supI1 le_supI2)
   288 
   289 lemma SUP_union:
   290   "(\<Squnion>i \<in> A \<union> B. M i) = (\<Squnion>i \<in> A. M i) \<squnion> (\<Squnion>i\<in>B. M i)"
   291   by (auto intro!: antisym SUP_mono intro: le_supI1 le_supI2 SUP_least SUP_upper)
   292 
   293 lemma INF_inf_distrib: "(\<Sqinter>a\<in>A. f a) \<sqinter> (\<Sqinter>a\<in>A. g a) = (\<Sqinter>a\<in>A. f a \<sqinter> g a)"
   294   by (rule antisym) (rule INF_greatest, auto intro: le_infI1 le_infI2 INF_lower INF_mono)
   295 
   296 lemma SUP_sup_distrib: "(\<Squnion>a\<in>A. f a) \<squnion> (\<Squnion>a\<in>A. g a) = (\<Squnion>a\<in>A. f a \<squnion> g a)" (is "?L = ?R")
   297 proof (rule antisym)
   298   show "?L \<le> ?R" by (auto intro: le_supI1 le_supI2 SUP_upper SUP_mono)
   299 next
   300   show "?R \<le> ?L" by (rule SUP_least) (auto intro: le_supI1 le_supI2 SUP_upper)
   301 qed
   302 
   303 lemma Inf_top_conv [simp, no_atp]:
   304   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   305   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   306 proof -
   307   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   308   proof
   309     assume "\<forall>x\<in>A. x = \<top>"
   310     then have "A = {} \<or> A = {\<top>}" by auto
   311     then show "\<Sqinter>A = \<top>" by auto
   312   next
   313     assume "\<Sqinter>A = \<top>"
   314     show "\<forall>x\<in>A. x = \<top>"
   315     proof (rule ccontr)
   316       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   317       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   318       then obtain B where "A = insert x B" by blast
   319       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by simp
   320     qed
   321   qed
   322   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   323 qed
   324 
   325 lemma INF_top_conv [simp]:
   326  "(\<Sqinter>x\<in>A. B x) = \<top> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   327  "\<top> = (\<Sqinter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   328   by (auto simp add: INF_def)
   329 
   330 lemma Sup_bot_conv [simp, no_atp]:
   331   "\<Squnion>A = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?P)
   332   "\<bottom> = \<Squnion>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?Q)
   333   using dual_complete_lattice
   334   by (rule complete_lattice.Inf_top_conv)+
   335 
   336 lemma SUP_bot_conv [simp]:
   337  "(\<Squnion>x\<in>A. B x) = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   338  "\<bottom> = (\<Squnion>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   339   by (auto simp add: SUP_def)
   340 
   341 lemma INF_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. f) = f"
   342   by (auto intro: antisym INF_lower INF_greatest)
   343 
   344 lemma SUP_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. f) = f"
   345   by (auto intro: antisym SUP_upper SUP_least)
   346 
   347 lemma INF_top [simp]: "(\<Sqinter>x\<in>A. \<top>) = \<top>"
   348   by (cases "A = {}") simp_all
   349 
   350 lemma SUP_bot [simp]: "(\<Squnion>x\<in>A. \<bottom>) = \<bottom>"
   351   by (cases "A = {}") simp_all
   352 
   353 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   354   by (iprover intro: INF_lower INF_greatest order_trans antisym)
   355 
   356 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   357   by (iprover intro: SUP_upper SUP_least order_trans antisym)
   358 
   359 lemma INF_absorb:
   360   assumes "k \<in> I"
   361   shows "A k \<sqinter> (\<Sqinter>i\<in>I. A i) = (\<Sqinter>i\<in>I. A i)"
   362 proof -
   363   from assms obtain J where "I = insert k J" by blast
   364   then show ?thesis by (simp add: INF_insert)
   365 qed
   366 
   367 lemma SUP_absorb:
   368   assumes "k \<in> I"
   369   shows "A k \<squnion> (\<Squnion>i\<in>I. A i) = (\<Squnion>i\<in>I. A i)"
   370 proof -
   371   from assms obtain J where "I = insert k J" by blast
   372   then show ?thesis by (simp add: SUP_insert)
   373 qed
   374 
   375 lemma INF_constant:
   376   "(\<Sqinter>y\<in>A. c) = (if A = {} then \<top> else c)"
   377   by simp
   378 
   379 lemma SUP_constant:
   380   "(\<Squnion>y\<in>A. c) = (if A = {} then \<bottom> else c)"
   381   by simp
   382 
   383 lemma less_INF_D:
   384   assumes "y < (\<Sqinter>i\<in>A. f i)" "i \<in> A" shows "y < f i"
   385 proof -
   386   note `y < (\<Sqinter>i\<in>A. f i)`
   387   also have "(\<Sqinter>i\<in>A. f i) \<le> f i" using `i \<in> A`
   388     by (rule INF_lower)
   389   finally show "y < f i" .
   390 qed
   391 
   392 lemma SUP_lessD:
   393   assumes "(\<Squnion>i\<in>A. f i) < y" "i \<in> A" shows "f i < y"
   394 proof -
   395   have "f i \<le> (\<Squnion>i\<in>A. f i)" using `i \<in> A`
   396     by (rule SUP_upper)
   397   also note `(\<Squnion>i\<in>A. f i) < y`
   398   finally show "f i < y" .
   399 qed
   400 
   401 lemma INF_UNIV_bool_expand:
   402   "(\<Sqinter>b. A b) = A True \<sqinter> A False"
   403   by (simp add: UNIV_bool INF_insert inf_commute)
   404 
   405 lemma SUP_UNIV_bool_expand:
   406   "(\<Squnion>b. A b) = A True \<squnion> A False"
   407   by (simp add: UNIV_bool SUP_insert sup_commute)
   408 
   409 lemma Inf_le_Sup: "A \<noteq> {} \<Longrightarrow> Inf A \<le> Sup A"
   410   by (blast intro: Sup_upper2 Inf_lower ex_in_conv)
   411 
   412 lemma INF_le_SUP: "A \<noteq> {} \<Longrightarrow> INFI A f \<le> SUPR A f"
   413   unfolding INF_def SUP_def by (rule Inf_le_Sup) auto
   414 
   415 end
   416 
   417 class complete_distrib_lattice = complete_lattice +
   418   assumes sup_Inf: "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
   419   assumes inf_Sup: "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   420 begin
   421 
   422 lemma sup_INF:
   423   "a \<squnion> (\<Sqinter>b\<in>B. f b) = (\<Sqinter>b\<in>B. a \<squnion> f b)"
   424   by (simp add: INF_def sup_Inf image_image)
   425 
   426 lemma inf_SUP:
   427   "a \<sqinter> (\<Squnion>b\<in>B. f b) = (\<Squnion>b\<in>B. a \<sqinter> f b)"
   428   by (simp add: SUP_def inf_Sup image_image)
   429 
   430 lemma dual_complete_distrib_lattice:
   431   "class.complete_distrib_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   432   apply (rule class.complete_distrib_lattice.intro)
   433   apply (fact dual_complete_lattice)
   434   apply (rule class.complete_distrib_lattice_axioms.intro)
   435   apply (simp_all only: INF_foundation_dual SUP_foundation_dual inf_Sup sup_Inf)
   436   done
   437 
   438 subclass distrib_lattice proof
   439   fix a b c
   440   from sup_Inf have "a \<squnion> \<Sqinter>{b, c} = (\<Sqinter>d\<in>{b, c}. a \<squnion> d)" .
   441   then show "a \<squnion> b \<sqinter> c = (a \<squnion> b) \<sqinter> (a \<squnion> c)" by (simp add: INF_def)
   442 qed
   443 
   444 lemma Inf_sup:
   445   "\<Sqinter>B \<squnion> a = (\<Sqinter>b\<in>B. b \<squnion> a)"
   446   by (simp add: sup_Inf sup_commute)
   447 
   448 lemma Sup_inf:
   449   "\<Squnion>B \<sqinter> a = (\<Squnion>b\<in>B. b \<sqinter> a)"
   450   by (simp add: inf_Sup inf_commute)
   451 
   452 lemma INF_sup: 
   453   "(\<Sqinter>b\<in>B. f b) \<squnion> a = (\<Sqinter>b\<in>B. f b \<squnion> a)"
   454   by (simp add: sup_INF sup_commute)
   455 
   456 lemma SUP_inf:
   457   "(\<Squnion>b\<in>B. f b) \<sqinter> a = (\<Squnion>b\<in>B. f b \<sqinter> a)"
   458   by (simp add: inf_SUP inf_commute)
   459 
   460 lemma Inf_sup_eq_top_iff:
   461   "(\<Sqinter>B \<squnion> a = \<top>) \<longleftrightarrow> (\<forall>b\<in>B. b \<squnion> a = \<top>)"
   462   by (simp only: Inf_sup INF_top_conv)
   463 
   464 lemma Sup_inf_eq_bot_iff:
   465   "(\<Squnion>B \<sqinter> a = \<bottom>) \<longleftrightarrow> (\<forall>b\<in>B. b \<sqinter> a = \<bottom>)"
   466   by (simp only: Sup_inf SUP_bot_conv)
   467 
   468 lemma INF_sup_distrib2:
   469   "(\<Sqinter>a\<in>A. f a) \<squnion> (\<Sqinter>b\<in>B. g b) = (\<Sqinter>a\<in>A. \<Sqinter>b\<in>B. f a \<squnion> g b)"
   470   by (subst INF_commute) (simp add: sup_INF INF_sup)
   471 
   472 lemma SUP_inf_distrib2:
   473   "(\<Squnion>a\<in>A. f a) \<sqinter> (\<Squnion>b\<in>B. g b) = (\<Squnion>a\<in>A. \<Squnion>b\<in>B. f a \<sqinter> g b)"
   474   by (subst SUP_commute) (simp add: inf_SUP SUP_inf)
   475 
   476 end
   477 
   478 class complete_boolean_algebra = boolean_algebra + complete_distrib_lattice
   479 begin
   480 
   481 lemma dual_complete_boolean_algebra:
   482   "class.complete_boolean_algebra Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom> (\<lambda>x y. x \<squnion> - y) uminus"
   483   by (rule class.complete_boolean_algebra.intro, rule dual_complete_distrib_lattice, rule dual_boolean_algebra)
   484 
   485 lemma uminus_Inf:
   486   "- (\<Sqinter>A) = \<Squnion>(uminus ` A)"
   487 proof (rule antisym)
   488   show "- \<Sqinter>A \<le> \<Squnion>(uminus ` A)"
   489     by (rule compl_le_swap2, rule Inf_greatest, rule compl_le_swap2, rule Sup_upper) simp
   490   show "\<Squnion>(uminus ` A) \<le> - \<Sqinter>A"
   491     by (rule Sup_least, rule compl_le_swap1, rule Inf_lower) auto
   492 qed
   493 
   494 lemma uminus_INF: "- (\<Sqinter>x\<in>A. B x) = (\<Squnion>x\<in>A. - B x)"
   495   by (simp add: INF_def SUP_def uminus_Inf image_image)
   496 
   497 lemma uminus_Sup:
   498   "- (\<Squnion>A) = \<Sqinter>(uminus ` A)"
   499 proof -
   500   have "\<Squnion>A = - \<Sqinter>(uminus ` A)" by (simp add: image_image uminus_Inf)
   501   then show ?thesis by simp
   502 qed
   503   
   504 lemma uminus_SUP: "- (\<Squnion>x\<in>A. B x) = (\<Sqinter>x\<in>A. - B x)"
   505   by (simp add: INF_def SUP_def uminus_Sup image_image)
   506 
   507 end
   508 
   509 class complete_linorder = linorder + complete_lattice
   510 begin
   511 
   512 lemma dual_complete_linorder:
   513   "class.complete_linorder Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   514   by (rule class.complete_linorder.intro, rule dual_complete_lattice, rule dual_linorder)
   515 
   516 lemma complete_linorder_inf_min: "inf = min"
   517   by (auto intro: antisym simp add: min_def fun_eq_iff)
   518 
   519 lemma complete_linorder_sup_max: "sup = max"
   520   by (auto intro: antisym simp add: max_def fun_eq_iff)
   521 
   522 lemma Inf_less_iff:
   523   "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   524   unfolding not_le [symmetric] le_Inf_iff by auto
   525 
   526 lemma INF_less_iff:
   527   "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   528   unfolding INF_def Inf_less_iff by auto
   529 
   530 lemma less_Sup_iff:
   531   "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   532   unfolding not_le [symmetric] Sup_le_iff by auto
   533 
   534 lemma less_SUP_iff:
   535   "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   536   unfolding SUP_def less_Sup_iff by auto
   537 
   538 lemma Sup_eq_top_iff [simp]:
   539   "\<Squnion>A = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < i)"
   540 proof
   541   assume *: "\<Squnion>A = \<top>"
   542   show "(\<forall>x<\<top>. \<exists>i\<in>A. x < i)" unfolding * [symmetric]
   543   proof (intro allI impI)
   544     fix x assume "x < \<Squnion>A" then show "\<exists>i\<in>A. x < i"
   545       unfolding less_Sup_iff by auto
   546   qed
   547 next
   548   assume *: "\<forall>x<\<top>. \<exists>i\<in>A. x < i"
   549   show "\<Squnion>A = \<top>"
   550   proof (rule ccontr)
   551     assume "\<Squnion>A \<noteq> \<top>"
   552     with top_greatest [of "\<Squnion>A"]
   553     have "\<Squnion>A < \<top>" unfolding le_less by auto
   554     then have "\<Squnion>A < \<Squnion>A"
   555       using * unfolding less_Sup_iff by auto
   556     then show False by auto
   557   qed
   558 qed
   559 
   560 lemma SUP_eq_top_iff [simp]:
   561   "(\<Squnion>i\<in>A. f i) = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < f i)"
   562   unfolding SUP_def by auto
   563 
   564 lemma Inf_eq_bot_iff [simp]:
   565   "\<Sqinter>A = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. i < x)"
   566   using dual_complete_linorder
   567   by (rule complete_linorder.Sup_eq_top_iff)
   568 
   569 lemma INF_eq_bot_iff [simp]:
   570   "(\<Sqinter>i\<in>A. f i) = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. f i < x)"
   571   unfolding INF_def by auto
   572 
   573 lemma le_Sup_iff: "x \<le> \<Squnion>A \<longleftrightarrow> (\<forall>y<x. \<exists>a\<in>A. y < a)"
   574 proof safe
   575   fix y assume "x \<le> \<Squnion>A" "y < x"
   576   then have "y < \<Squnion>A" by auto
   577   then show "\<exists>a\<in>A. y < a"
   578     unfolding less_Sup_iff .
   579 qed (auto elim!: allE[of _ "\<Squnion>A"] simp add: not_le[symmetric] Sup_upper)
   580 
   581 lemma le_SUP_iff: "x \<le> SUPR A f \<longleftrightarrow> (\<forall>y<x. \<exists>i\<in>A. y < f i)"
   582   unfolding le_Sup_iff SUP_def by simp
   583 
   584 lemma Inf_le_iff: "\<Sqinter>A \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>a\<in>A. y > a)"
   585 proof safe
   586   fix y assume "x \<ge> \<Sqinter>A" "y > x"
   587   then have "y > \<Sqinter>A" by auto
   588   then show "\<exists>a\<in>A. y > a"
   589     unfolding Inf_less_iff .
   590 qed (auto elim!: allE[of _ "\<Sqinter>A"] simp add: not_le[symmetric] Inf_lower)
   591 
   592 lemma INF_le_iff:
   593   "INFI A f \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>i\<in>A. y > f i)"
   594   unfolding Inf_le_iff INF_def by simp
   595 
   596 subclass complete_distrib_lattice
   597 proof
   598   fix a and B
   599   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)" and "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   600     by (safe intro!: INF_eqI [symmetric] sup_mono Inf_lower SUP_eqI [symmetric] inf_mono Sup_upper)
   601       (auto simp: not_less [symmetric] Inf_less_iff less_Sup_iff
   602         le_max_iff_disj complete_linorder_sup_max min_le_iff_disj complete_linorder_inf_min)
   603 qed
   604 
   605 end
   606 
   607 
   608 subsection {* Complete lattice on @{typ bool} *}
   609 
   610 instantiation bool :: complete_lattice
   611 begin
   612 
   613 definition
   614   [simp, code]: "\<Sqinter>A \<longleftrightarrow> False \<notin> A"
   615 
   616 definition
   617   [simp, code]: "\<Squnion>A \<longleftrightarrow> True \<in> A"
   618 
   619 instance proof
   620 qed (auto intro: bool_induct)
   621 
   622 end
   623 
   624 lemma not_False_in_image_Ball [simp]:
   625   "False \<notin> P ` A \<longleftrightarrow> Ball A P"
   626   by auto
   627 
   628 lemma True_in_image_Bex [simp]:
   629   "True \<in> P ` A \<longleftrightarrow> Bex A P"
   630   by auto
   631 
   632 lemma INF_bool_eq [simp]:
   633   "INFI = Ball"
   634   by (simp add: fun_eq_iff INF_def)
   635 
   636 lemma SUP_bool_eq [simp]:
   637   "SUPR = Bex"
   638   by (simp add: fun_eq_iff SUP_def)
   639 
   640 instance bool :: complete_boolean_algebra proof
   641 qed (auto intro: bool_induct)
   642 
   643 
   644 subsection {* Complete lattice on @{typ "_ \<Rightarrow> _"} *}
   645 
   646 instantiation "fun" :: (type, complete_lattice) complete_lattice
   647 begin
   648 
   649 definition
   650   "\<Sqinter>A = (\<lambda>x. \<Sqinter>f\<in>A. f x)"
   651 
   652 lemma Inf_apply [simp, code]:
   653   "(\<Sqinter>A) x = (\<Sqinter>f\<in>A. f x)"
   654   by (simp add: Inf_fun_def)
   655 
   656 definition
   657   "\<Squnion>A = (\<lambda>x. \<Squnion>f\<in>A. f x)"
   658 
   659 lemma Sup_apply [simp, code]:
   660   "(\<Squnion>A) x = (\<Squnion>f\<in>A. f x)"
   661   by (simp add: Sup_fun_def)
   662 
   663 instance proof
   664 qed (auto simp add: le_fun_def intro: INF_lower INF_greatest SUP_upper SUP_least)
   665 
   666 end
   667 
   668 lemma INF_apply [simp]:
   669   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   670   by (auto intro: arg_cong [of _ _ Inf] simp add: INF_def)
   671 
   672 lemma SUP_apply [simp]:
   673   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   674   by (auto intro: arg_cong [of _ _ Sup] simp add: SUP_def)
   675 
   676 instance "fun" :: (type, complete_distrib_lattice) complete_distrib_lattice proof
   677 qed (auto simp add: INF_def SUP_def inf_Sup sup_Inf image_image)
   678 
   679 instance "fun" :: (type, complete_boolean_algebra) complete_boolean_algebra ..
   680 
   681 
   682 subsection {* Complete lattice on unary and binary predicates *}
   683 
   684 lemma INF1_iff: "(\<Sqinter>x\<in>A. B x) b = (\<forall>x\<in>A. B x b)"
   685   by simp
   686 
   687 lemma INF2_iff: "(\<Sqinter>x\<in>A. B x) b c = (\<forall>x\<in>A. B x b c)"
   688   by simp
   689 
   690 lemma INF1_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b"
   691   by auto
   692 
   693 lemma INF2_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b c) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b c"
   694   by auto
   695 
   696 lemma INF1_D: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> a \<in> A \<Longrightarrow> B a b"
   697   by auto
   698 
   699 lemma INF2_D: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> a \<in> A \<Longrightarrow> B a b c"
   700   by auto
   701 
   702 lemma INF1_E: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> (B a b \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   703   by auto
   704 
   705 lemma INF2_E: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> (B a b c \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   706   by auto
   707 
   708 lemma SUP1_iff: "(\<Squnion>x\<in>A. B x) b = (\<exists>x\<in>A. B x b)"
   709   by simp
   710 
   711 lemma SUP2_iff: "(\<Squnion>x\<in>A. B x) b c = (\<exists>x\<in>A. B x b c)"
   712   by simp
   713 
   714 lemma SUP1_I: "a \<in> A \<Longrightarrow> B a b \<Longrightarrow> (\<Squnion>x\<in>A. B x) b"
   715   by auto
   716 
   717 lemma SUP2_I: "a \<in> A \<Longrightarrow> B a b c \<Longrightarrow> (\<Squnion>x\<in>A. B x) b c"
   718   by auto
   719 
   720 lemma SUP1_E: "(\<Squnion>x\<in>A. B x) b \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b \<Longrightarrow> R) \<Longrightarrow> R"
   721   by auto
   722 
   723 lemma SUP2_E: "(\<Squnion>x\<in>A. B x) b c \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b c \<Longrightarrow> R) \<Longrightarrow> R"
   724   by auto
   725 
   726 
   727 subsection {* Complete lattice on @{typ "_ set"} *}
   728 
   729 instantiation "set" :: (type) complete_lattice
   730 begin
   731 
   732 definition
   733   "\<Sqinter>A = {x. \<Sqinter>((\<lambda>B. x \<in> B) ` A)}"
   734 
   735 definition
   736   "\<Squnion>A = {x. \<Squnion>((\<lambda>B. x \<in> B) ` A)}"
   737 
   738 instance proof
   739 qed (auto simp add: less_eq_set_def Inf_set_def Sup_set_def le_fun_def)
   740 
   741 end
   742 
   743 instance "set" :: (type) complete_boolean_algebra
   744 proof
   745 qed (auto simp add: INF_def SUP_def Inf_set_def Sup_set_def image_def)
   746   
   747 
   748 subsubsection {* Inter *}
   749 
   750 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   751   "Inter S \<equiv> \<Sqinter>S"
   752   
   753 notation (xsymbols)
   754   Inter  ("\<Inter>_" [90] 90)
   755 
   756 lemma Inter_eq:
   757   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   758 proof (rule set_eqI)
   759   fix x
   760   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   761     by auto
   762   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   763     by (simp add: Inf_set_def image_def)
   764 qed
   765 
   766 lemma Inter_iff [simp,no_atp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   767   by (unfold Inter_eq) blast
   768 
   769 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   770   by (simp add: Inter_eq)
   771 
   772 text {*
   773   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   774   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   775   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   776 *}
   777 
   778 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   779   by auto
   780 
   781 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   782   -- {* ``Classical'' elimination rule -- does not require proving
   783     @{prop "X \<in> C"}. *}
   784   by (unfold Inter_eq) blast
   785 
   786 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   787   by (fact Inf_lower)
   788 
   789 lemma Inter_subset:
   790   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   791   by (fact Inf_less_eq)
   792 
   793 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   794   by (fact Inf_greatest)
   795 
   796 lemma Inter_empty: "\<Inter>{} = UNIV"
   797   by (fact Inf_empty) (* already simp *)
   798 
   799 lemma Inter_UNIV: "\<Inter>UNIV = {}"
   800   by (fact Inf_UNIV) (* already simp *)
   801 
   802 lemma Inter_insert: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   803   by (fact Inf_insert) (* already simp *)
   804 
   805 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   806   by (fact less_eq_Inf_inter)
   807 
   808 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   809   by (fact Inf_union_distrib)
   810 
   811 lemma Inter_UNIV_conv [simp, no_atp]:
   812   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   813   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   814   by (fact Inf_top_conv)+
   815 
   816 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   817   by (fact Inf_superset_mono)
   818 
   819 
   820 subsubsection {* Intersections of families *}
   821 
   822 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   823   "INTER \<equiv> INFI"
   824 
   825 text {*
   826   Note: must use name @{const INTER} here instead of @{text INT}
   827   to allow the following syntax coexist with the plain constant name.
   828 *}
   829 
   830 syntax
   831   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   832   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   833 
   834 syntax (xsymbols)
   835   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   836   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   837 
   838 syntax (latex output)
   839   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   840   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   841 
   842 translations
   843   "INT x y. B"  == "INT x. INT y. B"
   844   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   845   "INT x. B"    == "INT x:CONST UNIV. B"
   846   "INT x:A. B"  == "CONST INTER A (%x. B)"
   847 
   848 print_translation {*
   849   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   850 *} -- {* to avoid eta-contraction of body *}
   851 
   852 lemma INTER_eq:
   853   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   854   by (auto simp add: INF_def)
   855 
   856 lemma Inter_image_eq [simp]:
   857   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   858   by (rule sym) (fact INF_def)
   859 
   860 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
   861   by (auto simp add: INF_def image_def)
   862 
   863 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
   864   by (auto simp add: INF_def image_def)
   865 
   866 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
   867   by auto
   868 
   869 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   870   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}. *}
   871   by (auto simp add: INF_def image_def)
   872 
   873 lemma INT_cong [cong]:
   874   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Inter>x\<in>A. C x) = (\<Inter>x\<in>B. D x)"
   875   by (fact INF_cong)
   876 
   877 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   878   by blast
   879 
   880 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   881   by blast
   882 
   883 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   884   by (fact INF_lower)
   885 
   886 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
   887   by (fact INF_greatest)
   888 
   889 lemma INT_empty: "(\<Inter>x\<in>{}. B x) = UNIV"
   890   by (fact INF_empty)
   891 
   892 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   893   by (fact INF_absorb)
   894 
   895 lemma INT_subset_iff: "B \<subseteq> (\<Inter>i\<in>I. A i) \<longleftrightarrow> (\<forall>i\<in>I. B \<subseteq> A i)"
   896   by (fact le_INF_iff)
   897 
   898 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   899   by (fact INF_insert)
   900 
   901 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   902   by (fact INF_union)
   903 
   904 lemma INT_insert_distrib:
   905   "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   906   by blast
   907 
   908 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   909   by (fact INF_constant)
   910 
   911 lemma INTER_UNIV_conv:
   912  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   913  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   914   by (fact INF_top_conv)+ (* already simp *)
   915 
   916 lemma INT_bool_eq: "(\<Inter>b. A b) = A True \<inter> A False"
   917   by (fact INF_UNIV_bool_expand)
   918 
   919 lemma INT_anti_mono:
   920   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow> (\<Inter>x\<in>B. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   921   -- {* The last inclusion is POSITIVE! *}
   922   by (fact INF_superset_mono)
   923 
   924 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   925   by blast
   926 
   927 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
   928   by blast
   929 
   930 
   931 subsubsection {* Union *}
   932 
   933 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   934   "Union S \<equiv> \<Squnion>S"
   935 
   936 notation (xsymbols)
   937   Union  ("\<Union>_" [90] 90)
   938 
   939 lemma Union_eq:
   940   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   941 proof (rule set_eqI)
   942   fix x
   943   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   944     by auto
   945   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   946     by (simp add: Sup_set_def image_def)
   947 qed
   948 
   949 lemma Union_iff [simp, no_atp]:
   950   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   951   by (unfold Union_eq) blast
   952 
   953 lemma UnionI [intro]:
   954   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   955   -- {* The order of the premises presupposes that @{term C} is rigid;
   956     @{term A} may be flexible. *}
   957   by auto
   958 
   959 lemma UnionE [elim!]:
   960   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
   961   by auto
   962 
   963 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
   964   by (fact Sup_upper)
   965 
   966 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
   967   by (fact Sup_least)
   968 
   969 lemma Union_empty: "\<Union>{} = {}"
   970   by (fact Sup_empty) (* already simp *)
   971 
   972 lemma Union_UNIV: "\<Union>UNIV = UNIV"
   973   by (fact Sup_UNIV) (* already simp *)
   974 
   975 lemma Union_insert: "\<Union>insert a B = a \<union> \<Union>B"
   976   by (fact Sup_insert) (* already simp *)
   977 
   978 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
   979   by (fact Sup_union_distrib)
   980 
   981 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   982   by (fact Sup_inter_less_eq)
   983 
   984 lemma Union_empty_conv [no_atp]: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   985   by (fact Sup_bot_conv) (* already simp *)
   986 
   987 lemma empty_Union_conv [no_atp]: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   988   by (fact Sup_bot_conv) (* already simp *)
   989 
   990 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   991   by blast
   992 
   993 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   994   by blast
   995 
   996 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
   997   by (fact Sup_subset_mono)
   998 
   999 
  1000 subsubsection {* Unions of families *}
  1001 
  1002 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
  1003   "UNION \<equiv> SUPR"
  1004 
  1005 text {*
  1006   Note: must use name @{const UNION} here instead of @{text UN}
  1007   to allow the following syntax coexist with the plain constant name.
  1008 *}
  1009 
  1010 syntax
  1011   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
  1012   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
  1013 
  1014 syntax (xsymbols)
  1015   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
  1016   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
  1017 
  1018 syntax (latex output)
  1019   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
  1020   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
  1021 
  1022 translations
  1023   "UN x y. B"   == "UN x. UN y. B"
  1024   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
  1025   "UN x. B"     == "UN x:CONST UNIV. B"
  1026   "UN x:A. B"   == "CONST UNION A (%x. B)"
  1027 
  1028 text {*
  1029   Note the difference between ordinary xsymbol syntax of indexed
  1030   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
  1031   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
  1032   former does not make the index expression a subscript of the
  1033   union/intersection symbol because this leads to problems with nested
  1034   subscripts in Proof General.
  1035 *}
  1036 
  1037 print_translation {*
  1038   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
  1039 *} -- {* to avoid eta-contraction of body *}
  1040 
  1041 lemma UNION_eq [no_atp]:
  1042   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
  1043   by (auto simp add: SUP_def)
  1044 
  1045 lemma bind_UNION [code]:
  1046   "Set.bind A f = UNION A f"
  1047   by (simp add: bind_def UNION_eq)
  1048 
  1049 lemma member_bind [simp]:
  1050   "x \<in> Set.bind P f \<longleftrightarrow> x \<in> UNION P f "
  1051   by (simp add: bind_UNION)
  1052 
  1053 lemma Union_image_eq [simp]:
  1054   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
  1055   by (rule sym) (fact SUP_def)
  1056 
  1057 lemma UN_iff [simp]: "b \<in> (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<exists>x\<in>A. b \<in> B x)"
  1058   by (auto simp add: SUP_def image_def)
  1059 
  1060 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
  1061   -- {* The order of the premises presupposes that @{term A} is rigid;
  1062     @{term b} may be flexible. *}
  1063   by auto
  1064 
  1065 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
  1066   by (auto simp add: SUP_def image_def)
  1067 
  1068 lemma UN_cong [cong]:
  1069   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
  1070   by (fact SUP_cong)
  1071 
  1072 lemma strong_UN_cong:
  1073   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
  1074   by (unfold simp_implies_def) (fact UN_cong)
  1075 
  1076 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
  1077   by blast
  1078 
  1079 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1080   by (fact SUP_upper)
  1081 
  1082 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
  1083   by (fact SUP_least)
  1084 
  1085 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1086   by blast
  1087 
  1088 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1089   by blast
  1090 
  1091 lemma UN_empty [no_atp]: "(\<Union>x\<in>{}. B x) = {}"
  1092   by (fact SUP_empty)
  1093 
  1094 lemma UN_empty2: "(\<Union>x\<in>A. {}) = {}"
  1095   by (fact SUP_bot) (* already simp *)
  1096 
  1097 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1098   by (fact SUP_absorb)
  1099 
  1100 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1101   by (fact SUP_insert)
  1102 
  1103 lemma UN_Un [simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1104   by (fact SUP_union)
  1105 
  1106 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1107   by blast
  1108 
  1109 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1110   by (fact SUP_le_iff)
  1111 
  1112 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1113   by (fact SUP_constant)
  1114 
  1115 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1116   by blast
  1117 
  1118 lemma UNION_empty_conv:
  1119   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1120   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1121   by (fact SUP_bot_conv)+ (* already simp *)
  1122 
  1123 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1124   by blast
  1125 
  1126 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) \<longleftrightarrow> (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1127   by blast
  1128 
  1129 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) \<longleftrightarrow> (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1130   by blast
  1131 
  1132 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1133   by (auto simp add: split_if_mem2)
  1134 
  1135 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
  1136   by (fact SUP_UNIV_bool_expand)
  1137 
  1138 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1139   by blast
  1140 
  1141 lemma UN_mono:
  1142   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
  1143     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1144   by (fact SUP_subset_mono)
  1145 
  1146 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
  1147   by blast
  1148 
  1149 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
  1150   by blast
  1151 
  1152 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
  1153   -- {* NOT suitable for rewriting *}
  1154   by blast
  1155 
  1156 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
  1157   by blast
  1158 
  1159 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1160   by blast
  1161 
  1162 
  1163 subsubsection {* Distributive laws *}
  1164 
  1165 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1166   by (fact inf_Sup)
  1167 
  1168 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1169   by (fact sup_Inf)
  1170 
  1171 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1172   by (fact Sup_inf)
  1173 
  1174 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1175   by (rule sym) (rule INF_inf_distrib)
  1176 
  1177 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1178   by (rule sym) (rule SUP_sup_distrib)
  1179 
  1180 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)"
  1181   by (simp only: INT_Int_distrib INF_def)
  1182 
  1183 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)"
  1184   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1185   -- {* Union of a family of unions *}
  1186   by (simp only: UN_Un_distrib SUP_def)
  1187 
  1188 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1189   by (fact sup_INF)
  1190 
  1191 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1192   -- {* Halmos, Naive Set Theory, page 35. *}
  1193   by (fact inf_SUP)
  1194 
  1195 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1196   by (fact SUP_inf_distrib2)
  1197 
  1198 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1199   by (fact INF_sup_distrib2)
  1200 
  1201 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
  1202   by (fact Sup_inf_eq_bot_iff)
  1203 
  1204 
  1205 subsubsection {* Complement *}
  1206 
  1207 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1208   by (fact uminus_INF)
  1209 
  1210 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1211   by (fact uminus_SUP)
  1212 
  1213 
  1214 subsubsection {* Miniscoping and maxiscoping *}
  1215 
  1216 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1217            and Intersections. *}
  1218 
  1219 lemma UN_simps [simp]:
  1220   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
  1221   "\<And>A B C. (\<Union>x\<in>C. A x \<union> B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
  1222   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
  1223   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter> B)"
  1224   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
  1225   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
  1226   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
  1227   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
  1228   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
  1229   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
  1230   by auto
  1231 
  1232 lemma INT_simps [simp]:
  1233   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter> B)"
  1234   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
  1235   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
  1236   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
  1237   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
  1238   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
  1239   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
  1240   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
  1241   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
  1242   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
  1243   by auto
  1244 
  1245 lemma UN_ball_bex_simps [simp, no_atp]:
  1246   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
  1247   "\<And>A B P. (\<forall>x\<in>UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
  1248   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
  1249   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
  1250   by auto
  1251 
  1252 
  1253 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1254 
  1255 lemma UN_extend_simps:
  1256   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
  1257   "\<And>A B C. (\<Union>x\<in>C. A x) \<union> B = (if C={} then B else (\<Union>x\<in>C. A x \<union> B))"
  1258   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
  1259   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
  1260   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
  1261   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
  1262   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
  1263   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
  1264   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
  1265   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
  1266   by auto
  1267 
  1268 lemma INT_extend_simps:
  1269   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
  1270   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
  1271   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
  1272   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
  1273   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
  1274   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
  1275   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
  1276   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
  1277   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
  1278   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
  1279   by auto
  1280 
  1281 text {* Finally *}
  1282 
  1283 no_notation
  1284   less_eq (infix "\<sqsubseteq>" 50) and
  1285   less (infix "\<sqsubset>" 50)
  1286 
  1287 lemmas mem_simps =
  1288   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  1289   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  1290   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  1291 
  1292 end
  1293