src/HOL/Limits.thy
author wenzelm
Wed Apr 10 21:20:35 2013 +0200 (2013-04-10)
changeset 51692 ecd34f863242
parent 51642 400ec5ae7f8f
child 52265 bb907eba5902
permissions -rw-r--r--
tuned pretty layout: avoid nested Pretty.string_of, which merely happens to work with Isabelle/jEdit since formatting is delegated to Scala side;
declare command "print_case_translations" where it is actually defined;
     1 (*  Title:      Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 
     7 *)
     8 
     9 header {* Limits on Real Vector Spaces *}
    10 
    11 theory Limits
    12 imports Real_Vector_Spaces
    13 begin
    14 
    15 subsection {* Filter going to infinity norm *}
    16 
    17 definition at_infinity :: "'a::real_normed_vector filter" where
    18   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
    19 
    20 lemma eventually_at_infinity:
    21   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    22 unfolding at_infinity_def
    23 proof (rule eventually_Abs_filter, rule is_filter.intro)
    24   fix P Q :: "'a \<Rightarrow> bool"
    25   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
    26   then obtain r s where
    27     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
    28   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
    29   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
    30 qed auto
    31 
    32 lemma at_infinity_eq_at_top_bot:
    33   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
    34   unfolding sup_filter_def at_infinity_def eventually_at_top_linorder eventually_at_bot_linorder
    35 proof (intro arg_cong[where f=Abs_filter] ext iffI)
    36   fix P :: "real \<Rightarrow> bool" assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    37   then guess r ..
    38   then have "(\<forall>x\<ge>r. P x) \<and> (\<forall>x\<le>-r. P x)" by auto
    39   then show "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)" by auto
    40 next
    41   fix P :: "real \<Rightarrow> bool" assume "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)"
    42   then obtain p q where "\<forall>x\<ge>p. P x" "\<forall>x\<le>q. P x" by auto
    43   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    44     by (intro exI[of _ "max p (-q)"])
    45        (auto simp: abs_real_def)
    46 qed
    47 
    48 lemma at_top_le_at_infinity:
    49   "at_top \<le> (at_infinity :: real filter)"
    50   unfolding at_infinity_eq_at_top_bot by simp
    51 
    52 lemma at_bot_le_at_infinity:
    53   "at_bot \<le> (at_infinity :: real filter)"
    54   unfolding at_infinity_eq_at_top_bot by simp
    55 
    56 subsubsection {* Boundedness *}
    57 
    58 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    59   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    60 
    61 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    62   "Bseq X \<equiv> Bfun X sequentially"
    63 
    64 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    65 
    66 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    67   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    68 
    69 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    70   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    71 
    72 lemma Bfun_def:
    73   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    74   unfolding Bfun_metric_def norm_conv_dist
    75 proof safe
    76   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    77   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    78     by (intro always_eventually) (metis dist_commute dist_triangle)
    79   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    80     by eventually_elim auto
    81   with `0 < K` show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    82     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    83 qed auto
    84 
    85 lemma BfunI:
    86   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    87 unfolding Bfun_def
    88 proof (intro exI conjI allI)
    89   show "0 < max K 1" by simp
    90 next
    91   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    92     using K by (rule eventually_elim1, simp)
    93 qed
    94 
    95 lemma BfunE:
    96   assumes "Bfun f F"
    97   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    98 using assms unfolding Bfun_def by fast
    99 
   100 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
   101   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
   102   apply (erule_tac x=1 in allE)
   103   apply simp
   104   apply safe
   105   apply (rule_tac x="X M" in exI)
   106   apply (rule_tac x=1 in exI)
   107   apply (erule_tac x=M in allE)
   108   apply simp
   109   apply (rule_tac x=M in exI)
   110   apply (auto simp: dist_commute)
   111   done
   112 
   113 
   114 subsubsection {* Bounded Sequences *}
   115 
   116 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   117   by (intro BfunI) (auto simp: eventually_sequentially)
   118 
   119 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   120   by (intro BfunI) (auto simp: eventually_sequentially)
   121 
   122 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   123   unfolding Bfun_def eventually_sequentially
   124 proof safe
   125   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   126   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   127     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] min_max.less_supI2)
   128        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   129 qed auto
   130 
   131 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   132 unfolding Bseq_def by auto
   133 
   134 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   135 by (simp add: Bseq_def)
   136 
   137 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   138 by (auto simp add: Bseq_def)
   139 
   140 lemma lemma_NBseq_def:
   141   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   142 proof safe
   143   fix K :: real
   144   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   145   then have "K \<le> real (Suc n)" by auto
   146   moreover assume "\<forall>m. norm (X m) \<le> K"
   147   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   148     by (blast intro: order_trans)
   149   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   150 qed (force simp add: real_of_nat_Suc)
   151 
   152 text{* alternative definition for Bseq *}
   153 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   154 apply (simp add: Bseq_def)
   155 apply (simp (no_asm) add: lemma_NBseq_def)
   156 done
   157 
   158 lemma lemma_NBseq_def2:
   159      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   160 apply (subst lemma_NBseq_def, auto)
   161 apply (rule_tac x = "Suc N" in exI)
   162 apply (rule_tac [2] x = N in exI)
   163 apply (auto simp add: real_of_nat_Suc)
   164  prefer 2 apply (blast intro: order_less_imp_le)
   165 apply (drule_tac x = n in spec, simp)
   166 done
   167 
   168 (* yet another definition for Bseq *)
   169 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   170 by (simp add: Bseq_def lemma_NBseq_def2)
   171 
   172 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   173 
   174 text{*alternative formulation for boundedness*}
   175 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   176 apply (unfold Bseq_def, safe)
   177 apply (rule_tac [2] x = "k + norm x" in exI)
   178 apply (rule_tac x = K in exI, simp)
   179 apply (rule exI [where x = 0], auto)
   180 apply (erule order_less_le_trans, simp)
   181 apply (drule_tac x=n in spec, fold diff_minus)
   182 apply (drule order_trans [OF norm_triangle_ineq2])
   183 apply simp
   184 done
   185 
   186 text{*alternative formulation for boundedness*}
   187 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
   188 apply safe
   189 apply (simp add: Bseq_def, safe)
   190 apply (rule_tac x = "K + norm (X N)" in exI)
   191 apply auto
   192 apply (erule order_less_le_trans, simp)
   193 apply (rule_tac x = N in exI, safe)
   194 apply (drule_tac x = n in spec)
   195 apply (rule order_trans [OF norm_triangle_ineq], simp)
   196 apply (auto simp add: Bseq_iff2)
   197 done
   198 
   199 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   200 apply (simp add: Bseq_def)
   201 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   202 apply (drule_tac x = n in spec, arith)
   203 done
   204 
   205 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   206 
   207 lemma Bseq_isUb:
   208   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   209 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   210 
   211 text{* Use completeness of reals (supremum property)
   212    to show that any bounded sequence has a least upper bound*}
   213 
   214 lemma Bseq_isLub:
   215   "!!(X::nat=>real). Bseq X ==>
   216    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   217 by (blast intro: reals_complete Bseq_isUb)
   218 
   219 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   220   by (simp add: Bseq_def)
   221 
   222 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   223   apply (simp add: subset_eq)
   224   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   225   apply (erule_tac x=n in allE)
   226   apply auto
   227   done
   228 
   229 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   230   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   231 
   232 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   233   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   234 
   235 subsection {* Bounded Monotonic Sequences *}
   236 
   237 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   238 
   239 (* TODO: delete *)
   240 (* FIXME: one use in NSA/HSEQ.thy *)
   241 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   242   apply (rule_tac x="X m" in exI)
   243   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   244   unfolding eventually_sequentially
   245   apply blast
   246   done
   247 
   248 subsection {* Convergence to Zero *}
   249 
   250 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   251   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   252 
   253 lemma ZfunI:
   254   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   255   unfolding Zfun_def by simp
   256 
   257 lemma ZfunD:
   258   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   259   unfolding Zfun_def by simp
   260 
   261 lemma Zfun_ssubst:
   262   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   263   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   264 
   265 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   266   unfolding Zfun_def by simp
   267 
   268 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   269   unfolding Zfun_def by simp
   270 
   271 lemma Zfun_imp_Zfun:
   272   assumes f: "Zfun f F"
   273   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   274   shows "Zfun (\<lambda>x. g x) F"
   275 proof (cases)
   276   assume K: "0 < K"
   277   show ?thesis
   278   proof (rule ZfunI)
   279     fix r::real assume "0 < r"
   280     hence "0 < r / K"
   281       using K by (rule divide_pos_pos)
   282     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   283       using ZfunD [OF f] by fast
   284     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   285     proof eventually_elim
   286       case (elim x)
   287       hence "norm (f x) * K < r"
   288         by (simp add: pos_less_divide_eq K)
   289       thus ?case
   290         by (simp add: order_le_less_trans [OF elim(1)])
   291     qed
   292   qed
   293 next
   294   assume "\<not> 0 < K"
   295   hence K: "K \<le> 0" by (simp only: not_less)
   296   show ?thesis
   297   proof (rule ZfunI)
   298     fix r :: real
   299     assume "0 < r"
   300     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   301     proof eventually_elim
   302       case (elim x)
   303       also have "norm (f x) * K \<le> norm (f x) * 0"
   304         using K norm_ge_zero by (rule mult_left_mono)
   305       finally show ?case
   306         using `0 < r` by simp
   307     qed
   308   qed
   309 qed
   310 
   311 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   312   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   313 
   314 lemma Zfun_add:
   315   assumes f: "Zfun f F" and g: "Zfun g F"
   316   shows "Zfun (\<lambda>x. f x + g x) F"
   317 proof (rule ZfunI)
   318   fix r::real assume "0 < r"
   319   hence r: "0 < r / 2" by simp
   320   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   321     using f r by (rule ZfunD)
   322   moreover
   323   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   324     using g r by (rule ZfunD)
   325   ultimately
   326   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   327   proof eventually_elim
   328     case (elim x)
   329     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   330       by (rule norm_triangle_ineq)
   331     also have "\<dots> < r/2 + r/2"
   332       using elim by (rule add_strict_mono)
   333     finally show ?case
   334       by simp
   335   qed
   336 qed
   337 
   338 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   339   unfolding Zfun_def by simp
   340 
   341 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   342   by (simp only: diff_minus Zfun_add Zfun_minus)
   343 
   344 lemma (in bounded_linear) Zfun:
   345   assumes g: "Zfun g F"
   346   shows "Zfun (\<lambda>x. f (g x)) F"
   347 proof -
   348   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   349     using bounded by fast
   350   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   351     by simp
   352   with g show ?thesis
   353     by (rule Zfun_imp_Zfun)
   354 qed
   355 
   356 lemma (in bounded_bilinear) Zfun:
   357   assumes f: "Zfun f F"
   358   assumes g: "Zfun g F"
   359   shows "Zfun (\<lambda>x. f x ** g x) F"
   360 proof (rule ZfunI)
   361   fix r::real assume r: "0 < r"
   362   obtain K where K: "0 < K"
   363     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   364     using pos_bounded by fast
   365   from K have K': "0 < inverse K"
   366     by (rule positive_imp_inverse_positive)
   367   have "eventually (\<lambda>x. norm (f x) < r) F"
   368     using f r by (rule ZfunD)
   369   moreover
   370   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   371     using g K' by (rule ZfunD)
   372   ultimately
   373   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   374   proof eventually_elim
   375     case (elim x)
   376     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   377       by (rule norm_le)
   378     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   379       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   380     also from K have "r * inverse K * K = r"
   381       by simp
   382     finally show ?case .
   383   qed
   384 qed
   385 
   386 lemma (in bounded_bilinear) Zfun_left:
   387   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   388   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   389 
   390 lemma (in bounded_bilinear) Zfun_right:
   391   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   392   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   393 
   394 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   395 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   396 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   397 
   398 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   399   by (simp only: tendsto_iff Zfun_def dist_norm)
   400 
   401 subsubsection {* Distance and norms *}
   402 
   403 lemma tendsto_dist [tendsto_intros]:
   404   fixes l m :: "'a :: metric_space"
   405   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   406   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   407 proof (rule tendstoI)
   408   fix e :: real assume "0 < e"
   409   hence e2: "0 < e/2" by simp
   410   from tendstoD [OF f e2] tendstoD [OF g e2]
   411   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   412   proof (eventually_elim)
   413     case (elim x)
   414     then show "dist (dist (f x) (g x)) (dist l m) < e"
   415       unfolding dist_real_def
   416       using dist_triangle2 [of "f x" "g x" "l"]
   417       using dist_triangle2 [of "g x" "l" "m"]
   418       using dist_triangle3 [of "l" "m" "f x"]
   419       using dist_triangle [of "f x" "m" "g x"]
   420       by arith
   421   qed
   422 qed
   423 
   424 lemma continuous_dist[continuous_intros]:
   425   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   426   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   427   unfolding continuous_def by (rule tendsto_dist)
   428 
   429 lemma continuous_on_dist[continuous_on_intros]:
   430   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   431   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   432   unfolding continuous_on_def by (auto intro: tendsto_dist)
   433 
   434 lemma tendsto_norm [tendsto_intros]:
   435   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   436   unfolding norm_conv_dist by (intro tendsto_intros)
   437 
   438 lemma continuous_norm [continuous_intros]:
   439   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   440   unfolding continuous_def by (rule tendsto_norm)
   441 
   442 lemma continuous_on_norm [continuous_on_intros]:
   443   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   444   unfolding continuous_on_def by (auto intro: tendsto_norm)
   445 
   446 lemma tendsto_norm_zero:
   447   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   448   by (drule tendsto_norm, simp)
   449 
   450 lemma tendsto_norm_zero_cancel:
   451   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   452   unfolding tendsto_iff dist_norm by simp
   453 
   454 lemma tendsto_norm_zero_iff:
   455   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   456   unfolding tendsto_iff dist_norm by simp
   457 
   458 lemma tendsto_rabs [tendsto_intros]:
   459   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   460   by (fold real_norm_def, rule tendsto_norm)
   461 
   462 lemma continuous_rabs [continuous_intros]:
   463   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   464   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   465 
   466 lemma continuous_on_rabs [continuous_on_intros]:
   467   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   468   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   469 
   470 lemma tendsto_rabs_zero:
   471   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   472   by (fold real_norm_def, rule tendsto_norm_zero)
   473 
   474 lemma tendsto_rabs_zero_cancel:
   475   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   476   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   477 
   478 lemma tendsto_rabs_zero_iff:
   479   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   480   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   481 
   482 subsubsection {* Addition and subtraction *}
   483 
   484 lemma tendsto_add [tendsto_intros]:
   485   fixes a b :: "'a::real_normed_vector"
   486   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   487   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   488 
   489 lemma continuous_add [continuous_intros]:
   490   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   491   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   492   unfolding continuous_def by (rule tendsto_add)
   493 
   494 lemma continuous_on_add [continuous_on_intros]:
   495   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   496   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   497   unfolding continuous_on_def by (auto intro: tendsto_add)
   498 
   499 lemma tendsto_add_zero:
   500   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   501   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   502   by (drule (1) tendsto_add, simp)
   503 
   504 lemma tendsto_minus [tendsto_intros]:
   505   fixes a :: "'a::real_normed_vector"
   506   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   507   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   508 
   509 lemma continuous_minus [continuous_intros]:
   510   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   511   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   512   unfolding continuous_def by (rule tendsto_minus)
   513 
   514 lemma continuous_on_minus [continuous_on_intros]:
   515   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   516   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   517   unfolding continuous_on_def by (auto intro: tendsto_minus)
   518 
   519 lemma tendsto_minus_cancel:
   520   fixes a :: "'a::real_normed_vector"
   521   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   522   by (drule tendsto_minus, simp)
   523 
   524 lemma tendsto_minus_cancel_left:
   525     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   526   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   527   by auto
   528 
   529 lemma tendsto_diff [tendsto_intros]:
   530   fixes a b :: "'a::real_normed_vector"
   531   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   532   by (simp add: diff_minus tendsto_add tendsto_minus)
   533 
   534 lemma continuous_diff [continuous_intros]:
   535   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   536   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   537   unfolding continuous_def by (rule tendsto_diff)
   538 
   539 lemma continuous_on_diff [continuous_on_intros]:
   540   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   541   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   542   unfolding continuous_on_def by (auto intro: tendsto_diff)
   543 
   544 lemma tendsto_setsum [tendsto_intros]:
   545   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   546   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   547   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   548 proof (cases "finite S")
   549   assume "finite S" thus ?thesis using assms
   550     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   551 next
   552   assume "\<not> finite S" thus ?thesis
   553     by (simp add: tendsto_const)
   554 qed
   555 
   556 lemma continuous_setsum [continuous_intros]:
   557   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   558   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   559   unfolding continuous_def by (rule tendsto_setsum)
   560 
   561 lemma continuous_on_setsum [continuous_intros]:
   562   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   563   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   564   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   565 
   566 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   567 
   568 subsubsection {* Linear operators and multiplication *}
   569 
   570 lemma (in bounded_linear) tendsto:
   571   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   572   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   573 
   574 lemma (in bounded_linear) continuous:
   575   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   576   using tendsto[of g _ F] by (auto simp: continuous_def)
   577 
   578 lemma (in bounded_linear) continuous_on:
   579   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   580   using tendsto[of g] by (auto simp: continuous_on_def)
   581 
   582 lemma (in bounded_linear) tendsto_zero:
   583   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   584   by (drule tendsto, simp only: zero)
   585 
   586 lemma (in bounded_bilinear) tendsto:
   587   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   588   by (simp only: tendsto_Zfun_iff prod_diff_prod
   589                  Zfun_add Zfun Zfun_left Zfun_right)
   590 
   591 lemma (in bounded_bilinear) continuous:
   592   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   593   using tendsto[of f _ F g] by (auto simp: continuous_def)
   594 
   595 lemma (in bounded_bilinear) continuous_on:
   596   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   597   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   598 
   599 lemma (in bounded_bilinear) tendsto_zero:
   600   assumes f: "(f ---> 0) F"
   601   assumes g: "(g ---> 0) F"
   602   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   603   using tendsto [OF f g] by (simp add: zero_left)
   604 
   605 lemma (in bounded_bilinear) tendsto_left_zero:
   606   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   607   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   608 
   609 lemma (in bounded_bilinear) tendsto_right_zero:
   610   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   611   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   612 
   613 lemmas tendsto_of_real [tendsto_intros] =
   614   bounded_linear.tendsto [OF bounded_linear_of_real]
   615 
   616 lemmas tendsto_scaleR [tendsto_intros] =
   617   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   618 
   619 lemmas tendsto_mult [tendsto_intros] =
   620   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   621 
   622 lemmas continuous_of_real [continuous_intros] =
   623   bounded_linear.continuous [OF bounded_linear_of_real]
   624 
   625 lemmas continuous_scaleR [continuous_intros] =
   626   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   627 
   628 lemmas continuous_mult [continuous_intros] =
   629   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   630 
   631 lemmas continuous_on_of_real [continuous_on_intros] =
   632   bounded_linear.continuous_on [OF bounded_linear_of_real]
   633 
   634 lemmas continuous_on_scaleR [continuous_on_intros] =
   635   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   636 
   637 lemmas continuous_on_mult [continuous_on_intros] =
   638   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   639 
   640 lemmas tendsto_mult_zero =
   641   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   642 
   643 lemmas tendsto_mult_left_zero =
   644   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   645 
   646 lemmas tendsto_mult_right_zero =
   647   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   648 
   649 lemma tendsto_power [tendsto_intros]:
   650   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   651   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   652   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   653 
   654 lemma continuous_power [continuous_intros]:
   655   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   656   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   657   unfolding continuous_def by (rule tendsto_power)
   658 
   659 lemma continuous_on_power [continuous_on_intros]:
   660   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   661   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   662   unfolding continuous_on_def by (auto intro: tendsto_power)
   663 
   664 lemma tendsto_setprod [tendsto_intros]:
   665   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   666   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   667   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   668 proof (cases "finite S")
   669   assume "finite S" thus ?thesis using assms
   670     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   671 next
   672   assume "\<not> finite S" thus ?thesis
   673     by (simp add: tendsto_const)
   674 qed
   675 
   676 lemma continuous_setprod [continuous_intros]:
   677   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   678   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   679   unfolding continuous_def by (rule tendsto_setprod)
   680 
   681 lemma continuous_on_setprod [continuous_intros]:
   682   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   683   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   684   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   685 
   686 subsubsection {* Inverse and division *}
   687 
   688 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   689   assumes f: "Zfun f F"
   690   assumes g: "Bfun g F"
   691   shows "Zfun (\<lambda>x. f x ** g x) F"
   692 proof -
   693   obtain K where K: "0 \<le> K"
   694     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   695     using nonneg_bounded by fast
   696   obtain B where B: "0 < B"
   697     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   698     using g by (rule BfunE)
   699   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   700   using norm_g proof eventually_elim
   701     case (elim x)
   702     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   703       by (rule norm_le)
   704     also have "\<dots> \<le> norm (f x) * B * K"
   705       by (intro mult_mono' order_refl norm_g norm_ge_zero
   706                 mult_nonneg_nonneg K elim)
   707     also have "\<dots> = norm (f x) * (B * K)"
   708       by (rule mult_assoc)
   709     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   710   qed
   711   with f show ?thesis
   712     by (rule Zfun_imp_Zfun)
   713 qed
   714 
   715 lemma (in bounded_bilinear) flip:
   716   "bounded_bilinear (\<lambda>x y. y ** x)"
   717   apply default
   718   apply (rule add_right)
   719   apply (rule add_left)
   720   apply (rule scaleR_right)
   721   apply (rule scaleR_left)
   722   apply (subst mult_commute)
   723   using bounded by fast
   724 
   725 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   726   assumes f: "Bfun f F"
   727   assumes g: "Zfun g F"
   728   shows "Zfun (\<lambda>x. f x ** g x) F"
   729   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   730 
   731 lemma Bfun_inverse_lemma:
   732   fixes x :: "'a::real_normed_div_algebra"
   733   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   734   apply (subst nonzero_norm_inverse, clarsimp)
   735   apply (erule (1) le_imp_inverse_le)
   736   done
   737 
   738 lemma Bfun_inverse:
   739   fixes a :: "'a::real_normed_div_algebra"
   740   assumes f: "(f ---> a) F"
   741   assumes a: "a \<noteq> 0"
   742   shows "Bfun (\<lambda>x. inverse (f x)) F"
   743 proof -
   744   from a have "0 < norm a" by simp
   745   hence "\<exists>r>0. r < norm a" by (rule dense)
   746   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   747   have "eventually (\<lambda>x. dist (f x) a < r) F"
   748     using tendstoD [OF f r1] by fast
   749   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   750   proof eventually_elim
   751     case (elim x)
   752     hence 1: "norm (f x - a) < r"
   753       by (simp add: dist_norm)
   754     hence 2: "f x \<noteq> 0" using r2 by auto
   755     hence "norm (inverse (f x)) = inverse (norm (f x))"
   756       by (rule nonzero_norm_inverse)
   757     also have "\<dots> \<le> inverse (norm a - r)"
   758     proof (rule le_imp_inverse_le)
   759       show "0 < norm a - r" using r2 by simp
   760     next
   761       have "norm a - norm (f x) \<le> norm (a - f x)"
   762         by (rule norm_triangle_ineq2)
   763       also have "\<dots> = norm (f x - a)"
   764         by (rule norm_minus_commute)
   765       also have "\<dots> < r" using 1 .
   766       finally show "norm a - r \<le> norm (f x)" by simp
   767     qed
   768     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   769   qed
   770   thus ?thesis by (rule BfunI)
   771 qed
   772 
   773 lemma tendsto_inverse [tendsto_intros]:
   774   fixes a :: "'a::real_normed_div_algebra"
   775   assumes f: "(f ---> a) F"
   776   assumes a: "a \<noteq> 0"
   777   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   778 proof -
   779   from a have "0 < norm a" by simp
   780   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   781     by (rule tendstoD)
   782   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   783     unfolding dist_norm by (auto elim!: eventually_elim1)
   784   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   785     - (inverse (f x) * (f x - a) * inverse a)) F"
   786     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   787   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   788     by (intro Zfun_minus Zfun_mult_left
   789       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   790       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   791   ultimately show ?thesis
   792     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   793 qed
   794 
   795 lemma continuous_inverse:
   796   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   797   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   798   shows "continuous F (\<lambda>x. inverse (f x))"
   799   using assms unfolding continuous_def by (rule tendsto_inverse)
   800 
   801 lemma continuous_at_within_inverse[continuous_intros]:
   802   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   803   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   804   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   805   using assms unfolding continuous_within by (rule tendsto_inverse)
   806 
   807 lemma isCont_inverse[continuous_intros, simp]:
   808   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   809   assumes "isCont f a" and "f a \<noteq> 0"
   810   shows "isCont (\<lambda>x. inverse (f x)) a"
   811   using assms unfolding continuous_at by (rule tendsto_inverse)
   812 
   813 lemma continuous_on_inverse[continuous_on_intros]:
   814   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   815   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   816   shows "continuous_on s (\<lambda>x. inverse (f x))"
   817   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   818 
   819 lemma tendsto_divide [tendsto_intros]:
   820   fixes a b :: "'a::real_normed_field"
   821   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   822     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   823   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   824 
   825 lemma continuous_divide:
   826   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   827   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   828   shows "continuous F (\<lambda>x. (f x) / (g x))"
   829   using assms unfolding continuous_def by (rule tendsto_divide)
   830 
   831 lemma continuous_at_within_divide[continuous_intros]:
   832   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   833   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   834   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   835   using assms unfolding continuous_within by (rule tendsto_divide)
   836 
   837 lemma isCont_divide[continuous_intros, simp]:
   838   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   839   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   840   shows "isCont (\<lambda>x. (f x) / g x) a"
   841   using assms unfolding continuous_at by (rule tendsto_divide)
   842 
   843 lemma continuous_on_divide[continuous_on_intros]:
   844   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   845   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   846   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   847   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   848 
   849 lemma tendsto_sgn [tendsto_intros]:
   850   fixes l :: "'a::real_normed_vector"
   851   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   852   unfolding sgn_div_norm by (simp add: tendsto_intros)
   853 
   854 lemma continuous_sgn:
   855   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   856   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   857   shows "continuous F (\<lambda>x. sgn (f x))"
   858   using assms unfolding continuous_def by (rule tendsto_sgn)
   859 
   860 lemma continuous_at_within_sgn[continuous_intros]:
   861   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   862   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   863   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   864   using assms unfolding continuous_within by (rule tendsto_sgn)
   865 
   866 lemma isCont_sgn[continuous_intros]:
   867   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   868   assumes "isCont f a" and "f a \<noteq> 0"
   869   shows "isCont (\<lambda>x. sgn (f x)) a"
   870   using assms unfolding continuous_at by (rule tendsto_sgn)
   871 
   872 lemma continuous_on_sgn[continuous_on_intros]:
   873   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   874   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   875   shows "continuous_on s (\<lambda>x. sgn (f x))"
   876   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   877 
   878 lemma filterlim_at_infinity:
   879   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
   880   assumes "0 \<le> c"
   881   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   882   unfolding filterlim_iff eventually_at_infinity
   883 proof safe
   884   fix P :: "'a \<Rightarrow> bool" and b
   885   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   886     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   887   have "max b (c + 1) > c" by auto
   888   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   889     by auto
   890   then show "eventually (\<lambda>x. P (f x)) F"
   891   proof eventually_elim
   892     fix x assume "max b (c + 1) \<le> norm (f x)"
   893     with P show "P (f x)" by auto
   894   qed
   895 qed force
   896 
   897 
   898 subsection {* Relate @{const at}, @{const at_left} and @{const at_right} *}
   899 
   900 text {*
   901 
   902 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   903 @{term "at_right x"} and also @{term "at_right 0"}.
   904 
   905 *}
   906 
   907 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   908 
   909 lemma filtermap_homeomorph:
   910   assumes f: "continuous (at a) f"
   911   assumes g: "continuous (at (f a)) g"
   912   assumes bij1: "\<forall>x. f (g x) = x" and bij2: "\<forall>x. g (f x) = x"
   913   shows "filtermap f (nhds a) = nhds (f a)"
   914   unfolding filter_eq_iff eventually_filtermap eventually_nhds
   915 proof safe
   916   fix P S assume S: "open S" "f a \<in> S" and P: "\<forall>x\<in>S. P x"
   917   from continuous_within_topological[THEN iffD1, rule_format, OF f S] P
   918   show "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P (f x))" by auto
   919 next
   920   fix P S assume S: "open S" "a \<in> S" and P: "\<forall>x\<in>S. P (f x)"
   921   with continuous_within_topological[THEN iffD1, rule_format, OF g, of S] bij2
   922   obtain A where "open A" "f a \<in> A" "(\<forall>y\<in>A. g y \<in> S)"
   923     by (metis UNIV_I)
   924   with P bij1 show "\<exists>S. open S \<and> f a \<in> S \<and> (\<forall>x\<in>S. P x)"
   925     by (force intro!: exI[of _ A])
   926 qed
   927 
   928 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
   929   by (rule filtermap_homeomorph[where g="\<lambda>x. x + d"]) (auto intro: continuous_intros)
   930 
   931 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
   932   by (rule filtermap_homeomorph[where g=uminus]) (auto intro: continuous_minus)
   933 
   934 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
   935   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   936 
   937 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   938   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   939 
   940 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   941   using filtermap_at_right_shift[of "-a" 0] by simp
   942 
   943 lemma filterlim_at_right_to_0:
   944   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   945   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   946 
   947 lemma eventually_at_right_to_0:
   948   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   949   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   950 
   951 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
   952   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   953 
   954 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   955   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   956 
   957 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   958   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   959 
   960 lemma filterlim_at_left_to_right:
   961   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   962   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   963 
   964 lemma eventually_at_left_to_right:
   965   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   966   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   967 
   968 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   969   unfolding filter_eq_iff eventually_filtermap eventually_at_top_linorder eventually_at_bot_linorder
   970   by (metis le_minus_iff minus_minus)
   971 
   972 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   973   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   974 
   975 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   976   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   977 
   978 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   979   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   980 
   981 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   982   unfolding filterlim_at_top eventually_at_bot_dense
   983   by (metis leI minus_less_iff order_less_asym)
   984 
   985 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
   986   unfolding filterlim_at_bot eventually_at_top_dense
   987   by (metis leI less_minus_iff order_less_asym)
   988 
   989 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
   990   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
   991   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
   992   by auto
   993 
   994 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
   995   unfolding filterlim_uminus_at_top by simp
   996 
   997 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
   998   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
   999 proof safe
  1000   fix Z :: real assume [arith]: "0 < Z"
  1001   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1002     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1003   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1004     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1005 qed
  1006 
  1007 lemma filterlim_inverse_at_top:
  1008   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1009   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1010      (simp add: filterlim_def eventually_filtermap eventually_elim1 at_within_def le_principal)
  1011 
  1012 lemma filterlim_inverse_at_bot_neg:
  1013   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1014   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1015 
  1016 lemma filterlim_inverse_at_bot:
  1017   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1018   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1019   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1020 
  1021 lemma tendsto_inverse_0:
  1022   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
  1023   shows "(inverse ---> (0::'a)) at_infinity"
  1024   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1025 proof safe
  1026   fix r :: real assume "0 < r"
  1027   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1028   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1029     fix x :: 'a
  1030     from `0 < r` have "0 < inverse (r / 2)" by simp
  1031     also assume *: "inverse (r / 2) \<le> norm x"
  1032     finally show "norm (inverse x) < r"
  1033       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1034   qed
  1035 qed
  1036 
  1037 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1038 proof (rule antisym)
  1039   have "(inverse ---> (0::real)) at_top"
  1040     by (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1041   then show "filtermap inverse at_top \<le> at_right (0::real)"
  1042     by (simp add: le_principal eventually_filtermap eventually_gt_at_top filterlim_def at_within_def)
  1043 next
  1044   have "filtermap inverse (filtermap inverse (at_right (0::real))) \<le> filtermap inverse at_top"
  1045     using filterlim_inverse_at_top_right unfolding filterlim_def by (rule filtermap_mono)
  1046   then show "at_right (0::real) \<le> filtermap inverse at_top"
  1047     by (simp add: filtermap_ident filtermap_filtermap)
  1048 qed
  1049 
  1050 lemma eventually_at_right_to_top:
  1051   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1052   unfolding at_right_to_top eventually_filtermap ..
  1053 
  1054 lemma filterlim_at_right_to_top:
  1055   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1056   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1057 
  1058 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1059   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1060 
  1061 lemma eventually_at_top_to_right:
  1062   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1063   unfolding at_top_to_right eventually_filtermap ..
  1064 
  1065 lemma filterlim_at_top_to_right:
  1066   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1067   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1068 
  1069 lemma filterlim_inverse_at_infinity:
  1070   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1071   shows "filterlim inverse at_infinity (at (0::'a))"
  1072   unfolding filterlim_at_infinity[OF order_refl]
  1073 proof safe
  1074   fix r :: real assume "0 < r"
  1075   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1076     unfolding eventually_at norm_inverse
  1077     by (intro exI[of _ "inverse r"])
  1078        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1079 qed
  1080 
  1081 lemma filterlim_inverse_at_iff:
  1082   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1083   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1084   unfolding filterlim_def filtermap_filtermap[symmetric]
  1085 proof
  1086   assume "filtermap g F \<le> at_infinity"
  1087   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1088     by (rule filtermap_mono)
  1089   also have "\<dots> \<le> at 0"
  1090     using tendsto_inverse_0[where 'a='b]
  1091     by (auto intro!: exI[of _ 1]
  1092              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1093   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1094 next
  1095   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1096   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1097     by (rule filtermap_mono)
  1098   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1099     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1100 qed
  1101 
  1102 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
  1103  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1104 
  1105 text {*
  1106 
  1107 We only show rules for multiplication and addition when the functions are either against a real
  1108 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1109 
  1110 *}
  1111 
  1112 lemma filterlim_tendsto_pos_mult_at_top: 
  1113   assumes f: "(f ---> c) F" and c: "0 < c"
  1114   assumes g: "LIM x F. g x :> at_top"
  1115   shows "LIM x F. (f x * g x :: real) :> at_top"
  1116   unfolding filterlim_at_top_gt[where c=0]
  1117 proof safe
  1118   fix Z :: real assume "0 < Z"
  1119   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
  1120     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
  1121              simp: dist_real_def abs_real_def split: split_if_asm)
  1122   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1123     unfolding filterlim_at_top by auto
  1124   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1125   proof eventually_elim
  1126     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1127     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1128       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1129     with `0 < c` show "Z \<le> f x * g x"
  1130        by simp
  1131   qed
  1132 qed
  1133 
  1134 lemma filterlim_at_top_mult_at_top: 
  1135   assumes f: "LIM x F. f x :> at_top"
  1136   assumes g: "LIM x F. g x :> at_top"
  1137   shows "LIM x F. (f x * g x :: real) :> at_top"
  1138   unfolding filterlim_at_top_gt[where c=0]
  1139 proof safe
  1140   fix Z :: real assume "0 < Z"
  1141   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1142     unfolding filterlim_at_top by auto
  1143   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1144     unfolding filterlim_at_top by auto
  1145   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1146   proof eventually_elim
  1147     fix x assume "1 \<le> f x" "Z \<le> g x"
  1148     with `0 < Z` have "1 * Z \<le> f x * g x"
  1149       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1150     then show "Z \<le> f x * g x"
  1151        by simp
  1152   qed
  1153 qed
  1154 
  1155 lemma filterlim_tendsto_pos_mult_at_bot:
  1156   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1157   shows "LIM x F. f x * g x :> at_bot"
  1158   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1159   unfolding filterlim_uminus_at_bot by simp
  1160 
  1161 lemma filterlim_tendsto_add_at_top: 
  1162   assumes f: "(f ---> c) F"
  1163   assumes g: "LIM x F. g x :> at_top"
  1164   shows "LIM x F. (f x + g x :: real) :> at_top"
  1165   unfolding filterlim_at_top_gt[where c=0]
  1166 proof safe
  1167   fix Z :: real assume "0 < Z"
  1168   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1169     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
  1170   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1171     unfolding filterlim_at_top by auto
  1172   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1173     by eventually_elim simp
  1174 qed
  1175 
  1176 lemma LIM_at_top_divide:
  1177   fixes f g :: "'a \<Rightarrow> real"
  1178   assumes f: "(f ---> a) F" "0 < a"
  1179   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1180   shows "LIM x F. f x / g x :> at_top"
  1181   unfolding divide_inverse
  1182   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1183 
  1184 lemma filterlim_at_top_add_at_top: 
  1185   assumes f: "LIM x F. f x :> at_top"
  1186   assumes g: "LIM x F. g x :> at_top"
  1187   shows "LIM x F. (f x + g x :: real) :> at_top"
  1188   unfolding filterlim_at_top_gt[where c=0]
  1189 proof safe
  1190   fix Z :: real assume "0 < Z"
  1191   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1192     unfolding filterlim_at_top by auto
  1193   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1194     unfolding filterlim_at_top by auto
  1195   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1196     by eventually_elim simp
  1197 qed
  1198 
  1199 lemma tendsto_divide_0:
  1200   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1201   assumes f: "(f ---> c) F"
  1202   assumes g: "LIM x F. g x :> at_infinity"
  1203   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1204   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1205 
  1206 lemma linear_plus_1_le_power:
  1207   fixes x :: real
  1208   assumes x: "0 \<le> x"
  1209   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1210 proof (induct n)
  1211   case (Suc n)
  1212   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1213     by (simp add: field_simps real_of_nat_Suc mult_nonneg_nonneg x)
  1214   also have "\<dots> \<le> (x + 1)^Suc n"
  1215     using Suc x by (simp add: mult_left_mono)
  1216   finally show ?case .
  1217 qed simp
  1218 
  1219 lemma filterlim_realpow_sequentially_gt1:
  1220   fixes x :: "'a :: real_normed_div_algebra"
  1221   assumes x[arith]: "1 < norm x"
  1222   shows "LIM n sequentially. x ^ n :> at_infinity"
  1223 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1224   fix y :: real assume "0 < y"
  1225   have "0 < norm x - 1" by simp
  1226   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1227   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1228   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1229   also have "\<dots> = norm x ^ N" by simp
  1230   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1231     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1232   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1233     unfolding eventually_sequentially
  1234     by (auto simp: norm_power)
  1235 qed simp
  1236 
  1237 
  1238 subsection {* Limits of Sequences *}
  1239 
  1240 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
  1241   by simp
  1242 
  1243 lemma LIMSEQ_iff:
  1244   fixes L :: "'a::real_normed_vector"
  1245   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1246 unfolding LIMSEQ_def dist_norm ..
  1247 
  1248 lemma LIMSEQ_I:
  1249   fixes L :: "'a::real_normed_vector"
  1250   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
  1251 by (simp add: LIMSEQ_iff)
  1252 
  1253 lemma LIMSEQ_D:
  1254   fixes L :: "'a::real_normed_vector"
  1255   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1256 by (simp add: LIMSEQ_iff)
  1257 
  1258 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
  1259   unfolding tendsto_def eventually_sequentially
  1260   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
  1261 
  1262 lemma Bseq_inverse_lemma:
  1263   fixes x :: "'a::real_normed_div_algebra"
  1264   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1265 apply (subst nonzero_norm_inverse, clarsimp)
  1266 apply (erule (1) le_imp_inverse_le)
  1267 done
  1268 
  1269 lemma Bseq_inverse:
  1270   fixes a :: "'a::real_normed_div_algebra"
  1271   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1272   by (rule Bfun_inverse)
  1273 
  1274 lemma LIMSEQ_diff_approach_zero:
  1275   fixes L :: "'a::real_normed_vector"
  1276   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
  1277   by (drule (1) tendsto_add, simp)
  1278 
  1279 lemma LIMSEQ_diff_approach_zero2:
  1280   fixes L :: "'a::real_normed_vector"
  1281   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
  1282   by (drule (1) tendsto_diff, simp)
  1283 
  1284 text{*An unbounded sequence's inverse tends to 0*}
  1285 
  1286 lemma LIMSEQ_inverse_zero:
  1287   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
  1288   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1289   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1290   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1291   done
  1292 
  1293 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
  1294 
  1295 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
  1296   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1297             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1298 
  1299 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1300 infinity is now easily proved*}
  1301 
  1302 lemma LIMSEQ_inverse_real_of_nat_add:
  1303      "(%n. r + inverse(real(Suc n))) ----> r"
  1304   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1305 
  1306 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1307      "(%n. r + -inverse(real(Suc n))) ----> r"
  1308   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1309   by auto
  1310 
  1311 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1312      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
  1313   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1314   by auto
  1315 
  1316 subsection {* Convergence on sequences *}
  1317 
  1318 lemma convergent_add:
  1319   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1320   assumes "convergent (\<lambda>n. X n)"
  1321   assumes "convergent (\<lambda>n. Y n)"
  1322   shows "convergent (\<lambda>n. X n + Y n)"
  1323   using assms unfolding convergent_def by (fast intro: tendsto_add)
  1324 
  1325 lemma convergent_setsum:
  1326   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1327   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1328   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1329 proof (cases "finite A")
  1330   case True from this and assms show ?thesis
  1331     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1332 qed (simp add: convergent_const)
  1333 
  1334 lemma (in bounded_linear) convergent:
  1335   assumes "convergent (\<lambda>n. X n)"
  1336   shows "convergent (\<lambda>n. f (X n))"
  1337   using assms unfolding convergent_def by (fast intro: tendsto)
  1338 
  1339 lemma (in bounded_bilinear) convergent:
  1340   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1341   shows "convergent (\<lambda>n. X n ** Y n)"
  1342   using assms unfolding convergent_def by (fast intro: tendsto)
  1343 
  1344 lemma convergent_minus_iff:
  1345   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1346   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1347 apply (simp add: convergent_def)
  1348 apply (auto dest: tendsto_minus)
  1349 apply (drule tendsto_minus, auto)
  1350 done
  1351 
  1352 
  1353 text {* A monotone sequence converges to its least upper bound. *}
  1354 
  1355 lemma isLub_mono_imp_LIMSEQ:
  1356   fixes X :: "nat \<Rightarrow> real"
  1357   assumes u: "isLub UNIV {x. \<exists>n. X n = x} u" (* FIXME: use 'range X' *)
  1358   assumes X: "\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n"
  1359   shows "X ----> u"
  1360 proof (rule LIMSEQ_I)
  1361   have 1: "\<forall>n. X n \<le> u"
  1362     using isLubD2 [OF u] by auto
  1363   have "\<forall>y. (\<forall>n. X n \<le> y) \<longrightarrow> u \<le> y"
  1364     using isLub_le_isUb [OF u] by (auto simp add: isUb_def setle_def)
  1365   hence 2: "\<forall>y<u. \<exists>n. y < X n"
  1366     by (metis not_le)
  1367   fix r :: real assume "0 < r"
  1368   hence "u - r < u" by simp
  1369   hence "\<exists>m. u - r < X m" using 2 by simp
  1370   then obtain m where "u - r < X m" ..
  1371   with X have "\<forall>n\<ge>m. u - r < X n"
  1372     by (fast intro: less_le_trans)
  1373   hence "\<exists>m. \<forall>n\<ge>m. u - r < X n" ..
  1374   thus "\<exists>m. \<forall>n\<ge>m. norm (X n - u) < r"
  1375     using 1 by (simp add: diff_less_eq add_commute)
  1376 qed
  1377 
  1378 text{*A standard proof of the theorem for monotone increasing sequence*}
  1379 
  1380 lemma Bseq_mono_convergent:
  1381    "Bseq X \<Longrightarrow> \<forall>m. \<forall>n \<ge> m. X m \<le> X n \<Longrightarrow> convergent (X::nat=>real)"
  1382   by (metis Bseq_isLub isLub_mono_imp_LIMSEQ convergentI)
  1383 
  1384 text{*Main monotonicity theorem*}
  1385 
  1386 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1387   by (metis monoseq_iff incseq_def decseq_eq_incseq convergent_minus_iff Bseq_minus_iff
  1388             Bseq_mono_convergent)
  1389 
  1390 lemma Cauchy_iff:
  1391   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1392   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1393   unfolding Cauchy_def dist_norm ..
  1394 
  1395 lemma CauchyI:
  1396   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1397   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1398 by (simp add: Cauchy_iff)
  1399 
  1400 lemma CauchyD:
  1401   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1402   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1403 by (simp add: Cauchy_iff)
  1404 
  1405 lemma incseq_convergent:
  1406   fixes X :: "nat \<Rightarrow> real"
  1407   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1408   obtains L where "X ----> L" "\<forall>i. X i \<le> L"
  1409 proof atomize_elim
  1410   from incseq_bounded[OF assms] `incseq X` Bseq_monoseq_convergent[of X]
  1411   obtain L where "X ----> L"
  1412     by (auto simp: convergent_def monoseq_def incseq_def)
  1413   with `incseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. X i \<le> L)"
  1414     by (auto intro!: exI[of _ L] incseq_le)
  1415 qed
  1416 
  1417 lemma decseq_convergent:
  1418   fixes X :: "nat \<Rightarrow> real"
  1419   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1420   obtains L where "X ----> L" "\<forall>i. L \<le> X i"
  1421 proof atomize_elim
  1422   from decseq_bounded[OF assms] `decseq X` Bseq_monoseq_convergent[of X]
  1423   obtain L where "X ----> L"
  1424     by (auto simp: convergent_def monoseq_def decseq_def)
  1425   with `decseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. L \<le> X i)"
  1426     by (auto intro!: exI[of _ L] decseq_le)
  1427 qed
  1428 
  1429 subsubsection {* Cauchy Sequences are Bounded *}
  1430 
  1431 text{*A Cauchy sequence is bounded -- this is the standard
  1432   proof mechanization rather than the nonstandard proof*}
  1433 
  1434 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1435           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1436 apply (clarify, drule spec, drule (1) mp)
  1437 apply (simp only: norm_minus_commute)
  1438 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1439 apply simp
  1440 done
  1441 
  1442 subsection {* Power Sequences *}
  1443 
  1444 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1445 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1446   also fact that bounded and monotonic sequence converges.*}
  1447 
  1448 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1449 apply (simp add: Bseq_def)
  1450 apply (rule_tac x = 1 in exI)
  1451 apply (simp add: power_abs)
  1452 apply (auto dest: power_mono)
  1453 done
  1454 
  1455 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1456 apply (clarify intro!: mono_SucI2)
  1457 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1458 done
  1459 
  1460 lemma convergent_realpow:
  1461   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1462 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1463 
  1464 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1465   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1466 
  1467 lemma LIMSEQ_realpow_zero:
  1468   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1469 proof cases
  1470   assume "0 \<le> x" and "x \<noteq> 0"
  1471   hence x0: "0 < x" by simp
  1472   assume x1: "x < 1"
  1473   from x0 x1 have "1 < inverse x"
  1474     by (rule one_less_inverse)
  1475   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1476     by (rule LIMSEQ_inverse_realpow_zero)
  1477   thus ?thesis by (simp add: power_inverse)
  1478 qed (rule LIMSEQ_imp_Suc, simp add: tendsto_const)
  1479 
  1480 lemma LIMSEQ_power_zero:
  1481   fixes x :: "'a::{real_normed_algebra_1}"
  1482   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1483 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1484 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1485 apply (simp add: power_abs norm_power_ineq)
  1486 done
  1487 
  1488 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
  1489   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1490 
  1491 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1492 
  1493 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
  1494   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1495 
  1496 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
  1497   by (rule LIMSEQ_power_zero) simp
  1498 
  1499 
  1500 subsection {* Limits of Functions *}
  1501 
  1502 lemma LIM_eq:
  1503   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1504   shows "f -- a --> L =
  1505      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1506 by (simp add: LIM_def dist_norm)
  1507 
  1508 lemma LIM_I:
  1509   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1510   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1511       ==> f -- a --> L"
  1512 by (simp add: LIM_eq)
  1513 
  1514 lemma LIM_D:
  1515   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1516   shows "[| f -- a --> L; 0<r |]
  1517       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1518 by (simp add: LIM_eq)
  1519 
  1520 lemma LIM_offset:
  1521   fixes a :: "'a::real_normed_vector"
  1522   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
  1523   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1524 
  1525 lemma LIM_offset_zero:
  1526   fixes a :: "'a::real_normed_vector"
  1527   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1528 by (drule_tac k="a" in LIM_offset, simp add: add_commute)
  1529 
  1530 lemma LIM_offset_zero_cancel:
  1531   fixes a :: "'a::real_normed_vector"
  1532   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
  1533 by (drule_tac k="- a" in LIM_offset, simp)
  1534 
  1535 lemma LIM_offset_zero_iff:
  1536   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1537   shows  "f -- a --> L \<longleftrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1538   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1539 
  1540 lemma LIM_zero:
  1541   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1542   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
  1543 unfolding tendsto_iff dist_norm by simp
  1544 
  1545 lemma LIM_zero_cancel:
  1546   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1547   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
  1548 unfolding tendsto_iff dist_norm by simp
  1549 
  1550 lemma LIM_zero_iff:
  1551   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1552   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
  1553 unfolding tendsto_iff dist_norm by simp
  1554 
  1555 lemma LIM_imp_LIM:
  1556   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1557   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1558   assumes f: "f -- a --> l"
  1559   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  1560   shows "g -- a --> m"
  1561   by (rule metric_LIM_imp_LIM [OF f],
  1562     simp add: dist_norm le)
  1563 
  1564 lemma LIM_equal2:
  1565   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1566   assumes 1: "0 < R"
  1567   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  1568   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
  1569 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  1570 
  1571 lemma LIM_compose2:
  1572   fixes a :: "'a::real_normed_vector"
  1573   assumes f: "f -- a --> b"
  1574   assumes g: "g -- b --> c"
  1575   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  1576   shows "(\<lambda>x. g (f x)) -- a --> c"
  1577 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  1578 
  1579 lemma real_LIM_sandwich_zero:
  1580   fixes f g :: "'a::topological_space \<Rightarrow> real"
  1581   assumes f: "f -- a --> 0"
  1582   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  1583   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  1584   shows "g -- a --> 0"
  1585 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  1586   fix x assume x: "x \<noteq> a"
  1587   have "norm (g x - 0) = g x" by (simp add: 1 x)
  1588   also have "g x \<le> f x" by (rule 2 [OF x])
  1589   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  1590   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  1591   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  1592 qed
  1593 
  1594 
  1595 subsection {* Continuity *}
  1596 
  1597 lemma LIM_isCont_iff:
  1598   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1599   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
  1600 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  1601 
  1602 lemma isCont_iff:
  1603   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1604   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
  1605 by (simp add: isCont_def LIM_isCont_iff)
  1606 
  1607 lemma isCont_LIM_compose2:
  1608   fixes a :: "'a::real_normed_vector"
  1609   assumes f [unfolded isCont_def]: "isCont f a"
  1610   assumes g: "g -- f a --> l"
  1611   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  1612   shows "(\<lambda>x. g (f x)) -- a --> l"
  1613 by (rule LIM_compose2 [OF f g inj])
  1614 
  1615 
  1616 lemma isCont_norm [simp]:
  1617   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1618   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  1619   by (fact continuous_norm)
  1620 
  1621 lemma isCont_rabs [simp]:
  1622   fixes f :: "'a::t2_space \<Rightarrow> real"
  1623   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  1624   by (fact continuous_rabs)
  1625 
  1626 lemma isCont_add [simp]:
  1627   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1628   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  1629   by (fact continuous_add)
  1630 
  1631 lemma isCont_minus [simp]:
  1632   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1633   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  1634   by (fact continuous_minus)
  1635 
  1636 lemma isCont_diff [simp]:
  1637   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1638   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  1639   by (fact continuous_diff)
  1640 
  1641 lemma isCont_mult [simp]:
  1642   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  1643   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  1644   by (fact continuous_mult)
  1645 
  1646 lemma (in bounded_linear) isCont:
  1647   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  1648   by (fact continuous)
  1649 
  1650 lemma (in bounded_bilinear) isCont:
  1651   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  1652   by (fact continuous)
  1653 
  1654 lemmas isCont_scaleR [simp] = 
  1655   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  1656 
  1657 lemmas isCont_of_real [simp] =
  1658   bounded_linear.isCont [OF bounded_linear_of_real]
  1659 
  1660 lemma isCont_power [simp]:
  1661   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  1662   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  1663   by (fact continuous_power)
  1664 
  1665 lemma isCont_setsum [simp]:
  1666   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  1667   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  1668   by (auto intro: continuous_setsum)
  1669 
  1670 lemmas isCont_intros =
  1671   isCont_ident isCont_const isCont_norm isCont_rabs isCont_add isCont_minus
  1672   isCont_diff isCont_mult isCont_inverse isCont_divide isCont_scaleR
  1673   isCont_of_real isCont_power isCont_sgn isCont_setsum
  1674 
  1675 subsection {* Uniform Continuity *}
  1676 
  1677 definition
  1678   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  1679   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  1680 
  1681 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  1682 by (simp add: isUCont_def isCont_def LIM_def, force)
  1683 
  1684 lemma isUCont_Cauchy:
  1685   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1686 unfolding isUCont_def
  1687 apply (rule metric_CauchyI)
  1688 apply (drule_tac x=e in spec, safe)
  1689 apply (drule_tac e=s in metric_CauchyD, safe)
  1690 apply (rule_tac x=M in exI, simp)
  1691 done
  1692 
  1693 lemma (in bounded_linear) isUCont: "isUCont f"
  1694 unfolding isUCont_def dist_norm
  1695 proof (intro allI impI)
  1696   fix r::real assume r: "0 < r"
  1697   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  1698     using pos_bounded by fast
  1699   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  1700   proof (rule exI, safe)
  1701     from r K show "0 < r / K" by (rule divide_pos_pos)
  1702   next
  1703     fix x y :: 'a
  1704     assume xy: "norm (x - y) < r / K"
  1705     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  1706     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  1707     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  1708     finally show "norm (f x - f y) < r" .
  1709   qed
  1710 qed
  1711 
  1712 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1713 by (rule isUCont [THEN isUCont_Cauchy])
  1714 
  1715 lemma LIM_less_bound: 
  1716   fixes f :: "real \<Rightarrow> real"
  1717   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  1718   shows "0 \<le> f x"
  1719 proof (rule tendsto_le_const)
  1720   show "(f ---> f x) (at_left x)"
  1721     using `isCont f x` by (simp add: filterlim_at_split isCont_def)
  1722   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  1723     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  1724 qed simp
  1725 
  1726 
  1727 subsection {* Nested Intervals and Bisection -- Needed for Compactness *}
  1728 
  1729 lemma nested_sequence_unique:
  1730   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) ----> 0"
  1731   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f ----> l) \<and> ((\<forall>n. l \<le> g n) \<and> g ----> l)"
  1732 proof -
  1733   have "incseq f" unfolding incseq_Suc_iff by fact
  1734   have "decseq g" unfolding decseq_Suc_iff by fact
  1735 
  1736   { fix n
  1737     from `decseq g` have "g n \<le> g 0" by (rule decseqD) simp
  1738     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f n \<le> g 0" by auto }
  1739   then obtain u where "f ----> u" "\<forall>i. f i \<le> u"
  1740     using incseq_convergent[OF `incseq f`] by auto
  1741   moreover
  1742   { fix n
  1743     from `incseq f` have "f 0 \<le> f n" by (rule incseqD) simp
  1744     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f 0 \<le> g n" by simp }
  1745   then obtain l where "g ----> l" "\<forall>i. l \<le> g i"
  1746     using decseq_convergent[OF `decseq g`] by auto
  1747   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF `f ----> u` `g ----> l`]]
  1748   ultimately show ?thesis by auto
  1749 qed
  1750 
  1751 lemma Bolzano[consumes 1, case_names trans local]:
  1752   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  1753   assumes [arith]: "a \<le> b"
  1754   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  1755   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  1756   shows "P a b"
  1757 proof -
  1758   def bisect \<equiv> "nat_rec (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  1759   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  1760   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  1761     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  1762     by (simp_all add: l_def u_def bisect_def split: prod.split)
  1763 
  1764   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  1765 
  1766   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l ----> x) \<and> ((\<forall>n. x \<le> u n) \<and> u ----> x)"
  1767   proof (safe intro!: nested_sequence_unique)
  1768     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  1769   next
  1770     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  1771     then show "(\<lambda>n. l n - u n) ----> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  1772   qed fact
  1773   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l ----> x" "u ----> x" by auto
  1774   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  1775     using `l 0 \<le> x` `x \<le> u 0` local[of x] by auto
  1776 
  1777   show "P a b"
  1778   proof (rule ccontr)
  1779     assume "\<not> P a b" 
  1780     { fix n have "\<not> P (l n) (u n)"
  1781       proof (induct n)
  1782         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  1783       qed (simp add: `\<not> P a b`) }
  1784     moreover
  1785     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  1786         using `0 < d` `l ----> x` by (intro order_tendstoD[of _ x]) auto
  1787       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  1788         using `0 < d` `u ----> x` by (intro order_tendstoD[of _ x]) auto
  1789       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  1790       proof eventually_elim
  1791         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  1792         from add_strict_mono[OF this] have "u n - l n < d" by simp
  1793         with x show "P (l n) (u n)" by (rule d)
  1794       qed }
  1795     ultimately show False by simp
  1796   qed
  1797 qed
  1798 
  1799 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  1800 proof (cases "a \<le> b", rule compactI)
  1801   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  1802   def T == "{a .. b}"
  1803   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  1804   proof (induct rule: Bolzano)
  1805     case (trans a b c)
  1806     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  1807     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  1808       by (auto simp: *)
  1809     with trans show ?case
  1810       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  1811   next
  1812     case (local x)
  1813     then have "x \<in> \<Union>C" using C by auto
  1814     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  1815     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  1816       by (auto simp: open_real_def dist_real_def subset_eq Ball_def abs_less_iff)
  1817     with `c \<in> C` show ?case
  1818       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  1819   qed
  1820 qed simp
  1821 
  1822 
  1823 subsection {* Boundedness of continuous functions *}
  1824 
  1825 text{*By bisection, function continuous on closed interval is bounded above*}
  1826 
  1827 lemma isCont_eq_Ub:
  1828   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1829   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1830     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1831   using continuous_attains_sup[of "{a .. b}" f]
  1832   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1833 
  1834 lemma isCont_eq_Lb:
  1835   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1836   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1837     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1838   using continuous_attains_inf[of "{a .. b}" f]
  1839   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1840 
  1841 lemma isCont_bounded:
  1842   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1843   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  1844   using isCont_eq_Ub[of a b f] by auto
  1845 
  1846 lemma isCont_has_Ub:
  1847   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1848   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1849     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  1850   using isCont_eq_Ub[of a b f] by auto
  1851 
  1852 (*HOL style here: object-level formulations*)
  1853 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  1854       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1855       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1856   by (blast intro: IVT)
  1857 
  1858 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  1859       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1860       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1861   by (blast intro: IVT2)
  1862 
  1863 lemma isCont_Lb_Ub:
  1864   fixes f :: "real \<Rightarrow> real"
  1865   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1866   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and> 
  1867                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  1868 proof -
  1869   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  1870     using isCont_eq_Ub[OF assms] by auto
  1871   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  1872     using isCont_eq_Lb[OF assms] by auto
  1873   show ?thesis
  1874     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  1875     apply (rule_tac x="f L" in exI)
  1876     apply (rule_tac x="f M" in exI)
  1877     apply (cases "L \<le> M")
  1878     apply (simp, metis order_trans)
  1879     apply (simp, metis order_trans)
  1880     done
  1881 qed
  1882 
  1883 
  1884 text{*Continuity of inverse function*}
  1885 
  1886 lemma isCont_inverse_function:
  1887   fixes f g :: "real \<Rightarrow> real"
  1888   assumes d: "0 < d"
  1889       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  1890       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  1891   shows "isCont g (f x)"
  1892 proof -
  1893   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  1894 
  1895   have f: "continuous_on ?D f"
  1896     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  1897   then have g: "continuous_on (f`?D) g"
  1898     using inj by (intro continuous_on_inv) auto
  1899 
  1900   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  1901     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  1902   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  1903     by (rule continuous_on_subset)
  1904   moreover
  1905   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  1906     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  1907   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  1908     by auto
  1909   ultimately
  1910   show ?thesis
  1911     by (simp add: continuous_on_eq_continuous_at)
  1912 qed
  1913 
  1914 lemma isCont_inverse_function2:
  1915   fixes f g :: "real \<Rightarrow> real" shows
  1916   "\<lbrakk>a < x; x < b;
  1917     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  1918     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  1919    \<Longrightarrow> isCont g (f x)"
  1920 apply (rule isCont_inverse_function
  1921        [where f=f and d="min (x - a) (b - x)"])
  1922 apply (simp_all add: abs_le_iff)
  1923 done
  1924 
  1925 (* need to rename second isCont_inverse *)
  1926 
  1927 lemma isCont_inv_fun:
  1928   fixes f g :: "real \<Rightarrow> real"
  1929   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1930          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1931       ==> isCont g (f x)"
  1932 by (rule isCont_inverse_function)
  1933 
  1934 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  1935 lemma LIM_fun_gt_zero:
  1936   fixes f :: "real \<Rightarrow> real"
  1937   shows "f -- c --> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  1938 apply (drule (1) LIM_D, clarify)
  1939 apply (rule_tac x = s in exI)
  1940 apply (simp add: abs_less_iff)
  1941 done
  1942 
  1943 lemma LIM_fun_less_zero:
  1944   fixes f :: "real \<Rightarrow> real"
  1945   shows "f -- c --> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  1946 apply (drule LIM_D [where r="-l"], simp, clarify)
  1947 apply (rule_tac x = s in exI)
  1948 apply (simp add: abs_less_iff)
  1949 done
  1950 
  1951 lemma LIM_fun_not_zero:
  1952   fixes f :: "real \<Rightarrow> real"
  1953   shows "f -- c --> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  1954   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  1955 
  1956 end
  1957