src/ZF/CardinalArith.thy
author paulson
Tue Mar 13 17:11:49 2012 +0000 (2012-03-13)
changeset 46907 eea3eb057fea
parent 46901 1382bba4b7a5
child 46935 38ecb2dc3636
permissions -rw-r--r--
Structured proofs concerning the square of an infinite cardinal
     1 (*  Title:      ZF/CardinalArith.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header{*Cardinal Arithmetic Without the Axiom of Choice*}
     7 
     8 theory CardinalArith imports Cardinal OrderArith ArithSimp Finite begin
     9 
    10 definition
    11   InfCard       :: "i=>o"  where
    12     "InfCard(i) == Card(i) & nat \<le> i"
    13 
    14 definition
    15   cmult         :: "[i,i]=>i"       (infixl "|*|" 70)  where
    16     "i |*| j == |i*j|"
    17 
    18 definition
    19   cadd          :: "[i,i]=>i"       (infixl "|+|" 65)  where
    20     "i |+| j == |i+j|"
    21 
    22 definition
    23   csquare_rel   :: "i=>i"  where
    24     "csquare_rel(K) ==
    25           rvimage(K*K,
    26                   lam <x,y>:K*K. <x \<union> y, x, y>,
    27                   rmult(K,Memrel(K), K*K, rmult(K,Memrel(K), K,Memrel(K))))"
    28 
    29 definition
    30   jump_cardinal :: "i=>i"  where
    31     --{*This def is more complex than Kunen's but it more easily proved to
    32         be a cardinal*}
    33     "jump_cardinal(K) ==
    34          \<Union>X\<in>Pow(K). {z. r: Pow(K*K), well_ord(X,r) & z = ordertype(X,r)}"
    35 
    36 definition
    37   csucc         :: "i=>i"  where
    38     --{*needed because @{term "jump_cardinal(K)"} might not be the successor
    39         of @{term K}*}
    40     "csucc(K) == LEAST L. Card(L) & K<L"
    41 
    42 notation (xsymbols)
    43   cadd  (infixl "\<oplus>" 65) and
    44   cmult  (infixl "\<otimes>" 70)
    45 
    46 notation (HTML)
    47   cadd  (infixl "\<oplus>" 65) and
    48   cmult  (infixl "\<otimes>" 70)
    49 
    50 
    51 lemma Card_Union [simp,intro,TC]: 
    52   assumes A: "\<And>x. x\<in>A \<Longrightarrow> Card(x)" shows "Card(\<Union>(A))"
    53 proof (rule CardI)
    54   show "Ord(\<Union>A)" using A 
    55     by (simp add: Card_is_Ord)
    56 next
    57   fix j
    58   assume j: "j < \<Union>A"
    59   hence "\<exists>c\<in>A. j < c & Card(c)" using A
    60     by (auto simp add: lt_def intro: Card_is_Ord)
    61   then obtain c where c: "c\<in>A" "j < c" "Card(c)"
    62     by blast
    63   hence jls: "j \<prec> c" 
    64     by (simp add: lt_Card_imp_lesspoll) 
    65   { assume eqp: "j \<approx> \<Union>A"
    66     have  "c \<lesssim> \<Union>A" using c
    67       by (blast intro: subset_imp_lepoll)
    68     also have "... \<approx> j"  by (rule eqpoll_sym [OF eqp])
    69     also have "... \<prec> c"  by (rule jls)
    70     finally have "c \<prec> c" .
    71     hence False 
    72       by auto
    73   } thus "\<not> j \<approx> \<Union>A" by blast
    74 qed
    75 
    76 lemma Card_UN: "(!!x. x:A ==> Card(K(x))) ==> Card(\<Union>x\<in>A. K(x))"
    77   by blast
    78 
    79 lemma Card_OUN [simp,intro,TC]:
    80      "(!!x. x:A ==> Card(K(x))) ==> Card(\<Union>x<A. K(x))"
    81   by (auto simp add: OUnion_def Card_0)
    82 
    83 lemma in_Card_imp_lesspoll: "[| Card(K); b \<in> K |] ==> b \<prec> K"
    84 apply (unfold lesspoll_def)
    85 apply (simp add: Card_iff_initial)
    86 apply (fast intro!: le_imp_lepoll ltI leI)
    87 done
    88 
    89 
    90 subsection{*Cardinal addition*}
    91 
    92 text{*Note: Could omit proving the algebraic laws for cardinal addition and
    93 multiplication.  On finite cardinals these operations coincide with
    94 addition and multiplication of natural numbers; on infinite cardinals they
    95 coincide with union (maximum).  Either way we get most laws for free.*}
    96 
    97 subsubsection{*Cardinal addition is commutative*}
    98 
    99 lemma sum_commute_eqpoll: "A+B \<approx> B+A"
   100 proof (unfold eqpoll_def, rule exI)
   101   show "(\<lambda>z\<in>A+B. case(Inr,Inl,z)) \<in> bij(A+B, B+A)"
   102     by (auto intro: lam_bijective [where d = "case(Inr,Inl)"]) 
   103 qed
   104 
   105 lemma cadd_commute: "i \<oplus> j = j \<oplus> i"
   106 apply (unfold cadd_def)
   107 apply (rule sum_commute_eqpoll [THEN cardinal_cong])
   108 done
   109 
   110 subsubsection{*Cardinal addition is associative*}
   111 
   112 lemma sum_assoc_eqpoll: "(A+B)+C \<approx> A+(B+C)"
   113 apply (unfold eqpoll_def)
   114 apply (rule exI)
   115 apply (rule sum_assoc_bij)
   116 done
   117 
   118 text{*Unconditional version requires AC*}
   119 lemma well_ord_cadd_assoc:
   120   assumes i: "well_ord(i,ri)" and j: "well_ord(j,rj)" and k: "well_ord(k,rk)"
   121   shows "(i \<oplus> j) \<oplus> k = i \<oplus> (j \<oplus> k)"
   122 proof (unfold cadd_def, rule cardinal_cong)
   123   have "|i + j| + k \<approx> (i + j) + k"
   124     by (blast intro: sum_eqpoll_cong well_ord_cardinal_eqpoll eqpoll_refl well_ord_radd i j) 
   125   also have "...  \<approx> i + (j + k)"
   126     by (rule sum_assoc_eqpoll) 
   127   also have "...  \<approx> i + |j + k|"
   128     by (blast intro: sum_eqpoll_cong well_ord_cardinal_eqpoll eqpoll_refl well_ord_radd j k eqpoll_sym) 
   129   finally show "|i + j| + k \<approx> i + |j + k|" .
   130 qed
   131 
   132 
   133 subsubsection{*0 is the identity for addition*}
   134 
   135 lemma sum_0_eqpoll: "0+A \<approx> A"
   136 apply (unfold eqpoll_def)
   137 apply (rule exI)
   138 apply (rule bij_0_sum)
   139 done
   140 
   141 lemma cadd_0 [simp]: "Card(K) ==> 0 \<oplus> K = K"
   142 apply (unfold cadd_def)
   143 apply (simp add: sum_0_eqpoll [THEN cardinal_cong] Card_cardinal_eq)
   144 done
   145 
   146 subsubsection{*Addition by another cardinal*}
   147 
   148 lemma sum_lepoll_self: "A \<lesssim> A+B"
   149 proof (unfold lepoll_def, rule exI)
   150   show "(\<lambda>x\<in>A. Inl (x)) \<in> inj(A, A + B)"
   151     by (simp add: inj_def) 
   152 qed
   153 
   154 (*Could probably weaken the premises to well_ord(K,r), or removing using AC*)
   155 
   156 lemma cadd_le_self:
   157     "[| Card(K);  Ord(L) |] ==> K \<le> (K \<oplus> L)"
   158 apply (unfold cadd_def)
   159 apply (rule le_trans [OF Card_cardinal_le well_ord_lepoll_imp_Card_le],
   160        assumption)
   161 apply (rule_tac [2] sum_lepoll_self)
   162 apply (blast intro: well_ord_radd well_ord_Memrel Card_is_Ord)
   163 done
   164 
   165 subsubsection{*Monotonicity of addition*}
   166 
   167 lemma sum_lepoll_mono:
   168      "[| A \<lesssim> C;  B \<lesssim> D |] ==> A + B \<lesssim> C + D"
   169 apply (unfold lepoll_def)
   170 apply (elim exE)
   171 apply (rule_tac x = "\<lambda>z\<in>A+B. case (%w. Inl(f`w), %y. Inr(fa`y), z)" in exI)
   172 apply (rule_tac d = "case (%w. Inl(converse(f) `w), %y. Inr(converse(fa) ` y))"
   173        in lam_injective)
   174 apply (typecheck add: inj_is_fun, auto)
   175 done
   176 
   177 lemma cadd_le_mono:
   178     "[| K' \<le> K;  L' \<le> L |] ==> (K' \<oplus> L') \<le> (K \<oplus> L)"
   179 apply (unfold cadd_def)
   180 apply (safe dest!: le_subset_iff [THEN iffD1])
   181 apply (rule well_ord_lepoll_imp_Card_le)
   182 apply (blast intro: well_ord_radd well_ord_Memrel)
   183 apply (blast intro: sum_lepoll_mono subset_imp_lepoll)
   184 done
   185 
   186 subsubsection{*Addition of finite cardinals is "ordinary" addition*}
   187 
   188 lemma sum_succ_eqpoll: "succ(A)+B \<approx> succ(A+B)"
   189 apply (unfold eqpoll_def)
   190 apply (rule exI)
   191 apply (rule_tac c = "%z. if z=Inl (A) then A+B else z"
   192             and d = "%z. if z=A+B then Inl (A) else z" in lam_bijective)
   193    apply simp_all
   194 apply (blast dest: sym [THEN eq_imp_not_mem] elim: mem_irrefl)+
   195 done
   196 
   197 (*Pulling the  succ(...)  outside the |...| requires m, n: nat  *)
   198 (*Unconditional version requires AC*)
   199 lemma cadd_succ_lemma:
   200     "[| Ord(m);  Ord(n) |] ==> succ(m) \<oplus> n = |succ(m \<oplus> n)|"
   201 apply (unfold cadd_def)
   202 apply (rule sum_succ_eqpoll [THEN cardinal_cong, THEN trans])
   203 apply (rule succ_eqpoll_cong [THEN cardinal_cong])
   204 apply (rule well_ord_cardinal_eqpoll [THEN eqpoll_sym])
   205 apply (blast intro: well_ord_radd well_ord_Memrel)
   206 done
   207 
   208 lemma nat_cadd_eq_add: "[| m: nat;  n: nat |] ==> m \<oplus> n = m#+n"
   209 apply (induct_tac m)
   210 apply (simp add: nat_into_Card [THEN cadd_0])
   211 apply (simp add: cadd_succ_lemma nat_into_Card [THEN Card_cardinal_eq])
   212 done
   213 
   214 
   215 subsection{*Cardinal multiplication*}
   216 
   217 subsubsection{*Cardinal multiplication is commutative*}
   218 
   219 lemma prod_commute_eqpoll: "A*B \<approx> B*A"
   220 apply (unfold eqpoll_def)
   221 apply (rule exI)
   222 apply (rule_tac c = "%<x,y>.<y,x>" and d = "%<x,y>.<y,x>" in lam_bijective,
   223        auto)
   224 done
   225 
   226 lemma cmult_commute: "i \<otimes> j = j \<otimes> i"
   227 apply (unfold cmult_def)
   228 apply (rule prod_commute_eqpoll [THEN cardinal_cong])
   229 done
   230 
   231 subsubsection{*Cardinal multiplication is associative*}
   232 
   233 lemma prod_assoc_eqpoll: "(A*B)*C \<approx> A*(B*C)"
   234 apply (unfold eqpoll_def)
   235 apply (rule exI)
   236 apply (rule prod_assoc_bij)
   237 done
   238 
   239 text{*Unconditional version requires AC*}
   240 lemma well_ord_cmult_assoc:
   241   assumes i: "well_ord(i,ri)" and j: "well_ord(j,rj)" and k: "well_ord(k,rk)"
   242   shows "(i \<otimes> j) \<otimes> k = i \<otimes> (j \<otimes> k)"
   243 proof (unfold cmult_def, rule cardinal_cong)
   244   have "|i * j| * k \<approx> (i * j) * k"
   245     by (blast intro: prod_eqpoll_cong well_ord_cardinal_eqpoll eqpoll_refl well_ord_rmult i j) 
   246   also have "...  \<approx> i * (j * k)"
   247     by (rule prod_assoc_eqpoll) 
   248   also have "...  \<approx> i * |j * k|"
   249     by (blast intro: prod_eqpoll_cong well_ord_cardinal_eqpoll eqpoll_refl well_ord_rmult j k eqpoll_sym) 
   250   finally show "|i * j| * k \<approx> i * |j * k|" .
   251 qed
   252 
   253 subsubsection{*Cardinal multiplication distributes over addition*}
   254 
   255 lemma sum_prod_distrib_eqpoll: "(A+B)*C \<approx> (A*C)+(B*C)"
   256 apply (unfold eqpoll_def)
   257 apply (rule exI)
   258 apply (rule sum_prod_distrib_bij)
   259 done
   260 
   261 lemma well_ord_cadd_cmult_distrib:
   262   assumes i: "well_ord(i,ri)" and j: "well_ord(j,rj)" and k: "well_ord(k,rk)"
   263   shows "(i \<oplus> j) \<otimes> k = (i \<otimes> k) \<oplus> (j \<otimes> k)"
   264 proof (unfold cadd_def cmult_def, rule cardinal_cong)
   265   have "|i + j| * k \<approx> (i + j) * k"
   266     by (blast intro: prod_eqpoll_cong well_ord_cardinal_eqpoll eqpoll_refl well_ord_radd i j) 
   267   also have "...  \<approx> i * k + j * k"
   268     by (rule sum_prod_distrib_eqpoll) 
   269   also have "...  \<approx> |i * k| + |j * k|"
   270     by (blast intro: sum_eqpoll_cong well_ord_cardinal_eqpoll well_ord_rmult i j k eqpoll_sym) 
   271   finally show "|i + j| * k \<approx> |i * k| + |j * k|" .
   272 qed
   273 
   274 subsubsection{*Multiplication by 0 yields 0*}
   275 
   276 lemma prod_0_eqpoll: "0*A \<approx> 0"
   277 apply (unfold eqpoll_def)
   278 apply (rule exI)
   279 apply (rule lam_bijective, safe)
   280 done
   281 
   282 lemma cmult_0 [simp]: "0 \<otimes> i = 0"
   283 by (simp add: cmult_def prod_0_eqpoll [THEN cardinal_cong])
   284 
   285 subsubsection{*1 is the identity for multiplication*}
   286 
   287 lemma prod_singleton_eqpoll: "{x}*A \<approx> A"
   288 apply (unfold eqpoll_def)
   289 apply (rule exI)
   290 apply (rule singleton_prod_bij [THEN bij_converse_bij])
   291 done
   292 
   293 lemma cmult_1 [simp]: "Card(K) ==> 1 \<otimes> K = K"
   294 apply (unfold cmult_def succ_def)
   295 apply (simp add: prod_singleton_eqpoll [THEN cardinal_cong] Card_cardinal_eq)
   296 done
   297 
   298 subsection{*Some inequalities for multiplication*}
   299 
   300 lemma prod_square_lepoll: "A \<lesssim> A*A"
   301 apply (unfold lepoll_def inj_def)
   302 apply (rule_tac x = "\<lambda>x\<in>A. <x,x>" in exI, simp)
   303 done
   304 
   305 (*Could probably weaken the premise to well_ord(K,r), or remove using AC*)
   306 lemma cmult_square_le: "Card(K) ==> K \<le> K \<otimes> K"
   307 apply (unfold cmult_def)
   308 apply (rule le_trans)
   309 apply (rule_tac [2] well_ord_lepoll_imp_Card_le)
   310 apply (rule_tac [3] prod_square_lepoll)
   311 apply (simp add: le_refl Card_is_Ord Card_cardinal_eq)
   312 apply (blast intro: well_ord_rmult well_ord_Memrel Card_is_Ord)
   313 done
   314 
   315 subsubsection{*Multiplication by a non-zero cardinal*}
   316 
   317 lemma prod_lepoll_self: "b: B ==> A \<lesssim> A*B"
   318 apply (unfold lepoll_def inj_def)
   319 apply (rule_tac x = "\<lambda>x\<in>A. <x,b>" in exI, simp)
   320 done
   321 
   322 (*Could probably weaken the premises to well_ord(K,r), or removing using AC*)
   323 lemma cmult_le_self:
   324     "[| Card(K);  Ord(L);  0<L |] ==> K \<le> (K \<otimes> L)"
   325 apply (unfold cmult_def)
   326 apply (rule le_trans [OF Card_cardinal_le well_ord_lepoll_imp_Card_le])
   327   apply assumption
   328  apply (blast intro: well_ord_rmult well_ord_Memrel Card_is_Ord)
   329 apply (blast intro: prod_lepoll_self ltD)
   330 done
   331 
   332 subsubsection{*Monotonicity of multiplication*}
   333 
   334 lemma prod_lepoll_mono:
   335      "[| A \<lesssim> C;  B \<lesssim> D |] ==> A * B  \<lesssim>  C * D"
   336 apply (unfold lepoll_def)
   337 apply (elim exE)
   338 apply (rule_tac x = "lam <w,y>:A*B. <f`w, fa`y>" in exI)
   339 apply (rule_tac d = "%<w,y>. <converse (f) `w, converse (fa) `y>"
   340        in lam_injective)
   341 apply (typecheck add: inj_is_fun, auto)
   342 done
   343 
   344 lemma cmult_le_mono:
   345     "[| K' \<le> K;  L' \<le> L |] ==> (K' \<otimes> L') \<le> (K \<otimes> L)"
   346 apply (unfold cmult_def)
   347 apply (safe dest!: le_subset_iff [THEN iffD1])
   348 apply (rule well_ord_lepoll_imp_Card_le)
   349  apply (blast intro: well_ord_rmult well_ord_Memrel)
   350 apply (blast intro: prod_lepoll_mono subset_imp_lepoll)
   351 done
   352 
   353 subsection{*Multiplication of finite cardinals is "ordinary" multiplication*}
   354 
   355 lemma prod_succ_eqpoll: "succ(A)*B \<approx> B + A*B"
   356 apply (unfold eqpoll_def)
   357 apply (rule exI)
   358 apply (rule_tac c = "%<x,y>. if x=A then Inl (y) else Inr (<x,y>)"
   359             and d = "case (%y. <A,y>, %z. z)" in lam_bijective)
   360 apply safe
   361 apply (simp_all add: succI2 if_type mem_imp_not_eq)
   362 done
   363 
   364 (*Unconditional version requires AC*)
   365 lemma cmult_succ_lemma:
   366     "[| Ord(m);  Ord(n) |] ==> succ(m) \<otimes> n = n \<oplus> (m \<otimes> n)"
   367 apply (unfold cmult_def cadd_def)
   368 apply (rule prod_succ_eqpoll [THEN cardinal_cong, THEN trans])
   369 apply (rule cardinal_cong [symmetric])
   370 apply (rule sum_eqpoll_cong [OF eqpoll_refl well_ord_cardinal_eqpoll])
   371 apply (blast intro: well_ord_rmult well_ord_Memrel)
   372 done
   373 
   374 lemma nat_cmult_eq_mult: "[| m: nat;  n: nat |] ==> m \<otimes> n = m#*n"
   375 apply (induct_tac m)
   376 apply (simp_all add: cmult_succ_lemma nat_cadd_eq_add)
   377 done
   378 
   379 lemma cmult_2: "Card(n) ==> 2 \<otimes> n = n \<oplus> n"
   380 by (simp add: cmult_succ_lemma Card_is_Ord cadd_commute [of _ 0])
   381 
   382 lemma sum_lepoll_prod: 
   383   assumes C: "2 \<lesssim> C" shows "B+B \<lesssim> C*B"
   384 proof -
   385   have "B+B \<lesssim> 2*B"
   386     by (simp add: sum_eq_2_times) 
   387   also have "... \<lesssim> C*B"
   388     by (blast intro: prod_lepoll_mono lepoll_refl C) 
   389   finally show "B+B \<lesssim> C*B" .
   390 qed
   391 
   392 lemma lepoll_imp_sum_lepoll_prod: "[| A \<lesssim> B; 2 \<lesssim> A |] ==> A+B \<lesssim> A*B"
   393 by (blast intro: sum_lepoll_mono sum_lepoll_prod lepoll_trans lepoll_refl)
   394 
   395 
   396 subsection{*Infinite Cardinals are Limit Ordinals*}
   397 
   398 (*This proof is modelled upon one assuming nat<=A, with injection
   399   \<lambda>z\<in>cons(u,A). if z=u then 0 else if z \<in> nat then succ(z) else z
   400   and inverse %y. if y:nat then nat_case(u, %z. z, y) else y.  \
   401   If f: inj(nat,A) then range(f) behaves like the natural numbers.*)
   402 lemma nat_cons_lepoll: "nat \<lesssim> A ==> cons(u,A) \<lesssim> A"
   403 apply (unfold lepoll_def)
   404 apply (erule exE)
   405 apply (rule_tac x =
   406           "\<lambda>z\<in>cons (u,A).
   407              if z=u then f`0
   408              else if z: range (f) then f`succ (converse (f) `z) else z"
   409        in exI)
   410 apply (rule_tac d =
   411           "%y. if y: range(f) then nat_case (u, %z. f`z, converse(f) `y)
   412                               else y"
   413        in lam_injective)
   414 apply (fast intro!: if_type apply_type intro: inj_is_fun inj_converse_fun)
   415 apply (simp add: inj_is_fun [THEN apply_rangeI]
   416                  inj_converse_fun [THEN apply_rangeI]
   417                  inj_converse_fun [THEN apply_funtype])
   418 done
   419 
   420 lemma nat_cons_eqpoll: "nat \<lesssim> A ==> cons(u,A) \<approx> A"
   421 apply (erule nat_cons_lepoll [THEN eqpollI])
   422 apply (rule subset_consI [THEN subset_imp_lepoll])
   423 done
   424 
   425 (*Specialized version required below*)
   426 lemma nat_succ_eqpoll: "nat \<subseteq> A ==> succ(A) \<approx> A"
   427 apply (unfold succ_def)
   428 apply (erule subset_imp_lepoll [THEN nat_cons_eqpoll])
   429 done
   430 
   431 lemma InfCard_nat: "InfCard(nat)"
   432 apply (unfold InfCard_def)
   433 apply (blast intro: Card_nat le_refl Card_is_Ord)
   434 done
   435 
   436 lemma InfCard_is_Card: "InfCard(K) ==> Card(K)"
   437 apply (unfold InfCard_def)
   438 apply (erule conjunct1)
   439 done
   440 
   441 lemma InfCard_Un:
   442     "[| InfCard(K);  Card(L) |] ==> InfCard(K \<union> L)"
   443 apply (unfold InfCard_def)
   444 apply (simp add: Card_Un Un_upper1_le [THEN [2] le_trans]  Card_is_Ord)
   445 done
   446 
   447 (*Kunen's Lemma 10.11*)
   448 lemma InfCard_is_Limit: "InfCard(K) ==> Limit(K)"
   449 apply (unfold InfCard_def)
   450 apply (erule conjE)
   451 apply (frule Card_is_Ord)
   452 apply (rule ltI [THEN non_succ_LimitI])
   453 apply (erule le_imp_subset [THEN subsetD])
   454 apply (safe dest!: Limit_nat [THEN Limit_le_succD])
   455 apply (unfold Card_def)
   456 apply (drule trans)
   457 apply (erule le_imp_subset [THEN nat_succ_eqpoll, THEN cardinal_cong])
   458 apply (erule Ord_cardinal_le [THEN lt_trans2, THEN lt_irrefl])
   459 apply (rule le_eqI, assumption)
   460 apply (rule Ord_cardinal)
   461 done
   462 
   463 
   464 (*** An infinite cardinal equals its square (Kunen, Thm 10.12, page 29) ***)
   465 
   466 (*A general fact about ordermap*)
   467 lemma ordermap_eqpoll_pred:
   468     "[| well_ord(A,r);  x:A |] ==> ordermap(A,r)`x \<approx> Order.pred(A,x,r)"
   469 apply (unfold eqpoll_def)
   470 apply (rule exI)
   471 apply (simp add: ordermap_eq_image well_ord_is_wf)
   472 apply (erule ordermap_bij [THEN bij_is_inj, THEN restrict_bij,
   473                            THEN bij_converse_bij])
   474 apply (rule pred_subset)
   475 done
   476 
   477 subsubsection{*Establishing the well-ordering*}
   478 
   479 lemma well_ord_csquare: 
   480   assumes K: "Ord(K)" shows "well_ord(K*K, csquare_rel(K))"
   481 proof (unfold csquare_rel_def, rule well_ord_rvimage)
   482   show "(\<lambda>\<langle>x,y\<rangle>\<in>K \<times> K. \<langle>x \<union> y, x, y\<rangle>) \<in> inj(K \<times> K, K \<times> K \<times> K)" using K
   483     by (force simp add: inj_def intro: lam_type Un_least_lt [THEN ltD] ltI)
   484 next
   485   show "well_ord(K \<times> K \<times> K, rmult(K, Memrel(K), K \<times> K, rmult(K, Memrel(K), K, Memrel(K))))"
   486     using K by (blast intro: well_ord_rmult well_ord_Memrel)
   487 qed
   488 
   489 subsubsection{*Characterising initial segments of the well-ordering*}
   490 
   491 lemma csquareD:
   492  "[| <<x,y>, <z,z>> \<in> csquare_rel(K);  x<K;  y<K;  z<K |] ==> x \<le> z & y \<le> z"
   493 apply (unfold csquare_rel_def)
   494 apply (erule rev_mp)
   495 apply (elim ltE)
   496 apply (simp add: rvimage_iff Un_absorb Un_least_mem_iff ltD)
   497 apply (safe elim!: mem_irrefl intro!: Un_upper1_le Un_upper2_le)
   498 apply (simp_all add: lt_def succI2)
   499 done
   500 
   501 lemma pred_csquare_subset:
   502     "z<K ==> Order.pred(K*K, <z,z>, csquare_rel(K)) \<subseteq> succ(z)*succ(z)"
   503 apply (unfold Order.pred_def)
   504 apply (safe del: SigmaI dest!: csquareD)
   505 apply (unfold lt_def, auto)
   506 done
   507 
   508 lemma csquare_ltI:
   509  "[| x<z;  y<z;  z<K |] ==>  <<x,y>, <z,z>> \<in> csquare_rel(K)"
   510 apply (unfold csquare_rel_def)
   511 apply (subgoal_tac "x<K & y<K")
   512  prefer 2 apply (blast intro: lt_trans)
   513 apply (elim ltE)
   514 apply (simp add: rvimage_iff Un_absorb Un_least_mem_iff ltD)
   515 done
   516 
   517 (*Part of the traditional proof.  UNUSED since it's harder to prove & apply *)
   518 lemma csquare_or_eqI:
   519  "[| x \<le> z;  y \<le> z;  z<K |] ==> <<x,y>, <z,z>> \<in> csquare_rel(K) | x=z & y=z"
   520 apply (unfold csquare_rel_def)
   521 apply (subgoal_tac "x<K & y<K")
   522  prefer 2 apply (blast intro: lt_trans1)
   523 apply (elim ltE)
   524 apply (simp add: rvimage_iff Un_absorb Un_least_mem_iff ltD)
   525 apply (elim succE)
   526 apply (simp_all add: subset_Un_iff [THEN iff_sym]
   527                      subset_Un_iff2 [THEN iff_sym] OrdmemD)
   528 done
   529 
   530 subsubsection{*The cardinality of initial segments*}
   531 
   532 lemma ordermap_z_lt:
   533       "[| Limit(K);  x<K;  y<K;  z=succ(x \<union> y) |] ==>
   534           ordermap(K*K, csquare_rel(K)) ` <x,y> <
   535           ordermap(K*K, csquare_rel(K)) ` <z,z>"
   536 apply (subgoal_tac "z<K & well_ord (K*K, csquare_rel (K))")
   537 prefer 2 apply (blast intro!: Un_least_lt Limit_has_succ
   538                               Limit_is_Ord [THEN well_ord_csquare], clarify)
   539 apply (rule csquare_ltI [THEN ordermap_mono, THEN ltI])
   540 apply (erule_tac [4] well_ord_is_wf)
   541 apply (blast intro!: Un_upper1_le Un_upper2_le Ord_ordermap elim!: ltE)+
   542 done
   543 
   544 text{*Kunen: "each @{term"\<langle>x,y\<rangle> \<in> K \<times> K"} has no more than @{term"z \<times> z"} predecessors..." (page 29) *}
   545 lemma ordermap_csquare_le:
   546   assumes K: "Limit(K)" and x: "x<K" and y: " y<K" 
   547   defines "z \<equiv> succ(x \<union> y)"
   548   shows "|ordermap(K \<times> K, csquare_rel(K)) ` \<langle>x,y\<rangle>| \<le> |succ(z)| \<otimes> |succ(z)|"
   549 proof (unfold cmult_def, rule well_ord_lepoll_imp_Card_le)
   550   show "well_ord(|succ(z)| \<times> |succ(z)|, 
   551                  rmult(|succ(z)|, Memrel(|succ(z)|), |succ(z)|, Memrel(|succ(z)|)))"
   552     by (blast intro: Ord_cardinal well_ord_Memrel well_ord_rmult) 
   553 next
   554   have zK: "z<K" using x y K z_def
   555     by (blast intro: Un_least_lt Limit_has_succ)
   556   hence oz: "Ord(z)" by (elim ltE) 
   557   have "ordermap(K \<times> K, csquare_rel(K)) ` \<langle>x,y\<rangle> \<lesssim> ordermap(K \<times> K, csquare_rel(K)) ` \<langle>z,z\<rangle>"
   558     using z_def
   559     by (blast intro: ordermap_z_lt leI le_imp_lepoll K x y) 
   560   also have "... \<approx>  Order.pred(K \<times> K, \<langle>z,z\<rangle>, csquare_rel(K))"
   561     proof (rule ordermap_eqpoll_pred)
   562       show "well_ord(K \<times> K, csquare_rel(K))" using K 
   563         by (rule Limit_is_Ord [THEN well_ord_csquare])
   564     next
   565       show "\<langle>z, z\<rangle> \<in> K \<times> K" using zK
   566         by (blast intro: ltD)
   567     qed
   568   also have "...  \<lesssim> succ(z) \<times> succ(z)" using zK
   569     by (rule pred_csquare_subset [THEN subset_imp_lepoll])
   570   also have "... \<approx> |succ(z)| \<times> |succ(z)|" using oz
   571     by (blast intro: prod_eqpoll_cong Ord_succ Ord_cardinal_eqpoll eqpoll_sym) 
   572   finally show "ordermap(K \<times> K, csquare_rel(K)) ` \<langle>x,y\<rangle> \<lesssim> |succ(z)| \<times> |succ(z)|" .
   573 qed
   574 
   575 text{*Kunen: "... so the order type is @{text"\<le>"} K" *}
   576 lemma ordertype_csquare_le:
   577   assumes IK: "InfCard(K)" and eq: "\<And>y. y\<in>K \<Longrightarrow> InfCard(y) \<Longrightarrow> y \<otimes> y = y"
   578   shows "ordertype(K*K, csquare_rel(K)) \<le> K"
   579 proof -
   580   have  CK: "Card(K)" using IK by (rule InfCard_is_Card) 
   581   hence OK: "Ord(K)"  by (rule Card_is_Ord) 
   582   moreover have "Ord(ordertype(K \<times> K, csquare_rel(K)))" using OK
   583     by (rule well_ord_csquare [THEN Ord_ordertype])
   584   ultimately show ?thesis
   585   proof (rule all_lt_imp_le)
   586     fix i
   587     assume i: "i < ordertype(K \<times> K, csquare_rel(K))"
   588     hence Oi: "Ord(i)" by (elim ltE)
   589     obtain x y where x: "x \<in> K" and y: "y \<in> K" 
   590                  and ieq: "i = ordermap(K \<times> K, csquare_rel(K)) ` \<langle>x,y\<rangle>"
   591       using i by (auto simp add: ordertype_unfold elim: ltE)
   592     hence xy: "Ord(x)" "Ord(y)" "x < K" "y < K" using OK 
   593       by (blast intro: Ord_in_Ord ltI)+
   594     hence ou: "Ord(x \<union> y)"
   595       by (simp add: Ord_Un) 
   596     show "i < K"
   597       proof (rule Card_lt_imp_lt [OF _ Oi CK])
   598         have "|i| \<le> |succ(succ(x \<union> y))| \<otimes> |succ(succ(x \<union> y))|" using IK xy
   599           by (auto simp add: ieq intro: InfCard_is_Limit [THEN ordermap_csquare_le])
   600         moreover have "|succ(succ(x \<union> y))| \<otimes> |succ(succ(x \<union> y))| < K" 
   601           proof (cases rule: Ord_linear2 [OF ou Ord_nat])
   602             assume "x \<union> y < nat"
   603             hence "|succ(succ(x \<union> y))| \<otimes> |succ(succ(x \<union> y))| \<in> nat"
   604               by (simp add: lt_def nat_cmult_eq_mult nat_succI mult_type
   605                          nat_into_Card [THEN Card_cardinal_eq]  Ord_nat)
   606             also have "... \<subseteq> K" using IK
   607               by (simp add: InfCard_def le_imp_subset)
   608             finally show "|succ(succ(x \<union> y))| \<otimes> |succ(succ(x \<union> y))| < K" 
   609               by (simp add: ltI OK) 
   610           next
   611             assume natxy: "nat \<le> x \<union> y"
   612             hence seq: "|succ(succ(x \<union> y))| = |x \<union> y|" using xy 
   613               by (simp add: le_imp_subset nat_succ_eqpoll [THEN cardinal_cong] le_succ_iff)
   614             also have "... < K" using xy  
   615               by (simp add: Un_least_lt Ord_cardinal_le [THEN lt_trans1])
   616             finally have "|succ(succ(x \<union> y))| < K" .
   617             moreover have "InfCard(|succ(succ(x \<union> y))|)" using xy natxy
   618               by (simp add: seq InfCard_def Card_cardinal nat_le_cardinal)
   619             ultimately show ?thesis  by (simp add: eq ltD) 
   620           qed
   621         ultimately show "|i| < K" by (blast intro: lt_trans1) 
   622     qed
   623   qed
   624 qed
   625 
   626 (*Main result: Kunen's Theorem 10.12*)
   627 lemma InfCard_csquare_eq: 
   628   assumes IK: "InfCard(K)" shows "InfCard(K) ==> K \<otimes> K = K"
   629 proof -
   630   have  OK: "Ord(K)" using IK by (simp add: Card_is_Ord InfCard_is_Card) 
   631   have "InfCard(K) \<longrightarrow> K \<otimes> K = K"
   632     proof (rule trans_induct [OF OK], rule impI)
   633       fix i
   634       assume i: "Ord(i)" "InfCard(i)"
   635          and ih: " \<forall>y\<in>i. InfCard(y) \<longrightarrow> y \<otimes> y = y"
   636       show "i \<otimes> i = i"
   637         proof (rule le_anti_sym)
   638           have "|i \<times> i| = |ordertype(i \<times> i, csquare_rel(i))|" 
   639             by (rule cardinal_cong, 
   640                 simp add: i well_ord_csquare [THEN ordermap_bij, THEN bij_imp_eqpoll])
   641           hence "i \<otimes> i \<le> ordertype(i \<times> i, csquare_rel(i))" using i
   642             by (simp add: cmult_def Ord_cardinal_le well_ord_csquare [THEN Ord_ordertype])
   643           moreover
   644           have "ordertype(i \<times> i, csquare_rel(i)) \<le> i" using ih i
   645             by (simp add: ordertype_csquare_le) 
   646           ultimately show "i \<otimes> i \<le> i" by (rule le_trans)
   647         next
   648           show "i \<le> i \<otimes> i" using i
   649             by (blast intro: cmult_square_le InfCard_is_Card) 
   650         qed
   651     qed
   652   thus ?thesis using IK ..
   653 qed
   654 
   655 (*Corollary for arbitrary well-ordered sets (all sets, assuming AC)*)
   656 lemma well_ord_InfCard_square_eq:
   657   assumes r: "well_ord(A,r)" and I: "InfCard(|A|)" shows "A \<times> A \<approx> A"
   658 proof -
   659   have "A \<times> A \<approx> |A| \<times> |A|"
   660     by (blast intro: prod_eqpoll_cong well_ord_cardinal_eqpoll eqpoll_sym r) 
   661   also have "... \<approx> A"
   662     proof (rule well_ord_cardinal_eqE [OF _ r])
   663       show "well_ord(|A| \<times> |A|, rmult(|A|, Memrel(|A|), |A|, Memrel(|A|)))"
   664         by (blast intro: Ord_cardinal well_ord_rmult well_ord_Memrel r)
   665     next
   666       show "||A| \<times> |A|| = |A|" using InfCard_csquare_eq I
   667         by (simp add: cmult_def)
   668     qed    
   669   finally show ?thesis .
   670 qed
   671 
   672 lemma InfCard_square_eqpoll: "InfCard(K) ==> K \<times> K \<approx> K"
   673 apply (rule well_ord_InfCard_square_eq)
   674  apply (erule InfCard_is_Card [THEN Card_is_Ord, THEN well_ord_Memrel])
   675 apply (simp add: InfCard_is_Card [THEN Card_cardinal_eq])
   676 done
   677 
   678 lemma Inf_Card_is_InfCard: "[| ~Finite(i); Card(i) |] ==> InfCard(i)"
   679 by (simp add: InfCard_def Card_is_Ord [THEN nat_le_infinite_Ord])
   680 
   681 subsubsection{*Toward's Kunen's Corollary 10.13 (1)*}
   682 
   683 lemma InfCard_le_cmult_eq: "[| InfCard(K);  L \<le> K;  0<L |] ==> K \<otimes> L = K"
   684 apply (rule le_anti_sym)
   685  prefer 2
   686  apply (erule ltE, blast intro: cmult_le_self InfCard_is_Card)
   687 apply (frule InfCard_is_Card [THEN Card_is_Ord, THEN le_refl])
   688 apply (rule cmult_le_mono [THEN le_trans], assumption+)
   689 apply (simp add: InfCard_csquare_eq)
   690 done
   691 
   692 (*Corollary 10.13 (1), for cardinal multiplication*)
   693 lemma InfCard_cmult_eq: "[| InfCard(K);  InfCard(L) |] ==> K \<otimes> L = K \<union> L"
   694 apply (rule_tac i = K and j = L in Ord_linear_le)
   695 apply (typecheck add: InfCard_is_Card Card_is_Ord)
   696 apply (rule cmult_commute [THEN ssubst])
   697 apply (rule Un_commute [THEN ssubst])
   698 apply (simp_all add: InfCard_is_Limit [THEN Limit_has_0] InfCard_le_cmult_eq
   699                      subset_Un_iff2 [THEN iffD1] le_imp_subset)
   700 done
   701 
   702 lemma InfCard_cdouble_eq: "InfCard(K) ==> K \<oplus> K = K"
   703 apply (simp add: cmult_2 [symmetric] InfCard_is_Card cmult_commute)
   704 apply (simp add: InfCard_le_cmult_eq InfCard_is_Limit Limit_has_0 Limit_has_succ)
   705 done
   706 
   707 (*Corollary 10.13 (1), for cardinal addition*)
   708 lemma InfCard_le_cadd_eq: "[| InfCard(K);  L \<le> K |] ==> K \<oplus> L = K"
   709 apply (rule le_anti_sym)
   710  prefer 2
   711  apply (erule ltE, blast intro: cadd_le_self InfCard_is_Card)
   712 apply (frule InfCard_is_Card [THEN Card_is_Ord, THEN le_refl])
   713 apply (rule cadd_le_mono [THEN le_trans], assumption+)
   714 apply (simp add: InfCard_cdouble_eq)
   715 done
   716 
   717 lemma InfCard_cadd_eq: "[| InfCard(K);  InfCard(L) |] ==> K \<oplus> L = K \<union> L"
   718 apply (rule_tac i = K and j = L in Ord_linear_le)
   719 apply (typecheck add: InfCard_is_Card Card_is_Ord)
   720 apply (rule cadd_commute [THEN ssubst])
   721 apply (rule Un_commute [THEN ssubst])
   722 apply (simp_all add: InfCard_le_cadd_eq subset_Un_iff2 [THEN iffD1] le_imp_subset)
   723 done
   724 
   725 (*The other part, Corollary 10.13 (2), refers to the cardinality of the set
   726   of all n-tuples of elements of K.  A better version for the Isabelle theory
   727   might be  InfCard(K) ==> |list(K)| = K.
   728 *)
   729 
   730 subsection{*For Every Cardinal Number There Exists A Greater One*}
   731 
   732 text{*This result is Kunen's Theorem 10.16, which would be trivial using AC*}
   733 
   734 lemma Ord_jump_cardinal: "Ord(jump_cardinal(K))"
   735 apply (unfold jump_cardinal_def)
   736 apply (rule Ord_is_Transset [THEN [2] OrdI])
   737  prefer 2 apply (blast intro!: Ord_ordertype)
   738 apply (unfold Transset_def)
   739 apply (safe del: subsetI)
   740 apply (simp add: ordertype_pred_unfold, safe)
   741 apply (rule UN_I)
   742 apply (rule_tac [2] ReplaceI)
   743    prefer 4 apply (blast intro: well_ord_subset elim!: predE)+
   744 done
   745 
   746 (*Allows selective unfolding.  Less work than deriving intro/elim rules*)
   747 lemma jump_cardinal_iff:
   748      "i \<in> jump_cardinal(K) \<longleftrightarrow>
   749       (\<exists>r X. r \<subseteq> K*K & X \<subseteq> K & well_ord(X,r) & i = ordertype(X,r))"
   750 apply (unfold jump_cardinal_def)
   751 apply (blast del: subsetI)
   752 done
   753 
   754 (*The easy part of Theorem 10.16: jump_cardinal(K) exceeds K*)
   755 lemma K_lt_jump_cardinal: "Ord(K) ==> K < jump_cardinal(K)"
   756 apply (rule Ord_jump_cardinal [THEN [2] ltI])
   757 apply (rule jump_cardinal_iff [THEN iffD2])
   758 apply (rule_tac x="Memrel(K)" in exI)
   759 apply (rule_tac x=K in exI)
   760 apply (simp add: ordertype_Memrel well_ord_Memrel)
   761 apply (simp add: Memrel_def subset_iff)
   762 done
   763 
   764 (*The proof by contradiction: the bijection f yields a wellordering of X
   765   whose ordertype is jump_cardinal(K).  *)
   766 lemma Card_jump_cardinal_lemma:
   767      "[| well_ord(X,r);  r \<subseteq> K * K;  X \<subseteq> K;
   768          f \<in> bij(ordertype(X,r), jump_cardinal(K)) |]
   769       ==> jump_cardinal(K) \<in> jump_cardinal(K)"
   770 apply (subgoal_tac "f O ordermap (X,r) \<in> bij (X, jump_cardinal (K))")
   771  prefer 2 apply (blast intro: comp_bij ordermap_bij)
   772 apply (rule jump_cardinal_iff [THEN iffD2])
   773 apply (intro exI conjI)
   774 apply (rule subset_trans [OF rvimage_type Sigma_mono], assumption+)
   775 apply (erule bij_is_inj [THEN well_ord_rvimage])
   776 apply (rule Ord_jump_cardinal [THEN well_ord_Memrel])
   777 apply (simp add: well_ord_Memrel [THEN [2] bij_ordertype_vimage]
   778                  ordertype_Memrel Ord_jump_cardinal)
   779 done
   780 
   781 (*The hard part of Theorem 10.16: jump_cardinal(K) is itself a cardinal*)
   782 lemma Card_jump_cardinal: "Card(jump_cardinal(K))"
   783 apply (rule Ord_jump_cardinal [THEN CardI])
   784 apply (unfold eqpoll_def)
   785 apply (safe dest!: ltD jump_cardinal_iff [THEN iffD1])
   786 apply (blast intro: Card_jump_cardinal_lemma [THEN mem_irrefl])
   787 done
   788 
   789 subsection{*Basic Properties of Successor Cardinals*}
   790 
   791 lemma csucc_basic: "Ord(K) ==> Card(csucc(K)) & K < csucc(K)"
   792 apply (unfold csucc_def)
   793 apply (rule LeastI)
   794 apply (blast intro: Card_jump_cardinal K_lt_jump_cardinal Ord_jump_cardinal)+
   795 done
   796 
   797 lemmas Card_csucc = csucc_basic [THEN conjunct1]
   798 
   799 lemmas lt_csucc = csucc_basic [THEN conjunct2]
   800 
   801 lemma Ord_0_lt_csucc: "Ord(K) ==> 0 < csucc(K)"
   802 by (blast intro: Ord_0_le lt_csucc lt_trans1)
   803 
   804 lemma csucc_le: "[| Card(L);  K<L |] ==> csucc(K) \<le> L"
   805 apply (unfold csucc_def)
   806 apply (rule Least_le)
   807 apply (blast intro: Card_is_Ord)+
   808 done
   809 
   810 lemma lt_csucc_iff: "[| Ord(i); Card(K) |] ==> i < csucc(K) \<longleftrightarrow> |i| \<le> K"
   811 apply (rule iffI)
   812 apply (rule_tac [2] Card_lt_imp_lt)
   813 apply (erule_tac [2] lt_trans1)
   814 apply (simp_all add: lt_csucc Card_csucc Card_is_Ord)
   815 apply (rule notI [THEN not_lt_imp_le])
   816 apply (rule Card_cardinal [THEN csucc_le, THEN lt_trans1, THEN lt_irrefl], assumption)
   817 apply (rule Ord_cardinal_le [THEN lt_trans1])
   818 apply (simp_all add: Ord_cardinal Card_is_Ord)
   819 done
   820 
   821 lemma Card_lt_csucc_iff:
   822      "[| Card(K'); Card(K) |] ==> K' < csucc(K) \<longleftrightarrow> K' \<le> K"
   823 by (simp add: lt_csucc_iff Card_cardinal_eq Card_is_Ord)
   824 
   825 lemma InfCard_csucc: "InfCard(K) ==> InfCard(csucc(K))"
   826 by (simp add: InfCard_def Card_csucc Card_is_Ord
   827               lt_csucc [THEN leI, THEN [2] le_trans])
   828 
   829 
   830 subsubsection{*Removing elements from a finite set decreases its cardinality*}
   831 
   832 lemma Fin_imp_not_cons_lepoll: "A: Fin(U) ==> x\<notin>A \<longrightarrow> ~ cons(x,A) \<lesssim> A"
   833 apply (erule Fin_induct)
   834 apply (simp add: lepoll_0_iff)
   835 apply (subgoal_tac "cons (x,cons (xa,y)) = cons (xa,cons (x,y))")
   836 apply simp
   837 apply (blast dest!: cons_lepoll_consD, blast)
   838 done
   839 
   840 lemma Finite_imp_cardinal_cons [simp]:
   841      "[| Finite(A);  a\<notin>A |] ==> |cons(a,A)| = succ(|A|)"
   842 apply (unfold cardinal_def)
   843 apply (rule Least_equality)
   844 apply (fold cardinal_def)
   845 apply (simp add: succ_def)
   846 apply (blast intro: cons_eqpoll_cong well_ord_cardinal_eqpoll
   847              elim!: mem_irrefl  dest!: Finite_imp_well_ord)
   848 apply (blast intro: Card_cardinal Card_is_Ord)
   849 apply (rule notI)
   850 apply (rule Finite_into_Fin [THEN Fin_imp_not_cons_lepoll, THEN mp, THEN notE],
   851        assumption, assumption)
   852 apply (erule eqpoll_sym [THEN eqpoll_imp_lepoll, THEN lepoll_trans])
   853 apply (erule le_imp_lepoll [THEN lepoll_trans])
   854 apply (blast intro: well_ord_cardinal_eqpoll [THEN eqpoll_imp_lepoll]
   855              dest!: Finite_imp_well_ord)
   856 done
   857 
   858 
   859 lemma Finite_imp_succ_cardinal_Diff:
   860      "[| Finite(A);  a:A |] ==> succ(|A-{a}|) = |A|"
   861 apply (rule_tac b = A in cons_Diff [THEN subst], assumption)
   862 apply (simp add: Finite_imp_cardinal_cons Diff_subset [THEN subset_Finite])
   863 apply (simp add: cons_Diff)
   864 done
   865 
   866 lemma Finite_imp_cardinal_Diff: "[| Finite(A);  a:A |] ==> |A-{a}| < |A|"
   867 apply (rule succ_leE)
   868 apply (simp add: Finite_imp_succ_cardinal_Diff)
   869 done
   870 
   871 lemma Finite_cardinal_in_nat [simp]: "Finite(A) ==> |A| \<in> nat"
   872 apply (erule Finite_induct)
   873 apply (auto simp add: cardinal_0 Finite_imp_cardinal_cons)
   874 done
   875 
   876 lemma card_Un_Int:
   877      "[|Finite(A); Finite(B)|] ==> |A| #+ |B| = |A \<union> B| #+ |A \<inter> B|"
   878 apply (erule Finite_induct, simp)
   879 apply (simp add: Finite_Int cons_absorb Un_cons Int_cons_left)
   880 done
   881 
   882 lemma card_Un_disjoint:
   883      "[|Finite(A); Finite(B); A \<inter> B = 0|] ==> |A \<union> B| = |A| #+ |B|"
   884 by (simp add: Finite_Un card_Un_Int)
   885 
   886 lemma card_partition [rule_format]:
   887      "Finite(C) ==>
   888         Finite (\<Union> C) \<longrightarrow>
   889         (\<forall>c\<in>C. |c| = k) \<longrightarrow>
   890         (\<forall>c1 \<in> C. \<forall>c2 \<in> C. c1 \<noteq> c2 \<longrightarrow> c1 \<inter> c2 = 0) \<longrightarrow>
   891         k #* |C| = |\<Union> C|"
   892 apply (erule Finite_induct, auto)
   893 apply (subgoal_tac " x \<inter> \<Union>B = 0")
   894 apply (auto simp add: card_Un_disjoint Finite_Union
   895        subset_Finite [of _ "\<Union> (cons(x,F))"])
   896 done
   897 
   898 
   899 subsubsection{*Theorems by Krzysztof Grabczewski, proofs by lcp*}
   900 
   901 lemmas nat_implies_well_ord = nat_into_Ord [THEN well_ord_Memrel]
   902 
   903 lemma nat_sum_eqpoll_sum: 
   904   assumes m: "m \<in> nat" and n: "n \<in> nat" shows "m + n \<approx> m #+ n"
   905 proof -
   906   have "m + n \<approx> |m+n|" using m n
   907     by (blast intro: nat_implies_well_ord well_ord_radd well_ord_cardinal_eqpoll eqpoll_sym) 
   908   also have "... = m #+ n" using m n
   909     by (simp add: nat_cadd_eq_add [symmetric] cadd_def)
   910   finally show ?thesis .
   911 qed
   912 
   913 lemma Ord_subset_natD [rule_format]: "Ord(i) ==> i \<subseteq> nat \<longrightarrow> i \<in> nat | i=nat"
   914 apply (erule trans_induct3, auto)
   915 apply (blast dest!: nat_le_Limit [THEN le_imp_subset])
   916 done
   917 
   918 lemma Ord_nat_subset_into_Card: "[| Ord(i); i \<subseteq> nat |] ==> Card(i)"
   919 by (blast dest: Ord_subset_natD intro: Card_nat nat_into_Card)
   920 
   921 lemma Finite_Diff_sing_eq_diff_1: "[| Finite(A); x:A |] ==> |A-{x}| = |A| #- 1"
   922 apply (rule succ_inject)
   923 apply (rule_tac b = "|A|" in trans)
   924  apply (simp add: Finite_imp_succ_cardinal_Diff)
   925 apply (subgoal_tac "1 \<lesssim> A")
   926  prefer 2 apply (blast intro: not_0_is_lepoll_1)
   927 apply (frule Finite_imp_well_ord, clarify)
   928 apply (drule well_ord_lepoll_imp_Card_le)
   929  apply (auto simp add: cardinal_1)
   930 apply (rule trans)
   931  apply (rule_tac [2] diff_succ)
   932   apply (auto simp add: Finite_cardinal_in_nat)
   933 done
   934 
   935 lemma cardinal_lt_imp_Diff_not_0 [rule_format]:
   936      "Finite(B) ==> \<forall>A. |B|<|A| \<longrightarrow> A - B \<noteq> 0"
   937 apply (erule Finite_induct, auto)
   938 apply (case_tac "Finite (A)")
   939  apply (subgoal_tac [2] "Finite (cons (x, B))")
   940   apply (drule_tac [2] B = "cons (x, B) " in Diff_Finite)
   941    apply (auto simp add: Finite_0 Finite_cons)
   942 apply (subgoal_tac "|B|<|A|")
   943  prefer 2 apply (blast intro: lt_trans Ord_cardinal)
   944 apply (case_tac "x:A")
   945  apply (subgoal_tac [2] "A - cons (x, B) = A - B")
   946   apply auto
   947 apply (subgoal_tac "|A| \<le> |cons (x, B) |")
   948  prefer 2
   949  apply (blast dest: Finite_cons [THEN Finite_imp_well_ord]
   950               intro: well_ord_lepoll_imp_Card_le subset_imp_lepoll)
   951 apply (auto simp add: Finite_imp_cardinal_cons)
   952 apply (auto dest!: Finite_cardinal_in_nat simp add: le_iff)
   953 apply (blast intro: lt_trans)
   954 done
   955 
   956 end