src/HOL/Relation.thy
author krauss
Sun May 09 12:00:43 2010 +0200 (2010-05-09)
changeset 36772 ef97c5006840
parent 36729 f5b63d2bd8fa
child 40923 be80c93ac0a2
permissions -rw-r--r--
added lemmas rel_comp_UNION_distrib(2)
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1996  University of Cambridge
     4 *)
     5 
     6 header {* Relations *}
     7 
     8 theory Relation
     9 imports Datatype Finite_Set
    10 begin
    11 
    12 subsection {* Definitions *}
    13 
    14 definition
    15   converse :: "('a * 'b) set => ('b * 'a) set"
    16     ("(_^-1)" [1000] 999) where
    17   "r^-1 == {(y, x). (x, y) : r}"
    18 
    19 notation (xsymbols)
    20   converse  ("(_\<inverse>)" [1000] 999)
    21 
    22 definition
    23   rel_comp  :: "[('a * 'b) set, ('b * 'c) set] => ('a * 'c) set"
    24     (infixr "O" 75) where
    25   "r O s == {(x,z). EX y. (x, y) : r & (y, z) : s}"
    26 
    27 definition
    28   Image :: "[('a * 'b) set, 'a set] => 'b set"
    29     (infixl "``" 90) where
    30   "r `` s == {y. EX x:s. (x,y):r}"
    31 
    32 definition
    33   Id :: "('a * 'a) set" where -- {* the identity relation *}
    34   "Id == {p. EX x. p = (x,x)}"
    35 
    36 definition
    37   Id_on  :: "'a set => ('a * 'a) set" where -- {* diagonal: identity over a set *}
    38   "Id_on A == \<Union>x\<in>A. {(x,x)}"
    39 
    40 definition
    41   Domain :: "('a * 'b) set => 'a set" where
    42   "Domain r == {x. EX y. (x,y):r}"
    43 
    44 definition
    45   Range  :: "('a * 'b) set => 'b set" where
    46   "Range r == Domain(r^-1)"
    47 
    48 definition
    49   Field :: "('a * 'a) set => 'a set" where
    50   "Field r == Domain r \<union> Range r"
    51 
    52 definition
    53   refl_on :: "['a set, ('a * 'a) set] => bool" where -- {* reflexivity over a set *}
    54   "refl_on A r == r \<subseteq> A \<times> A & (ALL x: A. (x,x) : r)"
    55 
    56 abbreviation
    57   refl :: "('a * 'a) set => bool" where -- {* reflexivity over a type *}
    58   "refl == refl_on UNIV"
    59 
    60 definition
    61   sym :: "('a * 'a) set => bool" where -- {* symmetry predicate *}
    62   "sym r == ALL x y. (x,y): r --> (y,x): r"
    63 
    64 definition
    65   antisym :: "('a * 'a) set => bool" where -- {* antisymmetry predicate *}
    66   "antisym r == ALL x y. (x,y):r --> (y,x):r --> x=y"
    67 
    68 definition
    69   trans :: "('a * 'a) set => bool" where -- {* transitivity predicate *}
    70   "trans r == (ALL x y z. (x,y):r --> (y,z):r --> (x,z):r)"
    71 
    72 definition
    73 irrefl :: "('a * 'a) set => bool" where
    74 "irrefl r \<equiv> \<forall>x. (x,x) \<notin> r"
    75 
    76 definition
    77 total_on :: "'a set => ('a * 'a) set => bool" where
    78 "total_on A r \<equiv> \<forall>x\<in>A.\<forall>y\<in>A. x\<noteq>y \<longrightarrow> (x,y)\<in>r \<or> (y,x)\<in>r"
    79 
    80 abbreviation "total \<equiv> total_on UNIV"
    81 
    82 definition
    83   single_valued :: "('a * 'b) set => bool" where
    84   "single_valued r == ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z)"
    85 
    86 definition
    87   inv_image :: "('b * 'b) set => ('a => 'b) => ('a * 'a) set" where
    88   "inv_image r f == {(x, y). (f x, f y) : r}"
    89 
    90 
    91 subsection {* The identity relation *}
    92 
    93 lemma IdI [intro]: "(a, a) : Id"
    94 by (simp add: Id_def)
    95 
    96 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
    97 by (unfold Id_def) (iprover elim: CollectE)
    98 
    99 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   100 by (unfold Id_def) blast
   101 
   102 lemma refl_Id: "refl Id"
   103 by (simp add: refl_on_def)
   104 
   105 lemma antisym_Id: "antisym Id"
   106   -- {* A strange result, since @{text Id} is also symmetric. *}
   107 by (simp add: antisym_def)
   108 
   109 lemma sym_Id: "sym Id"
   110 by (simp add: sym_def)
   111 
   112 lemma trans_Id: "trans Id"
   113 by (simp add: trans_def)
   114 
   115 
   116 subsection {* Diagonal: identity over a set *}
   117 
   118 lemma Id_on_empty [simp]: "Id_on {} = {}"
   119 by (simp add: Id_on_def) 
   120 
   121 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   122 by (simp add: Id_on_def)
   123 
   124 lemma Id_onI [intro!,no_atp]: "a : A ==> (a, a) : Id_on A"
   125 by (rule Id_on_eqI) (rule refl)
   126 
   127 lemma Id_onE [elim!]:
   128   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   129   -- {* The general elimination rule. *}
   130 by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   131 
   132 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   133 by blast
   134 
   135 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   136 by blast
   137 
   138 
   139 subsection {* Composition of two relations *}
   140 
   141 lemma rel_compI [intro]:
   142   "(a, b) : r ==> (b, c) : s ==> (a, c) : r O s"
   143 by (unfold rel_comp_def) blast
   144 
   145 lemma rel_compE [elim!]: "xz : r O s ==>
   146   (!!x y z. xz = (x, z) ==> (x, y) : r ==> (y, z) : s  ==> P) ==> P"
   147 by (unfold rel_comp_def) (iprover elim!: CollectE splitE exE conjE)
   148 
   149 lemma rel_compEpair:
   150   "(a, c) : r O s ==> (!!y. (a, y) : r ==> (y, c) : s ==> P) ==> P"
   151 by (iprover elim: rel_compE Pair_inject ssubst)
   152 
   153 lemma R_O_Id [simp]: "R O Id = R"
   154 by fast
   155 
   156 lemma Id_O_R [simp]: "Id O R = R"
   157 by fast
   158 
   159 lemma rel_comp_empty1[simp]: "{} O R = {}"
   160 by blast
   161 
   162 lemma rel_comp_empty2[simp]: "R O {} = {}"
   163 by blast
   164 
   165 lemma O_assoc: "(R O S) O T = R O (S O T)"
   166 by blast
   167 
   168 lemma trans_O_subset: "trans r ==> r O r \<subseteq> r"
   169 by (unfold trans_def) blast
   170 
   171 lemma rel_comp_mono: "r' \<subseteq> r ==> s' \<subseteq> s ==> (r' O s') \<subseteq> (r O s)"
   172 by blast
   173 
   174 lemma rel_comp_subset_Sigma:
   175     "r \<subseteq> A \<times> B ==> s \<subseteq> B \<times> C ==> (r O s) \<subseteq> A \<times> C"
   176 by blast
   177 
   178 lemma rel_comp_distrib[simp]: "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   179 by auto
   180 
   181 lemma rel_comp_distrib2[simp]: "(S \<union> T) O R = (S O R) \<union> (T O R)"
   182 by auto
   183 
   184 lemma rel_comp_UNION_distrib: "s O UNION I r = UNION I (%i. s O r i)"
   185 by auto
   186 
   187 lemma rel_comp_UNION_distrib2: "UNION I r O s = UNION I (%i. r i O s)"
   188 by auto
   189 
   190 
   191 subsection {* Reflexivity *}
   192 
   193 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   194 by (unfold refl_on_def) (iprover intro!: ballI)
   195 
   196 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   197 by (unfold refl_on_def) blast
   198 
   199 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   200 by (unfold refl_on_def) blast
   201 
   202 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   203 by (unfold refl_on_def) blast
   204 
   205 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   206 by (unfold refl_on_def) blast
   207 
   208 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   209 by (unfold refl_on_def) blast
   210 
   211 lemma refl_on_INTER:
   212   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   213 by (unfold refl_on_def) fast
   214 
   215 lemma refl_on_UNION:
   216   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   217 by (unfold refl_on_def) blast
   218 
   219 lemma refl_on_empty[simp]: "refl_on {} {}"
   220 by(simp add:refl_on_def)
   221 
   222 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   223 by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   224 
   225 
   226 subsection {* Antisymmetry *}
   227 
   228 lemma antisymI:
   229   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   230 by (unfold antisym_def) iprover
   231 
   232 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   233 by (unfold antisym_def) iprover
   234 
   235 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   236 by (unfold antisym_def) blast
   237 
   238 lemma antisym_empty [simp]: "antisym {}"
   239 by (unfold antisym_def) blast
   240 
   241 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   242 by (unfold antisym_def) blast
   243 
   244 
   245 subsection {* Symmetry *}
   246 
   247 lemma symI: "(!!a b. (a, b) : r ==> (b, a) : r) ==> sym r"
   248 by (unfold sym_def) iprover
   249 
   250 lemma symD: "sym r ==> (a, b) : r ==> (b, a) : r"
   251 by (unfold sym_def, blast)
   252 
   253 lemma sym_Int: "sym r ==> sym s ==> sym (r \<inter> s)"
   254 by (fast intro: symI dest: symD)
   255 
   256 lemma sym_Un: "sym r ==> sym s ==> sym (r \<union> s)"
   257 by (fast intro: symI dest: symD)
   258 
   259 lemma sym_INTER: "ALL x:S. sym (r x) ==> sym (INTER S r)"
   260 by (fast intro: symI dest: symD)
   261 
   262 lemma sym_UNION: "ALL x:S. sym (r x) ==> sym (UNION S r)"
   263 by (fast intro: symI dest: symD)
   264 
   265 lemma sym_Id_on [simp]: "sym (Id_on A)"
   266 by (rule symI) clarify
   267 
   268 
   269 subsection {* Transitivity *}
   270 
   271 lemma transI:
   272   "(!!x y z. (x, y) : r ==> (y, z) : r ==> (x, z) : r) ==> trans r"
   273 by (unfold trans_def) iprover
   274 
   275 lemma transD: "trans r ==> (a, b) : r ==> (b, c) : r ==> (a, c) : r"
   276 by (unfold trans_def) iprover
   277 
   278 lemma trans_Int: "trans r ==> trans s ==> trans (r \<inter> s)"
   279 by (fast intro: transI elim: transD)
   280 
   281 lemma trans_INTER: "ALL x:S. trans (r x) ==> trans (INTER S r)"
   282 by (fast intro: transI elim: transD)
   283 
   284 lemma trans_Id_on [simp]: "trans (Id_on A)"
   285 by (fast intro: transI elim: transD)
   286 
   287 lemma trans_diff_Id: " trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r-Id)"
   288 unfolding antisym_def trans_def by blast
   289 
   290 subsection {* Irreflexivity *}
   291 
   292 lemma irrefl_diff_Id[simp]: "irrefl(r-Id)"
   293 by(simp add:irrefl_def)
   294 
   295 subsection {* Totality *}
   296 
   297 lemma total_on_empty[simp]: "total_on {} r"
   298 by(simp add:total_on_def)
   299 
   300 lemma total_on_diff_Id[simp]: "total_on A (r-Id) = total_on A r"
   301 by(simp add: total_on_def)
   302 
   303 subsection {* Converse *}
   304 
   305 lemma converse_iff [iff]: "((a,b): r^-1) = ((b,a) : r)"
   306 by (simp add: converse_def)
   307 
   308 lemma converseI[sym]: "(a, b) : r ==> (b, a) : r^-1"
   309 by (simp add: converse_def)
   310 
   311 lemma converseD[sym]: "(a,b) : r^-1 ==> (b, a) : r"
   312 by (simp add: converse_def)
   313 
   314 lemma converseE [elim!]:
   315   "yx : r^-1 ==> (!!x y. yx = (y, x) ==> (x, y) : r ==> P) ==> P"
   316     -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   317 by (unfold converse_def) (iprover elim!: CollectE splitE bexE)
   318 
   319 lemma converse_converse [simp]: "(r^-1)^-1 = r"
   320 by (unfold converse_def) blast
   321 
   322 lemma converse_rel_comp: "(r O s)^-1 = s^-1 O r^-1"
   323 by blast
   324 
   325 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   326 by blast
   327 
   328 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   329 by blast
   330 
   331 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   332 by fast
   333 
   334 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   335 by blast
   336 
   337 lemma converse_Id [simp]: "Id^-1 = Id"
   338 by blast
   339 
   340 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   341 by blast
   342 
   343 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   344 by (unfold refl_on_def) auto
   345 
   346 lemma sym_converse [simp]: "sym (converse r) = sym r"
   347 by (unfold sym_def) blast
   348 
   349 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   350 by (unfold antisym_def) blast
   351 
   352 lemma trans_converse [simp]: "trans (converse r) = trans r"
   353 by (unfold trans_def) blast
   354 
   355 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   356 by (unfold sym_def) fast
   357 
   358 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   359 by (unfold sym_def) blast
   360 
   361 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   362 by (unfold sym_def) blast
   363 
   364 lemma total_on_converse[simp]: "total_on A (r^-1) = total_on A r"
   365 by (auto simp: total_on_def)
   366 
   367 
   368 subsection {* Domain *}
   369 
   370 declare Domain_def [no_atp]
   371 
   372 lemma Domain_iff: "(a : Domain r) = (EX y. (a, y) : r)"
   373 by (unfold Domain_def) blast
   374 
   375 lemma DomainI [intro]: "(a, b) : r ==> a : Domain r"
   376 by (iprover intro!: iffD2 [OF Domain_iff])
   377 
   378 lemma DomainE [elim!]:
   379   "a : Domain r ==> (!!y. (a, y) : r ==> P) ==> P"
   380 by (iprover dest!: iffD1 [OF Domain_iff])
   381 
   382 lemma Domain_empty [simp]: "Domain {} = {}"
   383 by blast
   384 
   385 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   386   by auto
   387 
   388 lemma Domain_insert: "Domain (insert (a, b) r) = insert a (Domain r)"
   389 by blast
   390 
   391 lemma Domain_Id [simp]: "Domain Id = UNIV"
   392 by blast
   393 
   394 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   395 by blast
   396 
   397 lemma Domain_Un_eq: "Domain(A \<union> B) = Domain(A) \<union> Domain(B)"
   398 by blast
   399 
   400 lemma Domain_Int_subset: "Domain(A \<inter> B) \<subseteq> Domain(A) \<inter> Domain(B)"
   401 by blast
   402 
   403 lemma Domain_Diff_subset: "Domain(A) - Domain(B) \<subseteq> Domain(A - B)"
   404 by blast
   405 
   406 lemma Domain_Union: "Domain (Union S) = (\<Union>A\<in>S. Domain A)"
   407 by blast
   408 
   409 lemma Domain_converse[simp]: "Domain(r^-1) = Range r"
   410 by(auto simp:Range_def)
   411 
   412 lemma Domain_mono: "r \<subseteq> s ==> Domain r \<subseteq> Domain s"
   413 by blast
   414 
   415 lemma fst_eq_Domain: "fst ` R = Domain R"
   416 by (auto intro!:image_eqI)
   417 
   418 lemma Domain_dprod [simp]: "Domain (dprod r s) = uprod (Domain r) (Domain s)"
   419 by auto
   420 
   421 lemma Domain_dsum [simp]: "Domain (dsum r s) = usum (Domain r) (Domain s)"
   422 by auto
   423 
   424 
   425 subsection {* Range *}
   426 
   427 lemma Range_iff: "(a : Range r) = (EX y. (y, a) : r)"
   428 by (simp add: Domain_def Range_def)
   429 
   430 lemma RangeI [intro]: "(a, b) : r ==> b : Range r"
   431 by (unfold Range_def) (iprover intro!: converseI DomainI)
   432 
   433 lemma RangeE [elim!]: "b : Range r ==> (!!x. (x, b) : r ==> P) ==> P"
   434 by (unfold Range_def) (iprover elim!: DomainE dest!: converseD)
   435 
   436 lemma Range_empty [simp]: "Range {} = {}"
   437 by blast
   438 
   439 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   440   by auto
   441 
   442 lemma Range_insert: "Range (insert (a, b) r) = insert b (Range r)"
   443 by blast
   444 
   445 lemma Range_Id [simp]: "Range Id = UNIV"
   446 by blast
   447 
   448 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   449 by auto
   450 
   451 lemma Range_Un_eq: "Range(A \<union> B) = Range(A) \<union> Range(B)"
   452 by blast
   453 
   454 lemma Range_Int_subset: "Range(A \<inter> B) \<subseteq> Range(A) \<inter> Range(B)"
   455 by blast
   456 
   457 lemma Range_Diff_subset: "Range(A) - Range(B) \<subseteq> Range(A - B)"
   458 by blast
   459 
   460 lemma Range_Union: "Range (Union S) = (\<Union>A\<in>S. Range A)"
   461 by blast
   462 
   463 lemma Range_converse[simp]: "Range(r^-1) = Domain r"
   464 by blast
   465 
   466 lemma snd_eq_Range: "snd ` R = Range R"
   467 by (auto intro!:image_eqI)
   468 
   469 
   470 subsection {* Field *}
   471 
   472 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   473 by(auto simp:Field_def Domain_def Range_def)
   474 
   475 lemma Field_empty[simp]: "Field {} = {}"
   476 by(auto simp:Field_def)
   477 
   478 lemma Field_insert[simp]: "Field (insert (a,b) r) = {a,b} \<union> Field r"
   479 by(auto simp:Field_def)
   480 
   481 lemma Field_Un[simp]: "Field (r \<union> s) = Field r \<union> Field s"
   482 by(auto simp:Field_def)
   483 
   484 lemma Field_Union[simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   485 by(auto simp:Field_def)
   486 
   487 lemma Field_converse[simp]: "Field(r^-1) = Field r"
   488 by(auto simp:Field_def)
   489 
   490 
   491 subsection {* Image of a set under a relation *}
   492 
   493 declare Image_def [no_atp]
   494 
   495 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   496 by (simp add: Image_def)
   497 
   498 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   499 by (simp add: Image_def)
   500 
   501 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   502 by (rule Image_iff [THEN trans]) simp
   503 
   504 lemma ImageI [intro,no_atp]: "(a, b) : r ==> a : A ==> b : r``A"
   505 by (unfold Image_def) blast
   506 
   507 lemma ImageE [elim!]:
   508     "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   509 by (unfold Image_def) (iprover elim!: CollectE bexE)
   510 
   511 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   512   -- {* This version's more effective when we already have the required @{text a} *}
   513 by blast
   514 
   515 lemma Image_empty [simp]: "R``{} = {}"
   516 by blast
   517 
   518 lemma Image_Id [simp]: "Id `` A = A"
   519 by blast
   520 
   521 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
   522 by blast
   523 
   524 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   525 by blast
   526 
   527 lemma Image_Int_eq:
   528      "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   529 by (simp add: single_valued_def, blast) 
   530 
   531 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   532 by blast
   533 
   534 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   535 by blast
   536 
   537 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
   538 by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   539 
   540 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   541   -- {* NOT suitable for rewriting *}
   542 by blast
   543 
   544 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
   545 by blast
   546 
   547 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
   548 by blast
   549 
   550 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
   551 by blast
   552 
   553 text{*Converse inclusion requires some assumptions*}
   554 lemma Image_INT_eq:
   555      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
   556 apply (rule equalityI)
   557  apply (rule Image_INT_subset) 
   558 apply  (simp add: single_valued_def, blast)
   559 done
   560 
   561 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
   562 by blast
   563 
   564 
   565 subsection {* Single valued relations *}
   566 
   567 lemma single_valuedI:
   568   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   569 by (unfold single_valued_def)
   570 
   571 lemma single_valuedD:
   572   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   573 by (simp add: single_valued_def)
   574 
   575 lemma single_valued_rel_comp:
   576   "single_valued r ==> single_valued s ==> single_valued (r O s)"
   577 by (unfold single_valued_def) blast
   578 
   579 lemma single_valued_subset:
   580   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   581 by (unfold single_valued_def) blast
   582 
   583 lemma single_valued_Id [simp]: "single_valued Id"
   584 by (unfold single_valued_def) blast
   585 
   586 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   587 by (unfold single_valued_def) blast
   588 
   589 
   590 subsection {* Graphs given by @{text Collect} *}
   591 
   592 lemma Domain_Collect_split [simp]: "Domain{(x,y). P x y} = {x. EX y. P x y}"
   593 by auto
   594 
   595 lemma Range_Collect_split [simp]: "Range{(x,y). P x y} = {y. EX x. P x y}"
   596 by auto
   597 
   598 lemma Image_Collect_split [simp]: "{(x,y). P x y} `` A = {y. EX x:A. P x y}"
   599 by auto
   600 
   601 
   602 subsection {* Inverse image *}
   603 
   604 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
   605 by (unfold sym_def inv_image_def) blast
   606 
   607 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
   608   apply (unfold trans_def inv_image_def)
   609   apply (simp (no_asm))
   610   apply blast
   611   done
   612 
   613 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
   614   by (auto simp:inv_image_def)
   615 
   616 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
   617 unfolding inv_image_def converse_def by auto
   618 
   619 
   620 subsection {* Finiteness *}
   621 
   622 lemma finite_converse [iff]: "finite (r^-1) = finite r"
   623   apply (subgoal_tac "r^-1 = (%(x,y). (y,x))`r")
   624    apply simp
   625    apply (rule iffI)
   626     apply (erule finite_imageD [unfolded inj_on_def])
   627     apply (simp split add: split_split)
   628    apply (erule finite_imageI)
   629   apply (simp add: converse_def image_def, auto)
   630   apply (rule bexI)
   631    prefer 2 apply assumption
   632   apply simp
   633   done
   634 
   635 lemma finite_Domain: "finite r ==> finite (Domain r)"
   636   by (induct set: finite) (auto simp add: Domain_insert)
   637 
   638 lemma finite_Range: "finite r ==> finite (Range r)"
   639   by (induct set: finite) (auto simp add: Range_insert)
   640 
   641 lemma finite_Field: "finite r ==> finite (Field r)"
   642   -- {* A finite relation has a finite field (@{text "= domain \<union> range"}. *}
   643   apply (induct set: finite)
   644    apply (auto simp add: Field_def Domain_insert Range_insert)
   645   done
   646 
   647 
   648 subsection {* Miscellaneous *}
   649 
   650 text {* Version of @{thm[source] lfp_induct} for binary relations *}
   651 
   652 lemmas lfp_induct2 = 
   653   lfp_induct_set [of "(a, b)", split_format (complete)]
   654 
   655 text {* Version of @{thm[source] subsetI} for binary relations *}
   656 
   657 lemma subrelI: "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
   658 by auto
   659 
   660 end