src/Pure/context.ML
author wenzelm
Wed Jun 22 19:41:18 2005 +0200 (2005-06-22)
changeset 16533 f1152f75f6fc
parent 16489 f66ab8a4e98f
child 16594 5d73fbf4eb1e
permissions -rw-r--r--
begin_thy: merge maximal imports;
incorporate proof data;
added generic context;
     1 (*  Title:      Pure/context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Generic theory contexts with unique identity, arbitrarily typed data,
     6 development graph and history support.  Implicit theory contexts in ML.
     7 Generic proof contexts with arbitrarily typed data.
     8 *)
     9 
    10 signature BASIC_CONTEXT =
    11 sig
    12   type theory
    13   type theory_ref
    14   exception THEORY of string * theory list
    15   val context: theory -> unit
    16   val the_context: unit -> theory
    17 end;
    18 
    19 signature CONTEXT =
    20 sig
    21   include BASIC_CONTEXT
    22   exception DATA_FAIL of exn * string
    23   (*theory context*)
    24   val theory_name: theory -> string
    25   val parents_of: theory -> theory list
    26   val ancestors_of: theory -> theory list
    27   val is_stale: theory -> bool
    28   val ProtoPureN: string
    29   val PureN: string
    30   val CPureN: string
    31   val draftN: string
    32   val exists_name: string -> theory -> bool
    33   val names_of: theory -> string list
    34   val pretty_thy: theory -> Pretty.T
    35   val string_of_thy: theory -> string
    36   val pprint_thy: theory -> pprint_args -> unit
    37   val pretty_abbrev_thy: theory -> Pretty.T
    38   val str_of_thy: theory -> string
    39   val check_thy: string -> theory -> theory
    40   val eq_thy: theory * theory -> bool
    41   val subthy: theory * theory -> bool
    42   val merge: theory * theory -> theory                     (*exception TERM*)
    43   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    44   val self_ref: theory -> theory_ref
    45   val deref: theory_ref -> theory
    46   val copy_thy: theory -> theory
    47   val checkpoint_thy: theory -> theory
    48   val finish_thy: theory -> theory
    49   val theory_data_of: theory -> string list
    50   val pre_pure_thy: theory
    51   val begin_thy: (theory -> Pretty.pp) -> string -> theory list -> theory
    52   (*ML theory context*)
    53   val get_context: unit -> theory option
    54   val set_context: theory option -> unit
    55   val reset_context: unit -> unit
    56   val setmp: theory option -> ('a -> 'b) -> 'a -> 'b
    57   val pass: theory option -> ('a -> 'b) -> 'a -> 'b * theory option
    58   val pass_theory: theory -> ('a -> 'b) -> 'a -> 'b * theory
    59   val save: ('a -> 'b) -> 'a -> 'b
    60   val >> : (theory -> theory) -> unit
    61   val ml_output: (string -> unit) * (string -> unit)
    62   val use_mltext: string -> bool -> theory option -> unit
    63   val use_mltext_theory: string -> bool -> theory -> theory
    64   val use_let: string -> string -> string -> theory -> theory
    65   val add_setup: (theory -> theory) list -> unit
    66   val setup: unit -> (theory -> theory) list
    67   (*proof context*)
    68   type proof
    69   val theory_of_proof: proof -> theory
    70   val init_proof: theory -> proof
    71   val proof_data_of: theory -> string list
    72   (*generic context*)
    73   datatype context = Theory of theory | Proof of proof
    74   val theory_of: context -> theory
    75   val proof_of: context -> proof
    76 end;
    77 
    78 signature PRIVATE_CONTEXT =
    79 sig
    80   include CONTEXT
    81   structure TheoryData:
    82   sig
    83     val declare: string -> Object.T -> (Object.T -> Object.T) -> (Object.T -> Object.T) ->
    84       (Pretty.pp -> Object.T * Object.T -> Object.T) -> serial
    85     val init: serial -> theory -> theory
    86     val get: serial -> (Object.T -> 'a) -> theory -> 'a
    87     val put: serial -> ('a -> Object.T) -> 'a -> theory -> theory
    88   end
    89   structure ProofData:
    90   sig
    91     val declare: string -> (theory -> Object.T) -> serial
    92     val init: serial -> theory -> theory
    93     val get: serial -> (Object.T -> 'a) -> proof -> 'a
    94     val put: serial -> ('a -> Object.T) -> 'a -> proof -> proof
    95   end
    96 end;
    97 
    98 structure Context: PRIVATE_CONTEXT =
    99 struct
   100 
   101 (*** theory context ***)
   102 
   103 (** theory data **)
   104 
   105 (* data kinds and access methods *)
   106 
   107 exception DATA_FAIL of exn * string;
   108 
   109 local
   110 
   111 type kind =
   112  {name: string,
   113   empty: Object.T,
   114   copy: Object.T -> Object.T,
   115   extend: Object.T -> Object.T,
   116   merge: Pretty.pp -> Object.T * Object.T -> Object.T};
   117 
   118 val kinds = ref (Inttab.empty: kind Inttab.table);
   119 
   120 fun invoke meth_name meth_fn k =
   121   (case Inttab.lookup (! kinds, k) of
   122     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   123       DATA_FAIL (exn, "Theory data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   124   | NONE => sys_error ("Invalid theory data identifier " ^ string_of_int k));
   125 
   126 in
   127 
   128 fun invoke_name k    = invoke "name" (K o #name) k ();
   129 fun invoke_empty k   = invoke "empty" (K o #empty) k ();
   130 val invoke_copy      = invoke "copy" #copy;
   131 val invoke_extend    = invoke "extend" #extend;
   132 fun invoke_merge pp  = invoke "merge" (fn kind => #merge kind pp);
   133 
   134 fun declare_theory_data name empty copy extend merge =
   135   let
   136     val k = serial ();
   137     val kind = {name = name, empty = empty, copy = copy, extend = extend, merge = merge};
   138     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   139       warning ("Duplicate declaration of theory data " ^ quote name));
   140     val _ = kinds := Inttab.update ((k, kind), ! kinds);
   141   in k end;
   142 
   143 val copy_data = Inttab.map' invoke_copy;
   144 val extend_data = Inttab.map' invoke_extend;
   145 fun merge_data pp = Inttab.join (SOME oo invoke_merge pp) o pairself extend_data;
   146 
   147 end;
   148 
   149 
   150 
   151 (** datatype theory **)
   152 
   153 datatype theory =
   154   Theory of
   155    (*identity*)
   156    {self: theory ref option,            (*dynamic self reference -- follows theory changes*)
   157     id: serial * string,                (*identifier of this theory*)
   158     ids: string Inttab.table,           (*identifiers of ancestors*)
   159     iids: string Inttab.table} *        (*identifiers of intermediate checkpoints*)
   160    (*data*)
   161    {theory: Object.T Inttab.table,      (*theory data record*)
   162     proof: unit Inttab.table} *         (*proof data kinds*)
   163    (*ancestry*)
   164    {parents: theory list,               (*immediate predecessors*)
   165     ancestors: theory list} *           (*all predecessors*)
   166    (*history*)
   167    {name: string,                       (*prospective name of finished theory*)
   168     version: int,                       (*checkpoint counter*)
   169     intermediates: theory list};        (*intermediate checkpoints*)
   170 
   171 exception THEORY of string * theory list;
   172 
   173 fun rep_theory (Theory args) = args;
   174 
   175 val identity_of = #1 o rep_theory;
   176 val data_of     = #2 o rep_theory;
   177 val ancestry_of = #3 o rep_theory;
   178 val history_of  = #4 o rep_theory;
   179 
   180 fun make_identity self id ids iids = {self = self, id = id, ids = ids, iids = iids};
   181 fun make_data theory proof = {theory = theory, proof = proof};
   182 fun make_ancestry parents ancestors = {parents = parents, ancestors = ancestors};
   183 fun make_history name vers ints = {name = name, version = vers, intermediates = ints};
   184 
   185 fun map_theory f {theory, proof} = make_data (f theory) proof;
   186 fun map_proof f {theory, proof} = make_data theory (f proof);
   187 
   188 val the_self = the o #self o identity_of;
   189 val parents_of = #parents o ancestry_of;
   190 val ancestors_of = #ancestors o ancestry_of;
   191 val theory_name = #name o history_of;
   192 
   193 
   194 (* staleness *)
   195 
   196 fun eq_id ((i: int, _), (j, _)) = (i = j);
   197 
   198 fun is_stale
   199     (Theory ({self = SOME (ref (Theory ({id = id', ...}, _, _, _))), id, ...}, _, _, _)) =
   200       not (eq_id (id, id'))
   201   | is_stale (Theory ({self = NONE, ...}, _, _, _)) = true;
   202 
   203 fun vitalize (thy as Theory ({self = SOME r, ...}, _, _, _)) = (r := thy; thy)
   204   | vitalize (thy as Theory ({self = NONE, id, ids, iids}, data, ancestry, history)) =
   205       let
   206         val r = ref thy;
   207         val thy' = Theory (make_identity (SOME r) id ids iids, data, ancestry, history);
   208       in r := thy'; thy' end;
   209 
   210 
   211 (* names *)
   212 
   213 val ProtoPureN = "ProtoPure";
   214 val PureN = "Pure";
   215 val CPureN = "CPure";
   216 
   217 val draftN = "#";
   218 fun draft_id (_, name) = (name = draftN);
   219 val is_draft = draft_id o #id o identity_of;
   220 
   221 fun exists_name name (Theory ({id, ids, iids, ...}, _, _, _)) =
   222   name = #2 id orelse
   223   Inttab.exists (equal name o #2) ids orelse
   224   Inttab.exists (equal name o #2) iids;
   225 
   226 fun names_of (Theory ({id, ids, iids, ...}, _, _, _)) =
   227   rev (#2 id :: Inttab.fold (cons o #2) iids (Inttab.fold (cons o #2) ids []));
   228 
   229 fun pretty_thy thy =
   230   Pretty.str_list "{" "}" (names_of thy @ (if is_stale thy then ["!"] else []));
   231 
   232 val string_of_thy = Pretty.string_of o pretty_thy;
   233 val pprint_thy = Pretty.pprint o pretty_thy;
   234 
   235 fun pretty_abbrev_thy thy =
   236   let
   237     val names = names_of thy;
   238     val n = length names;
   239     val abbrev = if n > 5 then "..." :: List.drop (names, n - 5) else names;
   240   in Pretty.str_list "{" "}" abbrev end;
   241 
   242 val str_of_thy = Pretty.str_of o pretty_abbrev_thy;
   243 
   244 
   245 (* consistency *)    (*exception TERM*)
   246 
   247 fun check_thy pos thy =
   248   if is_stale thy then
   249     raise TERM ("Stale theory encountered (in " ^ pos ^ "):\n" ^ string_of_thy thy, [])
   250   else thy;
   251 
   252 fun check_ins id ids =
   253   if draft_id id orelse is_some (Inttab.lookup (ids, #1 id)) then ids
   254   else if Inttab.exists (equal (#2 id) o #2) ids then
   255     raise TERM ("Different versions of theory component " ^ quote (#2 id), [])
   256   else Inttab.update (id, ids);
   257 
   258 fun check_insert intermediate id (ids, iids) =
   259   let val ids' = check_ins id ids and iids' = check_ins id iids
   260   in if intermediate then (ids, iids') else (ids', iids) end;
   261 
   262 fun check_merge
   263     (Theory ({id = id1, ids = ids1, iids = iids1, ...}, _, _, history1))
   264     (Theory ({id = id2, ids = ids2, iids = iids2, ...}, _, _, history2)) =
   265   (Inttab.fold check_ins ids2 ids1, Inttab.fold check_ins iids2 iids1)
   266   |> check_insert (#version history1 > 0) id1
   267   |> check_insert (#version history2 > 0) id2;
   268 
   269 
   270 (* equality and inclusion *)
   271 
   272 val eq_thy = eq_id o pairself (#id o identity_of o check_thy "Context.eq_thy");
   273 
   274 fun proper_subthy
   275   (thy1 as Theory ({id = (i, _), ...}, _, _, _),
   276     thy2 as Theory ({ids, iids, ...}, _, _, _)) =
   277   (pairself (check_thy "Context.proper_subthy") (thy1, thy2);
   278     is_some (Inttab.lookup (ids, i)) orelse is_some (Inttab.lookup (iids, i)));
   279 
   280 fun subthy thys = eq_thy thys orelse proper_subthy thys;
   281 
   282 
   283 (* theory references *)
   284 
   285 (*theory_ref provides a safe way to store dynamic references to a
   286   theory in external data structures -- a plain theory value would
   287   become stale as the self reference moves on*)
   288 
   289 datatype theory_ref = TheoryRef of theory ref;
   290 
   291 val self_ref = TheoryRef o the_self o check_thy "Context.self_ref";
   292 fun deref (TheoryRef (ref thy)) = thy;
   293 
   294 
   295 (* trivial merge *)    (*exception TERM*)
   296 
   297 fun merge (thy1, thy2) =
   298   if subthy (thy2, thy1) then thy1
   299   else if subthy (thy1, thy2) then thy2
   300   else (check_merge thy1 thy2;
   301     raise TERM (cat_lines ["Attempt to perform non-trivial merge of theories:",
   302       str_of_thy thy1, str_of_thy thy2], []));
   303 
   304 fun merge_refs (ref1, ref2) = self_ref (merge (deref ref1, deref ref2));
   305 
   306 
   307 
   308 (** build theories **)
   309 
   310 (* primitives *)
   311 
   312 fun create_thy name self id ids iids data ancestry history =
   313   let
   314     val intermediate = #version history > 0;
   315     val (ids', iids') = check_insert intermediate id (ids, iids);
   316     val id' = (serial (), name);
   317     val _ = check_insert intermediate id' (ids', iids');
   318     val identity' = make_identity self id' ids' iids';
   319   in vitalize (Theory (identity', data, ancestry, history)) end;
   320 
   321 fun change_thy name f (thy as Theory ({self, id, ids, iids}, data, ancestry, history)) =
   322   let
   323     val _ = check_thy "Context.change_thy" thy;
   324     val (self', data', ancestry') =
   325       if is_draft thy then (self, data, ancestry)    (*destructive change!*)
   326       else if #version history > 0
   327       then (NONE, map_theory copy_data data, ancestry)
   328       else (NONE, map_theory extend_data data, make_ancestry [thy] (thy :: #ancestors ancestry));
   329     val data'' = f data';
   330   in create_thy name self' id ids iids data'' ancestry' history end;
   331 
   332 fun name_thy name = change_thy name I;
   333 val modify_thy = change_thy draftN;
   334 val extend_thy = modify_thy I;
   335 
   336 fun copy_thy (thy as Theory ({id, ids, iids, ...}, data, ancestry, history)) =
   337   (check_thy "Context.copy_thy" thy;
   338     create_thy draftN NONE id ids iids (map_theory copy_data data) ancestry history);
   339 
   340 val pre_pure_thy = create_thy draftN NONE (serial (), draftN) Inttab.empty Inttab.empty
   341   (make_data Inttab.empty Inttab.empty) (make_ancestry [] []) (make_history ProtoPureN 0 []);
   342 
   343 
   344 (* named theory nodes *)
   345 
   346 fun merge_thys pp (thy1, thy2) =
   347   if exists_name CPureN thy1 <> exists_name CPureN thy2 then
   348     error "Cannot merge Pure and CPure developments"
   349   else
   350     let
   351       val (ids, iids) = check_merge thy1 thy2;
   352       val data1 = data_of thy1 and data2 = data_of thy2;
   353       val data = make_data
   354         (merge_data (pp thy1) (#theory data1, #theory data2))
   355         (Inttab.merge (K true) (#proof data1, #proof data2));
   356       val ancestry = make_ancestry [] [];
   357       val history = make_history "" 0 [];
   358     in create_thy draftN NONE (serial (), draftN) ids iids data ancestry history end;
   359 
   360 fun maximal_thys thys =
   361   thys |> filter (fn thy => not (exists (fn thy' => proper_subthy (thy, thy')) thys));
   362 
   363 fun begin_thy pp name imports =
   364   if name = draftN then error ("Illegal theory name: " ^ quote draftN)
   365   else
   366     let
   367       val parents =
   368         maximal_thys (gen_distinct eq_thy (map (check_thy "Context.begin_thy") imports));
   369       val ancestors = gen_distinct eq_thy (parents @ List.concat (map ancestors_of parents));
   370       val Theory ({id, ids, iids, ...}, data, _, _) =
   371         (case parents of
   372           [] => error "No parent theories"
   373         | [thy] => extend_thy thy
   374         | thy :: thys => Library.foldl (merge_thys pp) (thy, thys));
   375       val ancestry = make_ancestry parents ancestors;
   376       val history = make_history name 0 [];
   377     in create_thy draftN NONE id ids iids data ancestry history end;
   378 
   379 
   380 (* undoable checkpoints *)
   381 
   382 fun checkpoint_thy thy =
   383   if not (is_draft thy) then thy
   384   else
   385     let
   386       val {name, version, intermediates} = history_of thy;
   387       val thy' as Theory (identity', data', ancestry', _) =
   388         name_thy (name ^ ":" ^ string_of_int version) thy;
   389       val history' = make_history name (version + 1) (thy' :: intermediates);
   390     in vitalize (Theory (identity', data', ancestry', history')) end;
   391 
   392 fun finish_thy thy =
   393   let
   394     val {name, version, intermediates} = history_of thy;
   395     val rs = map (the_self o check_thy "Context.finish_thy") intermediates;
   396     val thy' as Theory ({self, id, ids, ...}, data', ancestry', _) = name_thy name thy;
   397     val identity' = make_identity self id ids Inttab.empty;
   398     val history' = make_history name 0 [];
   399     val thy'' = vitalize (Theory (identity', data', ancestry', history'));
   400     val _ = List.app (fn r => r := thy'') rs;
   401   in thy'' end;
   402 
   403 
   404 (* theory data *)
   405 
   406 fun dest_data name_of tab =
   407   map name_of (Inttab.keys tab)
   408   |> map (rpair ()) |> Symtab.make_multi |> Symtab.dest
   409   |> map (apsnd length)
   410   |> map (fn (name, 1) => name | (name, n) => name ^ enclose "[" "]" (string_of_int n));
   411 
   412 val theory_data_of = dest_data invoke_name o #theory o data_of;
   413 
   414 structure TheoryData =
   415 struct
   416 
   417 val declare = declare_theory_data;
   418 
   419 fun get k dest thy =
   420   (case Inttab.lookup (#theory (data_of thy), k) of
   421     SOME x => (dest x handle Match =>
   422       error ("Failed to access theory data " ^ quote (invoke_name k)))
   423   | NONE => error ("Uninitialized theory data " ^ quote (invoke_name k)));
   424 
   425 fun put k mk x = modify_thy (map_theory (curry Inttab.update (k, mk x)));
   426 fun init k = put k I (invoke_empty k);
   427 
   428 end;
   429 
   430 
   431 
   432 (*** ML theory context ***)
   433 
   434 local
   435   val current_theory = ref (NONE: theory option);
   436 in
   437   fun get_context () = ! current_theory;
   438   fun set_context opt_thy = current_theory := opt_thy;
   439   fun setmp opt_thy f x = Library.setmp current_theory opt_thy f x;
   440 end;
   441 
   442 fun the_context () =
   443   (case get_context () of
   444     SOME thy => thy
   445   | _ => error "Unknown theory context");
   446 
   447 fun context thy = set_context (SOME thy);
   448 fun reset_context () = set_context NONE;
   449 
   450 fun pass opt_thy f x =
   451   setmp opt_thy (fn x => let val y = f x in (y, get_context ()) end) x;
   452 
   453 fun pass_theory thy f x =
   454   (case pass (SOME thy) f x of
   455     (y, SOME thy') => (y, thy')
   456   | (_, NONE) => error "Lost theory context in ML");
   457 
   458 fun save f x = setmp (get_context ()) f x;
   459 
   460 
   461 (* map context *)
   462 
   463 nonfix >>;
   464 fun >> f = set_context (SOME (f (the_context ())));
   465 
   466 
   467 (* use ML text *)
   468 
   469 val ml_output = (writeln, error_msg);
   470 
   471 fun use_output verb txt = use_text ml_output verb (Symbol.escape txt);
   472 
   473 fun use_mltext txt verb opt_thy = setmp opt_thy (fn () => use_output verb txt) ();
   474 fun use_mltext_theory txt verb thy = #2 (pass_theory thy (use_output verb) txt);
   475 
   476 fun use_context txt = use_mltext_theory ("Context.>> (" ^ txt ^ ");") false;
   477 
   478 fun use_let bind body txt =
   479   use_context ("let " ^ bind ^ " = " ^ txt ^ " in\n" ^ body ^ " end");
   480 
   481 
   482 (* delayed theory setup *)
   483 
   484 local
   485   val setup_fns = ref ([]: (theory -> theory) list);
   486 in
   487   fun add_setup fns = setup_fns := ! setup_fns @ fns;
   488   fun setup () = let val fns = ! setup_fns in setup_fns := []; fns end;
   489 end;
   490 
   491 
   492 
   493 (*** proof context ***)
   494 
   495 (* datatype proof *)
   496 
   497 datatype proof = Proof of theory * Object.T Inttab.table;
   498 
   499 fun theory_of_proof (Proof (thy, _)) = thy;
   500 fun data_of_proof (Proof (_, data)) = data;
   501 fun map_prf f (Proof (thy, data)) = Proof (thy, f data);
   502 
   503 
   504 (* proof data kinds *)
   505 
   506 local
   507 
   508 type kind =
   509  {name: string,
   510   init: theory -> Object.T};
   511 
   512 val kinds = ref (Inttab.empty: kind Inttab.table);
   513 
   514 fun invoke meth_name meth_fn k =
   515   (case Inttab.lookup (! kinds, k) of
   516     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   517       DATA_FAIL (exn, "Proof data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   518   | NONE => sys_error ("Invalid proof data identifier " ^ string_of_int k));
   519 
   520 fun invoke_name k = invoke "name" (K o #name) k ();
   521 val invoke_init   = invoke "init" #init;
   522 
   523 in
   524 
   525 val proof_data_of = dest_data invoke_name o #proof o data_of;
   526 
   527 fun init_proof thy =
   528   Proof (thy, Inttab.map' (fn k => fn _ => invoke_init k thy) (#proof (data_of thy)));
   529 
   530 structure ProofData =
   531 struct
   532 
   533 fun declare name init =
   534   let
   535     val k = serial ();
   536     val kind = {name = name, init = init};
   537     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   538       warning ("Duplicate declaration of proof data " ^ quote name));
   539     val _ = kinds := Inttab.update ((k, kind), ! kinds);
   540   in k end;
   541 
   542 fun init k = modify_thy (map_proof (curry Inttab.update (k, ())));
   543 
   544 fun get k dest prf =
   545   (case Inttab.lookup (data_of_proof prf, k) of
   546     SOME x => (dest x handle Match =>
   547       error ("Failed to access proof data " ^ quote (invoke_name k)))
   548   | NONE => error ("Uninitialized proof data " ^ quote (invoke_name k)));
   549 
   550 fun put k mk x = map_prf (curry Inttab.update (k, mk x));
   551 
   552 end;
   553 
   554 end;
   555 
   556 
   557 (*** generic context ***)
   558 
   559 datatype context = Theory of theory | Proof of proof;
   560 
   561 fun theory_of (Theory thy) = thy
   562   | theory_of (Proof prf) = theory_of_proof prf;
   563 
   564 fun proof_of (Theory thy) = init_proof thy
   565   | proof_of (Proof prf) = prf;
   566 
   567 end;
   568 
   569 structure BasicContext: BASIC_CONTEXT = Context;
   570 open BasicContext;
   571 
   572 
   573 
   574 (*** type-safe interfaces for data declarations ***)
   575 
   576 (** theory data **)
   577 
   578 signature THEORY_DATA_ARGS =
   579 sig
   580   val name: string
   581   type T
   582   val empty: T
   583   val copy: T -> T
   584   val extend: T -> T
   585   val merge: Pretty.pp -> T * T -> T
   586   val print: theory -> T -> unit
   587 end;
   588 
   589 signature THEORY_DATA =
   590 sig
   591   type T
   592   val init: theory -> theory
   593   val print: theory -> unit
   594   val get: theory -> T
   595   val get_sg: theory -> T    (*obsolete*)
   596   val put: T -> theory -> theory
   597   val map: (T -> T) -> theory -> theory
   598 end;
   599 
   600 functor TheoryDataFun(Data: THEORY_DATA_ARGS): THEORY_DATA =
   601 struct
   602 
   603 structure TheoryData = Context.TheoryData;
   604 
   605 type T = Data.T;
   606 exception Data of T;
   607 
   608 val kind = TheoryData.declare Data.name
   609   (Data Data.empty)
   610   (fn Data x => Data (Data.copy x))
   611   (fn Data x => Data (Data.extend x))
   612   (fn pp => fn (Data x1, Data x2) => Data (Data.merge pp (x1, x2)));
   613 
   614 val init = TheoryData.init kind;
   615 val get = TheoryData.get kind (fn Data x => x);
   616 val get_sg = get;
   617 fun print thy = Data.print thy (get thy);
   618 val put = TheoryData.put kind Data;
   619 fun map f thy = put (f (get thy)) thy;
   620 
   621 end;
   622 
   623 
   624 
   625 (** proof data **)
   626 
   627 signature PROOF_DATA_ARGS =
   628 sig
   629   val name: string
   630   type T
   631   val init: theory -> T
   632   val print: Context.proof -> T -> unit
   633 end;
   634 
   635 signature PROOF_DATA =
   636 sig
   637   type T
   638   val init: theory -> theory
   639   val print: Context.proof -> unit
   640   val get: Context.proof -> T
   641   val put: T -> Context.proof -> Context.proof
   642   val map: (T -> T) -> Context.proof -> Context.proof
   643 end;
   644 
   645 functor ProofDataFun(Data: PROOF_DATA_ARGS): PROOF_DATA =
   646 struct
   647 
   648 structure ProofData = Context.ProofData;
   649 
   650 type T = Data.T;
   651 exception Data of T;
   652 
   653 val kind = ProofData.declare Data.name (Data o Data.init);
   654 
   655 val init = ProofData.init kind;
   656 val get = ProofData.get kind (fn Data x => x);
   657 fun print prf = Data.print prf (get prf);
   658 val put = ProofData.put kind Data;
   659 fun map f prf = put (f (get prf)) prf;
   660 
   661 end;
   662 
   663 (*hide private interface*)
   664 structure Context: CONTEXT = Context;