src/Pure/sign.ML
author wenzelm
Mon Feb 15 17:17:51 2010 +0100 (2010-02-15)
changeset 35129 ed24ba6f69aa
parent 34259 2ba492b8b6e8
child 35200 aaddb2b526d6
permissions -rw-r--r--
discontinued unnamed infix syntax;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: Name_Space.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    16   val naming_of: theory -> Name_Space.naming
    17   val full_name: theory -> binding -> string
    18   val full_name_path: theory -> string -> binding -> string
    19   val full_bname: theory -> bstring -> string
    20   val full_bname_path: theory -> string -> bstring -> string
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val defaultS: theory -> sort
    29   val subsort: theory -> sort * sort -> bool
    30   val of_sort: theory -> typ * sort -> bool
    31   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    32   val is_logtype: theory -> string -> bool
    33   val typ_instance: theory -> typ * typ -> bool
    34   val typ_equiv: theory -> typ * typ -> bool
    35   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    36   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    37   val consts_of: theory -> Consts.T
    38   val the_const_constraint: theory -> string -> typ
    39   val const_type: theory -> string -> typ option
    40   val the_const_type: theory -> string -> typ
    41   val declared_tyname: theory -> string -> bool
    42   val declared_const: theory -> string -> bool
    43   val const_monomorphic: theory -> string -> bool
    44   val const_syntax_name: theory -> string -> string
    45   val const_typargs: theory -> string * typ -> typ list
    46   val const_instance: theory -> string * typ list -> typ
    47   val mk_const: theory -> string * typ list -> term
    48   val class_space: theory -> Name_Space.T
    49   val type_space: theory -> Name_Space.T
    50   val const_space: theory -> Name_Space.T
    51   val intern_class: theory -> xstring -> string
    52   val extern_class: theory -> string -> xstring
    53   val intern_type: theory -> xstring -> string
    54   val extern_type: theory -> string -> xstring
    55   val intern_const: theory -> xstring -> string
    56   val extern_const: theory -> string -> xstring
    57   val intern_sort: theory -> sort -> sort
    58   val extern_sort: theory -> sort -> sort
    59   val intern_typ: theory -> typ -> typ
    60   val extern_typ: theory -> typ -> typ
    61   val intern_term: theory -> term -> term
    62   val extern_term: (string -> xstring) -> theory -> term -> term
    63   val intern_tycons: theory -> typ -> typ
    64   val arity_number: theory -> string -> int
    65   val arity_sorts: theory -> string -> sort -> sort list
    66   val certify_class: theory -> class -> class
    67   val certify_sort: theory -> sort -> sort
    68   val certify_typ: theory -> typ -> typ
    69   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    70   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    71   val certify_term: theory -> term -> term * typ * int
    72   val cert_term: theory -> term -> term
    73   val cert_prop: theory -> term -> term
    74   val no_frees: Pretty.pp -> term -> term
    75   val no_vars: Pretty.pp -> term -> term
    76   val cert_def: Proof.context -> term -> (string * typ) * term
    77   val read_class: theory -> xstring -> class
    78   val read_arity: theory -> xstring * string list * string -> arity
    79   val cert_arity: theory -> arity -> arity
    80   val add_defsort: string -> theory -> theory
    81   val add_defsort_i: sort -> theory -> theory
    82   val add_types: (binding * int * mixfix) list -> theory -> theory
    83   val add_nonterminals: binding list -> theory -> theory
    84   val add_tyabbrs: (binding * string list * string * mixfix) list -> theory -> theory
    85   val add_tyabbrs_i: (binding * string list * typ * mixfix) list -> theory -> theory
    86   val add_syntax: (string * string * mixfix) list -> theory -> theory
    87   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    88   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    89   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    90   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    91   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    92   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    93   val declare_const: (binding * typ) * mixfix -> theory -> term * theory
    94   val add_consts: (binding * string * mixfix) list -> theory -> theory
    95   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    96   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    97   val revert_abbrev: string -> string -> theory -> theory
    98   val add_const_constraint: string * typ option -> theory -> theory
    99   val primitive_class: binding * class list -> theory -> theory
   100   val primitive_classrel: class * class -> theory -> theory
   101   val primitive_arity: arity -> theory -> theory
   102   val add_trfuns:
   103     (string * (ast list -> ast)) list *
   104     (string * (term list -> term)) list *
   105     (string * (term list -> term)) list *
   106     (string * (ast list -> ast)) list -> theory -> theory
   107   val add_trfunsT:
   108     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   109   val add_advanced_trfuns:
   110     (string * (Proof.context -> ast list -> ast)) list *
   111     (string * (Proof.context -> term list -> term)) list *
   112     (string * (Proof.context -> term list -> term)) list *
   113     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   114   val add_advanced_trfunsT:
   115     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   116   val add_tokentrfuns:
   117     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   118   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   119     -> theory -> theory
   120   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   121   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   122   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   123   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   124   val new_group: theory -> theory
   125   val reset_group: theory -> theory
   126   val add_path: string -> theory -> theory
   127   val root_path: theory -> theory
   128   val parent_path: theory -> theory
   129   val mandatory_path: string -> theory -> theory
   130   val local_path: theory -> theory
   131   val restore_naming: theory -> theory -> theory
   132   val hide_class: bool -> string -> theory -> theory
   133   val hide_type: bool -> string -> theory -> theory
   134   val hide_const: bool -> string -> theory -> theory
   135 end
   136 
   137 structure Sign: SIGN =
   138 struct
   139 
   140 (** datatype sign **)
   141 
   142 datatype sign = Sign of
   143  {naming: Name_Space.naming,    (*common naming conventions*)
   144   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   145   tsig: Type.tsig,              (*order-sorted signature of types*)
   146   consts: Consts.T};            (*polymorphic constants*)
   147 
   148 fun make_sign (naming, syn, tsig, consts) =
   149   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   150 
   151 structure SignData = Theory_Data_PP
   152 (
   153   type T = sign;
   154   fun extend (Sign {syn, tsig, consts, ...}) =
   155     make_sign (Name_Space.default_naming, syn, tsig, consts);
   156 
   157   val empty =
   158     make_sign (Name_Space.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   159 
   160   fun merge pp (sign1, sign2) =
   161     let
   162       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   163       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   164 
   165       val naming = Name_Space.default_naming;
   166       val syn = Syntax.merge_syntaxes syn1 syn2;
   167       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   168       val consts = Consts.merge (consts1, consts2);
   169     in make_sign (naming, syn, tsig, consts) end;
   170 );
   171 
   172 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   173 
   174 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   175   make_sign (f (naming, syn, tsig, consts)));
   176 
   177 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   178 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   179 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   180 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   181 
   182 
   183 (* naming *)
   184 
   185 val naming_of = #naming o rep_sg;
   186 
   187 val full_name = Name_Space.full_name o naming_of;
   188 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   189 
   190 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   191 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   192 
   193 
   194 (* syntax *)
   195 
   196 val syn_of = #syn o rep_sg;
   197 
   198 
   199 (* type signature *)
   200 
   201 val tsig_of = #tsig o rep_sg;
   202 
   203 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   204 val all_classes = Sorts.all_classes o classes_of;
   205 val super_classes = Sorts.super_classes o classes_of;
   206 val minimize_sort = Sorts.minimize_sort o classes_of;
   207 val complete_sort = Sorts.complete_sort o classes_of;
   208 
   209 val defaultS = Type.defaultS o tsig_of;
   210 val subsort = Type.subsort o tsig_of;
   211 val of_sort = Type.of_sort o tsig_of;
   212 val witness_sorts = Type.witness_sorts o tsig_of;
   213 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   214 
   215 val typ_instance = Type.typ_instance o tsig_of;
   216 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   217 val typ_match = Type.typ_match o tsig_of;
   218 val typ_unify = Type.unify o tsig_of;
   219 
   220 
   221 (* polymorphic constants *)
   222 
   223 val consts_of = #consts o rep_sg;
   224 val the_const_constraint = Consts.the_constraint o consts_of;
   225 val the_const_type = Consts.the_type o consts_of;
   226 val const_type = try o the_const_type;
   227 val const_monomorphic = Consts.is_monomorphic o consts_of;
   228 val const_syntax_name = Consts.syntax_name o consts_of;
   229 val const_typargs = Consts.typargs o consts_of;
   230 val const_instance = Consts.instance o consts_of;
   231 
   232 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   233 
   234 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   235 val declared_const = can o the_const_constraint;
   236 
   237 
   238 
   239 (** intern / extern names **)
   240 
   241 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   242 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   243 val const_space = Consts.space_of o consts_of;
   244 
   245 val intern_class = Name_Space.intern o class_space;
   246 val extern_class = Name_Space.extern o class_space;
   247 val intern_type = Name_Space.intern o type_space;
   248 val extern_type = Name_Space.extern o type_space;
   249 val intern_const = Name_Space.intern o const_space;
   250 val extern_const = Name_Space.extern o const_space;
   251 
   252 val intern_sort = map o intern_class;
   253 val extern_sort = map o extern_class;
   254 
   255 local
   256 
   257 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   258   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   259   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   260 
   261 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   262   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   263   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   264   | map_term _ _ _ (t as Bound _) = t
   265   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   266   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   267 
   268 val add_classesT = Term.fold_atyps
   269   (fn TFree (_, S) => fold (insert (op =)) S
   270     | TVar (_, S) => fold (insert (op =)) S
   271     | _ => I);
   272 
   273 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   274   | add_tyconsT _ = I;
   275 
   276 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   277 
   278 fun mapping add_names f t =
   279   let
   280     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   281     val tab = map_filter f' (add_names t []);
   282     fun get x = the_default x (AList.lookup (op =) tab x);
   283   in get end;
   284 
   285 fun typ_mapping f g thy T =
   286   T |> map_typ
   287     (mapping add_classesT (f thy) T)
   288     (mapping add_tyconsT (g thy) T);
   289 
   290 fun term_mapping f g h thy t =
   291   t |> map_term
   292     (mapping (Term.fold_types add_classesT) (f thy) t)
   293     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   294     (mapping add_consts (h thy) t);
   295 
   296 in
   297 
   298 val intern_typ = typ_mapping intern_class intern_type;
   299 val extern_typ = typ_mapping extern_class extern_type;
   300 val intern_term = term_mapping intern_class intern_type intern_const;
   301 fun extern_term h = term_mapping extern_class extern_type (K h);
   302 val intern_tycons = typ_mapping (K I) intern_type;
   303 
   304 end;
   305 
   306 
   307 
   308 (** certify entities **)    (*exception TYPE*)
   309 
   310 (* certify wrt. type signature *)
   311 
   312 val arity_number = Type.arity_number o tsig_of;
   313 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   314 
   315 val certify_class         = Type.cert_class o tsig_of;
   316 val certify_sort          = Type.cert_sort o tsig_of;
   317 val certify_typ           = Type.cert_typ o tsig_of;
   318 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   319 
   320 
   321 (* certify term/prop *)
   322 
   323 local
   324 
   325 fun type_check pp tm =
   326   let
   327     fun err_appl why bs t T u U =
   328       let
   329         val xs = map Free bs;           (*we do not rename here*)
   330         val t' = subst_bounds (xs, t);
   331         val u' = subst_bounds (xs, u);
   332         val msg = cat_lines
   333           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   334       in raise TYPE (msg, [T, U], [t', u']) end;
   335 
   336     fun typ_of (_, Const (_, T)) = T
   337       | typ_of (_, Free  (_, T)) = T
   338       | typ_of (_, Var (_, T)) = T
   339       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   340           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   341       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   342       | typ_of (bs, t $ u) =
   343           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   344             (case T of
   345               Type ("fun", [T1, T2]) =>
   346                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   347             | _ => err_appl "Operator not of function type" bs t T u U)
   348           end;
   349   in typ_of ([], tm) end;
   350 
   351 fun err msg = raise TYPE (msg, [], []);
   352 
   353 fun check_vars (t $ u) = (check_vars t; check_vars u)
   354   | check_vars (Abs (_, _, t)) = check_vars t
   355   | check_vars (Free (x, _)) =
   356       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   357   | check_vars (Var (xi as (_, i), _)) =
   358       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   359   | check_vars _ = ();
   360 
   361 in
   362 
   363 fun certify' prop pp do_expand consts thy tm =
   364   let
   365     val _ = check_vars tm;
   366     val tm' = Term.map_types (certify_typ thy) tm;
   367     val T = type_check pp tm';
   368     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   369     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   370   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   371 
   372 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   373 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   374 val cert_term = #1 oo certify_term;
   375 fun cert_prop thy = #1 o certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   376 
   377 end;
   378 
   379 
   380 (* specifications *)
   381 
   382 fun no_variables kind add addT mk mkT pp tm =
   383   (case (add tm [], addT tm []) of
   384     ([], []) => tm
   385   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   386       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   387        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   388 
   389 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   390 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   391 
   392 fun cert_def ctxt tm =
   393   let val ((lhs, rhs), _) = tm
   394     |> no_vars (Syntax.pp ctxt)
   395     |> Logic.strip_imp_concl
   396     |> Primitive_Defs.dest_def ctxt Term.is_Const (K false) (K false)
   397   in (Term.dest_Const (Term.head_of lhs), rhs) end
   398   handle TERM (msg, _) => error msg;
   399 
   400 
   401 
   402 (** read and certify entities **)    (*exception ERROR*)
   403 
   404 (* classes *)
   405 
   406 fun read_class thy c = certify_class thy (intern_class thy c)
   407   handle TYPE (msg, _, _) => error msg;
   408 
   409 
   410 (* type arities *)
   411 
   412 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   413   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   414   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   415 
   416 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   417 val cert_arity = prep_arity (K I) certify_sort;
   418 
   419 
   420 
   421 (** signature extension functions **)  (*exception ERROR/TYPE*)
   422 
   423 (* add default sort *)
   424 
   425 fun gen_add_defsort prep_sort s thy =
   426   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   427 
   428 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   429 val add_defsort_i = gen_add_defsort certify_sort;
   430 
   431 
   432 (* add type constructors *)
   433 
   434 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   435   let
   436     val syn' = Syntax.update_type_gram (map (fn (a, n, mx) => (Name.of_binding a, n, mx)) types) syn;
   437     val decls = map (fn (a, n, _) => (a, n)) types;
   438     val tsig' = fold (Type.add_type naming) decls tsig;
   439   in (naming, syn', tsig', consts) end);
   440 
   441 
   442 (* add nonterminals *)
   443 
   444 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   445   let
   446     val syn' = Syntax.update_consts (map Name.of_binding ns) syn;
   447     val tsig' = fold (Type.add_nonterminal naming) ns tsig;
   448   in (naming, syn', tsig', consts) end);
   449 
   450 
   451 (* add type abbreviations *)
   452 
   453 fun gen_add_tyabbr parse_typ (b, vs, rhs, mx) thy =
   454   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   455     let
   456       val ctxt = ProofContext.init thy;
   457       val syn' = Syntax.update_type_gram [(Name.of_binding b, length vs, mx)] syn;
   458       val abbr = (b, vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   459         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote (Binding.str_of b));
   460       val tsig' = Type.add_abbrev naming abbr tsig;
   461     in (naming, syn', tsig', consts) end);
   462 
   463 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   464 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   465 
   466 
   467 (* modify syntax *)
   468 
   469 fun gen_syntax change_gram parse_typ mode args thy =
   470   let
   471     val ctxt = ProofContext.init thy;
   472     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   473       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   474   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   475 
   476 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   477 
   478 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   479 val add_modesyntax_i = gen_add_syntax (K I);
   480 val add_syntax = add_modesyntax Syntax.mode_default;
   481 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   482 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   483 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   484 
   485 fun notation add mode args thy =
   486   let
   487     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   488     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   489       | const_syntax _ = NONE;
   490   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   491 
   492 
   493 (* add constants *)
   494 
   495 local
   496 
   497 fun gen_add_consts parse_typ authentic raw_args thy =
   498   let
   499     val ctxt = ProofContext.init thy;
   500     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   501     fun prep (b, raw_T, mx) =
   502       let
   503         val c = full_name thy b;
   504         val c_syn = if authentic then Syntax.constN ^ c else Name.of_binding b;
   505         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   506           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   507         val T' = Logic.varifyT T;
   508       in ((b, T'), (c_syn, T', mx), Const (c, T)) end;
   509     val args = map prep raw_args;
   510   in
   511     thy
   512     |> map_consts (fold (Consts.declare authentic (naming_of thy) o #1) args)
   513     |> add_syntax_i (map #2 args)
   514     |> pair (map #3 args)
   515   end;
   516 
   517 in
   518 
   519 fun add_consts args = snd o gen_add_consts Syntax.parse_typ false args;
   520 fun add_consts_i args = snd o gen_add_consts (K I) false args;
   521 
   522 fun declare_const ((b, T), mx) thy =
   523   let
   524     val pos = Binding.pos_of b;
   525     val ([const as Const (c, _)], thy') = gen_add_consts (K I) true [(b, T, mx)] thy;
   526     val _ = Position.report (Markup.const_decl c) pos;
   527   in (const, thy') end;
   528 
   529 end;
   530 
   531 
   532 (* abbreviations *)
   533 
   534 fun add_abbrev mode (b, raw_t) thy =
   535   let
   536     val pp = Syntax.pp_global thy;
   537     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   538     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   539       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   540     val (res, consts') = consts_of thy
   541       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode (b, t);
   542   in (res, thy |> map_consts (K consts')) end;
   543 
   544 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   545 
   546 
   547 (* add constraints *)
   548 
   549 fun add_const_constraint (c, opt_T) thy =
   550   let
   551     fun prepT raw_T =
   552       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   553       in cert_term thy (Const (c, T)); T end
   554       handle TYPE (msg, _, _) => error msg;
   555   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   556 
   557 
   558 (* primitive classes and arities *)
   559 
   560 fun primitive_class (bclass, classes) thy =
   561   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   562     let
   563       val syn' = Syntax.update_consts [Name.of_binding bclass] syn;
   564       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   565     in (naming, syn', tsig', consts) end)
   566   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   567 
   568 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   569 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   570 
   571 
   572 (* add translation functions *)
   573 
   574 local
   575 
   576 fun mk trs = map Syntax.mk_trfun trs;
   577 
   578 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   579   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   580 
   581 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   582 
   583 in
   584 
   585 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   586 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   587 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   588 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   589 
   590 end;
   591 
   592 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   593 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   594 
   595 
   596 (* translation rules *)
   597 
   598 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   599   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   600   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   601 
   602 val add_trrules = gen_trrules Syntax.update_trrules;
   603 val del_trrules = gen_trrules Syntax.remove_trrules;
   604 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   605 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   606 
   607 
   608 (* naming *)
   609 
   610 val new_group = map_naming Name_Space.new_group;
   611 val reset_group = map_naming Name_Space.reset_group;
   612 
   613 val add_path = map_naming o Name_Space.add_path;
   614 val root_path = map_naming Name_Space.root_path;
   615 val parent_path = map_naming Name_Space.parent_path;
   616 val mandatory_path = map_naming o Name_Space.mandatory_path;
   617 
   618 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   619 
   620 val restore_naming = map_naming o K o naming_of;
   621 
   622 
   623 (* hide names *)
   624 
   625 val hide_class = map_tsig oo Type.hide_class;
   626 val hide_type = map_tsig oo Type.hide_type;
   627 val hide_const = map_consts oo Consts.hide;
   628 
   629 end;