src/HOL/Transcendental.thy
author wenzelm
Fri Jan 14 15:44:47 2011 +0100 (2011-01-14)
changeset 41550 efa734d9b221
parent 38642 8fa437809c67
child 41970 47d6e13d1710
permissions -rw-r--r--
eliminated global prems;
tuned proofs;
     1 (*  Title:      HOL/Transcendental.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge, University of Edinburgh
     3     Author:     Lawrence C Paulson
     4 *)
     5 
     6 header{*Power Series, Transcendental Functions etc.*}
     7 
     8 theory Transcendental
     9 imports Fact Series Deriv NthRoot
    10 begin
    11 
    12 subsection {* Properties of Power Series *}
    13 
    14 lemma lemma_realpow_diff:
    15   fixes y :: "'a::monoid_mult"
    16   shows "p \<le> n \<Longrightarrow> y ^ (Suc n - p) = (y ^ (n - p)) * y"
    17 proof -
    18   assume "p \<le> n"
    19   hence "Suc n - p = Suc (n - p)" by (rule Suc_diff_le)
    20   thus ?thesis by (simp add: power_commutes)
    21 qed
    22 
    23 lemma lemma_realpow_diff_sumr:
    24   fixes y :: "'a::{comm_semiring_0,monoid_mult}" shows
    25      "(\<Sum>p=0..<Suc n. (x ^ p) * y ^ (Suc n - p)) =  
    26       y * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    27 by (simp add: setsum_right_distrib lemma_realpow_diff mult_ac
    28          del: setsum_op_ivl_Suc)
    29 
    30 lemma lemma_realpow_diff_sumr2:
    31   fixes y :: "'a::{comm_ring,monoid_mult}" shows
    32      "x ^ (Suc n) - y ^ (Suc n) =  
    33       (x - y) * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    34 apply (induct n, simp)
    35 apply (simp del: setsum_op_ivl_Suc)
    36 apply (subst setsum_op_ivl_Suc)
    37 apply (subst lemma_realpow_diff_sumr)
    38 apply (simp add: right_distrib del: setsum_op_ivl_Suc)
    39 apply (subst mult_left_commute [of "x - y"])
    40 apply (erule subst)
    41 apply (simp add: algebra_simps)
    42 done
    43 
    44 lemma lemma_realpow_rev_sumr:
    45      "(\<Sum>p=0..<Suc n. (x ^ p) * (y ^ (n - p))) =  
    46       (\<Sum>p=0..<Suc n. (x ^ (n - p)) * (y ^ p))"
    47 apply (rule setsum_reindex_cong [where f="\<lambda>i. n - i"])
    48 apply (rule inj_onI, simp)
    49 apply auto
    50 apply (rule_tac x="n - x" in image_eqI, simp, simp)
    51 done
    52 
    53 text{*Power series has a `circle` of convergence, i.e. if it sums for @{term
    54 x}, then it sums absolutely for @{term z} with @{term "\<bar>z\<bar> < \<bar>x\<bar>"}.*}
    55 
    56 lemma powser_insidea:
    57   fixes x z :: "'a::{real_normed_field,banach}"
    58   assumes 1: "summable (\<lambda>n. f n * x ^ n)"
    59   assumes 2: "norm z < norm x"
    60   shows "summable (\<lambda>n. norm (f n * z ^ n))"
    61 proof -
    62   from 2 have x_neq_0: "x \<noteq> 0" by clarsimp
    63   from 1 have "(\<lambda>n. f n * x ^ n) ----> 0"
    64     by (rule summable_LIMSEQ_zero)
    65   hence "convergent (\<lambda>n. f n * x ^ n)"
    66     by (rule convergentI)
    67   hence "Cauchy (\<lambda>n. f n * x ^ n)"
    68     by (simp add: Cauchy_convergent_iff)
    69   hence "Bseq (\<lambda>n. f n * x ^ n)"
    70     by (rule Cauchy_Bseq)
    71   then obtain K where 3: "0 < K" and 4: "\<forall>n. norm (f n * x ^ n) \<le> K"
    72     by (simp add: Bseq_def, safe)
    73   have "\<exists>N. \<forall>n\<ge>N. norm (norm (f n * z ^ n)) \<le>
    74                    K * norm (z ^ n) * inverse (norm (x ^ n))"
    75   proof (intro exI allI impI)
    76     fix n::nat assume "0 \<le> n"
    77     have "norm (norm (f n * z ^ n)) * norm (x ^ n) =
    78           norm (f n * x ^ n) * norm (z ^ n)"
    79       by (simp add: norm_mult abs_mult)
    80     also have "\<dots> \<le> K * norm (z ^ n)"
    81       by (simp only: mult_right_mono 4 norm_ge_zero)
    82     also have "\<dots> = K * norm (z ^ n) * (inverse (norm (x ^ n)) * norm (x ^ n))"
    83       by (simp add: x_neq_0)
    84     also have "\<dots> = K * norm (z ^ n) * inverse (norm (x ^ n)) * norm (x ^ n)"
    85       by (simp only: mult_assoc)
    86     finally show "norm (norm (f n * z ^ n)) \<le>
    87                   K * norm (z ^ n) * inverse (norm (x ^ n))"
    88       by (simp add: mult_le_cancel_right x_neq_0)
    89   qed
    90   moreover have "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
    91   proof -
    92     from 2 have "norm (norm (z * inverse x)) < 1"
    93       using x_neq_0
    94       by (simp add: nonzero_norm_divide divide_inverse [symmetric])
    95     hence "summable (\<lambda>n. norm (z * inverse x) ^ n)"
    96       by (rule summable_geometric)
    97     hence "summable (\<lambda>n. K * norm (z * inverse x) ^ n)"
    98       by (rule summable_mult)
    99     thus "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
   100       using x_neq_0
   101       by (simp add: norm_mult nonzero_norm_inverse power_mult_distrib
   102                     power_inverse norm_power mult_assoc)
   103   qed
   104   ultimately show "summable (\<lambda>n. norm (f n * z ^ n))"
   105     by (rule summable_comparison_test)
   106 qed
   107 
   108 lemma powser_inside:
   109   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}" shows
   110      "[| summable (%n. f(n) * (x ^ n)); norm z < norm x |]  
   111       ==> summable (%n. f(n) * (z ^ n))"
   112 by (rule powser_insidea [THEN summable_norm_cancel])
   113 
   114 lemma sum_split_even_odd: fixes f :: "nat \<Rightarrow> real" shows
   115   "(\<Sum> i = 0 ..< 2 * n. if even i then f i else g i) = 
   116    (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1))"
   117 proof (induct n)
   118   case (Suc n)
   119   have "(\<Sum> i = 0 ..< 2 * Suc n. if even i then f i else g i) = 
   120         (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1)) + (f (2 * n) + g (2 * n + 1))"
   121     using Suc.hyps unfolding One_nat_def by auto
   122   also have "\<dots> = (\<Sum> i = 0 ..< Suc n. f (2 * i)) + (\<Sum> i = 0 ..< Suc n. g (2 * i + 1))" by auto
   123   finally show ?case .
   124 qed auto
   125 
   126 lemma sums_if': fixes g :: "nat \<Rightarrow> real" assumes "g sums x"
   127   shows "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x"
   128   unfolding sums_def
   129 proof (rule LIMSEQ_I)
   130   fix r :: real assume "0 < r"
   131   from `g sums x`[unfolded sums_def, THEN LIMSEQ_D, OF this]
   132   obtain no where no_eq: "\<And> n. n \<ge> no \<Longrightarrow> (norm (setsum g { 0..<n } - x) < r)" by blast
   133 
   134   let ?SUM = "\<lambda> m. \<Sum> i = 0 ..< m. if even i then 0 else g ((i - 1) div 2)"
   135   { fix m assume "m \<ge> 2 * no" hence "m div 2 \<ge> no" by auto
   136     have sum_eq: "?SUM (2 * (m div 2)) = setsum g { 0 ..< m div 2 }" 
   137       using sum_split_even_odd by auto
   138     hence "(norm (?SUM (2 * (m div 2)) - x) < r)" using no_eq unfolding sum_eq using `m div 2 \<ge> no` by auto
   139     moreover
   140     have "?SUM (2 * (m div 2)) = ?SUM m"
   141     proof (cases "even m")
   142       case True show ?thesis unfolding even_nat_div_two_times_two[OF True, unfolded numeral_2_eq_2[symmetric]] ..
   143     next
   144       case False hence "even (Suc m)" by auto
   145       from even_nat_div_two_times_two[OF this, unfolded numeral_2_eq_2[symmetric]] odd_nat_plus_one_div_two[OF False, unfolded numeral_2_eq_2[symmetric]]
   146       have eq: "Suc (2 * (m div 2)) = m" by auto
   147       hence "even (2 * (m div 2))" using `odd m` by auto
   148       have "?SUM m = ?SUM (Suc (2 * (m div 2)))" unfolding eq ..
   149       also have "\<dots> = ?SUM (2 * (m div 2))" using `even (2 * (m div 2))` by auto
   150       finally show ?thesis by auto
   151     qed
   152     ultimately have "(norm (?SUM m - x) < r)" by auto
   153   }
   154   thus "\<exists> no. \<forall> m \<ge> no. norm (?SUM m - x) < r" by blast
   155 qed
   156 
   157 lemma sums_if: fixes g :: "nat \<Rightarrow> real" assumes "g sums x" and "f sums y"
   158   shows "(\<lambda> n. if even n then f (n div 2) else g ((n - 1) div 2)) sums (x + y)"
   159 proof -
   160   let ?s = "\<lambda> n. if even n then 0 else f ((n - 1) div 2)"
   161   { fix B T E have "(if B then (0 :: real) else E) + (if B then T else 0) = (if B then T else E)"
   162       by (cases B) auto } note if_sum = this
   163   have g_sums: "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x" using sums_if'[OF `g sums x`] .
   164   { 
   165     have "?s 0 = 0" by auto
   166     have Suc_m1: "\<And> n. Suc n - 1 = n" by auto
   167     have if_eq: "\<And>B T E. (if \<not> B then T else E) = (if B then E else T)" by auto
   168 
   169     have "?s sums y" using sums_if'[OF `f sums y`] .
   170     from this[unfolded sums_def, THEN LIMSEQ_Suc] 
   171     have "(\<lambda> n. if even n then f (n div 2) else 0) sums y"
   172       unfolding sums_def setsum_shift_lb_Suc0_0_upt[where f="?s", OF `?s 0 = 0`, symmetric]
   173                 image_Suc_atLeastLessThan[symmetric] setsum_reindex[OF inj_Suc, unfolded comp_def]
   174                 even_Suc Suc_m1 if_eq .
   175   } from sums_add[OF g_sums this]
   176   show ?thesis unfolding if_sum .
   177 qed
   178 
   179 subsection {* Alternating series test / Leibniz formula *}
   180 
   181 lemma sums_alternating_upper_lower:
   182   fixes a :: "nat \<Rightarrow> real"
   183   assumes mono: "\<And>n. a (Suc n) \<le> a n" and a_pos: "\<And>n. 0 \<le> a n" and "a ----> 0"
   184   shows "\<exists>l. ((\<forall>n. (\<Sum>i=0..<2*n. -1^i*a i) \<le> l) \<and> (\<lambda> n. \<Sum>i=0..<2*n. -1^i*a i) ----> l) \<and> 
   185              ((\<forall>n. l \<le> (\<Sum>i=0..<2*n + 1. -1^i*a i)) \<and> (\<lambda> n. \<Sum>i=0..<2*n + 1. -1^i*a i) ----> l)"
   186   (is "\<exists>l. ((\<forall>n. ?f n \<le> l) \<and> _) \<and> ((\<forall>n. l \<le> ?g n) \<and> _)")
   187 proof -
   188   have fg_diff: "\<And>n. ?f n - ?g n = - a (2 * n)" unfolding One_nat_def by auto
   189 
   190   have "\<forall> n. ?f n \<le> ?f (Suc n)"
   191   proof fix n show "?f n \<le> ?f (Suc n)" using mono[of "2*n"] by auto qed
   192   moreover
   193   have "\<forall> n. ?g (Suc n) \<le> ?g n"
   194   proof fix n show "?g (Suc n) \<le> ?g n" using mono[of "Suc (2*n)"]
   195     unfolding One_nat_def by auto qed
   196   moreover
   197   have "\<forall> n. ?f n \<le> ?g n" 
   198   proof fix n show "?f n \<le> ?g n" using fg_diff a_pos
   199     unfolding One_nat_def by auto qed
   200   moreover
   201   have "(\<lambda> n. ?f n - ?g n) ----> 0" unfolding fg_diff
   202   proof (rule LIMSEQ_I)
   203     fix r :: real assume "0 < r"
   204     with `a ----> 0`[THEN LIMSEQ_D] 
   205     obtain N where "\<And> n. n \<ge> N \<Longrightarrow> norm (a n - 0) < r" by auto
   206     hence "\<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   207     thus "\<exists> N. \<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   208   qed
   209   ultimately
   210   show ?thesis by (rule lemma_nest_unique)
   211 qed 
   212 
   213 lemma summable_Leibniz': fixes a :: "nat \<Rightarrow> real"
   214   assumes a_zero: "a ----> 0" and a_pos: "\<And> n. 0 \<le> a n"
   215   and a_monotone: "\<And> n. a (Suc n) \<le> a n"
   216   shows summable: "summable (\<lambda> n. (-1)^n * a n)"
   217   and "\<And>n. (\<Sum>i=0..<2*n. (-1)^i*a i) \<le> (\<Sum>i. (-1)^i*a i)"
   218   and "(\<lambda>n. \<Sum>i=0..<2*n. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   219   and "\<And>n. (\<Sum>i. (-1)^i*a i) \<le> (\<Sum>i=0..<2*n+1. (-1)^i*a i)"
   220   and "(\<lambda>n. \<Sum>i=0..<2*n+1. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   221 proof -
   222   let "?S n" = "(-1)^n * a n"
   223   let "?P n" = "\<Sum>i=0..<n. ?S i"
   224   let "?f n" = "?P (2 * n)"
   225   let "?g n" = "?P (2 * n + 1)"
   226   obtain l :: real where below_l: "\<forall> n. ?f n \<le> l" and "?f ----> l" and above_l: "\<forall> n. l \<le> ?g n" and "?g ----> l"
   227     using sums_alternating_upper_lower[OF a_monotone a_pos a_zero] by blast
   228   
   229   let ?Sa = "\<lambda> m. \<Sum> n = 0..<m. ?S n"
   230   have "?Sa ----> l"
   231   proof (rule LIMSEQ_I)
   232     fix r :: real assume "0 < r"
   233 
   234     with `?f ----> l`[THEN LIMSEQ_D] 
   235     obtain f_no where f: "\<And> n. n \<ge> f_no \<Longrightarrow> norm (?f n - l) < r" by auto
   236 
   237     from `0 < r` `?g ----> l`[THEN LIMSEQ_D] 
   238     obtain g_no where g: "\<And> n. n \<ge> g_no \<Longrightarrow> norm (?g n - l) < r" by auto
   239 
   240     { fix n :: nat
   241       assume "n \<ge> (max (2 * f_no) (2 * g_no))" hence "n \<ge> 2 * f_no" and "n \<ge> 2 * g_no" by auto
   242       have "norm (?Sa n - l) < r"
   243       proof (cases "even n")
   244         case True from even_nat_div_two_times_two[OF this]
   245         have n_eq: "2 * (n div 2) = n" unfolding numeral_2_eq_2[symmetric] by auto
   246         with `n \<ge> 2 * f_no` have "n div 2 \<ge> f_no" by auto
   247         from f[OF this]
   248         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost .
   249       next
   250         case False hence "even (n - 1)" by simp
   251         from even_nat_div_two_times_two[OF this]
   252         have n_eq: "2 * ((n - 1) div 2) = n - 1" unfolding numeral_2_eq_2[symmetric] by auto
   253         hence range_eq: "n - 1 + 1 = n" using odd_pos[OF False] by auto
   254 
   255         from n_eq `n \<ge> 2 * g_no` have "(n - 1) div 2 \<ge> g_no" by auto
   256         from g[OF this]
   257         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost range_eq .
   258       qed
   259     }
   260     thus "\<exists> no. \<forall> n \<ge> no. norm (?Sa n - l) < r" by blast
   261   qed
   262   hence sums_l: "(\<lambda>i. (-1)^i * a i) sums l" unfolding sums_def atLeastLessThanSuc_atLeastAtMost[symmetric] .
   263   thus "summable ?S" using summable_def by auto
   264 
   265   have "l = suminf ?S" using sums_unique[OF sums_l] .
   266 
   267   { fix n show "suminf ?S \<le> ?g n" unfolding sums_unique[OF sums_l, symmetric] using above_l by auto }
   268   { fix n show "?f n \<le> suminf ?S" unfolding sums_unique[OF sums_l, symmetric] using below_l by auto }
   269   show "?g ----> suminf ?S" using `?g ----> l` `l = suminf ?S` by auto
   270   show "?f ----> suminf ?S" using `?f ----> l` `l = suminf ?S` by auto
   271 qed
   272 
   273 theorem summable_Leibniz: fixes a :: "nat \<Rightarrow> real"
   274   assumes a_zero: "a ----> 0" and "monoseq a"
   275   shows "summable (\<lambda> n. (-1)^n * a n)" (is "?summable")
   276   and "0 < a 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n. -1^i * a i .. \<Sum>i=0..<2*n+1. -1^i * a i})" (is "?pos")
   277   and "a 0 < 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n+1. -1^i * a i .. \<Sum>i=0..<2*n. -1^i * a i})" (is "?neg")
   278   and "(\<lambda>n. \<Sum>i=0..<2*n. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?f")
   279   and "(\<lambda>n. \<Sum>i=0..<2*n+1. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?g")
   280 proof -
   281   have "?summable \<and> ?pos \<and> ?neg \<and> ?f \<and> ?g"
   282   proof (cases "(\<forall> n. 0 \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)")
   283     case True
   284     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> a n \<le> a m" and ge0: "\<And> n. 0 \<le> a n" by auto
   285     { fix n have "a (Suc n) \<le> a n" using ord[where n="Suc n" and m=n] by auto }
   286     note leibniz = summable_Leibniz'[OF `a ----> 0` ge0] and mono = this
   287     from leibniz[OF mono]
   288     show ?thesis using `0 \<le> a 0` by auto
   289   next
   290     let ?a = "\<lambda> n. - a n"
   291     case False
   292     with monoseq_le[OF `monoseq a` `a ----> 0`]
   293     have "(\<forall> n. a n \<le> 0) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)" by auto
   294     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> ?a n \<le> ?a m" and ge0: "\<And> n. 0 \<le> ?a n" by auto
   295     { fix n have "?a (Suc n) \<le> ?a n" using ord[where n="Suc n" and m=n] by auto }
   296     note monotone = this
   297     note leibniz = summable_Leibniz'[OF _ ge0, of "\<lambda>x. x", OF LIMSEQ_minus[OF `a ----> 0`, unfolded minus_zero] monotone]
   298     have "summable (\<lambda> n. (-1)^n * ?a n)" using leibniz(1) by auto
   299     then obtain l where "(\<lambda> n. (-1)^n * ?a n) sums l" unfolding summable_def by auto
   300     from this[THEN sums_minus]
   301     have "(\<lambda> n. (-1)^n * a n) sums -l" by auto
   302     hence ?summable unfolding summable_def by auto
   303     moreover
   304     have "\<And> a b :: real. \<bar> - a - - b \<bar> = \<bar>a - b\<bar>" unfolding minus_diff_minus by auto
   305     
   306     from suminf_minus[OF leibniz(1), unfolded mult_minus_right minus_minus]
   307     have move_minus: "(\<Sum>n. - (-1 ^ n * a n)) = - (\<Sum>n. -1 ^ n * a n)" by auto
   308 
   309     have ?pos using `0 \<le> ?a 0` by auto
   310     moreover have ?neg using leibniz(2,4) unfolding mult_minus_right setsum_negf move_minus neg_le_iff_le by auto
   311     moreover have ?f and ?g using leibniz(3,5)[unfolded mult_minus_right setsum_negf move_minus, THEN LIMSEQ_minus_cancel] by auto
   312     ultimately show ?thesis by auto
   313   qed
   314   from this[THEN conjunct1] this[THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct1]
   315        this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct2]
   316   show ?summable and ?pos and ?neg and ?f and ?g .
   317 qed
   318 
   319 subsection {* Term-by-Term Differentiability of Power Series *}
   320 
   321 definition
   322   diffs :: "(nat => 'a::ring_1) => nat => 'a" where
   323   "diffs c = (%n. of_nat (Suc n) * c(Suc n))"
   324 
   325 text{*Lemma about distributing negation over it*}
   326 lemma diffs_minus: "diffs (%n. - c n) = (%n. - diffs c n)"
   327 by (simp add: diffs_def)
   328 
   329 lemma sums_Suc_imp:
   330   assumes f: "f 0 = 0"
   331   shows "(\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   332 unfolding sums_def
   333 apply (rule LIMSEQ_imp_Suc)
   334 apply (subst setsum_shift_lb_Suc0_0_upt [where f=f, OF f, symmetric])
   335 apply (simp only: setsum_shift_bounds_Suc_ivl)
   336 done
   337 
   338 lemma diffs_equiv:
   339      "summable (%n. (diffs c)(n) * (x ^ n)) ==>  
   340       (%n. of_nat n * c(n) * (x ^ (n - Suc 0))) sums  
   341          (\<Sum>n. (diffs c)(n) * (x ^ n))"
   342 unfolding diffs_def
   343 apply (drule summable_sums)
   344 apply (rule sums_Suc_imp, simp_all)
   345 done
   346 
   347 lemma lemma_termdiff1:
   348   fixes z :: "'a :: {monoid_mult,comm_ring}" shows
   349   "(\<Sum>p=0..<m. (((z + h) ^ (m - p)) * (z ^ p)) - (z ^ m)) =  
   350    (\<Sum>p=0..<m. (z ^ p) * (((z + h) ^ (m - p)) - (z ^ (m - p))))"
   351 by(auto simp add: algebra_simps power_add [symmetric])
   352 
   353 lemma sumr_diff_mult_const2:
   354   "setsum f {0..<n} - of_nat n * (r::'a::ring_1) = (\<Sum>i = 0..<n. f i - r)"
   355 by (simp add: setsum_subtractf)
   356 
   357 lemma lemma_termdiff2:
   358   fixes h :: "'a :: {field}"
   359   assumes h: "h \<noteq> 0" shows
   360   "((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0) =
   361    h * (\<Sum>p=0..< n - Suc 0. \<Sum>q=0..< n - Suc 0 - p.
   362         (z + h) ^ q * z ^ (n - 2 - q))" (is "?lhs = ?rhs")
   363 apply (subgoal_tac "h * ?lhs = h * ?rhs", simp add: h)
   364 apply (simp add: right_diff_distrib diff_divide_distrib h)
   365 apply (simp add: mult_assoc [symmetric])
   366 apply (cases "n", simp)
   367 apply (simp add: lemma_realpow_diff_sumr2 h
   368                  right_diff_distrib [symmetric] mult_assoc
   369             del: power_Suc setsum_op_ivl_Suc of_nat_Suc)
   370 apply (subst lemma_realpow_rev_sumr)
   371 apply (subst sumr_diff_mult_const2)
   372 apply simp
   373 apply (simp only: lemma_termdiff1 setsum_right_distrib)
   374 apply (rule setsum_cong [OF refl])
   375 apply (simp add: diff_minus [symmetric] less_iff_Suc_add)
   376 apply (clarify)
   377 apply (simp add: setsum_right_distrib lemma_realpow_diff_sumr2 mult_ac
   378             del: setsum_op_ivl_Suc power_Suc)
   379 apply (subst mult_assoc [symmetric], subst power_add [symmetric])
   380 apply (simp add: mult_ac)
   381 done
   382 
   383 lemma real_setsum_nat_ivl_bounded2:
   384   fixes K :: "'a::linordered_semidom"
   385   assumes f: "\<And>p::nat. p < n \<Longrightarrow> f p \<le> K"
   386   assumes K: "0 \<le> K"
   387   shows "setsum f {0..<n-k} \<le> of_nat n * K"
   388 apply (rule order_trans [OF setsum_mono])
   389 apply (rule f, simp)
   390 apply (simp add: mult_right_mono K)
   391 done
   392 
   393 lemma lemma_termdiff3:
   394   fixes h z :: "'a::{real_normed_field}"
   395   assumes 1: "h \<noteq> 0"
   396   assumes 2: "norm z \<le> K"
   397   assumes 3: "norm (z + h) \<le> K"
   398   shows "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0))
   399           \<le> of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   400 proof -
   401   have "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0)) =
   402         norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   403           (z + h) ^ q * z ^ (n - 2 - q)) * norm h"
   404     apply (subst lemma_termdiff2 [OF 1])
   405     apply (subst norm_mult)
   406     apply (rule mult_commute)
   407     done
   408   also have "\<dots> \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2)) * norm h"
   409   proof (rule mult_right_mono [OF _ norm_ge_zero])
   410     from norm_ge_zero 2 have K: "0 \<le> K" by (rule order_trans)
   411     have le_Kn: "\<And>i j n. i + j = n \<Longrightarrow> norm ((z + h) ^ i * z ^ j) \<le> K ^ n"
   412       apply (erule subst)
   413       apply (simp only: norm_mult norm_power power_add)
   414       apply (intro mult_mono power_mono 2 3 norm_ge_zero zero_le_power K)
   415       done
   416     show "norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   417               (z + h) ^ q * z ^ (n - 2 - q))
   418           \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2))"
   419       apply (intro
   420          order_trans [OF norm_setsum]
   421          real_setsum_nat_ivl_bounded2
   422          mult_nonneg_nonneg
   423          zero_le_imp_of_nat
   424          zero_le_power K)
   425       apply (rule le_Kn, simp)
   426       done
   427   qed
   428   also have "\<dots> = of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   429     by (simp only: mult_assoc)
   430   finally show ?thesis .
   431 qed
   432 
   433 lemma lemma_termdiff4:
   434   fixes f :: "'a::{real_normed_field} \<Rightarrow>
   435               'b::real_normed_vector"
   436   assumes k: "0 < (k::real)"
   437   assumes le: "\<And>h. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (f h) \<le> K * norm h"
   438   shows "f -- 0 --> 0"
   439 unfolding LIM_eq diff_0_right
   440 proof (safe)
   441   let ?h = "of_real (k / 2)::'a"
   442   have "?h \<noteq> 0" and "norm ?h < k" using k by simp_all
   443   hence "norm (f ?h) \<le> K * norm ?h" by (rule le)
   444   hence "0 \<le> K * norm ?h" by (rule order_trans [OF norm_ge_zero])
   445   hence zero_le_K: "0 \<le> K" using k by (simp add: zero_le_mult_iff)
   446 
   447   fix r::real assume r: "0 < r"
   448   show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   449   proof (cases)
   450     assume "K = 0"
   451     with k r le have "0 < k \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < k \<longrightarrow> norm (f x) < r)"
   452       by simp
   453     thus "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)" ..
   454   next
   455     assume K_neq_zero: "K \<noteq> 0"
   456     with zero_le_K have K: "0 < K" by simp
   457     show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   458     proof (rule exI, safe)
   459       from k r K show "0 < min k (r * inverse K / 2)"
   460         by (simp add: mult_pos_pos positive_imp_inverse_positive)
   461     next
   462       fix x::'a
   463       assume x1: "x \<noteq> 0" and x2: "norm x < min k (r * inverse K / 2)"
   464       from x2 have x3: "norm x < k" and x4: "norm x < r * inverse K / 2"
   465         by simp_all
   466       from x1 x3 le have "norm (f x) \<le> K * norm x" by simp
   467       also from x4 K have "K * norm x < K * (r * inverse K / 2)"
   468         by (rule mult_strict_left_mono)
   469       also have "\<dots> = r / 2"
   470         using K_neq_zero by simp
   471       also have "r / 2 < r"
   472         using r by simp
   473       finally show "norm (f x) < r" .
   474     qed
   475   qed
   476 qed
   477 
   478 lemma lemma_termdiff5:
   479   fixes g :: "'a::{real_normed_field} \<Rightarrow>
   480               nat \<Rightarrow> 'b::banach"
   481   assumes k: "0 < (k::real)"
   482   assumes f: "summable f"
   483   assumes le: "\<And>h n. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (g h n) \<le> f n * norm h"
   484   shows "(\<lambda>h. suminf (g h)) -- 0 --> 0"
   485 proof (rule lemma_termdiff4 [OF k])
   486   fix h::'a assume "h \<noteq> 0" and "norm h < k"
   487   hence A: "\<forall>n. norm (g h n) \<le> f n * norm h"
   488     by (simp add: le)
   489   hence "\<exists>N. \<forall>n\<ge>N. norm (norm (g h n)) \<le> f n * norm h"
   490     by simp
   491   moreover from f have B: "summable (\<lambda>n. f n * norm h)"
   492     by (rule summable_mult2)
   493   ultimately have C: "summable (\<lambda>n. norm (g h n))"
   494     by (rule summable_comparison_test)
   495   hence "norm (suminf (g h)) \<le> (\<Sum>n. norm (g h n))"
   496     by (rule summable_norm)
   497   also from A C B have "(\<Sum>n. norm (g h n)) \<le> (\<Sum>n. f n * norm h)"
   498     by (rule summable_le)
   499   also from f have "(\<Sum>n. f n * norm h) = suminf f * norm h"
   500     by (rule suminf_mult2 [symmetric])
   501   finally show "norm (suminf (g h)) \<le> suminf f * norm h" .
   502 qed
   503 
   504 
   505 text{* FIXME: Long proofs*}
   506 
   507 lemma termdiffs_aux:
   508   fixes x :: "'a::{real_normed_field,banach}"
   509   assumes 1: "summable (\<lambda>n. diffs (diffs c) n * K ^ n)"
   510   assumes 2: "norm x < norm K"
   511   shows "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h
   512              - of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   513 proof -
   514   from dense [OF 2]
   515   obtain r where r1: "norm x < r" and r2: "r < norm K" by fast
   516   from norm_ge_zero r1 have r: "0 < r"
   517     by (rule order_le_less_trans)
   518   hence r_neq_0: "r \<noteq> 0" by simp
   519   show ?thesis
   520   proof (rule lemma_termdiff5)
   521     show "0 < r - norm x" using r1 by simp
   522   next
   523     from r r2 have "norm (of_real r::'a) < norm K"
   524       by simp
   525     with 1 have "summable (\<lambda>n. norm (diffs (diffs c) n * (of_real r ^ n)))"
   526       by (rule powser_insidea)
   527     hence "summable (\<lambda>n. diffs (diffs (\<lambda>n. norm (c n))) n * r ^ n)"
   528       using r
   529       by (simp add: diffs_def norm_mult norm_power del: of_nat_Suc)
   530     hence "summable (\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))"
   531       by (rule diffs_equiv [THEN sums_summable])
   532     also have "(\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))
   533       = (\<lambda>n. diffs (%m. of_nat (m - Suc 0) * norm (c m) * inverse r) n * (r ^ n))"
   534       apply (rule ext)
   535       apply (simp add: diffs_def)
   536       apply (case_tac n, simp_all add: r_neq_0)
   537       done
   538     finally have "summable 
   539       (\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) * r ^ (n - Suc 0))"
   540       by (rule diffs_equiv [THEN sums_summable])
   541     also have
   542       "(\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) *
   543            r ^ (n - Suc 0)) =
   544        (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))"
   545       apply (rule ext)
   546       apply (case_tac "n", simp)
   547       apply (case_tac "nat", simp)
   548       apply (simp add: r_neq_0)
   549       done
   550     finally show
   551       "summable (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))" .
   552   next
   553     fix h::'a and n::nat
   554     assume h: "h \<noteq> 0"
   555     assume "norm h < r - norm x"
   556     hence "norm x + norm h < r" by simp
   557     with norm_triangle_ineq have xh: "norm (x + h) < r"
   558       by (rule order_le_less_trans)
   559     show "norm (c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))
   560           \<le> norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2) * norm h"
   561       apply (simp only: norm_mult mult_assoc)
   562       apply (rule mult_left_mono [OF _ norm_ge_zero])
   563       apply (simp (no_asm) add: mult_assoc [symmetric])
   564       apply (rule lemma_termdiff3)
   565       apply (rule h)
   566       apply (rule r1 [THEN order_less_imp_le])
   567       apply (rule xh [THEN order_less_imp_le])
   568       done
   569   qed
   570 qed
   571 
   572 lemma termdiffs:
   573   fixes K x :: "'a::{real_normed_field,banach}"
   574   assumes 1: "summable (\<lambda>n. c n * K ^ n)"
   575   assumes 2: "summable (\<lambda>n. (diffs c) n * K ^ n)"
   576   assumes 3: "summable (\<lambda>n. (diffs (diffs c)) n * K ^ n)"
   577   assumes 4: "norm x < norm K"
   578   shows "DERIV (\<lambda>x. \<Sum>n. c n * x ^ n) x :> (\<Sum>n. (diffs c) n * x ^ n)"
   579 unfolding deriv_def
   580 proof (rule LIM_zero_cancel)
   581   show "(\<lambda>h. (suminf (\<lambda>n. c n * (x + h) ^ n) - suminf (\<lambda>n. c n * x ^ n)) / h
   582             - suminf (\<lambda>n. diffs c n * x ^ n)) -- 0 --> 0"
   583   proof (rule LIM_equal2)
   584     show "0 < norm K - norm x" using 4 by (simp add: less_diff_eq)
   585   next
   586     fix h :: 'a
   587     assume "h \<noteq> 0"
   588     assume "norm (h - 0) < norm K - norm x"
   589     hence "norm x + norm h < norm K" by simp
   590     hence 5: "norm (x + h) < norm K"
   591       by (rule norm_triangle_ineq [THEN order_le_less_trans])
   592     have A: "summable (\<lambda>n. c n * x ^ n)"
   593       by (rule powser_inside [OF 1 4])
   594     have B: "summable (\<lambda>n. c n * (x + h) ^ n)"
   595       by (rule powser_inside [OF 1 5])
   596     have C: "summable (\<lambda>n. diffs c n * x ^ n)"
   597       by (rule powser_inside [OF 2 4])
   598     show "((\<Sum>n. c n * (x + h) ^ n) - (\<Sum>n. c n * x ^ n)) / h
   599              - (\<Sum>n. diffs c n * x ^ n) = 
   600           (\<Sum>n. c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))"
   601       apply (subst sums_unique [OF diffs_equiv [OF C]])
   602       apply (subst suminf_diff [OF B A])
   603       apply (subst suminf_divide [symmetric])
   604       apply (rule summable_diff [OF B A])
   605       apply (subst suminf_diff)
   606       apply (rule summable_divide)
   607       apply (rule summable_diff [OF B A])
   608       apply (rule sums_summable [OF diffs_equiv [OF C]])
   609       apply (rule arg_cong [where f="suminf"], rule ext)
   610       apply (simp add: algebra_simps)
   611       done
   612   next
   613     show "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h -
   614                of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   615         by (rule termdiffs_aux [OF 3 4])
   616   qed
   617 qed
   618 
   619 
   620 subsection{* Some properties of factorials *}
   621 
   622 lemma real_of_nat_fact_not_zero [simp]: "real (fact (n::nat)) \<noteq> 0"
   623 by auto
   624 
   625 lemma real_of_nat_fact_gt_zero [simp]: "0 < real(fact (n::nat))"
   626 by auto
   627 
   628 lemma real_of_nat_fact_ge_zero [simp]: "0 \<le> real(fact (n::nat))"
   629 by simp
   630 
   631 lemma inv_real_of_nat_fact_gt_zero [simp]: "0 < inverse (real (fact (n::nat)))"
   632 by (auto simp add: positive_imp_inverse_positive)
   633 
   634 lemma inv_real_of_nat_fact_ge_zero [simp]: "0 \<le> inverse (real (fact (n::nat)))"
   635 by (auto intro: order_less_imp_le)
   636 
   637 subsection {* Derivability of power series *}
   638 
   639 lemma DERIV_series': fixes f :: "real \<Rightarrow> nat \<Rightarrow> real"
   640   assumes DERIV_f: "\<And> n. DERIV (\<lambda> x. f x n) x0 :> (f' x0 n)"
   641   and allf_summable: "\<And> x. x \<in> {a <..< b} \<Longrightarrow> summable (f x)" and x0_in_I: "x0 \<in> {a <..< b}"
   642   and "summable (f' x0)"
   643   and "summable L" and L_def: "\<And> n x y. \<lbrakk> x \<in> { a <..< b} ; y \<in> { a <..< b} \<rbrakk> \<Longrightarrow> \<bar> f x n - f y n \<bar> \<le> L n * \<bar> x - y \<bar>"
   644   shows "DERIV (\<lambda> x. suminf (f x)) x0 :> (suminf (f' x0))"
   645   unfolding deriv_def
   646 proof (rule LIM_I)
   647   fix r :: real assume "0 < r" hence "0 < r/3" by auto
   648 
   649   obtain N_L where N_L: "\<And> n. N_L \<le> n \<Longrightarrow> \<bar> \<Sum> i. L (i + n) \<bar> < r/3" 
   650     using suminf_exist_split[OF `0 < r/3` `summable L`] by auto
   651 
   652   obtain N_f' where N_f': "\<And> n. N_f' \<le> n \<Longrightarrow> \<bar> \<Sum> i. f' x0 (i + n) \<bar> < r/3" 
   653     using suminf_exist_split[OF `0 < r/3` `summable (f' x0)`] by auto
   654 
   655   let ?N = "Suc (max N_L N_f')"
   656   have "\<bar> \<Sum> i. f' x0 (i + ?N) \<bar> < r/3" (is "?f'_part < r/3") and
   657     L_estimate: "\<bar> \<Sum> i. L (i + ?N) \<bar> < r/3" using N_L[of "?N"] and N_f' [of "?N"] by auto
   658 
   659   let "?diff i x" = "(f (x0 + x) i - f x0 i) / x"
   660 
   661   let ?r = "r / (3 * real ?N)"
   662   have "0 < 3 * real ?N" by auto
   663   from divide_pos_pos[OF `0 < r` this]
   664   have "0 < ?r" .
   665 
   666   let "?s n" = "SOME s. 0 < s \<and> (\<forall> x. x \<noteq> 0 \<and> \<bar> x \<bar> < s \<longrightarrow> \<bar> ?diff n x - f' x0 n \<bar> < ?r)"
   667   def S' \<equiv> "Min (?s ` { 0 ..< ?N })"
   668 
   669   have "0 < S'" unfolding S'_def
   670   proof (rule iffD2[OF Min_gr_iff])
   671     show "\<forall> x \<in> (?s ` { 0 ..< ?N }). 0 < x"
   672     proof (rule ballI)
   673       fix x assume "x \<in> ?s ` {0..<?N}"
   674       then obtain n where "x = ?s n" and "n \<in> {0..<?N}" using image_iff[THEN iffD1] by blast
   675       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def] 
   676       obtain s where s_bound: "0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < s \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r)" by auto
   677       have "0 < ?s n" by (rule someI2[where a=s], auto simp add: s_bound)
   678       thus "0 < x" unfolding `x = ?s n` .
   679     qed
   680   qed auto
   681 
   682   def S \<equiv> "min (min (x0 - a) (b - x0)) S'"
   683   hence "0 < S" and S_a: "S \<le> x0 - a" and S_b: "S \<le> b - x0" and "S \<le> S'" using x0_in_I and `0 < S'`
   684     by auto
   685 
   686   { fix x assume "x \<noteq> 0" and "\<bar> x \<bar> < S"
   687     hence x_in_I: "x0 + x \<in> { a <..< b }" using S_a S_b by auto
   688     
   689     note diff_smbl = summable_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   690     note div_smbl = summable_divide[OF diff_smbl]
   691     note all_smbl = summable_diff[OF div_smbl `summable (f' x0)`]
   692     note ign = summable_ignore_initial_segment[where k="?N"]
   693     note diff_shft_smbl = summable_diff[OF ign[OF allf_summable[OF x_in_I]] ign[OF allf_summable[OF x0_in_I]]]
   694     note div_shft_smbl = summable_divide[OF diff_shft_smbl]
   695     note all_shft_smbl = summable_diff[OF div_smbl ign[OF `summable (f' x0)`]]
   696 
   697     { fix n
   698       have "\<bar> ?diff (n + ?N) x \<bar> \<le> L (n + ?N) * \<bar> (x0 + x) - x0 \<bar> / \<bar> x \<bar>" 
   699         using divide_right_mono[OF L_def[OF x_in_I x0_in_I] abs_ge_zero] unfolding abs_divide .
   700       hence "\<bar> ( \<bar> ?diff (n + ?N) x \<bar>) \<bar> \<le> L (n + ?N)" using `x \<noteq> 0` by auto
   701     } note L_ge = summable_le2[OF allI[OF this] ign[OF `summable L`]]
   702     from order_trans[OF summable_rabs[OF conjunct1[OF L_ge]] L_ge[THEN conjunct2]]
   703     have "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> (\<Sum> i. L (i + ?N))" .
   704     hence "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> r / 3" (is "?L_part \<le> r/3") using L_estimate by auto
   705 
   706     have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> \<le> (\<Sum>n \<in> { 0 ..< ?N}. \<bar>?diff n x - f' x0 n \<bar>)" ..
   707     also have "\<dots> < (\<Sum>n \<in> { 0 ..< ?N}. ?r)"
   708     proof (rule setsum_strict_mono)
   709       fix n assume "n \<in> { 0 ..< ?N}"
   710       have "\<bar> x \<bar> < S" using `\<bar> x \<bar> < S` .
   711       also have "S \<le> S'" using `S \<le> S'` .
   712       also have "S' \<le> ?s n" unfolding S'_def 
   713       proof (rule Min_le_iff[THEN iffD2])
   714         have "?s n \<in> (?s ` {0..<?N}) \<and> ?s n \<le> ?s n" using `n \<in> { 0 ..< ?N}` by auto
   715         thus "\<exists> a \<in> (?s ` {0..<?N}). a \<le> ?s n" by blast
   716       qed auto
   717       finally have "\<bar> x \<bar> < ?s n" .
   718 
   719       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def diff_0_right, unfolded some_eq_ex[symmetric], THEN conjunct2]
   720       have "\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < ?s n \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r" .
   721       with `x \<noteq> 0` and `\<bar>x\<bar> < ?s n`
   722       show "\<bar>?diff n x - f' x0 n\<bar> < ?r" by blast
   723     qed auto
   724     also have "\<dots> = of_nat (card {0 ..< ?N}) * ?r" by (rule setsum_constant)
   725     also have "\<dots> = real ?N * ?r" unfolding real_eq_of_nat by auto
   726     also have "\<dots> = r/3" by auto
   727     finally have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> < r / 3" (is "?diff_part < r / 3") .
   728 
   729     from suminf_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   730     have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> = 
   731                     \<bar> \<Sum>n. ?diff n x - f' x0 n \<bar>" unfolding suminf_diff[OF div_smbl `summable (f' x0)`, symmetric] using suminf_divide[OF diff_smbl, symmetric] by auto
   732     also have "\<dots> \<le> ?diff_part + \<bar> (\<Sum>n. ?diff (n + ?N) x) - (\<Sum> n. f' x0 (n + ?N)) \<bar>" unfolding suminf_split_initial_segment[OF all_smbl, where k="?N"] unfolding suminf_diff[OF div_shft_smbl ign[OF `summable (f' x0)`]] by (rule abs_triangle_ineq)
   733     also have "\<dots> \<le> ?diff_part + ?L_part + ?f'_part" using abs_triangle_ineq4 by auto
   734     also have "\<dots> < r /3 + r/3 + r/3" 
   735       using `?diff_part < r/3` `?L_part \<le> r/3` and `?f'_part < r/3`
   736       by (rule add_strict_mono [OF add_less_le_mono])
   737     finally have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> < r"
   738       by auto
   739   } thus "\<exists> s > 0. \<forall> x. x \<noteq> 0 \<and> norm (x - 0) < s \<longrightarrow> 
   740       norm (((\<Sum>n. f (x0 + x) n) - (\<Sum>n. f x0 n)) / x - (\<Sum>n. f' x0 n)) < r" using `0 < S`
   741     unfolding real_norm_def diff_0_right by blast
   742 qed
   743 
   744 lemma DERIV_power_series': fixes f :: "nat \<Rightarrow> real"
   745   assumes converges: "\<And> x. x \<in> {-R <..< R} \<Longrightarrow> summable (\<lambda> n. f n * real (Suc n) * x^n)"
   746   and x0_in_I: "x0 \<in> {-R <..< R}" and "0 < R"
   747   shows "DERIV (\<lambda> x. (\<Sum> n. f n * x^(Suc n))) x0 :> (\<Sum> n. f n * real (Suc n) * x0^n)"
   748   (is "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))")
   749 proof -
   750   { fix R' assume "0 < R'" and "R' < R" and "-R' < x0" and "x0 < R'"
   751     hence "x0 \<in> {-R' <..< R'}" and "R' \<in> {-R <..< R}" and "x0 \<in> {-R <..< R}" by auto
   752     have "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))"
   753     proof (rule DERIV_series')
   754       show "summable (\<lambda> n. \<bar>f n * real (Suc n) * R'^n\<bar>)"
   755       proof -
   756         have "(R' + R) / 2 < R" and "0 < (R' + R) / 2" using `0 < R'` `0 < R` `R' < R` by auto
   757         hence in_Rball: "(R' + R) / 2 \<in> {-R <..< R}" using `R' < R` by auto
   758         have "norm R' < norm ((R' + R) / 2)" using `0 < R'` `0 < R` `R' < R` by auto
   759         from powser_insidea[OF converges[OF in_Rball] this] show ?thesis by auto
   760       qed
   761       { fix n x y assume "x \<in> {-R' <..< R'}" and "y \<in> {-R' <..< R'}"
   762         show "\<bar>?f x n - ?f y n\<bar> \<le> \<bar>f n * real (Suc n) * R'^n\<bar> * \<bar>x-y\<bar>"
   763         proof -
   764           have "\<bar>f n * x ^ (Suc n) - f n * y ^ (Suc n)\<bar> = (\<bar>f n\<bar> * \<bar>x-y\<bar>) * \<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar>" 
   765             unfolding right_diff_distrib[symmetric] lemma_realpow_diff_sumr2 abs_mult by auto
   766           also have "\<dots> \<le> (\<bar>f n\<bar> * \<bar>x-y\<bar>) * (\<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>)" 
   767           proof (rule mult_left_mono)
   768             have "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> (\<Sum>p = 0..<Suc n. \<bar>x ^ p * y ^ (n - p)\<bar>)" by (rule setsum_abs)
   769             also have "\<dots> \<le> (\<Sum>p = 0..<Suc n. R' ^ n)"
   770             proof (rule setsum_mono)
   771               fix p assume "p \<in> {0..<Suc n}" hence "p \<le> n" by auto
   772               { fix n fix x :: real assume "x \<in> {-R'<..<R'}"
   773                 hence "\<bar>x\<bar> \<le> R'"  by auto
   774                 hence "\<bar>x^n\<bar> \<le> R'^n" unfolding power_abs by (rule power_mono, auto)
   775               } from mult_mono[OF this[OF `x \<in> {-R'<..<R'}`, of p] this[OF `y \<in> {-R'<..<R'}`, of "n-p"]] `0 < R'`
   776               have "\<bar>x^p * y^(n-p)\<bar> \<le> R'^p * R'^(n-p)" unfolding abs_mult by auto
   777               thus "\<bar>x^p * y^(n-p)\<bar> \<le> R'^n" unfolding power_add[symmetric] using `p \<le> n` by auto
   778             qed
   779             also have "\<dots> = real (Suc n) * R' ^ n" unfolding setsum_constant card_atLeastLessThan real_of_nat_def by auto
   780             finally show "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> \<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>" unfolding abs_real_of_nat_cancel abs_of_nonneg[OF zero_le_power[OF less_imp_le[OF `0 < R'`]]] .
   781             show "0 \<le> \<bar>f n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult[symmetric] by auto
   782           qed
   783           also have "\<dots> = \<bar>f n * real (Suc n) * R' ^ n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult mult_assoc[symmetric] by algebra
   784           finally show ?thesis .
   785         qed }
   786       { fix n show "DERIV (\<lambda> x. ?f x n) x0 :> (?f' x0 n)"
   787           by (auto intro!: DERIV_intros simp del: power_Suc) }
   788       { fix x assume "x \<in> {-R' <..< R'}" hence "R' \<in> {-R <..< R}" and "norm x < norm R'" using assms `R' < R` by auto
   789         have "summable (\<lambda> n. f n * x^n)"
   790         proof (rule summable_le2[THEN conjunct1, OF _ powser_insidea[OF converges[OF `R' \<in> {-R <..< R}`] `norm x < norm R'`]], rule allI)
   791           fix n
   792           have le: "\<bar>f n\<bar> * 1 \<le> \<bar>f n\<bar> * real (Suc n)" by (rule mult_left_mono, auto)
   793           show "\<bar>f n * x ^ n\<bar> \<le> norm (f n * real (Suc n) * x ^ n)" unfolding real_norm_def abs_mult
   794             by (rule mult_right_mono, auto simp add: le[unfolded mult_1_right])
   795         qed
   796         from this[THEN summable_mult2[where c=x], unfolded mult_assoc, unfolded mult_commute]
   797         show "summable (?f x)" by auto }
   798       show "summable (?f' x0)" using converges[OF `x0 \<in> {-R <..< R}`] .
   799       show "x0 \<in> {-R' <..< R'}" using `x0 \<in> {-R' <..< R'}` .
   800     qed
   801   } note for_subinterval = this
   802   let ?R = "(R + \<bar>x0\<bar>) / 2"
   803   have "\<bar>x0\<bar> < ?R" using assms by auto
   804   hence "- ?R < x0"
   805   proof (cases "x0 < 0")
   806     case True
   807     hence "- x0 < ?R" using `\<bar>x0\<bar> < ?R` by auto
   808     thus ?thesis unfolding neg_less_iff_less[symmetric, of "- x0"] by auto
   809   next
   810     case False
   811     have "- ?R < 0" using assms by auto
   812     also have "\<dots> \<le> x0" using False by auto 
   813     finally show ?thesis .
   814   qed
   815   hence "0 < ?R" "?R < R" "- ?R < x0" and "x0 < ?R" using assms by auto
   816   from for_subinterval[OF this]
   817   show ?thesis .
   818 qed
   819 
   820 subsection {* Exponential Function *}
   821 
   822 definition
   823   exp :: "'a \<Rightarrow> 'a::{real_normed_field,banach}" where
   824   "exp x = (\<Sum>n. x ^ n /\<^sub>R real (fact n))"
   825 
   826 lemma summable_exp_generic:
   827   fixes x :: "'a::{real_normed_algebra_1,banach}"
   828   defines S_def: "S \<equiv> \<lambda>n. x ^ n /\<^sub>R real (fact n)"
   829   shows "summable S"
   830 proof -
   831   have S_Suc: "\<And>n. S (Suc n) = (x * S n) /\<^sub>R real (Suc n)"
   832     unfolding S_def by (simp del: mult_Suc)
   833   obtain r :: real where r0: "0 < r" and r1: "r < 1"
   834     using dense [OF zero_less_one] by fast
   835   obtain N :: nat where N: "norm x < real N * r"
   836     using reals_Archimedean3 [OF r0] by fast
   837   from r1 show ?thesis
   838   proof (rule ratio_test [rule_format])
   839     fix n :: nat
   840     assume n: "N \<le> n"
   841     have "norm x \<le> real N * r"
   842       using N by (rule order_less_imp_le)
   843     also have "real N * r \<le> real (Suc n) * r"
   844       using r0 n by (simp add: mult_right_mono)
   845     finally have "norm x * norm (S n) \<le> real (Suc n) * r * norm (S n)"
   846       using norm_ge_zero by (rule mult_right_mono)
   847     hence "norm (x * S n) \<le> real (Suc n) * r * norm (S n)"
   848       by (rule order_trans [OF norm_mult_ineq])
   849     hence "norm (x * S n) / real (Suc n) \<le> r * norm (S n)"
   850       by (simp add: pos_divide_le_eq mult_ac)
   851     thus "norm (S (Suc n)) \<le> r * norm (S n)"
   852       by (simp add: S_Suc inverse_eq_divide)
   853   qed
   854 qed
   855 
   856 lemma summable_norm_exp:
   857   fixes x :: "'a::{real_normed_algebra_1,banach}"
   858   shows "summable (\<lambda>n. norm (x ^ n /\<^sub>R real (fact n)))"
   859 proof (rule summable_norm_comparison_test [OF exI, rule_format])
   860   show "summable (\<lambda>n. norm x ^ n /\<^sub>R real (fact n))"
   861     by (rule summable_exp_generic)
   862 next
   863   fix n show "norm (x ^ n /\<^sub>R real (fact n)) \<le> norm x ^ n /\<^sub>R real (fact n)"
   864     by (simp add: norm_power_ineq)
   865 qed
   866 
   867 lemma summable_exp: "summable (%n. inverse (real (fact n)) * x ^ n)"
   868 by (insert summable_exp_generic [where x=x], simp)
   869 
   870 lemma exp_converges: "(\<lambda>n. x ^ n /\<^sub>R real (fact n)) sums exp x"
   871 unfolding exp_def by (rule summable_exp_generic [THEN summable_sums])
   872 
   873 
   874 lemma exp_fdiffs: 
   875       "diffs (%n. inverse(real (fact n))) = (%n. inverse(real (fact n)))"
   876 by (simp add: diffs_def mult_assoc [symmetric] real_of_nat_def of_nat_mult
   877          del: mult_Suc of_nat_Suc)
   878 
   879 lemma diffs_of_real: "diffs (\<lambda>n. of_real (f n)) = (\<lambda>n. of_real (diffs f n))"
   880 by (simp add: diffs_def)
   881 
   882 lemma lemma_exp_ext: "exp = (\<lambda>x. \<Sum>n. x ^ n /\<^sub>R real (fact n))"
   883 by (auto intro!: ext simp add: exp_def)
   884 
   885 lemma DERIV_exp [simp]: "DERIV exp x :> exp(x)"
   886 apply (simp add: exp_def)
   887 apply (subst lemma_exp_ext)
   888 apply (subgoal_tac "DERIV (\<lambda>u. \<Sum>n. of_real (inverse (real (fact n))) * u ^ n) x :> (\<Sum>n. diffs (\<lambda>n. of_real (inverse (real (fact n)))) n * x ^ n)")
   889 apply (rule_tac [2] K = "of_real (1 + norm x)" in termdiffs)
   890 apply (simp_all only: diffs_of_real scaleR_conv_of_real exp_fdiffs)
   891 apply (rule exp_converges [THEN sums_summable, unfolded scaleR_conv_of_real])+
   892 apply (simp del: of_real_add)
   893 done
   894 
   895 lemma isCont_exp [simp]: "isCont exp x"
   896 by (rule DERIV_exp [THEN DERIV_isCont])
   897 
   898 
   899 subsubsection {* Properties of the Exponential Function *}
   900 
   901 lemma powser_zero:
   902   fixes f :: "nat \<Rightarrow> 'a::{real_normed_algebra_1}"
   903   shows "(\<Sum>n. f n * 0 ^ n) = f 0"
   904 proof -
   905   have "(\<Sum>n = 0..<1. f n * 0 ^ n) = (\<Sum>n. f n * 0 ^ n)"
   906     by (rule sums_unique [OF series_zero], simp add: power_0_left)
   907   thus ?thesis unfolding One_nat_def by simp
   908 qed
   909 
   910 lemma exp_zero [simp]: "exp 0 = 1"
   911 unfolding exp_def by (simp add: scaleR_conv_of_real powser_zero)
   912 
   913 lemma setsum_cl_ivl_Suc2:
   914   "(\<Sum>i=m..Suc n. f i) = (if Suc n < m then 0 else f m + (\<Sum>i=m..n. f (Suc i)))"
   915 by (simp add: setsum_head_Suc setsum_shift_bounds_cl_Suc_ivl
   916          del: setsum_cl_ivl_Suc)
   917 
   918 lemma exp_series_add:
   919   fixes x y :: "'a::{real_field}"
   920   defines S_def: "S \<equiv> \<lambda>x n. x ^ n /\<^sub>R real (fact n)"
   921   shows "S (x + y) n = (\<Sum>i=0..n. S x i * S y (n - i))"
   922 proof (induct n)
   923   case 0
   924   show ?case
   925     unfolding S_def by simp
   926 next
   927   case (Suc n)
   928   have S_Suc: "\<And>x n. S x (Suc n) = (x * S x n) /\<^sub>R real (Suc n)"
   929     unfolding S_def by (simp del: mult_Suc)
   930   hence times_S: "\<And>x n. x * S x n = real (Suc n) *\<^sub>R S x (Suc n)"
   931     by simp
   932 
   933   have "real (Suc n) *\<^sub>R S (x + y) (Suc n) = (x + y) * S (x + y) n"
   934     by (simp only: times_S)
   935   also have "\<dots> = (x + y) * (\<Sum>i=0..n. S x i * S y (n-i))"
   936     by (simp only: Suc)
   937   also have "\<dots> = x * (\<Sum>i=0..n. S x i * S y (n-i))
   938                 + y * (\<Sum>i=0..n. S x i * S y (n-i))"
   939     by (rule left_distrib)
   940   also have "\<dots> = (\<Sum>i=0..n. (x * S x i) * S y (n-i))
   941                 + (\<Sum>i=0..n. S x i * (y * S y (n-i)))"
   942     by (simp only: setsum_right_distrib mult_ac)
   943   also have "\<dots> = (\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i)))
   944                 + (\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   945     by (simp add: times_S Suc_diff_le)
   946   also have "(\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i))) =
   947              (\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i)))"
   948     by (subst setsum_cl_ivl_Suc2, simp)
   949   also have "(\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   950              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   951     by (subst setsum_cl_ivl_Suc, simp)
   952   also have "(\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i))) +
   953              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   954              (\<Sum>i=0..Suc n. real (Suc n) *\<^sub>R (S x i * S y (Suc n-i)))"
   955     by (simp only: setsum_addf [symmetric] scaleR_left_distrib [symmetric]
   956               real_of_nat_add [symmetric], simp)
   957   also have "\<dots> = real (Suc n) *\<^sub>R (\<Sum>i=0..Suc n. S x i * S y (Suc n-i))"
   958     by (simp only: scaleR_right.setsum)
   959   finally show
   960     "S (x + y) (Suc n) = (\<Sum>i=0..Suc n. S x i * S y (Suc n - i))"
   961     by (simp del: setsum_cl_ivl_Suc)
   962 qed
   963 
   964 lemma exp_add: "exp (x + y) = exp x * exp y"
   965 unfolding exp_def
   966 by (simp only: Cauchy_product summable_norm_exp exp_series_add)
   967 
   968 lemma mult_exp_exp: "exp x * exp y = exp (x + y)"
   969 by (rule exp_add [symmetric])
   970 
   971 lemma exp_of_real: "exp (of_real x) = of_real (exp x)"
   972 unfolding exp_def
   973 apply (subst of_real.suminf)
   974 apply (rule summable_exp_generic)
   975 apply (simp add: scaleR_conv_of_real)
   976 done
   977 
   978 lemma exp_not_eq_zero [simp]: "exp x \<noteq> 0"
   979 proof
   980   have "exp x * exp (- x) = 1" by (simp add: mult_exp_exp)
   981   also assume "exp x = 0"
   982   finally show "False" by simp
   983 qed
   984 
   985 lemma exp_minus: "exp (- x) = inverse (exp x)"
   986 by (rule inverse_unique [symmetric], simp add: mult_exp_exp)
   987 
   988 lemma exp_diff: "exp (x - y) = exp x / exp y"
   989   unfolding diff_minus divide_inverse
   990   by (simp add: exp_add exp_minus)
   991 
   992 
   993 subsubsection {* Properties of the Exponential Function on Reals *}
   994 
   995 text {* Comparisons of @{term "exp x"} with zero. *}
   996 
   997 text{*Proof: because every exponential can be seen as a square.*}
   998 lemma exp_ge_zero [simp]: "0 \<le> exp (x::real)"
   999 proof -
  1000   have "0 \<le> exp (x/2) * exp (x/2)" by simp
  1001   thus ?thesis by (simp add: exp_add [symmetric])
  1002 qed
  1003 
  1004 lemma exp_gt_zero [simp]: "0 < exp (x::real)"
  1005 by (simp add: order_less_le)
  1006 
  1007 lemma not_exp_less_zero [simp]: "\<not> exp (x::real) < 0"
  1008 by (simp add: not_less)
  1009 
  1010 lemma not_exp_le_zero [simp]: "\<not> exp (x::real) \<le> 0"
  1011 by (simp add: not_le)
  1012 
  1013 lemma abs_exp_cancel [simp]: "\<bar>exp x::real\<bar> = exp x"
  1014 by simp
  1015 
  1016 lemma exp_real_of_nat_mult: "exp(real n * x) = exp(x) ^ n"
  1017 apply (induct "n")
  1018 apply (auto simp add: real_of_nat_Suc right_distrib exp_add mult_commute)
  1019 done
  1020 
  1021 text {* Strict monotonicity of exponential. *}
  1022 
  1023 lemma exp_ge_add_one_self_aux: "0 \<le> (x::real) ==> (1 + x) \<le> exp(x)"
  1024 apply (drule order_le_imp_less_or_eq, auto)
  1025 apply (simp add: exp_def)
  1026 apply (rule order_trans)
  1027 apply (rule_tac [2] n = 2 and f = "(%n. inverse (real (fact n)) * x ^ n)" in series_pos_le)
  1028 apply (auto intro: summable_exp simp add: numeral_2_eq_2 zero_le_mult_iff)
  1029 done
  1030 
  1031 lemma exp_gt_one: "0 < (x::real) \<Longrightarrow> 1 < exp x"
  1032 proof -
  1033   assume x: "0 < x"
  1034   hence "1 < 1 + x" by simp
  1035   also from x have "1 + x \<le> exp x"
  1036     by (simp add: exp_ge_add_one_self_aux)
  1037   finally show ?thesis .
  1038 qed
  1039 
  1040 lemma exp_less_mono:
  1041   fixes x y :: real
  1042   assumes "x < y" shows "exp x < exp y"
  1043 proof -
  1044   from `x < y` have "0 < y - x" by simp
  1045   hence "1 < exp (y - x)" by (rule exp_gt_one)
  1046   hence "1 < exp y / exp x" by (simp only: exp_diff)
  1047   thus "exp x < exp y" by simp
  1048 qed
  1049 
  1050 lemma exp_less_cancel: "exp (x::real) < exp y ==> x < y"
  1051 apply (simp add: linorder_not_le [symmetric])
  1052 apply (auto simp add: order_le_less exp_less_mono)
  1053 done
  1054 
  1055 lemma exp_less_cancel_iff [iff]: "exp (x::real) < exp y \<longleftrightarrow> x < y"
  1056 by (auto intro: exp_less_mono exp_less_cancel)
  1057 
  1058 lemma exp_le_cancel_iff [iff]: "exp (x::real) \<le> exp y \<longleftrightarrow> x \<le> y"
  1059 by (auto simp add: linorder_not_less [symmetric])
  1060 
  1061 lemma exp_inj_iff [iff]: "exp (x::real) = exp y \<longleftrightarrow> x = y"
  1062 by (simp add: order_eq_iff)
  1063 
  1064 text {* Comparisons of @{term "exp x"} with one. *}
  1065 
  1066 lemma one_less_exp_iff [simp]: "1 < exp (x::real) \<longleftrightarrow> 0 < x"
  1067   using exp_less_cancel_iff [where x=0 and y=x] by simp
  1068 
  1069 lemma exp_less_one_iff [simp]: "exp (x::real) < 1 \<longleftrightarrow> x < 0"
  1070   using exp_less_cancel_iff [where x=x and y=0] by simp
  1071 
  1072 lemma one_le_exp_iff [simp]: "1 \<le> exp (x::real) \<longleftrightarrow> 0 \<le> x"
  1073   using exp_le_cancel_iff [where x=0 and y=x] by simp
  1074 
  1075 lemma exp_le_one_iff [simp]: "exp (x::real) \<le> 1 \<longleftrightarrow> x \<le> 0"
  1076   using exp_le_cancel_iff [where x=x and y=0] by simp
  1077 
  1078 lemma exp_eq_one_iff [simp]: "exp (x::real) = 1 \<longleftrightarrow> x = 0"
  1079   using exp_inj_iff [where x=x and y=0] by simp
  1080 
  1081 lemma lemma_exp_total: "1 \<le> y ==> \<exists>x. 0 \<le> x & x \<le> y - 1 & exp(x::real) = y"
  1082 apply (rule IVT)
  1083 apply (auto intro: isCont_exp simp add: le_diff_eq)
  1084 apply (subgoal_tac "1 + (y - 1) \<le> exp (y - 1)") 
  1085 apply simp
  1086 apply (rule exp_ge_add_one_self_aux, simp)
  1087 done
  1088 
  1089 lemma exp_total: "0 < (y::real) ==> \<exists>x. exp x = y"
  1090 apply (rule_tac x = 1 and y = y in linorder_cases)
  1091 apply (drule order_less_imp_le [THEN lemma_exp_total])
  1092 apply (rule_tac [2] x = 0 in exI)
  1093 apply (frule_tac [3] one_less_inverse)
  1094 apply (drule_tac [4] order_less_imp_le [THEN lemma_exp_total], auto)
  1095 apply (rule_tac x = "-x" in exI)
  1096 apply (simp add: exp_minus)
  1097 done
  1098 
  1099 
  1100 subsection {* Natural Logarithm *}
  1101 
  1102 definition
  1103   ln :: "real => real" where
  1104   "ln x = (THE u. exp u = x)"
  1105 
  1106 lemma ln_exp [simp]: "ln (exp x) = x"
  1107 by (simp add: ln_def)
  1108 
  1109 lemma exp_ln [simp]: "0 < x \<Longrightarrow> exp (ln x) = x"
  1110 by (auto dest: exp_total)
  1111 
  1112 lemma exp_ln_iff [simp]: "exp (ln x) = x \<longleftrightarrow> 0 < x"
  1113 apply (rule iffI)
  1114 apply (erule subst, rule exp_gt_zero)
  1115 apply (erule exp_ln)
  1116 done
  1117 
  1118 lemma ln_unique: "exp y = x \<Longrightarrow> ln x = y"
  1119 by (erule subst, rule ln_exp)
  1120 
  1121 lemma ln_one [simp]: "ln 1 = 0"
  1122 by (rule ln_unique, simp)
  1123 
  1124 lemma ln_mult: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x * y) = ln x + ln y"
  1125 by (rule ln_unique, simp add: exp_add)
  1126 
  1127 lemma ln_inverse: "0 < x \<Longrightarrow> ln (inverse x) = - ln x"
  1128 by (rule ln_unique, simp add: exp_minus)
  1129 
  1130 lemma ln_div: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x / y) = ln x - ln y"
  1131 by (rule ln_unique, simp add: exp_diff)
  1132 
  1133 lemma ln_realpow: "0 < x \<Longrightarrow> ln (x ^ n) = real n * ln x"
  1134 by (rule ln_unique, simp add: exp_real_of_nat_mult)
  1135 
  1136 lemma ln_less_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x < ln y \<longleftrightarrow> x < y"
  1137 by (subst exp_less_cancel_iff [symmetric], simp)
  1138 
  1139 lemma ln_le_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x \<le> ln y \<longleftrightarrow> x \<le> y"
  1140 by (simp add: linorder_not_less [symmetric])
  1141 
  1142 lemma ln_inj_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x = ln y \<longleftrightarrow> x = y"
  1143 by (simp add: order_eq_iff)
  1144 
  1145 lemma ln_add_one_self_le_self [simp]: "0 \<le> x \<Longrightarrow> ln (1 + x) \<le> x"
  1146 apply (rule exp_le_cancel_iff [THEN iffD1])
  1147 apply (simp add: exp_ge_add_one_self_aux)
  1148 done
  1149 
  1150 lemma ln_less_self [simp]: "0 < x \<Longrightarrow> ln x < x"
  1151 by (rule order_less_le_trans [where y="ln (1 + x)"]) simp_all
  1152 
  1153 lemma ln_ge_zero [simp]:
  1154   assumes x: "1 \<le> x" shows "0 \<le> ln x"
  1155 proof -
  1156   have "0 < x" using x by arith
  1157   hence "exp 0 \<le> exp (ln x)"
  1158     by (simp add: x)
  1159   thus ?thesis by (simp only: exp_le_cancel_iff)
  1160 qed
  1161 
  1162 lemma ln_ge_zero_imp_ge_one:
  1163   assumes ln: "0 \<le> ln x" 
  1164       and x:  "0 < x"
  1165   shows "1 \<le> x"
  1166 proof -
  1167   from ln have "ln 1 \<le> ln x" by simp
  1168   thus ?thesis by (simp add: x del: ln_one) 
  1169 qed
  1170 
  1171 lemma ln_ge_zero_iff [simp]: "0 < x ==> (0 \<le> ln x) = (1 \<le> x)"
  1172 by (blast intro: ln_ge_zero ln_ge_zero_imp_ge_one)
  1173 
  1174 lemma ln_less_zero_iff [simp]: "0 < x ==> (ln x < 0) = (x < 1)"
  1175 by (insert ln_ge_zero_iff [of x], arith)
  1176 
  1177 lemma ln_gt_zero:
  1178   assumes x: "1 < x" shows "0 < ln x"
  1179 proof -
  1180   have "0 < x" using x by arith
  1181   hence "exp 0 < exp (ln x)" by (simp add: x)
  1182   thus ?thesis  by (simp only: exp_less_cancel_iff)
  1183 qed
  1184 
  1185 lemma ln_gt_zero_imp_gt_one:
  1186   assumes ln: "0 < ln x" 
  1187       and x:  "0 < x"
  1188   shows "1 < x"
  1189 proof -
  1190   from ln have "ln 1 < ln x" by simp
  1191   thus ?thesis by (simp add: x del: ln_one) 
  1192 qed
  1193 
  1194 lemma ln_gt_zero_iff [simp]: "0 < x ==> (0 < ln x) = (1 < x)"
  1195 by (blast intro: ln_gt_zero ln_gt_zero_imp_gt_one)
  1196 
  1197 lemma ln_eq_zero_iff [simp]: "0 < x ==> (ln x = 0) = (x = 1)"
  1198 by (insert ln_less_zero_iff [of x] ln_gt_zero_iff [of x], arith)
  1199 
  1200 lemma ln_less_zero: "[| 0 < x; x < 1 |] ==> ln x < 0"
  1201 by simp
  1202 
  1203 lemma exp_ln_eq: "exp u = x ==> ln x = u"
  1204 by auto
  1205 
  1206 lemma isCont_ln: "0 < x \<Longrightarrow> isCont ln x"
  1207 apply (subgoal_tac "isCont ln (exp (ln x))", simp)
  1208 apply (rule isCont_inverse_function [where f=exp], simp_all)
  1209 done
  1210 
  1211 lemma DERIV_ln: "0 < x \<Longrightarrow> DERIV ln x :> inverse x"
  1212 apply (rule DERIV_inverse_function [where f=exp and a=0 and b="x+1"])
  1213 apply (erule lemma_DERIV_subst [OF DERIV_exp exp_ln])
  1214 apply (simp_all add: abs_if isCont_ln)
  1215 done
  1216 
  1217 lemma DERIV_ln_divide: "0 < x ==> DERIV ln x :> 1 / x"
  1218   by (rule DERIV_ln[THEN DERIV_cong], simp, simp add: divide_inverse)
  1219 
  1220 lemma ln_series: assumes "0 < x" and "x < 2"
  1221   shows "ln x = (\<Sum> n. (-1)^n * (1 / real (n + 1)) * (x - 1)^(Suc n))" (is "ln x = suminf (?f (x - 1))")
  1222 proof -
  1223   let "?f' x n" = "(-1)^n * (x - 1)^n"
  1224 
  1225   have "ln x - suminf (?f (x - 1)) = ln 1 - suminf (?f (1 - 1))"
  1226   proof (rule DERIV_isconst3[where x=x])
  1227     fix x :: real assume "x \<in> {0 <..< 2}" hence "0 < x" and "x < 2" by auto
  1228     have "norm (1 - x) < 1" using `0 < x` and `x < 2` by auto
  1229     have "1 / x = 1 / (1 - (1 - x))" by auto
  1230     also have "\<dots> = (\<Sum> n. (1 - x)^n)" using geometric_sums[OF `norm (1 - x) < 1`] by (rule sums_unique)
  1231     also have "\<dots> = suminf (?f' x)" unfolding power_mult_distrib[symmetric] by (rule arg_cong[where f=suminf], rule arg_cong[where f="op ^"], auto)
  1232     finally have "DERIV ln x :> suminf (?f' x)" using DERIV_ln[OF `0 < x`] unfolding divide_inverse by auto
  1233     moreover
  1234     have repos: "\<And> h x :: real. h - 1 + x = h + x - 1" by auto
  1235     have "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> (\<Sum>n. (-1)^n * (1 / real (n + 1)) * real (Suc n) * (x - 1) ^ n)"
  1236     proof (rule DERIV_power_series')
  1237       show "x - 1 \<in> {- 1<..<1}" and "(0 :: real) < 1" using `0 < x` `x < 2` by auto
  1238       { fix x :: real assume "x \<in> {- 1<..<1}" hence "norm (-x) < 1" by auto
  1239         show "summable (\<lambda>n. -1 ^ n * (1 / real (n + 1)) * real (Suc n) * x ^ n)"
  1240           unfolding One_nat_def
  1241           by (auto simp add: power_mult_distrib[symmetric] summable_geometric[OF `norm (-x) < 1`])
  1242       }
  1243     qed
  1244     hence "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> suminf (?f' x)" unfolding One_nat_def by auto
  1245     hence "DERIV (\<lambda>x. suminf (?f (x - 1))) x :> suminf (?f' x)" unfolding DERIV_iff repos .
  1246     ultimately have "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> (suminf (?f' x) - suminf (?f' x))"
  1247       by (rule DERIV_diff)
  1248     thus "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> 0" by auto
  1249   qed (auto simp add: assms)
  1250   thus ?thesis by (auto simp add: suminf_zero)
  1251 qed
  1252 
  1253 subsection {* Sine and Cosine *}
  1254 
  1255 definition
  1256   sin_coeff :: "nat \<Rightarrow> real" where
  1257   "sin_coeff = (\<lambda>n. if even n then 0 else -1 ^ ((n - Suc 0) div 2) / real (fact n))"
  1258 
  1259 definition
  1260   cos_coeff :: "nat \<Rightarrow> real" where
  1261   "cos_coeff = (\<lambda>n. if even n then (-1 ^ (n div 2)) / real (fact n) else 0)"
  1262 
  1263 definition
  1264   sin :: "real => real" where
  1265   "sin x = (\<Sum>n. sin_coeff n * x ^ n)"
  1266 
  1267 definition
  1268   cos :: "real => real" where
  1269   "cos x = (\<Sum>n. cos_coeff n * x ^ n)"
  1270 
  1271 lemma summable_sin: "summable (\<lambda>n. sin_coeff n * x ^ n)"
  1272 unfolding sin_coeff_def
  1273 apply (rule_tac g = "(%n. inverse (real (fact n)) * \<bar>x\<bar> ^ n)" in summable_comparison_test)
  1274 apply (rule_tac [2] summable_exp)
  1275 apply (rule_tac x = 0 in exI)
  1276 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1277 done
  1278 
  1279 lemma summable_cos: "summable (\<lambda>n. cos_coeff n * x ^ n)"
  1280 unfolding cos_coeff_def
  1281 apply (rule_tac g = "(%n. inverse (real (fact n)) * \<bar>x\<bar> ^ n)" in summable_comparison_test)
  1282 apply (rule_tac [2] summable_exp)
  1283 apply (rule_tac x = 0 in exI)
  1284 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1285 done
  1286 
  1287 lemma lemma_STAR_sin:
  1288      "(if even n then 0  
  1289        else -1 ^ ((n - Suc 0) div 2)/(real (fact n))) * 0 ^ n = 0"
  1290 by (induct "n", auto)
  1291 
  1292 lemma lemma_STAR_cos:
  1293      "0 < n -->  
  1294       -1 ^ (n div 2)/(real (fact n)) * 0 ^ n = 0"
  1295 by (induct "n", auto)
  1296 
  1297 lemma lemma_STAR_cos1:
  1298      "0 < n -->  
  1299       (-1) ^ (n div 2)/(real (fact n)) * 0 ^ n = 0"
  1300 by (induct "n", auto)
  1301 
  1302 lemma lemma_STAR_cos2:
  1303   "(\<Sum>n=1..<n. if even n then -1 ^ (n div 2)/(real (fact n)) *  0 ^ n 
  1304                          else 0) = 0"
  1305 apply (induct "n")
  1306 apply (case_tac [2] "n", auto)
  1307 done
  1308 
  1309 lemma sin_converges: "(\<lambda>n. sin_coeff n * x ^ n) sums sin(x)"
  1310 unfolding sin_def by (rule summable_sin [THEN summable_sums])
  1311 
  1312 lemma cos_converges: "(\<lambda>n. cos_coeff n * x ^ n) sums cos(x)"
  1313 unfolding cos_def by (rule summable_cos [THEN summable_sums])
  1314 
  1315 lemma sin_fdiffs: "diffs sin_coeff = cos_coeff"
  1316 unfolding sin_coeff_def cos_coeff_def
  1317 by (auto intro!: ext 
  1318          simp add: diffs_def divide_inverse real_of_nat_def of_nat_mult
  1319          simp del: mult_Suc of_nat_Suc)
  1320 
  1321 lemma sin_fdiffs2: "diffs sin_coeff n = cos_coeff n"
  1322 by (simp only: sin_fdiffs)
  1323 
  1324 lemma cos_fdiffs: "diffs cos_coeff = (\<lambda>n. - sin_coeff n)"
  1325 unfolding sin_coeff_def cos_coeff_def
  1326 by (auto intro!: ext 
  1327          simp add: diffs_def divide_inverse odd_Suc_mult_two_ex real_of_nat_def of_nat_mult
  1328          simp del: mult_Suc of_nat_Suc)
  1329 
  1330 lemma cos_fdiffs2: "diffs cos_coeff n = - sin_coeff n"
  1331 by (simp only: cos_fdiffs)
  1332 
  1333 text{*Now at last we can get the derivatives of exp, sin and cos*}
  1334 
  1335 lemma lemma_sin_minus: "- sin x = (\<Sum>n. - (sin_coeff n * x ^ n))"
  1336 by (auto intro!: sums_unique sums_minus sin_converges)
  1337 
  1338 lemma lemma_sin_ext: "sin = (\<lambda>x. \<Sum>n. sin_coeff n * x ^ n)"
  1339 by (auto intro!: ext simp add: sin_def)
  1340 
  1341 lemma lemma_cos_ext: "cos = (\<lambda>x. \<Sum>n. cos_coeff n * x ^ n)"
  1342 by (auto intro!: ext simp add: cos_def)
  1343 
  1344 lemma DERIV_sin [simp]: "DERIV sin x :> cos(x)"
  1345 apply (simp add: cos_def)
  1346 apply (subst lemma_sin_ext)
  1347 apply (auto simp add: sin_fdiffs2 [symmetric])
  1348 apply (rule_tac K = "1 + \<bar>x\<bar>" in termdiffs)
  1349 apply (auto intro: sin_converges cos_converges sums_summable intro!: sums_minus [THEN sums_summable] simp add: cos_fdiffs sin_fdiffs)
  1350 done
  1351 
  1352 lemma DERIV_cos [simp]: "DERIV cos x :> -sin(x)"
  1353 apply (subst lemma_cos_ext)
  1354 apply (auto simp add: lemma_sin_minus cos_fdiffs2 [symmetric] minus_mult_left)
  1355 apply (rule_tac K = "1 + \<bar>x\<bar>" in termdiffs)
  1356 apply (auto intro: sin_converges cos_converges sums_summable intro!: sums_minus [THEN sums_summable] simp add: cos_fdiffs sin_fdiffs diffs_minus)
  1357 done
  1358 
  1359 lemma isCont_sin [simp]: "isCont sin x"
  1360 by (rule DERIV_sin [THEN DERIV_isCont])
  1361 
  1362 lemma isCont_cos [simp]: "isCont cos x"
  1363 by (rule DERIV_cos [THEN DERIV_isCont])
  1364 
  1365 
  1366 declare
  1367   DERIV_exp[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1368   DERIV_ln[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1369   DERIV_sin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1370   DERIV_cos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1371 
  1372 subsection {* Properties of Sine and Cosine *}
  1373 
  1374 lemma sin_zero [simp]: "sin 0 = 0"
  1375 unfolding sin_def sin_coeff_def by (simp add: powser_zero)
  1376 
  1377 lemma cos_zero [simp]: "cos 0 = 1"
  1378 unfolding cos_def cos_coeff_def by (simp add: powser_zero)
  1379 
  1380 lemma DERIV_sin_sin_mult [simp]:
  1381      "DERIV (%x. sin(x)*sin(x)) x :> cos(x) * sin(x) + cos(x) * sin(x)"
  1382 by (rule DERIV_mult, auto)
  1383 
  1384 lemma DERIV_sin_sin_mult2 [simp]:
  1385      "DERIV (%x. sin(x)*sin(x)) x :> 2 * cos(x) * sin(x)"
  1386 apply (cut_tac x = x in DERIV_sin_sin_mult)
  1387 apply (auto simp add: mult_assoc)
  1388 done
  1389 
  1390 lemma DERIV_sin_realpow2 [simp]:
  1391      "DERIV (%x. (sin x)\<twosuperior>) x :> cos(x) * sin(x) + cos(x) * sin(x)"
  1392 by (auto simp add: numeral_2_eq_2 mult_assoc [symmetric])
  1393 
  1394 lemma DERIV_sin_realpow2a [simp]:
  1395      "DERIV (%x. (sin x)\<twosuperior>) x :> 2 * cos(x) * sin(x)"
  1396 by (auto simp add: numeral_2_eq_2)
  1397 
  1398 lemma DERIV_cos_cos_mult [simp]:
  1399      "DERIV (%x. cos(x)*cos(x)) x :> -sin(x) * cos(x) + -sin(x) * cos(x)"
  1400 by (rule DERIV_mult, auto)
  1401 
  1402 lemma DERIV_cos_cos_mult2 [simp]:
  1403      "DERIV (%x. cos(x)*cos(x)) x :> -2 * cos(x) * sin(x)"
  1404 apply (cut_tac x = x in DERIV_cos_cos_mult)
  1405 apply (auto simp add: mult_ac)
  1406 done
  1407 
  1408 lemma DERIV_cos_realpow2 [simp]:
  1409      "DERIV (%x. (cos x)\<twosuperior>) x :> -sin(x) * cos(x) + -sin(x) * cos(x)"
  1410 by (auto simp add: numeral_2_eq_2 mult_assoc [symmetric])
  1411 
  1412 lemma DERIV_cos_realpow2a [simp]:
  1413      "DERIV (%x. (cos x)\<twosuperior>) x :> -2 * cos(x) * sin(x)"
  1414 by (auto simp add: numeral_2_eq_2)
  1415 
  1416 lemma lemma_DERIV_subst: "[| DERIV f x :> D; D = E |] ==> DERIV f x :> E"
  1417 by auto
  1418 
  1419 lemma DERIV_cos_realpow2b: "DERIV (%x. (cos x)\<twosuperior>) x :> -(2 * cos(x) * sin(x))"
  1420   by (auto intro!: DERIV_intros)
  1421 
  1422 (* most useful *)
  1423 lemma DERIV_cos_cos_mult3 [simp]:
  1424      "DERIV (%x. cos(x)*cos(x)) x :> -(2 * cos(x) * sin(x))"
  1425   by (auto intro!: DERIV_intros)
  1426 
  1427 lemma DERIV_sin_circle_all: 
  1428      "\<forall>x. DERIV (%x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :>  
  1429              (2*cos(x)*sin(x) - 2*cos(x)*sin(x))"
  1430   by (auto intro!: DERIV_intros)
  1431 
  1432 lemma DERIV_sin_circle_all_zero [simp]:
  1433      "\<forall>x. DERIV (%x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :> 0"
  1434 by (cut_tac DERIV_sin_circle_all, auto)
  1435 
  1436 lemma sin_cos_squared_add [simp]: "((sin x)\<twosuperior>) + ((cos x)\<twosuperior>) = 1"
  1437 apply (cut_tac x = x and y = 0 in DERIV_sin_circle_all_zero [THEN DERIV_isconst_all])
  1438 apply (auto simp add: numeral_2_eq_2)
  1439 done
  1440 
  1441 lemma sin_cos_squared_add2 [simp]: "((cos x)\<twosuperior>) + ((sin x)\<twosuperior>) = 1"
  1442 apply (subst add_commute)
  1443 apply (rule sin_cos_squared_add)
  1444 done
  1445 
  1446 lemma sin_cos_squared_add3 [simp]: "cos x * cos x + sin x * sin x = 1"
  1447 apply (cut_tac x = x in sin_cos_squared_add2)
  1448 apply (simp add: power2_eq_square)
  1449 done
  1450 
  1451 lemma sin_squared_eq: "(sin x)\<twosuperior> = 1 - (cos x)\<twosuperior>"
  1452 apply (rule_tac a1 = "(cos x)\<twosuperior>" in add_right_cancel [THEN iffD1])
  1453 apply simp
  1454 done
  1455 
  1456 lemma cos_squared_eq: "(cos x)\<twosuperior> = 1 - (sin x)\<twosuperior>"
  1457 apply (rule_tac a1 = "(sin x)\<twosuperior>" in add_right_cancel [THEN iffD1])
  1458 apply simp
  1459 done
  1460 
  1461 lemma abs_sin_le_one [simp]: "\<bar>sin x\<bar> \<le> 1"
  1462 by (rule power2_le_imp_le, simp_all add: sin_squared_eq)
  1463 
  1464 lemma sin_ge_minus_one [simp]: "-1 \<le> sin x"
  1465 apply (insert abs_sin_le_one [of x]) 
  1466 apply (simp add: abs_le_iff del: abs_sin_le_one) 
  1467 done
  1468 
  1469 lemma sin_le_one [simp]: "sin x \<le> 1"
  1470 apply (insert abs_sin_le_one [of x]) 
  1471 apply (simp add: abs_le_iff del: abs_sin_le_one) 
  1472 done
  1473 
  1474 lemma abs_cos_le_one [simp]: "\<bar>cos x\<bar> \<le> 1"
  1475 by (rule power2_le_imp_le, simp_all add: cos_squared_eq)
  1476 
  1477 lemma cos_ge_minus_one [simp]: "-1 \<le> cos x"
  1478 apply (insert abs_cos_le_one [of x]) 
  1479 apply (simp add: abs_le_iff del: abs_cos_le_one) 
  1480 done
  1481 
  1482 lemma cos_le_one [simp]: "cos x \<le> 1"
  1483 apply (insert abs_cos_le_one [of x]) 
  1484 apply (simp add: abs_le_iff del: abs_cos_le_one)
  1485 done
  1486 
  1487 lemma DERIV_fun_pow: "DERIV g x :> m ==>  
  1488       DERIV (%x. (g x) ^ n) x :> real n * (g x) ^ (n - 1) * m"
  1489 unfolding One_nat_def
  1490 apply (rule lemma_DERIV_subst)
  1491 apply (rule_tac f = "(%x. x ^ n)" in DERIV_chain2)
  1492 apply (rule DERIV_pow, auto)
  1493 done
  1494 
  1495 lemma DERIV_fun_exp:
  1496      "DERIV g x :> m ==> DERIV (%x. exp(g x)) x :> exp(g x) * m"
  1497 apply (rule lemma_DERIV_subst)
  1498 apply (rule_tac f = exp in DERIV_chain2)
  1499 apply (rule DERIV_exp, auto)
  1500 done
  1501 
  1502 lemma DERIV_fun_sin:
  1503      "DERIV g x :> m ==> DERIV (%x. sin(g x)) x :> cos(g x) * m"
  1504 apply (rule lemma_DERIV_subst)
  1505 apply (rule_tac f = sin in DERIV_chain2)
  1506 apply (rule DERIV_sin, auto)
  1507 done
  1508 
  1509 lemma DERIV_fun_cos:
  1510      "DERIV g x :> m ==> DERIV (%x. cos(g x)) x :> -sin(g x) * m"
  1511 apply (rule lemma_DERIV_subst)
  1512 apply (rule_tac f = cos in DERIV_chain2)
  1513 apply (rule DERIV_cos, auto)
  1514 done
  1515 
  1516 (* lemma *)
  1517 lemma lemma_DERIV_sin_cos_add:
  1518      "\<forall>x.  
  1519          DERIV (%x. (sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +  
  1520                (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2) x :> 0"
  1521   by (auto intro!: DERIV_intros simp add: algebra_simps)
  1522 
  1523 lemma sin_cos_add [simp]:
  1524      "(sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +  
  1525       (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2 = 0"
  1526 apply (cut_tac y = 0 and x = x and y7 = y 
  1527        in lemma_DERIV_sin_cos_add [THEN DERIV_isconst_all])
  1528 apply (auto simp add: numeral_2_eq_2)
  1529 done
  1530 
  1531 lemma sin_add: "sin (x + y) = sin x * cos y + cos x * sin y"
  1532 apply (cut_tac x = x and y = y in sin_cos_add)
  1533 apply (simp del: sin_cos_add)
  1534 done
  1535 
  1536 lemma cos_add: "cos (x + y) = cos x * cos y - sin x * sin y"
  1537 apply (cut_tac x = x and y = y in sin_cos_add)
  1538 apply (simp del: sin_cos_add)
  1539 done
  1540 
  1541 lemma lemma_DERIV_sin_cos_minus:
  1542     "\<forall>x. DERIV (%x. (sin(-x) + (sin x)) ^ 2 + (cos(-x) - (cos x)) ^ 2) x :> 0"
  1543   by (auto intro!: DERIV_intros simp add: algebra_simps)
  1544 
  1545 
  1546 lemma sin_cos_minus: 
  1547     "(sin(-x) + (sin x)) ^ 2 + (cos(-x) - (cos x)) ^ 2 = 0"
  1548 apply (cut_tac y = 0 and x = x 
  1549        in lemma_DERIV_sin_cos_minus [THEN DERIV_isconst_all])
  1550 apply simp
  1551 done
  1552 
  1553 lemma sin_minus [simp]: "sin (-x) = -sin(x)"
  1554   using sin_cos_minus [where x=x] by simp
  1555 
  1556 lemma cos_minus [simp]: "cos (-x) = cos(x)"
  1557   using sin_cos_minus [where x=x] by simp
  1558 
  1559 lemma sin_diff: "sin (x - y) = sin x * cos y - cos x * sin y"
  1560 by (simp add: diff_minus sin_add)
  1561 
  1562 lemma sin_diff2: "sin (x - y) = cos y * sin x - sin y * cos x"
  1563 by (simp add: sin_diff mult_commute)
  1564 
  1565 lemma cos_diff: "cos (x - y) = cos x * cos y + sin x * sin y"
  1566 by (simp add: diff_minus cos_add)
  1567 
  1568 lemma cos_diff2: "cos (x - y) = cos y * cos x + sin y * sin x"
  1569 by (simp add: cos_diff mult_commute)
  1570 
  1571 lemma sin_double [simp]: "sin(2 * x) = 2* sin x * cos x"
  1572   using sin_add [where x=x and y=x] by simp
  1573 
  1574 lemma cos_double: "cos(2* x) = ((cos x)\<twosuperior>) - ((sin x)\<twosuperior>)"
  1575   using cos_add [where x=x and y=x]
  1576   by (simp add: power2_eq_square)
  1577 
  1578 
  1579 subsection {* The Constant Pi *}
  1580 
  1581 definition
  1582   pi :: "real" where
  1583   "pi = 2 * (THE x. 0 \<le> (x::real) & x \<le> 2 & cos x = 0)"
  1584 
  1585 text{*Show that there's a least positive @{term x} with @{term "cos(x) = 0"}; 
  1586    hence define pi.*}
  1587 
  1588 lemma sin_paired:
  1589      "(%n. -1 ^ n /(real (fact (2 * n + 1))) * x ^ (2 * n + 1)) 
  1590       sums  sin x"
  1591 proof -
  1592   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. sin_coeff k * x ^ k) sums sin x"
  1593     unfolding sin_def
  1594     by (rule sin_converges [THEN sums_summable, THEN sums_group], simp) 
  1595   thus ?thesis unfolding One_nat_def sin_coeff_def by (simp add: mult_ac)
  1596 qed
  1597 
  1598 text {* FIXME: This is a long, ugly proof! *}
  1599 lemma sin_gt_zero: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1600 apply (subgoal_tac 
  1601        "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2.
  1602               -1 ^ k / real (fact (2 * k + 1)) * x ^ (2 * k + 1)) 
  1603      sums (\<Sum>n. -1 ^ n / real (fact (2 * n + 1)) * x ^ (2 * n + 1))")
  1604  prefer 2
  1605  apply (rule sin_paired [THEN sums_summable, THEN sums_group], simp) 
  1606 apply (rotate_tac 2)
  1607 apply (drule sin_paired [THEN sums_unique, THEN ssubst])
  1608 unfolding One_nat_def
  1609 apply (auto simp del: fact_Suc)
  1610 apply (frule sums_unique)
  1611 apply (auto simp del: fact_Suc)
  1612 apply (rule_tac n1 = 0 in series_pos_less [THEN [2] order_le_less_trans])
  1613 apply (auto simp del: fact_Suc)
  1614 apply (erule sums_summable)
  1615 apply (case_tac "m=0")
  1616 apply (simp (no_asm_simp))
  1617 apply (subgoal_tac "6 * (x * (x * x) / real (Suc (Suc (Suc (Suc (Suc (Suc 0))))))) < 6 * x") 
  1618 apply (simp only: mult_less_cancel_left, simp)  
  1619 apply (simp (no_asm_simp) add: numeral_2_eq_2 [symmetric] mult_assoc [symmetric])
  1620 apply (subgoal_tac "x*x < 2*3", simp) 
  1621 apply (rule mult_strict_mono)
  1622 apply (auto simp add: real_0_less_add_iff real_of_nat_Suc simp del: fact_Suc)
  1623 apply (subst fact_Suc)
  1624 apply (subst fact_Suc)
  1625 apply (subst fact_Suc)
  1626 apply (subst fact_Suc)
  1627 apply (subst real_of_nat_mult)
  1628 apply (subst real_of_nat_mult)
  1629 apply (subst real_of_nat_mult)
  1630 apply (subst real_of_nat_mult)
  1631 apply (simp (no_asm) add: divide_inverse del: fact_Suc)
  1632 apply (auto simp add: mult_assoc [symmetric] simp del: fact_Suc)
  1633 apply (rule_tac c="real (Suc (Suc (4*m)))" in mult_less_imp_less_right) 
  1634 apply (auto simp add: mult_assoc simp del: fact_Suc)
  1635 apply (rule_tac c="real (Suc (Suc (Suc (4*m))))" in mult_less_imp_less_right) 
  1636 apply (auto simp add: mult_assoc mult_less_cancel_left simp del: fact_Suc)
  1637 apply (subgoal_tac "x * (x * x ^ (4*m)) = (x ^ (4*m)) * (x * x)") 
  1638 apply (erule ssubst)+
  1639 apply (auto simp del: fact_Suc)
  1640 apply (subgoal_tac "0 < x ^ (4 * m) ")
  1641  prefer 2 apply (simp only: zero_less_power) 
  1642 apply (simp (no_asm_simp) add: mult_less_cancel_left)
  1643 apply (rule mult_strict_mono)
  1644 apply (simp_all (no_asm_simp))
  1645 done
  1646 
  1647 lemma sin_gt_zero1: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1648 by (auto intro: sin_gt_zero)
  1649 
  1650 lemma cos_double_less_one: "[| 0 < x; x < 2 |] ==> cos (2 * x) < 1"
  1651 apply (cut_tac x = x in sin_gt_zero1)
  1652 apply (auto simp add: cos_squared_eq cos_double)
  1653 done
  1654 
  1655 lemma cos_paired:
  1656      "(%n. -1 ^ n /(real (fact (2 * n))) * x ^ (2 * n)) sums cos x"
  1657 proof -
  1658   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. cos_coeff k * x ^ k) sums cos x"
  1659     unfolding cos_def
  1660     by (rule cos_converges [THEN sums_summable, THEN sums_group], simp) 
  1661   thus ?thesis unfolding cos_coeff_def by (simp add: mult_ac)
  1662 qed
  1663 
  1664 lemma fact_lemma: "real (n::nat) * 4 = real (4 * n)"
  1665 by simp
  1666 
  1667 lemma real_mult_inverse_cancel:
  1668      "[|(0::real) < x; 0 < x1; x1 * y < x * u |] 
  1669       ==> inverse x * y < inverse x1 * u"
  1670 apply (rule_tac c=x in mult_less_imp_less_left) 
  1671 apply (auto simp add: mult_assoc [symmetric])
  1672 apply (simp (no_asm) add: mult_ac)
  1673 apply (rule_tac c=x1 in mult_less_imp_less_right) 
  1674 apply (auto simp add: mult_ac)
  1675 done
  1676 
  1677 lemma real_mult_inverse_cancel2:
  1678      "[|(0::real) < x;0 < x1; x1 * y < x * u |] ==> y * inverse x < u * inverse x1"
  1679 apply (auto dest: real_mult_inverse_cancel simp add: mult_ac)
  1680 done
  1681 
  1682 lemma realpow_num_eq_if:
  1683   fixes m :: "'a::power"
  1684   shows "m ^ n = (if n=0 then 1 else m * m ^ (n - 1))"
  1685 by (cases n, auto)
  1686 
  1687 lemma cos_two_less_zero [simp]: "cos (2) < 0"
  1688 apply (cut_tac x = 2 in cos_paired)
  1689 apply (drule sums_minus)
  1690 apply (rule neg_less_iff_less [THEN iffD1]) 
  1691 apply (frule sums_unique, auto)
  1692 apply (rule_tac y =
  1693  "\<Sum>n=0..< Suc(Suc(Suc 0)). - (-1 ^ n / (real(fact (2*n))) * 2 ^ (2*n))"
  1694        in order_less_trans)
  1695 apply (simp (no_asm) add: fact_num_eq_if_nat realpow_num_eq_if del: fact_Suc)
  1696 apply (simp (no_asm) add: mult_assoc del: setsum_op_ivl_Suc)
  1697 apply (rule sumr_pos_lt_pair)
  1698 apply (erule sums_summable, safe)
  1699 unfolding One_nat_def
  1700 apply (simp (no_asm) add: divide_inverse real_0_less_add_iff mult_assoc [symmetric] 
  1701             del: fact_Suc)
  1702 apply (rule real_mult_inverse_cancel2)
  1703 apply (rule real_of_nat_fact_gt_zero)+
  1704 apply (simp (no_asm) add: mult_assoc [symmetric] del: fact_Suc)
  1705 apply (subst fact_lemma) 
  1706 apply (subst fact_Suc [of "Suc (Suc (Suc (Suc (Suc (Suc (Suc (4 * d)))))))"])
  1707 apply (simp only: real_of_nat_mult)
  1708 apply (rule mult_strict_mono, force)
  1709   apply (rule_tac [3] real_of_nat_ge_zero)
  1710  prefer 2 apply force
  1711 apply (rule real_of_nat_less_iff [THEN iffD2])
  1712 apply (rule fact_less_mono_nat, auto)
  1713 done
  1714 
  1715 lemmas cos_two_neq_zero [simp] = cos_two_less_zero [THEN less_imp_neq]
  1716 lemmas cos_two_le_zero [simp] = cos_two_less_zero [THEN order_less_imp_le]
  1717 
  1718 lemma cos_is_zero: "EX! x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1719 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> 2 & cos x = 0")
  1720 apply (rule_tac [2] IVT2)
  1721 apply (auto intro: DERIV_isCont DERIV_cos)
  1722 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1723 apply (rule ccontr)
  1724 apply (subgoal_tac " (\<forall>x. cos differentiable x) & (\<forall>x. isCont cos x) ")
  1725 apply (auto intro: DERIV_cos DERIV_isCont simp add: differentiable_def)
  1726 apply (drule_tac f = cos in Rolle)
  1727 apply (drule_tac [5] f = cos in Rolle)
  1728 apply (auto dest!: DERIV_cos [THEN DERIV_unique] simp add: differentiable_def)
  1729 apply (metis order_less_le_trans less_le sin_gt_zero)
  1730 apply (metis order_less_le_trans less_le sin_gt_zero)
  1731 done
  1732 
  1733 lemma pi_half: "pi/2 = (THE x. 0 \<le> x & x \<le> 2 & cos x = 0)"
  1734 by (simp add: pi_def)
  1735 
  1736 lemma cos_pi_half [simp]: "cos (pi / 2) = 0"
  1737 by (simp add: pi_half cos_is_zero [THEN theI'])
  1738 
  1739 lemma pi_half_gt_zero [simp]: "0 < pi / 2"
  1740 apply (rule order_le_neq_trans)
  1741 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1742 apply (rule notI, drule arg_cong [where f=cos], simp)
  1743 done
  1744 
  1745 lemmas pi_half_neq_zero [simp] = pi_half_gt_zero [THEN less_imp_neq, symmetric]
  1746 lemmas pi_half_ge_zero [simp] = pi_half_gt_zero [THEN order_less_imp_le]
  1747 
  1748 lemma pi_half_less_two [simp]: "pi / 2 < 2"
  1749 apply (rule order_le_neq_trans)
  1750 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1751 apply (rule notI, drule arg_cong [where f=cos], simp)
  1752 done
  1753 
  1754 lemmas pi_half_neq_two [simp] = pi_half_less_two [THEN less_imp_neq]
  1755 lemmas pi_half_le_two [simp] =  pi_half_less_two [THEN order_less_imp_le]
  1756 
  1757 lemma pi_gt_zero [simp]: "0 < pi"
  1758 by (insert pi_half_gt_zero, simp)
  1759 
  1760 lemma pi_ge_zero [simp]: "0 \<le> pi"
  1761 by (rule pi_gt_zero [THEN order_less_imp_le])
  1762 
  1763 lemma pi_neq_zero [simp]: "pi \<noteq> 0"
  1764 by (rule pi_gt_zero [THEN less_imp_neq, THEN not_sym])
  1765 
  1766 lemma pi_not_less_zero [simp]: "\<not> pi < 0"
  1767 by (simp add: linorder_not_less)
  1768 
  1769 lemma minus_pi_half_less_zero: "-(pi/2) < 0"
  1770 by simp
  1771 
  1772 lemma m2pi_less_pi: "- (2 * pi) < pi"
  1773 proof -
  1774   have "- (2 * pi) < 0" and "0 < pi" by auto
  1775   from order_less_trans[OF this] show ?thesis .
  1776 qed
  1777 
  1778 lemma sin_pi_half [simp]: "sin(pi/2) = 1"
  1779 apply (cut_tac x = "pi/2" in sin_cos_squared_add2)
  1780 apply (cut_tac sin_gt_zero [OF pi_half_gt_zero pi_half_less_two])
  1781 apply (simp add: power2_eq_1_iff)
  1782 done
  1783 
  1784 lemma cos_pi [simp]: "cos pi = -1"
  1785 by (cut_tac x = "pi/2" and y = "pi/2" in cos_add, simp)
  1786 
  1787 lemma sin_pi [simp]: "sin pi = 0"
  1788 by (cut_tac x = "pi/2" and y = "pi/2" in sin_add, simp)
  1789 
  1790 lemma sin_cos_eq: "sin x = cos (pi/2 - x)"
  1791 by (simp add: diff_minus cos_add)
  1792 declare sin_cos_eq [symmetric, simp]
  1793 
  1794 lemma minus_sin_cos_eq: "-sin x = cos (x + pi/2)"
  1795 by (simp add: cos_add)
  1796 declare minus_sin_cos_eq [symmetric, simp]
  1797 
  1798 lemma cos_sin_eq: "cos x = sin (pi/2 - x)"
  1799 by (simp add: diff_minus sin_add)
  1800 declare cos_sin_eq [symmetric, simp]
  1801 
  1802 lemma sin_periodic_pi [simp]: "sin (x + pi) = - sin x"
  1803 by (simp add: sin_add)
  1804 
  1805 lemma sin_periodic_pi2 [simp]: "sin (pi + x) = - sin x"
  1806 by (simp add: sin_add)
  1807 
  1808 lemma cos_periodic_pi [simp]: "cos (x + pi) = - cos x"
  1809 by (simp add: cos_add)
  1810 
  1811 lemma sin_periodic [simp]: "sin (x + 2*pi) = sin x"
  1812 by (simp add: sin_add cos_double)
  1813 
  1814 lemma cos_periodic [simp]: "cos (x + 2*pi) = cos x"
  1815 by (simp add: cos_add cos_double)
  1816 
  1817 lemma cos_npi [simp]: "cos (real n * pi) = -1 ^ n"
  1818 apply (induct "n")
  1819 apply (auto simp add: real_of_nat_Suc left_distrib)
  1820 done
  1821 
  1822 lemma cos_npi2 [simp]: "cos (pi * real n) = -1 ^ n"
  1823 proof -
  1824   have "cos (pi * real n) = cos (real n * pi)" by (simp only: mult_commute)
  1825   also have "... = -1 ^ n" by (rule cos_npi) 
  1826   finally show ?thesis .
  1827 qed
  1828 
  1829 lemma sin_npi [simp]: "sin (real (n::nat) * pi) = 0"
  1830 apply (induct "n")
  1831 apply (auto simp add: real_of_nat_Suc left_distrib)
  1832 done
  1833 
  1834 lemma sin_npi2 [simp]: "sin (pi * real (n::nat)) = 0"
  1835 by (simp add: mult_commute [of pi]) 
  1836 
  1837 lemma cos_two_pi [simp]: "cos (2 * pi) = 1"
  1838 by (simp add: cos_double)
  1839 
  1840 lemma sin_two_pi [simp]: "sin (2 * pi) = 0"
  1841 by simp
  1842 
  1843 lemma sin_gt_zero2: "[| 0 < x; x < pi/2 |] ==> 0 < sin x"
  1844 apply (rule sin_gt_zero, assumption)
  1845 apply (rule order_less_trans, assumption)
  1846 apply (rule pi_half_less_two)
  1847 done
  1848 
  1849 lemma sin_less_zero: 
  1850   assumes lb: "- pi/2 < x" and "x < 0" shows "sin x < 0"
  1851 proof -
  1852   have "0 < sin (- x)" using assms by (simp only: sin_gt_zero2) 
  1853   thus ?thesis by simp
  1854 qed
  1855 
  1856 lemma pi_less_4: "pi < 4"
  1857 by (cut_tac pi_half_less_two, auto)
  1858 
  1859 lemma cos_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < cos x"
  1860 apply (cut_tac pi_less_4)
  1861 apply (cut_tac f = cos and a = 0 and b = x and y = 0 in IVT2_objl, safe, simp_all)
  1862 apply (cut_tac cos_is_zero, safe)
  1863 apply (rename_tac y z)
  1864 apply (drule_tac x = y in spec)
  1865 apply (drule_tac x = "pi/2" in spec, simp) 
  1866 done
  1867 
  1868 lemma cos_gt_zero_pi: "[| -(pi/2) < x; x < pi/2 |] ==> 0 < cos x"
  1869 apply (rule_tac x = x and y = 0 in linorder_cases)
  1870 apply (rule cos_minus [THEN subst])
  1871 apply (rule cos_gt_zero)
  1872 apply (auto intro: cos_gt_zero)
  1873 done
  1874  
  1875 lemma cos_ge_zero: "[| -(pi/2) \<le> x; x \<le> pi/2 |] ==> 0 \<le> cos x"
  1876 apply (auto simp add: order_le_less cos_gt_zero_pi)
  1877 apply (subgoal_tac "x = pi/2", auto) 
  1878 done
  1879 
  1880 lemma sin_gt_zero_pi: "[| 0 < x; x < pi  |] ==> 0 < sin x"
  1881 apply (subst sin_cos_eq)
  1882 apply (rotate_tac 1)
  1883 apply (drule real_sum_of_halves [THEN ssubst])
  1884 apply (auto intro!: cos_gt_zero_pi simp del: sin_cos_eq [symmetric])
  1885 done
  1886 
  1887 
  1888 lemma pi_ge_two: "2 \<le> pi"
  1889 proof (rule ccontr)
  1890   assume "\<not> 2 \<le> pi" hence "pi < 2" by auto
  1891   have "\<exists>y > pi. y < 2 \<and> y < 2 * pi"
  1892   proof (cases "2 < 2 * pi")
  1893     case True with dense[OF `pi < 2`] show ?thesis by auto
  1894   next
  1895     case False have "pi < 2 * pi" by auto
  1896     from dense[OF this] and False show ?thesis by auto
  1897   qed
  1898   then obtain y where "pi < y" and "y < 2" and "y < 2 * pi" by blast
  1899   hence "0 < sin y" using sin_gt_zero by auto
  1900   moreover 
  1901   have "sin y < 0" using sin_gt_zero_pi[of "y - pi"] `pi < y` and `y < 2 * pi` sin_periodic_pi[of "y - pi"] by auto
  1902   ultimately show False by auto
  1903 qed
  1904 
  1905 lemma sin_ge_zero: "[| 0 \<le> x; x \<le> pi |] ==> 0 \<le> sin x"
  1906 by (auto simp add: order_le_less sin_gt_zero_pi)
  1907 
  1908 lemma cos_total: "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. 0 \<le> x & x \<le> pi & (cos x = y)"
  1909 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> pi & cos x = y")
  1910 apply (rule_tac [2] IVT2)
  1911 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos)
  1912 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1913 apply (rule ccontr, auto)
  1914 apply (drule_tac f = cos in Rolle)
  1915 apply (drule_tac [5] f = cos in Rolle)
  1916 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos
  1917             dest!: DERIV_cos [THEN DERIV_unique] 
  1918             simp add: differentiable_def)
  1919 apply (auto dest: sin_gt_zero_pi [OF order_le_less_trans order_less_le_trans])
  1920 done
  1921 
  1922 lemma sin_total:
  1923      "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. -(pi/2) \<le> x & x \<le> pi/2 & (sin x = y)"
  1924 apply (rule ccontr)
  1925 apply (subgoal_tac "\<forall>x. (- (pi/2) \<le> x & x \<le> pi/2 & (sin x = y)) = (0 \<le> (x + pi/2) & (x + pi/2) \<le> pi & (cos (x + pi/2) = -y))")
  1926 apply (erule contrapos_np)
  1927 apply (simp del: minus_sin_cos_eq [symmetric])
  1928 apply (cut_tac y="-y" in cos_total, simp) apply simp 
  1929 apply (erule ex1E)
  1930 apply (rule_tac a = "x - (pi/2)" in ex1I)
  1931 apply (simp (no_asm) add: add_assoc)
  1932 apply (rotate_tac 3)
  1933 apply (drule_tac x = "xa + pi/2" in spec, safe, simp_all) 
  1934 done
  1935 
  1936 lemma reals_Archimedean4:
  1937      "[| 0 < y; 0 \<le> x |] ==> \<exists>n. real n * y \<le> x & x < real (Suc n) * y"
  1938 apply (auto dest!: reals_Archimedean3)
  1939 apply (drule_tac x = x in spec, clarify) 
  1940 apply (subgoal_tac "x < real(LEAST m::nat. x < real m * y) * y")
  1941  prefer 2 apply (erule LeastI) 
  1942 apply (case_tac "LEAST m::nat. x < real m * y", simp) 
  1943 apply (subgoal_tac "~ x < real nat * y")
  1944  prefer 2 apply (rule not_less_Least, simp, force)  
  1945 done
  1946 
  1947 (* Pre Isabelle99-2 proof was simpler- numerals arithmetic 
  1948    now causes some unwanted re-arrangements of literals!   *)
  1949 lemma cos_zero_lemma:
  1950      "[| 0 \<le> x; cos x = 0 |] ==>  
  1951       \<exists>n::nat. ~even n & x = real n * (pi/2)"
  1952 apply (drule pi_gt_zero [THEN reals_Archimedean4], safe)
  1953 apply (subgoal_tac "0 \<le> x - real n * pi & 
  1954                     (x - real n * pi) \<le> pi & (cos (x - real n * pi) = 0) ")
  1955 apply (auto simp add: algebra_simps real_of_nat_Suc)
  1956  prefer 2 apply (simp add: cos_diff)
  1957 apply (simp add: cos_diff)
  1958 apply (subgoal_tac "EX! x. 0 \<le> x & x \<le> pi & cos x = 0")
  1959 apply (rule_tac [2] cos_total, safe)
  1960 apply (drule_tac x = "x - real n * pi" in spec)
  1961 apply (drule_tac x = "pi/2" in spec)
  1962 apply (simp add: cos_diff)
  1963 apply (rule_tac x = "Suc (2 * n)" in exI)
  1964 apply (simp add: real_of_nat_Suc algebra_simps, auto)
  1965 done
  1966 
  1967 lemma sin_zero_lemma:
  1968      "[| 0 \<le> x; sin x = 0 |] ==>  
  1969       \<exists>n::nat. even n & x = real n * (pi/2)"
  1970 apply (subgoal_tac "\<exists>n::nat. ~ even n & x + pi/2 = real n * (pi/2) ")
  1971  apply (clarify, rule_tac x = "n - 1" in exI)
  1972  apply (force simp add: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib)
  1973 apply (rule cos_zero_lemma)
  1974 apply (simp_all add: add_increasing)  
  1975 done
  1976 
  1977 
  1978 lemma cos_zero_iff:
  1979      "(cos x = 0) =  
  1980       ((\<exists>n::nat. ~even n & (x = real n * (pi/2))) |    
  1981        (\<exists>n::nat. ~even n & (x = -(real n * (pi/2)))))"
  1982 apply (rule iffI)
  1983 apply (cut_tac linorder_linear [of 0 x], safe)
  1984 apply (drule cos_zero_lemma, assumption+)
  1985 apply (cut_tac x="-x" in cos_zero_lemma, simp, simp) 
  1986 apply (force simp add: minus_equation_iff [of x]) 
  1987 apply (auto simp only: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib) 
  1988 apply (auto simp add: cos_add)
  1989 done
  1990 
  1991 (* ditto: but to a lesser extent *)
  1992 lemma sin_zero_iff:
  1993      "(sin x = 0) =  
  1994       ((\<exists>n::nat. even n & (x = real n * (pi/2))) |    
  1995        (\<exists>n::nat. even n & (x = -(real n * (pi/2)))))"
  1996 apply (rule iffI)
  1997 apply (cut_tac linorder_linear [of 0 x], safe)
  1998 apply (drule sin_zero_lemma, assumption+)
  1999 apply (cut_tac x="-x" in sin_zero_lemma, simp, simp, safe)
  2000 apply (force simp add: minus_equation_iff [of x]) 
  2001 apply (auto simp add: even_mult_two_ex)
  2002 done
  2003 
  2004 lemma cos_monotone_0_pi: assumes "0 \<le> y" and "y < x" and "x \<le> pi"
  2005   shows "cos x < cos y"
  2006 proof -
  2007   have "- (x - y) < 0" using assms by auto
  2008 
  2009   from MVT2[OF `y < x` DERIV_cos[THEN impI, THEN allI]]
  2010   obtain z where "y < z" and "z < x" and cos_diff: "cos x - cos y = (x - y) * - sin z" by auto
  2011   hence "0 < z" and "z < pi" using assms by auto
  2012   hence "0 < sin z" using sin_gt_zero_pi by auto
  2013   hence "cos x - cos y < 0" unfolding cos_diff minus_mult_commute[symmetric] using `- (x - y) < 0` by (rule mult_pos_neg2)
  2014   thus ?thesis by auto
  2015 qed
  2016 
  2017 lemma cos_monotone_0_pi': assumes "0 \<le> y" and "y \<le> x" and "x \<le> pi" shows "cos x \<le> cos y"
  2018 proof (cases "y < x")
  2019   case True show ?thesis using cos_monotone_0_pi[OF `0 \<le> y` True `x \<le> pi`] by auto
  2020 next
  2021   case False hence "y = x" using `y \<le> x` by auto
  2022   thus ?thesis by auto
  2023 qed
  2024 
  2025 lemma cos_monotone_minus_pi_0: assumes "-pi \<le> y" and "y < x" and "x \<le> 0"
  2026   shows "cos y < cos x"
  2027 proof -
  2028   have "0 \<le> -x" and "-x < -y" and "-y \<le> pi" using assms by auto
  2029   from cos_monotone_0_pi[OF this]
  2030   show ?thesis unfolding cos_minus .
  2031 qed
  2032 
  2033 lemma cos_monotone_minus_pi_0': assumes "-pi \<le> y" and "y \<le> x" and "x \<le> 0" shows "cos y \<le> cos x"
  2034 proof (cases "y < x")
  2035   case True show ?thesis using cos_monotone_minus_pi_0[OF `-pi \<le> y` True `x \<le> 0`] by auto
  2036 next
  2037   case False hence "y = x" using `y \<le> x` by auto
  2038   thus ?thesis by auto
  2039 qed
  2040 
  2041 lemma sin_monotone_2pi': assumes "- (pi / 2) \<le> y" and "y \<le> x" and "x \<le> pi / 2" shows "sin y \<le> sin x"
  2042 proof -
  2043   have "0 \<le> y + pi / 2" and "y + pi / 2 \<le> x + pi / 2" and "x + pi /2 \<le> pi"
  2044     using pi_ge_two and assms by auto
  2045   from cos_monotone_0_pi'[OF this] show ?thesis unfolding minus_sin_cos_eq[symmetric] by auto
  2046 qed
  2047 
  2048 subsection {* Tangent *}
  2049 
  2050 definition
  2051   tan :: "real => real" where
  2052   "tan x = (sin x)/(cos x)"
  2053 
  2054 lemma tan_zero [simp]: "tan 0 = 0"
  2055 by (simp add: tan_def)
  2056 
  2057 lemma tan_pi [simp]: "tan pi = 0"
  2058 by (simp add: tan_def)
  2059 
  2060 lemma tan_npi [simp]: "tan (real (n::nat) * pi) = 0"
  2061 by (simp add: tan_def)
  2062 
  2063 lemma tan_minus [simp]: "tan (-x) = - tan x"
  2064 by (simp add: tan_def minus_mult_left)
  2065 
  2066 lemma tan_periodic [simp]: "tan (x + 2*pi) = tan x"
  2067 by (simp add: tan_def)
  2068 
  2069 lemma lemma_tan_add1: 
  2070       "[| cos x \<noteq> 0; cos y \<noteq> 0 |]  
  2071         ==> 1 - tan(x)*tan(y) = cos (x + y)/(cos x * cos y)"
  2072 apply (simp add: tan_def divide_inverse)
  2073 apply (auto simp del: inverse_mult_distrib 
  2074             simp add: inverse_mult_distrib [symmetric] mult_ac)
  2075 apply (rule_tac c1 = "cos x * cos y" in real_mult_right_cancel [THEN subst])
  2076 apply (auto simp del: inverse_mult_distrib 
  2077             simp add: mult_assoc left_diff_distrib cos_add)
  2078 done
  2079 
  2080 lemma add_tan_eq: 
  2081       "[| cos x \<noteq> 0; cos y \<noteq> 0 |]  
  2082        ==> tan x + tan y = sin(x + y)/(cos x * cos y)"
  2083 apply (simp add: tan_def)
  2084 apply (rule_tac c1 = "cos x * cos y" in real_mult_right_cancel [THEN subst])
  2085 apply (auto simp add: mult_assoc left_distrib)
  2086 apply (simp add: sin_add)
  2087 done
  2088 
  2089 lemma tan_add:
  2090      "[| cos x \<noteq> 0; cos y \<noteq> 0; cos (x + y) \<noteq> 0 |]  
  2091       ==> tan(x + y) = (tan(x) + tan(y))/(1 - tan(x) * tan(y))"
  2092 apply (simp (no_asm_simp) add: add_tan_eq lemma_tan_add1)
  2093 apply (simp add: tan_def)
  2094 done
  2095 
  2096 lemma tan_double:
  2097      "[| cos x \<noteq> 0; cos (2 * x) \<noteq> 0 |]  
  2098       ==> tan (2 * x) = (2 * tan x)/(1 - (tan(x) ^ 2))"
  2099 apply (insert tan_add [of x x]) 
  2100 apply (simp add: mult_2 [symmetric])  
  2101 apply (auto simp add: numeral_2_eq_2)
  2102 done
  2103 
  2104 lemma tan_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < tan x"
  2105 by (simp add: tan_def zero_less_divide_iff sin_gt_zero2 cos_gt_zero_pi) 
  2106 
  2107 lemma tan_less_zero: 
  2108   assumes lb: "- pi/2 < x" and "x < 0" shows "tan x < 0"
  2109 proof -
  2110   have "0 < tan (- x)" using assms by (simp only: tan_gt_zero) 
  2111   thus ?thesis by simp
  2112 qed
  2113 
  2114 lemma tan_half: fixes x :: real assumes "- (pi / 2) < x" and "x < pi / 2"
  2115   shows "tan x = sin (2 * x) / (cos (2 * x) + 1)"
  2116 proof -
  2117   from cos_gt_zero_pi[OF `- (pi / 2) < x` `x < pi / 2`]
  2118   have "cos x \<noteq> 0" by auto
  2119 
  2120   have minus_cos_2x: "\<And>X. X - cos (2*x) = X - (cos x) ^ 2 + (sin x) ^ 2" unfolding cos_double by algebra
  2121 
  2122   have "tan x = (tan x + tan x) / 2" by auto
  2123   also have "\<dots> = sin (x + x) / (cos x * cos x) / 2" unfolding add_tan_eq[OF `cos x \<noteq> 0` `cos x \<noteq> 0`] ..
  2124   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + (cos x) ^ 2 + cos (2*x) - cos (2*x))" unfolding divide_divide_eq_left numeral_2_eq_2 by auto
  2125   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + cos (2*x) + (sin x)^2)" unfolding minus_cos_2x by auto
  2126   also have "\<dots> = sin (2 * x) / (cos (2*x) + 1)" by auto
  2127   finally show ?thesis .
  2128 qed
  2129 
  2130 lemma lemma_DERIV_tan:
  2131      "cos x \<noteq> 0 ==> DERIV (%x. sin(x)/cos(x)) x :> inverse((cos x)\<twosuperior>)"
  2132   by (auto intro!: DERIV_intros simp add: field_simps numeral_2_eq_2)
  2133 
  2134 lemma DERIV_tan [simp]: "cos x \<noteq> 0 ==> DERIV tan x :> inverse((cos x)\<twosuperior>)"
  2135 by (auto dest: lemma_DERIV_tan simp add: tan_def [symmetric])
  2136 
  2137 lemma isCont_tan [simp]: "cos x \<noteq> 0 ==> isCont tan x"
  2138 by (rule DERIV_tan [THEN DERIV_isCont])
  2139 
  2140 lemma LIM_cos_div_sin [simp]: "(%x. cos(x)/sin(x)) -- pi/2 --> 0"
  2141 apply (subgoal_tac "(\<lambda>x. cos x * inverse (sin x)) -- pi * inverse 2 --> 0*1")
  2142 apply (simp add: divide_inverse [symmetric])
  2143 apply (rule LIM_mult)
  2144 apply (rule_tac [2] inverse_1 [THEN subst])
  2145 apply (rule_tac [2] LIM_inverse)
  2146 apply (simp_all add: divide_inverse [symmetric]) 
  2147 apply (simp_all only: isCont_def [symmetric] cos_pi_half [symmetric] sin_pi_half [symmetric]) 
  2148 apply (blast intro!: DERIV_isCont DERIV_sin DERIV_cos)+
  2149 done
  2150 
  2151 lemma lemma_tan_total: "0 < y ==> \<exists>x. 0 < x & x < pi/2 & y < tan x"
  2152 apply (cut_tac LIM_cos_div_sin)
  2153 apply (simp only: LIM_eq)
  2154 apply (drule_tac x = "inverse y" in spec, safe, force)
  2155 apply (drule_tac ?d1.0 = s in pi_half_gt_zero [THEN [2] real_lbound_gt_zero], safe)
  2156 apply (rule_tac x = "(pi/2) - e" in exI)
  2157 apply (simp (no_asm_simp))
  2158 apply (drule_tac x = "(pi/2) - e" in spec)
  2159 apply (auto simp add: tan_def)
  2160 apply (rule inverse_less_iff_less [THEN iffD1])
  2161 apply (auto simp add: divide_inverse)
  2162 apply (rule mult_pos_pos)
  2163 apply (subgoal_tac [3] "0 < sin e & 0 < cos e")
  2164 apply (auto intro: cos_gt_zero sin_gt_zero2 simp add: mult_commute)
  2165 done
  2166 
  2167 lemma tan_total_pos: "0 \<le> y ==> \<exists>x. 0 \<le> x & x < pi/2 & tan x = y"
  2168 apply (frule order_le_imp_less_or_eq, safe)
  2169  prefer 2 apply force
  2170 apply (drule lemma_tan_total, safe)
  2171 apply (cut_tac f = tan and a = 0 and b = x and y = y in IVT_objl)
  2172 apply (auto intro!: DERIV_tan [THEN DERIV_isCont])
  2173 apply (drule_tac y = xa in order_le_imp_less_or_eq)
  2174 apply (auto dest: cos_gt_zero)
  2175 done
  2176 
  2177 lemma lemma_tan_total1: "\<exists>x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2178 apply (cut_tac linorder_linear [of 0 y], safe)
  2179 apply (drule tan_total_pos)
  2180 apply (cut_tac [2] y="-y" in tan_total_pos, safe)
  2181 apply (rule_tac [3] x = "-x" in exI)
  2182 apply (auto intro!: exI)
  2183 done
  2184 
  2185 lemma tan_total: "EX! x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2186 apply (cut_tac y = y in lemma_tan_total1, auto)
  2187 apply (cut_tac x = xa and y = y in linorder_less_linear, auto)
  2188 apply (subgoal_tac [2] "\<exists>z. y < z & z < xa & DERIV tan z :> 0")
  2189 apply (subgoal_tac "\<exists>z. xa < z & z < y & DERIV tan z :> 0")
  2190 apply (rule_tac [4] Rolle)
  2191 apply (rule_tac [2] Rolle)
  2192 apply (auto intro!: DERIV_tan DERIV_isCont exI 
  2193             simp add: differentiable_def)
  2194 txt{*Now, simulate TRYALL*}
  2195 apply (rule_tac [!] DERIV_tan asm_rl)
  2196 apply (auto dest!: DERIV_unique [OF _ DERIV_tan]
  2197             simp add: cos_gt_zero_pi [THEN less_imp_neq, THEN not_sym]) 
  2198 done
  2199 
  2200 lemma tan_monotone: assumes "- (pi / 2) < y" and "y < x" and "x < pi / 2"
  2201   shows "tan y < tan x"
  2202 proof -
  2203   have "\<forall> x'. y \<le> x' \<and> x' \<le> x \<longrightarrow> DERIV tan x' :> inverse (cos x'^2)"
  2204   proof (rule allI, rule impI)
  2205     fix x' :: real assume "y \<le> x' \<and> x' \<le> x"
  2206     hence "-(pi/2) < x'" and "x' < pi/2" using assms by auto
  2207     from cos_gt_zero_pi[OF this]
  2208     have "cos x' \<noteq> 0" by auto
  2209     thus "DERIV tan x' :> inverse (cos x'^2)" by (rule DERIV_tan)
  2210   qed
  2211   from MVT2[OF `y < x` this] 
  2212   obtain z where "y < z" and "z < x" and tan_diff: "tan x - tan y = (x - y) * inverse ((cos z)\<twosuperior>)" by auto
  2213   hence "- (pi / 2) < z" and "z < pi / 2" using assms by auto
  2214   hence "0 < cos z" using cos_gt_zero_pi by auto
  2215   hence inv_pos: "0 < inverse ((cos z)\<twosuperior>)" by auto
  2216   have "0 < x - y" using `y < x` by auto
  2217   from mult_pos_pos [OF this inv_pos]
  2218   have "0 < tan x - tan y" unfolding tan_diff by auto
  2219   thus ?thesis by auto
  2220 qed
  2221 
  2222 lemma tan_monotone': assumes "- (pi / 2) < y" and "y < pi / 2" and "- (pi / 2) < x" and "x < pi / 2"
  2223   shows "(y < x) = (tan y < tan x)"
  2224 proof
  2225   assume "y < x" thus "tan y < tan x" using tan_monotone and `- (pi / 2) < y` and `x < pi / 2` by auto
  2226 next
  2227   assume "tan y < tan x"
  2228   show "y < x"
  2229   proof (rule ccontr)
  2230     assume "\<not> y < x" hence "x \<le> y" by auto
  2231     hence "tan x \<le> tan y" 
  2232     proof (cases "x = y")
  2233       case True thus ?thesis by auto
  2234     next
  2235       case False hence "x < y" using `x \<le> y` by auto
  2236       from tan_monotone[OF `- (pi/2) < x` this `y < pi / 2`] show ?thesis by auto
  2237     qed
  2238     thus False using `tan y < tan x` by auto
  2239   qed
  2240 qed
  2241 
  2242 lemma tan_inverse: "1 / (tan y) = tan (pi / 2 - y)" unfolding tan_def sin_cos_eq[of y] cos_sin_eq[of y] by auto
  2243 
  2244 lemma tan_periodic_pi[simp]: "tan (x + pi) = tan x" 
  2245   by (simp add: tan_def)
  2246 
  2247 lemma tan_periodic_nat[simp]: fixes n :: nat shows "tan (x + real n * pi) = tan x" 
  2248 proof (induct n arbitrary: x)
  2249   case (Suc n)
  2250   have split_pi_off: "x + real (Suc n) * pi = (x + real n * pi) + pi" unfolding Suc_eq_plus1 real_of_nat_add real_of_one left_distrib by auto
  2251   show ?case unfolding split_pi_off using Suc by auto
  2252 qed auto
  2253 
  2254 lemma tan_periodic_int[simp]: fixes i :: int shows "tan (x + real i * pi) = tan x"
  2255 proof (cases "0 \<le> i")
  2256   case True hence i_nat: "real i = real (nat i)" by auto
  2257   show ?thesis unfolding i_nat by auto
  2258 next
  2259   case False hence i_nat: "real i = - real (nat (-i))" by auto
  2260   have "tan x = tan (x + real i * pi - real i * pi)" by auto
  2261   also have "\<dots> = tan (x + real i * pi)" unfolding i_nat mult_minus_left diff_minus_eq_add by (rule tan_periodic_nat)
  2262   finally show ?thesis by auto
  2263 qed
  2264 
  2265 lemma tan_periodic_n[simp]: "tan (x + number_of n * pi) = tan x"
  2266   using tan_periodic_int[of _ "number_of n" ] unfolding real_number_of .
  2267 
  2268 subsection {* Inverse Trigonometric Functions *}
  2269 
  2270 definition
  2271   arcsin :: "real => real" where
  2272   "arcsin y = (THE x. -(pi/2) \<le> x & x \<le> pi/2 & sin x = y)"
  2273 
  2274 definition
  2275   arccos :: "real => real" where
  2276   "arccos y = (THE x. 0 \<le> x & x \<le> pi & cos x = y)"
  2277 
  2278 definition     
  2279   arctan :: "real => real" where
  2280   "arctan y = (THE x. -(pi/2) < x & x < pi/2 & tan x = y)"
  2281 
  2282 lemma arcsin:
  2283      "[| -1 \<le> y; y \<le> 1 |]  
  2284       ==> -(pi/2) \<le> arcsin y &  
  2285            arcsin y \<le> pi/2 & sin(arcsin y) = y"
  2286 unfolding arcsin_def by (rule theI' [OF sin_total])
  2287 
  2288 lemma arcsin_pi:
  2289      "[| -1 \<le> y; y \<le> 1 |]  
  2290       ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi & sin(arcsin y) = y"
  2291 apply (drule (1) arcsin)
  2292 apply (force intro: order_trans)
  2293 done
  2294 
  2295 lemma sin_arcsin [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> sin(arcsin y) = y"
  2296 by (blast dest: arcsin)
  2297       
  2298 lemma arcsin_bounded:
  2299      "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi/2"
  2300 by (blast dest: arcsin)
  2301 
  2302 lemma arcsin_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y"
  2303 by (blast dest: arcsin)
  2304 
  2305 lemma arcsin_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arcsin y \<le> pi/2"
  2306 by (blast dest: arcsin)
  2307 
  2308 lemma arcsin_lt_bounded:
  2309      "[| -1 < y; y < 1 |] ==> -(pi/2) < arcsin y & arcsin y < pi/2"
  2310 apply (frule order_less_imp_le)
  2311 apply (frule_tac y = y in order_less_imp_le)
  2312 apply (frule arcsin_bounded)
  2313 apply (safe, simp)
  2314 apply (drule_tac y = "arcsin y" in order_le_imp_less_or_eq)
  2315 apply (drule_tac [2] y = "pi/2" in order_le_imp_less_or_eq, safe)
  2316 apply (drule_tac [!] f = sin in arg_cong, auto)
  2317 done
  2318 
  2319 lemma arcsin_sin: "[|-(pi/2) \<le> x; x \<le> pi/2 |] ==> arcsin(sin x) = x"
  2320 apply (unfold arcsin_def)
  2321 apply (rule the1_equality)
  2322 apply (rule sin_total, auto)
  2323 done
  2324 
  2325 lemma arccos:
  2326      "[| -1 \<le> y; y \<le> 1 |]  
  2327       ==> 0 \<le> arccos y & arccos y \<le> pi & cos(arccos y) = y"
  2328 unfolding arccos_def by (rule theI' [OF cos_total])
  2329 
  2330 lemma cos_arccos [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> cos(arccos y) = y"
  2331 by (blast dest: arccos)
  2332       
  2333 lemma arccos_bounded: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y & arccos y \<le> pi"
  2334 by (blast dest: arccos)
  2335 
  2336 lemma arccos_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y"
  2337 by (blast dest: arccos)
  2338 
  2339 lemma arccos_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arccos y \<le> pi"
  2340 by (blast dest: arccos)
  2341 
  2342 lemma arccos_lt_bounded:
  2343      "[| -1 < y; y < 1 |]  
  2344       ==> 0 < arccos y & arccos y < pi"
  2345 apply (frule order_less_imp_le)
  2346 apply (frule_tac y = y in order_less_imp_le)
  2347 apply (frule arccos_bounded, auto)
  2348 apply (drule_tac y = "arccos y" in order_le_imp_less_or_eq)
  2349 apply (drule_tac [2] y = pi in order_le_imp_less_or_eq, auto)
  2350 apply (drule_tac [!] f = cos in arg_cong, auto)
  2351 done
  2352 
  2353 lemma arccos_cos: "[|0 \<le> x; x \<le> pi |] ==> arccos(cos x) = x"
  2354 apply (simp add: arccos_def)
  2355 apply (auto intro!: the1_equality cos_total)
  2356 done
  2357 
  2358 lemma arccos_cos2: "[|x \<le> 0; -pi \<le> x |] ==> arccos(cos x) = -x"
  2359 apply (simp add: arccos_def)
  2360 apply (auto intro!: the1_equality cos_total)
  2361 done
  2362 
  2363 lemma cos_arcsin: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> cos (arcsin x) = sqrt (1 - x\<twosuperior>)"
  2364 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2365 apply (rule power2_eq_imp_eq)
  2366 apply (simp add: cos_squared_eq)
  2367 apply (rule cos_ge_zero)
  2368 apply (erule (1) arcsin_lbound)
  2369 apply (erule (1) arcsin_ubound)
  2370 apply simp
  2371 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2372 apply (rule power_mono, simp, simp)
  2373 done
  2374 
  2375 lemma sin_arccos: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> sin (arccos x) = sqrt (1 - x\<twosuperior>)"
  2376 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2377 apply (rule power2_eq_imp_eq)
  2378 apply (simp add: sin_squared_eq)
  2379 apply (rule sin_ge_zero)
  2380 apply (erule (1) arccos_lbound)
  2381 apply (erule (1) arccos_ubound)
  2382 apply simp
  2383 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2384 apply (rule power_mono, simp, simp)
  2385 done
  2386 
  2387 lemma arctan [simp]:
  2388      "- (pi/2) < arctan y  & arctan y < pi/2 & tan (arctan y) = y"
  2389 unfolding arctan_def by (rule theI' [OF tan_total])
  2390 
  2391 lemma tan_arctan: "tan(arctan y) = y"
  2392 by auto
  2393 
  2394 lemma arctan_bounded: "- (pi/2) < arctan y  & arctan y < pi/2"
  2395 by (auto simp only: arctan)
  2396 
  2397 lemma arctan_lbound: "- (pi/2) < arctan y"
  2398 by auto
  2399 
  2400 lemma arctan_ubound: "arctan y < pi/2"
  2401 by (auto simp only: arctan)
  2402 
  2403 lemma arctan_tan: 
  2404       "[|-(pi/2) < x; x < pi/2 |] ==> arctan(tan x) = x"
  2405 apply (unfold arctan_def)
  2406 apply (rule the1_equality)
  2407 apply (rule tan_total, auto)
  2408 done
  2409 
  2410 lemma arctan_zero_zero [simp]: "arctan 0 = 0"
  2411 by (insert arctan_tan [of 0], simp)
  2412 
  2413 lemma cos_arctan_not_zero [simp]: "cos(arctan x) \<noteq> 0"
  2414 apply (auto simp add: cos_zero_iff)
  2415 apply (case_tac "n")
  2416 apply (case_tac [3] "n")
  2417 apply (cut_tac [2] y = x in arctan_ubound)
  2418 apply (cut_tac [4] y = x in arctan_lbound) 
  2419 apply (auto simp add: real_of_nat_Suc left_distrib mult_less_0_iff)
  2420 done
  2421 
  2422 lemma tan_sec: "cos x \<noteq> 0 ==> 1 + tan(x) ^ 2 = inverse(cos x) ^ 2"
  2423 apply (rule power_inverse [THEN subst])
  2424 apply (rule_tac c1 = "(cos x)\<twosuperior>" in real_mult_right_cancel [THEN iffD1])
  2425 apply (auto dest: field_power_not_zero
  2426         simp add: power_mult_distrib left_distrib power_divide tan_def 
  2427                   mult_assoc power_inverse [symmetric])
  2428 done
  2429 
  2430 lemma isCont_inverse_function2:
  2431   fixes f g :: "real \<Rightarrow> real" shows
  2432   "\<lbrakk>a < x; x < b;
  2433     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2434     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2435    \<Longrightarrow> isCont g (f x)"
  2436 apply (rule isCont_inverse_function
  2437        [where f=f and d="min (x - a) (b - x)"])
  2438 apply (simp_all add: abs_le_iff)
  2439 done
  2440 
  2441 lemma isCont_arcsin: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arcsin x"
  2442 apply (subgoal_tac "isCont arcsin (sin (arcsin x))", simp)
  2443 apply (rule isCont_inverse_function2 [where f=sin])
  2444 apply (erule (1) arcsin_lt_bounded [THEN conjunct1])
  2445 apply (erule (1) arcsin_lt_bounded [THEN conjunct2])
  2446 apply (fast intro: arcsin_sin, simp)
  2447 done
  2448 
  2449 lemma isCont_arccos: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arccos x"
  2450 apply (subgoal_tac "isCont arccos (cos (arccos x))", simp)
  2451 apply (rule isCont_inverse_function2 [where f=cos])
  2452 apply (erule (1) arccos_lt_bounded [THEN conjunct1])
  2453 apply (erule (1) arccos_lt_bounded [THEN conjunct2])
  2454 apply (fast intro: arccos_cos, simp)
  2455 done
  2456 
  2457 lemma isCont_arctan: "isCont arctan x"
  2458 apply (rule arctan_lbound [of x, THEN dense, THEN exE], clarify)
  2459 apply (rule arctan_ubound [of x, THEN dense, THEN exE], clarify)
  2460 apply (subgoal_tac "isCont arctan (tan (arctan x))", simp)
  2461 apply (erule (1) isCont_inverse_function2 [where f=tan])
  2462 apply (metis arctan_tan order_le_less_trans order_less_le_trans)
  2463 apply (metis cos_gt_zero_pi isCont_tan order_less_le_trans less_le)
  2464 done
  2465 
  2466 lemma DERIV_arcsin:
  2467   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arcsin x :> inverse (sqrt (1 - x\<twosuperior>))"
  2468 apply (rule DERIV_inverse_function [where f=sin and a="-1" and b="1"])
  2469 apply (rule lemma_DERIV_subst [OF DERIV_sin])
  2470 apply (simp add: cos_arcsin)
  2471 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2472 apply (rule power_strict_mono, simp, simp, simp)
  2473 apply assumption
  2474 apply assumption
  2475 apply simp
  2476 apply (erule (1) isCont_arcsin)
  2477 done
  2478 
  2479 lemma DERIV_arccos:
  2480   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arccos x :> inverse (- sqrt (1 - x\<twosuperior>))"
  2481 apply (rule DERIV_inverse_function [where f=cos and a="-1" and b="1"])
  2482 apply (rule lemma_DERIV_subst [OF DERIV_cos])
  2483 apply (simp add: sin_arccos)
  2484 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2485 apply (rule power_strict_mono, simp, simp, simp)
  2486 apply assumption
  2487 apply assumption
  2488 apply simp
  2489 apply (erule (1) isCont_arccos)
  2490 done
  2491 
  2492 lemma DERIV_arctan: "DERIV arctan x :> inverse (1 + x\<twosuperior>)"
  2493 apply (rule DERIV_inverse_function [where f=tan and a="x - 1" and b="x + 1"])
  2494 apply (rule lemma_DERIV_subst [OF DERIV_tan])
  2495 apply (rule cos_arctan_not_zero)
  2496 apply (simp add: power_inverse tan_sec [symmetric])
  2497 apply (subgoal_tac "0 < 1 + x\<twosuperior>", simp)
  2498 apply (simp add: add_pos_nonneg)
  2499 apply (simp, simp, simp, rule isCont_arctan)
  2500 done
  2501 
  2502 declare
  2503   DERIV_arcsin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2504   DERIV_arccos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2505   DERIV_arctan[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2506 
  2507 subsection {* More Theorems about Sin and Cos *}
  2508 
  2509 lemma cos_45: "cos (pi / 4) = sqrt 2 / 2"
  2510 proof -
  2511   let ?c = "cos (pi / 4)" and ?s = "sin (pi / 4)"
  2512   have nonneg: "0 \<le> ?c"
  2513     by (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2514   have "0 = cos (pi / 4 + pi / 4)"
  2515     by simp
  2516   also have "cos (pi / 4 + pi / 4) = ?c\<twosuperior> - ?s\<twosuperior>"
  2517     by (simp only: cos_add power2_eq_square)
  2518   also have "\<dots> = 2 * ?c\<twosuperior> - 1"
  2519     by (simp add: sin_squared_eq)
  2520   finally have "?c\<twosuperior> = (sqrt 2 / 2)\<twosuperior>"
  2521     by (simp add: power_divide)
  2522   thus ?thesis
  2523     using nonneg by (rule power2_eq_imp_eq) simp
  2524 qed
  2525 
  2526 lemma cos_30: "cos (pi / 6) = sqrt 3 / 2"
  2527 proof -
  2528   let ?c = "cos (pi / 6)" and ?s = "sin (pi / 6)"
  2529   have pos_c: "0 < ?c"
  2530     by (rule cos_gt_zero, simp, simp)
  2531   have "0 = cos (pi / 6 + pi / 6 + pi / 6)"
  2532     by simp
  2533   also have "\<dots> = (?c * ?c - ?s * ?s) * ?c - (?s * ?c + ?c * ?s) * ?s"
  2534     by (simp only: cos_add sin_add)
  2535   also have "\<dots> = ?c * (?c\<twosuperior> - 3 * ?s\<twosuperior>)"
  2536     by (simp add: algebra_simps power2_eq_square)
  2537   finally have "?c\<twosuperior> = (sqrt 3 / 2)\<twosuperior>"
  2538     using pos_c by (simp add: sin_squared_eq power_divide)
  2539   thus ?thesis
  2540     using pos_c [THEN order_less_imp_le]
  2541     by (rule power2_eq_imp_eq) simp
  2542 qed
  2543 
  2544 lemma sin_45: "sin (pi / 4) = sqrt 2 / 2"
  2545 proof -
  2546   have "sin (pi / 4) = cos (pi / 2 - pi / 4)" by (rule sin_cos_eq)
  2547   also have "pi / 2 - pi / 4 = pi / 4" by simp
  2548   also have "cos (pi / 4) = sqrt 2 / 2" by (rule cos_45)
  2549   finally show ?thesis .
  2550 qed
  2551 
  2552 lemma sin_60: "sin (pi / 3) = sqrt 3 / 2"
  2553 proof -
  2554   have "sin (pi / 3) = cos (pi / 2 - pi / 3)" by (rule sin_cos_eq)
  2555   also have "pi / 2 - pi / 3 = pi / 6" by simp
  2556   also have "cos (pi / 6) = sqrt 3 / 2" by (rule cos_30)
  2557   finally show ?thesis .
  2558 qed
  2559 
  2560 lemma cos_60: "cos (pi / 3) = 1 / 2"
  2561 apply (rule power2_eq_imp_eq)
  2562 apply (simp add: cos_squared_eq sin_60 power_divide)
  2563 apply (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2564 done
  2565 
  2566 lemma sin_30: "sin (pi / 6) = 1 / 2"
  2567 proof -
  2568   have "sin (pi / 6) = cos (pi / 2 - pi / 6)" by (rule sin_cos_eq)
  2569   also have "pi / 2 - pi / 6 = pi / 3" by simp
  2570   also have "cos (pi / 3) = 1 / 2" by (rule cos_60)
  2571   finally show ?thesis .
  2572 qed
  2573 
  2574 lemma tan_30: "tan (pi / 6) = 1 / sqrt 3"
  2575 unfolding tan_def by (simp add: sin_30 cos_30)
  2576 
  2577 lemma tan_45: "tan (pi / 4) = 1"
  2578 unfolding tan_def by (simp add: sin_45 cos_45)
  2579 
  2580 lemma tan_60: "tan (pi / 3) = sqrt 3"
  2581 unfolding tan_def by (simp add: sin_60 cos_60)
  2582 
  2583 lemma DERIV_sin_add [simp]: "DERIV (%x. sin (x + k)) xa :> cos (xa + k)"
  2584   by (auto intro!: DERIV_intros)
  2585 
  2586 lemma sin_cos_npi [simp]: "sin (real (Suc (2 * n)) * pi / 2) = (-1) ^ n"
  2587 proof -
  2588   have "sin ((real n + 1/2) * pi) = cos (real n * pi)"
  2589     by (auto simp add: algebra_simps sin_add)
  2590   thus ?thesis
  2591     by (simp add: real_of_nat_Suc left_distrib add_divide_distrib 
  2592                   mult_commute [of pi])
  2593 qed
  2594 
  2595 lemma cos_2npi [simp]: "cos (2 * real (n::nat) * pi) = 1"
  2596 by (simp add: cos_double mult_assoc power_add [symmetric] numeral_2_eq_2)
  2597 
  2598 lemma cos_3over2_pi [simp]: "cos (3 / 2 * pi) = 0"
  2599 apply (subgoal_tac "cos (pi + pi/2) = 0", simp)
  2600 apply (subst cos_add, simp)
  2601 done
  2602 
  2603 lemma sin_2npi [simp]: "sin (2 * real (n::nat) * pi) = 0"
  2604 by (auto simp add: mult_assoc)
  2605 
  2606 lemma sin_3over2_pi [simp]: "sin (3 / 2 * pi) = - 1"
  2607 apply (subgoal_tac "sin (pi + pi/2) = - 1", simp)
  2608 apply (subst sin_add, simp)
  2609 done
  2610 
  2611 lemma cos_pi_eq_zero [simp]: "cos (pi * real (Suc (2 * m)) / 2) = 0"
  2612 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib right_distrib add_divide_distrib, auto)
  2613 
  2614 lemma DERIV_cos_add [simp]: "DERIV (%x. cos (x + k)) xa :> - sin (xa + k)"
  2615   by (auto intro!: DERIV_intros)
  2616 
  2617 lemma sin_zero_abs_cos_one: "sin x = 0 ==> \<bar>cos x\<bar> = 1"
  2618 by (auto simp add: sin_zero_iff even_mult_two_ex)
  2619 
  2620 lemma cos_one_sin_zero: "cos x = 1 ==> sin x = 0"
  2621 by (cut_tac x = x in sin_cos_squared_add3, auto)
  2622 
  2623 subsection {* Machins formula *}
  2624 
  2625 lemma tan_total_pi4: assumes "\<bar>x\<bar> < 1"
  2626   shows "\<exists> z. - (pi / 4) < z \<and> z < pi / 4 \<and> tan z = x"
  2627 proof -
  2628   obtain z where "- (pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  2629   have "tan (pi / 4) = 1" and "tan (- (pi / 4)) = - 1" using tan_45 tan_minus by auto
  2630   have "z \<noteq> pi / 4" 
  2631   proof (rule ccontr)
  2632     assume "\<not> (z \<noteq> pi / 4)" hence "z = pi / 4" by auto
  2633     have "tan z = 1" unfolding `z = pi / 4` `tan (pi / 4) = 1` ..
  2634     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2635   qed
  2636   have "z \<noteq> - (pi / 4)"
  2637   proof (rule ccontr)
  2638     assume "\<not> (z \<noteq> - (pi / 4))" hence "z = - (pi / 4)" by auto
  2639     have "tan z = - 1" unfolding `z = - (pi / 4)` `tan (- (pi / 4)) = - 1` ..
  2640     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2641   qed
  2642 
  2643   have "z < pi / 4"
  2644   proof (rule ccontr)
  2645     assume "\<not> (z < pi / 4)" hence "pi / 4 < z" using `z \<noteq> pi / 4` by auto
  2646     have "- (pi / 2) < pi / 4" using m2pi_less_pi by auto
  2647     from tan_monotone[OF this `pi / 4 < z` `z < pi / 2`] 
  2648     have "1 < x" unfolding `tan z = x` `tan (pi / 4) = 1` .
  2649     thus False using `\<bar>x\<bar> < 1` by auto
  2650   qed
  2651   moreover 
  2652   have "-(pi / 4) < z"
  2653   proof (rule ccontr)
  2654     assume "\<not> (-(pi / 4) < z)" hence "z < - (pi / 4)" using `z \<noteq> - (pi / 4)` by auto
  2655     have "-(pi / 4) < pi / 2" using m2pi_less_pi by auto
  2656     from tan_monotone[OF `-(pi / 2) < z` `z < -(pi / 4)` this]
  2657     have "x < - 1" unfolding `tan z = x` `tan (-(pi / 4)) = - 1` .
  2658     thus False using `\<bar>x\<bar> < 1` by auto
  2659   qed
  2660   ultimately show ?thesis using `tan z = x` by auto
  2661 qed
  2662 
  2663 lemma arctan_add: assumes "\<bar>x\<bar> \<le> 1" and "\<bar>y\<bar> < 1"
  2664   shows "arctan x + arctan y = arctan ((x + y) / (1 - x * y))"
  2665 proof -
  2666   obtain y' where "-(pi/4) < y'" and "y' < pi/4" and "tan y' = y" using tan_total_pi4[OF `\<bar>y\<bar> < 1`] by blast
  2667 
  2668   have "pi / 4 < pi / 2" by auto
  2669 
  2670   have "\<exists> x'. -(pi/4) \<le> x' \<and> x' \<le> pi/4 \<and> tan x' = x"
  2671   proof (cases "\<bar>x\<bar> < 1")
  2672     case True from tan_total_pi4[OF this] obtain x' where "-(pi/4) < x'" and "x' < pi/4" and "tan x' = x" by blast
  2673     hence "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by auto
  2674     thus ?thesis by auto
  2675   next
  2676     case False
  2677     show ?thesis
  2678     proof (cases "x = 1")
  2679       case True hence "tan (pi/4) = x" using tan_45 by auto
  2680       moreover 
  2681       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2682       hence "-(pi/4) \<le> pi/4" and "pi/4 \<le> pi/4" by auto
  2683       ultimately show ?thesis by blast
  2684     next
  2685       case False hence "x = -1" using `\<not> \<bar>x\<bar> < 1` and `\<bar>x\<bar> \<le> 1` by auto
  2686       hence "tan (-(pi/4)) = x" using tan_45 tan_minus by auto
  2687       moreover 
  2688       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2689       hence "-(pi/4) \<le> pi/4" and "-(pi/4) \<le> -(pi/4)" by auto
  2690       ultimately show ?thesis by blast
  2691     qed
  2692   qed
  2693   then obtain x' where "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by blast
  2694   hence "-(pi/2) < x'" and "x' < pi/2" using order_le_less_trans[OF `x' \<le> pi/4` `pi / 4 < pi / 2`] by auto
  2695 
  2696   have "cos x' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/2) < x'` and `x' < pi/2` by auto
  2697   moreover have "cos y' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/4) < y'` and `y' < pi/4` by auto
  2698   ultimately have "cos x' * cos y' \<noteq> 0" by auto
  2699 
  2700   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> (A / C) / (B / C) = A / B" by auto
  2701   have divide_mult_commute: "\<And> A B C D :: real. A * B / (C * D) = (A / C) * (B / D)" by auto
  2702 
  2703   have "tan (x' + y') = sin (x' + y') / (cos x' * cos y' - sin x' * sin y')" unfolding tan_def cos_add ..
  2704   also have "\<dots> = (tan x' + tan y') / ((cos x' * cos y' - sin x' * sin y') / (cos x' * cos y'))" unfolding add_tan_eq[OF `cos x' \<noteq> 0` `cos y' \<noteq> 0`] divide_nonzero_divide[OF `cos x' * cos y' \<noteq> 0`] ..
  2705   also have "\<dots> = (tan x' + tan y') / (1 - tan x' * tan y')" unfolding tan_def diff_divide_distrib divide_self[OF `cos x' * cos y' \<noteq> 0`] unfolding divide_mult_commute ..
  2706   finally have tan_eq: "tan (x' + y') = (x + y) / (1 - x * y)" unfolding `tan y' = y` `tan x' = x` .
  2707 
  2708   have "arctan (tan (x' + y')) = x' + y'" using `-(pi/4) < y'` `-(pi/4) \<le> x'` `y' < pi/4` and `x' \<le> pi/4` by (auto intro!: arctan_tan)
  2709   moreover have "arctan (tan (x')) = x'" using `-(pi/2) < x'` and `x' < pi/2` by (auto intro!: arctan_tan)
  2710   moreover have "arctan (tan (y')) = y'" using `-(pi/4) < y'` and `y' < pi/4` by (auto intro!: arctan_tan)
  2711   ultimately have "arctan x + arctan y = arctan (tan (x' + y'))" unfolding `tan y' = y` [symmetric] `tan x' = x`[symmetric] by auto
  2712   thus "arctan x + arctan y = arctan ((x + y) / (1 - x * y))" unfolding tan_eq .
  2713 qed
  2714 
  2715 lemma arctan1_eq_pi4: "arctan 1 = pi / 4" unfolding tan_45[symmetric] by (rule arctan_tan, auto simp add: m2pi_less_pi)
  2716 
  2717 theorem machin: "pi / 4 = 4 * arctan (1/5) - arctan (1 / 239)"
  2718 proof -
  2719   have "\<bar>1 / 5\<bar> < (1 :: real)" by auto
  2720   from arctan_add[OF less_imp_le[OF this] this]
  2721   have "2 * arctan (1 / 5) = arctan (5 / 12)" by auto
  2722   moreover
  2723   have "\<bar>5 / 12\<bar> < (1 :: real)" by auto
  2724   from arctan_add[OF less_imp_le[OF this] this]
  2725   have "2 * arctan (5 / 12) = arctan (120 / 119)" by auto
  2726   moreover 
  2727   have "\<bar>1\<bar> \<le> (1::real)" and "\<bar>1 / 239\<bar> < (1::real)" by auto
  2728   from arctan_add[OF this]
  2729   have "arctan 1 + arctan (1 / 239) = arctan (120 / 119)" by auto
  2730   ultimately have "arctan 1 + arctan (1 / 239) = 4 * arctan (1 / 5)" by auto
  2731   thus ?thesis unfolding arctan1_eq_pi4 by algebra
  2732 qed
  2733 subsection {* Introducing the arcus tangens power series *}
  2734 
  2735 lemma monoseq_arctan_series: fixes x :: real
  2736   assumes "\<bar>x\<bar> \<le> 1" shows "monoseq (\<lambda> n. 1 / real (n*2+1) * x^(n*2+1))" (is "monoseq ?a")
  2737 proof (cases "x = 0") case True thus ?thesis unfolding monoseq_def One_nat_def by auto
  2738 next
  2739   case False
  2740   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2741   show "monoseq ?a"
  2742   proof -
  2743     { fix n fix x :: real assume "0 \<le> x" and "x \<le> 1"
  2744       have "1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<le> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)"
  2745       proof (rule mult_mono)
  2746         show "1 / real (Suc (Suc n * 2)) \<le> 1 / real (Suc (n * 2))" by (rule frac_le) simp_all
  2747         show "0 \<le> 1 / real (Suc (n * 2))" by auto
  2748         show "x ^ Suc (Suc n * 2) \<le> x ^ Suc (n * 2)" by (rule power_decreasing) (simp_all add: `0 \<le> x` `x \<le> 1`)
  2749         show "0 \<le> x ^ Suc (Suc n * 2)" by (rule zero_le_power) (simp add: `0 \<le> x`)
  2750       qed
  2751     } note mono = this
  2752     
  2753     show ?thesis
  2754     proof (cases "0 \<le> x")
  2755       case True from mono[OF this `x \<le> 1`, THEN allI]
  2756       show ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI2)
  2757     next
  2758       case False hence "0 \<le> -x" and "-x \<le> 1" using `-1 \<le> x` by auto
  2759       from mono[OF this]
  2760       have "\<And>n. 1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<ge> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)" using `0 \<le> -x` by auto
  2761       thus ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI1[OF allI])
  2762     qed
  2763   qed
  2764 qed
  2765 
  2766 lemma zeroseq_arctan_series: fixes x :: real
  2767   assumes "\<bar>x\<bar> \<le> 1" shows "(\<lambda> n. 1 / real (n*2+1) * x^(n*2+1)) ----> 0" (is "?a ----> 0")
  2768 proof (cases "x = 0") case True thus ?thesis unfolding One_nat_def by (auto simp add: LIMSEQ_const)
  2769 next
  2770   case False
  2771   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2772   show "?a ----> 0"
  2773   proof (cases "\<bar>x\<bar> < 1")
  2774     case True hence "norm x < 1" by auto
  2775     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat LIMSEQ_power_zero[OF `norm x < 1`, THEN LIMSEQ_Suc]]
  2776     have "(\<lambda>n. 1 / real (n + 1) * x ^ (n + 1)) ----> 0"
  2777       unfolding inverse_eq_divide Suc_eq_plus1 by simp
  2778     then show ?thesis using pos2 by (rule LIMSEQ_linear)
  2779   next
  2780     case False hence "x = -1 \<or> x = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2781     hence n_eq: "\<And> n. x ^ (n * 2 + 1) = x" unfolding One_nat_def by auto
  2782     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat[THEN LIMSEQ_linear, OF pos2, unfolded inverse_eq_divide] LIMSEQ_const[of x]]
  2783     show ?thesis unfolding n_eq Suc_eq_plus1 by auto
  2784   qed
  2785 qed
  2786 
  2787 lemma summable_arctan_series: fixes x :: real and n :: nat
  2788   assumes "\<bar>x\<bar> \<le> 1" shows "summable (\<lambda> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "summable (?c x)")
  2789   by (rule summable_Leibniz(1), rule zeroseq_arctan_series[OF assms], rule monoseq_arctan_series[OF assms])
  2790 
  2791 lemma less_one_imp_sqr_less_one: fixes x :: real assumes "\<bar>x\<bar> < 1" shows "x^2 < 1"
  2792 proof -
  2793   from mult_left_mono[OF less_imp_le[OF `\<bar>x\<bar> < 1`] abs_ge_zero[of x]]
  2794   have "\<bar> x^2 \<bar> < 1" using `\<bar> x \<bar> < 1` unfolding numeral_2_eq_2 power_Suc2 by auto
  2795   thus ?thesis using zero_le_power2 by auto
  2796 qed 
  2797 
  2798 lemma DERIV_arctan_series: assumes "\<bar> x \<bar> < 1"
  2799   shows "DERIV (\<lambda> x'. \<Sum> k. (-1)^k * (1 / real (k*2+1) * x' ^ (k*2+1))) x :> (\<Sum> k. (-1)^k * x^(k*2))" (is "DERIV ?arctan _ :> ?Int")
  2800 proof -
  2801   let "?f n" = "if even n then (-1)^(n div 2) * 1 / real (Suc n) else 0"
  2802 
  2803   { fix n :: nat assume "even n" hence "2 * (n div 2) = n" by presburger } note n_even=this
  2804   have if_eq: "\<And> n x'. ?f n * real (Suc n) * x'^n = (if even n then (-1)^(n div 2) * x'^(2 * (n div 2)) else 0)" using n_even by auto
  2805 
  2806   { fix x :: real assume "\<bar>x\<bar> < 1" hence "x^2 < 1" by (rule less_one_imp_sqr_less_one)
  2807     have "summable (\<lambda> n. -1 ^ n * (x^2) ^n)"
  2808       by (rule summable_Leibniz(1), auto intro!: LIMSEQ_realpow_zero monoseq_realpow `x^2 < 1` order_less_imp_le[OF `x^2 < 1`])
  2809     hence "summable (\<lambda> n. -1 ^ n * x^(2*n))" unfolding power_mult .
  2810   } note summable_Integral = this
  2811 
  2812   { fix f :: "nat \<Rightarrow> real"
  2813     have "\<And> x. f sums x = (\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2814     proof
  2815       fix x :: real assume "f sums x" 
  2816       from sums_if[OF sums_zero this]
  2817       show "(\<lambda> n. if even n then f (n div 2) else 0) sums x" by auto
  2818     next
  2819       fix x :: real assume "(\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2820       from LIMSEQ_linear[OF this[unfolded sums_def] pos2, unfolded sum_split_even_odd[unfolded mult_commute]]
  2821       show "f sums x" unfolding sums_def by auto
  2822     qed
  2823     hence "op sums f = op sums (\<lambda> n. if even n then f (n div 2) else 0)" ..
  2824   } note sums_even = this
  2825 
  2826   have Int_eq: "(\<Sum> n. ?f n * real (Suc n) * x^n) = ?Int" unfolding if_eq mult_commute[of _ 2] suminf_def sums_even[of "\<lambda> n. -1 ^ n * x ^ (2 * n)", symmetric]
  2827     by auto
  2828 
  2829   { fix x :: real
  2830     have if_eq': "\<And> n. (if even n then -1 ^ (n div 2) * 1 / real (Suc n) else 0) * x ^ Suc n = 
  2831       (if even n then -1 ^ (n div 2) * (1 / real (Suc (2 * (n div 2))) * x ^ Suc (2 * (n div 2))) else 0)"
  2832       using n_even by auto
  2833     have idx_eq: "\<And> n. n * 2 + 1 = Suc (2 * n)" by auto 
  2834     have "(\<Sum> n. ?f n * x^(Suc n)) = ?arctan x" unfolding if_eq' idx_eq suminf_def sums_even[of "\<lambda> n. -1 ^ n * (1 / real (Suc (2 * n)) * x ^ Suc (2 * n))", symmetric]
  2835       by auto
  2836   } note arctan_eq = this
  2837 
  2838   have "DERIV (\<lambda> x. \<Sum> n. ?f n * x^(Suc n)) x :> (\<Sum> n. ?f n * real (Suc n) * x^n)"
  2839   proof (rule DERIV_power_series')
  2840     show "x \<in> {- 1 <..< 1}" using `\<bar> x \<bar> < 1` by auto
  2841     { fix x' :: real assume x'_bounds: "x' \<in> {- 1 <..< 1}"
  2842       hence "\<bar>x'\<bar> < 1" by auto
  2843 
  2844       let ?S = "\<Sum> n. (-1)^n * x'^(2 * n)"
  2845       show "summable (\<lambda> n. ?f n * real (Suc n) * x'^n)" unfolding if_eq
  2846         by (rule sums_summable[where l="0 + ?S"], rule sums_if, rule sums_zero, rule summable_sums, rule summable_Integral[OF `\<bar>x'\<bar> < 1`])
  2847     }
  2848   qed auto
  2849   thus ?thesis unfolding Int_eq arctan_eq .
  2850 qed
  2851 
  2852 lemma arctan_series: assumes "\<bar> x \<bar> \<le> 1"
  2853   shows "arctan x = (\<Sum> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "_ = suminf (\<lambda> n. ?c x n)")
  2854 proof -
  2855   let "?c' x n" = "(-1)^n * x^(n*2)"
  2856 
  2857   { fix r x :: real assume "0 < r" and "r < 1" and "\<bar> x \<bar> < r"
  2858     have "\<bar>x\<bar> < 1" using `r < 1` and `\<bar>x\<bar> < r` by auto
  2859     from DERIV_arctan_series[OF this]
  2860     have "DERIV (\<lambda> x. suminf (?c x)) x :> (suminf (?c' x))" .
  2861   } note DERIV_arctan_suminf = this
  2862 
  2863   { fix x :: real assume "\<bar>x\<bar> \<le> 1" note summable_Leibniz[OF zeroseq_arctan_series[OF this] monoseq_arctan_series[OF this]] }
  2864   note arctan_series_borders = this
  2865 
  2866   { fix x :: real assume "\<bar>x\<bar> < 1" have "arctan x = (\<Sum> k. ?c x k)"
  2867   proof -
  2868     obtain r where "\<bar>x\<bar> < r" and "r < 1" using dense[OF `\<bar>x\<bar> < 1`] by blast
  2869     hence "0 < r" and "-r < x" and "x < r" by auto
  2870 
  2871     have suminf_eq_arctan_bounded: "\<And> x a b. \<lbrakk> -r < a ; b < r ; a < b ; a \<le> x ; x \<le> b \<rbrakk> \<Longrightarrow> suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2872     proof -
  2873       fix x a b assume "-r < a" and "b < r" and "a < b" and "a \<le> x" and "x \<le> b"
  2874       hence "\<bar>x\<bar> < r" by auto
  2875       show "suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2876       proof (rule DERIV_isconst2[of "a" "b"])
  2877         show "a < b" and "a \<le> x" and "x \<le> b" using `a < b` `a \<le> x` `x \<le> b` by auto
  2878         have "\<forall> x. -r < x \<and> x < r \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0"
  2879         proof (rule allI, rule impI)
  2880           fix x assume "-r < x \<and> x < r" hence "\<bar>x\<bar> < r" by auto
  2881           hence "\<bar>x\<bar> < 1" using `r < 1` by auto
  2882           have "\<bar> - (x^2) \<bar> < 1" using less_one_imp_sqr_less_one[OF `\<bar>x\<bar> < 1`] by auto
  2883           hence "(\<lambda> n. (- (x^2)) ^ n) sums (1 / (1 - (- (x^2))))" unfolding real_norm_def[symmetric] by (rule geometric_sums)
  2884           hence "(?c' x) sums (1 / (1 - (- (x^2))))" unfolding power_mult_distrib[symmetric] power_mult nat_mult_commute[of _ 2] by auto
  2885           hence suminf_c'_eq_geom: "inverse (1 + x^2) = suminf (?c' x)" using sums_unique unfolding inverse_eq_divide by auto
  2886           have "DERIV (\<lambda> x. suminf (?c x)) x :> (inverse (1 + x^2))" unfolding suminf_c'_eq_geom
  2887             by (rule DERIV_arctan_suminf[OF `0 < r` `r < 1` `\<bar>x\<bar> < r`])
  2888           from DERIV_add_minus[OF this DERIV_arctan]
  2889           show "DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0" unfolding diff_minus by auto
  2890         qed
  2891         hence DERIV_in_rball: "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `-r < a` `b < r` by auto
  2892         thus "\<forall> y. a < y \<and> y < b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `\<bar>x\<bar> < r` by auto
  2893         show "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> isCont (\<lambda> x. suminf (?c x) - arctan x) y" using DERIV_in_rball DERIV_isCont by auto
  2894       qed
  2895     qed
  2896     
  2897     have suminf_arctan_zero: "suminf (?c 0) - arctan 0 = 0"
  2898       unfolding Suc_eq_plus1[symmetric] power_Suc2 mult_zero_right arctan_zero_zero suminf_zero by auto
  2899     
  2900     have "suminf (?c x) - arctan x = 0"
  2901     proof (cases "x = 0")
  2902       case True thus ?thesis using suminf_arctan_zero by auto
  2903     next
  2904       case False hence "0 < \<bar>x\<bar>" and "- \<bar>x\<bar> < \<bar>x\<bar>" by auto
  2905       have "suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>) = suminf (?c 0) - arctan 0"
  2906         by (rule suminf_eq_arctan_bounded[where x="0" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>", symmetric])
  2907           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2908       moreover
  2909       have "suminf (?c x) - arctan x = suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>)"
  2910         by (rule suminf_eq_arctan_bounded[where x="x" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>"])
  2911           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2912       ultimately 
  2913       show ?thesis using suminf_arctan_zero by auto
  2914     qed
  2915     thus ?thesis by auto
  2916   qed } note when_less_one = this
  2917 
  2918   show "arctan x = suminf (\<lambda> n. ?c x n)"
  2919   proof (cases "\<bar>x\<bar> < 1")
  2920     case True thus ?thesis by (rule when_less_one)
  2921   next case False hence "\<bar>x\<bar> = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2922     let "?a x n" = "\<bar>1 / real (n*2+1) * x^(n*2+1)\<bar>"
  2923     let "?diff x n" = "\<bar> arctan x - (\<Sum> i = 0..<n. ?c x i)\<bar>"
  2924     { fix n :: nat
  2925       have "0 < (1 :: real)" by auto
  2926       moreover
  2927       { fix x :: real assume "0 < x" and "x < 1" hence "\<bar>x\<bar> \<le> 1" and "\<bar>x\<bar> < 1" by auto
  2928         from `0 < x` have "0 < 1 / real (0 * 2 + (1::nat)) * x ^ (0 * 2 + 1)" by auto
  2929         note bounds = mp[OF arctan_series_borders(2)[OF `\<bar>x\<bar> \<le> 1`] this, unfolded when_less_one[OF `\<bar>x\<bar> < 1`, symmetric], THEN spec]
  2930         have "0 < 1 / real (n*2+1) * x^(n*2+1)" by (rule mult_pos_pos, auto simp only: zero_less_power[OF `0 < x`], auto)
  2931         hence a_pos: "?a x n = 1 / real (n*2+1) * x^(n*2+1)" by (rule abs_of_pos)
  2932         have "?diff x n \<le> ?a x n"
  2933         proof (cases "even n")
  2934           case True hence sgn_pos: "(-1)^n = (1::real)" by auto
  2935           from `even n` obtain m where "2 * m = n" unfolding even_mult_two_ex by auto
  2936           from bounds[of m, unfolded this atLeastAtMost_iff]
  2937           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n + 1. (?c x i)) - (\<Sum>i = 0..<n. (?c x i))" by auto
  2938           also have "\<dots> = ?c x n" unfolding One_nat_def by auto
  2939           also have "\<dots> = ?a x n" unfolding sgn_pos a_pos by auto
  2940           finally show ?thesis .
  2941         next
  2942           case False hence sgn_neg: "(-1)^n = (-1::real)" by auto
  2943           from `odd n` obtain m where m_def: "2 * m + 1 = n" unfolding odd_Suc_mult_two_ex by auto
  2944           hence m_plus: "2 * (m + 1) = n + 1" by auto
  2945           from bounds[of "m + 1", unfolded this atLeastAtMost_iff, THEN conjunct1] bounds[of m, unfolded m_def atLeastAtMost_iff, THEN conjunct2]
  2946           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n. (?c x i)) - (\<Sum>i = 0..<n+1. (?c x i))" by auto
  2947           also have "\<dots> = - ?c x n" unfolding One_nat_def by auto
  2948           also have "\<dots> = ?a x n" unfolding sgn_neg a_pos by auto
  2949           finally show ?thesis .
  2950         qed
  2951         hence "0 \<le> ?a x n - ?diff x n" by auto
  2952       }
  2953       hence "\<forall> x \<in> { 0 <..< 1 }. 0 \<le> ?a x n - ?diff x n" by auto
  2954       moreover have "\<And>x. isCont (\<lambda> x. ?a x n - ?diff x n) x"
  2955         unfolding diff_minus divide_inverse
  2956         by (auto intro!: isCont_add isCont_rabs isCont_ident isCont_minus isCont_arctan isCont_inverse isCont_mult isCont_power isCont_const isCont_setsum)
  2957       ultimately have "0 \<le> ?a 1 n - ?diff 1 n" by (rule LIM_less_bound)
  2958       hence "?diff 1 n \<le> ?a 1 n" by auto
  2959     }
  2960     have "?a 1 ----> 0"
  2961       unfolding LIMSEQ_rabs_zero power_one divide_inverse One_nat_def
  2962       by (auto intro!: LIMSEQ_mult LIMSEQ_linear LIMSEQ_inverse_real_of_nat)
  2963     have "?diff 1 ----> 0"
  2964     proof (rule LIMSEQ_I)
  2965       fix r :: real assume "0 < r"
  2966       obtain N :: nat where N_I: "\<And> n. N \<le> n \<Longrightarrow> ?a 1 n < r" using LIMSEQ_D[OF `?a 1 ----> 0` `0 < r`] by auto
  2967       { fix n assume "N \<le> n" from `?diff 1 n \<le> ?a 1 n` N_I[OF this]
  2968         have "norm (?diff 1 n - 0) < r" by auto }
  2969       thus "\<exists> N. \<forall> n \<ge> N. norm (?diff 1 n - 0) < r" by blast
  2970     qed
  2971     from this[unfolded LIMSEQ_rabs_zero diff_minus add_commute[of "arctan 1"], THEN LIMSEQ_add_const, of "- arctan 1", THEN LIMSEQ_minus]
  2972     have "(?c 1) sums (arctan 1)" unfolding sums_def by auto
  2973     hence "arctan 1 = (\<Sum> i. ?c 1 i)" by (rule sums_unique)
  2974     
  2975     show ?thesis
  2976     proof (cases "x = 1", simp add: `arctan 1 = (\<Sum> i. ?c 1 i)`)
  2977       assume "x \<noteq> 1" hence "x = -1" using `\<bar>x\<bar> = 1` by auto
  2978       
  2979       have "- (pi / 2) < 0" using pi_gt_zero by auto
  2980       have "- (2 * pi) < 0" using pi_gt_zero by auto
  2981       
  2982       have c_minus_minus: "\<And> i. ?c (- 1) i = - ?c 1 i" unfolding One_nat_def by auto
  2983     
  2984       have "arctan (- 1) = arctan (tan (-(pi / 4)))" unfolding tan_45 tan_minus ..
  2985       also have "\<dots> = - (pi / 4)" by (rule arctan_tan, auto simp add: order_less_trans[OF `- (pi / 2) < 0` pi_gt_zero])
  2986       also have "\<dots> = - (arctan (tan (pi / 4)))" unfolding neg_equal_iff_equal by (rule arctan_tan[symmetric], auto simp add: order_less_trans[OF `- (2 * pi) < 0` pi_gt_zero])
  2987       also have "\<dots> = - (arctan 1)" unfolding tan_45 ..
  2988       also have "\<dots> = - (\<Sum> i. ?c 1 i)" using `arctan 1 = (\<Sum> i. ?c 1 i)` by auto
  2989       also have "\<dots> = (\<Sum> i. ?c (- 1) i)" using suminf_minus[OF sums_summable[OF `(?c 1) sums (arctan 1)`]] unfolding c_minus_minus by auto
  2990       finally show ?thesis using `x = -1` by auto
  2991     qed
  2992   qed
  2993 qed
  2994 
  2995 lemma arctan_half: fixes x :: real
  2996   shows "arctan x = 2 * arctan (x / (1 + sqrt(1 + x^2)))"
  2997 proof -
  2998   obtain y where low: "- (pi / 2) < y" and high: "y < pi / 2" and y_eq: "tan y = x" using tan_total by blast
  2999   hence low2: "- (pi / 2) < y / 2" and high2: "y / 2 < pi / 2" by auto
  3000 
  3001   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> A / B = (A / C) / (B / C)" by auto
  3002   
  3003   have "0 < cos y" using cos_gt_zero_pi[OF low high] .
  3004   hence "cos y \<noteq> 0" and cos_sqrt: "sqrt ((cos y) ^ 2) = cos y" by auto
  3005 
  3006   have "1 + (tan y)^2 = 1 + sin y^2 / cos y^2" unfolding tan_def power_divide ..
  3007   also have "\<dots> = cos y^2 / cos y^2 + sin y^2 / cos y^2" using `cos y \<noteq> 0` by auto
  3008   also have "\<dots> = 1 / cos y^2" unfolding add_divide_distrib[symmetric] sin_cos_squared_add2 ..
  3009   finally have "1 + (tan y)^2 = 1 / cos y^2" .
  3010 
  3011   have "sin y / (cos y + 1) = tan y / ((cos y + 1) / cos y)" unfolding tan_def divide_nonzero_divide[OF `cos y \<noteq> 0`, symmetric] ..
  3012   also have "\<dots> = tan y / (1 + 1 / cos y)" using `cos y \<noteq> 0` unfolding add_divide_distrib by auto
  3013   also have "\<dots> = tan y / (1 + 1 / sqrt(cos y^2))" unfolding cos_sqrt ..
  3014   also have "\<dots> = tan y / (1 + sqrt(1 / cos y^2))" unfolding real_sqrt_divide by auto
  3015   finally have eq: "sin y / (cos y + 1) = tan y / (1 + sqrt(1 + (tan y)^2))" unfolding `1 + (tan y)^2 = 1 / cos y^2` .
  3016 
  3017   have "arctan x = y" using arctan_tan low high y_eq by auto
  3018   also have "\<dots> = 2 * (arctan (tan (y/2)))" using arctan_tan[OF low2 high2] by auto
  3019   also have "\<dots> = 2 * (arctan (sin y / (cos y + 1)))" unfolding tan_half[OF low2 high2] by auto
  3020   finally show ?thesis unfolding eq `tan y = x` .
  3021 qed
  3022 
  3023 lemma arctan_monotone: assumes "x < y"
  3024   shows "arctan x < arctan y"
  3025 proof -
  3026   obtain z where "-(pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  3027   obtain w where "-(pi / 2) < w" and "w < pi / 2" and "tan w = y" using tan_total by blast
  3028   have "z < w" unfolding tan_monotone'[OF `-(pi / 2) < z` `z < pi / 2` `-(pi / 2) < w` `w < pi / 2`] `tan z = x` `tan w = y` using `x < y` .
  3029   thus ?thesis
  3030     unfolding `tan z = x`[symmetric] arctan_tan[OF `-(pi / 2) < z` `z < pi / 2`]
  3031     unfolding `tan w = y`[symmetric] arctan_tan[OF `-(pi / 2) < w` `w < pi / 2`] .
  3032 qed
  3033 
  3034 lemma arctan_monotone': assumes "x \<le> y" shows "arctan x \<le> arctan y"
  3035 proof (cases "x = y") 
  3036   case False hence "x < y" using `x \<le> y` by auto from arctan_monotone[OF this] show ?thesis by auto
  3037 qed auto
  3038 
  3039 lemma arctan_minus: "arctan (- x) = - arctan x" 
  3040 proof -
  3041   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  3042   thus ?thesis unfolding `tan y = x`[symmetric] tan_minus[symmetric] using arctan_tan[of y] arctan_tan[of "-y"] by auto 
  3043 qed
  3044 
  3045 lemma arctan_inverse: assumes "x \<noteq> 0" shows "arctan (1 / x) = sgn x * pi / 2 - arctan x"
  3046 proof -
  3047   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  3048   hence "y = arctan x" unfolding `tan y = x`[symmetric] using arctan_tan by auto
  3049 
  3050   { fix y x :: real assume "0 < y" and "y < pi /2" and "y = arctan x" and "tan y = x" hence "- (pi / 2) < y" by auto
  3051     have "tan y > 0" using tan_monotone'[OF _ _ `- (pi / 2) < y` `y < pi / 2`, of 0] tan_zero `0 < y` by auto
  3052     hence "x > 0" using `tan y = x` by auto
  3053 
  3054     have "- (pi / 2) < pi / 2 - y" using `y > 0` `y < pi / 2` by auto
  3055     moreover have "pi / 2 - y < pi / 2" using `y > 0` `y < pi / 2` by auto
  3056     ultimately have "arctan (1 / x) = pi / 2 - y" unfolding `tan y = x`[symmetric] tan_inverse using arctan_tan by auto
  3057     hence "arctan (1 / x) = sgn x * pi / 2 - arctan x" unfolding `y = arctan x` real_sgn_pos[OF `x > 0`] by auto
  3058   } note pos_y = this
  3059 
  3060   show ?thesis
  3061   proof (cases "y > 0")
  3062     case True from pos_y[OF this `y < pi / 2` `y = arctan x` `tan y = x`] show ?thesis .
  3063   next
  3064     case False hence "y \<le> 0" by auto
  3065     moreover have "y \<noteq> 0" 
  3066     proof (rule ccontr)
  3067       assume "\<not> y \<noteq> 0" hence "y = 0" by auto
  3068       have "x = 0" unfolding `tan y = x`[symmetric] `y = 0` tan_zero ..
  3069       thus False using `x \<noteq> 0` by auto
  3070     qed
  3071     ultimately have "y < 0" by auto
  3072     hence "0 < - y" and "-y < pi / 2" using `- (pi / 2) < y` by auto
  3073     moreover have "-y = arctan (-x)" unfolding arctan_minus `y = arctan x` ..
  3074     moreover have "tan (-y) = -x" unfolding tan_minus `tan y = x` ..
  3075     ultimately have "arctan (1 / -x) = sgn (-x) * pi / 2 - arctan (-x)" using pos_y by blast
  3076     hence "arctan (- (1 / x)) = - (sgn x * pi / 2 - arctan x)" unfolding arctan_minus[of x] divide_minus_right sgn_minus by auto
  3077     thus ?thesis unfolding arctan_minus neg_equal_iff_equal .
  3078   qed
  3079 qed
  3080 
  3081 theorem pi_series: "pi / 4 = (\<Sum> k. (-1)^k * 1 / real (k*2+1))" (is "_ = ?SUM")
  3082 proof -
  3083   have "pi / 4 = arctan 1" using arctan1_eq_pi4 by auto
  3084   also have "\<dots> = ?SUM" using arctan_series[of 1] by auto
  3085   finally show ?thesis by auto
  3086 qed
  3087 
  3088 subsection {* Existence of Polar Coordinates *}
  3089 
  3090 lemma cos_x_y_le_one: "\<bar>x / sqrt (x\<twosuperior> + y\<twosuperior>)\<bar> \<le> 1"
  3091 apply (rule power2_le_imp_le [OF _ zero_le_one])
  3092 apply (simp add: power_divide divide_le_eq not_sum_power2_lt_zero)
  3093 done
  3094 
  3095 lemma cos_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> cos (arccos y) = y"
  3096 by (simp add: abs_le_iff)
  3097 
  3098 lemma sin_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> sin (arccos y) = sqrt (1 - y\<twosuperior>)"
  3099 by (simp add: sin_arccos abs_le_iff)
  3100 
  3101 lemmas cos_arccos_lemma1 = cos_arccos_abs [OF cos_x_y_le_one]
  3102 
  3103 lemmas sin_arccos_lemma1 = sin_arccos_abs [OF cos_x_y_le_one]
  3104 
  3105 lemma polar_ex1:
  3106      "0 < y ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3107 apply (rule_tac x = "sqrt (x\<twosuperior> + y\<twosuperior>)" in exI)
  3108 apply (rule_tac x = "arccos (x / sqrt (x\<twosuperior> + y\<twosuperior>))" in exI)
  3109 apply (simp add: cos_arccos_lemma1)
  3110 apply (simp add: sin_arccos_lemma1)
  3111 apply (simp add: power_divide)
  3112 apply (simp add: real_sqrt_mult [symmetric])
  3113 apply (simp add: right_diff_distrib)
  3114 done
  3115 
  3116 lemma polar_ex2:
  3117      "y < 0 ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3118 apply (insert polar_ex1 [where x=x and y="-y"], simp, clarify)
  3119 apply (metis cos_minus minus_minus minus_mult_right sin_minus)
  3120 done
  3121 
  3122 lemma polar_Ex: "\<exists>r a. x = r * cos a & y = r * sin a"
  3123 apply (rule_tac x=0 and y=y in linorder_cases)
  3124 apply (erule polar_ex1)
  3125 apply (rule_tac x=x in exI, rule_tac x=0 in exI, simp)
  3126 apply (erule polar_ex2)
  3127 done
  3128 
  3129 end