src/HOL/Limits.thy
author haftmann
Fri Jun 19 07:53:35 2015 +0200 (2015-06-19)
changeset 60517 f16e4fb20652
parent 60182 e1ea5a6379c9
child 60721 c1b7793c23a3
permissions -rw-r--r--
separate class for notions specific for integral (semi)domains, in contrast to fields where these are trivial
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 *)
     7 
     8 section {* Limits on Real Vector Spaces *}
     9 
    10 theory Limits
    11 imports Real_Vector_Spaces
    12 begin
    13 
    14 subsection {* Filter going to infinity norm *}
    15 
    16 definition at_infinity :: "'a::real_normed_vector filter" where
    17   "at_infinity = (INF r. principal {x. r \<le> norm x})"
    18 
    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    20   unfolding at_infinity_def
    21   by (subst eventually_INF_base)
    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
    23 
    24 lemma at_infinity_eq_at_top_bot:
    25   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
    26   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
    27                    eventually_at_top_linorder eventually_at_bot_linorder)
    28   apply safe
    29   apply (rule_tac x="b" in exI, simp)
    30   apply (rule_tac x="- b" in exI, simp)
    31   apply (rule_tac x="max (- Na) N" in exI, auto simp: abs_real_def)
    32   done
    33 
    34 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
    35   unfolding at_infinity_eq_at_top_bot by simp
    36 
    37 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
    38   unfolding at_infinity_eq_at_top_bot by simp
    39 
    40 lemma filterlim_at_top_imp_at_infinity:
    41   fixes f :: "_ \<Rightarrow> real"
    42   shows "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    43   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    44 
    45 lemma lim_infinity_imp_sequentially:
    46   "(f ---> l) at_infinity \<Longrightarrow> ((\<lambda>n. f(n)) ---> l) sequentially"
    47 by (simp add: filterlim_at_top_imp_at_infinity filterlim_compose filterlim_real_sequentially)
    48 
    49 
    50 subsubsection {* Boundedness *}
    51 
    52 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    53   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    54 
    55 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    56   "Bseq X \<equiv> Bfun X sequentially"
    57 
    58 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    59 
    60 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    61   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    62 
    63 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    64   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    65 
    66 lemma Bfun_def:
    67   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    68   unfolding Bfun_metric_def norm_conv_dist
    69 proof safe
    70   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    71   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    72     by (intro always_eventually) (metis dist_commute dist_triangle)
    73   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    74     by eventually_elim auto
    75   with `0 < K` show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    76     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    77 qed auto
    78 
    79 lemma BfunI:
    80   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    81 unfolding Bfun_def
    82 proof (intro exI conjI allI)
    83   show "0 < max K 1" by simp
    84 next
    85   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    86     using K by (rule eventually_elim1, simp)
    87 qed
    88 
    89 lemma BfunE:
    90   assumes "Bfun f F"
    91   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    92 using assms unfolding Bfun_def by fast
    93 
    94 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
    95   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
    96   apply (erule_tac x=1 in allE)
    97   apply simp
    98   apply safe
    99   apply (rule_tac x="X M" in exI)
   100   apply (rule_tac x=1 in exI)
   101   apply (erule_tac x=M in allE)
   102   apply simp
   103   apply (rule_tac x=M in exI)
   104   apply (auto simp: dist_commute)
   105   done
   106 
   107 
   108 subsubsection {* Bounded Sequences *}
   109 
   110 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   111   by (intro BfunI) (auto simp: eventually_sequentially)
   112 
   113 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   114   by (intro BfunI) (auto simp: eventually_sequentially)
   115 
   116 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   117   unfolding Bfun_def eventually_sequentially
   118 proof safe
   119   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   120   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   121     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   122        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   123 qed auto
   124 
   125 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   126 unfolding Bseq_def by auto
   127 
   128 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   129 by (simp add: Bseq_def)
   130 
   131 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   132 by (auto simp add: Bseq_def)
   133 
   134 lemma Bseq_bdd_above: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_above (range X)"
   135 proof (elim BseqE, intro bdd_aboveI2)
   136   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "X n \<le> K"
   137     by (auto elim!: allE[of _ n])
   138 qed
   139 
   140 lemma Bseq_bdd_below: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_below (range X)"
   141 proof (elim BseqE, intro bdd_belowI2)
   142   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "- K \<le> X n"
   143     by (auto elim!: allE[of _ n])
   144 qed
   145 
   146 lemma lemma_NBseq_def:
   147   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   148 proof safe
   149   fix K :: real
   150   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   151   then have "K \<le> real (Suc n)" by auto
   152   moreover assume "\<forall>m. norm (X m) \<le> K"
   153   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   154     by (blast intro: order_trans)
   155   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   156 qed (force simp add: real_of_nat_Suc)
   157 
   158 text{* alternative definition for Bseq *}
   159 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   160 apply (simp add: Bseq_def)
   161 apply (simp (no_asm) add: lemma_NBseq_def)
   162 done
   163 
   164 lemma lemma_NBseq_def2:
   165      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   166 apply (subst lemma_NBseq_def, auto)
   167 apply (rule_tac x = "Suc N" in exI)
   168 apply (rule_tac [2] x = N in exI)
   169 apply (auto simp add: real_of_nat_Suc)
   170  prefer 2 apply (blast intro: order_less_imp_le)
   171 apply (drule_tac x = n in spec, simp)
   172 done
   173 
   174 (* yet another definition for Bseq *)
   175 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   176 by (simp add: Bseq_def lemma_NBseq_def2)
   177 
   178 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   179 
   180 text{*alternative formulation for boundedness*}
   181 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   182 apply (unfold Bseq_def, safe)
   183 apply (rule_tac [2] x = "k + norm x" in exI)
   184 apply (rule_tac x = K in exI, simp)
   185 apply (rule exI [where x = 0], auto)
   186 apply (erule order_less_le_trans, simp)
   187 apply (drule_tac x=n in spec)
   188 apply (drule order_trans [OF norm_triangle_ineq2])
   189 apply simp
   190 done
   191 
   192 text{*alternative formulation for boundedness*}
   193 lemma Bseq_iff3:
   194   "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)" (is "?P \<longleftrightarrow> ?Q")
   195 proof
   196   assume ?P
   197   then obtain K
   198     where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K" by (auto simp add: Bseq_def)
   199   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   200   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   201     by (auto intro: order_trans norm_triangle_ineq4)
   202   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   203     by simp
   204   with `0 < K + norm (X 0)` show ?Q by blast
   205 next
   206   assume ?Q then show ?P by (auto simp add: Bseq_iff2)
   207 qed
   208 
   209 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   210 apply (simp add: Bseq_def)
   211 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   212 apply (drule_tac x = n in spec, arith)
   213 done
   214 
   215 
   216 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   217 
   218 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   219   by (simp add: Bseq_def)
   220 
   221 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   222   apply (simp add: subset_eq)
   223   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   224   apply (erule_tac x=n in allE)
   225   apply auto
   226   done
   227 
   228 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   229   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   230 
   231 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   232   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   233 
   234 subsection {* Bounded Monotonic Sequences *}
   235 
   236 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   237 
   238 (* TODO: delete *)
   239 (* FIXME: one use in NSA/HSEQ.thy *)
   240 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   241   apply (rule_tac x="X m" in exI)
   242   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   243   unfolding eventually_sequentially
   244   apply blast
   245   done
   246 
   247 subsection {* Convergence to Zero *}
   248 
   249 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   250   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   251 
   252 lemma ZfunI:
   253   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   254   unfolding Zfun_def by simp
   255 
   256 lemma ZfunD:
   257   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   258   unfolding Zfun_def by simp
   259 
   260 lemma Zfun_ssubst:
   261   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   262   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   263 
   264 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   265   unfolding Zfun_def by simp
   266 
   267 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   268   unfolding Zfun_def by simp
   269 
   270 lemma Zfun_imp_Zfun:
   271   assumes f: "Zfun f F"
   272   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   273   shows "Zfun (\<lambda>x. g x) F"
   274 proof (cases)
   275   assume K: "0 < K"
   276   show ?thesis
   277   proof (rule ZfunI)
   278     fix r::real assume "0 < r"
   279     hence "0 < r / K" using K by simp
   280     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   281       using ZfunD [OF f] by fast
   282     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   283     proof eventually_elim
   284       case (elim x)
   285       hence "norm (f x) * K < r"
   286         by (simp add: pos_less_divide_eq K)
   287       thus ?case
   288         by (simp add: order_le_less_trans [OF elim(1)])
   289     qed
   290   qed
   291 next
   292   assume "\<not> 0 < K"
   293   hence K: "K \<le> 0" by (simp only: not_less)
   294   show ?thesis
   295   proof (rule ZfunI)
   296     fix r :: real
   297     assume "0 < r"
   298     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   299     proof eventually_elim
   300       case (elim x)
   301       also have "norm (f x) * K \<le> norm (f x) * 0"
   302         using K norm_ge_zero by (rule mult_left_mono)
   303       finally show ?case
   304         using `0 < r` by simp
   305     qed
   306   qed
   307 qed
   308 
   309 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   310   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   311 
   312 lemma Zfun_add:
   313   assumes f: "Zfun f F" and g: "Zfun g F"
   314   shows "Zfun (\<lambda>x. f x + g x) F"
   315 proof (rule ZfunI)
   316   fix r::real assume "0 < r"
   317   hence r: "0 < r / 2" by simp
   318   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   319     using f r by (rule ZfunD)
   320   moreover
   321   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   322     using g r by (rule ZfunD)
   323   ultimately
   324   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   325   proof eventually_elim
   326     case (elim x)
   327     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   328       by (rule norm_triangle_ineq)
   329     also have "\<dots> < r/2 + r/2"
   330       using elim by (rule add_strict_mono)
   331     finally show ?case
   332       by simp
   333   qed
   334 qed
   335 
   336 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   337   unfolding Zfun_def by simp
   338 
   339 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   340   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   341 
   342 lemma (in bounded_linear) Zfun:
   343   assumes g: "Zfun g F"
   344   shows "Zfun (\<lambda>x. f (g x)) F"
   345 proof -
   346   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   347     using bounded by fast
   348   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   349     by simp
   350   with g show ?thesis
   351     by (rule Zfun_imp_Zfun)
   352 qed
   353 
   354 lemma (in bounded_bilinear) Zfun:
   355   assumes f: "Zfun f F"
   356   assumes g: "Zfun g F"
   357   shows "Zfun (\<lambda>x. f x ** g x) F"
   358 proof (rule ZfunI)
   359   fix r::real assume r: "0 < r"
   360   obtain K where K: "0 < K"
   361     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   362     using pos_bounded by fast
   363   from K have K': "0 < inverse K"
   364     by (rule positive_imp_inverse_positive)
   365   have "eventually (\<lambda>x. norm (f x) < r) F"
   366     using f r by (rule ZfunD)
   367   moreover
   368   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   369     using g K' by (rule ZfunD)
   370   ultimately
   371   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   372   proof eventually_elim
   373     case (elim x)
   374     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   375       by (rule norm_le)
   376     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   377       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   378     also from K have "r * inverse K * K = r"
   379       by simp
   380     finally show ?case .
   381   qed
   382 qed
   383 
   384 lemma (in bounded_bilinear) Zfun_left:
   385   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   386   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   387 
   388 lemma (in bounded_bilinear) Zfun_right:
   389   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   390   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   391 
   392 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   393 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   394 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   395 
   396 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   397   by (simp only: tendsto_iff Zfun_def dist_norm)
   398 
   399 lemma tendsto_0_le: "\<lbrakk>(f ---> 0) F; eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F\<rbrakk>
   400                      \<Longrightarrow> (g ---> 0) F"
   401   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   402 
   403 subsubsection {* Distance and norms *}
   404 
   405 lemma tendsto_dist [tendsto_intros]:
   406   fixes l m :: "'a :: metric_space"
   407   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   408   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   409 proof (rule tendstoI)
   410   fix e :: real assume "0 < e"
   411   hence e2: "0 < e/2" by simp
   412   from tendstoD [OF f e2] tendstoD [OF g e2]
   413   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   414   proof (eventually_elim)
   415     case (elim x)
   416     then show "dist (dist (f x) (g x)) (dist l m) < e"
   417       unfolding dist_real_def
   418       using dist_triangle2 [of "f x" "g x" "l"]
   419       using dist_triangle2 [of "g x" "l" "m"]
   420       using dist_triangle3 [of "l" "m" "f x"]
   421       using dist_triangle [of "f x" "m" "g x"]
   422       by arith
   423   qed
   424 qed
   425 
   426 lemma continuous_dist[continuous_intros]:
   427   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   428   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   429   unfolding continuous_def by (rule tendsto_dist)
   430 
   431 lemma continuous_on_dist[continuous_intros]:
   432   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   433   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   434   unfolding continuous_on_def by (auto intro: tendsto_dist)
   435 
   436 lemma tendsto_norm [tendsto_intros]:
   437   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   438   unfolding norm_conv_dist by (intro tendsto_intros)
   439 
   440 lemma continuous_norm [continuous_intros]:
   441   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   442   unfolding continuous_def by (rule tendsto_norm)
   443 
   444 lemma continuous_on_norm [continuous_intros]:
   445   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   446   unfolding continuous_on_def by (auto intro: tendsto_norm)
   447 
   448 lemma tendsto_norm_zero:
   449   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   450   by (drule tendsto_norm, simp)
   451 
   452 lemma tendsto_norm_zero_cancel:
   453   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   454   unfolding tendsto_iff dist_norm by simp
   455 
   456 lemma tendsto_norm_zero_iff:
   457   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   458   unfolding tendsto_iff dist_norm by simp
   459 
   460 lemma tendsto_rabs [tendsto_intros]:
   461   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   462   by (fold real_norm_def, rule tendsto_norm)
   463 
   464 lemma continuous_rabs [continuous_intros]:
   465   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   466   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   467 
   468 lemma continuous_on_rabs [continuous_intros]:
   469   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   470   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   471 
   472 lemma tendsto_rabs_zero:
   473   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   474   by (fold real_norm_def, rule tendsto_norm_zero)
   475 
   476 lemma tendsto_rabs_zero_cancel:
   477   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   478   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   479 
   480 lemma tendsto_rabs_zero_iff:
   481   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   482   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   483 
   484 subsubsection {* Addition and subtraction *}
   485 
   486 lemma tendsto_add [tendsto_intros]:
   487   fixes a b :: "'a::real_normed_vector"
   488   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   489   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   490 
   491 lemma continuous_add [continuous_intros]:
   492   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   493   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   494   unfolding continuous_def by (rule tendsto_add)
   495 
   496 lemma continuous_on_add [continuous_intros]:
   497   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   498   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   499   unfolding continuous_on_def by (auto intro: tendsto_add)
   500 
   501 lemma tendsto_add_zero:
   502   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   503   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   504   by (drule (1) tendsto_add, simp)
   505 
   506 lemma tendsto_minus [tendsto_intros]:
   507   fixes a :: "'a::real_normed_vector"
   508   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   509   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   510 
   511 lemma continuous_minus [continuous_intros]:
   512   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   513   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   514   unfolding continuous_def by (rule tendsto_minus)
   515 
   516 lemma continuous_on_minus [continuous_intros]:
   517   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   518   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   519   unfolding continuous_on_def by (auto intro: tendsto_minus)
   520 
   521 lemma tendsto_minus_cancel:
   522   fixes a :: "'a::real_normed_vector"
   523   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   524   by (drule tendsto_minus, simp)
   525 
   526 lemma tendsto_minus_cancel_left:
   527     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   528   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   529   by auto
   530 
   531 lemma tendsto_diff [tendsto_intros]:
   532   fixes a b :: "'a::real_normed_vector"
   533   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   534   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   535 
   536 lemma continuous_diff [continuous_intros]:
   537   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   538   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   539   unfolding continuous_def by (rule tendsto_diff)
   540 
   541 lemma continuous_on_diff [continuous_intros]:
   542   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   543   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   544   unfolding continuous_on_def by (auto intro: tendsto_diff)
   545 
   546 lemma tendsto_setsum [tendsto_intros]:
   547   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   548   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   549   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   550 proof (cases "finite S")
   551   assume "finite S" thus ?thesis using assms
   552     by (induct, simp, simp add: tendsto_add)
   553 qed simp
   554 
   555 lemma continuous_setsum [continuous_intros]:
   556   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   557   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   558   unfolding continuous_def by (rule tendsto_setsum)
   559 
   560 lemma continuous_on_setsum [continuous_intros]:
   561   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   562   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   563   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   564 
   565 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   566 
   567 subsubsection {* Linear operators and multiplication *}
   568 
   569 lemma (in bounded_linear) tendsto:
   570   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   571   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   572 
   573 lemma (in bounded_linear) continuous:
   574   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   575   using tendsto[of g _ F] by (auto simp: continuous_def)
   576 
   577 lemma (in bounded_linear) continuous_on:
   578   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   579   using tendsto[of g] by (auto simp: continuous_on_def)
   580 
   581 lemma (in bounded_linear) tendsto_zero:
   582   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   583   by (drule tendsto, simp only: zero)
   584 
   585 lemma (in bounded_bilinear) tendsto:
   586   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   587   by (simp only: tendsto_Zfun_iff prod_diff_prod
   588                  Zfun_add Zfun Zfun_left Zfun_right)
   589 
   590 lemma (in bounded_bilinear) continuous:
   591   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   592   using tendsto[of f _ F g] by (auto simp: continuous_def)
   593 
   594 lemma (in bounded_bilinear) continuous_on:
   595   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   596   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   597 
   598 lemma (in bounded_bilinear) tendsto_zero:
   599   assumes f: "(f ---> 0) F"
   600   assumes g: "(g ---> 0) F"
   601   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   602   using tendsto [OF f g] by (simp add: zero_left)
   603 
   604 lemma (in bounded_bilinear) tendsto_left_zero:
   605   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   606   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   607 
   608 lemma (in bounded_bilinear) tendsto_right_zero:
   609   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   610   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   611 
   612 lemmas tendsto_of_real [tendsto_intros] =
   613   bounded_linear.tendsto [OF bounded_linear_of_real]
   614 
   615 lemmas tendsto_scaleR [tendsto_intros] =
   616   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   617 
   618 lemmas tendsto_mult [tendsto_intros] =
   619   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   620 
   621 lemmas continuous_of_real [continuous_intros] =
   622   bounded_linear.continuous [OF bounded_linear_of_real]
   623 
   624 lemmas continuous_scaleR [continuous_intros] =
   625   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   626 
   627 lemmas continuous_mult [continuous_intros] =
   628   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   629 
   630 lemmas continuous_on_of_real [continuous_intros] =
   631   bounded_linear.continuous_on [OF bounded_linear_of_real]
   632 
   633 lemmas continuous_on_scaleR [continuous_intros] =
   634   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   635 
   636 lemmas continuous_on_mult [continuous_intros] =
   637   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   638 
   639 lemmas tendsto_mult_zero =
   640   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   641 
   642 lemmas tendsto_mult_left_zero =
   643   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   644 
   645 lemmas tendsto_mult_right_zero =
   646   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   647 
   648 lemma tendsto_power [tendsto_intros]:
   649   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   650   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   651   by (induct n) (simp_all add: tendsto_mult)
   652 
   653 lemma continuous_power [continuous_intros]:
   654   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   655   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   656   unfolding continuous_def by (rule tendsto_power)
   657 
   658 lemma continuous_on_power [continuous_intros]:
   659   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   660   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   661   unfolding continuous_on_def by (auto intro: tendsto_power)
   662 
   663 lemma tendsto_setprod [tendsto_intros]:
   664   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   665   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   666   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   667 proof (cases "finite S")
   668   assume "finite S" thus ?thesis using assms
   669     by (induct, simp, simp add: tendsto_mult)
   670 qed simp
   671 
   672 lemma continuous_setprod [continuous_intros]:
   673   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   674   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   675   unfolding continuous_def by (rule tendsto_setprod)
   676 
   677 lemma continuous_on_setprod [continuous_intros]:
   678   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   679   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   680   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   681 
   682 subsubsection {* Inverse and division *}
   683 
   684 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   685   assumes f: "Zfun f F"
   686   assumes g: "Bfun g F"
   687   shows "Zfun (\<lambda>x. f x ** g x) F"
   688 proof -
   689   obtain K where K: "0 \<le> K"
   690     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   691     using nonneg_bounded by fast
   692   obtain B where B: "0 < B"
   693     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   694     using g by (rule BfunE)
   695   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   696   using norm_g proof eventually_elim
   697     case (elim x)
   698     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   699       by (rule norm_le)
   700     also have "\<dots> \<le> norm (f x) * B * K"
   701       by (intro mult_mono' order_refl norm_g norm_ge_zero
   702                 mult_nonneg_nonneg K elim)
   703     also have "\<dots> = norm (f x) * (B * K)"
   704       by (rule mult.assoc)
   705     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   706   qed
   707   with f show ?thesis
   708     by (rule Zfun_imp_Zfun)
   709 qed
   710 
   711 lemma (in bounded_bilinear) flip:
   712   "bounded_bilinear (\<lambda>x y. y ** x)"
   713   apply default
   714   apply (rule add_right)
   715   apply (rule add_left)
   716   apply (rule scaleR_right)
   717   apply (rule scaleR_left)
   718   apply (subst mult.commute)
   719   using bounded by fast
   720 
   721 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   722   assumes f: "Bfun f F"
   723   assumes g: "Zfun g F"
   724   shows "Zfun (\<lambda>x. f x ** g x) F"
   725   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   726 
   727 lemma Bfun_inverse_lemma:
   728   fixes x :: "'a::real_normed_div_algebra"
   729   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   730   apply (subst nonzero_norm_inverse, clarsimp)
   731   apply (erule (1) le_imp_inverse_le)
   732   done
   733 
   734 lemma Bfun_inverse:
   735   fixes a :: "'a::real_normed_div_algebra"
   736   assumes f: "(f ---> a) F"
   737   assumes a: "a \<noteq> 0"
   738   shows "Bfun (\<lambda>x. inverse (f x)) F"
   739 proof -
   740   from a have "0 < norm a" by simp
   741   hence "\<exists>r>0. r < norm a" by (rule dense)
   742   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   743   have "eventually (\<lambda>x. dist (f x) a < r) F"
   744     using tendstoD [OF f r1] by fast
   745   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   746   proof eventually_elim
   747     case (elim x)
   748     hence 1: "norm (f x - a) < r"
   749       by (simp add: dist_norm)
   750     hence 2: "f x \<noteq> 0" using r2 by auto
   751     hence "norm (inverse (f x)) = inverse (norm (f x))"
   752       by (rule nonzero_norm_inverse)
   753     also have "\<dots> \<le> inverse (norm a - r)"
   754     proof (rule le_imp_inverse_le)
   755       show "0 < norm a - r" using r2 by simp
   756     next
   757       have "norm a - norm (f x) \<le> norm (a - f x)"
   758         by (rule norm_triangle_ineq2)
   759       also have "\<dots> = norm (f x - a)"
   760         by (rule norm_minus_commute)
   761       also have "\<dots> < r" using 1 .
   762       finally show "norm a - r \<le> norm (f x)" by simp
   763     qed
   764     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   765   qed
   766   thus ?thesis by (rule BfunI)
   767 qed
   768 
   769 lemma tendsto_inverse [tendsto_intros]:
   770   fixes a :: "'a::real_normed_div_algebra"
   771   assumes f: "(f ---> a) F"
   772   assumes a: "a \<noteq> 0"
   773   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   774 proof -
   775   from a have "0 < norm a" by simp
   776   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   777     by (rule tendstoD)
   778   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   779     unfolding dist_norm by (auto elim!: eventually_elim1)
   780   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   781     - (inverse (f x) * (f x - a) * inverse a)) F"
   782     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   783   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   784     by (intro Zfun_minus Zfun_mult_left
   785       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   786       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   787   ultimately show ?thesis
   788     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   789 qed
   790 
   791 lemma continuous_inverse:
   792   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   793   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   794   shows "continuous F (\<lambda>x. inverse (f x))"
   795   using assms unfolding continuous_def by (rule tendsto_inverse)
   796 
   797 lemma continuous_at_within_inverse[continuous_intros]:
   798   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   799   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   800   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   801   using assms unfolding continuous_within by (rule tendsto_inverse)
   802 
   803 lemma isCont_inverse[continuous_intros, simp]:
   804   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   805   assumes "isCont f a" and "f a \<noteq> 0"
   806   shows "isCont (\<lambda>x. inverse (f x)) a"
   807   using assms unfolding continuous_at by (rule tendsto_inverse)
   808 
   809 lemma continuous_on_inverse[continuous_intros]:
   810   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   811   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   812   shows "continuous_on s (\<lambda>x. inverse (f x))"
   813   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   814 
   815 lemma tendsto_divide [tendsto_intros]:
   816   fixes a b :: "'a::real_normed_field"
   817   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   818     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   819   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   820 
   821 lemma continuous_divide:
   822   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   823   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   824   shows "continuous F (\<lambda>x. (f x) / (g x))"
   825   using assms unfolding continuous_def by (rule tendsto_divide)
   826 
   827 lemma continuous_at_within_divide[continuous_intros]:
   828   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   829   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   830   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   831   using assms unfolding continuous_within by (rule tendsto_divide)
   832 
   833 lemma isCont_divide[continuous_intros, simp]:
   834   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   835   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   836   shows "isCont (\<lambda>x. (f x) / g x) a"
   837   using assms unfolding continuous_at by (rule tendsto_divide)
   838 
   839 lemma continuous_on_divide[continuous_intros]:
   840   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   841   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   842   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   843   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   844 
   845 lemma tendsto_sgn [tendsto_intros]:
   846   fixes l :: "'a::real_normed_vector"
   847   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   848   unfolding sgn_div_norm by (simp add: tendsto_intros)
   849 
   850 lemma continuous_sgn:
   851   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   852   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   853   shows "continuous F (\<lambda>x. sgn (f x))"
   854   using assms unfolding continuous_def by (rule tendsto_sgn)
   855 
   856 lemma continuous_at_within_sgn[continuous_intros]:
   857   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   858   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   859   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   860   using assms unfolding continuous_within by (rule tendsto_sgn)
   861 
   862 lemma isCont_sgn[continuous_intros]:
   863   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   864   assumes "isCont f a" and "f a \<noteq> 0"
   865   shows "isCont (\<lambda>x. sgn (f x)) a"
   866   using assms unfolding continuous_at by (rule tendsto_sgn)
   867 
   868 lemma continuous_on_sgn[continuous_intros]:
   869   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   870   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   871   shows "continuous_on s (\<lambda>x. sgn (f x))"
   872   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   873 
   874 lemma filterlim_at_infinity:
   875   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
   876   assumes "0 \<le> c"
   877   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   878   unfolding filterlim_iff eventually_at_infinity
   879 proof safe
   880   fix P :: "'a \<Rightarrow> bool" and b
   881   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   882     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   883   have "max b (c + 1) > c" by auto
   884   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   885     by auto
   886   then show "eventually (\<lambda>x. P (f x)) F"
   887   proof eventually_elim
   888     fix x assume "max b (c + 1) \<le> norm (f x)"
   889     with P show "P (f x)" by auto
   890   qed
   891 qed force
   892 
   893 subsection {* Relate @{const at}, @{const at_left} and @{const at_right} *}
   894 
   895 text {*
   896 
   897 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   898 @{term "at_right x"} and also @{term "at_right 0"}.
   899 
   900 *}
   901 
   902 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   903 
   904 lemma filtermap_homeomorph:
   905   assumes f: "continuous (at a) f"
   906   assumes g: "continuous (at (f a)) g"
   907   assumes bij1: "\<forall>x. f (g x) = x" and bij2: "\<forall>x. g (f x) = x"
   908   shows "filtermap f (nhds a) = nhds (f a)"
   909   unfolding filter_eq_iff eventually_filtermap eventually_nhds
   910 proof safe
   911   fix P S assume S: "open S" "f a \<in> S" and P: "\<forall>x\<in>S. P x"
   912   from continuous_within_topological[THEN iffD1, rule_format, OF f S] P
   913   show "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P (f x))" by auto
   914 next
   915   fix P S assume S: "open S" "a \<in> S" and P: "\<forall>x\<in>S. P (f x)"
   916   with continuous_within_topological[THEN iffD1, rule_format, OF g, of S] bij2
   917   obtain A where "open A" "f a \<in> A" "(\<forall>y\<in>A. g y \<in> S)"
   918     by (metis UNIV_I)
   919   with P bij1 show "\<exists>S. open S \<and> f a \<in> S \<and> (\<forall>x\<in>S. P x)"
   920     by (force intro!: exI[of _ A])
   921 qed
   922 
   923 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
   924   by (rule filtermap_homeomorph[where g="\<lambda>x. x + d"]) (auto intro: continuous_intros)
   925 
   926 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
   927   by (rule filtermap_homeomorph[where g=uminus]) (auto intro: continuous_minus)
   928 
   929 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
   930   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   931 
   932 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   933   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   934 
   935 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   936   using filtermap_at_right_shift[of "-a" 0] by simp
   937 
   938 lemma filterlim_at_right_to_0:
   939   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   940   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   941 
   942 lemma eventually_at_right_to_0:
   943   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   944   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   945 
   946 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
   947   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   948 
   949 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   950   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   951 
   952 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   953   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   954 
   955 lemma filterlim_at_left_to_right:
   956   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   957   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   958 
   959 lemma eventually_at_left_to_right:
   960   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   961   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   962 
   963 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   964   unfolding filter_eq_iff eventually_filtermap eventually_at_top_linorder eventually_at_bot_linorder
   965   by (metis le_minus_iff minus_minus)
   966 
   967 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   968   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   969 
   970 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   971   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   972 
   973 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   974   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   975 
   976 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   977   unfolding filterlim_at_top eventually_at_bot_dense
   978   by (metis leI minus_less_iff order_less_asym)
   979 
   980 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
   981   unfolding filterlim_at_bot eventually_at_top_dense
   982   by (metis leI less_minus_iff order_less_asym)
   983 
   984 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
   985   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
   986   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
   987   by auto
   988 
   989 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
   990   unfolding filterlim_uminus_at_top by simp
   991 
   992 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
   993   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
   994 proof safe
   995   fix Z :: real assume [arith]: "0 < Z"
   996   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
   997     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
   998   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
   999     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1000 qed
  1001 
  1002 lemma filterlim_inverse_at_top:
  1003   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1004   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1005      (simp add: filterlim_def eventually_filtermap eventually_elim1 at_within_def le_principal)
  1006 
  1007 lemma filterlim_inverse_at_bot_neg:
  1008   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1009   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1010 
  1011 lemma filterlim_inverse_at_bot:
  1012   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1013   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1014   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1015 
  1016 lemma tendsto_inverse_0:
  1017   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
  1018   shows "(inverse ---> (0::'a)) at_infinity"
  1019   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1020 proof safe
  1021   fix r :: real assume "0 < r"
  1022   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1023   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1024     fix x :: 'a
  1025     from `0 < r` have "0 < inverse (r / 2)" by simp
  1026     also assume *: "inverse (r / 2) \<le> norm x"
  1027     finally show "norm (inverse x) < r"
  1028       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1029   qed
  1030 qed
  1031 
  1032 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1033 proof (rule antisym)
  1034   have "(inverse ---> (0::real)) at_top"
  1035     by (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1036   then show "filtermap inverse at_top \<le> at_right (0::real)"
  1037     by (simp add: le_principal eventually_filtermap eventually_gt_at_top filterlim_def at_within_def)
  1038 next
  1039   have "filtermap inverse (filtermap inverse (at_right (0::real))) \<le> filtermap inverse at_top"
  1040     using filterlim_inverse_at_top_right unfolding filterlim_def by (rule filtermap_mono)
  1041   then show "at_right (0::real) \<le> filtermap inverse at_top"
  1042     by (simp add: filtermap_ident filtermap_filtermap)
  1043 qed
  1044 
  1045 lemma eventually_at_right_to_top:
  1046   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1047   unfolding at_right_to_top eventually_filtermap ..
  1048 
  1049 lemma filterlim_at_right_to_top:
  1050   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1051   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1052 
  1053 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1054   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1055 
  1056 lemma eventually_at_top_to_right:
  1057   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1058   unfolding at_top_to_right eventually_filtermap ..
  1059 
  1060 lemma filterlim_at_top_to_right:
  1061   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1062   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1063 
  1064 lemma filterlim_inverse_at_infinity:
  1065   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring}"
  1066   shows "filterlim inverse at_infinity (at (0::'a))"
  1067   unfolding filterlim_at_infinity[OF order_refl]
  1068 proof safe
  1069   fix r :: real assume "0 < r"
  1070   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1071     unfolding eventually_at norm_inverse
  1072     by (intro exI[of _ "inverse r"])
  1073        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1074 qed
  1075 
  1076 lemma filterlim_inverse_at_iff:
  1077   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring}"
  1078   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1079   unfolding filterlim_def filtermap_filtermap[symmetric]
  1080 proof
  1081   assume "filtermap g F \<le> at_infinity"
  1082   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1083     by (rule filtermap_mono)
  1084   also have "\<dots> \<le> at 0"
  1085     using tendsto_inverse_0[where 'a='b]
  1086     by (auto intro!: exI[of _ 1]
  1087              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1088   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1089 next
  1090   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1091   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1092     by (rule filtermap_mono)
  1093   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1094     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1095 qed
  1096 
  1097 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
  1098  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1099 
  1100 
  1101 lemma at_to_infinity:
  1102   fixes x :: "'a \<Colon> {real_normed_field,field}"
  1103   shows "(at (0::'a)) = filtermap inverse at_infinity"
  1104 proof (rule antisym)
  1105   have "(inverse ---> (0::'a)) at_infinity"
  1106     by (fact tendsto_inverse_0)
  1107   then show "filtermap inverse at_infinity \<le> at (0::'a)"
  1108     apply (simp add: le_principal eventually_filtermap eventually_at_infinity filterlim_def at_within_def)
  1109     apply (rule_tac x="1" in exI, auto)
  1110     done
  1111 next
  1112   have "filtermap inverse (filtermap inverse (at (0::'a))) \<le> filtermap inverse at_infinity"
  1113     using filterlim_inverse_at_infinity unfolding filterlim_def
  1114     by (rule filtermap_mono)
  1115   then show "at (0::'a) \<le> filtermap inverse at_infinity"
  1116     by (simp add: filtermap_ident filtermap_filtermap)
  1117 qed
  1118 
  1119 lemma lim_at_infinity_0:
  1120   fixes l :: "'a :: {real_normed_field,field}"
  1121   shows "(f ---> l) at_infinity \<longleftrightarrow> ((f o inverse) ---> l) (at (0::'a))"
  1122 by (simp add: tendsto_compose_filtermap at_to_infinity filtermap_filtermap)
  1123 
  1124 lemma lim_zero_infinity:
  1125   fixes l :: "'a :: {real_normed_field,field}"
  1126   shows "((\<lambda>x. f(1 / x)) ---> l) (at (0::'a)) \<Longrightarrow> (f ---> l) at_infinity"
  1127 by (simp add: inverse_eq_divide lim_at_infinity_0 comp_def)
  1128 
  1129 
  1130 text {*
  1131 
  1132 We only show rules for multiplication and addition when the functions are either against a real
  1133 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1134 
  1135 *}
  1136 
  1137 lemma filterlim_tendsto_pos_mult_at_top:
  1138   assumes f: "(f ---> c) F" and c: "0 < c"
  1139   assumes g: "LIM x F. g x :> at_top"
  1140   shows "LIM x F. (f x * g x :: real) :> at_top"
  1141   unfolding filterlim_at_top_gt[where c=0]
  1142 proof safe
  1143   fix Z :: real assume "0 < Z"
  1144   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
  1145     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
  1146              simp: dist_real_def abs_real_def split: split_if_asm)
  1147   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1148     unfolding filterlim_at_top by auto
  1149   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1150   proof eventually_elim
  1151     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1152     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1153       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1154     with `0 < c` show "Z \<le> f x * g x"
  1155        by simp
  1156   qed
  1157 qed
  1158 
  1159 lemma filterlim_at_top_mult_at_top:
  1160   assumes f: "LIM x F. f x :> at_top"
  1161   assumes g: "LIM x F. g x :> at_top"
  1162   shows "LIM x F. (f x * g x :: real) :> at_top"
  1163   unfolding filterlim_at_top_gt[where c=0]
  1164 proof safe
  1165   fix Z :: real assume "0 < Z"
  1166   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1167     unfolding filterlim_at_top by auto
  1168   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1169     unfolding filterlim_at_top by auto
  1170   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1171   proof eventually_elim
  1172     fix x assume "1 \<le> f x" "Z \<le> g x"
  1173     with `0 < Z` have "1 * Z \<le> f x * g x"
  1174       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1175     then show "Z \<le> f x * g x"
  1176        by simp
  1177   qed
  1178 qed
  1179 
  1180 lemma filterlim_tendsto_pos_mult_at_bot:
  1181   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1182   shows "LIM x F. f x * g x :> at_bot"
  1183   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1184   unfolding filterlim_uminus_at_bot by simp
  1185 
  1186 lemma filterlim_tendsto_neg_mult_at_bot:
  1187   assumes c: "(f ---> c) F" "(c::real) < 0" and g: "filterlim g at_top F"
  1188   shows "LIM x F. f x * g x :> at_bot"
  1189   using c filterlim_tendsto_pos_mult_at_top[of "\<lambda>x. - f x" "- c" F, OF _ _ g]
  1190   unfolding filterlim_uminus_at_bot tendsto_minus_cancel_left by simp
  1191 
  1192 lemma filterlim_pow_at_top:
  1193   fixes f :: "real \<Rightarrow> real"
  1194   assumes "0 < n" and f: "LIM x F. f x :> at_top"
  1195   shows "LIM x F. (f x)^n :: real :> at_top"
  1196 using `0 < n` proof (induct n)
  1197   case (Suc n) with f show ?case
  1198     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1199 qed simp
  1200 
  1201 lemma filterlim_pow_at_bot_even:
  1202   fixes f :: "real \<Rightarrow> real"
  1203   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1204   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1205 
  1206 lemma filterlim_pow_at_bot_odd:
  1207   fixes f :: "real \<Rightarrow> real"
  1208   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1209   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1210 
  1211 lemma filterlim_tendsto_add_at_top:
  1212   assumes f: "(f ---> c) F"
  1213   assumes g: "LIM x F. g x :> at_top"
  1214   shows "LIM x F. (f x + g x :: real) :> at_top"
  1215   unfolding filterlim_at_top_gt[where c=0]
  1216 proof safe
  1217   fix Z :: real assume "0 < Z"
  1218   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1219     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
  1220   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1221     unfolding filterlim_at_top by auto
  1222   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1223     by eventually_elim simp
  1224 qed
  1225 
  1226 lemma LIM_at_top_divide:
  1227   fixes f g :: "'a \<Rightarrow> real"
  1228   assumes f: "(f ---> a) F" "0 < a"
  1229   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1230   shows "LIM x F. f x / g x :> at_top"
  1231   unfolding divide_inverse
  1232   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1233 
  1234 lemma filterlim_at_top_add_at_top:
  1235   assumes f: "LIM x F. f x :> at_top"
  1236   assumes g: "LIM x F. g x :> at_top"
  1237   shows "LIM x F. (f x + g x :: real) :> at_top"
  1238   unfolding filterlim_at_top_gt[where c=0]
  1239 proof safe
  1240   fix Z :: real assume "0 < Z"
  1241   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1242     unfolding filterlim_at_top by auto
  1243   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1244     unfolding filterlim_at_top by auto
  1245   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1246     by eventually_elim simp
  1247 qed
  1248 
  1249 lemma tendsto_divide_0:
  1250   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring}"
  1251   assumes f: "(f ---> c) F"
  1252   assumes g: "LIM x F. g x :> at_infinity"
  1253   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1254   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1255 
  1256 lemma linear_plus_1_le_power:
  1257   fixes x :: real
  1258   assumes x: "0 \<le> x"
  1259   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1260 proof (induct n)
  1261   case (Suc n)
  1262   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1263     by (simp add: field_simps real_of_nat_Suc x)
  1264   also have "\<dots> \<le> (x + 1)^Suc n"
  1265     using Suc x by (simp add: mult_left_mono)
  1266   finally show ?case .
  1267 qed simp
  1268 
  1269 lemma filterlim_realpow_sequentially_gt1:
  1270   fixes x :: "'a :: real_normed_div_algebra"
  1271   assumes x[arith]: "1 < norm x"
  1272   shows "LIM n sequentially. x ^ n :> at_infinity"
  1273 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1274   fix y :: real assume "0 < y"
  1275   have "0 < norm x - 1" by simp
  1276   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1277   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1278   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1279   also have "\<dots> = norm x ^ N" by simp
  1280   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1281     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1282   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1283     unfolding eventually_sequentially
  1284     by (auto simp: norm_power)
  1285 qed simp
  1286 
  1287 
  1288 subsection {* Limits of Sequences *}
  1289 
  1290 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
  1291   by simp
  1292 
  1293 lemma LIMSEQ_iff:
  1294   fixes L :: "'a::real_normed_vector"
  1295   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1296 unfolding lim_sequentially dist_norm ..
  1297 
  1298 lemma LIMSEQ_I:
  1299   fixes L :: "'a::real_normed_vector"
  1300   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
  1301 by (simp add: LIMSEQ_iff)
  1302 
  1303 lemma LIMSEQ_D:
  1304   fixes L :: "'a::real_normed_vector"
  1305   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1306 by (simp add: LIMSEQ_iff)
  1307 
  1308 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
  1309   unfolding tendsto_def eventually_sequentially
  1310   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
  1311 
  1312 lemma Bseq_inverse_lemma:
  1313   fixes x :: "'a::real_normed_div_algebra"
  1314   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1315 apply (subst nonzero_norm_inverse, clarsimp)
  1316 apply (erule (1) le_imp_inverse_le)
  1317 done
  1318 
  1319 lemma Bseq_inverse:
  1320   fixes a :: "'a::real_normed_div_algebra"
  1321   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1322   by (rule Bfun_inverse)
  1323 
  1324 text{* Transformation of limit. *}
  1325 
  1326 lemma eventually_at2:
  1327   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
  1328   unfolding eventually_at dist_nz by auto
  1329 
  1330 lemma Lim_transform:
  1331   fixes a b :: "'a::real_normed_vector"
  1332   shows "\<lbrakk>(g ---> a) F; ((\<lambda>x. f x - g x) ---> 0) F\<rbrakk> \<Longrightarrow> (f ---> a) F"
  1333   using tendsto_add [of g a F "\<lambda>x. f x - g x" 0] by simp
  1334 
  1335 lemma Lim_transform2:
  1336   fixes a b :: "'a::real_normed_vector"
  1337   shows "\<lbrakk>(f ---> a) F; ((\<lambda>x. f x - g x) ---> 0) F\<rbrakk> \<Longrightarrow> (g ---> a) F"
  1338   by (erule Lim_transform) (simp add: tendsto_minus_cancel)
  1339 
  1340 lemma Lim_transform_eventually:
  1341   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f ---> l) net \<Longrightarrow> (g ---> l) net"
  1342   apply (rule topological_tendstoI)
  1343   apply (drule (2) topological_tendstoD)
  1344   apply (erule (1) eventually_elim2, simp)
  1345   done
  1346 
  1347 lemma Lim_transform_within:
  1348   assumes "0 < d"
  1349     and "\<forall>x'\<in>S. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1350     and "(f ---> l) (at x within S)"
  1351   shows "(g ---> l) (at x within S)"
  1352 proof (rule Lim_transform_eventually)
  1353   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1354     using assms(1,2) by (auto simp: dist_nz eventually_at)
  1355   show "(f ---> l) (at x within S)" by fact
  1356 qed
  1357 
  1358 lemma Lim_transform_at:
  1359   assumes "0 < d"
  1360     and "\<forall>x'. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1361     and "(f ---> l) (at x)"
  1362   shows "(g ---> l) (at x)"
  1363   using _ assms(3)
  1364 proof (rule Lim_transform_eventually)
  1365   show "eventually (\<lambda>x. f x = g x) (at x)"
  1366     unfolding eventually_at2
  1367     using assms(1,2) by auto
  1368 qed
  1369 
  1370 text{* Common case assuming being away from some crucial point like 0. *}
  1371 
  1372 lemma Lim_transform_away_within:
  1373   fixes a b :: "'a::t1_space"
  1374   assumes "a \<noteq> b"
  1375     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1376     and "(f ---> l) (at a within S)"
  1377   shows "(g ---> l) (at a within S)"
  1378 proof (rule Lim_transform_eventually)
  1379   show "(f ---> l) (at a within S)" by fact
  1380   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1381     unfolding eventually_at_topological
  1382     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1383 qed
  1384 
  1385 lemma Lim_transform_away_at:
  1386   fixes a b :: "'a::t1_space"
  1387   assumes ab: "a\<noteq>b"
  1388     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1389     and fl: "(f ---> l) (at a)"
  1390   shows "(g ---> l) (at a)"
  1391   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  1392 
  1393 text{* Alternatively, within an open set. *}
  1394 
  1395 lemma Lim_transform_within_open:
  1396   assumes "open S" and "a \<in> S"
  1397     and "\<forall>x\<in>S. x \<noteq> a \<longrightarrow> f x = g x"
  1398     and "(f ---> l) (at a)"
  1399   shows "(g ---> l) (at a)"
  1400 proof (rule Lim_transform_eventually)
  1401   show "eventually (\<lambda>x. f x = g x) (at a)"
  1402     unfolding eventually_at_topological
  1403     using assms(1,2,3) by auto
  1404   show "(f ---> l) (at a)" by fact
  1405 qed
  1406 
  1407 text{* A congruence rule allowing us to transform limits assuming not at point. *}
  1408 
  1409 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1410 
  1411 lemma Lim_cong_within(*[cong add]*):
  1412   assumes "a = b"
  1413     and "x = y"
  1414     and "S = T"
  1415     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1416   shows "(f ---> x) (at a within S) \<longleftrightarrow> (g ---> y) (at b within T)"
  1417   unfolding tendsto_def eventually_at_topological
  1418   using assms by simp
  1419 
  1420 lemma Lim_cong_at(*[cong add]*):
  1421   assumes "a = b" "x = y"
  1422     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1423   shows "((\<lambda>x. f x) ---> x) (at a) \<longleftrightarrow> ((g ---> y) (at a))"
  1424   unfolding tendsto_def eventually_at_topological
  1425   using assms by simp
  1426 text{*An unbounded sequence's inverse tends to 0*}
  1427 
  1428 lemma LIMSEQ_inverse_zero:
  1429   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
  1430   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1431   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1432   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1433   done
  1434 
  1435 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
  1436 
  1437 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
  1438   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1439             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1440 
  1441 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1442 infinity is now easily proved*}
  1443 
  1444 lemma LIMSEQ_inverse_real_of_nat_add:
  1445      "(%n. r + inverse(real(Suc n))) ----> r"
  1446   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1447 
  1448 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1449      "(%n. r + -inverse(real(Suc n))) ----> r"
  1450   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1451   by auto
  1452 
  1453 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1454      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
  1455   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1456   by auto
  1457 
  1458 subsection {* Convergence on sequences *}
  1459 
  1460 lemma convergent_add:
  1461   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1462   assumes "convergent (\<lambda>n. X n)"
  1463   assumes "convergent (\<lambda>n. Y n)"
  1464   shows "convergent (\<lambda>n. X n + Y n)"
  1465   using assms unfolding convergent_def by (fast intro: tendsto_add)
  1466 
  1467 lemma convergent_setsum:
  1468   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1469   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1470   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1471 proof (cases "finite A")
  1472   case True from this and assms show ?thesis
  1473     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1474 qed (simp add: convergent_const)
  1475 
  1476 lemma (in bounded_linear) convergent:
  1477   assumes "convergent (\<lambda>n. X n)"
  1478   shows "convergent (\<lambda>n. f (X n))"
  1479   using assms unfolding convergent_def by (fast intro: tendsto)
  1480 
  1481 lemma (in bounded_bilinear) convergent:
  1482   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1483   shows "convergent (\<lambda>n. X n ** Y n)"
  1484   using assms unfolding convergent_def by (fast intro: tendsto)
  1485 
  1486 lemma convergent_minus_iff:
  1487   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1488   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1489 apply (simp add: convergent_def)
  1490 apply (auto dest: tendsto_minus)
  1491 apply (drule tendsto_minus, auto)
  1492 done
  1493 
  1494 
  1495 text {* A monotone sequence converges to its least upper bound. *}
  1496 
  1497 lemma LIMSEQ_incseq_SUP:
  1498   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1499   assumes u: "bdd_above (range X)"
  1500   assumes X: "incseq X"
  1501   shows "X ----> (SUP i. X i)"
  1502   by (rule order_tendstoI)
  1503      (auto simp: eventually_sequentially u less_cSUP_iff intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  1504 
  1505 lemma LIMSEQ_decseq_INF:
  1506   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1507   assumes u: "bdd_below (range X)"
  1508   assumes X: "decseq X"
  1509   shows "X ----> (INF i. X i)"
  1510   by (rule order_tendstoI)
  1511      (auto simp: eventually_sequentially u cINF_less_iff intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  1512 
  1513 text{*Main monotonicity theorem*}
  1514 
  1515 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1516   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP dest: Bseq_bdd_above Bseq_bdd_below)
  1517 
  1518 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1519   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  1520 
  1521 lemma Cauchy_iff:
  1522   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1523   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1524   unfolding Cauchy_def dist_norm ..
  1525 
  1526 lemma CauchyI:
  1527   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1528   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1529 by (simp add: Cauchy_iff)
  1530 
  1531 lemma CauchyD:
  1532   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1533   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1534 by (simp add: Cauchy_iff)
  1535 
  1536 lemma incseq_convergent:
  1537   fixes X :: "nat \<Rightarrow> real"
  1538   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1539   obtains L where "X ----> L" "\<forall>i. X i \<le> L"
  1540 proof atomize_elim
  1541   from incseq_bounded[OF assms] `incseq X` Bseq_monoseq_convergent[of X]
  1542   obtain L where "X ----> L"
  1543     by (auto simp: convergent_def monoseq_def incseq_def)
  1544   with `incseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. X i \<le> L)"
  1545     by (auto intro!: exI[of _ L] incseq_le)
  1546 qed
  1547 
  1548 lemma decseq_convergent:
  1549   fixes X :: "nat \<Rightarrow> real"
  1550   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1551   obtains L where "X ----> L" "\<forall>i. L \<le> X i"
  1552 proof atomize_elim
  1553   from decseq_bounded[OF assms] `decseq X` Bseq_monoseq_convergent[of X]
  1554   obtain L where "X ----> L"
  1555     by (auto simp: convergent_def monoseq_def decseq_def)
  1556   with `decseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. L \<le> X i)"
  1557     by (auto intro!: exI[of _ L] decseq_le)
  1558 qed
  1559 
  1560 subsubsection {* Cauchy Sequences are Bounded *}
  1561 
  1562 text{*A Cauchy sequence is bounded -- this is the standard
  1563   proof mechanization rather than the nonstandard proof*}
  1564 
  1565 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1566           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1567 apply (clarify, drule spec, drule (1) mp)
  1568 apply (simp only: norm_minus_commute)
  1569 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1570 apply simp
  1571 done
  1572 
  1573 subsection {* Power Sequences *}
  1574 
  1575 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1576 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1577   also fact that bounded and monotonic sequence converges.*}
  1578 
  1579 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1580 apply (simp add: Bseq_def)
  1581 apply (rule_tac x = 1 in exI)
  1582 apply (simp add: power_abs)
  1583 apply (auto dest: power_mono)
  1584 done
  1585 
  1586 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1587 apply (clarify intro!: mono_SucI2)
  1588 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1589 done
  1590 
  1591 lemma convergent_realpow:
  1592   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1593 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1594 
  1595 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1596   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1597 
  1598 lemma LIMSEQ_realpow_zero:
  1599   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1600 proof cases
  1601   assume "0 \<le> x" and "x \<noteq> 0"
  1602   hence x0: "0 < x" by simp
  1603   assume x1: "x < 1"
  1604   from x0 x1 have "1 < inverse x"
  1605     by (rule one_less_inverse)
  1606   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1607     by (rule LIMSEQ_inverse_realpow_zero)
  1608   thus ?thesis by (simp add: power_inverse)
  1609 qed (rule LIMSEQ_imp_Suc, simp)
  1610 
  1611 lemma LIMSEQ_power_zero:
  1612   fixes x :: "'a::{real_normed_algebra_1}"
  1613   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1614 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1615 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1616 apply (simp add: power_abs norm_power_ineq)
  1617 done
  1618 
  1619 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
  1620   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1621 
  1622 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1623 
  1624 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
  1625   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1626 
  1627 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
  1628   by (rule LIMSEQ_power_zero) simp
  1629 
  1630 
  1631 subsection {* Limits of Functions *}
  1632 
  1633 lemma LIM_eq:
  1634   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1635   shows "f -- a --> L =
  1636      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1637 by (simp add: LIM_def dist_norm)
  1638 
  1639 lemma LIM_I:
  1640   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1641   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1642       ==> f -- a --> L"
  1643 by (simp add: LIM_eq)
  1644 
  1645 lemma LIM_D:
  1646   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1647   shows "[| f -- a --> L; 0<r |]
  1648       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1649 by (simp add: LIM_eq)
  1650 
  1651 lemma LIM_offset:
  1652   fixes a :: "'a::real_normed_vector"
  1653   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
  1654   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1655 
  1656 lemma LIM_offset_zero:
  1657   fixes a :: "'a::real_normed_vector"
  1658   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1659 by (drule_tac k="a" in LIM_offset, simp add: add.commute)
  1660 
  1661 lemma LIM_offset_zero_cancel:
  1662   fixes a :: "'a::real_normed_vector"
  1663   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
  1664 by (drule_tac k="- a" in LIM_offset, simp)
  1665 
  1666 lemma LIM_offset_zero_iff:
  1667   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1668   shows  "f -- a --> L \<longleftrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1669   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1670 
  1671 lemma LIM_zero:
  1672   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1673   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
  1674 unfolding tendsto_iff dist_norm by simp
  1675 
  1676 lemma LIM_zero_cancel:
  1677   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1678   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
  1679 unfolding tendsto_iff dist_norm by simp
  1680 
  1681 lemma LIM_zero_iff:
  1682   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1683   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
  1684 unfolding tendsto_iff dist_norm by simp
  1685 
  1686 lemma LIM_imp_LIM:
  1687   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1688   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1689   assumes f: "f -- a --> l"
  1690   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  1691   shows "g -- a --> m"
  1692   by (rule metric_LIM_imp_LIM [OF f],
  1693     simp add: dist_norm le)
  1694 
  1695 lemma LIM_equal2:
  1696   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1697   assumes 1: "0 < R"
  1698   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  1699   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
  1700 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  1701 
  1702 lemma LIM_compose2:
  1703   fixes a :: "'a::real_normed_vector"
  1704   assumes f: "f -- a --> b"
  1705   assumes g: "g -- b --> c"
  1706   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  1707   shows "(\<lambda>x. g (f x)) -- a --> c"
  1708 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  1709 
  1710 lemma real_LIM_sandwich_zero:
  1711   fixes f g :: "'a::topological_space \<Rightarrow> real"
  1712   assumes f: "f -- a --> 0"
  1713   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  1714   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  1715   shows "g -- a --> 0"
  1716 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  1717   fix x assume x: "x \<noteq> a"
  1718   have "norm (g x - 0) = g x" by (simp add: 1 x)
  1719   also have "g x \<le> f x" by (rule 2 [OF x])
  1720   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  1721   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  1722   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  1723 qed
  1724 
  1725 
  1726 subsection {* Continuity *}
  1727 
  1728 lemma LIM_isCont_iff:
  1729   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1730   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
  1731 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  1732 
  1733 lemma isCont_iff:
  1734   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1735   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
  1736 by (simp add: isCont_def LIM_isCont_iff)
  1737 
  1738 lemma isCont_LIM_compose2:
  1739   fixes a :: "'a::real_normed_vector"
  1740   assumes f [unfolded isCont_def]: "isCont f a"
  1741   assumes g: "g -- f a --> l"
  1742   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  1743   shows "(\<lambda>x. g (f x)) -- a --> l"
  1744 by (rule LIM_compose2 [OF f g inj])
  1745 
  1746 
  1747 lemma isCont_norm [simp]:
  1748   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1749   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  1750   by (fact continuous_norm)
  1751 
  1752 lemma isCont_rabs [simp]:
  1753   fixes f :: "'a::t2_space \<Rightarrow> real"
  1754   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  1755   by (fact continuous_rabs)
  1756 
  1757 lemma isCont_add [simp]:
  1758   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1759   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  1760   by (fact continuous_add)
  1761 
  1762 lemma isCont_minus [simp]:
  1763   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1764   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  1765   by (fact continuous_minus)
  1766 
  1767 lemma isCont_diff [simp]:
  1768   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1769   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  1770   by (fact continuous_diff)
  1771 
  1772 lemma isCont_mult [simp]:
  1773   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  1774   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  1775   by (fact continuous_mult)
  1776 
  1777 lemma (in bounded_linear) isCont:
  1778   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  1779   by (fact continuous)
  1780 
  1781 lemma (in bounded_bilinear) isCont:
  1782   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  1783   by (fact continuous)
  1784 
  1785 lemmas isCont_scaleR [simp] =
  1786   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  1787 
  1788 lemmas isCont_of_real [simp] =
  1789   bounded_linear.isCont [OF bounded_linear_of_real]
  1790 
  1791 lemma isCont_power [simp]:
  1792   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  1793   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  1794   by (fact continuous_power)
  1795 
  1796 lemma isCont_setsum [simp]:
  1797   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  1798   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  1799   by (auto intro: continuous_setsum)
  1800 
  1801 subsection {* Uniform Continuity *}
  1802 
  1803 definition
  1804   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  1805   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  1806 
  1807 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  1808 by (simp add: isUCont_def isCont_def LIM_def, force)
  1809 
  1810 lemma isUCont_Cauchy:
  1811   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1812 unfolding isUCont_def
  1813 apply (rule metric_CauchyI)
  1814 apply (drule_tac x=e in spec, safe)
  1815 apply (drule_tac e=s in metric_CauchyD, safe)
  1816 apply (rule_tac x=M in exI, simp)
  1817 done
  1818 
  1819 lemma (in bounded_linear) isUCont: "isUCont f"
  1820 unfolding isUCont_def dist_norm
  1821 proof (intro allI impI)
  1822   fix r::real assume r: "0 < r"
  1823   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  1824     using pos_bounded by fast
  1825   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  1826   proof (rule exI, safe)
  1827     from r K show "0 < r / K" by simp
  1828   next
  1829     fix x y :: 'a
  1830     assume xy: "norm (x - y) < r / K"
  1831     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  1832     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  1833     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  1834     finally show "norm (f x - f y) < r" .
  1835   qed
  1836 qed
  1837 
  1838 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1839 by (rule isUCont [THEN isUCont_Cauchy])
  1840 
  1841 lemma LIM_less_bound:
  1842   fixes f :: "real \<Rightarrow> real"
  1843   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  1844   shows "0 \<le> f x"
  1845 proof (rule tendsto_le_const)
  1846   show "(f ---> f x) (at_left x)"
  1847     using `isCont f x` by (simp add: filterlim_at_split isCont_def)
  1848   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  1849     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  1850 qed simp
  1851 
  1852 
  1853 subsection {* Nested Intervals and Bisection -- Needed for Compactness *}
  1854 
  1855 lemma nested_sequence_unique:
  1856   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) ----> 0"
  1857   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f ----> l) \<and> ((\<forall>n. l \<le> g n) \<and> g ----> l)"
  1858 proof -
  1859   have "incseq f" unfolding incseq_Suc_iff by fact
  1860   have "decseq g" unfolding decseq_Suc_iff by fact
  1861 
  1862   { fix n
  1863     from `decseq g` have "g n \<le> g 0" by (rule decseqD) simp
  1864     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f n \<le> g 0" by auto }
  1865   then obtain u where "f ----> u" "\<forall>i. f i \<le> u"
  1866     using incseq_convergent[OF `incseq f`] by auto
  1867   moreover
  1868   { fix n
  1869     from `incseq f` have "f 0 \<le> f n" by (rule incseqD) simp
  1870     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f 0 \<le> g n" by simp }
  1871   then obtain l where "g ----> l" "\<forall>i. l \<le> g i"
  1872     using decseq_convergent[OF `decseq g`] by auto
  1873   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF `f ----> u` `g ----> l`]]
  1874   ultimately show ?thesis by auto
  1875 qed
  1876 
  1877 lemma Bolzano[consumes 1, case_names trans local]:
  1878   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  1879   assumes [arith]: "a \<le> b"
  1880   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  1881   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  1882   shows "P a b"
  1883 proof -
  1884   def bisect \<equiv> "rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  1885   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  1886   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  1887     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  1888     by (simp_all add: l_def u_def bisect_def split: prod.split)
  1889 
  1890   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  1891 
  1892   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l ----> x) \<and> ((\<forall>n. x \<le> u n) \<and> u ----> x)"
  1893   proof (safe intro!: nested_sequence_unique)
  1894     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  1895   next
  1896     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  1897     then show "(\<lambda>n. l n - u n) ----> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  1898   qed fact
  1899   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l ----> x" "u ----> x" by auto
  1900   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  1901     using `l 0 \<le> x` `x \<le> u 0` local[of x] by auto
  1902 
  1903   show "P a b"
  1904   proof (rule ccontr)
  1905     assume "\<not> P a b"
  1906     { fix n have "\<not> P (l n) (u n)"
  1907       proof (induct n)
  1908         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  1909       qed (simp add: `\<not> P a b`) }
  1910     moreover
  1911     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  1912         using `0 < d` `l ----> x` by (intro order_tendstoD[of _ x]) auto
  1913       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  1914         using `0 < d` `u ----> x` by (intro order_tendstoD[of _ x]) auto
  1915       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  1916       proof eventually_elim
  1917         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  1918         from add_strict_mono[OF this] have "u n - l n < d" by simp
  1919         with x show "P (l n) (u n)" by (rule d)
  1920       qed }
  1921     ultimately show False by simp
  1922   qed
  1923 qed
  1924 
  1925 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  1926 proof (cases "a \<le> b", rule compactI)
  1927   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  1928   def T == "{a .. b}"
  1929   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  1930   proof (induct rule: Bolzano)
  1931     case (trans a b c)
  1932     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  1933     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  1934       by (auto simp: *)
  1935     with trans show ?case
  1936       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  1937   next
  1938     case (local x)
  1939     then have "x \<in> \<Union>C" using C by auto
  1940     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  1941     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  1942       by (auto simp: open_real_def dist_real_def subset_eq Ball_def abs_less_iff)
  1943     with `c \<in> C` show ?case
  1944       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  1945   qed
  1946 qed simp
  1947 
  1948 
  1949 lemma continuous_image_closed_interval:
  1950   fixes a b and f :: "real \<Rightarrow> real"
  1951   defines "S \<equiv> {a..b}"
  1952   assumes "a \<le> b" and f: "continuous_on S f"
  1953   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
  1954 proof -
  1955   have S: "compact S" "S \<noteq> {}"
  1956     using `a \<le> b` by (auto simp: S_def)
  1957   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
  1958     using continuous_attains_sup[OF S f] by auto
  1959   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
  1960     using continuous_attains_inf[OF S f] by auto
  1961   moreover have "connected (f`S)"
  1962     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
  1963   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
  1964     by (auto simp: connected_iff_interval)
  1965   then show ?thesis
  1966     by auto
  1967 qed
  1968 
  1969 subsection {* Boundedness of continuous functions *}
  1970 
  1971 text{*By bisection, function continuous on closed interval is bounded above*}
  1972 
  1973 lemma isCont_eq_Ub:
  1974   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1975   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1976     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1977   using continuous_attains_sup[of "{a .. b}" f]
  1978   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1979 
  1980 lemma isCont_eq_Lb:
  1981   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1982   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1983     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1984   using continuous_attains_inf[of "{a .. b}" f]
  1985   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1986 
  1987 lemma isCont_bounded:
  1988   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1989   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  1990   using isCont_eq_Ub[of a b f] by auto
  1991 
  1992 lemma isCont_has_Ub:
  1993   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1994   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1995     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  1996   using isCont_eq_Ub[of a b f] by auto
  1997 
  1998 (*HOL style here: object-level formulations*)
  1999 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  2000       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  2001       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  2002   by (blast intro: IVT)
  2003 
  2004 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  2005       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  2006       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  2007   by (blast intro: IVT2)
  2008 
  2009 lemma isCont_Lb_Ub:
  2010   fixes f :: "real \<Rightarrow> real"
  2011   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  2012   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and>
  2013                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  2014 proof -
  2015   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  2016     using isCont_eq_Ub[OF assms] by auto
  2017   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  2018     using isCont_eq_Lb[OF assms] by auto
  2019   show ?thesis
  2020     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  2021     apply (rule_tac x="f L" in exI)
  2022     apply (rule_tac x="f M" in exI)
  2023     apply (cases "L \<le> M")
  2024     apply (simp, metis order_trans)
  2025     apply (simp, metis order_trans)
  2026     done
  2027 qed
  2028 
  2029 
  2030 text{*Continuity of inverse function*}
  2031 
  2032 lemma isCont_inverse_function:
  2033   fixes f g :: "real \<Rightarrow> real"
  2034   assumes d: "0 < d"
  2035       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  2036       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  2037   shows "isCont g (f x)"
  2038 proof -
  2039   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  2040 
  2041   have f: "continuous_on ?D f"
  2042     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  2043   then have g: "continuous_on (f`?D) g"
  2044     using inj by (intro continuous_on_inv) auto
  2045 
  2046   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  2047     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  2048   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  2049     by (rule continuous_on_subset)
  2050   moreover
  2051   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  2052     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  2053   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  2054     by auto
  2055   ultimately
  2056   show ?thesis
  2057     by (simp add: continuous_on_eq_continuous_at)
  2058 qed
  2059 
  2060 lemma isCont_inverse_function2:
  2061   fixes f g :: "real \<Rightarrow> real" shows
  2062   "\<lbrakk>a < x; x < b;
  2063     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2064     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2065    \<Longrightarrow> isCont g (f x)"
  2066 apply (rule isCont_inverse_function
  2067        [where f=f and d="min (x - a) (b - x)"])
  2068 apply (simp_all add: abs_le_iff)
  2069 done
  2070 
  2071 (* need to rename second isCont_inverse *)
  2072 
  2073 lemma isCont_inv_fun:
  2074   fixes f g :: "real \<Rightarrow> real"
  2075   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;
  2076          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]
  2077       ==> isCont g (f x)"
  2078 by (rule isCont_inverse_function)
  2079 
  2080 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  2081 lemma LIM_fun_gt_zero:
  2082   fixes f :: "real \<Rightarrow> real"
  2083   shows "f -- c --> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  2084 apply (drule (1) LIM_D, clarify)
  2085 apply (rule_tac x = s in exI)
  2086 apply (simp add: abs_less_iff)
  2087 done
  2088 
  2089 lemma LIM_fun_less_zero:
  2090   fixes f :: "real \<Rightarrow> real"
  2091   shows "f -- c --> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  2092 apply (drule LIM_D [where r="-l"], simp, clarify)
  2093 apply (rule_tac x = s in exI)
  2094 apply (simp add: abs_less_iff)
  2095 done
  2096 
  2097 lemma LIM_fun_not_zero:
  2098   fixes f :: "real \<Rightarrow> real"
  2099   shows "f -- c --> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  2100   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  2101 
  2102 end
  2103