src/Pure/Isar/class.ML
author wenzelm
Sat Oct 13 17:16:44 2007 +0200 (2007-10-13)
changeset 25020 f1344290e420
parent 25010 8bc74ba1423d
child 25024 0615bb9955dd
permissions -rw-r--r--
(un)overload: full rewrite;
use Attrib.attribute_i for internal args;
misc tuning;
     1 (*  Title:      Pure/Isar/class.ML
     2     ID:         $Id$
     3     Author:     Florian Haftmann, TU Muenchen
     4 
     5 Type classes derived from primitive axclasses and locales.
     6 *)
     7 
     8 signature CLASS =
     9 sig
    10   val fork_mixfix: bool -> bool -> mixfix -> mixfix * mixfix
    11 
    12   val axclass_cmd: bstring * xstring list
    13     -> ((bstring * Attrib.src list) * string list) list
    14     -> theory -> class * theory
    15   val classrel_cmd: xstring * xstring -> theory -> Proof.state
    16 
    17   val class: bstring -> class list -> Element.context_i Locale.element list
    18     -> string list -> theory -> string * Proof.context
    19   val class_cmd: bstring -> xstring list -> Element.context Locale.element list
    20     -> xstring list -> theory -> string * Proof.context
    21   val init: class -> Proof.context -> Proof.context;
    22   val add_const_in_class: string -> (string * term) * Syntax.mixfix
    23     -> theory -> string * theory
    24   val add_abbrev_in_class: string -> Syntax.mode -> (string * term) * mixfix
    25     -> theory -> string * theory
    26   val remove_constraint: class -> string -> Proof.context -> Proof.context
    27   val class_of_locale: theory -> string -> class option
    28   val locale_of_class: theory -> class -> string
    29   val these_params: theory -> sort -> (string * (string * typ)) list
    30   val intro_classes_tac: thm list -> tactic
    31   val default_intro_classes_tac: thm list -> tactic
    32   val print_classes: theory -> unit
    33   val uncheck: bool ref
    34 
    35   val instance_arity: (theory -> theory) -> arity list -> theory -> Proof.state
    36   val instance: arity list -> ((bstring * Attrib.src list) * term) list
    37     -> (thm list -> theory -> theory)
    38     -> theory -> Proof.state
    39   val instance_cmd: (bstring * xstring list * xstring) list
    40     -> ((bstring * Attrib.src list) * xstring) list
    41     -> (thm list -> theory -> theory)
    42     -> theory -> Proof.state
    43   val prove_instance: tactic -> arity list
    44     -> ((bstring * Attrib.src list) * term) list
    45     -> theory -> thm list * theory
    46   val unoverload: theory -> conv
    47   val overload: theory -> conv
    48   val unoverload_const: theory -> string * typ -> string
    49   val inst_const: theory -> string * string -> string
    50   val param_const: theory -> string -> (string * string) option
    51 end;
    52 
    53 structure Class : CLASS =
    54 struct
    55 
    56 (** auxiliary **)
    57 
    58 fun fork_mixfix is_locale is_class mx =
    59   let
    60     val mx' = Syntax.unlocalize_mixfix mx;
    61     val mx_global = if not is_locale orelse (is_class andalso not (mx = mx'))
    62       then mx' else NoSyn;
    63     val mx_local = if is_locale then mx else NoSyn;
    64   in (mx_global, mx_local) end;
    65 
    66 fun prove_interpretation tac prfx_atts expr inst =
    67   Locale.interpretation_i I prfx_atts expr inst
    68   #> Proof.global_terminal_proof
    69       (Method.Basic (K (Method.SIMPLE_METHOD tac), Position.none), NONE)
    70   #> ProofContext.theory_of;
    71 
    72 fun OF_LAST thm1 thm2 = thm1 RSN (Thm.nprems_of thm2, thm2);
    73 
    74 fun strip_all_ofclass thy sort =
    75   let
    76     val typ = TVar ((Name.aT, 0), sort);
    77     fun prem_inclass t =
    78       case Logic.strip_imp_prems t
    79        of ofcls :: _ => try Logic.dest_inclass ofcls
    80         | [] => NONE;
    81     fun strip_ofclass class thm =
    82       thm OF (fst o AxClass.of_sort thy (typ, [class])) AxClass.cache;
    83     fun strip thm = case (prem_inclass o Thm.prop_of) thm
    84      of SOME (_, class) => thm |> strip_ofclass class |> strip
    85       | NONE => thm;
    86   in strip end;
    87 
    88 
    89 (** axclass command **)
    90 
    91 fun axclass_cmd (class, raw_superclasses) raw_specs thy =
    92   let
    93     val ctxt = ProofContext.init thy;
    94     val superclasses = map (Sign.read_class thy) raw_superclasses;
    95     val name_atts = map ((apsnd o map) (Attrib.attribute thy) o fst)
    96       raw_specs;
    97     val axiomss = ProofContext.read_propp (ctxt, map (map (rpair []) o snd)
    98           raw_specs)
    99       |> snd
   100       |> (map o map) fst;
   101   in
   102     AxClass.define_class (class, superclasses) []
   103       (name_atts ~~ axiomss) thy
   104   end;
   105 
   106 local
   107 
   108 fun gen_instance mk_prop add_thm after_qed insts thy =
   109   let
   110     fun after_qed' results =
   111       ProofContext.theory ((fold o fold) add_thm results #> after_qed);
   112   in
   113     thy
   114     |> ProofContext.init
   115     |> Proof.theorem_i NONE after_qed' ((map (fn t => [(t, [])])
   116         o maps (mk_prop thy)) insts)
   117   end;
   118 
   119 in
   120 
   121 val instance_arity =
   122   gen_instance (Logic.mk_arities oo Sign.cert_arity) AxClass.add_arity;
   123 val classrel =
   124   gen_instance (single oo (Logic.mk_classrel oo AxClass.cert_classrel))
   125     AxClass.add_classrel I o single;
   126 val classrel_cmd =
   127   gen_instance (single oo (Logic.mk_classrel oo AxClass.read_classrel))
   128     AxClass.add_classrel I o single;
   129 
   130 end; (*local*)
   131 
   132 
   133 (** explicit constants for overloaded definitions **)
   134 
   135 structure InstData = TheoryDataFun
   136 (
   137   type T = (string * thm) Symtab.table Symtab.table * (string * string) Symtab.table;
   138     (*constant name ~> type constructor ~> (constant name, equation),
   139         constant name ~> (constant name, type constructor)*)
   140   val empty = (Symtab.empty, Symtab.empty);
   141   val copy = I;
   142   val extend = I;
   143   fun merge _ ((taba1, tabb1), (taba2, tabb2)) =
   144     (Symtab.join (K (Symtab.merge (K true))) (taba1, taba2),
   145       Symtab.merge (K true) (tabb1, tabb2));
   146 );
   147 
   148 fun inst_thms thy = (Symtab.fold (Symtab.fold (cons o snd o snd) o snd) o fst)
   149     (InstData.get thy) [];
   150 fun add_inst (c, tyco) inst = (InstData.map o apfst
   151       o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   152   #> (InstData.map o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   153 
   154 fun unoverload thy = MetaSimplifier.rewrite true (inst_thms thy);
   155 fun overload thy = MetaSimplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   156 
   157 fun inst_const thy (c, tyco) =
   158   (fst o the o Symtab.lookup ((the o Symtab.lookup (fst (InstData.get thy))) c)) tyco;
   159 fun unoverload_const thy (c_ty as (c, _)) =
   160   case AxClass.class_of_param thy c
   161    of SOME class => (case Sign.const_typargs thy c_ty
   162        of [Type (tyco, _)] => (case Symtab.lookup
   163            ((the o Symtab.lookup (fst (InstData.get thy))) c) tyco
   164              of SOME (c, _) => c
   165               | NONE => c)
   166         | [_] => c)
   167     | NONE => c;
   168 
   169 val param_const = Symtab.lookup o snd o InstData.get;
   170 
   171 fun add_inst_def (class, tyco) (c, ty) thy =
   172   let
   173     val tyco_base = NameSpace.base tyco;
   174     val name_inst = NameSpace.base class ^ "_" ^ tyco_base ^ "_inst";
   175     val c_inst_base = NameSpace.base c ^ "_" ^ tyco_base;
   176   in
   177     thy
   178     |> Sign.sticky_prefix name_inst
   179     |> Sign.declare_const [] (c_inst_base, ty, NoSyn)
   180     |-> (fn const as Const (c_inst, _) =>
   181       PureThy.add_defs_i false
   182         [((Thm.def_name c_inst_base, Logic.mk_equals (const, Const (c, ty))), [])]
   183       #-> (fn [thm] => add_inst (c, tyco) (c_inst, Thm.symmetric thm)))
   184     |> Sign.restore_naming thy
   185   end;
   186 
   187 fun add_inst_def' (class, tyco) (c, ty) thy =
   188   if case Symtab.lookup (fst (InstData.get thy)) c
   189    of NONE => true
   190     | SOME tab => is_none (Symtab.lookup tab tyco)
   191   then add_inst_def (class, tyco) (c, Logic.unvarifyT ty) thy
   192   else thy;
   193 
   194 fun add_def ((class, tyco), ((name, prop), atts)) thy =
   195   let
   196     val ((lhs as Const (c, ty), args), rhs) =
   197       (apfst Term.strip_comb o Logic.dest_equals) prop;
   198     fun (*add_inst' def ([], (Const (c_inst, ty))) =
   199           if forall (fn TFree _ => true | _ => false) (Sign.const_typargs thy (c_inst, ty))
   200           then add_inst (c, tyco) (c_inst, def)
   201           else add_inst_def (class, tyco) (c, ty)
   202       |*) add_inst' _ t = add_inst_def (class, tyco) (c, ty);
   203   in
   204     thy
   205     |> PureThy.add_defs_i true [((name, prop), map (Attrib.attribute_i thy) atts)]
   206     |-> (fn [def] => add_inst' def (args, rhs) #> pair def)
   207   end;
   208 
   209 
   210 (** instances with implicit parameter handling **)
   211 
   212 local
   213 
   214 fun gen_read_def thy prep_att parse_prop ((raw_name, raw_atts), raw_t) =
   215   let
   216     val ctxt = ProofContext.init thy;
   217     val t = parse_prop ctxt raw_t |> Syntax.check_prop ctxt;
   218     val ((c, ty), _) = Sign.cert_def ctxt t;
   219     val atts = map (prep_att thy) raw_atts;
   220     val insts = Consts.typargs (Sign.consts_of thy) (c, ty);
   221     val name = case raw_name
   222      of "" => NONE
   223       | _ => SOME raw_name;
   224   in (c, (insts, ((name, t), atts))) end;
   225 
   226 fun read_def_cmd thy = gen_read_def thy Attrib.intern_src Syntax.parse_prop;
   227 fun read_def thy = gen_read_def thy (K I) (K I);
   228 
   229 fun gen_instance prep_arity read_def do_proof raw_arities raw_defs after_qed theory =
   230   let
   231     val arities = map (prep_arity theory) raw_arities;
   232     val _ = if null arities then error "At least one arity must be given" else ();
   233     val _ = case (duplicates (op =) o map #1) arities
   234      of [] => ()
   235       | dupl_tycos => error ("Type constructors occur more than once in arities: "
   236           ^ commas_quote dupl_tycos);
   237     fun get_remove_constraint c thy =
   238       let
   239         val ty = Sign.the_const_constraint thy c;
   240       in
   241         thy
   242         |> Sign.add_const_constraint (c, NONE)
   243         |> pair (c, Logic.unvarifyT ty)
   244       end;
   245     fun get_consts_class tyco ty class =
   246       let
   247         val cs = (these o try (#params o AxClass.get_info theory)) class;
   248         val subst_ty = map_type_tfree (K ty);
   249       in
   250         map (fn (c, ty) => (c, ((class, tyco), subst_ty ty))) cs
   251       end;
   252     fun get_consts_sort (tyco, asorts, sort) =
   253       let
   254         val ty = Type (tyco, map (fn (v, sort) => TVar ((v, 0), sort))
   255           (Name.names Name.context Name.aT asorts))
   256       in maps (get_consts_class tyco ty) (Sign.complete_sort theory sort) end;
   257     val cs = maps get_consts_sort arities;
   258     fun mk_typnorm thy (ty, ty_sc) =
   259       case try (Sign.typ_match thy (Logic.varifyT ty_sc, ty)) Vartab.empty
   260        of SOME env => SOME (Logic.varifyT #> Envir.typ_subst_TVars env #> Logic.unvarifyT)
   261         | NONE => NONE;
   262     fun read_defs defs cs thy_read =
   263       let
   264         fun read raw_def cs =
   265           let
   266             val (c, (inst, ((name_opt, t), atts))) = read_def thy_read raw_def;
   267             val ty = Consts.instance (Sign.consts_of thy_read) (c, inst);
   268             val ((class, tyco), ty') = case AList.lookup (op =) cs c
   269              of NONE => error ("Illegal definition for constant " ^ quote c)
   270               | SOME class_ty => class_ty;
   271             val name = case name_opt
   272              of NONE => Thm.def_name (Logic.name_arity (tyco, [], c))
   273               | SOME name => name;
   274             val t' = case mk_typnorm thy_read (ty', ty)
   275              of NONE => error ("Illegal definition for constant " ^
   276                   quote (c ^ "::" ^ setmp show_sorts true
   277                     (Sign.string_of_typ thy_read) ty))
   278               | SOME norm => map_types norm t
   279           in (((class, tyco), ((name, t'), atts)), AList.delete (op =) c cs) end;
   280       in fold_map read defs cs end;
   281     val (defs, other_cs) = read_defs raw_defs cs
   282       (fold Sign.primitive_arity arities (Theory.copy theory));
   283     fun after_qed' cs defs =
   284       fold Sign.add_const_constraint (map (apsnd SOME) cs)
   285       #> after_qed defs;
   286   in
   287     theory
   288     |> fold_map get_remove_constraint (map fst cs |> distinct (op =))
   289     ||>> fold_map add_def defs
   290     ||> fold (fn (c, ((class, tyco), ty)) => add_inst_def' (class, tyco) (c, ty)) other_cs
   291     |-> (fn (cs, defs) => do_proof (after_qed' cs defs) arities defs)
   292   end;
   293 
   294 fun tactic_proof tac f arities defs =
   295   fold (fn arity => AxClass.prove_arity arity tac) arities
   296   #> f
   297   #> pair defs;
   298 
   299 in
   300 
   301 val instance = gen_instance Sign.cert_arity read_def
   302   (fn f => fn arities => fn defs => instance_arity f arities);
   303 val instance_cmd = gen_instance Sign.read_arity read_def_cmd
   304   (fn f => fn arities => fn defs => instance_arity f arities);
   305 fun prove_instance tac arities defs =
   306   gen_instance Sign.cert_arity read_def
   307     (tactic_proof tac) arities defs (K I);
   308 
   309 end; (*local*)
   310 
   311 
   312 
   313 (** class data **)
   314 
   315 datatype class_data = ClassData of {
   316   locale: string,
   317   consts: (string * string) list
   318     (*locale parameter ~> constant name*),
   319   local_sort: sort,
   320   inst: typ Symtab.table * term Symtab.table
   321     (*canonical interpretation*),
   322   intro: thm,
   323   defs: thm list,
   324   operations: (string * (term * (typ * int))) list
   325     (*constant name ~> (locale term, (constant constraint, instantiaton index of class typ))*),
   326   operations_rev: (string * string) list
   327     (*locale operation ~> constant name*)
   328 };
   329 
   330 fun rep_class_data (ClassData d) = d;
   331 fun mk_class_data ((locale, consts, local_sort, inst, intro),
   332     (defs, operations, operations_rev)) =
   333   ClassData { locale = locale, consts = consts, local_sort = local_sort, inst = inst,
   334     intro = intro, defs = defs, operations = operations,
   335     operations_rev = operations_rev };
   336 fun map_class_data f (ClassData { locale, consts, local_sort, inst, intro,
   337     defs, operations, operations_rev }) =
   338   mk_class_data (f ((locale, consts, local_sort, inst, intro),
   339     (defs, operations, operations_rev)));
   340 fun merge_class_data _ (ClassData { locale = locale, consts = consts,
   341     local_sort = local_sort, inst = inst, intro = intro,
   342     defs = defs1, operations = operations1, operations_rev = operations_rev1 },
   343   ClassData { locale = _, consts = _, local_sort = _, inst = _, intro = _,
   344     defs = defs2, operations = operations2, operations_rev = operations_rev2 }) =
   345   mk_class_data ((locale, consts, local_sort, inst, intro),
   346     (Thm.merge_thms (defs1, defs2),
   347       AList.merge (op =) (K true) (operations1, operations2),
   348       AList.merge (op =) (K true) (operations_rev1, operations_rev2)));
   349 
   350 fun merge_pair f1 f2 ((x1, y1), (x2, y2)) = (f1 (x1, x2), f2 (y1, y2));
   351 
   352 structure ClassData = TheoryDataFun
   353 (
   354   type T = class_data Graph.T * class Symtab.table
   355     (*locale name ~> class name*);
   356   val empty = (Graph.empty, Symtab.empty);
   357   val copy = I;
   358   val extend = I;
   359   fun merge _ = merge_pair (Graph.join merge_class_data) (Symtab.merge (K true));
   360 );
   361 
   362 
   363 (* queries *)
   364 
   365 val lookup_class_data = Option.map rep_class_data oo try o Graph.get_node
   366   o fst o ClassData.get;
   367 fun class_of_locale thy = Symtab.lookup ((snd o ClassData.get) thy);
   368 
   369 fun the_class_data thy class = case lookup_class_data thy class
   370  of NONE => error ("Undeclared class " ^ quote class)
   371   | SOME data => data;
   372 
   373 val locale_of_class = #locale oo the_class_data;
   374 
   375 val ancestry = Graph.all_succs o fst o ClassData.get;
   376 
   377 fun these_params thy =
   378   let
   379     fun params class =
   380       let
   381         val const_typs = (#params o AxClass.get_info thy) class;
   382         val const_names = (#consts o the_class_data thy) class;
   383       in
   384         (map o apsnd) (fn c => (c, (the o AList.lookup (op =) const_typs) c)) const_names
   385       end;
   386   in maps params o ancestry thy end;
   387 
   388 fun these_defs thy = maps (these o Option.map #defs o lookup_class_data thy) o ancestry thy;
   389 
   390 fun these_intros thy =
   391   Graph.fold (fn (_, (data, _)) => insert Thm.eq_thm ((#intro o rep_class_data) data))
   392     ((fst o ClassData.get) thy) [];
   393 
   394 fun these_operations thy =
   395   maps (#operations o the_class_data thy) o ancestry thy;
   396 
   397 fun these_operations_rev thy =
   398   maps (#operations_rev o the_class_data thy) o ancestry thy;
   399 
   400 fun local_operation thy = AList.lookup (op =) o these_operations thy;
   401 
   402 fun global_operation thy = AList.lookup (op =) o these_operations_rev thy;
   403 
   404 fun sups_local_sort thy sort =
   405   let
   406     val sups = filter (is_some o lookup_class_data thy) sort
   407       |> Sign.minimize_sort thy;
   408     val local_sort = case sups
   409      of sup :: _ => #local_sort (the_class_data thy sup)
   410       | [] => sort;
   411   in (sups, local_sort) end;
   412 
   413 fun print_classes thy =
   414   let
   415     val ctxt = ProofContext.init thy;
   416 
   417     val algebra = Sign.classes_of thy;
   418     val arities =
   419       Symtab.empty
   420       |> Symtab.fold (fn (tyco, arities) => fold (fn (class, _) =>
   421            Symtab.map_default (class, []) (insert (op =) tyco)) arities)
   422              ((#arities o Sorts.rep_algebra) algebra);
   423     val the_arities = these o Symtab.lookup arities;
   424     fun mk_arity class tyco =
   425       let
   426         val Ss = Sorts.mg_domain algebra tyco [class];
   427       in Syntax.pretty_arity ctxt (tyco, Ss, [class]) end;
   428     fun mk_param (c, ty) = Pretty.str (Sign.extern_const thy c ^ " :: "
   429       ^ setmp show_sorts false (Syntax.string_of_typ ctxt o Type.strip_sorts) ty);
   430     fun mk_entry class = (Pretty.block o Pretty.fbreaks o map_filter I) [
   431       (SOME o Pretty.str) ("class " ^ class ^ ":"),
   432       (SOME o Pretty.block) [Pretty.str "supersort: ",
   433         (Syntax.pretty_sort ctxt o Sign.minimize_sort thy o Sign.super_classes thy) class],
   434       Option.map (Pretty.str o prefix "locale: " o #locale) (lookup_class_data thy class),
   435       ((fn [] => NONE | ps => (SOME o Pretty.block o Pretty.fbreaks) (Pretty.str "parameters:" :: ps)) o map mk_param
   436         o these o Option.map #params o try (AxClass.get_info thy)) class,
   437       (SOME o Pretty.block o Pretty.breaks) [
   438         Pretty.str "instances:",
   439         Pretty.list "" "" (map (mk_arity class) (the_arities class))
   440       ]
   441     ]
   442   in
   443     (Pretty.writeln o Pretty.chunks o separate (Pretty.str "")
   444       o map mk_entry o Sorts.all_classes) algebra
   445   end;
   446 
   447 
   448 (* updaters *)
   449 
   450 fun add_class_data ((class, superclasses), (locale, cs, local_sort, inst, intro)) =
   451   let
   452     val operations = map (fn (v_ty, (c, ty)) => (c, (Free v_ty, (ty, 0)))) cs;
   453     val cs = (map o pairself) fst cs;
   454     val add_class = Graph.new_node (class, mk_class_data ((locale,
   455           cs, local_sort, inst, intro),
   456             ([], operations, [])))
   457       #> fold (curry Graph.add_edge class) superclasses;
   458     val add_locale = Symtab.update (locale, class);
   459   in
   460     ClassData.map (fn (gr, tab) => (add_class gr, add_locale tab))
   461   end;
   462 
   463 fun register_operation class (entry, some_def) =
   464   (ClassData.map o apfst o Graph.map_node class o map_class_data o apsnd)
   465     (fn (defs, operations, operations_rev) =>
   466       (case some_def of NONE => defs | SOME def => def :: defs,
   467         entry :: operations, (*FIXME*)operations_rev));
   468 
   469 
   470 (** rule calculation, tactics and methods **)
   471 
   472 fun class_intro thy locale class sups =
   473   let
   474     fun class_elim class =
   475       case (#axioms o AxClass.get_info thy) class
   476        of [thm] => SOME (Drule.unconstrainTs thm)
   477         | [] => NONE;
   478     val pred_intro = case Locale.intros thy locale
   479      of ([ax_intro], [intro]) => intro |> OF_LAST ax_intro |> SOME
   480       | ([intro], []) => SOME intro
   481       | ([], [intro]) => SOME intro
   482       | _ => NONE;
   483     val pred_intro' = pred_intro
   484       |> Option.map (fn intro => intro OF map_filter class_elim sups);
   485     val class_intro = (#intro o AxClass.get_info thy) class;
   486     val raw_intro = case pred_intro'
   487      of SOME pred_intro => class_intro |> OF_LAST pred_intro
   488       | NONE => class_intro;
   489     val sort = Sign.super_classes thy class;
   490     val typ = TVar ((Name.aT, 0), sort);
   491     val defs = these_defs thy sups;
   492   in
   493     raw_intro
   494     |> Drule.instantiate' [SOME (Thm.ctyp_of thy typ)] []
   495     |> strip_all_ofclass thy sort
   496     |> Thm.strip_shyps
   497     |> MetaSimplifier.rewrite_rule defs
   498     |> Drule.unconstrainTs
   499   end;
   500 
   501 fun class_interpretation class facts defs thy =
   502   let
   503     val { locale, inst, ... } = the_class_data thy class;
   504     val tac = ALLGOALS (ProofContext.fact_tac facts);
   505     val prfx = Logic.const_of_class (NameSpace.base class);
   506   in
   507     prove_interpretation tac ((false, prfx), []) (Locale.Locale locale)
   508       (inst, defs) thy
   509   end;
   510 
   511 fun interpretation_in_rule thy (class1, class2) =
   512   let
   513     val ctxt = ProofContext.init thy;
   514     fun mk_axioms class =
   515       let
   516         val { locale, inst = (_, insttab), ... } = the_class_data thy class;
   517       in
   518         Locale.global_asms_of thy locale
   519         |> maps snd
   520         |> (map o map_aterms) (fn Free (s, _) => (the o Symtab.lookup insttab) s | t => t)
   521         |> (map o map_types o map_atyps) (fn TFree _ => TFree (Name.aT, [class1]) | T => T)
   522         |> map (ObjectLogic.ensure_propT thy)
   523       end;
   524     val (prems, concls) = pairself mk_axioms (class1, class2);
   525   in
   526     Goal.prove_global thy [] prems (Logic.mk_conjunction_list concls)
   527       (Locale.intro_locales_tac true ctxt)
   528   end;
   529 
   530 fun intro_classes_tac facts st =
   531   let
   532     val thy = Thm.theory_of_thm st;
   533     val classes = Sign.all_classes thy;
   534     val class_trivs = map (Thm.class_triv thy) classes;
   535     val class_intros = these_intros thy;
   536     val axclass_intros = map_filter (try (#intro o AxClass.get_info thy)) classes;
   537   in
   538     (ALLGOALS (Method.insert_tac facts THEN'
   539       REPEAT_ALL_NEW (resolve_tac (class_trivs @ class_intros @ axclass_intros)))
   540     THEN Tactic.distinct_subgoals_tac) st
   541   end;
   542 
   543 fun default_intro_classes_tac [] = intro_classes_tac []
   544   | default_intro_classes_tac _ = no_tac;
   545 
   546 fun default_tac rules ctxt facts =
   547   HEADGOAL (Method.some_rule_tac rules ctxt facts) ORELSE
   548     default_intro_classes_tac facts;
   549 
   550 val _ = Context.add_setup (Method.add_methods
   551  [("intro_classes", Method.no_args (Method.METHOD intro_classes_tac),
   552     "back-chain introduction rules of classes"),
   553   ("default", Method.thms_ctxt_args (Method.METHOD oo default_tac),
   554     "apply some intro/elim rule")]);
   555 
   556 
   557 (** classes and class target **)
   558 
   559 (* class context syntax *)
   560 
   561 fun internal_remove_constraint local_sort (c, (_, (ty, typidx))) ctxt =
   562   let
   563     val consts = ProofContext.consts_of ctxt;
   564     val typargs = Consts.typargs consts (c, ty);
   565     val typargs' = nth_map typidx (K (TVar ((Name.aT, 0), local_sort))) typargs;
   566     val ty' = Consts.instance consts (c, typargs');
   567   in ProofContext.add_const_constraint (c, SOME ty') ctxt end;
   568 
   569 fun remove_constraint class c ctxt =
   570   let
   571     val thy = ProofContext.theory_of ctxt;
   572     val SOME entry = local_operation thy [class] c;
   573   in
   574     internal_remove_constraint
   575       ((#local_sort o the_class_data thy) class) (c, entry) ctxt
   576   end;
   577 
   578 fun sort_term_check sups local_sort ts ctxt =
   579   let
   580     val thy = ProofContext.theory_of ctxt;
   581     val local_operation = local_operation thy sups;
   582     val constraints = these_operations thy sups |> (map o apsnd) (fst o snd);
   583     val consts = ProofContext.consts_of ctxt;
   584     fun check_typ (c, ty) (t', idx) = case nth (Consts.typargs consts (c, ty)) idx
   585      of TFree (v, _) => if v = Name.aT
   586           then apfst (AList.update (op =) ((c, ty), t')) else I
   587       | TVar (vi, _) => if TypeInfer.is_param vi
   588           then apfst (AList.update (op =) ((c, ty), t'))
   589             #> apsnd (insert (op =) vi) else I
   590       | _ => I;
   591     fun add_const (Const (c, ty)) = (case local_operation c
   592          of SOME (t', (_, idx)) => check_typ (c, ty) (t', idx)
   593           | NONE => I)
   594       | add_const _ = I;
   595     val (cs, typarams) = (fold o fold_aterms) add_const ts ([], []);
   596     val ts' = map (map_aterms
   597         (fn t as Const (c, ty) => the_default t (AList.lookup (op =) cs (c, ty)) | t => t)
   598       #> (map_types o map_type_tvar) (fn var as (vi, _) => if member (op =) typarams vi
   599            then TFree (Name.aT, local_sort) else TVar var)) ts;
   600     val ctxt' = fold (ProofContext.add_const_constraint o apsnd SOME) constraints ctxt;
   601   in (ts', ctxt') end;
   602 
   603 val uncheck = ref false;
   604 
   605 fun sort_term_uncheck sups ts ctxt =
   606   let
   607     val thy = ProofContext.theory_of ctxt;
   608     val global_param = AList.lookup (op =) (these_params thy sups) #> Option.map fst;
   609     val global_operation = global_operation thy sups;
   610     fun globalize (t as Free (v, ty)) = (case global_param v
   611          of SOME c => Const (c, ty)
   612           | NONE => t)
   613       | globalize (t as Const (c, ty)) = (case global_operation c
   614          of SOME c => Const (c, ty)
   615           | NONE => t)
   616       | globalize t = t;
   617     val ts' = if ! uncheck then (map o map_aterms) globalize ts else ts;
   618   in (ts', ctxt) end;
   619 
   620 fun init_class_ctxt sups local_sort ctxt =
   621   let
   622     val operations = these_operations (ProofContext.theory_of ctxt) sups;
   623   in
   624     ctxt
   625     |> Variable.declare_term
   626         (Logic.mk_type (TFree (Name.aT, local_sort)))
   627     |> fold (internal_remove_constraint local_sort) operations
   628     |> Context.proof_map (Syntax.add_term_check 50 "class"
   629         (sort_term_check sups local_sort)
   630         #> Syntax.add_term_uncheck 50 "class"
   631           (sort_term_uncheck sups))
   632   end;
   633 
   634 fun init class ctxt =
   635   init_class_ctxt [class]
   636     ((#local_sort o the_class_data (ProofContext.theory_of ctxt)) class) ctxt;
   637 
   638 
   639 (* class definition *)
   640 
   641 local
   642 
   643 fun gen_class_spec prep_class prep_expr process_expr thy raw_supclasses raw_includes_elems =
   644   let
   645     val supclasses = map (prep_class thy) raw_supclasses;
   646     val (sups, local_sort) = sups_local_sort thy supclasses;
   647     val supsort = Sign.minimize_sort thy supclasses;
   648     val suplocales = map (Locale.Locale o #locale o the_class_data thy) sups;
   649     val (raw_elems, includes) = fold_rev (fn Locale.Elem e => apfst (cons e)
   650       | Locale.Expr i => apsnd (cons (prep_expr thy i))) raw_includes_elems ([], []);
   651     val supexpr = Locale.Merge suplocales;
   652     val supparams = (map fst o Locale.parameters_of_expr thy) supexpr;
   653     val supconsts = AList.make (the o AList.lookup (op =) (these_params thy sups))
   654       (map fst supparams);
   655     val mergeexpr = Locale.Merge (suplocales @ includes);
   656     val constrain = Element.Constrains ((map o apsnd o map_atyps)
   657       (fn TFree (_, sort) => TFree (Name.aT, sort)) supparams);
   658   in
   659     ProofContext.init thy
   660     |> Locale.cert_expr supexpr [constrain]
   661     |> snd
   662     |> init_class_ctxt sups local_sort
   663     |> process_expr Locale.empty raw_elems
   664     |> fst
   665     |> (fn elems => ((((sups, supconsts), (supsort, local_sort, mergeexpr)),
   666           (*FIXME*) if null includes then constrain :: elems else elems)))
   667   end;
   668 
   669 val read_class_spec = gen_class_spec Sign.intern_class Locale.intern_expr Locale.read_expr;
   670 val check_class_spec = gen_class_spec (K I) (K I) Locale.cert_expr;
   671 
   672 fun define_class_params (name, raw_superclasses) raw_consts raw_dep_axioms other_consts thy =
   673   let
   674     val superclasses = map (Sign.certify_class thy) raw_superclasses;
   675     val consts = (map o apfst o apsnd) (Sign.certify_typ thy) raw_consts;
   676     fun add_const ((c, ty), syn) = Sign.declare_const [] (c, ty, syn) #>> Term.dest_Const;
   677     fun mk_axioms cs thy =
   678       raw_dep_axioms thy cs
   679       |> (map o apsnd o map) (Sign.cert_prop thy)
   680       |> rpair thy;
   681     fun constrain_typs class = (map o apsnd o Term.map_type_tfree)
   682       (fn (v, _) => TFree (v, [class]))
   683   in
   684     thy
   685     |> Sign.add_path (Logic.const_of_class name)
   686     |> fold_map add_const consts
   687     ||> Sign.restore_naming thy
   688     |-> (fn cs => mk_axioms cs
   689     #-> (fn axioms_prop => AxClass.define_class (name, superclasses)
   690            (map fst cs @ other_consts) axioms_prop
   691     #-> (fn class => `(fn _ => constrain_typs class cs)
   692     #-> (fn cs' => `(fn thy => AxClass.get_info thy class)
   693     #-> (fn {axioms, ...} => fold (Sign.add_const_constraint o apsnd SOME) cs'
   694     #> pair (class, (cs', axioms)))))))
   695   end;
   696 
   697 fun gen_class prep_spec prep_param bname
   698     raw_supclasses raw_includes_elems raw_other_consts thy =
   699   let
   700     val (((sups, supconsts), (supsort, local_sort, mergeexpr)), elems) =
   701       prep_spec thy raw_supclasses raw_includes_elems;
   702     val other_consts = map (tap (Sign.the_const_type thy) o prep_param thy) raw_other_consts;
   703     fun mk_instT class = Symtab.empty
   704       |> Symtab.update (Name.aT, TFree (Name.aT, [class]));
   705     fun mk_inst class param_names cs =
   706       Symtab.empty
   707       |> fold2 (fn v => fn (c, ty) => Symtab.update (v, Const
   708            (c, Term.map_type_tfree (fn (v, _) => TFree (v, [class])) ty))) param_names cs;
   709     fun extract_params thy name_locale =
   710       let
   711         val params = Locale.parameters_of thy name_locale;
   712         val _ = if Sign.subsort thy (supsort, local_sort) then () else error
   713           ("Sort " ^ Sign.string_of_sort thy local_sort
   714             ^ " is less general than permitted least general sort "
   715             ^ Sign.string_of_sort thy supsort);
   716       in
   717         (map fst params, params
   718         |> (map o apfst o apsnd o Term.map_type_tfree) (K (TFree (Name.aT, local_sort)))
   719         |> (map o apsnd) (fork_mixfix true true #> fst)
   720         |> chop (length supconsts)
   721         |> snd)
   722       end;
   723     fun extract_assumes name_locale params thy cs =
   724       let
   725         val consts = supconsts @ (map (fst o fst) params ~~ cs);
   726         fun subst (Free (c, ty)) =
   727               Const ((fst o the o AList.lookup (op =) consts) c, ty)
   728           | subst t = t;
   729         fun prep_asm ((name, atts), ts) =
   730           ((NameSpace.base name, map (Attrib.attribute_i thy) atts),
   731             (map o map_aterms) subst ts);
   732       in
   733         Locale.global_asms_of thy name_locale
   734         |> map prep_asm
   735       end;
   736     fun note_intro name_axclass class_intro =
   737       PureThy.note_thmss_qualified "" ((Logic.const_of_class o NameSpace.base) name_axclass)
   738         [(("intro", []), [([class_intro], [])])]
   739       #> snd
   740   in
   741     thy
   742     |> Locale.add_locale_i (SOME "") bname mergeexpr elems
   743     |-> (fn name_locale => ProofContext.theory_result (
   744       `(fn thy => extract_params thy name_locale)
   745       #-> (fn (globals, params) =>
   746         define_class_params (bname, supsort) params
   747           (extract_assumes name_locale params) other_consts
   748       #-> (fn (name_axclass, (consts, axioms)) =>
   749         `(fn thy => class_intro thy name_locale name_axclass sups)
   750       #-> (fn class_intro =>
   751         add_class_data ((name_axclass, sups),
   752           (name_locale, map fst params ~~ consts, local_sort,
   753             (mk_instT name_axclass, mk_inst name_axclass (map fst globals)
   754               (map snd supconsts @ consts)), class_intro))
   755       #> note_intro name_axclass class_intro
   756       #> class_interpretation name_axclass axioms []
   757       #> pair name_axclass
   758       )))))
   759   end;
   760 
   761 in
   762 
   763 val class_cmd = gen_class read_class_spec ((#1 o Term.dest_Const) oo Sign.read_const);
   764 val class = gen_class check_class_spec (K I);
   765 
   766 end; (*local*)
   767 
   768 
   769 (* definition in class target *)
   770 
   771 fun export_fixes thy class =
   772   let
   773     val cs = these_params thy [class];
   774     fun subst_aterm (t as Free (v, ty)) = (case AList.lookup (op =) cs v
   775          of SOME (c, _) => Const (c, ty)
   776           | NONE => t)
   777       | subst_aterm t = t;
   778   in Term.map_aterms subst_aterm end;
   779 
   780 fun mk_operation_entry thy (c, rhs) =
   781   let
   782     val ty = Logic.unvarifyT (Sign.the_const_constraint thy c);
   783     val typargs = Sign.const_typargs thy (c, ty);
   784     val typidx = find_index (fn TFree (w, _) => Name.aT = w | _ => false) typargs;
   785   in (c, (rhs, (ty, typidx))) end;
   786 
   787 fun add_const_in_class class ((c, rhs), syn) thy =
   788   let
   789     val prfx = (Logic.const_of_class o NameSpace.base) class;
   790     fun mk_name c =
   791       let
   792         val n1 = Sign.full_name thy c;
   793         val n2 = NameSpace.qualifier n1;
   794         val n3 = NameSpace.base n1;
   795       in NameSpace.implode [n2, prfx, n3] end;
   796     val rhs' = export_fixes thy class rhs;
   797     val subst_typ = Term.map_type_tfree (fn var as (w, sort) =>
   798       if w = Name.aT then TFree (w, [class]) else TFree var);
   799     val ty' = Term.fastype_of rhs';
   800     val ty'' = subst_typ ty';
   801     val c' = mk_name c;
   802     val def = (c, Logic.mk_equals (Const (c', ty'), rhs'));
   803     val (syn', _) = fork_mixfix true true syn;
   804     fun interpret def thy =
   805       let
   806         val def' = symmetric def;
   807         val def_eq = (map_types Logic.unvarifyT o Thm.prop_of) def';
   808       in
   809         thy
   810         |> class_interpretation class [def'] [def_eq]
   811         |> Sign.add_const_constraint (c', SOME ty'')
   812         |> `(fn thy => mk_operation_entry thy (c', rhs))
   813         |-> (fn entry => register_operation class (entry, SOME def'))
   814       end;
   815   in
   816     thy
   817     |> Sign.add_path prfx
   818     |> Sign.declare_const [] (c, ty', syn') |> snd
   819     |> Sign.parent_path
   820     |> Sign.sticky_prefix prfx
   821     |> PureThy.add_defs_i false [(def, [])]
   822     |-> (fn [def] => interpret def)
   823     |> Sign.restore_naming thy
   824     |> pair c'
   825   end;
   826 
   827 
   828 (* abbreviation in class target *)
   829 
   830 fun add_abbrev_in_class class prmode ((c, rhs), syn) thy =
   831   let
   832     val prfx = (Logic.const_of_class o NameSpace.base) class;
   833     fun mk_name c =
   834       let
   835         val n1 = Sign.full_name thy c;
   836         val n2 = NameSpace.qualifier n1;
   837         val n3 = NameSpace.base n1;
   838       in NameSpace.implode [n2, prfx, prfx, n3] end;
   839     val c' = mk_name c;
   840     val rhs' = export_fixes thy class rhs;
   841     val ty' = Term.fastype_of rhs';
   842     val entry = mk_operation_entry thy (c', rhs);
   843   in
   844     thy
   845     |> Sign.notation true prmode [(Const (c', ty'), syn)]
   846     |> register_operation class (entry, NONE)
   847     |> pair c'
   848   end;
   849 
   850 end;