src/HOL/Tools/Nitpick/nitpick_mono.ML
author blanchet
Tue Dec 07 11:56:01 2010 +0100 (2010-12-07)
changeset 41050 effbaa323cf0
parent 41049 0edd245892ed
child 41052 3db267a01c1d
permissions -rw-r--r--
updated monotonicity calculus w.r.t. set products
     1 (*  Title:      HOL/Tools/Nitpick/nitpick_mono.ML
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2009, 2010
     4 
     5 Monotonicity inference for higher-order logic.
     6 *)
     7 
     8 signature NITPICK_MONO =
     9 sig
    10   type hol_context = Nitpick_HOL.hol_context
    11 
    12   val trace : bool Unsynchronized.ref
    13   val formulas_monotonic :
    14     hol_context -> bool -> typ -> term list * term list -> bool
    15   val finitize_funs :
    16     hol_context -> bool -> (typ option * bool option) list -> typ
    17     -> term list * term list -> term list * term list
    18 end;
    19 
    20 structure Nitpick_Mono : NITPICK_MONO =
    21 struct
    22 
    23 open Nitpick_Util
    24 open Nitpick_HOL
    25 
    26 structure PL = PropLogic
    27 
    28 datatype sign = Plus | Minus
    29 
    30 type var = int
    31 
    32 datatype annotation = Gen | New | Fls | Tru
    33 datatype annotation_atom = A of annotation | V of var
    34 
    35 type assign_literal = var * (sign * annotation)
    36 
    37 datatype mtyp =
    38   MAlpha |
    39   MFun of mtyp * annotation_atom * mtyp |
    40   MPair of mtyp * mtyp |
    41   MType of string * mtyp list |
    42   MRec of string * typ list
    43 
    44 datatype mterm =
    45   MRaw of term * mtyp |
    46   MAbs of string * typ * mtyp * annotation_atom * mterm |
    47   MApp of mterm * mterm
    48 
    49 type mdata =
    50   {hol_ctxt: hol_context,
    51    binarize: bool,
    52    alpha_T: typ,
    53    no_harmless: bool,
    54    max_fresh: int Unsynchronized.ref,
    55    datatype_mcache: ((string * typ list) * mtyp) list Unsynchronized.ref,
    56    constr_mcache: (styp * mtyp) list Unsynchronized.ref}
    57 
    58 exception UNSOLVABLE of unit
    59 exception MTYPE of string * mtyp list * typ list
    60 exception MTERM of string * mterm list
    61 
    62 val trace = Unsynchronized.ref false
    63 fun trace_msg msg = if !trace then tracing (msg ()) else ()
    64 
    65 fun string_for_sign Plus = "+"
    66   | string_for_sign Minus = "-"
    67 
    68 fun negate_sign Plus = Minus
    69   | negate_sign Minus = Plus
    70 
    71 val string_for_var = signed_string_of_int
    72 fun string_for_vars sep [] = "0\<^bsub>" ^ sep ^ "\<^esub>"
    73   | string_for_vars sep xs = space_implode sep (map string_for_var xs)
    74 fun subscript_string_for_vars sep xs =
    75   if null xs then "" else "\<^bsub>" ^ string_for_vars sep xs ^ "\<^esub>"
    76 
    77 fun string_for_annotation Gen = "G"
    78   | string_for_annotation New = "N"
    79   | string_for_annotation Fls = "F"
    80   | string_for_annotation Tru = "T"
    81 
    82 fun string_for_annotation_atom (A a) = string_for_annotation a
    83   | string_for_annotation_atom (V x) = string_for_var x
    84 
    85 fun string_for_assign_literal (x, (sn, a)) =
    86   string_for_var x ^ (case sn of Plus => " = " | Minus => " \<noteq> ") ^
    87   string_for_annotation a
    88 
    89 val bool_M = MType (@{type_name bool}, [])
    90 val dummy_M = MType (nitpick_prefix ^ "dummy", [])
    91 
    92 fun is_MRec (MRec _) = true
    93   | is_MRec _ = false
    94 fun dest_MFun (MFun z) = z
    95   | dest_MFun M = raise MTYPE ("Nitpick_Mono.dest_MFun", [M], [])
    96 
    97 val no_prec = 100
    98 
    99 fun precedence_of_mtype (MFun _) = 1
   100   | precedence_of_mtype (MPair _) = 2
   101   | precedence_of_mtype _ = no_prec
   102 
   103 val string_for_mtype =
   104   let
   105     fun aux outer_prec M =
   106       let
   107         val prec = precedence_of_mtype M
   108         val need_parens = (prec < outer_prec)
   109       in
   110         (if need_parens then "(" else "") ^
   111         (if M = dummy_M then
   112            "_"
   113          else case M of
   114              MAlpha => "\<alpha>"
   115            | MFun (M1, aa, M2) =>
   116              aux (prec + 1) M1 ^ " \<Rightarrow>\<^bsup>" ^
   117              string_for_annotation_atom aa ^ "\<^esup> " ^ aux prec M2
   118            | MPair (M1, M2) => aux (prec + 1) M1 ^ " \<times> " ^ aux prec M2
   119            | MType (s, []) =>
   120              if s = @{type_name prop} orelse s = @{type_name bool} then "o"
   121              else s
   122            | MType (s, Ms) => "(" ^ commas (map (aux 0) Ms) ^ ") " ^ s
   123            | MRec (s, _) => "[" ^ s ^ "]") ^
   124         (if need_parens then ")" else "")
   125       end
   126   in aux 0 end
   127 
   128 fun flatten_mtype (MPair (M1, M2)) = maps flatten_mtype [M1, M2]
   129   | flatten_mtype (MType (_, Ms)) = maps flatten_mtype Ms
   130   | flatten_mtype M = [M]
   131 
   132 fun precedence_of_mterm (MRaw _) = no_prec
   133   | precedence_of_mterm (MAbs _) = 1
   134   | precedence_of_mterm (MApp _) = 2
   135 
   136 fun string_for_mterm ctxt =
   137   let
   138     fun mtype_annotation M = "\<^bsup>" ^ string_for_mtype M ^ "\<^esup>"
   139     fun aux outer_prec m =
   140       let
   141         val prec = precedence_of_mterm m
   142         val need_parens = (prec < outer_prec)
   143       in
   144         (if need_parens then "(" else "") ^
   145         (case m of
   146            MRaw (t, M) => Syntax.string_of_term ctxt t ^ mtype_annotation M
   147          | MAbs (s, _, M, aa, m) =>
   148            "\<lambda>" ^ s ^ mtype_annotation M ^ ".\<^bsup>" ^
   149            string_for_annotation_atom aa ^ "\<^esup> " ^ aux prec m
   150          | MApp (m1, m2) => aux prec m1 ^ " " ^ aux (prec + 1) m2) ^
   151         (if need_parens then ")" else "")
   152       end
   153   in aux 0 end
   154 
   155 fun mtype_of_mterm (MRaw (_, M)) = M
   156   | mtype_of_mterm (MAbs (_, _, M, aa, m)) = MFun (M, aa, mtype_of_mterm m)
   157   | mtype_of_mterm (MApp (m1, _)) =
   158     case mtype_of_mterm m1 of
   159       MFun (_, _, M12) => M12
   160     | M1 => raise MTYPE ("Nitpick_Mono.mtype_of_mterm", [M1], [])
   161 
   162 fun strip_mcomb (MApp (m1, m2)) = strip_mcomb m1 ||> (fn ms => append ms [m2])
   163   | strip_mcomb m = (m, [])
   164 
   165 fun initial_mdata hol_ctxt binarize no_harmless alpha_T =
   166   ({hol_ctxt = hol_ctxt, binarize = binarize, alpha_T = alpha_T,
   167     no_harmless = no_harmless, max_fresh = Unsynchronized.ref 0,
   168     datatype_mcache = Unsynchronized.ref [],
   169     constr_mcache = Unsynchronized.ref []} : mdata)
   170 
   171 fun could_exist_alpha_subtype alpha_T (T as Type (_, Ts)) =
   172     T = alpha_T orelse (not (is_fp_iterator_type T) andalso
   173                         exists (could_exist_alpha_subtype alpha_T) Ts)
   174   | could_exist_alpha_subtype alpha_T T = (T = alpha_T)
   175 fun could_exist_alpha_sub_mtype _ (alpha_T as TFree _) T =
   176     could_exist_alpha_subtype alpha_T T
   177   | could_exist_alpha_sub_mtype ctxt alpha_T T =
   178     (T = alpha_T orelse is_datatype ctxt [(NONE, true)] T)
   179 
   180 fun exists_alpha_sub_mtype MAlpha = true
   181   | exists_alpha_sub_mtype (MFun (M1, _, M2)) =
   182     exists exists_alpha_sub_mtype [M1, M2]
   183   | exists_alpha_sub_mtype (MPair (M1, M2)) =
   184     exists exists_alpha_sub_mtype [M1, M2]
   185   | exists_alpha_sub_mtype (MType (_, Ms)) = exists exists_alpha_sub_mtype Ms
   186   | exists_alpha_sub_mtype (MRec _) = true
   187 
   188 fun exists_alpha_sub_mtype_fresh MAlpha = true
   189   | exists_alpha_sub_mtype_fresh (MFun (_, V _, _)) = true
   190   | exists_alpha_sub_mtype_fresh (MFun (_, _, M2)) =
   191     exists_alpha_sub_mtype_fresh M2
   192   | exists_alpha_sub_mtype_fresh (MPair (M1, M2)) =
   193     exists exists_alpha_sub_mtype_fresh [M1, M2]
   194   | exists_alpha_sub_mtype_fresh (MType (_, Ms)) =
   195     exists exists_alpha_sub_mtype_fresh Ms
   196   | exists_alpha_sub_mtype_fresh (MRec _) = true
   197 
   198 fun constr_mtype_for_binders z Ms =
   199   fold_rev (fn M => curry3 MFun M (A Gen)) Ms (MRec z)
   200 
   201 fun repair_mtype _ _ MAlpha = MAlpha
   202   | repair_mtype cache seen (MFun (M1, aa, M2)) =
   203     MFun (repair_mtype cache seen M1, aa, repair_mtype cache seen M2)
   204   | repair_mtype cache seen (MPair Mp) =
   205     MPair (pairself (repair_mtype cache seen) Mp)
   206   | repair_mtype cache seen (MType (s, Ms)) =
   207     MType (s, maps (flatten_mtype o repair_mtype cache seen) Ms)
   208   | repair_mtype cache seen (MRec (z as (s, _))) =
   209     case AList.lookup (op =) cache z |> the of
   210       MRec _ => MType (s, [])
   211     | M => if member (op =) seen M then MType (s, [])
   212            else repair_mtype cache (M :: seen) M
   213 
   214 fun repair_datatype_mcache cache =
   215   let
   216     fun repair_one (z, M) =
   217       Unsynchronized.change cache
   218           (AList.update (op =) (z, repair_mtype (!cache) [] M))
   219   in List.app repair_one (rev (!cache)) end
   220 
   221 fun repair_constr_mcache dtype_cache constr_mcache =
   222   let
   223     fun repair_one (x, M) =
   224       Unsynchronized.change constr_mcache
   225           (AList.update (op =) (x, repair_mtype dtype_cache [] M))
   226   in List.app repair_one (!constr_mcache) end
   227 
   228 fun is_fin_fun_supported_type @{typ prop} = true
   229   | is_fin_fun_supported_type @{typ bool} = true
   230   | is_fin_fun_supported_type (Type (@{type_name option}, _)) = true
   231   | is_fin_fun_supported_type _ = false
   232 
   233 (* TODO: clean this up *)
   234 fun fin_fun_body _ _ (t as @{term False}) = SOME t
   235   | fin_fun_body _ _ (t as Const (@{const_name None}, _)) = SOME t
   236   | fin_fun_body dom_T ran_T
   237                  ((t0 as Const (@{const_name If}, _))
   238                   $ (t1 as Const (@{const_name HOL.eq}, _) $ Bound 0 $ t1')
   239                   $ t2 $ t3) =
   240     (if loose_bvar1 (t1', 0) then
   241        NONE
   242      else case fin_fun_body dom_T ran_T t3 of
   243        NONE => NONE
   244      | SOME t3 =>
   245        SOME (t0 $ (Const (@{const_name is_unknown}, dom_T --> bool_T) $ t1')
   246                 $ (Const (@{const_name unknown}, ran_T)) $ (t0 $ t1 $ t2 $ t3)))
   247   | fin_fun_body _ _ _ = NONE
   248 
   249 (* ### FIXME: make sure well-annotated! *)
   250 
   251 fun fresh_mfun_for_fun_type (mdata as {max_fresh, ...} : mdata) all_minus
   252                             T1 T2 =
   253   let
   254     val M1 = fresh_mtype_for_type mdata all_minus T1
   255     val M2 = fresh_mtype_for_type mdata all_minus T2
   256     val aa = if not all_minus andalso exists_alpha_sub_mtype_fresh M1 andalso
   257                 is_fin_fun_supported_type (body_type T2) then
   258                V (Unsynchronized.inc max_fresh)
   259              else
   260                A Gen
   261   in (M1, aa, M2) end
   262 and fresh_mtype_for_type (mdata as {hol_ctxt as {ctxt, ...}, binarize, alpha_T,
   263                                     datatype_mcache, constr_mcache, ...})
   264                          all_minus =
   265   let
   266     fun do_type T =
   267       if T = alpha_T then
   268         MAlpha
   269       else case T of
   270         Type (@{type_name fun}, [T1, T2]) =>
   271         MFun (fresh_mfun_for_fun_type mdata all_minus T1 T2)
   272       | Type (@{type_name prod}, [T1, T2]) => MPair (pairself do_type (T1, T2))
   273       | Type (z as (s, _)) =>
   274         if could_exist_alpha_sub_mtype ctxt alpha_T T then
   275           case AList.lookup (op =) (!datatype_mcache) z of
   276             SOME M => M
   277           | NONE =>
   278             let
   279               val _ = Unsynchronized.change datatype_mcache (cons (z, MRec z))
   280               val xs = binarized_and_boxed_datatype_constrs hol_ctxt binarize T
   281               val (all_Ms, constr_Ms) =
   282                 fold_rev (fn (_, T') => fn (all_Ms, constr_Ms) =>
   283                              let
   284                                val binder_Ms = map do_type (binder_types T')
   285                                val new_Ms = filter exists_alpha_sub_mtype_fresh
   286                                                    binder_Ms
   287                                val constr_M = constr_mtype_for_binders z
   288                                                                        binder_Ms
   289                              in
   290                                (union (op =) new_Ms all_Ms,
   291                                 constr_M :: constr_Ms)
   292                              end)
   293                          xs ([], [])
   294               val M = MType (s, all_Ms)
   295               val _ = Unsynchronized.change datatype_mcache
   296                           (AList.update (op =) (z, M))
   297               val _ = Unsynchronized.change constr_mcache
   298                           (append (xs ~~ constr_Ms))
   299             in
   300               if forall (not o is_MRec o snd) (!datatype_mcache) then
   301                 (repair_datatype_mcache datatype_mcache;
   302                  repair_constr_mcache (!datatype_mcache) constr_mcache;
   303                  AList.lookup (op =) (!datatype_mcache) z |> the)
   304               else
   305                 M
   306             end
   307         else
   308           MType (s, [])
   309       | _ => MType (simple_string_of_typ T, [])
   310   in do_type end
   311 
   312 val ground_and_sole_base_constrs = [] (* FIXME: [@{const_name Nil}, @{const_name None}], cf. lists_empty *)
   313 
   314 fun prodM_factors (MPair (M1, M2)) = maps prodM_factors [M1, M2]
   315   | prodM_factors M = [M]
   316 fun curried_strip_mtype (MFun (M1, _, M2)) =
   317     curried_strip_mtype M2 |>> append (prodM_factors M1)
   318   | curried_strip_mtype M = ([], M)
   319 fun sel_mtype_from_constr_mtype s M =
   320   let
   321     val (arg_Ms, dataM) = curried_strip_mtype M
   322     val a = if member (op =) ground_and_sole_base_constrs
   323                              (constr_name_for_sel_like s) then
   324               Fls
   325             else
   326               Gen
   327   in
   328     MFun (dataM, A a,
   329           case sel_no_from_name s of ~1 => bool_M | n => nth arg_Ms n)
   330   end
   331 
   332 fun mtype_for_constr (mdata as {hol_ctxt = {ctxt, ...}, alpha_T, constr_mcache,
   333                                 ...}) (x as (_, T)) =
   334   if could_exist_alpha_sub_mtype ctxt alpha_T T then
   335     case AList.lookup (op =) (!constr_mcache) x of
   336       SOME M => M
   337     | NONE => if T = alpha_T then
   338                 let val M = fresh_mtype_for_type mdata false T in
   339                   (Unsynchronized.change constr_mcache (cons (x, M)); M)
   340                 end
   341               else
   342                 (fresh_mtype_for_type mdata false (body_type T);
   343                  AList.lookup (op =) (!constr_mcache) x |> the)
   344   else
   345     fresh_mtype_for_type mdata false T
   346 fun mtype_for_sel (mdata as {hol_ctxt, binarize, ...}) (x as (s, _)) =
   347   x |> binarized_and_boxed_constr_for_sel hol_ctxt binarize
   348     |> mtype_for_constr mdata |> sel_mtype_from_constr_mtype s
   349 
   350 fun resolve_annotation_atom asgs (V x) =
   351     x |> AList.lookup (op =) asgs |> Option.map A |> the_default (V x)
   352   | resolve_annotation_atom _ aa = aa
   353 fun resolve_mtype asgs =
   354   let
   355     fun aux MAlpha = MAlpha
   356       | aux (MFun (M1, aa, M2)) =
   357         MFun (aux M1, resolve_annotation_atom asgs aa, aux M2)
   358       | aux (MPair Mp) = MPair (pairself aux Mp)
   359       | aux (MType (s, Ms)) = MType (s, map aux Ms)
   360       | aux (MRec z) = MRec z
   361   in aux end
   362 
   363 datatype comp_op = Eq | Neq | Leq
   364 
   365 type comp = annotation_atom * annotation_atom * comp_op * var list
   366 type assign_clause = assign_literal list
   367 
   368 type constraint_set = comp list * assign_clause list
   369 
   370 fun string_for_comp_op Eq = "="
   371   | string_for_comp_op Neq = "\<noteq>"
   372   | string_for_comp_op Leq = "\<le>"
   373 
   374 fun string_for_comp (aa1, aa2, cmp, xs) =
   375   string_for_annotation_atom aa1 ^ " " ^ string_for_comp_op cmp ^
   376   subscript_string_for_vars " \<and> " xs ^ " " ^ string_for_annotation_atom aa2
   377 
   378 fun string_for_assign_clause NONE = "\<top>"
   379   | string_for_assign_clause (SOME []) = "\<bot>"
   380   | string_for_assign_clause (SOME asgs) =
   381     space_implode " \<or> " (map string_for_assign_literal asgs)
   382 
   383 fun add_assign_literal (x, (sn, a)) clauses =
   384   if exists (fn [(x', (sn', a'))] =>
   385                 x = x' andalso ((sn = sn' andalso a <> a') orelse
   386                                 (sn <> sn' andalso a = a'))
   387               | _ => false) clauses then
   388     NONE
   389   else
   390     SOME ([(x, (sn, a))] :: clauses)
   391 
   392 fun add_assign_disjunct _ NONE = NONE
   393   | add_assign_disjunct asg (SOME asgs) = SOME (insert (op =) asg asgs)
   394 
   395 fun add_assign_clause NONE = I
   396   | add_assign_clause (SOME clause) = insert (op =) clause
   397 
   398 fun annotation_comp Eq a1 a2 = (a1 = a2)
   399   | annotation_comp Neq a1 a2 = (a1 <> a2)
   400   | annotation_comp Leq a1 a2 = (a1 = a2 orelse a2 = Gen)
   401 
   402 fun sign_for_comp_op Eq = Plus
   403   | sign_for_comp_op Neq = Minus
   404   | sign_for_comp_op Leq = raise BAD ("sign_for_comp_op", "unexpected \"Leq\"")
   405 
   406 fun do_annotation_atom_comp Leq [] aa1 aa2 (cset as (comps, clauses)) =
   407     (case (aa1, aa2) of
   408        (A a1, A a2) => if annotation_comp Leq a1 a2 then SOME cset else NONE
   409      | _ => SOME (insert (op =) (aa1, aa2, Leq, []) comps, clauses))
   410   | do_annotation_atom_comp cmp [] aa1 aa2 (cset as (comps, clauses)) =
   411     (case (aa1, aa2) of
   412        (A a1, A a2) => if annotation_comp cmp a1 a2 then SOME cset else NONE
   413      | (V x1, A a2) =>
   414        clauses |> add_assign_literal (x1, (sign_for_comp_op cmp, a2))
   415                |> Option.map (pair comps)
   416      | (A _, V _) => do_annotation_atom_comp cmp [] aa2 aa1 cset
   417      | (V _, V _) => SOME (insert (op =) (aa1, aa2, cmp, []) comps, clauses))
   418   | do_annotation_atom_comp cmp xs aa1 aa2 (comps, clauses) =
   419     SOME (insert (op =) (aa1, aa2, cmp, xs) comps, clauses)
   420 
   421 fun add_annotation_atom_comp cmp xs aa1 aa2 (comps, clauses) =
   422   (trace_msg (fn () => "*** Add " ^ string_for_comp (aa1, aa2, cmp, xs));
   423    case do_annotation_atom_comp cmp xs aa1 aa2 (comps, clauses) of
   424      NONE => (trace_msg (K "**** Unsolvable"); raise UNSOLVABLE ())
   425    | SOME cset => cset)
   426 
   427 fun do_mtype_comp _ _ _ _ NONE = NONE
   428   | do_mtype_comp _ _ MAlpha MAlpha cset = cset
   429   | do_mtype_comp Eq xs (MFun (M11, aa1, M12)) (MFun (M21, aa2, M22))
   430                   (SOME cset) =
   431     cset |> do_annotation_atom_comp Eq xs aa1 aa2
   432          |> do_mtype_comp Eq xs M11 M21 |> do_mtype_comp Eq xs M12 M22
   433   | do_mtype_comp Leq xs (MFun (M11, aa1, M12)) (MFun (M21, aa2, M22))
   434                   (SOME cset) =
   435     (if exists_alpha_sub_mtype M11 then
   436        cset |> do_annotation_atom_comp Leq xs aa1 aa2
   437             |> do_mtype_comp Leq xs M21 M11
   438             |> (case aa2 of
   439                   A Gen => I
   440                 | A _ => do_mtype_comp Leq xs M11 M21
   441                 | V x => do_mtype_comp Leq (x :: xs) M11 M21)
   442      else
   443        SOME cset)
   444     |> do_mtype_comp Leq xs M12 M22
   445   | do_mtype_comp cmp xs (M1 as MPair (M11, M12)) (M2 as MPair (M21, M22))
   446                   cset =
   447     (cset |> fold (uncurry (do_mtype_comp cmp xs)) [(M11, M21), (M12, M22)]
   448      handle ListPair.UnequalLengths =>
   449             raise MTYPE ("Nitpick_Mono.do_mtype_comp", [M1, M2], []))
   450   | do_mtype_comp _ _ (MType _) (MType _) cset =
   451     cset (* no need to compare them thanks to the cache *)
   452   | do_mtype_comp cmp _ M1 M2 _ =
   453     raise MTYPE ("Nitpick_Mono.do_mtype_comp (" ^ string_for_comp_op cmp ^ ")",
   454                  [M1, M2], [])
   455 
   456 fun add_mtype_comp cmp M1 M2 cset =
   457   (trace_msg (fn () => "*** Add " ^ string_for_mtype M1 ^ " " ^
   458                        string_for_comp_op cmp ^ " " ^ string_for_mtype M2);
   459    case SOME cset |> do_mtype_comp cmp [] M1 M2 of
   460      NONE => (trace_msg (K "**** Unsolvable"); raise UNSOLVABLE ())
   461    | SOME cset => cset)
   462 
   463 val add_mtypes_equal = add_mtype_comp Eq
   464 val add_is_sub_mtype = add_mtype_comp Leq
   465 
   466 fun do_notin_mtype_fv _ _ _ NONE = NONE
   467   | do_notin_mtype_fv Minus _ MAlpha cset = cset
   468   | do_notin_mtype_fv Plus [] MAlpha _ = NONE
   469   | do_notin_mtype_fv Plus [asg] MAlpha (SOME clauses) =
   470     clauses |> add_assign_literal asg
   471   | do_notin_mtype_fv Plus unless MAlpha (SOME clauses) =
   472     SOME (insert (op =) unless clauses)
   473   | do_notin_mtype_fv sn unless (MFun (M1, A a, M2)) cset =
   474     cset |> (if a <> Gen andalso sn = Plus then do_notin_mtype_fv Plus unless M1
   475              else I)
   476          |> (if a = Gen orelse sn = Plus then do_notin_mtype_fv Minus unless M1
   477              else I)
   478          |> do_notin_mtype_fv sn unless M2
   479   | do_notin_mtype_fv Plus unless (MFun (M1, V x, M2)) cset =
   480     cset |> (case add_assign_disjunct (x, (Plus, Gen)) (SOME unless) of
   481                NONE => I
   482              | SOME unless' => do_notin_mtype_fv Plus unless' M1)
   483          |> do_notin_mtype_fv Minus unless M1
   484          |> do_notin_mtype_fv Plus unless M2
   485   | do_notin_mtype_fv Minus unless (MFun (M1, V x, M2)) cset =
   486     cset |> (case fold (fn a => add_assign_disjunct (x, (Plus, a))) [Fls, Tru]
   487                        (SOME unless) of
   488                NONE => I
   489              | SOME unless' => do_notin_mtype_fv Plus unless' M1)
   490          |> do_notin_mtype_fv Minus unless M2
   491   | do_notin_mtype_fv sn unless (MPair (M1, M2)) cset =
   492     cset |> fold (do_notin_mtype_fv sn unless) [M1, M2]
   493   | do_notin_mtype_fv sn unless (MType (_, Ms)) cset =
   494     cset |> fold (do_notin_mtype_fv sn unless) Ms
   495  | do_notin_mtype_fv _ _ M _ =
   496    raise MTYPE ("Nitpick_Mono.do_notin_mtype_fv", [M], [])
   497 
   498 fun add_notin_mtype_fv sn unless M (comps, clauses) =
   499   (trace_msg (fn () => "*** Add " ^ string_for_mtype M ^ " is " ^
   500                        (case sn of Minus => "concrete" | Plus => "complete"));
   501    case SOME clauses |> do_notin_mtype_fv sn unless M of
   502      NONE => (trace_msg (K "**** Unsolvable"); raise UNSOLVABLE ())
   503    | SOME clauses => (comps, clauses))
   504 
   505 val add_mtype_is_concrete = add_notin_mtype_fv Minus
   506 val add_mtype_is_complete = add_notin_mtype_fv Plus
   507 
   508 val bool_table =
   509   [(Gen, (false, false)),
   510    (New, (false, true)),
   511    (Fls, (true, false)),
   512    (Tru, (true, true))]
   513 
   514 fun fst_var n = 2 * n
   515 fun snd_var n = 2 * n + 1
   516 
   517 val bools_from_annotation = AList.lookup (op =) bool_table #> the
   518 val annotation_from_bools = AList.find (op =) bool_table #> the_single
   519 
   520 fun prop_for_bool b = if b then PL.True else PL.False
   521 fun prop_for_bool_var_equality (v1, v2) =
   522   PL.SAnd (PL.SOr (PL.BoolVar v1, PL.SNot (PL.BoolVar v2)),
   523            PL.SOr (PL.SNot (PL.BoolVar v1), PL.BoolVar v2))
   524 fun prop_for_assign (x, a) =
   525   let val (b1, b2) = bools_from_annotation a in
   526     PL.SAnd (PL.BoolVar (fst_var x) |> not b1 ? PL.SNot,
   527              PL.BoolVar (snd_var x) |> not b2 ? PL.SNot)
   528   end
   529 fun prop_for_assign_literal (x, (Plus, a)) = prop_for_assign (x, a)
   530   | prop_for_assign_literal (x, (Minus, a)) = PL.SNot (prop_for_assign (x, a))
   531 fun prop_for_atom_assign (A a', a) = prop_for_bool (a = a')
   532   | prop_for_atom_assign (V x, a) = prop_for_assign_literal (x, (Plus, a))
   533 fun prop_for_atom_equality (aa1, A a2) = prop_for_atom_assign (aa1, a2)
   534   | prop_for_atom_equality (A a1, aa2) = prop_for_atom_assign (aa2, a1)
   535   | prop_for_atom_equality (V x1, V x2) =
   536     PL.SAnd (prop_for_bool_var_equality (pairself fst_var (x1, x2)),
   537              prop_for_bool_var_equality (pairself snd_var (x1, x2)))
   538 val prop_for_assign_clause = PL.exists o map prop_for_assign_literal
   539 fun prop_for_exists_var_assign_literal xs a =
   540   PL.exists (map (fn x => prop_for_assign_literal (x, (Plus, a))) xs)
   541 fun prop_for_comp (aa1, aa2, Eq, []) =
   542     PL.SAnd (prop_for_comp (aa1, aa2, Leq, []),
   543              prop_for_comp (aa2, aa1, Leq, []))
   544   | prop_for_comp (aa1, aa2, Neq, []) =
   545     PL.SNot (prop_for_comp (aa1, aa2, Eq, []))
   546   | prop_for_comp (aa1, aa2, Leq, []) =
   547     PL.SOr (prop_for_atom_equality (aa1, aa2), prop_for_atom_assign (aa2, Gen))
   548   | prop_for_comp (aa1, aa2, cmp, xs) =
   549     PL.SOr (prop_for_exists_var_assign_literal xs Gen,
   550             prop_for_comp (aa1, aa2, cmp, []))
   551 
   552 fun extract_assigns max_var assigns asgs =
   553   fold (fn x => fn accum =>
   554            if AList.defined (op =) asgs x then
   555              accum
   556            else case (fst_var x, snd_var x) |> pairself assigns of
   557              (NONE, NONE) => accum
   558            | bp => (x, annotation_from_bools (pairself (the_default false) bp))
   559                    :: accum)
   560        (max_var downto 1) asgs
   561 
   562 fun print_problem comps clauses =
   563   trace_msg (fn () => "*** Problem:\n" ^
   564                       cat_lines (map string_for_comp comps @
   565                                  map (string_for_assign_clause o SOME) clauses))
   566 
   567 fun print_solution asgs =
   568   trace_msg (fn () => "*** Solution:\n" ^
   569       (asgs
   570        |> map swap
   571        |> AList.group (op =)
   572        |> map (fn (a, xs) => string_for_annotation a ^ ": " ^
   573                              string_for_vars ", " (sort int_ord xs))
   574        |> space_implode "\n"))
   575 
   576 (* The ML solver timeout should correspond more or less to the overhead of
   577    invoking an external prover. *)
   578 val ml_solver_timeout = SOME (seconds 0.02)
   579 
   580 fun solve tac_timeout max_var (comps, clauses) =
   581   let
   582     val asgs =
   583       map_filter (fn [(x, (Plus, a))] => SOME (x, a) | _ => NONE) clauses
   584     fun do_assigns assigns =
   585       SOME (extract_assigns max_var assigns asgs |> tap print_solution)
   586     val _ = print_problem comps clauses
   587     val prop =
   588       PL.all (map prop_for_comp comps @ map prop_for_assign_clause clauses)
   589   in
   590     if PL.eval (K false) prop then
   591       do_assigns (K (SOME false))
   592     else if PL.eval (K true) prop then
   593       do_assigns (K (SOME true))
   594     else
   595       let
   596         (* use the first ML solver (to avoid startup overhead) *)
   597         val (ml_solvers, nonml_solvers) =
   598           !SatSolver.solvers
   599           |> List.partition (member (op =) ["dptsat", "dpll"] o fst)
   600         val res =
   601           if null nonml_solvers then
   602             time_limit tac_timeout (snd (hd ml_solvers)) prop
   603           else
   604             time_limit ml_solver_timeout (snd (hd ml_solvers)) prop
   605             handle TimeLimit.TimeOut =>
   606                    time_limit tac_timeout (SatSolver.invoke_solver "auto") prop
   607       in
   608         case res of
   609           SatSolver.SATISFIABLE assigns => do_assigns assigns
   610         | _ => (trace_msg (K "*** Unsolvable"); NONE)
   611       end
   612       handle TimeLimit.TimeOut => (trace_msg (K "*** Timed out"); NONE)
   613   end
   614 
   615 type mcontext =
   616   {bound_Ts: typ list,
   617    bound_Ms: mtyp list,
   618    frame: (int * annotation_atom) list,
   619    frees: (styp * mtyp) list,
   620    consts: (styp * mtyp) list}
   621 
   622 fun string_for_bound ctxt Ms (j, aa) =
   623   Syntax.string_of_term ctxt (Bound (length Ms - j - 1)) ^ " :\<^bsup>" ^
   624   string_for_annotation_atom aa ^ "\<^esup> " ^
   625   string_for_mtype (nth Ms (length Ms - j - 1))
   626 fun string_for_free relevant_frees ((s, _), M) =
   627   if member (op =) relevant_frees s then SOME (s ^ " : " ^ string_for_mtype M)
   628   else NONE
   629 fun string_for_mcontext ctxt t {bound_Ms, frame, frees, ...} =
   630   (map_filter (string_for_free (Term.add_free_names t [])) frees @
   631    map (string_for_bound ctxt bound_Ms) frame)
   632   |> commas |> enclose "[" "]"
   633 
   634 val initial_gamma =
   635   {bound_Ts = [], bound_Ms = [], frame = [], frees = [], consts = []}
   636 
   637 fun push_bound aa T M {bound_Ts, bound_Ms, frame, frees, consts} =
   638   {bound_Ts = T :: bound_Ts, bound_Ms = M :: bound_Ms,
   639    frame = frame @ [(length bound_Ts, aa)], frees = frees, consts = consts}
   640 fun pop_bound {bound_Ts, bound_Ms, frame, frees, consts} =
   641   {bound_Ts = tl bound_Ts, bound_Ms = tl bound_Ms,
   642    frame = frame |> filter_out (fn (j, _) => j = length bound_Ts - 1),
   643    frees = frees, consts = consts}
   644   handle List.Empty => initial_gamma (* FIXME: needed? *)
   645 
   646 fun set_frame frame ({bound_Ts, bound_Ms, frees, consts, ...} : mcontext) =
   647   {bound_Ts = bound_Ts, bound_Ms = bound_Ms, frame = frame, frees = frees,
   648    consts = consts}
   649 
   650 (* FIXME: make sure tracing messages are complete *)
   651 
   652 fun add_comp_frame aa cmp = fold (add_annotation_atom_comp cmp [] aa o snd)
   653 
   654 fun add_bound_frame j frame =
   655   let
   656     val (new_frame, gen_frame) = List.partition (curry (op =) j o fst) frame
   657   in
   658     add_comp_frame (A New) Leq new_frame
   659     #> add_comp_frame (A Gen) Eq gen_frame
   660   end
   661 
   662 fun fresh_frame ({max_fresh, ...} : mdata) fls tru =
   663   map (apsnd (fn aa =>
   664                  case (aa, fls, tru) of
   665                    (A Fls, SOME a, _) => A a
   666                  | (A Tru, _, SOME a) => A a
   667                  | (A Gen, _, _) => A Gen
   668                  | _ => V (Unsynchronized.inc max_fresh)))
   669 
   670 fun conj_clauses res_aa aa1 aa2 =
   671   [[(aa1, (Neq, Tru)), (aa2, (Neq, Tru)), (res_aa, (Eq, Tru))],
   672    [(aa1, (Neq, Fls)), (res_aa, (Eq, Fls))],
   673    [(aa2, (Neq, Fls)), (res_aa, (Eq, Fls))],
   674    [(aa1, (Neq, Gen)), (aa2, (Eq, Fls)), (res_aa, (Eq, Gen))],
   675    [(aa1, (Neq, New)), (aa2, (Eq, Fls)), (res_aa, (Eq, Gen))],
   676    [(aa1, (Eq, Fls)), (aa2, (Neq, Gen)), (res_aa, (Eq, Gen))],
   677    [(aa1, (Eq, Fls)), (aa2, (Neq, New)), (res_aa, (Eq, Gen))]]
   678 
   679 fun disj_clauses res_aa aa1 aa2 =
   680   [[(aa1, (Neq, Tru)), (res_aa, (Eq, Tru))],
   681    [(aa2, (Neq, Tru)), (res_aa, (Eq, Tru))],
   682    [(aa1, (Neq, Fls)), (aa2, (Neq, Fls)), (res_aa, (Eq, Fls))],
   683    [(aa1, (Neq, Gen)), (aa2, (Eq, Tru)), (res_aa, (Eq, Gen))],
   684    [(aa1, (Neq, New)), (aa2, (Eq, Tru)), (res_aa, (Eq, Gen))],
   685    [(aa1, (Eq, Tru)), (aa2, (Neq, Gen)), (res_aa, (Eq, Gen))],
   686    [(aa1, (Eq, Tru)), (aa2, (Neq, New)), (res_aa, (Eq, Gen))]]
   687 
   688 fun imp_clauses res_aa aa1 aa2 =
   689   [[(aa1, (Neq, Fls)), (res_aa, (Eq, Tru))],
   690    [(aa2, (Neq, Tru)), (res_aa, (Eq, Tru))],
   691    [(aa1, (Neq, Tru)), (aa2, (Neq, Fls)), (res_aa, (Eq, Fls))],
   692    [(aa1, (Neq, Gen)), (aa2, (Eq, Tru)), (res_aa, (Eq, Gen))],
   693    [(aa1, (Neq, New)), (aa2, (Eq, Tru)), (res_aa, (Eq, Gen))],
   694    [(aa1, (Eq, Fls)), (aa2, (Neq, Gen)), (res_aa, (Eq, Gen))],
   695    [(aa1, (Eq, Fls)), (aa2, (Neq, New)), (res_aa, (Eq, Gen))]]
   696 
   697 val meta_conj_triple = ("\<and>", conj_clauses, @{const Pure.conjunction})
   698 val meta_imp_triple = ("\<implies>", imp_clauses, @{const "==>"})
   699 val conj_triple = ("\<and>", conj_clauses, @{const conj})
   700 val disj_triple = ("\<or>", disj_clauses, @{const disj})
   701 val imp_triple = ("\<implies>", imp_clauses, @{const implies})
   702 
   703 fun add_annotation_clause_from_quasi_clause _ NONE = NONE
   704   | add_annotation_clause_from_quasi_clause [] accum = accum
   705   | add_annotation_clause_from_quasi_clause ((aa, (cmp, a)) :: rest) accum =
   706     case aa of
   707       A a' => if annotation_comp cmp a' a then NONE
   708               else add_annotation_clause_from_quasi_clause rest accum
   709     | V x => add_annotation_clause_from_quasi_clause rest accum
   710              |> Option.map (cons (x, (sign_for_comp_op cmp, a)))
   711 
   712 fun assign_clause_from_quasi_clause unless =
   713   add_annotation_clause_from_quasi_clause unless (SOME [])
   714 
   715 fun add_connective_var conn mk_quasi_clauses res_aa aa1 aa2 =
   716   (trace_msg (fn () => "*** Add " ^ string_for_annotation_atom res_aa ^ " = " ^
   717                        string_for_annotation_atom aa1 ^ " " ^ conn ^ " " ^
   718                        string_for_annotation_atom aa2);
   719    fold (add_assign_clause o assign_clause_from_quasi_clause)
   720         (mk_quasi_clauses res_aa aa1 aa2))
   721 fun add_connective_frames conn mk_quasi_clauses res_frame frame1 frame2 =
   722   fold I (map3 (fn (_, res_aa) => fn (_, aa1) => fn (_, aa2) =>
   723                    add_connective_var conn mk_quasi_clauses res_aa aa1 aa2)
   724                res_frame frame1 frame2)
   725 
   726 fun kill_unused_in_frame is_in (accum as ({frame, ...}, _)) =
   727   let val (used_frame, unused_frame) = List.partition is_in frame in
   728     accum |>> set_frame used_frame
   729           ||> add_comp_frame (A Gen) Eq unused_frame
   730   end
   731 
   732 fun split_frame is_in_fun (gamma as {frame, ...}, cset) =
   733   let
   734     fun bubble fun_frame arg_frame [] cset =
   735         ((rev fun_frame, rev arg_frame), cset)
   736       | bubble fun_frame arg_frame ((bound as (_, aa)) :: rest) cset =
   737         if is_in_fun bound then
   738           bubble (bound :: fun_frame) arg_frame rest
   739                  (cset |> add_comp_frame aa Leq arg_frame)
   740         else
   741           bubble fun_frame (bound :: arg_frame) rest cset
   742   in cset |> bubble [] [] frame ||> pair gamma end
   743 
   744 fun add_annotation_atom_comp_alt _ (A Gen) _ _ = I
   745   | add_annotation_atom_comp_alt _ (A _) _ _ =
   746     (trace_msg (K "*** Expected G"); raise UNSOLVABLE ())
   747   | add_annotation_atom_comp_alt cmp (V x) aa1 aa2 =
   748     add_annotation_atom_comp cmp [x] aa1 aa2
   749 
   750 fun add_arg_order1 ((_, aa), (_, prev_aa)) = I
   751   add_annotation_atom_comp_alt Neq prev_aa (A Gen) aa
   752 fun add_app1 fun_aa ((_, res_aa), (_, arg_aa)) = I
   753   let
   754     val clause = [(arg_aa, (Eq, New)), (res_aa, (Eq, Gen))]
   755                  |> assign_clause_from_quasi_clause
   756   in
   757     trace_msg (fn () => "*** Add " ^ string_for_assign_clause clause);
   758     apsnd (add_assign_clause clause)
   759     #> add_annotation_atom_comp_alt Leq arg_aa fun_aa res_aa
   760   end
   761 fun add_app _ [] [] = I
   762   | add_app fun_aa res_frame arg_frame =
   763     add_comp_frame (A New) Leq arg_frame
   764     #> fold add_arg_order1 (tl arg_frame ~~ (fst (split_last arg_frame)))
   765     #> fold (add_app1 fun_aa) (res_frame ~~ arg_frame)
   766 
   767 fun consider_connective mdata (conn, mk_quasi_clauses, t0) do_t1 do_t2
   768                         (accum as ({frame, ...}, _)) =
   769   let
   770     val mtype_for = fresh_mtype_for_type mdata false
   771     val frame1 = fresh_frame mdata (SOME Tru) NONE frame
   772     val frame2 = fresh_frame mdata (SOME Fls) NONE frame
   773     val (m1, accum) = accum |>> set_frame frame1 |> do_t1
   774     val (m2, accum) = accum |>> set_frame frame2 |> do_t2
   775   in
   776     (MApp (MApp (MRaw (t0, mtype_for (fastype_of t0)), m1), m2),
   777      accum |>> set_frame frame
   778            ||> apsnd (add_connective_frames conn mk_quasi_clauses frame frame1
   779                                             frame2))
   780   end
   781 
   782 fun consider_term (mdata as {hol_ctxt = {thy, ctxt, stds, ...}, alpha_T,
   783                              max_fresh, ...}) =
   784   let
   785     fun is_enough_eta_expanded t =
   786       case strip_comb t of
   787         (Const x, ts) => the_default 0 (arity_of_built_in_const thy stds x)
   788         <= length ts
   789       | _ => true
   790     val mtype_for = fresh_mtype_for_type mdata false
   791     fun do_all T (gamma, cset) =
   792       let
   793         val abs_M = mtype_for (domain_type (domain_type T))
   794         val x = Unsynchronized.inc max_fresh
   795         val body_M = mtype_for (body_type T)
   796       in
   797         (MFun (MFun (abs_M, V x, body_M), A Gen, body_M),
   798          (gamma, cset |> add_mtype_is_complete [(x, (Plus, Tru))] abs_M))
   799       end
   800     fun do_equals T (gamma, cset) =
   801       let
   802         val M = mtype_for (domain_type T)
   803         val x = Unsynchronized.inc max_fresh
   804       in
   805         (MFun (M, A Gen, MFun (M, V x, mtype_for (nth_range_type 2 T))),
   806          (gamma, cset |> add_mtype_is_concrete [] M
   807                       |> add_annotation_atom_comp Leq [] (A Fls) (V x)))
   808       end
   809     fun do_robust_set_operation T (gamma, cset) =
   810       let
   811         val set_T = domain_type T
   812         val M1 = mtype_for set_T
   813         val M2 = mtype_for set_T
   814         val M3 = mtype_for set_T
   815       in
   816         (MFun (M1, A Gen, MFun (M2, A Gen, M3)),
   817          (gamma, cset |> add_is_sub_mtype M1 M3 |> add_is_sub_mtype M2 M3))
   818       end
   819     fun do_fragile_set_operation T (gamma, cset) =
   820       let
   821         val set_T = domain_type T
   822         val set_M = mtype_for set_T
   823         fun custom_mtype_for (T as Type (@{type_name fun}, [T1, T2])) =
   824             if T = set_T then set_M
   825             else MFun (custom_mtype_for T1, A Gen, custom_mtype_for T2)
   826           | custom_mtype_for T = mtype_for T
   827       in
   828         (custom_mtype_for T, (gamma, cset |> add_mtype_is_concrete [] set_M))
   829       end
   830     fun do_pair_constr T accum =
   831       case mtype_for (nth_range_type 2 T) of
   832         M as MPair (a_M, b_M) =>
   833         (MFun (a_M, A Gen, MFun (b_M, A Gen, M)), accum)
   834       | M => raise MTYPE ("Nitpick_Mono.consider_term.do_pair_constr", [M], [])
   835     fun do_nth_pair_sel n T =
   836       case mtype_for (domain_type T) of
   837         M as MPair (a_M, b_M) =>
   838         pair (MFun (M, A Gen, if n = 0 then a_M else b_M))
   839       | M => raise MTYPE ("Nitpick_Mono.consider_term.do_nth_pair_sel", [M], [])
   840     and do_connect triple t1 t2 =
   841       consider_connective mdata triple (do_term t1) (do_term t2)
   842     and do_term t
   843             (accum as (gamma as {bound_Ts, bound_Ms, frame, frees, consts},
   844                        cset)) =
   845       (trace_msg (fn () => "  " ^ string_for_mcontext ctxt t gamma ^
   846                            " \<turnstile> " ^ Syntax.string_of_term ctxt t ^
   847                            " : _?");
   848        case t of
   849          @{const False} =>
   850          (MRaw (t, bool_M), accum ||> add_comp_frame (A Fls) Leq frame)
   851        | Const (@{const_name None}, T) =>
   852          (MRaw (t, mtype_for T), accum ||> add_comp_frame (A Fls) Leq frame)
   853        | @{const True} =>
   854          (MRaw (t, bool_M), accum ||> add_comp_frame (A Tru) Leq frame)
   855        | (t0 as Const (@{const_name HOL.eq}, _)) $ Bound 0 $ t2 =>
   856          (* hack to exploit symmetry of equality when typing "insert" *)
   857          (if t2 = Bound 0 then do_term @{term True}
   858           else do_term (t0 $ t2 $ Bound 0)) accum
   859        | Const (x as (s, T)) =>
   860          (case AList.lookup (op =) consts x of
   861             SOME M => (M, accum)
   862           | NONE =>
   863             if not (could_exist_alpha_subtype alpha_T T) then
   864               (mtype_for T, accum)
   865             else case s of
   866               @{const_name all} => do_all T accum
   867             | @{const_name "=="} => do_equals T accum
   868             | @{const_name All} => do_all T accum
   869             | @{const_name Ex} =>
   870               let val set_T = domain_type T in
   871                 do_term (Abs (Name.uu, set_T,
   872                               @{const Not} $ (HOLogic.mk_eq
   873                                   (Abs (Name.uu, domain_type set_T,
   874                                         @{const False}),
   875                                    Bound 0)))) accum
   876                 |>> mtype_of_mterm
   877               end
   878             | @{const_name HOL.eq} => do_equals T accum
   879             | @{const_name The} =>
   880               (trace_msg (K "*** The"); raise UNSOLVABLE ())
   881             | @{const_name Eps} =>
   882               (trace_msg (K "*** Eps"); raise UNSOLVABLE ())
   883             | @{const_name If} =>
   884               do_robust_set_operation (range_type T) accum
   885               |>> curry3 MFun bool_M (A Gen)
   886             | @{const_name Pair} => do_pair_constr T accum
   887             | @{const_name fst} => do_nth_pair_sel 0 T accum
   888             | @{const_name snd} => do_nth_pair_sel 1 T accum
   889             | @{const_name Id} =>
   890               (MFun (mtype_for (domain_type T), A Gen, bool_M), accum)
   891             | @{const_name converse} =>
   892               let
   893                 val x = Unsynchronized.inc max_fresh
   894                 fun mtype_for_set T =
   895                   MFun (mtype_for (domain_type T), V x, bool_M)
   896                 val ab_set_M = domain_type T |> mtype_for_set
   897                 val ba_set_M = range_type T |> mtype_for_set
   898               in
   899                 (MFun (ab_set_M, A Gen, ba_set_M),
   900                  accum ||> add_annotation_atom_comp Neq [] (V x) (A New))
   901               end
   902             | @{const_name trancl} => do_fragile_set_operation T accum
   903             | @{const_name rel_comp} =>
   904               let
   905                 val x = Unsynchronized.inc max_fresh
   906                 fun mtype_for_set T =
   907                   MFun (mtype_for (domain_type T), V x, bool_M)
   908                 val bc_set_M = domain_type T |> mtype_for_set
   909                 val ab_set_M = domain_type (range_type T) |> mtype_for_set
   910                 val ac_set_M = nth_range_type 2 T |> mtype_for_set
   911               in
   912                 (MFun (bc_set_M, A Gen, MFun (ab_set_M, A Gen, ac_set_M)),
   913                  accum ||> add_annotation_atom_comp Neq [] (V x) (A New))
   914               end
   915             | @{const_name finite} =>
   916               let
   917                 val M1 = mtype_for (domain_type (domain_type T))
   918                 val a = if exists_alpha_sub_mtype M1 then Fls else Gen
   919               in (MFun (MFun (M1, A a, bool_M), A Gen, bool_M), accum) end
   920             | @{const_name prod} =>
   921               let
   922                 val x = Unsynchronized.inc max_fresh
   923                 fun mtype_for_set T =
   924                   MFun (mtype_for (domain_type T), V x, bool_M)
   925                 val a_set_M = mtype_for_set (domain_type T)
   926                 val b_set_M =
   927                   mtype_for_set (range_type (domain_type (range_type T)))
   928                 val ab_set_M = mtype_for_set (nth_range_type 2 T)
   929               in
   930                 (MFun (a_set_M, A Gen, MFun (b_set_M, A Gen, ab_set_M)),
   931                  accum ||> add_annotation_atom_comp Neq [] (V x) (A New))
   932               end
   933             | _ =>
   934               if s = @{const_name safe_The} then
   935                 let
   936                   val a_set_M = mtype_for (domain_type T)
   937                   val a_M = dest_MFun a_set_M |> #1
   938                 in (MFun (a_set_M, A Gen, a_M), accum) end
   939               else if s = @{const_name ord_class.less_eq} andalso
   940                       is_set_type (domain_type T) then
   941                 do_fragile_set_operation T accum
   942               else if is_sel s then
   943                 (mtype_for_sel mdata x, accum)
   944               else if is_constr ctxt stds x then
   945                 (mtype_for_constr mdata x, accum)
   946               else if is_built_in_const thy stds x then
   947                 (fresh_mtype_for_type mdata true T, accum)
   948               else
   949                 let val M = mtype_for T in
   950                   (M, ({bound_Ts = bound_Ts, bound_Ms = bound_Ms, frame = frame,
   951                         frees = frees, consts = (x, M) :: consts}, cset))
   952                 end)
   953            |>> curry MRaw t
   954            ||> apsnd (add_comp_frame (A Gen) Eq frame)
   955          | Free (x as (_, T)) =>
   956            (case AList.lookup (op =) frees x of
   957               SOME M => (M, accum)
   958             | NONE =>
   959               let val M = mtype_for T in
   960                 (M, ({bound_Ts = bound_Ts, bound_Ms = bound_Ms, frame = frame,
   961                       frees = (x, M) :: frees, consts = consts}, cset))
   962               end)
   963            |>> curry MRaw t ||> apsnd (add_comp_frame (A Gen) Eq frame)
   964          | Var _ => (trace_msg (K "*** Var"); raise UNSOLVABLE ())
   965          | Bound j =>
   966            (MRaw (t, nth bound_Ms j),
   967             accum ||> add_bound_frame (length bound_Ts - j - 1) frame)
   968          | Abs (s, T, t') =>
   969            (case fin_fun_body T (fastype_of1 (T :: bound_Ts, t')) t' of
   970               SOME t' =>
   971               let
   972                 val M = mtype_for T
   973                 val x = Unsynchronized.inc max_fresh
   974                 val (m', accum) = do_term t' (accum |>> push_bound (V x) T M)
   975               in
   976                 (MAbs (s, T, M, V x, m'),
   977                  accum |>> pop_bound
   978                        ||> add_annotation_atom_comp Leq [] (A Fls) (V x))
   979               end
   980             | NONE =>
   981               ((case t' of
   982                   t1' $ Bound 0 =>
   983                   if not (loose_bvar1 (t1', 0)) andalso
   984                      is_enough_eta_expanded t1' then
   985                     do_term (incr_boundvars ~1 t1') accum
   986                   else
   987                     raise SAME ()
   988                 | (t11 as Const (@{const_name HOL.eq}, _)) $ Bound 0 $ t13 =>
   989                   if not (loose_bvar1 (t13, 0)) then
   990                     do_term (incr_boundvars ~1 (t11 $ t13)) accum
   991                   else
   992                     raise SAME ()
   993                 | _ => raise SAME ())
   994                handle SAME () =>
   995                       let
   996                         val M = mtype_for T
   997                         val x = Unsynchronized.inc max_fresh
   998                         val (m', accum) =
   999                           do_term t' (accum |>> push_bound (V x) T M)
  1000                       in (MAbs (s, T, M, V x, m'), accum |>> pop_bound) end))
  1001          | @{const Not} $ t1 => do_connect imp_triple t1 @{const False} accum
  1002          | @{const conj} $ t1 $ t2 => do_connect conj_triple t1 t2 accum
  1003          | @{const disj} $ t1 $ t2 => do_connect disj_triple t1 t2 accum
  1004          | @{const implies} $ t1 $ t2 => do_connect imp_triple t1 t2 accum
  1005          | Const (@{const_name Let}, _) $ t1 $ t2 =>
  1006            do_term (betapply (t2, t1)) accum
  1007          | t1 $ t2 =>
  1008            let
  1009              fun is_in t (j, _) = loose_bvar1 (t, length bound_Ts - j - 1)
  1010              val accum as ({frame, ...}, _) =
  1011                accum |> kill_unused_in_frame (is_in t)
  1012              val ((frame1a, frame1b), accum) = accum |> split_frame (is_in t1)
  1013              val frame2a = frame1a |> map (apsnd (K (A Gen)))
  1014              val frame2b =
  1015                frame1b |> map (apsnd (fn _ => V (Unsynchronized.inc max_fresh)))
  1016              val frame2 = frame2a @ frame2b
  1017              val (m1, accum) = accum |>> set_frame frame1a |> do_term t1
  1018              val (m2, accum) = accum |>> set_frame frame2 |> do_term t2
  1019            in
  1020              let
  1021                val (M11, aa, _) = mtype_of_mterm m1 |> dest_MFun
  1022                val M2 = mtype_of_mterm m2
  1023              in
  1024                (MApp (m1, m2),
  1025                 accum |>> set_frame frame
  1026                       ||> add_is_sub_mtype M2 M11
  1027                       ||> add_app aa frame1b frame2b)
  1028              end
  1029            end)
  1030         |> tap (fn (m, (gamma, _)) =>
  1031                    trace_msg (fn () => "  " ^ string_for_mcontext ctxt t gamma ^
  1032                                        " \<turnstile> " ^
  1033                                        string_for_mterm ctxt m))
  1034   in do_term end
  1035 
  1036 fun force_gen_funs 0 _ = I
  1037   | force_gen_funs n (M as MFun (M1, _, M2)) =
  1038     add_mtypes_equal M (MFun (M1, A Gen, M2)) #> force_gen_funs (n - 1) M2
  1039   | force_gen_funs _ M = raise MTYPE ("Nitpick_Mono.force_gen_funs", [M], [])
  1040 fun consider_general_equals mdata def (x as (_, T)) t1 t2 accum =
  1041   let
  1042     val (m1, accum) = consider_term mdata t1 accum
  1043     val (m2, accum) = consider_term mdata t2 accum
  1044     val M1 = mtype_of_mterm m1
  1045     val M2 = mtype_of_mterm m2
  1046     val accum = accum ||> add_mtypes_equal M1 M2
  1047     val body_M = fresh_mtype_for_type mdata false (nth_range_type 2 T)
  1048     val m = MApp (MApp (MRaw (Const x,
  1049                            MFun (M1, A Gen, MFun (M2, A Gen, body_M))), m1), m2)
  1050   in
  1051     (m, (if def then
  1052            let val (head_m, arg_ms) = strip_mcomb m1 in
  1053              accum ||> force_gen_funs (length arg_ms) (mtype_of_mterm head_m)
  1054            end
  1055          else
  1056            accum))
  1057   end
  1058 
  1059 fun consider_general_formula (mdata as {hol_ctxt = {ctxt, ...}, max_fresh,
  1060                                         ...}) =
  1061   let
  1062     val mtype_for = fresh_mtype_for_type mdata false
  1063     val do_term = consider_term mdata
  1064     fun do_formula sn t (accum as (gamma, _)) =
  1065       let
  1066         fun do_quantifier (quant_x as (quant_s, _)) abs_s abs_T body_t =
  1067           let
  1068             val abs_M = mtype_for abs_T
  1069             val x = Unsynchronized.inc max_fresh
  1070             val side_cond = ((sn = Minus) = (quant_s = @{const_name Ex}))
  1071             fun ann () = if quant_s = @{const_name Ex} then Fls else Tru
  1072             val (body_m, accum) =
  1073               accum ||> side_cond
  1074                         ? add_mtype_is_complete [(x, (Plus, ann ()))] abs_M
  1075                     |>> push_bound (V x) abs_T abs_M |> do_formula sn body_t
  1076             val body_M = mtype_of_mterm body_m
  1077           in
  1078             (MApp (MRaw (Const quant_x,
  1079                          MFun (MFun (abs_M, A Gen, body_M), A Gen, body_M)),
  1080                    MAbs (abs_s, abs_T, abs_M, A Gen, body_m)),
  1081              accum |>> pop_bound)
  1082           end
  1083         fun do_connect triple neg1 t1 t2 =
  1084           consider_connective mdata triple
  1085               (do_formula (sn |> neg1 ? negate_sign) t1) (do_formula sn t2)
  1086         fun do_equals x t1 t2 =
  1087           case sn of
  1088             Plus => do_term t accum
  1089           | Minus => consider_general_equals mdata false x t1 t2 accum
  1090       in
  1091         trace_msg (fn () => "  " ^ string_for_mcontext ctxt t gamma ^
  1092                             " \<turnstile> " ^ Syntax.string_of_term ctxt t ^
  1093                             " : o\<^sup>" ^ string_for_sign sn ^ "?");
  1094         case t of
  1095           Const (x as (@{const_name all}, _)) $ Abs (s1, T1, t1) =>
  1096           do_quantifier x s1 T1 t1
  1097         | Const (x as (@{const_name "=="}, _)) $ t1 $ t2 => do_equals x t1 t2
  1098         | @{const Trueprop} $ t1 =>
  1099           let val (m1, accum) = do_formula sn t1 accum in
  1100             (MApp (MRaw (@{const Trueprop}, mtype_for (bool_T --> prop_T)), m1),
  1101              accum)
  1102           end
  1103         | Const (x as (@{const_name All}, _)) $ Abs (s1, T1, t1) =>
  1104           do_quantifier x s1 T1 t1
  1105         | Const (x0 as (@{const_name Ex}, T0)) $ (t1 as Abs (s1, T1, t1')) =>
  1106           (case sn of
  1107              Plus => do_quantifier x0 s1 T1 t1'
  1108            | Minus =>
  1109              (* FIXME: Move elsewhere *)
  1110              do_term (@{const Not}
  1111                       $ (HOLogic.eq_const (domain_type T0) $ t1
  1112                          $ Abs (Name.uu, T1, @{const False}))) accum)
  1113         | Const (x as (@{const_name HOL.eq}, _)) $ t1 $ t2 => do_equals x t1 t2
  1114         | Const (@{const_name Let}, _) $ t1 $ t2 =>
  1115           do_formula sn (betapply (t2, t1)) accum
  1116         | @{const Pure.conjunction} $ t1 $ t2 =>
  1117           do_connect meta_conj_triple false t1 t2 accum
  1118         | @{const "==>"} $ t1 $ t2 =>
  1119           do_connect meta_imp_triple true t1 t2 accum
  1120         | @{const Not} $ t1 =>
  1121           do_connect imp_triple true t1 @{const False} accum
  1122         | @{const conj} $ t1 $ t2 => do_connect conj_triple false t1 t2 accum
  1123         | @{const disj} $ t1 $ t2 => do_connect disj_triple false t1 t2 accum
  1124         | @{const implies} $ t1 $ t2 => do_connect imp_triple true t1 t2 accum
  1125         | _ => do_term t accum
  1126       end
  1127       |> tap (fn (m, (gamma, _)) =>
  1128                  trace_msg (fn () => string_for_mcontext ctxt t gamma ^
  1129                                      " \<turnstile> " ^
  1130                                      string_for_mterm ctxt m ^ " : o\<^sup>" ^
  1131                                      string_for_sign sn))
  1132   in do_formula end
  1133 
  1134 (* The harmless axiom optimization below is somewhat too aggressive in the face
  1135    of (rather peculiar) user-defined axioms. *)
  1136 val harmless_consts =
  1137   [@{const_name ord_class.less}, @{const_name ord_class.less_eq}]
  1138 val bounteous_consts = [@{const_name bisim}]
  1139 
  1140 fun is_harmless_axiom ({no_harmless = true, ...} : mdata) _ = false
  1141   | is_harmless_axiom {hol_ctxt = {thy, stds, ...}, ...} t =
  1142     Term.add_consts t []
  1143     |> filter_out (is_built_in_const thy stds)
  1144     |> (forall (member (op =) harmless_consts o original_name o fst) orf
  1145         exists (member (op =) bounteous_consts o fst))
  1146 
  1147 fun consider_nondefinitional_axiom mdata t =
  1148   if is_harmless_axiom mdata t then pair (MRaw (t, dummy_M))
  1149   else consider_general_formula mdata Plus t
  1150 
  1151 fun consider_definitional_axiom (mdata as {hol_ctxt = {ctxt, ...}, ...}) t =
  1152   if not (is_constr_pattern_formula ctxt t) then
  1153     consider_nondefinitional_axiom mdata t
  1154   else if is_harmless_axiom mdata t then
  1155     pair (MRaw (t, dummy_M))
  1156   else
  1157     let
  1158       val mtype_for = fresh_mtype_for_type mdata false
  1159       val do_term = consider_term mdata
  1160       fun do_all quant_t abs_s abs_T body_t accum =
  1161         let
  1162           val abs_M = mtype_for abs_T
  1163           val (body_m, accum) =
  1164             accum |>> push_bound (A Gen) abs_T abs_M |> do_formula body_t
  1165           val body_M = mtype_of_mterm body_m
  1166         in
  1167           (MApp (MRaw (quant_t, MFun (MFun (abs_M, A Gen, body_M), A Gen,
  1168                        body_M)),
  1169                  MAbs (abs_s, abs_T, abs_M, A Gen, body_m)),
  1170            accum |>> pop_bound)
  1171         end
  1172       and do_conjunction t0 t1 t2 accum =
  1173         let
  1174           val (m1, accum) = do_formula t1 accum
  1175           val (m2, accum) = do_formula t2 accum
  1176         in
  1177           (MApp (MApp (MRaw (t0, mtype_for (fastype_of t0)), m1), m2), accum)
  1178         end
  1179       and do_implies t0 t1 t2 accum =
  1180         let
  1181           val (m1, accum) = do_term t1 accum
  1182           val (m2, accum) = do_formula t2 accum
  1183         in
  1184           (MApp (MApp (MRaw (t0, mtype_for (fastype_of t0)), m1), m2), accum)
  1185         end
  1186       and do_formula t accum =
  1187         case t of
  1188           (t0 as Const (@{const_name all}, _)) $ Abs (s1, T1, t1) =>
  1189           do_all t0 s1 T1 t1 accum
  1190         | @{const Trueprop} $ t1 =>
  1191           let val (m1, accum) = do_formula t1 accum in
  1192             (MApp (MRaw (@{const Trueprop}, mtype_for (bool_T --> prop_T)), m1),
  1193              accum)
  1194           end
  1195         | Const (x as (@{const_name "=="}, _)) $ t1 $ t2 =>
  1196           consider_general_equals mdata true x t1 t2 accum
  1197         | (t0 as @{const "==>"}) $ t1 $ t2 => do_implies t0 t1 t2 accum
  1198         | (t0 as @{const Pure.conjunction}) $ t1 $ t2 =>
  1199           do_conjunction t0 t1 t2 accum
  1200         | (t0 as Const (@{const_name All}, _)) $ Abs (s0, T1, t1) =>
  1201           do_all t0 s0 T1 t1 accum
  1202         | Const (x as (@{const_name HOL.eq}, _)) $ t1 $ t2 =>
  1203           consider_general_equals mdata true x t1 t2 accum
  1204         | (t0 as @{const conj}) $ t1 $ t2 => do_conjunction t0 t1 t2 accum
  1205         | (t0 as @{const implies}) $ t1 $ t2 => do_implies t0 t1 t2 accum
  1206         | _ => raise TERM ("Nitpick_Mono.consider_definitional_axiom.\
  1207                            \do_formula", [t])
  1208     in do_formula t end
  1209 
  1210 fun string_for_mtype_of_term ctxt asgs t M =
  1211   Syntax.string_of_term ctxt t ^ " : " ^ string_for_mtype (resolve_mtype asgs M)
  1212 
  1213 fun print_mcontext ctxt asgs ({frees, consts, ...} : mcontext) =
  1214   trace_msg (fn () =>
  1215       map (fn (x, M) => string_for_mtype_of_term ctxt asgs (Free x) M) frees @
  1216       map (fn (x, M) => string_for_mtype_of_term ctxt asgs (Const x) M) consts
  1217       |> cat_lines)
  1218 
  1219 fun amass f t (ms, accum) =
  1220   let val (m, accum) = f t accum in (m :: ms, accum) end
  1221 
  1222 fun infer which no_harmless (hol_ctxt as {ctxt, tac_timeout, ...}) binarize
  1223           alpha_T (nondef_ts, def_ts) =
  1224   let
  1225     val _ = trace_msg (fn () => "****** " ^ which ^ " analysis: " ^
  1226                                 string_for_mtype MAlpha ^ " is " ^
  1227                                 Syntax.string_of_typ ctxt alpha_T)
  1228     val mdata as {max_fresh, constr_mcache, ...} =
  1229       initial_mdata hol_ctxt binarize no_harmless alpha_T
  1230     val accum = (initial_gamma, ([], []))
  1231     val (nondef_ms, accum) =
  1232       ([], accum) |> amass (consider_general_formula mdata Plus) (hd nondef_ts)
  1233                   |> fold (amass (consider_nondefinitional_axiom mdata))
  1234                           (tl nondef_ts)
  1235     val (def_ms, (gamma, cset)) =
  1236       ([], accum) |> fold (amass (consider_definitional_axiom mdata)) def_ts
  1237   in
  1238     case solve tac_timeout (!max_fresh) cset of
  1239       SOME asgs => (print_mcontext ctxt asgs gamma;
  1240                     SOME (asgs, (nondef_ms, def_ms), !constr_mcache))
  1241     | _ => NONE
  1242   end
  1243   handle UNSOLVABLE () => NONE
  1244        | MTYPE (loc, Ms, Ts) =>
  1245          raise BAD (loc, commas (map string_for_mtype Ms @
  1246                                  map (Syntax.string_of_typ ctxt) Ts))
  1247        | MTERM (loc, ms) =>
  1248          raise BAD (loc, commas (map (string_for_mterm ctxt) ms))
  1249 
  1250 val formulas_monotonic = is_some oooo infer "Monotonicity" false
  1251 
  1252 fun fin_fun_constr T1 T2 =
  1253   (@{const_name FinFun}, (T1 --> T2) --> Type (@{type_name fin_fun}, [T1, T2]))
  1254 
  1255 fun finitize_funs (hol_ctxt as {thy, ctxt, stds, constr_cache, ...}) binarize
  1256                   finitizes alpha_T tsp =
  1257   case infer "Finiteness" true hol_ctxt binarize alpha_T tsp of
  1258     SOME (asgs, msp, constr_mtypes) =>
  1259     if forall (curry (op =) Gen o snd) asgs then
  1260       tsp
  1261     else
  1262       let
  1263         fun should_finitize T aa =
  1264           case triple_lookup (type_match thy) finitizes T of
  1265             SOME (SOME false) => false
  1266           | _ => resolve_annotation_atom asgs aa = A Fls
  1267         fun type_from_mtype T M =
  1268           case (M, T) of
  1269             (MAlpha, _) => T
  1270           | (MFun (M1, aa, M2), Type (@{type_name fun}, Ts)) =>
  1271             Type (if should_finitize T aa then @{type_name fin_fun}
  1272                   else @{type_name fun}, map2 type_from_mtype Ts [M1, M2])
  1273           | (MPair (M1, M2), Type (@{type_name prod}, Ts)) =>
  1274             Type (@{type_name prod}, map2 type_from_mtype Ts [M1, M2])
  1275           | (MType _, _) => T
  1276           | _ => raise MTYPE ("Nitpick_Mono.finitize_funs.type_from_mtype",
  1277                               [M], [T])
  1278         fun finitize_constr (x as (s, T)) =
  1279           (s, case AList.lookup (op =) constr_mtypes x of
  1280                 SOME M => type_from_mtype T M
  1281               | NONE => T)
  1282         fun term_from_mterm new_Ts old_Ts m =
  1283           case m of
  1284             MRaw (t, M) =>
  1285             let
  1286               val T = fastype_of1 (old_Ts, t)
  1287               val T' = type_from_mtype T M
  1288             in
  1289               case t of
  1290                 Const (x as (s, _)) =>
  1291                 if s = @{const_name finite} then
  1292                   case domain_type T' of
  1293                     set_T' as Type (@{type_name fin_fun}, _) =>
  1294                     Abs (Name.uu, set_T', @{const True})
  1295                   | _ => Const (s, T')
  1296                 else if s = @{const_name "=="} orelse
  1297                         s = @{const_name HOL.eq} then
  1298                   let
  1299                     val T =
  1300                       case T' of
  1301                         Type (_, [T1, Type (_, [T2, T3])]) =>
  1302                         T1 --> T2 --> T3
  1303                       | _ => raise TYPE ("Nitpick_Mono.finitize_funs.\
  1304                                          \term_from_mterm", [T, T'], [])
  1305                   in coerce_term hol_ctxt new_Ts T' T (Const (s, T)) end
  1306                 else if is_built_in_const thy stds x then
  1307                   coerce_term hol_ctxt new_Ts T' T t
  1308                 else if is_constr ctxt stds x then
  1309                   Const (finitize_constr x)
  1310                 else if is_sel s then
  1311                   let
  1312                     val n = sel_no_from_name s
  1313                     val x' =
  1314                       x |> binarized_and_boxed_constr_for_sel hol_ctxt binarize
  1315                         |> finitize_constr
  1316                     val x'' =
  1317                       binarized_and_boxed_nth_sel_for_constr hol_ctxt binarize
  1318                                                              x' n
  1319                   in Const x'' end
  1320                 else
  1321                   Const (s, T')
  1322               | Free (s, T) => Free (s, type_from_mtype T M)
  1323               | Bound _ => t
  1324               | _ => raise MTERM ("Nitpick_Mono.finitize_funs.term_from_mterm",
  1325                                   [m])
  1326             end
  1327           | MApp (m1, m2) =>
  1328             let
  1329               val (t1, t2) = pairself (term_from_mterm new_Ts old_Ts) (m1, m2)
  1330               val (T1, T2) = pairself (curry fastype_of1 new_Ts) (t1, t2)
  1331               val (t1', T2') =
  1332                 case T1 of
  1333                   Type (s, [T11, T12]) =>
  1334                   (if s = @{type_name fin_fun} then
  1335                      select_nth_constr_arg ctxt stds (fin_fun_constr T11 T12) t1
  1336                                            0 (T11 --> T12)
  1337                    else
  1338                      t1, T11)
  1339                 | _ => raise TYPE ("Nitpick_Mono.finitize_funs.term_from_mterm",
  1340                                    [T1], [])
  1341             in betapply (t1', coerce_term hol_ctxt new_Ts T2' T2 t2) end
  1342           | MAbs (s, old_T, M, aa, m') =>
  1343             let
  1344               val new_T = type_from_mtype old_T M
  1345               val t' = term_from_mterm (new_T :: new_Ts) (old_T :: old_Ts) m'
  1346               val T' = fastype_of1 (new_T :: new_Ts, t')
  1347             in
  1348               Abs (s, new_T, t')
  1349               |> should_finitize (new_T --> T') aa
  1350                  ? construct_value ctxt stds (fin_fun_constr new_T T') o single
  1351             end
  1352       in
  1353         Unsynchronized.change constr_cache (map (apsnd (map finitize_constr)));
  1354         pairself (map (term_from_mterm [] [])) msp
  1355       end
  1356   | NONE => tsp
  1357 
  1358 end;