src/HOL/HOLCF/Cfun.thy
author huffman
Tue Oct 09 17:33:46 2012 +0200 (2012-10-09)
changeset 49759 ecf1d5d87e5e
parent 45695 b108b3d7c49e
child 51717 9e7d1c139569
permissions -rw-r--r--
removed support for set constant definitions in HOLCF {cpo,pcpo,domain}def commands;
removed '(open)', '(set_name)' and '(open set_name)' options
     1 (*  Title:      HOL/HOLCF/Cfun.thy
     2     Author:     Franz Regensburger
     3     Author:     Brian Huffman
     4 *)
     5 
     6 header {* The type of continuous functions *}
     7 
     8 theory Cfun
     9 imports Cpodef Fun_Cpo Product_Cpo
    10 begin
    11 
    12 default_sort cpo
    13 
    14 subsection {* Definition of continuous function type *}
    15 
    16 definition "cfun = {f::'a => 'b. cont f}"
    17 
    18 cpodef ('a, 'b) cfun (infixr "->" 0) = "cfun :: ('a => 'b) set"
    19   unfolding cfun_def by (auto intro: cont_const adm_cont)
    20 
    21 type_notation (xsymbols)
    22   cfun  ("(_ \<rightarrow>/ _)" [1, 0] 0)
    23 
    24 notation
    25   Rep_cfun  ("(_$/_)" [999,1000] 999)
    26 
    27 notation (xsymbols)
    28   Rep_cfun  ("(_\<cdot>/_)" [999,1000] 999)
    29 
    30 notation (HTML output)
    31   Rep_cfun  ("(_\<cdot>/_)" [999,1000] 999)
    32 
    33 subsection {* Syntax for continuous lambda abstraction *}
    34 
    35 syntax "_cabs" :: "[logic, logic] \<Rightarrow> logic"
    36 
    37 parse_translation {*
    38 (* rewrite (_cabs x t) => (Abs_cfun (%x. t)) *)
    39   [Syntax_Trans.mk_binder_tr (@{syntax_const "_cabs"}, @{const_syntax Abs_cfun})];
    40 *}
    41 
    42 print_translation {*
    43   [(@{const_syntax Abs_cfun}, fn [Abs abs] =>
    44       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
    45       in Syntax.const @{syntax_const "_cabs"} $ x $ t end)]
    46 *}  -- {* To avoid eta-contraction of body *}
    47 
    48 text {* Syntax for nested abstractions *}
    49 
    50 syntax
    51   "_Lambda" :: "[cargs, logic] \<Rightarrow> logic"  ("(3LAM _./ _)" [1000, 10] 10)
    52 
    53 syntax (xsymbols)
    54   "_Lambda" :: "[cargs, logic] \<Rightarrow> logic" ("(3\<Lambda> _./ _)" [1000, 10] 10)
    55 
    56 parse_ast_translation {*
    57 (* rewrite (LAM x y z. t) => (_cabs x (_cabs y (_cabs z t))) *)
    58 (* cf. Syntax.lambda_ast_tr from src/Pure/Syntax/syn_trans.ML *)
    59   let
    60     fun Lambda_ast_tr [pats, body] =
    61           Ast.fold_ast_p @{syntax_const "_cabs"}
    62             (Ast.unfold_ast @{syntax_const "_cargs"} (Ast.strip_positions pats), body)
    63       | Lambda_ast_tr asts = raise Ast.AST ("Lambda_ast_tr", asts);
    64   in [(@{syntax_const "_Lambda"}, Lambda_ast_tr)] end;
    65 *}
    66 
    67 print_ast_translation {*
    68 (* rewrite (_cabs x (_cabs y (_cabs z t))) => (LAM x y z. t) *)
    69 (* cf. Syntax.abs_ast_tr' from src/Pure/Syntax/syn_trans.ML *)
    70   let
    71     fun cabs_ast_tr' asts =
    72       (case Ast.unfold_ast_p @{syntax_const "_cabs"}
    73           (Ast.Appl (Ast.Constant @{syntax_const "_cabs"} :: asts)) of
    74         ([], _) => raise Ast.AST ("cabs_ast_tr'", asts)
    75       | (xs, body) => Ast.Appl
    76           [Ast.Constant @{syntax_const "_Lambda"},
    77            Ast.fold_ast @{syntax_const "_cargs"} xs, body]);
    78   in [(@{syntax_const "_cabs"}, cabs_ast_tr')] end
    79 *}
    80 
    81 text {* Dummy patterns for continuous abstraction *}
    82 translations
    83   "\<Lambda> _. t" => "CONST Abs_cfun (\<lambda> _. t)"
    84 
    85 subsection {* Continuous function space is pointed *}
    86 
    87 lemma bottom_cfun: "\<bottom> \<in> cfun"
    88 by (simp add: cfun_def inst_fun_pcpo)
    89 
    90 instance cfun :: (cpo, discrete_cpo) discrete_cpo
    91 by intro_classes (simp add: below_cfun_def Rep_cfun_inject)
    92 
    93 instance cfun :: (cpo, pcpo) pcpo
    94 by (rule typedef_pcpo [OF type_definition_cfun below_cfun_def bottom_cfun])
    95 
    96 lemmas Rep_cfun_strict =
    97   typedef_Rep_strict [OF type_definition_cfun below_cfun_def bottom_cfun]
    98 
    99 lemmas Abs_cfun_strict =
   100   typedef_Abs_strict [OF type_definition_cfun below_cfun_def bottom_cfun]
   101 
   102 text {* function application is strict in its first argument *}
   103 
   104 lemma Rep_cfun_strict1 [simp]: "\<bottom>\<cdot>x = \<bottom>"
   105 by (simp add: Rep_cfun_strict)
   106 
   107 lemma LAM_strict [simp]: "(\<Lambda> x. \<bottom>) = \<bottom>"
   108 by (simp add: inst_fun_pcpo [symmetric] Abs_cfun_strict)
   109 
   110 text {* for compatibility with old HOLCF-Version *}
   111 lemma inst_cfun_pcpo: "\<bottom> = (\<Lambda> x. \<bottom>)"
   112 by simp
   113 
   114 subsection {* Basic properties of continuous functions *}
   115 
   116 text {* Beta-equality for continuous functions *}
   117 
   118 lemma Abs_cfun_inverse2: "cont f \<Longrightarrow> Rep_cfun (Abs_cfun f) = f"
   119 by (simp add: Abs_cfun_inverse cfun_def)
   120 
   121 lemma beta_cfun: "cont f \<Longrightarrow> (\<Lambda> x. f x)\<cdot>u = f u"
   122 by (simp add: Abs_cfun_inverse2)
   123 
   124 text {* Beta-reduction simproc *}
   125 
   126 text {*
   127   Given the term @{term "(\<Lambda> x. f x)\<cdot>y"}, the procedure tries to
   128   construct the theorem @{term "(\<Lambda> x. f x)\<cdot>y == f y"}.  If this
   129   theorem cannot be completely solved by the cont2cont rules, then
   130   the procedure returns the ordinary conditional @{text beta_cfun}
   131   rule.
   132 
   133   The simproc does not solve any more goals that would be solved by
   134   using @{text beta_cfun} as a simp rule.  The advantage of the
   135   simproc is that it can avoid deeply-nested calls to the simplifier
   136   that would otherwise be caused by large continuity side conditions.
   137 
   138   Update: The simproc now uses rule @{text Abs_cfun_inverse2} instead
   139   of @{text beta_cfun}, to avoid problems with eta-contraction.
   140 *}
   141 
   142 simproc_setup beta_cfun_proc ("Rep_cfun (Abs_cfun f)") = {*
   143   fn phi => fn ss => fn ct =>
   144     let
   145       val dest = Thm.dest_comb;
   146       val f = (snd o dest o snd o dest) ct;
   147       val [T, U] = Thm.dest_ctyp (ctyp_of_term f);
   148       val tr = instantiate' [SOME T, SOME U] [SOME f]
   149           (mk_meta_eq @{thm Abs_cfun_inverse2});
   150       val rules = Cont2ContData.get (Simplifier.the_context ss);
   151       val tac = SOLVED' (REPEAT_ALL_NEW (match_tac rules));
   152     in SOME (perhaps (SINGLE (tac 1)) tr) end
   153 *}
   154 
   155 text {* Eta-equality for continuous functions *}
   156 
   157 lemma eta_cfun: "(\<Lambda> x. f\<cdot>x) = f"
   158 by (rule Rep_cfun_inverse)
   159 
   160 text {* Extensionality for continuous functions *}
   161 
   162 lemma cfun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f\<cdot>x = g\<cdot>x)"
   163 by (simp add: Rep_cfun_inject [symmetric] fun_eq_iff)
   164 
   165 lemma cfun_eqI: "(\<And>x. f\<cdot>x = g\<cdot>x) \<Longrightarrow> f = g"
   166 by (simp add: cfun_eq_iff)
   167 
   168 text {* Extensionality wrt. ordering for continuous functions *}
   169 
   170 lemma cfun_below_iff: "f \<sqsubseteq> g \<longleftrightarrow> (\<forall>x. f\<cdot>x \<sqsubseteq> g\<cdot>x)" 
   171 by (simp add: below_cfun_def fun_below_iff)
   172 
   173 lemma cfun_belowI: "(\<And>x. f\<cdot>x \<sqsubseteq> g\<cdot>x) \<Longrightarrow> f \<sqsubseteq> g"
   174 by (simp add: cfun_below_iff)
   175 
   176 text {* Congruence for continuous function application *}
   177 
   178 lemma cfun_cong: "\<lbrakk>f = g; x = y\<rbrakk> \<Longrightarrow> f\<cdot>x = g\<cdot>y"
   179 by simp
   180 
   181 lemma cfun_fun_cong: "f = g \<Longrightarrow> f\<cdot>x = g\<cdot>x"
   182 by simp
   183 
   184 lemma cfun_arg_cong: "x = y \<Longrightarrow> f\<cdot>x = f\<cdot>y"
   185 by simp
   186 
   187 subsection {* Continuity of application *}
   188 
   189 lemma cont_Rep_cfun1: "cont (\<lambda>f. f\<cdot>x)"
   190 by (rule cont_Rep_cfun [OF cont_id, THEN cont2cont_fun])
   191 
   192 lemma cont_Rep_cfun2: "cont (\<lambda>x. f\<cdot>x)"
   193 apply (cut_tac x=f in Rep_cfun)
   194 apply (simp add: cfun_def)
   195 done
   196 
   197 lemmas monofun_Rep_cfun = cont_Rep_cfun [THEN cont2mono]
   198 
   199 lemmas monofun_Rep_cfun1 = cont_Rep_cfun1 [THEN cont2mono]
   200 lemmas monofun_Rep_cfun2 = cont_Rep_cfun2 [THEN cont2mono]
   201 
   202 text {* contlub, cont properties of @{term Rep_cfun} in each argument *}
   203 
   204 lemma contlub_cfun_arg: "chain Y \<Longrightarrow> f\<cdot>(\<Squnion>i. Y i) = (\<Squnion>i. f\<cdot>(Y i))"
   205 by (rule cont_Rep_cfun2 [THEN cont2contlubE])
   206 
   207 lemma contlub_cfun_fun: "chain F \<Longrightarrow> (\<Squnion>i. F i)\<cdot>x = (\<Squnion>i. F i\<cdot>x)"
   208 by (rule cont_Rep_cfun1 [THEN cont2contlubE])
   209 
   210 text {* monotonicity of application *}
   211 
   212 lemma monofun_cfun_fun: "f \<sqsubseteq> g \<Longrightarrow> f\<cdot>x \<sqsubseteq> g\<cdot>x"
   213 by (simp add: cfun_below_iff)
   214 
   215 lemma monofun_cfun_arg: "x \<sqsubseteq> y \<Longrightarrow> f\<cdot>x \<sqsubseteq> f\<cdot>y"
   216 by (rule monofun_Rep_cfun2 [THEN monofunE])
   217 
   218 lemma monofun_cfun: "\<lbrakk>f \<sqsubseteq> g; x \<sqsubseteq> y\<rbrakk> \<Longrightarrow> f\<cdot>x \<sqsubseteq> g\<cdot>y"
   219 by (rule below_trans [OF monofun_cfun_fun monofun_cfun_arg])
   220 
   221 text {* ch2ch - rules for the type @{typ "'a -> 'b"} *}
   222 
   223 lemma chain_monofun: "chain Y \<Longrightarrow> chain (\<lambda>i. f\<cdot>(Y i))"
   224 by (erule monofun_Rep_cfun2 [THEN ch2ch_monofun])
   225 
   226 lemma ch2ch_Rep_cfunR: "chain Y \<Longrightarrow> chain (\<lambda>i. f\<cdot>(Y i))"
   227 by (rule monofun_Rep_cfun2 [THEN ch2ch_monofun])
   228 
   229 lemma ch2ch_Rep_cfunL: "chain F \<Longrightarrow> chain (\<lambda>i. (F i)\<cdot>x)"
   230 by (rule monofun_Rep_cfun1 [THEN ch2ch_monofun])
   231 
   232 lemma ch2ch_Rep_cfun [simp]:
   233   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> chain (\<lambda>i. (F i)\<cdot>(Y i))"
   234 by (simp add: chain_def monofun_cfun)
   235 
   236 lemma ch2ch_LAM [simp]:
   237   "\<lbrakk>\<And>x. chain (\<lambda>i. S i x); \<And>i. cont (\<lambda>x. S i x)\<rbrakk> \<Longrightarrow> chain (\<lambda>i. \<Lambda> x. S i x)"
   238 by (simp add: chain_def cfun_below_iff)
   239 
   240 text {* contlub, cont properties of @{term Rep_cfun} in both arguments *}
   241 
   242 lemma lub_APP:
   243   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> (\<Squnion>i. F i\<cdot>(Y i)) = (\<Squnion>i. F i)\<cdot>(\<Squnion>i. Y i)"
   244 by (simp add: contlub_cfun_fun contlub_cfun_arg diag_lub)
   245 
   246 lemma lub_LAM:
   247   "\<lbrakk>\<And>x. chain (\<lambda>i. F i x); \<And>i. cont (\<lambda>x. F i x)\<rbrakk>
   248     \<Longrightarrow> (\<Squnion>i. \<Lambda> x. F i x) = (\<Lambda> x. \<Squnion>i. F i x)"
   249 by (simp add: lub_cfun lub_fun ch2ch_lambda)
   250 
   251 lemmas lub_distribs = lub_APP lub_LAM
   252 
   253 text {* strictness *}
   254 
   255 lemma strictI: "f\<cdot>x = \<bottom> \<Longrightarrow> f\<cdot>\<bottom> = \<bottom>"
   256 apply (rule bottomI)
   257 apply (erule subst)
   258 apply (rule minimal [THEN monofun_cfun_arg])
   259 done
   260 
   261 text {* type @{typ "'a -> 'b"} is chain complete *}
   262 
   263 lemma lub_cfun: "chain F \<Longrightarrow> (\<Squnion>i. F i) = (\<Lambda> x. \<Squnion>i. F i\<cdot>x)"
   264 by (simp add: lub_cfun lub_fun ch2ch_lambda)
   265 
   266 subsection {* Continuity simplification procedure *}
   267 
   268 text {* cont2cont lemma for @{term Rep_cfun} *}
   269 
   270 lemma cont2cont_APP [simp, cont2cont]:
   271   assumes f: "cont (\<lambda>x. f x)"
   272   assumes t: "cont (\<lambda>x. t x)"
   273   shows "cont (\<lambda>x. (f x)\<cdot>(t x))"
   274 proof -
   275   have 1: "\<And>y. cont (\<lambda>x. (f x)\<cdot>y)"
   276     using cont_Rep_cfun1 f by (rule cont_compose)
   277   show "cont (\<lambda>x. (f x)\<cdot>(t x))"
   278     using t cont_Rep_cfun2 1 by (rule cont_apply)
   279 qed
   280 
   281 text {*
   282   Two specific lemmas for the combination of LCF and HOL terms.
   283   These lemmas are needed in theories that use types like @{typ "'a \<rightarrow> 'b \<Rightarrow> 'c"}.
   284 *}
   285 
   286 lemma cont_APP_app [simp]: "\<lbrakk>cont f; cont g\<rbrakk> \<Longrightarrow> cont (\<lambda>x. ((f x)\<cdot>(g x)) s)"
   287 by (rule cont2cont_APP [THEN cont2cont_fun])
   288 
   289 lemma cont_APP_app_app [simp]: "\<lbrakk>cont f; cont g\<rbrakk> \<Longrightarrow> cont (\<lambda>x. ((f x)\<cdot>(g x)) s t)"
   290 by (rule cont_APP_app [THEN cont2cont_fun])
   291 
   292 
   293 text {* cont2mono Lemma for @{term "%x. LAM y. c1(x)(y)"} *}
   294 
   295 lemma cont2mono_LAM:
   296   "\<lbrakk>\<And>x. cont (\<lambda>y. f x y); \<And>y. monofun (\<lambda>x. f x y)\<rbrakk>
   297     \<Longrightarrow> monofun (\<lambda>x. \<Lambda> y. f x y)"
   298   unfolding monofun_def cfun_below_iff by simp
   299 
   300 text {* cont2cont Lemma for @{term "%x. LAM y. f x y"} *}
   301 
   302 text {*
   303   Not suitable as a cont2cont rule, because on nested lambdas
   304   it causes exponential blow-up in the number of subgoals.
   305 *}
   306 
   307 lemma cont2cont_LAM:
   308   assumes f1: "\<And>x. cont (\<lambda>y. f x y)"
   309   assumes f2: "\<And>y. cont (\<lambda>x. f x y)"
   310   shows "cont (\<lambda>x. \<Lambda> y. f x y)"
   311 proof (rule cont_Abs_cfun)
   312   fix x
   313   from f1 show "f x \<in> cfun" by (simp add: cfun_def)
   314   from f2 show "cont f" by (rule cont2cont_lambda)
   315 qed
   316 
   317 text {*
   318   This version does work as a cont2cont rule, since it
   319   has only a single subgoal.
   320 *}
   321 
   322 lemma cont2cont_LAM' [simp, cont2cont]:
   323   fixes f :: "'a::cpo \<Rightarrow> 'b::cpo \<Rightarrow> 'c::cpo"
   324   assumes f: "cont (\<lambda>p. f (fst p) (snd p))"
   325   shows "cont (\<lambda>x. \<Lambda> y. f x y)"
   326 using assms by (simp add: cont2cont_LAM prod_cont_iff)
   327 
   328 lemma cont2cont_LAM_discrete [simp, cont2cont]:
   329   "(\<And>y::'a::discrete_cpo. cont (\<lambda>x. f x y)) \<Longrightarrow> cont (\<lambda>x. \<Lambda> y. f x y)"
   330 by (simp add: cont2cont_LAM)
   331 
   332 subsection {* Miscellaneous *}
   333 
   334 text {* Monotonicity of @{term Abs_cfun} *}
   335 
   336 lemma monofun_LAM:
   337   "\<lbrakk>cont f; cont g; \<And>x. f x \<sqsubseteq> g x\<rbrakk> \<Longrightarrow> (\<Lambda> x. f x) \<sqsubseteq> (\<Lambda> x. g x)"
   338 by (simp add: cfun_below_iff)
   339 
   340 text {* some lemmata for functions with flat/chfin domain/range types *}
   341 
   342 lemma chfin_Rep_cfunR: "chain (Y::nat => 'a::cpo->'b::chfin)  
   343       ==> !s. ? n. (LUB i. Y i)$s = Y n$s"
   344 apply (rule allI)
   345 apply (subst contlub_cfun_fun)
   346 apply assumption
   347 apply (fast intro!: lub_eqI chfin lub_finch2 chfin2finch ch2ch_Rep_cfunL)
   348 done
   349 
   350 lemma adm_chfindom: "adm (\<lambda>(u::'a::cpo \<rightarrow> 'b::chfin). P(u\<cdot>s))"
   351 by (rule adm_subst, simp, rule adm_chfin)
   352 
   353 subsection {* Continuous injection-retraction pairs *}
   354 
   355 text {* Continuous retractions are strict. *}
   356 
   357 lemma retraction_strict:
   358   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> f\<cdot>\<bottom> = \<bottom>"
   359 apply (rule bottomI)
   360 apply (drule_tac x="\<bottom>" in spec)
   361 apply (erule subst)
   362 apply (rule monofun_cfun_arg)
   363 apply (rule minimal)
   364 done
   365 
   366 lemma injection_eq:
   367   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> (g\<cdot>x = g\<cdot>y) = (x = y)"
   368 apply (rule iffI)
   369 apply (drule_tac f=f in cfun_arg_cong)
   370 apply simp
   371 apply simp
   372 done
   373 
   374 lemma injection_below:
   375   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> (g\<cdot>x \<sqsubseteq> g\<cdot>y) = (x \<sqsubseteq> y)"
   376 apply (rule iffI)
   377 apply (drule_tac f=f in monofun_cfun_arg)
   378 apply simp
   379 apply (erule monofun_cfun_arg)
   380 done
   381 
   382 lemma injection_defined_rev:
   383   "\<lbrakk>\<forall>x. f\<cdot>(g\<cdot>x) = x; g\<cdot>z = \<bottom>\<rbrakk> \<Longrightarrow> z = \<bottom>"
   384 apply (drule_tac f=f in cfun_arg_cong)
   385 apply (simp add: retraction_strict)
   386 done
   387 
   388 lemma injection_defined:
   389   "\<lbrakk>\<forall>x. f\<cdot>(g\<cdot>x) = x; z \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> g\<cdot>z \<noteq> \<bottom>"
   390 by (erule contrapos_nn, rule injection_defined_rev)
   391 
   392 text {* a result about functions with flat codomain *}
   393 
   394 lemma flat_eqI: "\<lbrakk>(x::'a::flat) \<sqsubseteq> y; x \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> x = y"
   395 by (drule ax_flat, simp)
   396 
   397 lemma flat_codom:
   398   "f\<cdot>x = (c::'b::flat) \<Longrightarrow> f\<cdot>\<bottom> = \<bottom> \<or> (\<forall>z. f\<cdot>z = c)"
   399 apply (case_tac "f\<cdot>x = \<bottom>")
   400 apply (rule disjI1)
   401 apply (rule bottomI)
   402 apply (erule_tac t="\<bottom>" in subst)
   403 apply (rule minimal [THEN monofun_cfun_arg])
   404 apply clarify
   405 apply (rule_tac a = "f\<cdot>\<bottom>" in refl [THEN box_equals])
   406 apply (erule minimal [THEN monofun_cfun_arg, THEN flat_eqI])
   407 apply (erule minimal [THEN monofun_cfun_arg, THEN flat_eqI])
   408 done
   409 
   410 subsection {* Identity and composition *}
   411 
   412 definition
   413   ID :: "'a \<rightarrow> 'a" where
   414   "ID = (\<Lambda> x. x)"
   415 
   416 definition
   417   cfcomp  :: "('b \<rightarrow> 'c) \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'a \<rightarrow> 'c" where
   418   oo_def: "cfcomp = (\<Lambda> f g x. f\<cdot>(g\<cdot>x))"
   419 
   420 abbreviation
   421   cfcomp_syn :: "['b \<rightarrow> 'c, 'a \<rightarrow> 'b] \<Rightarrow> 'a \<rightarrow> 'c"  (infixr "oo" 100)  where
   422   "f oo g == cfcomp\<cdot>f\<cdot>g"
   423 
   424 lemma ID1 [simp]: "ID\<cdot>x = x"
   425 by (simp add: ID_def)
   426 
   427 lemma cfcomp1: "(f oo g) = (\<Lambda> x. f\<cdot>(g\<cdot>x))"
   428 by (simp add: oo_def)
   429 
   430 lemma cfcomp2 [simp]: "(f oo g)\<cdot>x = f\<cdot>(g\<cdot>x)"
   431 by (simp add: cfcomp1)
   432 
   433 lemma cfcomp_LAM: "cont g \<Longrightarrow> f oo (\<Lambda> x. g x) = (\<Lambda> x. f\<cdot>(g x))"
   434 by (simp add: cfcomp1)
   435 
   436 lemma cfcomp_strict [simp]: "\<bottom> oo f = \<bottom>"
   437 by (simp add: cfun_eq_iff)
   438 
   439 text {*
   440   Show that interpretation of (pcpo,@{text "_->_"}) is a category.
   441   The class of objects is interpretation of syntactical class pcpo.
   442   The class of arrows  between objects @{typ 'a} and @{typ 'b} is interpret. of @{typ "'a -> 'b"}.
   443   The identity arrow is interpretation of @{term ID}.
   444   The composition of f and g is interpretation of @{text "oo"}.
   445 *}
   446 
   447 lemma ID2 [simp]: "f oo ID = f"
   448 by (rule cfun_eqI, simp)
   449 
   450 lemma ID3 [simp]: "ID oo f = f"
   451 by (rule cfun_eqI, simp)
   452 
   453 lemma assoc_oo: "f oo (g oo h) = (f oo g) oo h"
   454 by (rule cfun_eqI, simp)
   455 
   456 subsection {* Strictified functions *}
   457 
   458 default_sort pcpo
   459 
   460 definition
   461   seq :: "'a \<rightarrow> 'b \<rightarrow> 'b" where
   462   "seq = (\<Lambda> x. if x = \<bottom> then \<bottom> else ID)"
   463 
   464 lemma cont2cont_if_bottom [cont2cont, simp]:
   465   assumes f: "cont (\<lambda>x. f x)" and g: "cont (\<lambda>x. g x)"
   466   shows "cont (\<lambda>x. if f x = \<bottom> then \<bottom> else g x)"
   467 proof (rule cont_apply [OF f])
   468   show "\<And>x. cont (\<lambda>y. if y = \<bottom> then \<bottom> else g x)"
   469     unfolding cont_def is_lub_def is_ub_def ball_simps
   470     by (simp add: lub_eq_bottom_iff)
   471   show "\<And>y. cont (\<lambda>x. if y = \<bottom> then \<bottom> else g x)"
   472     by (simp add: g)
   473 qed
   474 
   475 lemma seq_conv_if: "seq\<cdot>x = (if x = \<bottom> then \<bottom> else ID)"
   476 unfolding seq_def by simp
   477 
   478 lemma seq_simps [simp]:
   479   "seq\<cdot>\<bottom> = \<bottom>"
   480   "seq\<cdot>x\<cdot>\<bottom> = \<bottom>"
   481   "x \<noteq> \<bottom> \<Longrightarrow> seq\<cdot>x = ID"
   482 by (simp_all add: seq_conv_if)
   483 
   484 definition
   485   strictify  :: "('a \<rightarrow> 'b) \<rightarrow> 'a \<rightarrow> 'b" where
   486   "strictify = (\<Lambda> f x. seq\<cdot>x\<cdot>(f\<cdot>x))"
   487 
   488 lemma strictify_conv_if: "strictify\<cdot>f\<cdot>x = (if x = \<bottom> then \<bottom> else f\<cdot>x)"
   489 unfolding strictify_def by simp
   490 
   491 lemma strictify1 [simp]: "strictify\<cdot>f\<cdot>\<bottom> = \<bottom>"
   492 by (simp add: strictify_conv_if)
   493 
   494 lemma strictify2 [simp]: "x \<noteq> \<bottom> \<Longrightarrow> strictify\<cdot>f\<cdot>x = f\<cdot>x"
   495 by (simp add: strictify_conv_if)
   496 
   497 subsection {* Continuity of let-bindings *}
   498 
   499 lemma cont2cont_Let:
   500   assumes f: "cont (\<lambda>x. f x)"
   501   assumes g1: "\<And>y. cont (\<lambda>x. g x y)"
   502   assumes g2: "\<And>x. cont (\<lambda>y. g x y)"
   503   shows "cont (\<lambda>x. let y = f x in g x y)"
   504 unfolding Let_def using f g2 g1 by (rule cont_apply)
   505 
   506 lemma cont2cont_Let' [simp, cont2cont]:
   507   assumes f: "cont (\<lambda>x. f x)"
   508   assumes g: "cont (\<lambda>p. g (fst p) (snd p))"
   509   shows "cont (\<lambda>x. let y = f x in g x y)"
   510 using f
   511 proof (rule cont2cont_Let)
   512   fix x show "cont (\<lambda>y. g x y)"
   513     using g by (simp add: prod_cont_iff)
   514 next
   515   fix y show "cont (\<lambda>x. g x y)"
   516     using g by (simp add: prod_cont_iff)
   517 qed
   518 
   519 text {* The simple version (suggested by Joachim Breitner) is needed if
   520   the type of the defined term is not a cpo. *}
   521 
   522 lemma cont2cont_Let_simple [simp, cont2cont]:
   523   assumes "\<And>y. cont (\<lambda>x. g x y)"
   524   shows "cont (\<lambda>x. let y = t in g x y)"
   525 unfolding Let_def using assms .
   526 
   527 end