src/HOL/Binomial.thy
author haftmann
Fri Jun 19 07:53:35 2015 +0200 (2015-06-19)
changeset 60517 f16e4fb20652
parent 60301 ff82ba1893c8
child 60604 dd4253d5dd82
permissions -rw-r--r--
separate class for notions specific for integral (semi)domains, in contrast to fields where these are trivial
     1 (*  Title       : Binomial.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     5     The integer version of factorial and other additions by Jeremy Avigad.
     6 *)
     7 
     8 section{*Factorial Function, Binomial Coefficients and Binomial Theorem*}
     9 
    10 theory Binomial
    11 imports Main
    12 begin
    13 
    14 subsection {* Factorial *}
    15 
    16 fun fact :: "nat \<Rightarrow> ('a::semiring_char_0)"
    17   where "fact 0 = 1" | "fact (Suc n) = of_nat (Suc n) * fact n"
    18 
    19 lemmas fact_Suc = fact.simps(2)
    20 
    21 lemma fact_1 [simp]: "fact 1 = 1"
    22   by simp
    23 
    24 lemma fact_Suc_0 [simp]: "fact (Suc 0) = Suc 0"
    25   by simp
    26 
    27 lemma of_nat_fact [simp]: "of_nat (fact n) = fact n"
    28   by (induct n) (auto simp add: algebra_simps of_nat_mult)
    29  
    30 lemma fact_reduce: "n > 0 \<Longrightarrow> fact n = of_nat n * fact (n - 1)"
    31   by (cases n) auto
    32 
    33 lemma fact_nonzero [simp]: "fact n \<noteq> (0::'a::{semiring_char_0,semiring_no_zero_divisors})"
    34   apply (induct n)
    35   apply auto
    36   using of_nat_eq_0_iff by fastforce
    37 
    38 lemma fact_mono_nat: "m \<le> n \<Longrightarrow> fact m \<le> (fact n :: nat)"
    39   by (induct n) (auto simp: le_Suc_eq)
    40 
    41 context
    42   assumes "SORT_CONSTRAINT('a::linordered_semidom)"
    43 begin
    44   
    45   lemma fact_mono: "m \<le> n \<Longrightarrow> fact m \<le> (fact n :: 'a)"
    46     by (metis of_nat_fact of_nat_le_iff fact_mono_nat)
    47   
    48   lemma fact_ge_1 [simp]: "fact n \<ge> (1 :: 'a)"
    49     by (metis le0 fact.simps(1) fact_mono)
    50   
    51   lemma fact_gt_zero [simp]: "fact n > (0 :: 'a)"
    52     using fact_ge_1 less_le_trans zero_less_one by blast
    53   
    54   lemma fact_ge_zero [simp]: "fact n \<ge> (0 :: 'a)"
    55     by (simp add: less_imp_le)
    56 
    57   lemma fact_not_neg [simp]: "~ (fact n < (0 :: 'a))"
    58     by (simp add: not_less_iff_gr_or_eq)
    59     
    60   lemma fact_le_power:
    61       "fact n \<le> (of_nat (n^n) ::'a)"
    62   proof (induct n)
    63     case (Suc n)
    64     then have *: "fact n \<le> (of_nat (Suc n ^ n) ::'a)"
    65       by (rule order_trans) (simp add: power_mono)
    66     have "fact (Suc n) = (of_nat (Suc n) * fact n ::'a)"
    67       by (simp add: algebra_simps)
    68     also have "... \<le> (of_nat (Suc n) * of_nat (Suc n ^ n) ::'a)"
    69       by (simp add: "*" ordered_comm_semiring_class.comm_mult_left_mono)
    70     also have "... \<le> (of_nat (Suc n ^ Suc n) ::'a)"
    71       by (metis of_nat_mult order_refl power_Suc)
    72     finally show ?case .
    73   qed simp
    74 
    75 end
    76 
    77 text{*Note that @{term "fact 0 = fact 1"}*}
    78 lemma fact_less_mono_nat: "\<lbrakk>0 < m; m < n\<rbrakk> \<Longrightarrow> fact m < (fact n :: nat)"
    79   by (induct n) (auto simp: less_Suc_eq)
    80 
    81 lemma fact_less_mono:
    82   "\<lbrakk>0 < m; m < n\<rbrakk> \<Longrightarrow> fact m < (fact n :: 'a::linordered_semidom)"
    83   by (metis of_nat_fact of_nat_less_iff fact_less_mono_nat)
    84 
    85 lemma fact_ge_Suc_0_nat [simp]: "fact n \<ge> Suc 0"
    86   by (metis One_nat_def fact_ge_1)
    87 
    88 lemma dvd_fact: 
    89   shows "1 \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> m dvd fact n"
    90   by (induct n) (auto simp: dvdI le_Suc_eq)
    91 
    92 lemma fact_altdef_nat: "fact n = \<Prod>{1..n}"
    93   by (induct n) (auto simp: atLeastAtMostSuc_conv)
    94 
    95 lemma fact_altdef: "fact n = setprod of_nat {1..n}"
    96   by (induct n) (auto simp: atLeastAtMostSuc_conv)
    97 
    98 lemma fact_dvd: "n \<le> m \<Longrightarrow> fact n dvd (fact m :: 'a :: {semiring_div,linordered_semidom})"
    99   by (induct m) (auto simp: le_Suc_eq)
   100 
   101 lemma fact_mod: "m \<le> n \<Longrightarrow> fact n mod (fact m :: 'a :: {semiring_div,linordered_semidom}) = 0"
   102   by (auto simp add: fact_dvd)
   103 
   104 lemma fact_div_fact:
   105   assumes "m \<ge> n"
   106   shows "(fact m) div (fact n) = \<Prod>{n + 1..m}"
   107 proof -
   108   obtain d where "d = m - n" by auto
   109   from assms this have "m = n + d" by auto
   110   have "fact (n + d) div (fact n) = \<Prod>{n + 1..n + d}"
   111   proof (induct d)
   112     case 0
   113     show ?case by simp
   114   next
   115     case (Suc d')
   116     have "fact (n + Suc d') div fact n = Suc (n + d') * fact (n + d') div fact n"
   117       by simp
   118     also from Suc.hyps have "... = Suc (n + d') * \<Prod>{n + 1..n + d'}"
   119       unfolding div_mult1_eq[of _ "fact (n + d')"] by (simp add: fact_mod)
   120     also have "... = \<Prod>{n + 1..n + Suc d'}"
   121       by (simp add: atLeastAtMostSuc_conv)
   122     finally show ?case .
   123   qed
   124   from this `m = n + d` show ?thesis by simp
   125 qed
   126 
   127 lemma fact_num_eq_if: 
   128     "fact m = (if m=0 then 1 else of_nat m * fact (m - 1))"
   129 by (cases m) auto
   130 
   131 lemma fact_eq_rev_setprod_nat: "fact k = (\<Prod>i<k. k - i)"
   132   unfolding fact_altdef_nat
   133   by (rule setprod.reindex_bij_witness[where i="\<lambda>i. k - i" and j="\<lambda>i. k - i"]) auto
   134 
   135 lemma fact_div_fact_le_pow:
   136   assumes "r \<le> n" shows "fact n div fact (n - r) \<le> n ^ r"
   137 proof -
   138   have "\<And>r. r \<le> n \<Longrightarrow> \<Prod>{n - r..n} = (n - r) * \<Prod>{Suc (n - r)..n}"
   139     by (subst setprod.insert[symmetric]) (auto simp: atLeastAtMost_insertL)
   140   with assms show ?thesis
   141     by (induct r rule: nat.induct) (auto simp add: fact_div_fact Suc_diff_Suc mult_le_mono)
   142 qed
   143 
   144 lemma fact_numeral:  --{*Evaluation for specific numerals*}
   145   "fact (numeral k) = (numeral k) * (fact (pred_numeral k))"
   146   by (metis fact.simps(2) numeral_eq_Suc of_nat_numeral)
   147 
   148 
   149 text {* This development is based on the work of Andy Gordon and
   150   Florian Kammueller. *}
   151 
   152 subsection {* Basic definitions and lemmas *}
   153 
   154 primrec binomial :: "nat \<Rightarrow> nat \<Rightarrow> nat" (infixl "choose" 65)
   155 where
   156   "0 choose k = (if k = 0 then 1 else 0)"
   157 | "Suc n choose k = (if k = 0 then 1 else (n choose (k - 1)) + (n choose k))"
   158 
   159 lemma binomial_n_0 [simp]: "(n choose 0) = 1"
   160   by (cases n) simp_all
   161 
   162 lemma binomial_0_Suc [simp]: "(0 choose Suc k) = 0"
   163   by simp
   164 
   165 lemma binomial_Suc_Suc [simp]: "(Suc n choose Suc k) = (n choose k) + (n choose Suc k)"
   166   by simp
   167 
   168 lemma choose_reduce_nat:
   169   "0 < (n::nat) \<Longrightarrow> 0 < k \<Longrightarrow>
   170     (n choose k) = ((n - 1) choose (k - 1)) + ((n - 1) choose k)"
   171   by (metis Suc_diff_1 binomial.simps(2) neq0_conv)
   172 
   173 lemma binomial_eq_0: "n < k \<Longrightarrow> n choose k = 0"
   174   by (induct n arbitrary: k) auto
   175 
   176 declare binomial.simps [simp del]
   177 
   178 lemma binomial_n_n [simp]: "n choose n = 1"
   179   by (induct n) (simp_all add: binomial_eq_0)
   180 
   181 lemma binomial_Suc_n [simp]: "Suc n choose n = Suc n"
   182   by (induct n) simp_all
   183 
   184 lemma binomial_1 [simp]: "n choose Suc 0 = n"
   185   by (induct n) simp_all
   186 
   187 lemma zero_less_binomial: "k \<le> n \<Longrightarrow> n choose k > 0"
   188   by (induct n k rule: diff_induct) simp_all
   189 
   190 lemma binomial_eq_0_iff [simp]: "n choose k = 0 \<longleftrightarrow> n < k"
   191   by (metis binomial_eq_0 less_numeral_extra(3) not_less zero_less_binomial)
   192 
   193 lemma zero_less_binomial_iff [simp]: "n choose k > 0 \<longleftrightarrow> k \<le> n"
   194   by (metis binomial_eq_0_iff not_less0 not_less zero_less_binomial)
   195 
   196 lemma Suc_times_binomial_eq:
   197   "Suc n * (n choose k) = (Suc n choose Suc k) * Suc k"
   198   apply (induct n arbitrary: k, simp add: binomial.simps)
   199   apply (case_tac k)
   200    apply (auto simp add: add_mult_distrib add_mult_distrib2 le_Suc_eq binomial_eq_0)
   201   done
   202 
   203 lemma binomial_le_pow2: "n choose k \<le> 2^n"
   204   apply (induction n arbitrary: k)
   205   apply (simp add: binomial.simps)
   206   apply (case_tac k)
   207   apply (auto simp: power_Suc)
   208   by (simp add: add_le_mono mult_2)
   209 
   210 text{*The absorption property*}
   211 lemma Suc_times_binomial:
   212   "Suc k * (Suc n choose Suc k) = Suc n * (n choose k)"
   213   using Suc_times_binomial_eq by auto
   214 
   215 text{*This is the well-known version of absorption, but it's harder to use because of the
   216   need to reason about division.*}
   217 lemma binomial_Suc_Suc_eq_times:
   218     "(Suc n choose Suc k) = (Suc n * (n choose k)) div Suc k"
   219   by (simp add: Suc_times_binomial_eq del: mult_Suc mult_Suc_right)
   220 
   221 text{*Another version of absorption, with -1 instead of Suc.*}
   222 lemma times_binomial_minus1_eq:
   223   "0 < k \<Longrightarrow> k * (n choose k) = n * ((n - 1) choose (k - 1))"
   224   using Suc_times_binomial_eq [where n = "n - 1" and k = "k - 1"]
   225   by (auto split add: nat_diff_split)
   226 
   227 
   228 subsection {* Combinatorial theorems involving @{text "choose"} *}
   229 
   230 text {*By Florian Kamm\"uller, tidied by LCP.*}
   231 
   232 lemma card_s_0_eq_empty: "finite A \<Longrightarrow> card {B. B \<subseteq> A & card B = 0} = 1"
   233   by (simp cong add: conj_cong add: finite_subset [THEN card_0_eq])
   234 
   235 lemma choose_deconstruct: "finite M \<Longrightarrow> x \<notin> M \<Longrightarrow>
   236     {s. s \<subseteq> insert x M \<and> card s = Suc k} =
   237     {s. s \<subseteq> M \<and> card s = Suc k} \<union> {s. \<exists>t. t \<subseteq> M \<and> card t = k \<and> s = insert x t}"
   238   apply safe
   239      apply (auto intro: finite_subset [THEN card_insert_disjoint])
   240   by (metis (full_types) Diff_insert_absorb Set.set_insert Zero_neq_Suc card_Diff_singleton_if
   241      card_eq_0_iff diff_Suc_1 in_mono subset_insert_iff)
   242 
   243 lemma finite_bex_subset [simp]:
   244   assumes "finite B"
   245     and "\<And>A. A \<subseteq> B \<Longrightarrow> finite {x. P x A}"
   246   shows "finite {x. \<exists>A \<subseteq> B. P x A}"
   247   by (metis (no_types) assms finite_Collect_bounded_ex finite_Collect_subsets)
   248 
   249 text{*There are as many subsets of @{term A} having cardinality @{term k}
   250  as there are sets obtained from the former by inserting a fixed element
   251  @{term x} into each.*}
   252 lemma constr_bij:
   253    "finite A \<Longrightarrow> x \<notin> A \<Longrightarrow>
   254     card {B. \<exists>C. C \<subseteq> A \<and> card C = k \<and> B = insert x C} =
   255     card {B. B \<subseteq> A & card(B) = k}"
   256   apply (rule card_bij_eq [where f = "\<lambda>s. s - {x}" and g = "insert x"])
   257   apply (auto elim!: equalityE simp add: inj_on_def)
   258   apply (metis card_Diff_singleton_if finite_subset in_mono)
   259   done
   260 
   261 text {*
   262   Main theorem: combinatorial statement about number of subsets of a set.
   263 *}
   264 
   265 theorem n_subsets: "finite A \<Longrightarrow> card {B. B \<subseteq> A \<and> card B = k} = (card A choose k)"
   266 proof (induct k arbitrary: A)
   267   case 0 then show ?case by (simp add: card_s_0_eq_empty)
   268 next
   269   case (Suc k)
   270   show ?case using `finite A`
   271   proof (induct A)
   272     case empty show ?case by (simp add: card_s_0_eq_empty)
   273   next
   274     case (insert x A)
   275     then show ?case using Suc.hyps
   276       apply (simp add: card_s_0_eq_empty choose_deconstruct)
   277       apply (subst card_Un_disjoint)
   278          prefer 4 apply (force simp add: constr_bij)
   279         prefer 3 apply force
   280        prefer 2 apply (blast intro: finite_Pow_iff [THEN iffD2]
   281          finite_subset [of _ "Pow (insert x F)" for F])
   282       apply (blast intro: finite_Pow_iff [THEN iffD2, THEN [2] finite_subset])
   283       done
   284   qed
   285 qed
   286 
   287 
   288 subsection {* The binomial theorem (courtesy of Tobias Nipkow): *}
   289 
   290 text{* Avigad's version, generalized to any commutative ring *}
   291 theorem binomial_ring: "(a+b::'a::{comm_ring_1,power})^n =
   292   (\<Sum>k=0..n. (of_nat (n choose k)) * a^k * b^(n-k))" (is "?P n")
   293 proof (induct n)
   294   case 0 then show "?P 0" by simp
   295 next
   296   case (Suc n)
   297   have decomp: "{0..n+1} = {0} Un {n+1} Un {1..n}"
   298     by auto
   299   have decomp2: "{0..n} = {0} Un {1..n}"
   300     by auto
   301   have "(a+b)^(n+1) =
   302       (a+b) * (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n-k))"
   303     using Suc.hyps by simp
   304   also have "\<dots> = a*(\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n-k)) +
   305                    b*(\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n-k))"
   306     by (rule distrib_right)
   307   also have "\<dots> = (\<Sum>k=0..n. of_nat (n choose k) * a^(k+1) * b^(n-k)) +
   308                   (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n-k+1))"
   309     by (auto simp add: setsum_right_distrib ac_simps)
   310   also have "\<dots> = (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n+1-k)) +
   311                   (\<Sum>k=1..n+1. of_nat (n choose (k - 1)) * a^k * b^(n+1-k))"
   312     by (simp add:setsum_shift_bounds_cl_Suc_ivl Suc_diff_le field_simps
   313         del:setsum_cl_ivl_Suc)
   314   also have "\<dots> = a^(n+1) + b^(n+1) +
   315                   (\<Sum>k=1..n. of_nat (n choose (k - 1)) * a^k * b^(n+1-k)) +
   316                   (\<Sum>k=1..n. of_nat (n choose k) * a^k * b^(n+1-k))"
   317     by (simp add: decomp2)
   318   also have
   319       "\<dots> = a^(n+1) + b^(n+1) +
   320             (\<Sum>k=1..n. of_nat(n+1 choose k) * a^k * b^(n+1-k))"
   321     by (auto simp add: field_simps setsum.distrib [symmetric] choose_reduce_nat)
   322   also have "\<dots> = (\<Sum>k=0..n+1. of_nat (n+1 choose k) * a^k * b^(n+1-k))"
   323     using decomp by (simp add: field_simps)
   324   finally show "?P (Suc n)" by simp
   325 qed
   326 
   327 text{* Original version for the naturals *}
   328 corollary binomial: "(a+b::nat)^n = (\<Sum>k=0..n. (of_nat (n choose k)) * a^k * b^(n-k))"
   329     using binomial_ring [of "int a" "int b" n]
   330   by (simp only: of_nat_add [symmetric] of_nat_mult [symmetric] of_nat_power [symmetric]
   331            of_nat_setsum [symmetric]
   332            of_nat_eq_iff of_nat_id)
   333 
   334 lemma binomial_fact_lemma: "k \<le> n \<Longrightarrow> fact k * fact (n - k) * (n choose k) = fact n"
   335 proof (induct n arbitrary: k rule: nat_less_induct)
   336   fix n k assume H: "\<forall>m<n. \<forall>x\<le>m. fact x * fact (m - x) * (m choose x) =
   337                       fact m" and kn: "k \<le> n"
   338   let ?ths = "fact k * fact (n - k) * (n choose k) = fact n"
   339   { assume "n=0" then have ?ths using kn by simp }
   340   moreover
   341   { assume "k=0" then have ?ths using kn by simp }
   342   moreover
   343   { assume nk: "n=k" then have ?ths by simp }
   344   moreover
   345   { fix m h assume n: "n = Suc m" and h: "k = Suc h" and hm: "h < m"
   346     from n have mn: "m < n" by arith
   347     from hm have hm': "h \<le> m" by arith
   348     from hm h n kn have km: "k \<le> m" by arith
   349     have "m - h = Suc (m - Suc h)" using  h km hm by arith
   350     with km h have th0: "fact (m - h) = (m - h) * fact (m - k)"
   351       by simp
   352     from n h th0
   353     have "fact k * fact (n - k) * (n choose k) =
   354         k * (fact h * fact (m - h) * (m choose h)) +
   355         (m - h) * (fact k * fact (m - k) * (m choose k))"
   356       by (simp add: field_simps)
   357     also have "\<dots> = (k + (m - h)) * fact m"
   358       using H[rule_format, OF mn hm'] H[rule_format, OF mn km]
   359       by (simp add: field_simps)
   360     finally have ?ths using h n km by simp }
   361   moreover have "n=0 \<or> k = 0 \<or> k = n \<or> (\<exists>m h. n = Suc m \<and> k = Suc h \<and> h < m)"
   362     using kn by presburger
   363   ultimately show ?ths by blast
   364 qed
   365 
   366 lemma binomial_fact:
   367   assumes kn: "k \<le> n"
   368   shows "(of_nat (n choose k) :: 'a::field_char_0) =
   369          (fact n) / (fact k * fact(n - k))"
   370   using binomial_fact_lemma[OF kn]
   371   apply (simp add: field_simps)
   372   by (metis mult.commute of_nat_fact of_nat_mult)
   373 
   374 lemma choose_row_sum: "(\<Sum>k=0..n. n choose k) = 2^n"
   375   using binomial [of 1 "1" n]
   376   by (simp add: numeral_2_eq_2)
   377 
   378 lemma sum_choose_lower: "(\<Sum>k=0..n. (r+k) choose k) = Suc (r+n) choose n"
   379   by (induct n) auto
   380 
   381 lemma sum_choose_upper: "(\<Sum>k=0..n. k choose m) = Suc n choose Suc m"
   382   by (induct n) auto
   383 
   384 lemma natsum_reverse_index:
   385   fixes m::nat
   386   shows "(\<And>k. m \<le> k \<Longrightarrow> k \<le> n \<Longrightarrow> g k = f (m + n - k)) \<Longrightarrow> (\<Sum>k=m..n. f k) = (\<Sum>k=m..n. g k)"
   387   by (rule setsum.reindex_bij_witness[where i="\<lambda>k. m+n-k" and j="\<lambda>k. m+n-k"]) auto
   388 
   389 text{*NW diagonal sum property*}
   390 lemma sum_choose_diagonal:
   391   assumes "m\<le>n" shows "(\<Sum>k=0..m. (n-k) choose (m-k)) = Suc n choose m"
   392 proof -
   393   have "(\<Sum>k=0..m. (n-k) choose (m-k)) = (\<Sum>k=0..m. (n-m+k) choose k)"
   394     by (rule natsum_reverse_index) (simp add: assms)
   395   also have "... = Suc (n-m+m) choose m"
   396     by (rule sum_choose_lower)
   397   also have "... = Suc n choose m" using assms
   398     by simp
   399   finally show ?thesis .
   400 qed
   401 
   402 subsection{* Pochhammer's symbol : generalized rising factorial *}
   403 
   404 text {* See @{url "http://en.wikipedia.org/wiki/Pochhammer_symbol"} *}
   405 
   406 definition "pochhammer (a::'a::comm_semiring_1) n =
   407   (if n = 0 then 1 else setprod (\<lambda>n. a + of_nat n) {0 .. n - 1})"
   408 
   409 lemma pochhammer_0 [simp]: "pochhammer a 0 = 1"
   410   by (simp add: pochhammer_def)
   411 
   412 lemma pochhammer_1 [simp]: "pochhammer a 1 = a"
   413   by (simp add: pochhammer_def)
   414 
   415 lemma pochhammer_Suc0 [simp]: "pochhammer a (Suc 0) = a"
   416   by (simp add: pochhammer_def)
   417 
   418 lemma pochhammer_Suc_setprod: "pochhammer a (Suc n) = setprod (\<lambda>n. a + of_nat n) {0 .. n}"
   419   by (simp add: pochhammer_def)
   420 
   421 lemma setprod_nat_ivl_Suc: "setprod f {0 .. Suc n} = setprod f {0..n} * f (Suc n)"
   422 proof -
   423   have "{0..Suc n} = {0..n} \<union> {Suc n}" by auto
   424   then show ?thesis by (simp add: field_simps)
   425 qed
   426 
   427 lemma setprod_nat_ivl_1_Suc: "setprod f {0 .. Suc n} = f 0 * setprod f {1.. Suc n}"
   428 proof -
   429   have "{0..Suc n} = {0} \<union> {1 .. Suc n}" by auto
   430   then show ?thesis by simp
   431 qed
   432 
   433 
   434 lemma pochhammer_Suc: "pochhammer a (Suc n) = pochhammer a n * (a + of_nat n)"
   435 proof (cases n)
   436   case 0
   437   then show ?thesis by simp
   438 next
   439   case (Suc n)
   440   show ?thesis unfolding Suc pochhammer_Suc_setprod setprod_nat_ivl_Suc ..
   441 qed
   442 
   443 lemma pochhammer_rec: "pochhammer a (Suc n) = a * pochhammer (a + 1) n"
   444 proof (cases "n = 0")
   445   case True
   446   then show ?thesis by (simp add: pochhammer_Suc_setprod)
   447 next
   448   case False
   449   have *: "finite {1 .. n}" "0 \<notin> {1 .. n}" by auto
   450   have eq: "insert 0 {1 .. n} = {0..n}" by auto
   451   have **: "(\<Prod>n\<in>{1\<Colon>nat..n}. a + of_nat n) = (\<Prod>n\<in>{0\<Colon>nat..n - 1}. a + 1 + of_nat n)"
   452     apply (rule setprod.reindex_cong [where l = Suc])
   453     using False
   454     apply (auto simp add: fun_eq_iff field_simps)
   455     done
   456   show ?thesis
   457     apply (simp add: pochhammer_def)
   458     unfolding setprod.insert [OF *, unfolded eq]
   459     using ** apply (simp add: field_simps)
   460     done
   461 qed
   462 
   463 lemma pochhammer_fact: "fact n = pochhammer 1 n"
   464   unfolding fact_altdef
   465   apply (cases n)
   466    apply (simp_all add: of_nat_setprod pochhammer_Suc_setprod)
   467   apply (rule setprod.reindex_cong [where l = Suc])
   468     apply (auto simp add: fun_eq_iff)
   469   done
   470 
   471 lemma pochhammer_of_nat_eq_0_lemma:
   472   assumes "k > n"
   473   shows "pochhammer (- (of_nat n :: 'a:: idom)) k = 0"
   474 proof (cases "n = 0")
   475   case True
   476   then show ?thesis
   477     using assms by (cases k) (simp_all add: pochhammer_rec)
   478 next
   479   case False
   480   from assms obtain h where "k = Suc h" by (cases k) auto
   481   then show ?thesis
   482     by (simp add: pochhammer_Suc_setprod)
   483        (metis Suc_leI Suc_le_mono assms atLeastAtMost_iff less_eq_nat.simps(1))
   484 qed
   485 
   486 lemma pochhammer_of_nat_eq_0_lemma':
   487   assumes kn: "k \<le> n"
   488   shows "pochhammer (- (of_nat n :: 'a:: {idom,ring_char_0})) k \<noteq> 0"
   489 proof (cases k)
   490   case 0
   491   then show ?thesis by simp
   492 next
   493   case (Suc h)
   494   then show ?thesis
   495     apply (simp add: pochhammer_Suc_setprod)
   496     using Suc kn apply (auto simp add: algebra_simps)
   497     done
   498 qed
   499 
   500 lemma pochhammer_of_nat_eq_0_iff:
   501   shows "pochhammer (- (of_nat n :: 'a:: {idom,ring_char_0})) k = 0 \<longleftrightarrow> k > n"
   502   (is "?l = ?r")
   503   using pochhammer_of_nat_eq_0_lemma[of n k, where ?'a='a]
   504     pochhammer_of_nat_eq_0_lemma'[of k n, where ?'a = 'a]
   505   by (auto simp add: not_le[symmetric])
   506 
   507 lemma pochhammer_eq_0_iff: "pochhammer a n = (0::'a::field_char_0) \<longleftrightarrow> (\<exists>k < n. a = - of_nat k)"
   508   apply (auto simp add: pochhammer_of_nat_eq_0_iff)
   509   apply (cases n)
   510    apply (auto simp add: pochhammer_def algebra_simps group_add_class.eq_neg_iff_add_eq_0)
   511   apply (metis leD not_less_eq)
   512   done
   513 
   514 lemma pochhammer_eq_0_mono:
   515   "pochhammer a n = (0::'a::field_char_0) \<Longrightarrow> m \<ge> n \<Longrightarrow> pochhammer a m = 0"
   516   unfolding pochhammer_eq_0_iff by auto
   517 
   518 lemma pochhammer_neq_0_mono:
   519   "pochhammer a m \<noteq> (0::'a::field_char_0) \<Longrightarrow> m \<ge> n \<Longrightarrow> pochhammer a n \<noteq> 0"
   520   unfolding pochhammer_eq_0_iff by auto
   521 
   522 lemma pochhammer_minus:
   523     "pochhammer (- b) k = ((- 1) ^ k :: 'a::comm_ring_1) * pochhammer (b - of_nat k + 1) k"
   524 proof (cases k)
   525   case 0
   526   then show ?thesis by simp
   527 next
   528   case (Suc h)
   529   have eq: "((- 1) ^ Suc h :: 'a) = (\<Prod>i=0..h. - 1)"
   530     using setprod_constant[where A="{0 .. h}" and y="- 1 :: 'a"]
   531     by auto
   532   show ?thesis
   533     unfolding Suc pochhammer_Suc_setprod eq setprod.distrib[symmetric]
   534     by (rule setprod.reindex_bij_witness[where i="op - h" and j="op - h"])
   535        (auto simp: of_nat_diff)
   536 qed
   537 
   538 lemma pochhammer_minus':
   539     "pochhammer (b - of_nat k + 1) k = ((- 1) ^ k :: 'a::comm_ring_1) * pochhammer (- b) k"
   540   unfolding pochhammer_minus[where b=b]
   541   unfolding mult.assoc[symmetric]
   542   unfolding power_add[symmetric]
   543   by simp
   544 
   545 lemma pochhammer_same: "pochhammer (- of_nat n) n =
   546     ((- 1) ^ n :: 'a::{semiring_char_0,comm_ring_1,semiring_no_zero_divisors}) * (fact n)"
   547   unfolding pochhammer_minus
   548   by (simp add: of_nat_diff pochhammer_fact)
   549 
   550 
   551 subsection{* Generalized binomial coefficients *}
   552 
   553 definition gbinomial :: "'a::field_char_0 \<Rightarrow> nat \<Rightarrow> 'a" (infixl "gchoose" 65)
   554   where "a gchoose n =
   555     (if n = 0 then 1 else (setprod (\<lambda>i. a - of_nat i) {0 .. n - 1}) / (fact n))"
   556 
   557 lemma gbinomial_0 [simp]: "a gchoose 0 = 1" "0 gchoose (Suc n) = 0"
   558   by (simp_all add: gbinomial_def)
   559 
   560 lemma gbinomial_pochhammer: "a gchoose n = (- 1) ^ n * pochhammer (- a) n / (fact n)"
   561 proof (cases "n = 0")
   562   case True
   563   then show ?thesis by simp
   564 next
   565   case False
   566   from this setprod_constant[of "{0 .. n - 1}" "- (1:: 'a)"]
   567   have eq: "(- (1\<Colon>'a)) ^ n = setprod (\<lambda>i. - 1) {0 .. n - 1}"
   568     by auto
   569   from False show ?thesis
   570     by (simp add: pochhammer_def gbinomial_def field_simps
   571       eq setprod.distrib[symmetric])
   572 qed
   573 
   574 lemma binomial_gbinomial: 
   575     "of_nat (n choose k) = (of_nat n gchoose k :: 'a::field_char_0)"
   576 proof -
   577   { assume kn: "k > n"
   578     then have ?thesis
   579       by (subst binomial_eq_0[OF kn])
   580          (simp add: gbinomial_pochhammer field_simps  pochhammer_of_nat_eq_0_iff) }
   581   moreover
   582   { assume "k=0" then have ?thesis by simp }
   583   moreover
   584   { assume kn: "k \<le> n" and k0: "k\<noteq> 0"
   585     from k0 obtain h where h: "k = Suc h" by (cases k) auto
   586     from h
   587     have eq:"(- 1 :: 'a) ^ k = setprod (\<lambda>i. - 1) {0..h}"
   588       by (subst setprod_constant) auto
   589     have eq': "(\<Prod>i\<in>{0..h}. of_nat n + - (of_nat i :: 'a)) = (\<Prod>i\<in>{n - h..n}. of_nat i)"
   590         using h kn
   591       by (intro setprod.reindex_bij_witness[where i="op - n" and j="op - n"])
   592          (auto simp: of_nat_diff)
   593     have th0: "finite {1..n - Suc h}" "finite {n - h .. n}"
   594         "{1..n - Suc h} \<inter> {n - h .. n} = {}" and
   595         eq3: "{1..n - Suc h} \<union> {n - h .. n} = {1..n}"
   596       using h kn by auto
   597     from eq[symmetric]
   598     have ?thesis using kn
   599       apply (simp add: binomial_fact[OF kn, where ?'a = 'a]
   600         gbinomial_pochhammer field_simps pochhammer_Suc_setprod)
   601       apply (simp add: pochhammer_Suc_setprod fact_altdef h 
   602         of_nat_setprod setprod.distrib[symmetric] eq' del: One_nat_def power_Suc)
   603       unfolding setprod.union_disjoint[OF th0, unfolded eq3, of "of_nat:: nat \<Rightarrow> 'a"] eq[unfolded h]
   604       unfolding mult.assoc
   605       unfolding setprod.distrib[symmetric]
   606       apply simp
   607       apply (intro setprod.reindex_bij_witness[where i="op - n" and j="op - n"])
   608       apply (auto simp: of_nat_diff)
   609       done
   610   }
   611   moreover
   612   have "k > n \<or> k = 0 \<or> (k \<le> n \<and> k \<noteq> 0)" by arith
   613   ultimately show ?thesis by blast
   614 qed
   615 
   616 lemma gbinomial_1[simp]: "a gchoose 1 = a"
   617   by (simp add: gbinomial_def)
   618 
   619 lemma gbinomial_Suc0[simp]: "a gchoose (Suc 0) = a"
   620   by (simp add: gbinomial_def)
   621 
   622 lemma gbinomial_mult_1:
   623   fixes a :: "'a :: field_char_0"
   624   shows "a * (a gchoose n) =
   625     of_nat n * (a gchoose n) + of_nat (Suc n) * (a gchoose (Suc n))"  (is "?l = ?r")
   626 proof -
   627   have "?r = ((- 1) ^n * pochhammer (- a) n / (fact n)) * (of_nat n - (- a + of_nat n))"
   628     unfolding gbinomial_pochhammer
   629       pochhammer_Suc of_nat_mult right_diff_distrib power_Suc
   630     apply (simp del: of_nat_Suc fact.simps)
   631     apply (auto simp add: field_simps simp del: of_nat_Suc)
   632     done
   633   also have "\<dots> = ?l" unfolding gbinomial_pochhammer
   634     by (simp add: field_simps)
   635   finally show ?thesis ..
   636 qed
   637 
   638 lemma gbinomial_mult_1':
   639   fixes a :: "'a :: field_char_0"
   640   shows "(a gchoose n) * a = of_nat n * (a gchoose n) + of_nat (Suc n) * (a gchoose (Suc n))"
   641   by (simp add: mult.commute gbinomial_mult_1)
   642 
   643 lemma gbinomial_Suc:
   644     "a gchoose (Suc k) = (setprod (\<lambda>i. a - of_nat i) {0 .. k}) / (fact (Suc k))"
   645   by (simp add: gbinomial_def)
   646 
   647 lemma gbinomial_mult_fact:
   648   fixes a :: "'a::field_char_0"
   649   shows
   650    "fact (Suc k) * (a gchoose (Suc k)) =
   651     (setprod (\<lambda>i. a - of_nat i) {0 .. k})"
   652   by (simp_all add: gbinomial_Suc field_simps del: fact.simps)
   653 
   654 lemma gbinomial_mult_fact':
   655   fixes a :: "'a::field_char_0"
   656   shows "(a gchoose (Suc k)) * fact (Suc k) = (setprod (\<lambda>i. a - of_nat i) {0 .. k})"
   657   using gbinomial_mult_fact[of k a]
   658   by (subst mult.commute)
   659 
   660 lemma gbinomial_Suc_Suc:
   661   fixes a :: "'a :: field_char_0"
   662   shows "(a + 1) gchoose (Suc k) = a gchoose k + (a gchoose (Suc k))"
   663 proof (cases k)
   664   case 0
   665   then show ?thesis by simp
   666 next
   667   case (Suc h)
   668   have eq0: "(\<Prod>i\<in>{1..k}. (a + 1) - of_nat i) = (\<Prod>i\<in>{0..h}. a - of_nat i)"
   669     apply (rule setprod.reindex_cong [where l = Suc])
   670       using Suc
   671       apply auto
   672     done
   673   have "fact (Suc k) * (a gchoose k + (a gchoose (Suc k))) =
   674         (a gchoose Suc h) * (fact (Suc (Suc h))) +
   675         (a gchoose Suc (Suc h)) * (fact (Suc (Suc h)))"
   676     by (simp add: Suc field_simps del: fact.simps)
   677   also have "... = (a gchoose Suc h) * of_nat (Suc (Suc h) * fact (Suc h)) + 
   678                    (\<Prod>i = 0..Suc h. a - of_nat i)"
   679     by (metis fact.simps(2) gbinomial_mult_fact' of_nat_fact of_nat_id)
   680   also have "... = (fact (Suc h) * (a gchoose Suc h)) * of_nat (Suc (Suc h)) + 
   681                    (\<Prod>i = 0..Suc h. a - of_nat i)"
   682     by (simp only: fact.simps(2) mult.commute mult.left_commute of_nat_fact of_nat_id of_nat_mult)
   683   also have "... =  of_nat (Suc (Suc h)) * (\<Prod>i = 0..h. a - of_nat i) + 
   684                     (\<Prod>i = 0..Suc h. a - of_nat i)"
   685     by (metis gbinomial_mult_fact mult.commute)
   686   also have "... = (\<Prod>i = 0..Suc h. a - of_nat i) +
   687                    (of_nat h * (\<Prod>i = 0..h. a - of_nat i) + 2 * (\<Prod>i = 0..h. a - of_nat i))"
   688     by (simp add: field_simps)
   689   also have "... = 
   690     ((a gchoose Suc h) * (fact (Suc h)) * of_nat (Suc k)) + (\<Prod>i\<in>{0\<Colon>nat..Suc h}. a - of_nat i)"
   691     unfolding gbinomial_mult_fact'
   692     by (simp add: comm_semiring_class.distrib field_simps Suc)
   693   also have "\<dots> = (\<Prod>i\<in>{0..h}. a - of_nat i) * (a + 1)"
   694     unfolding gbinomial_mult_fact' setprod_nat_ivl_Suc
   695     by (simp add: field_simps Suc)
   696   also have "\<dots> = (\<Prod>i\<in>{0..k}. (a + 1) - of_nat i)"
   697     using eq0
   698     by (simp add: Suc setprod_nat_ivl_1_Suc)
   699   also have "\<dots> = (fact (Suc k)) * ((a + 1) gchoose (Suc k))"
   700     unfolding gbinomial_mult_fact ..
   701   finally show ?thesis
   702     by (metis fact_nonzero mult_cancel_left) 
   703 qed
   704 
   705 lemma gbinomial_reduce_nat:
   706   fixes a :: "'a :: field_char_0"
   707   shows "0 < k \<Longrightarrow> a gchoose k = (a - 1) gchoose (k - 1) + ((a - 1) gchoose k)"
   708   by (metis Suc_pred' diff_add_cancel gbinomial_Suc_Suc)
   709 
   710 lemma gchoose_row_sum_weighted:
   711   fixes r :: "'a::field_char_0"
   712   shows "(\<Sum>k = 0..m. (r gchoose k) * (r/2 - of_nat k)) = of_nat(Suc m) / 2 * (r gchoose (Suc m))"
   713 proof (induct m)
   714   case 0 show ?case by simp
   715 next
   716   case (Suc m)
   717   from Suc show ?case
   718     by (simp add: algebra_simps distrib gbinomial_mult_1)
   719 qed
   720 
   721 lemma binomial_symmetric:
   722   assumes kn: "k \<le> n"
   723   shows "n choose k = n choose (n - k)"
   724 proof-
   725   from kn have kn': "n - k \<le> n" by arith
   726   from binomial_fact_lemma[OF kn] binomial_fact_lemma[OF kn']
   727   have "fact k * fact (n - k) * (n choose k) =
   728     fact (n - k) * fact (n - (n - k)) * (n choose (n - k))" by simp
   729   then show ?thesis using kn by simp
   730 qed
   731 
   732 text{*Contributed by Manuel Eberl, generalised by LCP.
   733   Alternative definition of the binomial coefficient as @{term "\<Prod>i<k. (n - i) / (k - i)"} *}
   734 lemma gbinomial_altdef_of_nat:
   735   fixes k :: nat
   736     and x :: "'a :: {field_char_0,field}"
   737   shows "x gchoose k = (\<Prod>i<k. (x - of_nat i) / of_nat (k - i) :: 'a)"
   738 proof -
   739   have "(x gchoose k) = (\<Prod>i<k. x - of_nat i) / of_nat (fact k)"
   740     unfolding gbinomial_def
   741     by (auto simp: gr0_conv_Suc lessThan_Suc_atMost atLeast0AtMost)
   742   also have "\<dots> = (\<Prod>i<k. (x - of_nat i) / of_nat (k - i) :: 'a)"
   743     unfolding fact_eq_rev_setprod_nat of_nat_setprod
   744     by (auto simp add: setprod_dividef intro!: setprod.cong of_nat_diff[symmetric])
   745   finally show ?thesis .
   746 qed
   747 
   748 lemma gbinomial_ge_n_over_k_pow_k:
   749   fixes k :: nat
   750     and x :: "'a :: linordered_field"
   751   assumes "of_nat k \<le> x"
   752   shows "(x / of_nat k :: 'a) ^ k \<le> x gchoose k"
   753 proof -
   754   have x: "0 \<le> x"
   755     using assms of_nat_0_le_iff order_trans by blast
   756   have "(x / of_nat k :: 'a) ^ k = (\<Prod>i<k. x / of_nat k :: 'a)"
   757     by (simp add: setprod_constant)
   758   also have "\<dots> \<le> x gchoose k"
   759     unfolding gbinomial_altdef_of_nat
   760   proof (safe intro!: setprod_mono)
   761     fix i :: nat
   762     assume ik: "i < k"
   763     from assms have "x * of_nat i \<ge> of_nat (i * k)"
   764       by (metis mult.commute mult_le_cancel_right of_nat_less_0_iff of_nat_mult)
   765     then have "x * of_nat k - x * of_nat i \<le> x * of_nat k - of_nat (i * k)" by arith
   766     then have "x * of_nat (k - i) \<le> (x - of_nat i) * of_nat k"
   767       using ik
   768       by (simp add: algebra_simps zero_less_mult_iff of_nat_diff of_nat_mult)
   769     then have "x * of_nat (k - i) \<le> (x - of_nat i) * (of_nat k :: 'a)"
   770       unfolding of_nat_mult[symmetric] of_nat_le_iff .
   771     with assms show "x / of_nat k \<le> (x - of_nat i) / (of_nat (k - i) :: 'a)"
   772       using `i < k` by (simp add: field_simps)
   773   qed (simp add: x zero_le_divide_iff)
   774   finally show ?thesis .
   775 qed
   776 
   777 text{*Versions of the theorems above for the natural-number version of "choose"*}
   778 lemma binomial_altdef_of_nat:
   779   fixes n k :: nat
   780     and x :: "'a :: {field_char_0,field}"  --{*the point is to constrain @{typ 'a}*}
   781   assumes "k \<le> n"
   782   shows "of_nat (n choose k) = (\<Prod>i<k. of_nat (n - i) / of_nat (k - i) :: 'a)"
   783 using assms
   784 by (simp add: gbinomial_altdef_of_nat binomial_gbinomial of_nat_diff)
   785 
   786 lemma binomial_ge_n_over_k_pow_k:
   787   fixes k n :: nat
   788     and x :: "'a :: linordered_field"
   789   assumes "k \<le> n"
   790   shows "(of_nat n / of_nat k :: 'a) ^ k \<le> of_nat (n choose k)"
   791 by (simp add: assms gbinomial_ge_n_over_k_pow_k binomial_gbinomial of_nat_diff)
   792 
   793 lemma binomial_le_pow:
   794   assumes "r \<le> n"
   795   shows "n choose r \<le> n ^ r"
   796 proof -
   797   have "n choose r \<le> fact n div fact (n - r)"
   798     using `r \<le> n` by (subst binomial_fact_lemma[symmetric]) auto
   799   with fact_div_fact_le_pow [OF assms] show ?thesis by auto
   800 qed
   801 
   802 lemma binomial_altdef_nat: "(k::nat) \<le> n \<Longrightarrow>
   803     n choose k = fact n div (fact k * fact (n - k))"
   804  by (subst binomial_fact_lemma [symmetric]) auto
   805 
   806 lemma choose_dvd: "k \<le> n \<Longrightarrow> fact k * fact (n - k) dvd (fact n :: 'a :: {semiring_div,linordered_semidom})"
   807   unfolding dvd_def
   808   apply (rule exI [where x="of_nat (n choose k)"])
   809   using binomial_fact_lemma [of k n, THEN arg_cong [where f = of_nat and 'b='a]]
   810   apply (auto simp: of_nat_mult)
   811   done
   812 
   813 lemma fact_fact_dvd_fact: 
   814     "fact k * fact n dvd (fact (k+n) :: 'a :: {semiring_div,linordered_semidom})"
   815 by (metis add.commute add_diff_cancel_left' choose_dvd le_add2)
   816 
   817 lemma choose_mult_lemma:
   818      "((m+r+k) choose (m+k)) * ((m+k) choose k) = ((m+r+k) choose k) * ((m+r) choose m)"
   819 proof -
   820   have "((m+r+k) choose (m+k)) * ((m+k) choose k) =
   821         fact (m+r + k) div (fact (m + k) * fact (m+r - m)) * (fact (m + k) div (fact k * fact m))"
   822     by (simp add: assms binomial_altdef_nat)
   823   also have "... = fact (m+r+k) div (fact r * (fact k * fact m))"
   824     apply (subst div_mult_div_if_dvd)
   825     apply (auto simp: algebra_simps fact_fact_dvd_fact)
   826     apply (metis add.assoc add.commute fact_fact_dvd_fact)
   827     done
   828   also have "... = (fact (m+r+k) * fact (m+r)) div (fact r * (fact k * fact m) * fact (m+r))"
   829     apply (subst div_mult_div_if_dvd [symmetric])
   830     apply (auto simp add: algebra_simps)
   831     apply (metis fact_fact_dvd_fact dvd.order.trans nat_mult_dvd_cancel_disj)
   832     done
   833   also have "... = (fact (m+r+k) div (fact k * fact (m+r)) * (fact (m+r) div (fact r * fact m)))"
   834     apply (subst div_mult_div_if_dvd)
   835     apply (auto simp: fact_fact_dvd_fact algebra_simps)
   836     done
   837   finally show ?thesis
   838     by (simp add: binomial_altdef_nat mult.commute)
   839 qed
   840 
   841 text{*The "Subset of a Subset" identity*}
   842 lemma choose_mult:
   843   assumes "k\<le>m" "m\<le>n"
   844     shows "(n choose m) * (m choose k) = (n choose k) * ((n-k) choose (m-k))"
   845 using assms choose_mult_lemma [of "m-k" "n-m" k]
   846 by simp
   847 
   848 
   849 subsection {* Binomial coefficients *}
   850 
   851 lemma choose_one: "(n::nat) choose 1 = n"
   852   by simp
   853 
   854 (*FIXME: messy and apparently unused*)
   855 lemma binomial_induct [rule_format]: "(ALL (n::nat). P n n) \<longrightarrow>
   856     (ALL n. P (Suc n) 0) \<longrightarrow> (ALL n. (ALL k < n. P n k \<longrightarrow> P n (Suc k) \<longrightarrow>
   857     P (Suc n) (Suc k))) \<longrightarrow> (ALL k <= n. P n k)"
   858   apply (induct n)
   859   apply auto
   860   apply (case_tac "k = 0")
   861   apply auto
   862   apply (case_tac "k = Suc n")
   863   apply auto
   864   apply (metis Suc_le_eq fact.cases le_Suc_eq le_eq_less_or_eq)
   865   done
   866 
   867 lemma card_UNION:
   868   assumes "finite A" and "\<forall>k \<in> A. finite k"
   869   shows "card (\<Union>A) = nat (\<Sum>I | I \<subseteq> A \<and> I \<noteq> {}. (- 1) ^ (card I + 1) * int (card (\<Inter>I)))"
   870   (is "?lhs = ?rhs")
   871 proof -
   872   have "?rhs = nat (\<Sum>I | I \<subseteq> A \<and> I \<noteq> {}. (- 1) ^ (card I + 1) * (\<Sum>_\<in>\<Inter>I. 1))" by simp
   873   also have "\<dots> = nat (\<Sum>I | I \<subseteq> A \<and> I \<noteq> {}. (\<Sum>_\<in>\<Inter>I. (- 1) ^ (card I + 1)))" (is "_ = nat ?rhs")
   874     by(subst setsum_right_distrib) simp
   875   also have "?rhs = (\<Sum>(I, _)\<in>Sigma {I. I \<subseteq> A \<and> I \<noteq> {}} Inter. (- 1) ^ (card I + 1))"
   876     using assms by(subst setsum.Sigma)(auto)
   877   also have "\<dots> = (\<Sum>(x, I)\<in>(SIGMA x:UNIV. {I. I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I}). (- 1) ^ (card I + 1))"
   878     by (rule setsum.reindex_cong [where l = "\<lambda>(x, y). (y, x)"]) (auto intro: inj_onI simp add: split_beta)
   879   also have "\<dots> = (\<Sum>(x, I)\<in>(SIGMA x:\<Union>A. {I. I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I}). (- 1) ^ (card I + 1))"
   880     using assms by(auto intro!: setsum.mono_neutral_cong_right finite_SigmaI2 intro: finite_subset[where B="\<Union>A"])
   881   also have "\<dots> = (\<Sum>x\<in>\<Union>A. (\<Sum>I|I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I. (- 1) ^ (card I + 1)))"
   882     using assms by(subst setsum.Sigma) auto
   883   also have "\<dots> = (\<Sum>_\<in>\<Union>A. 1)" (is "setsum ?lhs _ = _")
   884   proof(rule setsum.cong[OF refl])
   885     fix x
   886     assume x: "x \<in> \<Union>A"
   887     def K \<equiv> "{X \<in> A. x \<in> X}"
   888     with `finite A` have K: "finite K" by auto
   889     let ?I = "\<lambda>i. {I. I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I}"
   890     have "inj_on snd (SIGMA i:{1..card A}. ?I i)"
   891       using assms by(auto intro!: inj_onI)
   892     moreover have [symmetric]: "snd ` (SIGMA i:{1..card A}. ?I i) = {I. I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I}"
   893       using assms by(auto intro!: rev_image_eqI[where x="(card a, a)" for a]
   894         simp add: card_gt_0_iff[folded Suc_le_eq]
   895         dest: finite_subset intro: card_mono)
   896     ultimately have "?lhs x = (\<Sum>(i, I)\<in>(SIGMA i:{1..card A}. ?I i). (- 1) ^ (i + 1))"
   897       by (rule setsum.reindex_cong [where l = snd]) fastforce
   898     also have "\<dots> = (\<Sum>i=1..card A. (\<Sum>I|I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. (- 1) ^ (i + 1)))"
   899       using assms by(subst setsum.Sigma) auto
   900     also have "\<dots> = (\<Sum>i=1..card A. (- 1) ^ (i + 1) * (\<Sum>I|I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. 1))"
   901       by(subst setsum_right_distrib) simp
   902     also have "\<dots> = (\<Sum>i=1..card K. (- 1) ^ (i + 1) * (\<Sum>I|I \<subseteq> K \<and> card I = i. 1))" (is "_ = ?rhs")
   903     proof(rule setsum.mono_neutral_cong_right[rule_format])
   904       show "{1..card K} \<subseteq> {1..card A}" using `finite A`
   905         by(auto simp add: K_def intro: card_mono)
   906     next
   907       fix i
   908       assume "i \<in> {1..card A} - {1..card K}"
   909       hence i: "i \<le> card A" "card K < i" by auto
   910       have "{I. I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I} = {I. I \<subseteq> K \<and> card I = i}"
   911         by(auto simp add: K_def)
   912       also have "\<dots> = {}" using `finite A` i
   913         by(auto simp add: K_def dest: card_mono[rotated 1])
   914       finally show "(- 1) ^ (i + 1) * (\<Sum>I | I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. 1 :: int) = 0"
   915         by(simp only:) simp
   916     next
   917       fix i
   918       have "(\<Sum>I | I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. 1) = (\<Sum>I | I \<subseteq> K \<and> card I = i. 1 :: int)"
   919         (is "?lhs = ?rhs")
   920         by(rule setsum.cong)(auto simp add: K_def)
   921       thus "(- 1) ^ (i + 1) * ?lhs = (- 1) ^ (i + 1) * ?rhs" by simp
   922     qed simp
   923     also have "{I. I \<subseteq> K \<and> card I = 0} = {{}}" using assms
   924       by(auto simp add: card_eq_0_iff K_def dest: finite_subset)
   925     hence "?rhs = (\<Sum>i = 0..card K. (- 1) ^ (i + 1) * (\<Sum>I | I \<subseteq> K \<and> card I = i. 1 :: int)) + 1"
   926       by(subst (2) setsum_head_Suc)(simp_all )
   927     also have "\<dots> = (\<Sum>i = 0..card K. (- 1) * ((- 1) ^ i * int (card K choose i))) + 1"
   928       using K by(subst n_subsets[symmetric]) simp_all
   929     also have "\<dots> = - (\<Sum>i = 0..card K. (- 1) ^ i * int (card K choose i)) + 1"
   930       by(subst setsum_right_distrib[symmetric]) simp
   931     also have "\<dots> =  - ((-1 + 1) ^ card K) + 1"
   932       by(subst binomial_ring)(simp add: ac_simps)
   933     also have "\<dots> = 1" using x K by(auto simp add: K_def card_gt_0_iff)
   934     finally show "?lhs x = 1" .
   935   qed
   936   also have "nat \<dots> = card (\<Union>A)" by simp
   937   finally show ?thesis ..
   938 qed
   939 
   940 text{* The number of nat lists of length @{text m} summing to @{text N} is
   941 @{term "(N + m - 1) choose N"}: *}
   942 
   943 lemma card_length_listsum_rec:
   944   assumes "m\<ge>1"
   945   shows "card {l::nat list. length l = m \<and> listsum l = N} =
   946     (card {l. length l = (m - 1) \<and> listsum l = N} +
   947     card {l. length l = m \<and> listsum l + 1 =  N})"
   948     (is "card ?C = (card ?A + card ?B)")
   949 proof -
   950   let ?A'="{l. length l = m \<and> listsum l = N \<and> hd l = 0}"
   951   let ?B'="{l. length l = m \<and> listsum l = N \<and> hd l \<noteq> 0}"
   952   let ?f ="\<lambda> l. 0#l"
   953   let ?g ="\<lambda> l. (hd l + 1) # tl l"
   954   have 1: "\<And>xs x. xs \<noteq> [] \<Longrightarrow> x = hd xs \<Longrightarrow> x # tl xs = xs" by simp
   955   have 2: "\<And>xs. (xs::nat list) \<noteq> [] \<Longrightarrow> listsum(tl xs) = listsum xs - hd xs"
   956     by(auto simp add: neq_Nil_conv)
   957   have f: "bij_betw ?f ?A ?A'"
   958     apply(rule bij_betw_byWitness[where f' = tl])
   959     using assms
   960     by (auto simp: 2 length_0_conv[symmetric] 1 simp del: length_0_conv)
   961   have 3: "\<And>xs:: nat list. xs \<noteq> [] \<Longrightarrow> hd xs + (listsum xs - hd xs) = listsum xs"
   962     by (metis 1 listsum_simps(2) 2)
   963   have g: "bij_betw ?g ?B ?B'"
   964     apply(rule bij_betw_byWitness[where f' = "\<lambda> l. (hd l - 1) # tl l"])
   965     using assms
   966     by (auto simp: 2 length_0_conv[symmetric] intro!: 3
   967       simp del: length_greater_0_conv length_0_conv)
   968   { fix M N :: nat have "finite {xs. size xs = M \<and> set xs \<subseteq> {0..<N}}"
   969     using finite_lists_length_eq[OF finite_atLeastLessThan] conj_commute by auto }
   970     note fin = this
   971   have fin_A: "finite ?A" using fin[of _ "N+1"]
   972     by (intro finite_subset[where ?A = "?A" and ?B = "{xs. size xs = m - 1 \<and> set xs \<subseteq> {0..<N+1}}"],
   973       auto simp: member_le_listsum_nat less_Suc_eq_le)
   974   have fin_B: "finite ?B"
   975     by (intro finite_subset[where ?A = "?B" and ?B = "{xs. size xs = m \<and> set xs \<subseteq> {0..<N}}"],
   976       auto simp: member_le_listsum_nat less_Suc_eq_le fin)
   977   have uni: "?C = ?A' \<union> ?B'" by auto
   978   have disj: "?A' \<inter> ?B' = {}" by auto
   979   have "card ?C = card(?A' \<union> ?B')" using uni by simp
   980   also have "\<dots> = card ?A + card ?B"
   981     using card_Un_disjoint[OF _ _ disj] bij_betw_finite[OF f] bij_betw_finite[OF g]
   982       bij_betw_same_card[OF f] bij_betw_same_card[OF g] fin_A fin_B
   983     by presburger
   984   finally show ?thesis .
   985 qed
   986 
   987 lemma card_length_listsum: --"By Holden Lee, tidied by Tobias Nipkow"
   988   "card {l::nat list. size l = m \<and> listsum l = N} = (N + m - 1) choose N"
   989 proof (cases m)
   990   case 0 then show ?thesis
   991     by (cases N) (auto simp: cong: conj_cong)
   992 next
   993   case (Suc m')
   994     have m: "m\<ge>1" by (simp add: Suc)
   995     then show ?thesis
   996     proof (induct "N + m - 1" arbitrary: N m)
   997       case 0   -- "In the base case, the only solution is [0]."
   998       have [simp]: "{l::nat list. length l = Suc 0 \<and> (\<forall>n\<in>set l. n = 0)} = {[0]}"
   999         by (auto simp: length_Suc_conv)
  1000       have "m=1 \<and> N=0" using 0 by linarith
  1001       then show ?case by simp
  1002     next
  1003       case (Suc k)
  1004 
  1005       have c1: "card {l::nat list. size l = (m - 1) \<and> listsum l =  N} =
  1006         (N + (m - 1) - 1) choose N"
  1007       proof cases
  1008         assume "m = 1"
  1009         with Suc.hyps have "N\<ge>1" by auto
  1010         with `m = 1` show ?thesis by (simp add: binomial_eq_0)
  1011       next
  1012         assume "m \<noteq> 1" thus ?thesis using Suc by fastforce
  1013       qed
  1014 
  1015       from Suc have c2: "card {l::nat list. size l = m \<and> listsum l + 1 = N} =
  1016         (if N>0 then ((N - 1) + m - 1) choose (N - 1) else 0)"
  1017       proof -
  1018         have aux: "\<And>m n. n > 0 \<Longrightarrow> Suc m = n \<longleftrightarrow> m = n - 1" by arith
  1019         from Suc have "N>0 \<Longrightarrow>
  1020           card {l::nat list. size l = m \<and> listsum l + 1 = N} =
  1021           ((N - 1) + m - 1) choose (N - 1)" by (simp add: aux)
  1022         thus ?thesis by auto
  1023       qed
  1024 
  1025       from Suc.prems have "(card {l::nat list. size l = (m - 1) \<and> listsum l = N} +
  1026           card {l::nat list. size l = m \<and> listsum l + 1 = N}) = (N + m - 1) choose N"
  1027         by (auto simp: c1 c2 choose_reduce_nat[of "N + m - 1" N] simp del: One_nat_def)
  1028       thus ?case using card_length_listsum_rec[OF Suc.prems] by auto
  1029     qed
  1030 qed
  1031 
  1032 end