src/Pure/Isar/class_declaration.ML
author haftmann
Tue Oct 26 14:06:22 2010 +0200 (2010-10-26)
changeset 40188 eddda8e38360
parent 38875 c7a66b584147
child 41585 45d7da4e4ccf
permissions -rw-r--r--
consider base sorts of superclasses simultaneously during processing of class specification -- avoids clash of different base sorts
     1 (*  Title:      Pure/Isar/class_declaration.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Declaring classes and subclass relations.
     5 *)
     6 
     7 signature CLASS_DECLARATION =
     8 sig
     9   val class: binding -> class list -> Element.context_i list
    10     -> theory -> string * local_theory
    11   val class_cmd: binding -> xstring list -> Element.context list
    12     -> theory -> string * local_theory
    13   val prove_subclass: tactic -> class -> local_theory -> local_theory
    14   val subclass: class -> local_theory -> Proof.state
    15   val subclass_cmd: xstring -> local_theory -> Proof.state
    16 end;
    17 
    18 structure Class_Declaration: CLASS_DECLARATION =
    19 struct
    20 
    21 (** class definitions **)
    22 
    23 local
    24 
    25 (* calculating class-related rules including canonical interpretation *)
    26 
    27 fun calculate thy class sups base_sort param_map assm_axiom =
    28   let
    29     val empty_ctxt = ProofContext.init_global thy;
    30 
    31     (* instantiation of canonical interpretation *)
    32     val aT = TFree (Name.aT, base_sort);
    33     val param_map_const = (map o apsnd) Const param_map;
    34     val param_map_inst = (map o apsnd)
    35       (Const o apsnd (map_atyps (K aT))) param_map;
    36     val const_morph = Element.inst_morphism thy
    37       (Symtab.empty, Symtab.make param_map_inst);
    38     val typ_morph = Element.inst_morphism thy
    39       (Symtab.empty |> Symtab.update (Name.aT, TFree (Name.aT, [class])), Symtab.empty);
    40     val (([raw_props], [(_, raw_inst_morph)], export_morph), _) = empty_ctxt
    41       |> Expression.cert_goal_expression ([(class, (("", false),
    42            Expression.Named param_map_const))], []);
    43     val (props, inst_morph) = if null param_map
    44       then (raw_props |> map (Morphism.term typ_morph),
    45         raw_inst_morph $> typ_morph)
    46       else (raw_props, raw_inst_morph); (*FIXME proper handling in
    47         locale.ML / expression.ML would be desirable*)
    48 
    49     (* witness for canonical interpretation *)
    50     val prop = try the_single props;
    51     val wit = Option.map (fn prop => let
    52         val sup_axioms = map_filter (fst o Class.rules thy) sups;
    53         val loc_intro_tac = case Locale.intros_of thy class
    54           of (_, NONE) => all_tac
    55            | (_, SOME intro) => ALLGOALS (Tactic.rtac intro);
    56         val tac = loc_intro_tac
    57           THEN ALLGOALS (ProofContext.fact_tac (sup_axioms @ the_list assm_axiom))
    58       in Element.prove_witness empty_ctxt prop tac end) prop;
    59     val axiom = Option.map Element.conclude_witness wit;
    60 
    61     (* canonical interpretation *)
    62     val base_morph = inst_morph
    63       $> Morphism.binding_morphism (Binding.prefix false (Class.class_prefix class))
    64       $> Element.satisfy_morphism (the_list wit);
    65     val eq_morph = Element.eq_morphism thy (Class.these_defs thy sups);
    66 
    67     (* assm_intro *)
    68     fun prove_assm_intro thm =
    69       let
    70         val ((_, [thm']), _) = Variable.import true [thm] empty_ctxt;
    71         val const_eq_morph = case eq_morph
    72          of SOME eq_morph => const_morph $> eq_morph
    73           | NONE => const_morph
    74         val thm'' = Morphism.thm const_eq_morph thm';
    75         val tac = ALLGOALS (ProofContext.fact_tac [thm'']);
    76       in Skip_Proof.prove_global thy [] [] (Thm.prop_of thm'') (K tac) end;
    77     val assm_intro = Option.map prove_assm_intro
    78       (fst (Locale.intros_of thy class));
    79 
    80     (* of_class *)
    81     val of_class_prop_concl = Logic.mk_of_class (aT, class);
    82     val of_class_prop = case prop of NONE => of_class_prop_concl
    83       | SOME prop => Logic.mk_implies (Morphism.term const_morph
    84           ((map_types o map_atyps) (K aT) prop), of_class_prop_concl);
    85     val sup_of_classes = map (snd o Class.rules thy) sups;
    86     val loc_axiom_intros = map Drule.export_without_context_open (Locale.axioms_of thy class);
    87     val axclass_intro = #intro (AxClass.get_info thy class);
    88     val base_sort_trivs = Thm.of_sort (Thm.ctyp_of thy aT, base_sort);
    89     val tac = REPEAT (SOMEGOAL
    90       (Tactic.match_tac (axclass_intro :: sup_of_classes
    91          @ loc_axiom_intros @ base_sort_trivs)
    92            ORELSE' Tactic.assume_tac));
    93     val of_class = Skip_Proof.prove_global thy [] [] of_class_prop (K tac);
    94 
    95   in (base_morph, eq_morph, export_morph, axiom, assm_intro, of_class) end;
    96 
    97 
    98 (* reading and processing class specifications *)
    99 
   100 fun prep_class_elems prep_decl thy sups raw_elems =
   101   let
   102 
   103     (* user space type system: only permits 'a type variable, improves towards 'a *)
   104     val algebra = Sign.classes_of thy;
   105     val inter_sort = curry (Sorts.inter_sort algebra);
   106     val proto_base_sort = if null sups then Sign.defaultS thy
   107       else fold inter_sort (map (Class.base_sort thy) sups) [];
   108     val base_constraints = (map o apsnd)
   109       (map_type_tfree (K (TVar ((Name.aT, 0), proto_base_sort))) o fst o snd)
   110         (Class.these_operations thy sups);
   111     val reject_bcd_etc = (map o map_atyps) (fn T as TFree (v, sort) =>
   112           if v = Name.aT then T
   113           else error ("No type variable other than " ^ Name.aT ^ " allowed in class specification")
   114       | T => T);
   115     fun singleton_fixate Ts =
   116       let
   117         fun extract f = (fold o fold_atyps) f Ts [];
   118         val tfrees = extract
   119           (fn TFree (v, sort) => insert (op =) (v, sort) | _ => I);
   120         val inferred_sort = extract
   121           (fn TVar (_, sort) => inter_sort sort | _ => I);
   122         val fixate_sort = if null tfrees then inferred_sort
   123           else case tfrees
   124            of [(_, a_sort)] => if Sorts.sort_le algebra (a_sort, inferred_sort)
   125                 then inter_sort a_sort inferred_sort
   126                 else error ("Type inference imposes additional sort constraint "
   127                   ^ Syntax.string_of_sort_global thy inferred_sort
   128                   ^ " of type parameter " ^ Name.aT ^ " of sort "
   129                   ^ Syntax.string_of_sort_global thy a_sort)
   130             | _ => error "Multiple type variables in class specification";
   131       in (map o map_atyps) (K (TFree (Name.aT, fixate_sort))) Ts end;
   132     fun after_infer_fixate Ts =
   133       let
   134         val sort' = (fold o fold_atyps) (fn T as TFree _ => I | T as TVar (vi, sort) =>
   135           if Type_Infer.is_param vi then inter_sort sort else I) Ts [];
   136       in
   137         (map o map_atyps)
   138           (fn T as TFree _ => T | T as TVar (vi, _) =>
   139             if Type_Infer.is_param vi then Type_Infer.param 0 (Name.aT, sort') else T) Ts
   140       end;
   141     fun add_typ_check level name f = Context.proof_map
   142       (Syntax.add_typ_check level name (fn Ts => fn ctxt =>
   143         let val Ts' = f Ts in if eq_list (op =) (Ts, Ts') then NONE else SOME (Ts', ctxt) end));
   144 
   145     (* preprocessing elements, retrieving base sort from type-checked elements *)
   146     val raw_supexpr = (map (fn sup => (sup, (("", false),
   147       Expression.Positional []))) sups, []);
   148     val init_class_body = fold (ProofContext.add_const_constraint o apsnd SOME) base_constraints
   149       #> Class.redeclare_operations thy sups
   150       #> add_typ_check 10 "reject_bcd_etc" reject_bcd_etc
   151       #> add_typ_check ~10 "singleton_fixate" singleton_fixate;
   152     val ((raw_supparams, _, raw_inferred_elems), _) = ProofContext.init_global thy
   153       |> add_typ_check 5 "after_infer_fixate" after_infer_fixate
   154       |> prep_decl raw_supexpr init_class_body raw_elems;
   155     fun filter_element (Element.Fixes []) = NONE
   156       | filter_element (e as Element.Fixes _) = SOME e
   157       | filter_element (Element.Constrains []) = NONE
   158       | filter_element (e as Element.Constrains _) = SOME e
   159       | filter_element (Element.Assumes []) = NONE
   160       | filter_element (e as Element.Assumes _) = SOME e
   161       | filter_element (Element.Defines _) = error ("\"defines\" element not allowed in class specification.")
   162       | filter_element (Element.Notes _) = error ("\"notes\" element not allowed in class specification.");
   163     val inferred_elems = map_filter filter_element raw_inferred_elems;
   164     fun fold_element_types f (Element.Fixes fxs) = fold (fn (_, SOME T, _) => f T) fxs
   165       | fold_element_types f (Element.Constrains cnstrs) = fold (f o snd) cnstrs
   166       | fold_element_types f (Element.Assumes assms) = fold (fold (fn (t, ts) =>
   167           fold_types f t #> (fold o fold_types) f ts) o snd) assms
   168     val base_sort = if null inferred_elems then proto_base_sort else
   169       case (fold o fold_element_types) Term.add_tfreesT inferred_elems []
   170        of [] => error "No type variable in class specification"
   171         | [(_, sort)] => sort
   172         | _ => error "Multiple type variables in class specification";
   173     val supparams = map (fn ((c, T), _) =>
   174       (c, map_atyps (K (TFree (Name.aT, base_sort))) T)) raw_supparams;
   175     val supparam_names = map fst supparams;
   176     fun mk_param ((c, _), _) = Free (c, (the o AList.lookup (op =) supparams) c);
   177     val supexpr = (map (fn sup => (sup, (("", false),
   178       Expression.Positional (map (SOME o mk_param) (Locale.params_of thy sup))))) sups,
   179         map (fn (c, T) => (Binding.name c, SOME T, NoSyn)) supparams);
   180 
   181   in (base_sort, supparam_names, supexpr, inferred_elems) end;
   182 
   183 val cert_class_elems = prep_class_elems Expression.cert_declaration;
   184 val read_class_elems = prep_class_elems Expression.cert_read_declaration;
   185 
   186 fun prep_class_spec prep_class prep_class_elems thy raw_supclasses raw_elems =
   187   let
   188 
   189     (* prepare import *)
   190     val inter_sort = curry (Sorts.inter_sort (Sign.classes_of thy));
   191     val sups = map (prep_class thy) raw_supclasses
   192       |> Sign.minimize_sort thy;
   193     val _ = case filter_out (Class.is_class thy) sups
   194      of [] => ()
   195       | no_classes => error ("No (proper) classes: " ^ commas (map quote no_classes));
   196     val raw_supparams = (map o apsnd) (snd o snd) (Class.these_params thy sups);
   197     val raw_supparam_names = map fst raw_supparams;
   198     val _ = if has_duplicates (op =) raw_supparam_names
   199       then error ("Duplicate parameter(s) in superclasses: "
   200         ^ (commas o map quote o duplicates (op =)) raw_supparam_names)
   201       else ();
   202 
   203     (* infer types and base sort *)
   204     val (base_sort, supparam_names, supexpr, inferred_elems) =
   205       prep_class_elems thy sups raw_elems;
   206     val sup_sort = inter_sort base_sort sups;
   207 
   208     (* process elements as class specification *)
   209     val class_ctxt = Class.begin sups base_sort (ProofContext.init_global thy);
   210     val ((_, _, syntax_elems), _) = class_ctxt
   211       |> Expression.cert_declaration supexpr I inferred_elems;
   212     fun check_vars e vs = if null vs
   213       then error ("No type variable in part of specification element "
   214         ^ (Pretty.string_of o Pretty.chunks) (Element.pretty_ctxt class_ctxt e))
   215       else ();
   216     fun check_element (e as Element.Fixes fxs) =
   217           map (fn (_, SOME T, _) => check_vars e (Term.add_tfreesT T [])) fxs
   218       | check_element (e as Element.Assumes assms) =
   219           maps (fn (_, ts_pss) => map
   220             (fn (t, _) => check_vars e (Term.add_tfrees t [])) ts_pss) assms
   221       | check_element e = [()];
   222     val _ = map check_element syntax_elems;
   223     fun fork_syn (Element.Fixes xs) =
   224           fold_map (fn (c, ty, syn) => cons (c, syn) #> pair (c, ty, NoSyn)) xs
   225           #>> Element.Fixes
   226       | fork_syn x = pair x;
   227     val (elems, global_syntax) = fold_map fork_syn syntax_elems [];
   228 
   229   in (((sups, supparam_names), (sup_sort, base_sort, supexpr)), (elems, global_syntax)) end;
   230 
   231 val cert_class_spec = prep_class_spec (K I) cert_class_elems;
   232 val read_class_spec = prep_class_spec Sign.intern_class read_class_elems;
   233 
   234 
   235 (* class establishment *)
   236 
   237 fun add_consts class base_sort sups supparam_names global_syntax thy =
   238   let
   239     (*FIXME simplify*)
   240     val supconsts = supparam_names
   241       |> AList.make (snd o the o AList.lookup (op =) (Class.these_params thy sups))
   242       |> (map o apsnd o apsnd o map_atyps o K o TFree) (Name.aT, [class]);
   243     val all_params = Locale.params_of thy class;
   244     val raw_params = (snd o chop (length supparam_names)) all_params;
   245     fun add_const ((raw_c, raw_ty), _) thy =
   246       let
   247         val b = Binding.name raw_c;
   248         val c = Sign.full_name thy b;
   249         val ty = map_atyps (K (TFree (Name.aT, base_sort))) raw_ty;
   250         val ty0 = Type.strip_sorts ty;
   251         val ty' = map_atyps (K (TFree (Name.aT, [class]))) ty0;
   252         val syn = (the_default NoSyn o AList.lookup Binding.eq_name global_syntax) b;
   253       in
   254         thy
   255         |> Sign.declare_const ((b, ty0), syn)
   256         |> snd
   257         |> pair ((Name.of_binding b, ty), (c, ty'))
   258       end;
   259   in
   260     thy
   261     |> Sign.add_path (Class.class_prefix class)
   262     |> fold_map add_const raw_params
   263     ||> Sign.restore_naming thy
   264     |-> (fn params => pair (supconsts @ (map o apfst) fst params, params))
   265   end;
   266 
   267 fun adjungate_axclass bname class base_sort sups supsort supparam_names global_syntax thy =
   268   let
   269     (*FIXME simplify*)
   270     fun globalize param_map = map_aterms
   271       (fn Free (v, ty) => Const ((fst o the o AList.lookup (op =) param_map) v, ty)
   272         | t => t);
   273     val raw_pred = Locale.intros_of thy class
   274       |> fst
   275       |> Option.map (Logic.unvarify_global o Logic.strip_imp_concl o Thm.prop_of);
   276     fun get_axiom thy = case (#axioms o AxClass.get_info thy) class
   277      of [] => NONE
   278       | [thm] => SOME thm;
   279   in
   280     thy
   281     |> add_consts class base_sort sups supparam_names global_syntax
   282     |-> (fn (param_map, params) => AxClass.define_class (bname, supsort)
   283           (map (fst o snd) params)
   284           [(Thm.empty_binding, Option.map (globalize param_map) raw_pred |> the_list)]
   285     #> snd
   286     #> `get_axiom
   287     #-> (fn assm_axiom => fold (Sign.add_const_constraint o apsnd SOME o snd) params
   288     #> pair (param_map, params, assm_axiom)))
   289   end;
   290 
   291 fun gen_class prep_class_spec b raw_supclasses raw_elems thy =
   292   let
   293     val class = Sign.full_name thy b;
   294     val (((sups, supparam_names), (supsort, base_sort, supexpr)), (elems, global_syntax)) =
   295       prep_class_spec thy raw_supclasses raw_elems;
   296   in
   297     thy
   298     |> Expression.add_locale b (Binding.qualify true "class" b) supexpr elems
   299     |> snd |> Local_Theory.exit_global
   300     |> adjungate_axclass b class base_sort sups supsort supparam_names global_syntax
   301     ||> Theory.checkpoint
   302     |-> (fn (param_map, params, assm_axiom) =>
   303        `(fn thy => calculate thy class sups base_sort param_map assm_axiom)
   304     #-> (fn (base_morph, eq_morph, export_morph, axiom, assm_intro, of_class) =>
   305        Context.theory_map (Locale.add_registration (class, base_morph)
   306          (Option.map (rpair true) eq_morph) export_morph)
   307     #> Class.register class sups params base_sort base_morph export_morph axiom assm_intro of_class))
   308     |> Named_Target.init class
   309     |> pair class
   310   end;
   311 
   312 in
   313 
   314 val class = gen_class cert_class_spec;
   315 val class_cmd = gen_class read_class_spec;
   316 
   317 end; (*local*)
   318 
   319 
   320 (** subclass relations **)
   321 
   322 local
   323 
   324 fun gen_subclass prep_class do_proof raw_sup lthy =
   325   let
   326     val thy = ProofContext.theory_of lthy;
   327     val proto_sup = prep_class thy raw_sup;
   328     val proto_sub = case Named_Target.peek lthy
   329      of SOME {target, is_class = true, ...} => target
   330       | _ => error "Not in a class target";
   331     val (sub, sup) = AxClass.cert_classrel thy (proto_sub, proto_sup);
   332 
   333     val expr = ([(sup, (("", false), Expression.Positional []))], []);
   334     val (([props], deps, export), goal_ctxt) =
   335       Expression.cert_goal_expression expr lthy;
   336     val some_prop = try the_single props;
   337     val some_dep_morph = try the_single (map snd deps);
   338     fun after_qed some_wit =
   339       ProofContext.background_theory (Class.register_subclass (sub, sup)
   340         some_dep_morph some_wit export)
   341       #> ProofContext.theory_of #> Named_Target.init sub;
   342   in do_proof after_qed some_prop goal_ctxt end;
   343 
   344 fun user_proof after_qed some_prop =
   345   Element.witness_proof (after_qed o try the_single o the_single)
   346     [the_list some_prop];
   347 
   348 fun tactic_proof tac after_qed some_prop ctxt =
   349   after_qed (Option.map
   350     (fn prop => Element.prove_witness ctxt prop tac) some_prop) ctxt;
   351 
   352 in
   353 
   354 val subclass = gen_subclass (K I) user_proof;
   355 fun prove_subclass tac = gen_subclass (K I) (tactic_proof tac);
   356 val subclass_cmd = gen_subclass (ProofContext.read_class o ProofContext.init_global) user_proof;
   357 
   358 end; (*local*)
   359 
   360 end;