src/HOL/Divides.thy
author wenzelm
Wed Apr 10 21:20:35 2013 +0200 (2013-04-10)
changeset 51692 ecd34f863242
parent 51299 30b014246e21
child 51717 9e7d1c139569
permissions -rw-r--r--
tuned pretty layout: avoid nested Pretty.string_of, which merely happens to work with Isabelle/jEdit since formatting is delegated to Scala side;
declare command "print_case_translations" where it is actually defined;
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Transfer
    10 begin
    11 
    12 subsection {* Syntactic division operations *}
    13 
    14 class div = dvd +
    15   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    16     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    17 
    18 
    19 subsection {* Abstract division in commutative semirings. *}
    20 
    21 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    22   assumes mod_div_equality: "a div b * b + a mod b = a"
    23     and div_by_0 [simp]: "a div 0 = 0"
    24     and div_0 [simp]: "0 div a = 0"
    25     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    26     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    27 begin
    28 
    29 text {* @{const div} and @{const mod} *}
    30 
    31 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    32   unfolding mult_commute [of b]
    33   by (rule mod_div_equality)
    34 
    35 lemma mod_div_equality': "a mod b + a div b * b = a"
    36   using mod_div_equality [of a b]
    37   by (simp only: add_ac)
    38 
    39 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    40   by (simp add: mod_div_equality)
    41 
    42 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    43   by (simp add: mod_div_equality2)
    44 
    45 lemma mod_by_0 [simp]: "a mod 0 = a"
    46   using mod_div_equality [of a zero] by simp
    47 
    48 lemma mod_0 [simp]: "0 mod a = 0"
    49   using mod_div_equality [of zero a] div_0 by simp
    50 
    51 lemma div_mult_self2 [simp]:
    52   assumes "b \<noteq> 0"
    53   shows "(a + b * c) div b = c + a div b"
    54   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    55 
    56 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    57 proof (cases "b = 0")
    58   case True then show ?thesis by simp
    59 next
    60   case False
    61   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    62     by (simp add: mod_div_equality)
    63   also from False div_mult_self1 [of b a c] have
    64     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    65       by (simp add: algebra_simps)
    66   finally have "a = a div b * b + (a + c * b) mod b"
    67     by (simp add: add_commute [of a] add_assoc distrib_right)
    68   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    69     by (simp add: mod_div_equality)
    70   then show ?thesis by simp
    71 qed
    72 
    73 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    74   by (simp add: mult_commute [of b])
    75 
    76 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    77   using div_mult_self2 [of b 0 a] by simp
    78 
    79 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    80   using div_mult_self1 [of b 0 a] by simp
    81 
    82 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    83   using mod_mult_self2 [of 0 b a] by simp
    84 
    85 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    86   using mod_mult_self1 [of 0 a b] by simp
    87 
    88 lemma div_by_1 [simp]: "a div 1 = a"
    89   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    90 
    91 lemma mod_by_1 [simp]: "a mod 1 = 0"
    92 proof -
    93   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    94   then have "a + a mod 1 = a + 0" by simp
    95   then show ?thesis by (rule add_left_imp_eq)
    96 qed
    97 
    98 lemma mod_self [simp]: "a mod a = 0"
    99   using mod_mult_self2_is_0 [of 1] by simp
   100 
   101 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   102   using div_mult_self2_is_id [of _ 1] by simp
   103 
   104 lemma div_add_self1 [simp]:
   105   assumes "b \<noteq> 0"
   106   shows "(b + a) div b = a div b + 1"
   107   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   108 
   109 lemma div_add_self2 [simp]:
   110   assumes "b \<noteq> 0"
   111   shows "(a + b) div b = a div b + 1"
   112   using assms div_add_self1 [of b a] by (simp add: add_commute)
   113 
   114 lemma mod_add_self1 [simp]:
   115   "(b + a) mod b = a mod b"
   116   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   117 
   118 lemma mod_add_self2 [simp]:
   119   "(a + b) mod b = a mod b"
   120   using mod_mult_self1 [of a 1 b] by simp
   121 
   122 lemma mod_div_decomp:
   123   fixes a b
   124   obtains q r where "q = a div b" and "r = a mod b"
   125     and "a = q * b + r"
   126 proof -
   127   from mod_div_equality have "a = a div b * b + a mod b" by simp
   128   moreover have "a div b = a div b" ..
   129   moreover have "a mod b = a mod b" ..
   130   note that ultimately show thesis by blast
   131 qed
   132 
   133 lemma dvd_eq_mod_eq_0 [code]: "a dvd b \<longleftrightarrow> b mod a = 0"
   134 proof
   135   assume "b mod a = 0"
   136   with mod_div_equality [of b a] have "b div a * a = b" by simp
   137   then have "b = a * (b div a)" unfolding mult_commute ..
   138   then have "\<exists>c. b = a * c" ..
   139   then show "a dvd b" unfolding dvd_def .
   140 next
   141   assume "a dvd b"
   142   then have "\<exists>c. b = a * c" unfolding dvd_def .
   143   then obtain c where "b = a * c" ..
   144   then have "b mod a = a * c mod a" by simp
   145   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   146   then show "b mod a = 0" by simp
   147 qed
   148 
   149 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   150 proof (cases "b = 0")
   151   assume "b = 0"
   152   thus ?thesis by simp
   153 next
   154   assume "b \<noteq> 0"
   155   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   156     by (rule div_mult_self1 [symmetric])
   157   also have "\<dots> = a div b"
   158     by (simp only: mod_div_equality')
   159   also have "\<dots> = a div b + 0"
   160     by simp
   161   finally show ?thesis
   162     by (rule add_left_imp_eq)
   163 qed
   164 
   165 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   166 proof -
   167   have "a mod b mod b = (a mod b + a div b * b) mod b"
   168     by (simp only: mod_mult_self1)
   169   also have "\<dots> = a mod b"
   170     by (simp only: mod_div_equality')
   171   finally show ?thesis .
   172 qed
   173 
   174 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   175 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   176 
   177 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   178 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   179 
   180 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   181 by (drule dvd_div_mult_self) (simp add: mult_commute)
   182 
   183 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   184 apply (cases "a = 0")
   185  apply simp
   186 apply (auto simp: dvd_def mult_assoc)
   187 done
   188 
   189 lemma div_dvd_div[simp]:
   190   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   191 apply (cases "a = 0")
   192  apply simp
   193 apply (unfold dvd_def)
   194 apply auto
   195  apply(blast intro:mult_assoc[symmetric])
   196 apply(fastforce simp add: mult_assoc)
   197 done
   198 
   199 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   200   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   201    apply (simp add: mod_div_equality)
   202   apply (simp only: dvd_add dvd_mult)
   203   done
   204 
   205 text {* Addition respects modular equivalence. *}
   206 
   207 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   208 proof -
   209   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   210     by (simp only: mod_div_equality)
   211   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   212     by (simp only: add_ac)
   213   also have "\<dots> = (a mod c + b) mod c"
   214     by (rule mod_mult_self1)
   215   finally show ?thesis .
   216 qed
   217 
   218 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   219 proof -
   220   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   221     by (simp only: mod_div_equality)
   222   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   223     by (simp only: add_ac)
   224   also have "\<dots> = (a + b mod c) mod c"
   225     by (rule mod_mult_self1)
   226   finally show ?thesis .
   227 qed
   228 
   229 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   230 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   231 
   232 lemma mod_add_cong:
   233   assumes "a mod c = a' mod c"
   234   assumes "b mod c = b' mod c"
   235   shows "(a + b) mod c = (a' + b') mod c"
   236 proof -
   237   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   238     unfolding assms ..
   239   thus ?thesis
   240     by (simp only: mod_add_eq [symmetric])
   241 qed
   242 
   243 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   244   \<Longrightarrow> (x + y) div z = x div z + y div z"
   245 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   246 
   247 text {* Multiplication respects modular equivalence. *}
   248 
   249 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   250 proof -
   251   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   252     by (simp only: mod_div_equality)
   253   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   254     by (simp only: algebra_simps)
   255   also have "\<dots> = (a mod c * b) mod c"
   256     by (rule mod_mult_self1)
   257   finally show ?thesis .
   258 qed
   259 
   260 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   261 proof -
   262   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   263     by (simp only: mod_div_equality)
   264   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   265     by (simp only: algebra_simps)
   266   also have "\<dots> = (a * (b mod c)) mod c"
   267     by (rule mod_mult_self1)
   268   finally show ?thesis .
   269 qed
   270 
   271 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   272 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   273 
   274 lemma mod_mult_cong:
   275   assumes "a mod c = a' mod c"
   276   assumes "b mod c = b' mod c"
   277   shows "(a * b) mod c = (a' * b') mod c"
   278 proof -
   279   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   280     unfolding assms ..
   281   thus ?thesis
   282     by (simp only: mod_mult_eq [symmetric])
   283 qed
   284 
   285 text {* Exponentiation respects modular equivalence. *}
   286 
   287 lemma power_mod: "(a mod b)^n mod b = a^n mod b"
   288 apply (induct n, simp_all)
   289 apply (rule mod_mult_right_eq [THEN trans])
   290 apply (simp (no_asm_simp))
   291 apply (rule mod_mult_eq [symmetric])
   292 done
   293 
   294 lemma mod_mod_cancel:
   295   assumes "c dvd b"
   296   shows "a mod b mod c = a mod c"
   297 proof -
   298   from `c dvd b` obtain k where "b = c * k"
   299     by (rule dvdE)
   300   have "a mod b mod c = a mod (c * k) mod c"
   301     by (simp only: `b = c * k`)
   302   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   303     by (simp only: mod_mult_self1)
   304   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   305     by (simp only: add_ac mult_ac)
   306   also have "\<dots> = a mod c"
   307     by (simp only: mod_div_equality)
   308   finally show ?thesis .
   309 qed
   310 
   311 lemma div_mult_div_if_dvd:
   312   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   313   apply (cases "y = 0", simp)
   314   apply (cases "z = 0", simp)
   315   apply (auto elim!: dvdE simp add: algebra_simps)
   316   apply (subst mult_assoc [symmetric])
   317   apply (simp add: no_zero_divisors)
   318   done
   319 
   320 lemma div_mult_swap:
   321   assumes "c dvd b"
   322   shows "a * (b div c) = (a * b) div c"
   323 proof -
   324   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   325     by (simp only: div_mult_div_if_dvd one_dvd)
   326   then show ?thesis by (simp add: mult_commute)
   327 qed
   328    
   329 lemma div_mult_mult2 [simp]:
   330   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   331   by (drule div_mult_mult1) (simp add: mult_commute)
   332 
   333 lemma div_mult_mult1_if [simp]:
   334   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   335   by simp_all
   336 
   337 lemma mod_mult_mult1:
   338   "(c * a) mod (c * b) = c * (a mod b)"
   339 proof (cases "c = 0")
   340   case True then show ?thesis by simp
   341 next
   342   case False
   343   from mod_div_equality
   344   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   345   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   346     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   347   with mod_div_equality show ?thesis by simp 
   348 qed
   349   
   350 lemma mod_mult_mult2:
   351   "(a * c) mod (b * c) = (a mod b) * c"
   352   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   353 
   354 lemma mult_mod_left: "(a mod b) * c = (a * c) mod (b * c)"
   355   by (fact mod_mult_mult2 [symmetric])
   356 
   357 lemma mult_mod_right: "c * (a mod b) = (c * a) mod (c * b)"
   358   by (fact mod_mult_mult1 [symmetric])
   359 
   360 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   361   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   362 
   363 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   364 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   365 
   366 lemma div_power:
   367   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   368 apply (induct n)
   369  apply simp
   370 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   371 done
   372 
   373 lemma dvd_div_eq_mult:
   374   assumes "a \<noteq> 0" and "a dvd b"  
   375   shows "b div a = c \<longleftrightarrow> b = c * a"
   376 proof
   377   assume "b = c * a"
   378   then show "b div a = c" by (simp add: assms)
   379 next
   380   assume "b div a = c"
   381   then have "b div a * a = c * a" by simp
   382   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   383   ultimately show "b = c * a" by simp
   384 qed
   385    
   386 lemma dvd_div_div_eq_mult:
   387   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   388   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   389   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   390 
   391 end
   392 
   393 class ring_div = semiring_div + comm_ring_1
   394 begin
   395 
   396 subclass ring_1_no_zero_divisors ..
   397 
   398 text {* Negation respects modular equivalence. *}
   399 
   400 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   401 proof -
   402   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   403     by (simp only: mod_div_equality)
   404   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   405     by (simp only: minus_add_distrib minus_mult_left add_ac)
   406   also have "\<dots> = (- (a mod b)) mod b"
   407     by (rule mod_mult_self1)
   408   finally show ?thesis .
   409 qed
   410 
   411 lemma mod_minus_cong:
   412   assumes "a mod b = a' mod b"
   413   shows "(- a) mod b = (- a') mod b"
   414 proof -
   415   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   416     unfolding assms ..
   417   thus ?thesis
   418     by (simp only: mod_minus_eq [symmetric])
   419 qed
   420 
   421 text {* Subtraction respects modular equivalence. *}
   422 
   423 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   424   unfolding diff_minus
   425   by (intro mod_add_cong mod_minus_cong) simp_all
   426 
   427 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   428   unfolding diff_minus
   429   by (intro mod_add_cong mod_minus_cong) simp_all
   430 
   431 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   432   unfolding diff_minus
   433   by (intro mod_add_cong mod_minus_cong) simp_all
   434 
   435 lemma mod_diff_cong:
   436   assumes "a mod c = a' mod c"
   437   assumes "b mod c = b' mod c"
   438   shows "(a - b) mod c = (a' - b') mod c"
   439   unfolding diff_minus using assms
   440   by (intro mod_add_cong mod_minus_cong)
   441 
   442 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   443 apply (case_tac "y = 0") apply simp
   444 apply (auto simp add: dvd_def)
   445 apply (subgoal_tac "-(y * k) = y * - k")
   446  apply (erule ssubst)
   447  apply (erule div_mult_self1_is_id)
   448 apply simp
   449 done
   450 
   451 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   452 apply (case_tac "y = 0") apply simp
   453 apply (auto simp add: dvd_def)
   454 apply (subgoal_tac "y * k = -y * -k")
   455  apply (erule ssubst)
   456  apply (rule div_mult_self1_is_id)
   457  apply simp
   458 apply simp
   459 done
   460 
   461 lemma div_minus_minus [simp]: "(-a) div (-b) = a div b"
   462   using div_mult_mult1 [of "- 1" a b]
   463   unfolding neg_equal_0_iff_equal by simp
   464 
   465 lemma mod_minus_minus [simp]: "(-a) mod (-b) = - (a mod b)"
   466   using mod_mult_mult1 [of "- 1" a b] by simp
   467 
   468 lemma div_minus_right: "a div (-b) = (-a) div b"
   469   using div_minus_minus [of "-a" b] by simp
   470 
   471 lemma mod_minus_right: "a mod (-b) = - ((-a) mod b)"
   472   using mod_minus_minus [of "-a" b] by simp
   473 
   474 lemma div_minus1_right [simp]: "a div (-1) = -a"
   475   using div_minus_right [of a 1] by simp
   476 
   477 lemma mod_minus1_right [simp]: "a mod (-1) = 0"
   478   using mod_minus_right [of a 1] by simp
   479 
   480 end
   481 
   482 
   483 subsection {* Division on @{typ nat} *}
   484 
   485 text {*
   486   We define @{const div} and @{const mod} on @{typ nat} by means
   487   of a characteristic relation with two input arguments
   488   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   489   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   490 *}
   491 
   492 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   493   "divmod_nat_rel m n qr \<longleftrightarrow>
   494     m = fst qr * n + snd qr \<and>
   495       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   496 
   497 text {* @{const divmod_nat_rel} is total: *}
   498 
   499 lemma divmod_nat_rel_ex:
   500   obtains q r where "divmod_nat_rel m n (q, r)"
   501 proof (cases "n = 0")
   502   case True  with that show thesis
   503     by (auto simp add: divmod_nat_rel_def)
   504 next
   505   case False
   506   have "\<exists>q r. m = q * n + r \<and> r < n"
   507   proof (induct m)
   508     case 0 with `n \<noteq> 0`
   509     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   510     then show ?case by blast
   511   next
   512     case (Suc m) then obtain q' r'
   513       where m: "m = q' * n + r'" and n: "r' < n" by auto
   514     then show ?case proof (cases "Suc r' < n")
   515       case True
   516       from m n have "Suc m = q' * n + Suc r'" by simp
   517       with True show ?thesis by blast
   518     next
   519       case False then have "n \<le> Suc r'" by auto
   520       moreover from n have "Suc r' \<le> n" by auto
   521       ultimately have "n = Suc r'" by auto
   522       with m have "Suc m = Suc q' * n + 0" by simp
   523       with `n \<noteq> 0` show ?thesis by blast
   524     qed
   525   qed
   526   with that show thesis
   527     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   528 qed
   529 
   530 text {* @{const divmod_nat_rel} is injective: *}
   531 
   532 lemma divmod_nat_rel_unique:
   533   assumes "divmod_nat_rel m n qr"
   534     and "divmod_nat_rel m n qr'"
   535   shows "qr = qr'"
   536 proof (cases "n = 0")
   537   case True with assms show ?thesis
   538     by (cases qr, cases qr')
   539       (simp add: divmod_nat_rel_def)
   540 next
   541   case False
   542   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   543   apply (rule leI)
   544   apply (subst less_iff_Suc_add)
   545   apply (auto simp add: add_mult_distrib)
   546   done
   547   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   548     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   549   moreover from this assms have "snd qr = snd qr'"
   550     by (simp add: divmod_nat_rel_def)
   551   ultimately show ?thesis by (cases qr, cases qr') simp
   552 qed
   553 
   554 text {*
   555   We instantiate divisibility on the natural numbers by
   556   means of @{const divmod_nat_rel}:
   557 *}
   558 
   559 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   560   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   561 
   562 lemma divmod_nat_rel_divmod_nat:
   563   "divmod_nat_rel m n (divmod_nat m n)"
   564 proof -
   565   from divmod_nat_rel_ex
   566     obtain qr where rel: "divmod_nat_rel m n qr" .
   567   then show ?thesis
   568   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   569 qed
   570 
   571 lemma divmod_nat_unique:
   572   assumes "divmod_nat_rel m n qr" 
   573   shows "divmod_nat m n = qr"
   574   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   575 
   576 instantiation nat :: semiring_div
   577 begin
   578 
   579 definition div_nat where
   580   "m div n = fst (divmod_nat m n)"
   581 
   582 lemma fst_divmod_nat [simp]:
   583   "fst (divmod_nat m n) = m div n"
   584   by (simp add: div_nat_def)
   585 
   586 definition mod_nat where
   587   "m mod n = snd (divmod_nat m n)"
   588 
   589 lemma snd_divmod_nat [simp]:
   590   "snd (divmod_nat m n) = m mod n"
   591   by (simp add: mod_nat_def)
   592 
   593 lemma divmod_nat_div_mod:
   594   "divmod_nat m n = (m div n, m mod n)"
   595   by (simp add: prod_eq_iff)
   596 
   597 lemma div_nat_unique:
   598   assumes "divmod_nat_rel m n (q, r)" 
   599   shows "m div n = q"
   600   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   601 
   602 lemma mod_nat_unique:
   603   assumes "divmod_nat_rel m n (q, r)" 
   604   shows "m mod n = r"
   605   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   606 
   607 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   608   using divmod_nat_rel_divmod_nat by (simp add: divmod_nat_div_mod)
   609 
   610 lemma divmod_nat_zero: "divmod_nat m 0 = (0, m)"
   611   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   612 
   613 lemma divmod_nat_zero_left: "divmod_nat 0 n = (0, 0)"
   614   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   615 
   616 lemma divmod_nat_base: "m < n \<Longrightarrow> divmod_nat m n = (0, m)"
   617   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   618 
   619 lemma divmod_nat_step:
   620   assumes "0 < n" and "n \<le> m"
   621   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   622 proof (rule divmod_nat_unique)
   623   have "divmod_nat_rel (m - n) n ((m - n) div n, (m - n) mod n)"
   624     by (rule divmod_nat_rel)
   625   thus "divmod_nat_rel m n (Suc ((m - n) div n), (m - n) mod n)"
   626     unfolding divmod_nat_rel_def using assms by auto
   627 qed
   628 
   629 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   630 
   631 lemma div_less [simp]:
   632   fixes m n :: nat
   633   assumes "m < n"
   634   shows "m div n = 0"
   635   using assms divmod_nat_base by (simp add: prod_eq_iff)
   636 
   637 lemma le_div_geq:
   638   fixes m n :: nat
   639   assumes "0 < n" and "n \<le> m"
   640   shows "m div n = Suc ((m - n) div n)"
   641   using assms divmod_nat_step by (simp add: prod_eq_iff)
   642 
   643 lemma mod_less [simp]:
   644   fixes m n :: nat
   645   assumes "m < n"
   646   shows "m mod n = m"
   647   using assms divmod_nat_base by (simp add: prod_eq_iff)
   648 
   649 lemma le_mod_geq:
   650   fixes m n :: nat
   651   assumes "n \<le> m"
   652   shows "m mod n = (m - n) mod n"
   653   using assms divmod_nat_step by (cases "n = 0") (simp_all add: prod_eq_iff)
   654 
   655 instance proof
   656   fix m n :: nat
   657   show "m div n * n + m mod n = m"
   658     using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   659 next
   660   fix m n q :: nat
   661   assume "n \<noteq> 0"
   662   then show "(q + m * n) div n = m + q div n"
   663     by (induct m) (simp_all add: le_div_geq)
   664 next
   665   fix m n q :: nat
   666   assume "m \<noteq> 0"
   667   hence "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   668     unfolding divmod_nat_rel_def
   669     by (auto split: split_if_asm, simp_all add: algebra_simps)
   670   moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   671   ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   672   thus "(m * n) div (m * q) = n div q" by (rule div_nat_unique)
   673 next
   674   fix n :: nat show "n div 0 = 0"
   675     by (simp add: div_nat_def divmod_nat_zero)
   676 next
   677   fix n :: nat show "0 div n = 0"
   678     by (simp add: div_nat_def divmod_nat_zero_left)
   679 qed
   680 
   681 end
   682 
   683 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   684   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   685   by (simp add: prod_eq_iff prod_case_beta not_less le_div_geq le_mod_geq)
   686 
   687 text {* Simproc for cancelling @{const div} and @{const mod} *}
   688 
   689 ML_file "~~/src/Provers/Arith/cancel_div_mod.ML"
   690 
   691 ML {*
   692 structure Cancel_Div_Mod_Nat = Cancel_Div_Mod
   693 (
   694   val div_name = @{const_name div};
   695   val mod_name = @{const_name mod};
   696   val mk_binop = HOLogic.mk_binop;
   697   val mk_plus = HOLogic.mk_binop @{const_name Groups.plus};
   698   val dest_plus = HOLogic.dest_bin @{const_name Groups.plus} HOLogic.natT;
   699   fun mk_sum [] = HOLogic.zero
   700     | mk_sum [t] = t
   701     | mk_sum (t :: ts) = mk_plus (t, mk_sum ts);
   702   fun dest_sum tm =
   703     if HOLogic.is_zero tm then []
   704     else
   705       (case try HOLogic.dest_Suc tm of
   706         SOME t => HOLogic.Suc_zero :: dest_sum t
   707       | NONE =>
   708           (case try dest_plus tm of
   709             SOME (t, u) => dest_sum t @ dest_sum u
   710           | NONE => [tm]));
   711 
   712   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   713 
   714   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   715     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   716 )
   717 *}
   718 
   719 simproc_setup cancel_div_mod_nat ("(m::nat) + n") = {* K Cancel_Div_Mod_Nat.proc *}
   720 
   721 
   722 subsubsection {* Quotient *}
   723 
   724 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   725 by (simp add: le_div_geq linorder_not_less)
   726 
   727 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   728 by (simp add: div_geq)
   729 
   730 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   731 by simp
   732 
   733 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   734 by simp
   735 
   736 
   737 subsubsection {* Remainder *}
   738 
   739 lemma mod_less_divisor [simp]:
   740   fixes m n :: nat
   741   assumes "n > 0"
   742   shows "m mod n < (n::nat)"
   743   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   744 
   745 lemma mod_Suc_le_divisor [simp]:
   746   "m mod Suc n \<le> n"
   747   using mod_less_divisor [of "Suc n" m] by arith
   748 
   749 lemma mod_less_eq_dividend [simp]:
   750   fixes m n :: nat
   751   shows "m mod n \<le> m"
   752 proof (rule add_leD2)
   753   from mod_div_equality have "m div n * n + m mod n = m" .
   754   then show "m div n * n + m mod n \<le> m" by auto
   755 qed
   756 
   757 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   758 by (simp add: le_mod_geq linorder_not_less)
   759 
   760 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   761 by (simp add: le_mod_geq)
   762 
   763 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   764 by (induct m) (simp_all add: mod_geq)
   765 
   766 (* a simple rearrangement of mod_div_equality: *)
   767 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   768   using mod_div_equality2 [of n m] by arith
   769 
   770 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   771   apply (drule mod_less_divisor [where m = m])
   772   apply simp
   773   done
   774 
   775 subsubsection {* Quotient and Remainder *}
   776 
   777 lemma divmod_nat_rel_mult1_eq:
   778   "divmod_nat_rel b c (q, r)
   779    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   780 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   781 
   782 lemma div_mult1_eq:
   783   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   784 by (blast intro: divmod_nat_rel_mult1_eq [THEN div_nat_unique] divmod_nat_rel)
   785 
   786 lemma divmod_nat_rel_add1_eq:
   787   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br)
   788    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   789 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   790 
   791 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   792 lemma div_add1_eq:
   793   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   794 by (blast intro: divmod_nat_rel_add1_eq [THEN div_nat_unique] divmod_nat_rel)
   795 
   796 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   797   apply (cut_tac m = q and n = c in mod_less_divisor)
   798   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   799   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   800   apply (simp add: add_mult_distrib2)
   801   done
   802 
   803 lemma divmod_nat_rel_mult2_eq:
   804   "divmod_nat_rel a b (q, r)
   805    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   806 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   807 
   808 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   809 by (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_nat_unique])
   810 
   811 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   812 by (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_nat_unique])
   813 
   814 
   815 subsubsection {* Further Facts about Quotient and Remainder *}
   816 
   817 lemma div_1 [simp]: "m div Suc 0 = m"
   818 by (induct m) (simp_all add: div_geq)
   819 
   820 (* Monotonicity of div in first argument *)
   821 lemma div_le_mono [rule_format (no_asm)]:
   822     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   823 apply (case_tac "k=0", simp)
   824 apply (induct "n" rule: nat_less_induct, clarify)
   825 apply (case_tac "n<k")
   826 (* 1  case n<k *)
   827 apply simp
   828 (* 2  case n >= k *)
   829 apply (case_tac "m<k")
   830 (* 2.1  case m<k *)
   831 apply simp
   832 (* 2.2  case m>=k *)
   833 apply (simp add: div_geq diff_le_mono)
   834 done
   835 
   836 (* Antimonotonicity of div in second argument *)
   837 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   838 apply (subgoal_tac "0<n")
   839  prefer 2 apply simp
   840 apply (induct_tac k rule: nat_less_induct)
   841 apply (rename_tac "k")
   842 apply (case_tac "k<n", simp)
   843 apply (subgoal_tac "~ (k<m) ")
   844  prefer 2 apply simp
   845 apply (simp add: div_geq)
   846 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   847  prefer 2
   848  apply (blast intro: div_le_mono diff_le_mono2)
   849 apply (rule le_trans, simp)
   850 apply (simp)
   851 done
   852 
   853 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   854 apply (case_tac "n=0", simp)
   855 apply (subgoal_tac "m div n \<le> m div 1", simp)
   856 apply (rule div_le_mono2)
   857 apply (simp_all (no_asm_simp))
   858 done
   859 
   860 (* Similar for "less than" *)
   861 lemma div_less_dividend [simp]:
   862   "\<lbrakk>(1::nat) < n; 0 < m\<rbrakk> \<Longrightarrow> m div n < m"
   863 apply (induct m rule: nat_less_induct)
   864 apply (rename_tac "m")
   865 apply (case_tac "m<n", simp)
   866 apply (subgoal_tac "0<n")
   867  prefer 2 apply simp
   868 apply (simp add: div_geq)
   869 apply (case_tac "n<m")
   870  apply (subgoal_tac "(m-n) div n < (m-n) ")
   871   apply (rule impI less_trans_Suc)+
   872 apply assumption
   873   apply (simp_all)
   874 done
   875 
   876 text{*A fact for the mutilated chess board*}
   877 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   878 apply (case_tac "n=0", simp)
   879 apply (induct "m" rule: nat_less_induct)
   880 apply (case_tac "Suc (na) <n")
   881 (* case Suc(na) < n *)
   882 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   883 (* case n \<le> Suc(na) *)
   884 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   885 apply (auto simp add: Suc_diff_le le_mod_geq)
   886 done
   887 
   888 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   889 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   890 
   891 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   892 
   893 (*Loses information, namely we also have r<d provided d is nonzero*)
   894 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   895   apply (cut_tac a = m in mod_div_equality)
   896   apply (simp only: add_ac)
   897   apply (blast intro: sym)
   898   done
   899 
   900 lemma split_div:
   901  "P(n div k :: nat) =
   902  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   903  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   904 proof
   905   assume P: ?P
   906   show ?Q
   907   proof (cases)
   908     assume "k = 0"
   909     with P show ?Q by simp
   910   next
   911     assume not0: "k \<noteq> 0"
   912     thus ?Q
   913     proof (simp, intro allI impI)
   914       fix i j
   915       assume n: "n = k*i + j" and j: "j < k"
   916       show "P i"
   917       proof (cases)
   918         assume "i = 0"
   919         with n j P show "P i" by simp
   920       next
   921         assume "i \<noteq> 0"
   922         with not0 n j P show "P i" by(simp add:add_ac)
   923       qed
   924     qed
   925   qed
   926 next
   927   assume Q: ?Q
   928   show ?P
   929   proof (cases)
   930     assume "k = 0"
   931     with Q show ?P by simp
   932   next
   933     assume not0: "k \<noteq> 0"
   934     with Q have R: ?R by simp
   935     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   936     show ?P by simp
   937   qed
   938 qed
   939 
   940 lemma split_div_lemma:
   941   assumes "0 < n"
   942   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   943 proof
   944   assume ?rhs
   945   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   946   then have A: "n * q \<le> m" by simp
   947   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   948   then have "m < m + (n - (m mod n))" by simp
   949   then have "m < n + (m - (m mod n))" by simp
   950   with nq have "m < n + n * q" by simp
   951   then have B: "m < n * Suc q" by simp
   952   from A B show ?lhs ..
   953 next
   954   assume P: ?lhs
   955   then have "divmod_nat_rel m n (q, m - n * q)"
   956     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   957   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   958   have "(q, m - n * q) = (m div n, m mod n)" by auto
   959   then show ?rhs by simp
   960 qed
   961 
   962 theorem split_div':
   963   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   964    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   965   apply (case_tac "0 < n")
   966   apply (simp only: add: split_div_lemma)
   967   apply simp_all
   968   done
   969 
   970 lemma split_mod:
   971  "P(n mod k :: nat) =
   972  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   973  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   974 proof
   975   assume P: ?P
   976   show ?Q
   977   proof (cases)
   978     assume "k = 0"
   979     with P show ?Q by simp
   980   next
   981     assume not0: "k \<noteq> 0"
   982     thus ?Q
   983     proof (simp, intro allI impI)
   984       fix i j
   985       assume "n = k*i + j" "j < k"
   986       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   987     qed
   988   qed
   989 next
   990   assume Q: ?Q
   991   show ?P
   992   proof (cases)
   993     assume "k = 0"
   994     with Q show ?P by simp
   995   next
   996     assume not0: "k \<noteq> 0"
   997     with Q have R: ?R by simp
   998     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   999     show ?P by simp
  1000   qed
  1001 qed
  1002 
  1003 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
  1004   using mod_div_equality [of m n] by arith
  1005 
  1006 lemma div_mod_equality': "(m::nat) div n * n = m - m mod n"
  1007   using mod_div_equality [of m n] by arith
  1008 (* FIXME: very similar to mult_div_cancel *)
  1009 
  1010 
  1011 subsubsection {* An ``induction'' law for modulus arithmetic. *}
  1012 
  1013 lemma mod_induct_0:
  1014   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1015   and base: "P i" and i: "i<p"
  1016   shows "P 0"
  1017 proof (rule ccontr)
  1018   assume contra: "\<not>(P 0)"
  1019   from i have p: "0<p" by simp
  1020   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1021   proof
  1022     fix k
  1023     show "?A k"
  1024     proof (induct k)
  1025       show "?A 0" by simp  -- "by contradiction"
  1026     next
  1027       fix n
  1028       assume ih: "?A n"
  1029       show "?A (Suc n)"
  1030       proof (clarsimp)
  1031         assume y: "P (p - Suc n)"
  1032         have n: "Suc n < p"
  1033         proof (rule ccontr)
  1034           assume "\<not>(Suc n < p)"
  1035           hence "p - Suc n = 0"
  1036             by simp
  1037           with y contra show "False"
  1038             by simp
  1039         qed
  1040         hence n2: "Suc (p - Suc n) = p-n" by arith
  1041         from p have "p - Suc n < p" by arith
  1042         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1043           by blast
  1044         show "False"
  1045         proof (cases "n=0")
  1046           case True
  1047           with z n2 contra show ?thesis by simp
  1048         next
  1049           case False
  1050           with p have "p-n < p" by arith
  1051           with z n2 False ih show ?thesis by simp
  1052         qed
  1053       qed
  1054     qed
  1055   qed
  1056   moreover
  1057   from i obtain k where "0<k \<and> i+k=p"
  1058     by (blast dest: less_imp_add_positive)
  1059   hence "0<k \<and> i=p-k" by auto
  1060   moreover
  1061   note base
  1062   ultimately
  1063   show "False" by blast
  1064 qed
  1065 
  1066 lemma mod_induct:
  1067   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1068   and base: "P i" and i: "i<p" and j: "j<p"
  1069   shows "P j"
  1070 proof -
  1071   have "\<forall>j<p. P j"
  1072   proof
  1073     fix j
  1074     show "j<p \<longrightarrow> P j" (is "?A j")
  1075     proof (induct j)
  1076       from step base i show "?A 0"
  1077         by (auto elim: mod_induct_0)
  1078     next
  1079       fix k
  1080       assume ih: "?A k"
  1081       show "?A (Suc k)"
  1082       proof
  1083         assume suc: "Suc k < p"
  1084         hence k: "k<p" by simp
  1085         with ih have "P k" ..
  1086         with step k have "P (Suc k mod p)"
  1087           by blast
  1088         moreover
  1089         from suc have "Suc k mod p = Suc k"
  1090           by simp
  1091         ultimately
  1092         show "P (Suc k)" by simp
  1093       qed
  1094     qed
  1095   qed
  1096   with j show ?thesis by blast
  1097 qed
  1098 
  1099 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1100   by (simp add: numeral_2_eq_2 le_div_geq)
  1101 
  1102 lemma mod2_Suc_Suc [simp]: "Suc (Suc m) mod 2 = m mod 2"
  1103   by (simp add: numeral_2_eq_2 le_mod_geq)
  1104 
  1105 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1106 by (simp add: mult_2 [symmetric])
  1107 
  1108 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1109 proof -
  1110   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1111   moreover have "m mod 2 < 2" by simp
  1112   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1113   then show ?thesis by auto
  1114 qed
  1115 
  1116 text{*These lemmas collapse some needless occurrences of Suc:
  1117     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1118     We already have some rules to simplify operands smaller than 3.*}
  1119 
  1120 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1121 by (simp add: Suc3_eq_add_3)
  1122 
  1123 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1124 by (simp add: Suc3_eq_add_3)
  1125 
  1126 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1127 by (simp add: Suc3_eq_add_3)
  1128 
  1129 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1130 by (simp add: Suc3_eq_add_3)
  1131 
  1132 lemmas Suc_div_eq_add3_div_numeral [simp] = Suc_div_eq_add3_div [of _ "numeral v"] for v
  1133 lemmas Suc_mod_eq_add3_mod_numeral [simp] = Suc_mod_eq_add3_mod [of _ "numeral v"] for v
  1134 
  1135 
  1136 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1137 apply (induct "m")
  1138 apply (simp_all add: mod_Suc)
  1139 done
  1140 
  1141 declare Suc_times_mod_eq [of "numeral w", simp] for w
  1142 
  1143 lemma Suc_div_le_mono [simp]: "n div k \<le> (Suc n) div k"
  1144 by (simp add: div_le_mono)
  1145 
  1146 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1147 by (cases n) simp_all
  1148 
  1149 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1150 proof -
  1151   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1152   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1153 qed
  1154 
  1155   (* Potential use of algebra : Equality modulo n*)
  1156 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1157 by (simp add: mult_ac add_ac)
  1158 
  1159 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1160 proof -
  1161   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1162   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1163   finally show ?thesis .
  1164 qed
  1165 
  1166 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1167 apply (subst mod_Suc [of m]) 
  1168 apply (subst mod_Suc [of "m mod n"], simp) 
  1169 done
  1170 
  1171 lemma mod_2_not_eq_zero_eq_one_nat:
  1172   fixes n :: nat
  1173   shows "n mod 2 \<noteq> 0 \<longleftrightarrow> n mod 2 = 1"
  1174   by simp
  1175 
  1176 
  1177 subsection {* Division on @{typ int} *}
  1178 
  1179 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1180     --{*definition of quotient and remainder*}
  1181   "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1182     (if 0 < b then 0 \<le> r \<and> r < b else if b < 0 then b < r \<and> r \<le> 0 else q = 0))"
  1183 
  1184 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1185     --{*for the division algorithm*}
  1186     "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1187                          else (2 * q, r))"
  1188 
  1189 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1190 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1191   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1192      else adjust b (posDivAlg a (2 * b)))"
  1193 by auto
  1194 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1195   (auto simp add: mult_2)
  1196 
  1197 text{*algorithm for the case @{text "a<0, b>0"}*}
  1198 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1199   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1200      else adjust b (negDivAlg a (2 * b)))"
  1201 by auto
  1202 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1203   (auto simp add: mult_2)
  1204 
  1205 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1206 
  1207 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1208     --{*The full division algorithm considers all possible signs for a, b
  1209        including the special case @{text "a=0, b<0"} because 
  1210        @{term negDivAlg} requires @{term "a<0"}.*}
  1211   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1212                   else if a = 0 then (0, 0)
  1213                        else apsnd uminus (negDivAlg (-a) (-b))
  1214                else 
  1215                   if 0 < b then negDivAlg a b
  1216                   else apsnd uminus (posDivAlg (-a) (-b)))"
  1217 
  1218 instantiation int :: Divides.div
  1219 begin
  1220 
  1221 definition div_int where
  1222   "a div b = fst (divmod_int a b)"
  1223 
  1224 lemma fst_divmod_int [simp]:
  1225   "fst (divmod_int a b) = a div b"
  1226   by (simp add: div_int_def)
  1227 
  1228 definition mod_int where
  1229   "a mod b = snd (divmod_int a b)"
  1230 
  1231 lemma snd_divmod_int [simp]:
  1232   "snd (divmod_int a b) = a mod b"
  1233   by (simp add: mod_int_def)
  1234 
  1235 instance ..
  1236 
  1237 end
  1238 
  1239 lemma divmod_int_mod_div:
  1240   "divmod_int p q = (p div q, p mod q)"
  1241   by (simp add: prod_eq_iff)
  1242 
  1243 text{*
  1244 Here is the division algorithm in ML:
  1245 
  1246 \begin{verbatim}
  1247     fun posDivAlg (a,b) =
  1248       if a<b then (0,a)
  1249       else let val (q,r) = posDivAlg(a, 2*b)
  1250                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1251            end
  1252 
  1253     fun negDivAlg (a,b) =
  1254       if 0\<le>a+b then (~1,a+b)
  1255       else let val (q,r) = negDivAlg(a, 2*b)
  1256                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1257            end;
  1258 
  1259     fun negateSnd (q,r:int) = (q,~r);
  1260 
  1261     fun divmod (a,b) = if 0\<le>a then 
  1262                           if b>0 then posDivAlg (a,b) 
  1263                            else if a=0 then (0,0)
  1264                                 else negateSnd (negDivAlg (~a,~b))
  1265                        else 
  1266                           if 0<b then negDivAlg (a,b)
  1267                           else        negateSnd (posDivAlg (~a,~b));
  1268 \end{verbatim}
  1269 *}
  1270 
  1271 
  1272 subsubsection {* Uniqueness and Monotonicity of Quotients and Remainders *}
  1273 
  1274 lemma unique_quotient_lemma:
  1275      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1276       ==> q' \<le> (q::int)"
  1277 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1278  prefer 2 apply (simp add: right_diff_distrib)
  1279 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1280 apply (erule_tac [2] order_le_less_trans)
  1281  prefer 2 apply (simp add: right_diff_distrib distrib_left)
  1282 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1283  prefer 2 apply (simp add: right_diff_distrib distrib_left)
  1284 apply (simp add: mult_less_cancel_left)
  1285 done
  1286 
  1287 lemma unique_quotient_lemma_neg:
  1288      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1289       ==> q \<le> (q'::int)"
  1290 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1291     auto)
  1292 
  1293 lemma unique_quotient:
  1294      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1295       ==> q = q'"
  1296 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1297 apply (blast intro: order_antisym
  1298              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1299              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1300 done
  1301 
  1302 
  1303 lemma unique_remainder:
  1304      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1305       ==> r = r'"
  1306 apply (subgoal_tac "q = q'")
  1307  apply (simp add: divmod_int_rel_def)
  1308 apply (blast intro: unique_quotient)
  1309 done
  1310 
  1311 
  1312 subsubsection {* Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends *}
  1313 
  1314 text{*And positive divisors*}
  1315 
  1316 lemma adjust_eq [simp]:
  1317      "adjust b (q, r) = 
  1318       (let diff = r - b in  
  1319         if 0 \<le> diff then (2 * q + 1, diff)   
  1320                      else (2*q, r))"
  1321   by (simp add: Let_def adjust_def)
  1322 
  1323 declare posDivAlg.simps [simp del]
  1324 
  1325 text{*use with a simproc to avoid repeatedly proving the premise*}
  1326 lemma posDivAlg_eqn:
  1327      "0 < b ==>  
  1328       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1329 by (rule posDivAlg.simps [THEN trans], simp)
  1330 
  1331 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1332 theorem posDivAlg_correct:
  1333   assumes "0 \<le> a" and "0 < b"
  1334   shows "divmod_int_rel a b (posDivAlg a b)"
  1335   using assms
  1336   apply (induct a b rule: posDivAlg.induct)
  1337   apply auto
  1338   apply (simp add: divmod_int_rel_def)
  1339   apply (subst posDivAlg_eqn, simp add: distrib_left)
  1340   apply (case_tac "a < b")
  1341   apply simp_all
  1342   apply (erule splitE)
  1343   apply (auto simp add: distrib_left Let_def mult_ac mult_2_right)
  1344   done
  1345 
  1346 
  1347 subsubsection {* Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends *}
  1348 
  1349 text{*And positive divisors*}
  1350 
  1351 declare negDivAlg.simps [simp del]
  1352 
  1353 text{*use with a simproc to avoid repeatedly proving the premise*}
  1354 lemma negDivAlg_eqn:
  1355      "0 < b ==>  
  1356       negDivAlg a b =       
  1357        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1358 by (rule negDivAlg.simps [THEN trans], simp)
  1359 
  1360 (*Correctness of negDivAlg: it computes quotients correctly
  1361   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1362 lemma negDivAlg_correct:
  1363   assumes "a < 0" and "b > 0"
  1364   shows "divmod_int_rel a b (negDivAlg a b)"
  1365   using assms
  1366   apply (induct a b rule: negDivAlg.induct)
  1367   apply (auto simp add: linorder_not_le)
  1368   apply (simp add: divmod_int_rel_def)
  1369   apply (subst negDivAlg_eqn, assumption)
  1370   apply (case_tac "a + b < (0\<Colon>int)")
  1371   apply simp_all
  1372   apply (erule splitE)
  1373   apply (auto simp add: distrib_left Let_def mult_ac mult_2_right)
  1374   done
  1375 
  1376 
  1377 subsubsection {* Existence Shown by Proving the Division Algorithm to be Correct *}
  1378 
  1379 (*the case a=0*)
  1380 lemma divmod_int_rel_0: "divmod_int_rel 0 b (0, 0)"
  1381 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1382 
  1383 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1384 by (subst posDivAlg.simps, auto)
  1385 
  1386 lemma posDivAlg_0_right [simp]: "posDivAlg a 0 = (0, a)"
  1387 by (subst posDivAlg.simps, auto)
  1388 
  1389 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1390 by (subst negDivAlg.simps, auto)
  1391 
  1392 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (apsnd uminus qr)"
  1393 by (auto simp add: divmod_int_rel_def)
  1394 
  1395 lemma divmod_int_correct: "divmod_int_rel a b (divmod_int a b)"
  1396 apply (cases "b = 0", simp add: divmod_int_def divmod_int_rel_def)
  1397 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1398                     posDivAlg_correct negDivAlg_correct)
  1399 
  1400 lemma divmod_int_unique:
  1401   assumes "divmod_int_rel a b qr" 
  1402   shows "divmod_int a b = qr"
  1403   using assms divmod_int_correct [of a b]
  1404   using unique_quotient [of a b] unique_remainder [of a b]
  1405   by (metis pair_collapse)
  1406 
  1407 lemma divmod_int_rel_div_mod: "divmod_int_rel a b (a div b, a mod b)"
  1408   using divmod_int_correct by (simp add: divmod_int_mod_div)
  1409 
  1410 lemma div_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a div b = q"
  1411   by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1412 
  1413 lemma mod_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a mod b = r"
  1414   by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1415 
  1416 instance int :: ring_div
  1417 proof
  1418   fix a b :: int
  1419   show "a div b * b + a mod b = a"
  1420     using divmod_int_rel_div_mod [of a b]
  1421     unfolding divmod_int_rel_def by (simp add: mult_commute)
  1422 next
  1423   fix a b c :: int
  1424   assume "b \<noteq> 0"
  1425   hence "divmod_int_rel (a + c * b) b (c + a div b, a mod b)"
  1426     using divmod_int_rel_div_mod [of a b]
  1427     unfolding divmod_int_rel_def by (auto simp: algebra_simps)
  1428   thus "(a + c * b) div b = c + a div b"
  1429     by (rule div_int_unique)
  1430 next
  1431   fix a b c :: int
  1432   assume "c \<noteq> 0"
  1433   hence "\<And>q r. divmod_int_rel a b (q, r)
  1434     \<Longrightarrow> divmod_int_rel (c * a) (c * b) (q, c * r)"
  1435     unfolding divmod_int_rel_def
  1436     by - (rule linorder_cases [of 0 b], auto simp: algebra_simps
  1437       mult_less_0_iff zero_less_mult_iff mult_strict_right_mono
  1438       mult_strict_right_mono_neg zero_le_mult_iff mult_le_0_iff)
  1439   hence "divmod_int_rel (c * a) (c * b) (a div b, c * (a mod b))"
  1440     using divmod_int_rel_div_mod [of a b] .
  1441   thus "(c * a) div (c * b) = a div b"
  1442     by (rule div_int_unique)
  1443 next
  1444   fix a :: int show "a div 0 = 0"
  1445     by (rule div_int_unique, simp add: divmod_int_rel_def)
  1446 next
  1447   fix a :: int show "0 div a = 0"
  1448     by (rule div_int_unique, auto simp add: divmod_int_rel_def)
  1449 qed
  1450 
  1451 text{*Basic laws about division and remainder*}
  1452 
  1453 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1454   by (fact mod_div_equality2 [symmetric])
  1455 
  1456 text {* Tool setup *}
  1457 
  1458 (* FIXME: Theorem list add_0s doesn't exist, because Numeral0 has gone. *)
  1459 lemmas add_0s = add_0_left add_0_right
  1460 
  1461 ML {*
  1462 structure Cancel_Div_Mod_Int = Cancel_Div_Mod
  1463 (
  1464   val div_name = @{const_name div};
  1465   val mod_name = @{const_name mod};
  1466   val mk_binop = HOLogic.mk_binop;
  1467   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1468   val dest_sum = Arith_Data.dest_sum;
  1469 
  1470   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
  1471 
  1472   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1473     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1474 )
  1475 *}
  1476 
  1477 simproc_setup cancel_div_mod_int ("(k::int) + l") = {* K Cancel_Div_Mod_Int.proc *}
  1478 
  1479 lemma pos_mod_conj: "(0::int) < b \<Longrightarrow> 0 \<le> a mod b \<and> a mod b < b"
  1480   using divmod_int_correct [of a b]
  1481   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1482 
  1483 lemmas pos_mod_sign [simp] = pos_mod_conj [THEN conjunct1]
  1484    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2]
  1485 
  1486 lemma neg_mod_conj: "b < (0::int) \<Longrightarrow> a mod b \<le> 0 \<and> b < a mod b"
  1487   using divmod_int_correct [of a b]
  1488   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1489 
  1490 lemmas neg_mod_sign [simp] = neg_mod_conj [THEN conjunct1]
  1491    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2]
  1492 
  1493 
  1494 subsubsection {* General Properties of div and mod *}
  1495 
  1496 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1497 apply (rule div_int_unique)
  1498 apply (auto simp add: divmod_int_rel_def)
  1499 done
  1500 
  1501 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1502 apply (rule div_int_unique)
  1503 apply (auto simp add: divmod_int_rel_def)
  1504 done
  1505 
  1506 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1507 apply (rule div_int_unique)
  1508 apply (auto simp add: divmod_int_rel_def)
  1509 done
  1510 
  1511 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1512 
  1513 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1514 apply (rule_tac q = 0 in mod_int_unique)
  1515 apply (auto simp add: divmod_int_rel_def)
  1516 done
  1517 
  1518 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1519 apply (rule_tac q = 0 in mod_int_unique)
  1520 apply (auto simp add: divmod_int_rel_def)
  1521 done
  1522 
  1523 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1524 apply (rule_tac q = "-1" in mod_int_unique)
  1525 apply (auto simp add: divmod_int_rel_def)
  1526 done
  1527 
  1528 text{*There is no @{text mod_neg_pos_trivial}.*}
  1529 
  1530 
  1531 subsubsection {* Laws for div and mod with Unary Minus *}
  1532 
  1533 lemma zminus1_lemma:
  1534      "divmod_int_rel a b (q, r) ==> b \<noteq> 0
  1535       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1536                           if r=0 then 0 else b-r)"
  1537 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1538 
  1539 
  1540 lemma zdiv_zminus1_eq_if:
  1541      "b \<noteq> (0::int)  
  1542       ==> (-a) div b =  
  1543           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1544 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN div_int_unique])
  1545 
  1546 lemma zmod_zminus1_eq_if:
  1547      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1548 apply (case_tac "b = 0", simp)
  1549 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN mod_int_unique])
  1550 done
  1551 
  1552 lemma zmod_zminus1_not_zero:
  1553   fixes k l :: int
  1554   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1555   unfolding zmod_zminus1_eq_if by auto
  1556 
  1557 lemma zdiv_zminus2_eq_if:
  1558      "b \<noteq> (0::int)  
  1559       ==> a div (-b) =  
  1560           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1561 by (simp add: zdiv_zminus1_eq_if div_minus_right)
  1562 
  1563 lemma zmod_zminus2_eq_if:
  1564      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1565 by (simp add: zmod_zminus1_eq_if mod_minus_right)
  1566 
  1567 lemma zmod_zminus2_not_zero:
  1568   fixes k l :: int
  1569   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1570   unfolding zmod_zminus2_eq_if by auto 
  1571 
  1572 
  1573 subsubsection {* Computation of Division and Remainder *}
  1574 
  1575 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1576 by (simp add: div_int_def divmod_int_def)
  1577 
  1578 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1579 by (simp add: mod_int_def divmod_int_def)
  1580 
  1581 text{*a positive, b positive *}
  1582 
  1583 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1584 by (simp add: div_int_def divmod_int_def)
  1585 
  1586 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1587 by (simp add: mod_int_def divmod_int_def)
  1588 
  1589 text{*a negative, b positive *}
  1590 
  1591 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1592 by (simp add: div_int_def divmod_int_def)
  1593 
  1594 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1595 by (simp add: mod_int_def divmod_int_def)
  1596 
  1597 text{*a positive, b negative *}
  1598 
  1599 lemma div_pos_neg:
  1600      "[| 0 < a;  b < 0 |] ==> a div b = fst (apsnd uminus (negDivAlg (-a) (-b)))"
  1601 by (simp add: div_int_def divmod_int_def)
  1602 
  1603 lemma mod_pos_neg:
  1604      "[| 0 < a;  b < 0 |] ==> a mod b = snd (apsnd uminus (negDivAlg (-a) (-b)))"
  1605 by (simp add: mod_int_def divmod_int_def)
  1606 
  1607 text{*a negative, b negative *}
  1608 
  1609 lemma div_neg_neg:
  1610      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (apsnd uminus (posDivAlg (-a) (-b)))"
  1611 by (simp add: div_int_def divmod_int_def)
  1612 
  1613 lemma mod_neg_neg:
  1614      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (apsnd uminus (posDivAlg (-a) (-b)))"
  1615 by (simp add: mod_int_def divmod_int_def)
  1616 
  1617 text {*Simplify expresions in which div and mod combine numerical constants*}
  1618 
  1619 lemma int_div_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a div b = q"
  1620   by (rule div_int_unique [of a b q r]) (simp add: divmod_int_rel_def)
  1621 
  1622 lemma int_div_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a div b = q"
  1623   by (rule div_int_unique [of a b q r],
  1624     simp add: divmod_int_rel_def)
  1625 
  1626 lemma int_mod_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a mod b = r"
  1627   by (rule mod_int_unique [of a b q r],
  1628     simp add: divmod_int_rel_def)
  1629 
  1630 lemma int_mod_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a mod b = r"
  1631   by (rule mod_int_unique [of a b q r],
  1632     simp add: divmod_int_rel_def)
  1633 
  1634 (* simprocs adapted from HOL/ex/Binary.thy *)
  1635 ML {*
  1636 local
  1637   val mk_number = HOLogic.mk_number HOLogic.intT
  1638   val plus = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"}
  1639   val times = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"}
  1640   val zero = @{term "0 :: int"}
  1641   val less = @{term "op < :: int \<Rightarrow> int \<Rightarrow> bool"}
  1642   val le = @{term "op \<le> :: int \<Rightarrow> int \<Rightarrow> bool"}
  1643   val simps = @{thms arith_simps} @ @{thms rel_simps} @
  1644     map (fn th => th RS sym) [@{thm numeral_1_eq_1}]
  1645   fun prove ctxt goal = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop goal)
  1646     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps simps))));
  1647   fun binary_proc proc ss ct =
  1648     (case Thm.term_of ct of
  1649       _ $ t $ u =>
  1650       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1651         SOME args => proc (Simplifier.the_context ss) args
  1652       | NONE => NONE)
  1653     | _ => NONE);
  1654 in
  1655   fun divmod_proc posrule negrule =
  1656     binary_proc (fn ctxt => fn ((a, t), (b, u)) =>
  1657       if b = 0 then NONE else let
  1658         val (q, r) = pairself mk_number (Integer.div_mod a b)
  1659         val goal1 = HOLogic.mk_eq (t, plus $ (times $ u $ q) $ r)
  1660         val (goal2, goal3, rule) = if b > 0
  1661           then (le $ zero $ r, less $ r $ u, posrule RS eq_reflection)
  1662           else (le $ r $ zero, less $ u $ r, negrule RS eq_reflection)
  1663       in SOME (rule OF map (prove ctxt) [goal1, goal2, goal3]) end)
  1664 end
  1665 *}
  1666 
  1667 simproc_setup binary_int_div
  1668   ("numeral m div numeral n :: int" |
  1669    "numeral m div neg_numeral n :: int" |
  1670    "neg_numeral m div numeral n :: int" |
  1671    "neg_numeral m div neg_numeral n :: int") =
  1672   {* K (divmod_proc @{thm int_div_pos_eq} @{thm int_div_neg_eq}) *}
  1673 
  1674 simproc_setup binary_int_mod
  1675   ("numeral m mod numeral n :: int" |
  1676    "numeral m mod neg_numeral n :: int" |
  1677    "neg_numeral m mod numeral n :: int" |
  1678    "neg_numeral m mod neg_numeral n :: int") =
  1679   {* K (divmod_proc @{thm int_mod_pos_eq} @{thm int_mod_neg_eq}) *}
  1680 
  1681 lemmas posDivAlg_eqn_numeral [simp] =
  1682     posDivAlg_eqn [of "numeral v" "numeral w", OF zero_less_numeral] for v w
  1683 
  1684 lemmas negDivAlg_eqn_numeral [simp] =
  1685     negDivAlg_eqn [of "numeral v" "neg_numeral w", OF zero_less_numeral] for v w
  1686 
  1687 
  1688 text{*Special-case simplification *}
  1689 
  1690 (** The last remaining special cases for constant arithmetic:
  1691     1 div z and 1 mod z **)
  1692 
  1693 lemmas div_pos_pos_1_numeral [simp] =
  1694   div_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1695 
  1696 lemmas div_pos_neg_1_numeral [simp] =
  1697   div_pos_neg [OF zero_less_one, of "neg_numeral w",
  1698   OF neg_numeral_less_zero] for w
  1699 
  1700 lemmas mod_pos_pos_1_numeral [simp] =
  1701   mod_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1702 
  1703 lemmas mod_pos_neg_1_numeral [simp] =
  1704   mod_pos_neg [OF zero_less_one, of "neg_numeral w",
  1705   OF neg_numeral_less_zero] for w
  1706 
  1707 lemmas posDivAlg_eqn_1_numeral [simp] =
  1708     posDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1709 
  1710 lemmas negDivAlg_eqn_1_numeral [simp] =
  1711     negDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1712 
  1713 
  1714 subsubsection {* Monotonicity in the First Argument (Dividend) *}
  1715 
  1716 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1717 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1718 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1719 apply (rule unique_quotient_lemma)
  1720 apply (erule subst)
  1721 apply (erule subst, simp_all)
  1722 done
  1723 
  1724 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1725 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1726 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1727 apply (rule unique_quotient_lemma_neg)
  1728 apply (erule subst)
  1729 apply (erule subst, simp_all)
  1730 done
  1731 
  1732 
  1733 subsubsection {* Monotonicity in the Second Argument (Divisor) *}
  1734 
  1735 lemma q_pos_lemma:
  1736      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1737 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1738  apply (simp add: zero_less_mult_iff)
  1739 apply (simp add: distrib_left)
  1740 done
  1741 
  1742 lemma zdiv_mono2_lemma:
  1743      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1744          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1745       ==> q \<le> (q'::int)"
  1746 apply (frule q_pos_lemma, assumption+) 
  1747 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1748  apply (simp add: mult_less_cancel_left)
  1749 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1750  prefer 2 apply simp
  1751 apply (simp (no_asm_simp) add: distrib_left)
  1752 apply (subst add_commute, rule add_less_le_mono, arith)
  1753 apply (rule mult_right_mono, auto)
  1754 done
  1755 
  1756 lemma zdiv_mono2:
  1757      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1758 apply (subgoal_tac "b \<noteq> 0")
  1759  prefer 2 apply arith
  1760 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1761 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1762 apply (rule zdiv_mono2_lemma)
  1763 apply (erule subst)
  1764 apply (erule subst, simp_all)
  1765 done
  1766 
  1767 lemma q_neg_lemma:
  1768      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1769 apply (subgoal_tac "b'*q' < 0")
  1770  apply (simp add: mult_less_0_iff, arith)
  1771 done
  1772 
  1773 lemma zdiv_mono2_neg_lemma:
  1774      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1775          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1776       ==> q' \<le> (q::int)"
  1777 apply (frule q_neg_lemma, assumption+) 
  1778 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1779  apply (simp add: mult_less_cancel_left)
  1780 apply (simp add: distrib_left)
  1781 apply (subgoal_tac "b*q' \<le> b'*q'")
  1782  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1783 done
  1784 
  1785 lemma zdiv_mono2_neg:
  1786      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1787 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1788 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1789 apply (rule zdiv_mono2_neg_lemma)
  1790 apply (erule subst)
  1791 apply (erule subst, simp_all)
  1792 done
  1793 
  1794 
  1795 subsubsection {* More Algebraic Laws for div and mod *}
  1796 
  1797 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1798 
  1799 lemma zmult1_lemma:
  1800      "[| divmod_int_rel b c (q, r) |]  
  1801       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1802 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff distrib_left mult_ac)
  1803 
  1804 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1805 apply (case_tac "c = 0", simp)
  1806 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN div_int_unique])
  1807 done
  1808 
  1809 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1810 
  1811 lemma zadd1_lemma:
  1812      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br) |]  
  1813       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1814 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff distrib_left)
  1815 
  1816 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1817 lemma zdiv_zadd1_eq:
  1818      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1819 apply (case_tac "c = 0", simp)
  1820 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] div_int_unique)
  1821 done
  1822 
  1823 lemma posDivAlg_div_mod:
  1824   assumes "k \<ge> 0"
  1825   and "l \<ge> 0"
  1826   shows "posDivAlg k l = (k div l, k mod l)"
  1827 proof (cases "l = 0")
  1828   case True then show ?thesis by (simp add: posDivAlg.simps)
  1829 next
  1830   case False with assms posDivAlg_correct
  1831     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1832     by simp
  1833   from div_int_unique [OF this] mod_int_unique [OF this]
  1834   show ?thesis by simp
  1835 qed
  1836 
  1837 lemma negDivAlg_div_mod:
  1838   assumes "k < 0"
  1839   and "l > 0"
  1840   shows "negDivAlg k l = (k div l, k mod l)"
  1841 proof -
  1842   from assms have "l \<noteq> 0" by simp
  1843   from assms negDivAlg_correct
  1844     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1845     by simp
  1846   from div_int_unique [OF this] mod_int_unique [OF this]
  1847   show ?thesis by simp
  1848 qed
  1849 
  1850 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1851 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1852 
  1853 (* REVISIT: should this be generalized to all semiring_div types? *)
  1854 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1855 
  1856 lemma zmod_zdiv_equality':
  1857   "(m\<Colon>int) mod n = m - (m div n) * n"
  1858   using mod_div_equality [of m n] by arith
  1859 
  1860 
  1861 subsubsection {* Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1862 
  1863 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1864   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1865   to cause particular problems.*)
  1866 
  1867 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1868 
  1869 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1870 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1871  apply (simp add: algebra_simps)
  1872 apply (rule order_le_less_trans)
  1873  apply (erule_tac [2] mult_strict_right_mono)
  1874  apply (rule mult_left_mono_neg)
  1875   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1876  apply (simp)
  1877 apply (simp)
  1878 done
  1879 
  1880 lemma zmult2_lemma_aux2:
  1881      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1882 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1883  apply arith
  1884 apply (simp add: mult_le_0_iff)
  1885 done
  1886 
  1887 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1888 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1889 apply arith
  1890 apply (simp add: zero_le_mult_iff)
  1891 done
  1892 
  1893 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1894 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1895  apply (simp add: right_diff_distrib)
  1896 apply (rule order_less_le_trans)
  1897  apply (erule mult_strict_right_mono)
  1898  apply (rule_tac [2] mult_left_mono)
  1899   apply simp
  1900  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1901 apply simp
  1902 done
  1903 
  1904 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r); 0 < c |]  
  1905       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1906 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  1907                    zero_less_mult_iff distrib_left [symmetric] 
  1908                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4 mult_less_0_iff split: split_if_asm)
  1909 
  1910 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  1911 apply (case_tac "b = 0", simp)
  1912 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN div_int_unique])
  1913 done
  1914 
  1915 lemma zmod_zmult2_eq:
  1916      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  1917 apply (case_tac "b = 0", simp)
  1918 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN mod_int_unique])
  1919 done
  1920 
  1921 lemma div_pos_geq:
  1922   fixes k l :: int
  1923   assumes "0 < l" and "l \<le> k"
  1924   shows "k div l = (k - l) div l + 1"
  1925 proof -
  1926   have "k = (k - l) + l" by simp
  1927   then obtain j where k: "k = j + l" ..
  1928   with assms show ?thesis by simp
  1929 qed
  1930 
  1931 lemma mod_pos_geq:
  1932   fixes k l :: int
  1933   assumes "0 < l" and "l \<le> k"
  1934   shows "k mod l = (k - l) mod l"
  1935 proof -
  1936   have "k = (k - l) + l" by simp
  1937   then obtain j where k: "k = j + l" ..
  1938   with assms show ?thesis by simp
  1939 qed
  1940 
  1941 
  1942 subsubsection {* Splitting Rules for div and mod *}
  1943 
  1944 text{*The proofs of the two lemmas below are essentially identical*}
  1945 
  1946 lemma split_pos_lemma:
  1947  "0<k ==> 
  1948     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  1949 apply (rule iffI, clarify)
  1950  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1951  apply (subst mod_add_eq) 
  1952  apply (subst zdiv_zadd1_eq) 
  1953  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  1954 txt{*converse direction*}
  1955 apply (drule_tac x = "n div k" in spec) 
  1956 apply (drule_tac x = "n mod k" in spec, simp)
  1957 done
  1958 
  1959 lemma split_neg_lemma:
  1960  "k<0 ==>
  1961     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  1962 apply (rule iffI, clarify)
  1963  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1964  apply (subst mod_add_eq) 
  1965  apply (subst zdiv_zadd1_eq) 
  1966  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  1967 txt{*converse direction*}
  1968 apply (drule_tac x = "n div k" in spec) 
  1969 apply (drule_tac x = "n mod k" in spec, simp)
  1970 done
  1971 
  1972 lemma split_zdiv:
  1973  "P(n div k :: int) =
  1974   ((k = 0 --> P 0) & 
  1975    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  1976    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  1977 apply (case_tac "k=0", simp)
  1978 apply (simp only: linorder_neq_iff)
  1979 apply (erule disjE) 
  1980  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  1981                       split_neg_lemma [of concl: "%x y. P x"])
  1982 done
  1983 
  1984 lemma split_zmod:
  1985  "P(n mod k :: int) =
  1986   ((k = 0 --> P n) & 
  1987    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  1988    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  1989 apply (case_tac "k=0", simp)
  1990 apply (simp only: linorder_neq_iff)
  1991 apply (erule disjE) 
  1992  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  1993                       split_neg_lemma [of concl: "%x y. P y"])
  1994 done
  1995 
  1996 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  1997   when these are applied to some constant that is of the form
  1998   @{term "numeral k"}: *}
  1999 declare split_zdiv [of _ _ "numeral k", arith_split] for k
  2000 declare split_zmod [of _ _ "numeral k", arith_split] for k
  2001 
  2002 
  2003 subsubsection {* Computing @{text "div"} and @{text "mod"} with shifting *}
  2004 
  2005 lemma pos_divmod_int_rel_mult_2:
  2006   assumes "0 \<le> b"
  2007   assumes "divmod_int_rel a b (q, r)"
  2008   shows "divmod_int_rel (1 + 2*a) (2*b) (q, 1 + 2*r)"
  2009   using assms unfolding divmod_int_rel_def by auto
  2010 
  2011 lemma neg_divmod_int_rel_mult_2:
  2012   assumes "b \<le> 0"
  2013   assumes "divmod_int_rel (a + 1) b (q, r)"
  2014   shows "divmod_int_rel (1 + 2*a) (2*b) (q, 2*r - 1)"
  2015   using assms unfolding divmod_int_rel_def by auto
  2016 
  2017 text{*computing div by shifting *}
  2018 
  2019 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2020   using pos_divmod_int_rel_mult_2 [OF _ divmod_int_rel_div_mod]
  2021   by (rule div_int_unique)
  2022 
  2023 lemma neg_zdiv_mult_2: 
  2024   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2025   using neg_divmod_int_rel_mult_2 [OF A divmod_int_rel_div_mod]
  2026   by (rule div_int_unique)
  2027 
  2028 (* FIXME: add rules for negative numerals *)
  2029 lemma zdiv_numeral_Bit0 [simp]:
  2030   "numeral (Num.Bit0 v) div numeral (Num.Bit0 w) =
  2031     numeral v div (numeral w :: int)"
  2032   unfolding numeral.simps unfolding mult_2 [symmetric]
  2033   by (rule div_mult_mult1, simp)
  2034 
  2035 lemma zdiv_numeral_Bit1 [simp]:
  2036   "numeral (Num.Bit1 v) div numeral (Num.Bit0 w) =  
  2037     (numeral v div (numeral w :: int))"
  2038   unfolding numeral.simps
  2039   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2040   by (rule pos_zdiv_mult_2, simp)
  2041 
  2042 lemma pos_zmod_mult_2:
  2043   fixes a b :: int
  2044   assumes "0 \<le> a"
  2045   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2046   using pos_divmod_int_rel_mult_2 [OF assms divmod_int_rel_div_mod]
  2047   by (rule mod_int_unique)
  2048 
  2049 lemma neg_zmod_mult_2:
  2050   fixes a b :: int
  2051   assumes "a \<le> 0"
  2052   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2053   using neg_divmod_int_rel_mult_2 [OF assms divmod_int_rel_div_mod]
  2054   by (rule mod_int_unique)
  2055 
  2056 (* FIXME: add rules for negative numerals *)
  2057 lemma zmod_numeral_Bit0 [simp]:
  2058   "numeral (Num.Bit0 v) mod numeral (Num.Bit0 w) =  
  2059     (2::int) * (numeral v mod numeral w)"
  2060   unfolding numeral_Bit0 [of v] numeral_Bit0 [of w]
  2061   unfolding mult_2 [symmetric] by (rule mod_mult_mult1)
  2062 
  2063 lemma zmod_numeral_Bit1 [simp]:
  2064   "numeral (Num.Bit1 v) mod numeral (Num.Bit0 w) =
  2065     2 * (numeral v mod numeral w) + (1::int)"
  2066   unfolding numeral_Bit1 [of v] numeral_Bit0 [of w]
  2067   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2068   by (rule pos_zmod_mult_2, simp)
  2069 
  2070 lemma zdiv_eq_0_iff:
  2071  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2072 proof
  2073   assume ?L
  2074   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2075   with `?L` show ?R by blast
  2076 next
  2077   assume ?R thus ?L
  2078     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2079 qed
  2080 
  2081 
  2082 subsubsection {* Quotients of Signs *}
  2083 
  2084 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2085 apply (subgoal_tac "a div b \<le> -1", force)
  2086 apply (rule order_trans)
  2087 apply (rule_tac a' = "-1" in zdiv_mono1)
  2088 apply (auto simp add: div_eq_minus1)
  2089 done
  2090 
  2091 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2092 by (drule zdiv_mono1_neg, auto)
  2093 
  2094 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2095 by (drule zdiv_mono1, auto)
  2096 
  2097 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2098 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2099 They should all be simp rules unless that causes too much search. *}
  2100 
  2101 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2102 apply auto
  2103 apply (drule_tac [2] zdiv_mono1)
  2104 apply (auto simp add: linorder_neq_iff)
  2105 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2106 apply (blast intro: div_neg_pos_less0)
  2107 done
  2108 
  2109 lemma neg_imp_zdiv_nonneg_iff:
  2110   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2111 apply (subst div_minus_minus [symmetric])
  2112 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2113 done
  2114 
  2115 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2116 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2117 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2118 
  2119 lemma pos_imp_zdiv_pos_iff:
  2120   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2121 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2122 by arith
  2123 
  2124 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2125 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2126 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2127 
  2128 lemma nonneg1_imp_zdiv_pos_iff:
  2129   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2130 apply rule
  2131  apply rule
  2132   using div_pos_pos_trivial[of a b]apply arith
  2133  apply(cases "b=0")apply simp
  2134  using div_nonneg_neg_le0[of a b]apply arith
  2135 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2136 done
  2137 
  2138 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2139 apply (rule split_zmod[THEN iffD2])
  2140 apply(fastforce dest: q_pos_lemma intro: split_mult_pos_le)
  2141 done
  2142 
  2143 
  2144 subsubsection {* The Divides Relation *}
  2145 
  2146 lemma dvd_neg_numeral_left [simp]:
  2147   fixes y :: "'a::comm_ring_1"
  2148   shows "(neg_numeral k) dvd y \<longleftrightarrow> (numeral k) dvd y"
  2149   unfolding neg_numeral_def minus_dvd_iff ..
  2150 
  2151 lemma dvd_neg_numeral_right [simp]:
  2152   fixes x :: "'a::comm_ring_1"
  2153   shows "x dvd (neg_numeral k) \<longleftrightarrow> x dvd (numeral k)"
  2154   unfolding neg_numeral_def dvd_minus_iff ..
  2155 
  2156 lemmas dvd_eq_mod_eq_0_numeral [simp] =
  2157   dvd_eq_mod_eq_0 [of "numeral x" "numeral y"] for x y
  2158 
  2159 
  2160 subsubsection {* Further properties *}
  2161 
  2162 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2163   using zmod_zdiv_equality[where a="m" and b="n"]
  2164   by (simp add: algebra_simps) (* FIXME: generalize *)
  2165 
  2166 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2167 apply (subst split_div, auto)
  2168 apply (subst split_zdiv, auto)
  2169 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2170 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2171 done
  2172 
  2173 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2174 apply (subst split_mod, auto)
  2175 apply (subst split_zmod, auto)
  2176 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2177        in unique_remainder)
  2178 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2179 done
  2180 
  2181 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2182 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2183 
  2184 text{*Suggested by Matthias Daum*}
  2185 lemma int_power_div_base:
  2186      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2187 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2188  apply (erule ssubst)
  2189  apply (simp only: power_add)
  2190  apply simp_all
  2191 done
  2192 
  2193 text {* by Brian Huffman *}
  2194 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2195 by (rule mod_minus_eq [symmetric])
  2196 
  2197 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2198 by (rule mod_diff_left_eq [symmetric])
  2199 
  2200 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2201 by (rule mod_diff_right_eq [symmetric])
  2202 
  2203 lemmas zmod_simps =
  2204   mod_add_left_eq  [symmetric]
  2205   mod_add_right_eq [symmetric]
  2206   mod_mult_right_eq[symmetric]
  2207   mod_mult_left_eq [symmetric]
  2208   power_mod
  2209   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2210 
  2211 text {* Distributive laws for function @{text nat}. *}
  2212 
  2213 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2214 apply (rule linorder_cases [of y 0])
  2215 apply (simp add: div_nonneg_neg_le0)
  2216 apply simp
  2217 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2218 done
  2219 
  2220 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2221 lemma nat_mod_distrib:
  2222   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2223 apply (case_tac "y = 0", simp)
  2224 apply (simp add: nat_eq_iff zmod_int)
  2225 done
  2226 
  2227 text  {* transfer setup *}
  2228 
  2229 lemma transfer_nat_int_functions:
  2230     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2231     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2232   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2233 
  2234 lemma transfer_nat_int_function_closures:
  2235     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2236     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2237   apply (cases "y = 0")
  2238   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2239   apply (cases "y = 0")
  2240   apply auto
  2241 done
  2242 
  2243 declare transfer_morphism_nat_int [transfer add return:
  2244   transfer_nat_int_functions
  2245   transfer_nat_int_function_closures
  2246 ]
  2247 
  2248 lemma transfer_int_nat_functions:
  2249     "(int x) div (int y) = int (x div y)"
  2250     "(int x) mod (int y) = int (x mod y)"
  2251   by (auto simp add: zdiv_int zmod_int)
  2252 
  2253 lemma transfer_int_nat_function_closures:
  2254     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2255     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2256   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2257 
  2258 declare transfer_morphism_int_nat [transfer add return:
  2259   transfer_int_nat_functions
  2260   transfer_int_nat_function_closures
  2261 ]
  2262 
  2263 text{*Suggested by Matthias Daum*}
  2264 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2265 apply (subgoal_tac "nat x div nat k < nat x")
  2266  apply (simp add: nat_div_distrib [symmetric])
  2267 apply (rule Divides.div_less_dividend, simp_all)
  2268 done
  2269 
  2270 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2271 proof
  2272   assume H: "x mod n = y mod n"
  2273   hence "x mod n - y mod n = 0" by simp
  2274   hence "(x mod n - y mod n) mod n = 0" by simp 
  2275   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2276   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2277 next
  2278   assume H: "n dvd x - y"
  2279   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2280   hence "x = n*k + y" by simp
  2281   hence "x mod n = (n*k + y) mod n" by simp
  2282   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2283 qed
  2284 
  2285 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2286   shows "\<exists>q. x = y + n * q"
  2287 proof-
  2288   from xy have th: "int x - int y = int (x - y)" by simp 
  2289   from xyn have "int x mod int n = int y mod int n" 
  2290     by (simp add: zmod_int [symmetric])
  2291   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2292   hence "n dvd x - y" by (simp add: th zdvd_int)
  2293   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2294 qed
  2295 
  2296 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2297   (is "?lhs = ?rhs")
  2298 proof
  2299   assume H: "x mod n = y mod n"
  2300   {assume xy: "x \<le> y"
  2301     from H have th: "y mod n = x mod n" by simp
  2302     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2303       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2304   moreover
  2305   {assume xy: "y \<le> x"
  2306     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2307       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2308   ultimately  show ?rhs using linear[of x y] by blast  
  2309 next
  2310   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2311   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2312   thus  ?lhs by simp
  2313 qed
  2314 
  2315 lemma div_nat_numeral [simp]:
  2316   "(numeral v :: nat) div numeral v' = nat (numeral v div numeral v')"
  2317   by (simp add: nat_div_distrib)
  2318 
  2319 lemma one_div_nat_numeral [simp]:
  2320   "Suc 0 div numeral v' = nat (1 div numeral v')"
  2321   by (subst nat_div_distrib, simp_all)
  2322 
  2323 lemma mod_nat_numeral [simp]:
  2324   "(numeral v :: nat) mod numeral v' = nat (numeral v mod numeral v')"
  2325   by (simp add: nat_mod_distrib)
  2326 
  2327 lemma one_mod_nat_numeral [simp]:
  2328   "Suc 0 mod numeral v' = nat (1 mod numeral v')"
  2329   by (subst nat_mod_distrib) simp_all
  2330 
  2331 lemma mod_2_not_eq_zero_eq_one_int:
  2332   fixes k :: int
  2333   shows "k mod 2 \<noteq> 0 \<longleftrightarrow> k mod 2 = 1"
  2334   by auto
  2335 
  2336 
  2337 subsubsection {* Tools setup *}
  2338 
  2339 text {* Nitpick *}
  2340 
  2341 lemmas [nitpick_unfold] = dvd_eq_mod_eq_0 mod_div_equality' zmod_zdiv_equality'
  2342 
  2343 
  2344 subsubsection {* Code generation *}
  2345 
  2346 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2347   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2348 
  2349 lemma pdivmod_posDivAlg [code]:
  2350   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2351 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2352 
  2353 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2354   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2355     then pdivmod k l
  2356     else (let (r, s) = pdivmod k l in
  2357        if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2358 proof -
  2359   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2360   show ?thesis
  2361     by (simp add: divmod_int_mod_div pdivmod_def)
  2362       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2363       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2364 qed
  2365 
  2366 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2367   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2368     then pdivmod k l
  2369     else (let (r, s) = pdivmod k l in
  2370       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2371 proof -
  2372   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2373     by (auto simp add: not_less sgn_if)
  2374   then show ?thesis by (simp add: divmod_int_pdivmod)
  2375 qed
  2376 
  2377 code_modulename SML
  2378   Divides Arith
  2379 
  2380 code_modulename OCaml
  2381   Divides Arith
  2382 
  2383 code_modulename Haskell
  2384   Divides Arith
  2385 
  2386 end