src/HOL/Orderings.thy
author haftmann
Sat Sep 29 08:58:51 2007 +0200 (2007-09-29)
changeset 24748 ee0a0eb6b738
parent 24741 a53f5db5acbb
child 24867 e5b55d7be9bb
permissions -rw-r--r--
proper syntax during class specification
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports Set Fun
    10 uses
    11   "~~/src/Provers/order.ML"
    12 begin
    13 
    14 subsection {* Partial orders *}
    15 
    16 class order = ord +
    17   assumes less_le: "x \<^loc>< y \<longleftrightarrow> x \<^loc>\<le> y \<and> x \<noteq> y"
    18   and order_refl [iff]: "x \<^loc>\<le> x"
    19   and order_trans: "x \<^loc>\<le> y \<Longrightarrow> y \<^loc>\<le> z \<Longrightarrow> x \<^loc>\<le> z"
    20   assumes antisym: "x \<^loc>\<le> y \<Longrightarrow> y \<^loc>\<le> x \<Longrightarrow> x = y"
    21 
    22 begin
    23 
    24 notation (input)
    25   less_eq (infix "\<sqsubseteq>" 50)
    26 and
    27   less    (infix "\<sqsubset>" 50)
    28 
    29 text {* Reflexivity. *}
    30 
    31 lemma eq_refl: "x = y \<Longrightarrow> x \<^loc>\<le> y"
    32     -- {* This form is useful with the classical reasoner. *}
    33 by (erule ssubst) (rule order_refl)
    34 
    35 lemma less_irrefl [iff]: "\<not> x \<^loc>< x"
    36 by (simp add: less_le)
    37 
    38 lemma le_less: "x \<^loc>\<le> y \<longleftrightarrow> x \<^loc>< y \<or> x = y"
    39     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    40 by (simp add: less_le) blast
    41 
    42 lemma le_imp_less_or_eq: "x \<^loc>\<le> y \<Longrightarrow> x \<^loc>< y \<or> x = y"
    43 unfolding less_le by blast
    44 
    45 lemma less_imp_le: "x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y"
    46 unfolding less_le by blast
    47 
    48 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    49 by (erule contrapos_pn, erule subst, rule less_irrefl)
    50 
    51 
    52 text {* Useful for simplification, but too risky to include by default. *}
    53 
    54 lemma less_imp_not_eq: "x \<^loc>< y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
    55 by auto
    56 
    57 lemma less_imp_not_eq2: "x \<^loc>< y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
    58 by auto
    59 
    60 
    61 text {* Transitivity rules for calculational reasoning *}
    62 
    63 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<^loc>\<le> b \<Longrightarrow> a \<^loc>< b"
    64 by (simp add: less_le)
    65 
    66 lemma le_neq_trans: "a \<^loc>\<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<^loc>< b"
    67 by (simp add: less_le)
    68 
    69 
    70 text {* Asymmetry. *}
    71 
    72 lemma less_not_sym: "x \<^loc>< y \<Longrightarrow> \<not> (y \<^loc>< x)"
    73 by (simp add: less_le antisym)
    74 
    75 lemma less_asym: "x \<^loc>< y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<^loc>< x) \<Longrightarrow> P"
    76 by (drule less_not_sym, erule contrapos_np) simp
    77 
    78 lemma eq_iff: "x = y \<longleftrightarrow> x \<^loc>\<le> y \<and> y \<^loc>\<le> x"
    79 by (blast intro: antisym)
    80 
    81 lemma antisym_conv: "y \<^loc>\<le> x \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
    82 by (blast intro: antisym)
    83 
    84 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    85 by (erule contrapos_pn, erule subst, rule less_irrefl)
    86 
    87 
    88 text {* Transitivity. *}
    89 
    90 lemma less_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    91 by (simp add: less_le) (blast intro: order_trans antisym)
    92 
    93 lemma le_less_trans: "x \<^loc>\<le> y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    94 by (simp add: less_le) (blast intro: order_trans antisym)
    95 
    96 lemma less_le_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> z \<Longrightarrow> x \<^loc>< z"
    97 by (simp add: less_le) (blast intro: order_trans antisym)
    98 
    99 
   100 text {* Useful for simplification, but too risky to include by default. *}
   101 
   102 lemma less_imp_not_less: "x \<^loc>< y \<Longrightarrow> (\<not> y \<^loc>< x) \<longleftrightarrow> True"
   103 by (blast elim: less_asym)
   104 
   105 lemma less_imp_triv: "x \<^loc>< y \<Longrightarrow> (y \<^loc>< x \<longrightarrow> P) \<longleftrightarrow> True"
   106 by (blast elim: less_asym)
   107 
   108 
   109 text {* Transitivity rules for calculational reasoning *}
   110 
   111 lemma less_asym': "a \<^loc>< b \<Longrightarrow> b \<^loc>< a \<Longrightarrow> P"
   112 by (rule less_asym)
   113 
   114 
   115 text {* Reverse order *}
   116 
   117 lemma order_reverse:
   118   "order (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   119 by unfold_locales
   120    (simp add: less_le, auto intro: antisym order_trans)
   121 
   122 end
   123 
   124 
   125 subsection {* Linear (total) orders *}
   126 
   127 class linorder = order +
   128   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   129 begin
   130 
   131 lemma less_linear: "x \<^loc>< y \<or> x = y \<or> y \<^loc>< x"
   132 unfolding less_le using less_le linear by blast
   133 
   134 lemma le_less_linear: "x \<^loc>\<le> y \<or> y \<^loc>< x"
   135 by (simp add: le_less less_linear)
   136 
   137 lemma le_cases [case_names le ge]:
   138   "(x \<^loc>\<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>\<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   139 using linear by blast
   140 
   141 lemma linorder_cases [case_names less equal greater]:
   142   "(x \<^loc>< y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> P) \<Longrightarrow> P"
   143 using less_linear by blast
   144 
   145 lemma not_less: "\<not> x \<^loc>< y \<longleftrightarrow> y \<^loc>\<le> x"
   146 apply (simp add: less_le)
   147 using linear apply (blast intro: antisym)
   148 done
   149 
   150 lemma not_less_iff_gr_or_eq:
   151  "\<not>(x \<^loc>< y) \<longleftrightarrow> (x \<^loc>> y | x = y)"
   152 apply(simp add:not_less le_less)
   153 apply blast
   154 done
   155 
   156 lemma not_le: "\<not> x \<^loc>\<le> y \<longleftrightarrow> y \<^loc>< x"
   157 apply (simp add: less_le)
   158 using linear apply (blast intro: antisym)
   159 done
   160 
   161 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<^loc>< y \<or> y \<^loc>< x"
   162 by (cut_tac x = x and y = y in less_linear, auto)
   163 
   164 lemma neqE: "x \<noteq> y \<Longrightarrow> (x \<^loc>< y \<Longrightarrow> R) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> R) \<Longrightarrow> R"
   165 by (simp add: neq_iff) blast
   166 
   167 lemma antisym_conv1: "\<not> x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
   168 by (blast intro: antisym dest: not_less [THEN iffD1])
   169 
   170 lemma antisym_conv2: "x \<^loc>\<le> y \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   171 by (blast intro: antisym dest: not_less [THEN iffD1])
   172 
   173 lemma antisym_conv3: "\<not> y \<^loc>< x \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   174 by (blast intro: antisym dest: not_less [THEN iffD1])
   175 
   176 text{*Replacing the old Nat.leI*}
   177 lemma leI: "\<not> x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> x"
   178 unfolding not_less .
   179 
   180 lemma leD: "y \<^loc>\<le> x \<Longrightarrow> \<not> x \<^loc>< y"
   181 unfolding not_less .
   182 
   183 (*FIXME inappropriate name (or delete altogether)*)
   184 lemma not_leE: "\<not> y \<^loc>\<le> x \<Longrightarrow> x \<^loc>< y"
   185 unfolding not_le .
   186 
   187 
   188 text {* Reverse order *}
   189 
   190 lemma linorder_reverse:
   191   "linorder (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   192 by unfold_locales
   193   (simp add: less_le, auto intro: antisym order_trans simp add: linear)
   194 
   195 
   196 text {* min/max *}
   197 
   198 text {* for historic reasons, definitions are done in context ord *}
   199 
   200 definition (in ord)
   201   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   202   [code unfold, code inline del]: "min a b = (if a \<^loc>\<le> b then a else b)"
   203 
   204 definition (in ord)
   205   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   206   [code unfold, code inline del]: "max a b = (if a \<^loc>\<le> b then b else a)"
   207 
   208 lemma min_le_iff_disj:
   209   "min x y \<^loc>\<le> z \<longleftrightarrow> x \<^loc>\<le> z \<or> y \<^loc>\<le> z"
   210 unfolding min_def using linear by (auto intro: order_trans)
   211 
   212 lemma le_max_iff_disj:
   213   "z \<^loc>\<le> max x y \<longleftrightarrow> z \<^loc>\<le> x \<or> z \<^loc>\<le> y"
   214 unfolding max_def using linear by (auto intro: order_trans)
   215 
   216 lemma min_less_iff_disj:
   217   "min x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<or> y \<^loc>< z"
   218 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   219 
   220 lemma less_max_iff_disj:
   221   "z \<^loc>< max x y \<longleftrightarrow> z \<^loc>< x \<or> z \<^loc>< y"
   222 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   223 
   224 lemma min_less_iff_conj [simp]:
   225   "z \<^loc>< min x y \<longleftrightarrow> z \<^loc>< x \<and> z \<^loc>< y"
   226 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   227 
   228 lemma max_less_iff_conj [simp]:
   229   "max x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<and> y \<^loc>< z"
   230 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   231 
   232 lemma split_min [noatp]:
   233   "P (min i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P i) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P j)"
   234 by (simp add: min_def)
   235 
   236 lemma split_max [noatp]:
   237   "P (max i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P j) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P i)"
   238 by (simp add: max_def)
   239 
   240 end
   241 
   242 
   243 subsection {* Reasoning tools setup *}
   244 
   245 ML {*
   246 
   247 signature ORDERS =
   248 sig
   249   val print_structures: Proof.context -> unit
   250   val setup: theory -> theory
   251   val order_tac: thm list -> Proof.context -> int -> tactic
   252 end;
   253 
   254 structure Orders: ORDERS =
   255 struct
   256 
   257 (** Theory and context data **)
   258 
   259 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   260   (s1 = s2) andalso eq_list (op aconv) (ts1, ts2);
   261 
   262 structure Data = GenericDataFun
   263 (
   264   type T = ((string * term list) * Order_Tac.less_arith) list;
   265     (* Order structures:
   266        identifier of the structure, list of operations and record of theorems
   267        needed to set up the transitivity reasoner,
   268        identifier and operations identify the structure uniquely. *)
   269   val empty = [];
   270   val extend = I;
   271   fun merge _ = AList.join struct_eq (K fst);
   272 );
   273 
   274 fun print_structures ctxt =
   275   let
   276     val structs = Data.get (Context.Proof ctxt);
   277     fun pretty_term t = Pretty.block
   278       [Pretty.quote (ProofContext.pretty_term ctxt t), Pretty.brk 1,
   279         Pretty.str "::", Pretty.brk 1,
   280         Pretty.quote (ProofContext.pretty_typ ctxt (type_of t))];
   281     fun pretty_struct ((s, ts), _) = Pretty.block
   282       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   283        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   284   in
   285     Pretty.writeln (Pretty.big_list "Order structures:" (map pretty_struct structs))
   286   end;
   287 
   288 
   289 (** Method **)
   290 
   291 fun struct_tac ((s, [eq, le, less]), thms) prems =
   292   let
   293     fun decomp thy (Trueprop $ t) =
   294       let
   295         fun excluded t =
   296           (* exclude numeric types: linear arithmetic subsumes transitivity *)
   297           let val T = type_of t
   298           in
   299 	    T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   300           end;
   301 	fun rel (bin_op $ t1 $ t2) =
   302               if excluded t1 then NONE
   303               else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   304               else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   305               else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   306               else NONE
   307 	  | rel _ = NONE;
   308 	fun dec (Const (@{const_name Not}, _) $ t) = (case rel t
   309 	      of NONE => NONE
   310 	       | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   311           | dec x = rel x;
   312       in dec t end;
   313   in
   314     case s of
   315       "order" => Order_Tac.partial_tac decomp thms prems
   316     | "linorder" => Order_Tac.linear_tac decomp thms prems
   317     | _ => error ("Unknown kind of order `" ^ s ^ "' encountered in transitivity reasoner.")
   318   end
   319 
   320 fun order_tac prems ctxt =
   321   FIRST' (map (fn s => CHANGED o struct_tac s prems) (Data.get (Context.Proof ctxt)));
   322 
   323 
   324 (** Attribute **)
   325 
   326 fun add_struct_thm s tag =
   327   Thm.declaration_attribute
   328     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   329 fun del_struct s =
   330   Thm.declaration_attribute
   331     (fn _ => Data.map (AList.delete struct_eq s));
   332 
   333 val attribute = Attrib.syntax
   334      (Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) ||
   335           Args.del >> K NONE) --| Args.colon (* FIXME ||
   336         Scan.succeed true *) ) -- Scan.lift Args.name --
   337       Scan.repeat Args.term
   338       >> (fn ((SOME tag, n), ts) => add_struct_thm (n, ts) tag
   339            | ((NONE, n), ts) => del_struct (n, ts)));
   340 
   341 
   342 (** Diagnostic command **)
   343 
   344 val print = Toplevel.unknown_context o
   345   Toplevel.keep (Toplevel.node_case
   346     (Context.cases (print_structures o ProofContext.init) print_structures)
   347     (print_structures o Proof.context_of));
   348 
   349 val printP =
   350   OuterSyntax.improper_command "print_orders"
   351     "print order structures available to transitivity reasoner" OuterKeyword.diag
   352     (Scan.succeed (Toplevel.no_timing o print));
   353 
   354 
   355 (** Setup **)
   356 
   357 val setup = let val _ = OuterSyntax.add_parsers [printP] in
   358     Method.add_methods [("order", Method.ctxt_args (Method.SIMPLE_METHOD' o order_tac []),
   359       "normalisation of algebraic structure")] #>
   360     Attrib.add_attributes [("order", attribute, "theorems controlling transitivity reasoner")]
   361   end;
   362 
   363 end;
   364 
   365 *}
   366 
   367 setup Orders.setup
   368 
   369 
   370 text {* Declarations to set up transitivity reasoner of partial and linear orders. *}
   371 
   372 (* The type constraint on @{term op =} below is necessary since the operation
   373    is not a parameter of the locale. *)
   374 lemmas (in order)
   375   [order add less_reflE: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   376   less_irrefl [THEN notE]
   377 lemmas (in order)
   378   [order add le_refl: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   379   order_refl
   380 lemmas (in order)
   381   [order add less_imp_le: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   382   less_imp_le
   383 lemmas (in order)
   384   [order add eqI: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   385   antisym
   386 lemmas (in order)
   387   [order add eqD1: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   388   eq_refl
   389 lemmas (in order)
   390   [order add eqD2: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   391   sym [THEN eq_refl]
   392 lemmas (in order)
   393   [order add less_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   394   less_trans
   395 lemmas (in order)
   396   [order add less_le_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   397   less_le_trans
   398 lemmas (in order)
   399   [order add le_less_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   400   le_less_trans
   401 lemmas (in order)
   402   [order add le_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   403   order_trans
   404 lemmas (in order)
   405   [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   406   le_neq_trans
   407 lemmas (in order)
   408   [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   409   neq_le_trans
   410 lemmas (in order)
   411   [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   412   less_imp_neq
   413 lemmas (in order)
   414   [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   415    eq_neq_eq_imp_neq
   416 lemmas (in order)
   417   [order add not_sym: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   418   not_sym
   419 
   420 lemmas (in linorder) [order del: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] = _
   421 
   422 lemmas (in linorder)
   423   [order add less_reflE: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   424   less_irrefl [THEN notE]
   425 lemmas (in linorder)
   426   [order add le_refl: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   427   order_refl
   428 lemmas (in linorder)
   429   [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   430   less_imp_le
   431 lemmas (in linorder)
   432   [order add not_lessI: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   433   not_less [THEN iffD2]
   434 lemmas (in linorder)
   435   [order add not_leI: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   436   not_le [THEN iffD2]
   437 lemmas (in linorder)
   438   [order add not_lessD: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   439   not_less [THEN iffD1]
   440 lemmas (in linorder)
   441   [order add not_leD: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   442   not_le [THEN iffD1]
   443 lemmas (in linorder)
   444   [order add eqI: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   445   antisym
   446 lemmas (in linorder)
   447   [order add eqD1: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   448   eq_refl
   449 lemmas (in linorder)
   450   [order add eqD2: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   451   sym [THEN eq_refl]
   452 lemmas (in linorder)
   453   [order add less_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   454   less_trans
   455 lemmas (in linorder)
   456   [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   457   less_le_trans
   458 lemmas (in linorder)
   459   [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   460   le_less_trans
   461 lemmas (in linorder)
   462   [order add le_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   463   order_trans
   464 lemmas (in linorder)
   465   [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   466   le_neq_trans
   467 lemmas (in linorder)
   468   [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   469   neq_le_trans
   470 lemmas (in linorder)
   471   [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   472   less_imp_neq
   473 lemmas (in linorder)
   474   [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   475   eq_neq_eq_imp_neq
   476 lemmas (in linorder)
   477   [order add not_sym: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   478   not_sym
   479 
   480 
   481 setup {*
   482 let
   483 
   484 fun prp t thm = (#prop (rep_thm thm) = t);
   485 
   486 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   487   let val prems = prems_of_ss ss;
   488       val less = Const (@{const_name less}, T);
   489       val t = HOLogic.mk_Trueprop(le $ s $ r);
   490   in case find_first (prp t) prems of
   491        NONE =>
   492          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   493          in case find_first (prp t) prems of
   494               NONE => NONE
   495             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   496          end
   497      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   498   end
   499   handle THM _ => NONE;
   500 
   501 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   502   let val prems = prems_of_ss ss;
   503       val le = Const (@{const_name less_eq}, T);
   504       val t = HOLogic.mk_Trueprop(le $ r $ s);
   505   in case find_first (prp t) prems of
   506        NONE =>
   507          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   508          in case find_first (prp t) prems of
   509               NONE => NONE
   510             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   511          end
   512      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   513   end
   514   handle THM _ => NONE;
   515 
   516 fun add_simprocs procs thy =
   517   (Simplifier.change_simpset_of thy (fn ss => ss
   518     addsimprocs (map (fn (name, raw_ts, proc) =>
   519       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   520 fun add_solver name tac thy =
   521   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   522     (mk_solver' name (fn ss => tac (MetaSimplifier.prems_of_ss ss) (MetaSimplifier.the_context ss)))); thy);
   523 
   524 in
   525   add_simprocs [
   526        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   527        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   528      ]
   529   #> add_solver "Transitivity" Orders.order_tac
   530   (* Adding the transitivity reasoners also as safe solvers showed a slight
   531      speed up, but the reasoning strength appears to be not higher (at least
   532      no breaking of additional proofs in the entire HOL distribution, as
   533      of 5 March 2004, was observed). *)
   534 end
   535 *}
   536 
   537 
   538 subsection {* Dense orders *}
   539 
   540 class dense_linear_order = linorder + 
   541   assumes gt_ex: "\<exists>y. x \<sqsubset> y" 
   542   and lt_ex: "\<exists>y. y \<sqsubset> x"
   543   and dense: "x \<sqsubset> y \<Longrightarrow> (\<exists>z. x \<sqsubset> z \<and> z \<sqsubset> y)"
   544   (*see further theory Dense_Linear_Order*)
   545 
   546 
   547 lemma interval_empty_iff:
   548   fixes x y z :: "'a\<Colon>dense_linear_order"
   549   shows "{y. x < y \<and> y < z} = {} \<longleftrightarrow> \<not> x < z"
   550   by (auto dest: dense)
   551 
   552 subsection {* Name duplicates *}
   553 
   554 lemmas order_less_le = less_le
   555 lemmas order_eq_refl = order_class.eq_refl
   556 lemmas order_less_irrefl = order_class.less_irrefl
   557 lemmas order_le_less = order_class.le_less
   558 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
   559 lemmas order_less_imp_le = order_class.less_imp_le
   560 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
   561 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
   562 lemmas order_neq_le_trans = order_class.neq_le_trans
   563 lemmas order_le_neq_trans = order_class.le_neq_trans
   564 
   565 lemmas order_antisym = antisym
   566 lemmas order_less_not_sym = order_class.less_not_sym
   567 lemmas order_less_asym = order_class.less_asym
   568 lemmas order_eq_iff = order_class.eq_iff
   569 lemmas order_antisym_conv = order_class.antisym_conv
   570 lemmas order_less_trans = order_class.less_trans
   571 lemmas order_le_less_trans = order_class.le_less_trans
   572 lemmas order_less_le_trans = order_class.less_le_trans
   573 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   574 lemmas order_less_imp_triv = order_class.less_imp_triv
   575 lemmas order_less_asym' = order_class.less_asym'
   576 
   577 lemmas linorder_linear = linear
   578 lemmas linorder_less_linear = linorder_class.less_linear
   579 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   580 lemmas linorder_le_cases = linorder_class.le_cases
   581 lemmas linorder_not_less = linorder_class.not_less
   582 lemmas linorder_not_le = linorder_class.not_le
   583 lemmas linorder_neq_iff = linorder_class.neq_iff
   584 lemmas linorder_neqE = linorder_class.neqE
   585 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   586 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   587 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   588 
   589 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj
   590 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj
   591 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj
   592 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj
   593 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj
   594 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj
   595 lemmas split_min = linorder_class.split_min
   596 lemmas split_max = linorder_class.split_max
   597 
   598 
   599 subsection {* Bounded quantifiers *}
   600 
   601 syntax
   602   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   603   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   604   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   605   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   606 
   607   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   608   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   609   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   610   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   611 
   612 syntax (xsymbols)
   613   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   614   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   615   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   616   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   617 
   618   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   619   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   620   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   621   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   622 
   623 syntax (HOL)
   624   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   625   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   626   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   627   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   628 
   629 syntax (HTML output)
   630   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   631   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   632   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   633   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   634 
   635   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   636   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   637   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   638   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   639 
   640 translations
   641   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   642   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   643   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   644   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   645   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   646   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   647   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   648   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   649 
   650 print_translation {*
   651 let
   652   val All_binder = Syntax.binder_name @{const_syntax All};
   653   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   654   val impl = @{const_syntax "op -->"};
   655   val conj = @{const_syntax "op &"};
   656   val less = @{const_syntax less};
   657   val less_eq = @{const_syntax less_eq};
   658 
   659   val trans =
   660    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   661     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   662     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   663     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   664 
   665   fun matches_bound v t = 
   666      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   667               | _ => false
   668   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   669   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   670 
   671   fun tr' q = (q,
   672     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   673       (case AList.lookup (op =) trans (q, c, d) of
   674         NONE => raise Match
   675       | SOME (l, g) =>
   676           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   677           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   678           else raise Match)
   679      | _ => raise Match);
   680 in [tr' All_binder, tr' Ex_binder] end
   681 *}
   682 
   683 
   684 subsection {* Transitivity reasoning *}
   685 
   686 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   687 by (rule subst)
   688 
   689 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   690 by (rule ssubst)
   691 
   692 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   693 by (rule subst)
   694 
   695 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   696 by (rule ssubst)
   697 
   698 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   699   (!!x y. x < y ==> f x < f y) ==> f a < c"
   700 proof -
   701   assume r: "!!x y. x < y ==> f x < f y"
   702   assume "a < b" hence "f a < f b" by (rule r)
   703   also assume "f b < c"
   704   finally (order_less_trans) show ?thesis .
   705 qed
   706 
   707 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   708   (!!x y. x < y ==> f x < f y) ==> a < f c"
   709 proof -
   710   assume r: "!!x y. x < y ==> f x < f y"
   711   assume "a < f b"
   712   also assume "b < c" hence "f b < f c" by (rule r)
   713   finally (order_less_trans) show ?thesis .
   714 qed
   715 
   716 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   717   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   718 proof -
   719   assume r: "!!x y. x <= y ==> f x <= f y"
   720   assume "a <= b" hence "f a <= f b" by (rule r)
   721   also assume "f b < c"
   722   finally (order_le_less_trans) show ?thesis .
   723 qed
   724 
   725 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   726   (!!x y. x < y ==> f x < f y) ==> a < f c"
   727 proof -
   728   assume r: "!!x y. x < y ==> f x < f y"
   729   assume "a <= f b"
   730   also assume "b < c" hence "f b < f c" by (rule r)
   731   finally (order_le_less_trans) show ?thesis .
   732 qed
   733 
   734 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   735   (!!x y. x < y ==> f x < f y) ==> f a < c"
   736 proof -
   737   assume r: "!!x y. x < y ==> f x < f y"
   738   assume "a < b" hence "f a < f b" by (rule r)
   739   also assume "f b <= c"
   740   finally (order_less_le_trans) show ?thesis .
   741 qed
   742 
   743 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   744   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   745 proof -
   746   assume r: "!!x y. x <= y ==> f x <= f y"
   747   assume "a < f b"
   748   also assume "b <= c" hence "f b <= f c" by (rule r)
   749   finally (order_less_le_trans) show ?thesis .
   750 qed
   751 
   752 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   753   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   754 proof -
   755   assume r: "!!x y. x <= y ==> f x <= f y"
   756   assume "a <= f b"
   757   also assume "b <= c" hence "f b <= f c" by (rule r)
   758   finally (order_trans) show ?thesis .
   759 qed
   760 
   761 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   762   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   763 proof -
   764   assume r: "!!x y. x <= y ==> f x <= f y"
   765   assume "a <= b" hence "f a <= f b" by (rule r)
   766   also assume "f b <= c"
   767   finally (order_trans) show ?thesis .
   768 qed
   769 
   770 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   771   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   772 proof -
   773   assume r: "!!x y. x <= y ==> f x <= f y"
   774   assume "a <= b" hence "f a <= f b" by (rule r)
   775   also assume "f b = c"
   776   finally (ord_le_eq_trans) show ?thesis .
   777 qed
   778 
   779 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   780   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   781 proof -
   782   assume r: "!!x y. x <= y ==> f x <= f y"
   783   assume "a = f b"
   784   also assume "b <= c" hence "f b <= f c" by (rule r)
   785   finally (ord_eq_le_trans) show ?thesis .
   786 qed
   787 
   788 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   789   (!!x y. x < y ==> f x < f y) ==> f a < c"
   790 proof -
   791   assume r: "!!x y. x < y ==> f x < f y"
   792   assume "a < b" hence "f a < f b" by (rule r)
   793   also assume "f b = c"
   794   finally (ord_less_eq_trans) show ?thesis .
   795 qed
   796 
   797 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   798   (!!x y. x < y ==> f x < f y) ==> a < f c"
   799 proof -
   800   assume r: "!!x y. x < y ==> f x < f y"
   801   assume "a = f b"
   802   also assume "b < c" hence "f b < f c" by (rule r)
   803   finally (ord_eq_less_trans) show ?thesis .
   804 qed
   805 
   806 text {*
   807   Note that this list of rules is in reverse order of priorities.
   808 *}
   809 
   810 lemmas order_trans_rules [trans] =
   811   order_less_subst2
   812   order_less_subst1
   813   order_le_less_subst2
   814   order_le_less_subst1
   815   order_less_le_subst2
   816   order_less_le_subst1
   817   order_subst2
   818   order_subst1
   819   ord_le_eq_subst
   820   ord_eq_le_subst
   821   ord_less_eq_subst
   822   ord_eq_less_subst
   823   forw_subst
   824   back_subst
   825   rev_mp
   826   mp
   827   order_neq_le_trans
   828   order_le_neq_trans
   829   order_less_trans
   830   order_less_asym'
   831   order_le_less_trans
   832   order_less_le_trans
   833   order_trans
   834   order_antisym
   835   ord_le_eq_trans
   836   ord_eq_le_trans
   837   ord_less_eq_trans
   838   ord_eq_less_trans
   839   trans
   840 
   841 
   842 (* FIXME cleanup *)
   843 
   844 text {* These support proving chains of decreasing inequalities
   845     a >= b >= c ... in Isar proofs. *}
   846 
   847 lemma xt1:
   848   "a = b ==> b > c ==> a > c"
   849   "a > b ==> b = c ==> a > c"
   850   "a = b ==> b >= c ==> a >= c"
   851   "a >= b ==> b = c ==> a >= c"
   852   "(x::'a::order) >= y ==> y >= x ==> x = y"
   853   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   854   "(x::'a::order) > y ==> y >= z ==> x > z"
   855   "(x::'a::order) >= y ==> y > z ==> x > z"
   856   "(a::'a::order) > b ==> b > a ==> P"
   857   "(x::'a::order) > y ==> y > z ==> x > z"
   858   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   859   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   860   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   861   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   862   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   863   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   864 by auto
   865 
   866 lemma xt2:
   867   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   868 by (subgoal_tac "f b >= f c", force, force)
   869 
   870 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   871     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   872 by (subgoal_tac "f a >= f b", force, force)
   873 
   874 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   875   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   876 by (subgoal_tac "f b >= f c", force, force)
   877 
   878 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   879     (!!x y. x > y ==> f x > f y) ==> f a > c"
   880 by (subgoal_tac "f a > f b", force, force)
   881 
   882 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   883     (!!x y. x > y ==> f x > f y) ==> a > f c"
   884 by (subgoal_tac "f b > f c", force, force)
   885 
   886 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   887     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   888 by (subgoal_tac "f a >= f b", force, force)
   889 
   890 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   891     (!!x y. x > y ==> f x > f y) ==> a > f c"
   892 by (subgoal_tac "f b > f c", force, force)
   893 
   894 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   895     (!!x y. x > y ==> f x > f y) ==> f a > c"
   896 by (subgoal_tac "f a > f b", force, force)
   897 
   898 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   899 
   900 (* 
   901   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   902   for the wrong thing in an Isar proof.
   903 
   904   The extra transitivity rules can be used as follows: 
   905 
   906 lemma "(a::'a::order) > z"
   907 proof -
   908   have "a >= b" (is "_ >= ?rhs")
   909     sorry
   910   also have "?rhs >= c" (is "_ >= ?rhs")
   911     sorry
   912   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   913     sorry
   914   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   915     sorry
   916   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   917     sorry
   918   also (xtrans) have "?rhs > z"
   919     sorry
   920   finally (xtrans) show ?thesis .
   921 qed
   922 
   923   Alternatively, one can use "declare xtrans [trans]" and then
   924   leave out the "(xtrans)" above.
   925 *)
   926 
   927 subsection {* Order on bool *}
   928 
   929 instance bool :: order 
   930   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   931   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   932   by intro_classes (auto simp add: le_bool_def less_bool_def)
   933 lemmas [code func del] = le_bool_def less_bool_def
   934 
   935 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   936 by (simp add: le_bool_def)
   937 
   938 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   939 by (simp add: le_bool_def)
   940 
   941 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   942 by (simp add: le_bool_def)
   943 
   944 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   945 by (simp add: le_bool_def)
   946 
   947 lemma [code func]:
   948   "False \<le> b \<longleftrightarrow> True"
   949   "True \<le> b \<longleftrightarrow> b"
   950   "False < b \<longleftrightarrow> b"
   951   "True < b \<longleftrightarrow> False"
   952   unfolding le_bool_def less_bool_def by simp_all
   953 
   954 
   955 subsection {* Order on sets *}
   956 
   957 instance set :: (type) order
   958   by (intro_classes,
   959       (assumption | rule subset_refl subset_trans subset_antisym psubset_eq)+)
   960 
   961 lemmas basic_trans_rules [trans] =
   962   order_trans_rules set_rev_mp set_mp
   963 
   964 
   965 subsection {* Order on functions *}
   966 
   967 instance "fun" :: (type, ord) ord
   968   le_fun_def: "f \<le> g \<equiv> \<forall>x. f x \<le> g x"
   969   less_fun_def: "f < g \<equiv> f \<le> g \<and> f \<noteq> g" ..
   970 
   971 lemmas [code func del] = le_fun_def less_fun_def
   972 
   973 instance "fun" :: (type, order) order
   974   by default
   975     (auto simp add: le_fun_def less_fun_def expand_fun_eq
   976        intro: order_trans order_antisym)
   977 
   978 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
   979   unfolding le_fun_def by simp
   980 
   981 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
   982   unfolding le_fun_def by simp
   983 
   984 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
   985   unfolding le_fun_def by simp
   986 
   987 text {*
   988   Handy introduction and elimination rules for @{text "\<le>"}
   989   on unary and binary predicates
   990 *}
   991 
   992 lemma predicate1I [Pure.intro!, intro!]:
   993   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
   994   shows "P \<le> Q"
   995   apply (rule le_funI)
   996   apply (rule le_boolI)
   997   apply (rule PQ)
   998   apply assumption
   999   done
  1000 
  1001 lemma predicate1D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1002   apply (erule le_funE)
  1003   apply (erule le_boolE)
  1004   apply assumption+
  1005   done
  1006 
  1007 lemma predicate2I [Pure.intro!, intro!]:
  1008   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1009   shows "P \<le> Q"
  1010   apply (rule le_funI)+
  1011   apply (rule le_boolI)
  1012   apply (rule PQ)
  1013   apply assumption
  1014   done
  1015 
  1016 lemma predicate2D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1017   apply (erule le_funE)+
  1018   apply (erule le_boolE)
  1019   apply assumption+
  1020   done
  1021 
  1022 lemma rev_predicate1D: "P x ==> P <= Q ==> Q x"
  1023   by (rule predicate1D)
  1024 
  1025 lemma rev_predicate2D: "P x y ==> P <= Q ==> Q x y"
  1026   by (rule predicate2D)
  1027 
  1028 
  1029 subsection {* Monotonicity, least value operator and min/max *}
  1030 
  1031 locale mono =
  1032   fixes f
  1033   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
  1034 
  1035 lemmas monoI [intro?] = mono.intro
  1036   and monoD [dest?] = mono.mono
  1037 
  1038 lemma LeastI2_order:
  1039   "[| P (x::'a::order);
  1040       !!y. P y ==> x <= y;
  1041       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
  1042    ==> Q (Least P)"
  1043 apply (unfold Least_def)
  1044 apply (rule theI2)
  1045   apply (blast intro: order_antisym)+
  1046 done
  1047 
  1048 lemma Least_mono:
  1049   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1050     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1051     -- {* Courtesy of Stephan Merz *}
  1052   apply clarify
  1053   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
  1054   apply (rule LeastI2_order)
  1055   apply (auto elim: monoD intro!: order_antisym)
  1056   done
  1057 
  1058 lemma Least_equality:
  1059   "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
  1060 apply (simp add: Least_def)
  1061 apply (rule the_equality)
  1062 apply (auto intro!: order_antisym)
  1063 done
  1064 
  1065 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
  1066 by (simp add: min_def)
  1067 
  1068 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
  1069 by (simp add: max_def)
  1070 
  1071 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
  1072 apply (simp add: min_def)
  1073 apply (blast intro: order_antisym)
  1074 done
  1075 
  1076 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
  1077 apply (simp add: max_def)
  1078 apply (blast intro: order_antisym)
  1079 done
  1080 
  1081 lemma min_of_mono:
  1082   "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
  1083 by (simp add: min_def)
  1084 
  1085 lemma max_of_mono:
  1086   "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
  1087 by (simp add: max_def)
  1088 
  1089 
  1090 subsection {* legacy ML bindings *}
  1091 
  1092 ML {*
  1093 val monoI = @{thm monoI};
  1094 *}
  1095 
  1096 end