src/HOL/Fun.thy
author wenzelm
Wed Apr 10 21:20:35 2013 +0200 (2013-04-10)
changeset 51692 ecd34f863242
parent 51598 5dbe537087aa
child 51717 9e7d1c139569
permissions -rw-r--r--
tuned pretty layout: avoid nested Pretty.string_of, which merely happens to work with Isabelle/jEdit since formatting is delegated to Scala side;
declare command "print_case_translations" where it is actually defined;
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattices
    10 keywords "enriched_type" :: thy_goal
    11 begin
    12 
    13 lemma apply_inverse:
    14   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    15   by auto
    16 
    17 
    18 subsection {* The Identity Function @{text id} *}
    19 
    20 definition id :: "'a \<Rightarrow> 'a" where
    21   "id = (\<lambda>x. x)"
    22 
    23 lemma id_apply [simp]: "id x = x"
    24   by (simp add: id_def)
    25 
    26 lemma image_id [simp]: "image id = id"
    27   by (simp add: id_def fun_eq_iff)
    28 
    29 lemma vimage_id [simp]: "vimage id = id"
    30   by (simp add: id_def fun_eq_iff)
    31 
    32 
    33 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    34 
    35 definition comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55) where
    36   "f o g = (\<lambda>x. f (g x))"
    37 
    38 notation (xsymbols)
    39   comp  (infixl "\<circ>" 55)
    40 
    41 notation (HTML output)
    42   comp  (infixl "\<circ>" 55)
    43 
    44 lemma comp_apply [simp]: "(f o g) x = f (g x)"
    45   by (simp add: comp_def)
    46 
    47 lemma comp_assoc: "(f o g) o h = f o (g o h)"
    48   by (simp add: fun_eq_iff)
    49 
    50 lemma id_comp [simp]: "id o g = g"
    51   by (simp add: fun_eq_iff)
    52 
    53 lemma comp_id [simp]: "f o id = f"
    54   by (simp add: fun_eq_iff)
    55 
    56 lemma comp_eq_dest:
    57   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    58   by (simp add: fun_eq_iff)
    59 
    60 lemma comp_eq_elim:
    61   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    62   by (simp add: fun_eq_iff) 
    63 
    64 lemma image_comp:
    65   "(f o g) ` r = f ` (g ` r)"
    66   by auto
    67 
    68 lemma vimage_comp:
    69   "(g \<circ> f) -` x = f -` (g -` x)"
    70   by auto
    71 
    72 lemma INF_comp:
    73   "INFI A (g \<circ> f) = INFI (f ` A) g"
    74   by (simp add: INF_def image_comp)
    75 
    76 lemma SUP_comp:
    77   "SUPR A (g \<circ> f) = SUPR (f ` A) g"
    78   by (simp add: SUP_def image_comp)
    79 
    80 
    81 subsection {* The Forward Composition Operator @{text fcomp} *}
    82 
    83 definition fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60) where
    84   "f \<circ>> g = (\<lambda>x. g (f x))"
    85 
    86 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
    87   by (simp add: fcomp_def)
    88 
    89 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
    90   by (simp add: fcomp_def)
    91 
    92 lemma id_fcomp [simp]: "id \<circ>> g = g"
    93   by (simp add: fcomp_def)
    94 
    95 lemma fcomp_id [simp]: "f \<circ>> id = f"
    96   by (simp add: fcomp_def)
    97 
    98 code_const fcomp
    99   (Eval infixl 1 "#>")
   100 
   101 no_notation fcomp (infixl "\<circ>>" 60)
   102 
   103 
   104 subsection {* Mapping functions *}
   105 
   106 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   107   "map_fun f g h = g \<circ> h \<circ> f"
   108 
   109 lemma map_fun_apply [simp]:
   110   "map_fun f g h x = g (h (f x))"
   111   by (simp add: map_fun_def)
   112 
   113 
   114 subsection {* Injectivity and Bijectivity *}
   115 
   116 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   117   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   118 
   119 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   120   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   121 
   122 text{*A common special case: functions injective, surjective or bijective over
   123 the entire domain type.*}
   124 
   125 abbreviation
   126   "inj f \<equiv> inj_on f UNIV"
   127 
   128 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   129   "surj f \<equiv> (range f = UNIV)"
   130 
   131 abbreviation
   132   "bij f \<equiv> bij_betw f UNIV UNIV"
   133 
   134 text{* The negated case: *}
   135 translations
   136 "\<not> CONST surj f" <= "CONST range f \<noteq> CONST UNIV"
   137 
   138 lemma injI:
   139   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   140   shows "inj f"
   141   using assms unfolding inj_on_def by auto
   142 
   143 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   144   by (unfold inj_on_def, blast)
   145 
   146 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   147 by (simp add: inj_on_def)
   148 
   149 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   150 by (force simp add: inj_on_def)
   151 
   152 lemma inj_on_cong:
   153   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   154 unfolding inj_on_def by auto
   155 
   156 lemma inj_on_strict_subset:
   157   "\<lbrakk> inj_on f B; A < B \<rbrakk> \<Longrightarrow> f`A < f`B"
   158 unfolding inj_on_def unfolding image_def by blast
   159 
   160 lemma inj_comp:
   161   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   162   by (simp add: inj_on_def)
   163 
   164 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   165   by (simp add: inj_on_def fun_eq_iff)
   166 
   167 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   168 by (simp add: inj_on_eq_iff)
   169 
   170 lemma inj_on_id[simp]: "inj_on id A"
   171   by (simp add: inj_on_def)
   172 
   173 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   174 by (simp add: inj_on_def)
   175 
   176 lemma inj_on_Int: "inj_on f A \<or> inj_on f B \<Longrightarrow> inj_on f (A \<inter> B)"
   177 unfolding inj_on_def by blast
   178 
   179 lemma inj_on_INTER:
   180   "\<lbrakk>I \<noteq> {}; \<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)\<rbrakk> \<Longrightarrow> inj_on f (\<Inter> i \<in> I. A i)"
   181 unfolding inj_on_def by blast
   182 
   183 lemma inj_on_Inter:
   184   "\<lbrakk>S \<noteq> {}; \<And> A. A \<in> S \<Longrightarrow> inj_on f A\<rbrakk> \<Longrightarrow> inj_on f (Inter S)"
   185 unfolding inj_on_def by blast
   186 
   187 lemma inj_on_UNION_chain:
   188   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   189          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   190   shows "inj_on f (\<Union> i \<in> I. A i)"
   191 proof -
   192   {
   193     fix i j x y
   194     assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
   195       and ***: "f x = f y"
   196     have "x = y"
   197     proof -
   198       {
   199         assume "A i \<le> A j"
   200         with ** have "x \<in> A j" by auto
   201         with INJ * ** *** have ?thesis
   202         by(auto simp add: inj_on_def)
   203       }
   204       moreover
   205       {
   206         assume "A j \<le> A i"
   207         with ** have "y \<in> A i" by auto
   208         with INJ * ** *** have ?thesis
   209         by(auto simp add: inj_on_def)
   210       }
   211       ultimately show ?thesis using CH * by blast
   212     qed
   213   }
   214   then show ?thesis by (unfold inj_on_def UNION_eq) auto
   215 qed
   216 
   217 lemma surj_id: "surj id"
   218 by simp
   219 
   220 lemma bij_id[simp]: "bij id"
   221 by (simp add: bij_betw_def)
   222 
   223 lemma inj_onI:
   224     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   225 by (simp add: inj_on_def)
   226 
   227 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   228 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   229 
   230 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   231 by (unfold inj_on_def, blast)
   232 
   233 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   234 by (blast dest!: inj_onD)
   235 
   236 lemma comp_inj_on:
   237      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   238 by (simp add: comp_def inj_on_def)
   239 
   240 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   241 apply(simp add:inj_on_def image_def)
   242 apply blast
   243 done
   244 
   245 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   246   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   247 apply(unfold inj_on_def)
   248 apply blast
   249 done
   250 
   251 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   252 by (unfold inj_on_def, blast)
   253 
   254 lemma inj_singleton: "inj (%s. {s})"
   255 by (simp add: inj_on_def)
   256 
   257 lemma inj_on_empty[iff]: "inj_on f {}"
   258 by(simp add: inj_on_def)
   259 
   260 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   261 by (unfold inj_on_def, blast)
   262 
   263 lemma inj_on_Un:
   264  "inj_on f (A Un B) =
   265   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   266 apply(unfold inj_on_def)
   267 apply (blast intro:sym)
   268 done
   269 
   270 lemma inj_on_insert[iff]:
   271   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   272 apply(unfold inj_on_def)
   273 apply (blast intro:sym)
   274 done
   275 
   276 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   277 apply(unfold inj_on_def)
   278 apply (blast)
   279 done
   280 
   281 lemma comp_inj_on_iff:
   282   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   283 by(auto simp add: comp_inj_on inj_on_def)
   284 
   285 lemma inj_on_imageI2:
   286   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   287 by(auto simp add: comp_inj_on inj_on_def)
   288 
   289 lemma inj_img_insertE:
   290   assumes "inj_on f A"
   291   assumes "x \<notin> B" and "insert x B = f ` A"
   292   obtains x' A' where "x' \<notin> A'" and "A = insert x' A'"
   293     and "x = f x'" and "B = f ` A'" 
   294 proof -
   295   from assms have "x \<in> f ` A" by auto
   296   then obtain x' where *: "x' \<in> A" "x = f x'" by auto
   297   then have "A = insert x' (A - {x'})" by auto
   298   with assms * have "B = f ` (A - {x'})"
   299     by (auto dest: inj_on_contraD)
   300   have "x' \<notin> A - {x'}" by simp
   301   from `x' \<notin> A - {x'}` `A = insert x' (A - {x'})` `x = f x'` `B = image f (A - {x'})`
   302   show ?thesis ..
   303 qed
   304 
   305 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   306   by auto
   307 
   308 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   309   using *[symmetric] by auto
   310 
   311 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   312   by (simp add: surj_def)
   313 
   314 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   315   by (simp add: surj_def, blast)
   316 
   317 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   318 apply (simp add: comp_def surj_def, clarify)
   319 apply (drule_tac x = y in spec, clarify)
   320 apply (drule_tac x = x in spec, blast)
   321 done
   322 
   323 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   324   unfolding bij_betw_def by auto
   325 
   326 lemma bij_betw_empty1:
   327   assumes "bij_betw f {} A"
   328   shows "A = {}"
   329 using assms unfolding bij_betw_def by blast
   330 
   331 lemma bij_betw_empty2:
   332   assumes "bij_betw f A {}"
   333   shows "A = {}"
   334 using assms unfolding bij_betw_def by blast
   335 
   336 lemma inj_on_imp_bij_betw:
   337   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   338 unfolding bij_betw_def by simp
   339 
   340 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   341   unfolding bij_betw_def ..
   342 
   343 lemma bijI: "[| inj f; surj f |] ==> bij f"
   344 by (simp add: bij_def)
   345 
   346 lemma bij_is_inj: "bij f ==> inj f"
   347 by (simp add: bij_def)
   348 
   349 lemma bij_is_surj: "bij f ==> surj f"
   350 by (simp add: bij_def)
   351 
   352 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   353 by (simp add: bij_betw_def)
   354 
   355 lemma bij_betw_trans:
   356   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   357 by(auto simp add:bij_betw_def comp_inj_on)
   358 
   359 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   360   by (rule bij_betw_trans)
   361 
   362 lemma bij_betw_comp_iff:
   363   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   364 by(auto simp add: bij_betw_def inj_on_def)
   365 
   366 lemma bij_betw_comp_iff2:
   367   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   368   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   369 using assms
   370 proof(auto simp add: bij_betw_comp_iff)
   371   assume *: "bij_betw (f' \<circ> f) A A''"
   372   thus "bij_betw f A A'"
   373   using IM
   374   proof(auto simp add: bij_betw_def)
   375     assume "inj_on (f' \<circ> f) A"
   376     thus "inj_on f A" using inj_on_imageI2 by blast
   377   next
   378     fix a' assume **: "a' \<in> A'"
   379     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   380     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   381     unfolding bij_betw_def by force
   382     hence "f a \<in> A'" using IM by auto
   383     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   384     thus "a' \<in> f ` A" using 1 by auto
   385   qed
   386 qed
   387 
   388 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   389 proof -
   390   have i: "inj_on f A" and s: "f ` A = B"
   391     using assms by(auto simp:bij_betw_def)
   392   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   393   { fix a b assume P: "?P b a"
   394     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   395     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   396     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   397   } note g = this
   398   have "inj_on ?g B"
   399   proof(rule inj_onI)
   400     fix x y assume "x:B" "y:B" "?g x = ?g y"
   401     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   402     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   403     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   404   qed
   405   moreover have "?g ` B = A"
   406   proof(auto simp:image_def)
   407     fix b assume "b:B"
   408     with s obtain a where P: "?P b a" unfolding image_def by blast
   409     thus "?g b \<in> A" using g[OF P] by auto
   410   next
   411     fix a assume "a:A"
   412     then obtain b where P: "?P b a" using s unfolding image_def by blast
   413     then have "b:B" using s unfolding image_def by blast
   414     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   415   qed
   416   ultimately show ?thesis by(auto simp:bij_betw_def)
   417 qed
   418 
   419 lemma bij_betw_cong:
   420   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   421 unfolding bij_betw_def inj_on_def by force
   422 
   423 lemma bij_betw_id[intro, simp]:
   424   "bij_betw id A A"
   425 unfolding bij_betw_def id_def by auto
   426 
   427 lemma bij_betw_id_iff:
   428   "bij_betw id A B \<longleftrightarrow> A = B"
   429 by(auto simp add: bij_betw_def)
   430 
   431 lemma bij_betw_combine:
   432   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   433   shows "bij_betw f (A \<union> C) (B \<union> D)"
   434   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   435 
   436 lemma bij_betw_UNION_chain:
   437   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   438          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
   439   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
   440 proof (unfold bij_betw_def, auto)
   441   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   442   using BIJ bij_betw_def[of f] by auto
   443   thus "inj_on f (\<Union> i \<in> I. A i)"
   444   using CH inj_on_UNION_chain[of I A f] by auto
   445 next
   446   fix i x
   447   assume *: "i \<in> I" "x \<in> A i"
   448   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
   449   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
   450 next
   451   fix i x'
   452   assume *: "i \<in> I" "x' \<in> A' i"
   453   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
   454   then have "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
   455     using * by blast
   456   then show "x' \<in> f ` (\<Union>x\<in>I. A x)" by (simp add: image_def)
   457 qed
   458 
   459 lemma bij_betw_subset:
   460   assumes BIJ: "bij_betw f A A'" and
   461           SUB: "B \<le> A" and IM: "f ` B = B'"
   462   shows "bij_betw f B B'"
   463 using assms
   464 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   465 
   466 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   467 by simp
   468 
   469 lemma surj_vimage_empty:
   470   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   471   using surj_image_vimage_eq[OF `surj f`, of A]
   472   by (intro iffI) fastforce+
   473 
   474 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   475 by (simp add: inj_on_def, blast)
   476 
   477 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   478 by (blast intro: sym)
   479 
   480 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   481 by (unfold inj_on_def, blast)
   482 
   483 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   484 apply (unfold bij_def)
   485 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   486 done
   487 
   488 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   489 by(blast dest: inj_onD)
   490 
   491 lemma inj_on_image_Int:
   492    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   493 apply (simp add: inj_on_def, blast)
   494 done
   495 
   496 lemma inj_on_image_set_diff:
   497    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   498 apply (simp add: inj_on_def, blast)
   499 done
   500 
   501 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   502 by (simp add: inj_on_def, blast)
   503 
   504 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   505 by (simp add: inj_on_def, blast)
   506 
   507 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   508 by (blast dest: injD)
   509 
   510 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   511 by (simp add: inj_on_def, blast)
   512 
   513 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   514 by (blast dest: injD)
   515 
   516 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   517 lemma image_INT:
   518    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   519     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   520 apply (simp add: inj_on_def, blast)
   521 done
   522 
   523 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   524   it doesn't matter whether A is empty*)
   525 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   526 apply (simp add: bij_def)
   527 apply (simp add: inj_on_def surj_def, blast)
   528 done
   529 
   530 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   531 by auto
   532 
   533 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   534 by (auto simp add: inj_on_def)
   535 
   536 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   537 apply (simp add: bij_def)
   538 apply (rule equalityI)
   539 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   540 done
   541 
   542 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   543   -- {* The inverse image of a singleton under an injective function
   544          is included in a singleton. *}
   545   apply (auto simp add: inj_on_def)
   546   apply (blast intro: the_equality [symmetric])
   547   done
   548 
   549 lemma inj_on_vimage_singleton:
   550   "inj_on f A \<Longrightarrow> f -` {a} \<inter> A \<subseteq> {THE x. x \<in> A \<and> f x = a}"
   551   by (auto simp add: inj_on_def intro: the_equality [symmetric])
   552 
   553 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   554   by (auto intro!: inj_onI)
   555 
   556 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   557   by (auto intro!: inj_onI dest: strict_mono_eq)
   558 
   559 
   560 subsection{*Function Updating*}
   561 
   562 definition fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   563   "fun_upd f a b == % x. if x=a then b else f x"
   564 
   565 nonterminal updbinds and updbind
   566 
   567 syntax
   568   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   569   ""         :: "updbind => updbinds"             ("_")
   570   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   571   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   572 
   573 translations
   574   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   575   "f(x:=y)" == "CONST fun_upd f x y"
   576 
   577 (* Hint: to define the sum of two functions (or maps), use sum_case.
   578          A nice infix syntax could be defined (in Datatype.thy or below) by
   579 notation
   580   sum_case  (infixr "'(+')"80)
   581 *)
   582 
   583 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   584 apply (simp add: fun_upd_def, safe)
   585 apply (erule subst)
   586 apply (rule_tac [2] ext, auto)
   587 done
   588 
   589 lemma fun_upd_idem: "f x = y ==> f(x:=y) = f"
   590   by (simp only: fun_upd_idem_iff)
   591 
   592 lemma fun_upd_triv [iff]: "f(x := f x) = f"
   593   by (simp only: fun_upd_idem)
   594 
   595 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   596 by (simp add: fun_upd_def)
   597 
   598 (* fun_upd_apply supersedes these two,   but they are useful
   599    if fun_upd_apply is intentionally removed from the simpset *)
   600 lemma fun_upd_same: "(f(x:=y)) x = y"
   601 by simp
   602 
   603 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   604 by simp
   605 
   606 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   607 by (simp add: fun_eq_iff)
   608 
   609 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   610 by (rule ext, auto)
   611 
   612 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   613 by (fastforce simp:inj_on_def image_def)
   614 
   615 lemma fun_upd_image:
   616      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   617 by auto
   618 
   619 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   620   by auto
   621 
   622 lemma UNION_fun_upd:
   623   "UNION J (A(i:=B)) = (UNION (J-{i}) A \<union> (if i\<in>J then B else {}))"
   624 by (auto split: if_splits)
   625 
   626 
   627 subsection {* @{text override_on} *}
   628 
   629 definition override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b" where
   630   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   631 
   632 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   633 by(simp add:override_on_def)
   634 
   635 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   636 by(simp add:override_on_def)
   637 
   638 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   639 by(simp add:override_on_def)
   640 
   641 
   642 subsection {* @{text swap} *}
   643 
   644 definition swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)" where
   645   "swap a b f = f (a := f b, b:= f a)"
   646 
   647 lemma swap_self [simp]: "swap a a f = f"
   648 by (simp add: swap_def)
   649 
   650 lemma swap_commute: "swap a b f = swap b a f"
   651 by (rule ext, simp add: fun_upd_def swap_def)
   652 
   653 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   654 by (rule ext, simp add: fun_upd_def swap_def)
   655 
   656 lemma swap_triple:
   657   assumes "a \<noteq> c" and "b \<noteq> c"
   658   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   659   using assms by (simp add: fun_eq_iff swap_def)
   660 
   661 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   662 by (rule ext, simp add: fun_upd_def swap_def)
   663 
   664 lemma swap_image_eq [simp]:
   665   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   666 proof -
   667   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   668     using assms by (auto simp: image_iff swap_def)
   669   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   670   with subset[of f] show ?thesis by auto
   671 qed
   672 
   673 lemma inj_on_imp_inj_on_swap:
   674   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   675   by (simp add: inj_on_def swap_def, blast)
   676 
   677 lemma inj_on_swap_iff [simp]:
   678   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   679 proof
   680   assume "inj_on (swap a b f) A"
   681   with A have "inj_on (swap a b (swap a b f)) A"
   682     by (iprover intro: inj_on_imp_inj_on_swap)
   683   thus "inj_on f A" by simp
   684 next
   685   assume "inj_on f A"
   686   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   687 qed
   688 
   689 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   690   by simp
   691 
   692 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   693   by simp
   694 
   695 lemma bij_betw_swap_iff [simp]:
   696   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   697   by (auto simp: bij_betw_def)
   698 
   699 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   700   by simp
   701 
   702 hide_const (open) swap
   703 
   704 subsection {* Inversion of injective functions *}
   705 
   706 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   707   "the_inv_into A f == %x. THE y. y : A & f y = x"
   708 
   709 lemma the_inv_into_f_f:
   710   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   711 apply (simp add: the_inv_into_def inj_on_def)
   712 apply blast
   713 done
   714 
   715 lemma f_the_inv_into_f:
   716   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   717 apply (simp add: the_inv_into_def)
   718 apply (rule the1I2)
   719  apply(blast dest: inj_onD)
   720 apply blast
   721 done
   722 
   723 lemma the_inv_into_into:
   724   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   725 apply (simp add: the_inv_into_def)
   726 apply (rule the1I2)
   727  apply(blast dest: inj_onD)
   728 apply blast
   729 done
   730 
   731 lemma the_inv_into_onto[simp]:
   732   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   733 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   734 
   735 lemma the_inv_into_f_eq:
   736   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   737   apply (erule subst)
   738   apply (erule the_inv_into_f_f, assumption)
   739   done
   740 
   741 lemma the_inv_into_comp:
   742   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   743   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   744 apply (rule the_inv_into_f_eq)
   745   apply (fast intro: comp_inj_on)
   746  apply (simp add: f_the_inv_into_f the_inv_into_into)
   747 apply (simp add: the_inv_into_into)
   748 done
   749 
   750 lemma inj_on_the_inv_into:
   751   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   752 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   753 
   754 lemma bij_betw_the_inv_into:
   755   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   756 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   757 
   758 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   759   "the_inv f \<equiv> the_inv_into UNIV f"
   760 
   761 lemma the_inv_f_f:
   762   assumes "inj f"
   763   shows "the_inv f (f x) = x" using assms UNIV_I
   764   by (rule the_inv_into_f_f)
   765 
   766 
   767 subsection {* Cantor's Paradox *}
   768 
   769 lemma Cantors_paradox [no_atp]:
   770   "\<not>(\<exists>f. f ` A = Pow A)"
   771 proof clarify
   772   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   773   let ?X = "{a \<in> A. a \<notin> f a}"
   774   have "?X \<in> Pow A" unfolding Pow_def by auto
   775   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   776   thus False by best
   777 qed
   778 
   779 subsection {* Setup *} 
   780 
   781 subsubsection {* Proof tools *}
   782 
   783 text {* simplifies terms of the form
   784   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   785 
   786 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   787 let
   788   fun gen_fun_upd NONE T _ _ = NONE
   789     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   790   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   791   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   792     let
   793       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   794             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   795         | find t = NONE
   796     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   797 
   798   fun proc ss ct =
   799     let
   800       val ctxt = Simplifier.the_context ss
   801       val t = Thm.term_of ct
   802     in
   803       case find_double t of
   804         (T, NONE) => NONE
   805       | (T, SOME rhs) =>
   806           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   807             (fn _ =>
   808               rtac eq_reflection 1 THEN
   809               rtac ext 1 THEN
   810               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   811     end
   812 in proc end
   813 *}
   814 
   815 
   816 subsubsection {* Code generator *}
   817 
   818 code_const "op \<circ>"
   819   (SML infixl 5 "o")
   820   (Haskell infixr 9 ".")
   821 
   822 code_const "id"
   823   (Haskell "id")
   824 
   825 
   826 subsubsection {* Functorial structure of types *}
   827 
   828 ML_file "Tools/enriched_type.ML"
   829 
   830 enriched_type map_fun: map_fun
   831   by (simp_all add: fun_eq_iff)
   832 
   833 enriched_type vimage
   834   by (simp_all add: fun_eq_iff vimage_comp)
   835 
   836 text {* Legacy theorem names *}
   837 
   838 lemmas o_def = comp_def
   839 lemmas o_apply = comp_apply
   840 lemmas o_assoc = comp_assoc [symmetric]
   841 lemmas id_o = id_comp
   842 lemmas o_id = comp_id
   843 lemmas o_eq_dest = comp_eq_dest
   844 lemmas o_eq_elim = comp_eq_elim
   845 lemmas image_compose = image_comp
   846 lemmas vimage_compose = vimage_comp
   847 
   848 end
   849