src/HOL/Probability/Probability_Mass_Function.thy
author Andreas Lochbihler
Tue Apr 14 14:15:10 2015 +0200 (2015-04-14)
changeset 60068 ef2123db900c
parent 59731 7fccaeec22f0
child 60495 d7ff0a1df90a
permissions -rw-r--r--
add various lemmas about pmfs
     1 (*  Title:      HOL/Probability/Probability_Mass_Function.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Andreas Lochbihler, ETH Zurich
     4 *)
     5 
     6 section \<open> Probability mass function \<close>
     7 
     8 theory Probability_Mass_Function
     9 imports
    10   Giry_Monad
    11   "~~/src/HOL/Library/Multiset"
    12 begin
    13 
    14 lemma AE_emeasure_singleton:
    15   assumes x: "emeasure M {x} \<noteq> 0" and ae: "AE x in M. P x" shows "P x"
    16 proof -
    17   from x have x_M: "{x} \<in> sets M"
    18     by (auto intro: emeasure_notin_sets)
    19   from ae obtain N where N: "{x\<in>space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
    20     by (auto elim: AE_E)
    21   { assume "\<not> P x"
    22     with x_M[THEN sets.sets_into_space] N have "emeasure M {x} \<le> emeasure M N"
    23       by (intro emeasure_mono) auto
    24     with x N have False
    25       by (auto simp: emeasure_le_0_iff) }
    26   then show "P x" by auto
    27 qed
    28 
    29 lemma AE_measure_singleton: "measure M {x} \<noteq> 0 \<Longrightarrow> AE x in M. P x \<Longrightarrow> P x"
    30   by (metis AE_emeasure_singleton measure_def emeasure_empty measure_empty)
    31 
    32 lemma ereal_divide': "b \<noteq> 0 \<Longrightarrow> ereal (a / b) = ereal a / ereal b"
    33   using ereal_divide[of a b] by simp
    34 
    35 lemma (in finite_measure) countable_support:
    36   "countable {x. measure M {x} \<noteq> 0}"
    37 proof cases
    38   assume "measure M (space M) = 0"
    39   with bounded_measure measure_le_0_iff have "{x. measure M {x} \<noteq> 0} = {}"
    40     by auto
    41   then show ?thesis
    42     by simp
    43 next
    44   let ?M = "measure M (space M)" and ?m = "\<lambda>x. measure M {x}"
    45   assume "?M \<noteq> 0"
    46   then have *: "{x. ?m x \<noteq> 0} = (\<Union>n. {x. ?M / Suc n < ?m x})"
    47     using reals_Archimedean[of "?m x / ?M" for x]
    48     by (auto simp: field_simps not_le[symmetric] measure_nonneg divide_le_0_iff measure_le_0_iff)
    49   have **: "\<And>n. finite {x. ?M / Suc n < ?m x}"
    50   proof (rule ccontr)
    51     fix n assume "infinite {x. ?M / Suc n < ?m x}" (is "infinite ?X")
    52     then obtain X where "finite X" "card X = Suc (Suc n)" "X \<subseteq> ?X"
    53       by (metis infinite_arbitrarily_large)
    54     from this(3) have *: "\<And>x. x \<in> X \<Longrightarrow> ?M / Suc n \<le> ?m x"
    55       by auto
    56     { fix x assume "x \<in> X"
    57       from `?M \<noteq> 0` *[OF this] have "?m x \<noteq> 0" by (auto simp: field_simps measure_le_0_iff)
    58       then have "{x} \<in> sets M" by (auto dest: measure_notin_sets) }
    59     note singleton_sets = this
    60     have "?M < (\<Sum>x\<in>X. ?M / Suc n)"
    61       using `?M \<noteq> 0`
    62       by (simp add: `card X = Suc (Suc n)` real_eq_of_nat[symmetric] real_of_nat_Suc field_simps less_le measure_nonneg)
    63     also have "\<dots> \<le> (\<Sum>x\<in>X. ?m x)"
    64       by (rule setsum_mono) fact
    65     also have "\<dots> = measure M (\<Union>x\<in>X. {x})"
    66       using singleton_sets `finite X`
    67       by (intro finite_measure_finite_Union[symmetric]) (auto simp: disjoint_family_on_def)
    68     finally have "?M < measure M (\<Union>x\<in>X. {x})" .
    69     moreover have "measure M (\<Union>x\<in>X. {x}) \<le> ?M"
    70       using singleton_sets[THEN sets.sets_into_space] by (intro finite_measure_mono) auto
    71     ultimately show False by simp
    72   qed
    73   show ?thesis
    74     unfolding * by (intro countable_UN countableI_type countable_finite[OF **])
    75 qed
    76 
    77 lemma (in finite_measure) AE_support_countable:
    78   assumes [simp]: "sets M = UNIV"
    79   shows "(AE x in M. measure M {x} \<noteq> 0) \<longleftrightarrow> (\<exists>S. countable S \<and> (AE x in M. x \<in> S))"
    80 proof
    81   assume "\<exists>S. countable S \<and> (AE x in M. x \<in> S)"
    82   then obtain S where S[intro]: "countable S" and ae: "AE x in M. x \<in> S"
    83     by auto
    84   then have "emeasure M (\<Union>x\<in>{x\<in>S. emeasure M {x} \<noteq> 0}. {x}) =
    85     (\<integral>\<^sup>+ x. emeasure M {x} * indicator {x\<in>S. emeasure M {x} \<noteq> 0} x \<partial>count_space UNIV)"
    86     by (subst emeasure_UN_countable)
    87        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    88   also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} * indicator S x \<partial>count_space UNIV)"
    89     by (auto intro!: nn_integral_cong split: split_indicator)
    90   also have "\<dots> = emeasure M (\<Union>x\<in>S. {x})"
    91     by (subst emeasure_UN_countable)
    92        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    93   also have "\<dots> = emeasure M (space M)"
    94     using ae by (intro emeasure_eq_AE) auto
    95   finally have "emeasure M {x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0} = emeasure M (space M)"
    96     by (simp add: emeasure_single_in_space cong: rev_conj_cong)
    97   with finite_measure_compl[of "{x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0}"]
    98   have "AE x in M. x \<in> S \<and> emeasure M {x} \<noteq> 0"
    99     by (intro AE_I[OF order_refl]) (auto simp: emeasure_eq_measure set_diff_eq cong: conj_cong)
   100   then show "AE x in M. measure M {x} \<noteq> 0"
   101     by (auto simp: emeasure_eq_measure)
   102 qed (auto intro!: exI[of _ "{x. measure M {x} \<noteq> 0}"] countable_support)
   103 
   104 subsection \<open> PMF as measure \<close>
   105 
   106 typedef 'a pmf = "{M :: 'a measure. prob_space M \<and> sets M = UNIV \<and> (AE x in M. measure M {x} \<noteq> 0)}"
   107   morphisms measure_pmf Abs_pmf
   108   by (intro exI[of _ "uniform_measure (count_space UNIV) {undefined}"])
   109      (auto intro!: prob_space_uniform_measure AE_uniform_measureI)
   110 
   111 declare [[coercion measure_pmf]]
   112 
   113 lemma prob_space_measure_pmf: "prob_space (measure_pmf p)"
   114   using pmf.measure_pmf[of p] by auto
   115 
   116 interpretation measure_pmf!: prob_space "measure_pmf M" for M
   117   by (rule prob_space_measure_pmf)
   118 
   119 interpretation measure_pmf!: subprob_space "measure_pmf M" for M
   120   by (rule prob_space_imp_subprob_space) unfold_locales
   121 
   122 lemma subprob_space_measure_pmf: "subprob_space (measure_pmf x)"
   123   by unfold_locales
   124 
   125 locale pmf_as_measure
   126 begin
   127 
   128 setup_lifting type_definition_pmf
   129 
   130 end
   131 
   132 context
   133 begin
   134 
   135 interpretation pmf_as_measure .
   136 
   137 lemma sets_measure_pmf[simp]: "sets (measure_pmf p) = UNIV"
   138   by transfer blast
   139 
   140 lemma sets_measure_pmf_count_space[measurable_cong]:
   141   "sets (measure_pmf M) = sets (count_space UNIV)"
   142   by simp
   143 
   144 lemma space_measure_pmf[simp]: "space (measure_pmf p) = UNIV"
   145   using sets_eq_imp_space_eq[of "measure_pmf p" "count_space UNIV"] by simp
   146 
   147 lemma measure_pmf_in_subprob_algebra[measurable (raw)]: "measure_pmf x \<in> space (subprob_algebra (count_space UNIV))"
   148   by (simp add: space_subprob_algebra subprob_space_measure_pmf)
   149 
   150 lemma measurable_pmf_measure1[simp]: "measurable (M :: 'a pmf) N = UNIV \<rightarrow> space N"
   151   by (auto simp: measurable_def)
   152 
   153 lemma measurable_pmf_measure2[simp]: "measurable N (M :: 'a pmf) = measurable N (count_space UNIV)"
   154   by (intro measurable_cong_sets) simp_all
   155 
   156 lemma measurable_pair_restrict_pmf2:
   157   assumes "countable A"
   158   assumes [measurable]: "\<And>y. y \<in> A \<Longrightarrow> (\<lambda>x. f (x, y)) \<in> measurable M L"
   159   shows "f \<in> measurable (M \<Otimes>\<^sub>M restrict_space (measure_pmf N) A) L" (is "f \<in> measurable ?M _")
   160 proof -
   161   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   162     by (simp add: restrict_count_space)
   163 
   164   show ?thesis
   165     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (fst b, a)" and g=snd and I=A,
   166                                             unfolded pair_collapse] assms)
   167         measurable
   168 qed
   169 
   170 lemma measurable_pair_restrict_pmf1:
   171   assumes "countable A"
   172   assumes [measurable]: "\<And>x. x \<in> A \<Longrightarrow> (\<lambda>y. f (x, y)) \<in> measurable N L"
   173   shows "f \<in> measurable (restrict_space (measure_pmf M) A \<Otimes>\<^sub>M N) L"
   174 proof -
   175   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   176     by (simp add: restrict_count_space)
   177 
   178   show ?thesis
   179     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (a, snd b)" and g=fst and I=A,
   180                                             unfolded pair_collapse] assms)
   181         measurable
   182 qed
   183 
   184 lift_definition pmf :: "'a pmf \<Rightarrow> 'a \<Rightarrow> real" is "\<lambda>M x. measure M {x}" .
   185 
   186 lift_definition set_pmf :: "'a pmf \<Rightarrow> 'a set" is "\<lambda>M. {x. measure M {x} \<noteq> 0}" .
   187 declare [[coercion set_pmf]]
   188 
   189 lemma AE_measure_pmf: "AE x in (M::'a pmf). x \<in> M"
   190   by transfer simp
   191 
   192 lemma emeasure_pmf_single_eq_zero_iff:
   193   fixes M :: "'a pmf"
   194   shows "emeasure M {y} = 0 \<longleftrightarrow> y \<notin> M"
   195   by transfer (simp add: finite_measure.emeasure_eq_measure[OF prob_space.finite_measure])
   196 
   197 lemma AE_measure_pmf_iff: "(AE x in measure_pmf M. P x) \<longleftrightarrow> (\<forall>y\<in>M. P y)"
   198   using AE_measure_singleton[of M] AE_measure_pmf[of M]
   199   by (auto simp: set_pmf.rep_eq)
   200 
   201 lemma countable_set_pmf [simp]: "countable (set_pmf p)"
   202   by transfer (metis prob_space.finite_measure finite_measure.countable_support)
   203 
   204 lemma pmf_positive: "x \<in> set_pmf p \<Longrightarrow> 0 < pmf p x"
   205   by transfer (simp add: less_le measure_nonneg)
   206 
   207 lemma pmf_nonneg: "0 \<le> pmf p x"
   208   by transfer (simp add: measure_nonneg)
   209 
   210 lemma pmf_le_1: "pmf p x \<le> 1"
   211   by (simp add: pmf.rep_eq)
   212 
   213 lemma set_pmf_not_empty: "set_pmf M \<noteq> {}"
   214   using AE_measure_pmf[of M] by (intro notI) simp
   215 
   216 lemma set_pmf_iff: "x \<in> set_pmf M \<longleftrightarrow> pmf M x \<noteq> 0"
   217   by transfer simp
   218 
   219 lemma set_pmf_eq: "set_pmf M = {x. pmf M x \<noteq> 0}"
   220   by (auto simp: set_pmf_iff)
   221 
   222 lemma emeasure_pmf_single:
   223   fixes M :: "'a pmf"
   224   shows "emeasure M {x} = pmf M x"
   225   by transfer (simp add: finite_measure.emeasure_eq_measure[OF prob_space.finite_measure])
   226 
   227 lemma measure_pmf_single: "measure (measure_pmf M) {x} = pmf M x"
   228 using emeasure_pmf_single[of M x] by(simp add: measure_pmf.emeasure_eq_measure)
   229 
   230 lemma emeasure_measure_pmf_finite: "finite S \<Longrightarrow> emeasure (measure_pmf M) S = (\<Sum>s\<in>S. pmf M s)"
   231   by (subst emeasure_eq_setsum_singleton) (auto simp: emeasure_pmf_single)
   232 
   233 lemma measure_measure_pmf_finite: "finite S \<Longrightarrow> measure (measure_pmf M) S = setsum (pmf M) S"
   234   using emeasure_measure_pmf_finite[of S M] by(simp add: measure_pmf.emeasure_eq_measure)
   235 
   236 lemma nn_integral_measure_pmf_support:
   237   fixes f :: "'a \<Rightarrow> ereal"
   238   assumes f: "finite A" and nn: "\<And>x. x \<in> A \<Longrightarrow> 0 \<le> f x" "\<And>x. x \<in> set_pmf M \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = 0"
   239   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>A. f x * pmf M x)"
   240 proof -
   241   have "(\<integral>\<^sup>+x. f x \<partial>M) = (\<integral>\<^sup>+x. f x * indicator A x \<partial>M)"
   242     using nn by (intro nn_integral_cong_AE) (auto simp: AE_measure_pmf_iff split: split_indicator)
   243   also have "\<dots> = (\<Sum>x\<in>A. f x * emeasure M {x})"
   244     using assms by (intro nn_integral_indicator_finite) auto
   245   finally show ?thesis
   246     by (simp add: emeasure_measure_pmf_finite)
   247 qed
   248 
   249 lemma nn_integral_measure_pmf_finite:
   250   fixes f :: "'a \<Rightarrow> ereal"
   251   assumes f: "finite (set_pmf M)" and nn: "\<And>x. x \<in> set_pmf M \<Longrightarrow> 0 \<le> f x"
   252   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>set_pmf M. f x * pmf M x)"
   253   using assms by (intro nn_integral_measure_pmf_support) auto
   254 lemma integrable_measure_pmf_finite:
   255   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
   256   shows "finite (set_pmf M) \<Longrightarrow> integrable M f"
   257   by (auto intro!: integrableI_bounded simp: nn_integral_measure_pmf_finite)
   258 
   259 lemma integral_measure_pmf:
   260   assumes [simp]: "finite A" and "\<And>a. a \<in> set_pmf M \<Longrightarrow> f a \<noteq> 0 \<Longrightarrow> a \<in> A"
   261   shows "(\<integral>x. f x \<partial>measure_pmf M) = (\<Sum>a\<in>A. f a * pmf M a)"
   262 proof -
   263   have "(\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x * indicator A x \<partial>measure_pmf M)"
   264     using assms(2) by (intro integral_cong_AE) (auto split: split_indicator simp: AE_measure_pmf_iff)
   265   also have "\<dots> = (\<Sum>a\<in>A. f a * pmf M a)"
   266     by (subst integral_indicator_finite_real) (auto simp: measure_def emeasure_measure_pmf_finite)
   267   finally show ?thesis .
   268 qed
   269 
   270 lemma integrable_pmf: "integrable (count_space X) (pmf M)"
   271 proof -
   272   have " (\<integral>\<^sup>+ x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+ x. pmf M x \<partial>count_space (M \<inter> X))"
   273     by (auto simp add: nn_integral_count_space_indicator set_pmf_iff intro!: nn_integral_cong split: split_indicator)
   274   then have "integrable (count_space X) (pmf M) = integrable (count_space (M \<inter> X)) (pmf M)"
   275     by (simp add: integrable_iff_bounded pmf_nonneg)
   276   then show ?thesis
   277     by (simp add: pmf.rep_eq measure_pmf.integrable_measure disjoint_family_on_def)
   278 qed
   279 
   280 lemma integral_pmf: "(\<integral>x. pmf M x \<partial>count_space X) = measure M X"
   281 proof -
   282   have "(\<integral>x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+x. pmf M x \<partial>count_space X)"
   283     by (simp add: pmf_nonneg integrable_pmf nn_integral_eq_integral)
   284   also have "\<dots> = (\<integral>\<^sup>+x. emeasure M {x} \<partial>count_space (X \<inter> M))"
   285     by (auto intro!: nn_integral_cong_AE split: split_indicator
   286              simp: pmf.rep_eq measure_pmf.emeasure_eq_measure nn_integral_count_space_indicator
   287                    AE_count_space set_pmf_iff)
   288   also have "\<dots> = emeasure M (X \<inter> M)"
   289     by (rule emeasure_countable_singleton[symmetric]) (auto intro: countable_set_pmf)
   290   also have "\<dots> = emeasure M X"
   291     by (auto intro!: emeasure_eq_AE simp: AE_measure_pmf_iff)
   292   finally show ?thesis
   293     by (simp add: measure_pmf.emeasure_eq_measure)
   294 qed
   295 
   296 lemma integral_pmf_restrict:
   297   "(f::'a \<Rightarrow> 'b::{banach, second_countable_topology}) \<in> borel_measurable (count_space UNIV) \<Longrightarrow>
   298     (\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x \<partial>restrict_space M M)"
   299   by (auto intro!: integral_cong_AE simp add: integral_restrict_space AE_measure_pmf_iff)
   300 
   301 lemma emeasure_pmf: "emeasure (M::'a pmf) M = 1"
   302 proof -
   303   have "emeasure (M::'a pmf) M = emeasure (M::'a pmf) (space M)"
   304     by (intro emeasure_eq_AE) (simp_all add: AE_measure_pmf)
   305   then show ?thesis
   306     using measure_pmf.emeasure_space_1 by simp
   307 qed
   308 
   309 lemma emeasure_pmf_UNIV [simp]: "emeasure (measure_pmf M) UNIV = 1"
   310 using measure_pmf.emeasure_space_1[of M] by simp
   311 
   312 lemma in_null_sets_measure_pmfI:
   313   "A \<inter> set_pmf p = {} \<Longrightarrow> A \<in> null_sets (measure_pmf p)"
   314 using emeasure_eq_0_AE[where ?P="\<lambda>x. x \<in> A" and M="measure_pmf p"]
   315 by(auto simp add: null_sets_def AE_measure_pmf_iff)
   316 
   317 lemma measure_subprob: "measure_pmf M \<in> space (subprob_algebra (count_space UNIV))"
   318   by (simp add: space_subprob_algebra subprob_space_measure_pmf)
   319 
   320 subsection \<open> Monad Interpretation \<close>
   321 
   322 lemma measurable_measure_pmf[measurable]:
   323   "(\<lambda>x. measure_pmf (M x)) \<in> measurable (count_space UNIV) (subprob_algebra (count_space UNIV))"
   324   by (auto simp: space_subprob_algebra intro!: prob_space_imp_subprob_space) unfold_locales
   325 
   326 lemma bind_measure_pmf_cong:
   327   assumes "\<And>x. A x \<in> space (subprob_algebra N)" "\<And>x. B x \<in> space (subprob_algebra N)"
   328   assumes "\<And>i. i \<in> set_pmf x \<Longrightarrow> A i = B i"
   329   shows "bind (measure_pmf x) A = bind (measure_pmf x) B"
   330 proof (rule measure_eqI)
   331   show "sets (measure_pmf x \<guillemotright>= A) = sets (measure_pmf x \<guillemotright>= B)"
   332     using assms by (subst (1 2) sets_bind) (auto simp: space_subprob_algebra)
   333 next
   334   fix X assume "X \<in> sets (measure_pmf x \<guillemotright>= A)"
   335   then have X: "X \<in> sets N"
   336     using assms by (subst (asm) sets_bind) (auto simp: space_subprob_algebra)
   337   show "emeasure (measure_pmf x \<guillemotright>= A) X = emeasure (measure_pmf x \<guillemotright>= B) X"
   338     using assms
   339     by (subst (1 2) emeasure_bind[where N=N, OF _ _ X])
   340        (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   341 qed
   342 
   343 lift_definition bind_pmf :: "'a pmf \<Rightarrow> ('a \<Rightarrow> 'b pmf ) \<Rightarrow> 'b pmf" is bind
   344 proof (clarify, intro conjI)
   345   fix f :: "'a measure" and g :: "'a \<Rightarrow> 'b measure"
   346   assume "prob_space f"
   347   then interpret f: prob_space f .
   348   assume "sets f = UNIV" and ae_f: "AE x in f. measure f {x} \<noteq> 0"
   349   then have s_f[simp]: "sets f = sets (count_space UNIV)"
   350     by simp
   351   assume g: "\<And>x. prob_space (g x) \<and> sets (g x) = UNIV \<and> (AE y in g x. measure (g x) {y} \<noteq> 0)"
   352   then have g: "\<And>x. prob_space (g x)" and s_g[simp]: "\<And>x. sets (g x) = sets (count_space UNIV)"
   353     and ae_g: "\<And>x. AE y in g x. measure (g x) {y} \<noteq> 0"
   354     by auto
   355 
   356   have [measurable]: "g \<in> measurable f (subprob_algebra (count_space UNIV))"
   357     by (auto simp: measurable_def space_subprob_algebra prob_space_imp_subprob_space g)
   358 
   359   show "prob_space (f \<guillemotright>= g)"
   360     using g by (intro f.prob_space_bind[where S="count_space UNIV"]) auto
   361   then interpret fg: prob_space "f \<guillemotright>= g" .
   362   show [simp]: "sets (f \<guillemotright>= g) = UNIV"
   363     using sets_eq_imp_space_eq[OF s_f]
   364     by (subst sets_bind[where N="count_space UNIV"]) auto
   365   show "AE x in f \<guillemotright>= g. measure (f \<guillemotright>= g) {x} \<noteq> 0"
   366     apply (simp add: fg.prob_eq_0 AE_bind[where B="count_space UNIV"])
   367     using ae_f
   368     apply eventually_elim
   369     using ae_g
   370     apply eventually_elim
   371     apply (auto dest: AE_measure_singleton)
   372     done
   373 qed
   374 
   375 lemma ereal_pmf_bind: "pmf (bind_pmf N f) i = (\<integral>\<^sup>+x. pmf (f x) i \<partial>measure_pmf N)"
   376   unfolding pmf.rep_eq bind_pmf.rep_eq
   377   by (auto simp: measure_pmf.measure_bind[where N="count_space UNIV"] measure_subprob measure_nonneg
   378            intro!: nn_integral_eq_integral[symmetric] measure_pmf.integrable_const_bound[where B=1])
   379 
   380 lemma pmf_bind: "pmf (bind_pmf N f) i = (\<integral>x. pmf (f x) i \<partial>measure_pmf N)"
   381   using ereal_pmf_bind[of N f i]
   382   by (subst (asm) nn_integral_eq_integral)
   383      (auto simp: pmf_nonneg pmf_le_1
   384            intro!: nn_integral_eq_integral[symmetric] measure_pmf.integrable_const_bound[where B=1])
   385 
   386 lemma bind_pmf_const[simp]: "bind_pmf M (\<lambda>x. c) = c"
   387   by transfer (simp add: bind_const' prob_space_imp_subprob_space)
   388 
   389 lemma set_bind_pmf[simp]: "set_pmf (bind_pmf M N) = (\<Union>M\<in>set_pmf M. set_pmf (N M))"
   390   unfolding set_pmf_eq ereal_eq_0(1)[symmetric] ereal_pmf_bind
   391   by (auto simp add: nn_integral_0_iff_AE AE_measure_pmf_iff set_pmf_eq not_le less_le pmf_nonneg)
   392 
   393 lemma bind_pmf_cong:
   394   assumes "p = q"
   395   shows "(\<And>x. x \<in> set_pmf q \<Longrightarrow> f x = g x) \<Longrightarrow> bind_pmf p f = bind_pmf q g"
   396   unfolding `p = q`[symmetric] measure_pmf_inject[symmetric] bind_pmf.rep_eq
   397   by (auto simp: AE_measure_pmf_iff Pi_iff space_subprob_algebra subprob_space_measure_pmf
   398                  sets_bind[where N="count_space UNIV"] emeasure_bind[where N="count_space UNIV"]
   399            intro!: nn_integral_cong_AE measure_eqI)
   400 
   401 lemma bind_pmf_cong_simp:
   402   "p = q \<Longrightarrow> (\<And>x. x \<in> set_pmf q =simp=> f x = g x) \<Longrightarrow> bind_pmf p f = bind_pmf q g"
   403   by (simp add: simp_implies_def cong: bind_pmf_cong)
   404 
   405 lemma measure_pmf_bind: "measure_pmf (bind_pmf M f) = (measure_pmf M \<guillemotright>= (\<lambda>x. measure_pmf (f x)))"
   406   by transfer simp
   407 
   408 lemma nn_integral_bind_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>bind_pmf M N) = (\<integral>\<^sup>+x. \<integral>\<^sup>+y. f y \<partial>N x \<partial>M)"
   409   using measurable_measure_pmf[of N]
   410   unfolding measure_pmf_bind
   411   apply (subst (1 3) nn_integral_max_0[symmetric])
   412   apply (intro nn_integral_bind[where B="count_space UNIV"])
   413   apply auto
   414   done
   415 
   416 lemma emeasure_bind_pmf[simp]: "emeasure (bind_pmf M N) X = (\<integral>\<^sup>+x. emeasure (N x) X \<partial>M)"
   417   using measurable_measure_pmf[of N]
   418   unfolding measure_pmf_bind
   419   by (subst emeasure_bind[where N="count_space UNIV"]) auto
   420 
   421 lift_definition return_pmf :: "'a \<Rightarrow> 'a pmf" is "return (count_space UNIV)"
   422   by (auto intro!: prob_space_return simp: AE_return measure_return)
   423 
   424 lemma bind_return_pmf: "bind_pmf (return_pmf x) f = f x"
   425   by transfer
   426      (auto intro!: prob_space_imp_subprob_space bind_return[where N="count_space UNIV"]
   427            simp: space_subprob_algebra)
   428 
   429 lemma set_return_pmf[simp]: "set_pmf (return_pmf x) = {x}"
   430   by transfer (auto simp add: measure_return split: split_indicator)
   431 
   432 lemma bind_return_pmf': "bind_pmf N return_pmf = N"
   433 proof (transfer, clarify)
   434   fix N :: "'a measure" assume "sets N = UNIV" then show "N \<guillemotright>= return (count_space UNIV) = N"
   435     by (subst return_sets_cong[where N=N]) (simp_all add: bind_return')
   436 qed
   437 
   438 lemma bind_assoc_pmf: "bind_pmf (bind_pmf A B) C = bind_pmf A (\<lambda>x. bind_pmf (B x) C)"
   439   by transfer
   440      (auto intro!: bind_assoc[where N="count_space UNIV" and R="count_space UNIV"]
   441            simp: measurable_def space_subprob_algebra prob_space_imp_subprob_space)
   442 
   443 definition "map_pmf f M = bind_pmf M (\<lambda>x. return_pmf (f x))"
   444 
   445 lemma map_bind_pmf: "map_pmf f (bind_pmf M g) = bind_pmf M (\<lambda>x. map_pmf f (g x))"
   446   by (simp add: map_pmf_def bind_assoc_pmf)
   447 
   448 lemma bind_map_pmf: "bind_pmf (map_pmf f M) g = bind_pmf M (\<lambda>x. g (f x))"
   449   by (simp add: map_pmf_def bind_assoc_pmf bind_return_pmf)
   450 
   451 lemma map_pmf_transfer[transfer_rule]:
   452   "rel_fun op = (rel_fun cr_pmf cr_pmf) (\<lambda>f M. distr M (count_space UNIV) f) map_pmf"
   453 proof -
   454   have "rel_fun op = (rel_fun pmf_as_measure.cr_pmf pmf_as_measure.cr_pmf)
   455      (\<lambda>f M. M \<guillemotright>= (return (count_space UNIV) o f)) map_pmf"
   456     unfolding map_pmf_def[abs_def] comp_def by transfer_prover
   457   then show ?thesis
   458     by (force simp: rel_fun_def cr_pmf_def bind_return_distr)
   459 qed
   460 
   461 lemma map_pmf_rep_eq:
   462   "measure_pmf (map_pmf f M) = distr (measure_pmf M) (count_space UNIV) f"
   463   unfolding map_pmf_def bind_pmf.rep_eq comp_def return_pmf.rep_eq
   464   using bind_return_distr[of M f "count_space UNIV"] by (simp add: comp_def)
   465 
   466 lemma map_pmf_id[simp]: "map_pmf id = id"
   467   by (rule, transfer) (auto simp: emeasure_distr measurable_def intro!: measure_eqI)
   468 
   469 lemma map_pmf_ident[simp]: "map_pmf (\<lambda>x. x) = (\<lambda>x. x)"
   470   using map_pmf_id unfolding id_def .
   471 
   472 lemma map_pmf_compose: "map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g"
   473   by (rule, transfer) (simp add: distr_distr[symmetric, where N="count_space UNIV"] measurable_def)
   474 
   475 lemma map_pmf_comp: "map_pmf f (map_pmf g M) = map_pmf (\<lambda>x. f (g x)) M"
   476   using map_pmf_compose[of f g] by (simp add: comp_def)
   477 
   478 lemma map_pmf_cong: "p = q \<Longrightarrow> (\<And>x. x \<in> set_pmf q \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g q"
   479   unfolding map_pmf_def by (rule bind_pmf_cong) auto
   480 
   481 lemma pmf_set_map: "set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
   482   by (auto simp add: comp_def fun_eq_iff map_pmf_def)
   483 
   484 lemma set_map_pmf[simp]: "set_pmf (map_pmf f M) = f`set_pmf M"
   485   using pmf_set_map[of f] by (auto simp: comp_def fun_eq_iff)
   486 
   487 lemma emeasure_map_pmf[simp]: "emeasure (map_pmf f M) X = emeasure M (f -` X)"
   488   unfolding map_pmf_rep_eq by (subst emeasure_distr) auto
   489 
   490 lemma nn_integral_map_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>map_pmf g M) = (\<integral>\<^sup>+x. f (g x) \<partial>M)"
   491   unfolding map_pmf_rep_eq by (intro nn_integral_distr) auto
   492 
   493 lemma ereal_pmf_map: "pmf (map_pmf f p) x = (\<integral>\<^sup>+ y. indicator (f -` {x}) y \<partial>measure_pmf p)"
   494 proof (transfer fixing: f x)
   495   fix p :: "'b measure"
   496   presume "prob_space p"
   497   then interpret prob_space p .
   498   presume "sets p = UNIV"
   499   then show "ereal (measure (distr p (count_space UNIV) f) {x}) = integral\<^sup>N p (indicator (f -` {x}))"
   500     by(simp add: measure_distr measurable_def emeasure_eq_measure)
   501 qed simp_all
   502 
   503 lemma nn_integral_pmf: "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = emeasure (measure_pmf p) A"
   504 proof -
   505   have "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = (\<integral>\<^sup>+ x. pmf p x \<partial>count_space (A \<inter> set_pmf p))"
   506     by(auto simp add: nn_integral_count_space_indicator indicator_def set_pmf_iff intro: nn_integral_cong)
   507   also have "\<dots> = emeasure (measure_pmf p) (\<Union>x\<in>A \<inter> set_pmf p. {x})"
   508     by(subst emeasure_UN_countable)(auto simp add: emeasure_pmf_single disjoint_family_on_def)
   509   also have "\<dots> = emeasure (measure_pmf p) ((\<Union>x\<in>A \<inter> set_pmf p. {x}) \<union> {x. x \<in> A \<and> x \<notin> set_pmf p})"
   510     by(rule emeasure_Un_null_set[symmetric])(auto intro: in_null_sets_measure_pmfI)
   511   also have "\<dots> = emeasure (measure_pmf p) A"
   512     by(auto intro: arg_cong2[where f=emeasure])
   513   finally show ?thesis .
   514 qed
   515 
   516 lemma map_return_pmf [simp]: "map_pmf f (return_pmf x) = return_pmf (f x)"
   517   by transfer (simp add: distr_return)
   518 
   519 lemma map_pmf_const[simp]: "map_pmf (\<lambda>_. c) M = return_pmf c"
   520   by transfer (auto simp: prob_space.distr_const)
   521 
   522 lemma pmf_return [simp]: "pmf (return_pmf x) y = indicator {y} x"
   523   by transfer (simp add: measure_return)
   524 
   525 lemma nn_integral_return_pmf[simp]: "0 \<le> f x \<Longrightarrow> (\<integral>\<^sup>+x. f x \<partial>return_pmf x) = f x"
   526   unfolding return_pmf.rep_eq by (intro nn_integral_return) auto
   527 
   528 lemma emeasure_return_pmf[simp]: "emeasure (return_pmf x) X = indicator X x"
   529   unfolding return_pmf.rep_eq by (intro emeasure_return) auto
   530 
   531 lemma return_pmf_inj[simp]: "return_pmf x = return_pmf y \<longleftrightarrow> x = y"
   532   by (metis insertI1 set_return_pmf singletonD)
   533 
   534 lemma map_pmf_eq_return_pmf_iff:
   535   "map_pmf f p = return_pmf x \<longleftrightarrow> (\<forall>y \<in> set_pmf p. f y = x)"
   536 proof
   537   assume "map_pmf f p = return_pmf x"
   538   then have "set_pmf (map_pmf f p) = set_pmf (return_pmf x)" by simp
   539   then show "\<forall>y \<in> set_pmf p. f y = x" by auto
   540 next
   541   assume "\<forall>y \<in> set_pmf p. f y = x"
   542   then show "map_pmf f p = return_pmf x"
   543     unfolding map_pmf_const[symmetric, of _ p] by (intro map_pmf_cong) auto
   544 qed
   545 
   546 definition "pair_pmf A B = bind_pmf A (\<lambda>x. bind_pmf B (\<lambda>y. return_pmf (x, y)))"
   547 
   548 lemma pmf_pair: "pmf (pair_pmf M N) (a, b) = pmf M a * pmf N b"
   549   unfolding pair_pmf_def pmf_bind pmf_return
   550   apply (subst integral_measure_pmf[where A="{b}"])
   551   apply (auto simp: indicator_eq_0_iff)
   552   apply (subst integral_measure_pmf[where A="{a}"])
   553   apply (auto simp: indicator_eq_0_iff setsum_nonneg_eq_0_iff pmf_nonneg)
   554   done
   555 
   556 lemma set_pair_pmf[simp]: "set_pmf (pair_pmf A B) = set_pmf A \<times> set_pmf B"
   557   unfolding pair_pmf_def set_bind_pmf set_return_pmf by auto
   558 
   559 lemma measure_pmf_in_subprob_space[measurable (raw)]:
   560   "measure_pmf M \<in> space (subprob_algebra (count_space UNIV))"
   561   by (simp add: space_subprob_algebra) intro_locales
   562 
   563 lemma nn_integral_pair_pmf': "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. f (a, b) \<partial>B \<partial>A)"
   564 proof -
   565   have "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+x. max 0 (f x) * indicator (A \<times> B) x \<partial>pair_pmf A B)"
   566     by (subst nn_integral_max_0[symmetric])
   567        (auto simp: AE_measure_pmf_iff intro!: nn_integral_cong_AE)
   568   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. max 0 (f (a, b)) * indicator (A \<times> B) (a, b) \<partial>B \<partial>A)"
   569     by (simp add: pair_pmf_def)
   570   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. max 0 (f (a, b)) \<partial>B \<partial>A)"
   571     by (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   572   finally show ?thesis
   573     unfolding nn_integral_max_0 .
   574 qed
   575 
   576 lemma bind_pair_pmf:
   577   assumes M[measurable]: "M \<in> measurable (count_space UNIV \<Otimes>\<^sub>M count_space UNIV) (subprob_algebra N)"
   578   shows "measure_pmf (pair_pmf A B) \<guillemotright>= M = (measure_pmf A \<guillemotright>= (\<lambda>x. measure_pmf B \<guillemotright>= (\<lambda>y. M (x, y))))"
   579     (is "?L = ?R")
   580 proof (rule measure_eqI)
   581   have M'[measurable]: "M \<in> measurable (pair_pmf A B) (subprob_algebra N)"
   582     using M[THEN measurable_space] by (simp_all add: space_pair_measure)
   583 
   584   note measurable_bind[where N="count_space UNIV", measurable]
   585   note measure_pmf_in_subprob_space[simp]
   586 
   587   have sets_eq_N: "sets ?L = N"
   588     by (subst sets_bind[OF sets_kernel[OF M']]) auto
   589   show "sets ?L = sets ?R"
   590     using measurable_space[OF M]
   591     by (simp add: sets_eq_N space_pair_measure space_subprob_algebra)
   592   fix X assume "X \<in> sets ?L"
   593   then have X[measurable]: "X \<in> sets N"
   594     unfolding sets_eq_N .
   595   then show "emeasure ?L X = emeasure ?R X"
   596     apply (simp add: emeasure_bind[OF _ M' X])
   597     apply (simp add: nn_integral_bind[where B="count_space UNIV"] pair_pmf_def measure_pmf_bind[of A]
   598                      nn_integral_measure_pmf_finite emeasure_nonneg one_ereal_def[symmetric])
   599     apply (subst emeasure_bind[OF _ _ X])
   600     apply measurable
   601     apply (subst emeasure_bind[OF _ _ X])
   602     apply measurable
   603     done
   604 qed
   605 
   606 lemma map_fst_pair_pmf: "map_pmf fst (pair_pmf A B) = A"
   607   by (simp add: pair_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
   608 
   609 lemma map_snd_pair_pmf: "map_pmf snd (pair_pmf A B) = B"
   610   by (simp add: pair_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
   611 
   612 lemma nn_integral_pmf':
   613   "inj_on f A \<Longrightarrow> (\<integral>\<^sup>+x. pmf p (f x) \<partial>count_space A) = emeasure p (f ` A)"
   614   by (subst nn_integral_bij_count_space[where g=f and B="f`A"])
   615      (auto simp: bij_betw_def nn_integral_pmf)
   616 
   617 lemma pmf_le_0_iff[simp]: "pmf M p \<le> 0 \<longleftrightarrow> pmf M p = 0"
   618   using pmf_nonneg[of M p] by simp
   619 
   620 lemma min_pmf_0[simp]: "min (pmf M p) 0 = 0" "min 0 (pmf M p) = 0"
   621   using pmf_nonneg[of M p] by simp_all
   622 
   623 lemma pmf_eq_0_set_pmf: "pmf M p = 0 \<longleftrightarrow> p \<notin> set_pmf M"
   624   unfolding set_pmf_iff by simp
   625 
   626 lemma pmf_map_inj: "inj_on f (set_pmf M) \<Longrightarrow> x \<in> set_pmf M \<Longrightarrow> pmf (map_pmf f M) (f x) = pmf M x"
   627   by (auto simp: pmf.rep_eq map_pmf_rep_eq measure_distr AE_measure_pmf_iff inj_onD
   628            intro!: measure_pmf.finite_measure_eq_AE)
   629 
   630 lemma pmf_map_inj': "inj f \<Longrightarrow> pmf (map_pmf f M) (f x) = pmf M x"
   631 apply(cases "x \<in> set_pmf M")
   632  apply(simp add: pmf_map_inj[OF subset_inj_on])
   633 apply(simp add: pmf_eq_0_set_pmf[symmetric])
   634 apply(auto simp add: pmf_eq_0_set_pmf dest: injD)
   635 done
   636 
   637 lemma pmf_map_outside: "x \<notin> f ` set_pmf M \<Longrightarrow> pmf (map_pmf f M) x = 0"
   638 unfolding pmf_eq_0_set_pmf by simp
   639 
   640 subsection \<open> PMFs as function \<close>
   641 
   642 context
   643   fixes f :: "'a \<Rightarrow> real"
   644   assumes nonneg: "\<And>x. 0 \<le> f x"
   645   assumes prob: "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   646 begin
   647 
   648 lift_definition embed_pmf :: "'a pmf" is "density (count_space UNIV) (ereal \<circ> f)"
   649 proof (intro conjI)
   650   have *[simp]: "\<And>x y. ereal (f y) * indicator {x} y = ereal (f x) * indicator {x} y"
   651     by (simp split: split_indicator)
   652   show "AE x in density (count_space UNIV) (ereal \<circ> f).
   653     measure (density (count_space UNIV) (ereal \<circ> f)) {x} \<noteq> 0"
   654     by (simp add: AE_density nonneg measure_def emeasure_density max_def)
   655   show "prob_space (density (count_space UNIV) (ereal \<circ> f))"
   656     by default (simp add: emeasure_density prob)
   657 qed simp
   658 
   659 lemma pmf_embed_pmf: "pmf embed_pmf x = f x"
   660 proof transfer
   661   have *[simp]: "\<And>x y. ereal (f y) * indicator {x} y = ereal (f x) * indicator {x} y"
   662     by (simp split: split_indicator)
   663   fix x show "measure (density (count_space UNIV) (ereal \<circ> f)) {x} = f x"
   664     by transfer (simp add: measure_def emeasure_density nonneg max_def)
   665 qed
   666 
   667 lemma set_embed_pmf: "set_pmf embed_pmf = {x. f x \<noteq> 0}"
   668 by(auto simp add: set_pmf_eq assms pmf_embed_pmf)
   669 
   670 end
   671 
   672 lemma embed_pmf_transfer:
   673   "rel_fun (eq_onp (\<lambda>f. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ereal (f x) \<partial>count_space UNIV) = 1)) pmf_as_measure.cr_pmf (\<lambda>f. density (count_space UNIV) (ereal \<circ> f)) embed_pmf"
   674   by (auto simp: rel_fun_def eq_onp_def embed_pmf.transfer)
   675 
   676 lemma measure_pmf_eq_density: "measure_pmf p = density (count_space UNIV) (pmf p)"
   677 proof (transfer, elim conjE)
   678   fix M :: "'a measure" assume [simp]: "sets M = UNIV" and ae: "AE x in M. measure M {x} \<noteq> 0"
   679   assume "prob_space M" then interpret prob_space M .
   680   show "M = density (count_space UNIV) (\<lambda>x. ereal (measure M {x}))"
   681   proof (rule measure_eqI)
   682     fix A :: "'a set"
   683     have "(\<integral>\<^sup>+ x. ereal (measure M {x}) * indicator A x \<partial>count_space UNIV) =
   684       (\<integral>\<^sup>+ x. emeasure M {x} * indicator (A \<inter> {x. measure M {x} \<noteq> 0}) x \<partial>count_space UNIV)"
   685       by (auto intro!: nn_integral_cong simp: emeasure_eq_measure split: split_indicator)
   686     also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} \<partial>count_space (A \<inter> {x. measure M {x} \<noteq> 0}))"
   687       by (subst nn_integral_restrict_space[symmetric]) (auto simp: restrict_count_space)
   688     also have "\<dots> = emeasure M (\<Union>x\<in>(A \<inter> {x. measure M {x} \<noteq> 0}). {x})"
   689       by (intro emeasure_UN_countable[symmetric] countable_Int2 countable_support)
   690          (auto simp: disjoint_family_on_def)
   691     also have "\<dots> = emeasure M A"
   692       using ae by (intro emeasure_eq_AE) auto
   693     finally show " emeasure M A = emeasure (density (count_space UNIV) (\<lambda>x. ereal (measure M {x}))) A"
   694       using emeasure_space_1 by (simp add: emeasure_density)
   695   qed simp
   696 qed
   697 
   698 lemma td_pmf_embed_pmf:
   699   "type_definition pmf embed_pmf {f::'a \<Rightarrow> real. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ereal (f x) \<partial>count_space UNIV) = 1}"
   700   unfolding type_definition_def
   701 proof safe
   702   fix p :: "'a pmf"
   703   have "(\<integral>\<^sup>+ x. 1 \<partial>measure_pmf p) = 1"
   704     using measure_pmf.emeasure_space_1[of p] by simp
   705   then show *: "(\<integral>\<^sup>+ x. ereal (pmf p x) \<partial>count_space UNIV) = 1"
   706     by (simp add: measure_pmf_eq_density nn_integral_density pmf_nonneg del: nn_integral_const)
   707 
   708   show "embed_pmf (pmf p) = p"
   709     by (intro measure_pmf_inject[THEN iffD1])
   710        (simp add: * embed_pmf.rep_eq pmf_nonneg measure_pmf_eq_density[of p] comp_def)
   711 next
   712   fix f :: "'a \<Rightarrow> real" assume "\<forall>x. 0 \<le> f x" "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   713   then show "pmf (embed_pmf f) = f"
   714     by (auto intro!: pmf_embed_pmf)
   715 qed (rule pmf_nonneg)
   716 
   717 end
   718 
   719 lemma nn_integral_measure_pmf: "(\<integral>\<^sup>+ x. f x \<partial>measure_pmf p) = \<integral>\<^sup>+ x. ereal (pmf p x) * f x \<partial>count_space UNIV"
   720 by(simp add: measure_pmf_eq_density nn_integral_density pmf_nonneg)
   721 
   722 locale pmf_as_function
   723 begin
   724 
   725 setup_lifting td_pmf_embed_pmf
   726 
   727 lemma set_pmf_transfer[transfer_rule]:
   728   assumes "bi_total A"
   729   shows "rel_fun (pcr_pmf A) (rel_set A) (\<lambda>f. {x. f x \<noteq> 0}) set_pmf"
   730   using `bi_total A`
   731   by (auto simp: pcr_pmf_def cr_pmf_def rel_fun_def rel_set_def bi_total_def Bex_def set_pmf_iff)
   732      metis+
   733 
   734 end
   735 
   736 context
   737 begin
   738 
   739 interpretation pmf_as_function .
   740 
   741 lemma pmf_eqI: "(\<And>i. pmf M i = pmf N i) \<Longrightarrow> M = N"
   742   by transfer auto
   743 
   744 lemma pmf_eq_iff: "M = N \<longleftrightarrow> (\<forall>i. pmf M i = pmf N i)"
   745   by (auto intro: pmf_eqI)
   746 
   747 lemma bind_commute_pmf: "bind_pmf A (\<lambda>x. bind_pmf B (C x)) = bind_pmf B (\<lambda>y. bind_pmf A (\<lambda>x. C x y))"
   748   unfolding pmf_eq_iff pmf_bind
   749 proof
   750   fix i
   751   interpret B: prob_space "restrict_space B B"
   752     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   753        (auto simp: AE_measure_pmf_iff)
   754   interpret A: prob_space "restrict_space A A"
   755     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   756        (auto simp: AE_measure_pmf_iff)
   757 
   758   interpret AB: pair_prob_space "restrict_space A A" "restrict_space B B"
   759     by unfold_locales
   760 
   761   have "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>A)"
   762     by (rule integral_cong) (auto intro!: integral_pmf_restrict)
   763   also have "\<dots> = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>restrict_space A A)"
   764     by (intro integral_pmf_restrict B.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   765               countable_set_pmf borel_measurable_count_space)
   766   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>restrict_space B B)"
   767     by (rule AB.Fubini_integral[symmetric])
   768        (auto intro!: AB.integrable_const_bound[where B=1] measurable_pair_restrict_pmf2
   769              simp: pmf_nonneg pmf_le_1 measurable_restrict_space1)
   770   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>B)"
   771     by (intro integral_pmf_restrict[symmetric] A.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   772               countable_set_pmf borel_measurable_count_space)
   773   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)"
   774     by (rule integral_cong) (auto intro!: integral_pmf_restrict[symmetric])
   775   finally show "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)" .
   776 qed
   777 
   778 lemma pair_map_pmf1: "pair_pmf (map_pmf f A) B = map_pmf (apfst f) (pair_pmf A B)"
   779 proof (safe intro!: pmf_eqI)
   780   fix a :: "'a" and b :: "'b"
   781   have [simp]: "\<And>c d. indicator (apfst f -` {(a, b)}) (c, d) = indicator (f -` {a}) c * (indicator {b} d::ereal)"
   782     by (auto split: split_indicator)
   783 
   784   have "ereal (pmf (pair_pmf (map_pmf f A) B) (a, b)) =
   785          ereal (pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b))"
   786     unfolding pmf_pair ereal_pmf_map
   787     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_multc pmf_nonneg
   788                   emeasure_map_pmf[symmetric] del: emeasure_map_pmf)
   789   then show "pmf (pair_pmf (map_pmf f A) B) (a, b) = pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b)"
   790     by simp
   791 qed
   792 
   793 lemma pair_map_pmf2: "pair_pmf A (map_pmf f B) = map_pmf (apsnd f) (pair_pmf A B)"
   794 proof (safe intro!: pmf_eqI)
   795   fix a :: "'a" and b :: "'b"
   796   have [simp]: "\<And>c d. indicator (apsnd f -` {(a, b)}) (c, d) = indicator {a} c * (indicator (f -` {b}) d::ereal)"
   797     by (auto split: split_indicator)
   798 
   799   have "ereal (pmf (pair_pmf A (map_pmf f B)) (a, b)) =
   800          ereal (pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b))"
   801     unfolding pmf_pair ereal_pmf_map
   802     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_cmult nn_integral_multc pmf_nonneg
   803                   emeasure_map_pmf[symmetric] del: emeasure_map_pmf)
   804   then show "pmf (pair_pmf A (map_pmf f B)) (a, b) = pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b)"
   805     by simp
   806 qed
   807 
   808 lemma map_pair: "map_pmf (\<lambda>(a, b). (f a, g b)) (pair_pmf A B) = pair_pmf (map_pmf f A) (map_pmf g B)"
   809   by (simp add: pair_map_pmf2 pair_map_pmf1 map_pmf_comp split_beta')
   810 
   811 end
   812 
   813 subsection \<open> Conditional Probabilities \<close>
   814 
   815 lemma measure_pmf_zero_iff: "measure (measure_pmf p) s = 0 \<longleftrightarrow> set_pmf p \<inter> s = {}"
   816   by (subst measure_pmf.prob_eq_0) (auto simp: AE_measure_pmf_iff)
   817 
   818 context
   819   fixes p :: "'a pmf" and s :: "'a set"
   820   assumes not_empty: "set_pmf p \<inter> s \<noteq> {}"
   821 begin
   822 
   823 interpretation pmf_as_measure .
   824 
   825 lemma emeasure_measure_pmf_not_zero: "emeasure (measure_pmf p) s \<noteq> 0"
   826 proof
   827   assume "emeasure (measure_pmf p) s = 0"
   828   then have "AE x in measure_pmf p. x \<notin> s"
   829     by (rule AE_I[rotated]) auto
   830   with not_empty show False
   831     by (auto simp: AE_measure_pmf_iff)
   832 qed
   833 
   834 lemma measure_measure_pmf_not_zero: "measure (measure_pmf p) s \<noteq> 0"
   835   using emeasure_measure_pmf_not_zero unfolding measure_pmf.emeasure_eq_measure by simp
   836 
   837 lift_definition cond_pmf :: "'a pmf" is
   838   "uniform_measure (measure_pmf p) s"
   839 proof (intro conjI)
   840   show "prob_space (uniform_measure (measure_pmf p) s)"
   841     by (intro prob_space_uniform_measure) (auto simp: emeasure_measure_pmf_not_zero)
   842   show "AE x in uniform_measure (measure_pmf p) s. measure (uniform_measure (measure_pmf p) s) {x} \<noteq> 0"
   843     by (simp add: emeasure_measure_pmf_not_zero measure_measure_pmf_not_zero AE_uniform_measure
   844                   AE_measure_pmf_iff set_pmf.rep_eq)
   845 qed simp
   846 
   847 lemma pmf_cond: "pmf cond_pmf x = (if x \<in> s then pmf p x / measure p s else 0)"
   848   by transfer (simp add: emeasure_measure_pmf_not_zero pmf.rep_eq)
   849 
   850 lemma set_cond_pmf[simp]: "set_pmf cond_pmf = set_pmf p \<inter> s"
   851   by (auto simp add: set_pmf_iff pmf_cond measure_measure_pmf_not_zero split: split_if_asm)
   852 
   853 end
   854 
   855 lemma cond_map_pmf:
   856   assumes "set_pmf p \<inter> f -` s \<noteq> {}"
   857   shows "cond_pmf (map_pmf f p) s = map_pmf f (cond_pmf p (f -` s))"
   858 proof -
   859   have *: "set_pmf (map_pmf f p) \<inter> s \<noteq> {}"
   860     using assms by auto
   861   { fix x
   862     have "ereal (pmf (map_pmf f (cond_pmf p (f -` s))) x) =
   863       emeasure p (f -` s \<inter> f -` {x}) / emeasure p (f -` s)"
   864       unfolding ereal_pmf_map cond_pmf.rep_eq[OF assms] by (simp add: nn_integral_uniform_measure)
   865     also have "f -` s \<inter> f -` {x} = (if x \<in> s then f -` {x} else {})"
   866       by auto
   867     also have "emeasure p (if x \<in> s then f -` {x} else {}) / emeasure p (f -` s) =
   868       ereal (pmf (cond_pmf (map_pmf f p) s) x)"
   869       using measure_measure_pmf_not_zero[OF *]
   870       by (simp add: pmf_cond[OF *] ereal_divide' ereal_pmf_map measure_pmf.emeasure_eq_measure[symmetric]
   871                del: ereal_divide)
   872     finally have "ereal (pmf (cond_pmf (map_pmf f p) s) x) = ereal (pmf (map_pmf f (cond_pmf p (f -` s))) x)"
   873       by simp }
   874   then show ?thesis
   875     by (intro pmf_eqI) simp
   876 qed
   877 
   878 lemma bind_cond_pmf_cancel:
   879   assumes [simp]: "\<And>x. x \<in> set_pmf p \<Longrightarrow> set_pmf q \<inter> {y. R x y} \<noteq> {}"
   880   assumes [simp]: "\<And>y. y \<in> set_pmf q \<Longrightarrow> set_pmf p \<inter> {x. R x y} \<noteq> {}"
   881   assumes [simp]: "\<And>x y. x \<in> set_pmf p \<Longrightarrow> y \<in> set_pmf q \<Longrightarrow> R x y \<Longrightarrow> measure q {y. R x y} = measure p {x. R x y}"
   882   shows "bind_pmf p (\<lambda>x. cond_pmf q {y. R x y}) = q"
   883 proof (rule pmf_eqI)
   884   fix i
   885   have "ereal (pmf (bind_pmf p (\<lambda>x. cond_pmf q {y. R x y})) i) =
   886     (\<integral>\<^sup>+x. ereal (pmf q i / measure p {x. R x i}) * ereal (indicator {x. R x i} x) \<partial>p)"
   887     by (auto simp add: ereal_pmf_bind AE_measure_pmf_iff pmf_cond pmf_eq_0_set_pmf intro!: nn_integral_cong_AE)
   888   also have "\<dots> = (pmf q i * measure p {x. R x i}) / measure p {x. R x i}"
   889     by (simp add: pmf_nonneg measure_nonneg zero_ereal_def[symmetric] ereal_indicator
   890                   nn_integral_cmult measure_pmf.emeasure_eq_measure)
   891   also have "\<dots> = pmf q i"
   892     by (cases "pmf q i = 0") (simp_all add: pmf_eq_0_set_pmf measure_measure_pmf_not_zero)
   893   finally show "pmf (bind_pmf p (\<lambda>x. cond_pmf q {y. R x y})) i = pmf q i"
   894     by simp
   895 qed
   896 
   897 subsection \<open> Relator \<close>
   898 
   899 inductive rel_pmf :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a pmf \<Rightarrow> 'b pmf \<Rightarrow> bool"
   900 for R p q
   901 where
   902   "\<lbrakk> \<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y;
   903      map_pmf fst pq = p; map_pmf snd pq = q \<rbrakk>
   904   \<Longrightarrow> rel_pmf R p q"
   905 
   906 lemma rel_pmfI:
   907   assumes R: "rel_set R (set_pmf p) (set_pmf q)"
   908   assumes eq: "\<And>x y. x \<in> set_pmf p \<Longrightarrow> y \<in> set_pmf q \<Longrightarrow> R x y \<Longrightarrow>
   909     measure p {x. R x y} = measure q {y. R x y}"
   910   shows "rel_pmf R p q"
   911 proof
   912   let ?pq = "bind_pmf p (\<lambda>x. bind_pmf (cond_pmf q {y. R x y}) (\<lambda>y. return_pmf (x, y)))"
   913   have "\<And>x. x \<in> set_pmf p \<Longrightarrow> set_pmf q \<inter> {y. R x y} \<noteq> {}"
   914     using R by (auto simp: rel_set_def)
   915   then show "\<And>x y. (x, y) \<in> set_pmf ?pq \<Longrightarrow> R x y"
   916     by auto
   917   show "map_pmf fst ?pq = p"
   918     by (simp add: map_bind_pmf bind_return_pmf')
   919 
   920   show "map_pmf snd ?pq = q"
   921     using R eq
   922     apply (simp add: bind_cond_pmf_cancel map_bind_pmf bind_return_pmf')
   923     apply (rule bind_cond_pmf_cancel)
   924     apply (auto simp: rel_set_def)
   925     done
   926 qed
   927 
   928 lemma rel_pmf_imp_rel_set: "rel_pmf R p q \<Longrightarrow> rel_set R (set_pmf p) (set_pmf q)"
   929   by (force simp add: rel_pmf.simps rel_set_def)
   930 
   931 lemma rel_pmfD_measure:
   932   assumes rel_R: "rel_pmf R p q" and R: "\<And>a b. R a b \<Longrightarrow> R a y \<longleftrightarrow> R x b"
   933   assumes "x \<in> set_pmf p" "y \<in> set_pmf q"
   934   shows "measure p {x. R x y} = measure q {y. R x y}"
   935 proof -
   936   from rel_R obtain pq where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
   937     and eq: "p = map_pmf fst pq" "q = map_pmf snd pq"
   938     by (auto elim: rel_pmf.cases)
   939   have "measure p {x. R x y} = measure pq {x. R (fst x) y}"
   940     by (simp add: eq map_pmf_rep_eq measure_distr)
   941   also have "\<dots> = measure pq {y. R x (snd y)}"
   942     by (intro measure_pmf.finite_measure_eq_AE)
   943        (auto simp: AE_measure_pmf_iff R dest!: pq)
   944   also have "\<dots> = measure q {y. R x y}"
   945     by (simp add: eq map_pmf_rep_eq measure_distr)
   946   finally show "measure p {x. R x y} = measure q {y. R x y}" .
   947 qed
   948 
   949 lemma rel_pmf_iff_measure:
   950   assumes "symp R" "transp R"
   951   shows "rel_pmf R p q \<longleftrightarrow>
   952     rel_set R (set_pmf p) (set_pmf q) \<and>
   953     (\<forall>x\<in>set_pmf p. \<forall>y\<in>set_pmf q. R x y \<longrightarrow> measure p {x. R x y} = measure q {y. R x y})"
   954   by (safe intro!: rel_pmf_imp_rel_set rel_pmfI)
   955      (auto intro!: rel_pmfD_measure dest: sympD[OF \<open>symp R\<close>] transpD[OF \<open>transp R\<close>])
   956 
   957 lemma quotient_rel_set_disjoint:
   958   "equivp R \<Longrightarrow> C \<in> UNIV // {(x, y). R x y} \<Longrightarrow> rel_set R A B \<Longrightarrow> A \<inter> C = {} \<longleftrightarrow> B \<inter> C = {}"
   959   using in_quotient_imp_closed[of UNIV "{(x, y). R x y}" C] 
   960   by (auto 0 0 simp: equivp_equiv rel_set_def set_eq_iff elim: equivpE)
   961      (blast dest: equivp_symp)+
   962 
   963 lemma quotientD: "equiv X R \<Longrightarrow> A \<in> X // R \<Longrightarrow> x \<in> A \<Longrightarrow> A = R `` {x}"
   964   by (metis Image_singleton_iff equiv_class_eq_iff quotientE)
   965 
   966 lemma rel_pmf_iff_equivp:
   967   assumes "equivp R"
   968   shows "rel_pmf R p q \<longleftrightarrow> (\<forall>C\<in>UNIV // {(x, y). R x y}. measure p C = measure q C)"
   969     (is "_ \<longleftrightarrow>   (\<forall>C\<in>_//?R. _)")
   970 proof (subst rel_pmf_iff_measure, safe)
   971   show "symp R" "transp R"
   972     using assms by (auto simp: equivp_reflp_symp_transp)
   973 next
   974   fix C assume C: "C \<in> UNIV // ?R" and R: "rel_set R (set_pmf p) (set_pmf q)"
   975   assume eq: "\<forall>x\<in>set_pmf p. \<forall>y\<in>set_pmf q. R x y \<longrightarrow> measure p {x. R x y} = measure q {y. R x y}"
   976   
   977   show "measure p C = measure q C"
   978   proof cases
   979     assume "p \<inter> C = {}"
   980     moreover then have "q \<inter> C = {}"  
   981       using quotient_rel_set_disjoint[OF assms C R] by simp
   982     ultimately show ?thesis
   983       unfolding measure_pmf_zero_iff[symmetric] by simp
   984   next
   985     assume "p \<inter> C \<noteq> {}"
   986     moreover then have "q \<inter> C \<noteq> {}"  
   987       using quotient_rel_set_disjoint[OF assms C R] by simp
   988     ultimately obtain x y where in_set: "x \<in> set_pmf p" "y \<in> set_pmf q" and in_C: "x \<in> C" "y \<in> C"
   989       by auto
   990     then have "R x y"
   991       using in_quotient_imp_in_rel[of UNIV ?R C x y] C assms
   992       by (simp add: equivp_equiv)
   993     with in_set eq have "measure p {x. R x y} = measure q {y. R x y}"
   994       by auto
   995     moreover have "{y. R x y} = C"
   996       using assms `x \<in> C` C quotientD[of UNIV ?R C x] by (simp add: equivp_equiv)
   997     moreover have "{x. R x y} = C"
   998       using assms `y \<in> C` C quotientD[of UNIV "?R" C y] sympD[of R]
   999       by (auto simp add: equivp_equiv elim: equivpE)
  1000     ultimately show ?thesis
  1001       by auto
  1002   qed
  1003 next
  1004   assume eq: "\<forall>C\<in>UNIV // ?R. measure p C = measure q C"
  1005   show "rel_set R (set_pmf p) (set_pmf q)"
  1006     unfolding rel_set_def
  1007   proof safe
  1008     fix x assume x: "x \<in> set_pmf p"
  1009     have "{y. R x y} \<in> UNIV // ?R"
  1010       by (auto simp: quotient_def)
  1011     with eq have *: "measure q {y. R x y} = measure p {y. R x y}"
  1012       by auto
  1013     have "measure q {y. R x y} \<noteq> 0"
  1014       using x assms unfolding * by (auto simp: measure_pmf_zero_iff set_eq_iff dest: equivp_reflp)
  1015     then show "\<exists>y\<in>set_pmf q. R x y"
  1016       unfolding measure_pmf_zero_iff by auto
  1017   next
  1018     fix y assume y: "y \<in> set_pmf q"
  1019     have "{x. R x y} \<in> UNIV // ?R"
  1020       using assms by (auto simp: quotient_def dest: equivp_symp)
  1021     with eq have *: "measure p {x. R x y} = measure q {x. R x y}"
  1022       by auto
  1023     have "measure p {x. R x y} \<noteq> 0"
  1024       using y assms unfolding * by (auto simp: measure_pmf_zero_iff set_eq_iff dest: equivp_reflp)
  1025     then show "\<exists>x\<in>set_pmf p. R x y"
  1026       unfolding measure_pmf_zero_iff by auto
  1027   qed
  1028 
  1029   fix x y assume "x \<in> set_pmf p" "y \<in> set_pmf q" "R x y"
  1030   have "{y. R x y} \<in> UNIV // ?R" "{x. R x y} = {y. R x y}"
  1031     using assms `R x y` by (auto simp: quotient_def dest: equivp_symp equivp_transp)
  1032   with eq show "measure p {x. R x y} = measure q {y. R x y}"
  1033     by auto
  1034 qed
  1035 
  1036 bnf pmf: "'a pmf" map: map_pmf sets: set_pmf bd : "natLeq" rel: rel_pmf
  1037 proof -
  1038   show "map_pmf id = id" by (rule map_pmf_id)
  1039   show "\<And>f g. map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g" by (rule map_pmf_compose)
  1040   show "\<And>f g::'a \<Rightarrow> 'b. \<And>p. (\<And>x. x \<in> set_pmf p \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g p"
  1041     by (intro map_pmf_cong refl)
  1042 
  1043   show "\<And>f::'a \<Rightarrow> 'b. set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
  1044     by (rule pmf_set_map)
  1045 
  1046   { fix p :: "'s pmf"
  1047     have "(card_of (set_pmf p), card_of (UNIV :: nat set)) \<in> ordLeq"
  1048       by (rule card_of_ordLeqI[where f="to_nat_on (set_pmf p)"])
  1049          (auto intro: countable_set_pmf)
  1050     also have "(card_of (UNIV :: nat set), natLeq) \<in> ordLeq"
  1051       by (metis Field_natLeq card_of_least natLeq_Well_order)
  1052     finally show "(card_of (set_pmf p), natLeq) \<in> ordLeq" . }
  1053 
  1054   show "\<And>R. rel_pmf R =
  1055          (BNF_Def.Grp {x. set_pmf x \<subseteq> {(x, y). R x y}} (map_pmf fst))\<inverse>\<inverse> OO
  1056          BNF_Def.Grp {x. set_pmf x \<subseteq> {(x, y). R x y}} (map_pmf snd)"
  1057      by (auto simp add: fun_eq_iff BNF_Def.Grp_def OO_def rel_pmf.simps)
  1058 
  1059   { fix p :: "'a pmf" and f :: "'a \<Rightarrow> 'b" and g x
  1060     assume p: "\<And>z. z \<in> set_pmf p \<Longrightarrow> f z = g z"
  1061       and x: "x \<in> set_pmf p"
  1062     thus "f x = g x" by simp }
  1063 
  1064   fix R :: "'a \<Rightarrow> 'b \<Rightarrow> bool" and S :: "'b \<Rightarrow> 'c \<Rightarrow> bool"
  1065   { fix p q r
  1066     assume pq: "rel_pmf R p q"
  1067       and qr:"rel_pmf S q r"
  1068     from pq obtain pq where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1069       and p: "p = map_pmf fst pq" and q: "q = map_pmf snd pq" by cases auto
  1070     from qr obtain qr where qr: "\<And>y z. (y, z) \<in> set_pmf qr \<Longrightarrow> S y z"
  1071       and q': "q = map_pmf fst qr" and r: "r = map_pmf snd qr" by cases auto
  1072 
  1073     def pr \<equiv> "bind_pmf pq (\<lambda>xy. bind_pmf (cond_pmf qr {yz. fst yz = snd xy}) (\<lambda>yz. return_pmf (fst xy, snd yz)))"
  1074     have pr_welldefined: "\<And>y. y \<in> q \<Longrightarrow> qr \<inter> {yz. fst yz = y} \<noteq> {}"
  1075       by (force simp: q')
  1076 
  1077     have "rel_pmf (R OO S) p r"
  1078     proof (rule rel_pmf.intros)
  1079       fix x z assume "(x, z) \<in> pr"
  1080       then have "\<exists>y. (x, y) \<in> pq \<and> (y, z) \<in> qr"
  1081         by (auto simp: q pr_welldefined pr_def split_beta)
  1082       with pq qr show "(R OO S) x z"
  1083         by blast
  1084     next
  1085       have "map_pmf snd pr = map_pmf snd (bind_pmf q (\<lambda>y. cond_pmf qr {yz. fst yz = y}))"
  1086         by (simp add: pr_def q split_beta bind_map_pmf map_pmf_def[symmetric] map_bind_pmf map_pmf_comp)
  1087       then show "map_pmf snd pr = r"
  1088         unfolding r q' bind_map_pmf by (subst (asm) bind_cond_pmf_cancel) (auto simp: eq_commute)
  1089     qed (simp add: pr_def map_bind_pmf split_beta map_pmf_def[symmetric] p map_pmf_comp) }
  1090   then show "rel_pmf R OO rel_pmf S \<le> rel_pmf (R OO S)"
  1091     by(auto simp add: le_fun_def)
  1092 qed (fact natLeq_card_order natLeq_cinfinite)+
  1093 
  1094 lemma rel_pmf_conj[simp]:
  1095   "rel_pmf (\<lambda>x y. P \<and> Q x y) x y \<longleftrightarrow> P \<and> rel_pmf Q x y"
  1096   "rel_pmf (\<lambda>x y. Q x y \<and> P) x y \<longleftrightarrow> P \<and> rel_pmf Q x y"
  1097   using set_pmf_not_empty by (fastforce simp: pmf.in_rel subset_eq)+
  1098 
  1099 lemma rel_pmf_top[simp]: "rel_pmf top = top"
  1100   by (auto simp: pmf.in_rel[abs_def] fun_eq_iff map_fst_pair_pmf map_snd_pair_pmf
  1101            intro: exI[of _ "pair_pmf x y" for x y])
  1102 
  1103 lemma rel_pmf_return_pmf1: "rel_pmf R (return_pmf x) M \<longleftrightarrow> (\<forall>a\<in>M. R x a)"
  1104 proof safe
  1105   fix a assume "a \<in> M" "rel_pmf R (return_pmf x) M"
  1106   then obtain pq where *: "\<And>a b. (a, b) \<in> set_pmf pq \<Longrightarrow> R a b"
  1107     and eq: "return_pmf x = map_pmf fst pq" "M = map_pmf snd pq"
  1108     by (force elim: rel_pmf.cases)
  1109   moreover have "set_pmf (return_pmf x) = {x}"
  1110     by simp
  1111   with `a \<in> M` have "(x, a) \<in> pq"
  1112     by (force simp: eq)
  1113   with * show "R x a"
  1114     by auto
  1115 qed (auto intro!: rel_pmf.intros[where pq="pair_pmf (return_pmf x) M"]
  1116           simp: map_fst_pair_pmf map_snd_pair_pmf)
  1117 
  1118 lemma rel_pmf_return_pmf2: "rel_pmf R M (return_pmf x) \<longleftrightarrow> (\<forall>a\<in>M. R a x)"
  1119   by (subst pmf.rel_flip[symmetric]) (simp add: rel_pmf_return_pmf1)
  1120 
  1121 lemma rel_return_pmf[simp]: "rel_pmf R (return_pmf x1) (return_pmf x2) = R x1 x2"
  1122   unfolding rel_pmf_return_pmf2 set_return_pmf by simp
  1123 
  1124 lemma rel_pmf_False[simp]: "rel_pmf (\<lambda>x y. False) x y = False"
  1125   unfolding pmf.in_rel fun_eq_iff using set_pmf_not_empty by fastforce
  1126 
  1127 lemma rel_pmf_rel_prod:
  1128   "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B') \<longleftrightarrow> rel_pmf R A B \<and> rel_pmf S A' B'"
  1129 proof safe
  1130   assume "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1131   then obtain pq where pq: "\<And>a b c d. ((a, c), (b, d)) \<in> set_pmf pq \<Longrightarrow> R a b \<and> S c d"
  1132     and eq: "map_pmf fst pq = pair_pmf A A'" "map_pmf snd pq = pair_pmf B B'"
  1133     by (force elim: rel_pmf.cases)
  1134   show "rel_pmf R A B"
  1135   proof (rule rel_pmf.intros)
  1136     let ?f = "\<lambda>(a, b). (fst a, fst b)"
  1137     have [simp]: "(\<lambda>x. fst (?f x)) = fst o fst" "(\<lambda>x. snd (?f x)) = fst o snd"
  1138       by auto
  1139 
  1140     show "map_pmf fst (map_pmf ?f pq) = A"
  1141       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1142     show "map_pmf snd (map_pmf ?f pq) = B"
  1143       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1144 
  1145     fix a b assume "(a, b) \<in> set_pmf (map_pmf ?f pq)"
  1146     then obtain c d where "((a, c), (b, d)) \<in> set_pmf pq"
  1147       by auto
  1148     from pq[OF this] show "R a b" ..
  1149   qed
  1150   show "rel_pmf S A' B'"
  1151   proof (rule rel_pmf.intros)
  1152     let ?f = "\<lambda>(a, b). (snd a, snd b)"
  1153     have [simp]: "(\<lambda>x. fst (?f x)) = snd o fst" "(\<lambda>x. snd (?f x)) = snd o snd"
  1154       by auto
  1155 
  1156     show "map_pmf fst (map_pmf ?f pq) = A'"
  1157       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1158     show "map_pmf snd (map_pmf ?f pq) = B'"
  1159       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1160 
  1161     fix c d assume "(c, d) \<in> set_pmf (map_pmf ?f pq)"
  1162     then obtain a b where "((a, c), (b, d)) \<in> set_pmf pq"
  1163       by auto
  1164     from pq[OF this] show "S c d" ..
  1165   qed
  1166 next
  1167   assume "rel_pmf R A B" "rel_pmf S A' B'"
  1168   then obtain Rpq Spq
  1169     where Rpq: "\<And>a b. (a, b) \<in> set_pmf Rpq \<Longrightarrow> R a b"
  1170         "map_pmf fst Rpq = A" "map_pmf snd Rpq = B"
  1171       and Spq: "\<And>a b. (a, b) \<in> set_pmf Spq \<Longrightarrow> S a b"
  1172         "map_pmf fst Spq = A'" "map_pmf snd Spq = B'"
  1173     by (force elim: rel_pmf.cases)
  1174 
  1175   let ?f = "(\<lambda>((a, c), (b, d)). ((a, b), (c, d)))"
  1176   let ?pq = "map_pmf ?f (pair_pmf Rpq Spq)"
  1177   have [simp]: "(\<lambda>x. fst (?f x)) = (\<lambda>(a, b). (fst a, fst b))" "(\<lambda>x. snd (?f x)) = (\<lambda>(a, b). (snd a, snd b))"
  1178     by auto
  1179 
  1180   show "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1181     by (rule rel_pmf.intros[where pq="?pq"])
  1182        (auto simp: map_snd_pair_pmf map_fst_pair_pmf map_pmf_comp Rpq Spq
  1183                    map_pair)
  1184 qed
  1185 
  1186 lemma rel_pmf_reflI:
  1187   assumes "\<And>x. x \<in> set_pmf p \<Longrightarrow> P x x"
  1188   shows "rel_pmf P p p"
  1189   by (rule rel_pmf.intros[where pq="map_pmf (\<lambda>x. (x, x)) p"])
  1190      (auto simp add: pmf.map_comp o_def assms)
  1191 
  1192 context
  1193 begin
  1194 
  1195 interpretation pmf_as_measure .
  1196 
  1197 definition "join_pmf M = bind_pmf M (\<lambda>x. x)"
  1198 
  1199 lemma bind_eq_join_pmf: "bind_pmf M f = join_pmf (map_pmf f M)"
  1200   unfolding join_pmf_def bind_map_pmf ..
  1201 
  1202 lemma join_eq_bind_pmf: "join_pmf M = bind_pmf M id"
  1203   by (simp add: join_pmf_def id_def)
  1204 
  1205 lemma pmf_join: "pmf (join_pmf N) i = (\<integral>M. pmf M i \<partial>measure_pmf N)"
  1206   unfolding join_pmf_def pmf_bind ..
  1207 
  1208 lemma ereal_pmf_join: "ereal (pmf (join_pmf N) i) = (\<integral>\<^sup>+M. pmf M i \<partial>measure_pmf N)"
  1209   unfolding join_pmf_def ereal_pmf_bind ..
  1210 
  1211 lemma set_pmf_join_pmf[simp]: "set_pmf (join_pmf f) = (\<Union>p\<in>set_pmf f. set_pmf p)"
  1212   by (simp add: join_pmf_def)
  1213 
  1214 lemma join_return_pmf: "join_pmf (return_pmf M) = M"
  1215   by (simp add: integral_return pmf_eq_iff pmf_join return_pmf.rep_eq)
  1216 
  1217 lemma map_join_pmf: "map_pmf f (join_pmf AA) = join_pmf (map_pmf (map_pmf f) AA)"
  1218   by (simp add: join_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf)
  1219 
  1220 lemma join_map_return_pmf: "join_pmf (map_pmf return_pmf A) = A"
  1221   by (simp add: join_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
  1222 
  1223 end
  1224 
  1225 lemma rel_pmf_joinI:
  1226   assumes "rel_pmf (rel_pmf P) p q"
  1227   shows "rel_pmf P (join_pmf p) (join_pmf q)"
  1228 proof -
  1229   from assms obtain pq where p: "p = map_pmf fst pq"
  1230     and q: "q = map_pmf snd pq"
  1231     and P: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> rel_pmf P x y"
  1232     by cases auto
  1233   from P obtain PQ
  1234     where PQ: "\<And>x y a b. \<lbrakk> (x, y) \<in> set_pmf pq; (a, b) \<in> set_pmf (PQ x y) \<rbrakk> \<Longrightarrow> P a b"
  1235     and x: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> map_pmf fst (PQ x y) = x"
  1236     and y: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> map_pmf snd (PQ x y) = y"
  1237     by(metis rel_pmf.simps)
  1238 
  1239   let ?r = "bind_pmf pq (\<lambda>(x, y). PQ x y)"
  1240   have "\<And>a b. (a, b) \<in> set_pmf ?r \<Longrightarrow> P a b" by (auto intro: PQ)
  1241   moreover have "map_pmf fst ?r = join_pmf p" "map_pmf snd ?r = join_pmf q"
  1242     by (simp_all add: p q x y join_pmf_def map_bind_pmf bind_map_pmf split_def cong: bind_pmf_cong)
  1243   ultimately show ?thesis ..
  1244 qed
  1245 
  1246 lemma rel_pmf_bindI:
  1247   assumes pq: "rel_pmf R p q"
  1248   and fg: "\<And>x y. R x y \<Longrightarrow> rel_pmf P (f x) (g y)"
  1249   shows "rel_pmf P (bind_pmf p f) (bind_pmf q g)"
  1250   unfolding bind_eq_join_pmf
  1251   by (rule rel_pmf_joinI)
  1252      (auto simp add: pmf.rel_map intro: pmf.rel_mono[THEN le_funD, THEN le_funD, THEN le_boolD, THEN mp, OF _ pq] fg)
  1253 
  1254 text {*
  1255   Proof that @{const rel_pmf} preserves orders.
  1256   Antisymmetry proof follows Thm. 1 in N. Saheb-Djahromi, Cpo's of measures for nondeterminism,
  1257   Theoretical Computer Science 12(1):19--37, 1980,
  1258   @{url "http://dx.doi.org/10.1016/0304-3975(80)90003-1"}
  1259 *}
  1260 
  1261 lemma
  1262   assumes *: "rel_pmf R p q"
  1263   and refl: "reflp R" and trans: "transp R"
  1264   shows measure_Ici: "measure p {y. R x y} \<le> measure q {y. R x y}" (is ?thesis1)
  1265   and measure_Ioi: "measure p {y. R x y \<and> \<not> R y x} \<le> measure q {y. R x y \<and> \<not> R y x}" (is ?thesis2)
  1266 proof -
  1267   from * obtain pq
  1268     where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1269     and p: "p = map_pmf fst pq"
  1270     and q: "q = map_pmf snd pq"
  1271     by cases auto
  1272   show ?thesis1 ?thesis2 unfolding p q map_pmf_rep_eq using refl trans
  1273     by(auto 4 3 simp add: measure_distr reflpD AE_measure_pmf_iff intro!: measure_pmf.finite_measure_mono_AE dest!: pq elim: transpE)
  1274 qed
  1275 
  1276 lemma rel_pmf_inf:
  1277   fixes p q :: "'a pmf"
  1278   assumes 1: "rel_pmf R p q"
  1279   assumes 2: "rel_pmf R q p"
  1280   and refl: "reflp R" and trans: "transp R"
  1281   shows "rel_pmf (inf R R\<inverse>\<inverse>) p q"
  1282 proof (subst rel_pmf_iff_equivp, safe)
  1283   show "equivp (inf R R\<inverse>\<inverse>)"
  1284     using trans refl by (auto simp: equivp_reflp_symp_transp intro: sympI transpI reflpI dest: transpD reflpD)
  1285   
  1286   fix C assume "C \<in> UNIV // {(x, y). inf R R\<inverse>\<inverse> x y}"
  1287   then obtain x where C: "C = {y. R x y \<and> R y x}"
  1288     by (auto elim: quotientE)
  1289 
  1290   let ?R = "\<lambda>x y. R x y \<and> R y x"
  1291   let ?\<mu>R = "\<lambda>y. measure q {x. ?R x y}"
  1292   have "measure p {y. ?R x y} = measure p ({y. R x y} - {y. R x y \<and> \<not> R y x})"
  1293     by(auto intro!: arg_cong[where f="measure p"])
  1294   also have "\<dots> = measure p {y. R x y} - measure p {y. R x y \<and> \<not> R y x}"
  1295     by (rule measure_pmf.finite_measure_Diff) auto
  1296   also have "measure p {y. R x y \<and> \<not> R y x} = measure q {y. R x y \<and> \<not> R y x}"
  1297     using 1 2 refl trans by(auto intro!: Orderings.antisym measure_Ioi)
  1298   also have "measure p {y. R x y} = measure q {y. R x y}"
  1299     using 1 2 refl trans by(auto intro!: Orderings.antisym measure_Ici)
  1300   also have "measure q {y. R x y} - measure q {y. R x y \<and> \<not> R y x} =
  1301     measure q ({y. R x y} - {y. R x y \<and> \<not> R y x})"
  1302     by(rule measure_pmf.finite_measure_Diff[symmetric]) auto
  1303   also have "\<dots> = ?\<mu>R x"
  1304     by(auto intro!: arg_cong[where f="measure q"])
  1305   finally show "measure p C = measure q C"
  1306     by (simp add: C conj_commute)
  1307 qed
  1308 
  1309 lemma rel_pmf_antisym:
  1310   fixes p q :: "'a pmf"
  1311   assumes 1: "rel_pmf R p q"
  1312   assumes 2: "rel_pmf R q p"
  1313   and refl: "reflp R" and trans: "transp R" and antisym: "antisymP R"
  1314   shows "p = q"
  1315 proof -
  1316   from 1 2 refl trans have "rel_pmf (inf R R\<inverse>\<inverse>) p q" by(rule rel_pmf_inf)
  1317   also have "inf R R\<inverse>\<inverse> = op ="
  1318     using refl antisym by (auto intro!: ext simp add: reflpD dest: antisymD)
  1319   finally show ?thesis unfolding pmf.rel_eq .
  1320 qed
  1321 
  1322 lemma reflp_rel_pmf: "reflp R \<Longrightarrow> reflp (rel_pmf R)"
  1323 by(blast intro: reflpI rel_pmf_reflI reflpD)
  1324 
  1325 lemma antisymP_rel_pmf:
  1326   "\<lbrakk> reflp R; transp R; antisymP R \<rbrakk>
  1327   \<Longrightarrow> antisymP (rel_pmf R)"
  1328 by(rule antisymI)(blast intro: rel_pmf_antisym)
  1329 
  1330 lemma transp_rel_pmf:
  1331   assumes "transp R"
  1332   shows "transp (rel_pmf R)"
  1333 proof (rule transpI)
  1334   fix x y z
  1335   assume "rel_pmf R x y" and "rel_pmf R y z"
  1336   hence "rel_pmf (R OO R) x z" by (simp add: pmf.rel_compp relcompp.relcompI)
  1337   thus "rel_pmf R x z"
  1338     using assms by (metis (no_types) pmf.rel_mono rev_predicate2D transp_relcompp_less_eq)
  1339 qed
  1340 
  1341 subsection \<open> Distributions \<close>
  1342 
  1343 context
  1344 begin
  1345 
  1346 interpretation pmf_as_function .
  1347 
  1348 subsubsection \<open> Bernoulli Distribution \<close>
  1349 
  1350 lift_definition bernoulli_pmf :: "real \<Rightarrow> bool pmf" is
  1351   "\<lambda>p b. ((\<lambda>p. if b then p else 1 - p) \<circ> min 1 \<circ> max 0) p"
  1352   by (auto simp: nn_integral_count_space_finite[where A="{False, True}"] UNIV_bool
  1353            split: split_max split_min)
  1354 
  1355 lemma pmf_bernoulli_True[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) True = p"
  1356   by transfer simp
  1357 
  1358 lemma pmf_bernoulli_False[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) False = 1 - p"
  1359   by transfer simp
  1360 
  1361 lemma set_pmf_bernoulli: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (bernoulli_pmf p) = UNIV"
  1362   by (auto simp add: set_pmf_iff UNIV_bool)
  1363 
  1364 lemma nn_integral_bernoulli_pmf[simp]:
  1365   assumes [simp]: "0 \<le> p" "p \<le> 1" "\<And>x. 0 \<le> f x"
  1366   shows "(\<integral>\<^sup>+x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
  1367   by (subst nn_integral_measure_pmf_support[of UNIV])
  1368      (auto simp: UNIV_bool field_simps)
  1369 
  1370 lemma integral_bernoulli_pmf[simp]:
  1371   assumes [simp]: "0 \<le> p" "p \<le> 1"
  1372   shows "(\<integral>x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
  1373   by (subst integral_measure_pmf[of UNIV]) (auto simp: UNIV_bool)
  1374 
  1375 lemma pmf_bernoulli_half [simp]: "pmf (bernoulli_pmf (1 / 2)) x = 1 / 2"
  1376 by(cases x) simp_all
  1377 
  1378 lemma measure_pmf_bernoulli_half: "measure_pmf (bernoulli_pmf (1 / 2)) = uniform_count_measure UNIV"
  1379 by(rule measure_eqI)(simp_all add: nn_integral_pmf[symmetric] emeasure_uniform_count_measure nn_integral_count_space_finite sets_uniform_count_measure)
  1380 
  1381 subsubsection \<open> Geometric Distribution \<close>
  1382 
  1383 lift_definition geometric_pmf :: "nat pmf" is "\<lambda>n. 1 / 2^Suc n"
  1384 proof
  1385   note geometric_sums[of "1 / 2"]
  1386   note sums_mult[OF this, of "1 / 2"]
  1387   from sums_suminf_ereal[OF this]
  1388   show "(\<integral>\<^sup>+ x. ereal (1 / 2 ^ Suc x) \<partial>count_space UNIV) = 1"
  1389     by (simp add: nn_integral_count_space_nat field_simps)
  1390 qed simp
  1391 
  1392 lemma pmf_geometric[simp]: "pmf geometric_pmf n = 1 / 2^Suc n"
  1393   by transfer rule
  1394 
  1395 lemma set_pmf_geometric[simp]: "set_pmf geometric_pmf = UNIV"
  1396   by (auto simp: set_pmf_iff)
  1397 
  1398 subsubsection \<open> Uniform Multiset Distribution \<close>
  1399 
  1400 context
  1401   fixes M :: "'a multiset" assumes M_not_empty: "M \<noteq> {#}"
  1402 begin
  1403 
  1404 lift_definition pmf_of_multiset :: "'a pmf" is "\<lambda>x. count M x / size M"
  1405 proof
  1406   show "(\<integral>\<^sup>+ x. ereal (real (count M x) / real (size M)) \<partial>count_space UNIV) = 1"
  1407     using M_not_empty
  1408     by (simp add: zero_less_divide_iff nn_integral_count_space nonempty_has_size
  1409                   setsum_divide_distrib[symmetric])
  1410        (auto simp: size_multiset_overloaded_eq intro!: setsum.cong)
  1411 qed simp
  1412 
  1413 lemma pmf_of_multiset[simp]: "pmf pmf_of_multiset x = count M x / size M"
  1414   by transfer rule
  1415 
  1416 lemma set_pmf_of_multiset[simp]: "set_pmf pmf_of_multiset = set_of M"
  1417   by (auto simp: set_pmf_iff)
  1418 
  1419 end
  1420 
  1421 subsubsection \<open> Uniform Distribution \<close>
  1422 
  1423 context
  1424   fixes S :: "'a set" assumes S_not_empty: "S \<noteq> {}" and S_finite: "finite S"
  1425 begin
  1426 
  1427 lift_definition pmf_of_set :: "'a pmf" is "\<lambda>x. indicator S x / card S"
  1428 proof
  1429   show "(\<integral>\<^sup>+ x. ereal (indicator S x / real (card S)) \<partial>count_space UNIV) = 1"
  1430     using S_not_empty S_finite by (subst nn_integral_count_space'[of S]) auto
  1431 qed simp
  1432 
  1433 lemma pmf_of_set[simp]: "pmf pmf_of_set x = indicator S x / card S"
  1434   by transfer rule
  1435 
  1436 lemma set_pmf_of_set[simp]: "set_pmf pmf_of_set = S"
  1437   using S_finite S_not_empty by (auto simp: set_pmf_iff)
  1438 
  1439 lemma emeasure_pmf_of_set[simp]: "emeasure pmf_of_set S = 1"
  1440   by (rule measure_pmf.emeasure_eq_1_AE) (auto simp: AE_measure_pmf_iff)
  1441 
  1442 lemma nn_integral_pmf_of_set': 
  1443   "(\<And>x. x \<in> S \<Longrightarrow> f x \<ge> 0) \<Longrightarrow> nn_integral (measure_pmf pmf_of_set) f = setsum f S / card S"
  1444 apply(subst nn_integral_measure_pmf_finite, simp_all add: S_finite)
  1445 apply(simp add: setsum_ereal_left_distrib[symmetric])
  1446 apply(subst ereal_divide', simp add: S_not_empty S_finite)
  1447 apply(simp add: ereal_times_divide_eq one_ereal_def[symmetric])
  1448 done
  1449 
  1450 lemma nn_integral_pmf_of_set: 
  1451   "nn_integral (measure_pmf pmf_of_set) f = setsum (max 0 \<circ> f) S / card S"
  1452 apply(subst nn_integral_max_0[symmetric])
  1453 apply(subst nn_integral_pmf_of_set')
  1454 apply simp_all
  1455 done
  1456 
  1457 lemma integral_pmf_of_set:
  1458   "integral\<^sup>L (measure_pmf pmf_of_set) f = setsum f S / card S"
  1459 apply(simp add: real_lebesgue_integral_def integrable_measure_pmf_finite nn_integral_pmf_of_set S_finite)
  1460 apply(subst real_of_ereal_minus')
  1461  apply(simp add: ereal_max_0 S_finite del: ereal_max)
  1462 apply(simp add: ereal_max_0 S_finite S_not_empty del: ereal_max)
  1463 apply(simp add: field_simps S_finite S_not_empty)
  1464 apply(subst setsum.distrib[symmetric])
  1465 apply(rule setsum.cong; simp_all)
  1466 done
  1467 
  1468 end
  1469 
  1470 lemma pmf_of_set_singleton: "pmf_of_set {x} = return_pmf x"
  1471 by(rule pmf_eqI)(simp add: indicator_def)
  1472 
  1473 lemma map_pmf_of_set_inj: 
  1474   assumes f: "inj_on f A"
  1475   and [simp]: "A \<noteq> {}" "finite A"
  1476   shows "map_pmf f (pmf_of_set A) = pmf_of_set (f ` A)" (is "?lhs = ?rhs")
  1477 proof(rule pmf_eqI)
  1478   fix i
  1479   show "pmf ?lhs i = pmf ?rhs i"
  1480   proof(cases "i \<in> f ` A")
  1481     case True
  1482     then obtain i' where "i = f i'" "i' \<in> A" by auto
  1483     thus ?thesis using f by(simp add: card_image pmf_map_inj)
  1484   next
  1485     case False
  1486     hence "pmf ?lhs i = 0" by(simp add: pmf_eq_0_set_pmf set_map_pmf)
  1487     moreover have "pmf ?rhs i = 0" using False by simp
  1488     ultimately show ?thesis by simp
  1489   qed
  1490 qed
  1491 
  1492 lemma bernoulli_pmf_half_conv_pmf_of_set: "bernoulli_pmf (1 / 2) = pmf_of_set UNIV"
  1493 by(rule pmf_eqI) simp_all
  1494 
  1495 subsubsection \<open> Poisson Distribution \<close>
  1496 
  1497 context
  1498   fixes rate :: real assumes rate_pos: "0 < rate"
  1499 begin
  1500 
  1501 lift_definition poisson_pmf :: "nat pmf" is "\<lambda>k. rate ^ k / fact k * exp (-rate)"
  1502 proof  (* by Manuel Eberl *)
  1503   have summable: "summable (\<lambda>x::nat. rate ^ x / fact x)" using summable_exp
  1504     by (simp add: field_simps divide_inverse [symmetric])
  1505   have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x * exp (-rate) \<partial>count_space UNIV) =
  1506           exp (-rate) * (\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV)"
  1507     by (simp add: field_simps nn_integral_cmult[symmetric])
  1508   also from rate_pos have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV) = (\<Sum>x. rate ^ x / fact x)"
  1509     by (simp_all add: nn_integral_count_space_nat suminf_ereal summable suminf_ereal_finite)
  1510   also have "... = exp rate" unfolding exp_def
  1511     by (simp add: field_simps divide_inverse [symmetric])
  1512   also have "ereal (exp (-rate)) * ereal (exp rate) = 1"
  1513     by (simp add: mult_exp_exp)
  1514   finally show "(\<integral>\<^sup>+ x. ereal (rate ^ x / (fact x) * exp (- rate)) \<partial>count_space UNIV) = 1" .
  1515 qed (simp add: rate_pos[THEN less_imp_le])
  1516 
  1517 lemma pmf_poisson[simp]: "pmf poisson_pmf k = rate ^ k / fact k * exp (-rate)"
  1518   by transfer rule
  1519 
  1520 lemma set_pmf_poisson[simp]: "set_pmf poisson_pmf = UNIV"
  1521   using rate_pos by (auto simp: set_pmf_iff)
  1522 
  1523 end
  1524 
  1525 subsubsection \<open> Binomial Distribution \<close>
  1526 
  1527 context
  1528   fixes n :: nat and p :: real assumes p_nonneg: "0 \<le> p" and p_le_1: "p \<le> 1"
  1529 begin
  1530 
  1531 lift_definition binomial_pmf :: "nat pmf" is "\<lambda>k. (n choose k) * p^k * (1 - p)^(n - k)"
  1532 proof
  1533   have "(\<integral>\<^sup>+k. ereal (real (n choose k) * p ^ k * (1 - p) ^ (n - k)) \<partial>count_space UNIV) =
  1534     ereal (\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k))"
  1535     using p_le_1 p_nonneg by (subst nn_integral_count_space') auto
  1536   also have "(\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k)) = (p + (1 - p)) ^ n"
  1537     by (subst binomial_ring) (simp add: atLeast0AtMost real_of_nat_def)
  1538   finally show "(\<integral>\<^sup>+ x. ereal (real (n choose x) * p ^ x * (1 - p) ^ (n - x)) \<partial>count_space UNIV) = 1"
  1539     by simp
  1540 qed (insert p_nonneg p_le_1, simp)
  1541 
  1542 lemma pmf_binomial[simp]: "pmf binomial_pmf k = (n choose k) * p^k * (1 - p)^(n - k)"
  1543   by transfer rule
  1544 
  1545 lemma set_pmf_binomial_eq: "set_pmf binomial_pmf = (if p = 0 then {0} else if p = 1 then {n} else {.. n})"
  1546   using p_nonneg p_le_1 unfolding set_eq_iff set_pmf_iff pmf_binomial by (auto simp: set_pmf_iff)
  1547 
  1548 end
  1549 
  1550 end
  1551 
  1552 lemma set_pmf_binomial_0[simp]: "set_pmf (binomial_pmf n 0) = {0}"
  1553   by (simp add: set_pmf_binomial_eq)
  1554 
  1555 lemma set_pmf_binomial_1[simp]: "set_pmf (binomial_pmf n 1) = {n}"
  1556   by (simp add: set_pmf_binomial_eq)
  1557 
  1558 lemma set_pmf_binomial[simp]: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (binomial_pmf n p) = {..n}"
  1559   by (simp add: set_pmf_binomial_eq)
  1560 
  1561 end