src/Pure/variable.ML
author wenzelm
Sun Jul 30 21:28:55 2006 +0200 (2006-07-30)
changeset 20262 ef3ee6a91c18
parent 20251 6379135f21c2
child 20303 e25d5a2a50bc
permissions -rw-r--r--
export: refrain from adjusting maxidx;
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Context.proof -> bool
    11   val set_body: bool -> Context.proof -> Context.proof
    12   val restore_body: Context.proof -> Context.proof -> Context.proof
    13   val names_of: Context.proof -> Name.context
    14   val fixes_of: Context.proof -> (string * string) list
    15   val binds_of: Context.proof -> (typ * term) Vartab.table
    16   val constraints_of: Context.proof -> typ Vartab.table * sort Vartab.table
    17   val is_declared: Context.proof -> string -> bool
    18   val is_fixed: Context.proof -> string -> bool
    19   val newly_fixed: Context.proof -> Context.proof -> string -> bool
    20   val default_type: Context.proof -> string -> typ option
    21   val def_type: Context.proof -> bool -> indexname -> typ option
    22   val def_sort: Context.proof -> indexname -> sort option
    23   val declare_constraints: term -> Context.proof -> Context.proof
    24   val declare_internal: term -> Context.proof -> Context.proof
    25   val declare_term: term -> Context.proof -> Context.proof
    26   val declare_thm: thm -> Context.proof -> Context.proof
    27   val thm_context: thm -> Context.proof
    28   val variant_frees: Context.proof -> term list -> (string * 'a) list -> (string * 'a) list
    29   val add_fixes: string list -> Context.proof -> string list * Context.proof
    30   val add_fixes_direct: string list -> Context.proof -> Context.proof
    31   val fix_frees: term -> Context.proof -> Context.proof
    32   val invent_fixes: string list -> Context.proof -> string list * Context.proof
    33   val invent_types: sort list -> Context.proof -> (string * sort) list * Context.proof
    34   val export_inst: Context.proof -> Context.proof -> string list * string list
    35   val exportT_inst: Context.proof -> Context.proof -> string list
    36   val export_terms: Context.proof -> Context.proof -> term list -> term list
    37   val exportT_terms: Context.proof -> Context.proof -> term list -> term list
    38   val exportT: Context.proof -> Context.proof -> thm list -> thm list
    39   val export: Context.proof -> Context.proof -> thm list -> thm list
    40   val importT_inst: term list -> Context.proof -> ((indexname * sort) * typ) list * Context.proof
    41   val import_inst: bool -> term list -> Context.proof ->
    42     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Context.proof
    43   val importT_terms: term list -> Context.proof -> term list * Context.proof
    44   val import_terms: bool -> term list -> Context.proof -> term list * Context.proof
    45   val importT: thm list -> Context.proof -> (ctyp list * thm list) * Context.proof
    46   val import: bool -> thm list -> Context.proof ->
    47     ((ctyp list * cterm list) * thm list) * Context.proof
    48   val tradeT: Context.proof -> (thm list -> thm list) -> thm list -> thm list
    49   val trade: Context.proof -> (thm list -> thm list) -> thm list -> thm list
    50   val focus: cterm -> Context.proof -> (cterm list * cterm) * Context.proof
    51   val warn_extra_tfrees: Context.proof -> Context.proof -> unit
    52   val polymorphic: Context.proof -> term list -> term list
    53   val hidden_polymorphism: term -> typ -> (indexname * sort) list
    54   val add_binds: (indexname * term option) list -> Context.proof -> Context.proof
    55   val expand_binds: Context.proof -> term -> term
    56 end;
    57 
    58 structure Variable: VARIABLE =
    59 struct
    60 
    61 (** local context data **)
    62 
    63 datatype data = Data of
    64  {is_body: bool,                        (*inner body mode*)
    65   names: Name.context,                  (*type/term variable names*)
    66   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    67   binds: (typ * term) Vartab.table,     (*term bindings*)
    68   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    69   constraints:
    70     typ Vartab.table *                  (*type constraints*)
    71     sort Vartab.table};                 (*default sorts*)
    72 
    73 fun make_data (is_body, names, fixes, binds, type_occs, constraints) =
    74   Data {is_body = is_body, names = names, fixes = fixes, binds = binds,
    75     type_occs = type_occs, constraints = constraints};
    76 
    77 structure Data = ProofDataFun
    78 (
    79   val name = "Pure/variable";
    80   type T = data;
    81   fun init thy =
    82     make_data (false, Name.context, [], Vartab.empty, Symtab.empty, (Vartab.empty, Vartab.empty));
    83   fun print _ _ = ();
    84 );
    85 
    86 val _ = Context.add_setup Data.init;
    87 
    88 fun map_data f =
    89   Data.map (fn Data {is_body, names, fixes, binds, type_occs, constraints} =>
    90     make_data (f (is_body, names, fixes, binds, type_occs, constraints)));
    91 
    92 fun map_names f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    93   (is_body, f names, fixes, binds, type_occs, constraints));
    94 
    95 fun map_fixes f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    96   (is_body, names, f fixes, binds, type_occs, constraints));
    97 
    98 fun map_binds f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    99   (is_body, names, fixes, f binds, type_occs, constraints));
   100 
   101 fun map_type_occs f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   102   (is_body, names, fixes, binds, f type_occs, constraints));
   103 
   104 fun map_constraints f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   105   (is_body, names, fixes, binds, type_occs, f constraints));
   106 
   107 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   108 
   109 val is_body = #is_body o rep_data;
   110 fun set_body b = map_data (fn (_, names, fixes, binds, type_occs, constraints) =>
   111   (b, names, fixes, binds, type_occs, constraints));
   112 fun restore_body ctxt = set_body (is_body ctxt);
   113 
   114 val names_of = #names o rep_data;
   115 val fixes_of = #fixes o rep_data;
   116 val binds_of = #binds o rep_data;
   117 val type_occs_of = #type_occs o rep_data;
   118 val constraints_of = #constraints o rep_data;
   119 
   120 val is_declared = Name.is_declared o names_of;
   121 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   122 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   123 
   124 
   125 
   126 (** declarations **)
   127 
   128 (* default sorts and types *)
   129 
   130 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   131 
   132 fun def_type ctxt pattern xi =
   133   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   134     (case Vartab.lookup types xi of
   135       NONE =>
   136         if pattern then NONE
   137         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   138     | some => some)
   139   end;
   140 
   141 val def_sort = Vartab.lookup o #2 o constraints_of;
   142 
   143 
   144 (* names *)
   145 
   146 val declare_type_names = map_names o
   147   fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I));
   148 
   149 fun declare_names t =
   150   declare_type_names t #>
   151   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t);
   152 
   153 
   154 (* type occurrences *)
   155 
   156 val declare_type_occs = map_type_occs o fold_term_types
   157   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   158     | _ => fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I));
   159 
   160 
   161 (* constraints *)
   162 
   163 fun redeclare_skolems ctxt = ctxt |> map_constraints (apfst (fn types =>
   164   let
   165     fun decl (x, x') =
   166       (case default_type ctxt x' of
   167         SOME T => Vartab.update ((x, ~1), T)
   168       | NONE => I);
   169   in fold_rev decl (fixes_of ctxt) types end));
   170 
   171 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   172   let
   173     val types' = fold_aterms
   174       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   175         | Var v => Vartab.update v
   176         | _ => I) t types;
   177     val sorts' = fold_types (fold_atyps
   178       (fn TFree (x, S) => Vartab.update ((x, ~1), S)
   179         | TVar v => Vartab.update v
   180         | _ => I)) t sorts;
   181   in (types', sorts') end)
   182   #> declare_type_names t
   183   #> redeclare_skolems;
   184 
   185 
   186 (* common declarations *)
   187 
   188 fun declare_internal t =
   189   declare_names t #>
   190   declare_type_occs t;
   191 
   192 fun declare_term t =
   193   declare_internal t #>
   194   declare_constraints t;
   195 
   196 fun declare_thm th = fold declare_internal (Thm.full_prop_of th :: Thm.hyps_of th);
   197 fun thm_context th = declare_thm th (Context.init_proof (Thm.theory_of_thm th));
   198 
   199 
   200 (* renaming term/type frees *)
   201 
   202 fun variant_frees ctxt ts frees =
   203   let
   204     val names = names_of (fold declare_names ts ctxt);
   205     val xs = fst (Name.variants (map #1 frees) names);
   206   in xs ~~ map snd frees end;
   207 
   208 
   209 
   210 (** fixes **)
   211 
   212 local
   213 
   214 fun no_dups [] = ()
   215   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   216 
   217 fun new_fixes names' xs xs' =
   218   map_names (K names') #>
   219   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   220   fold (declare_constraints o Syntax.free) xs' #>
   221   pair xs';
   222 
   223 in
   224 
   225 fun add_fixes xs ctxt =
   226   let
   227     val _ =
   228       (case filter (can Name.dest_skolem) xs of [] => ()
   229       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   230     val _ = no_dups (duplicates (op =) xs);
   231     val (ys, zs) = split_list (fixes_of ctxt);
   232     val names = names_of ctxt;
   233     val (xs', names') =
   234       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   235       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   236         (xs, fold Name.declare xs names));
   237   in ctxt |> new_fixes names' xs xs' end;
   238 
   239 fun invent_fixes raw_xs ctxt =
   240   let
   241     val names = names_of ctxt;
   242     val xs = map Name.clean raw_xs;
   243     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   244   in ctxt |> new_fixes names' xs xs' end;
   245 
   246 end;
   247 
   248 
   249 fun add_fixes_direct xs ctxt = ctxt
   250   |> set_body false
   251   |> (snd o add_fixes xs)
   252   |> restore_body ctxt;
   253 
   254 fun fix_frees t ctxt = ctxt
   255   |> add_fixes_direct
   256       (rev (fold_aterms (fn Free (x, _) =>
   257         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []))
   258   |> declare_term t;
   259 
   260 fun invent_types Ss ctxt =
   261   let
   262     val tfrees = Name.invents (names_of ctxt) "'a" (length Ss) ~~ Ss;
   263     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   264   in (tfrees, ctxt') end;
   265 
   266 
   267 
   268 (** export -- generalize type/term variables **)
   269 
   270 fun export_inst inner outer =
   271   let
   272     val declared_outer = is_declared outer;
   273     val fixes_inner = fixes_of inner;
   274     val fixes_outer = fixes_of outer;
   275 
   276     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   277     val still_fixed = not o member (op =) gen_fixes;
   278     val gen_fixesT =
   279       Symtab.fold (fn (a, xs) =>
   280         if declared_outer a orelse exists still_fixed xs
   281         then I else cons a) (type_occs_of inner) [];
   282   in (gen_fixesT, gen_fixes) end;
   283 
   284 fun exportT_inst inner outer = #1 (export_inst inner outer);
   285 
   286 fun exportT_terms inner outer ts =
   287   map (Term.generalize (exportT_inst (fold declare_type_occs ts inner) outer, [])
   288     (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1)) ts;
   289 
   290 fun export_terms inner outer ts =
   291   map (Term.generalize (export_inst (fold declare_type_occs ts inner) outer)
   292     (fold Term.maxidx_term ts ~1 + 1)) ts;
   293 
   294 fun gen_export inst inner outer ths =
   295   let
   296     val inner' = fold (declare_type_occs o Thm.full_prop_of) ths inner;
   297   in map (Thm.generalize (inst inner' outer) (fold Thm.maxidx_thm ths ~1 + 1)) ths end;
   298 
   299 val exportT = gen_export (rpair [] oo exportT_inst);
   300 val export = gen_export export_inst;
   301 
   302 
   303 
   304 (** import -- fix schematic type/term variables **)
   305 
   306 fun importT_inst ts ctxt =
   307   let
   308     val tvars = rev (fold Term.add_tvars ts []);
   309     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   310   in (tvars ~~ map TFree tfrees, ctxt') end;
   311 
   312 fun import_inst is_open ts ctxt =
   313   let
   314     val ren = if is_open then I else Name.internal;
   315     val (instT, ctxt') = importT_inst ts ctxt;
   316     val vars = map (apsnd (Term.instantiateT instT)) (rev (fold Term.add_vars ts []));
   317     val (xs, ctxt'') = invent_fixes (map (ren o #1 o #1) vars) ctxt';
   318     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   319   in ((instT, inst), ctxt'') end;
   320 
   321 fun importT_terms ts ctxt =
   322   let val (instT, ctxt') = importT_inst ts ctxt
   323   in (map (Term.instantiate (instT, [])) ts, ctxt') end;
   324 
   325 fun import_terms is_open ts ctxt =
   326   let val (inst, ctxt') = import_inst is_open ts ctxt
   327   in (map (Term.instantiate inst) ts, ctxt') end;
   328 
   329 fun importT ths ctxt =
   330   let
   331     val thy = Context.theory_of_proof ctxt;
   332     val certT = Thm.ctyp_of thy;
   333     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   334     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   335     val ths' = map (Thm.instantiate (instT', [])) ths;
   336   in ((map #2 instT', ths'), ctxt') end;
   337 
   338 fun import is_open ths ctxt =
   339   let
   340     val thy = Context.theory_of_proof ctxt;
   341     val cert = Thm.cterm_of thy;
   342     val certT = Thm.ctyp_of thy;
   343     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   344     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   345     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   346     val ths' = map (Thm.instantiate (instT', inst')) ths;
   347   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   348 
   349 
   350 (* import/export *)
   351 
   352 fun gen_trade imp exp ctxt f ths =
   353   let val ((_, ths'), ctxt') = imp ths ctxt
   354   in exp ctxt' ctxt (f ths') end;
   355 
   356 val tradeT = gen_trade importT exportT;
   357 val trade = gen_trade (import true) export;
   358 
   359 
   360 (* focus on outermost parameters *)
   361 
   362 fun forall_elim_prop t prop =
   363   Thm.beta_conversion false (Thm.capply (#2 (Thm.dest_comb prop)) t)
   364   |> Thm.cprop_of |> Thm.dest_comb |> #2;
   365 
   366 fun focus goal ctxt =
   367   let
   368     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   369     val t = Thm.term_of goal;
   370     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   371     val (xs, Ts) = split_list ps;
   372     val (xs', ctxt') = invent_fixes xs ctxt;
   373     val ps' = ListPair.map (cert o Free) (xs', Ts);
   374     val goal' = fold forall_elim_prop ps' goal;
   375   in ((ps', goal'), ctxt') end;
   376 
   377 
   378 (** implicit polymorphism **)
   379 
   380 (* warn_extra_tfrees *)
   381 
   382 fun warn_extra_tfrees ctxt1 ctxt2 =
   383   let
   384     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   385     fun occs_free a x =
   386       (case def_type ctxt1 false (x, ~1) of
   387         SOME T => if occs_typ a T then I else cons (a, x)
   388       | NONE => cons (a, x));
   389 
   390     val occs1 = type_occs_of ctxt1;
   391     val occs2 = type_occs_of ctxt2;
   392     val extras = Symtab.fold (fn (a, xs) =>
   393       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   394     val tfrees = map #1 extras |> sort_distinct string_ord;
   395     val frees = map #2 extras |> sort_distinct string_ord;
   396   in
   397     if null extras then ()
   398     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   399       space_implode " or " (map quote frees))
   400   end;
   401 
   402 
   403 (* polymorphic terms *)
   404 
   405 fun polymorphic ctxt ts =
   406   let
   407     val ctxt' = fold declare_term ts ctxt;
   408     val occs = type_occs_of ctxt;
   409     val occs' = type_occs_of ctxt';
   410     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   411     val idx = fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1;
   412   in map (Term.generalize (types, []) idx) ts end;
   413 
   414 fun hidden_polymorphism t T =
   415   let
   416     val tvarsT = Term.add_tvarsT T [];
   417     val extra_tvars = Term.fold_types (Term.fold_atyps
   418       (fn TVar v => if member (op =) tvarsT v then I else insert (op =) v | _ => I)) t [];
   419   in extra_tvars end;
   420 
   421 
   422 
   423 (** term bindings **)
   424 
   425 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   426   | add_bind ((x, i), SOME t) =
   427       let
   428         val T = Term.fastype_of t;
   429         val t' =
   430           if null (hidden_polymorphism t T) then t
   431           else Var ((x ^ "_has_extra_type_vars_on_rhs", i), T);
   432       in declare_term t' #> map_binds (Vartab.update ((x, i), (T, t'))) end;
   433 
   434 val add_binds = fold add_bind;
   435 
   436 fun expand_binds ctxt =
   437   let
   438     val binds = binds_of ctxt;
   439     fun expand (t as Var (xi, T)) =
   440           (case Vartab.lookup binds xi of
   441             SOME u => Envir.expand_atom T u
   442           | NONE => t)
   443       | expand t = t;
   444   in Envir.beta_norm o Term.map_aterms expand end;
   445 
   446 end;