src/HOL/Product_Type.thy
author wenzelm
Wed Jun 29 17:35:46 2011 +0200 (2011-06-29)
changeset 43594 ef1ddc59b825
parent 42411 ff997038e8eb
child 43595 7ae4a23b5be6
permissions -rw-r--r--
modernized some simproc setup;
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_codegen.ML")
    13   ("Tools/inductive_set.ML")
    14 begin
    15 
    16 subsection {* @{typ bool} is a datatype *}
    17 
    18 rep_datatype True False by (auto intro: bool_induct)
    19 
    20 declare case_split [cases type: bool]
    21   -- "prefer plain propositional version"
    22 
    23 lemma
    24   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    25     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    26     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P" 
    27     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    28     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    29   by (simp_all add: equal)
    30 
    31 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    32   (Haskell infix 4 "==")
    33 
    34 code_instance bool :: equal
    35   (Haskell -)
    36 
    37 
    38 subsection {* The @{text unit} type *}
    39 
    40 typedef (open) unit = "{True}"
    41 proof
    42   show "True : ?unit" ..
    43 qed
    44 
    45 definition
    46   Unity :: unit    ("'(')")
    47 where
    48   "() = Abs_unit True"
    49 
    50 lemma unit_eq [no_atp]: "u = ()"
    51   by (induct u) (simp add: Unity_def)
    52 
    53 text {*
    54   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    55   this rule directly --- it loops!
    56 *}
    57 
    58 simproc_setup unit_eq ("x::unit") = {*
    59   fn _ => fn _ => fn ct =>
    60     if HOLogic.is_unit (term_of ct) then NONE
    61     else SOME (mk_meta_eq @{thm unit_eq})
    62 *}
    63 
    64 rep_datatype "()" by simp
    65 
    66 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    67   by simp
    68 
    69 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    70   by (rule triv_forall_equality)
    71 
    72 text {*
    73   This rewrite counters the effect of simproc @{text unit_eq} on @{term
    74   [source] "%u::unit. f u"}, replacing it by @{term [source]
    75   f} rather than by @{term [source] "%u. f ()"}.
    76 *}
    77 
    78 lemma unit_abs_eta_conv [simp,no_atp]: "(%u::unit. f ()) = f"
    79   by (rule ext) simp
    80 
    81 instantiation unit :: default
    82 begin
    83 
    84 definition "default = ()"
    85 
    86 instance ..
    87 
    88 end
    89 
    90 lemma [code]:
    91   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
    92 
    93 code_type unit
    94   (SML "unit")
    95   (OCaml "unit")
    96   (Haskell "()")
    97   (Scala "Unit")
    98 
    99 code_const Unity
   100   (SML "()")
   101   (OCaml "()")
   102   (Haskell "()")
   103   (Scala "()")
   104 
   105 code_instance unit :: equal
   106   (Haskell -)
   107 
   108 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   109   (Haskell infix 4 "==")
   110 
   111 code_reserved SML
   112   unit
   113 
   114 code_reserved OCaml
   115   unit
   116 
   117 code_reserved Scala
   118   Unit
   119 
   120 
   121 subsection {* The product type *}
   122 
   123 subsubsection {* Type definition *}
   124 
   125 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   126   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   127 
   128 typedef ('a, 'b) prod (infixr "*" 20)
   129   = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   130 proof
   131   fix a b show "Pair_Rep a b \<in> ?prod"
   132     by rule+
   133 qed
   134 
   135 type_notation (xsymbols)
   136   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   137 type_notation (HTML output)
   138   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   139 
   140 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   141   "Pair a b = Abs_prod (Pair_Rep a b)"
   142 
   143 rep_datatype Pair proof -
   144   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   145   assume "\<And>a b. P (Pair a b)"
   146   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   147 next
   148   fix a c :: 'a and b d :: 'b
   149   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   150     by (auto simp add: Pair_Rep_def fun_eq_iff)
   151   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   152     by (auto simp add: prod_def)
   153   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   154     by (simp add: Pair_def Abs_prod_inject)
   155 qed
   156 
   157 declare prod.simps(2) [nitpick_simp del]
   158 
   159 declare prod.weak_case_cong [cong del]
   160 
   161 
   162 subsubsection {* Tuple syntax *}
   163 
   164 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   165   "split \<equiv> prod_case"
   166 
   167 text {*
   168   Patterns -- extends pre-defined type @{typ pttrn} used in
   169   abstractions.
   170 *}
   171 
   172 nonterminal tuple_args and patterns
   173 
   174 syntax
   175   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   176   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   177   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   178   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   179   ""            :: "pttrn => patterns"                  ("_")
   180   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   181 
   182 translations
   183   "(x, y)" == "CONST Pair x y"
   184   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   185   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   186   "%(x, y). b" == "CONST prod_case (%x y. b)"
   187   "_abs (CONST Pair x y) t" => "%(x, y). t"
   188   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   189      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   190 
   191 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   192   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   193 print_translation {*
   194 let
   195   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   196         (* split (%x y. t) => %(x,y) t *)
   197         let
   198           val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   199           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   200         in
   201           Syntax.const @{syntax_const "_abs"} $
   202             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   203         end
   204     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   205         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   206         let
   207           val Const (@{syntax_const "_abs"}, _) $
   208             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   209           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   210         in
   211           Syntax.const @{syntax_const "_abs"} $
   212             (Syntax.const @{syntax_const "_pattern"} $ x' $
   213               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   214         end
   215     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   216         (* split (split (%x y z. t)) => %((x, y), z). t *)
   217         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   218     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   219         (* split (%pttrn z. t) => %(pttrn,z). t *)
   220         let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   221           Syntax.const @{syntax_const "_abs"} $
   222             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   223         end
   224     | split_tr' _ = raise Match;
   225 in [(@{const_syntax prod_case}, split_tr')] end
   226 *}
   227 
   228 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   229 typed_print_translation {*
   230 let
   231   fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   232     | split_guess_names_tr' T [Abs (x, xT, t)] =
   233         (case (head_of t) of
   234           Const (@{const_syntax prod_case}, _) => raise Match
   235         | _ =>
   236           let 
   237             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   238             val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   239             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   240           in
   241             Syntax.const @{syntax_const "_abs"} $
   242               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   243           end)
   244     | split_guess_names_tr' T [t] =
   245         (case head_of t of
   246           Const (@{const_syntax prod_case}, _) => raise Match
   247         | _ =>
   248           let
   249             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   250             val (y, t') =
   251               Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   252             val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   253           in
   254             Syntax.const @{syntax_const "_abs"} $
   255               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   256           end)
   257     | split_guess_names_tr' _ _ = raise Match;
   258 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   259 *}
   260 
   261 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   262    where Q is some bounded quantifier or set operator.
   263    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   264    whereas we want "Q (x,y):A. P x y".
   265    Otherwise prevent eta-contraction.
   266 *)
   267 print_translation {*
   268 let
   269   fun contract Q f ts =
   270     case ts of
   271       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   272       => if Term.is_dependent t then f ts else Syntax.const Q $ A $ s
   273     | _ => f ts;
   274   fun contract2 (Q,f) = (Q, contract Q f);
   275   val pairs =
   276     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   277      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   278      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   279      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   280 in map contract2 pairs end
   281 *}
   282 
   283 subsubsection {* Code generator setup *}
   284 
   285 code_type prod
   286   (SML infix 2 "*")
   287   (OCaml infix 2 "*")
   288   (Haskell "!((_),/ (_))")
   289   (Scala "((_),/ (_))")
   290 
   291 code_const Pair
   292   (SML "!((_),/ (_))")
   293   (OCaml "!((_),/ (_))")
   294   (Haskell "!((_),/ (_))")
   295   (Scala "!((_),/ (_))")
   296 
   297 code_instance prod :: equal
   298   (Haskell -)
   299 
   300 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   301   (Haskell infix 4 "==")
   302 
   303 types_code
   304   "prod"     ("(_ */ _)")
   305 attach (term_of) {*
   306 fun term_of_prod aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   307 *}
   308 attach (test) {*
   309 fun gen_prod aG aT bG bT i =
   310   let
   311     val (x, t) = aG i;
   312     val (y, u) = bG i
   313   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   314 *}
   315 
   316 consts_code
   317   "Pair"    ("(_,/ _)")
   318 
   319 setup {*
   320 let
   321 
   322 fun strip_abs_split 0 t = ([], t)
   323   | strip_abs_split i (Abs (s, T, t)) =
   324       let
   325         val s' = Codegen.new_name t s;
   326         val v = Free (s', T)
   327       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   328   | strip_abs_split i (u as Const (@{const_name prod_case}, _) $ t) =
   329       (case strip_abs_split (i+1) t of
   330         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   331       | _ => ([], u))
   332   | strip_abs_split i t =
   333       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
   334 
   335 fun let_codegen thy mode defs dep thyname brack t gr =
   336   (case strip_comb t of
   337     (t1 as Const (@{const_name Let}, _), t2 :: t3 :: ts) =>
   338     let
   339       fun dest_let (l as Const (@{const_name Let}, _) $ t $ u) =
   340           (case strip_abs_split 1 u of
   341              ([p], u') => apfst (cons (p, t)) (dest_let u')
   342            | _ => ([], l))
   343         | dest_let t = ([], t);
   344       fun mk_code (l, r) gr =
   345         let
   346           val (pl, gr1) = Codegen.invoke_codegen thy mode defs dep thyname false l gr;
   347           val (pr, gr2) = Codegen.invoke_codegen thy mode defs dep thyname false r gr1;
   348         in ((pl, pr), gr2) end
   349     in case dest_let (t1 $ t2 $ t3) of
   350         ([], _) => NONE
   351       | (ps, u) =>
   352           let
   353             val (qs, gr1) = fold_map mk_code ps gr;
   354             val (pu, gr2) = Codegen.invoke_codegen thy mode defs dep thyname false u gr1;
   355             val (pargs, gr3) = fold_map
   356               (Codegen.invoke_codegen thy mode defs dep thyname true) ts gr2
   357           in
   358             SOME (Codegen.mk_app brack
   359               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
   360                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   361                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
   362                        Pretty.brk 1, pr]]) qs))),
   363                 Pretty.brk 1, Codegen.str "in ", pu,
   364                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
   365           end
   366     end
   367   | _ => NONE);
   368 
   369 fun split_codegen thy mode defs dep thyname brack t gr = (case strip_comb t of
   370     (t1 as Const (@{const_name prod_case}, _), t2 :: ts) =>
   371       let
   372         val ([p], u) = strip_abs_split 1 (t1 $ t2);
   373         val (q, gr1) = Codegen.invoke_codegen thy mode defs dep thyname false p gr;
   374         val (pu, gr2) = Codegen.invoke_codegen thy mode defs dep thyname false u gr1;
   375         val (pargs, gr3) = fold_map
   376           (Codegen.invoke_codegen thy mode defs dep thyname true) ts gr2
   377       in
   378         SOME (Codegen.mk_app brack
   379           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
   380             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
   381       end
   382   | _ => NONE);
   383 
   384 in
   385 
   386   Codegen.add_codegen "let_codegen" let_codegen
   387   #> Codegen.add_codegen "split_codegen" split_codegen
   388 
   389 end
   390 *}
   391 
   392 
   393 subsubsection {* Fundamental operations and properties *}
   394 
   395 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   396   by (cases p) simp
   397 
   398 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   399   "fst p = (case p of (a, b) \<Rightarrow> a)"
   400 
   401 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   402   "snd p = (case p of (a, b) \<Rightarrow> b)"
   403 
   404 lemma fst_conv [simp, code]: "fst (a, b) = a"
   405   unfolding fst_def by simp
   406 
   407 lemma snd_conv [simp, code]: "snd (a, b) = b"
   408   unfolding snd_def by simp
   409 
   410 code_const fst and snd
   411   (Haskell "fst" and "snd")
   412 
   413 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   414   by (simp add: fun_eq_iff split: prod.split)
   415 
   416 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   417   by simp
   418 
   419 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   420   by simp
   421 
   422 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   423   by (cases p) simp
   424 
   425 lemmas surjective_pairing = pair_collapse [symmetric]
   426 
   427 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   428   by (cases s, cases t) simp
   429 
   430 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   431   by (simp add: Pair_fst_snd_eq)
   432 
   433 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   434   by (fact prod.cases)
   435 
   436 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   437   by (rule split_conv [THEN iffD2])
   438 
   439 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   440   by (rule split_conv [THEN iffD1])
   441 
   442 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   443   by (simp add: fun_eq_iff split: prod.split)
   444 
   445 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   446   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   447   by (simp add: fun_eq_iff split: prod.split)
   448 
   449 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   450   by (cases x) simp
   451 
   452 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   453   by (cases p) simp
   454 
   455 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   456   by (simp add: prod_case_unfold)
   457 
   458 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   459   -- {* Prevents simplification of @{term c}: much faster *}
   460   by (fact prod.weak_case_cong)
   461 
   462 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   463   by (simp add: split_eta)
   464 
   465 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   466 proof
   467   fix a b
   468   assume "!!x. PROP P x"
   469   then show "PROP P (a, b)" .
   470 next
   471   fix x
   472   assume "!!a b. PROP P (a, b)"
   473   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   474 qed
   475 
   476 text {*
   477   The rule @{thm [source] split_paired_all} does not work with the
   478   Simplifier because it also affects premises in congrence rules,
   479   where this can lead to premises of the form @{text "!!a b. ... =
   480   ?P(a, b)"} which cannot be solved by reflexivity.
   481 *}
   482 
   483 lemmas split_tupled_all = split_paired_all unit_all_eq2
   484 
   485 ML {*
   486   (* replace parameters of product type by individual component parameters *)
   487   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   488   local (* filtering with exists_paired_all is an essential optimization *)
   489     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   490           can HOLogic.dest_prodT T orelse exists_paired_all t
   491       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   492       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   493       | exists_paired_all _ = false;
   494     val ss = HOL_basic_ss
   495       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   496       addsimprocs [@{simproc unit_eq}];
   497   in
   498     val split_all_tac = SUBGOAL (fn (t, i) =>
   499       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   500     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   501       if exists_paired_all t then full_simp_tac ss i else no_tac);
   502     fun split_all th =
   503    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   504   end;
   505 *}
   506 
   507 declaration {* fn _ =>
   508   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   509 *}
   510 
   511 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   512   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   513   by fast
   514 
   515 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   516   by fast
   517 
   518 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   519   -- {* Can't be added to simpset: loops! *}
   520   by (simp add: split_eta)
   521 
   522 text {*
   523   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   524   @{thm [source] split_eta} as a rewrite rule is not general enough,
   525   and using @{thm [source] cond_split_eta} directly would render some
   526   existing proofs very inefficient; similarly for @{text
   527   split_beta}.
   528 *}
   529 
   530 ML {*
   531 local
   532   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   533   fun Pair_pat k 0 (Bound m) = (m = k)
   534     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   535         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   536     | Pair_pat _ _ _ = false;
   537   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   538     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   539     | no_args k i (Bound m) = m < k orelse m > k + i
   540     | no_args _ _ _ = true;
   541   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   542     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   543     | split_pat tp i _ = NONE;
   544   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   545         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   546         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   547 
   548   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   549     | beta_term_pat k i (t $ u) =
   550         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   551     | beta_term_pat k i t = no_args k i t;
   552   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   553     | eta_term_pat _ _ _ = false;
   554   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   555     | subst arg k i (t $ u) =
   556         if Pair_pat k i (t $ u) then incr_boundvars k arg
   557         else (subst arg k i t $ subst arg k i u)
   558     | subst arg k i t = t;
   559   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   560         (case split_pat beta_term_pat 1 t of
   561           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   562         | NONE => NONE)
   563     | beta_proc _ _ = NONE;
   564   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   565         (case split_pat eta_term_pat 1 t of
   566           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   567         | NONE => NONE)
   568     | eta_proc _ _ = NONE;
   569 in
   570   val split_beta_proc = Simplifier.simproc_global @{theory} "split_beta" ["split f z"] (K beta_proc);
   571   val split_eta_proc = Simplifier.simproc_global @{theory} "split_eta" ["split f"] (K eta_proc);
   572 end;
   573 
   574 Addsimprocs [split_beta_proc, split_eta_proc];
   575 *}
   576 
   577 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   578   by (subst surjective_pairing, rule split_conv)
   579 
   580 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   581   -- {* For use with @{text split} and the Simplifier. *}
   582   by (insert surj_pair [of p], clarify, simp)
   583 
   584 text {*
   585   @{thm [source] split_split} could be declared as @{text "[split]"}
   586   done after the Splitter has been speeded up significantly;
   587   precompute the constants involved and don't do anything unless the
   588   current goal contains one of those constants.
   589 *}
   590 
   591 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   592 by (subst split_split, simp)
   593 
   594 text {*
   595   \medskip @{term split} used as a logical connective or set former.
   596 
   597   \medskip These rules are for use with @{text blast}; could instead
   598   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   599 
   600 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   601   apply (simp only: split_tupled_all)
   602   apply (simp (no_asm_simp))
   603   done
   604 
   605 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   606   apply (simp only: split_tupled_all)
   607   apply (simp (no_asm_simp))
   608   done
   609 
   610 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   611   by (induct p) auto
   612 
   613 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   614   by (induct p) auto
   615 
   616 lemma splitE2:
   617   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   618 proof -
   619   assume q: "Q (split P z)"
   620   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   621   show R
   622     apply (rule r surjective_pairing)+
   623     apply (rule split_beta [THEN subst], rule q)
   624     done
   625 qed
   626 
   627 lemma splitD': "split R (a,b) c ==> R a b c"
   628   by simp
   629 
   630 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   631   by simp
   632 
   633 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   634 by (simp only: split_tupled_all, simp)
   635 
   636 lemma mem_splitE:
   637   assumes major: "z \<in> split c p"
   638     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   639   shows Q
   640   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   641 
   642 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   643 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   644 
   645 ML {*
   646 local (* filtering with exists_p_split is an essential optimization *)
   647   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   648     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   649     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   650     | exists_p_split _ = false;
   651   val ss = HOL_basic_ss addsimps @{thms split_conv};
   652 in
   653 val split_conv_tac = SUBGOAL (fn (t, i) =>
   654     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   655 end;
   656 *}
   657 
   658 (* This prevents applications of splitE for already splitted arguments leading
   659    to quite time-consuming computations (in particular for nested tuples) *)
   660 declaration {* fn _ =>
   661   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   662 *}
   663 
   664 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   665   by (rule ext) fast
   666 
   667 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   668   by (rule ext) fast
   669 
   670 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   671   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   672   by (rule ext) blast
   673 
   674 (* Do NOT make this a simp rule as it
   675    a) only helps in special situations
   676    b) can lead to nontermination in the presence of split_def
   677 *)
   678 lemma split_comp_eq: 
   679   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   680   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   681   by (rule ext) auto
   682 
   683 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   684   apply (rule_tac x = "(a, b)" in image_eqI)
   685    apply auto
   686   done
   687 
   688 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   689   by blast
   690 
   691 (*
   692 the following  would be slightly more general,
   693 but cannot be used as rewrite rule:
   694 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   695 ### ?y = .x
   696 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   697 by (rtac some_equality 1)
   698 by ( Simp_tac 1)
   699 by (split_all_tac 1)
   700 by (Asm_full_simp_tac 1)
   701 qed "The_split_eq";
   702 *)
   703 
   704 text {*
   705   Setup of internal @{text split_rule}.
   706 *}
   707 
   708 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   709 
   710 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   711   by (fact splitI2)
   712 
   713 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   714   by (fact splitI2')
   715 
   716 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   717   by (fact splitE)
   718 
   719 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   720   by (fact splitE')
   721 
   722 declare prod_caseI [intro!]
   723 
   724 lemma prod_case_beta:
   725   "prod_case f p = f (fst p) (snd p)"
   726   by (fact split_beta)
   727 
   728 lemma prod_cases3 [cases type]:
   729   obtains (fields) a b c where "y = (a, b, c)"
   730   by (cases y, case_tac b) blast
   731 
   732 lemma prod_induct3 [case_names fields, induct type]:
   733     "(!!a b c. P (a, b, c)) ==> P x"
   734   by (cases x) blast
   735 
   736 lemma prod_cases4 [cases type]:
   737   obtains (fields) a b c d where "y = (a, b, c, d)"
   738   by (cases y, case_tac c) blast
   739 
   740 lemma prod_induct4 [case_names fields, induct type]:
   741     "(!!a b c d. P (a, b, c, d)) ==> P x"
   742   by (cases x) blast
   743 
   744 lemma prod_cases5 [cases type]:
   745   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   746   by (cases y, case_tac d) blast
   747 
   748 lemma prod_induct5 [case_names fields, induct type]:
   749     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   750   by (cases x) blast
   751 
   752 lemma prod_cases6 [cases type]:
   753   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   754   by (cases y, case_tac e) blast
   755 
   756 lemma prod_induct6 [case_names fields, induct type]:
   757     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   758   by (cases x) blast
   759 
   760 lemma prod_cases7 [cases type]:
   761   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   762   by (cases y, case_tac f) blast
   763 
   764 lemma prod_induct7 [case_names fields, induct type]:
   765     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   766   by (cases x) blast
   767 
   768 lemma split_def:
   769   "split = (\<lambda>c p. c (fst p) (snd p))"
   770   by (fact prod_case_unfold)
   771 
   772 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   773   "internal_split == split"
   774 
   775 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   776   by (simp only: internal_split_def split_conv)
   777 
   778 use "Tools/split_rule.ML"
   779 setup Split_Rule.setup
   780 
   781 hide_const internal_split
   782 
   783 
   784 subsubsection {* Derived operations *}
   785 
   786 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   787   "curry = (\<lambda>c x y. c (x, y))"
   788 
   789 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   790   by (simp add: curry_def)
   791 
   792 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   793   by (simp add: curry_def)
   794 
   795 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   796   by (simp add: curry_def)
   797 
   798 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   799   by (simp add: curry_def)
   800 
   801 lemma curry_split [simp]: "curry (split f) = f"
   802   by (simp add: curry_def split_def)
   803 
   804 lemma split_curry [simp]: "split (curry f) = f"
   805   by (simp add: curry_def split_def)
   806 
   807 text {*
   808   The composition-uncurry combinator.
   809 *}
   810 
   811 notation fcomp (infixl "\<circ>>" 60)
   812 
   813 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   814   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   815 
   816 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   817   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   818 
   819 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   820   by (simp add: scomp_unfold prod_case_unfold)
   821 
   822 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   823   by (simp add: fun_eq_iff scomp_apply)
   824 
   825 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   826   by (simp add: fun_eq_iff scomp_apply)
   827 
   828 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   829   by (simp add: fun_eq_iff scomp_unfold)
   830 
   831 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   832   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   833 
   834 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   835   by (simp add: fun_eq_iff scomp_unfold fcomp_apply)
   836 
   837 code_const scomp
   838   (Eval infixl 3 "#->")
   839 
   840 no_notation fcomp (infixl "\<circ>>" 60)
   841 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   842 
   843 text {*
   844   @{term map_pair} --- action of the product functor upon
   845   functions.
   846 *}
   847 
   848 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   849   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   850 
   851 lemma map_pair_simp [simp, code]:
   852   "map_pair f g (a, b) = (f a, g b)"
   853   by (simp add: map_pair_def)
   854 
   855 enriched_type map_pair: map_pair
   856   by (auto simp add: split_paired_all intro: ext)
   857 
   858 lemma fst_map_pair [simp]:
   859   "fst (map_pair f g x) = f (fst x)"
   860   by (cases x) simp_all
   861 
   862 lemma snd_prod_fun [simp]:
   863   "snd (map_pair f g x) = g (snd x)"
   864   by (cases x) simp_all
   865 
   866 lemma fst_comp_map_pair [simp]:
   867   "fst \<circ> map_pair f g = f \<circ> fst"
   868   by (rule ext) simp_all
   869 
   870 lemma snd_comp_map_pair [simp]:
   871   "snd \<circ> map_pair f g = g \<circ> snd"
   872   by (rule ext) simp_all
   873 
   874 lemma map_pair_compose:
   875   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   876   by (rule ext) (simp add: map_pair.compositionality comp_def)
   877 
   878 lemma map_pair_ident [simp]:
   879   "map_pair (%x. x) (%y. y) = (%z. z)"
   880   by (rule ext) (simp add: map_pair.identity)
   881 
   882 lemma map_pair_imageI [intro]:
   883   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   884   by (rule image_eqI) simp_all
   885 
   886 lemma prod_fun_imageE [elim!]:
   887   assumes major: "c \<in> map_pair f g ` R"
   888     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   889   shows P
   890   apply (rule major [THEN imageE])
   891   apply (case_tac x)
   892   apply (rule cases)
   893   apply simp_all
   894   done
   895 
   896 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   897   "apfst f = map_pair f id"
   898 
   899 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   900   "apsnd f = map_pair id f"
   901 
   902 lemma apfst_conv [simp, code]:
   903   "apfst f (x, y) = (f x, y)" 
   904   by (simp add: apfst_def)
   905 
   906 lemma apsnd_conv [simp, code]:
   907   "apsnd f (x, y) = (x, f y)" 
   908   by (simp add: apsnd_def)
   909 
   910 lemma fst_apfst [simp]:
   911   "fst (apfst f x) = f (fst x)"
   912   by (cases x) simp
   913 
   914 lemma fst_apsnd [simp]:
   915   "fst (apsnd f x) = fst x"
   916   by (cases x) simp
   917 
   918 lemma snd_apfst [simp]:
   919   "snd (apfst f x) = snd x"
   920   by (cases x) simp
   921 
   922 lemma snd_apsnd [simp]:
   923   "snd (apsnd f x) = f (snd x)"
   924   by (cases x) simp
   925 
   926 lemma apfst_compose:
   927   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   928   by (cases x) simp
   929 
   930 lemma apsnd_compose:
   931   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   932   by (cases x) simp
   933 
   934 lemma apfst_apsnd [simp]:
   935   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   936   by (cases x) simp
   937 
   938 lemma apsnd_apfst [simp]:
   939   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   940   by (cases x) simp
   941 
   942 lemma apfst_id [simp] :
   943   "apfst id = id"
   944   by (simp add: fun_eq_iff)
   945 
   946 lemma apsnd_id [simp] :
   947   "apsnd id = id"
   948   by (simp add: fun_eq_iff)
   949 
   950 lemma apfst_eq_conv [simp]:
   951   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   952   by (cases x) simp
   953 
   954 lemma apsnd_eq_conv [simp]:
   955   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   956   by (cases x) simp
   957 
   958 lemma apsnd_apfst_commute:
   959   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   960   by simp
   961 
   962 text {*
   963   Disjoint union of a family of sets -- Sigma.
   964 *}
   965 
   966 definition Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   967   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   968 
   969 abbreviation
   970   Times :: "['a set, 'b set] => ('a * 'b) set"
   971     (infixr "<*>" 80) where
   972   "A <*> B == Sigma A (%_. B)"
   973 
   974 notation (xsymbols)
   975   Times  (infixr "\<times>" 80)
   976 
   977 notation (HTML output)
   978   Times  (infixr "\<times>" 80)
   979 
   980 syntax
   981   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   982 translations
   983   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   984 
   985 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   986   by (unfold Sigma_def) blast
   987 
   988 lemma SigmaE [elim!]:
   989     "[| c: Sigma A B;
   990         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   991      |] ==> P"
   992   -- {* The general elimination rule. *}
   993   by (unfold Sigma_def) blast
   994 
   995 text {*
   996   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   997   eigenvariables.
   998 *}
   999 
  1000 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
  1001   by blast
  1002 
  1003 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1004   by blast
  1005 
  1006 lemma SigmaE2:
  1007     "[| (a, b) : Sigma A B;
  1008         [| a:A;  b:B(a) |] ==> P
  1009      |] ==> P"
  1010   by blast
  1011 
  1012 lemma Sigma_cong:
  1013      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1014       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1015   by auto
  1016 
  1017 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1018   by blast
  1019 
  1020 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1021   by blast
  1022 
  1023 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1024   by blast
  1025 
  1026 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1027   by auto
  1028 
  1029 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1030   by auto
  1031 
  1032 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1033   by auto
  1034 
  1035 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1036   by blast
  1037 
  1038 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1039   by blast
  1040 
  1041 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1042   by (blast elim: equalityE)
  1043 
  1044 lemma SetCompr_Sigma_eq:
  1045     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1046   by blast
  1047 
  1048 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1049   by blast
  1050 
  1051 lemma UN_Times_distrib:
  1052   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1053   -- {* Suggested by Pierre Chartier *}
  1054   by blast
  1055 
  1056 lemma split_paired_Ball_Sigma [simp,no_atp]:
  1057     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1058   by blast
  1059 
  1060 lemma split_paired_Bex_Sigma [simp,no_atp]:
  1061     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1062   by blast
  1063 
  1064 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1065   by blast
  1066 
  1067 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1068   by blast
  1069 
  1070 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1071   by blast
  1072 
  1073 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1074   by blast
  1075 
  1076 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1077   by blast
  1078 
  1079 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1080   by blast
  1081 
  1082 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1083   by blast
  1084 
  1085 text {*
  1086   Non-dependent versions are needed to avoid the need for higher-order
  1087   matching, especially when the rules are re-oriented.
  1088 *}
  1089 
  1090 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1091 by blast
  1092 
  1093 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1094 by blast
  1095 
  1096 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1097 by blast
  1098 
  1099 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1100   by auto
  1101 
  1102 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1103   by (auto intro!: image_eqI)
  1104 
  1105 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1106   by (auto intro!: image_eqI)
  1107 
  1108 lemma insert_times_insert[simp]:
  1109   "insert a A \<times> insert b B =
  1110    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1111 by blast
  1112 
  1113 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1114   by (auto, case_tac "f x", auto)
  1115 
  1116 lemma swap_inj_on:
  1117   "inj_on (\<lambda>(i, j). (j, i)) A"
  1118   by (auto intro!: inj_onI)
  1119 
  1120 lemma swap_product:
  1121   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1122   by (simp add: split_def image_def) blast
  1123 
  1124 lemma image_split_eq_Sigma:
  1125   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1126 proof (safe intro!: imageI vimageI)
  1127   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1128   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1129     using * eq[symmetric] by auto
  1130 qed simp_all
  1131 
  1132 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1133 
  1134 lemma map_pair_inj_on:
  1135   assumes "inj_on f A" and "inj_on g B"
  1136   shows "inj_on (map_pair f g) (A \<times> B)"
  1137 proof (rule inj_onI)
  1138   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1139   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1140   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1141   assume "map_pair f g x = map_pair f g y"
  1142   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1143   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1144   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1145   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1146   moreover from `map_pair f g x = map_pair f g y`
  1147   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1148   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1149   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1150   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1151   ultimately show "x = y" by(rule prod_eqI)
  1152 qed
  1153 
  1154 lemma map_pair_surj:
  1155   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1156   assumes "surj f" and "surj g"
  1157   shows "surj (map_pair f g)"
  1158 unfolding surj_def
  1159 proof
  1160   fix y :: "'b \<times> 'd"
  1161   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1162   moreover
  1163   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1164   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1165   thus "\<exists>x. y = map_pair f g x" by auto
  1166 qed
  1167 
  1168 lemma map_pair_surj_on:
  1169   assumes "f ` A = A'" and "g ` B = B'"
  1170   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1171 unfolding image_def
  1172 proof(rule set_eqI,rule iffI)
  1173   fix x :: "'a \<times> 'c"
  1174   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1175   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1176   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1177   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1178   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1179   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1180 next
  1181   fix x :: "'a \<times> 'c"
  1182   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1183   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1184   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1185   moreover from `image g B = B'` and `snd x \<in> B'`
  1186   obtain b where "b \<in> B" and "snd x = g b" by auto
  1187   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1188   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1189   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1190   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1191 qed
  1192 
  1193 
  1194 subsection {* Inductively defined sets *}
  1195 
  1196 use "Tools/inductive_codegen.ML"
  1197 setup Inductive_Codegen.setup
  1198 
  1199 use "Tools/inductive_set.ML"
  1200 setup Inductive_Set.setup
  1201 
  1202 
  1203 subsection {* Legacy theorem bindings and duplicates *}
  1204 
  1205 lemma PairE:
  1206   obtains x y where "p = (x, y)"
  1207   by (fact prod.exhaust)
  1208 
  1209 lemma Pair_inject:
  1210   assumes "(a, b) = (a', b')"
  1211     and "a = a' ==> b = b' ==> R"
  1212   shows R
  1213   using assms by simp
  1214 
  1215 lemmas Pair_eq = prod.inject
  1216 
  1217 lemmas split = split_conv  -- {* for backwards compatibility *}
  1218 
  1219 end