src/HOL/Relation.thy
author noschinl
Mon Mar 12 15:12:22 2012 +0100 (2012-03-12)
changeset 46883 eec472dae593
parent 46882 6242b4bc05bc
child 46884 154dc6ec0041
permissions -rw-r--r--
tuned pred_set_conv lemmas. Skipped lemmas changing the lemmas generated by inductive_set
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory; Stefan Berghofer, TU Muenchen
     3 *)
     4 
     5 header {* Relations – as sets of pairs, and binary predicates *}
     6 
     7 theory Relation
     8 imports Datatype Finite_Set
     9 begin
    10 
    11 text {* A preliminary: classical rules for reasoning on predicates *}
    12 
    13 declare predicate1I [Pure.intro!, intro!]
    14 declare predicate1D [Pure.dest, dest]
    15 declare predicate2I [Pure.intro!, intro!]
    16 declare predicate2D [Pure.dest, dest]
    17 declare bot1E [elim!] 
    18 declare bot2E [elim!]
    19 declare top1I [intro!]
    20 declare top2I [intro!]
    21 declare inf1I [intro!]
    22 declare inf2I [intro!]
    23 declare inf1E [elim!]
    24 declare inf2E [elim!]
    25 declare sup1I1 [intro?]
    26 declare sup2I1 [intro?]
    27 declare sup1I2 [intro?]
    28 declare sup2I2 [intro?]
    29 declare sup1E [elim!]
    30 declare sup2E [elim!]
    31 declare sup1CI [intro!]
    32 declare sup2CI [intro!]
    33 declare INF1_I [intro!]
    34 declare INF2_I [intro!]
    35 declare INF1_D [elim]
    36 declare INF2_D [elim]
    37 declare INF1_E [elim]
    38 declare INF2_E [elim]
    39 declare SUP1_I [intro]
    40 declare SUP2_I [intro]
    41 declare SUP1_E [elim!]
    42 declare SUP2_E [elim!]
    43 
    44 subsection {* Fundamental *}
    45 
    46 subsubsection {* Relations as sets of pairs *}
    47 
    48 type_synonym 'a rel = "('a * 'a) set"
    49 
    50 lemma subrelI: -- {* Version of @{thm [source] subsetI} for binary relations *}
    51   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    52   by auto
    53 
    54 lemma lfp_induct2: -- {* Version of @{thm [source] lfp_induct} for binary relations *}
    55   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    56     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    57   using lfp_induct_set [of "(a, b)" f "prod_case P"] by auto
    58 
    59 
    60 subsubsection {* Conversions between set and predicate relations *}
    61 
    62 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    63   by (simp add: set_eq_iff fun_eq_iff)
    64 
    65 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    66   by (simp add: set_eq_iff fun_eq_iff)
    67 
    68 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    69   by (simp add: subset_iff le_fun_def)
    70 
    71 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    72   by (simp add: subset_iff le_fun_def)
    73 
    74 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    75   by (auto simp add: fun_eq_iff)
    76 
    77 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    78   by (auto simp add: fun_eq_iff)
    79 
    80 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    81   by (auto simp add: fun_eq_iff)
    82 
    83 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    84   by (auto simp add: fun_eq_iff)
    85 
    86 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
    87   by (simp add: inf_fun_def)
    88 
    89 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
    90   by (simp add: inf_fun_def)
    91 
    92 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
    93   by (simp add: sup_fun_def)
    94 
    95 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
    96   by (simp add: sup_fun_def)
    97 
    98 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
    99   by (simp add: fun_eq_iff Inf_apply)
   100 
   101 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   102   by (simp add: fun_eq_iff INF_apply)
   103 
   104 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (prod_case ` S) Collect)"
   105   by (simp add: fun_eq_iff Inf_apply INF_apply)
   106 
   107 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   108   by (simp add: fun_eq_iff INF_apply)
   109 
   110 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   111   by (simp add: fun_eq_iff Sup_apply)
   112 
   113 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   114   by (simp add: fun_eq_iff SUP_apply)
   115 
   116 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (prod_case ` S) Collect)"
   117   by (simp add: fun_eq_iff Sup_apply SUP_apply)
   118 
   119 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   120   by (simp add: fun_eq_iff SUP_apply)
   121 
   122 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i. r i))"
   123   by (simp add: INF_apply fun_eq_iff)
   124 
   125 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   126   by (simp add: INF_apply fun_eq_iff)
   127 
   128 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i. r i))"
   129   by (simp add: SUP_apply fun_eq_iff)
   130 
   131 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   132   by (simp add: SUP_apply fun_eq_iff)
   133 
   134 
   135 
   136 subsection {* Properties of relations *}
   137 
   138 subsubsection {* Reflexivity *}
   139 
   140 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   141 where
   142   "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   143 
   144 abbreviation refl :: "'a rel \<Rightarrow> bool"
   145 where -- {* reflexivity over a type *}
   146   "refl \<equiv> refl_on UNIV"
   147 
   148 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   149 where
   150   "reflp r \<longleftrightarrow> refl {(x, y). r x y}"
   151 
   152 lemma reflp_refl_eq [pred_set_conv]:
   153   "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r" 
   154   by (simp add: refl_on_def reflp_def)
   155 
   156 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   157   by (unfold refl_on_def) (iprover intro!: ballI)
   158 
   159 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   160   by (unfold refl_on_def) blast
   161 
   162 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   163   by (unfold refl_on_def) blast
   164 
   165 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   166   by (unfold refl_on_def) blast
   167 
   168 lemma reflpI:
   169   "(\<And>x. r x x) \<Longrightarrow> reflp r"
   170   by (auto intro: refl_onI simp add: reflp_def)
   171 
   172 lemma reflpE:
   173   assumes "reflp r"
   174   obtains "r x x"
   175   using assms by (auto dest: refl_onD simp add: reflp_def)
   176 
   177 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   178   by (unfold refl_on_def) blast
   179 
   180 lemma reflp_inf:
   181   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   182   by (auto intro: reflpI elim: reflpE)
   183 
   184 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   185   by (unfold refl_on_def) blast
   186 
   187 lemma reflp_sup:
   188   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   189   by (auto intro: reflpI elim: reflpE)
   190 
   191 lemma refl_on_INTER:
   192   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   193   by (unfold refl_on_def) fast
   194 
   195 lemma refl_on_UNION:
   196   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   197   by (unfold refl_on_def) blast
   198 
   199 lemma refl_on_empty [simp]: "refl_on {} {}"
   200   by (simp add:refl_on_def)
   201 
   202 lemma refl_on_def' [nitpick_unfold, code]:
   203   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   204   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   205 
   206 
   207 subsubsection {* Irreflexivity *}
   208 
   209 definition irrefl :: "'a rel \<Rightarrow> bool"
   210 where
   211   "irrefl r \<longleftrightarrow> (\<forall>x. (x, x) \<notin> r)"
   212 
   213 lemma irrefl_distinct [code]:
   214   "irrefl r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<noteq> y)"
   215   by (auto simp add: irrefl_def)
   216 
   217 
   218 subsubsection {* Symmetry *}
   219 
   220 definition sym :: "'a rel \<Rightarrow> bool"
   221 where
   222   "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   223 
   224 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   225 where
   226   "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   227 
   228 lemma symp_sym_eq [pred_set_conv]:
   229   "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r" 
   230   by (simp add: sym_def symp_def)
   231 
   232 lemma symI:
   233   "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   234   by (unfold sym_def) iprover
   235 
   236 lemma sympI:
   237   "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   238   by (fact symI [to_pred])
   239 
   240 lemma symE:
   241   assumes "sym r" and "(b, a) \<in> r"
   242   obtains "(a, b) \<in> r"
   243   using assms by (simp add: sym_def)
   244 
   245 lemma sympE:
   246   assumes "symp r" and "r b a"
   247   obtains "r a b"
   248   using assms by (rule symE [to_pred])
   249 
   250 lemma symD:
   251   assumes "sym r" and "(b, a) \<in> r"
   252   shows "(a, b) \<in> r"
   253   using assms by (rule symE)
   254 
   255 lemma sympD:
   256   assumes "symp r" and "r b a"
   257   shows "r a b"
   258   using assms by (rule symD [to_pred])
   259 
   260 lemma sym_Int:
   261   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   262   by (fast intro: symI elim: symE)
   263 
   264 lemma symp_inf:
   265   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   266   by (fact sym_Int [to_pred])
   267 
   268 lemma sym_Un:
   269   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   270   by (fast intro: symI elim: symE)
   271 
   272 lemma symp_sup:
   273   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   274   by (fact sym_Un [to_pred])
   275 
   276 lemma sym_INTER:
   277   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   278   by (fast intro: symI elim: symE)
   279 
   280 (* FIXME thm sym_INTER [to_pred] *)
   281 
   282 lemma sym_UNION:
   283   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   284   by (fast intro: symI elim: symE)
   285 
   286 (* FIXME thm sym_UNION [to_pred] *)
   287 
   288 
   289 subsubsection {* Antisymmetry *}
   290 
   291 definition antisym :: "'a rel \<Rightarrow> bool"
   292 where
   293   "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   294 
   295 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   296 where
   297   "antisymP r \<equiv> antisym {(x, y). r x y}"
   298 
   299 lemma antisymI:
   300   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   301   by (unfold antisym_def) iprover
   302 
   303 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   304   by (unfold antisym_def) iprover
   305 
   306 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   307   by (unfold antisym_def) blast
   308 
   309 lemma antisym_empty [simp]: "antisym {}"
   310   by (unfold antisym_def) blast
   311 
   312 
   313 subsubsection {* Transitivity *}
   314 
   315 definition trans :: "'a rel \<Rightarrow> bool"
   316 where
   317   "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   318 
   319 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   320 where
   321   "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   322 
   323 lemma transp_trans_eq [pred_set_conv]:
   324   "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r" 
   325   by (simp add: trans_def transp_def)
   326 
   327 abbreviation transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   328 where -- {* FIXME drop *}
   329   "transP r \<equiv> trans {(x, y). r x y}"
   330 
   331 lemma transI:
   332   "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   333   by (unfold trans_def) iprover
   334 
   335 lemma transpI:
   336   "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   337   by (fact transI [to_pred])
   338 
   339 lemma transE:
   340   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   341   obtains "(x, z) \<in> r"
   342   using assms by (unfold trans_def) iprover
   343 
   344 lemma transpE:
   345   assumes "transp r" and "r x y" and "r y z"
   346   obtains "r x z"
   347   using assms by (rule transE [to_pred])
   348 
   349 lemma transD:
   350   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   351   shows "(x, z) \<in> r"
   352   using assms by (rule transE)
   353 
   354 lemma transpD:
   355   assumes "transp r" and "r x y" and "r y z"
   356   shows "r x z"
   357   using assms by (rule transD [to_pred])
   358 
   359 lemma trans_Int:
   360   "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   361   by (fast intro: transI elim: transE)
   362 
   363 lemma transp_inf:
   364   "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   365   by (fact trans_Int [to_pred])
   366 
   367 lemma trans_INTER:
   368   "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   369   by (fast intro: transI elim: transD)
   370 
   371 (* FIXME thm trans_INTER [to_pred] *)
   372 
   373 lemma trans_join [code]:
   374   "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   375   by (auto simp add: trans_def)
   376 
   377 lemma transp_trans:
   378   "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   379   by (simp add: trans_def transp_def)
   380 
   381 
   382 subsubsection {* Totality *}
   383 
   384 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   385 where
   386   "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   387 
   388 abbreviation "total \<equiv> total_on UNIV"
   389 
   390 lemma total_on_empty [simp]: "total_on {} r"
   391   by (simp add: total_on_def)
   392 
   393 
   394 subsubsection {* Single valued relations *}
   395 
   396 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   397 where
   398   "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   399 
   400 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
   401   "single_valuedP r \<equiv> single_valued {(x, y). r x y}"
   402 
   403 lemma single_valuedI:
   404   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   405   by (unfold single_valued_def)
   406 
   407 lemma single_valuedD:
   408   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   409   by (simp add: single_valued_def)
   410 
   411 lemma single_valued_subset:
   412   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   413   by (unfold single_valued_def) blast
   414 
   415 
   416 subsection {* Relation operations *}
   417 
   418 subsubsection {* The identity relation *}
   419 
   420 definition Id :: "'a rel"
   421 where
   422   "Id = {p. \<exists>x. p = (x, x)}"
   423 
   424 lemma IdI [intro]: "(a, a) : Id"
   425   by (simp add: Id_def)
   426 
   427 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
   428   by (unfold Id_def) (iprover elim: CollectE)
   429 
   430 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   431   by (unfold Id_def) blast
   432 
   433 lemma refl_Id: "refl Id"
   434   by (simp add: refl_on_def)
   435 
   436 lemma antisym_Id: "antisym Id"
   437   -- {* A strange result, since @{text Id} is also symmetric. *}
   438   by (simp add: antisym_def)
   439 
   440 lemma sym_Id: "sym Id"
   441   by (simp add: sym_def)
   442 
   443 lemma trans_Id: "trans Id"
   444   by (simp add: trans_def)
   445 
   446 lemma single_valued_Id [simp]: "single_valued Id"
   447   by (unfold single_valued_def) blast
   448 
   449 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   450   by (simp add:irrefl_def)
   451 
   452 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   453   unfolding antisym_def trans_def by blast
   454 
   455 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   456   by (simp add: total_on_def)
   457 
   458 
   459 subsubsection {* Diagonal: identity over a set *}
   460 
   461 definition Id_on  :: "'a set \<Rightarrow> 'a rel"
   462 where
   463   "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   464 
   465 lemma Id_on_empty [simp]: "Id_on {} = {}"
   466   by (simp add: Id_on_def) 
   467 
   468 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   469   by (simp add: Id_on_def)
   470 
   471 lemma Id_onI [intro!,no_atp]: "a : A ==> (a, a) : Id_on A"
   472   by (rule Id_on_eqI) (rule refl)
   473 
   474 lemma Id_onE [elim!]:
   475   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   476   -- {* The general elimination rule. *}
   477   by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   478 
   479 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   480   by blast
   481 
   482 lemma Id_on_def' [nitpick_unfold]:
   483   "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   484   by auto
   485 
   486 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   487   by blast
   488 
   489 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   490   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   491 
   492 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   493   by (unfold antisym_def) blast
   494 
   495 lemma sym_Id_on [simp]: "sym (Id_on A)"
   496   by (rule symI) clarify
   497 
   498 lemma trans_Id_on [simp]: "trans (Id_on A)"
   499   by (fast intro: transI elim: transD)
   500 
   501 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   502   by (unfold single_valued_def) blast
   503 
   504 
   505 subsubsection {* Composition *}
   506 
   507 inductive_set rel_comp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set" (infixr "O" 75)
   508   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   509 where
   510   rel_compI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   511 
   512 abbreviation pred_comp (infixr "OO" 75) where
   513   "pred_comp \<equiv> rel_compp"
   514 
   515 lemmas pred_compI = rel_compp.intros
   516 
   517 text {*
   518   For historic reasons, the elimination rules are not wholly corresponding.
   519   Feel free to consolidate this.
   520 *}
   521 
   522 inductive_cases rel_compEpair: "(a, c) \<in> r O s"
   523 inductive_cases pred_compE [elim!]: "(r OO s) a c"
   524 
   525 lemma rel_compE [elim!]: "xz \<in> r O s \<Longrightarrow>
   526   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   527   by (cases xz) (simp, erule rel_compEpair, iprover)
   528 
   529 lemmas pred_comp_rel_comp_eq = rel_compp_rel_comp_eq
   530 
   531 lemma R_O_Id [simp]:
   532   "R O Id = R"
   533   by fast
   534 
   535 lemma Id_O_R [simp]:
   536   "Id O R = R"
   537   by fast
   538 
   539 lemma rel_comp_empty1 [simp]:
   540   "{} O R = {}"
   541   by blast
   542 
   543 lemma prod_comp_bot1 [simp]:
   544   "\<bottom> OO R = \<bottom>"
   545   by (fact rel_comp_empty1 [to_pred])
   546 
   547 lemma rel_comp_empty2 [simp]:
   548   "R O {} = {}"
   549   by blast
   550 
   551 lemma pred_comp_bot2 [simp]:
   552   "R OO \<bottom> = \<bottom>"
   553   by (fact rel_comp_empty2 [to_pred])
   554 
   555 lemma O_assoc:
   556   "(R O S) O T = R O (S O T)"
   557   by blast
   558 
   559 
   560 lemma pred_comp_assoc:
   561   "(r OO s) OO t = r OO (s OO t)"
   562   by (fact O_assoc [to_pred])
   563 
   564 lemma trans_O_subset:
   565   "trans r \<Longrightarrow> r O r \<subseteq> r"
   566   by (unfold trans_def) blast
   567 
   568 lemma transp_pred_comp_less_eq:
   569   "transp r \<Longrightarrow> r OO r \<le> r "
   570   by (fact trans_O_subset [to_pred])
   571 
   572 lemma rel_comp_mono:
   573   "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   574   by blast
   575 
   576 lemma pred_comp_mono:
   577   "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   578   by (fact rel_comp_mono [to_pred])
   579 
   580 lemma rel_comp_subset_Sigma:
   581   "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   582   by blast
   583 
   584 lemma rel_comp_distrib [simp]:
   585   "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   586   by auto
   587 
   588 lemma pred_comp_distrib [simp]:
   589   "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   590   by (fact rel_comp_distrib [to_pred])
   591 
   592 lemma rel_comp_distrib2 [simp]:
   593   "(S \<union> T) O R = (S O R) \<union> (T O R)"
   594   by auto
   595 
   596 lemma pred_comp_distrib2 [simp]:
   597   "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   598   by (fact rel_comp_distrib2 [to_pred])
   599 
   600 lemma rel_comp_UNION_distrib:
   601   "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   602   by auto
   603 
   604 (* FIXME thm rel_comp_UNION_distrib [to_pred] *)
   605 
   606 lemma rel_comp_UNION_distrib2:
   607   "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   608   by auto
   609 
   610 (* FIXME thm rel_comp_UNION_distrib2 [to_pred] *)
   611 
   612 lemma single_valued_rel_comp:
   613   "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   614   by (unfold single_valued_def) blast
   615 
   616 lemma rel_comp_unfold:
   617   "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   618   by (auto simp add: set_eq_iff)
   619 
   620 
   621 subsubsection {* Converse *}
   622 
   623 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set" ("(_^-1)" [1000] 999)
   624   for r :: "('a \<times> 'b) set"
   625 where
   626   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r^-1"
   627 
   628 notation (xsymbols)
   629   converse  ("(_\<inverse>)" [1000] 999)
   630 
   631 notation
   632   conversep ("(_^--1)" [1000] 1000)
   633 
   634 notation (xsymbols)
   635   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   636 
   637 lemma converseI [sym]:
   638   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   639   by (fact converse.intros)
   640 
   641 lemma conversepI (* CANDIDATE [sym] *):
   642   "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   643   by (fact conversep.intros)
   644 
   645 lemma converseD [sym]:
   646   "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   647   by (erule converse.cases) iprover
   648 
   649 lemma conversepD (* CANDIDATE [sym] *):
   650   "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   651   by (fact converseD [to_pred])
   652 
   653 lemma converseE [elim!]:
   654   -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   655   "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   656   by (cases yx) (simp, erule converse.cases, iprover)
   657 
   658 lemmas conversepE [elim!] = conversep.cases
   659 
   660 lemma converse_iff [iff]:
   661   "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   662   by (auto intro: converseI)
   663 
   664 lemma conversep_iff [iff]:
   665   "r\<inverse>\<inverse> a b = r b a"
   666   by (fact converse_iff [to_pred])
   667 
   668 lemma converse_converse [simp]:
   669   "(r\<inverse>)\<inverse> = r"
   670   by (simp add: set_eq_iff)
   671 
   672 lemma conversep_conversep [simp]:
   673   "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   674   by (fact converse_converse [to_pred])
   675 
   676 lemma converse_rel_comp: "(r O s)^-1 = s^-1 O r^-1"
   677   by blast
   678 
   679 lemma converse_pred_comp: "(r OO s)^--1 = s^--1 OO r^--1"
   680   by (iprover intro: order_antisym conversepI pred_compI
   681     elim: pred_compE dest: conversepD)
   682 
   683 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   684   by blast
   685 
   686 lemma converse_meet: "(r \<sqinter> s)^--1 = r^--1 \<sqinter> s^--1"
   687   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   688 
   689 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   690   by blast
   691 
   692 lemma converse_join: "(r \<squnion> s)^--1 = r^--1 \<squnion> s^--1"
   693   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   694 
   695 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   696   by fast
   697 
   698 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   699   by blast
   700 
   701 lemma converse_Id [simp]: "Id^-1 = Id"
   702   by blast
   703 
   704 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   705   by blast
   706 
   707 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   708   by (unfold refl_on_def) auto
   709 
   710 lemma sym_converse [simp]: "sym (converse r) = sym r"
   711   by (unfold sym_def) blast
   712 
   713 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   714   by (unfold antisym_def) blast
   715 
   716 lemma trans_converse [simp]: "trans (converse r) = trans r"
   717   by (unfold trans_def) blast
   718 
   719 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   720   by (unfold sym_def) fast
   721 
   722 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   723   by (unfold sym_def) blast
   724 
   725 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   726   by (unfold sym_def) blast
   727 
   728 lemma total_on_converse [simp]: "total_on A (r^-1) = total_on A r"
   729   by (auto simp: total_on_def)
   730 
   731 lemma finite_converse [iff]: "finite (r^-1) = finite r"
   732   apply (subgoal_tac "r^-1 = (%(x,y). (y,x))`r")
   733    apply simp
   734    apply (rule iffI)
   735     apply (erule finite_imageD [unfolded inj_on_def])
   736     apply (simp split add: split_split)
   737    apply (erule finite_imageI)
   738   apply (simp add: set_eq_iff image_def, auto)
   739   apply (rule bexI)
   740    prefer 2 apply assumption
   741   apply simp
   742   done
   743 
   744 lemma conversep_noteq [simp]: "(op \<noteq>)^--1 = op \<noteq>"
   745   by (auto simp add: fun_eq_iff)
   746 
   747 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   748   by (auto simp add: fun_eq_iff)
   749 
   750 lemma converse_unfold:
   751   "r\<inverse> = {(y, x). (x, y) \<in> r}"
   752   by (simp add: set_eq_iff)
   753 
   754 
   755 subsubsection {* Domain, range and field *}
   756 
   757 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set"
   758   for r :: "('a \<times> 'b) set"
   759 where
   760   DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   761 
   762 abbreviation (input) "DomainP \<equiv> Domainp"
   763 
   764 lemmas DomainPI = Domainp.DomainI
   765 
   766 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   767 inductive_cases DomainpE [elim!]: "Domainp r a"
   768 
   769 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set"
   770   for r :: "('a \<times> 'b) set"
   771 where
   772   RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   773 
   774 abbreviation (input) "RangeP \<equiv> Rangep"
   775 
   776 lemmas RangePI = Rangep.RangeI
   777 
   778 inductive_cases RangeE [elim!]: "b \<in> Range r"
   779 inductive_cases RangepE [elim!]: "Rangep r b"
   780 
   781 definition Field :: "'a rel \<Rightarrow> 'a set"
   782 where
   783   "Field r = Domain r \<union> Range r"
   784 
   785 lemma Domain_fst [code]:
   786   "Domain r = fst ` r"
   787   by force
   788 
   789 lemma Range_snd [code]:
   790   "Range r = snd ` r"
   791   by force
   792 
   793 lemma fst_eq_Domain: "fst ` R = Domain R"
   794   by force
   795 
   796 lemma snd_eq_Range: "snd ` R = Range R"
   797   by force
   798 
   799 lemma Domain_empty [simp]: "Domain {} = {}"
   800   by auto
   801 
   802 lemma Range_empty [simp]: "Range {} = {}"
   803   by auto
   804 
   805 lemma Field_empty [simp]: "Field {} = {}"
   806   by (simp add: Field_def)
   807 
   808 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   809   by auto
   810 
   811 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   812   by auto
   813 
   814 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   815   by blast
   816 
   817 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   818   by blast
   819 
   820 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   821   by (auto simp add: Field_def Domain_insert Range_insert)
   822 
   823 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   824   by blast
   825 
   826 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   827   by blast
   828 
   829 lemma Domain_Id [simp]: "Domain Id = UNIV"
   830   by blast
   831 
   832 lemma Range_Id [simp]: "Range Id = UNIV"
   833   by blast
   834 
   835 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   836   by blast
   837 
   838 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   839   by blast
   840 
   841 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   842   by blast
   843 
   844 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   845   by blast
   846 
   847 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   848   by (auto simp: Field_def)
   849 
   850 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   851   by blast
   852 
   853 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   854   by blast
   855 
   856 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   857   by blast
   858 
   859 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   860   by blast
   861 
   862 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   863   by blast
   864 
   865 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   866   by blast
   867 
   868 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   869   by (auto simp: Field_def)
   870 
   871 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   872   by auto
   873 
   874 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   875   by blast
   876 
   877 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   878   by (auto simp: Field_def)
   879 
   880 lemma Domain_Collect_split [simp]: "Domain {(x, y). P x y} = {x. EX y. P x y}"
   881   by auto
   882 
   883 lemma Range_Collect_split [simp]: "Range {(x, y). P x y} = {y. EX x. P x y}"
   884   by auto
   885 
   886 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   887   by (induct set: finite) (auto simp add: Domain_insert)
   888 
   889 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   890   by (induct set: finite) (auto simp add: Range_insert)
   891 
   892 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   893   by (simp add: Field_def finite_Domain finite_Range)
   894 
   895 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   896   by blast
   897 
   898 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   899   by blast
   900 
   901 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   902   by (auto simp: Field_def Domain_def Range_def)
   903 
   904 lemma Domain_unfold:
   905   "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   906   by blast
   907 
   908 lemma Domain_dprod [simp]: "Domain (dprod r s) = uprod (Domain r) (Domain s)"
   909   by auto
   910 
   911 lemma Domain_dsum [simp]: "Domain (dsum r s) = usum (Domain r) (Domain s)"
   912   by auto
   913 
   914 
   915 subsubsection {* Image of a set under a relation *}
   916 
   917 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set" (infixl "``" 90)
   918 where
   919   "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   920 
   921 declare Image_def [no_atp]
   922 
   923 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   924   by (simp add: Image_def)
   925 
   926 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   927   by (simp add: Image_def)
   928 
   929 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   930   by (rule Image_iff [THEN trans]) simp
   931 
   932 lemma ImageI [intro,no_atp]: "(a, b) : r ==> a : A ==> b : r``A"
   933   by (unfold Image_def) blast
   934 
   935 lemma ImageE [elim!]:
   936   "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   937   by (unfold Image_def) (iprover elim!: CollectE bexE)
   938 
   939 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   940   -- {* This version's more effective when we already have the required @{text a} *}
   941   by blast
   942 
   943 lemma Image_empty [simp]: "R``{} = {}"
   944   by blast
   945 
   946 lemma Image_Id [simp]: "Id `` A = A"
   947   by blast
   948 
   949 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
   950   by blast
   951 
   952 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   953   by blast
   954 
   955 lemma Image_Int_eq:
   956   "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   957   by (simp add: single_valued_def, blast) 
   958 
   959 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   960   by blast
   961 
   962 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   963   by blast
   964 
   965 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
   966   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   967 
   968 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   969   -- {* NOT suitable for rewriting *}
   970   by blast
   971 
   972 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
   973   by blast
   974 
   975 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
   976   by blast
   977 
   978 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
   979   by blast
   980 
   981 text{*Converse inclusion requires some assumptions*}
   982 lemma Image_INT_eq:
   983      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
   984 apply (rule equalityI)
   985  apply (rule Image_INT_subset) 
   986 apply  (simp add: single_valued_def, blast)
   987 done
   988 
   989 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
   990   by blast
   991 
   992 lemma Image_Collect_split [simp]: "{(x, y). P x y} `` A = {y. EX x:A. P x y}"
   993   by auto
   994 
   995 
   996 subsubsection {* Inverse image *}
   997 
   998 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
   999 where
  1000   "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1001 
  1002 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1003 where
  1004   "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1005 
  1006 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1007   by (simp add: inv_image_def inv_imagep_def)
  1008 
  1009 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
  1010   by (unfold sym_def inv_image_def) blast
  1011 
  1012 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
  1013   apply (unfold trans_def inv_image_def)
  1014   apply (simp (no_asm))
  1015   apply blast
  1016   done
  1017 
  1018 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
  1019   by (auto simp:inv_image_def)
  1020 
  1021 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
  1022   unfolding inv_image_def converse_unfold by auto
  1023 
  1024 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1025   by (simp add: inv_imagep_def)
  1026 
  1027 
  1028 subsubsection {* Powerset *}
  1029 
  1030 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1031 where
  1032   "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1033 
  1034 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1035   by (auto simp add: Powp_def fun_eq_iff)
  1036 
  1037 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1038 
  1039 end
  1040