src/HOL/Hilbert_Choice.thy
author haftmann
Fri Jun 19 07:53:35 2015 +0200 (2015-06-19)
changeset 60517 f16e4fb20652
parent 59094 9ced35b4a2a9
child 60585 48fdff264eb2
permissions -rw-r--r--
separate class for notions specific for integral (semi)domains, in contrast to fields where these are trivial
     1 (*  Title:      HOL/Hilbert_Choice.thy
     2     Author:     Lawrence C Paulson, Tobias Nipkow
     3     Copyright   2001  University of Cambridge
     4 *)
     5 
     6 section {* Hilbert's Epsilon-Operator and the Axiom of Choice *}
     7 
     8 theory Hilbert_Choice
     9 imports Nat Wellfounded
    10 keywords "specification" :: thy_goal
    11 begin
    12 
    13 subsection {* Hilbert's epsilon *}
    14 
    15 axiomatization Eps :: "('a => bool) => 'a" where
    16   someI: "P x ==> P (Eps P)"
    17 
    18 syntax (epsilon)
    19   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3\<some>_./ _)" [0, 10] 10)
    20 syntax (HOL)
    21   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3@ _./ _)" [0, 10] 10)
    22 syntax
    23   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3SOME _./ _)" [0, 10] 10)
    24 translations
    25   "SOME x. P" == "CONST Eps (%x. P)"
    26 
    27 print_translation {*
    28   [(@{const_syntax Eps}, fn _ => fn [Abs abs] =>
    29       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
    30       in Syntax.const @{syntax_const "_Eps"} $ x $ t end)]
    31 *} -- {* to avoid eta-contraction of body *}
    32 
    33 definition inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
    34 "inv_into A f == %x. SOME y. y : A & f y = x"
    35 
    36 abbreviation inv :: "('a => 'b) => ('b => 'a)" where
    37 "inv == inv_into UNIV"
    38 
    39 
    40 subsection {*Hilbert's Epsilon-operator*}
    41 
    42 text{*Easier to apply than @{text someI} if the witness comes from an
    43 existential formula*}
    44 lemma someI_ex [elim?]: "\<exists>x. P x ==> P (SOME x. P x)"
    45 apply (erule exE)
    46 apply (erule someI)
    47 done
    48 
    49 text{*Easier to apply than @{text someI} because the conclusion has only one
    50 occurrence of @{term P}.*}
    51 lemma someI2: "[| P a;  !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    52 by (blast intro: someI)
    53 
    54 text{*Easier to apply than @{text someI2} if the witness comes from an
    55 existential formula*}
    56 lemma someI2_ex: "[| \<exists>a. P a; !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    57 by (blast intro: someI2)
    58 
    59 lemma some_equality [intro]:
    60      "[| P a;  !!x. P x ==> x=a |] ==> (SOME x. P x) = a"
    61 by (blast intro: someI2)
    62 
    63 lemma some1_equality: "[| EX!x. P x; P a |] ==> (SOME x. P x) = a"
    64 by blast
    65 
    66 lemma some_eq_ex: "P (SOME x. P x) =  (\<exists>x. P x)"
    67 by (blast intro: someI)
    68 
    69 lemma some_in_eq: "(SOME x. x \<in> A) \<in> A \<longleftrightarrow> A \<noteq> {}"
    70   unfolding ex_in_conv[symmetric] by (rule some_eq_ex)
    71 
    72 lemma some_eq_trivial [simp]: "(SOME y. y=x) = x"
    73 apply (rule some_equality)
    74 apply (rule refl, assumption)
    75 done
    76 
    77 lemma some_sym_eq_trivial [simp]: "(SOME y. x=y) = x"
    78 apply (rule some_equality)
    79 apply (rule refl)
    80 apply (erule sym)
    81 done
    82 
    83 
    84 subsection{*Axiom of Choice, Proved Using the Description Operator*}
    85 
    86 lemma choice: "\<forall>x. \<exists>y. Q x y ==> \<exists>f. \<forall>x. Q x (f x)"
    87 by (fast elim: someI)
    88 
    89 lemma bchoice: "\<forall>x\<in>S. \<exists>y. Q x y ==> \<exists>f. \<forall>x\<in>S. Q x (f x)"
    90 by (fast elim: someI)
    91 
    92 lemma choice_iff: "(\<forall>x. \<exists>y. Q x y) \<longleftrightarrow> (\<exists>f. \<forall>x. Q x (f x))"
    93 by (fast elim: someI)
    94 
    95 lemma choice_iff': "(\<forall>x. P x \<longrightarrow> (\<exists>y. Q x y)) \<longleftrightarrow> (\<exists>f. \<forall>x. P x \<longrightarrow> Q x (f x))"
    96 by (fast elim: someI)
    97 
    98 lemma bchoice_iff: "(\<forall>x\<in>S. \<exists>y. Q x y) \<longleftrightarrow> (\<exists>f. \<forall>x\<in>S. Q x (f x))"
    99 by (fast elim: someI)
   100 
   101 lemma bchoice_iff': "(\<forall>x\<in>S. P x \<longrightarrow> (\<exists>y. Q x y)) \<longleftrightarrow> (\<exists>f. \<forall>x\<in>S. P x \<longrightarrow> Q x (f x))"
   102 by (fast elim: someI)
   103 
   104 lemma dependent_nat_choice:
   105   assumes  1: "\<exists>x. P 0 x" and 
   106            2: "\<And>x n. P n x \<Longrightarrow> \<exists>y. P (Suc n) y \<and> Q n x y"
   107   shows "\<exists>f. \<forall>n. P n (f n) \<and> Q n (f n) (f (Suc n))"
   108 proof (intro exI allI conjI)
   109   fix n def f \<equiv> "rec_nat (SOME x. P 0 x) (\<lambda>n x. SOME y. P (Suc n) y \<and> Q n x y)"
   110   have "P 0 (f 0)" "\<And>n. P n (f n) \<Longrightarrow> P (Suc n) (f (Suc n)) \<and> Q n (f n) (f (Suc n))"
   111     using someI_ex[OF 1] someI_ex[OF 2] by (simp_all add: f_def)
   112   then show "P n (f n)" "Q n (f n) (f (Suc n))"
   113     by (induct n) auto
   114 qed
   115 
   116 
   117 subsection {*Function Inverse*}
   118 
   119 lemma inv_def: "inv f = (%y. SOME x. f x = y)"
   120 by(simp add: inv_into_def)
   121 
   122 lemma inv_into_into: "x : f ` A ==> inv_into A f x : A"
   123 apply (simp add: inv_into_def)
   124 apply (fast intro: someI2)
   125 done
   126 
   127 lemma inv_id [simp]: "inv id = id"
   128 by (simp add: inv_into_def id_def)
   129 
   130 lemma inv_into_f_f [simp]:
   131   "[| inj_on f A;  x : A |] ==> inv_into A f (f x) = x"
   132 apply (simp add: inv_into_def inj_on_def)
   133 apply (blast intro: someI2)
   134 done
   135 
   136 lemma inv_f_f: "inj f ==> inv f (f x) = x"
   137 by simp
   138 
   139 lemma f_inv_into_f: "y : f`A  ==> f (inv_into A f y) = y"
   140 apply (simp add: inv_into_def)
   141 apply (fast intro: someI2)
   142 done
   143 
   144 lemma inv_into_f_eq: "[| inj_on f A; x : A; f x = y |] ==> inv_into A f y = x"
   145 apply (erule subst)
   146 apply (fast intro: inv_into_f_f)
   147 done
   148 
   149 lemma inv_f_eq: "[| inj f; f x = y |] ==> inv f y = x"
   150 by (simp add:inv_into_f_eq)
   151 
   152 lemma inj_imp_inv_eq: "[| inj f; ALL x. f(g x) = x |] ==> inv f = g"
   153   by (blast intro: inv_into_f_eq)
   154 
   155 text{*But is it useful?*}
   156 lemma inj_transfer:
   157   assumes injf: "inj f" and minor: "!!y. y \<in> range(f) ==> P(inv f y)"
   158   shows "P x"
   159 proof -
   160   have "f x \<in> range f" by auto
   161   hence "P(inv f (f x))" by (rule minor)
   162   thus "P x" by (simp add: inv_into_f_f [OF injf])
   163 qed
   164 
   165 lemma inj_iff: "(inj f) = (inv f o f = id)"
   166 apply (simp add: o_def fun_eq_iff)
   167 apply (blast intro: inj_on_inverseI inv_into_f_f)
   168 done
   169 
   170 lemma inv_o_cancel[simp]: "inj f ==> inv f o f = id"
   171 by (simp add: inj_iff)
   172 
   173 lemma o_inv_o_cancel[simp]: "inj f ==> g o inv f o f = g"
   174 by (simp add: comp_assoc)
   175 
   176 lemma inv_into_image_cancel[simp]:
   177   "inj_on f A ==> S <= A ==> inv_into A f ` f ` S = S"
   178 by(fastforce simp: image_def)
   179 
   180 lemma inj_imp_surj_inv: "inj f ==> surj (inv f)"
   181 by (blast intro!: surjI inv_into_f_f)
   182 
   183 lemma surj_f_inv_f: "surj f ==> f(inv f y) = y"
   184 by (simp add: f_inv_into_f)
   185 
   186 lemma inv_into_injective:
   187   assumes eq: "inv_into A f x = inv_into A f y"
   188       and x: "x: f`A"
   189       and y: "y: f`A"
   190   shows "x=y"
   191 proof -
   192   have "f (inv_into A f x) = f (inv_into A f y)" using eq by simp
   193   thus ?thesis by (simp add: f_inv_into_f x y)
   194 qed
   195 
   196 lemma inj_on_inv_into: "B <= f`A ==> inj_on (inv_into A f) B"
   197 by (blast intro: inj_onI dest: inv_into_injective injD)
   198 
   199 lemma bij_betw_inv_into: "bij_betw f A B ==> bij_betw (inv_into A f) B A"
   200 by (auto simp add: bij_betw_def inj_on_inv_into)
   201 
   202 lemma surj_imp_inj_inv: "surj f ==> inj (inv f)"
   203 by (simp add: inj_on_inv_into)
   204 
   205 lemma surj_iff: "(surj f) = (f o inv f = id)"
   206 by (auto intro!: surjI simp: surj_f_inv_f fun_eq_iff[where 'b='a])
   207 
   208 lemma surj_iff_all: "surj f \<longleftrightarrow> (\<forall>x. f (inv f x) = x)"
   209   unfolding surj_iff by (simp add: o_def fun_eq_iff)
   210 
   211 lemma surj_imp_inv_eq: "[| surj f; \<forall>x. g(f x) = x |] ==> inv f = g"
   212 apply (rule ext)
   213 apply (drule_tac x = "inv f x" in spec)
   214 apply (simp add: surj_f_inv_f)
   215 done
   216 
   217 lemma bij_imp_bij_inv: "bij f ==> bij (inv f)"
   218 by (simp add: bij_def inj_imp_surj_inv surj_imp_inj_inv)
   219 
   220 lemma inv_equality: "[| !!x. g (f x) = x;  !!y. f (g y) = y |] ==> inv f = g"
   221 apply (rule ext)
   222 apply (auto simp add: inv_into_def)
   223 done
   224 
   225 lemma inv_inv_eq: "bij f ==> inv (inv f) = f"
   226 apply (rule inv_equality)
   227 apply (auto simp add: bij_def surj_f_inv_f)
   228 done
   229 
   230 (** bij(inv f) implies little about f.  Consider f::bool=>bool such that
   231     f(True)=f(False)=True.  Then it's consistent with axiom someI that
   232     inv f could be any function at all, including the identity function.
   233     If inv f=id then inv f is a bijection, but inj f, surj(f) and
   234     inv(inv f)=f all fail.
   235 **)
   236 
   237 lemma inv_into_comp:
   238   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   239   inv_into A (f o g) x = (inv_into A g o inv_into (g ` A) f) x"
   240 apply (rule inv_into_f_eq)
   241   apply (fast intro: comp_inj_on)
   242  apply (simp add: inv_into_into)
   243 apply (simp add: f_inv_into_f inv_into_into)
   244 done
   245 
   246 lemma o_inv_distrib: "[| bij f; bij g |] ==> inv (f o g) = inv g o inv f"
   247 apply (rule inv_equality)
   248 apply (auto simp add: bij_def surj_f_inv_f)
   249 done
   250 
   251 lemma image_surj_f_inv_f: "surj f ==> f ` (inv f ` A) = A"
   252 by (simp add: image_eq_UN surj_f_inv_f)
   253 
   254 lemma image_inv_f_f: "inj f ==> inv f ` (f ` A) = A"
   255   by (simp add: image_eq_UN)
   256 
   257 lemma inv_image_comp: "inj f ==> inv f ` (f ` X) = X"
   258   by (fact image_inv_f_f)
   259 
   260 lemma bij_image_Collect_eq: "bij f ==> f ` Collect P = {y. P (inv f y)}"
   261 apply auto
   262 apply (force simp add: bij_is_inj)
   263 apply (blast intro: bij_is_surj [THEN surj_f_inv_f, symmetric])
   264 done
   265 
   266 lemma bij_vimage_eq_inv_image: "bij f ==> f -` A = inv f ` A" 
   267 apply (auto simp add: bij_is_surj [THEN surj_f_inv_f])
   268 apply (blast intro: bij_is_inj [THEN inv_into_f_f, symmetric])
   269 done
   270 
   271 lemma finite_fun_UNIVD1:
   272   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
   273   and card: "card (UNIV :: 'b set) \<noteq> Suc 0"
   274   shows "finite (UNIV :: 'a set)"
   275 proof -
   276   from fin have finb: "finite (UNIV :: 'b set)" by (rule finite_fun_UNIVD2)
   277   with card have "card (UNIV :: 'b set) \<ge> Suc (Suc 0)"
   278     by (cases "card (UNIV :: 'b set)") (auto simp add: card_eq_0_iff)
   279   then obtain n where "card (UNIV :: 'b set) = Suc (Suc n)" "n = card (UNIV :: 'b set) - Suc (Suc 0)" by auto
   280   then obtain b1 b2 where b1b2: "(b1 :: 'b) \<noteq> (b2 :: 'b)" by (auto simp add: card_Suc_eq)
   281   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1))" by (rule finite_imageI)
   282   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1)"
   283   proof (rule UNIV_eq_I)
   284     fix x :: 'a
   285     from b1b2 have "x = inv (\<lambda>y. if y = x then b1 else b2) b1" by (simp add: inv_into_def)
   286     thus "x \<in> range (\<lambda>f\<Colon>'a \<Rightarrow> 'b. inv f b1)" by blast
   287   qed
   288   ultimately show "finite (UNIV :: 'a set)" by simp
   289 qed
   290 
   291 text {*
   292   Every infinite set contains a countable subset. More precisely we
   293   show that a set @{text S} is infinite if and only if there exists an
   294   injective function from the naturals into @{text S}.
   295 
   296   The ``only if'' direction is harder because it requires the
   297   construction of a sequence of pairwise different elements of an
   298   infinite set @{text S}. The idea is to construct a sequence of
   299   non-empty and infinite subsets of @{text S} obtained by successively
   300   removing elements of @{text S}.
   301 *}
   302 
   303 lemma infinite_countable_subset:
   304   assumes inf: "\<not> finite (S::'a set)"
   305   shows "\<exists>f. inj (f::nat \<Rightarrow> 'a) \<and> range f \<subseteq> S"
   306   -- {* Courtesy of Stephan Merz *}
   307 proof -
   308   def Sseq \<equiv> "rec_nat S (\<lambda>n T. T - {SOME e. e \<in> T})"
   309   def pick \<equiv> "\<lambda>n. (SOME e. e \<in> Sseq n)"
   310   { fix n have "Sseq n \<subseteq> S" "\<not> finite (Sseq n)" by (induct n) (auto simp add: Sseq_def inf) }
   311   moreover then have *: "\<And>n. pick n \<in> Sseq n"
   312     unfolding pick_def by (subst (asm) finite.simps) (auto simp add: ex_in_conv intro: someI_ex)
   313   ultimately have "range pick \<subseteq> S" by auto
   314   moreover
   315   { fix n m                 
   316     have "pick n \<notin> Sseq (n + Suc m)" by (induct m) (auto simp add: Sseq_def pick_def)
   317     with * have "pick n \<noteq> pick (n + Suc m)" by auto
   318   }
   319   then have "inj pick" by (intro linorder_injI) (auto simp add: less_iff_Suc_add)
   320   ultimately show ?thesis by blast
   321 qed
   322 
   323 lemma infinite_iff_countable_subset: "\<not> finite S \<longleftrightarrow> (\<exists>f. inj (f::nat \<Rightarrow> 'a) \<and> range f \<subseteq> S)"
   324   -- {* Courtesy of Stephan Merz *}
   325   using finite_imageD finite_subset infinite_UNIV_char_0 infinite_countable_subset by auto
   326 
   327 lemma image_inv_into_cancel:
   328   assumes SURJ: "f`A=A'" and SUB: "B' \<le> A'"
   329   shows "f `((inv_into A f)`B') = B'"
   330   using assms
   331 proof (auto simp add: f_inv_into_f)
   332   let ?f' = "(inv_into A f)"
   333   fix a' assume *: "a' \<in> B'"
   334   then have "a' \<in> A'" using SUB by auto
   335   then have "a' = f (?f' a')"
   336     using SURJ by (auto simp add: f_inv_into_f)
   337   then show "a' \<in> f ` (?f' ` B')" using * by blast
   338 qed
   339 
   340 lemma inv_into_inv_into_eq:
   341   assumes "bij_betw f A A'" "a \<in> A"
   342   shows "inv_into A' (inv_into A f) a = f a"
   343 proof -
   344   let ?f' = "inv_into A f"   let ?f'' = "inv_into A' ?f'"
   345   have 1: "bij_betw ?f' A' A" using assms
   346   by (auto simp add: bij_betw_inv_into)
   347   obtain a' where 2: "a' \<in> A'" and 3: "?f' a' = a"
   348     using 1 `a \<in> A` unfolding bij_betw_def by force
   349   hence "?f'' a = a'"
   350     using `a \<in> A` 1 3 by (auto simp add: f_inv_into_f bij_betw_def)
   351   moreover have "f a = a'" using assms 2 3
   352     by (auto simp add: bij_betw_def)
   353   ultimately show "?f'' a = f a" by simp
   354 qed
   355 
   356 lemma inj_on_iff_surj:
   357   assumes "A \<noteq> {}"
   358   shows "(\<exists>f. inj_on f A \<and> f ` A \<le> A') \<longleftrightarrow> (\<exists>g. g ` A' = A)"
   359 proof safe
   360   fix f assume INJ: "inj_on f A" and INCL: "f ` A \<le> A'"
   361   let ?phi = "\<lambda>a' a. a \<in> A \<and> f a = a'"  let ?csi = "\<lambda>a. a \<in> A"
   362   let ?g = "\<lambda>a'. if a' \<in> f ` A then (SOME a. ?phi a' a) else (SOME a. ?csi a)"
   363   have "?g ` A' = A"
   364   proof
   365     show "?g ` A' \<le> A"
   366     proof clarify
   367       fix a' assume *: "a' \<in> A'"
   368       show "?g a' \<in> A"
   369       proof cases
   370         assume Case1: "a' \<in> f ` A"
   371         then obtain a where "?phi a' a" by blast
   372         hence "?phi a' (SOME a. ?phi a' a)" using someI[of "?phi a'" a] by blast
   373         with Case1 show ?thesis by auto
   374       next
   375         assume Case2: "a' \<notin> f ` A"
   376         hence "?csi (SOME a. ?csi a)" using assms someI_ex[of ?csi] by blast
   377         with Case2 show ?thesis by auto
   378       qed
   379     qed
   380   next
   381     show "A \<le> ?g ` A'"
   382     proof-
   383       {fix a assume *: "a \<in> A"
   384        let ?b = "SOME aa. ?phi (f a) aa"
   385        have "?phi (f a) a" using * by auto
   386        hence 1: "?phi (f a) ?b" using someI[of "?phi(f a)" a] by blast
   387        hence "?g(f a) = ?b" using * by auto
   388        moreover have "a = ?b" using 1 INJ * by (auto simp add: inj_on_def)
   389        ultimately have "?g(f a) = a" by simp
   390        with INCL * have "?g(f a) = a \<and> f a \<in> A'" by auto
   391       }
   392       thus ?thesis by force
   393     qed
   394   qed
   395   thus "\<exists>g. g ` A' = A" by blast
   396 next
   397   fix g  let ?f = "inv_into A' g"
   398   have "inj_on ?f (g ` A')"
   399     by (auto simp add: inj_on_inv_into)
   400   moreover
   401   {fix a' assume *: "a' \<in> A'"
   402    let ?phi = "\<lambda> b'. b' \<in> A' \<and> g b' = g a'"
   403    have "?phi a'" using * by auto
   404    hence "?phi(SOME b'. ?phi b')" using someI[of ?phi] by blast
   405    hence "?f(g a') \<in> A'" unfolding inv_into_def by auto
   406   }
   407   ultimately show "\<exists>f. inj_on f (g ` A') \<and> f ` g ` A' \<subseteq> A'" by auto
   408 qed
   409 
   410 lemma Ex_inj_on_UNION_Sigma:
   411   "\<exists>f. (inj_on f (\<Union> i \<in> I. A i) \<and> f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i))"
   412 proof
   413   let ?phi = "\<lambda> a i. i \<in> I \<and> a \<in> A i"
   414   let ?sm = "\<lambda> a. SOME i. ?phi a i"
   415   let ?f = "\<lambda>a. (?sm a, a)"
   416   have "inj_on ?f (\<Union> i \<in> I. A i)" unfolding inj_on_def by auto
   417   moreover
   418   { { fix i a assume "i \<in> I" and "a \<in> A i"
   419       hence "?sm a \<in> I \<and> a \<in> A(?sm a)" using someI[of "?phi a" i] by auto
   420     }
   421     hence "?f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i)" by auto
   422   }
   423   ultimately
   424   show "inj_on ?f (\<Union> i \<in> I. A i) \<and> ?f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i)"
   425   by auto
   426 qed
   427 
   428 lemma inv_unique_comp:
   429   assumes fg: "f \<circ> g = id"
   430     and gf: "g \<circ> f = id"
   431   shows "inv f = g"
   432   using fg gf inv_equality[of g f] by (auto simp add: fun_eq_iff)
   433 
   434 
   435 subsection {* The Cantor-Bernstein Theorem *}
   436 
   437 lemma Cantor_Bernstein_aux:
   438   shows "\<exists>A' h. A' \<le> A \<and>
   439                 (\<forall>a \<in> A'. a \<notin> g`(B - f ` A')) \<and>
   440                 (\<forall>a \<in> A'. h a = f a) \<and>
   441                 (\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a))"
   442 proof-
   443   obtain H where H_def: "H = (\<lambda> A'. A - (g`(B - (f ` A'))))" by blast
   444   have 0: "mono H" unfolding mono_def H_def by blast
   445   then obtain A' where 1: "H A' = A'" using lfp_unfold by blast
   446   hence 2: "A' = A - (g`(B - (f ` A')))" unfolding H_def by simp
   447   hence 3: "A' \<le> A" by blast
   448   have 4: "\<forall>a \<in> A'.  a \<notin> g`(B - f ` A')"
   449   using 2 by blast
   450   have 5: "\<forall>a \<in> A - A'. \<exists>b \<in> B - (f ` A'). a = g b"
   451   using 2 by blast
   452   (*  *)
   453   obtain h where h_def:
   454   "h = (\<lambda> a. if a \<in> A' then f a else (SOME b. b \<in> B - (f ` A') \<and> a = g b))" by blast
   455   hence "\<forall>a \<in> A'. h a = f a" by auto
   456   moreover
   457   have "\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a)"
   458   proof
   459     fix a assume *: "a \<in> A - A'"
   460     let ?phi = "\<lambda> b. b \<in> B - (f ` A') \<and> a = g b"
   461     have "h a = (SOME b. ?phi b)" using h_def * by auto
   462     moreover have "\<exists>b. ?phi b" using 5 *  by auto
   463     ultimately show  "?phi (h a)" using someI_ex[of ?phi] by auto
   464   qed
   465   ultimately show ?thesis using 3 4 by blast
   466 qed
   467 
   468 theorem Cantor_Bernstein:
   469   assumes INJ1: "inj_on f A" and SUB1: "f ` A \<le> B" and
   470           INJ2: "inj_on g B" and SUB2: "g ` B \<le> A"
   471   shows "\<exists>h. bij_betw h A B"
   472 proof-
   473   obtain A' and h where 0: "A' \<le> A" and
   474   1: "\<forall>a \<in> A'. a \<notin> g`(B - f ` A')" and
   475   2: "\<forall>a \<in> A'. h a = f a" and
   476   3: "\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a)"
   477   using Cantor_Bernstein_aux[of A g B f] by blast
   478   have "inj_on h A"
   479   proof (intro inj_onI)
   480     fix a1 a2
   481     assume 4: "a1 \<in> A" and 5: "a2 \<in> A" and 6: "h a1 = h a2"
   482     show "a1 = a2"
   483     proof(cases "a1 \<in> A'")
   484       assume Case1: "a1 \<in> A'"
   485       show ?thesis
   486       proof(cases "a2 \<in> A'")
   487         assume Case11: "a2 \<in> A'"
   488         hence "f a1 = f a2" using Case1 2 6 by auto
   489         thus ?thesis using INJ1 Case1 Case11 0
   490         unfolding inj_on_def by blast
   491       next
   492         assume Case12: "a2 \<notin> A'"
   493         hence False using 3 5 2 6 Case1 by force
   494         thus ?thesis by simp
   495       qed
   496     next
   497     assume Case2: "a1 \<notin> A'"
   498       show ?thesis
   499       proof(cases "a2 \<in> A'")
   500         assume Case21: "a2 \<in> A'"
   501         hence False using 3 4 2 6 Case2 by auto
   502         thus ?thesis by simp
   503       next
   504         assume Case22: "a2 \<notin> A'"
   505         hence "a1 = g(h a1) \<and> a2 = g(h a2)" using Case2 4 5 3 by auto
   506         thus ?thesis using 6 by simp
   507       qed
   508     qed
   509   qed
   510   (*  *)
   511   moreover
   512   have "h ` A = B"
   513   proof safe
   514     fix a assume "a \<in> A"
   515     thus "h a \<in> B" using SUB1 2 3 by (cases "a \<in> A'") auto
   516   next
   517     fix b assume *: "b \<in> B"
   518     show "b \<in> h ` A"
   519     proof(cases "b \<in> f ` A'")
   520       assume Case1: "b \<in> f ` A'"
   521       then obtain a where "a \<in> A' \<and> b = f a" by blast
   522       thus ?thesis using 2 0 by force
   523     next
   524       assume Case2: "b \<notin> f ` A'"
   525       hence "g b \<notin> A'" using 1 * by auto
   526       hence 4: "g b \<in> A - A'" using * SUB2 by auto
   527       hence "h(g b) \<in> B \<and> g(h(g b)) = g b"
   528       using 3 by auto
   529       hence "h(g b) = b" using * INJ2 unfolding inj_on_def by auto
   530       thus ?thesis using 4 by force
   531     qed
   532   qed
   533   (*  *)
   534   ultimately show ?thesis unfolding bij_betw_def by auto
   535 qed
   536 
   537 subsection {*Other Consequences of Hilbert's Epsilon*}
   538 
   539 text {*Hilbert's Epsilon and the @{term split} Operator*}
   540 
   541 text{*Looping simprule*}
   542 lemma split_paired_Eps: "(SOME x. P x) = (SOME (a,b). P(a,b))"
   543   by simp
   544 
   545 lemma Eps_split: "Eps (split P) = (SOME xy. P (fst xy) (snd xy))"
   546   by (simp add: split_def)
   547 
   548 lemma Eps_split_eq [simp]: "(@(x',y'). x = x' & y = y') = (x,y)"
   549   by blast
   550 
   551 
   552 text{*A relation is wellfounded iff it has no infinite descending chain*}
   553 lemma wf_iff_no_infinite_down_chain:
   554   "wf r = (~(\<exists>f. \<forall>i. (f(Suc i),f i) \<in> r))"
   555 apply (simp only: wf_eq_minimal)
   556 apply (rule iffI)
   557  apply (rule notI)
   558  apply (erule exE)
   559  apply (erule_tac x = "{w. \<exists>i. w=f i}" in allE, blast)
   560 apply (erule contrapos_np, simp, clarify)
   561 apply (subgoal_tac "\<forall>n. rec_nat x (%i y. @z. z:Q & (z,y) :r) n \<in> Q")
   562  apply (rule_tac x = "rec_nat x (%i y. @z. z:Q & (z,y) :r)" in exI)
   563  apply (rule allI, simp)
   564  apply (rule someI2_ex, blast, blast)
   565 apply (rule allI)
   566 apply (induct_tac "n", simp_all)
   567 apply (rule someI2_ex, blast+)
   568 done
   569 
   570 lemma wf_no_infinite_down_chainE:
   571   assumes "wf r" obtains k where "(f (Suc k), f k) \<notin> r"
   572 using `wf r` wf_iff_no_infinite_down_chain[of r] by blast
   573 
   574 
   575 text{*A dynamically-scoped fact for TFL *}
   576 lemma tfl_some: "\<forall>P x. P x --> P (Eps P)"
   577   by (blast intro: someI)
   578 
   579 
   580 subsection {* Least value operator *}
   581 
   582 definition
   583   LeastM :: "['a => 'b::ord, 'a => bool] => 'a" where
   584   "LeastM m P == SOME x. P x & (\<forall>y. P y --> m x <= m y)"
   585 
   586 syntax
   587   "_LeastM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"    ("LEAST _ WRT _. _" [0, 4, 10] 10)
   588 translations
   589   "LEAST x WRT m. P" == "CONST LeastM m (%x. P)"
   590 
   591 lemma LeastMI2:
   592   "P x ==> (!!y. P y ==> m x <= m y)
   593     ==> (!!x. P x ==> \<forall>y. P y --> m x \<le> m y ==> Q x)
   594     ==> Q (LeastM m P)"
   595   apply (simp add: LeastM_def)
   596   apply (rule someI2_ex, blast, blast)
   597   done
   598 
   599 lemma LeastM_equality:
   600   "P k ==> (!!x. P x ==> m k <= m x)
   601     ==> m (LEAST x WRT m. P x) = (m k::'a::order)"
   602   apply (rule LeastMI2, assumption, blast)
   603   apply (blast intro!: order_antisym)
   604   done
   605 
   606 lemma wf_linord_ex_has_least:
   607   "wf r ==> \<forall>x y. ((x,y):r^+) = ((y,x)~:r^*) ==> P k
   608     ==> \<exists>x. P x & (!y. P y --> (m x,m y):r^*)"
   609   apply (drule wf_trancl [THEN wf_eq_minimal [THEN iffD1]])
   610   apply (drule_tac x = "m`Collect P" in spec, force)
   611   done
   612 
   613 lemma ex_has_least_nat:
   614     "P k ==> \<exists>x. P x & (\<forall>y. P y --> m x <= (m y::nat))"
   615   apply (simp only: pred_nat_trancl_eq_le [symmetric])
   616   apply (rule wf_pred_nat [THEN wf_linord_ex_has_least])
   617    apply (simp add: less_eq linorder_not_le pred_nat_trancl_eq_le, assumption)
   618   done
   619 
   620 lemma LeastM_nat_lemma:
   621     "P k ==> P (LeastM m P) & (\<forall>y. P y --> m (LeastM m P) <= (m y::nat))"
   622   apply (simp add: LeastM_def)
   623   apply (rule someI_ex)
   624   apply (erule ex_has_least_nat)
   625   done
   626 
   627 lemmas LeastM_natI = LeastM_nat_lemma [THEN conjunct1]
   628 
   629 lemma LeastM_nat_le: "P x ==> m (LeastM m P) <= (m x::nat)"
   630 by (rule LeastM_nat_lemma [THEN conjunct2, THEN spec, THEN mp], assumption, assumption)
   631 
   632 
   633 subsection {* Greatest value operator *}
   634 
   635 definition
   636   GreatestM :: "['a => 'b::ord, 'a => bool] => 'a" where
   637   "GreatestM m P == SOME x. P x & (\<forall>y. P y --> m y <= m x)"
   638 
   639 definition
   640   Greatest :: "('a::ord => bool) => 'a" (binder "GREATEST " 10) where
   641   "Greatest == GreatestM (%x. x)"
   642 
   643 syntax
   644   "_GreatestM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"
   645       ("GREATEST _ WRT _. _" [0, 4, 10] 10)
   646 translations
   647   "GREATEST x WRT m. P" == "CONST GreatestM m (%x. P)"
   648 
   649 lemma GreatestMI2:
   650   "P x ==> (!!y. P y ==> m y <= m x)
   651     ==> (!!x. P x ==> \<forall>y. P y --> m y \<le> m x ==> Q x)
   652     ==> Q (GreatestM m P)"
   653   apply (simp add: GreatestM_def)
   654   apply (rule someI2_ex, blast, blast)
   655   done
   656 
   657 lemma GreatestM_equality:
   658  "P k ==> (!!x. P x ==> m x <= m k)
   659     ==> m (GREATEST x WRT m. P x) = (m k::'a::order)"
   660   apply (rule_tac m = m in GreatestMI2, assumption, blast)
   661   apply (blast intro!: order_antisym)
   662   done
   663 
   664 lemma Greatest_equality:
   665   "P (k::'a::order) ==> (!!x. P x ==> x <= k) ==> (GREATEST x. P x) = k"
   666   apply (simp add: Greatest_def)
   667   apply (erule GreatestM_equality, blast)
   668   done
   669 
   670 lemma ex_has_greatest_nat_lemma:
   671   "P k ==> \<forall>x. P x --> (\<exists>y. P y & ~ ((m y::nat) <= m x))
   672     ==> \<exists>y. P y & ~ (m y < m k + n)"
   673   apply (induct n, force)
   674   apply (force simp add: le_Suc_eq)
   675   done
   676 
   677 lemma ex_has_greatest_nat:
   678   "P k ==> \<forall>y. P y --> m y < b
   679     ==> \<exists>x. P x & (\<forall>y. P y --> (m y::nat) <= m x)"
   680   apply (rule ccontr)
   681   apply (cut_tac P = P and n = "b - m k" in ex_has_greatest_nat_lemma)
   682     apply (subgoal_tac [3] "m k <= b", auto)
   683   done
   684 
   685 lemma GreatestM_nat_lemma:
   686   "P k ==> \<forall>y. P y --> m y < b
   687     ==> P (GreatestM m P) & (\<forall>y. P y --> (m y::nat) <= m (GreatestM m P))"
   688   apply (simp add: GreatestM_def)
   689   apply (rule someI_ex)
   690   apply (erule ex_has_greatest_nat, assumption)
   691   done
   692 
   693 lemmas GreatestM_natI = GreatestM_nat_lemma [THEN conjunct1]
   694 
   695 lemma GreatestM_nat_le:
   696   "P x ==> \<forall>y. P y --> m y < b
   697     ==> (m x::nat) <= m (GreatestM m P)"
   698   apply (blast dest: GreatestM_nat_lemma [THEN conjunct2, THEN spec, of P])
   699   done
   700 
   701 
   702 text {* \medskip Specialization to @{text GREATEST}. *}
   703 
   704 lemma GreatestI: "P (k::nat) ==> \<forall>y. P y --> y < b ==> P (GREATEST x. P x)"
   705   apply (simp add: Greatest_def)
   706   apply (rule GreatestM_natI, auto)
   707   done
   708 
   709 lemma Greatest_le:
   710     "P x ==> \<forall>y. P y --> y < b ==> (x::nat) <= (GREATEST x. P x)"
   711   apply (simp add: Greatest_def)
   712   apply (rule GreatestM_nat_le, auto)
   713   done
   714 
   715 
   716 subsection {* An aside: bounded accessible part *}
   717 
   718 text {* Finite monotone eventually stable sequences *}
   719 
   720 lemma finite_mono_remains_stable_implies_strict_prefix:
   721   fixes f :: "nat \<Rightarrow> 'a::order"
   722   assumes S: "finite (range f)" "mono f" and eq: "\<forall>n. f n = f (Suc n) \<longrightarrow> f (Suc n) = f (Suc (Suc n))"
   723   shows "\<exists>N. (\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m < f n) \<and> (\<forall>n\<ge>N. f N = f n)"
   724   using assms
   725 proof -
   726   have "\<exists>n. f n = f (Suc n)"
   727   proof (rule ccontr)
   728     assume "\<not> ?thesis"
   729     then have "\<And>n. f n \<noteq> f (Suc n)" by auto
   730     then have "\<And>n. f n < f (Suc n)"
   731       using  `mono f` by (auto simp: le_less mono_iff_le_Suc)
   732     with lift_Suc_mono_less_iff[of f]
   733     have *: "\<And>n m. n < m \<Longrightarrow> f n < f m" by auto
   734     have "inj f"
   735     proof (intro injI)
   736       fix x y
   737       assume "f x = f y"
   738       then show "x = y" by (cases x y rule: linorder_cases) (auto dest: *)
   739     qed
   740     with `finite (range f)` have "finite (UNIV::nat set)"
   741       by (rule finite_imageD)
   742     then show False by simp
   743   qed
   744   then obtain n where n: "f n = f (Suc n)" ..
   745   def N \<equiv> "LEAST n. f n = f (Suc n)"
   746   have N: "f N = f (Suc N)"
   747     unfolding N_def using n by (rule LeastI)
   748   show ?thesis
   749   proof (intro exI[of _ N] conjI allI impI)
   750     fix n assume "N \<le> n"
   751     then have "\<And>m. N \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m = f N"
   752     proof (induct rule: dec_induct)
   753       case (step n) then show ?case
   754         using eq[rule_format, of "n - 1"] N
   755         by (cases n) (auto simp add: le_Suc_eq)
   756     qed simp
   757     from this[of n] `N \<le> n` show "f N = f n" by auto
   758   next
   759     fix n m :: nat assume "m < n" "n \<le> N"
   760     then show "f m < f n"
   761     proof (induct rule: less_Suc_induct[consumes 1])
   762       case (1 i)
   763       then have "i < N" by simp
   764       then have "f i \<noteq> f (Suc i)"
   765         unfolding N_def by (rule not_less_Least)
   766       with `mono f` show ?case by (simp add: mono_iff_le_Suc less_le)
   767     qed auto
   768   qed
   769 qed
   770 
   771 lemma finite_mono_strict_prefix_implies_finite_fixpoint:
   772   fixes f :: "nat \<Rightarrow> 'a set"
   773   assumes S: "\<And>i. f i \<subseteq> S" "finite S"
   774     and inj: "\<exists>N. (\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m \<subset> f n) \<and> (\<forall>n\<ge>N. f N = f n)"
   775   shows "f (card S) = (\<Union>n. f n)"
   776 proof -
   777   from inj obtain N where inj: "(\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m \<subset> f n)" and eq: "(\<forall>n\<ge>N. f N = f n)" by auto
   778 
   779   { fix i have "i \<le> N \<Longrightarrow> i \<le> card (f i)"
   780     proof (induct i)
   781       case 0 then show ?case by simp
   782     next
   783       case (Suc i)
   784       with inj[rule_format, of "Suc i" i]
   785       have "(f i) \<subset> (f (Suc i))" by auto
   786       moreover have "finite (f (Suc i))" using S by (rule finite_subset)
   787       ultimately have "card (f i) < card (f (Suc i))" by (intro psubset_card_mono)
   788       with Suc show ?case using inj by auto
   789     qed
   790   }
   791   then have "N \<le> card (f N)" by simp
   792   also have "\<dots> \<le> card S" using S by (intro card_mono)
   793   finally have "f (card S) = f N" using eq by auto
   794   then show ?thesis using eq inj[rule_format, of N]
   795     apply auto
   796     apply (case_tac "n < N")
   797     apply (auto simp: not_less)
   798     done
   799 qed
   800 
   801 
   802 subsection {* More on injections, bijections, and inverses *}
   803 
   804 lemma infinite_imp_bij_betw:
   805 assumes INF: "\<not> finite A"
   806 shows "\<exists>h. bij_betw h A (A - {a})"
   807 proof(cases "a \<in> A")
   808   assume Case1: "a \<notin> A"  hence "A - {a} = A" by blast
   809   thus ?thesis using bij_betw_id[of A] by auto
   810 next
   811   assume Case2: "a \<in> A"
   812   have "\<not> finite (A - {a})" using INF by auto
   813   with infinite_iff_countable_subset[of "A - {a}"] obtain f::"nat \<Rightarrow> 'a"
   814   where 1: "inj f" and 2: "f ` UNIV \<le> A - {a}" by blast
   815   obtain g where g_def: "g = (\<lambda> n. if n = 0 then a else f (Suc n))" by blast
   816   obtain A' where A'_def: "A' = g ` UNIV" by blast
   817   have temp: "\<forall>y. f y \<noteq> a" using 2 by blast
   818   have 3: "inj_on g UNIV \<and> g ` UNIV \<le> A \<and> a \<in> g ` UNIV"
   819   proof(auto simp add: Case2 g_def, unfold inj_on_def, intro ballI impI,
   820         case_tac "x = 0", auto simp add: 2)
   821     fix y  assume "a = (if y = 0 then a else f (Suc y))"
   822     thus "y = 0" using temp by (case_tac "y = 0", auto)
   823   next
   824     fix x y
   825     assume "f (Suc x) = (if y = 0 then a else f (Suc y))"
   826     thus "x = y" using 1 temp unfolding inj_on_def by (case_tac "y = 0", auto)
   827   next
   828     fix n show "f (Suc n) \<in> A" using 2 by blast
   829   qed
   830   hence 4: "bij_betw g UNIV A' \<and> a \<in> A' \<and> A' \<le> A"
   831   using inj_on_imp_bij_betw[of g] unfolding A'_def by auto
   832   hence 5: "bij_betw (inv g) A' UNIV"
   833   by (auto simp add: bij_betw_inv_into)
   834   (*  *)
   835   obtain n where "g n = a" using 3 by auto
   836   hence 6: "bij_betw g (UNIV - {n}) (A' - {a})"
   837   using 3 4 unfolding A'_def
   838   by clarify (rule bij_betw_subset, auto simp: image_set_diff)
   839   (*  *)
   840   obtain v where v_def: "v = (\<lambda> m. if m < n then m else Suc m)" by blast
   841   have 7: "bij_betw v UNIV (UNIV - {n})"
   842   proof(unfold bij_betw_def inj_on_def, intro conjI, clarify)
   843     fix m1 m2 assume "v m1 = v m2"
   844     thus "m1 = m2"
   845     by(case_tac "m1 < n", case_tac "m2 < n",
   846        auto simp add: inj_on_def v_def, case_tac "m2 < n", auto)
   847   next
   848     show "v ` UNIV = UNIV - {n}"
   849     proof(auto simp add: v_def)
   850       fix m assume *: "m \<noteq> n" and **: "m \<notin> Suc ` {m'. \<not> m' < n}"
   851       {assume "n \<le> m" with * have 71: "Suc n \<le> m" by auto
   852        then obtain m' where 72: "m = Suc m'" using Suc_le_D by auto
   853        with 71 have "n \<le> m'" by auto
   854        with 72 ** have False by auto
   855       }
   856       thus "m < n" by force
   857     qed
   858   qed
   859   (*  *)
   860   obtain h' where h'_def: "h' = g o v o (inv g)" by blast
   861   hence 8: "bij_betw h' A' (A' - {a})" using 5 7 6
   862   by (auto simp add: bij_betw_trans)
   863   (*  *)
   864   obtain h where h_def: "h = (\<lambda> b. if b \<in> A' then h' b else b)" by blast
   865   have "\<forall>b \<in> A'. h b = h' b" unfolding h_def by auto
   866   hence "bij_betw h  A' (A' - {a})" using 8 bij_betw_cong[of A' h] by auto
   867   moreover
   868   {have "\<forall>b \<in> A - A'. h b = b" unfolding h_def by auto
   869    hence "bij_betw h  (A - A') (A - A')"
   870    using bij_betw_cong[of "A - A'" h id] bij_betw_id[of "A - A'"] by auto
   871   }
   872   moreover
   873   have "(A' Int (A - A') = {} \<and> A' \<union> (A - A') = A) \<and>
   874         ((A' - {a}) Int (A - A') = {} \<and> (A' - {a}) \<union> (A - A') = A - {a})"
   875   using 4 by blast
   876   ultimately have "bij_betw h A (A - {a})"
   877   using bij_betw_combine[of h A' "A' - {a}" "A - A'" "A - A'"] by simp
   878   thus ?thesis by blast
   879 qed
   880 
   881 lemma infinite_imp_bij_betw2:
   882 assumes INF: "\<not> finite A"
   883 shows "\<exists>h. bij_betw h A (A \<union> {a})"
   884 proof(cases "a \<in> A")
   885   assume Case1: "a \<in> A"  hence "A \<union> {a} = A" by blast
   886   thus ?thesis using bij_betw_id[of A] by auto
   887 next
   888   let ?A' = "A \<union> {a}"
   889   assume Case2: "a \<notin> A" hence "A = ?A' - {a}" by blast
   890   moreover have "\<not> finite ?A'" using INF by auto
   891   ultimately obtain f where "bij_betw f ?A' A"
   892   using infinite_imp_bij_betw[of ?A' a] by auto
   893   hence "bij_betw(inv_into ?A' f) A ?A'" using bij_betw_inv_into by blast
   894   thus ?thesis by auto
   895 qed
   896 
   897 lemma bij_betw_inv_into_left:
   898 assumes BIJ: "bij_betw f A A'" and IN: "a \<in> A"
   899 shows "(inv_into A f) (f a) = a"
   900 using assms unfolding bij_betw_def
   901 by clarify (rule inv_into_f_f)
   902 
   903 lemma bij_betw_inv_into_right:
   904 assumes "bij_betw f A A'" "a' \<in> A'"
   905 shows "f(inv_into A f a') = a'"
   906 using assms unfolding bij_betw_def using f_inv_into_f by force
   907 
   908 lemma bij_betw_inv_into_subset:
   909 assumes BIJ: "bij_betw f A A'" and
   910         SUB: "B \<le> A" and IM: "f ` B = B'"
   911 shows "bij_betw (inv_into A f) B' B"
   912 using assms unfolding bij_betw_def
   913 by (auto intro: inj_on_inv_into)
   914 
   915 
   916 subsection {* Specification package -- Hilbertized version *}
   917 
   918 lemma exE_some: "[| Ex P ; c == Eps P |] ==> P c"
   919   by (simp only: someI_ex)
   920 
   921 ML_file "Tools/choice_specification.ML"
   922 
   923 end