src/HOL/Divides.thy
author wenzelm
Fri Jan 14 15:44:47 2011 +0100 (2011-01-14)
changeset 41550 efa734d9b221
parent 39489 8bb7f32a3a08
child 41792 ff3cb0c418b7
permissions -rw-r--r--
eliminated global prems;
tuned proofs;
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Numeral Nat_Transfer
    10 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    11 begin
    12 
    13 subsection {* Syntactic division operations *}
    14 
    15 class div = dvd +
    16   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    17     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    18 
    19 
    20 subsection {* Abstract division in commutative semirings. *}
    21 
    22 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    23   assumes mod_div_equality: "a div b * b + a mod b = a"
    24     and div_by_0 [simp]: "a div 0 = 0"
    25     and div_0 [simp]: "0 div a = 0"
    26     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    27     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    28 begin
    29 
    30 text {* @{const div} and @{const mod} *}
    31 
    32 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    33   unfolding mult_commute [of b]
    34   by (rule mod_div_equality)
    35 
    36 lemma mod_div_equality': "a mod b + a div b * b = a"
    37   using mod_div_equality [of a b]
    38   by (simp only: add_ac)
    39 
    40 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    41   by (simp add: mod_div_equality)
    42 
    43 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    44   by (simp add: mod_div_equality2)
    45 
    46 lemma mod_by_0 [simp]: "a mod 0 = a"
    47   using mod_div_equality [of a zero] by simp
    48 
    49 lemma mod_0 [simp]: "0 mod a = 0"
    50   using mod_div_equality [of zero a] div_0 by simp
    51 
    52 lemma div_mult_self2 [simp]:
    53   assumes "b \<noteq> 0"
    54   shows "(a + b * c) div b = c + a div b"
    55   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    56 
    57 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    58 proof (cases "b = 0")
    59   case True then show ?thesis by simp
    60 next
    61   case False
    62   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    63     by (simp add: mod_div_equality)
    64   also from False div_mult_self1 [of b a c] have
    65     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    66       by (simp add: algebra_simps)
    67   finally have "a = a div b * b + (a + c * b) mod b"
    68     by (simp add: add_commute [of a] add_assoc left_distrib)
    69   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    70     by (simp add: mod_div_equality)
    71   then show ?thesis by simp
    72 qed
    73 
    74 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    75   by (simp add: mult_commute [of b])
    76 
    77 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    78   using div_mult_self2 [of b 0 a] by simp
    79 
    80 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    81   using div_mult_self1 [of b 0 a] by simp
    82 
    83 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    84   using mod_mult_self2 [of 0 b a] by simp
    85 
    86 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    87   using mod_mult_self1 [of 0 a b] by simp
    88 
    89 lemma div_by_1 [simp]: "a div 1 = a"
    90   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    91 
    92 lemma mod_by_1 [simp]: "a mod 1 = 0"
    93 proof -
    94   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    95   then have "a + a mod 1 = a + 0" by simp
    96   then show ?thesis by (rule add_left_imp_eq)
    97 qed
    98 
    99 lemma mod_self [simp]: "a mod a = 0"
   100   using mod_mult_self2_is_0 [of 1] by simp
   101 
   102 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   103   using div_mult_self2_is_id [of _ 1] by simp
   104 
   105 lemma div_add_self1 [simp]:
   106   assumes "b \<noteq> 0"
   107   shows "(b + a) div b = a div b + 1"
   108   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   109 
   110 lemma div_add_self2 [simp]:
   111   assumes "b \<noteq> 0"
   112   shows "(a + b) div b = a div b + 1"
   113   using assms div_add_self1 [of b a] by (simp add: add_commute)
   114 
   115 lemma mod_add_self1 [simp]:
   116   "(b + a) mod b = a mod b"
   117   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   118 
   119 lemma mod_add_self2 [simp]:
   120   "(a + b) mod b = a mod b"
   121   using mod_mult_self1 [of a 1 b] by simp
   122 
   123 lemma mod_div_decomp:
   124   fixes a b
   125   obtains q r where "q = a div b" and "r = a mod b"
   126     and "a = q * b + r"
   127 proof -
   128   from mod_div_equality have "a = a div b * b + a mod b" by simp
   129   moreover have "a div b = a div b" ..
   130   moreover have "a mod b = a mod b" ..
   131   note that ultimately show thesis by blast
   132 qed
   133 
   134 lemma dvd_eq_mod_eq_0 [code, code_unfold, code_inline del]: "a dvd b \<longleftrightarrow> b mod a = 0"
   135 proof
   136   assume "b mod a = 0"
   137   with mod_div_equality [of b a] have "b div a * a = b" by simp
   138   then have "b = a * (b div a)" unfolding mult_commute ..
   139   then have "\<exists>c. b = a * c" ..
   140   then show "a dvd b" unfolding dvd_def .
   141 next
   142   assume "a dvd b"
   143   then have "\<exists>c. b = a * c" unfolding dvd_def .
   144   then obtain c where "b = a * c" ..
   145   then have "b mod a = a * c mod a" by simp
   146   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   147   then show "b mod a = 0" by simp
   148 qed
   149 
   150 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   151 proof (cases "b = 0")
   152   assume "b = 0"
   153   thus ?thesis by simp
   154 next
   155   assume "b \<noteq> 0"
   156   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   157     by (rule div_mult_self1 [symmetric])
   158   also have "\<dots> = a div b"
   159     by (simp only: mod_div_equality')
   160   also have "\<dots> = a div b + 0"
   161     by simp
   162   finally show ?thesis
   163     by (rule add_left_imp_eq)
   164 qed
   165 
   166 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   167 proof -
   168   have "a mod b mod b = (a mod b + a div b * b) mod b"
   169     by (simp only: mod_mult_self1)
   170   also have "\<dots> = a mod b"
   171     by (simp only: mod_div_equality')
   172   finally show ?thesis .
   173 qed
   174 
   175 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   176 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   177 
   178 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   179 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   180 
   181 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   182 by (drule dvd_div_mult_self) (simp add: mult_commute)
   183 
   184 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   185 apply (cases "a = 0")
   186  apply simp
   187 apply (auto simp: dvd_def mult_assoc)
   188 done
   189 
   190 lemma div_dvd_div[simp]:
   191   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   192 apply (cases "a = 0")
   193  apply simp
   194 apply (unfold dvd_def)
   195 apply auto
   196  apply(blast intro:mult_assoc[symmetric])
   197 apply(fastsimp simp add: mult_assoc)
   198 done
   199 
   200 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   201   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   202    apply (simp add: mod_div_equality)
   203   apply (simp only: dvd_add dvd_mult)
   204   done
   205 
   206 text {* Addition respects modular equivalence. *}
   207 
   208 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   209 proof -
   210   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   211     by (simp only: mod_div_equality)
   212   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   213     by (simp only: add_ac)
   214   also have "\<dots> = (a mod c + b) mod c"
   215     by (rule mod_mult_self1)
   216   finally show ?thesis .
   217 qed
   218 
   219 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   220 proof -
   221   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   222     by (simp only: mod_div_equality)
   223   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   224     by (simp only: add_ac)
   225   also have "\<dots> = (a + b mod c) mod c"
   226     by (rule mod_mult_self1)
   227   finally show ?thesis .
   228 qed
   229 
   230 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   231 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   232 
   233 lemma mod_add_cong:
   234   assumes "a mod c = a' mod c"
   235   assumes "b mod c = b' mod c"
   236   shows "(a + b) mod c = (a' + b') mod c"
   237 proof -
   238   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   239     unfolding assms ..
   240   thus ?thesis
   241     by (simp only: mod_add_eq [symmetric])
   242 qed
   243 
   244 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   245   \<Longrightarrow> (x + y) div z = x div z + y div z"
   246 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   247 
   248 text {* Multiplication respects modular equivalence. *}
   249 
   250 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   251 proof -
   252   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   253     by (simp only: mod_div_equality)
   254   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   255     by (simp only: algebra_simps)
   256   also have "\<dots> = (a mod c * b) mod c"
   257     by (rule mod_mult_self1)
   258   finally show ?thesis .
   259 qed
   260 
   261 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   262 proof -
   263   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   264     by (simp only: mod_div_equality)
   265   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   266     by (simp only: algebra_simps)
   267   also have "\<dots> = (a * (b mod c)) mod c"
   268     by (rule mod_mult_self1)
   269   finally show ?thesis .
   270 qed
   271 
   272 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   273 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   274 
   275 lemma mod_mult_cong:
   276   assumes "a mod c = a' mod c"
   277   assumes "b mod c = b' mod c"
   278   shows "(a * b) mod c = (a' * b') mod c"
   279 proof -
   280   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   281     unfolding assms ..
   282   thus ?thesis
   283     by (simp only: mod_mult_eq [symmetric])
   284 qed
   285 
   286 lemma mod_mod_cancel:
   287   assumes "c dvd b"
   288   shows "a mod b mod c = a mod c"
   289 proof -
   290   from `c dvd b` obtain k where "b = c * k"
   291     by (rule dvdE)
   292   have "a mod b mod c = a mod (c * k) mod c"
   293     by (simp only: `b = c * k`)
   294   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   295     by (simp only: mod_mult_self1)
   296   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   297     by (simp only: add_ac mult_ac)
   298   also have "\<dots> = a mod c"
   299     by (simp only: mod_div_equality)
   300   finally show ?thesis .
   301 qed
   302 
   303 lemma div_mult_div_if_dvd:
   304   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   305   apply (cases "y = 0", simp)
   306   apply (cases "z = 0", simp)
   307   apply (auto elim!: dvdE simp add: algebra_simps)
   308   apply (subst mult_assoc [symmetric])
   309   apply (simp add: no_zero_divisors)
   310   done
   311 
   312 lemma div_mult_swap:
   313   assumes "c dvd b"
   314   shows "a * (b div c) = (a * b) div c"
   315 proof -
   316   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   317     by (simp only: div_mult_div_if_dvd one_dvd)
   318   then show ?thesis by (simp add: mult_commute)
   319 qed
   320    
   321 lemma div_mult_mult2 [simp]:
   322   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   323   by (drule div_mult_mult1) (simp add: mult_commute)
   324 
   325 lemma div_mult_mult1_if [simp]:
   326   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   327   by simp_all
   328 
   329 lemma mod_mult_mult1:
   330   "(c * a) mod (c * b) = c * (a mod b)"
   331 proof (cases "c = 0")
   332   case True then show ?thesis by simp
   333 next
   334   case False
   335   from mod_div_equality
   336   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   337   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   338     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   339   with mod_div_equality show ?thesis by simp 
   340 qed
   341   
   342 lemma mod_mult_mult2:
   343   "(a * c) mod (b * c) = (a mod b) * c"
   344   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   345 
   346 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   347   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   348 
   349 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   350 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   351 
   352 lemma div_power:
   353   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   354 apply (induct n)
   355  apply simp
   356 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   357 done
   358 
   359 lemma dvd_div_eq_mult:
   360   assumes "a \<noteq> 0" and "a dvd b"  
   361   shows "b div a = c \<longleftrightarrow> b = c * a"
   362 proof
   363   assume "b = c * a"
   364   then show "b div a = c" by (simp add: assms)
   365 next
   366   assume "b div a = c"
   367   then have "b div a * a = c * a" by simp
   368   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   369   ultimately show "b = c * a" by simp
   370 qed
   371    
   372 lemma dvd_div_div_eq_mult:
   373   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   374   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   375   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   376 
   377 end
   378 
   379 class ring_div = semiring_div + comm_ring_1
   380 begin
   381 
   382 subclass ring_1_no_zero_divisors ..
   383 
   384 text {* Negation respects modular equivalence. *}
   385 
   386 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   387 proof -
   388   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   389     by (simp only: mod_div_equality)
   390   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   391     by (simp only: minus_add_distrib minus_mult_left add_ac)
   392   also have "\<dots> = (- (a mod b)) mod b"
   393     by (rule mod_mult_self1)
   394   finally show ?thesis .
   395 qed
   396 
   397 lemma mod_minus_cong:
   398   assumes "a mod b = a' mod b"
   399   shows "(- a) mod b = (- a') mod b"
   400 proof -
   401   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   402     unfolding assms ..
   403   thus ?thesis
   404     by (simp only: mod_minus_eq [symmetric])
   405 qed
   406 
   407 text {* Subtraction respects modular equivalence. *}
   408 
   409 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   410   unfolding diff_minus
   411   by (intro mod_add_cong mod_minus_cong) simp_all
   412 
   413 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   414   unfolding diff_minus
   415   by (intro mod_add_cong mod_minus_cong) simp_all
   416 
   417 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   418   unfolding diff_minus
   419   by (intro mod_add_cong mod_minus_cong) simp_all
   420 
   421 lemma mod_diff_cong:
   422   assumes "a mod c = a' mod c"
   423   assumes "b mod c = b' mod c"
   424   shows "(a - b) mod c = (a' - b') mod c"
   425   unfolding diff_minus using assms
   426   by (intro mod_add_cong mod_minus_cong)
   427 
   428 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   429 apply (case_tac "y = 0") apply simp
   430 apply (auto simp add: dvd_def)
   431 apply (subgoal_tac "-(y * k) = y * - k")
   432  apply (erule ssubst)
   433  apply (erule div_mult_self1_is_id)
   434 apply simp
   435 done
   436 
   437 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   438 apply (case_tac "y = 0") apply simp
   439 apply (auto simp add: dvd_def)
   440 apply (subgoal_tac "y * k = -y * -k")
   441  apply (erule ssubst)
   442  apply (rule div_mult_self1_is_id)
   443  apply simp
   444 apply simp
   445 done
   446 
   447 end
   448 
   449 
   450 subsection {* Division on @{typ nat} *}
   451 
   452 text {*
   453   We define @{const div} and @{const mod} on @{typ nat} by means
   454   of a characteristic relation with two input arguments
   455   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   456   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   457 *}
   458 
   459 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   460   "divmod_nat_rel m n qr \<longleftrightarrow>
   461     m = fst qr * n + snd qr \<and>
   462       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   463 
   464 text {* @{const divmod_nat_rel} is total: *}
   465 
   466 lemma divmod_nat_rel_ex:
   467   obtains q r where "divmod_nat_rel m n (q, r)"
   468 proof (cases "n = 0")
   469   case True  with that show thesis
   470     by (auto simp add: divmod_nat_rel_def)
   471 next
   472   case False
   473   have "\<exists>q r. m = q * n + r \<and> r < n"
   474   proof (induct m)
   475     case 0 with `n \<noteq> 0`
   476     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   477     then show ?case by blast
   478   next
   479     case (Suc m) then obtain q' r'
   480       where m: "m = q' * n + r'" and n: "r' < n" by auto
   481     then show ?case proof (cases "Suc r' < n")
   482       case True
   483       from m n have "Suc m = q' * n + Suc r'" by simp
   484       with True show ?thesis by blast
   485     next
   486       case False then have "n \<le> Suc r'" by auto
   487       moreover from n have "Suc r' \<le> n" by auto
   488       ultimately have "n = Suc r'" by auto
   489       with m have "Suc m = Suc q' * n + 0" by simp
   490       with `n \<noteq> 0` show ?thesis by blast
   491     qed
   492   qed
   493   with that show thesis
   494     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   495 qed
   496 
   497 text {* @{const divmod_nat_rel} is injective: *}
   498 
   499 lemma divmod_nat_rel_unique:
   500   assumes "divmod_nat_rel m n qr"
   501     and "divmod_nat_rel m n qr'"
   502   shows "qr = qr'"
   503 proof (cases "n = 0")
   504   case True with assms show ?thesis
   505     by (cases qr, cases qr')
   506       (simp add: divmod_nat_rel_def)
   507 next
   508   case False
   509   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   510   apply (rule leI)
   511   apply (subst less_iff_Suc_add)
   512   apply (auto simp add: add_mult_distrib)
   513   done
   514   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   515     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   516   moreover from this assms have "snd qr = snd qr'"
   517     by (simp add: divmod_nat_rel_def)
   518   ultimately show ?thesis by (cases qr, cases qr') simp
   519 qed
   520 
   521 text {*
   522   We instantiate divisibility on the natural numbers by
   523   means of @{const divmod_nat_rel}:
   524 *}
   525 
   526 instantiation nat :: semiring_div
   527 begin
   528 
   529 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   530   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   531 
   532 lemma divmod_nat_rel_divmod_nat:
   533   "divmod_nat_rel m n (divmod_nat m n)"
   534 proof -
   535   from divmod_nat_rel_ex
   536     obtain qr where rel: "divmod_nat_rel m n qr" .
   537   then show ?thesis
   538   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   539 qed
   540 
   541 lemma divmod_nat_eq:
   542   assumes "divmod_nat_rel m n qr" 
   543   shows "divmod_nat m n = qr"
   544   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   545 
   546 definition div_nat where
   547   "m div n = fst (divmod_nat m n)"
   548 
   549 definition mod_nat where
   550   "m mod n = snd (divmod_nat m n)"
   551 
   552 lemma divmod_nat_div_mod:
   553   "divmod_nat m n = (m div n, m mod n)"
   554   unfolding div_nat_def mod_nat_def by simp
   555 
   556 lemma div_eq:
   557   assumes "divmod_nat_rel m n (q, r)" 
   558   shows "m div n = q"
   559   using assms by (auto dest: divmod_nat_eq simp add: divmod_nat_div_mod)
   560 
   561 lemma mod_eq:
   562   assumes "divmod_nat_rel m n (q, r)" 
   563   shows "m mod n = r"
   564   using assms by (auto dest: divmod_nat_eq simp add: divmod_nat_div_mod)
   565 
   566 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   567   by (simp add: div_nat_def mod_nat_def divmod_nat_rel_divmod_nat)
   568 
   569 lemma divmod_nat_zero:
   570   "divmod_nat m 0 = (0, m)"
   571 proof -
   572   from divmod_nat_rel [of m 0] show ?thesis
   573     unfolding divmod_nat_div_mod divmod_nat_rel_def by simp
   574 qed
   575 
   576 lemma divmod_nat_base:
   577   assumes "m < n"
   578   shows "divmod_nat m n = (0, m)"
   579 proof -
   580   from divmod_nat_rel [of m n] show ?thesis
   581     unfolding divmod_nat_div_mod divmod_nat_rel_def
   582     using assms by (cases "m div n = 0")
   583       (auto simp add: gr0_conv_Suc [of "m div n"])
   584 qed
   585 
   586 lemma divmod_nat_step:
   587   assumes "0 < n" and "n \<le> m"
   588   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   589 proof -
   590   from divmod_nat_rel have divmod_nat_m_n: "divmod_nat_rel m n (m div n, m mod n)" .
   591   with assms have m_div_n: "m div n \<ge> 1"
   592     by (cases "m div n") (auto simp add: divmod_nat_rel_def)
   593   have "divmod_nat_rel (m - n) n (m div n - Suc 0, m mod n)"
   594   proof -
   595     from assms have
   596       "n \<noteq> 0"
   597       "\<And>k. m = Suc k * n + m mod n ==> m - n = (Suc k - Suc 0) * n + m mod n"
   598       by simp_all
   599     then show ?thesis using assms divmod_nat_m_n 
   600       by (cases "m div n")
   601          (simp_all only: divmod_nat_rel_def fst_conv snd_conv, simp_all)
   602   qed
   603   with divmod_nat_eq have "divmod_nat (m - n) n = (m div n - Suc 0, m mod n)" by simp
   604   moreover from divmod_nat_div_mod have "divmod_nat (m - n) n = ((m - n) div n, (m - n) mod n)" .
   605   ultimately have "m div n = Suc ((m - n) div n)"
   606     and "m mod n = (m - n) mod n" using m_div_n by simp_all
   607   then show ?thesis using divmod_nat_div_mod by simp
   608 qed
   609 
   610 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   611 
   612 lemma div_less [simp]:
   613   fixes m n :: nat
   614   assumes "m < n"
   615   shows "m div n = 0"
   616   using assms divmod_nat_base divmod_nat_div_mod by simp
   617 
   618 lemma le_div_geq:
   619   fixes m n :: nat
   620   assumes "0 < n" and "n \<le> m"
   621   shows "m div n = Suc ((m - n) div n)"
   622   using assms divmod_nat_step divmod_nat_div_mod by simp
   623 
   624 lemma mod_less [simp]:
   625   fixes m n :: nat
   626   assumes "m < n"
   627   shows "m mod n = m"
   628   using assms divmod_nat_base divmod_nat_div_mod by simp
   629 
   630 lemma le_mod_geq:
   631   fixes m n :: nat
   632   assumes "n \<le> m"
   633   shows "m mod n = (m - n) mod n"
   634   using assms divmod_nat_step divmod_nat_div_mod by (cases "n = 0") simp_all
   635 
   636 instance proof -
   637   have [simp]: "\<And>n::nat. n div 0 = 0"
   638     by (simp add: div_nat_def divmod_nat_zero)
   639   have [simp]: "\<And>n::nat. 0 div n = 0"
   640   proof -
   641     fix n :: nat
   642     show "0 div n = 0"
   643       by (cases "n = 0") simp_all
   644   qed
   645   show "OFCLASS(nat, semiring_div_class)" proof
   646     fix m n :: nat
   647     show "m div n * n + m mod n = m"
   648       using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   649   next
   650     fix m n q :: nat
   651     assume "n \<noteq> 0"
   652     then show "(q + m * n) div n = m + q div n"
   653       by (induct m) (simp_all add: le_div_geq)
   654   next
   655     fix m n q :: nat
   656     assume "m \<noteq> 0"
   657     then show "(m * n) div (m * q) = n div q"
   658     proof (cases "n \<noteq> 0 \<and> q \<noteq> 0")
   659       case False then show ?thesis by auto
   660     next
   661       case True with `m \<noteq> 0`
   662         have "m > 0" and "n > 0" and "q > 0" by auto
   663       then have "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   664         by (auto simp add: divmod_nat_rel_def) (simp_all add: algebra_simps)
   665       moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   666       ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   667       then show ?thesis by (simp add: div_eq)
   668     qed
   669   qed simp_all
   670 qed
   671 
   672 end
   673 
   674 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   675   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   676 by (simp add: divmod_nat_zero divmod_nat_base divmod_nat_step)
   677     (simp add: divmod_nat_div_mod)
   678 
   679 text {* Simproc for cancelling @{const div} and @{const mod} *}
   680 
   681 ML {*
   682 local
   683 
   684 structure CancelDivMod = CancelDivModFun
   685 (
   686   val div_name = @{const_name div};
   687   val mod_name = @{const_name mod};
   688   val mk_binop = HOLogic.mk_binop;
   689   val mk_sum = Nat_Arith.mk_sum;
   690   val dest_sum = Nat_Arith.dest_sum;
   691 
   692   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   693 
   694   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   695     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   696 )
   697 
   698 in
   699 
   700 val cancel_div_mod_nat_proc = Simplifier.simproc_global @{theory}
   701   "cancel_div_mod" ["(m::nat) + n"] (K CancelDivMod.proc);
   702 
   703 val _ = Addsimprocs [cancel_div_mod_nat_proc];
   704 
   705 end
   706 *}
   707 
   708 
   709 subsubsection {* Quotient *}
   710 
   711 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   712 by (simp add: le_div_geq linorder_not_less)
   713 
   714 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   715 by (simp add: div_geq)
   716 
   717 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   718 by simp
   719 
   720 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   721 by simp
   722 
   723 
   724 subsubsection {* Remainder *}
   725 
   726 lemma mod_less_divisor [simp]:
   727   fixes m n :: nat
   728   assumes "n > 0"
   729   shows "m mod n < (n::nat)"
   730   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   731 
   732 lemma mod_less_eq_dividend [simp]:
   733   fixes m n :: nat
   734   shows "m mod n \<le> m"
   735 proof (rule add_leD2)
   736   from mod_div_equality have "m div n * n + m mod n = m" .
   737   then show "m div n * n + m mod n \<le> m" by auto
   738 qed
   739 
   740 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   741 by (simp add: le_mod_geq linorder_not_less)
   742 
   743 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   744 by (simp add: le_mod_geq)
   745 
   746 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   747 by (induct m) (simp_all add: mod_geq)
   748 
   749 lemma mod_mult_distrib: "(m mod n) * (k\<Colon>nat) = (m * k) mod (n * k)"
   750   apply (cases "n = 0", simp)
   751   apply (cases "k = 0", simp)
   752   apply (induct m rule: nat_less_induct)
   753   apply (subst mod_if, simp)
   754   apply (simp add: mod_geq diff_mult_distrib)
   755   done
   756 
   757 lemma mod_mult_distrib2: "(k::nat) * (m mod n) = (k*m) mod (k*n)"
   758 by (simp add: mult_commute [of k] mod_mult_distrib)
   759 
   760 (* a simple rearrangement of mod_div_equality: *)
   761 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   762 by (cut_tac a = m and b = n in mod_div_equality2, arith)
   763 
   764 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   765   apply (drule mod_less_divisor [where m = m])
   766   apply simp
   767   done
   768 
   769 subsubsection {* Quotient and Remainder *}
   770 
   771 lemma divmod_nat_rel_mult1_eq:
   772   "divmod_nat_rel b c (q, r) \<Longrightarrow> c > 0
   773    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   774 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   775 
   776 lemma div_mult1_eq:
   777   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   778 apply (cases "c = 0", simp)
   779 apply (blast intro: divmod_nat_rel [THEN divmod_nat_rel_mult1_eq, THEN div_eq])
   780 done
   781 
   782 lemma divmod_nat_rel_add1_eq:
   783   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br) \<Longrightarrow>  c > 0
   784    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   785 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   786 
   787 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   788 lemma div_add1_eq:
   789   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   790 apply (cases "c = 0", simp)
   791 apply (blast intro: divmod_nat_rel_add1_eq [THEN div_eq] divmod_nat_rel)
   792 done
   793 
   794 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   795   apply (cut_tac m = q and n = c in mod_less_divisor)
   796   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   797   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   798   apply (simp add: add_mult_distrib2)
   799   done
   800 
   801 lemma divmod_nat_rel_mult2_eq:
   802   "divmod_nat_rel a b (q, r) \<Longrightarrow> 0 < b \<Longrightarrow> 0 < c
   803    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   804 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   805 
   806 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   807   apply (cases "b = 0", simp)
   808   apply (cases "c = 0", simp)
   809   apply (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_eq])
   810   done
   811 
   812 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   813   apply (cases "b = 0", simp)
   814   apply (cases "c = 0", simp)
   815   apply (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_eq])
   816   done
   817 
   818 
   819 subsubsection{*Further Facts about Quotient and Remainder*}
   820 
   821 lemma div_1 [simp]: "m div Suc 0 = m"
   822 by (induct m) (simp_all add: div_geq)
   823 
   824 
   825 (* Monotonicity of div in first argument *)
   826 lemma div_le_mono [rule_format (no_asm)]:
   827     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   828 apply (case_tac "k=0", simp)
   829 apply (induct "n" rule: nat_less_induct, clarify)
   830 apply (case_tac "n<k")
   831 (* 1  case n<k *)
   832 apply simp
   833 (* 2  case n >= k *)
   834 apply (case_tac "m<k")
   835 (* 2.1  case m<k *)
   836 apply simp
   837 (* 2.2  case m>=k *)
   838 apply (simp add: div_geq diff_le_mono)
   839 done
   840 
   841 (* Antimonotonicity of div in second argument *)
   842 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   843 apply (subgoal_tac "0<n")
   844  prefer 2 apply simp
   845 apply (induct_tac k rule: nat_less_induct)
   846 apply (rename_tac "k")
   847 apply (case_tac "k<n", simp)
   848 apply (subgoal_tac "~ (k<m) ")
   849  prefer 2 apply simp
   850 apply (simp add: div_geq)
   851 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   852  prefer 2
   853  apply (blast intro: div_le_mono diff_le_mono2)
   854 apply (rule le_trans, simp)
   855 apply (simp)
   856 done
   857 
   858 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   859 apply (case_tac "n=0", simp)
   860 apply (subgoal_tac "m div n \<le> m div 1", simp)
   861 apply (rule div_le_mono2)
   862 apply (simp_all (no_asm_simp))
   863 done
   864 
   865 (* Similar for "less than" *)
   866 lemma div_less_dividend [rule_format]:
   867      "!!n::nat. 1<n ==> 0 < m --> m div n < m"
   868 apply (induct_tac m rule: nat_less_induct)
   869 apply (rename_tac "m")
   870 apply (case_tac "m<n", simp)
   871 apply (subgoal_tac "0<n")
   872  prefer 2 apply simp
   873 apply (simp add: div_geq)
   874 apply (case_tac "n<m")
   875  apply (subgoal_tac "(m-n) div n < (m-n) ")
   876   apply (rule impI less_trans_Suc)+
   877 apply assumption
   878   apply (simp_all)
   879 done
   880 
   881 declare div_less_dividend [simp]
   882 
   883 text{*A fact for the mutilated chess board*}
   884 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   885 apply (case_tac "n=0", simp)
   886 apply (induct "m" rule: nat_less_induct)
   887 apply (case_tac "Suc (na) <n")
   888 (* case Suc(na) < n *)
   889 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   890 (* case n \<le> Suc(na) *)
   891 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   892 apply (auto simp add: Suc_diff_le le_mod_geq)
   893 done
   894 
   895 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   896 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   897 
   898 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   899 
   900 (*Loses information, namely we also have r<d provided d is nonzero*)
   901 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   902   apply (cut_tac a = m in mod_div_equality)
   903   apply (simp only: add_ac)
   904   apply (blast intro: sym)
   905   done
   906 
   907 lemma split_div:
   908  "P(n div k :: nat) =
   909  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   910  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   911 proof
   912   assume P: ?P
   913   show ?Q
   914   proof (cases)
   915     assume "k = 0"
   916     with P show ?Q by simp
   917   next
   918     assume not0: "k \<noteq> 0"
   919     thus ?Q
   920     proof (simp, intro allI impI)
   921       fix i j
   922       assume n: "n = k*i + j" and j: "j < k"
   923       show "P i"
   924       proof (cases)
   925         assume "i = 0"
   926         with n j P show "P i" by simp
   927       next
   928         assume "i \<noteq> 0"
   929         with not0 n j P show "P i" by(simp add:add_ac)
   930       qed
   931     qed
   932   qed
   933 next
   934   assume Q: ?Q
   935   show ?P
   936   proof (cases)
   937     assume "k = 0"
   938     with Q show ?P by simp
   939   next
   940     assume not0: "k \<noteq> 0"
   941     with Q have R: ?R by simp
   942     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   943     show ?P by simp
   944   qed
   945 qed
   946 
   947 lemma split_div_lemma:
   948   assumes "0 < n"
   949   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   950 proof
   951   assume ?rhs
   952   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   953   then have A: "n * q \<le> m" by simp
   954   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   955   then have "m < m + (n - (m mod n))" by simp
   956   then have "m < n + (m - (m mod n))" by simp
   957   with nq have "m < n + n * q" by simp
   958   then have B: "m < n * Suc q" by simp
   959   from A B show ?lhs ..
   960 next
   961   assume P: ?lhs
   962   then have "divmod_nat_rel m n (q, m - n * q)"
   963     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   964   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   965   have "(q, m - n * q) = (m div n, m mod n)" by auto
   966   then show ?rhs by simp
   967 qed
   968 
   969 theorem split_div':
   970   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   971    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   972   apply (case_tac "0 < n")
   973   apply (simp only: add: split_div_lemma)
   974   apply simp_all
   975   done
   976 
   977 lemma split_mod:
   978  "P(n mod k :: nat) =
   979  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   980  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   981 proof
   982   assume P: ?P
   983   show ?Q
   984   proof (cases)
   985     assume "k = 0"
   986     with P show ?Q by simp
   987   next
   988     assume not0: "k \<noteq> 0"
   989     thus ?Q
   990     proof (simp, intro allI impI)
   991       fix i j
   992       assume "n = k*i + j" "j < k"
   993       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   994     qed
   995   qed
   996 next
   997   assume Q: ?Q
   998   show ?P
   999   proof (cases)
  1000     assume "k = 0"
  1001     with Q show ?P by simp
  1002   next
  1003     assume not0: "k \<noteq> 0"
  1004     with Q have R: ?R by simp
  1005     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
  1006     show ?P by simp
  1007   qed
  1008 qed
  1009 
  1010 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
  1011   apply (rule_tac P="%x. m mod n = x - (m div n) * n" in
  1012     subst [OF mod_div_equality [of _ n]])
  1013   apply arith
  1014   done
  1015 
  1016 lemma div_mod_equality':
  1017   fixes m n :: nat
  1018   shows "m div n * n = m - m mod n"
  1019 proof -
  1020   have "m mod n \<le> m mod n" ..
  1021   from div_mod_equality have 
  1022     "m div n * n + m mod n - m mod n = m - m mod n" by simp
  1023   with diff_add_assoc [OF `m mod n \<le> m mod n`, of "m div n * n"] have
  1024     "m div n * n + (m mod n - m mod n) = m - m mod n"
  1025     by simp
  1026   then show ?thesis by simp
  1027 qed
  1028 
  1029 
  1030 subsubsection {*An ``induction'' law for modulus arithmetic.*}
  1031 
  1032 lemma mod_induct_0:
  1033   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1034   and base: "P i" and i: "i<p"
  1035   shows "P 0"
  1036 proof (rule ccontr)
  1037   assume contra: "\<not>(P 0)"
  1038   from i have p: "0<p" by simp
  1039   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1040   proof
  1041     fix k
  1042     show "?A k"
  1043     proof (induct k)
  1044       show "?A 0" by simp  -- "by contradiction"
  1045     next
  1046       fix n
  1047       assume ih: "?A n"
  1048       show "?A (Suc n)"
  1049       proof (clarsimp)
  1050         assume y: "P (p - Suc n)"
  1051         have n: "Suc n < p"
  1052         proof (rule ccontr)
  1053           assume "\<not>(Suc n < p)"
  1054           hence "p - Suc n = 0"
  1055             by simp
  1056           with y contra show "False"
  1057             by simp
  1058         qed
  1059         hence n2: "Suc (p - Suc n) = p-n" by arith
  1060         from p have "p - Suc n < p" by arith
  1061         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1062           by blast
  1063         show "False"
  1064         proof (cases "n=0")
  1065           case True
  1066           with z n2 contra show ?thesis by simp
  1067         next
  1068           case False
  1069           with p have "p-n < p" by arith
  1070           with z n2 False ih show ?thesis by simp
  1071         qed
  1072       qed
  1073     qed
  1074   qed
  1075   moreover
  1076   from i obtain k where "0<k \<and> i+k=p"
  1077     by (blast dest: less_imp_add_positive)
  1078   hence "0<k \<and> i=p-k" by auto
  1079   moreover
  1080   note base
  1081   ultimately
  1082   show "False" by blast
  1083 qed
  1084 
  1085 lemma mod_induct:
  1086   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1087   and base: "P i" and i: "i<p" and j: "j<p"
  1088   shows "P j"
  1089 proof -
  1090   have "\<forall>j<p. P j"
  1091   proof
  1092     fix j
  1093     show "j<p \<longrightarrow> P j" (is "?A j")
  1094     proof (induct j)
  1095       from step base i show "?A 0"
  1096         by (auto elim: mod_induct_0)
  1097     next
  1098       fix k
  1099       assume ih: "?A k"
  1100       show "?A (Suc k)"
  1101       proof
  1102         assume suc: "Suc k < p"
  1103         hence k: "k<p" by simp
  1104         with ih have "P k" ..
  1105         with step k have "P (Suc k mod p)"
  1106           by blast
  1107         moreover
  1108         from suc have "Suc k mod p = Suc k"
  1109           by simp
  1110         ultimately
  1111         show "P (Suc k)" by simp
  1112       qed
  1113     qed
  1114   qed
  1115   with j show ?thesis by blast
  1116 qed
  1117 
  1118 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1119 by (auto simp add: numeral_2_eq_2 le_div_geq)
  1120 
  1121 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1122 by (simp add: nat_mult_2 [symmetric])
  1123 
  1124 lemma mod2_Suc_Suc [simp]: "Suc(Suc(m)) mod 2 = m mod 2"
  1125 apply (subgoal_tac "m mod 2 < 2")
  1126 apply (erule less_2_cases [THEN disjE])
  1127 apply (simp_all (no_asm_simp) add: Let_def mod_Suc)
  1128 done
  1129 
  1130 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1131 proof -
  1132   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1133   moreover have "m mod 2 < 2" by simp
  1134   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1135   then show ?thesis by auto
  1136 qed
  1137 
  1138 text{*These lemmas collapse some needless occurrences of Suc:
  1139     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1140     We already have some rules to simplify operands smaller than 3.*}
  1141 
  1142 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1143 by (simp add: Suc3_eq_add_3)
  1144 
  1145 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1146 by (simp add: Suc3_eq_add_3)
  1147 
  1148 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1149 by (simp add: Suc3_eq_add_3)
  1150 
  1151 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1152 by (simp add: Suc3_eq_add_3)
  1153 
  1154 lemmas Suc_div_eq_add3_div_number_of =
  1155     Suc_div_eq_add3_div [of _ "number_of v", standard]
  1156 declare Suc_div_eq_add3_div_number_of [simp]
  1157 
  1158 lemmas Suc_mod_eq_add3_mod_number_of =
  1159     Suc_mod_eq_add3_mod [of _ "number_of v", standard]
  1160 declare Suc_mod_eq_add3_mod_number_of [simp]
  1161 
  1162 
  1163 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1164 apply (induct "m")
  1165 apply (simp_all add: mod_Suc)
  1166 done
  1167 
  1168 declare Suc_times_mod_eq [of "number_of w", standard, simp]
  1169 
  1170 lemma [simp]: "n div k \<le> (Suc n) div k"
  1171 by (simp add: div_le_mono) 
  1172 
  1173 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1174 by (cases n) simp_all
  1175 
  1176 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1177 proof -
  1178   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1179   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1180 qed
  1181 
  1182   (* Potential use of algebra : Equality modulo n*)
  1183 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1184 by (simp add: mult_ac add_ac)
  1185 
  1186 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1187 proof -
  1188   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1189   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1190   finally show ?thesis .
  1191 qed
  1192 
  1193 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1194 apply (subst mod_Suc [of m]) 
  1195 apply (subst mod_Suc [of "m mod n"], simp) 
  1196 done
  1197 
  1198 
  1199 subsection {* Division on @{typ int} *}
  1200 
  1201 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1202     --{*definition of quotient and remainder*}
  1203     [code]: "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1204                (if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0))"
  1205 
  1206 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1207     --{*for the division algorithm*}
  1208     [code]: "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1209                          else (2 * q, r))"
  1210 
  1211 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1212 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1213   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1214      else adjust b (posDivAlg a (2 * b)))"
  1215 by auto
  1216 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1217   (auto simp add: mult_2)
  1218 
  1219 text{*algorithm for the case @{text "a<0, b>0"}*}
  1220 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1221   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1222      else adjust b (negDivAlg a (2 * b)))"
  1223 by auto
  1224 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1225   (auto simp add: mult_2)
  1226 
  1227 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1228 definition negateSnd :: "int \<times> int \<Rightarrow> int \<times> int" where
  1229   [code_unfold]: "negateSnd = apsnd uminus"
  1230 
  1231 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1232     --{*The full division algorithm considers all possible signs for a, b
  1233        including the special case @{text "a=0, b<0"} because 
  1234        @{term negDivAlg} requires @{term "a<0"}.*}
  1235   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1236                   else if a = 0 then (0, 0)
  1237                        else negateSnd (negDivAlg (-a) (-b))
  1238                else 
  1239                   if 0 < b then negDivAlg a b
  1240                   else negateSnd (posDivAlg (-a) (-b)))"
  1241 
  1242 instantiation int :: Divides.div
  1243 begin
  1244 
  1245 definition
  1246   "a div b = fst (divmod_int a b)"
  1247 
  1248 definition
  1249  "a mod b = snd (divmod_int a b)"
  1250 
  1251 instance ..
  1252 
  1253 end
  1254 
  1255 lemma divmod_int_mod_div:
  1256   "divmod_int p q = (p div q, p mod q)"
  1257   by (auto simp add: div_int_def mod_int_def)
  1258 
  1259 text{*
  1260 Here is the division algorithm in ML:
  1261 
  1262 \begin{verbatim}
  1263     fun posDivAlg (a,b) =
  1264       if a<b then (0,a)
  1265       else let val (q,r) = posDivAlg(a, 2*b)
  1266                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1267            end
  1268 
  1269     fun negDivAlg (a,b) =
  1270       if 0\<le>a+b then (~1,a+b)
  1271       else let val (q,r) = negDivAlg(a, 2*b)
  1272                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1273            end;
  1274 
  1275     fun negateSnd (q,r:int) = (q,~r);
  1276 
  1277     fun divmod (a,b) = if 0\<le>a then 
  1278                           if b>0 then posDivAlg (a,b) 
  1279                            else if a=0 then (0,0)
  1280                                 else negateSnd (negDivAlg (~a,~b))
  1281                        else 
  1282                           if 0<b then negDivAlg (a,b)
  1283                           else        negateSnd (posDivAlg (~a,~b));
  1284 \end{verbatim}
  1285 *}
  1286 
  1287 
  1288 
  1289 subsubsection{*Uniqueness and Monotonicity of Quotients and Remainders*}
  1290 
  1291 lemma unique_quotient_lemma:
  1292      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1293       ==> q' \<le> (q::int)"
  1294 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1295  prefer 2 apply (simp add: right_diff_distrib)
  1296 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1297 apply (erule_tac [2] order_le_less_trans)
  1298  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1299 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1300  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1301 apply (simp add: mult_less_cancel_left)
  1302 done
  1303 
  1304 lemma unique_quotient_lemma_neg:
  1305      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1306       ==> q \<le> (q'::int)"
  1307 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1308     auto)
  1309 
  1310 lemma unique_quotient:
  1311      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r');  b \<noteq> 0 |]  
  1312       ==> q = q'"
  1313 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1314 apply (blast intro: order_antisym
  1315              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1316              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1317 done
  1318 
  1319 
  1320 lemma unique_remainder:
  1321      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r');  b \<noteq> 0 |]  
  1322       ==> r = r'"
  1323 apply (subgoal_tac "q = q'")
  1324  apply (simp add: divmod_int_rel_def)
  1325 apply (blast intro: unique_quotient)
  1326 done
  1327 
  1328 
  1329 subsubsection{*Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends*}
  1330 
  1331 text{*And positive divisors*}
  1332 
  1333 lemma adjust_eq [simp]:
  1334      "adjust b (q,r) = 
  1335       (let diff = r-b in  
  1336         if 0 \<le> diff then (2*q + 1, diff)   
  1337                      else (2*q, r))"
  1338 by (simp add: Let_def adjust_def)
  1339 
  1340 declare posDivAlg.simps [simp del]
  1341 
  1342 text{*use with a simproc to avoid repeatedly proving the premise*}
  1343 lemma posDivAlg_eqn:
  1344      "0 < b ==>  
  1345       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1346 by (rule posDivAlg.simps [THEN trans], simp)
  1347 
  1348 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1349 theorem posDivAlg_correct:
  1350   assumes "0 \<le> a" and "0 < b"
  1351   shows "divmod_int_rel a b (posDivAlg a b)"
  1352   using assms
  1353   apply (induct a b rule: posDivAlg.induct)
  1354   apply auto
  1355   apply (simp add: divmod_int_rel_def)
  1356   apply (subst posDivAlg_eqn, simp add: right_distrib)
  1357   apply (case_tac "a < b")
  1358   apply simp_all
  1359   apply (erule splitE)
  1360   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1361   done
  1362 
  1363 
  1364 subsubsection{*Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends*}
  1365 
  1366 text{*And positive divisors*}
  1367 
  1368 declare negDivAlg.simps [simp del]
  1369 
  1370 text{*use with a simproc to avoid repeatedly proving the premise*}
  1371 lemma negDivAlg_eqn:
  1372      "0 < b ==>  
  1373       negDivAlg a b =       
  1374        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1375 by (rule negDivAlg.simps [THEN trans], simp)
  1376 
  1377 (*Correctness of negDivAlg: it computes quotients correctly
  1378   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1379 lemma negDivAlg_correct:
  1380   assumes "a < 0" and "b > 0"
  1381   shows "divmod_int_rel a b (negDivAlg a b)"
  1382   using assms
  1383   apply (induct a b rule: negDivAlg.induct)
  1384   apply (auto simp add: linorder_not_le)
  1385   apply (simp add: divmod_int_rel_def)
  1386   apply (subst negDivAlg_eqn, assumption)
  1387   apply (case_tac "a + b < (0\<Colon>int)")
  1388   apply simp_all
  1389   apply (erule splitE)
  1390   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1391   done
  1392 
  1393 
  1394 subsubsection{*Existence Shown by Proving the Division Algorithm to be Correct*}
  1395 
  1396 (*the case a=0*)
  1397 lemma divmod_int_rel_0: "b \<noteq> 0 ==> divmod_int_rel 0 b (0, 0)"
  1398 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1399 
  1400 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1401 by (subst posDivAlg.simps, auto)
  1402 
  1403 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1404 by (subst negDivAlg.simps, auto)
  1405 
  1406 lemma negateSnd_eq [simp]: "negateSnd(q,r) = (q,-r)"
  1407 by (simp add: negateSnd_def)
  1408 
  1409 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (negateSnd qr)"
  1410 by (auto simp add: split_ifs divmod_int_rel_def)
  1411 
  1412 lemma divmod_int_correct: "b \<noteq> 0 ==> divmod_int_rel a b (divmod_int a b)"
  1413 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1414                     posDivAlg_correct negDivAlg_correct)
  1415 
  1416 text{*Arbitrary definitions for division by zero.  Useful to simplify 
  1417     certain equations.*}
  1418 
  1419 lemma DIVISION_BY_ZERO [simp]: "a div (0::int) = 0 & a mod (0::int) = a"
  1420 by (simp add: div_int_def mod_int_def divmod_int_def posDivAlg.simps)  
  1421 
  1422 
  1423 text{*Basic laws about division and remainder*}
  1424 
  1425 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1426 apply (case_tac "b = 0", simp)
  1427 apply (cut_tac a = a and b = b in divmod_int_correct)
  1428 apply (auto simp add: divmod_int_rel_def div_int_def mod_int_def)
  1429 done
  1430 
  1431 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
  1432 by(simp add: zmod_zdiv_equality[symmetric])
  1433 
  1434 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
  1435 by(simp add: mult_commute zmod_zdiv_equality[symmetric])
  1436 
  1437 text {* Tool setup *}
  1438 
  1439 ML {*
  1440 local
  1441 
  1442 structure CancelDivMod = CancelDivModFun
  1443 (
  1444   val div_name = @{const_name div};
  1445   val mod_name = @{const_name mod};
  1446   val mk_binop = HOLogic.mk_binop;
  1447   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1448   val dest_sum = Arith_Data.dest_sum;
  1449 
  1450   val div_mod_eqs = map mk_meta_eq [@{thm zdiv_zmod_equality}, @{thm zdiv_zmod_equality2}];
  1451 
  1452   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1453     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1454 )
  1455 
  1456 in
  1457 
  1458 val cancel_div_mod_int_proc = Simplifier.simproc_global @{theory}
  1459   "cancel_zdiv_zmod" ["(k::int) + l"] (K CancelDivMod.proc);
  1460 
  1461 val _ = Addsimprocs [cancel_div_mod_int_proc];
  1462 
  1463 end
  1464 *}
  1465 
  1466 lemma pos_mod_conj : "(0::int) < b ==> 0 \<le> a mod b & a mod b < b"
  1467 apply (cut_tac a = a and b = b in divmod_int_correct)
  1468 apply (auto simp add: divmod_int_rel_def mod_int_def)
  1469 done
  1470 
  1471 lemmas pos_mod_sign  [simp] = pos_mod_conj [THEN conjunct1, standard]
  1472    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2, standard]
  1473 
  1474 lemma neg_mod_conj : "b < (0::int) ==> a mod b \<le> 0 & b < a mod b"
  1475 apply (cut_tac a = a and b = b in divmod_int_correct)
  1476 apply (auto simp add: divmod_int_rel_def div_int_def mod_int_def)
  1477 done
  1478 
  1479 lemmas neg_mod_sign  [simp] = neg_mod_conj [THEN conjunct1, standard]
  1480    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2, standard]
  1481 
  1482 
  1483 
  1484 subsubsection{*General Properties of div and mod*}
  1485 
  1486 lemma divmod_int_rel_div_mod: "b \<noteq> 0 ==> divmod_int_rel a b (a div b, a mod b)"
  1487 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1488 apply (force simp add: divmod_int_rel_def linorder_neq_iff)
  1489 done
  1490 
  1491 lemma divmod_int_rel_div: "[| divmod_int_rel a b (q, r);  b \<noteq> 0 |] ==> a div b = q"
  1492 by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1493 
  1494 lemma divmod_int_rel_mod: "[| divmod_int_rel a b (q, r);  b \<noteq> 0 |] ==> a mod b = r"
  1495 by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1496 
  1497 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1498 apply (rule divmod_int_rel_div)
  1499 apply (auto simp add: divmod_int_rel_def)
  1500 done
  1501 
  1502 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1503 apply (rule divmod_int_rel_div)
  1504 apply (auto simp add: divmod_int_rel_def)
  1505 done
  1506 
  1507 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1508 apply (rule divmod_int_rel_div)
  1509 apply (auto simp add: divmod_int_rel_def)
  1510 done
  1511 
  1512 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1513 
  1514 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1515 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1516 apply (auto simp add: divmod_int_rel_def)
  1517 done
  1518 
  1519 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1520 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1521 apply (auto simp add: divmod_int_rel_def)
  1522 done
  1523 
  1524 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1525 apply (rule_tac q = "-1" in divmod_int_rel_mod)
  1526 apply (auto simp add: divmod_int_rel_def)
  1527 done
  1528 
  1529 text{*There is no @{text mod_neg_pos_trivial}.*}
  1530 
  1531 
  1532 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)
  1533 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"
  1534 apply (case_tac "b = 0", simp)
  1535 apply (simp add: divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, 
  1536                                  THEN divmod_int_rel_div, THEN sym])
  1537 
  1538 done
  1539 
  1540 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)
  1541 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"
  1542 apply (case_tac "b = 0", simp)
  1543 apply (subst divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, THEN divmod_int_rel_mod],
  1544        auto)
  1545 done
  1546 
  1547 
  1548 subsubsection{*Laws for div and mod with Unary Minus*}
  1549 
  1550 lemma zminus1_lemma:
  1551      "divmod_int_rel a b (q, r)
  1552       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1553                           if r=0 then 0 else b-r)"
  1554 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1555 
  1556 
  1557 lemma zdiv_zminus1_eq_if:
  1558      "b \<noteq> (0::int)  
  1559       ==> (-a) div b =  
  1560           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1561 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_div])
  1562 
  1563 lemma zmod_zminus1_eq_if:
  1564      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1565 apply (case_tac "b = 0", simp)
  1566 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_mod])
  1567 done
  1568 
  1569 lemma zmod_zminus1_not_zero:
  1570   fixes k l :: int
  1571   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1572   unfolding zmod_zminus1_eq_if by auto
  1573 
  1574 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"
  1575 by (cut_tac a = "-a" in zdiv_zminus_zminus, auto)
  1576 
  1577 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"
  1578 by (cut_tac a = "-a" and b = b in zmod_zminus_zminus, auto)
  1579 
  1580 lemma zdiv_zminus2_eq_if:
  1581      "b \<noteq> (0::int)  
  1582       ==> a div (-b) =  
  1583           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1584 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)
  1585 
  1586 lemma zmod_zminus2_eq_if:
  1587      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1588 by (simp add: zmod_zminus1_eq_if zmod_zminus2)
  1589 
  1590 lemma zmod_zminus2_not_zero:
  1591   fixes k l :: int
  1592   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1593   unfolding zmod_zminus2_eq_if by auto 
  1594 
  1595 
  1596 subsubsection{*Division of a Number by Itself*}
  1597 
  1598 lemma self_quotient_aux1: "[| (0::int) < a; a = r + a*q; r < a |] ==> 1 \<le> q"
  1599 apply (subgoal_tac "0 < a*q")
  1600  apply (simp add: zero_less_mult_iff, arith)
  1601 done
  1602 
  1603 lemma self_quotient_aux2: "[| (0::int) < a; a = r + a*q; 0 \<le> r |] ==> q \<le> 1"
  1604 apply (subgoal_tac "0 \<le> a* (1-q) ")
  1605  apply (simp add: zero_le_mult_iff)
  1606 apply (simp add: right_diff_distrib)
  1607 done
  1608 
  1609 lemma self_quotient: "[| divmod_int_rel a a (q, r);  a \<noteq> (0::int) |] ==> q = 1"
  1610 apply (simp add: split_ifs divmod_int_rel_def linorder_neq_iff)
  1611 apply (rule order_antisym, safe, simp_all)
  1612 apply (rule_tac [3] a = "-a" and r = "-r" in self_quotient_aux1)
  1613 apply (rule_tac a = "-a" and r = "-r" in self_quotient_aux2)
  1614 apply (force intro: self_quotient_aux1 self_quotient_aux2 simp add: add_commute)+
  1615 done
  1616 
  1617 lemma self_remainder: "[| divmod_int_rel a a (q, r);  a \<noteq> (0::int) |] ==> r = 0"
  1618 apply (frule self_quotient, assumption)
  1619 apply (simp add: divmod_int_rel_def)
  1620 done
  1621 
  1622 lemma zdiv_self [simp]: "a \<noteq> 0 ==> a div a = (1::int)"
  1623 by (simp add: divmod_int_rel_div_mod [THEN self_quotient])
  1624 
  1625 (*Here we have 0 mod 0 = 0, also assumed by Knuth (who puts m mod 0 = 0) *)
  1626 lemma zmod_self [simp]: "a mod a = (0::int)"
  1627 apply (case_tac "a = 0", simp)
  1628 apply (simp add: divmod_int_rel_div_mod [THEN self_remainder])
  1629 done
  1630 
  1631 
  1632 subsubsection{*Computation of Division and Remainder*}
  1633 
  1634 lemma zdiv_zero [simp]: "(0::int) div b = 0"
  1635 by (simp add: div_int_def divmod_int_def)
  1636 
  1637 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1638 by (simp add: div_int_def divmod_int_def)
  1639 
  1640 lemma zmod_zero [simp]: "(0::int) mod b = 0"
  1641 by (simp add: mod_int_def divmod_int_def)
  1642 
  1643 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1644 by (simp add: mod_int_def divmod_int_def)
  1645 
  1646 text{*a positive, b positive *}
  1647 
  1648 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1649 by (simp add: div_int_def divmod_int_def)
  1650 
  1651 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1652 by (simp add: mod_int_def divmod_int_def)
  1653 
  1654 text{*a negative, b positive *}
  1655 
  1656 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1657 by (simp add: div_int_def divmod_int_def)
  1658 
  1659 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1660 by (simp add: mod_int_def divmod_int_def)
  1661 
  1662 text{*a positive, b negative *}
  1663 
  1664 lemma div_pos_neg:
  1665      "[| 0 < a;  b < 0 |] ==> a div b = fst (negateSnd (negDivAlg (-a) (-b)))"
  1666 by (simp add: div_int_def divmod_int_def)
  1667 
  1668 lemma mod_pos_neg:
  1669      "[| 0 < a;  b < 0 |] ==> a mod b = snd (negateSnd (negDivAlg (-a) (-b)))"
  1670 by (simp add: mod_int_def divmod_int_def)
  1671 
  1672 text{*a negative, b negative *}
  1673 
  1674 lemma div_neg_neg:
  1675      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (negateSnd (posDivAlg (-a) (-b)))"
  1676 by (simp add: div_int_def divmod_int_def)
  1677 
  1678 lemma mod_neg_neg:
  1679      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (negateSnd (posDivAlg (-a) (-b)))"
  1680 by (simp add: mod_int_def divmod_int_def)
  1681 
  1682 text {*Simplify expresions in which div and mod combine numerical constants*}
  1683 
  1684 lemma divmod_int_relI:
  1685   "\<lbrakk>a == b * q + r; if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0\<rbrakk>
  1686     \<Longrightarrow> divmod_int_rel a b (q, r)"
  1687   unfolding divmod_int_rel_def by simp
  1688 
  1689 lemmas divmod_int_rel_div_eq = divmod_int_relI [THEN divmod_int_rel_div, THEN eq_reflection]
  1690 lemmas divmod_int_rel_mod_eq = divmod_int_relI [THEN divmod_int_rel_mod, THEN eq_reflection]
  1691 lemmas arithmetic_simps =
  1692   arith_simps
  1693   add_special
  1694   add_0_left
  1695   add_0_right
  1696   mult_zero_left
  1697   mult_zero_right
  1698   mult_1_left
  1699   mult_1_right
  1700 
  1701 (* simprocs adapted from HOL/ex/Binary.thy *)
  1702 ML {*
  1703 local
  1704   val mk_number = HOLogic.mk_number HOLogic.intT;
  1705   fun mk_cert u k l = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"} $
  1706     (@{term "times :: int \<Rightarrow> int \<Rightarrow> int"} $ u $ mk_number k) $
  1707       mk_number l;
  1708   fun prove ctxt prop = Goal.prove ctxt [] [] prop
  1709     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps @{thms arithmetic_simps}))));
  1710   fun binary_proc proc ss ct =
  1711     (case Thm.term_of ct of
  1712       _ $ t $ u =>
  1713       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1714         SOME args => proc (Simplifier.the_context ss) args
  1715       | NONE => NONE)
  1716     | _ => NONE);
  1717 in
  1718   fun divmod_proc rule = binary_proc (fn ctxt => fn ((m, t), (n, u)) =>
  1719     if n = 0 then NONE
  1720     else let val (k, l) = Integer.div_mod m n;
  1721     in SOME (rule OF [prove ctxt (Logic.mk_equals (t, mk_cert u k l))]) end);
  1722 end
  1723 *}
  1724 
  1725 simproc_setup binary_int_div ("number_of m div number_of n :: int") =
  1726   {* K (divmod_proc (@{thm divmod_int_rel_div_eq})) *}
  1727 
  1728 simproc_setup binary_int_mod ("number_of m mod number_of n :: int") =
  1729   {* K (divmod_proc (@{thm divmod_int_rel_mod_eq})) *}
  1730 
  1731 lemmas posDivAlg_eqn_number_of [simp] =
  1732     posDivAlg_eqn [of "number_of v" "number_of w", standard]
  1733 
  1734 lemmas negDivAlg_eqn_number_of [simp] =
  1735     negDivAlg_eqn [of "number_of v" "number_of w", standard]
  1736 
  1737 
  1738 text{*Special-case simplification *}
  1739 
  1740 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
  1741 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
  1742 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
  1743 apply (auto simp del: neg_mod_sign neg_mod_bound)
  1744 done
  1745 
  1746 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
  1747 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
  1748 
  1749 (** The last remaining special cases for constant arithmetic:
  1750     1 div z and 1 mod z **)
  1751 
  1752 lemmas div_pos_pos_1_number_of [simp] =
  1753     div_pos_pos [OF int_0_less_1, of "number_of w", standard]
  1754 
  1755 lemmas div_pos_neg_1_number_of [simp] =
  1756     div_pos_neg [OF int_0_less_1, of "number_of w", standard]
  1757 
  1758 lemmas mod_pos_pos_1_number_of [simp] =
  1759     mod_pos_pos [OF int_0_less_1, of "number_of w", standard]
  1760 
  1761 lemmas mod_pos_neg_1_number_of [simp] =
  1762     mod_pos_neg [OF int_0_less_1, of "number_of w", standard]
  1763 
  1764 
  1765 lemmas posDivAlg_eqn_1_number_of [simp] =
  1766     posDivAlg_eqn [of concl: 1 "number_of w", standard]
  1767 
  1768 lemmas negDivAlg_eqn_1_number_of [simp] =
  1769     negDivAlg_eqn [of concl: 1 "number_of w", standard]
  1770 
  1771 
  1772 
  1773 subsubsection{*Monotonicity in the First Argument (Dividend)*}
  1774 
  1775 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1776 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1777 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1778 apply (rule unique_quotient_lemma)
  1779 apply (erule subst)
  1780 apply (erule subst, simp_all)
  1781 done
  1782 
  1783 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1784 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1785 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1786 apply (rule unique_quotient_lemma_neg)
  1787 apply (erule subst)
  1788 apply (erule subst, simp_all)
  1789 done
  1790 
  1791 
  1792 subsubsection{*Monotonicity in the Second Argument (Divisor)*}
  1793 
  1794 lemma q_pos_lemma:
  1795      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1796 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1797  apply (simp add: zero_less_mult_iff)
  1798 apply (simp add: right_distrib)
  1799 done
  1800 
  1801 lemma zdiv_mono2_lemma:
  1802      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1803          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1804       ==> q \<le> (q'::int)"
  1805 apply (frule q_pos_lemma, assumption+) 
  1806 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1807  apply (simp add: mult_less_cancel_left)
  1808 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1809  prefer 2 apply simp
  1810 apply (simp (no_asm_simp) add: right_distrib)
  1811 apply (subst add_commute, rule zadd_zless_mono, arith)
  1812 apply (rule mult_right_mono, auto)
  1813 done
  1814 
  1815 lemma zdiv_mono2:
  1816      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1817 apply (subgoal_tac "b \<noteq> 0")
  1818  prefer 2 apply arith
  1819 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1820 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1821 apply (rule zdiv_mono2_lemma)
  1822 apply (erule subst)
  1823 apply (erule subst, simp_all)
  1824 done
  1825 
  1826 lemma q_neg_lemma:
  1827      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1828 apply (subgoal_tac "b'*q' < 0")
  1829  apply (simp add: mult_less_0_iff, arith)
  1830 done
  1831 
  1832 lemma zdiv_mono2_neg_lemma:
  1833      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1834          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1835       ==> q' \<le> (q::int)"
  1836 apply (frule q_neg_lemma, assumption+) 
  1837 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1838  apply (simp add: mult_less_cancel_left)
  1839 apply (simp add: right_distrib)
  1840 apply (subgoal_tac "b*q' \<le> b'*q'")
  1841  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1842 done
  1843 
  1844 lemma zdiv_mono2_neg:
  1845      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1846 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1847 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1848 apply (rule zdiv_mono2_neg_lemma)
  1849 apply (erule subst)
  1850 apply (erule subst, simp_all)
  1851 done
  1852 
  1853 
  1854 subsubsection{*More Algebraic Laws for div and mod*}
  1855 
  1856 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1857 
  1858 lemma zmult1_lemma:
  1859      "[| divmod_int_rel b c (q, r);  c \<noteq> 0 |]  
  1860       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1861 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib mult_ac)
  1862 
  1863 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1864 apply (case_tac "c = 0", simp)
  1865 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_div])
  1866 done
  1867 
  1868 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
  1869 apply (case_tac "c = 0", simp)
  1870 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_mod])
  1871 done
  1872 
  1873 lemma zmod_zdiv_trivial: "(a mod b) div b = (0::int)"
  1874 apply (case_tac "b = 0", simp)
  1875 apply (auto simp add: linorder_neq_iff div_pos_pos_trivial div_neg_neg_trivial)
  1876 done
  1877 
  1878 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1879 
  1880 lemma zadd1_lemma:
  1881      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br);  c \<noteq> 0 |]  
  1882       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1883 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib)
  1884 
  1885 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1886 lemma zdiv_zadd1_eq:
  1887      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1888 apply (case_tac "c = 0", simp)
  1889 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] divmod_int_rel_div)
  1890 done
  1891 
  1892 instance int :: ring_div
  1893 proof
  1894   fix a b c :: int
  1895   assume not0: "b \<noteq> 0"
  1896   show "(a + c * b) div b = c + a div b"
  1897     unfolding zdiv_zadd1_eq [of a "c * b"] using not0 
  1898       by (simp add: zmod_zmult1_eq zmod_zdiv_trivial zdiv_zmult1_eq)
  1899 next
  1900   fix a b c :: int
  1901   assume "a \<noteq> 0"
  1902   then show "(a * b) div (a * c) = b div c"
  1903   proof (cases "b \<noteq> 0 \<and> c \<noteq> 0")
  1904     case False then show ?thesis by auto
  1905   next
  1906     case True then have "b \<noteq> 0" and "c \<noteq> 0" by auto
  1907     with `a \<noteq> 0`
  1908     have "\<And>q r. divmod_int_rel b c (q, r) \<Longrightarrow> divmod_int_rel (a * b) (a * c) (q, a * r)"
  1909       apply (auto simp add: divmod_int_rel_def) 
  1910       apply (auto simp add: algebra_simps)
  1911       apply (auto simp add: zero_less_mult_iff zero_le_mult_iff mult_le_0_iff mult_commute [of a] mult_less_cancel_right)
  1912       done
  1913     moreover with `c \<noteq> 0` divmod_int_rel_div_mod have "divmod_int_rel b c (b div c, b mod c)" by auto
  1914     ultimately have "divmod_int_rel (a * b) (a * c) (b div c, a * (b mod c))" .
  1915     moreover from  `a \<noteq> 0` `c \<noteq> 0` have "a * c \<noteq> 0" by simp
  1916     ultimately show ?thesis by (rule divmod_int_rel_div)
  1917   qed
  1918 qed auto
  1919 
  1920 lemma posDivAlg_div_mod:
  1921   assumes "k \<ge> 0"
  1922   and "l \<ge> 0"
  1923   shows "posDivAlg k l = (k div l, k mod l)"
  1924 proof (cases "l = 0")
  1925   case True then show ?thesis by (simp add: posDivAlg.simps)
  1926 next
  1927   case False with assms posDivAlg_correct
  1928     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1929     by simp
  1930   from divmod_int_rel_div [OF this `l \<noteq> 0`] divmod_int_rel_mod [OF this `l \<noteq> 0`]
  1931   show ?thesis by simp
  1932 qed
  1933 
  1934 lemma negDivAlg_div_mod:
  1935   assumes "k < 0"
  1936   and "l > 0"
  1937   shows "negDivAlg k l = (k div l, k mod l)"
  1938 proof -
  1939   from assms have "l \<noteq> 0" by simp
  1940   from assms negDivAlg_correct
  1941     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1942     by simp
  1943   from divmod_int_rel_div [OF this `l \<noteq> 0`] divmod_int_rel_mod [OF this `l \<noteq> 0`]
  1944   show ?thesis by simp
  1945 qed
  1946 
  1947 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1948 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1949 
  1950 (* REVISIT: should this be generalized to all semiring_div types? *)
  1951 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1952 
  1953 
  1954 subsubsection{*Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1955 
  1956 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1957   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1958   to cause particular problems.*)
  1959 
  1960 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1961 
  1962 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1963 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1964  apply (simp add: algebra_simps)
  1965 apply (rule order_le_less_trans)
  1966  apply (erule_tac [2] mult_strict_right_mono)
  1967  apply (rule mult_left_mono_neg)
  1968   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1969  apply (simp)
  1970 apply (simp)
  1971 done
  1972 
  1973 lemma zmult2_lemma_aux2:
  1974      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1975 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1976  apply arith
  1977 apply (simp add: mult_le_0_iff)
  1978 done
  1979 
  1980 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1981 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1982 apply arith
  1983 apply (simp add: zero_le_mult_iff)
  1984 done
  1985 
  1986 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1987 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1988  apply (simp add: right_diff_distrib)
  1989 apply (rule order_less_le_trans)
  1990  apply (erule mult_strict_right_mono)
  1991  apply (rule_tac [2] mult_left_mono)
  1992   apply simp
  1993  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1994 apply simp
  1995 done
  1996 
  1997 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r);  b \<noteq> 0;  0 < c |]  
  1998       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1999 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  2000                    zero_less_mult_iff right_distrib [symmetric] 
  2001                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4)
  2002 
  2003 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  2004 apply (case_tac "b = 0", simp)
  2005 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_div])
  2006 done
  2007 
  2008 lemma zmod_zmult2_eq:
  2009      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  2010 apply (case_tac "b = 0", simp)
  2011 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_mod])
  2012 done
  2013 
  2014 
  2015 subsubsection {*Splitting Rules for div and mod*}
  2016 
  2017 text{*The proofs of the two lemmas below are essentially identical*}
  2018 
  2019 lemma split_pos_lemma:
  2020  "0<k ==> 
  2021     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  2022 apply (rule iffI, clarify)
  2023  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2024  apply (subst mod_add_eq) 
  2025  apply (subst zdiv_zadd1_eq) 
  2026  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  2027 txt{*converse direction*}
  2028 apply (drule_tac x = "n div k" in spec) 
  2029 apply (drule_tac x = "n mod k" in spec, simp)
  2030 done
  2031 
  2032 lemma split_neg_lemma:
  2033  "k<0 ==>
  2034     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  2035 apply (rule iffI, clarify)
  2036  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2037  apply (subst mod_add_eq) 
  2038  apply (subst zdiv_zadd1_eq) 
  2039  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  2040 txt{*converse direction*}
  2041 apply (drule_tac x = "n div k" in spec) 
  2042 apply (drule_tac x = "n mod k" in spec, simp)
  2043 done
  2044 
  2045 lemma split_zdiv:
  2046  "P(n div k :: int) =
  2047   ((k = 0 --> P 0) & 
  2048    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  2049    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  2050 apply (case_tac "k=0", simp)
  2051 apply (simp only: linorder_neq_iff)
  2052 apply (erule disjE) 
  2053  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  2054                       split_neg_lemma [of concl: "%x y. P x"])
  2055 done
  2056 
  2057 lemma split_zmod:
  2058  "P(n mod k :: int) =
  2059   ((k = 0 --> P n) & 
  2060    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  2061    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  2062 apply (case_tac "k=0", simp)
  2063 apply (simp only: linorder_neq_iff)
  2064 apply (erule disjE) 
  2065  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  2066                       split_neg_lemma [of concl: "%x y. P y"])
  2067 done
  2068 
  2069 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  2070   when these are applied to some constant that is of the form
  2071   @{term "number_of k"}: *}
  2072 declare split_zdiv [of _ _ "number_of k", standard, arith_split]
  2073 declare split_zmod [of _ _ "number_of k", standard, arith_split]
  2074 
  2075 
  2076 subsubsection{*Speeding up the Division Algorithm with Shifting*}
  2077 
  2078 text{*computing div by shifting *}
  2079 
  2080 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2081 proof cases
  2082   assume "a=0"
  2083     thus ?thesis by simp
  2084 next
  2085   assume "a\<noteq>0" and le_a: "0\<le>a"   
  2086   hence a_pos: "1 \<le> a" by arith
  2087   hence one_less_a2: "1 < 2 * a" by arith
  2088   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
  2089     unfolding mult_le_cancel_left
  2090     by (simp add: add1_zle_eq add_commute [of 1])
  2091   with a_pos have "0 \<le> b mod a" by simp
  2092   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
  2093     by (simp add: mod_pos_pos_trivial one_less_a2)
  2094   with  le_2a
  2095   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
  2096     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
  2097                   right_distrib) 
  2098   thus ?thesis
  2099     by (subst zdiv_zadd1_eq,
  2100         simp add: mod_mult_mult1 one_less_a2
  2101                   div_pos_pos_trivial)
  2102 qed
  2103 
  2104 lemma neg_zdiv_mult_2: 
  2105   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2106 proof -
  2107   have R: "1 + - (2 * (b + 1)) = - (1 + 2 * b)" by simp
  2108   have "(1 + 2 * (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a)"
  2109     by (rule pos_zdiv_mult_2, simp add: A)
  2110   thus ?thesis
  2111     by (simp only: R zdiv_zminus_zminus diff_minus
  2112       minus_add_distrib [symmetric] mult_minus_right)
  2113 qed
  2114 
  2115 lemma zdiv_number_of_Bit0 [simp]:
  2116      "number_of (Int.Bit0 v) div number_of (Int.Bit0 w) =  
  2117           number_of v div (number_of w :: int)"
  2118 by (simp only: number_of_eq numeral_simps) (simp add: mult_2 [symmetric])
  2119 
  2120 lemma zdiv_number_of_Bit1 [simp]:
  2121      "number_of (Int.Bit1 v) div number_of (Int.Bit0 w) =  
  2122           (if (0::int) \<le> number_of w                    
  2123            then number_of v div (number_of w)     
  2124            else (number_of v + (1::int)) div (number_of w))"
  2125 apply (simp only: number_of_eq numeral_simps UNIV_I split: split_if) 
  2126 apply (simp add: pos_zdiv_mult_2 neg_zdiv_mult_2 add_ac mult_2 [symmetric])
  2127 done
  2128 
  2129 
  2130 subsubsection{*Computing mod by Shifting (proofs resemble those for div)*}
  2131 
  2132 lemma pos_zmod_mult_2:
  2133   fixes a b :: int
  2134   assumes "0 \<le> a"
  2135   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2136 proof (cases "0 < a")
  2137   case False with assms show ?thesis by simp
  2138 next
  2139   case True
  2140   then have "b mod a < a" by (rule pos_mod_bound)
  2141   then have "1 + b mod a \<le> a" by simp
  2142   then have A: "2 * (1 + b mod a) \<le> 2 * a" by simp
  2143   from `0 < a` have "0 \<le> b mod a" by (rule pos_mod_sign)
  2144   then have B: "0 \<le> 1 + 2 * (b mod a)" by simp
  2145   have "((1\<Colon>int) mod ((2\<Colon>int) * a) + (2\<Colon>int) * b mod ((2\<Colon>int) * a)) mod ((2\<Colon>int) * a) = (1\<Colon>int) + (2\<Colon>int) * (b mod a)"
  2146     using `0 < a` and A
  2147     by (auto simp add: mod_mult_mult1 mod_pos_pos_trivial ring_distribs intro!: mod_pos_pos_trivial B)
  2148   then show ?thesis by (subst mod_add_eq)
  2149 qed
  2150 
  2151 lemma neg_zmod_mult_2:
  2152   fixes a b :: int
  2153   assumes "a \<le> 0"
  2154   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2155 proof -
  2156   from assms have "0 \<le> - a" by auto
  2157   then have "(1 + 2 * (- b - 1)) mod (2 * (- a)) = 1 + 2 * ((- b - 1) mod (- a))"
  2158     by (rule pos_zmod_mult_2)
  2159   then show ?thesis by (simp add: zmod_zminus2 algebra_simps)
  2160      (simp add: diff_minus add_ac)
  2161 qed
  2162 
  2163 lemma zmod_number_of_Bit0 [simp]:
  2164      "number_of (Int.Bit0 v) mod number_of (Int.Bit0 w) =  
  2165       (2::int) * (number_of v mod number_of w)"
  2166 apply (simp only: number_of_eq numeral_simps) 
  2167 apply (simp add: mod_mult_mult1 pos_zmod_mult_2 
  2168                  neg_zmod_mult_2 add_ac mult_2 [symmetric])
  2169 done
  2170 
  2171 lemma zmod_number_of_Bit1 [simp]:
  2172      "number_of (Int.Bit1 v) mod number_of (Int.Bit0 w) =  
  2173       (if (0::int) \<le> number_of w  
  2174                 then 2 * (number_of v mod number_of w) + 1     
  2175                 else 2 * ((number_of v + (1::int)) mod number_of w) - 1)"
  2176 apply (simp only: number_of_eq numeral_simps) 
  2177 apply (simp add: mod_mult_mult1 pos_zmod_mult_2 
  2178                  neg_zmod_mult_2 add_ac mult_2 [symmetric])
  2179 done
  2180 
  2181 
  2182 lemma zdiv_eq_0_iff:
  2183  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2184 proof
  2185   assume ?L
  2186   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2187   with `?L` show ?R by blast
  2188 next
  2189   assume ?R thus ?L
  2190     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2191 qed
  2192 
  2193 
  2194 subsubsection{*Quotients of Signs*}
  2195 
  2196 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2197 apply (subgoal_tac "a div b \<le> -1", force)
  2198 apply (rule order_trans)
  2199 apply (rule_tac a' = "-1" in zdiv_mono1)
  2200 apply (auto simp add: div_eq_minus1)
  2201 done
  2202 
  2203 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2204 by (drule zdiv_mono1_neg, auto)
  2205 
  2206 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2207 by (drule zdiv_mono1, auto)
  2208 
  2209 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2210 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2211 They should all be simp rules unless that causes too much search. *}
  2212 
  2213 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2214 apply auto
  2215 apply (drule_tac [2] zdiv_mono1)
  2216 apply (auto simp add: linorder_neq_iff)
  2217 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2218 apply (blast intro: div_neg_pos_less0)
  2219 done
  2220 
  2221 lemma neg_imp_zdiv_nonneg_iff:
  2222   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2223 apply (subst zdiv_zminus_zminus [symmetric])
  2224 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2225 done
  2226 
  2227 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2228 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2229 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2230 
  2231 lemma pos_imp_zdiv_pos_iff:
  2232   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2233 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2234 by arith
  2235 
  2236 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2237 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2238 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2239 
  2240 lemma nonneg1_imp_zdiv_pos_iff:
  2241   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2242 apply rule
  2243  apply rule
  2244   using div_pos_pos_trivial[of a b]apply arith
  2245  apply(cases "b=0")apply simp
  2246  using div_nonneg_neg_le0[of a b]apply arith
  2247 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2248 done
  2249 
  2250 
  2251 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2252 apply (rule split_zmod[THEN iffD2])
  2253 apply(fastsimp dest: q_pos_lemma intro: split_mult_pos_le)
  2254 done
  2255 
  2256 
  2257 subsubsection {* The Divides Relation *}
  2258 
  2259 lemmas zdvd_iff_zmod_eq_0_number_of [simp] =
  2260   dvd_eq_mod_eq_0 [of "number_of x::int" "number_of y::int", standard]
  2261 
  2262 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  2263   by (rule dvd_mod) (* TODO: remove *)
  2264 
  2265 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  2266   by (rule dvd_mod_imp_dvd) (* TODO: remove *)
  2267 
  2268 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2269   using zmod_zdiv_equality[where a="m" and b="n"]
  2270   by (simp add: algebra_simps)
  2271 
  2272 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  2273 apply (induct "y", auto)
  2274 apply (rule zmod_zmult1_eq [THEN trans])
  2275 apply (simp (no_asm_simp))
  2276 apply (rule mod_mult_eq [symmetric])
  2277 done
  2278 
  2279 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2280 apply (subst split_div, auto)
  2281 apply (subst split_zdiv, auto)
  2282 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2283 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2284 done
  2285 
  2286 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2287 apply (subst split_mod, auto)
  2288 apply (subst split_zmod, auto)
  2289 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2290        in unique_remainder)
  2291 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2292 done
  2293 
  2294 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2295 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2296 
  2297 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  2298 apply (subgoal_tac "m mod n = 0")
  2299  apply (simp add: zmult_div_cancel)
  2300 apply (simp only: dvd_eq_mod_eq_0)
  2301 done
  2302 
  2303 text{*Suggested by Matthias Daum*}
  2304 lemma int_power_div_base:
  2305      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2306 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2307  apply (erule ssubst)
  2308  apply (simp only: power_add)
  2309  apply simp_all
  2310 done
  2311 
  2312 text {* by Brian Huffman *}
  2313 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2314 by (rule mod_minus_eq [symmetric])
  2315 
  2316 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2317 by (rule mod_diff_left_eq [symmetric])
  2318 
  2319 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2320 by (rule mod_diff_right_eq [symmetric])
  2321 
  2322 lemmas zmod_simps =
  2323   mod_add_left_eq  [symmetric]
  2324   mod_add_right_eq [symmetric]
  2325   zmod_zmult1_eq   [symmetric]
  2326   mod_mult_left_eq [symmetric]
  2327   zpower_zmod
  2328   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2329 
  2330 text {* Distributive laws for function @{text nat}. *}
  2331 
  2332 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2333 apply (rule linorder_cases [of y 0])
  2334 apply (simp add: div_nonneg_neg_le0)
  2335 apply simp
  2336 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2337 done
  2338 
  2339 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2340 lemma nat_mod_distrib:
  2341   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2342 apply (case_tac "y = 0", simp)
  2343 apply (simp add: nat_eq_iff zmod_int)
  2344 done
  2345 
  2346 text  {* transfer setup *}
  2347 
  2348 lemma transfer_nat_int_functions:
  2349     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2350     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2351   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2352 
  2353 lemma transfer_nat_int_function_closures:
  2354     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2355     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2356   apply (cases "y = 0")
  2357   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2358   apply (cases "y = 0")
  2359   apply auto
  2360 done
  2361 
  2362 declare transfer_morphism_nat_int [transfer add return:
  2363   transfer_nat_int_functions
  2364   transfer_nat_int_function_closures
  2365 ]
  2366 
  2367 lemma transfer_int_nat_functions:
  2368     "(int x) div (int y) = int (x div y)"
  2369     "(int x) mod (int y) = int (x mod y)"
  2370   by (auto simp add: zdiv_int zmod_int)
  2371 
  2372 lemma transfer_int_nat_function_closures:
  2373     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2374     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2375   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2376 
  2377 declare transfer_morphism_int_nat [transfer add return:
  2378   transfer_int_nat_functions
  2379   transfer_int_nat_function_closures
  2380 ]
  2381 
  2382 text{*Suggested by Matthias Daum*}
  2383 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2384 apply (subgoal_tac "nat x div nat k < nat x")
  2385  apply (simp add: nat_div_distrib [symmetric])
  2386 apply (rule Divides.div_less_dividend, simp_all)
  2387 done
  2388 
  2389 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2390 proof
  2391   assume H: "x mod n = y mod n"
  2392   hence "x mod n - y mod n = 0" by simp
  2393   hence "(x mod n - y mod n) mod n = 0" by simp 
  2394   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2395   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2396 next
  2397   assume H: "n dvd x - y"
  2398   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2399   hence "x = n*k + y" by simp
  2400   hence "x mod n = (n*k + y) mod n" by simp
  2401   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2402 qed
  2403 
  2404 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2405   shows "\<exists>q. x = y + n * q"
  2406 proof-
  2407   from xy have th: "int x - int y = int (x - y)" by simp 
  2408   from xyn have "int x mod int n = int y mod int n" 
  2409     by (simp add: zmod_int[symmetric])
  2410   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2411   hence "n dvd x - y" by (simp add: th zdvd_int)
  2412   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2413 qed
  2414 
  2415 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2416   (is "?lhs = ?rhs")
  2417 proof
  2418   assume H: "x mod n = y mod n"
  2419   {assume xy: "x \<le> y"
  2420     from H have th: "y mod n = x mod n" by simp
  2421     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2422       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2423   moreover
  2424   {assume xy: "y \<le> x"
  2425     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2426       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2427   ultimately  show ?rhs using linear[of x y] by blast  
  2428 next
  2429   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2430   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2431   thus  ?lhs by simp
  2432 qed
  2433 
  2434 lemma div_nat_number_of [simp]:
  2435      "(number_of v :: nat)  div  number_of v' =  
  2436           (if neg (number_of v :: int) then 0  
  2437            else nat (number_of v div number_of v'))"
  2438   unfolding nat_number_of_def number_of_is_id neg_def
  2439   by (simp add: nat_div_distrib)
  2440 
  2441 lemma one_div_nat_number_of [simp]:
  2442      "Suc 0 div number_of v' = nat (1 div number_of v')" 
  2443 by (simp del: nat_numeral_1_eq_1 add: numeral_1_eq_Suc_0 [symmetric]) 
  2444 
  2445 lemma mod_nat_number_of [simp]:
  2446      "(number_of v :: nat)  mod  number_of v' =  
  2447         (if neg (number_of v :: int) then 0  
  2448          else if neg (number_of v' :: int) then number_of v  
  2449          else nat (number_of v mod number_of v'))"
  2450   unfolding nat_number_of_def number_of_is_id neg_def
  2451   by (simp add: nat_mod_distrib)
  2452 
  2453 lemma one_mod_nat_number_of [simp]:
  2454      "Suc 0 mod number_of v' =  
  2455         (if neg (number_of v' :: int) then Suc 0
  2456          else nat (1 mod number_of v'))"
  2457 by (simp del: nat_numeral_1_eq_1 add: numeral_1_eq_Suc_0 [symmetric]) 
  2458 
  2459 lemmas dvd_eq_mod_eq_0_number_of =
  2460   dvd_eq_mod_eq_0 [of "number_of x" "number_of y", standard]
  2461 
  2462 declare dvd_eq_mod_eq_0_number_of [simp]
  2463 
  2464 
  2465 subsubsection {* Nitpick *}
  2466 
  2467 lemma zmod_zdiv_equality':
  2468 "(m\<Colon>int) mod n = m - (m div n) * n"
  2469 by (rule_tac P="%x. m mod n = x - (m div n) * n"
  2470     in subst [OF mod_div_equality [of _ n]])
  2471    arith
  2472 
  2473 lemmas [nitpick_def] = dvd_eq_mod_eq_0 [THEN eq_reflection]
  2474                        mod_div_equality' [THEN eq_reflection]
  2475                        zmod_zdiv_equality' [THEN eq_reflection]
  2476 
  2477 
  2478 subsubsection {* Code generation *}
  2479 
  2480 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2481   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2482 
  2483 lemma pdivmod_posDivAlg [code]:
  2484   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2485 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2486 
  2487 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2488   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2489     then pdivmod k l
  2490     else (let (r, s) = pdivmod k l in
  2491       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2492 proof -
  2493   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2494   show ?thesis
  2495     by (simp add: divmod_int_mod_div pdivmod_def)
  2496       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2497       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2498 qed
  2499 
  2500 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2501   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2502     then pdivmod k l
  2503     else (let (r, s) = pdivmod k l in
  2504       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2505 proof -
  2506   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2507     by (auto simp add: not_less sgn_if)
  2508   then show ?thesis by (simp add: divmod_int_pdivmod)
  2509 qed
  2510 
  2511 context ring_1
  2512 begin
  2513 
  2514 lemma of_int_num [code]:
  2515   "of_int k = (if k = 0 then 0 else if k < 0 then
  2516      - of_int (- k) else let
  2517        (l, m) = divmod_int k 2;
  2518        l' = of_int l
  2519      in if m = 0 then l' + l' else l' + l' + 1)"
  2520 proof -
  2521   have aux1: "k mod (2\<Colon>int) \<noteq> (0\<Colon>int) \<Longrightarrow> 
  2522     of_int k = of_int (k div 2 * 2 + 1)"
  2523   proof -
  2524     have "k mod 2 < 2" by (auto intro: pos_mod_bound)
  2525     moreover have "0 \<le> k mod 2" by (auto intro: pos_mod_sign)
  2526     moreover assume "k mod 2 \<noteq> 0"
  2527     ultimately have "k mod 2 = 1" by arith
  2528     moreover have "of_int k = of_int (k div 2 * 2 + k mod 2)" by simp
  2529     ultimately show ?thesis by auto
  2530   qed
  2531   have aux2: "\<And>x. of_int 2 * x = x + x"
  2532   proof -
  2533     fix x
  2534     have int2: "(2::int) = 1 + 1" by arith
  2535     show "of_int 2 * x = x + x"
  2536     unfolding int2 of_int_add left_distrib by simp
  2537   qed
  2538   have aux3: "\<And>x. x * of_int 2 = x + x"
  2539   proof -
  2540     fix x
  2541     have int2: "(2::int) = 1 + 1" by arith
  2542     show "x * of_int 2 = x + x" 
  2543     unfolding int2 of_int_add right_distrib by simp
  2544   qed
  2545   from aux1 show ?thesis by (auto simp add: divmod_int_mod_div Let_def aux2 aux3)
  2546 qed
  2547 
  2548 end
  2549 
  2550 code_modulename SML
  2551   Divides Arith
  2552 
  2553 code_modulename OCaml
  2554   Divides Arith
  2555 
  2556 code_modulename Haskell
  2557   Divides Arith
  2558 
  2559 end