src/HOL/Probability/Probability_Mass_Function.thy
author Andreas Lochbihler
Tue Feb 10 12:27:30 2015 +0100 (2015-02-10)
changeset 59492 ef195926dd98
parent 59490 f71732294f29
child 59496 6faf024a1893
permissions -rw-r--r--
tuned proof
     1 (*  Title:      HOL/Probability/Probability_Mass_Function.thy
     2     Author:     Johannes Hölzl, TU München 
     3     Author:     Andreas Lochbihler, ETH Zurich
     4 *)
     5 
     6 section \<open> Probability mass function \<close>
     7 
     8 theory Probability_Mass_Function
     9 imports
    10   Giry_Monad
    11   "~~/src/HOL/Number_Theory/Binomial"
    12   "~~/src/HOL/Library/Multiset"
    13 begin
    14 
    15 lemma (in finite_measure) countable_support:
    16   "countable {x. measure M {x} \<noteq> 0}"
    17 proof cases
    18   assume "measure M (space M) = 0"
    19   with bounded_measure measure_le_0_iff have "{x. measure M {x} \<noteq> 0} = {}"
    20     by auto
    21   then show ?thesis
    22     by simp
    23 next
    24   let ?M = "measure M (space M)" and ?m = "\<lambda>x. measure M {x}"
    25   assume "?M \<noteq> 0"
    26   then have *: "{x. ?m x \<noteq> 0} = (\<Union>n. {x. ?M / Suc n < ?m x})"
    27     using reals_Archimedean[of "?m x / ?M" for x]
    28     by (auto simp: field_simps not_le[symmetric] measure_nonneg divide_le_0_iff measure_le_0_iff)
    29   have **: "\<And>n. finite {x. ?M / Suc n < ?m x}"
    30   proof (rule ccontr)
    31     fix n assume "infinite {x. ?M / Suc n < ?m x}" (is "infinite ?X")
    32     then obtain X where "finite X" "card X = Suc (Suc n)" "X \<subseteq> ?X"
    33       by (metis infinite_arbitrarily_large)
    34     from this(3) have *: "\<And>x. x \<in> X \<Longrightarrow> ?M / Suc n \<le> ?m x" 
    35       by auto
    36     { fix x assume "x \<in> X"
    37       from `?M \<noteq> 0` *[OF this] have "?m x \<noteq> 0" by (auto simp: field_simps measure_le_0_iff)
    38       then have "{x} \<in> sets M" by (auto dest: measure_notin_sets) }
    39     note singleton_sets = this
    40     have "?M < (\<Sum>x\<in>X. ?M / Suc n)"
    41       using `?M \<noteq> 0` 
    42       by (simp add: `card X = Suc (Suc n)` real_eq_of_nat[symmetric] real_of_nat_Suc field_simps less_le measure_nonneg)
    43     also have "\<dots> \<le> (\<Sum>x\<in>X. ?m x)"
    44       by (rule setsum_mono) fact
    45     also have "\<dots> = measure M (\<Union>x\<in>X. {x})"
    46       using singleton_sets `finite X`
    47       by (intro finite_measure_finite_Union[symmetric]) (auto simp: disjoint_family_on_def)
    48     finally have "?M < measure M (\<Union>x\<in>X. {x})" .
    49     moreover have "measure M (\<Union>x\<in>X. {x}) \<le> ?M"
    50       using singleton_sets[THEN sets.sets_into_space] by (intro finite_measure_mono) auto
    51     ultimately show False by simp
    52   qed
    53   show ?thesis
    54     unfolding * by (intro countable_UN countableI_type countable_finite[OF **])
    55 qed
    56 
    57 lemma (in finite_measure) AE_support_countable:
    58   assumes [simp]: "sets M = UNIV"
    59   shows "(AE x in M. measure M {x} \<noteq> 0) \<longleftrightarrow> (\<exists>S. countable S \<and> (AE x in M. x \<in> S))"
    60 proof
    61   assume "\<exists>S. countable S \<and> (AE x in M. x \<in> S)"
    62   then obtain S where S[intro]: "countable S" and ae: "AE x in M. x \<in> S"
    63     by auto
    64   then have "emeasure M (\<Union>x\<in>{x\<in>S. emeasure M {x} \<noteq> 0}. {x}) = 
    65     (\<integral>\<^sup>+ x. emeasure M {x} * indicator {x\<in>S. emeasure M {x} \<noteq> 0} x \<partial>count_space UNIV)"
    66     by (subst emeasure_UN_countable)
    67        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    68   also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} * indicator S x \<partial>count_space UNIV)"
    69     by (auto intro!: nn_integral_cong split: split_indicator)
    70   also have "\<dots> = emeasure M (\<Union>x\<in>S. {x})"
    71     by (subst emeasure_UN_countable)
    72        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    73   also have "\<dots> = emeasure M (space M)"
    74     using ae by (intro emeasure_eq_AE) auto
    75   finally have "emeasure M {x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0} = emeasure M (space M)"
    76     by (simp add: emeasure_single_in_space cong: rev_conj_cong)
    77   with finite_measure_compl[of "{x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0}"]
    78   have "AE x in M. x \<in> S \<and> emeasure M {x} \<noteq> 0"
    79     by (intro AE_I[OF order_refl]) (auto simp: emeasure_eq_measure set_diff_eq cong: conj_cong)
    80   then show "AE x in M. measure M {x} \<noteq> 0"
    81     by (auto simp: emeasure_eq_measure)
    82 qed (auto intro!: exI[of _ "{x. measure M {x} \<noteq> 0}"] countable_support)
    83 
    84 subsection {* PMF as measure *}
    85 
    86 typedef 'a pmf = "{M :: 'a measure. prob_space M \<and> sets M = UNIV \<and> (AE x in M. measure M {x} \<noteq> 0)}"
    87   morphisms measure_pmf Abs_pmf
    88   by (intro exI[of _ "uniform_measure (count_space UNIV) {undefined}"])
    89      (auto intro!: prob_space_uniform_measure AE_uniform_measureI)
    90 
    91 declare [[coercion measure_pmf]]
    92 
    93 lemma prob_space_measure_pmf: "prob_space (measure_pmf p)"
    94   using pmf.measure_pmf[of p] by auto
    95 
    96 interpretation measure_pmf!: prob_space "measure_pmf M" for M
    97   by (rule prob_space_measure_pmf)
    98 
    99 interpretation measure_pmf!: subprob_space "measure_pmf M" for M
   100   by (rule prob_space_imp_subprob_space) unfold_locales
   101 
   102 lemma subprob_space_measure_pmf: "subprob_space (measure_pmf x)"
   103   by unfold_locales
   104 
   105 locale pmf_as_measure
   106 begin
   107 
   108 setup_lifting type_definition_pmf
   109 
   110 end
   111 
   112 context
   113 begin
   114 
   115 interpretation pmf_as_measure .
   116 
   117 lift_definition pmf :: "'a pmf \<Rightarrow> 'a \<Rightarrow> real" is "\<lambda>M x. measure M {x}" .
   118 
   119 lift_definition set_pmf :: "'a pmf \<Rightarrow> 'a set" is "\<lambda>M. {x. measure M {x} \<noteq> 0}" .
   120 
   121 lift_definition map_pmf :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a pmf \<Rightarrow> 'b pmf" is
   122   "\<lambda>f M. distr M (count_space UNIV) f"
   123 proof safe
   124   fix M and f :: "'a \<Rightarrow> 'b"
   125   let ?D = "distr M (count_space UNIV) f"
   126   assume "prob_space M" and [simp]: "sets M = UNIV" and ae: "AE x in M. measure M {x} \<noteq> 0"
   127   interpret prob_space M by fact
   128   from ae have "AE x in M. measure M (f -` {f x}) \<noteq> 0"
   129   proof eventually_elim
   130     fix x
   131     have "measure M {x} \<le> measure M (f -` {f x})"
   132       by (intro finite_measure_mono) auto
   133     then show "measure M {x} \<noteq> 0 \<Longrightarrow> measure M (f -` {f x}) \<noteq> 0"
   134       using measure_nonneg[of M "{x}"] by auto
   135   qed
   136   then show "AE x in ?D. measure ?D {x} \<noteq> 0"
   137     by (simp add: AE_distr_iff measure_distr measurable_def)
   138 qed (auto simp: measurable_def prob_space.prob_space_distr)
   139 
   140 declare [[coercion set_pmf]]
   141 
   142 lemma countable_set_pmf [simp]: "countable (set_pmf p)"
   143   by transfer (metis prob_space.finite_measure finite_measure.countable_support)
   144 
   145 lemma sets_measure_pmf[simp]: "sets (measure_pmf p) = UNIV"
   146   by transfer metis
   147 
   148 lemma sets_measure_pmf_count_space[measurable_cong]:
   149   "sets (measure_pmf M) = sets (count_space UNIV)"
   150   by simp
   151 
   152 lemma space_measure_pmf[simp]: "space (measure_pmf p) = UNIV"
   153   using sets_eq_imp_space_eq[of "measure_pmf p" "count_space UNIV"] by simp
   154 
   155 lemma measure_pmf_in_subprob_algebra[measurable (raw)]: "measure_pmf x \<in> space (subprob_algebra (count_space UNIV))"
   156   by (simp add: space_subprob_algebra subprob_space_measure_pmf)
   157 
   158 lemma measurable_pmf_measure1[simp]: "measurable (M :: 'a pmf) N = UNIV \<rightarrow> space N"
   159   by (auto simp: measurable_def)
   160 
   161 lemma measurable_pmf_measure2[simp]: "measurable N (M :: 'a pmf) = measurable N (count_space UNIV)"
   162   by (intro measurable_cong_sets) simp_all
   163 
   164 lemma pmf_positive: "x \<in> set_pmf p \<Longrightarrow> 0 < pmf p x"
   165   by transfer (simp add: less_le measure_nonneg)
   166 
   167 lemma pmf_nonneg: "0 \<le> pmf p x"
   168   by transfer (simp add: measure_nonneg)
   169 
   170 lemma pmf_le_1: "pmf p x \<le> 1"
   171   by (simp add: pmf.rep_eq)
   172 
   173 lemma emeasure_pmf_single:
   174   fixes M :: "'a pmf"
   175   shows "emeasure M {x} = pmf M x"
   176   by transfer (simp add: finite_measure.emeasure_eq_measure[OF prob_space.finite_measure])
   177 
   178 lemma AE_measure_pmf: "AE x in (M::'a pmf). x \<in> M"
   179   by transfer simp
   180 
   181 lemma emeasure_pmf_single_eq_zero_iff:
   182   fixes M :: "'a pmf"
   183   shows "emeasure M {y} = 0 \<longleftrightarrow> y \<notin> M"
   184   by transfer (simp add: finite_measure.emeasure_eq_measure[OF prob_space.finite_measure])
   185 
   186 lemma AE_measure_pmf_iff: "(AE x in measure_pmf M. P x) \<longleftrightarrow> (\<forall>y\<in>M. P y)"
   187 proof -
   188   { fix y assume y: "y \<in> M" and P: "AE x in M. P x" "\<not> P y"
   189     with P have "AE x in M. x \<noteq> y"
   190       by auto
   191     with y have False
   192       by (simp add: emeasure_pmf_single_eq_zero_iff AE_iff_measurable[OF _ refl]) }
   193   then show ?thesis
   194     using AE_measure_pmf[of M] by auto
   195 qed
   196 
   197 lemma set_pmf_not_empty: "set_pmf M \<noteq> {}"
   198   using AE_measure_pmf[of M] by (intro notI) simp
   199 
   200 lemma set_pmf_iff: "x \<in> set_pmf M \<longleftrightarrow> pmf M x \<noteq> 0"
   201   by transfer simp
   202 
   203 lemma emeasure_measure_pmf_finite: "finite S \<Longrightarrow> emeasure (measure_pmf M) S = (\<Sum>s\<in>S. pmf M s)"
   204   by (subst emeasure_eq_setsum_singleton) (auto simp: emeasure_pmf_single)
   205 
   206 lemma measure_measure_pmf_finite: "finite S \<Longrightarrow> measure (measure_pmf M) S = setsum (pmf M) S"
   207   using emeasure_measure_pmf_finite[of S M] by(simp add: measure_pmf.emeasure_eq_measure)
   208 
   209 lemma nn_integral_measure_pmf_support:
   210   fixes f :: "'a \<Rightarrow> ereal"
   211   assumes f: "finite A" and nn: "\<And>x. x \<in> A \<Longrightarrow> 0 \<le> f x" "\<And>x. x \<in> set_pmf M \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = 0"
   212   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>A. f x * pmf M x)"
   213 proof -
   214   have "(\<integral>\<^sup>+x. f x \<partial>M) = (\<integral>\<^sup>+x. f x * indicator A x \<partial>M)"
   215     using nn by (intro nn_integral_cong_AE) (auto simp: AE_measure_pmf_iff split: split_indicator)
   216   also have "\<dots> = (\<Sum>x\<in>A. f x * emeasure M {x})"
   217     using assms by (intro nn_integral_indicator_finite) auto
   218   finally show ?thesis
   219     by (simp add: emeasure_measure_pmf_finite)
   220 qed
   221 
   222 lemma nn_integral_measure_pmf_finite:
   223   fixes f :: "'a \<Rightarrow> ereal"
   224   assumes f: "finite (set_pmf M)" and nn: "\<And>x. x \<in> set_pmf M \<Longrightarrow> 0 \<le> f x"
   225   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>set_pmf M. f x * pmf M x)"
   226   using assms by (intro nn_integral_measure_pmf_support) auto
   227 lemma integrable_measure_pmf_finite:
   228   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
   229   shows "finite (set_pmf M) \<Longrightarrow> integrable M f"
   230   by (auto intro!: integrableI_bounded simp: nn_integral_measure_pmf_finite)
   231 
   232 lemma integral_measure_pmf:
   233   assumes [simp]: "finite A" and "\<And>a. a \<in> set_pmf M \<Longrightarrow> f a \<noteq> 0 \<Longrightarrow> a \<in> A"
   234   shows "(\<integral>x. f x \<partial>measure_pmf M) = (\<Sum>a\<in>A. f a * pmf M a)"
   235 proof -
   236   have "(\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x * indicator A x \<partial>measure_pmf M)"
   237     using assms(2) by (intro integral_cong_AE) (auto split: split_indicator simp: AE_measure_pmf_iff)
   238   also have "\<dots> = (\<Sum>a\<in>A. f a * pmf M a)"
   239     by (subst integral_indicator_finite_real) (auto simp: measure_def emeasure_measure_pmf_finite)
   240   finally show ?thesis .
   241 qed
   242 
   243 lemma integrable_pmf: "integrable (count_space X) (pmf M)"
   244 proof -
   245   have " (\<integral>\<^sup>+ x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+ x. pmf M x \<partial>count_space (M \<inter> X))"
   246     by (auto simp add: nn_integral_count_space_indicator set_pmf_iff intro!: nn_integral_cong split: split_indicator)
   247   then have "integrable (count_space X) (pmf M) = integrable (count_space (M \<inter> X)) (pmf M)"
   248     by (simp add: integrable_iff_bounded pmf_nonneg)
   249   then show ?thesis
   250     by (simp add: pmf.rep_eq measure_pmf.integrable_measure disjoint_family_on_def)
   251 qed
   252 
   253 lemma integral_pmf: "(\<integral>x. pmf M x \<partial>count_space X) = measure M X"
   254 proof -
   255   have "(\<integral>x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+x. pmf M x \<partial>count_space X)"
   256     by (simp add: pmf_nonneg integrable_pmf nn_integral_eq_integral)
   257   also have "\<dots> = (\<integral>\<^sup>+x. emeasure M {x} \<partial>count_space (X \<inter> M))"
   258     by (auto intro!: nn_integral_cong_AE split: split_indicator
   259              simp: pmf.rep_eq measure_pmf.emeasure_eq_measure nn_integral_count_space_indicator
   260                    AE_count_space set_pmf_iff)
   261   also have "\<dots> = emeasure M (X \<inter> M)"
   262     by (rule emeasure_countable_singleton[symmetric]) (auto intro: countable_set_pmf)
   263   also have "\<dots> = emeasure M X"
   264     by (auto intro!: emeasure_eq_AE simp: AE_measure_pmf_iff)
   265   finally show ?thesis
   266     by (simp add: measure_pmf.emeasure_eq_measure)
   267 qed
   268 
   269 lemma integral_pmf_restrict:
   270   "(f::'a \<Rightarrow> 'b::{banach, second_countable_topology}) \<in> borel_measurable (count_space UNIV) \<Longrightarrow>
   271     (\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x \<partial>restrict_space M M)"
   272   by (auto intro!: integral_cong_AE simp add: integral_restrict_space AE_measure_pmf_iff)
   273 
   274 lemma emeasure_pmf: "emeasure (M::'a pmf) M = 1"
   275 proof -
   276   have "emeasure (M::'a pmf) M = emeasure (M::'a pmf) (space M)"
   277     by (intro emeasure_eq_AE) (simp_all add: AE_measure_pmf)
   278   then show ?thesis
   279     using measure_pmf.emeasure_space_1 by simp
   280 qed
   281 
   282 lemma emeasure_pmf_UNIV [simp]: "emeasure (measure_pmf M) UNIV = 1"
   283 using measure_pmf.emeasure_space_1[of M] by simp
   284 
   285 lemma in_null_sets_measure_pmfI:
   286   "A \<inter> set_pmf p = {} \<Longrightarrow> A \<in> null_sets (measure_pmf p)"
   287 using emeasure_eq_0_AE[where ?P="\<lambda>x. x \<in> A" and M="measure_pmf p"]
   288 by(auto simp add: null_sets_def AE_measure_pmf_iff)
   289 
   290 lemma map_pmf_id[simp]: "map_pmf id = id"
   291   by (rule, transfer) (auto simp: emeasure_distr measurable_def intro!: measure_eqI)
   292 
   293 lemma map_pmf_ident[simp]: "map_pmf (\<lambda>x. x) = (\<lambda>x. x)"
   294   using map_pmf_id unfolding id_def .
   295 
   296 lemma map_pmf_compose: "map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g"
   297   by (rule, transfer) (simp add: distr_distr[symmetric, where N="count_space UNIV"] measurable_def) 
   298 
   299 lemma map_pmf_comp: "map_pmf f (map_pmf g M) = map_pmf (\<lambda>x. f (g x)) M"
   300   using map_pmf_compose[of f g] by (simp add: comp_def)
   301 
   302 lemma map_pmf_cong:
   303   assumes "p = q"
   304   shows "(\<And>x. x \<in> set_pmf q \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g q"
   305   unfolding `p = q`[symmetric] measure_pmf_inject[symmetric] map_pmf.rep_eq
   306   by (auto simp add: emeasure_distr AE_measure_pmf_iff intro!: emeasure_eq_AE measure_eqI)
   307 
   308 lemma emeasure_map_pmf[simp]: "emeasure (map_pmf f M) X = emeasure M (f -` X)"
   309   unfolding map_pmf.rep_eq by (subst emeasure_distr) auto
   310 
   311 lemma nn_integral_map_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>map_pmf g M) = (\<integral>\<^sup>+x. f (g x) \<partial>M)"
   312   unfolding map_pmf.rep_eq by (intro nn_integral_distr) auto
   313 
   314 lemma ereal_pmf_map: "pmf (map_pmf f p) x = (\<integral>\<^sup>+ y. indicator (f -` {x}) y \<partial>measure_pmf p)"
   315 proof(transfer fixing: f x)
   316   fix p :: "'b measure"
   317   presume "prob_space p"
   318   then interpret prob_space p .
   319   presume "sets p = UNIV"
   320   then show "ereal (measure (distr p (count_space UNIV) f) {x}) = integral\<^sup>N p (indicator (f -` {x}))"
   321     by(simp add: measure_distr measurable_def emeasure_eq_measure)
   322 qed simp_all
   323 
   324 lemma pmf_set_map: 
   325   fixes f :: "'a \<Rightarrow> 'b"
   326   shows "set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
   327 proof (rule, transfer, clarsimp simp add: measure_distr measurable_def)
   328   fix f :: "'a \<Rightarrow> 'b" and M :: "'a measure"
   329   assume "prob_space M" and ae: "AE x in M. measure M {x} \<noteq> 0" and [simp]: "sets M = UNIV"
   330   interpret prob_space M by fact
   331   show "{x. measure M (f -` {x}) \<noteq> 0} = f ` {x. measure M {x} \<noteq> 0}"
   332   proof safe
   333     fix x assume "measure M (f -` {x}) \<noteq> 0"
   334     moreover have "measure M (f -` {x}) = measure M {y. f y = x \<and> measure M {y} \<noteq> 0}"
   335       using ae by (intro finite_measure_eq_AE) auto
   336     ultimately have "{y. f y = x \<and> measure M {y} \<noteq> 0} \<noteq> {}"
   337       by (metis measure_empty)
   338     then show "x \<in> f ` {x. measure M {x} \<noteq> 0}"
   339       by auto
   340   next
   341     fix x assume "measure M {x} \<noteq> 0"
   342     then have "0 < measure M {x}"
   343       using measure_nonneg[of M "{x}"] by auto
   344     also have "measure M {x} \<le> measure M (f -` {f x})"
   345       by (intro finite_measure_mono) auto
   346     finally show "measure M (f -` {f x}) = 0 \<Longrightarrow> False"
   347       by simp
   348   qed
   349 qed
   350 
   351 lemma set_map_pmf: "set_pmf (map_pmf f M) = f`set_pmf M"
   352   using pmf_set_map[of f] by (auto simp: comp_def fun_eq_iff)
   353 
   354 lemma nn_integral_pmf: "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = emeasure (measure_pmf p) A"
   355 proof -
   356   have "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = (\<integral>\<^sup>+ x. pmf p x \<partial>count_space (A \<inter> set_pmf p))"
   357     by(auto simp add: nn_integral_count_space_indicator indicator_def set_pmf_iff intro: nn_integral_cong)
   358   also have "\<dots> = emeasure (measure_pmf p) (\<Union>x\<in>A \<inter> set_pmf p. {x})"
   359     by(subst emeasure_UN_countable)(auto simp add: emeasure_pmf_single disjoint_family_on_def)
   360   also have "\<dots> = emeasure (measure_pmf p) ((\<Union>x\<in>A \<inter> set_pmf p. {x}) \<union> {x. x \<in> A \<and> x \<notin> set_pmf p})"
   361     by(rule emeasure_Un_null_set[symmetric])(auto intro: in_null_sets_measure_pmfI)
   362   also have "\<dots> = emeasure (measure_pmf p) A"
   363     by(auto intro: arg_cong2[where f=emeasure])
   364   finally show ?thesis .
   365 qed
   366 
   367 subsection {* PMFs as function *}
   368 
   369 context
   370   fixes f :: "'a \<Rightarrow> real"
   371   assumes nonneg: "\<And>x. 0 \<le> f x"
   372   assumes prob: "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   373 begin
   374 
   375 lift_definition embed_pmf :: "'a pmf" is "density (count_space UNIV) (ereal \<circ> f)"
   376 proof (intro conjI)
   377   have *[simp]: "\<And>x y. ereal (f y) * indicator {x} y = ereal (f x) * indicator {x} y"
   378     by (simp split: split_indicator)
   379   show "AE x in density (count_space UNIV) (ereal \<circ> f).
   380     measure (density (count_space UNIV) (ereal \<circ> f)) {x} \<noteq> 0"
   381     by (simp add: AE_density nonneg measure_def emeasure_density max_def)
   382   show "prob_space (density (count_space UNIV) (ereal \<circ> f))"
   383     by default (simp add: emeasure_density prob)
   384 qed simp
   385 
   386 lemma pmf_embed_pmf: "pmf embed_pmf x = f x"
   387 proof transfer
   388   have *[simp]: "\<And>x y. ereal (f y) * indicator {x} y = ereal (f x) * indicator {x} y"
   389     by (simp split: split_indicator)
   390   fix x show "measure (density (count_space UNIV) (ereal \<circ> f)) {x} = f x"
   391     by transfer (simp add: measure_def emeasure_density nonneg max_def)
   392 qed
   393 
   394 end
   395 
   396 lemma embed_pmf_transfer:
   397   "rel_fun (eq_onp (\<lambda>f. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ereal (f x) \<partial>count_space UNIV) = 1)) pmf_as_measure.cr_pmf (\<lambda>f. density (count_space UNIV) (ereal \<circ> f)) embed_pmf"
   398   by (auto simp: rel_fun_def eq_onp_def embed_pmf.transfer)
   399 
   400 lemma measure_pmf_eq_density: "measure_pmf p = density (count_space UNIV) (pmf p)"
   401 proof (transfer, elim conjE)
   402   fix M :: "'a measure" assume [simp]: "sets M = UNIV" and ae: "AE x in M. measure M {x} \<noteq> 0"
   403   assume "prob_space M" then interpret prob_space M .
   404   show "M = density (count_space UNIV) (\<lambda>x. ereal (measure M {x}))"
   405   proof (rule measure_eqI)
   406     fix A :: "'a set"
   407     have "(\<integral>\<^sup>+ x. ereal (measure M {x}) * indicator A x \<partial>count_space UNIV) = 
   408       (\<integral>\<^sup>+ x. emeasure M {x} * indicator (A \<inter> {x. measure M {x} \<noteq> 0}) x \<partial>count_space UNIV)"
   409       by (auto intro!: nn_integral_cong simp: emeasure_eq_measure split: split_indicator)
   410     also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} \<partial>count_space (A \<inter> {x. measure M {x} \<noteq> 0}))"
   411       by (subst nn_integral_restrict_space[symmetric]) (auto simp: restrict_count_space)
   412     also have "\<dots> = emeasure M (\<Union>x\<in>(A \<inter> {x. measure M {x} \<noteq> 0}). {x})"
   413       by (intro emeasure_UN_countable[symmetric] countable_Int2 countable_support)
   414          (auto simp: disjoint_family_on_def)
   415     also have "\<dots> = emeasure M A"
   416       using ae by (intro emeasure_eq_AE) auto
   417     finally show " emeasure M A = emeasure (density (count_space UNIV) (\<lambda>x. ereal (measure M {x}))) A"
   418       using emeasure_space_1 by (simp add: emeasure_density)
   419   qed simp
   420 qed
   421 
   422 lemma td_pmf_embed_pmf:
   423   "type_definition pmf embed_pmf {f::'a \<Rightarrow> real. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ereal (f x) \<partial>count_space UNIV) = 1}"
   424   unfolding type_definition_def
   425 proof safe
   426   fix p :: "'a pmf"
   427   have "(\<integral>\<^sup>+ x. 1 \<partial>measure_pmf p) = 1"
   428     using measure_pmf.emeasure_space_1[of p] by simp
   429   then show *: "(\<integral>\<^sup>+ x. ereal (pmf p x) \<partial>count_space UNIV) = 1"
   430     by (simp add: measure_pmf_eq_density nn_integral_density pmf_nonneg del: nn_integral_const)
   431 
   432   show "embed_pmf (pmf p) = p"
   433     by (intro measure_pmf_inject[THEN iffD1])
   434        (simp add: * embed_pmf.rep_eq pmf_nonneg measure_pmf_eq_density[of p] comp_def)
   435 next
   436   fix f :: "'a \<Rightarrow> real" assume "\<forall>x. 0 \<le> f x" "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   437   then show "pmf (embed_pmf f) = f"
   438     by (auto intro!: pmf_embed_pmf)
   439 qed (rule pmf_nonneg)
   440 
   441 end
   442 
   443 locale pmf_as_function
   444 begin
   445 
   446 setup_lifting td_pmf_embed_pmf
   447 
   448 lemma set_pmf_transfer[transfer_rule]: 
   449   assumes "bi_total A"
   450   shows "rel_fun (pcr_pmf A) (rel_set A) (\<lambda>f. {x. f x \<noteq> 0}) set_pmf"  
   451   using `bi_total A`
   452   by (auto simp: pcr_pmf_def cr_pmf_def rel_fun_def rel_set_def bi_total_def Bex_def set_pmf_iff)
   453      metis+
   454 
   455 end
   456 
   457 context
   458 begin
   459 
   460 interpretation pmf_as_function .
   461 
   462 lemma pmf_eqI: "(\<And>i. pmf M i = pmf N i) \<Longrightarrow> M = N"
   463   by transfer auto
   464 
   465 lemma pmf_eq_iff: "M = N \<longleftrightarrow> (\<forall>i. pmf M i = pmf N i)"
   466   by (auto intro: pmf_eqI)
   467 
   468 end
   469 
   470 context
   471 begin
   472 
   473 interpretation pmf_as_function .
   474 
   475 subsubsection \<open> Bernoulli Distribution \<close>
   476 
   477 lift_definition bernoulli_pmf :: "real \<Rightarrow> bool pmf" is
   478   "\<lambda>p b. ((\<lambda>p. if b then p else 1 - p) \<circ> min 1 \<circ> max 0) p"
   479   by (auto simp: nn_integral_count_space_finite[where A="{False, True}"] UNIV_bool
   480            split: split_max split_min)
   481 
   482 lemma pmf_bernoulli_True[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) True = p"
   483   by transfer simp
   484 
   485 lemma pmf_bernoulli_False[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) False = 1 - p"
   486   by transfer simp
   487 
   488 lemma set_pmf_bernoulli: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (bernoulli_pmf p) = UNIV"
   489   by (auto simp add: set_pmf_iff UNIV_bool)
   490 
   491 lemma nn_integral_bernoulli_pmf[simp]: 
   492   assumes [simp]: "0 \<le> p" "p \<le> 1" "\<And>x. 0 \<le> f x"
   493   shows "(\<integral>\<^sup>+x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
   494   by (subst nn_integral_measure_pmf_support[of UNIV])
   495      (auto simp: UNIV_bool field_simps)
   496 
   497 lemma integral_bernoulli_pmf[simp]: 
   498   assumes [simp]: "0 \<le> p" "p \<le> 1"
   499   shows "(\<integral>x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
   500   by (subst integral_measure_pmf[of UNIV]) (auto simp: UNIV_bool)
   501 
   502 subsubsection \<open> Geometric Distribution \<close>
   503 
   504 lift_definition geometric_pmf :: "nat pmf" is "\<lambda>n. 1 / 2^Suc n"
   505 proof
   506   note geometric_sums[of "1 / 2"]
   507   note sums_mult[OF this, of "1 / 2"]
   508   from sums_suminf_ereal[OF this]
   509   show "(\<integral>\<^sup>+ x. ereal (1 / 2 ^ Suc x) \<partial>count_space UNIV) = 1"
   510     by (simp add: nn_integral_count_space_nat field_simps)
   511 qed simp
   512 
   513 lemma pmf_geometric[simp]: "pmf geometric_pmf n = 1 / 2^Suc n"
   514   by transfer rule
   515 
   516 lemma set_pmf_geometric[simp]: "set_pmf geometric_pmf = UNIV"
   517   by (auto simp: set_pmf_iff)
   518 
   519 subsubsection \<open> Uniform Multiset Distribution \<close>
   520 
   521 context
   522   fixes M :: "'a multiset" assumes M_not_empty: "M \<noteq> {#}"
   523 begin
   524 
   525 lift_definition pmf_of_multiset :: "'a pmf" is "\<lambda>x. count M x / size M"
   526 proof
   527   show "(\<integral>\<^sup>+ x. ereal (real (count M x) / real (size M)) \<partial>count_space UNIV) = 1"  
   528     using M_not_empty
   529     by (simp add: zero_less_divide_iff nn_integral_count_space nonempty_has_size
   530                   setsum_divide_distrib[symmetric])
   531        (auto simp: size_multiset_overloaded_eq intro!: setsum.cong)
   532 qed simp
   533 
   534 lemma pmf_of_multiset[simp]: "pmf pmf_of_multiset x = count M x / size M"
   535   by transfer rule
   536 
   537 lemma set_pmf_of_multiset[simp]: "set_pmf pmf_of_multiset = set_of M"
   538   by (auto simp: set_pmf_iff)
   539 
   540 end
   541 
   542 subsubsection \<open> Uniform Distribution \<close>
   543 
   544 context
   545   fixes S :: "'a set" assumes S_not_empty: "S \<noteq> {}" and S_finite: "finite S"
   546 begin
   547 
   548 lift_definition pmf_of_set :: "'a pmf" is "\<lambda>x. indicator S x / card S"
   549 proof
   550   show "(\<integral>\<^sup>+ x. ereal (indicator S x / real (card S)) \<partial>count_space UNIV) = 1"  
   551     using S_not_empty S_finite by (subst nn_integral_count_space'[of S]) auto
   552 qed simp
   553 
   554 lemma pmf_of_set[simp]: "pmf pmf_of_set x = indicator S x / card S"
   555   by transfer rule
   556 
   557 lemma set_pmf_of_set[simp]: "set_pmf pmf_of_set = S"
   558   using S_finite S_not_empty by (auto simp: set_pmf_iff)
   559 
   560 lemma emeasure_pmf_of_set[simp]: "emeasure pmf_of_set S = 1"
   561   by (rule measure_pmf.emeasure_eq_1_AE) (auto simp: AE_measure_pmf_iff)
   562 
   563 end
   564 
   565 subsubsection \<open> Poisson Distribution \<close>
   566 
   567 context
   568   fixes rate :: real assumes rate_pos: "0 < rate"
   569 begin
   570 
   571 lift_definition poisson_pmf :: "nat pmf" is "\<lambda>k. rate ^ k / fact k * exp (-rate)"
   572 proof
   573   (* Proof by Manuel Eberl *)
   574 
   575   have summable: "summable (\<lambda>x::nat. rate ^ x / fact x)" using summable_exp
   576     by (simp add: field_simps field_divide_inverse[symmetric])
   577   have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x * exp (-rate) \<partial>count_space UNIV) =
   578           exp (-rate) * (\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV)"
   579     by (simp add: field_simps nn_integral_cmult[symmetric])
   580   also from rate_pos have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV) = (\<Sum>x. rate ^ x / fact x)"
   581     by (simp_all add: nn_integral_count_space_nat suminf_ereal summable suminf_ereal_finite)
   582   also have "... = exp rate" unfolding exp_def
   583     by (simp add: field_simps field_divide_inverse[symmetric] transfer_int_nat_factorial)
   584   also have "ereal (exp (-rate)) * ereal (exp rate) = 1"
   585     by (simp add: mult_exp_exp)
   586   finally show "(\<integral>\<^sup>+ x. ereal (rate ^ x / real (fact x) * exp (- rate)) \<partial>count_space UNIV) = 1" .
   587 qed (simp add: rate_pos[THEN less_imp_le])
   588 
   589 lemma pmf_poisson[simp]: "pmf poisson_pmf k = rate ^ k / fact k * exp (-rate)"
   590   by transfer rule
   591 
   592 lemma set_pmf_poisson[simp]: "set_pmf poisson_pmf = UNIV"
   593   using rate_pos by (auto simp: set_pmf_iff)
   594 
   595 end
   596 
   597 subsubsection \<open> Binomial Distribution \<close>
   598 
   599 context
   600   fixes n :: nat and p :: real assumes p_nonneg: "0 \<le> p" and p_le_1: "p \<le> 1"
   601 begin
   602 
   603 lift_definition binomial_pmf :: "nat pmf" is "\<lambda>k. (n choose k) * p^k * (1 - p)^(n - k)"
   604 proof
   605   have "(\<integral>\<^sup>+k. ereal (real (n choose k) * p ^ k * (1 - p) ^ (n - k)) \<partial>count_space UNIV) =
   606     ereal (\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k))"
   607     using p_le_1 p_nonneg by (subst nn_integral_count_space') auto
   608   also have "(\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k)) = (p + (1 - p)) ^ n"
   609     by (subst binomial_ring) (simp add: atLeast0AtMost real_of_nat_def)
   610   finally show "(\<integral>\<^sup>+ x. ereal (real (n choose x) * p ^ x * (1 - p) ^ (n - x)) \<partial>count_space UNIV) = 1"
   611     by simp
   612 qed (insert p_nonneg p_le_1, simp)
   613 
   614 lemma pmf_binomial[simp]: "pmf binomial_pmf k = (n choose k) * p^k * (1 - p)^(n - k)"
   615   by transfer rule
   616 
   617 lemma set_pmf_binomial_eq: "set_pmf binomial_pmf = (if p = 0 then {0} else if p = 1 then {n} else {.. n})"
   618   using p_nonneg p_le_1 unfolding set_eq_iff set_pmf_iff pmf_binomial by (auto simp: set_pmf_iff)
   619 
   620 end
   621 
   622 end
   623 
   624 lemma set_pmf_binomial_0[simp]: "set_pmf (binomial_pmf n 0) = {0}"
   625   by (simp add: set_pmf_binomial_eq)
   626 
   627 lemma set_pmf_binomial_1[simp]: "set_pmf (binomial_pmf n 1) = {n}"
   628   by (simp add: set_pmf_binomial_eq)
   629 
   630 lemma set_pmf_binomial[simp]: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (binomial_pmf n p) = {..n}"
   631   by (simp add: set_pmf_binomial_eq)
   632 
   633 subsection \<open> Monad Interpretation \<close>
   634 
   635 lemma measurable_measure_pmf[measurable]:
   636   "(\<lambda>x. measure_pmf (M x)) \<in> measurable (count_space UNIV) (subprob_algebra (count_space UNIV))"
   637   by (auto simp: space_subprob_algebra intro!: prob_space_imp_subprob_space) unfold_locales
   638 
   639 lemma bind_pmf_cong:
   640   assumes "\<And>x. A x \<in> space (subprob_algebra N)" "\<And>x. B x \<in> space (subprob_algebra N)"
   641   assumes "\<And>i. i \<in> set_pmf x \<Longrightarrow> A i = B i"
   642   shows "bind (measure_pmf x) A = bind (measure_pmf x) B"
   643 proof (rule measure_eqI)
   644   show "sets (measure_pmf x \<guillemotright>= A) = sets (measure_pmf x \<guillemotright>= B)"
   645     using assms by (subst (1 2) sets_bind) (auto simp: space_subprob_algebra)
   646 next
   647   fix X assume "X \<in> sets (measure_pmf x \<guillemotright>= A)"
   648   then have X: "X \<in> sets N"
   649     using assms by (subst (asm) sets_bind) (auto simp: space_subprob_algebra)
   650   show "emeasure (measure_pmf x \<guillemotright>= A) X = emeasure (measure_pmf x \<guillemotright>= B) X"
   651     using assms
   652     by (subst (1 2) emeasure_bind[where N=N, OF _ _ X])
   653        (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   654 qed
   655 
   656 context
   657 begin
   658 
   659 interpretation pmf_as_measure .
   660 
   661 lift_definition join_pmf :: "'a pmf pmf \<Rightarrow> 'a pmf" is "\<lambda>M. measure_pmf M \<guillemotright>= measure_pmf"
   662 proof (intro conjI)
   663   fix M :: "'a pmf pmf"
   664 
   665   interpret bind: prob_space "measure_pmf M \<guillemotright>= measure_pmf"
   666     apply (intro measure_pmf.prob_space_bind[where S="count_space UNIV"] AE_I2)
   667     apply (auto intro!: subprob_space_measure_pmf simp: space_subprob_algebra)
   668     apply unfold_locales
   669     done
   670   show "prob_space (measure_pmf M \<guillemotright>= measure_pmf)"
   671     by intro_locales
   672   show "sets (measure_pmf M \<guillemotright>= measure_pmf) = UNIV"
   673     by (subst sets_bind) auto
   674   have "AE x in measure_pmf M \<guillemotright>= measure_pmf. emeasure (measure_pmf M \<guillemotright>= measure_pmf) {x} \<noteq> 0"
   675     by (auto simp: AE_bind[where B="count_space UNIV"] measure_pmf_in_subprob_algebra
   676                    emeasure_bind[where N="count_space UNIV"] AE_measure_pmf_iff nn_integral_0_iff_AE
   677                    measure_pmf.emeasure_eq_measure measure_le_0_iff set_pmf_iff pmf.rep_eq)
   678   then show "AE x in measure_pmf M \<guillemotright>= measure_pmf. measure (measure_pmf M \<guillemotright>= measure_pmf) {x} \<noteq> 0"
   679     unfolding bind.emeasure_eq_measure by simp
   680 qed
   681 
   682 lemma pmf_join: "pmf (join_pmf N) i = (\<integral>M. pmf M i \<partial>measure_pmf N)"
   683 proof (transfer fixing: N i)
   684   have N: "subprob_space (measure_pmf N)"
   685     by (rule prob_space_imp_subprob_space) intro_locales
   686   show "measure (measure_pmf N \<guillemotright>= measure_pmf) {i} = integral\<^sup>L (measure_pmf N) (\<lambda>M. measure M {i})"
   687     using measurable_measure_pmf[of "\<lambda>x. x"]
   688     by (intro subprob_space.measure_bind[where N="count_space UNIV", OF N]) auto
   689 qed (auto simp: Transfer.Rel_def rel_fun_def cr_pmf_def)
   690 
   691 lemma set_pmf_join_pmf: "set_pmf (join_pmf f) = (\<Union>p\<in>set_pmf f. set_pmf p)"
   692 apply(simp add: set_eq_iff set_pmf_iff pmf_join)
   693 apply(subst integral_nonneg_eq_0_iff_AE)
   694 apply(auto simp add: pmf_le_1 pmf_nonneg AE_measure_pmf_iff intro!: measure_pmf.integrable_const_bound[where B=1])
   695 done
   696 
   697 lift_definition return_pmf :: "'a \<Rightarrow> 'a pmf" is "return (count_space UNIV)"
   698   by (auto intro!: prob_space_return simp: AE_return measure_return)
   699 
   700 lemma join_return_pmf: "join_pmf (return_pmf M) = M"
   701   by (simp add: integral_return pmf_eq_iff pmf_join return_pmf.rep_eq)
   702 
   703 lemma map_return_pmf: "map_pmf f (return_pmf x) = return_pmf (f x)"
   704   by transfer (simp add: distr_return)
   705 
   706 lemma map_pmf_const[simp]: "map_pmf (\<lambda>_. c) M = return_pmf c"
   707   by transfer (auto simp: prob_space.distr_const)
   708 
   709 lemma set_return_pmf: "set_pmf (return_pmf x) = {x}"
   710   by transfer (auto simp add: measure_return split: split_indicator)
   711 
   712 lemma pmf_return: "pmf (return_pmf x) y = indicator {y} x"
   713   by transfer (simp add: measure_return)
   714 
   715 lemma nn_integral_return_pmf[simp]: "0 \<le> f x \<Longrightarrow> (\<integral>\<^sup>+x. f x \<partial>return_pmf x) = f x"
   716   unfolding return_pmf.rep_eq by (intro nn_integral_return) auto
   717 
   718 lemma emeasure_return_pmf[simp]: "emeasure (return_pmf x) X = indicator X x"
   719   unfolding return_pmf.rep_eq by (intro emeasure_return) auto
   720 
   721 end
   722 
   723 lemma return_pmf_inj[simp]: "return_pmf x = return_pmf y \<longleftrightarrow> x = y"
   724   by (metis insertI1 set_return_pmf singletonD)
   725 
   726 definition "bind_pmf M f = join_pmf (map_pmf f M)"
   727 
   728 lemma (in pmf_as_measure) bind_transfer[transfer_rule]:
   729   "rel_fun pmf_as_measure.cr_pmf (rel_fun (rel_fun op = pmf_as_measure.cr_pmf) pmf_as_measure.cr_pmf) op \<guillemotright>= bind_pmf"
   730 proof (auto simp: pmf_as_measure.cr_pmf_def rel_fun_def bind_pmf_def join_pmf.rep_eq map_pmf.rep_eq)
   731   fix M f and g :: "'a \<Rightarrow> 'b pmf" assume "\<forall>x. f x = measure_pmf (g x)"
   732   then have f: "f = (\<lambda>x. measure_pmf (g x))"
   733     by auto
   734   show "measure_pmf M \<guillemotright>= f = distr (measure_pmf M) (count_space UNIV) g \<guillemotright>= measure_pmf"
   735     unfolding f by (subst bind_distr[OF _ measurable_measure_pmf]) auto
   736 qed
   737 
   738 lemma pmf_bind: "pmf (bind_pmf N f) i = (\<integral>x. pmf (f x) i \<partial>measure_pmf N)"
   739   by (auto intro!: integral_distr simp: bind_pmf_def pmf_join map_pmf.rep_eq)
   740 
   741 lemma bind_return_pmf: "bind_pmf (return_pmf x) f = f x"
   742   unfolding bind_pmf_def map_return_pmf join_return_pmf ..
   743 
   744 lemma join_eq_bind_pmf: "join_pmf M = bind_pmf M id"
   745   by (simp add: bind_pmf_def)
   746 
   747 lemma bind_pmf_const[simp]: "bind_pmf M (\<lambda>x. c) = c"
   748   unfolding bind_pmf_def map_pmf_const join_return_pmf ..
   749 
   750 lemma set_bind_pmf: "set_pmf (bind_pmf M N) = (\<Union>M\<in>set_pmf M. set_pmf (N M))"
   751   apply (simp add: set_eq_iff set_pmf_iff pmf_bind)
   752   apply (subst integral_nonneg_eq_0_iff_AE)
   753   apply (auto simp: pmf_nonneg pmf_le_1 AE_measure_pmf_iff
   754               intro!: measure_pmf.integrable_const_bound[where B=1])
   755   done
   756 
   757 
   758 lemma measurable_pair_restrict_pmf2:
   759   assumes "countable A"
   760   assumes [measurable]: "\<And>y. y \<in> A \<Longrightarrow> (\<lambda>x. f (x, y)) \<in> measurable M L"
   761   shows "f \<in> measurable (M \<Otimes>\<^sub>M restrict_space (measure_pmf N) A) L" (is "f \<in> measurable ?M _")
   762 proof -
   763   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   764     by (simp add: restrict_count_space)
   765 
   766   show ?thesis
   767     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (fst b, a)" and g=snd and I=A,
   768                                             unfolded pair_collapse] assms)
   769         measurable
   770 qed
   771 
   772 lemma measurable_pair_restrict_pmf1:
   773   assumes "countable A"
   774   assumes [measurable]: "\<And>x. x \<in> A \<Longrightarrow> (\<lambda>y. f (x, y)) \<in> measurable N L"
   775   shows "f \<in> measurable (restrict_space (measure_pmf M) A \<Otimes>\<^sub>M N) L"
   776 proof -
   777   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   778     by (simp add: restrict_count_space)
   779 
   780   show ?thesis
   781     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (a, snd b)" and g=fst and I=A,
   782                                             unfolded pair_collapse] assms)
   783         measurable
   784 qed
   785                                 
   786 lemma bind_commute_pmf: "bind_pmf A (\<lambda>x. bind_pmf B (C x)) = bind_pmf B (\<lambda>y. bind_pmf A (\<lambda>x. C x y))"
   787   unfolding pmf_eq_iff pmf_bind
   788 proof
   789   fix i
   790   interpret B: prob_space "restrict_space B B"
   791     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   792        (auto simp: AE_measure_pmf_iff)
   793   interpret A: prob_space "restrict_space A A"
   794     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   795        (auto simp: AE_measure_pmf_iff)
   796 
   797   interpret AB: pair_prob_space "restrict_space A A" "restrict_space B B"
   798     by unfold_locales
   799 
   800   have "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>A)"
   801     by (rule integral_cong) (auto intro!: integral_pmf_restrict)
   802   also have "\<dots> = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>restrict_space A A)"
   803     by (intro integral_pmf_restrict B.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   804               countable_set_pmf borel_measurable_count_space)
   805   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>restrict_space B B)"
   806     by (rule AB.Fubini_integral[symmetric])
   807        (auto intro!: AB.integrable_const_bound[where B=1] measurable_pair_restrict_pmf2
   808              simp: pmf_nonneg pmf_le_1 measurable_restrict_space1)
   809   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>B)"
   810     by (intro integral_pmf_restrict[symmetric] A.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   811               countable_set_pmf borel_measurable_count_space)
   812   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)"
   813     by (rule integral_cong) (auto intro!: integral_pmf_restrict[symmetric])
   814   finally show "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)" .
   815 qed
   816 
   817 
   818 context
   819 begin
   820 
   821 interpretation pmf_as_measure .
   822 
   823 lemma measure_pmf_bind: "measure_pmf (bind_pmf M f) = (measure_pmf M \<guillemotright>= (\<lambda>x. measure_pmf (f x)))"
   824   by transfer simp
   825 
   826 lemma nn_integral_bind_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>bind_pmf M N) = (\<integral>\<^sup>+x. \<integral>\<^sup>+y. f y \<partial>N x \<partial>M)"
   827   using measurable_measure_pmf[of N]
   828   unfolding measure_pmf_bind
   829   apply (subst (1 3) nn_integral_max_0[symmetric])
   830   apply (intro nn_integral_bind[where B="count_space UNIV"])
   831   apply auto
   832   done
   833 
   834 lemma emeasure_bind_pmf[simp]: "emeasure (bind_pmf M N) X = (\<integral>\<^sup>+x. emeasure (N x) X \<partial>M)"
   835   using measurable_measure_pmf[of N]
   836   unfolding measure_pmf_bind
   837   by (subst emeasure_bind[where N="count_space UNIV"]) auto
   838 
   839 lemma bind_return_pmf': "bind_pmf N return_pmf = N"
   840 proof (transfer, clarify)
   841   fix N :: "'a measure" assume "sets N = UNIV" then show "N \<guillemotright>= return (count_space UNIV) = N"
   842     by (subst return_sets_cong[where N=N]) (simp_all add: bind_return')
   843 qed
   844 
   845 lemma bind_return_pmf'': "bind_pmf N (\<lambda>x. return_pmf (f x)) = map_pmf f N"
   846 proof (transfer, clarify)
   847   fix N :: "'b measure" and f :: "'b \<Rightarrow> 'a" assume "prob_space N" "sets N = UNIV"
   848   then show "N \<guillemotright>= (\<lambda>x. return (count_space UNIV) (f x)) = distr N (count_space UNIV) f"
   849     by (subst bind_return_distr[symmetric])
   850        (auto simp: prob_space.not_empty measurable_def comp_def)
   851 qed
   852 
   853 lemma bind_assoc_pmf: "bind_pmf (bind_pmf A B) C = bind_pmf A (\<lambda>x. bind_pmf (B x) C)"
   854   by transfer
   855      (auto intro!: bind_assoc[where N="count_space UNIV" and R="count_space UNIV"]
   856            simp: measurable_def space_subprob_algebra prob_space_imp_subprob_space)
   857 
   858 end
   859 
   860 lemma map_join_pmf: "map_pmf f (join_pmf AA) = join_pmf (map_pmf (map_pmf f) AA)"
   861   unfolding bind_pmf_def[symmetric]
   862   unfolding bind_return_pmf''[symmetric] join_eq_bind_pmf bind_assoc_pmf
   863   by (simp add: bind_return_pmf'')
   864 
   865 definition "pair_pmf A B = bind_pmf A (\<lambda>x. bind_pmf B (\<lambda>y. return_pmf (x, y)))"
   866 
   867 lemma pmf_pair: "pmf (pair_pmf M N) (a, b) = pmf M a * pmf N b"
   868   unfolding pair_pmf_def pmf_bind pmf_return
   869   apply (subst integral_measure_pmf[where A="{b}"])
   870   apply (auto simp: indicator_eq_0_iff)
   871   apply (subst integral_measure_pmf[where A="{a}"])
   872   apply (auto simp: indicator_eq_0_iff setsum_nonneg_eq_0_iff pmf_nonneg)
   873   done
   874 
   875 lemma set_pair_pmf: "set_pmf (pair_pmf A B) = set_pmf A \<times> set_pmf B"
   876   unfolding pair_pmf_def set_bind_pmf set_return_pmf by auto
   877 
   878 lemma measure_pmf_in_subprob_space[measurable (raw)]:
   879   "measure_pmf M \<in> space (subprob_algebra (count_space UNIV))"
   880   by (simp add: space_subprob_algebra) intro_locales
   881 
   882 lemma nn_integral_pair_pmf': "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. f (a, b) \<partial>B \<partial>A)"
   883 proof -
   884   have "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+x. max 0 (f x) * indicator (A \<times> B) x \<partial>pair_pmf A B)"
   885     by (subst nn_integral_max_0[symmetric])
   886        (auto simp: AE_measure_pmf_iff set_pair_pmf intro!: nn_integral_cong_AE)
   887   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. max 0 (f (a, b)) * indicator (A \<times> B) (a, b) \<partial>B \<partial>A)"
   888     by (simp add: pair_pmf_def)
   889   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. max 0 (f (a, b)) \<partial>B \<partial>A)"
   890     by (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   891   finally show ?thesis
   892     unfolding nn_integral_max_0 .
   893 qed
   894 
   895 lemma pair_map_pmf1: "pair_pmf (map_pmf f A) B = map_pmf (apfst f) (pair_pmf A B)"
   896 proof (safe intro!: pmf_eqI)
   897   fix a :: "'a" and b :: "'b"
   898   have [simp]: "\<And>c d. indicator (apfst f -` {(a, b)}) (c, d) = indicator (f -` {a}) c * (indicator {b} d::ereal)"
   899     by (auto split: split_indicator)
   900 
   901   have "ereal (pmf (pair_pmf (map_pmf f A) B) (a, b)) =
   902          ereal (pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b))"
   903     unfolding pmf_pair ereal_pmf_map
   904     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_multc pmf_nonneg
   905                   emeasure_map_pmf[symmetric] del: emeasure_map_pmf)
   906   then show "pmf (pair_pmf (map_pmf f A) B) (a, b) = pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b)"
   907     by simp
   908 qed
   909 
   910 lemma pair_map_pmf2: "pair_pmf A (map_pmf f B) = map_pmf (apsnd f) (pair_pmf A B)"
   911 proof (safe intro!: pmf_eqI)
   912   fix a :: "'a" and b :: "'b"
   913   have [simp]: "\<And>c d. indicator (apsnd f -` {(a, b)}) (c, d) = indicator {a} c * (indicator (f -` {b}) d::ereal)"
   914     by (auto split: split_indicator)
   915 
   916   have "ereal (pmf (pair_pmf A (map_pmf f B)) (a, b)) =
   917          ereal (pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b))"
   918     unfolding pmf_pair ereal_pmf_map
   919     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_cmult nn_integral_multc pmf_nonneg
   920                   emeasure_map_pmf[symmetric] del: emeasure_map_pmf)
   921   then show "pmf (pair_pmf A (map_pmf f B)) (a, b) = pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b)"
   922     by simp
   923 qed
   924 
   925 lemma map_pair: "map_pmf (\<lambda>(a, b). (f a, g b)) (pair_pmf A B) = pair_pmf (map_pmf f A) (map_pmf g B)"
   926   by (simp add: pair_map_pmf2 pair_map_pmf1 map_pmf_comp split_beta')
   927 
   928 lemma bind_pair_pmf:
   929   assumes M[measurable]: "M \<in> measurable (count_space UNIV \<Otimes>\<^sub>M count_space UNIV) (subprob_algebra N)"
   930   shows "measure_pmf (pair_pmf A B) \<guillemotright>= M = (measure_pmf A \<guillemotright>= (\<lambda>x. measure_pmf B \<guillemotright>= (\<lambda>y. M (x, y))))"
   931     (is "?L = ?R")
   932 proof (rule measure_eqI)
   933   have M'[measurable]: "M \<in> measurable (pair_pmf A B) (subprob_algebra N)"
   934     using M[THEN measurable_space] by (simp_all add: space_pair_measure)
   935 
   936   note measurable_bind[where N="count_space UNIV", measurable]
   937   note measure_pmf_in_subprob_space[simp]
   938 
   939   have sets_eq_N: "sets ?L = N"
   940     by (subst sets_bind[OF sets_kernel[OF M']]) auto
   941   show "sets ?L = sets ?R"
   942     using measurable_space[OF M]
   943     by (simp add: sets_eq_N space_pair_measure space_subprob_algebra)
   944   fix X assume "X \<in> sets ?L"
   945   then have X[measurable]: "X \<in> sets N"
   946     unfolding sets_eq_N .
   947   then show "emeasure ?L X = emeasure ?R X"
   948     apply (simp add: emeasure_bind[OF _ M' X])
   949     apply (simp add: nn_integral_bind[where B="count_space UNIV"] pair_pmf_def measure_pmf_bind[of A]
   950       nn_integral_measure_pmf_finite set_return_pmf emeasure_nonneg pmf_return one_ereal_def[symmetric])
   951     apply (subst emeasure_bind[OF _ _ X])
   952     apply measurable
   953     apply (subst emeasure_bind[OF _ _ X])
   954     apply measurable
   955     done
   956 qed
   957 
   958 lemma join_map_return_pmf: "join_pmf (map_pmf return_pmf A) = A"
   959   unfolding bind_pmf_def[symmetric] bind_return_pmf' ..
   960 
   961 lemma map_fst_pair_pmf: "map_pmf fst (pair_pmf A B) = A"
   962   by (simp add: pair_pmf_def bind_return_pmf''[symmetric] bind_assoc_pmf bind_return_pmf bind_return_pmf')
   963 
   964 lemma map_snd_pair_pmf: "map_pmf snd (pair_pmf A B) = B"
   965   by (simp add: pair_pmf_def bind_return_pmf''[symmetric] bind_assoc_pmf bind_return_pmf bind_return_pmf')
   966 
   967 lemma nn_integral_pmf':
   968   "inj_on f A \<Longrightarrow> (\<integral>\<^sup>+x. pmf p (f x) \<partial>count_space A) = emeasure p (f ` A)"
   969   by (subst nn_integral_bij_count_space[where g=f and B="f`A"])
   970      (auto simp: bij_betw_def nn_integral_pmf)
   971 
   972 lemma pmf_le_0_iff[simp]: "pmf M p \<le> 0 \<longleftrightarrow> pmf M p = 0"
   973   using pmf_nonneg[of M p] by simp
   974 
   975 lemma min_pmf_0[simp]: "min (pmf M p) 0 = 0" "min 0 (pmf M p) = 0"
   976   using pmf_nonneg[of M p] by simp_all
   977 
   978 lemma pmf_eq_0_set_pmf: "pmf M p = 0 \<longleftrightarrow> p \<notin> set_pmf M"
   979   unfolding set_pmf_iff by simp
   980 
   981 lemma pmf_map_inj: "inj_on f (set_pmf M) \<Longrightarrow> x \<in> set_pmf M \<Longrightarrow> pmf (map_pmf f M) (f x) = pmf M x"
   982   by (auto simp: pmf.rep_eq map_pmf.rep_eq measure_distr AE_measure_pmf_iff inj_onD
   983            intro!: measure_pmf.finite_measure_eq_AE)
   984 
   985 inductive rel_pmf :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a pmf \<Rightarrow> 'b pmf \<Rightarrow> bool"
   986 for R p q
   987 where
   988   "\<lbrakk> \<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y; 
   989      map_pmf fst pq = p; map_pmf snd pq = q \<rbrakk>
   990   \<Longrightarrow> rel_pmf R p q"
   991 
   992 bnf pmf: "'a pmf" map: map_pmf sets: set_pmf bd : "natLeq" rel: rel_pmf
   993 proof -
   994   show "map_pmf id = id" by (rule map_pmf_id)
   995   show "\<And>f g. map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g" by (rule map_pmf_compose) 
   996   show "\<And>f g::'a \<Rightarrow> 'b. \<And>p. (\<And>x. x \<in> set_pmf p \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g p"
   997     by (intro map_pmf_cong refl)
   998 
   999   show "\<And>f::'a \<Rightarrow> 'b. set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
  1000     by (rule pmf_set_map)
  1001 
  1002   { fix p :: "'s pmf"
  1003     have "(card_of (set_pmf p), card_of (UNIV :: nat set)) \<in> ordLeq"
  1004       by (rule card_of_ordLeqI[where f="to_nat_on (set_pmf p)"])
  1005          (auto intro: countable_set_pmf)
  1006     also have "(card_of (UNIV :: nat set), natLeq) \<in> ordLeq"
  1007       by (metis Field_natLeq card_of_least natLeq_Well_order)
  1008     finally show "(card_of (set_pmf p), natLeq) \<in> ordLeq" . }
  1009 
  1010   show "\<And>R. rel_pmf R =
  1011          (BNF_Def.Grp {x. set_pmf x \<subseteq> {(x, y). R x y}} (map_pmf fst))\<inverse>\<inverse> OO
  1012          BNF_Def.Grp {x. set_pmf x \<subseteq> {(x, y). R x y}} (map_pmf snd)"
  1013      by (auto simp add: fun_eq_iff BNF_Def.Grp_def OO_def rel_pmf.simps)
  1014 
  1015   { fix p :: "'a pmf" and f :: "'a \<Rightarrow> 'b" and g x
  1016     assume p: "\<And>z. z \<in> set_pmf p \<Longrightarrow> f z = g z"
  1017       and x: "x \<in> set_pmf p"
  1018     thus "f x = g x" by simp }
  1019 
  1020   fix R :: "'a => 'b \<Rightarrow> bool" and S :: "'b \<Rightarrow> 'c \<Rightarrow> bool"
  1021   { fix p q r
  1022     assume pq: "rel_pmf R p q"
  1023       and qr:"rel_pmf S q r"
  1024     from pq obtain pq where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1025       and p: "p = map_pmf fst pq" and q: "q = map_pmf snd pq" by cases auto
  1026     from qr obtain qr where qr: "\<And>y z. (y, z) \<in> set_pmf qr \<Longrightarrow> S y z"
  1027       and q': "q = map_pmf fst qr" and r: "r = map_pmf snd qr" by cases auto
  1028 
  1029     note pmf_nonneg[intro, simp]
  1030     let ?pq = "\<lambda>y x. pmf pq (x, y)"
  1031     let ?qr = "\<lambda>y z. pmf qr (y, z)"
  1032 
  1033     have nn_integral_pp2: "\<And>y. (\<integral>\<^sup>+ x. ?pq y x \<partial>count_space UNIV) = pmf q y"
  1034       by (simp add: nn_integral_pmf' inj_on_def q)
  1035          (auto simp add: ereal_pmf_map intro!: arg_cong2[where f=emeasure])
  1036     have nn_integral_rr1: "\<And>y. (\<integral>\<^sup>+ x. ?qr y x \<partial>count_space UNIV) = pmf q y"
  1037       by (simp add: nn_integral_pmf' inj_on_def q')
  1038          (auto simp add: ereal_pmf_map intro!: arg_cong2[where f=emeasure])
  1039     have eq: "\<And>y. (\<integral>\<^sup>+ x. ?pq y x \<partial>count_space UNIV) = (\<integral>\<^sup>+ z. ?qr y z \<partial>count_space UNIV)"
  1040       by(simp add: nn_integral_pp2 nn_integral_rr1)
  1041 
  1042     def assign \<equiv> "\<lambda>(z, x, y). ?pq y x * ?qr y z / pmf q y"
  1043     have assign_nonneg [simp]: "\<And>z x y. 0 \<le> assign (z, x, y)" by(simp add: assign_def)
  1044     have assign_eq_0_outside: "\<And>z x y. \<lbrakk> ?pq y x = 0 \<or> ?qr y z = 0 \<rbrakk> \<Longrightarrow> assign (z, x, y) = 0"
  1045       by(auto simp add: assign_def)
  1046     have nn_integral_assign1: "\<And>z y. (\<integral>\<^sup>+ x. assign (z, x, y) \<partial>count_space UNIV) = ?qr y z"
  1047     proof -
  1048       fix y z
  1049       have "(\<integral>\<^sup>+ x. assign (z, x, y) \<partial>count_space UNIV) = 
  1050             (\<integral>\<^sup>+ x. ?pq y x \<partial>count_space UNIV) * (?qr y z / pmf q y)"
  1051         by(simp add: assign_def nn_integral_multc times_ereal.simps(1)[symmetric] divide_real_def mult.assoc del: times_ereal.simps(1))
  1052       also have "\<dots> = ?qr y z" by(auto simp add: image_iff q' pmf_eq_0_set_pmf set_map_pmf nn_integral_pp2)
  1053       finally show "?thesis z y" .
  1054     qed
  1055     have nn_integral_assign2: "\<And>x y. (\<integral>\<^sup>+ z. assign (z, x, y) \<partial>count_space UNIV) = ?pq y x"
  1056     proof -
  1057       fix x y
  1058       have "(\<integral>\<^sup>+ z. assign (z, x, y) \<partial>count_space UNIV) = (\<integral>\<^sup>+ z. ?qr y z \<partial>count_space UNIV) * (?pq y x / pmf q y)"
  1059         by(simp add: assign_def divide_real_def mult.commute[where a="?pq y x"] mult.assoc nn_integral_multc times_ereal.simps(1)[symmetric] del: times_ereal.simps(1))
  1060       also have "\<dots> = ?pq y x" by(auto simp add: image_iff pmf_eq_0_set_pmf set_map_pmf q nn_integral_rr1)
  1061       finally show "?thesis x y" .
  1062     qed
  1063 
  1064     def pqr \<equiv> "embed_pmf assign"
  1065     { fix z x y
  1066       have "assign (z, x, y) = pmf pqr (z, x, y)"
  1067         unfolding pqr_def
  1068       proof (subst pmf_embed_pmf)
  1069         have "(\<integral>\<^sup>+ zxy. ereal (assign zxy) \<partial>count_space UNIV) = 
  1070               (\<integral>\<^sup>+ xy. \<integral>\<^sup>+ z. ereal (assign (z, xy)) \<partial>count_space UNIV \<partial>count_space UNIV)"
  1071           by(subst nn_integral_snd_count_space) simp
  1072         also have "\<dots> = (\<integral>\<^sup>+ z. ?pq (snd z) (fst z) \<partial>count_space UNIV)"
  1073           by (subst nn_integral_assign2[symmetric]) (auto intro!: nn_integral_cong)
  1074         finally show "(\<integral>\<^sup>+ zxy. ereal (assign zxy) \<partial>count_space UNIV) = 1"
  1075           by (simp add: nn_integral_pmf emeasure_pmf)
  1076       qed auto }
  1077     note a = this
  1078 
  1079     def pr \<equiv> "map_pmf (\<lambda>(z, x, y). (x, z)) pqr"
  1080 
  1081     have "rel_pmf (R OO S) p r"
  1082     proof
  1083       have pq_eq: "pq = map_pmf (\<lambda>(z, x, y). (x, y)) pqr"
  1084       proof (rule pmf_eqI)
  1085         fix i
  1086         show "pmf pq i = pmf (map_pmf (\<lambda>(z, x, y). (x, y)) pqr) i"
  1087           using nn_integral_assign2[of "fst i" "snd i", symmetric]
  1088           by(cases i)
  1089             (auto simp add: a nn_integral_pmf' inj_on_def ereal.inject[symmetric] ereal_pmf_map 
  1090                   simp del: ereal.inject intro!: arg_cong2[where f=emeasure])
  1091       qed
  1092       then show "map_pmf fst pr = p"
  1093         unfolding p pr_def by (simp add: map_pmf_comp split_beta)
  1094 
  1095       have qr_eq: "qr = map_pmf (\<lambda>(z, x, y). (y, z)) pqr"
  1096       proof (rule pmf_eqI)
  1097         fix i show "pmf qr i = pmf (map_pmf (\<lambda>(z, x, y). (y, z)) pqr) i"
  1098           using nn_integral_assign1[of "snd i" "fst i", symmetric]
  1099           by(cases i)
  1100             (auto simp add: a nn_integral_pmf' inj_on_def ereal.inject[symmetric] ereal_pmf_map 
  1101                   simp del: ereal.inject intro!: arg_cong2[where f=emeasure])
  1102       qed
  1103       then show "map_pmf snd pr = r"
  1104         unfolding r pr_def by (simp add: map_pmf_comp split_beta)
  1105 
  1106       fix x z assume "(x, z) \<in> set_pmf pr"
  1107       then have "\<exists>y. (x, y) \<in> set_pmf pq \<and> (y, z) \<in> set_pmf qr"
  1108         unfolding pr_def pq_eq qr_eq by (force simp: set_map_pmf)
  1109       with pq qr show "(R OO S) x z"
  1110         by blast
  1111     qed }
  1112   then show "rel_pmf R OO rel_pmf S \<le> rel_pmf (R OO S)"
  1113     by(auto simp add: le_fun_def)
  1114 qed (fact natLeq_card_order natLeq_cinfinite)+
  1115 
  1116 lemma rel_pmf_return_pmf1: "rel_pmf R (return_pmf x) M \<longleftrightarrow> (\<forall>a\<in>M. R x a)"
  1117 proof safe
  1118   fix a assume "a \<in> M" "rel_pmf R (return_pmf x) M"
  1119   then obtain pq where *: "\<And>a b. (a, b) \<in> set_pmf pq \<Longrightarrow> R a b"
  1120     and eq: "return_pmf x = map_pmf fst pq" "M = map_pmf snd pq"
  1121     by (force elim: rel_pmf.cases)
  1122   moreover have "set_pmf (return_pmf x) = {x}"
  1123     by (simp add: set_return_pmf)
  1124   with `a \<in> M` have "(x, a) \<in> pq"
  1125     by (force simp: eq set_map_pmf)
  1126   with * show "R x a"
  1127     by auto
  1128 qed (auto intro!: rel_pmf.intros[where pq="pair_pmf (return_pmf x) M"]
  1129           simp: map_fst_pair_pmf map_snd_pair_pmf set_pair_pmf set_return_pmf)
  1130 
  1131 lemma rel_pmf_return_pmf2: "rel_pmf R M (return_pmf x) \<longleftrightarrow> (\<forall>a\<in>M. R a x)"
  1132   by (subst pmf.rel_flip[symmetric]) (simp add: rel_pmf_return_pmf1)
  1133 
  1134 lemma rel_return_pmf[simp]: "rel_pmf R (return_pmf x1) (return_pmf x2) = R x1 x2"
  1135   unfolding rel_pmf_return_pmf2 set_return_pmf by simp
  1136 
  1137 lemma rel_pmf_False[simp]: "rel_pmf (\<lambda>x y. False) x y = False"
  1138   unfolding pmf.in_rel fun_eq_iff using set_pmf_not_empty by fastforce
  1139 
  1140 lemma rel_pmf_rel_prod:
  1141   "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B') \<longleftrightarrow> rel_pmf R A B \<and> rel_pmf S A' B'"
  1142 proof safe
  1143   assume "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1144   then obtain pq where pq: "\<And>a b c d. ((a, c), (b, d)) \<in> set_pmf pq \<Longrightarrow> R a b \<and> S c d"
  1145     and eq: "map_pmf fst pq = pair_pmf A A'" "map_pmf snd pq = pair_pmf B B'"
  1146     by (force elim: rel_pmf.cases)
  1147   show "rel_pmf R A B"
  1148   proof (rule rel_pmf.intros)
  1149     let ?f = "\<lambda>(a, b). (fst a, fst b)"
  1150     have [simp]: "(\<lambda>x. fst (?f x)) = fst o fst" "(\<lambda>x. snd (?f x)) = fst o snd"
  1151       by auto
  1152 
  1153     show "map_pmf fst (map_pmf ?f pq) = A"
  1154       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1155     show "map_pmf snd (map_pmf ?f pq) = B"
  1156       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1157 
  1158     fix a b assume "(a, b) \<in> set_pmf (map_pmf ?f pq)"
  1159     then obtain c d where "((a, c), (b, d)) \<in> set_pmf pq"
  1160       by (auto simp: set_map_pmf)
  1161     from pq[OF this] show "R a b" ..
  1162   qed
  1163   show "rel_pmf S A' B'"
  1164   proof (rule rel_pmf.intros)
  1165     let ?f = "\<lambda>(a, b). (snd a, snd b)"
  1166     have [simp]: "(\<lambda>x. fst (?f x)) = snd o fst" "(\<lambda>x. snd (?f x)) = snd o snd"
  1167       by auto
  1168 
  1169     show "map_pmf fst (map_pmf ?f pq) = A'"
  1170       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1171     show "map_pmf snd (map_pmf ?f pq) = B'"
  1172       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1173 
  1174     fix c d assume "(c, d) \<in> set_pmf (map_pmf ?f pq)"
  1175     then obtain a b where "((a, c), (b, d)) \<in> set_pmf pq"
  1176       by (auto simp: set_map_pmf)
  1177     from pq[OF this] show "S c d" ..
  1178   qed
  1179 next
  1180   assume "rel_pmf R A B" "rel_pmf S A' B'"
  1181   then obtain Rpq Spq
  1182     where Rpq: "\<And>a b. (a, b) \<in> set_pmf Rpq \<Longrightarrow> R a b"
  1183         "map_pmf fst Rpq = A" "map_pmf snd Rpq = B"
  1184       and Spq: "\<And>a b. (a, b) \<in> set_pmf Spq \<Longrightarrow> S a b"
  1185         "map_pmf fst Spq = A'" "map_pmf snd Spq = B'"
  1186     by (force elim: rel_pmf.cases)
  1187 
  1188   let ?f = "(\<lambda>((a, c), (b, d)). ((a, b), (c, d)))"
  1189   let ?pq = "map_pmf ?f (pair_pmf Rpq Spq)"
  1190   have [simp]: "(\<lambda>x. fst (?f x)) = (\<lambda>(a, b). (fst a, fst b))" "(\<lambda>x. snd (?f x)) = (\<lambda>(a, b). (snd a, snd b))"
  1191     by auto
  1192 
  1193   show "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1194     by (rule rel_pmf.intros[where pq="?pq"])
  1195        (auto simp: map_snd_pair_pmf map_fst_pair_pmf set_pair_pmf set_map_pmf map_pmf_comp Rpq Spq
  1196                    map_pair)
  1197 qed
  1198 
  1199 end
  1200