src/Pure/sign.ML
author wenzelm
Fri Sep 29 22:47:01 2006 +0200 (2006-09-29)
changeset 20784 eece9aaaf352
parent 20777 00e560b6c112
child 21183 a76f457b6d86
permissions -rw-r--r--
Syntax.mode;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_const_constraint: xstring * string option -> theory -> theory
    27   val add_const_constraint_i: string * typ option -> theory -> theory
    28   val primitive_class: string * class list -> theory -> theory
    29   val primitive_classrel: class * class -> theory -> theory
    30   val primitive_arity: arity -> theory -> theory
    31   val add_trfuns:
    32     (string * (ast list -> ast)) list *
    33     (string * (term list -> term)) list *
    34     (string * (term list -> term)) list *
    35     (string * (ast list -> ast)) list -> theory -> theory
    36   val add_trfunsT:
    37     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    38   val add_advanced_trfuns:
    39     (string * (Context.generic -> ast list -> ast)) list *
    40     (string * (Context.generic -> term list -> term)) list *
    41     (string * (Context.generic -> term list -> term)) list *
    42     (string * (Context.generic -> ast list -> ast)) list -> theory -> theory
    43   val add_advanced_trfunsT:
    44     (string * (Context.generic -> bool -> typ -> term list -> term)) list -> theory -> theory
    45   val add_tokentrfuns:
    46     (string * string * (string -> string * real)) list -> theory -> theory
    47   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    48     -> theory -> theory
    49   val parse_ast_translation: bool * string -> theory -> theory
    50   val parse_translation: bool * string -> theory -> theory
    51   val print_translation: bool * string -> theory -> theory
    52   val typed_print_translation: bool * string -> theory -> theory
    53   val print_ast_translation: bool * string -> theory -> theory
    54   val token_translation: string -> theory -> theory
    55   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    56   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    57   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    58   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    59   val add_path: string -> theory -> theory
    60   val parent_path: theory -> theory
    61   val root_path: theory -> theory
    62   val absolute_path: theory -> theory
    63   val local_path: theory -> theory
    64   val no_base_names: theory -> theory
    65   val qualified_names: theory -> theory
    66   val sticky_prefix: string -> theory -> theory
    67   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    68     theory -> theory
    69   val restore_naming: theory -> theory -> theory
    70   val hide_classes: bool -> xstring list -> theory -> theory
    71   val hide_classes_i: bool -> string list -> theory -> theory
    72   val hide_types: bool -> xstring list -> theory -> theory
    73   val hide_types_i: bool -> string list -> theory -> theory
    74   val hide_consts: bool -> xstring list -> theory -> theory
    75   val hide_consts_i: bool -> string list -> theory -> theory
    76   val hide_names: bool -> string * xstring list -> theory -> theory
    77   val hide_names_i: bool -> string * string list -> theory -> theory
    78 end
    79 
    80 signature SIGN =
    81 sig
    82   val init_data: theory -> theory
    83   val rep_sg: theory ->
    84    {naming: NameSpace.naming,
    85     syn: Syntax.syntax,
    86     tsig: Type.tsig,
    87     consts: Consts.T}
    88   val naming_of: theory -> NameSpace.naming
    89   val base_name: string -> bstring
    90   val full_name: theory -> bstring -> string
    91   val full_name_path: theory -> string -> bstring -> string
    92   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    93   val syn_of: theory -> Syntax.syntax
    94   val tsig_of: theory -> Type.tsig
    95   val classes_of: theory -> Sorts.algebra
    96   val classes: theory -> class list
    97   val super_classes: theory -> class -> class list
    98   val defaultS: theory -> sort
    99   val subsort: theory -> sort * sort -> bool
   100   val of_sort: theory -> typ * sort -> bool
   101   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
   102   val universal_witness: theory -> (typ * sort) option
   103   val all_sorts_nonempty: theory -> bool
   104   val typ_instance: theory -> typ * typ -> bool
   105   val typ_equiv: theory -> typ * typ -> bool
   106   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
   107   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
   108   val is_logtype: theory -> string -> bool
   109   val consts_of: theory -> Consts.T
   110   val const_constraint: theory -> string -> typ option
   111   val the_const_constraint: theory -> string -> typ
   112   val const_type: theory -> string -> typ option
   113   val the_const_type: theory -> string -> typ
   114   val declared_tyname: theory -> string -> bool
   115   val declared_const: theory -> string -> bool
   116   val const_monomorphic: theory -> string -> bool
   117   val const_typargs: theory -> string * typ -> typ list
   118   val const_instance: theory -> string * typ list -> typ
   119   val class_space: theory -> NameSpace.T
   120   val type_space: theory -> NameSpace.T
   121   val const_space: theory -> NameSpace.T
   122   val intern_class: theory -> xstring -> string
   123   val extern_class: theory -> string -> xstring
   124   val intern_type: theory -> xstring -> string
   125   val extern_type: theory -> string -> xstring
   126   val intern_const: theory -> xstring -> string
   127   val extern_const: theory -> string -> xstring
   128   val intern_sort: theory -> sort -> sort
   129   val extern_sort: theory -> sort -> sort
   130   val intern_typ: theory -> typ -> typ
   131   val extern_typ: theory -> typ -> typ
   132   val intern_term: theory -> term -> term
   133   val extern_term: (string -> xstring) -> theory -> term -> term
   134   val intern_tycons: theory -> typ -> typ
   135   val pretty_term': Context.generic -> Syntax.syntax -> (string -> xstring) -> term -> Pretty.T
   136   val pretty_term: theory -> term -> Pretty.T
   137   val pretty_typ: theory -> typ -> Pretty.T
   138   val pretty_sort: theory -> sort -> Pretty.T
   139   val pretty_classrel: theory -> class list -> Pretty.T
   140   val pretty_arity: theory -> arity -> Pretty.T
   141   val string_of_term: theory -> term -> string
   142   val string_of_typ: theory -> typ -> string
   143   val string_of_sort: theory -> sort -> string
   144   val string_of_classrel: theory -> class list -> string
   145   val string_of_arity: theory -> arity -> string
   146   val pp: theory -> Pretty.pp
   147   val arity_number: theory -> string -> int
   148   val arity_sorts: theory -> string -> sort -> sort list
   149   val certify_class: theory -> class -> class
   150   val certify_sort: theory -> sort -> sort
   151   val certify_typ: theory -> typ -> typ
   152   val certify_typ_syntax: theory -> typ -> typ
   153   val certify_typ_abbrev: theory -> typ -> typ
   154   val certify': bool -> bool -> Pretty.pp -> Consts.T -> theory -> term -> term * typ * int
   155   val certify_term: theory -> term -> term * typ * int
   156   val certify_prop: theory -> term -> term * typ * int
   157   val cert_term: theory -> term -> term
   158   val cert_prop: theory -> term -> term
   159   val no_vars: Pretty.pp -> term -> term
   160   val cert_def: Pretty.pp -> term -> (string * typ) * term
   161   val read_class: theory -> xstring -> class
   162   val read_sort': Syntax.syntax -> Context.generic -> string -> sort
   163   val read_sort: theory -> string -> sort
   164   val read_arity: theory -> xstring * string list * string -> arity
   165   val cert_arity: theory -> arity -> arity
   166   val read_typ': Syntax.syntax -> Context.generic ->
   167     (indexname -> sort option) -> string -> typ
   168   val read_typ_syntax': Syntax.syntax -> Context.generic ->
   169     (indexname -> sort option) -> string -> typ
   170   val read_typ_abbrev': Syntax.syntax -> Context.generic ->
   171     (indexname -> sort option) -> string -> typ
   172   val read_typ: theory * (indexname -> sort option) -> string -> typ
   173   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   174   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   175   val read_tyname: theory -> string -> typ
   176   val read_const: theory -> string -> term
   177   val infer_types_simult: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   178     (indexname -> sort option) -> Name.context -> bool
   179     -> (term list * typ) list -> term list * (indexname * typ) list
   180   val infer_types: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   181     (indexname -> sort option) -> Name.context -> bool
   182     -> term list * typ -> term * (indexname * typ) list
   183   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   184     Context.generic -> (indexname -> typ option) * (indexname -> sort option) ->
   185     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   186   val read_def_terms:
   187     theory * (indexname -> typ option) * (indexname -> sort option) ->
   188     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   189   val simple_read_term: theory -> typ -> string -> term
   190   val read_term: theory -> string -> term
   191   val read_prop: theory -> string -> term
   192   val add_consts_authentic: (bstring * typ * mixfix) list -> theory -> theory
   193   val add_const_syntax: Syntax.mode -> (string * mixfix) list -> theory -> theory
   194   val add_abbrevs: Syntax.mode -> ((bstring * mixfix) * term) list -> theory -> theory
   195   include SIGN_THEORY
   196 end
   197 
   198 structure Sign: SIGN =
   199 struct
   200 
   201 
   202 (** datatype sign **)
   203 
   204 datatype sign = Sign of
   205  {naming: NameSpace.naming,     (*common naming conventions*)
   206   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   207   tsig: Type.tsig,              (*order-sorted signature of types*)
   208   consts: Consts.T};            (*polymorphic constants*)
   209 
   210 fun make_sign (naming, syn, tsig, consts) =
   211   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   212 
   213 structure SignData = TheoryDataFun
   214 (struct
   215   val name = "Pure/sign";
   216   type T = sign;
   217   val copy = I;
   218   fun extend (Sign {syn, tsig, consts, ...}) =
   219     make_sign (NameSpace.default_naming, syn, tsig, consts);
   220 
   221   val empty =
   222     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   223 
   224   fun merge pp (sign1, sign2) =
   225     let
   226       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   227       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   228 
   229       val naming = NameSpace.default_naming;
   230       val syn = Syntax.merge_syntaxes syn1 syn2;
   231       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   232       val consts = Consts.merge (consts1, consts2);
   233     in make_sign (naming, syn, tsig, consts) end;
   234 
   235   fun print _ _ = ();
   236 end);
   237 
   238 val init_data = SignData.init;
   239 
   240 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   241 
   242 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   243   make_sign (f (naming, syn, tsig, consts)));
   244 
   245 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   246 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   247 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   248 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   249 
   250 
   251 (* naming *)
   252 
   253 val naming_of = #naming o rep_sg;
   254 val base_name = NameSpace.base;
   255 val full_name = NameSpace.full o naming_of;
   256 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   257 val declare_name = NameSpace.declare o naming_of;
   258 
   259 
   260 (* syntax *)
   261 
   262 val syn_of = #syn o rep_sg;
   263 
   264 
   265 (* type signature *)
   266 
   267 val tsig_of = #tsig o rep_sg;
   268 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   269 val classes = Sorts.classes o classes_of;
   270 val super_classes = Sorts.super_classes o classes_of;
   271 val defaultS = Type.defaultS o tsig_of;
   272 val subsort = Type.subsort o tsig_of;
   273 val of_sort = Type.of_sort o tsig_of;
   274 val witness_sorts = Type.witness_sorts o tsig_of;
   275 val universal_witness = Type.universal_witness o tsig_of;
   276 val all_sorts_nonempty = is_some o universal_witness;
   277 val typ_instance = Type.typ_instance o tsig_of;
   278 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   279 val typ_match = Type.typ_match o tsig_of;
   280 val typ_unify = Type.unify o tsig_of;
   281 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   282 
   283 
   284 (* polymorphic constants *)
   285 
   286 val consts_of = #consts o rep_sg;
   287 val the_const_constraint = Consts.constraint o consts_of;
   288 val const_constraint = try o the_const_constraint;
   289 val the_const_type = Consts.declaration o consts_of;
   290 val const_type = try o the_const_type;
   291 val const_monomorphic = Consts.monomorphic o consts_of;
   292 val const_typargs = Consts.typargs o consts_of;
   293 val const_instance = Consts.instance o consts_of;
   294 
   295 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   296 val declared_const = is_some oo const_constraint;
   297 
   298 
   299 
   300 (** intern / extern names **)
   301 
   302 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   303 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   304 val const_space = Consts.space_of o consts_of;
   305 
   306 val intern_class = NameSpace.intern o class_space;
   307 val extern_class = NameSpace.extern o class_space;
   308 val intern_type = NameSpace.intern o type_space;
   309 val extern_type = NameSpace.extern o type_space;
   310 val intern_const = NameSpace.intern o const_space;
   311 val extern_const = NameSpace.extern o const_space;
   312 
   313 val intern_sort = map o intern_class;
   314 val extern_sort = map o extern_class;
   315 
   316 local
   317 
   318 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   319   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   320   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   321 
   322 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   323   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   324   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   325   | map_term _ _ _ (t as Bound _) = t
   326   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   327   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   328 
   329 val add_classesT = Term.fold_atyps
   330   (fn TFree (_, S) => fold (insert (op =)) S
   331     | TVar (_, S) => fold (insert (op =)) S
   332     | _ => I);
   333 
   334 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   335   | add_tyconsT _ = I;
   336 
   337 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   338 
   339 fun mapping add_names f t =
   340   let
   341     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   342     val tab = map_filter f' (add_names t []);
   343     fun get x = the_default x (AList.lookup (op =) tab x);
   344   in get end;
   345 
   346 fun typ_mapping f g thy T =
   347   T |> map_typ
   348     (mapping add_classesT (f thy) T)
   349     (mapping add_tyconsT (g thy) T);
   350 
   351 fun term_mapping f g h thy t =
   352   t |> map_term
   353     (mapping (Term.fold_types add_classesT) (f thy) t)
   354     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   355     (mapping add_consts (h thy) t);
   356 
   357 in
   358 
   359 val intern_typ = typ_mapping intern_class intern_type;
   360 val extern_typ = typ_mapping extern_class extern_type;
   361 val intern_term = term_mapping intern_class intern_type intern_const;
   362 fun extern_term h = term_mapping extern_class extern_type (K h);
   363 val intern_tycons = typ_mapping (K I) intern_type;
   364 
   365 end;
   366 
   367 
   368 
   369 (** pretty printing of terms, types etc. **)
   370 
   371 fun pretty_term' context syn ext t =
   372   let val curried = Context.exists_name Context.CPureN (Context.theory_of context)
   373   in Syntax.pretty_term ext context syn curried t end;
   374 
   375 fun pretty_term thy t =
   376   pretty_term' (Context.Theory thy) (syn_of thy) (Consts.extern (consts_of thy))
   377     (extern_term (Consts.extern_early (consts_of thy)) thy t);
   378 
   379 fun pretty_typ thy T = Syntax.pretty_typ (Context.Theory thy) (syn_of thy) (extern_typ thy T);
   380 fun pretty_sort thy S = Syntax.pretty_sort (Context.Theory thy) (syn_of thy) (extern_sort thy S);
   381 
   382 fun pretty_classrel thy cs = Pretty.block (flat
   383   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   384 
   385 fun pretty_arity thy (a, Ss, S) =
   386   let
   387     val a' = extern_type thy a;
   388     val dom =
   389       if null Ss then []
   390       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   391   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   392 
   393 val string_of_term = Pretty.string_of oo pretty_term;
   394 val string_of_typ = Pretty.string_of oo pretty_typ;
   395 val string_of_sort = Pretty.string_of oo pretty_sort;
   396 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   397 val string_of_arity = Pretty.string_of oo pretty_arity;
   398 
   399 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   400   pretty_classrel thy, pretty_arity thy);
   401 
   402 
   403 
   404 (** certify entities **)    (*exception TYPE*)
   405 
   406 (* certify wrt. type signature *)
   407 
   408 val arity_number = Type.arity_number o tsig_of;
   409 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   410 
   411 fun certify cert = cert o tsig_of o Context.check_thy;
   412 
   413 val certify_class      = certify Type.cert_class;
   414 val certify_sort       = certify Type.cert_sort;
   415 val certify_typ        = certify Type.cert_typ;
   416 val certify_typ_syntax = certify Type.cert_typ_syntax;
   417 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   418 
   419 
   420 (* certify term/prop *)
   421 
   422 local
   423 
   424 fun type_check pp tm =
   425   let
   426     fun err_appl why bs t T u U =
   427       let
   428         val xs = map Free bs;           (*we do not rename here*)
   429         val t' = subst_bounds (xs, t);
   430         val u' = subst_bounds (xs, u);
   431         val msg = cat_lines
   432           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   433       in raise TYPE (msg, [T, U], [t', u']) end;
   434 
   435     fun typ_of (_, Const (_, T)) = T
   436       | typ_of (_, Free  (_, T)) = T
   437       | typ_of (_, Var (_, T)) = T
   438       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   439           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   440       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   441       | typ_of (bs, t $ u) =
   442           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   443             (case T of
   444               Type ("fun", [T1, T2]) =>
   445                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   446             | _ => err_appl "Operator not of function type" bs t T u U)
   447           end;
   448   in typ_of ([], tm) end;
   449 
   450 fun err msg = raise TYPE (msg, [], []);
   451 
   452 fun check_vars (t $ u) = (check_vars t; check_vars u)
   453   | check_vars (Abs (_, _, t)) = check_vars t
   454   | check_vars (Var (xi as (_, i), _)) =
   455       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   456   | check_vars _ = ();
   457 
   458 in
   459 
   460 fun certify' normalize prop pp consts thy tm =
   461   let
   462     val _ = Context.check_thy thy;
   463     val _ = check_vars tm;
   464     val tm' = Term.map_types (certify_typ thy) tm;
   465     val T = type_check pp tm';
   466     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   467     val tm'' = Consts.certify pp (tsig_of thy) consts tm';
   468     val tm'' = if normalize then tm'' else tm';
   469   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   470 
   471 fun certify_term thy = certify' true false (pp thy) (consts_of thy) thy;
   472 fun certify_prop thy = certify' true true (pp thy) (consts_of thy) thy;
   473 
   474 fun cert_term_abbrev thy = #1 o certify' false false (pp thy) (consts_of thy) thy;
   475 val cert_term = #1 oo certify_term;
   476 val cert_prop = #1 oo certify_prop;
   477 
   478 end;
   479 
   480 
   481 (* specifications *)
   482 
   483 fun no_vars pp tm =
   484   (case (Term.add_vars tm [], Term.add_tvars tm []) of
   485     ([], []) => tm
   486   | (vars, tvars) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   487       (Pretty.str "Illegal schematic variable(s) in term:" ::
   488        map (Pretty.term pp o Var) vars @ map (Pretty.typ pp o TVar) tvars)))));
   489 
   490 fun cert_def pp tm =
   491   let val ((lhs, rhs), _) = tm
   492     |> no_vars pp
   493     |> Logic.strip_imp_concl
   494     |> Logic.dest_def pp Term.is_Const (K false) (K false)
   495   in (Term.dest_Const (Term.head_of lhs), rhs) end
   496   handle TERM (msg, _) => error msg;
   497 
   498 
   499 
   500 (** read and certify entities **)    (*exception ERROR*)
   501 
   502 (* classes and sorts *)
   503 
   504 fun read_class thy c = certify_class thy (intern_class thy c)
   505   handle TYPE (msg, _, _) => error msg;
   506 
   507 fun read_sort' syn context str =
   508   let
   509     val thy = Context.theory_of context;
   510     val _ = Context.check_thy thy;
   511     val S = intern_sort thy (Syntax.read_sort context syn str);
   512   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   513 
   514 fun read_sort thy str = read_sort' (syn_of thy) (Context.Theory thy) str;
   515 
   516 
   517 (* type arities *)
   518 
   519 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   520   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   521   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   522 
   523 val read_arity = prep_arity intern_type read_sort;
   524 val cert_arity = prep_arity (K I) certify_sort;
   525 
   526 
   527 (* types *)
   528 
   529 local
   530 
   531 fun gen_read_typ' cert syn context def_sort str =
   532   let
   533     val thy = Context.theory_of context;
   534     val _ = Context.check_thy thy;
   535     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   536     val T = intern_tycons thy (Syntax.read_typ context syn get_sort (intern_sort thy) str);
   537   in cert thy T handle TYPE (msg, _, _) => error msg end
   538   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   539 
   540 fun gen_read_typ cert (thy, def_sort) str =
   541   gen_read_typ' cert (syn_of thy) (Context.Theory thy) def_sort str;
   542 
   543 in
   544 
   545 fun no_def_sort thy = (thy: theory, K NONE);
   546 
   547 val read_typ'        = gen_read_typ' certify_typ;
   548 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   549 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   550 val read_typ         = gen_read_typ certify_typ;
   551 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   552 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   553 
   554 end;
   555 
   556 
   557 (* type and constant names *)
   558 
   559 fun read_tyname thy raw_c =
   560   let val c = intern_type thy raw_c
   561   in Type (c, replicate (arity_number thy c) dummyT) end;
   562 
   563 val read_const = Consts.read_const o consts_of;
   564 
   565 
   566 
   567 (** infer_types **)         (*exception ERROR*)
   568 
   569 (*
   570   def_type: partial map from indexnames to types (constrains Frees and Vars)
   571   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   572   used: context of already used type variables
   573   freeze: if true then generated parameters are turned into TFrees, else TVars
   574 
   575   termss: lists of alternative parses (only one combination should be type-correct)
   576   typs: expected types
   577 *)
   578 
   579 fun infer_types_simult pp thy consts def_type def_sort used freeze args =
   580   let
   581     val termss = fold_rev (multiply o fst) args [[]];
   582     val typs =
   583       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   584 
   585     fun infer ts = Result (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   586         (try (Consts.constraint consts)) def_type def_sort (Consts.intern consts)
   587         (intern_tycons thy) (intern_sort thy) used freeze typs ts)
   588       handle TYPE (msg, _, _) => Exn (ERROR msg);
   589 
   590     val err_results = map infer termss;
   591     val errs = map_filter (fn Exn (ERROR msg) => SOME msg | _ => NONE) err_results;
   592     val results = map_filter get_result err_results;
   593 
   594     val ambiguity = length termss;
   595     fun ambig_msg () =
   596       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level then
   597         "Got more than one parse tree.\n\
   598         \Retry with smaller Syntax.ambiguity_level for more information."
   599       else "";
   600   in
   601     if null results then (cat_error (ambig_msg ()) (cat_lines errs))
   602     else if length results = 1 then
   603       (if ambiguity > ! Syntax.ambiguity_level then
   604         warning "Fortunately, only one parse tree is type correct.\n\
   605           \You may still want to disambiguate your grammar or your input."
   606       else (); hd results)
   607     else (cat_error (ambig_msg ()) ("More than one term is type correct:\n" ^
   608       cat_lines (map (Pretty.string_of_term pp) (maps fst results))))
   609   end;
   610 
   611 fun infer_types pp thy consts def_type def_sort used freeze tsT =
   612   apfst hd (infer_types_simult pp thy consts def_type def_sort used freeze [tsT]);
   613 
   614 
   615 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   616 
   617 fun read_def_terms' pp is_logtype syn consts context (types, sorts) used freeze sTs =
   618   let
   619     val thy = Context.theory_of context;
   620     fun read (s, T) =
   621       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   622       in (Syntax.read context is_logtype syn T' s, T') end;
   623   in infer_types_simult pp thy consts types sorts used freeze (map read sTs) end;
   624 
   625 fun read_def_terms (thy, types, sorts) used freeze sTs =
   626   let
   627     val pp = pp thy;
   628     val consts = consts_of thy;
   629     val cert_consts = Consts.certify pp (tsig_of thy) consts;
   630     val (ts, inst) =
   631       read_def_terms' pp (is_logtype thy) (syn_of thy) consts
   632         (Context.Theory thy) (types, sorts) (Name.make_context used) freeze sTs;
   633   in (map cert_consts ts, inst) end;
   634 
   635 fun simple_read_term thy T s =
   636   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   637   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   638 
   639 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   640 fun read_prop thy = simple_read_term thy propT;
   641 
   642 
   643 
   644 (** signature extension functions **)  (*exception ERROR/TYPE*)
   645 
   646 (* add default sort *)
   647 
   648 fun gen_add_defsort prep_sort s thy =
   649   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   650 
   651 val add_defsort = gen_add_defsort read_sort;
   652 val add_defsort_i = gen_add_defsort certify_sort;
   653 
   654 
   655 (* add type constructors *)
   656 
   657 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   658   let
   659     val syn' = Syntax.extend_type_gram types syn;
   660     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   661     val tsig' = Type.add_types naming decls tsig;
   662   in (naming, syn', tsig', consts) end);
   663 
   664 fun add_typedecls decls thy =
   665   let
   666     fun type_of (a, vs: string list, mx) =
   667       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   668       else error ("Duplicate parameters in type declaration: " ^ quote a);
   669   in add_types (map type_of decls) thy end;
   670 
   671 
   672 (* add nonterminals *)
   673 
   674 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   675   let
   676     val syn' = Syntax.extend_consts ns syn;
   677     val tsig' = Type.add_nonterminals naming ns tsig;
   678   in (naming, syn', tsig', consts) end);
   679 
   680 
   681 (* add type abbreviations *)
   682 
   683 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   684   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   685     let
   686       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   687       val a' = Syntax.type_name a mx;
   688       val abbr = (a', vs, prep_typ thy rhs)
   689         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   690       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   691     in (naming, syn', tsig', consts) end);
   692 
   693 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   694 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   695 
   696 
   697 (* modify syntax *)
   698 
   699 fun gen_syntax change_gram prep_typ mode args thy =
   700   let
   701     fun prep (c, T, mx) = (c, prep_typ thy T, mx) handle ERROR msg =>
   702       cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   703   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   704 
   705 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   706 
   707 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   708 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   709 val add_syntax = add_modesyntax Syntax.default_mode;
   710 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   711 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   712 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   713 
   714 fun add_const_syntax mode args thy =
   715   thy |> add_modesyntax_i mode (map (Consts.syntax (consts_of thy)) args);
   716 
   717 
   718 (* add constants *)
   719 
   720 local
   721 
   722 fun gen_add_consts prep_typ authentic raw_args thy =
   723   let
   724     val prepT = Compress.typ thy o Logic.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   725     fun prep (raw_c, raw_T, raw_mx) =
   726       let
   727         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   728         val c' = if authentic then Syntax.constN ^ full_name thy c else c;
   729         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   730           cat_error msg ("in declaration of constant " ^ quote c);
   731       in (((c, T), authentic), (c', T, mx)) end;
   732     val args = map prep raw_args;
   733   in
   734     thy
   735     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   736     |> add_syntax_i (map #2 args)
   737   end;
   738 
   739 in
   740 
   741 val add_consts = gen_add_consts (read_typ o no_def_sort) false;
   742 val add_consts_i = gen_add_consts certify_typ false;
   743 val add_consts_authentic = gen_add_consts certify_typ true;
   744 
   745 end;
   746 
   747 
   748 (* add abbreviations *)
   749 
   750 fun add_abbrevs (mode, inout) = fold (fn ((raw_c, raw_mx), raw_t) => fn thy =>
   751   let
   752     val prep_tm = Compress.term thy o Logic.varify o no_vars (pp thy) o
   753       Term.no_dummy_patterns o cert_term_abbrev thy;
   754 
   755     val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   756     val c' = Syntax.constN ^ full_name thy c;
   757     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   758       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   759     val T = Term.fastype_of t;
   760   in
   761     thy
   762     |> map_consts (Consts.abbreviate (pp thy) (tsig_of thy) (naming_of thy) mode ((c, t), true))
   763     |> add_modesyntax_i (mode, inout) [(c', T, mx)]
   764   end);
   765 
   766 
   767 (* add constraints *)
   768 
   769 fun gen_add_constraint int_const prep_typ (raw_c, opt_T) thy =
   770   let
   771     val c = int_const thy raw_c;
   772     fun prepT raw_T =
   773       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (prep_typ thy raw_T)))
   774       in cert_term thy (Const (c, T)); T end
   775       handle TYPE (msg, _, _) => error msg;
   776   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   777 
   778 val add_const_constraint = gen_add_constraint intern_const (read_typ o no_def_sort);
   779 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   780 
   781 
   782 (* primitive classes and arities *)
   783 
   784 fun primitive_class (bclass, classes) thy =
   785   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   786     let
   787       val syn' = Syntax.extend_consts [bclass] syn;
   788       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   789     in (naming, syn', tsig', consts) end)
   790   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   791 
   792 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   793 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   794 
   795 
   796 (* add translation functions *)
   797 
   798 local
   799 
   800 fun mk trs = map Syntax.mk_trfun trs;
   801 
   802 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   803   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   804 
   805 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   806 
   807 in
   808 
   809 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   810 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   811 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   812 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   813 
   814 end;
   815 
   816 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   817 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   818 
   819 
   820 (* compile translation functions *)
   821 
   822 local
   823 
   824 fun advancedT false = ""
   825   | advancedT true = "Context.generic -> ";
   826 
   827 fun advancedN false = ""
   828   | advancedN true = "advanced_";
   829 
   830 in
   831 
   832 fun parse_ast_translation (a, txt) =
   833   txt |> Context.use_let ("val parse_ast_translation: (string * (" ^ advancedT a ^
   834       "Syntax.ast list -> Syntax.ast)) list")
   835     ("Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], [])");
   836 
   837 fun parse_translation (a, txt) =
   838   txt |> Context.use_let ("val parse_translation: (string * (" ^ advancedT a ^
   839       "term list -> term)) list")
   840     ("Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], [])");
   841 
   842 fun print_translation (a, txt) =
   843   txt |> Context.use_let ("val print_translation: (string * (" ^ advancedT a ^
   844       "term list -> term)) list")
   845     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, [])");
   846 
   847 fun print_ast_translation (a, txt) =
   848   txt |> Context.use_let ("val print_ast_translation: (string * (" ^ advancedT a ^
   849       "Syntax.ast list -> Syntax.ast)) list")
   850     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation)");
   851 
   852 fun typed_print_translation (a, txt) =
   853   txt |> Context.use_let ("val typed_print_translation: (string * (" ^ advancedT a ^
   854       "bool -> typ -> term list -> term)) list")
   855     ("Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation");
   856 
   857 val token_translation =
   858   Context.use_let "val token_translation: (string * string * (string -> string * real)) list"
   859     "Sign.add_tokentrfuns token_translation";
   860 
   861 end;
   862 
   863 
   864 (* translation rules *)
   865 
   866 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   867   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   868   in f (Context.Theory thy) (is_logtype thy) syn rules syn end);
   869 
   870 val add_trrules = gen_trrules Syntax.extend_trrules;
   871 val del_trrules = gen_trrules Syntax.remove_trrules;
   872 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   873 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   874 
   875 
   876 (* modify naming *)
   877 
   878 val add_path        = map_naming o NameSpace.add_path;
   879 val no_base_names   = map_naming NameSpace.no_base_names;
   880 val qualified_names = map_naming NameSpace.qualified_names;
   881 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   882 val set_policy      = map_naming o NameSpace.set_policy;
   883 val restore_naming  = map_naming o K o naming_of;
   884 
   885 val parent_path   = add_path "..";
   886 val root_path     = add_path "/";
   887 val absolute_path = add_path "//";
   888 
   889 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   890 
   891 
   892 (* hide names *)
   893 
   894 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   895 val hide_classes_i = map_tsig oo Type.hide_classes;
   896 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   897 val hide_types_i = map_tsig oo Type.hide_types;
   898 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   899 val hide_consts_i = map_consts oo (fold o Consts.hide);
   900 
   901 local
   902 
   903 val kinds =
   904  [("class", (intern_class, can o certify_class, hide_classes_i)),
   905   ("type", (intern_type, declared_tyname, hide_types_i)),
   906   ("const", (intern_const, declared_const, hide_consts_i))];
   907 
   908 fun gen_hide int b (kind, xnames) thy =
   909   (case AList.lookup (op =) kinds kind of
   910     SOME (intern, check, hide) =>
   911       let
   912         val names = if int then map (intern thy) xnames else xnames;
   913         val bads = filter_out (check thy) names;
   914       in
   915         if null bads then hide b names thy
   916         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   917       end
   918   | NONE => error ("Bad name space specification: " ^ quote kind));
   919 
   920 in
   921 
   922 val hide_names = gen_hide true;
   923 val hide_names_i = gen_hide false;
   924 
   925 end;
   926 
   927 end;