src/HOL/Probability/Finite_Product_Measure.thy
author haftmann
Fri Jun 19 07:53:35 2015 +0200 (2015-06-19)
changeset 60517 f16e4fb20652
parent 59425 c5e79df8cc21
child 60580 7e741e22d7fc
permissions -rw-r--r--
separate class for notions specific for integral (semi)domains, in contrast to fields where these are trivial
     1 (*  Title:      HOL/Probability/Finite_Product_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 section {*Finite product measures*}
     6 
     7 theory Finite_Product_Measure
     8 imports Binary_Product_Measure
     9 begin
    10 
    11 lemma PiE_choice: "(\<exists>f\<in>PiE I F. \<forall>i\<in>I. P i (f i)) \<longleftrightarrow> (\<forall>i\<in>I. \<exists>x\<in>F i. P i x)"
    12   by (auto simp: Bex_def PiE_iff Ball_def dest!: choice_iff'[THEN iffD1])
    13      (force intro: exI[of _ "restrict f I" for f])
    14 
    15 lemma split_const: "(\<lambda>(i, j). c) = (\<lambda>_. c)"
    16   by auto
    17 
    18 subsubsection {* More about Function restricted by @{const extensional}  *}
    19 
    20 definition
    21   "merge I J = (\<lambda>(x, y) i. if i \<in> I then x i else if i \<in> J then y i else undefined)"
    22 
    23 lemma merge_apply[simp]:
    24   "I \<inter> J = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    25   "I \<inter> J = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    26   "J \<inter> I = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    27   "J \<inter> I = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    28   "i \<notin> I \<Longrightarrow> i \<notin> J \<Longrightarrow> merge I J (x, y) i = undefined"
    29   unfolding merge_def by auto
    30 
    31 lemma merge_commute:
    32   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) = merge J I (y, x)"
    33   by (force simp: merge_def)
    34 
    35 lemma Pi_cancel_merge_range[simp]:
    36   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    37   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    38   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    39   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    40   by (auto simp: Pi_def)
    41 
    42 lemma Pi_cancel_merge[simp]:
    43   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    44   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    45   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    46   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    47   by (auto simp: Pi_def)
    48 
    49 lemma extensional_merge[simp]: "merge I J (x, y) \<in> extensional (I \<union> J)"
    50   by (auto simp: extensional_def)
    51 
    52 lemma restrict_merge[simp]:
    53   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    54   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    55   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    56   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    57   by (auto simp: restrict_def)
    58 
    59 lemma split_merge: "P (merge I J (x,y) i) \<longleftrightarrow> (i \<in> I \<longrightarrow> P (x i)) \<and> (i \<in> J - I \<longrightarrow> P (y i)) \<and> (i \<notin> I \<union> J \<longrightarrow> P undefined)"
    60   unfolding merge_def by auto
    61 
    62 lemma PiE_cancel_merge[simp]:
    63   "I \<inter> J = {} \<Longrightarrow>
    64     merge I J (x, y) \<in> PiE (I \<union> J) B \<longleftrightarrow> x \<in> Pi I B \<and> y \<in> Pi J B"
    65   by (auto simp: PiE_def restrict_Pi_cancel)
    66 
    67 lemma merge_singleton[simp]: "i \<notin> I \<Longrightarrow> merge I {i} (x,y) = restrict (x(i := y i)) (insert i I)"
    68   unfolding merge_def by (auto simp: fun_eq_iff)
    69 
    70 lemma extensional_merge_sub: "I \<union> J \<subseteq> K \<Longrightarrow> merge I J (x, y) \<in> extensional K"
    71   unfolding merge_def extensional_def by auto
    72 
    73 lemma merge_restrict[simp]:
    74   "merge I J (restrict x I, y) = merge I J (x, y)"
    75   "merge I J (x, restrict y J) = merge I J (x, y)"
    76   unfolding merge_def by auto
    77 
    78 lemma merge_x_x_eq_restrict[simp]:
    79   "merge I J (x, x) = restrict x (I \<union> J)"
    80   unfolding merge_def by auto
    81 
    82 lemma injective_vimage_restrict:
    83   assumes J: "J \<subseteq> I"
    84   and sets: "A \<subseteq> (\<Pi>\<^sub>E i\<in>J. S i)" "B \<subseteq> (\<Pi>\<^sub>E i\<in>J. S i)" and ne: "(\<Pi>\<^sub>E i\<in>I. S i) \<noteq> {}"
    85   and eq: "(\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^sub>E i\<in>I. S i) = (\<lambda>x. restrict x J) -` B \<inter> (\<Pi>\<^sub>E i\<in>I. S i)"
    86   shows "A = B"
    87 proof  (intro set_eqI)
    88   fix x
    89   from ne obtain y where y: "\<And>i. i \<in> I \<Longrightarrow> y i \<in> S i" by auto
    90   have "J \<inter> (I - J) = {}" by auto
    91   show "x \<in> A \<longleftrightarrow> x \<in> B"
    92   proof cases
    93     assume x: "x \<in> (\<Pi>\<^sub>E i\<in>J. S i)"
    94     have "x \<in> A \<longleftrightarrow> merge J (I - J) (x,y) \<in> (\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^sub>E i\<in>I. S i)"
    95       using y x `J \<subseteq> I` PiE_cancel_merge[of "J" "I - J" x y S]
    96       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1)
    97     then show "x \<in> A \<longleftrightarrow> x \<in> B"
    98       using y x `J \<subseteq> I` PiE_cancel_merge[of "J" "I - J" x y S]
    99       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1 eq)
   100   qed (insert sets, auto)
   101 qed
   102 
   103 lemma restrict_vimage:
   104   "I \<inter> J = {} \<Longrightarrow>
   105     (\<lambda>x. (restrict x I, restrict x J)) -` (Pi\<^sub>E I E \<times> Pi\<^sub>E J F) = Pi (I \<union> J) (merge I J (E, F))"
   106   by (auto simp: restrict_Pi_cancel PiE_def)
   107 
   108 lemma merge_vimage:
   109   "I \<inter> J = {} \<Longrightarrow> merge I J -` Pi\<^sub>E (I \<union> J) E = Pi I E \<times> Pi J E"
   110   by (auto simp: restrict_Pi_cancel PiE_def)
   111 
   112 subsection {* Finite product spaces *}
   113 
   114 subsubsection {* Products *}
   115 
   116 definition prod_emb where
   117   "prod_emb I M K X = (\<lambda>x. restrict x K) -` X \<inter> (PIE i:I. space (M i))"
   118 
   119 lemma prod_emb_iff: 
   120   "f \<in> prod_emb I M K X \<longleftrightarrow> f \<in> extensional I \<and> (restrict f K \<in> X) \<and> (\<forall>i\<in>I. f i \<in> space (M i))"
   121   unfolding prod_emb_def PiE_def by auto
   122 
   123 lemma
   124   shows prod_emb_empty[simp]: "prod_emb M L K {} = {}"
   125     and prod_emb_Un[simp]: "prod_emb M L K (A \<union> B) = prod_emb M L K A \<union> prod_emb M L K B"
   126     and prod_emb_Int: "prod_emb M L K (A \<inter> B) = prod_emb M L K A \<inter> prod_emb M L K B"
   127     and prod_emb_UN[simp]: "prod_emb M L K (\<Union>i\<in>I. F i) = (\<Union>i\<in>I. prod_emb M L K (F i))"
   128     and prod_emb_INT[simp]: "I \<noteq> {} \<Longrightarrow> prod_emb M L K (\<Inter>i\<in>I. F i) = (\<Inter>i\<in>I. prod_emb M L K (F i))"
   129     and prod_emb_Diff[simp]: "prod_emb M L K (A - B) = prod_emb M L K A - prod_emb M L K B"
   130   by (auto simp: prod_emb_def)
   131 
   132 lemma prod_emb_PiE: "J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow>
   133     prod_emb I M J (\<Pi>\<^sub>E i\<in>J. E i) = (\<Pi>\<^sub>E i\<in>I. if i \<in> J then E i else space (M i))"
   134   by (force simp: prod_emb_def PiE_iff split_if_mem2)
   135 
   136 lemma prod_emb_PiE_same_index[simp]:
   137     "(\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow> prod_emb I M I (Pi\<^sub>E I E) = Pi\<^sub>E I E"
   138   by (auto simp: prod_emb_def PiE_iff)
   139 
   140 lemma prod_emb_trans[simp]:
   141   "J \<subseteq> K \<Longrightarrow> K \<subseteq> L \<Longrightarrow> prod_emb L M K (prod_emb K M J X) = prod_emb L M J X"
   142   by (auto simp add: Int_absorb1 prod_emb_def PiE_def)
   143 
   144 lemma prod_emb_Pi:
   145   assumes "X \<in> (\<Pi> j\<in>J. sets (M j))" "J \<subseteq> K"
   146   shows "prod_emb K M J (Pi\<^sub>E J X) = (\<Pi>\<^sub>E i\<in>K. if i \<in> J then X i else space (M i))"
   147   using assms sets.space_closed
   148   by (auto simp: prod_emb_def PiE_iff split: split_if_asm) blast+
   149 
   150 lemma prod_emb_id:
   151   "B \<subseteq> (\<Pi>\<^sub>E i\<in>L. space (M i)) \<Longrightarrow> prod_emb L M L B = B"
   152   by (auto simp: prod_emb_def subset_eq extensional_restrict)
   153 
   154 lemma prod_emb_mono:
   155   "F \<subseteq> G \<Longrightarrow> prod_emb A M B F \<subseteq> prod_emb A M B G"
   156   by (auto simp: prod_emb_def)
   157 
   158 definition PiM :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
   159   "PiM I M = extend_measure (\<Pi>\<^sub>E i\<in>I. space (M i))
   160     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
   161     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^sub>E j\<in>J. X j))
   162     (\<lambda>(J, X). \<Prod>j\<in>J \<union> {i\<in>I. emeasure (M i) (space (M i)) \<noteq> 1}. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   163 
   164 definition prod_algebra :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) set set" where
   165   "prod_algebra I M = (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^sub>E j\<in>J. X j)) `
   166     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}"
   167 
   168 abbreviation
   169   "Pi\<^sub>M I M \<equiv> PiM I M"
   170 
   171 syntax
   172   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3PIM _:_./ _)" 10)
   173 
   174 syntax (xsymbols)
   175   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^sub>M _\<in>_./ _)"  10)
   176 
   177 syntax (HTML output)
   178   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^sub>M _\<in>_./ _)"  10)
   179 
   180 translations
   181   "PIM x:I. M" == "CONST PiM I (%x. M)"
   182 
   183 lemma extend_measure_cong:
   184   assumes "\<Omega> = \<Omega>'" "I = I'" "G = G'" "\<And>i. i \<in> I' \<Longrightarrow> \<mu> i = \<mu>' i"
   185   shows "extend_measure \<Omega> I G \<mu> = extend_measure \<Omega>' I' G' \<mu>'"
   186   unfolding extend_measure_def by (auto simp add: assms)
   187 
   188 lemma Pi_cong_sets:
   189     "\<lbrakk>I = J; \<And>x. x \<in> I \<Longrightarrow> M x = N x\<rbrakk> \<Longrightarrow> Pi I M = Pi J N"
   190   unfolding Pi_def by auto 
   191 
   192 lemma PiM_cong:
   193   assumes "I = J" "\<And>x. x \<in> I \<Longrightarrow> M x = N x"
   194   shows "PiM I M = PiM J N"
   195 unfolding PiM_def
   196 proof (rule extend_measure_cong)
   197   case goal1 show ?case using assms
   198     by (subst assms(1), intro PiE_cong[of J "\<lambda>i. space (M i)" "\<lambda>i. space (N i)"]) simp_all
   199 next
   200   case goal2
   201   have "\<And>K. K \<subseteq> J \<Longrightarrow> (\<Pi> j\<in>K. sets (M j)) = (\<Pi> j\<in>K. sets (N j))"
   202     using assms by (intro Pi_cong_sets) auto
   203   thus ?case by (auto simp: assms)
   204 next
   205   case goal3 show ?case using assms 
   206     by (intro ext) (auto simp: prod_emb_def dest: PiE_mem)
   207 next
   208   case (goal4 x)
   209   thus ?case using assms 
   210     by (auto intro!: setprod.cong split: split_if_asm)
   211 qed
   212 
   213 
   214 lemma prod_algebra_sets_into_space:
   215   "prod_algebra I M \<subseteq> Pow (\<Pi>\<^sub>E i\<in>I. space (M i))"
   216   by (auto simp: prod_emb_def prod_algebra_def)
   217 
   218 lemma prod_algebra_eq_finite:
   219   assumes I: "finite I"
   220   shows "prod_algebra I M = {(\<Pi>\<^sub>E i\<in>I. X i) |X. X \<in> (\<Pi> j\<in>I. sets (M j))}" (is "?L = ?R")
   221 proof (intro iffI set_eqI)
   222   fix A assume "A \<in> ?L"
   223   then obtain J E where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   224     and A: "A = prod_emb I M J (PIE j:J. E j)"
   225     by (auto simp: prod_algebra_def)
   226   let ?A = "\<Pi>\<^sub>E i\<in>I. if i \<in> J then E i else space (M i)"
   227   have A: "A = ?A"
   228     unfolding A using J by (intro prod_emb_PiE sets.sets_into_space) auto
   229   show "A \<in> ?R" unfolding A using J sets.top
   230     by (intro CollectI exI[of _ "\<lambda>i. if i \<in> J then E i else space (M i)"]) simp
   231 next
   232   fix A assume "A \<in> ?R"
   233   then obtain X where A: "A = (\<Pi>\<^sub>E i\<in>I. X i)" and X: "X \<in> (\<Pi> j\<in>I. sets (M j))" by auto
   234   then have A: "A = prod_emb I M I (\<Pi>\<^sub>E i\<in>I. X i)"
   235     by (simp add: prod_emb_PiE_same_index[OF sets.sets_into_space] Pi_iff)
   236   from X I show "A \<in> ?L" unfolding A
   237     by (auto simp: prod_algebra_def)
   238 qed
   239 
   240 lemma prod_algebraI:
   241   "finite J \<Longrightarrow> (J \<noteq> {} \<or> I = {}) \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i))
   242     \<Longrightarrow> prod_emb I M J (PIE j:J. E j) \<in> prod_algebra I M"
   243   by (auto simp: prod_algebra_def)
   244 
   245 lemma prod_algebraI_finite:
   246   "finite I \<Longrightarrow> (\<forall>i\<in>I. E i \<in> sets (M i)) \<Longrightarrow> (Pi\<^sub>E I E) \<in> prod_algebra I M"
   247   using prod_algebraI[of I I E M] prod_emb_PiE_same_index[of I E M, OF sets.sets_into_space] by simp
   248 
   249 lemma Int_stable_PiE: "Int_stable {Pi\<^sub>E J E | E. \<forall>i\<in>I. E i \<in> sets (M i)}"
   250 proof (safe intro!: Int_stableI)
   251   fix E F assume "\<forall>i\<in>I. E i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
   252   then show "\<exists>G. Pi\<^sub>E J E \<inter> Pi\<^sub>E J F = Pi\<^sub>E J G \<and> (\<forall>i\<in>I. G i \<in> sets (M i))"
   253     by (auto intro!: exI[of _ "\<lambda>i. E i \<inter> F i"] simp: PiE_Int)
   254 qed
   255 
   256 lemma prod_algebraE:
   257   assumes A: "A \<in> prod_algebra I M"
   258   obtains J E where "A = prod_emb I M J (PIE j:J. E j)"
   259     "finite J" "J \<noteq> {} \<or> I = {}" "J \<subseteq> I" "\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i)" 
   260   using A by (auto simp: prod_algebra_def)
   261 
   262 lemma prod_algebraE_all:
   263   assumes A: "A \<in> prod_algebra I M"
   264   obtains E where "A = Pi\<^sub>E I E" "E \<in> (\<Pi> i\<in>I. sets (M i))"
   265 proof -
   266   from A obtain E J where A: "A = prod_emb I M J (Pi\<^sub>E J E)"
   267     and J: "J \<subseteq> I" and E: "E \<in> (\<Pi> i\<in>J. sets (M i))"
   268     by (auto simp: prod_algebra_def)
   269   from E have "\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)"
   270     using sets.sets_into_space by auto
   271   then have "A = (\<Pi>\<^sub>E i\<in>I. if i\<in>J then E i else space (M i))"
   272     using A J by (auto simp: prod_emb_PiE)
   273   moreover have "(\<lambda>i. if i\<in>J then E i else space (M i)) \<in> (\<Pi> i\<in>I. sets (M i))"
   274     using sets.top E by auto
   275   ultimately show ?thesis using that by auto
   276 qed
   277 
   278 lemma Int_stable_prod_algebra: "Int_stable (prod_algebra I M)"
   279 proof (unfold Int_stable_def, safe)
   280   fix A assume "A \<in> prod_algebra I M"
   281   from prod_algebraE[OF this] guess J E . note A = this
   282   fix B assume "B \<in> prod_algebra I M"
   283   from prod_algebraE[OF this] guess K F . note B = this
   284   have "A \<inter> B = prod_emb I M (J \<union> K) (\<Pi>\<^sub>E i\<in>J \<union> K. (if i \<in> J then E i else space (M i)) \<inter> 
   285       (if i \<in> K then F i else space (M i)))"
   286     unfolding A B using A(2,3,4) A(5)[THEN sets.sets_into_space] B(2,3,4)
   287       B(5)[THEN sets.sets_into_space]
   288     apply (subst (1 2 3) prod_emb_PiE)
   289     apply (simp_all add: subset_eq PiE_Int)
   290     apply blast
   291     apply (intro PiE_cong)
   292     apply auto
   293     done
   294   also have "\<dots> \<in> prod_algebra I M"
   295     using A B by (auto intro!: prod_algebraI)
   296   finally show "A \<inter> B \<in> prod_algebra I M" .
   297 qed
   298 
   299 lemma prod_algebra_mono:
   300   assumes space: "\<And>i. i \<in> I \<Longrightarrow> space (E i) = space (F i)"
   301   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> sets (E i) \<subseteq> sets (F i)"
   302   shows "prod_algebra I E \<subseteq> prod_algebra I F"
   303 proof
   304   fix A assume "A \<in> prod_algebra I E"
   305   then obtain J G where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I"
   306     and A: "A = prod_emb I E J (\<Pi>\<^sub>E i\<in>J. G i)"
   307     and G: "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (E i)"
   308     by (auto simp: prod_algebra_def)
   309   moreover
   310   from space have "(\<Pi>\<^sub>E i\<in>I. space (E i)) = (\<Pi>\<^sub>E i\<in>I. space (F i))"
   311     by (rule PiE_cong)
   312   with A have "A = prod_emb I F J (\<Pi>\<^sub>E i\<in>J. G i)"
   313     by (simp add: prod_emb_def)
   314   moreover
   315   from sets G J have "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (F i)"
   316     by auto
   317   ultimately show "A \<in> prod_algebra I F"
   318     apply (simp add: prod_algebra_def image_iff)
   319     apply (intro exI[of _ J] exI[of _ G] conjI)
   320     apply auto
   321     done
   322 qed
   323 
   324 lemma prod_algebra_cong:
   325   assumes "I = J" and sets: "(\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i))"
   326   shows "prod_algebra I M = prod_algebra J N"
   327 proof -
   328   have space: "\<And>i. i \<in> I \<Longrightarrow> space (M i) = space (N i)"
   329     using sets_eq_imp_space_eq[OF sets] by auto
   330   with sets show ?thesis unfolding `I = J`
   331     by (intro antisym prod_algebra_mono) auto
   332 qed
   333 
   334 lemma space_in_prod_algebra:
   335   "(\<Pi>\<^sub>E i\<in>I. space (M i)) \<in> prod_algebra I M"
   336 proof cases
   337   assume "I = {}" then show ?thesis
   338     by (auto simp add: prod_algebra_def image_iff prod_emb_def)
   339 next
   340   assume "I \<noteq> {}"
   341   then obtain i where "i \<in> I" by auto
   342   then have "(\<Pi>\<^sub>E i\<in>I. space (M i)) = prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. space (M i))"
   343     by (auto simp: prod_emb_def)
   344   also have "\<dots> \<in> prod_algebra I M"
   345     using `i \<in> I` by (intro prod_algebraI) auto
   346   finally show ?thesis .
   347 qed
   348 
   349 lemma space_PiM: "space (\<Pi>\<^sub>M i\<in>I. M i) = (\<Pi>\<^sub>E i\<in>I. space (M i))"
   350   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro space_extend_measure) simp
   351 
   352 lemma sets_PiM: "sets (\<Pi>\<^sub>M i\<in>I. M i) = sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) (prod_algebra I M)"
   353   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro sets_extend_measure) simp
   354 
   355 lemma sets_PiM_single: "sets (PiM I M) =
   356     sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) {{f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} | i A. i \<in> I \<and> A \<in> sets (M i)}"
   357     (is "_ = sigma_sets ?\<Omega> ?R")
   358   unfolding sets_PiM
   359 proof (rule sigma_sets_eqI)
   360   interpret R: sigma_algebra ?\<Omega> "sigma_sets ?\<Omega> ?R" by (rule sigma_algebra_sigma_sets) auto
   361   fix A assume "A \<in> prod_algebra I M"
   362   from prod_algebraE[OF this] guess J X . note X = this
   363   show "A \<in> sigma_sets ?\<Omega> ?R"
   364   proof cases
   365     assume "I = {}"
   366     with X have "A = {\<lambda>x. undefined}" by (auto simp: prod_emb_def)
   367     with `I = {}` show ?thesis by (auto intro!: sigma_sets_top)
   368   next
   369     assume "I \<noteq> {}"
   370     with X have "A = (\<Inter>j\<in>J. {f\<in>(\<Pi>\<^sub>E i\<in>I. space (M i)). f j \<in> X j})"
   371       by (auto simp: prod_emb_def)
   372     also have "\<dots> \<in> sigma_sets ?\<Omega> ?R"
   373       using X `I \<noteq> {}` by (intro R.finite_INT sigma_sets.Basic) auto
   374     finally show "A \<in> sigma_sets ?\<Omega> ?R" .
   375   qed
   376 next
   377   fix A assume "A \<in> ?R"
   378   then obtain i B where A: "A = {f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> B}" "i \<in> I" "B \<in> sets (M i)" 
   379     by auto
   380   then have "A = prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. B)"
   381      by (auto simp: prod_emb_def)
   382   also have "\<dots> \<in> sigma_sets ?\<Omega> (prod_algebra I M)"
   383     using A by (intro sigma_sets.Basic prod_algebraI) auto
   384   finally show "A \<in> sigma_sets ?\<Omega> (prod_algebra I M)" .
   385 qed
   386 
   387 lemma sets_PiM_eq_proj:
   388   "I \<noteq> {} \<Longrightarrow> sets (PiM I M) = sets (\<Squnion>\<^sub>\<sigma> i\<in>I. vimage_algebra (\<Pi>\<^sub>E i\<in>I. space (M i)) (\<lambda>x. x i) (M i))"
   389   apply (simp add: sets_PiM_single sets_Sup_sigma)
   390   apply (subst SUP_cong[OF refl])
   391   apply (rule sets_vimage_algebra2)
   392   apply auto []
   393   apply (auto intro!: arg_cong2[where f=sigma_sets])
   394   done
   395 
   396 lemma
   397   shows space_PiM_empty: "space (Pi\<^sub>M {} M) = {\<lambda>k. undefined}"
   398     and sets_PiM_empty: "sets (Pi\<^sub>M {} M) = { {}, {\<lambda>k. undefined} }"
   399   by (simp_all add: space_PiM sets_PiM_single image_constant sigma_sets_empty_eq)
   400 
   401 lemma sets_PiM_sigma:
   402   assumes \<Omega>_cover: "\<And>i. i \<in> I \<Longrightarrow> \<exists>S\<subseteq>E i. countable S \<and> \<Omega> i = \<Union>S"
   403   assumes E: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (\<Omega> i)"
   404   assumes J: "\<And>j. j \<in> J \<Longrightarrow> finite j" "\<Union>J = I"
   405   defines "P \<equiv> {{f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A i} | A j. j \<in> J \<and> A \<in> Pi j E}"
   406   shows "sets (\<Pi>\<^sub>M i\<in>I. sigma (\<Omega> i) (E i)) = sets (sigma (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P)"
   407 proof cases
   408   assume "I = {}" 
   409   with `\<Union>J = I` have "P = {{\<lambda>_. undefined}} \<or> P = {}"
   410     by (auto simp: P_def)
   411   with `I = {}` show ?thesis
   412     by (auto simp add: sets_PiM_empty sigma_sets_empty_eq)
   413 next
   414   let ?F = "\<lambda>i. {(\<lambda>x. x i) -` A \<inter> Pi\<^sub>E I \<Omega> |A. A \<in> E i}"
   415   assume "I \<noteq> {}"
   416   then have "sets (Pi\<^sub>M I (\<lambda>i. sigma (\<Omega> i) (E i))) = 
   417       sets (\<Squnion>\<^sub>\<sigma> i\<in>I. vimage_algebra (\<Pi>\<^sub>E i\<in>I. \<Omega> i) (\<lambda>x. x i) (sigma (\<Omega> i) (E i)))"
   418     by (subst sets_PiM_eq_proj) (auto simp: space_measure_of_conv)
   419   also have "\<dots> = sets (\<Squnion>\<^sub>\<sigma> i\<in>I. sigma (Pi\<^sub>E I \<Omega>) (?F i))"
   420     using E by (intro SUP_sigma_cong arg_cong[where f=sets] vimage_algebra_sigma) auto
   421   also have "\<dots> = sets (sigma (Pi\<^sub>E I \<Omega>) (\<Union>i\<in>I. ?F i))"
   422     using `I \<noteq> {}` by (intro arg_cong[where f=sets] SUP_sigma_sigma) auto
   423   also have "\<dots> = sets (sigma (Pi\<^sub>E I \<Omega>) P)"
   424   proof (intro arg_cong[where f=sets] sigma_eqI sigma_sets_eqI)
   425     show "(\<Union>i\<in>I. ?F i) \<subseteq> Pow (Pi\<^sub>E I \<Omega>)" "P \<subseteq> Pow (Pi\<^sub>E I \<Omega>)"
   426       by (auto simp: P_def)
   427   next
   428     interpret P: sigma_algebra "\<Pi>\<^sub>E i\<in>I. \<Omega> i" "sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P"
   429       by (auto intro!: sigma_algebra_sigma_sets simp: P_def)
   430 
   431     fix Z assume "Z \<in> (\<Union>i\<in>I. ?F i)"
   432     then obtain i A where i: "i \<in> I" "A \<in> E i" and Z_def: "Z = (\<lambda>x. x i) -` A \<inter> Pi\<^sub>E I \<Omega>"
   433       by auto
   434     from `i \<in> I` J obtain j where j: "i \<in> j" "j \<in> J" "j \<subseteq> I" "finite j"
   435       by auto
   436     obtain S where S: "\<And>i. i \<in> j \<Longrightarrow> S i \<subseteq> E i" "\<And>i. i \<in> j \<Longrightarrow> countable (S i)"
   437       "\<And>i. i \<in> j \<Longrightarrow> \<Omega> i = \<Union>(S i)"
   438       by (metis subset_eq \<Omega>_cover `j \<subseteq> I`)
   439     def A' \<equiv> "\<lambda>n. n(i := A)"
   440     then have A'_i: "\<And>n. A' n i = A"
   441       by simp
   442     { fix n assume "n \<in> Pi\<^sub>E (j - {i}) S"
   443       then have "A' n \<in> Pi j E"
   444         unfolding PiE_def Pi_def using S(1) by (auto simp: A'_def `A \<in> E i` )
   445       with `j \<in> J` have "{f \<in> Pi\<^sub>E I \<Omega>. \<forall>i\<in>j. f i \<in> A' n i} \<in> P"
   446         by (auto simp: P_def) }
   447     note A'_in_P = this
   448 
   449     { fix x assume "x i \<in> A" "x \<in> Pi\<^sub>E I \<Omega>"
   450       with S(3) `j \<subseteq> I` have "\<forall>i\<in>j. \<exists>s\<in>S i. x i \<in> s"
   451         by (auto simp: PiE_def Pi_def)
   452       then obtain s where s: "\<And>i. i \<in> j \<Longrightarrow> s i \<in> S i" "\<And>i. i \<in> j \<Longrightarrow> x i \<in> s i"
   453         by metis
   454       with `x i \<in> A` have "\<exists>n\<in>PiE (j-{i}) S. \<forall>i\<in>j. x i \<in> A' n i"
   455         by (intro bexI[of _ "restrict (s(i := A)) (j-{i})"]) (auto simp: A'_def split: if_splits) }
   456     then have "Z = (\<Union>n\<in>PiE (j-{i}) S. {f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A' n i})"
   457       unfolding Z_def
   458       by (auto simp add: set_eq_iff ball_conj_distrib `i\<in>j` A'_i dest: bspec[OF _ `i\<in>j`]
   459                cong: conj_cong)
   460     also have "\<dots> \<in> sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P"
   461       using `finite j` S(2)
   462       by (intro P.countable_UN' countable_PiE) (simp_all add: image_subset_iff A'_in_P)
   463     finally show "Z \<in> sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P" .
   464   next
   465     interpret F: sigma_algebra "\<Pi>\<^sub>E i\<in>I. \<Omega> i" "sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) (\<Union>i\<in>I. ?F i)"
   466       by (auto intro!: sigma_algebra_sigma_sets)
   467 
   468     fix b assume "b \<in> P"
   469     then obtain A j where b: "b = {f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A i}" "j \<in> J" "A \<in> Pi j E"
   470       by (auto simp: P_def)
   471     show "b \<in> sigma_sets (Pi\<^sub>E I \<Omega>) (\<Union>i\<in>I. ?F i)"
   472     proof cases
   473       assume "j = {}"
   474       with b have "b = (\<Pi>\<^sub>E i\<in>I. \<Omega> i)"
   475         by auto
   476       then show ?thesis
   477         by blast
   478     next
   479       assume "j \<noteq> {}"
   480       with J b(2,3) have eq: "b = (\<Inter>i\<in>j. ((\<lambda>x. x i) -` A i \<inter> Pi\<^sub>E I \<Omega>))"
   481         unfolding b(1)
   482         by (auto simp: PiE_def Pi_def)
   483       show ?thesis
   484         unfolding eq using `A \<in> Pi j E` `j \<in> J` J(2)
   485         by (intro F.finite_INT J `j \<in> J` `j \<noteq> {}` sigma_sets.Basic) blast
   486     qed
   487   qed
   488   finally show "?thesis" .
   489 qed
   490 
   491 lemma sets_PiM_in_sets:
   492   assumes space: "space N = (\<Pi>\<^sub>E i\<in>I. space (M i))"
   493   assumes sets: "\<And>i A. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {x\<in>space N. x i \<in> A} \<in> sets N"
   494   shows "sets (\<Pi>\<^sub>M i \<in> I. M i) \<subseteq> sets N"
   495   unfolding sets_PiM_single space[symmetric]
   496   by (intro sets.sigma_sets_subset subsetI) (auto intro: sets)
   497 
   498 lemma sets_PiM_cong[measurable_cong]:
   499   assumes "I = J" "\<And>i. i \<in> J \<Longrightarrow> sets (M i) = sets (N i)" shows "sets (PiM I M) = sets (PiM J N)"
   500   using assms sets_eq_imp_space_eq[OF assms(2)] by (simp add: sets_PiM_single cong: PiE_cong conj_cong)
   501 
   502 lemma sets_PiM_I:
   503   assumes "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   504   shows "prod_emb I M J (PIE j:J. E j) \<in> sets (PIM i:I. M i)"
   505 proof cases
   506   assume "J = {}"
   507   then have "prod_emb I M J (PIE j:J. E j) = (PIE j:I. space (M j))"
   508     by (auto simp: prod_emb_def)
   509   then show ?thesis
   510     by (auto simp add: sets_PiM intro!: sigma_sets_top)
   511 next
   512   assume "J \<noteq> {}" with assms show ?thesis
   513     by (force simp add: sets_PiM prod_algebra_def)
   514 qed
   515 
   516 lemma measurable_PiM:
   517   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   518   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   519     f -` prod_emb I M J (Pi\<^sub>E J X) \<inter> space N \<in> sets N" 
   520   shows "f \<in> measurable N (PiM I M)"
   521   using sets_PiM prod_algebra_sets_into_space space
   522 proof (rule measurable_sigma_sets)
   523   fix A assume "A \<in> prod_algebra I M"
   524   from prod_algebraE[OF this] guess J X .
   525   with sets[of J X] show "f -` A \<inter> space N \<in> sets N" by auto
   526 qed
   527 
   528 lemma measurable_PiM_Collect:
   529   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   530   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   531     {\<omega>\<in>space N. \<forall>i\<in>J. f \<omega> i \<in> X i} \<in> sets N" 
   532   shows "f \<in> measurable N (PiM I M)"
   533   using sets_PiM prod_algebra_sets_into_space space
   534 proof (rule measurable_sigma_sets)
   535   fix A assume "A \<in> prod_algebra I M"
   536   from prod_algebraE[OF this] guess J X . note X = this
   537   then have "f -` A \<inter> space N = {\<omega> \<in> space N. \<forall>i\<in>J. f \<omega> i \<in> X i}"
   538     using space by (auto simp: prod_emb_def del: PiE_I)
   539   also have "\<dots> \<in> sets N" using X(3,2,4,5) by (rule sets)
   540   finally show "f -` A \<inter> space N \<in> sets N" .
   541 qed
   542 
   543 lemma measurable_PiM_single:
   544   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   545   assumes sets: "\<And>A i. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {\<omega> \<in> space N. f \<omega> i \<in> A} \<in> sets N" 
   546   shows "f \<in> measurable N (PiM I M)"
   547   using sets_PiM_single
   548 proof (rule measurable_sigma_sets)
   549   fix A assume "A \<in> {{f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
   550   then obtain B i where "A = {f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> B}" and B: "i \<in> I" "B \<in> sets (M i)"
   551     by auto
   552   with space have "f -` A \<inter> space N = {\<omega> \<in> space N. f \<omega> i \<in> B}" by auto
   553   also have "\<dots> \<in> sets N" using B by (rule sets)
   554   finally show "f -` A \<inter> space N \<in> sets N" .
   555 qed (auto simp: space)
   556 
   557 lemma measurable_PiM_single':
   558   assumes f: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> measurable N (M i)"
   559     and "(\<lambda>\<omega> i. f i \<omega>) \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   560   shows "(\<lambda>\<omega> i. f i \<omega>) \<in> measurable N (Pi\<^sub>M I M)"
   561 proof (rule measurable_PiM_single)
   562   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   563   then have "{\<omega> \<in> space N. f i \<omega> \<in> A} = f i -` A \<inter> space N"
   564     by auto
   565   then show "{\<omega> \<in> space N. f i \<omega> \<in> A} \<in> sets N"
   566     using A f by (auto intro!: measurable_sets)
   567 qed fact
   568 
   569 lemma sets_PiM_I_finite[measurable]:
   570   assumes "finite I" and sets: "(\<And>i. i \<in> I \<Longrightarrow> E i \<in> sets (M i))"
   571   shows "(PIE j:I. E j) \<in> sets (PIM i:I. M i)"
   572   using sets_PiM_I[of I I E M] sets.sets_into_space[OF sets] `finite I` sets by auto
   573 
   574 lemma measurable_component_singleton[measurable (raw)]:
   575   assumes "i \<in> I" shows "(\<lambda>x. x i) \<in> measurable (Pi\<^sub>M I M) (M i)"
   576 proof (unfold measurable_def, intro CollectI conjI ballI)
   577   fix A assume "A \<in> sets (M i)"
   578   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M I M) = prod_emb I M {i} (\<Pi>\<^sub>E j\<in>{i}. A)"
   579     using sets.sets_into_space `i \<in> I`
   580     by (fastforce dest: Pi_mem simp: prod_emb_def space_PiM split: split_if_asm)
   581   then show "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M I M) \<in> sets (Pi\<^sub>M I M)"
   582     using `A \<in> sets (M i)` `i \<in> I` by (auto intro!: sets_PiM_I)
   583 qed (insert `i \<in> I`, auto simp: space_PiM)
   584 
   585 lemma measurable_component_singleton'[measurable_dest]:
   586   assumes f: "f \<in> measurable N (Pi\<^sub>M I M)"
   587   assumes g: "g \<in> measurable L N"
   588   assumes i: "i \<in> I"
   589   shows "(\<lambda>x. (f (g x)) i) \<in> measurable L (M i)"
   590   using measurable_compose[OF measurable_compose[OF g f] measurable_component_singleton, OF i] .
   591 
   592 lemma measurable_PiM_component_rev:
   593   "i \<in> I \<Longrightarrow> f \<in> measurable (M i) N \<Longrightarrow> (\<lambda>x. f (x i)) \<in> measurable (PiM I M) N"
   594   by simp
   595 
   596 lemma measurable_case_nat[measurable (raw)]:
   597   assumes [measurable (raw)]: "i = 0 \<Longrightarrow> f \<in> measurable M N"
   598     "\<And>j. i = Suc j \<Longrightarrow> (\<lambda>x. g x j) \<in> measurable M N"
   599   shows "(\<lambda>x. case_nat (f x) (g x) i) \<in> measurable M N"
   600   by (cases i) simp_all
   601  
   602 lemma measurable_case_nat'[measurable (raw)]:
   603   assumes fg[measurable]: "f \<in> measurable N M" "g \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
   604   shows "(\<lambda>x. case_nat (f x) (g x)) \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
   605   using fg[THEN measurable_space]
   606   by (auto intro!: measurable_PiM_single' simp add: space_PiM PiE_iff split: nat.split)
   607 
   608 lemma measurable_add_dim[measurable]:
   609   "(\<lambda>(f, y). f(i := y)) \<in> measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) (Pi\<^sub>M (insert i I) M)"
   610     (is "?f \<in> measurable ?P ?I")
   611 proof (rule measurable_PiM_single)
   612   fix j A assume j: "j \<in> insert i I" and A: "A \<in> sets (M j)"
   613   have "{\<omega> \<in> space ?P. (\<lambda>(f, x). fun_upd f i x) \<omega> j \<in> A} =
   614     (if j = i then space (Pi\<^sub>M I M) \<times> A else ((\<lambda>x. x j) \<circ> fst) -` A \<inter> space ?P)"
   615     using sets.sets_into_space[OF A] by (auto simp add: space_pair_measure space_PiM)
   616   also have "\<dots> \<in> sets ?P"
   617     using A j
   618     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   619   finally show "{\<omega> \<in> space ?P. case_prod (\<lambda>f. fun_upd f i) \<omega> j \<in> A} \<in> sets ?P" .
   620 qed (auto simp: space_pair_measure space_PiM PiE_def)
   621 
   622 lemma measurable_component_update:
   623   "x \<in> space (Pi\<^sub>M I M) \<Longrightarrow> i \<notin> I \<Longrightarrow> (\<lambda>v. x(i := v)) \<in> measurable (M i) (Pi\<^sub>M (insert i I) M)"
   624   by simp
   625 
   626 lemma measurable_merge[measurable]:
   627   "merge I J \<in> measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M)"
   628     (is "?f \<in> measurable ?P ?U")
   629 proof (rule measurable_PiM_single)
   630   fix i A assume A: "A \<in> sets (M i)" "i \<in> I \<union> J"
   631   then have "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} =
   632     (if i \<in> I then ((\<lambda>x. x i) \<circ> fst) -` A \<inter> space ?P else ((\<lambda>x. x i) \<circ> snd) -` A \<inter> space ?P)"
   633     by (auto simp: merge_def)
   634   also have "\<dots> \<in> sets ?P"
   635     using A
   636     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   637   finally show "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} \<in> sets ?P" .
   638 qed (auto simp: space_pair_measure space_PiM PiE_iff merge_def extensional_def)
   639 
   640 lemma measurable_restrict[measurable (raw)]:
   641   assumes X: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> measurable N (M i)"
   642   shows "(\<lambda>x. \<lambda>i\<in>I. X i x) \<in> measurable N (Pi\<^sub>M I M)"
   643 proof (rule measurable_PiM_single)
   644   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   645   then have "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} = X i -` A \<inter> space N"
   646     by auto
   647   then show "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} \<in> sets N"
   648     using A X by (auto intro!: measurable_sets)
   649 qed (insert X, auto simp add: PiE_def dest: measurable_space)
   650 
   651 lemma measurable_abs_UNIV: 
   652   "(\<And>n. (\<lambda>\<omega>. f n \<omega>) \<in> measurable M (N n)) \<Longrightarrow> (\<lambda>\<omega> n. f n \<omega>) \<in> measurable M (PiM UNIV N)"
   653   by (intro measurable_PiM_single) (auto dest: measurable_space)
   654 
   655 lemma measurable_restrict_subset: "J \<subseteq> L \<Longrightarrow> (\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M)"
   656   by (intro measurable_restrict measurable_component_singleton) auto
   657 
   658 lemma measurable_restrict_subset':
   659   assumes "J \<subseteq> L" "\<And>x. x \<in> J \<Longrightarrow> sets (M x) = sets (N x)"
   660   shows "(\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J N)"
   661 proof-
   662   from assms(1) have "(\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M)"
   663     by (rule measurable_restrict_subset)
   664   also from assms(2) have "measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M) = measurable (Pi\<^sub>M L M) (Pi\<^sub>M J N)"
   665     by (intro sets_PiM_cong measurable_cong_sets) simp_all
   666   finally show ?thesis .
   667 qed
   668 
   669 lemma measurable_prod_emb[intro, simp]:
   670   "J \<subseteq> L \<Longrightarrow> X \<in> sets (Pi\<^sub>M J M) \<Longrightarrow> prod_emb L M J X \<in> sets (Pi\<^sub>M L M)"
   671   unfolding prod_emb_def space_PiM[symmetric]
   672   by (auto intro!: measurable_sets measurable_restrict measurable_component_singleton)
   673 
   674 lemma sets_in_Pi_aux:
   675   "finite I \<Longrightarrow> (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
   676   {x\<in>space (PiM I M). x \<in> Pi I F} \<in> sets (PiM I M)"
   677   by (simp add: subset_eq Pi_iff)
   678 
   679 lemma sets_in_Pi[measurable (raw)]:
   680   "finite I \<Longrightarrow> f \<in> measurable N (PiM I M) \<Longrightarrow>
   681   (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
   682   Measurable.pred N (\<lambda>x. f x \<in> Pi I F)"
   683   unfolding pred_def
   684   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_Pi_aux]) auto
   685 
   686 lemma sets_in_extensional_aux:
   687   "{x\<in>space (PiM I M). x \<in> extensional I} \<in> sets (PiM I M)"
   688 proof -
   689   have "{x\<in>space (PiM I M). x \<in> extensional I} = space (PiM I M)"
   690     by (auto simp add: extensional_def space_PiM)
   691   then show ?thesis by simp
   692 qed
   693 
   694 lemma sets_in_extensional[measurable (raw)]:
   695   "f \<in> measurable N (PiM I M) \<Longrightarrow> Measurable.pred N (\<lambda>x. f x \<in> extensional I)"
   696   unfolding pred_def
   697   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_extensional_aux]) auto
   698 
   699 locale product_sigma_finite =
   700   fixes M :: "'i \<Rightarrow> 'a measure"
   701   assumes sigma_finite_measures: "\<And>i. sigma_finite_measure (M i)"
   702 
   703 sublocale product_sigma_finite \<subseteq> M: sigma_finite_measure "M i" for i
   704   by (rule sigma_finite_measures)
   705 
   706 locale finite_product_sigma_finite = product_sigma_finite M for M :: "'i \<Rightarrow> 'a measure" +
   707   fixes I :: "'i set"
   708   assumes finite_index: "finite I"
   709 
   710 lemma (in finite_product_sigma_finite) sigma_finite_pairs:
   711   "\<exists>F::'i \<Rightarrow> nat \<Rightarrow> 'a set.
   712     (\<forall>i\<in>I. range (F i) \<subseteq> sets (M i)) \<and>
   713     (\<forall>k. \<forall>i\<in>I. emeasure (M i) (F i k) \<noteq> \<infinity>) \<and> incseq (\<lambda>k. \<Pi>\<^sub>E i\<in>I. F i k) \<and>
   714     (\<Union>k. \<Pi>\<^sub>E i\<in>I. F i k) = space (PiM I M)"
   715 proof -
   716   have "\<forall>i::'i. \<exists>F::nat \<Rightarrow> 'a set. range F \<subseteq> sets (M i) \<and> incseq F \<and> (\<Union>i. F i) = space (M i) \<and> (\<forall>k. emeasure (M i) (F k) \<noteq> \<infinity>)"
   717     using M.sigma_finite_incseq by metis
   718   from choice[OF this] guess F :: "'i \<Rightarrow> nat \<Rightarrow> 'a set" ..
   719   then have F: "\<And>i. range (F i) \<subseteq> sets (M i)" "\<And>i. incseq (F i)" "\<And>i. (\<Union>j. F i j) = space (M i)" "\<And>i k. emeasure (M i) (F i k) \<noteq> \<infinity>"
   720     by auto
   721   let ?F = "\<lambda>k. \<Pi>\<^sub>E i\<in>I. F i k"
   722   note space_PiM[simp]
   723   show ?thesis
   724   proof (intro exI[of _ F] conjI allI incseq_SucI set_eqI iffI ballI)
   725     fix i show "range (F i) \<subseteq> sets (M i)" by fact
   726   next
   727     fix i k show "emeasure (M i) (F i k) \<noteq> \<infinity>" by fact
   728   next
   729     fix x assume "x \<in> (\<Union>i. ?F i)" with F(1) show "x \<in> space (PiM I M)"
   730       by (auto simp: PiE_def dest!: sets.sets_into_space)
   731   next
   732     fix f assume "f \<in> space (PiM I M)"
   733     with Pi_UN[OF finite_index, of "\<lambda>k i. F i k"] F
   734     show "f \<in> (\<Union>i. ?F i)" by (auto simp: incseq_def PiE_def)
   735   next
   736     fix i show "?F i \<subseteq> ?F (Suc i)"
   737       using `\<And>i. incseq (F i)`[THEN incseq_SucD] by auto
   738   qed
   739 qed
   740 
   741 lemma emeasure_PiM_empty[simp]: "emeasure (PiM {} M) {\<lambda>_. undefined} = 1"
   742 proof -
   743   let ?\<mu> = "\<lambda>A. if A = {} then 0 else (1::ereal)"
   744   have "emeasure (Pi\<^sub>M {} M) (prod_emb {} M {} (\<Pi>\<^sub>E i\<in>{}. {})) = 1"
   745   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   746     show "positive (PiM {} M) ?\<mu>"
   747       by (auto simp: positive_def)
   748     show "countably_additive (PiM {} M) ?\<mu>"
   749       by (rule sets.countably_additiveI_finite)
   750          (auto simp: additive_def positive_def sets_PiM_empty space_PiM_empty intro!: )
   751   qed (auto simp: prod_emb_def)
   752   also have "(prod_emb {} M {} (\<Pi>\<^sub>E i\<in>{}. {})) = {\<lambda>_. undefined}"
   753     by (auto simp: prod_emb_def)
   754   finally show ?thesis
   755     by simp
   756 qed
   757 
   758 lemma PiM_empty: "PiM {} M = count_space {\<lambda>_. undefined}"
   759   by (rule measure_eqI) (auto simp add: sets_PiM_empty one_ereal_def)
   760 
   761 lemma (in product_sigma_finite) emeasure_PiM:
   762   "finite I \<Longrightarrow> (\<And>i. i\<in>I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (PiM I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   763 proof (induct I arbitrary: A rule: finite_induct)
   764   case (insert i I)
   765   interpret finite_product_sigma_finite M I by default fact
   766   have "finite (insert i I)" using `finite I` by auto
   767   interpret I': finite_product_sigma_finite M "insert i I" by default fact
   768   let ?h = "(\<lambda>(f, y). f(i := y))"
   769 
   770   let ?P = "distr (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) (Pi\<^sub>M (insert i I) M) ?h"
   771   let ?\<mu> = "emeasure ?P"
   772   let ?I = "{j \<in> insert i I. emeasure (M j) (space (M j)) \<noteq> 1}"
   773   let ?f = "\<lambda>J E j. if j \<in> J then emeasure (M j) (E j) else emeasure (M j) (space (M j))"
   774 
   775   have "emeasure (Pi\<^sub>M (insert i I) M) (prod_emb (insert i I) M (insert i I) (Pi\<^sub>E (insert i I) A)) =
   776     (\<Prod>i\<in>insert i I. emeasure (M i) (A i))"
   777   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   778     fix J E assume "(J \<noteq> {} \<or> insert i I = {}) \<and> finite J \<and> J \<subseteq> insert i I \<and> E \<in> (\<Pi> j\<in>J. sets (M j))"
   779     then have J: "J \<noteq> {}" "finite J" "J \<subseteq> insert i I" and E: "\<forall>j\<in>J. E j \<in> sets (M j)" by auto
   780     let ?p = "prod_emb (insert i I) M J (Pi\<^sub>E J E)"
   781     let ?p' = "prod_emb I M (J - {i}) (\<Pi>\<^sub>E j\<in>J-{i}. E j)"
   782     have "?\<mu> ?p =
   783       emeasure (Pi\<^sub>M I M \<Otimes>\<^sub>M (M i)) (?h -` ?p \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M M i))"
   784       by (intro emeasure_distr measurable_add_dim sets_PiM_I) fact+
   785     also have "?h -` ?p \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) = ?p' \<times> (if i \<in> J then E i else space (M i))"
   786       using J E[rule_format, THEN sets.sets_into_space]
   787       by (force simp: space_pair_measure space_PiM prod_emb_iff PiE_def Pi_iff split: split_if_asm)
   788     also have "emeasure (Pi\<^sub>M I M \<Otimes>\<^sub>M (M i)) (?p' \<times> (if i \<in> J then E i else space (M i))) =
   789       emeasure (Pi\<^sub>M I M) ?p' * emeasure (M i) (if i \<in> J then (E i) else space (M i))"
   790       using J E by (intro M.emeasure_pair_measure_Times sets_PiM_I) auto
   791     also have "?p' = (\<Pi>\<^sub>E j\<in>I. if j \<in> J-{i} then E j else space (M j))"
   792       using J E[rule_format, THEN sets.sets_into_space]
   793       by (auto simp: prod_emb_iff PiE_def Pi_iff split: split_if_asm) blast+
   794     also have "emeasure (Pi\<^sub>M I M) (\<Pi>\<^sub>E j\<in>I. if j \<in> J-{i} then E j else space (M j)) =
   795       (\<Prod> j\<in>I. if j \<in> J-{i} then emeasure (M j) (E j) else emeasure (M j) (space (M j)))"
   796       using E by (subst insert) (auto intro!: setprod.cong)
   797     also have "(\<Prod>j\<in>I. if j \<in> J - {i} then emeasure (M j) (E j) else emeasure (M j) (space (M j))) *
   798        emeasure (M i) (if i \<in> J then E i else space (M i)) = (\<Prod>j\<in>insert i I. ?f J E j)"
   799       using insert by (auto simp: mult.commute intro!: arg_cong2[where f="op *"] setprod.cong)
   800     also have "\<dots> = (\<Prod>j\<in>J \<union> ?I. ?f J E j)"
   801       using insert(1,2) J E by (intro setprod.mono_neutral_right) auto
   802     finally show "?\<mu> ?p = \<dots>" .
   803 
   804     show "prod_emb (insert i I) M J (Pi\<^sub>E J E) \<in> Pow (\<Pi>\<^sub>E i\<in>insert i I. space (M i))"
   805       using J E[rule_format, THEN sets.sets_into_space] by (auto simp: prod_emb_iff PiE_def)
   806   next
   807     show "positive (sets (Pi\<^sub>M (insert i I) M)) ?\<mu>" "countably_additive (sets (Pi\<^sub>M (insert i I) M)) ?\<mu>"
   808       using emeasure_positive[of ?P] emeasure_countably_additive[of ?P] by simp_all
   809   next
   810     show "(insert i I \<noteq> {} \<or> insert i I = {}) \<and> finite (insert i I) \<and>
   811       insert i I \<subseteq> insert i I \<and> A \<in> (\<Pi> j\<in>insert i I. sets (M j))"
   812       using insert by auto
   813   qed (auto intro!: setprod.cong)
   814   with insert show ?case
   815     by (subst (asm) prod_emb_PiE_same_index) (auto intro!: sets.sets_into_space)
   816 qed simp
   817 
   818 lemma (in product_sigma_finite) sigma_finite: 
   819   assumes "finite I"
   820   shows "sigma_finite_measure (PiM I M)"
   821 proof
   822   interpret finite_product_sigma_finite M I by default fact
   823 
   824   obtain F where F: "\<And>j. countable (F j)" "\<And>j f. f \<in> F j \<Longrightarrow> f \<in> sets (M j)"
   825     "\<And>j f. f \<in> F j \<Longrightarrow> emeasure (M j) f \<noteq> \<infinity>" and
   826     in_space: "\<And>j. space (M j) = (\<Union>F j)"
   827     using sigma_finite_countable by (metis subset_eq)
   828   moreover have "(\<Union>(PiE I ` PiE I F)) = space (Pi\<^sub>M I M)"
   829     using in_space by (auto simp: space_PiM PiE_iff intro!: PiE_choice[THEN iffD2])
   830   ultimately show "\<exists>A. countable A \<and> A \<subseteq> sets (Pi\<^sub>M I M) \<and> \<Union>A = space (Pi\<^sub>M I M) \<and> (\<forall>a\<in>A. emeasure (Pi\<^sub>M I M) a \<noteq> \<infinity>)"
   831     by (intro exI[of _ "PiE I ` PiE I F"])
   832        (auto intro!: countable_PiE sets_PiM_I_finite
   833              simp: PiE_iff emeasure_PiM finite_index setprod_PInf emeasure_nonneg)
   834 qed
   835 
   836 sublocale finite_product_sigma_finite \<subseteq> sigma_finite_measure "Pi\<^sub>M I M"
   837   using sigma_finite[OF finite_index] .
   838 
   839 lemma (in finite_product_sigma_finite) measure_times:
   840   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (Pi\<^sub>M I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   841   using emeasure_PiM[OF finite_index] by auto
   842 
   843 lemma (in product_sigma_finite) nn_integral_empty:
   844   assumes pos: "0 \<le> f (\<lambda>k. undefined)"
   845   shows "integral\<^sup>N (Pi\<^sub>M {} M) f = f (\<lambda>k. undefined)"
   846 proof -
   847   interpret finite_product_sigma_finite M "{}" by default (fact finite.emptyI)
   848   have "\<And>A. emeasure (Pi\<^sub>M {} M) (Pi\<^sub>E {} A) = 1"
   849     using assms by (subst measure_times) auto
   850   then show ?thesis
   851     unfolding nn_integral_def simple_function_def simple_integral_def[abs_def]
   852   proof (simp add: space_PiM_empty sets_PiM_empty, intro antisym)
   853     show "f (\<lambda>k. undefined) \<le> (SUP f:{g. g \<le> max 0 \<circ> f}. f (\<lambda>k. undefined))"
   854       by (intro SUP_upper) (auto simp: le_fun_def split: split_max)
   855     show "(SUP f:{g. g \<le> max 0 \<circ> f}. f (\<lambda>k. undefined)) \<le> f (\<lambda>k. undefined)" using pos
   856       by (intro SUP_least) (auto simp: le_fun_def simp: max_def split: split_if_asm)
   857   qed
   858 qed
   859 
   860 lemma (in product_sigma_finite) distr_merge:
   861   assumes IJ[simp]: "I \<inter> J = {}" and fin: "finite I" "finite J"
   862   shows "distr (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M) (merge I J) = Pi\<^sub>M (I \<union> J) M"
   863    (is "?D = ?P")
   864 proof -
   865   interpret I: finite_product_sigma_finite M I by default fact
   866   interpret J: finite_product_sigma_finite M J by default fact
   867   have "finite (I \<union> J)" using fin by auto
   868   interpret IJ: finite_product_sigma_finite M "I \<union> J" by default fact
   869   interpret P: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" by default
   870   let ?g = "merge I J"
   871 
   872   from IJ.sigma_finite_pairs obtain F where
   873     F: "\<And>i. i\<in> I \<union> J \<Longrightarrow> range (F i) \<subseteq> sets (M i)"
   874        "incseq (\<lambda>k. \<Pi>\<^sub>E i\<in>I \<union> J. F i k)"
   875        "(\<Union>k. \<Pi>\<^sub>E i\<in>I \<union> J. F i k) = space ?P"
   876        "\<And>k. \<forall>i\<in>I\<union>J. emeasure (M i) (F i k) \<noteq> \<infinity>"
   877     by auto
   878   let ?F = "\<lambda>k. \<Pi>\<^sub>E i\<in>I \<union> J. F i k"
   879   
   880   show ?thesis
   881   proof (rule measure_eqI_generator_eq[symmetric])
   882     show "Int_stable (prod_algebra (I \<union> J) M)"
   883       by (rule Int_stable_prod_algebra)
   884     show "prod_algebra (I \<union> J) M \<subseteq> Pow (\<Pi>\<^sub>E i \<in> I \<union> J. space (M i))"
   885       by (rule prod_algebra_sets_into_space)
   886     show "sets ?P = sigma_sets (\<Pi>\<^sub>E i\<in>I \<union> J. space (M i)) (prod_algebra (I \<union> J) M)"
   887       by (rule sets_PiM)
   888     then show "sets ?D = sigma_sets (\<Pi>\<^sub>E i\<in>I \<union> J. space (M i)) (prod_algebra (I \<union> J) M)"
   889       by simp
   890 
   891     show "range ?F \<subseteq> prod_algebra (I \<union> J) M" using F
   892       using fin by (auto simp: prod_algebra_eq_finite)
   893     show "(\<Union>i. \<Pi>\<^sub>E ia\<in>I \<union> J. F ia i) = (\<Pi>\<^sub>E i\<in>I \<union> J. space (M i))"
   894       using F(3) by (simp add: space_PiM)
   895   next
   896     fix k
   897     from F `finite I` setprod_PInf[of "I \<union> J", OF emeasure_nonneg, of M]
   898     show "emeasure ?P (?F k) \<noteq> \<infinity>" by (subst IJ.measure_times) auto
   899   next
   900     fix A assume A: "A \<in> prod_algebra (I \<union> J) M"
   901     with fin obtain F where A_eq: "A = (Pi\<^sub>E (I \<union> J) F)" and F: "\<forall>i\<in>J. F i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
   902       by (auto simp add: prod_algebra_eq_finite)
   903     let ?B = "Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M"
   904     let ?X = "?g -` A \<inter> space ?B"
   905     have "Pi\<^sub>E I F \<subseteq> space (Pi\<^sub>M I M)" "Pi\<^sub>E J F \<subseteq> space (Pi\<^sub>M J M)"
   906       using F[rule_format, THEN sets.sets_into_space] by (force simp: space_PiM)+
   907     then have X: "?X = (Pi\<^sub>E I F \<times> Pi\<^sub>E J F)"
   908       unfolding A_eq by (subst merge_vimage) (auto simp: space_pair_measure space_PiM)
   909     have "emeasure ?D A = emeasure ?B ?X"
   910       using A by (intro emeasure_distr measurable_merge) (auto simp: sets_PiM)
   911     also have "emeasure ?B ?X = (\<Prod>i\<in>I. emeasure (M i) (F i)) * (\<Prod>i\<in>J. emeasure (M i) (F i))"
   912       using `finite J` `finite I` F unfolding X
   913       by (simp add: J.emeasure_pair_measure_Times I.measure_times J.measure_times)
   914     also have "\<dots> = (\<Prod>i\<in>I \<union> J. emeasure (M i) (F i))"
   915       using `finite J` `finite I` `I \<inter> J = {}`  by (simp add: setprod.union_inter_neutral)
   916     also have "\<dots> = emeasure ?P (Pi\<^sub>E (I \<union> J) F)"
   917       using `finite J` `finite I` F unfolding A
   918       by (intro IJ.measure_times[symmetric]) auto
   919     finally show "emeasure ?P A = emeasure ?D A" using A_eq by simp
   920   qed
   921 qed
   922 
   923 lemma (in product_sigma_finite) product_nn_integral_fold:
   924   assumes IJ: "I \<inter> J = {}" "finite I" "finite J"
   925   and f: "f \<in> borel_measurable (Pi\<^sub>M (I \<union> J) M)"
   926   shows "integral\<^sup>N (Pi\<^sub>M (I \<union> J) M) f =
   927     (\<integral>\<^sup>+ x. (\<integral>\<^sup>+ y. f (merge I J (x, y)) \<partial>(Pi\<^sub>M J M)) \<partial>(Pi\<^sub>M I M))"
   928 proof -
   929   interpret I: finite_product_sigma_finite M I by default fact
   930   interpret J: finite_product_sigma_finite M J by default fact
   931   interpret P: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" by default
   932   have P_borel: "(\<lambda>x. f (merge I J x)) \<in> borel_measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
   933     using measurable_comp[OF measurable_merge f] by (simp add: comp_def)
   934   show ?thesis
   935     apply (subst distr_merge[OF IJ, symmetric])
   936     apply (subst nn_integral_distr[OF measurable_merge f])
   937     apply (subst J.nn_integral_fst[symmetric, OF P_borel])
   938     apply simp
   939     done
   940 qed
   941 
   942 lemma (in product_sigma_finite) distr_singleton:
   943   "distr (Pi\<^sub>M {i} M) (M i) (\<lambda>x. x i) = M i" (is "?D = _")
   944 proof (intro measure_eqI[symmetric])
   945   interpret I: finite_product_sigma_finite M "{i}" by default simp
   946   fix A assume A: "A \<in> sets (M i)"
   947   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M {i} M) = (\<Pi>\<^sub>E i\<in>{i}. A)"
   948     using sets.sets_into_space by (auto simp: space_PiM)
   949   then show "emeasure (M i) A = emeasure ?D A"
   950     using A I.measure_times[of "\<lambda>_. A"]
   951     by (simp add: emeasure_distr measurable_component_singleton)
   952 qed simp
   953 
   954 lemma (in product_sigma_finite) product_nn_integral_singleton:
   955   assumes f: "f \<in> borel_measurable (M i)"
   956   shows "integral\<^sup>N (Pi\<^sub>M {i} M) (\<lambda>x. f (x i)) = integral\<^sup>N (M i) f"
   957 proof -
   958   interpret I: finite_product_sigma_finite M "{i}" by default simp
   959   from f show ?thesis
   960     apply (subst distr_singleton[symmetric])
   961     apply (subst nn_integral_distr[OF measurable_component_singleton])
   962     apply simp_all
   963     done
   964 qed
   965 
   966 lemma (in product_sigma_finite) product_nn_integral_insert:
   967   assumes I[simp]: "finite I" "i \<notin> I"
   968     and f: "f \<in> borel_measurable (Pi\<^sub>M (insert i I) M)"
   969   shows "integral\<^sup>N (Pi\<^sub>M (insert i I) M) f = (\<integral>\<^sup>+ x. (\<integral>\<^sup>+ y. f (x(i := y)) \<partial>(M i)) \<partial>(Pi\<^sub>M I M))"
   970 proof -
   971   interpret I: finite_product_sigma_finite M I by default auto
   972   interpret i: finite_product_sigma_finite M "{i}" by default auto
   973   have IJ: "I \<inter> {i} = {}" and insert: "I \<union> {i} = insert i I"
   974     using f by auto
   975   show ?thesis
   976     unfolding product_nn_integral_fold[OF IJ, unfolded insert, OF I(1) i.finite_index f]
   977   proof (rule nn_integral_cong, subst product_nn_integral_singleton[symmetric])
   978     fix x assume x: "x \<in> space (Pi\<^sub>M I M)"
   979     let ?f = "\<lambda>y. f (x(i := y))"
   980     show "?f \<in> borel_measurable (M i)"
   981       using measurable_comp[OF measurable_component_update f, OF x `i \<notin> I`]
   982       unfolding comp_def .
   983     show "(\<integral>\<^sup>+ y. f (merge I {i} (x, y)) \<partial>Pi\<^sub>M {i} M) = (\<integral>\<^sup>+ y. f (x(i := y i)) \<partial>Pi\<^sub>M {i} M)"
   984       using x
   985       by (auto intro!: nn_integral_cong arg_cong[where f=f]
   986                simp add: space_PiM extensional_def PiE_def)
   987   qed
   988 qed
   989 
   990 lemma (in product_sigma_finite) product_nn_integral_insert_rev:
   991   assumes I[simp]: "finite I" "i \<notin> I"
   992     and [measurable]: "f \<in> borel_measurable (Pi\<^sub>M (insert i I) M)"
   993   shows "integral\<^sup>N (Pi\<^sub>M (insert i I) M) f = (\<integral>\<^sup>+ y. (\<integral>\<^sup>+ x. f (x(i := y)) \<partial>(Pi\<^sub>M I M)) \<partial>(M i))"
   994   apply (subst product_nn_integral_insert[OF assms])
   995   apply (rule pair_sigma_finite.Fubini')
   996   apply intro_locales []
   997   apply (rule sigma_finite[OF I(1)])
   998   apply measurable
   999   done
  1000 
  1001 lemma (in product_sigma_finite) product_nn_integral_setprod:
  1002   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> ereal"
  1003   assumes "finite I" and borel: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> borel_measurable (M i)"
  1004   and pos: "\<And>i x. i \<in> I \<Longrightarrow> 0 \<le> f i x"
  1005   shows "(\<integral>\<^sup>+ x. (\<Prod>i\<in>I. f i (x i)) \<partial>Pi\<^sub>M I M) = (\<Prod>i\<in>I. integral\<^sup>N (M i) (f i))"
  1006 using assms proof induct
  1007   case (insert i I)
  1008   note `finite I`[intro, simp]
  1009   interpret I: finite_product_sigma_finite M I by default auto
  1010   have *: "\<And>x y. (\<Prod>j\<in>I. f j (if j = i then y else x j)) = (\<Prod>j\<in>I. f j (x j))"
  1011     using insert by (auto intro!: setprod.cong)
  1012   have prod: "\<And>J. J \<subseteq> insert i I \<Longrightarrow> (\<lambda>x. (\<Prod>i\<in>J. f i (x i))) \<in> borel_measurable (Pi\<^sub>M J M)"
  1013     using sets.sets_into_space insert
  1014     by (intro borel_measurable_ereal_setprod
  1015               measurable_comp[OF measurable_component_singleton, unfolded comp_def])
  1016        auto
  1017   then show ?case
  1018     apply (simp add: product_nn_integral_insert[OF insert(1,2) prod])
  1019     apply (simp add: insert(2-) * pos borel setprod_ereal_pos nn_integral_multc)
  1020     apply (subst nn_integral_cmult)
  1021     apply (auto simp add: pos borel insert(2-) setprod_ereal_pos nn_integral_nonneg)
  1022     done
  1023 qed (simp add: space_PiM)
  1024 
  1025 lemma (in product_sigma_finite) product_nn_integral_pair:
  1026   assumes [measurable]: "split f \<in> borel_measurable (M x \<Otimes>\<^sub>M M y)"
  1027   assumes xy: "x \<noteq> y"
  1028   shows "(\<integral>\<^sup>+\<sigma>. f (\<sigma> x) (\<sigma> y) \<partial>PiM {x, y} M) = (\<integral>\<^sup>+z. f (fst z) (snd z) \<partial>(M x \<Otimes>\<^sub>M M y))"
  1029 proof-
  1030   interpret psm: pair_sigma_finite "M x" "M y"
  1031     unfolding pair_sigma_finite_def using sigma_finite_measures by simp_all
  1032   have "{x, y} = {y, x}" by auto
  1033   also have "(\<integral>\<^sup>+\<sigma>. f (\<sigma> x) (\<sigma> y) \<partial>PiM {y, x} M) = (\<integral>\<^sup>+y. \<integral>\<^sup>+\<sigma>. f (\<sigma> x) y \<partial>PiM {x} M \<partial>M y)"
  1034     using xy by (subst product_nn_integral_insert_rev) simp_all
  1035   also have "... = (\<integral>\<^sup>+y. \<integral>\<^sup>+x. f x y \<partial>M x \<partial>M y)"
  1036     by (intro nn_integral_cong, subst product_nn_integral_singleton) simp_all
  1037   also have "... = (\<integral>\<^sup>+z. f (fst z) (snd z) \<partial>(M x \<Otimes>\<^sub>M M y))"
  1038     by (subst psm.nn_integral_snd[symmetric]) simp_all
  1039   finally show ?thesis .
  1040 qed
  1041 
  1042 lemma (in product_sigma_finite) distr_component:
  1043   "distr (M i) (Pi\<^sub>M {i} M) (\<lambda>x. \<lambda>i\<in>{i}. x) = Pi\<^sub>M {i} M" (is "?D = ?P")
  1044 proof (intro measure_eqI[symmetric])
  1045   interpret I: finite_product_sigma_finite M "{i}" by default simp
  1046 
  1047   have eq: "\<And>x. x \<in> extensional {i} \<Longrightarrow> (\<lambda>j\<in>{i}. x i) = x"
  1048     by (auto simp: extensional_def restrict_def)
  1049 
  1050   have [measurable]: "\<And>j. j \<in> {i} \<Longrightarrow> (\<lambda>x. x) \<in> measurable (M i) (M j)" by simp
  1051 
  1052   fix A assume A: "A \<in> sets ?P"
  1053   then have "emeasure ?P A = (\<integral>\<^sup>+x. indicator A x \<partial>?P)" 
  1054     by simp
  1055   also have "\<dots> = (\<integral>\<^sup>+x. indicator ((\<lambda>x. \<lambda>i\<in>{i}. x) -` A \<inter> space (M i)) (x i) \<partial>PiM {i} M)" 
  1056     by (intro nn_integral_cong) (auto simp: space_PiM indicator_def PiE_def eq)
  1057   also have "\<dots> = emeasure ?D A"
  1058     using A by (simp add: product_nn_integral_singleton emeasure_distr)
  1059   finally show "emeasure (Pi\<^sub>M {i} M) A = emeasure ?D A" .
  1060 qed simp
  1061 
  1062 lemma (in product_sigma_finite)
  1063   assumes IJ: "I \<inter> J = {}" "finite I" "finite J" and A: "A \<in> sets (Pi\<^sub>M (I \<union> J) M)"
  1064   shows emeasure_fold_integral:
  1065     "emeasure (Pi\<^sub>M (I \<union> J) M) A = (\<integral>\<^sup>+x. emeasure (Pi\<^sub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^sub>M J M)) \<partial>Pi\<^sub>M I M)" (is ?I)
  1066     and emeasure_fold_measurable:
  1067     "(\<lambda>x. emeasure (Pi\<^sub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^sub>M J M))) \<in> borel_measurable (Pi\<^sub>M I M)" (is ?B)
  1068 proof -
  1069   interpret I: finite_product_sigma_finite M I by default fact
  1070   interpret J: finite_product_sigma_finite M J by default fact
  1071   interpret IJ: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" ..
  1072   have merge: "merge I J -` A \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) \<in> sets (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
  1073     by (intro measurable_sets[OF _ A] measurable_merge assms)
  1074 
  1075   show ?I
  1076     apply (subst distr_merge[symmetric, OF IJ])
  1077     apply (subst emeasure_distr[OF measurable_merge A])
  1078     apply (subst J.emeasure_pair_measure_alt[OF merge])
  1079     apply (auto intro!: nn_integral_cong arg_cong2[where f=emeasure] simp: space_pair_measure)
  1080     done
  1081 
  1082   show ?B
  1083     using IJ.measurable_emeasure_Pair1[OF merge]
  1084     by (simp add: vimage_comp comp_def space_pair_measure cong: measurable_cong)
  1085 qed
  1086 
  1087 lemma sets_Collect_single:
  1088   "i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> { x \<in> space (Pi\<^sub>M I M). x i \<in> A } \<in> sets (Pi\<^sub>M I M)"
  1089   by simp
  1090 
  1091 lemma pair_measure_eq_distr_PiM:
  1092   fixes M1 :: "'a measure" and M2 :: "'a measure"
  1093   assumes "sigma_finite_measure M1" "sigma_finite_measure M2"
  1094   shows "(M1 \<Otimes>\<^sub>M M2) = distr (Pi\<^sub>M UNIV (case_bool M1 M2)) (M1 \<Otimes>\<^sub>M M2) (\<lambda>x. (x True, x False))"
  1095     (is "?P = ?D")
  1096 proof (rule pair_measure_eqI[OF assms])
  1097   interpret B: product_sigma_finite "case_bool M1 M2"
  1098     unfolding product_sigma_finite_def using assms by (auto split: bool.split)
  1099   let ?B = "Pi\<^sub>M UNIV (case_bool M1 M2)"
  1100 
  1101   have [simp]: "fst \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x True)" "snd \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x False)"
  1102     by auto
  1103   fix A B assume A: "A \<in> sets M1" and B: "B \<in> sets M2"
  1104   have "emeasure M1 A * emeasure M2 B = (\<Prod> i\<in>UNIV. emeasure (case_bool M1 M2 i) (case_bool A B i))"
  1105     by (simp add: UNIV_bool ac_simps)
  1106   also have "\<dots> = emeasure ?B (Pi\<^sub>E UNIV (case_bool A B))"
  1107     using A B by (subst B.emeasure_PiM) (auto split: bool.split)
  1108   also have "Pi\<^sub>E UNIV (case_bool A B) = (\<lambda>x. (x True, x False)) -` (A \<times> B) \<inter> space ?B"
  1109     using A[THEN sets.sets_into_space] B[THEN sets.sets_into_space]
  1110     by (auto simp: PiE_iff all_bool_eq space_PiM split: bool.split)
  1111   finally show "emeasure M1 A * emeasure M2 B = emeasure ?D (A \<times> B)"
  1112     using A B
  1113       measurable_component_singleton[of True UNIV "case_bool M1 M2"]
  1114       measurable_component_singleton[of False UNIV "case_bool M1 M2"]
  1115     by (subst emeasure_distr) (auto simp: measurable_pair_iff)
  1116 qed simp
  1117 
  1118 end