src/Pure/goal_display.ML
author wenzelm
Fri Sep 03 16:09:12 2010 +0200 (2010-09-03)
changeset 39116 f14735a88886
parent 39115 a00da1674c1c
child 39118 12f3788be67b
permissions -rw-r--r--
more explicit Config.declare vs. Config.declare_global;
     1 (*  Title:      Pure/goal_display.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Makarius
     4 
     5 Display tactical goal state.
     6 *)
     7 
     8 signature GOAL_DISPLAY =
     9 sig
    10   val goals_limit: int Unsynchronized.ref
    11   val show_consts_default: bool Unsynchronized.ref
    12   val show_consts_value: Config.value Config.T
    13   val show_consts: bool Config.T
    14   val pretty_flexpair: Proof.context -> term * term -> Pretty.T
    15   val pretty_goals: Proof.context -> {total: bool, main: bool, maxgoals: int} ->
    16     thm -> Pretty.T list
    17   val pretty_goals_without_context: int -> thm -> Pretty.T list
    18 end;
    19 
    20 structure Goal_Display: GOAL_DISPLAY =
    21 struct
    22 
    23 val goals_limit = Unsynchronized.ref 10;     (*max number of goals to print*)
    24 
    25 (*true: show consts with types in proof state output*)
    26 val show_consts_default = Unsynchronized.ref false;
    27 val show_consts_value = Config.declare "show_consts" (fn _ => Config.Bool (! show_consts_default));
    28 val show_consts = Config.bool show_consts_value;
    29 
    30 fun pretty_flexpair ctxt (t, u) = Pretty.block
    31   [Syntax.pretty_term ctxt t, Pretty.str " =?=", Pretty.brk 1, Syntax.pretty_term ctxt u];
    32 
    33 
    34 (*print thm A1,...,An/B in "goal style" -- premises as numbered subgoals*)
    35 
    36 local
    37 
    38 fun ins_entry (x, y) =
    39   AList.default (op =) (x, []) #>
    40   AList.map_entry (op =) x (insert (op =) y);
    41 
    42 val add_consts = Term.fold_aterms
    43   (fn Const (c, T) => ins_entry (T, (c, T))
    44     | _ => I);
    45 
    46 val add_vars = Term.fold_aterms
    47   (fn Free (x, T) => ins_entry (T, (x, ~1))
    48     | Var (xi, T) => ins_entry (T, xi)
    49     | _ => I);
    50 
    51 val add_varsT = Term.fold_atyps
    52   (fn TFree (x, S) => ins_entry (S, (x, ~1))
    53     | TVar (xi, S) => ins_entry (S, xi)
    54     | _ => I);
    55 
    56 fun sort_idxs vs = map (apsnd (sort (prod_ord string_ord int_ord))) vs;
    57 fun sort_cnsts cs = map (apsnd (sort_wrt fst)) cs;
    58 
    59 fun consts_of t = sort_cnsts (add_consts t []);
    60 fun vars_of t = sort_idxs (add_vars t []);
    61 fun varsT_of t = rev (sort_idxs (Term.fold_types add_varsT t []));
    62 
    63 in
    64 
    65 fun pretty_goals ctxt0 {total, main, maxgoals} state =
    66   let
    67     val ctxt = Config.put show_free_types false ctxt0;
    68 
    69     val prt_sort = Syntax.pretty_sort ctxt;
    70     val prt_typ = Syntax.pretty_typ ctxt;
    71     val prt_term = Syntax.pretty_term ctxt;
    72 
    73     fun prt_atoms prt prtT (X, xs) = Pretty.block
    74       [Pretty.block (Pretty.commas (map prt xs)), Pretty.str " ::",
    75         Pretty.brk 1, prtT X];
    76 
    77     fun prt_var (x, ~1) = prt_term (Syntax.free x)
    78       | prt_var xi = prt_term (Syntax.var xi);
    79 
    80     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
    81       | prt_varT xi = prt_typ (TVar (xi, []));
    82 
    83     val prt_consts = prt_atoms (prt_term o Const) prt_typ;
    84     val prt_vars = prt_atoms prt_var prt_typ;
    85     val prt_varsT = prt_atoms prt_varT prt_sort;
    86 
    87 
    88     fun pretty_list _ _ [] = []
    89       | pretty_list name prt lst = [Pretty.big_list name (map prt lst)];
    90 
    91     fun pretty_subgoal (n, A) = Pretty.markup Markup.subgoal
    92       [Pretty.str (" " ^ string_of_int n ^ ". "), prt_term A];
    93     fun pretty_subgoals As = map pretty_subgoal (1 upto length As ~~ As);
    94 
    95     val pretty_ffpairs = pretty_list "flex-flex pairs:" (pretty_flexpair ctxt);
    96 
    97     val pretty_consts = pretty_list "constants:" prt_consts o consts_of;
    98     val pretty_vars = pretty_list "variables:" prt_vars o vars_of;
    99     val pretty_varsT = pretty_list "type variables:" prt_varsT o varsT_of;
   100 
   101 
   102     val {prop, tpairs, ...} = Thm.rep_thm state;
   103     val (As, B) = Logic.strip_horn prop;
   104     val ngoals = length As;
   105 
   106     fun pretty_gs (types, sorts) =
   107       (if main then [prt_term B] else []) @
   108        (if ngoals = 0 then [Pretty.str "No subgoals!"]
   109         else if ngoals > maxgoals then
   110           pretty_subgoals (take maxgoals As) @
   111           (if total then [Pretty.str ("A total of " ^ string_of_int ngoals ^ " subgoals...")]
   112            else [])
   113         else pretty_subgoals As) @
   114       pretty_ffpairs tpairs @
   115       (if Config.get ctxt show_consts then pretty_consts prop else []) @
   116       (if types then pretty_vars prop else []) @
   117       (if sorts then pretty_varsT prop else []);
   118   in
   119     setmp_CRITICAL show_types (! show_types orelse ! show_sorts orelse ! show_all_types)
   120       (setmp_CRITICAL show_sorts false pretty_gs)
   121    (! show_types orelse ! show_sorts orelse ! show_all_types, ! show_sorts)
   122   end;
   123 
   124 fun pretty_goals_without_context n th =
   125   pretty_goals (Syntax.init_pretty_global (Thm.theory_of_thm th))
   126     {total = true, main = true, maxgoals = n} th;
   127 
   128 end;
   129 
   130 end;
   131