src/HOL/Divides.thy
author wenzelm
Fri Dec 07 16:25:33 2012 +0100 (2012-12-07)
changeset 50422 ee729dbd1b7f
parent 49962 a8cc904a6820
child 51173 3cbb4e95a565
permissions -rw-r--r--
avoid ML_file in large theory files to improve performance of dependency discovery of main HOL (approx. 1s CPU time) -- relevant for any application using it, e.g. small paper sessions;
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Transfer
    10 begin
    11 
    12 subsection {* Syntactic division operations *}
    13 
    14 class div = dvd +
    15   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    16     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    17 
    18 
    19 subsection {* Abstract division in commutative semirings. *}
    20 
    21 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    22   assumes mod_div_equality: "a div b * b + a mod b = a"
    23     and div_by_0 [simp]: "a div 0 = 0"
    24     and div_0 [simp]: "0 div a = 0"
    25     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    26     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    27 begin
    28 
    29 text {* @{const div} and @{const mod} *}
    30 
    31 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    32   unfolding mult_commute [of b]
    33   by (rule mod_div_equality)
    34 
    35 lemma mod_div_equality': "a mod b + a div b * b = a"
    36   using mod_div_equality [of a b]
    37   by (simp only: add_ac)
    38 
    39 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    40   by (simp add: mod_div_equality)
    41 
    42 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    43   by (simp add: mod_div_equality2)
    44 
    45 lemma mod_by_0 [simp]: "a mod 0 = a"
    46   using mod_div_equality [of a zero] by simp
    47 
    48 lemma mod_0 [simp]: "0 mod a = 0"
    49   using mod_div_equality [of zero a] div_0 by simp
    50 
    51 lemma div_mult_self2 [simp]:
    52   assumes "b \<noteq> 0"
    53   shows "(a + b * c) div b = c + a div b"
    54   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    55 
    56 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    57 proof (cases "b = 0")
    58   case True then show ?thesis by simp
    59 next
    60   case False
    61   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    62     by (simp add: mod_div_equality)
    63   also from False div_mult_self1 [of b a c] have
    64     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    65       by (simp add: algebra_simps)
    66   finally have "a = a div b * b + (a + c * b) mod b"
    67     by (simp add: add_commute [of a] add_assoc distrib_right)
    68   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    69     by (simp add: mod_div_equality)
    70   then show ?thesis by simp
    71 qed
    72 
    73 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    74   by (simp add: mult_commute [of b])
    75 
    76 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    77   using div_mult_self2 [of b 0 a] by simp
    78 
    79 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    80   using div_mult_self1 [of b 0 a] by simp
    81 
    82 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    83   using mod_mult_self2 [of 0 b a] by simp
    84 
    85 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    86   using mod_mult_self1 [of 0 a b] by simp
    87 
    88 lemma div_by_1 [simp]: "a div 1 = a"
    89   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    90 
    91 lemma mod_by_1 [simp]: "a mod 1 = 0"
    92 proof -
    93   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    94   then have "a + a mod 1 = a + 0" by simp
    95   then show ?thesis by (rule add_left_imp_eq)
    96 qed
    97 
    98 lemma mod_self [simp]: "a mod a = 0"
    99   using mod_mult_self2_is_0 [of 1] by simp
   100 
   101 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   102   using div_mult_self2_is_id [of _ 1] by simp
   103 
   104 lemma div_add_self1 [simp]:
   105   assumes "b \<noteq> 0"
   106   shows "(b + a) div b = a div b + 1"
   107   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   108 
   109 lemma div_add_self2 [simp]:
   110   assumes "b \<noteq> 0"
   111   shows "(a + b) div b = a div b + 1"
   112   using assms div_add_self1 [of b a] by (simp add: add_commute)
   113 
   114 lemma mod_add_self1 [simp]:
   115   "(b + a) mod b = a mod b"
   116   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   117 
   118 lemma mod_add_self2 [simp]:
   119   "(a + b) mod b = a mod b"
   120   using mod_mult_self1 [of a 1 b] by simp
   121 
   122 lemma mod_div_decomp:
   123   fixes a b
   124   obtains q r where "q = a div b" and "r = a mod b"
   125     and "a = q * b + r"
   126 proof -
   127   from mod_div_equality have "a = a div b * b + a mod b" by simp
   128   moreover have "a div b = a div b" ..
   129   moreover have "a mod b = a mod b" ..
   130   note that ultimately show thesis by blast
   131 qed
   132 
   133 lemma dvd_eq_mod_eq_0 [code]: "a dvd b \<longleftrightarrow> b mod a = 0"
   134 proof
   135   assume "b mod a = 0"
   136   with mod_div_equality [of b a] have "b div a * a = b" by simp
   137   then have "b = a * (b div a)" unfolding mult_commute ..
   138   then have "\<exists>c. b = a * c" ..
   139   then show "a dvd b" unfolding dvd_def .
   140 next
   141   assume "a dvd b"
   142   then have "\<exists>c. b = a * c" unfolding dvd_def .
   143   then obtain c where "b = a * c" ..
   144   then have "b mod a = a * c mod a" by simp
   145   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   146   then show "b mod a = 0" by simp
   147 qed
   148 
   149 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   150 proof (cases "b = 0")
   151   assume "b = 0"
   152   thus ?thesis by simp
   153 next
   154   assume "b \<noteq> 0"
   155   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   156     by (rule div_mult_self1 [symmetric])
   157   also have "\<dots> = a div b"
   158     by (simp only: mod_div_equality')
   159   also have "\<dots> = a div b + 0"
   160     by simp
   161   finally show ?thesis
   162     by (rule add_left_imp_eq)
   163 qed
   164 
   165 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   166 proof -
   167   have "a mod b mod b = (a mod b + a div b * b) mod b"
   168     by (simp only: mod_mult_self1)
   169   also have "\<dots> = a mod b"
   170     by (simp only: mod_div_equality')
   171   finally show ?thesis .
   172 qed
   173 
   174 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   175 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   176 
   177 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   178 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   179 
   180 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   181 by (drule dvd_div_mult_self) (simp add: mult_commute)
   182 
   183 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   184 apply (cases "a = 0")
   185  apply simp
   186 apply (auto simp: dvd_def mult_assoc)
   187 done
   188 
   189 lemma div_dvd_div[simp]:
   190   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   191 apply (cases "a = 0")
   192  apply simp
   193 apply (unfold dvd_def)
   194 apply auto
   195  apply(blast intro:mult_assoc[symmetric])
   196 apply(fastforce simp add: mult_assoc)
   197 done
   198 
   199 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   200   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   201    apply (simp add: mod_div_equality)
   202   apply (simp only: dvd_add dvd_mult)
   203   done
   204 
   205 text {* Addition respects modular equivalence. *}
   206 
   207 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   208 proof -
   209   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   210     by (simp only: mod_div_equality)
   211   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   212     by (simp only: add_ac)
   213   also have "\<dots> = (a mod c + b) mod c"
   214     by (rule mod_mult_self1)
   215   finally show ?thesis .
   216 qed
   217 
   218 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   219 proof -
   220   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   221     by (simp only: mod_div_equality)
   222   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   223     by (simp only: add_ac)
   224   also have "\<dots> = (a + b mod c) mod c"
   225     by (rule mod_mult_self1)
   226   finally show ?thesis .
   227 qed
   228 
   229 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   230 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   231 
   232 lemma mod_add_cong:
   233   assumes "a mod c = a' mod c"
   234   assumes "b mod c = b' mod c"
   235   shows "(a + b) mod c = (a' + b') mod c"
   236 proof -
   237   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   238     unfolding assms ..
   239   thus ?thesis
   240     by (simp only: mod_add_eq [symmetric])
   241 qed
   242 
   243 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   244   \<Longrightarrow> (x + y) div z = x div z + y div z"
   245 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   246 
   247 text {* Multiplication respects modular equivalence. *}
   248 
   249 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   250 proof -
   251   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   252     by (simp only: mod_div_equality)
   253   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   254     by (simp only: algebra_simps)
   255   also have "\<dots> = (a mod c * b) mod c"
   256     by (rule mod_mult_self1)
   257   finally show ?thesis .
   258 qed
   259 
   260 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   261 proof -
   262   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   263     by (simp only: mod_div_equality)
   264   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   265     by (simp only: algebra_simps)
   266   also have "\<dots> = (a * (b mod c)) mod c"
   267     by (rule mod_mult_self1)
   268   finally show ?thesis .
   269 qed
   270 
   271 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   272 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   273 
   274 lemma mod_mult_cong:
   275   assumes "a mod c = a' mod c"
   276   assumes "b mod c = b' mod c"
   277   shows "(a * b) mod c = (a' * b') mod c"
   278 proof -
   279   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   280     unfolding assms ..
   281   thus ?thesis
   282     by (simp only: mod_mult_eq [symmetric])
   283 qed
   284 
   285 text {* Exponentiation respects modular equivalence. *}
   286 
   287 lemma power_mod: "(a mod b)^n mod b = a^n mod b"
   288 apply (induct n, simp_all)
   289 apply (rule mod_mult_right_eq [THEN trans])
   290 apply (simp (no_asm_simp))
   291 apply (rule mod_mult_eq [symmetric])
   292 done
   293 
   294 lemma mod_mod_cancel:
   295   assumes "c dvd b"
   296   shows "a mod b mod c = a mod c"
   297 proof -
   298   from `c dvd b` obtain k where "b = c * k"
   299     by (rule dvdE)
   300   have "a mod b mod c = a mod (c * k) mod c"
   301     by (simp only: `b = c * k`)
   302   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   303     by (simp only: mod_mult_self1)
   304   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   305     by (simp only: add_ac mult_ac)
   306   also have "\<dots> = a mod c"
   307     by (simp only: mod_div_equality)
   308   finally show ?thesis .
   309 qed
   310 
   311 lemma div_mult_div_if_dvd:
   312   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   313   apply (cases "y = 0", simp)
   314   apply (cases "z = 0", simp)
   315   apply (auto elim!: dvdE simp add: algebra_simps)
   316   apply (subst mult_assoc [symmetric])
   317   apply (simp add: no_zero_divisors)
   318   done
   319 
   320 lemma div_mult_swap:
   321   assumes "c dvd b"
   322   shows "a * (b div c) = (a * b) div c"
   323 proof -
   324   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   325     by (simp only: div_mult_div_if_dvd one_dvd)
   326   then show ?thesis by (simp add: mult_commute)
   327 qed
   328    
   329 lemma div_mult_mult2 [simp]:
   330   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   331   by (drule div_mult_mult1) (simp add: mult_commute)
   332 
   333 lemma div_mult_mult1_if [simp]:
   334   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   335   by simp_all
   336 
   337 lemma mod_mult_mult1:
   338   "(c * a) mod (c * b) = c * (a mod b)"
   339 proof (cases "c = 0")
   340   case True then show ?thesis by simp
   341 next
   342   case False
   343   from mod_div_equality
   344   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   345   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   346     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   347   with mod_div_equality show ?thesis by simp 
   348 qed
   349   
   350 lemma mod_mult_mult2:
   351   "(a * c) mod (b * c) = (a mod b) * c"
   352   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   353 
   354 lemma mult_mod_left: "(a mod b) * c = (a * c) mod (b * c)"
   355   by (fact mod_mult_mult2 [symmetric])
   356 
   357 lemma mult_mod_right: "c * (a mod b) = (c * a) mod (c * b)"
   358   by (fact mod_mult_mult1 [symmetric])
   359 
   360 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   361   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   362 
   363 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   364 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   365 
   366 lemma div_power:
   367   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   368 apply (induct n)
   369  apply simp
   370 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   371 done
   372 
   373 lemma dvd_div_eq_mult:
   374   assumes "a \<noteq> 0" and "a dvd b"  
   375   shows "b div a = c \<longleftrightarrow> b = c * a"
   376 proof
   377   assume "b = c * a"
   378   then show "b div a = c" by (simp add: assms)
   379 next
   380   assume "b div a = c"
   381   then have "b div a * a = c * a" by simp
   382   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   383   ultimately show "b = c * a" by simp
   384 qed
   385    
   386 lemma dvd_div_div_eq_mult:
   387   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   388   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   389   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   390 
   391 end
   392 
   393 class ring_div = semiring_div + comm_ring_1
   394 begin
   395 
   396 subclass ring_1_no_zero_divisors ..
   397 
   398 text {* Negation respects modular equivalence. *}
   399 
   400 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   401 proof -
   402   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   403     by (simp only: mod_div_equality)
   404   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   405     by (simp only: minus_add_distrib minus_mult_left add_ac)
   406   also have "\<dots> = (- (a mod b)) mod b"
   407     by (rule mod_mult_self1)
   408   finally show ?thesis .
   409 qed
   410 
   411 lemma mod_minus_cong:
   412   assumes "a mod b = a' mod b"
   413   shows "(- a) mod b = (- a') mod b"
   414 proof -
   415   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   416     unfolding assms ..
   417   thus ?thesis
   418     by (simp only: mod_minus_eq [symmetric])
   419 qed
   420 
   421 text {* Subtraction respects modular equivalence. *}
   422 
   423 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   424   unfolding diff_minus
   425   by (intro mod_add_cong mod_minus_cong) simp_all
   426 
   427 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   428   unfolding diff_minus
   429   by (intro mod_add_cong mod_minus_cong) simp_all
   430 
   431 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   432   unfolding diff_minus
   433   by (intro mod_add_cong mod_minus_cong) simp_all
   434 
   435 lemma mod_diff_cong:
   436   assumes "a mod c = a' mod c"
   437   assumes "b mod c = b' mod c"
   438   shows "(a - b) mod c = (a' - b') mod c"
   439   unfolding diff_minus using assms
   440   by (intro mod_add_cong mod_minus_cong)
   441 
   442 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   443 apply (case_tac "y = 0") apply simp
   444 apply (auto simp add: dvd_def)
   445 apply (subgoal_tac "-(y * k) = y * - k")
   446  apply (erule ssubst)
   447  apply (erule div_mult_self1_is_id)
   448 apply simp
   449 done
   450 
   451 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   452 apply (case_tac "y = 0") apply simp
   453 apply (auto simp add: dvd_def)
   454 apply (subgoal_tac "y * k = -y * -k")
   455  apply (erule ssubst)
   456  apply (rule div_mult_self1_is_id)
   457  apply simp
   458 apply simp
   459 done
   460 
   461 lemma div_minus_minus [simp]: "(-a) div (-b) = a div b"
   462   using div_mult_mult1 [of "- 1" a b]
   463   unfolding neg_equal_0_iff_equal by simp
   464 
   465 lemma mod_minus_minus [simp]: "(-a) mod (-b) = - (a mod b)"
   466   using mod_mult_mult1 [of "- 1" a b] by simp
   467 
   468 lemma div_minus_right: "a div (-b) = (-a) div b"
   469   using div_minus_minus [of "-a" b] by simp
   470 
   471 lemma mod_minus_right: "a mod (-b) = - ((-a) mod b)"
   472   using mod_minus_minus [of "-a" b] by simp
   473 
   474 lemma div_minus1_right [simp]: "a div (-1) = -a"
   475   using div_minus_right [of a 1] by simp
   476 
   477 lemma mod_minus1_right [simp]: "a mod (-1) = 0"
   478   using mod_minus_right [of a 1] by simp
   479 
   480 end
   481 
   482 
   483 subsection {* Division on @{typ nat} *}
   484 
   485 text {*
   486   We define @{const div} and @{const mod} on @{typ nat} by means
   487   of a characteristic relation with two input arguments
   488   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   489   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   490 *}
   491 
   492 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   493   "divmod_nat_rel m n qr \<longleftrightarrow>
   494     m = fst qr * n + snd qr \<and>
   495       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   496 
   497 text {* @{const divmod_nat_rel} is total: *}
   498 
   499 lemma divmod_nat_rel_ex:
   500   obtains q r where "divmod_nat_rel m n (q, r)"
   501 proof (cases "n = 0")
   502   case True  with that show thesis
   503     by (auto simp add: divmod_nat_rel_def)
   504 next
   505   case False
   506   have "\<exists>q r. m = q * n + r \<and> r < n"
   507   proof (induct m)
   508     case 0 with `n \<noteq> 0`
   509     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   510     then show ?case by blast
   511   next
   512     case (Suc m) then obtain q' r'
   513       where m: "m = q' * n + r'" and n: "r' < n" by auto
   514     then show ?case proof (cases "Suc r' < n")
   515       case True
   516       from m n have "Suc m = q' * n + Suc r'" by simp
   517       with True show ?thesis by blast
   518     next
   519       case False then have "n \<le> Suc r'" by auto
   520       moreover from n have "Suc r' \<le> n" by auto
   521       ultimately have "n = Suc r'" by auto
   522       with m have "Suc m = Suc q' * n + 0" by simp
   523       with `n \<noteq> 0` show ?thesis by blast
   524     qed
   525   qed
   526   with that show thesis
   527     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   528 qed
   529 
   530 text {* @{const divmod_nat_rel} is injective: *}
   531 
   532 lemma divmod_nat_rel_unique:
   533   assumes "divmod_nat_rel m n qr"
   534     and "divmod_nat_rel m n qr'"
   535   shows "qr = qr'"
   536 proof (cases "n = 0")
   537   case True with assms show ?thesis
   538     by (cases qr, cases qr')
   539       (simp add: divmod_nat_rel_def)
   540 next
   541   case False
   542   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   543   apply (rule leI)
   544   apply (subst less_iff_Suc_add)
   545   apply (auto simp add: add_mult_distrib)
   546   done
   547   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   548     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   549   moreover from this assms have "snd qr = snd qr'"
   550     by (simp add: divmod_nat_rel_def)
   551   ultimately show ?thesis by (cases qr, cases qr') simp
   552 qed
   553 
   554 text {*
   555   We instantiate divisibility on the natural numbers by
   556   means of @{const divmod_nat_rel}:
   557 *}
   558 
   559 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   560   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   561 
   562 lemma divmod_nat_rel_divmod_nat:
   563   "divmod_nat_rel m n (divmod_nat m n)"
   564 proof -
   565   from divmod_nat_rel_ex
   566     obtain qr where rel: "divmod_nat_rel m n qr" .
   567   then show ?thesis
   568   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   569 qed
   570 
   571 lemma divmod_nat_unique:
   572   assumes "divmod_nat_rel m n qr" 
   573   shows "divmod_nat m n = qr"
   574   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   575 
   576 instantiation nat :: semiring_div
   577 begin
   578 
   579 definition div_nat where
   580   "m div n = fst (divmod_nat m n)"
   581 
   582 lemma fst_divmod_nat [simp]:
   583   "fst (divmod_nat m n) = m div n"
   584   by (simp add: div_nat_def)
   585 
   586 definition mod_nat where
   587   "m mod n = snd (divmod_nat m n)"
   588 
   589 lemma snd_divmod_nat [simp]:
   590   "snd (divmod_nat m n) = m mod n"
   591   by (simp add: mod_nat_def)
   592 
   593 lemma divmod_nat_div_mod:
   594   "divmod_nat m n = (m div n, m mod n)"
   595   by (simp add: prod_eq_iff)
   596 
   597 lemma div_nat_unique:
   598   assumes "divmod_nat_rel m n (q, r)" 
   599   shows "m div n = q"
   600   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   601 
   602 lemma mod_nat_unique:
   603   assumes "divmod_nat_rel m n (q, r)" 
   604   shows "m mod n = r"
   605   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   606 
   607 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   608   using divmod_nat_rel_divmod_nat by (simp add: divmod_nat_div_mod)
   609 
   610 lemma divmod_nat_zero: "divmod_nat m 0 = (0, m)"
   611   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   612 
   613 lemma divmod_nat_zero_left: "divmod_nat 0 n = (0, 0)"
   614   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   615 
   616 lemma divmod_nat_base: "m < n \<Longrightarrow> divmod_nat m n = (0, m)"
   617   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   618 
   619 lemma divmod_nat_step:
   620   assumes "0 < n" and "n \<le> m"
   621   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   622 proof (rule divmod_nat_unique)
   623   have "divmod_nat_rel (m - n) n ((m - n) div n, (m - n) mod n)"
   624     by (rule divmod_nat_rel)
   625   thus "divmod_nat_rel m n (Suc ((m - n) div n), (m - n) mod n)"
   626     unfolding divmod_nat_rel_def using assms by auto
   627 qed
   628 
   629 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   630 
   631 lemma div_less [simp]:
   632   fixes m n :: nat
   633   assumes "m < n"
   634   shows "m div n = 0"
   635   using assms divmod_nat_base by (simp add: prod_eq_iff)
   636 
   637 lemma le_div_geq:
   638   fixes m n :: nat
   639   assumes "0 < n" and "n \<le> m"
   640   shows "m div n = Suc ((m - n) div n)"
   641   using assms divmod_nat_step by (simp add: prod_eq_iff)
   642 
   643 lemma mod_less [simp]:
   644   fixes m n :: nat
   645   assumes "m < n"
   646   shows "m mod n = m"
   647   using assms divmod_nat_base by (simp add: prod_eq_iff)
   648 
   649 lemma le_mod_geq:
   650   fixes m n :: nat
   651   assumes "n \<le> m"
   652   shows "m mod n = (m - n) mod n"
   653   using assms divmod_nat_step by (cases "n = 0") (simp_all add: prod_eq_iff)
   654 
   655 instance proof
   656   fix m n :: nat
   657   show "m div n * n + m mod n = m"
   658     using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   659 next
   660   fix m n q :: nat
   661   assume "n \<noteq> 0"
   662   then show "(q + m * n) div n = m + q div n"
   663     by (induct m) (simp_all add: le_div_geq)
   664 next
   665   fix m n q :: nat
   666   assume "m \<noteq> 0"
   667   hence "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   668     unfolding divmod_nat_rel_def
   669     by (auto split: split_if_asm, simp_all add: algebra_simps)
   670   moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   671   ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   672   thus "(m * n) div (m * q) = n div q" by (rule div_nat_unique)
   673 next
   674   fix n :: nat show "n div 0 = 0"
   675     by (simp add: div_nat_def divmod_nat_zero)
   676 next
   677   fix n :: nat show "0 div n = 0"
   678     by (simp add: div_nat_def divmod_nat_zero_left)
   679 qed
   680 
   681 end
   682 
   683 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   684   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   685   by (simp add: prod_eq_iff prod_case_beta not_less le_div_geq le_mod_geq)
   686 
   687 text {* Simproc for cancelling @{const div} and @{const mod} *}
   688 
   689 ML {*
   690 structure Cancel_Div_Mod_Nat = Cancel_Div_Mod
   691 (
   692   val div_name = @{const_name div};
   693   val mod_name = @{const_name mod};
   694   val mk_binop = HOLogic.mk_binop;
   695   val mk_plus = HOLogic.mk_binop @{const_name Groups.plus};
   696   val dest_plus = HOLogic.dest_bin @{const_name Groups.plus} HOLogic.natT;
   697   fun mk_sum [] = HOLogic.zero
   698     | mk_sum [t] = t
   699     | mk_sum (t :: ts) = mk_plus (t, mk_sum ts);
   700   fun dest_sum tm =
   701     if HOLogic.is_zero tm then []
   702     else
   703       (case try HOLogic.dest_Suc tm of
   704         SOME t => HOLogic.Suc_zero :: dest_sum t
   705       | NONE =>
   706           (case try dest_plus tm of
   707             SOME (t, u) => dest_sum t @ dest_sum u
   708           | NONE => [tm]));
   709 
   710   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   711 
   712   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   713     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   714 )
   715 *}
   716 
   717 simproc_setup cancel_div_mod_nat ("(m::nat) + n") = {* K Cancel_Div_Mod_Nat.proc *}
   718 
   719 
   720 subsubsection {* Quotient *}
   721 
   722 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   723 by (simp add: le_div_geq linorder_not_less)
   724 
   725 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   726 by (simp add: div_geq)
   727 
   728 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   729 by simp
   730 
   731 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   732 by simp
   733 
   734 
   735 subsubsection {* Remainder *}
   736 
   737 lemma mod_less_divisor [simp]:
   738   fixes m n :: nat
   739   assumes "n > 0"
   740   shows "m mod n < (n::nat)"
   741   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   742 
   743 lemma mod_less_eq_dividend [simp]:
   744   fixes m n :: nat
   745   shows "m mod n \<le> m"
   746 proof (rule add_leD2)
   747   from mod_div_equality have "m div n * n + m mod n = m" .
   748   then show "m div n * n + m mod n \<le> m" by auto
   749 qed
   750 
   751 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   752 by (simp add: le_mod_geq linorder_not_less)
   753 
   754 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   755 by (simp add: le_mod_geq)
   756 
   757 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   758 by (induct m) (simp_all add: mod_geq)
   759 
   760 (* a simple rearrangement of mod_div_equality: *)
   761 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   762   using mod_div_equality2 [of n m] by arith
   763 
   764 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   765   apply (drule mod_less_divisor [where m = m])
   766   apply simp
   767   done
   768 
   769 subsubsection {* Quotient and Remainder *}
   770 
   771 lemma divmod_nat_rel_mult1_eq:
   772   "divmod_nat_rel b c (q, r)
   773    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   774 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   775 
   776 lemma div_mult1_eq:
   777   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   778 by (blast intro: divmod_nat_rel_mult1_eq [THEN div_nat_unique] divmod_nat_rel)
   779 
   780 lemma divmod_nat_rel_add1_eq:
   781   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br)
   782    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   783 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   784 
   785 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   786 lemma div_add1_eq:
   787   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   788 by (blast intro: divmod_nat_rel_add1_eq [THEN div_nat_unique] divmod_nat_rel)
   789 
   790 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   791   apply (cut_tac m = q and n = c in mod_less_divisor)
   792   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   793   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   794   apply (simp add: add_mult_distrib2)
   795   done
   796 
   797 lemma divmod_nat_rel_mult2_eq:
   798   "divmod_nat_rel a b (q, r)
   799    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   800 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   801 
   802 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   803 by (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_nat_unique])
   804 
   805 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   806 by (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_nat_unique])
   807 
   808 
   809 subsubsection {* Further Facts about Quotient and Remainder *}
   810 
   811 lemma div_1 [simp]: "m div Suc 0 = m"
   812 by (induct m) (simp_all add: div_geq)
   813 
   814 (* Monotonicity of div in first argument *)
   815 lemma div_le_mono [rule_format (no_asm)]:
   816     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   817 apply (case_tac "k=0", simp)
   818 apply (induct "n" rule: nat_less_induct, clarify)
   819 apply (case_tac "n<k")
   820 (* 1  case n<k *)
   821 apply simp
   822 (* 2  case n >= k *)
   823 apply (case_tac "m<k")
   824 (* 2.1  case m<k *)
   825 apply simp
   826 (* 2.2  case m>=k *)
   827 apply (simp add: div_geq diff_le_mono)
   828 done
   829 
   830 (* Antimonotonicity of div in second argument *)
   831 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   832 apply (subgoal_tac "0<n")
   833  prefer 2 apply simp
   834 apply (induct_tac k rule: nat_less_induct)
   835 apply (rename_tac "k")
   836 apply (case_tac "k<n", simp)
   837 apply (subgoal_tac "~ (k<m) ")
   838  prefer 2 apply simp
   839 apply (simp add: div_geq)
   840 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   841  prefer 2
   842  apply (blast intro: div_le_mono diff_le_mono2)
   843 apply (rule le_trans, simp)
   844 apply (simp)
   845 done
   846 
   847 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   848 apply (case_tac "n=0", simp)
   849 apply (subgoal_tac "m div n \<le> m div 1", simp)
   850 apply (rule div_le_mono2)
   851 apply (simp_all (no_asm_simp))
   852 done
   853 
   854 (* Similar for "less than" *)
   855 lemma div_less_dividend [simp]:
   856   "\<lbrakk>(1::nat) < n; 0 < m\<rbrakk> \<Longrightarrow> m div n < m"
   857 apply (induct m rule: nat_less_induct)
   858 apply (rename_tac "m")
   859 apply (case_tac "m<n", simp)
   860 apply (subgoal_tac "0<n")
   861  prefer 2 apply simp
   862 apply (simp add: div_geq)
   863 apply (case_tac "n<m")
   864  apply (subgoal_tac "(m-n) div n < (m-n) ")
   865   apply (rule impI less_trans_Suc)+
   866 apply assumption
   867   apply (simp_all)
   868 done
   869 
   870 text{*A fact for the mutilated chess board*}
   871 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   872 apply (case_tac "n=0", simp)
   873 apply (induct "m" rule: nat_less_induct)
   874 apply (case_tac "Suc (na) <n")
   875 (* case Suc(na) < n *)
   876 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   877 (* case n \<le> Suc(na) *)
   878 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   879 apply (auto simp add: Suc_diff_le le_mod_geq)
   880 done
   881 
   882 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   883 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   884 
   885 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   886 
   887 (*Loses information, namely we also have r<d provided d is nonzero*)
   888 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   889   apply (cut_tac a = m in mod_div_equality)
   890   apply (simp only: add_ac)
   891   apply (blast intro: sym)
   892   done
   893 
   894 lemma split_div:
   895  "P(n div k :: nat) =
   896  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   897  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   898 proof
   899   assume P: ?P
   900   show ?Q
   901   proof (cases)
   902     assume "k = 0"
   903     with P show ?Q by simp
   904   next
   905     assume not0: "k \<noteq> 0"
   906     thus ?Q
   907     proof (simp, intro allI impI)
   908       fix i j
   909       assume n: "n = k*i + j" and j: "j < k"
   910       show "P i"
   911       proof (cases)
   912         assume "i = 0"
   913         with n j P show "P i" by simp
   914       next
   915         assume "i \<noteq> 0"
   916         with not0 n j P show "P i" by(simp add:add_ac)
   917       qed
   918     qed
   919   qed
   920 next
   921   assume Q: ?Q
   922   show ?P
   923   proof (cases)
   924     assume "k = 0"
   925     with Q show ?P by simp
   926   next
   927     assume not0: "k \<noteq> 0"
   928     with Q have R: ?R by simp
   929     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   930     show ?P by simp
   931   qed
   932 qed
   933 
   934 lemma split_div_lemma:
   935   assumes "0 < n"
   936   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   937 proof
   938   assume ?rhs
   939   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   940   then have A: "n * q \<le> m" by simp
   941   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   942   then have "m < m + (n - (m mod n))" by simp
   943   then have "m < n + (m - (m mod n))" by simp
   944   with nq have "m < n + n * q" by simp
   945   then have B: "m < n * Suc q" by simp
   946   from A B show ?lhs ..
   947 next
   948   assume P: ?lhs
   949   then have "divmod_nat_rel m n (q, m - n * q)"
   950     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   951   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   952   have "(q, m - n * q) = (m div n, m mod n)" by auto
   953   then show ?rhs by simp
   954 qed
   955 
   956 theorem split_div':
   957   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   958    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   959   apply (case_tac "0 < n")
   960   apply (simp only: add: split_div_lemma)
   961   apply simp_all
   962   done
   963 
   964 lemma split_mod:
   965  "P(n mod k :: nat) =
   966  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   967  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   968 proof
   969   assume P: ?P
   970   show ?Q
   971   proof (cases)
   972     assume "k = 0"
   973     with P show ?Q by simp
   974   next
   975     assume not0: "k \<noteq> 0"
   976     thus ?Q
   977     proof (simp, intro allI impI)
   978       fix i j
   979       assume "n = k*i + j" "j < k"
   980       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   981     qed
   982   qed
   983 next
   984   assume Q: ?Q
   985   show ?P
   986   proof (cases)
   987     assume "k = 0"
   988     with Q show ?P by simp
   989   next
   990     assume not0: "k \<noteq> 0"
   991     with Q have R: ?R by simp
   992     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   993     show ?P by simp
   994   qed
   995 qed
   996 
   997 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
   998   using mod_div_equality [of m n] by arith
   999 
  1000 lemma div_mod_equality': "(m::nat) div n * n = m - m mod n"
  1001   using mod_div_equality [of m n] by arith
  1002 (* FIXME: very similar to mult_div_cancel *)
  1003 
  1004 
  1005 subsubsection {* An ``induction'' law for modulus arithmetic. *}
  1006 
  1007 lemma mod_induct_0:
  1008   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1009   and base: "P i" and i: "i<p"
  1010   shows "P 0"
  1011 proof (rule ccontr)
  1012   assume contra: "\<not>(P 0)"
  1013   from i have p: "0<p" by simp
  1014   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1015   proof
  1016     fix k
  1017     show "?A k"
  1018     proof (induct k)
  1019       show "?A 0" by simp  -- "by contradiction"
  1020     next
  1021       fix n
  1022       assume ih: "?A n"
  1023       show "?A (Suc n)"
  1024       proof (clarsimp)
  1025         assume y: "P (p - Suc n)"
  1026         have n: "Suc n < p"
  1027         proof (rule ccontr)
  1028           assume "\<not>(Suc n < p)"
  1029           hence "p - Suc n = 0"
  1030             by simp
  1031           with y contra show "False"
  1032             by simp
  1033         qed
  1034         hence n2: "Suc (p - Suc n) = p-n" by arith
  1035         from p have "p - Suc n < p" by arith
  1036         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1037           by blast
  1038         show "False"
  1039         proof (cases "n=0")
  1040           case True
  1041           with z n2 contra show ?thesis by simp
  1042         next
  1043           case False
  1044           with p have "p-n < p" by arith
  1045           with z n2 False ih show ?thesis by simp
  1046         qed
  1047       qed
  1048     qed
  1049   qed
  1050   moreover
  1051   from i obtain k where "0<k \<and> i+k=p"
  1052     by (blast dest: less_imp_add_positive)
  1053   hence "0<k \<and> i=p-k" by auto
  1054   moreover
  1055   note base
  1056   ultimately
  1057   show "False" by blast
  1058 qed
  1059 
  1060 lemma mod_induct:
  1061   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1062   and base: "P i" and i: "i<p" and j: "j<p"
  1063   shows "P j"
  1064 proof -
  1065   have "\<forall>j<p. P j"
  1066   proof
  1067     fix j
  1068     show "j<p \<longrightarrow> P j" (is "?A j")
  1069     proof (induct j)
  1070       from step base i show "?A 0"
  1071         by (auto elim: mod_induct_0)
  1072     next
  1073       fix k
  1074       assume ih: "?A k"
  1075       show "?A (Suc k)"
  1076       proof
  1077         assume suc: "Suc k < p"
  1078         hence k: "k<p" by simp
  1079         with ih have "P k" ..
  1080         with step k have "P (Suc k mod p)"
  1081           by blast
  1082         moreover
  1083         from suc have "Suc k mod p = Suc k"
  1084           by simp
  1085         ultimately
  1086         show "P (Suc k)" by simp
  1087       qed
  1088     qed
  1089   qed
  1090   with j show ?thesis by blast
  1091 qed
  1092 
  1093 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1094   by (simp add: numeral_2_eq_2 le_div_geq)
  1095 
  1096 lemma mod2_Suc_Suc [simp]: "Suc (Suc m) mod 2 = m mod 2"
  1097   by (simp add: numeral_2_eq_2 le_mod_geq)
  1098 
  1099 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1100 by (simp add: mult_2 [symmetric])
  1101 
  1102 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1103 proof -
  1104   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1105   moreover have "m mod 2 < 2" by simp
  1106   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1107   then show ?thesis by auto
  1108 qed
  1109 
  1110 text{*These lemmas collapse some needless occurrences of Suc:
  1111     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1112     We already have some rules to simplify operands smaller than 3.*}
  1113 
  1114 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1115 by (simp add: Suc3_eq_add_3)
  1116 
  1117 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1118 by (simp add: Suc3_eq_add_3)
  1119 
  1120 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1121 by (simp add: Suc3_eq_add_3)
  1122 
  1123 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1124 by (simp add: Suc3_eq_add_3)
  1125 
  1126 lemmas Suc_div_eq_add3_div_numeral [simp] = Suc_div_eq_add3_div [of _ "numeral v"] for v
  1127 lemmas Suc_mod_eq_add3_mod_numeral [simp] = Suc_mod_eq_add3_mod [of _ "numeral v"] for v
  1128 
  1129 
  1130 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1131 apply (induct "m")
  1132 apply (simp_all add: mod_Suc)
  1133 done
  1134 
  1135 declare Suc_times_mod_eq [of "numeral w", simp] for w
  1136 
  1137 lemma Suc_div_le_mono [simp]: "n div k \<le> (Suc n) div k"
  1138 by (simp add: div_le_mono)
  1139 
  1140 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1141 by (cases n) simp_all
  1142 
  1143 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1144 proof -
  1145   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1146   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1147 qed
  1148 
  1149   (* Potential use of algebra : Equality modulo n*)
  1150 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1151 by (simp add: mult_ac add_ac)
  1152 
  1153 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1154 proof -
  1155   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1156   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1157   finally show ?thesis .
  1158 qed
  1159 
  1160 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1161 apply (subst mod_Suc [of m]) 
  1162 apply (subst mod_Suc [of "m mod n"], simp) 
  1163 done
  1164 
  1165 lemma mod_2_not_eq_zero_eq_one_nat:
  1166   fixes n :: nat
  1167   shows "n mod 2 \<noteq> 0 \<longleftrightarrow> n mod 2 = 1"
  1168   by simp
  1169 
  1170 
  1171 subsection {* Division on @{typ int} *}
  1172 
  1173 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1174     --{*definition of quotient and remainder*}
  1175   "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1176     (if 0 < b then 0 \<le> r \<and> r < b else if b < 0 then b < r \<and> r \<le> 0 else q = 0))"
  1177 
  1178 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1179     --{*for the division algorithm*}
  1180     "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1181                          else (2 * q, r))"
  1182 
  1183 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1184 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1185   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1186      else adjust b (posDivAlg a (2 * b)))"
  1187 by auto
  1188 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1189   (auto simp add: mult_2)
  1190 
  1191 text{*algorithm for the case @{text "a<0, b>0"}*}
  1192 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1193   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1194      else adjust b (negDivAlg a (2 * b)))"
  1195 by auto
  1196 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1197   (auto simp add: mult_2)
  1198 
  1199 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1200 
  1201 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1202     --{*The full division algorithm considers all possible signs for a, b
  1203        including the special case @{text "a=0, b<0"} because 
  1204        @{term negDivAlg} requires @{term "a<0"}.*}
  1205   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1206                   else if a = 0 then (0, 0)
  1207                        else apsnd uminus (negDivAlg (-a) (-b))
  1208                else 
  1209                   if 0 < b then negDivAlg a b
  1210                   else apsnd uminus (posDivAlg (-a) (-b)))"
  1211 
  1212 instantiation int :: Divides.div
  1213 begin
  1214 
  1215 definition div_int where
  1216   "a div b = fst (divmod_int a b)"
  1217 
  1218 lemma fst_divmod_int [simp]:
  1219   "fst (divmod_int a b) = a div b"
  1220   by (simp add: div_int_def)
  1221 
  1222 definition mod_int where
  1223   "a mod b = snd (divmod_int a b)"
  1224 
  1225 lemma snd_divmod_int [simp]:
  1226   "snd (divmod_int a b) = a mod b"
  1227   by (simp add: mod_int_def)
  1228 
  1229 instance ..
  1230 
  1231 end
  1232 
  1233 lemma divmod_int_mod_div:
  1234   "divmod_int p q = (p div q, p mod q)"
  1235   by (simp add: prod_eq_iff)
  1236 
  1237 text{*
  1238 Here is the division algorithm in ML:
  1239 
  1240 \begin{verbatim}
  1241     fun posDivAlg (a,b) =
  1242       if a<b then (0,a)
  1243       else let val (q,r) = posDivAlg(a, 2*b)
  1244                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1245            end
  1246 
  1247     fun negDivAlg (a,b) =
  1248       if 0\<le>a+b then (~1,a+b)
  1249       else let val (q,r) = negDivAlg(a, 2*b)
  1250                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1251            end;
  1252 
  1253     fun negateSnd (q,r:int) = (q,~r);
  1254 
  1255     fun divmod (a,b) = if 0\<le>a then 
  1256                           if b>0 then posDivAlg (a,b) 
  1257                            else if a=0 then (0,0)
  1258                                 else negateSnd (negDivAlg (~a,~b))
  1259                        else 
  1260                           if 0<b then negDivAlg (a,b)
  1261                           else        negateSnd (posDivAlg (~a,~b));
  1262 \end{verbatim}
  1263 *}
  1264 
  1265 
  1266 subsubsection {* Uniqueness and Monotonicity of Quotients and Remainders *}
  1267 
  1268 lemma unique_quotient_lemma:
  1269      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1270       ==> q' \<le> (q::int)"
  1271 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1272  prefer 2 apply (simp add: right_diff_distrib)
  1273 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1274 apply (erule_tac [2] order_le_less_trans)
  1275  prefer 2 apply (simp add: right_diff_distrib distrib_left)
  1276 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1277  prefer 2 apply (simp add: right_diff_distrib distrib_left)
  1278 apply (simp add: mult_less_cancel_left)
  1279 done
  1280 
  1281 lemma unique_quotient_lemma_neg:
  1282      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1283       ==> q \<le> (q'::int)"
  1284 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1285     auto)
  1286 
  1287 lemma unique_quotient:
  1288      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1289       ==> q = q'"
  1290 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1291 apply (blast intro: order_antisym
  1292              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1293              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1294 done
  1295 
  1296 
  1297 lemma unique_remainder:
  1298      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1299       ==> r = r'"
  1300 apply (subgoal_tac "q = q'")
  1301  apply (simp add: divmod_int_rel_def)
  1302 apply (blast intro: unique_quotient)
  1303 done
  1304 
  1305 
  1306 subsubsection {* Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends *}
  1307 
  1308 text{*And positive divisors*}
  1309 
  1310 lemma adjust_eq [simp]:
  1311      "adjust b (q, r) = 
  1312       (let diff = r - b in  
  1313         if 0 \<le> diff then (2 * q + 1, diff)   
  1314                      else (2*q, r))"
  1315   by (simp add: Let_def adjust_def)
  1316 
  1317 declare posDivAlg.simps [simp del]
  1318 
  1319 text{*use with a simproc to avoid repeatedly proving the premise*}
  1320 lemma posDivAlg_eqn:
  1321      "0 < b ==>  
  1322       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1323 by (rule posDivAlg.simps [THEN trans], simp)
  1324 
  1325 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1326 theorem posDivAlg_correct:
  1327   assumes "0 \<le> a" and "0 < b"
  1328   shows "divmod_int_rel a b (posDivAlg a b)"
  1329   using assms
  1330   apply (induct a b rule: posDivAlg.induct)
  1331   apply auto
  1332   apply (simp add: divmod_int_rel_def)
  1333   apply (subst posDivAlg_eqn, simp add: distrib_left)
  1334   apply (case_tac "a < b")
  1335   apply simp_all
  1336   apply (erule splitE)
  1337   apply (auto simp add: distrib_left Let_def mult_ac mult_2_right)
  1338   done
  1339 
  1340 
  1341 subsubsection {* Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends *}
  1342 
  1343 text{*And positive divisors*}
  1344 
  1345 declare negDivAlg.simps [simp del]
  1346 
  1347 text{*use with a simproc to avoid repeatedly proving the premise*}
  1348 lemma negDivAlg_eqn:
  1349      "0 < b ==>  
  1350       negDivAlg a b =       
  1351        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1352 by (rule negDivAlg.simps [THEN trans], simp)
  1353 
  1354 (*Correctness of negDivAlg: it computes quotients correctly
  1355   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1356 lemma negDivAlg_correct:
  1357   assumes "a < 0" and "b > 0"
  1358   shows "divmod_int_rel a b (negDivAlg a b)"
  1359   using assms
  1360   apply (induct a b rule: negDivAlg.induct)
  1361   apply (auto simp add: linorder_not_le)
  1362   apply (simp add: divmod_int_rel_def)
  1363   apply (subst negDivAlg_eqn, assumption)
  1364   apply (case_tac "a + b < (0\<Colon>int)")
  1365   apply simp_all
  1366   apply (erule splitE)
  1367   apply (auto simp add: distrib_left Let_def mult_ac mult_2_right)
  1368   done
  1369 
  1370 
  1371 subsubsection {* Existence Shown by Proving the Division Algorithm to be Correct *}
  1372 
  1373 (*the case a=0*)
  1374 lemma divmod_int_rel_0: "divmod_int_rel 0 b (0, 0)"
  1375 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1376 
  1377 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1378 by (subst posDivAlg.simps, auto)
  1379 
  1380 lemma posDivAlg_0_right [simp]: "posDivAlg a 0 = (0, a)"
  1381 by (subst posDivAlg.simps, auto)
  1382 
  1383 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1384 by (subst negDivAlg.simps, auto)
  1385 
  1386 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (apsnd uminus qr)"
  1387 by (auto simp add: divmod_int_rel_def)
  1388 
  1389 lemma divmod_int_correct: "divmod_int_rel a b (divmod_int a b)"
  1390 apply (cases "b = 0", simp add: divmod_int_def divmod_int_rel_def)
  1391 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1392                     posDivAlg_correct negDivAlg_correct)
  1393 
  1394 lemma divmod_int_unique:
  1395   assumes "divmod_int_rel a b qr" 
  1396   shows "divmod_int a b = qr"
  1397   using assms divmod_int_correct [of a b]
  1398   using unique_quotient [of a b] unique_remainder [of a b]
  1399   by (metis pair_collapse)
  1400 
  1401 lemma divmod_int_rel_div_mod: "divmod_int_rel a b (a div b, a mod b)"
  1402   using divmod_int_correct by (simp add: divmod_int_mod_div)
  1403 
  1404 lemma div_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a div b = q"
  1405   by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1406 
  1407 lemma mod_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a mod b = r"
  1408   by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1409 
  1410 instance int :: ring_div
  1411 proof
  1412   fix a b :: int
  1413   show "a div b * b + a mod b = a"
  1414     using divmod_int_rel_div_mod [of a b]
  1415     unfolding divmod_int_rel_def by (simp add: mult_commute)
  1416 next
  1417   fix a b c :: int
  1418   assume "b \<noteq> 0"
  1419   hence "divmod_int_rel (a + c * b) b (c + a div b, a mod b)"
  1420     using divmod_int_rel_div_mod [of a b]
  1421     unfolding divmod_int_rel_def by (auto simp: algebra_simps)
  1422   thus "(a + c * b) div b = c + a div b"
  1423     by (rule div_int_unique)
  1424 next
  1425   fix a b c :: int
  1426   assume "c \<noteq> 0"
  1427   hence "\<And>q r. divmod_int_rel a b (q, r)
  1428     \<Longrightarrow> divmod_int_rel (c * a) (c * b) (q, c * r)"
  1429     unfolding divmod_int_rel_def
  1430     by - (rule linorder_cases [of 0 b], auto simp: algebra_simps
  1431       mult_less_0_iff zero_less_mult_iff mult_strict_right_mono
  1432       mult_strict_right_mono_neg zero_le_mult_iff mult_le_0_iff)
  1433   hence "divmod_int_rel (c * a) (c * b) (a div b, c * (a mod b))"
  1434     using divmod_int_rel_div_mod [of a b] .
  1435   thus "(c * a) div (c * b) = a div b"
  1436     by (rule div_int_unique)
  1437 next
  1438   fix a :: int show "a div 0 = 0"
  1439     by (rule div_int_unique, simp add: divmod_int_rel_def)
  1440 next
  1441   fix a :: int show "0 div a = 0"
  1442     by (rule div_int_unique, auto simp add: divmod_int_rel_def)
  1443 qed
  1444 
  1445 text{*Basic laws about division and remainder*}
  1446 
  1447 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1448   by (fact mod_div_equality2 [symmetric])
  1449 
  1450 text {* Tool setup *}
  1451 
  1452 (* FIXME: Theorem list add_0s doesn't exist, because Numeral0 has gone. *)
  1453 lemmas add_0s = add_0_left add_0_right
  1454 
  1455 ML {*
  1456 structure Cancel_Div_Mod_Int = Cancel_Div_Mod
  1457 (
  1458   val div_name = @{const_name div};
  1459   val mod_name = @{const_name mod};
  1460   val mk_binop = HOLogic.mk_binop;
  1461   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1462   val dest_sum = Arith_Data.dest_sum;
  1463 
  1464   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
  1465 
  1466   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1467     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1468 )
  1469 *}
  1470 
  1471 simproc_setup cancel_div_mod_int ("(k::int) + l") = {* K Cancel_Div_Mod_Int.proc *}
  1472 
  1473 lemma pos_mod_conj: "(0::int) < b \<Longrightarrow> 0 \<le> a mod b \<and> a mod b < b"
  1474   using divmod_int_correct [of a b]
  1475   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1476 
  1477 lemmas pos_mod_sign [simp] = pos_mod_conj [THEN conjunct1]
  1478    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2]
  1479 
  1480 lemma neg_mod_conj: "b < (0::int) \<Longrightarrow> a mod b \<le> 0 \<and> b < a mod b"
  1481   using divmod_int_correct [of a b]
  1482   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1483 
  1484 lemmas neg_mod_sign [simp] = neg_mod_conj [THEN conjunct1]
  1485    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2]
  1486 
  1487 
  1488 subsubsection {* General Properties of div and mod *}
  1489 
  1490 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1491 apply (rule div_int_unique)
  1492 apply (auto simp add: divmod_int_rel_def)
  1493 done
  1494 
  1495 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1496 apply (rule div_int_unique)
  1497 apply (auto simp add: divmod_int_rel_def)
  1498 done
  1499 
  1500 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1501 apply (rule div_int_unique)
  1502 apply (auto simp add: divmod_int_rel_def)
  1503 done
  1504 
  1505 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1506 
  1507 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1508 apply (rule_tac q = 0 in mod_int_unique)
  1509 apply (auto simp add: divmod_int_rel_def)
  1510 done
  1511 
  1512 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1513 apply (rule_tac q = 0 in mod_int_unique)
  1514 apply (auto simp add: divmod_int_rel_def)
  1515 done
  1516 
  1517 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1518 apply (rule_tac q = "-1" in mod_int_unique)
  1519 apply (auto simp add: divmod_int_rel_def)
  1520 done
  1521 
  1522 text{*There is no @{text mod_neg_pos_trivial}.*}
  1523 
  1524 
  1525 subsubsection {* Laws for div and mod with Unary Minus *}
  1526 
  1527 lemma zminus1_lemma:
  1528      "divmod_int_rel a b (q, r) ==> b \<noteq> 0
  1529       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1530                           if r=0 then 0 else b-r)"
  1531 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1532 
  1533 
  1534 lemma zdiv_zminus1_eq_if:
  1535      "b \<noteq> (0::int)  
  1536       ==> (-a) div b =  
  1537           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1538 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN div_int_unique])
  1539 
  1540 lemma zmod_zminus1_eq_if:
  1541      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1542 apply (case_tac "b = 0", simp)
  1543 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN mod_int_unique])
  1544 done
  1545 
  1546 lemma zmod_zminus1_not_zero:
  1547   fixes k l :: int
  1548   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1549   unfolding zmod_zminus1_eq_if by auto
  1550 
  1551 lemma zdiv_zminus2_eq_if:
  1552      "b \<noteq> (0::int)  
  1553       ==> a div (-b) =  
  1554           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1555 by (simp add: zdiv_zminus1_eq_if div_minus_right)
  1556 
  1557 lemma zmod_zminus2_eq_if:
  1558      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1559 by (simp add: zmod_zminus1_eq_if mod_minus_right)
  1560 
  1561 lemma zmod_zminus2_not_zero:
  1562   fixes k l :: int
  1563   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1564   unfolding zmod_zminus2_eq_if by auto 
  1565 
  1566 
  1567 subsubsection {* Computation of Division and Remainder *}
  1568 
  1569 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1570 by (simp add: div_int_def divmod_int_def)
  1571 
  1572 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1573 by (simp add: mod_int_def divmod_int_def)
  1574 
  1575 text{*a positive, b positive *}
  1576 
  1577 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1578 by (simp add: div_int_def divmod_int_def)
  1579 
  1580 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1581 by (simp add: mod_int_def divmod_int_def)
  1582 
  1583 text{*a negative, b positive *}
  1584 
  1585 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1586 by (simp add: div_int_def divmod_int_def)
  1587 
  1588 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1589 by (simp add: mod_int_def divmod_int_def)
  1590 
  1591 text{*a positive, b negative *}
  1592 
  1593 lemma div_pos_neg:
  1594      "[| 0 < a;  b < 0 |] ==> a div b = fst (apsnd uminus (negDivAlg (-a) (-b)))"
  1595 by (simp add: div_int_def divmod_int_def)
  1596 
  1597 lemma mod_pos_neg:
  1598      "[| 0 < a;  b < 0 |] ==> a mod b = snd (apsnd uminus (negDivAlg (-a) (-b)))"
  1599 by (simp add: mod_int_def divmod_int_def)
  1600 
  1601 text{*a negative, b negative *}
  1602 
  1603 lemma div_neg_neg:
  1604      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (apsnd uminus (posDivAlg (-a) (-b)))"
  1605 by (simp add: div_int_def divmod_int_def)
  1606 
  1607 lemma mod_neg_neg:
  1608      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (apsnd uminus (posDivAlg (-a) (-b)))"
  1609 by (simp add: mod_int_def divmod_int_def)
  1610 
  1611 text {*Simplify expresions in which div and mod combine numerical constants*}
  1612 
  1613 lemma int_div_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a div b = q"
  1614   by (rule div_int_unique [of a b q r]) (simp add: divmod_int_rel_def)
  1615 
  1616 lemma int_div_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a div b = q"
  1617   by (rule div_int_unique [of a b q r],
  1618     simp add: divmod_int_rel_def)
  1619 
  1620 lemma int_mod_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a mod b = r"
  1621   by (rule mod_int_unique [of a b q r],
  1622     simp add: divmod_int_rel_def)
  1623 
  1624 lemma int_mod_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a mod b = r"
  1625   by (rule mod_int_unique [of a b q r],
  1626     simp add: divmod_int_rel_def)
  1627 
  1628 (* simprocs adapted from HOL/ex/Binary.thy *)
  1629 ML {*
  1630 local
  1631   val mk_number = HOLogic.mk_number HOLogic.intT
  1632   val plus = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"}
  1633   val times = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"}
  1634   val zero = @{term "0 :: int"}
  1635   val less = @{term "op < :: int \<Rightarrow> int \<Rightarrow> bool"}
  1636   val le = @{term "op \<le> :: int \<Rightarrow> int \<Rightarrow> bool"}
  1637   val simps = @{thms arith_simps} @ @{thms rel_simps} @
  1638     map (fn th => th RS sym) [@{thm numeral_1_eq_1}]
  1639   fun prove ctxt goal = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop goal)
  1640     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps simps))));
  1641   fun binary_proc proc ss ct =
  1642     (case Thm.term_of ct of
  1643       _ $ t $ u =>
  1644       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1645         SOME args => proc (Simplifier.the_context ss) args
  1646       | NONE => NONE)
  1647     | _ => NONE);
  1648 in
  1649   fun divmod_proc posrule negrule =
  1650     binary_proc (fn ctxt => fn ((a, t), (b, u)) =>
  1651       if b = 0 then NONE else let
  1652         val (q, r) = pairself mk_number (Integer.div_mod a b)
  1653         val goal1 = HOLogic.mk_eq (t, plus $ (times $ u $ q) $ r)
  1654         val (goal2, goal3, rule) = if b > 0
  1655           then (le $ zero $ r, less $ r $ u, posrule RS eq_reflection)
  1656           else (le $ r $ zero, less $ u $ r, negrule RS eq_reflection)
  1657       in SOME (rule OF map (prove ctxt) [goal1, goal2, goal3]) end)
  1658 end
  1659 *}
  1660 
  1661 simproc_setup binary_int_div
  1662   ("numeral m div numeral n :: int" |
  1663    "numeral m div neg_numeral n :: int" |
  1664    "neg_numeral m div numeral n :: int" |
  1665    "neg_numeral m div neg_numeral n :: int") =
  1666   {* K (divmod_proc @{thm int_div_pos_eq} @{thm int_div_neg_eq}) *}
  1667 
  1668 simproc_setup binary_int_mod
  1669   ("numeral m mod numeral n :: int" |
  1670    "numeral m mod neg_numeral n :: int" |
  1671    "neg_numeral m mod numeral n :: int" |
  1672    "neg_numeral m mod neg_numeral n :: int") =
  1673   {* K (divmod_proc @{thm int_mod_pos_eq} @{thm int_mod_neg_eq}) *}
  1674 
  1675 lemmas posDivAlg_eqn_numeral [simp] =
  1676     posDivAlg_eqn [of "numeral v" "numeral w", OF zero_less_numeral] for v w
  1677 
  1678 lemmas negDivAlg_eqn_numeral [simp] =
  1679     negDivAlg_eqn [of "numeral v" "neg_numeral w", OF zero_less_numeral] for v w
  1680 
  1681 
  1682 text{*Special-case simplification *}
  1683 
  1684 (** The last remaining special cases for constant arithmetic:
  1685     1 div z and 1 mod z **)
  1686 
  1687 lemmas div_pos_pos_1_numeral [simp] =
  1688   div_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1689 
  1690 lemmas div_pos_neg_1_numeral [simp] =
  1691   div_pos_neg [OF zero_less_one, of "neg_numeral w",
  1692   OF neg_numeral_less_zero] for w
  1693 
  1694 lemmas mod_pos_pos_1_numeral [simp] =
  1695   mod_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1696 
  1697 lemmas mod_pos_neg_1_numeral [simp] =
  1698   mod_pos_neg [OF zero_less_one, of "neg_numeral w",
  1699   OF neg_numeral_less_zero] for w
  1700 
  1701 lemmas posDivAlg_eqn_1_numeral [simp] =
  1702     posDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1703 
  1704 lemmas negDivAlg_eqn_1_numeral [simp] =
  1705     negDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1706 
  1707 
  1708 subsubsection {* Monotonicity in the First Argument (Dividend) *}
  1709 
  1710 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1711 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1712 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1713 apply (rule unique_quotient_lemma)
  1714 apply (erule subst)
  1715 apply (erule subst, simp_all)
  1716 done
  1717 
  1718 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1719 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1720 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1721 apply (rule unique_quotient_lemma_neg)
  1722 apply (erule subst)
  1723 apply (erule subst, simp_all)
  1724 done
  1725 
  1726 
  1727 subsubsection {* Monotonicity in the Second Argument (Divisor) *}
  1728 
  1729 lemma q_pos_lemma:
  1730      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1731 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1732  apply (simp add: zero_less_mult_iff)
  1733 apply (simp add: distrib_left)
  1734 done
  1735 
  1736 lemma zdiv_mono2_lemma:
  1737      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1738          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1739       ==> q \<le> (q'::int)"
  1740 apply (frule q_pos_lemma, assumption+) 
  1741 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1742  apply (simp add: mult_less_cancel_left)
  1743 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1744  prefer 2 apply simp
  1745 apply (simp (no_asm_simp) add: distrib_left)
  1746 apply (subst add_commute, rule add_less_le_mono, arith)
  1747 apply (rule mult_right_mono, auto)
  1748 done
  1749 
  1750 lemma zdiv_mono2:
  1751      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1752 apply (subgoal_tac "b \<noteq> 0")
  1753  prefer 2 apply arith
  1754 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1755 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1756 apply (rule zdiv_mono2_lemma)
  1757 apply (erule subst)
  1758 apply (erule subst, simp_all)
  1759 done
  1760 
  1761 lemma q_neg_lemma:
  1762      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1763 apply (subgoal_tac "b'*q' < 0")
  1764  apply (simp add: mult_less_0_iff, arith)
  1765 done
  1766 
  1767 lemma zdiv_mono2_neg_lemma:
  1768      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1769          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1770       ==> q' \<le> (q::int)"
  1771 apply (frule q_neg_lemma, assumption+) 
  1772 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1773  apply (simp add: mult_less_cancel_left)
  1774 apply (simp add: distrib_left)
  1775 apply (subgoal_tac "b*q' \<le> b'*q'")
  1776  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1777 done
  1778 
  1779 lemma zdiv_mono2_neg:
  1780      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1781 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1782 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1783 apply (rule zdiv_mono2_neg_lemma)
  1784 apply (erule subst)
  1785 apply (erule subst, simp_all)
  1786 done
  1787 
  1788 
  1789 subsubsection {* More Algebraic Laws for div and mod *}
  1790 
  1791 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1792 
  1793 lemma zmult1_lemma:
  1794      "[| divmod_int_rel b c (q, r) |]  
  1795       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1796 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff distrib_left mult_ac)
  1797 
  1798 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1799 apply (case_tac "c = 0", simp)
  1800 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN div_int_unique])
  1801 done
  1802 
  1803 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1804 
  1805 lemma zadd1_lemma:
  1806      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br) |]  
  1807       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1808 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff distrib_left)
  1809 
  1810 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1811 lemma zdiv_zadd1_eq:
  1812      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1813 apply (case_tac "c = 0", simp)
  1814 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] div_int_unique)
  1815 done
  1816 
  1817 lemma posDivAlg_div_mod:
  1818   assumes "k \<ge> 0"
  1819   and "l \<ge> 0"
  1820   shows "posDivAlg k l = (k div l, k mod l)"
  1821 proof (cases "l = 0")
  1822   case True then show ?thesis by (simp add: posDivAlg.simps)
  1823 next
  1824   case False with assms posDivAlg_correct
  1825     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1826     by simp
  1827   from div_int_unique [OF this] mod_int_unique [OF this]
  1828   show ?thesis by simp
  1829 qed
  1830 
  1831 lemma negDivAlg_div_mod:
  1832   assumes "k < 0"
  1833   and "l > 0"
  1834   shows "negDivAlg k l = (k div l, k mod l)"
  1835 proof -
  1836   from assms have "l \<noteq> 0" by simp
  1837   from assms negDivAlg_correct
  1838     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1839     by simp
  1840   from div_int_unique [OF this] mod_int_unique [OF this]
  1841   show ?thesis by simp
  1842 qed
  1843 
  1844 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1845 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1846 
  1847 (* REVISIT: should this be generalized to all semiring_div types? *)
  1848 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1849 
  1850 lemma zmod_zdiv_equality':
  1851   "(m\<Colon>int) mod n = m - (m div n) * n"
  1852   using mod_div_equality [of m n] by arith
  1853 
  1854 
  1855 subsubsection {* Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1856 
  1857 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1858   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1859   to cause particular problems.*)
  1860 
  1861 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1862 
  1863 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1864 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1865  apply (simp add: algebra_simps)
  1866 apply (rule order_le_less_trans)
  1867  apply (erule_tac [2] mult_strict_right_mono)
  1868  apply (rule mult_left_mono_neg)
  1869   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1870  apply (simp)
  1871 apply (simp)
  1872 done
  1873 
  1874 lemma zmult2_lemma_aux2:
  1875      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1876 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1877  apply arith
  1878 apply (simp add: mult_le_0_iff)
  1879 done
  1880 
  1881 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1882 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1883 apply arith
  1884 apply (simp add: zero_le_mult_iff)
  1885 done
  1886 
  1887 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1888 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1889  apply (simp add: right_diff_distrib)
  1890 apply (rule order_less_le_trans)
  1891  apply (erule mult_strict_right_mono)
  1892  apply (rule_tac [2] mult_left_mono)
  1893   apply simp
  1894  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1895 apply simp
  1896 done
  1897 
  1898 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r); 0 < c |]  
  1899       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1900 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  1901                    zero_less_mult_iff distrib_left [symmetric] 
  1902                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4 mult_less_0_iff split: split_if_asm)
  1903 
  1904 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  1905 apply (case_tac "b = 0", simp)
  1906 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN div_int_unique])
  1907 done
  1908 
  1909 lemma zmod_zmult2_eq:
  1910      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  1911 apply (case_tac "b = 0", simp)
  1912 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN mod_int_unique])
  1913 done
  1914 
  1915 lemma div_pos_geq:
  1916   fixes k l :: int
  1917   assumes "0 < l" and "l \<le> k"
  1918   shows "k div l = (k - l) div l + 1"
  1919 proof -
  1920   have "k = (k - l) + l" by simp
  1921   then obtain j where k: "k = j + l" ..
  1922   with assms show ?thesis by simp
  1923 qed
  1924 
  1925 lemma mod_pos_geq:
  1926   fixes k l :: int
  1927   assumes "0 < l" and "l \<le> k"
  1928   shows "k mod l = (k - l) mod l"
  1929 proof -
  1930   have "k = (k - l) + l" by simp
  1931   then obtain j where k: "k = j + l" ..
  1932   with assms show ?thesis by simp
  1933 qed
  1934 
  1935 
  1936 subsubsection {* Splitting Rules for div and mod *}
  1937 
  1938 text{*The proofs of the two lemmas below are essentially identical*}
  1939 
  1940 lemma split_pos_lemma:
  1941  "0<k ==> 
  1942     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  1943 apply (rule iffI, clarify)
  1944  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1945  apply (subst mod_add_eq) 
  1946  apply (subst zdiv_zadd1_eq) 
  1947  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  1948 txt{*converse direction*}
  1949 apply (drule_tac x = "n div k" in spec) 
  1950 apply (drule_tac x = "n mod k" in spec, simp)
  1951 done
  1952 
  1953 lemma split_neg_lemma:
  1954  "k<0 ==>
  1955     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  1956 apply (rule iffI, clarify)
  1957  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1958  apply (subst mod_add_eq) 
  1959  apply (subst zdiv_zadd1_eq) 
  1960  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  1961 txt{*converse direction*}
  1962 apply (drule_tac x = "n div k" in spec) 
  1963 apply (drule_tac x = "n mod k" in spec, simp)
  1964 done
  1965 
  1966 lemma split_zdiv:
  1967  "P(n div k :: int) =
  1968   ((k = 0 --> P 0) & 
  1969    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  1970    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  1971 apply (case_tac "k=0", simp)
  1972 apply (simp only: linorder_neq_iff)
  1973 apply (erule disjE) 
  1974  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  1975                       split_neg_lemma [of concl: "%x y. P x"])
  1976 done
  1977 
  1978 lemma split_zmod:
  1979  "P(n mod k :: int) =
  1980   ((k = 0 --> P n) & 
  1981    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  1982    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  1983 apply (case_tac "k=0", simp)
  1984 apply (simp only: linorder_neq_iff)
  1985 apply (erule disjE) 
  1986  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  1987                       split_neg_lemma [of concl: "%x y. P y"])
  1988 done
  1989 
  1990 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  1991   when these are applied to some constant that is of the form
  1992   @{term "numeral k"}: *}
  1993 declare split_zdiv [of _ _ "numeral k", arith_split] for k
  1994 declare split_zmod [of _ _ "numeral k", arith_split] for k
  1995 
  1996 
  1997 subsubsection {* Computing @{text "div"} and @{text "mod"} with shifting *}
  1998 
  1999 lemma pos_divmod_int_rel_mult_2:
  2000   assumes "0 \<le> b"
  2001   assumes "divmod_int_rel a b (q, r)"
  2002   shows "divmod_int_rel (1 + 2*a) (2*b) (q, 1 + 2*r)"
  2003   using assms unfolding divmod_int_rel_def by auto
  2004 
  2005 lemma neg_divmod_int_rel_mult_2:
  2006   assumes "b \<le> 0"
  2007   assumes "divmod_int_rel (a + 1) b (q, r)"
  2008   shows "divmod_int_rel (1 + 2*a) (2*b) (q, 2*r - 1)"
  2009   using assms unfolding divmod_int_rel_def by auto
  2010 
  2011 text{*computing div by shifting *}
  2012 
  2013 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2014   using pos_divmod_int_rel_mult_2 [OF _ divmod_int_rel_div_mod]
  2015   by (rule div_int_unique)
  2016 
  2017 lemma neg_zdiv_mult_2: 
  2018   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2019   using neg_divmod_int_rel_mult_2 [OF A divmod_int_rel_div_mod]
  2020   by (rule div_int_unique)
  2021 
  2022 (* FIXME: add rules for negative numerals *)
  2023 lemma zdiv_numeral_Bit0 [simp]:
  2024   "numeral (Num.Bit0 v) div numeral (Num.Bit0 w) =
  2025     numeral v div (numeral w :: int)"
  2026   unfolding numeral.simps unfolding mult_2 [symmetric]
  2027   by (rule div_mult_mult1, simp)
  2028 
  2029 lemma zdiv_numeral_Bit1 [simp]:
  2030   "numeral (Num.Bit1 v) div numeral (Num.Bit0 w) =  
  2031     (numeral v div (numeral w :: int))"
  2032   unfolding numeral.simps
  2033   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2034   by (rule pos_zdiv_mult_2, simp)
  2035 
  2036 lemma pos_zmod_mult_2:
  2037   fixes a b :: int
  2038   assumes "0 \<le> a"
  2039   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2040   using pos_divmod_int_rel_mult_2 [OF assms divmod_int_rel_div_mod]
  2041   by (rule mod_int_unique)
  2042 
  2043 lemma neg_zmod_mult_2:
  2044   fixes a b :: int
  2045   assumes "a \<le> 0"
  2046   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2047   using neg_divmod_int_rel_mult_2 [OF assms divmod_int_rel_div_mod]
  2048   by (rule mod_int_unique)
  2049 
  2050 (* FIXME: add rules for negative numerals *)
  2051 lemma zmod_numeral_Bit0 [simp]:
  2052   "numeral (Num.Bit0 v) mod numeral (Num.Bit0 w) =  
  2053     (2::int) * (numeral v mod numeral w)"
  2054   unfolding numeral_Bit0 [of v] numeral_Bit0 [of w]
  2055   unfolding mult_2 [symmetric] by (rule mod_mult_mult1)
  2056 
  2057 lemma zmod_numeral_Bit1 [simp]:
  2058   "numeral (Num.Bit1 v) mod numeral (Num.Bit0 w) =
  2059     2 * (numeral v mod numeral w) + (1::int)"
  2060   unfolding numeral_Bit1 [of v] numeral_Bit0 [of w]
  2061   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2062   by (rule pos_zmod_mult_2, simp)
  2063 
  2064 lemma zdiv_eq_0_iff:
  2065  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2066 proof
  2067   assume ?L
  2068   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2069   with `?L` show ?R by blast
  2070 next
  2071   assume ?R thus ?L
  2072     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2073 qed
  2074 
  2075 
  2076 subsubsection {* Quotients of Signs *}
  2077 
  2078 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2079 apply (subgoal_tac "a div b \<le> -1", force)
  2080 apply (rule order_trans)
  2081 apply (rule_tac a' = "-1" in zdiv_mono1)
  2082 apply (auto simp add: div_eq_minus1)
  2083 done
  2084 
  2085 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2086 by (drule zdiv_mono1_neg, auto)
  2087 
  2088 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2089 by (drule zdiv_mono1, auto)
  2090 
  2091 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2092 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2093 They should all be simp rules unless that causes too much search. *}
  2094 
  2095 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2096 apply auto
  2097 apply (drule_tac [2] zdiv_mono1)
  2098 apply (auto simp add: linorder_neq_iff)
  2099 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2100 apply (blast intro: div_neg_pos_less0)
  2101 done
  2102 
  2103 lemma neg_imp_zdiv_nonneg_iff:
  2104   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2105 apply (subst div_minus_minus [symmetric])
  2106 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2107 done
  2108 
  2109 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2110 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2111 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2112 
  2113 lemma pos_imp_zdiv_pos_iff:
  2114   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2115 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2116 by arith
  2117 
  2118 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2119 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2120 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2121 
  2122 lemma nonneg1_imp_zdiv_pos_iff:
  2123   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2124 apply rule
  2125  apply rule
  2126   using div_pos_pos_trivial[of a b]apply arith
  2127  apply(cases "b=0")apply simp
  2128  using div_nonneg_neg_le0[of a b]apply arith
  2129 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2130 done
  2131 
  2132 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2133 apply (rule split_zmod[THEN iffD2])
  2134 apply(fastforce dest: q_pos_lemma intro: split_mult_pos_le)
  2135 done
  2136 
  2137 
  2138 subsubsection {* The Divides Relation *}
  2139 
  2140 lemma dvd_neg_numeral_left [simp]:
  2141   fixes y :: "'a::comm_ring_1"
  2142   shows "(neg_numeral k) dvd y \<longleftrightarrow> (numeral k) dvd y"
  2143   unfolding neg_numeral_def minus_dvd_iff ..
  2144 
  2145 lemma dvd_neg_numeral_right [simp]:
  2146   fixes x :: "'a::comm_ring_1"
  2147   shows "x dvd (neg_numeral k) \<longleftrightarrow> x dvd (numeral k)"
  2148   unfolding neg_numeral_def dvd_minus_iff ..
  2149 
  2150 lemmas dvd_eq_mod_eq_0_numeral [simp] =
  2151   dvd_eq_mod_eq_0 [of "numeral x" "numeral y"] for x y
  2152 
  2153 
  2154 subsubsection {* Further properties *}
  2155 
  2156 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2157   using zmod_zdiv_equality[where a="m" and b="n"]
  2158   by (simp add: algebra_simps) (* FIXME: generalize *)
  2159 
  2160 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2161 apply (subst split_div, auto)
  2162 apply (subst split_zdiv, auto)
  2163 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2164 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2165 done
  2166 
  2167 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2168 apply (subst split_mod, auto)
  2169 apply (subst split_zmod, auto)
  2170 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2171        in unique_remainder)
  2172 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2173 done
  2174 
  2175 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2176 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2177 
  2178 text{*Suggested by Matthias Daum*}
  2179 lemma int_power_div_base:
  2180      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2181 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2182  apply (erule ssubst)
  2183  apply (simp only: power_add)
  2184  apply simp_all
  2185 done
  2186 
  2187 text {* by Brian Huffman *}
  2188 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2189 by (rule mod_minus_eq [symmetric])
  2190 
  2191 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2192 by (rule mod_diff_left_eq [symmetric])
  2193 
  2194 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2195 by (rule mod_diff_right_eq [symmetric])
  2196 
  2197 lemmas zmod_simps =
  2198   mod_add_left_eq  [symmetric]
  2199   mod_add_right_eq [symmetric]
  2200   mod_mult_right_eq[symmetric]
  2201   mod_mult_left_eq [symmetric]
  2202   power_mod
  2203   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2204 
  2205 text {* Distributive laws for function @{text nat}. *}
  2206 
  2207 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2208 apply (rule linorder_cases [of y 0])
  2209 apply (simp add: div_nonneg_neg_le0)
  2210 apply simp
  2211 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2212 done
  2213 
  2214 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2215 lemma nat_mod_distrib:
  2216   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2217 apply (case_tac "y = 0", simp)
  2218 apply (simp add: nat_eq_iff zmod_int)
  2219 done
  2220 
  2221 text  {* transfer setup *}
  2222 
  2223 lemma transfer_nat_int_functions:
  2224     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2225     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2226   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2227 
  2228 lemma transfer_nat_int_function_closures:
  2229     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2230     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2231   apply (cases "y = 0")
  2232   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2233   apply (cases "y = 0")
  2234   apply auto
  2235 done
  2236 
  2237 declare transfer_morphism_nat_int [transfer add return:
  2238   transfer_nat_int_functions
  2239   transfer_nat_int_function_closures
  2240 ]
  2241 
  2242 lemma transfer_int_nat_functions:
  2243     "(int x) div (int y) = int (x div y)"
  2244     "(int x) mod (int y) = int (x mod y)"
  2245   by (auto simp add: zdiv_int zmod_int)
  2246 
  2247 lemma transfer_int_nat_function_closures:
  2248     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2249     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2250   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2251 
  2252 declare transfer_morphism_int_nat [transfer add return:
  2253   transfer_int_nat_functions
  2254   transfer_int_nat_function_closures
  2255 ]
  2256 
  2257 text{*Suggested by Matthias Daum*}
  2258 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2259 apply (subgoal_tac "nat x div nat k < nat x")
  2260  apply (simp add: nat_div_distrib [symmetric])
  2261 apply (rule Divides.div_less_dividend, simp_all)
  2262 done
  2263 
  2264 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2265 proof
  2266   assume H: "x mod n = y mod n"
  2267   hence "x mod n - y mod n = 0" by simp
  2268   hence "(x mod n - y mod n) mod n = 0" by simp 
  2269   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2270   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2271 next
  2272   assume H: "n dvd x - y"
  2273   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2274   hence "x = n*k + y" by simp
  2275   hence "x mod n = (n*k + y) mod n" by simp
  2276   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2277 qed
  2278 
  2279 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2280   shows "\<exists>q. x = y + n * q"
  2281 proof-
  2282   from xy have th: "int x - int y = int (x - y)" by simp 
  2283   from xyn have "int x mod int n = int y mod int n" 
  2284     by (simp add: zmod_int [symmetric])
  2285   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2286   hence "n dvd x - y" by (simp add: th zdvd_int)
  2287   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2288 qed
  2289 
  2290 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2291   (is "?lhs = ?rhs")
  2292 proof
  2293   assume H: "x mod n = y mod n"
  2294   {assume xy: "x \<le> y"
  2295     from H have th: "y mod n = x mod n" by simp
  2296     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2297       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2298   moreover
  2299   {assume xy: "y \<le> x"
  2300     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2301       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2302   ultimately  show ?rhs using linear[of x y] by blast  
  2303 next
  2304   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2305   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2306   thus  ?lhs by simp
  2307 qed
  2308 
  2309 lemma div_nat_numeral [simp]:
  2310   "(numeral v :: nat) div numeral v' = nat (numeral v div numeral v')"
  2311   by (simp add: nat_div_distrib)
  2312 
  2313 lemma one_div_nat_numeral [simp]:
  2314   "Suc 0 div numeral v' = nat (1 div numeral v')"
  2315   by (subst nat_div_distrib, simp_all)
  2316 
  2317 lemma mod_nat_numeral [simp]:
  2318   "(numeral v :: nat) mod numeral v' = nat (numeral v mod numeral v')"
  2319   by (simp add: nat_mod_distrib)
  2320 
  2321 lemma one_mod_nat_numeral [simp]:
  2322   "Suc 0 mod numeral v' = nat (1 mod numeral v')"
  2323   by (subst nat_mod_distrib) simp_all
  2324 
  2325 lemma mod_2_not_eq_zero_eq_one_int:
  2326   fixes k :: int
  2327   shows "k mod 2 \<noteq> 0 \<longleftrightarrow> k mod 2 = 1"
  2328   by auto
  2329 
  2330 
  2331 subsubsection {* Tools setup *}
  2332 
  2333 text {* Nitpick *}
  2334 
  2335 lemmas [nitpick_unfold] = dvd_eq_mod_eq_0 mod_div_equality' zmod_zdiv_equality'
  2336 
  2337 
  2338 subsubsection {* Code generation *}
  2339 
  2340 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2341   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2342 
  2343 lemma pdivmod_posDivAlg [code]:
  2344   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2345 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2346 
  2347 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2348   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2349     then pdivmod k l
  2350     else (let (r, s) = pdivmod k l in
  2351        if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2352 proof -
  2353   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2354   show ?thesis
  2355     by (simp add: divmod_int_mod_div pdivmod_def)
  2356       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2357       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2358 qed
  2359 
  2360 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2361   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2362     then pdivmod k l
  2363     else (let (r, s) = pdivmod k l in
  2364       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2365 proof -
  2366   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2367     by (auto simp add: not_less sgn_if)
  2368   then show ?thesis by (simp add: divmod_int_pdivmod)
  2369 qed
  2370 
  2371 code_modulename SML
  2372   Divides Arith
  2373 
  2374 code_modulename OCaml
  2375   Divides Arith
  2376 
  2377 code_modulename Haskell
  2378   Divides Arith
  2379 
  2380 end